qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 .float prevstrengthsound;
 131 .float prevstrengthsoundattempt;
 132 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 133 {
 134                 if((!g_minstagib)
 135                         && (player.items & IT_STRENGTH)
 136                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 137                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 138                 {
 139                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 140                         player.prevstrengthsound = time;
 141                 }
 142                 player.prevstrengthsoundattempt = time;
 143 }
 144
 145 // this function calculates w_shotorg and w_shotdir based on the weapon model
 146 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 147 // make sure you call makevectors first (FIXME?)
 148 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 149 {
 150         float nudge = 1; // added to traceline target and subtracted from result
 151         float oldsolid;
 152         vector vecs, dv;
 153         oldsolid = ent.dphitcontentsmask;
 154         if(ent.weapon == WEP_RIFLE)
 155                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 156         else
 157                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 158         if(antilag)
 159                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 160                 // passing world, because we do NOT want it to touch dphitcontentsmask
 161         else
 162                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 163         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 164
 165         vector vf, vr, vu;
 166         vf = v_forward;
 167         vr = v_right;
 168         vu = v_up;
 169         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 170         v_forward = vf;
 171         v_right = vr;
 172         v_up = vu;
 173
 174         // un-adjust trueaim if shotend is too close
 175         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 176                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 177
 178         // track max damage
 179         if(accuracy_canbegooddamage(ent))
 180                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 181
 182         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 183
 184         if(ent.weaponentity.movedir_x > 0)
 185                 vecs = ent.weaponentity.movedir;
 186         else
 187                 vecs = '0 0 0';
 188
 189         dv = v_right * -vecs_y + v_up * vecs_z;
 190         w_shotorg = ent.origin + ent.view_ofs + dv;
 191
 192         // now move the shotorg forward as much as requested if possible
 193         if(antilag)
 194         {
 195                 if(ent.antilag_debug)
 196                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 197                 else
 198                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 199         }
 200         else
 201                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 202         w_shotorg = trace_endpos - v_forward * nudge;
 203         // calculate the shotdir from the chosen shotorg
 204         w_shotdir = normalize(w_shotend - w_shotorg);
 205
 206         if (antilag)
 207         if (!ent.cvar_cl_noantilag)
 208         {
 209                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 210                 {
 211                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 212                         if (!trace_ent.takedamage)
 213                         {
 214                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 215                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 216                                 {
 217                                         entity e;
 218                                         e = trace_ent;
 219                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 220                                         if(trace_ent == e)
 221                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 222                                 }
 223                         }
 224                 }
 225                 else if(autocvar_g_antilag == 3) // client side hitscan
 226                 {
 227                         // this part MUST use prydon cursor
 228                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 229                         if (ent.cursor_trace_ent != ent)         // just to make sure
 230                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 231                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 232                         {
 233                                 // verify that the shot would miss without antilag
 234                                 // (avoids an issue where guns would always shoot at their origin)
 235                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 236                                 if (!trace_ent.takedamage)
 237                                 {
 238                                         // verify that the shot would hit if altered
 239                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 240                                         if (trace_ent == ent.cursor_trace_ent)
 241                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 242                                         else
 243                                                 print("antilag fail\n");
 244                                 }
 245                         }
 246                 }
 247         }
 248
 249         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 250
 251         if (!g_norecoil)
 252                 ent.punchangle_x = recoil * -1;
 253
 254         if (snd != "")
 255         {
 256                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 257                 W_PlayStrengthSound(ent);
 258         }
 259
 260         // nudge w_shotend so a trace to w_shotend hits
 261         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 262 }
 263
 264 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 265 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 266 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 268 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 269
 270 float CL_Weaponentity_CustomizeEntityForClient()
 271 {
 272         self.viewmodelforclient = self.owner;
 273         if(other.classname == "spectator")
 274                 if(other.enemy == self.owner)
 275                         self.viewmodelforclient = other;
 276         return TRUE;
 277 }
 278
 279 /*
 280  * supported formats:
 281  *
 282  * 1. simple animated model, muzzle flash handling on h_ model:
 283  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 284  *      tags:
 285  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 286  *        shell = casings ejection point (must be on the right hand side of the gun)
 287  *        weapon = attachment for v_tuba.md3
 288  *    v_tuba.md3 - first and third person model
 289  *    g_tuba.md3 - pickup model
 290  *
 291  * 2. simple animated model, muzzle flash handling on v_ model:
 292  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 293  *      tags:
 294  *        weapon = attachment for v_tuba.md3
 295  *    v_tuba.md3 - first and third person model
 296  *      tags:
 297  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 298  *        shell = casings ejection point (must be on the right hand side of the gun)
 299  *    g_tuba.md3 - pickup model
 300  *
 301  * 3. fully animated model, muzzle flash handling on h_ model:
 302  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 303  *      tags:
 304  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 305  *        shell = casings ejection point (must be on the right hand side of the gun)
 306  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 307  *    v_tuba.md3 - third person model
 308  *    g_tuba.md3 - pickup model
 309  *
 310  * 4. fully animated model, muzzle flash handling on v_ model:
 311  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 312  *      tags:
 313  *        shot = muzzle end (shot origin)
 314  *        shell = casings ejection point (must be on the right hand side of the gun)
 315  *    v_tuba.md3 - third person model
 316  *      tags:
 317  *        shot = muzzle end (for muzzle flashes)
 318  *    g_tuba.md3 - pickup model
 319  */
 320
 321 // writes:
 322 //   self.origin, self.angles
 323 //   self.weaponentity
 324 //   self.movedir, self.view_ofs
 325 //   attachment stuff
 326 //   anim stuff
 327 // to free:
 328 //   call again with ""
 329 //   remove the ent
 330 void CL_WeaponEntity_SetModel(string name)
 331 {
 332         float v_shot_idx;
 333         if (name != "")
 334         {
 335                 // if there is a child entity, hide it until we're sure we use it
 336                 if (self.weaponentity)
 337                         self.weaponentity.model = "";
 338                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 339                 v_shot_idx = gettagindex(self, "shot"); // used later
 340                 if(!v_shot_idx)
 341                         v_shot_idx = gettagindex(self, "tag_shot");
 342
 343                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 344                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 345                 self.anim_fire1  = animfixfps(self, '0 1 0.01');
 346                 self.anim_fire2  = animfixfps(self, '1 1 0.01');
 347                 self.anim_idle   = animfixfps(self, '2 1 0.01');
 348                 self.anim_reload = animfixfps(self, '3 1 0.01');
 349
 350                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 351                 // if we don't, this is a "real" animated model
 352                 if(gettagindex(self, "weapon"))
 353                 {
 354                         if (!self.weaponentity)
 355                                 self.weaponentity = spawn();
 356                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 357                         setattachment(self.weaponentity, self, "weapon");
 358                 }
 359                 else if(gettagindex(self, "tag_weapon"))
 360                 {
 361                         if (!self.weaponentity)
 362                                 self.weaponentity = spawn();
 363                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 364                         setattachment(self.weaponentity, self, "tag_weapon");
 365                 }
 366                 else
 367                 {
 368                         if(self.weaponentity)
 369                                 remove(self.weaponentity);
 370                         self.weaponentity = world;
 371                 }
 372
 373                 setorigin(self,'0 0 0');
 374                 self.angles = '0 0 0';
 375                 self.frame = 0;
 376                 self.viewmodelforclient = world;
 377
 378                 float idx;
 379
 380                 if(v_shot_idx) // v_ model attached to invisible h_ model
 381                 {
 382                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 383                 }
 384                 else
 385                 {
 386                         idx = gettagindex(self, "shot");
 387                         if(!idx)
 388                                 idx = gettagindex(self, "tag_shot");
 389                         if(idx)
 390                                 self.movedir = gettaginfo(self, idx);
 391                         else
 392                         {
 393                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 394                                 self.movedir = '0 0 0';
 395                         }
 396                 }
 397
 398                 if(self.weaponentity) // v_ model attached to invisible h_ model
 399                 {
 400                         idx = gettagindex(self.weaponentity, "shell");
 401                         if(!idx)
 402                                 idx = gettagindex(self.weaponentity, "tag_shell");
 403                         if(idx)
 404                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 405                 }
 406                 else
 407                         idx = 0;
 408                 if(!idx)
 409                 {
 410                         idx = gettagindex(self, "shell");
 411                         if(!idx)
 412                                 idx = gettagindex(self, "tag_shell");
 413                         if(idx)
 414                                 self.spawnorigin = gettaginfo(self, idx);
 415                         else
 416                         {
 417                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 418                                 self.spawnorigin = self.movedir;
 419                         }
 420                 }
 421
 422                 if(v_shot_idx)
 423                 {
 424                         self.oldorigin = '0 0 0'; // use regular attachment
 425                 }
 426                 else
 427                 {
 428                         if(self.weaponentity)
 429                         {
 430                                 idx = gettagindex(self, "weapon");
 431                                 if(!idx)
 432                                         idx = gettagindex(self, "tag_weapon");
 433                         }
 434                         else
 435                         {
 436                                 idx = gettagindex(self, "handle");
 437                                 if(!idx)
 438                                         idx = gettagindex(self, "tag_handle");
 439                         }
 440                         if(idx)
 441                         {
 442                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 443                         }
 444                         else
 445                         {
 446                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 447                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 448                         }
 449                 }
 450
 451                 self.viewmodelforclient = self.owner;
 452         }
 453         else
 454         {
 455                 self.model = "";
 456                 if(self.weaponentity)
 457                         remove(self.weaponentity);
 458                 self.weaponentity = world;
 459                 self.movedir = '0 0 0';
 460                 self.spawnorigin = '0 0 0';
 461                 self.oldorigin = '0 0 0';
 462                 self.anim_fire1  = '0 1 0.01';
 463                 self.anim_fire2  = '0 1 0.01';
 464                 self.anim_idle   = '0 1 0.01';
 465                 self.anim_reload = '0 1 0.01';
 466         }
 467
 468         self.view_ofs = '0 0 0';
 469
 470         if(self.movedir_x >= 0)
 471         {
 472                 vector v0;
 473                 v0 = self.movedir;
 474                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 475                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 476         }
 477         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 478         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 479
 480         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 481
 482         // check if an instant weapon switch occurred
 483         setorigin(self, self.view_ofs);
 484         // reset animstate now
 485         self.wframe = WFRAME_IDLE;
 486         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 487 }
 488
 489 vector CL_Weapon_GetShotOrg(float wpn)
 490 {
 491         entity wi, oldself;
 492         vector ret;
 493         wi = get_weaponinfo(wpn);
 494         oldself = self;
 495         self = spawn();
 496         CL_WeaponEntity_SetModel(wi.mdl);
 497         ret = self.movedir;
 498         CL_WeaponEntity_SetModel("");
 499         remove(self);
 500         self = oldself;
 501         return ret;
 502 }
 503
 504 void CL_Weaponentity_Think()
 505 {
 506         float tb;
 507         self.nextthink = time;
 508         if (intermission_running)
 509                 self.frame = self.anim_idle_x;
 510         if (self.owner.weaponentity != self)
 511         {
 512                 if (self.weaponentity)
 513                         remove(self.weaponentity);
 514                 remove(self);
 515                 return;
 516         }
 517         if (self.owner.deadflag != DEAD_NO)
 518         {
 519                 self.model = "";
 520                 if (self.weaponentity)
 521                         self.weaponentity.model = "";
 522                 return;
 523         }
 524         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 525         {
 526                 self.weaponname = self.owner.weaponname;
 527                 self.dmg = self.owner.modelindex;
 528                 self.deadflag = self.owner.deadflag;
 529
 530                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 531         }
 532
 533         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 534         self.effects = self.owner.effects & EFMASK_CHEAP;
 535         self.effects &~= EF_LOWPRECISION;
 536         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 537         self.effects &~= EF_TELEPORT_BIT;
 538         self.effects &~= EF_RESTARTANIM_BIT;
 539         self.effects |= tb;
 540
 541         if(self.owner.alpha == default_player_alpha)
 542                 self.alpha = default_weapon_alpha;
 543         else if(self.owner.alpha != 0)
 544                 self.alpha = self.owner.alpha;
 545         else
 546                 self.alpha = 1;
 547
 548         self.glowmod = self.owner.weaponentity_glowmod;
 549         self.colormap = self.owner.colormap;
 550         if (self.weaponentity)
 551         {
 552                 self.weaponentity.effects = self.effects;
 553                 self.weaponentity.alpha = self.alpha;
 554                 self.weaponentity.colormap = self.colormap;
 555                 self.weaponentity.glowmod = self.glowmod;
 556         }
 557
 558         self.angles = '0 0 0';
 559         float f;
 560         f = 0;
 561         if (self.state == WS_RAISE && !intermission_running)
 562         {
 563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 564                 self.angles_x = -90 * f * f;
 565         }
 566         else if (self.state == WS_DROP && !intermission_running)
 567         {
 568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 569                 self.angles_x = -90 * f * f;
 570         }
 571         else if (self.state == WS_CLEAR)
 572         {
 573                 f = 1;
 574                 self.angles_x = -90 * f * f;
 575         }
 576 }
 577
 578 void CL_ExteriorWeaponentity_Think()
 579 {
 580         float tag_found;
 581         vector ang;
 582         self.nextthink = time;
 583         if (self.owner.exteriorweaponentity != self)
 584         {
 585                 remove(self);
 586                 return;
 587         }
 588         if (self.owner.deadflag != DEAD_NO)
 589         {
 590                 self.model = "";
 591                 return;
 592         }
 593         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 594         {
 595                 self.weaponname = self.owner.weaponname;
 596                 self.dmg = self.owner.modelindex;
 597                 self.deadflag = self.owner.deadflag;
 598                 if (self.owner.weaponname != "")
 599                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 600                 else
 601                         self.model = "";
 602
 603                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 604                 {
 605                         self.tag_index = tag_found;
 606                         self.tag_entity = self.owner;
 607                 }
 608                 else
 609                         setattachment(self, self.owner, "bip01 r hand");
 610
 611                 // if that didn't find a tag, hide the exterior weapon model
 612                 if (!self.tag_index)
 613                         self.model = "";
 614         }
 615         self.effects = self.owner.effects;
 616         if(sv_pitch_min == sv_pitch_max)
 617                 self.effects |= EF_LOWPRECISION;
 618         else
 619                 self.effects &~= EF_LOWPRECISION;
 620         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 621         if(self.owner.alpha == default_player_alpha)
 622                 self.alpha = default_weapon_alpha;
 623         else if(self.owner.alpha != 0)
 624                 self.alpha = self.owner.alpha;
 625         else
 626                 self.alpha = 1;
 627
 628         if (!intermission_running)
 629         {
 630                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 631                 ang_y = 0;
 632                 ang_z = 0;
 633
 634                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 635                 {
 636                         ang_y = self.owner.v_angle_y;
 637                         makevectors(ang);
 638                         var vector v = v_forward;
 639                         var float t = self.tag_entity.frame1time;
 640                         var float f = self.tag_entity.frame;
 641                         self.tag_entity.frame1time = time;
 642                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 643                         gettaginfo(self.tag_entity, self.tag_index);
 644                         self.tag_entity.frame1time = t;
 645                         self.tag_entity.frame = f;
 646                         // untransform v according to this coordinate space
 647                         vector w;
 648                         w_x = v_forward * v;
 649                         w_y = -v_right * v;
 650                         w_z = v_up * v;
 651                         self.angles = vectoangles(w);
 652                 }
 653                 else
 654                 {
 655                         ang_x = -/* don't ask */ang_x;
 656                         self.angles = ang;
 657                 }
 658
 659                 if(autocvar_g_loituma)
 660                 {
 661                         vector modangles;
 662                         float t;
 663
 664                         t = time * autocvar_g_loituma;
 665
 666                         modangles_x = t * 360;
 667                         modangles_y = 90;
 668                         modangles_z = 0;
 669
 670                         self.angles =
 671                                 AnglesTransform_ToAngles(
 672                                         AnglesTransform_Multiply(
 673                                                 AnglesTransform_FromAngles(self.angles),
 674                                                 AnglesTransform_FromAngles(modangles)
 675                                         )
 676                                 );
 677                 }
 678         }
 679
 680         self.glowmod = self.owner.weaponentity_glowmod;
 681         self.colormap = self.owner.colormap;
 682
 683         CSQCMODEL_AUTOUPDATE();
 684 }
 685
 686 // spawning weaponentity for client
 687 void CL_SpawnWeaponentity()
 688 {
 689         self.weaponentity = spawn();
 690         self.weaponentity.classname = "weaponentity";
 691         self.weaponentity.solid = SOLID_NOT;
 692         self.weaponentity.owner = self;
 693         setmodel(self.weaponentity, ""); // precision set when changed
 694         setorigin(self.weaponentity, '0 0 0');
 695         self.weaponentity.angles = '0 0 0';
 696         self.weaponentity.viewmodelforclient = self;
 697         self.weaponentity.flags = 0;
 698         self.weaponentity.think = CL_Weaponentity_Think;
 699         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 700         self.weaponentity.nextthink = time;
 701
 702         self.exteriorweaponentity = spawn();
 703         self.exteriorweaponentity.classname = "exteriorweaponentity";
 704         self.exteriorweaponentity.solid = SOLID_NOT;
 705         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 706         self.exteriorweaponentity.owner = self;
 707         setorigin(self.exteriorweaponentity, '0 0 0');
 708         self.exteriorweaponentity.angles = '0 0 0';
 709         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 710         self.exteriorweaponentity.nextthink = time;
 711
 712         {
 713                 entity oldself = self;
 714                 self = self.exteriorweaponentity;
 715                 CSQCMODEL_AUTOINIT();
 716                 self = oldself;
 717         }
 718 }
 719
 720 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 721 {
 722         msg_entity = e;
 723         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 724         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 725         WriteByte(MSG_ONE, wpn);
 726         WriteString(MSG_ONE, wpnname);
 727         WriteByte(MSG_ONE, type);
 728 }
 729
 730 .float hasweapon_complain_spam;
 731
 732 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 733 {
 734         float weaponbit, f;
 735         entity oldself;
 736
 737         if(time < self.hasweapon_complain_spam)
 738                 complain = 0;
 739         if(complain)
 740                 self.hasweapon_complain_spam = time + 0.2;
 741
 742         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 743         {
 744                 if (complain)
 745                         sprint(self, "Invalid weapon\n");
 746                 return FALSE;
 747         }
 748         weaponbit = W_WeaponBit(wpn);
 749         if (cl.weapons & weaponbit)
 750         {
 751                 if (andammo)
 752                 {
 753                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 754                         {
 755                                 f = 1;
 756                         }
 757                         else
 758                         {
 759                                 oldself = self;
 760                                 self = cl;
 761                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 762                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 763
 764                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 765                                 entity mine;
 766                                 if(wpn == WEP_MINE_LAYER)
 767                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 768                                         f = 1;
 769
 770                                 self = oldself;
 771                         }
 772                         if (!f)
 773                         {
 774                                 if (complain)
 775                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 776                                 {
 777                                         play2(cl, "weapons/unavailable.wav");
 778                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 779                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 780                                 }
 781                                 return FALSE;
 782                         }
 783                 }
 784                 return TRUE;
 785         }
 786         if (complain)
 787         {
 788                 // DRESK - 3/16/07
 789                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 790                 if(weaponsInMap & weaponbit)
 791                 {
 792                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 793                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 794
 795                         if(autocvar_g_showweaponspawns)
 796                         {
 797                                 entity e;
 798                                 string s;
 799
 800                                 e = get_weaponinfo(wpn);
 801                                 s = e.model2;
 802
 803                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 804                                 {
 805                                         if(e.classname == "droppedweapon")
 806                                                 continue;
 807                                         if not(e.flags & FL_ITEM)
 808                                                 continue;
 809                                         WaypointSprite_Spawn(
 810                                                 s,
 811                                                 1, 0,
 812                                                 world, e.origin,
 813                                                 self, 0,
 814                                                 world, enemy,
 815                                                 0,
 816                                                 RADARICON_NONE, '0 0 0'
 817                                         );
 818                                 }
 819                         }
 820                 }
 821                 else
 822                 {
 823                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 824                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 825                 }
 826
 827                 play2(cl, "weapons/unavailable.wav");
 828         }
 829         return FALSE;
 830 }
 831
 832 // Weapon subs
 833 void w_clear()
 834 {
 835         if (self.weapon != -1)
 836         {
 837                 self.weapon = 0;
 838                 self.switchingweapon = 0;
 839         }
 840         if (self.weaponentity)
 841         {
 842                 self.weaponentity.state = WS_CLEAR;
 843                 self.weaponentity.effects = 0;
 844         }
 845 }
 846
 847 void w_ready()
 848 {
 849         if (self.weaponentity)
 850                 self.weaponentity.state = WS_READY;
 851         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 852 }
 853
 854 // Setup weapon for client (after this raise frame will be launched)
 855 void weapon_setup(float windex)
 856 {
 857         entity e;
 858         e = get_weaponinfo(windex);
 859         self.items &~= IT_AMMO;
 860         self.items = self.items | e.items;
 861
 862         // the two weapon entities will notice this has changed and update their models
 863         self.weapon = windex;
 864         self.switchingweapon = windex; // to make sure
 865         self.weaponname = e.mdl;
 866         self.bulletcounter = 0;
 867 }
 868
 869 // perform weapon to attack (weaponstate and attack_finished check is here)
 870 void W_SwitchToOtherWeapon(entity pl)
 871 {
 872         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 873         float w, ww;
 874         w = W_WeaponBit(pl.weapon);
 875         pl.weapons &~= w;
 876         ww = w_getbestweapon(pl);
 877         pl.weapons |= w;
 878         if(ww)
 879                 W_SwitchWeapon_Force(pl, ww);
 880 }
 881 .float prevdryfire;
 882 float weapon_prepareattack_checkammo(float secondary)
 883 {
 884         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 885         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 886         {
 887                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 888                 entity mine;
 889                 if(self.weapon == WEP_MINE_LAYER)
 890                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 891                         return FALSE;
 892
 893                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 894                 {
 895                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 896                         self.prevdryfire = time;
 897                 }
 898
 899                 W_SwitchToOtherWeapon(self);
 900                 return FALSE;
 901         }
 902         return TRUE;
 903 }
 904 .float race_penalty;
 905 float weapon_prepareattack_check(float secondary, float attacktime)
 906 {
 907         if(!weapon_prepareattack_checkammo(secondary))
 908                 return FALSE;
 909
 910         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 911         //if all players readied up and the countdown is running
 912         if(time < game_starttime || time < self.race_penalty) {
 913                 return FALSE;
 914         }
 915
 916         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 917                 return FALSE;
 918
 919         // do not even think about shooting if switching
 920         if(self.switchweapon != self.weapon)
 921                 return FALSE;
 922
 923         if(attacktime >= 0)
 924         {
 925                 // don't fire if previous attack is not finished
 926                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 927                         return FALSE;
 928                 // don't fire while changing weapon
 929                 if (self.weaponentity.state != WS_READY)
 930                         return FALSE;
 931         }
 932
 933         return TRUE;
 934 }
 935 float weapon_prepareattack_do(float secondary, float attacktime)
 936 {
 937         self.weaponentity.state = WS_INUSE;
 938
 939         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 940
 941         // if the weapon hasn't been firing continuously, reset the timer
 942         if(attacktime >= 0)
 943         {
 944                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 945                 {
 946                         ATTACK_FINISHED(self) = time;
 947                         //dprint("resetting attack finished to ", ftos(time), "\n");
 948                 }
 949                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 950         }
 951         self.bulletcounter += 1;
 952         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 953         return TRUE;
 954 }
 955 float weapon_prepareattack(float secondary, float attacktime)
 956 {
 957         if(weapon_prepareattack_check(secondary, attacktime))
 958         {
 959                 weapon_prepareattack_do(secondary, attacktime);
 960                 return TRUE;
 961         }
 962         else
 963                 return FALSE;
 964 }
 965
 966 void weapon_thinkf(float fr, float t, void() func)
 967 {
 968         vector a;
 969         vector of, or, ou;
 970         float restartanim;
 971
 972         if(fr == WFRAME_DONTCHANGE)
 973         {
 974                 fr = self.weaponentity.wframe;
 975                 restartanim = FALSE;
 976         }
 977         else if (fr == WFRAME_IDLE)
 978                 restartanim = FALSE;
 979         else
 980                 restartanim = TRUE;
 981
 982         of = v_forward;
 983         or = v_right;
 984         ou = v_up;
 985
 986         if (self.weaponentity)
 987         {
 988                 self.weaponentity.wframe = fr;
 989                 if (fr == WFRAME_IDLE)
 990                         a = self.weaponentity.anim_idle;
 991                 else if (fr == WFRAME_FIRE1)
 992                         a = self.weaponentity.anim_fire1;
 993                 else if (fr == WFRAME_FIRE2)
 994                         a = self.weaponentity.anim_fire2;
 995                 else if (fr == WFRAME_RELOAD)
 996                         a = self.weaponentity.anim_reload;
 997                 a_z *= g_weaponratefactor;
 998                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 999         }
1000
1001         v_forward = of;
1002         v_right = or;
1003         v_up = ou;
1004
1005         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1006         {
1007                 backtrace("Tried to override initial weapon think function - should this really happen?");
1008         }
1009
1010         t *= W_WeaponRateFactor();
1011
1012         // VorteX: haste can be added here
1013         if (self.weapon_think == w_ready)
1014         {
1015                 self.weapon_nextthink = time;
1016                 //dprint("started firing at ", ftos(time), "\n");
1017         }
1018         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1019         {
1020                 self.weapon_nextthink = time;
1021                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1022         }
1023         self.weapon_nextthink = self.weapon_nextthink + t;
1024         self.weapon_think = func;
1025         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1026
1027         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1028         //anim = self.anim_shoot;
1029         if (restartanim)
1030         if (t)
1031         if (!self.crouch) // shoot anim stands up, this looks bad
1032         {
1033                 vector anim;
1034                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1035                 {
1036                         anim = self.anim_melee;
1037                         anim_z = anim_y / (t + sys_frametime);
1038                         setanim(self, anim, FALSE, TRUE, TRUE);
1039                 }
1040                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1041                 {
1042                         anim = self.anim_shoot;
1043                         anim_z = anim_y / (t + sys_frametime);
1044                         setanim(self, anim, FALSE, TRUE, TRUE);
1045                 }
1046         }
1047 }
1048
1049 void weapon_boblayer1(float spd, vector org)
1050 {
1051         // VorteX: haste can be added here
1052 }
1053
1054 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1055 {
1056         vector mdirection;
1057         float mspeed;
1058         float outspeed;
1059         float nstyle;
1060         vector outvelocity;
1061
1062         mvelocity = mvelocity * g_weaponspeedfactor;
1063
1064         mdirection = normalize(mvelocity);
1065         mspeed = vlen(mvelocity);
1066
1067         nstyle = autocvar_g_projectiles_newton_style;
1068         if(nstyle == 0 || forceAbsolute)
1069         {
1070                 // absolute velocity
1071                 outvelocity = mvelocity;
1072         }
1073         else if(nstyle == 1)
1074         {
1075                 // true Newtonian projectiles
1076                 outvelocity = pvelocity + mvelocity;
1077         }
1078         else if(nstyle == 2)
1079         {
1080                 // true Newtonian projectiles with automatic aim adjustment
1081                 //
1082                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1083                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1084                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1085                 // PLUS SIGN!
1086                 // not defined?
1087                 // then...
1088                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1089                 // velocity without mdirection component > mspeed
1090                 // fire at smallest possible mspeed that works?
1091                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1092
1093                 vector solution;
1094                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1095                 if(solution_z)
1096                         outspeed = solution_y; // the larger one
1097                 else
1098                 {
1099                         //outspeed = 0; // slowest possible shot
1100                         outspeed = solution_x; // the real part (that is, the average!)
1101                         //dprint("impossible shot, adjusting\n");
1102                 }
1103
1104                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1105                 outvelocity = mdirection * outspeed;
1106         }
1107         else if(nstyle == 3)
1108         {
1109                 // pseudo-Newtonian:
1110                 outspeed = mspeed + mdirection * pvelocity;
1111                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1112                 outvelocity = mdirection * outspeed;
1113         }
1114         else if(nstyle == 4)
1115         {
1116                 // tZorkian:
1117                 outspeed = mspeed + vlen(pvelocity);
1118                 outvelocity = mdirection * outspeed;
1119         }
1120         else
1121                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1122
1123         return outvelocity;
1124 }
1125
1126 void W_AttachToShotorg(entity flash, vector offset)
1127 {
1128         entity xflash;
1129         flash.owner = self;
1130         flash.angles_z = random() * 360;
1131
1132         if(gettagindex(self.weaponentity, "shot"))
1133                 setattachment(flash, self.weaponentity, "shot");
1134         else
1135                 setattachment(flash, self.weaponentity, "tag_shot");
1136         setorigin(flash, offset);
1137
1138         xflash = spawn();
1139         copyentity(flash, xflash);
1140
1141         flash.viewmodelforclient = self;
1142
1143         if(self.weaponentity.oldorigin_x > 0)
1144         {
1145                 setattachment(xflash, self.exteriorweaponentity, "");
1146                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1147         }
1148         else
1149         {
1150                 if(gettagindex(self.exteriorweaponentity, "shot"))
1151                         setattachment(xflash, self.exteriorweaponentity, "shot");
1152                 else
1153                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1154                 setorigin(xflash, offset);
1155         }
1156 }
1157
1158 vector cliptoplane(vector v, vector p)
1159 {
1160         return v - (v * p) * p;
1161 }
1162
1163 vector solve_cubic_pq(float p, float q)
1164 {
1165         float D, u, v, a;
1166         D = q*q/4.0 + p*p*p/27.0;
1167         if(D < 0)
1168         {
1169                 // irreducibilis
1170                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1171                 u = sqrt(-4.0/3.0 * p);
1172                 // a in range 0..pi/3
1173                 // cos(a)
1174                 // cos(a + 2pi/3)
1175                 // cos(a + 4pi/3)
1176                 return
1177                         u *
1178                         (
1179                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1180                                 +
1181                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1182                                 +
1183                                 '0 0 1' * cos(a)
1184                         );
1185         }
1186         else if(D == 0)
1187         {
1188                 // simple
1189                 if(p == 0)
1190                         return '0 0 0';
1191                 u = 3*q/p;
1192                 v = -u/2;
1193                 if(u >= v)
1194                         return '1 1 0' * v + '0 0 1' * u;
1195                 else
1196                         return '0 1 1' * v + '1 0 0' * u;
1197         }
1198         else
1199         {
1200                 // cardano
1201                 u = cbrt(-q/2.0 + sqrt(D));
1202                 v = cbrt(-q/2.0 - sqrt(D));
1203                 return '1 1 1' * (u + v);
1204         }
1205 }
1206 vector solve_cubic_abcd(float a, float b, float c, float d)
1207 {
1208         // y = 3*a*x + b
1209         // x = (y - b) / 3a
1210         float p, q;
1211         vector v;
1212         p = (9*a*c - 3*b*b);
1213         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1214         v = solve_cubic_pq(p, q);
1215         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1216         if(a < 0)
1217                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1218         return v;
1219 }
1220
1221 vector findperpendicular(vector v)
1222 {
1223         vector p;
1224         p_x = v_z;
1225         p_y = -v_x;
1226         p_z = v_y;
1227         return normalize(cliptoplane(p, v));
1228 }
1229
1230 vector W_CalculateProjectileSpread(vector forward, float spread)
1231 {
1232         float sigma;
1233         vector v1, v2;
1234         float dx, dy, r;
1235         float sstyle;
1236         spread *= g_weaponspreadfactor;
1237         if(spread <= 0)
1238                 return forward;
1239         sstyle = autocvar_g_projectiles_spread_style;
1240
1241         if(sstyle == 0)
1242         {
1243                 // this is the baseline for the spread value!
1244                 // standard deviation: sqrt(2/5)
1245                 // density function: sqrt(1-r^2)
1246                 return forward + randomvec() * spread;
1247         }
1248         else if(sstyle == 1)
1249         {
1250                 // same thing, basically
1251                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1252         }
1253         else if(sstyle == 2)
1254         {
1255                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1256                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1257                 v1 = findperpendicular(forward);
1258                 v2 = cross(forward, v1);
1259                 // random point on unit circle
1260                 dx = random() * 2 * M_PI;
1261                 dy = sin(dx);
1262                 dx = cos(dx);
1263                 // radius in our dist function
1264                 r = random();
1265                 r = sqrt(r);
1266                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1267         }
1268         else if(sstyle == 3) // gauss 3d
1269         {
1270                 sigma = spread * 0.44721359549996; // match baseline stddev
1271                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1272                 v1 = forward;
1273                 v1_x += gsl_ran_gaussian(sigma);
1274                 v1_y += gsl_ran_gaussian(sigma);
1275                 v1_z += gsl_ran_gaussian(sigma);
1276                 return v1;
1277         }
1278         else if(sstyle == 4) // gauss 2d
1279         {
1280                 sigma = spread * 0.44721359549996; // match baseline stddev
1281                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1282                 v1_x = gsl_ran_gaussian(sigma);
1283                 v1_y = gsl_ran_gaussian(sigma);
1284                 v1_z = gsl_ran_gaussian(sigma);
1285                 return normalize(forward + cliptoplane(v1, forward));
1286         }
1287         else if(sstyle == 5) // 1-r
1288         {
1289                 sigma = spread * 1.154700538379252; // match baseline stddev
1290                 v1 = findperpendicular(forward);
1291                 v2 = cross(forward, v1);
1292                 // random point on unit circle
1293                 dx = random() * 2 * M_PI;
1294                 dy = sin(dx);
1295                 dx = cos(dx);
1296                 // radius in our dist function
1297                 r = random();
1298                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1299                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1300         }
1301         else if(sstyle == 6) // 1-r^2
1302         {
1303                 sigma = spread * 1.095445115010332; // match baseline stddev
1304                 v1 = findperpendicular(forward);
1305                 v2 = cross(forward, v1);
1306                 // random point on unit circle
1307                 dx = random() * 2 * M_PI;
1308                 dy = sin(dx);
1309                 dx = cos(dx);
1310                 // radius in our dist function
1311                 r = random();
1312                 r = sqrt(1 - r);
1313                 r = sqrt(1 - r);
1314                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1315         }
1316         else if(sstyle == 7) // (1-r) (2-r)
1317         {
1318                 sigma = spread * 1.224744871391589; // match baseline stddev
1319                 v1 = findperpendicular(forward);
1320                 v2 = cross(forward, v1);
1321                 // random point on unit circle
1322                 dx = random() * 2 * M_PI;
1323                 dy = sin(dx);
1324                 dx = cos(dx);
1325                 // radius in our dist function
1326                 r = random();
1327                 r = 1 - sqrt(r);
1328                 r = 1 - sqrt(r);
1329                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1330         }
1331         else
1332                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1333         return '0 0 0';
1334         /*
1335          * how to derive falloff functions:
1336          * rho(r) := (2-r) * (1-r);
1337          * a : 0;
1338          * b : 1;
1339          * rhor(r) := r * rho(r);
1340          * cr(t) := integrate(rhor(r), r, a, t);
1341          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1342          * variance : scr(b) / cr(b);
1343          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1344          * sqrt(0.4 / variance), numer;
1345          */
1346 }
1347
1348 #if 0
1349 float mspercallsum;
1350 float mspercallsstyle;
1351 float mspercallcount;
1352 #endif
1353 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1354 {
1355         if(missile.owner == world)
1356                 error("Unowned missile");
1357
1358         dir = dir + upDir * (pUpSpeed / pSpeed);
1359         dir_z += pZSpeed / pSpeed;
1360         pSpeed *= vlen(dir);
1361         dir = normalize(dir);
1362
1363 #if 0
1364         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1365         {
1366                 mspercallsum = mspercallcount = 0;
1367                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1368         }
1369         mspercallsum -= gettime(GETTIME_HIRES);
1370 #endif
1371         dir = W_CalculateProjectileSpread(dir, spread);
1372 #if 0
1373         mspercallsum += gettime(GETTIME_HIRES);
1374         mspercallcount += 1;
1375         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1376 #endif
1377
1378         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1379 }
1380
1381 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1382 {
1383         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1384 }
1385
1386 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1387 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1388
1389 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1390 {
1391         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1392                 return;
1393
1394         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1395         if(ammo_reload)
1396         {
1397                 self.clip_load -= ammo_use;
1398                 self.(weapon_load[self.weapon]) = self.clip_load;
1399         }
1400         else
1401                 self.(self.current_ammo) -= ammo_use;
1402 }
1403
1404 // weapon reloading code
1405
1406 .float reload_ammo_amount, reload_ammo_min, reload_time;
1407 .float reload_complain;
1408 .string reload_sound;
1409
1410 void W_ReloadedAndReady()
1411 {
1412         // finish the reloading process, and do the ammo transfer
1413
1414         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1415
1416         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1417         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1418                 self.clip_load = self.reload_ammo_amount;
1419         else
1420         {
1421                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1422                 {
1423                         self.clip_load += 1;
1424                         self.(self.current_ammo) -= 1;
1425                 }
1426         }
1427         self.(weapon_load[self.weapon]) = self.clip_load;
1428
1429         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1430         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1431         // so your weapon is disabled for a few seconds without reason
1432
1433         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1434
1435         w_ready();
1436 }
1437
1438 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1439 {
1440         // set global values to work with
1441
1442         self.reload_ammo_min = sent_ammo_min;
1443         self.reload_ammo_amount = sent_ammo_amount;
1444         self.reload_time = sent_time;
1445         self.reload_sound = sent_sound;
1446
1447         // check if we meet the necessary conditions to reload
1448
1449         entity e;
1450         e = get_weaponinfo(self.weapon);
1451
1452         // don't reload weapons that don't have the RELOADABLE flag
1453         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1454         {
1455                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1456                 return;
1457         }
1458
1459         // return if reloading is disabled for this weapon
1460         if(!self.reload_ammo_amount)
1461                 return;
1462
1463         // our weapon is fully loaded, no need to reload
1464         if (self.clip_load >= self.reload_ammo_amount)
1465                 return;
1466
1467         // no ammo, so nothing to load
1468         if(!self.(self.current_ammo) && self.reload_ammo_min)
1469         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1470         {
1471                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1472                 {
1473                         play2(self, "weapons/unavailable.wav");
1474                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1475                         self.reload_complain = time + 1;
1476                 }
1477                 // switch away if the amount of ammo is not enough to keep using this weapon
1478                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1479                 {
1480                         self.clip_load = -1; // reload later
1481                         W_SwitchToOtherWeapon(self);
1482                 }
1483                 return;
1484         }
1485
1486         if (self.weaponentity)
1487         {
1488                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1489                         return;
1490
1491                 // allow switching away while reloading, but this will cause a new reload!
1492                 self.weaponentity.state = WS_READY;
1493         }
1494
1495         // now begin the reloading process
1496
1497         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1498
1499         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1500         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1501         // so your weapon is disabled for a few seconds without reason
1502
1503         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1504
1505         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1506
1507         if(self.clip_load < 0)
1508                 self.clip_load = 0;
1509         self.old_clip_load = self.clip_load;
1510         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1511 }