qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/func/conveyor.qh"
  31 #include "../common/triggers/teleporters.qh"
  32
  33 #include "../common/vehicles/all.qh"
  34
  35 #include "weapons/hitplot.qh"
  36 #include "weapons/weaponsystem.qh"
  37
  38 #include "../common/net_notice.qh"
  39 #include "../common/physics/player.qh"
  40
  41 #include "../common/items/_mod.qh"
  42
  43 #include "../common/mutators/mutator/waypoints/all.qh"
  44
  45 #include "../common/triggers/subs.qh"
  46 #include "../common/triggers/triggers.qh"
  47 #include "../common/triggers/trigger/secret.qh"
  48
  49 #include "../common/minigames/sv_minigames.qh"
  50
  51 #include "../common/items/inventory.qh"
  52
  53 #include "../common/monsters/sv_monsters.qh"
  54
  55 #include "../lib/warpzone/server.qh"
  56
  57 STATIC_METHOD(Client, Add, void(Client this, int _team))
  58 {
  59     ClientConnect(this);
  60     TRANSMUTE(Player, this);
  61     this.frame = 12; // 7
  62     this.team = _team;
  63     PutClientInServer(this);
  64 }
  65
  66 void PutObserverInServer(entity this);
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     PutClientInServer(this);
  72     ClientDisconnect(this);
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 int CountSpectators(entity player, entity to)
  80 {
  81         if(!player) { return 0; } // not sure how, but best to be safe
  82
  83         int spec_count = 0;
  84
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  86         {
  87                 spec_count++;
  88         });
  89
  90         return spec_count;
  91 }
  92
  93 void WriteSpectators(entity player, entity to)
  94 {
  95         if(!player) { return; } // not sure how, but best to be safe
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 WriteByte(MSG_ENTITY, num_for_edict(it));
 100         });
 101 }
 102
 103 bool ClientData_Send(entity this, entity to, int sf)
 104 {
 105         assert(to == this.owner, return false);
 106
 107         entity e = to;
 108         if (IS_SPEC(e)) e = e.enemy;
 109
 110         sf = 0;
 111         if (e.race_completed)       sf |= 1; // forced scoreboard
 112         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 113         if (e.zoomstate)            sf |= 4; // zoomed
 114         if (e.porto_v_angle_held)   sf |= 8; // angles held
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124         if (sf & 8)
 125         {
 126                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 127                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 128         }
 129
 130         if(sf & 16)
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         this.clientdata.drawonlytoclient = this;
 144         this.clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(this.clientdata);
 150         this.clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         e.clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 159 }
 160
 161 .string netname_previous;
 162
 163 void SetSpectatee(entity this, entity spectatee);
 164 void SetSpectatee_status(entity this, int spectatee_num);
 165
 166
 167 /*
 168 =============
 169 CheckPlayerModel
 170
 171 Checks if the argument string can be a valid playermodel.
 172 Returns a valid one in doubt.
 173 =============
 174 */
 175 string FallbackPlayerModel;
 176 string CheckPlayerModel(string plyermodel) {
 177         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 178         {
 179                 // note: we cannot summon Don Strunzone here, some player may
 180                 // still have the model string set. In case anyone manages how
 181                 // to change a cvar default, we'll have a small leak here.
 182                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 183         }
 184         // only in right path
 185         if( substring(plyermodel,0,14) != "models/player/")
 186                 return FallbackPlayerModel;
 187         // only good file extensions
 188         if(substring(plyermodel,-4,4) != ".zym")
 189         if(substring(plyermodel,-4,4) != ".dpm")
 190         if(substring(plyermodel,-4,4) != ".iqm")
 191         if(substring(plyermodel,-4,4) != ".md3")
 192         if(substring(plyermodel,-4,4) != ".psk")
 193                 return FallbackPlayerModel;
 194         // forbid the LOD models
 195         if(substring(plyermodel, -9,5) == "_lod1")
 196                 return FallbackPlayerModel;
 197         if(substring(plyermodel, -9,5) == "_lod2")
 198                 return FallbackPlayerModel;
 199         if(plyermodel != strtolower(plyermodel))
 200                 return FallbackPlayerModel;
 201         // also, restrict to server models
 202         if(autocvar_sv_servermodelsonly)
 203         {
 204                 if(!fexists(plyermodel))
 205                         return FallbackPlayerModel;
 206         }
 207         return plyermodel;
 208 }
 209
 210 void setplayermodel(entity e, string modelname)
 211 {
 212         precache_model(modelname);
 213         _setmodel(e, modelname);
 214         player_setupanimsformodel(e);
 215         if(!autocvar_g_debug_globalsounds)
 216                 UpdatePlayerSounds(e);
 217 }
 218
 219 void FixPlayermodel(entity player);
 220 /** putting a client as observer in the server */
 221 void PutObserverInServer(entity this)
 222 {
 223     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 224         PlayerState_detach(this);
 225
 226         if (IS_PLAYER(this) && this.health >= 1) {
 227         // despawn effect
 228                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229     }
 230
 231     {
 232         entity spot = SelectSpawnPoint(this, true);
 233         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 234         this.angles = spot.angles;
 235         this.angles_z = 0;
 236         this.fixangle = true;
 237         // offset it so that the spectator spawns higher off the ground, looks better this way
 238         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 239         this.prevorigin = this.origin;
 240         if (IS_REAL_CLIENT(this))
 241         {
 242             msg_entity = this;
 243             WriteByte(MSG_ONE, SVC_SETVIEW);
 244             WriteEntity(MSG_ONE, this);
 245         }
 246         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 247         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 248         if(!autocvar_g_debug_globalsounds)
 249         {
 250                 // needed for player sounds
 251                 this.model = "";
 252                 FixPlayermodel(this);
 253         }
 254         setmodel(this, MDL_Null);
 255         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 256         this.view_ofs = '0 0 0';
 257     }
 258
 259     RemoveGrapplingHook(this);
 260         Portal_ClearAll(this);
 261         Unfreeze(this);
 262         SetSpectatee(this, NULL);
 263
 264         if (this.alivetime)
 265         {
 266                 if (!warmup_stage)
 267                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 268                 this.alivetime = 0;
 269         }
 270
 271         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 272
 273         WaypointSprite_PlayerDead(this);
 274
 275         if (mutator_returnvalue) {
 276             // mutator prevents resetting teams+score
 277         } else {
 278                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 279         this.frags = FRAGS_SPECTATOR;
 280         PlayerScore_Clear(this);  // clear scores when needed
 281     }
 282
 283         if (this.killcount != FRAGS_SPECTATOR)
 284         {
 285                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 286                 if(!intermission_running)
 287                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 288                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 289
 290                 if(this.just_joined == false) {
 291                         LogTeamchange(this.playerid, -1, 4);
 292                 } else
 293                         this.just_joined = false;
 294         }
 295
 296         accuracy_resend(this);
 297
 298         this.spectatortime = time;
 299         if(this.bot_attack)
 300                 IL_REMOVE(g_bot_targets, this);
 301         this.bot_attack = false;
 302     this.hud = HUD_NORMAL;
 303         TRANSMUTE(Observer, this);
 304         this.iscreature = false;
 305         this.teleportable = TELEPORT_SIMPLE;
 306         this.damagedbycontents = false;
 307         this.health = FRAGS_SPECTATOR;
 308         SetSpectatee_status(this, etof(this));
 309         this.takedamage = DAMAGE_NO;
 310         this.solid = SOLID_NOT;
 311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 312         this.flags = FL_CLIENT | FL_NOTARGET;
 313         this.armorvalue = 666;
 314         this.effects = 0;
 315         this.armorvalue = autocvar_g_balance_armor_start;
 316         this.pauserotarmor_finished = 0;
 317         this.pauserothealth_finished = 0;
 318         this.pauseregen_finished = 0;
 319         this.damageforcescale = 0;
 320         this.death_time = 0;
 321         this.respawn_flags = 0;
 322         this.respawn_time = 0;
 323         this.stat_respawn_time = 0;
 324         this.alpha = 0;
 325         this.scale = 0;
 326         this.fade_time = 0;
 327         this.pain_frame = 0;
 328         this.pain_finished = 0;
 329         this.strength_finished = 0;
 330         this.invincible_finished = 0;
 331         this.superweapons_finished = 0;
 332         this.pushltime = 0;
 333         this.istypefrag = 0;
 334         setthink(this, func_null);
 335         this.nextthink = 0;
 336         this.hook_time = 0;
 337         this.deadflag = DEAD_NO;
 338         this.crouch = false;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.drawonlytoclient = this;
 344
 345         this.weaponname = "";
 346         this.weaponmodel = "";
 347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 348         {
 349                 this.weaponentities[slot] = NULL;
 350         }
 351         this.exteriorweaponentity = NULL;
 352         this.killcount = FRAGS_SPECTATOR;
 353         this.velocity = '0 0 0';
 354         this.avelocity = '0 0 0';
 355         this.punchangle = '0 0 0';
 356         this.punchvector = '0 0 0';
 357         this.oldvelocity = this.velocity;
 358         this.fire_endtime = -1;
 359         this.event_damage = func_null;
 360
 361         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 362         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 363         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 364 }
 365
 366 int player_getspecies(entity this)
 367 {
 368         get_model_parameters(this.model, this.skin);
 369         int s = get_model_parameters_species;
 370         get_model_parameters(string_null, 0);
 371         if (s < 0) return SPECIES_HUMAN;
 372         return s;
 373 }
 374
 375 .float model_randomizer;
 376 void FixPlayermodel(entity player)
 377 {
 378         string defaultmodel = "";
 379         int defaultskin = 0;
 380         if(autocvar_sv_defaultcharacter)
 381         {
 382                 if(teamplay)
 383                 {
 384                         string s = Static_Team_ColorName_Lower(player.team);
 385                         if (s != "neutral")
 386                         {
 387                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 388                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * player.model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         string s = Static_Team_ColorName_Lower(player.team);
 420                         if (s != "neutral")
 421                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 422                 }
 423
 424                 if(!defaultskin)
 425                         defaultskin = autocvar_sv_defaultplayerskin;
 426         }
 427
 428         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 429         defaultmodel = M_ARGV(0, string);
 430         defaultskin = M_ARGV(1, int);
 431
 432         bool chmdl = false;
 433         int oldskin;
 434         if(defaultmodel != "")
 435         {
 436                 if (defaultmodel != player.model)
 437                 {
 438                         vector m1 = player.mins;
 439                         vector m2 = player.maxs;
 440                         setplayermodel (player, defaultmodel);
 441                         setsize (player, m1, m2);
 442                         chmdl = true;
 443                 }
 444
 445                 oldskin = player.skin;
 446                 player.skin = defaultskin;
 447         } else {
 448                 if (player.playermodel != player.model || player.playermodel == "")
 449                 {
 450                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 451                         vector m1 = player.mins;
 452                         vector m2 = player.maxs;
 453                         setplayermodel (player, player.playermodel);
 454                         setsize (player, m1, m2);
 455                         chmdl = true;
 456                 }
 457
 458                 if(!autocvar_sv_defaultcharacterskin)
 459                 {
 460                         oldskin = player.skin;
 461                         player.skin = stof(player.playerskin);
 462                 }
 463                 else
 464                 {
 465                         oldskin = player.skin;
 466                         player.skin = defaultskin;
 467                 }
 468         }
 469
 470         if(chmdl || oldskin != player.skin) // model or skin has changed
 471         {
 472                 player.species = player_getspecies(player); // update species
 473                 if(!autocvar_g_debug_globalsounds)
 474                         UpdatePlayerSounds(player); // update skin sounds
 475         }
 476
 477         if(!teamplay)
 478                 if(strlen(autocvar_sv_defaultplayercolors))
 479                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 480                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 481 }
 482
 483
 484 /** Called when a client spawns in the server */
 485 void PutClientInServer(entity this)
 486 {
 487         if (IS_BOT_CLIENT(this)) {
 488                 TRANSMUTE(Player, this);
 489         } else if (IS_REAL_CLIENT(this)) {
 490                 msg_entity = this;
 491                 WriteByte(MSG_ONE, SVC_SETVIEW);
 492                 WriteEntity(MSG_ONE, this);
 493         }
 494         if (gameover) {
 495                 TRANSMUTE(Observer, this);
 496         }
 497
 498         SetSpectatee(this, NULL);
 499
 500         // reset player keys
 501         this.itemkeys = 0;
 502
 503         MUTATOR_CALLHOOK(PutClientInServer, this);
 504
 505         if (IS_OBSERVER(this)) {
 506                 PutObserverInServer(this);
 507         } else if (IS_PLAYER(this)) {
 508                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 509
 510                 PlayerState_attach(this);
 511                 accuracy_resend(this);
 512
 513                 if (this.team < 0)
 514                         JoinBestTeam(this, false, true);
 515
 516                 entity spot = SelectSpawnPoint(this, false);
 517                 if (!spot) {
 518                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 519                         return; // spawn failed
 520                 }
 521
 522                 TRANSMUTE(Player, this);
 523
 524                 this.wasplayer = true;
 525                 this.iscreature = true;
 526                 this.teleportable = TELEPORT_NORMAL;
 527                 this.damagedbycontents = true;
 528                 set_movetype(this, MOVETYPE_WALK);
 529                 this.solid = SOLID_SLIDEBOX;
 530                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 531                 if (autocvar_g_playerclip_collisions)
 532                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 533                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 534                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 535                 this.frags = FRAGS_PLAYER;
 536                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 537                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 538                 if (autocvar__notarget)
 539                         this.flags |= FL_NOTARGET;
 540                 this.takedamage = DAMAGE_AIM;
 541                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 542                 this.dmg = 2; // WTF
 543
 544                 if (warmup_stage) {
 545                         this.ammo_shells = warmup_start_ammo_shells;
 546                         this.ammo_nails = warmup_start_ammo_nails;
 547                         this.ammo_rockets = warmup_start_ammo_rockets;
 548                         this.ammo_cells = warmup_start_ammo_cells;
 549                         this.ammo_plasma = warmup_start_ammo_plasma;
 550                         this.ammo_fuel = warmup_start_ammo_fuel;
 551                         this.health = warmup_start_health;
 552                         this.armorvalue = warmup_start_armorvalue;
 553                         this.weapons = WARMUP_START_WEAPONS;
 554                 } else {
 555                         this.ammo_shells = start_ammo_shells;
 556                         this.ammo_nails = start_ammo_nails;
 557                         this.ammo_rockets = start_ammo_rockets;
 558                         this.ammo_cells = start_ammo_cells;
 559                         this.ammo_plasma = start_ammo_plasma;
 560                         this.ammo_fuel = start_ammo_fuel;
 561                         this.health = start_health;
 562                         this.armorvalue = start_armorvalue;
 563                         this.weapons = start_weapons;
 564                 }
 565                 SetSpectatee_status(this, 0);
 566
 567                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 568
 569                 this.items = start_items;
 570
 571                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 572                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 573                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 574                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 575                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 576                 // extend the pause of rotting if client was reset at the beginning of the countdown
 577                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 578                         float f = game_starttime - time;
 579                         this.spawnshieldtime += f;
 580                         this.pauserotarmor_finished += f;
 581                         this.pauserothealth_finished += f;
 582                         this.pauseregen_finished += f;
 583                 }
 584                 this.damageforcescale = 2;
 585                 this.death_time = 0;
 586                 this.respawn_flags = 0;
 587                 this.respawn_time = 0;
 588                 this.stat_respawn_time = 0;
 589                 this.scale = autocvar_sv_player_scale;
 590                 this.fade_time = 0;
 591                 this.pain_frame = 0;
 592                 this.pain_finished = 0;
 593                 this.pushltime = 0;
 594                 setthink(this, func_null); // players have no think function
 595                 this.nextthink = 0;
 596                 this.dmg_team = 0;
 597                 this.ballistics_density = autocvar_g_ballistics_density_player;
 598
 599                 this.deadflag = DEAD_NO;
 600
 601                 this.angles = spot.angles;
 602                 this.angles_z = 0; // never spawn tilted even if the spot says to
 603                 if (IS_BOT_CLIENT(this))
 604                         this.v_angle = this.angles;
 605                 this.fixangle = true; // turn this way immediately
 606                 this.oldvelocity = this.velocity = '0 0 0';
 607                 this.avelocity = '0 0 0';
 608                 this.punchangle = '0 0 0';
 609                 this.punchvector = '0 0 0';
 610
 611                 this.strength_finished = 0;
 612                 this.invincible_finished = 0;
 613                 this.fire_endtime = -1;
 614                 this.revival_time = 0;
 615                 this.air_finished = time + 12;
 616
 617                 entity spawnevent = new_pure(spawnevent);
 618                 spawnevent.owner = this;
 619                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 620
 621                 // Cut off any still running player sounds.
 622                 stopsound(this, CH_PLAYER_SINGLE);
 623
 624                 this.model = "";
 625                 FixPlayermodel(this);
 626                 this.drawonlytoclient = NULL;
 627
 628                 this.viewloc = NULL;
 629
 630                 this.crouch = false;
 631                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 632                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 633                 this.spawnorigin = spot.origin;
 634                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 635                 // don't reset back to last position, even if new position is stuck in solid
 636                 this.oldorigin = this.origin;
 637                 this.prevorigin = this.origin;
 638                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 639                 if(this.conveyor)
 640                         IL_REMOVE(g_conveyed, this);
 641                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 642                 this.hud = HUD_NORMAL;
 643
 644                 this.event_damage = PlayerDamage;
 645
 646                 if(!this.bot_attack)
 647                         IL_PUSH(g_bot_targets, this);
 648                 this.bot_attack = true;
 649                 this.monster_attack = true;
 650
 651                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 652
 653                 if (this.killcount == FRAGS_SPECTATOR) {
 654                         PlayerScore_Clear(this);
 655                         this.killcount = 0;
 656                 }
 657
 658                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 659                 {
 660                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 661                 }
 662                 this.alpha = default_player_alpha;
 663                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 664                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 665
 666                 this.speedrunning = false;
 667
 668                 target_voicescript_clear(this);
 669
 670                 // reset fields the weapons may use
 671                 FOREACH(Weapons, true, LAMBDA(
 672                         it.wr_resetplayer(it, this);
 673                         // reload all reloadable weapons
 674                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 675                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 676                         }
 677                 ));
 678
 679                 {
 680                         string s = spot.target;
 681                         spot.target = string_null;
 682                         SUB_UseTargets(spot, this, NULL);
 683                         spot.target = s;
 684                 }
 685
 686                 Unfreeze(this);
 687
 688                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 689
 690                 if (autocvar_spawn_debug)
 691                 {
 692                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 693                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 694                 }
 695
 696                 PS(this).m_switchweapon = w_getbestweapon(this);
 697                 this.cnt = -1; // W_LastWeapon will not complain
 698                 PS(this).m_weapon = WEP_Null;
 699                 this.weaponname = "";
 700                 PS(this).m_switchingweapon = WEP_Null;
 701
 702                 if (!warmup_stage && !this.alivetime)
 703                         this.alivetime = time;
 704
 705                 antilag_clear(this, CS(this));
 706         }
 707 }
 708
 709 void ClientInit_misc(entity this);
 710
 711 .float ebouncefactor, ebouncestop; // electro's values
 712 // TODO do we need all these fields, or should we stop autodetecting runtime
 713 // changes and just have a console command to update this?
 714 bool ClientInit_SendEntity(entity this, entity to, int sf)
 715 {
 716         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 717         return = true;
 718         msg_entity = to;
 719         // MSG_INIT replacement
 720         // TODO: make easier to use
 721         Registry_send_all();
 722         W_PROP_reload(MSG_ONE, to);
 723         ClientInit_misc(this);
 724         MUTATOR_CALLHOOK(Ent_Init);
 725 }
 726 void ClientInit_misc(entity this)
 727 {
 728         int channel = MSG_ONE;
 729         WriteHeader(channel, ENT_CLIENT_INIT);
 730         WriteByte(channel, g_nexball_meter_period * 32);
 731         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 732         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 733         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 734         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 735         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 736         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 737         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 738         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 739
 740         if(sv_foginterval && world.fog != "")
 741                 WriteString(channel, world.fog);
 742         else
 743                 WriteString(channel, "");
 744         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 745         WriteByte(channel, serverflags);
 746         WriteCoord(channel, autocvar_g_trueaim_minrange);
 747 }
 748
 749 void ClientInit_CheckUpdate(entity this)
 750 {
 751         this.nextthink = time;
 752         if(this.count != autocvar_g_balance_armor_blockpercent)
 753         {
 754                 this.count = autocvar_g_balance_armor_blockpercent;
 755                 this.SendFlags |= 1;
 756         }
 757 }
 758
 759 void ClientInit_Spawn()
 760 {
 761         entity e = new_pure(clientinit);
 762         setthink(e, ClientInit_CheckUpdate);
 763         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 764
 765         ClientInit_CheckUpdate(e);
 766 }
 767
 768 /*
 769 =============
 770 SetNewParms
 771 =============
 772 */
 773 void SetNewParms ()
 774 {
 775         // initialize parms for a new player
 776         parm1 = -(86400 * 366);
 777
 778         MUTATOR_CALLHOOK(SetNewParms);
 779 }
 780
 781 /*
 782 =============
 783 SetChangeParms
 784 =============
 785 */
 786 void SetChangeParms (entity this)
 787 {
 788         // save parms for level change
 789         parm1 = this.parm_idlesince - time;
 790
 791         MUTATOR_CALLHOOK(SetChangeParms);
 792 }
 793
 794 /*
 795 =============
 796 DecodeLevelParms
 797 =============
 798 */
 799 void DecodeLevelParms(entity this)
 800 {
 801         // load parms
 802         this.parm_idlesince = parm1;
 803         if (this.parm_idlesince == -(86400 * 366))
 804                 this.parm_idlesince = time;
 805
 806         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 807         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 808
 809         MUTATOR_CALLHOOK(DecodeLevelParms);
 810 }
 811
 812 /*
 813 =============
 814 ClientKill
 815
 816 Called when a client types 'kill' in the console
 817 =============
 818 */
 819
 820 .float clientkill_nexttime;
 821 void ClientKill_Now_TeamChange(entity this)
 822 {
 823         if(this.killindicator_teamchange == -1)
 824         {
 825                 JoinBestTeam( this, false, true );
 826         }
 827         else if(this.killindicator_teamchange == -2)
 828         {
 829                 if(blockSpectators)
 830                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 831                 PutObserverInServer(this);
 832         }
 833         else
 834                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 835         this.killindicator_teamchange = 0;
 836 }
 837
 838 void ClientKill_Now(entity this)
 839 {
 840         if(this.vehicle)
 841         {
 842             vehicles_exit(this.vehicle, VHEF_RELEASE);
 843             if(!this.killindicator_teamchange)
 844             {
 845             this.vehicle_health = -1;
 846             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 847             }
 848         }
 849
 850         if(this.killindicator && !wasfreed(this.killindicator))
 851                 delete(this.killindicator);
 852
 853         this.killindicator = NULL;
 854
 855         if(this.killindicator_teamchange)
 856                 ClientKill_Now_TeamChange(this);
 857
 858         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 859                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 860
 861         // now I am sure the player IS dead
 862 }
 863 void KillIndicator_Think(entity this)
 864 {
 865         if (gameover)
 866         {
 867                 this.owner.killindicator = NULL;
 868                 delete(this);
 869                 return;
 870         }
 871
 872         if (this.owner.alpha < 0 && !this.owner.vehicle)
 873         {
 874                 this.owner.killindicator = NULL;
 875                 delete(this);
 876                 return;
 877         }
 878
 879         if(this.cnt <= 0)
 880         {
 881                 ClientKill_Now(this.owner);
 882                 return;
 883         }
 884     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 885     {
 886         this.nextthink = time + 1;
 887         this.cnt -= 1;
 888     }
 889         else
 890         {
 891                 if(this.cnt <= 10)
 892                         setmodel(this, MDL_NUM(this.cnt));
 893                 if(IS_REAL_CLIENT(this.owner))
 894                 {
 895                         if(this.cnt <= 10)
 896                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 897                 }
 898                 this.nextthink = time + 1;
 899                 this.cnt -= 1;
 900         }
 901 }
 902
 903 float clientkilltime;
 904 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 905 {
 906         float killtime;
 907         float starttime;
 908
 909         if (gameover)
 910                 return;
 911
 912         killtime = autocvar_g_balance_kill_delay;
 913
 914         if(g_race_qualifying || g_cts)
 915                 killtime = 0;
 916
 917     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 918         return;
 919
 920         this.killindicator_teamchange = targetteam;
 921
 922     if(!this.killindicator)
 923         {
 924                 if(!IS_DEAD(this))
 925                 {
 926                         killtime = max(killtime, this.clientkill_nexttime - time);
 927                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 928                 }
 929
 930                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 931                 {
 932                         ClientKill_Now(this);
 933                 }
 934                 else
 935                 {
 936                         starttime = max(time, clientkilltime);
 937
 938                         this.killindicator = spawn();
 939                         this.killindicator.owner = this;
 940                         this.killindicator.scale = 0.5;
 941                         setattachment(this.killindicator, this, "");
 942                         setorigin(this.killindicator, '0 0 52');
 943                         setthink(this.killindicator, KillIndicator_Think);
 944                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 945                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 946                         this.killindicator.cnt = ceil(killtime);
 947                         this.killindicator.count = bound(0, ceil(killtime), 10);
 948                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 949
 950                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 951                         {
 952                                 it.killindicator = spawn();
 953                                 it.killindicator.owner = it;
 954                                 it.killindicator.scale = 0.5;
 955                                 setattachment(it.killindicator, it, "");
 956                                 setorigin(it.killindicator, '0 0 52');
 957                                 setthink(it.killindicator, KillIndicator_Think);
 958                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 959                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 960                                 it.killindicator.cnt = ceil(killtime);
 961                         });
 962                         this.lip = 0;
 963                 }
 964         }
 965         if(this.killindicator)
 966         {
 967                 if(targetteam == 0) // just die
 968                 {
 969                         this.killindicator.colormod = '0 0 0';
 970                         if(IS_REAL_CLIENT(this))
 971                         if(this.killindicator.cnt > 0)
 972                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 973                 }
 974                 else if(targetteam == -1) // auto
 975                 {
 976                         this.killindicator.colormod = '0 1 0';
 977                         if(IS_REAL_CLIENT(this))
 978                         if(this.killindicator.cnt > 0)
 979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 980                 }
 981                 else if(targetteam == -2) // spectate
 982                 {
 983                         this.killindicator.colormod = '0.5 0.5 0.5';
 984                         if(IS_REAL_CLIENT(this))
 985                         if(this.killindicator.cnt > 0)
 986                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 987                 }
 988                 else
 989                 {
 990                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 991                         if(IS_REAL_CLIENT(this))
 992                         if(this.killindicator.cnt > 0)
 993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 994                 }
 995         }
 996
 997 }
 998
 999 void ClientKill (entity this)
1000 {
1001         if(gameover) return;
1002         if(this.player_blocked) return;
1003         if(STAT(FROZEN, this)) return;
1004
1005         ClientKill_TeamChange(this, 0);
1006 }
1007
1008 void FixClientCvars(entity e)
1009 {
1010         // send prediction settings to the client
1011         stuffcmd(e, "\nin_bindmap 0 0\n");
1012         if(autocvar_g_antilag == 3) // client side hitscan
1013                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1014         if(autocvar_sv_gentle)
1015                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1016
1017         MUTATOR_CALLHOOK(FixClientCvars, e);
1018 }
1019
1020 float PlayerInIDList(entity p, string idlist)
1021 {
1022         float n, i;
1023         string s;
1024
1025         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1026         if (!p.crypto_idfp)
1027                 return 0;
1028
1029         // this function allows abbreviated player IDs too!
1030         n = tokenize_console(idlist);
1031         for(i = 0; i < n; ++i)
1032         {
1033                 s = argv(i);
1034                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1035                         return 1;
1036         }
1037
1038         return 0;
1039 }
1040
1041 #ifdef DP_EXT_PRECONNECT
1042 /*
1043 =============
1044 ClientPreConnect
1045
1046 Called once (not at each match start) when a client begins a connection to the server
1047 =============
1048 */
1049 void ClientPreConnect ()
1050 {ENGINE_EVENT();
1051         if(autocvar_sv_eventlog)
1052         {
1053                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1054                         this.playerid,
1055                         etof(this),
1056                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1057                 ));
1058         }
1059 }
1060 #endif
1061
1062 /**
1063 =============
1064 ClientConnect
1065
1066 Called when a client connects to the server
1067 =============
1068 */
1069 void ClientConnect(entity this)
1070 {
1071         if (Ban_MaybeEnforceBanOnce(this)) return;
1072         assert(!IS_CLIENT(this), return);
1073         this.flags |= FL_CLIENT;
1074         assert(player_count >= 0, player_count = 0);
1075
1076 #ifdef WATERMARK
1077         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1078 #endif
1079         this.version_nagtime = time + 10 + random() * 10;
1080         TRANSMUTE(Client, this);
1081
1082         // identify the right forced team
1083         if (autocvar_g_campaign)
1084         {
1085                 if (IS_REAL_CLIENT(this)) // only players, not bots
1086                 {
1087                         switch (autocvar_g_campaign_forceteam)
1088                         {
1089                                 case 1: this.team_forced = NUM_TEAM_1; break;
1090                                 case 2: this.team_forced = NUM_TEAM_2; break;
1091                                 case 3: this.team_forced = NUM_TEAM_3; break;
1092                                 case 4: this.team_forced = NUM_TEAM_4; break;
1093                                 default: this.team_forced = 0;
1094                         }
1095                 }
1096         }
1097         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1098         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1099         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1100         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1101         else switch (autocvar_g_forced_team_otherwise)
1102         {
1103                 default: this.team_forced = 0; break;
1104                 case "red": this.team_forced = NUM_TEAM_1; break;
1105                 case "blue": this.team_forced = NUM_TEAM_2; break;
1106                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1107                 case "pink": this.team_forced = NUM_TEAM_4; break;
1108                 case "spectate":
1109                 case "spectator":
1110                         this.team_forced = -1;
1111                         break;
1112         }
1113         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1114
1115     {
1116         int id = this.playerid;
1117         this.playerid = 0; // silent
1118             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1119             this.playerid = id;
1120     }
1121
1122         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1123                 TRANSMUTE(Observer, this);
1124         } else {
1125                 if (!teamplay || autocvar_g_balance_teams) {
1126                         TRANSMUTE(Player, this);
1127                         campaign_bots_may_start = true;
1128                 } else {
1129                         TRANSMUTE(Observer, this); // do it anyway
1130                 }
1131         }
1132
1133         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1134
1135         // always track bots, don't ask for cl_allow_uidtracking
1136     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1137
1138         if (autocvar_sv_eventlog)
1139                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1140
1141         LogTeamchange(this.playerid, this.team, 1);
1142
1143         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1144
1145         this.netname_previous = strzone(this.netname);
1146
1147         if(teamplay && IS_PLAYER(this))
1148                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1149         else
1150                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1151
1152         stuffcmd(this, clientstuff, "\n");
1153         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1154
1155         FixClientCvars(this);
1156
1157         // get version info from player
1158         stuffcmd(this, "cmd clientversion $gameversion\n");
1159
1160         // notify about available teams
1161         if (teamplay)
1162         {
1163                 CheckAllowedTeams(this);
1164                 int t = 0;
1165                 if (c1 >= 0) t |= BIT(0);
1166                 if (c2 >= 0) t |= BIT(1);
1167                 if (c3 >= 0) t |= BIT(2);
1168                 if (c4 >= 0) t |= BIT(3);
1169                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1170         }
1171         else
1172         {
1173                 stuffcmd(this, "set _teams_available 0\n");
1174         }
1175
1176         bot_relinkplayerlist();
1177
1178         this.spectatortime = time;
1179         if (blockSpectators)
1180         {
1181                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1182         }
1183
1184         this.jointime = time;
1185         this.allowed_timeouts = autocvar_sv_timeout_number;
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign)
1190                 {
1191                         this.motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194
1195                 if (g_weaponarena_weapons == WEPSET(TUBA))
1196                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1197         }
1198
1199         if (!sv_foginterval && world.fog != "")
1200                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1201
1202         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1203                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1204                         send_CSQC_teamnagger();
1205
1206         CSQCMODEL_AUTOINIT(this);
1207
1208         this.model_randomizer = random();
1209
1210         if (IS_REAL_CLIENT(this))
1211                 sv_notice_join(this);
1212
1213         // update physics stats (players can spawn before physics runs)
1214         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1215
1216         IL_EACH(g_initforplayer, it.init_for_player, {
1217                 it.init_for_player(it, this);
1218         });
1219
1220         MUTATOR_CALLHOOK(ClientConnect, this);
1221 }
1222 /*
1223 =============
1224 ClientDisconnect
1225
1226 Called when a client disconnects from the server
1227 =============
1228 */
1229 .entity chatbubbleentity;
1230 void ReadyCount();
1231 void ClientDisconnect(entity this)
1232 {
1233         assert(IS_CLIENT(this), return);
1234
1235         PlayerStats_GameReport_FinalizePlayer(this);
1236         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1237         if (this.active_minigame) part_minigame(this);
1238         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1239
1240         if (autocvar_sv_eventlog)
1241                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1242
1243         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1244
1245         SetSpectatee(this, NULL);
1246
1247     MUTATOR_CALLHOOK(ClientDisconnect, this);
1248
1249         ClientState_detach(this);
1250
1251         Portal_ClearAll(this);
1252
1253         Unfreeze(this);
1254
1255         RemoveGrapplingHook(this);
1256
1257         // Here, everything has been done that requires this player to be a client.
1258
1259         this.flags &= ~FL_CLIENT;
1260
1261         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1262         if (this.killindicator) delete(this.killindicator);
1263
1264         WaypointSprite_PlayerGone(this);
1265
1266         bot_relinkplayerlist();
1267
1268         if (this.netname_previous) strunzone(this.netname_previous);
1269         if (this.clientstatus) strunzone(this.clientstatus);
1270         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1271         if (this.personal) delete(this.personal);
1272
1273         this.playerid = 0;
1274         ReadyCount();
1275         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1276 }
1277
1278 void ChatBubbleThink(entity this)
1279 {
1280         this.nextthink = time;
1281         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1282         {
1283                 if(this.owner) // but why can that ever be NULL?
1284                         this.owner.chatbubbleentity = NULL;
1285                 delete(this);
1286                 return;
1287         }
1288
1289         this.mdl = "";
1290
1291         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1292         {
1293                 if ( this.owner.active_minigame )
1294                         this.mdl = "models/sprites/minigame_busy.iqm";
1295                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1296                         this.mdl = "models/misc/chatbubble.spr";
1297         }
1298
1299         if ( this.model != this.mdl )
1300                 _setmodel(this, this.mdl);
1301
1302 }
1303
1304 void UpdateChatBubble(entity this)
1305 {
1306         if (this.alpha < 0)
1307                 return;
1308         // spawn a chatbubble entity if needed
1309         if (!this.chatbubbleentity)
1310         {
1311                 this.chatbubbleentity = new(chatbubbleentity);
1312                 this.chatbubbleentity.owner = this;
1313                 this.chatbubbleentity.exteriormodeltoclient = this;
1314                 setthink(this.chatbubbleentity, ChatBubbleThink);
1315                 this.chatbubbleentity.nextthink = time;
1316                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1317                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1318                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1319                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1320                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1321                 //this.chatbubbleentity.model = "";
1322                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1323         }
1324 }
1325
1326
1327 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1328 // added to the model skins
1329 /*void UpdateColorModHack()
1330 {
1331         float c;
1332         c = this.clientcolors & 15;
1333         // LordHavoc: only bothering to support white, green, red, yellow, blue
1334              if (!teamplay) this.colormod = '0 0 0';
1335         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1336         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1337         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1338         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1339         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1340         else this.colormod = '1 1 1';
1341 }*/
1342
1343 void respawn(entity this)
1344 {
1345         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1346         {
1347                 this.solid = SOLID_NOT;
1348                 this.takedamage = DAMAGE_NO;
1349                 set_movetype(this, MOVETYPE_FLY);
1350                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1351                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1352                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1353                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1354                 if(autocvar_g_respawn_ghosts_maxtime)
1355                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1356         }
1357
1358         CopyBody(this, 1);
1359
1360         this.effects |= EF_NODRAW; // prevent another CopyBody
1361         PutClientInServer(this);
1362 }
1363
1364 void play_countdown(entity this, float finished, Sound samp)
1365 {
1366     TC(Sound, samp);
1367         if(IS_REAL_CLIENT(this))
1368                 if(floor(finished - time - frametime) != floor(finished - time))
1369                         if(finished - time < 6)
1370                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1371 }
1372
1373 void player_powerups(entity this)
1374 {
1375         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1376         int items_prev = this.items;
1377
1378         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1379                 this.modelflags |= MF_ROCKET;
1380         else
1381                 this.modelflags &= ~MF_ROCKET;
1382
1383         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1384
1385         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1386                 return;
1387
1388         Fire_ApplyDamage(this);
1389         Fire_ApplyEffect(this);
1390
1391         if (!g_instagib)
1392         {
1393                 if (this.items & ITEM_Strength.m_itemid)
1394                 {
1395                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1396                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1397                         if (time > this.strength_finished)
1398                         {
1399                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1400                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1401                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1402                         }
1403                 }
1404                 else
1405                 {
1406                         if (time < this.strength_finished)
1407                         {
1408                                 this.items = this.items | ITEM_Strength.m_itemid;
1409                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1410                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1411                         }
1412                 }
1413                 if (this.items & ITEM_Shield.m_itemid)
1414                 {
1415                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1416                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1417                         if (time > this.invincible_finished)
1418                         {
1419                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1420                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1422                         }
1423                 }
1424                 else
1425                 {
1426                         if (time < this.invincible_finished)
1427                         {
1428                                 this.items = this.items | ITEM_Shield.m_itemid;
1429                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1430                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1431                         }
1432                 }
1433                 if (this.items & IT_SUPERWEAPON)
1434                 {
1435                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1436                         {
1437                                 this.superweapons_finished = 0;
1438                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1439                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1440                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1441                         }
1442                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1443                         {
1444                                 // don't let them run out
1445                         }
1446                         else
1447                         {
1448                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1449                                 if (time > this.superweapons_finished)
1450                                 {
1451                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1452                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1453                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1454                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1455                                 }
1456                         }
1457                 }
1458                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1459                 {
1460                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1461                         {
1462                                 this.items = this.items | IT_SUPERWEAPON;
1463                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1465                         }
1466                         else
1467                         {
1468                                 this.superweapons_finished = 0;
1469                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1470                         }
1471                 }
1472                 else
1473                 {
1474                         this.superweapons_finished = 0;
1475                 }
1476         }
1477
1478         if(autocvar_g_nodepthtestplayers)
1479                 this.effects = this.effects | EF_NODEPTHTEST;
1480
1481         if(autocvar_g_fullbrightplayers)
1482                 this.effects = this.effects | EF_FULLBRIGHT;
1483
1484         if (time >= game_starttime)
1485         if (time < this.spawnshieldtime)
1486                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1487
1488         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1489 }
1490
1491 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1492 {
1493         if(current > stable)
1494                 return current;
1495         else if(current > stable - 0.25) // when close enough, "snap"
1496                 return stable;
1497         else
1498                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1499 }
1500
1501 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1502 {
1503         if(current < stable)
1504                 return current;
1505         else if(current < stable + 0.25) // when close enough, "snap"
1506                 return stable;
1507         else
1508                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1509 }
1510
1511 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1512 {
1513         if(current > rotstable)
1514         {
1515                 if(rotframetime > 0)
1516                 {
1517                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1518                         current = max(rotstable, current - rotlinear * rotframetime);
1519                 }
1520         }
1521         else if(current < regenstable)
1522         {
1523                 if(regenframetime > 0)
1524                 {
1525                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1526                         current = min(regenstable, current + regenlinear * regenframetime);
1527                 }
1528         }
1529
1530         if(current > limit)
1531                 current = limit;
1532
1533         return current;
1534 }
1535
1536 void player_regen(entity this)
1537 {
1538         float max_mod, regen_mod, rot_mod, limit_mod;
1539         max_mod = regen_mod = rot_mod = limit_mod = 1;
1540
1541         float regen_health = autocvar_g_balance_health_regen;
1542         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1543         float regen_health_rot = autocvar_g_balance_health_rot;
1544         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1545         float regen_health_stable = autocvar_g_balance_health_regenstable;
1546         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1547         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1548                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1549         max_mod = M_ARGV(1, float);
1550         regen_mod = M_ARGV(2, float);
1551         rot_mod = M_ARGV(3, float);
1552         limit_mod = M_ARGV(4, float);
1553         regen_health = M_ARGV(5, float);
1554         regen_health_linear = M_ARGV(6, float);
1555         regen_health_rot = M_ARGV(7, float);
1556         regen_health_rotlinear = M_ARGV(8, float);
1557         regen_health_stable = M_ARGV(9, float);
1558         regen_health_rotstable = M_ARGV(10, float);
1559
1560
1561         if(!mutator_returnvalue)
1562         if(!STAT(FROZEN, this))
1563         {
1564                 float mina, maxa, limith, limita;
1565                 maxa = autocvar_g_balance_armor_rotstable;
1566                 mina = autocvar_g_balance_armor_regenstable;
1567                 limith = autocvar_g_balance_health_limit;
1568                 limita = autocvar_g_balance_armor_limit;
1569
1570                 regen_health_rotstable = regen_health_rotstable * max_mod;
1571                 regen_health_stable = regen_health_stable * max_mod;
1572                 limith = limith * limit_mod;
1573                 limita = limita * limit_mod;
1574
1575                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1576                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1577         }
1578
1579         // if player rotted to death...  die!
1580         // check this outside above checks, as player may still be able to rot to death
1581         if(this.health < 1)
1582         {
1583                 if(this.vehicle)
1584                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1585                 if(this.event_damage)
1586                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1587         }
1588
1589         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1590         {
1591                 float minf, maxf, limitf;
1592
1593                 maxf = autocvar_g_balance_fuel_rotstable;
1594                 minf = autocvar_g_balance_fuel_regenstable;
1595                 limitf = autocvar_g_balance_fuel_limit;
1596
1597                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1598         }
1599 }
1600
1601 bool zoomstate_set;
1602 void SetZoomState(entity this, float z)
1603 {
1604         if(z != this.zoomstate)
1605         {
1606                 this.zoomstate = z;
1607                 ClientData_Touch(this);
1608         }
1609         zoomstate_set = true;
1610 }
1611
1612 void GetPressedKeys(entity this)
1613 {
1614         MUTATOR_CALLHOOK(GetPressedKeys, this);
1615         int keys = STAT(PRESSED_KEYS, this);
1616         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1617         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1618         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1619         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1620
1621         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1622         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1623         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1624         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1625         this.pressedkeys = keys; // store for other users
1626
1627         STAT(PRESSED_KEYS, this) = keys;
1628 }
1629
1630 /*
1631 ======================
1632 spectate mode routines
1633 ======================
1634 */
1635
1636 void SpectateCopy(entity this, entity spectatee)
1637 {
1638     TC(Client, this); TC(Client, spectatee);
1639
1640         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1641         PS(this) = PS(spectatee);
1642         this.armortype = spectatee.armortype;
1643         this.armorvalue = spectatee.armorvalue;
1644         this.ammo_cells = spectatee.ammo_cells;
1645         this.ammo_plasma = spectatee.ammo_plasma;
1646         this.ammo_shells = spectatee.ammo_shells;
1647         this.ammo_nails = spectatee.ammo_nails;
1648         this.ammo_rockets = spectatee.ammo_rockets;
1649         this.ammo_fuel = spectatee.ammo_fuel;
1650         this.clip_load = spectatee.clip_load;
1651         this.clip_size = spectatee.clip_size;
1652         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1653         this.health = spectatee.health;
1654         this.impulse = 0;
1655         this.items = spectatee.items;
1656         this.last_pickup = spectatee.last_pickup;
1657         this.hit_time = spectatee.hit_time;
1658         this.strength_finished = spectatee.strength_finished;
1659         this.invincible_finished = spectatee.invincible_finished;
1660         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1661         this.weapons = spectatee.weapons;
1662         this.vortex_charge = spectatee.vortex_charge;
1663         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1664         this.hagar_load = spectatee.hagar_load;
1665         this.arc_heat_percent = spectatee.arc_heat_percent;
1666         this.minelayer_mines = spectatee.minelayer_mines;
1667         this.punchangle = spectatee.punchangle;
1668         this.view_ofs = spectatee.view_ofs;
1669         this.velocity = spectatee.velocity;
1670         this.dmg_take = spectatee.dmg_take;
1671         this.dmg_save = spectatee.dmg_save;
1672         this.dmg_inflictor = spectatee.dmg_inflictor;
1673         this.v_angle = spectatee.v_angle;
1674         this.angles = spectatee.v_angle;
1675         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1676         this.revive_progress = spectatee.revive_progress;
1677         this.viewloc = spectatee.viewloc;
1678         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1679                 this.fixangle = true;
1680         setorigin(this, spectatee.origin);
1681         setsize(this, spectatee.mins, spectatee.maxs);
1682         SetZoomState(this, spectatee.zoomstate);
1683
1684     anticheat_spectatecopy(this, spectatee);
1685         this.hud = spectatee.hud;
1686         if(spectatee.vehicle)
1687     {
1688         this.angles = spectatee.v_angle;
1689
1690         //this.fixangle = false;
1691         //this.velocity = spectatee.vehicle.velocity;
1692         this.vehicle_health = spectatee.vehicle_health;
1693         this.vehicle_shield = spectatee.vehicle_shield;
1694         this.vehicle_energy = spectatee.vehicle_energy;
1695         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1696         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1697         this.vehicle_reload1 = spectatee.vehicle_reload1;
1698         this.vehicle_reload2 = spectatee.vehicle_reload2;
1699
1700         //msg_entity = this;
1701
1702        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1703             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1704            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1705            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1706
1707         //WriteByte (MSG_ONE, SVC_SETVIEW);
1708         //    WriteEntity(MSG_ONE, this);
1709         //makevectors(spectatee.v_angle);
1710         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1711     }
1712 }
1713
1714 bool SpectateUpdate(entity this)
1715 {
1716         if(!this.enemy)
1717                 return false;
1718
1719         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1720         {
1721                 SetSpectatee(this, NULL);
1722                 return false;
1723         }
1724
1725         SpectateCopy(this, this.enemy);
1726
1727         return true;
1728 }
1729
1730 bool SpectateSet(entity this)
1731 {
1732         if(!IS_PLAYER(this.enemy))
1733                 return false;
1734
1735         ClientData_Touch(this.enemy);
1736
1737         msg_entity = this;
1738         WriteByte(MSG_ONE, SVC_SETVIEW);
1739         WriteEntity(MSG_ONE, this.enemy);
1740         set_movetype(this, MOVETYPE_NONE);
1741         accuracy_resend(this);
1742
1743         if(!SpectateUpdate(this))
1744                 PutObserverInServer(this);
1745
1746         return true;
1747 }
1748
1749 void SetSpectatee_status(entity this, int spectatee_num)
1750 {
1751         int oldspectatee_status = this.spectatee_status;
1752         this.spectatee_status = spectatee_num;
1753
1754         if (this.spectatee_status != oldspectatee_status)
1755         {
1756                 ClientData_Touch(this);
1757                 if (g_race || g_cts) race_InitSpectator();
1758         }
1759 }
1760
1761 void SetSpectatee(entity this, entity spectatee)
1762 {
1763         entity old_spectatee = this.enemy;
1764
1765         this.enemy = spectatee;
1766
1767         // WEAPONTODO
1768         // these are required to fix the spectator bug with arc
1769         if(old_spectatee)
1770         {
1771                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1772                 {
1773                         .entity weaponentity = weaponentities[slot];
1774                         if(old_spectatee.(weaponentity).arc_beam)
1775                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1776                 }
1777         }
1778         if(this.enemy)
1779         {
1780                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1781                 {
1782                         .entity weaponentity = weaponentities[slot];
1783                         if(this.enemy.(weaponentity).arc_beam)
1784                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1785                 }
1786         }
1787
1788         if (this.enemy)
1789                 SetSpectatee_status(this, etof(this.enemy));
1790
1791         // needed to update spectator list
1792         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1793 }
1794
1795 bool Spectate(entity this, entity pl)
1796 {
1797         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1798                 return false;
1799         pl = M_ARGV(1, entity);
1800
1801         SetSpectatee(this, pl);
1802         return SpectateSet(this);
1803 }
1804
1805 bool SpectateNext(entity this)
1806 {
1807         entity ent = find(this.enemy, classname, STR_PLAYER);
1808
1809         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1810                 ent = M_ARGV(1, entity);
1811         else if (!ent)
1812                 ent = find(ent, classname, STR_PLAYER);
1813
1814         if(ent) { SetSpectatee(this, ent); }
1815
1816         return SpectateSet(this);
1817 }
1818
1819 bool SpectatePrev(entity this)
1820 {
1821         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1822         entity ent = findchain(classname, STR_PLAYER);
1823         if (!ent) // no player
1824                 return false;
1825
1826         entity first = ent;
1827         // skip players until current spectated player
1828         if(this.enemy)
1829         while(ent && ent != this.enemy)
1830                 ent = ent.chain;
1831
1832         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1833         {
1834                 case MUT_SPECPREV_FOUND:
1835                     ent = M_ARGV(1, entity);
1836                     break;
1837                 case MUT_SPECPREV_RETURN:
1838                     return true;
1839                 case MUT_SPECPREV_CONTINUE:
1840                 default:
1841                 {
1842                         if(ent.chain)
1843                                 ent = ent.chain;
1844                         else
1845                                 ent = first;
1846                         break;
1847                 }
1848         }
1849
1850         SetSpectatee(this, ent);
1851         return SpectateSet(this);
1852 }
1853
1854 /*
1855 =============
1856 ShowRespawnCountdown()
1857
1858 Update a respawn countdown display.
1859 =============
1860 */
1861 void ShowRespawnCountdown(entity this)
1862 {
1863         float number;
1864         if(!IS_DEAD(this)) // just respawned?
1865                 return;
1866         else
1867         {
1868                 number = ceil(this.respawn_time - time);
1869                 if(number <= 0)
1870                         return;
1871                 if(number <= this.respawn_countdown)
1872                 {
1873                         this.respawn_countdown = number - 1;
1874                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1875                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1876                 }
1877         }
1878 }
1879
1880 .bool team_selected;
1881 bool ShowTeamSelection(entity this)
1882 {
1883         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1884                 return false;
1885         stuffcmd(this, "menu_showteamselect\n");
1886         return true;
1887 }
1888 void Join(entity this)
1889 {
1890         TRANSMUTE(Player, this);
1891
1892         if(!this.team_selected)
1893         if(autocvar_g_campaign || autocvar_g_balance_teams)
1894                 JoinBestTeam(this, false, true);
1895
1896         if(autocvar_g_campaign)
1897                 campaign_bots_may_start = true;
1898
1899         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1900
1901         PutClientInServer(this);
1902
1903         if(teamplay && this.team != -1)
1904                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1905         else
1906                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1907         this.team_selected = false;
1908 }
1909
1910 /**
1911  * Determines whether the player is allowed to join. This depends on cvar
1912  * g_maxplayers, if it isn't used this function always return true, otherwise
1913  * it checks whether the number of currently playing players exceeds g_maxplayers.
1914  * @return int number of free slots for players, 0 if none
1915  */
1916 int nJoinAllowed(entity this, entity ignore)
1917 {
1918         if(!ignore)
1919         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1920         // so report 0 free slots if restricted
1921         {
1922                 if(autocvar_g_forced_team_otherwise == "spectate")
1923                         return 0;
1924                 if(autocvar_g_forced_team_otherwise == "spectator")
1925                         return 0;
1926         }
1927
1928         if(this && this.team_forced < 0)
1929                 return 0; // forced spectators can never join
1930
1931         // TODO simplify this
1932         int totalClients = 0;
1933         int currentlyPlaying = 0;
1934         FOREACH_CLIENT(true, LAMBDA(
1935                 if(it != ignore)
1936                         ++totalClients;
1937                 if(IS_REAL_CLIENT(it))
1938                 if(IS_PLAYER(it) || it.caplayer)
1939                         ++currentlyPlaying;
1940         ));
1941
1942         float free_slots = 0;
1943         if (!autocvar_g_maxplayers)
1944                 free_slots = maxclients - totalClients;
1945         else if(currentlyPlaying < autocvar_g_maxplayers)
1946                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1947
1948         static float join_prevent_msg_time = 0;
1949         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1950         {
1951                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1952                 join_prevent_msg_time = time + 3;
1953         }
1954
1955         return free_slots;
1956 }
1957
1958 /**
1959  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1960  * g_maxplayers_spectator_blocktime seconds
1961  */
1962 void checkSpectatorBlock(entity this)
1963 {
1964         if(IS_SPEC(this) || IS_OBSERVER(this))
1965         if(!this.caplayer)
1966         if(IS_REAL_CLIENT(this))
1967         {
1968                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1969                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1970                         dropclient(this);
1971                 }
1972         }
1973 }
1974
1975 void PrintWelcomeMessage(entity this)
1976 {
1977         if(this.motd_actived_time == 0)
1978         {
1979                 if (autocvar_g_campaign) {
1980                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1981                                 this.motd_actived_time = time;
1982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1983                         }
1984                 } else {
1985                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1986                                 this.motd_actived_time = time;
1987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1988                         }
1989                 }
1990         }
1991         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1992         {
1993                 if (autocvar_g_campaign) {
1994                         if (PHYS_INPUT_BUTTON_INFO(this))
1995                                 this.motd_actived_time = time;
1996                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1997                                 this.motd_actived_time = 0;
1998                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1999                         }
2000                 } else {
2001                         if (PHYS_INPUT_BUTTON_INFO(this))
2002                                 this.motd_actived_time = time;
2003                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2004                                 this.motd_actived_time = 0;
2005                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2006                         }
2007                 }
2008         }
2009         else //if(this.motd_actived_time < 0) // just connected, motd is active
2010         {
2011                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2012                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2013                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2014                 {
2015                         // instanctly hide MOTD
2016                         this.motd_actived_time = 0;
2017                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2018                 }
2019         }
2020 }
2021
2022 bool joinAllowed(entity this)
2023 {
2024         if (this.version_mismatch) return false;
2025         if (!nJoinAllowed(this, this)) return false;
2026         if (teamplay && lockteams) return false;
2027         if (ShowTeamSelection(this)) return false;
2028         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2029         return true;
2030 }
2031
2032 void ObserverThink(entity this)
2033 {
2034         if ( this.impulse )
2035         {
2036                 MinigameImpulse(this, this.impulse);
2037                 this.impulse = 0;
2038         }
2039
2040         if (this.flags & FL_JUMPRELEASED) {
2041                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2042                         this.flags &= ~FL_JUMPRELEASED;
2043                         this.flags |= FL_SPAWNING;
2044                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2045                         this.flags &= ~FL_JUMPRELEASED;
2046                         if(SpectateNext(this)) {
2047                                 TRANSMUTE(Spectator, this);
2048                         }
2049                 } else {
2050                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2051                         set_movetype(this, preferred_movetype);
2052                 }
2053         } else {
2054                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2055                         this.flags |= FL_JUMPRELEASED;
2056                         if(this.flags & FL_SPAWNING)
2057                         {
2058                                 this.flags &= ~FL_SPAWNING;
2059                                 Join(this);
2060                                 return;
2061                         }
2062                 }
2063         }
2064 }
2065
2066 void SpectatorThink(entity this)
2067 {
2068         if ( this.impulse )
2069         {
2070                 if(MinigameImpulse(this, this.impulse))
2071                         this.impulse = 0;
2072
2073                 if (this.impulse == IMP_weapon_drop.impulse)
2074                 {
2075                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2076                         this.impulse = 0;
2077                         return;
2078                 }
2079         }
2080
2081         if (this.flags & FL_JUMPRELEASED) {
2082                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2083                         this.flags &= ~FL_JUMPRELEASED;
2084                         this.flags |= FL_SPAWNING;
2085                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2086                         this.flags &= ~FL_JUMPRELEASED;
2087                         if(SpectateNext(this)) {
2088                                 TRANSMUTE(Spectator, this);
2089                         } else {
2090                                 TRANSMUTE(Observer, this);
2091                                 PutClientInServer(this);
2092                         }
2093                         this.impulse = 0;
2094                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2095                         this.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectatePrev(this)) {
2097                                 TRANSMUTE(Spectator, this);
2098                         } else {
2099                                 TRANSMUTE(Observer, this);
2100                                 PutClientInServer(this);
2101                         }
2102                         this.impulse = 0;
2103                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2104                         this.flags &= ~FL_JUMPRELEASED;
2105                         TRANSMUTE(Observer, this);
2106                         PutClientInServer(this);
2107                 } else {
2108                         if(!SpectateUpdate(this))
2109                                 PutObserverInServer(this);
2110                 }
2111         } else {
2112                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2113                         this.flags |= FL_JUMPRELEASED;
2114                         if(this.flags & FL_SPAWNING)
2115                         {
2116                                 this.flags &= ~FL_SPAWNING;
2117                                 Join(this);
2118                                 return;
2119                         }
2120                 }
2121                 if(!SpectateUpdate(this))
2122                         PutObserverInServer(this);
2123         }
2124
2125         this.flags |= FL_CLIENT | FL_NOTARGET;
2126 }
2127
2128 void vehicles_enter (entity pl, entity veh);
2129 void PlayerUseKey(entity this)
2130 {
2131         if (!IS_PLAYER(this))
2132                 return;
2133
2134         if(this.vehicle)
2135         {
2136                 if(!gameover)
2137                 {
2138                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2139                         return;
2140                 }
2141         }
2142         else if(autocvar_g_vehicles_enter)
2143         {
2144                 if(!STAT(FROZEN, this))
2145                 if(!IS_DEAD(this))
2146                 if(!gameover)
2147                 {
2148                         entity head, closest_target = NULL;
2149                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2150
2151                         while(head) // find the closest acceptable target to enter
2152                         {
2153                                 if(IS_VEHICLE(head))
2154                                 if(!IS_DEAD(head))
2155                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2156                                 if(head.takedamage != DAMAGE_NO)
2157                                 {
2158                                         if(closest_target)
2159                                         {
2160                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2161                                                 { closest_target = head; }
2162                                         }
2163                                         else { closest_target = head; }
2164                                 }
2165
2166                                 head = head.chain;
2167                         }
2168
2169                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2170                 }
2171         }
2172
2173         // a use key was pressed; call handlers
2174         MUTATOR_CALLHOOK(PlayerUseKey, this);
2175 }
2176
2177
2178 /*
2179 =============
2180 PlayerPreThink
2181
2182 Called every frame for each client before the physics are run
2183 =============
2184 */
2185 .float usekeypressed;
2186 .float last_vehiclecheck;
2187 .int items_added;
2188 void PlayerPreThink (entity this)
2189 {
2190         WarpZone_PlayerPhysics_FixVAngle(this);
2191
2192     STAT(GAMESTARTTIME, this) = game_starttime;
2193         STAT(ROUNDSTARTTIME, this) = round_starttime;
2194         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2195         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2196
2197         STAT(WEAPONSINMAP, this) = weaponsInMap;
2198
2199         if (frametime) {
2200                 // physics frames: update anticheat stuff
2201                 anticheat_prethink(this);
2202         }
2203
2204         if (blockSpectators && frametime) {
2205                 // WORKAROUND: only use dropclient in server frames (frametime set).
2206                 // Never use it in cl_movement frames (frametime zero).
2207                 checkSpectatorBlock(this);
2208     }
2209
2210         zoomstate_set = false;
2211
2212         // Check for nameless players
2213         if (isInvisibleString(this.netname)) {
2214                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2215                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2216         }
2217         if (this.netname != this.netname_previous) {
2218                 if (autocvar_sv_eventlog) {
2219                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2220         }
2221                 if (this.netname_previous) strunzone(this.netname_previous);
2222                 this.netname_previous = strzone(this.netname);
2223         }
2224
2225         // version nagging
2226         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2227         this.version_nagtime = 0;
2228         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2229             // git client
2230         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2231             // git server
2232             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2233         } else {
2234             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2235             if (r < 0) { // old client
2236                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2237             } else if (r > 0) { // old server
2238                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2239             }
2240         }
2241     }
2242
2243         // GOD MODE info
2244         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2245         {
2246                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2247                 this.max_armorvalue = 0;
2248         }
2249
2250         if (STAT(FROZEN, this) == 2)
2251         {
2252                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2253                 this.health = max(1, this.revive_progress * start_health);
2254                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2255
2256                 if (this.revive_progress >= 1)
2257                         Unfreeze(this);
2258         }
2259         else if (STAT(FROZEN, this) == 3)
2260         {
2261                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2262                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2263
2264                 if (this.health < 1)
2265                 {
2266                         if (this.vehicle)
2267                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2268                         if(this.event_damage)
2269                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2270                 }
2271                 else if (this.revive_progress <= 0)
2272                         Unfreeze(this);
2273         }
2274
2275         MUTATOR_CALLHOOK(PlayerPreThink, this);
2276
2277         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2278         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2279         {
2280                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2281                 {
2282                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2283                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2284                         {
2285                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2286                         }
2287                         else if(!it.owner)
2288                         {
2289                                 if(!it.team || SAME_TEAM(this, it))
2290                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2291                                 else if(autocvar_g_vehicles_steal)
2292                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2293                         }
2294                 });
2295
2296                 this.last_vehiclecheck = time + 1;
2297         }
2298
2299         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2300         {
2301                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2302                         PlayerUseKey(this);
2303                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2304         }
2305
2306         if (IS_REAL_CLIENT(this))
2307                 PrintWelcomeMessage(this);
2308
2309         if (IS_PLAYER(this)) {
2310                 CheckRules_Player(this);
2311
2312                 if (intermission_running) {
2313                         IntermissionThink(this);
2314                         return;
2315                 }
2316
2317                 if (timeout_status == TIMEOUT_ACTIVE) {
2318             // don't allow the player to turn around while game is paused
2319                         // FIXME turn this into CSQC stuff
2320                         this.v_angle = this.lastV_angle;
2321                         this.angles = this.lastV_angle;
2322                         this.fixangle = true;
2323                 }
2324
2325                 if (frametime) player_powerups(this);
2326
2327                 if (IS_DEAD(this)) {
2328                         if (this.personal && g_race_qualifying) {
2329                                 if (time > this.respawn_time) {
2330                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2331                                         respawn(this);
2332                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2333                                 }
2334                         } else {
2335                                 if (frametime) player_anim(this);
2336                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2337
2338                                 switch(this.deadflag)
2339                                 {
2340                                         case DEAD_DYING:
2341                                         {
2342                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2343                                                         this.deadflag = DEAD_RESPAWNING;
2344                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2345                                                         this.deadflag = DEAD_DEAD;
2346                                                 break;
2347                                         }
2348                                         case DEAD_DEAD:
2349                                         {
2350                                                 if (button_pressed)
2351                                                         this.deadflag = DEAD_RESPAWNABLE;
2352                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2353                                                         this.deadflag = DEAD_RESPAWNING;
2354                                                 break;
2355                                         }
2356                                         case DEAD_RESPAWNABLE:
2357                                         {
2358                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2359                                                         this.deadflag = DEAD_RESPAWNING;
2360                                                 break;
2361                                         }
2362                                         case DEAD_RESPAWNING:
2363                                         {
2364                                                 if (time > this.respawn_time)
2365                                                 {
2366                                                         this.respawn_time = time + 1; // only retry once a second
2367                                                         this.respawn_time_max = this.respawn_time;
2368                                                         respawn(this);
2369                                                 }
2370                                                 break;
2371                                         }
2372                                 }
2373
2374                                 ShowRespawnCountdown(this);
2375
2376                                 if (this.respawn_flags & RESPAWN_SILENT)
2377                                         STAT(RESPAWN_TIME, this) = 0;
2378                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2379                                 {
2380                                         if (time < this.respawn_time)
2381                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2382                                         else if (this.deadflag != DEAD_RESPAWNING)
2383                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2384                                 }
2385                                 else
2386                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2387                         }
2388
2389                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2390                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2391                                 STAT(RESPAWN_TIME, this) *= -1;
2392
2393                         return;
2394                 }
2395
2396                 this.prevorigin = this.origin;
2397
2398                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2399                 if (this.hook.state) {
2400                         do_crouch = false;
2401                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2402                         do_crouch = false;
2403                 } else if (this.vehicle) {
2404                         do_crouch = false;
2405                 } else if (STAT(FROZEN, this)) {
2406                         do_crouch = false;
2407         }
2408
2409                 if (do_crouch) {
2410                         if (!this.crouch) {
2411                                 this.crouch = true;
2412                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2413                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2414                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2415                         }
2416                 } else if (this.crouch) {
2417             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2418             if (!trace_startsolid) {
2419                 this.crouch = false;
2420                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2421                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2422             }
2423                 }
2424
2425                 FixPlayermodel(this);
2426
2427                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2428                 //if(frametime)
2429                 {
2430                         this.items &= ~this.items_added;
2431
2432                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2433                         //{
2434                                 //.entity weaponentity = weaponentities[slot];
2435                                 //W_WeaponFrame(this, weaponentity);
2436                         //}
2437                         .entity weaponentity = weaponentities[0]; // TODO
2438                         W_WeaponFrame(this, weaponentity);
2439
2440                         this.items_added = 0;
2441                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2442                 this.items_added |= IT_FUEL;
2443
2444                         this.items |= this.items_added;
2445                 }
2446
2447                 player_regen(this);
2448
2449                 // WEAPONTODO: Add a weapon request for this
2450                 // rot vortex charge to the charge limit
2451                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2452                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2453
2454                 if (frametime) player_anim(this);
2455
2456                 // secret status
2457                 secrets_setstatus(this);
2458
2459                 // monsters status
2460                 monsters_setstatus(this);
2461
2462                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2463         }
2464         else if (gameover) {
2465                 if (intermission_running) IntermissionThink(this);
2466                 return;
2467         }
2468         else if (IS_OBSERVER(this)) {
2469                 ObserverThink(this);
2470         }
2471         else if (IS_SPEC(this)) {
2472                 SpectatorThink(this);
2473         }
2474
2475         // WEAPONTODO: Add weapon request for this
2476         if (!zoomstate_set) {
2477                 SetZoomState(this,
2478                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2479                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2480                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2481                 );
2482     }
2483
2484         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2485         {
2486                 this.teamkill_soundtime = 0;
2487
2488                 entity e = this.teamkill_soundsource;
2489                 entity oldpusher = e.pusher;
2490                 e.pusher = this;
2491                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2492                 e.pusher = oldpusher;
2493         }
2494
2495         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2496                 this.taunt_soundtime = 0;
2497                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2498         }
2499
2500         target_voicescript_next(this);
2501
2502         // WEAPONTODO: Move into weaponsystem somehow
2503         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2504         if (PS(this).m_weapon == WEP_Null)
2505                 this.clip_load = this.clip_size = 0;
2506 }
2507
2508 void DrownPlayer(entity this)
2509 {
2510         if(IS_DEAD(this))
2511                 return;
2512
2513         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2514         {
2515                 if(this.air_finished < time)
2516                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2517                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2518                 this.dmg = 2;
2519         }
2520         else if (this.air_finished < time)
2521         {       // drown!
2522                 if (this.pain_finished < time)
2523                 {
2524                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2525                         this.pain_finished = time + 0.5;
2526                 }
2527         }
2528 }
2529
2530 .bool move_qcphysics;
2531
2532 void Player_Physics(entity this)
2533 {
2534         set_movetype(this, this.move_movetype);
2535
2536         if(!this.move_qcphysics)
2537                 return;
2538
2539         if(!frametime && !this.pm_frametime)
2540                 return;
2541
2542         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2543
2544         this.pm_frametime = 0;
2545 }
2546
2547 /*
2548 =============
2549 PlayerPostThink
2550
2551 Called every frame for each client after the physics are run
2552 =============
2553 */
2554 .float idlekick_lasttimeleft;
2555 void PlayerPostThink (entity this)
2556 {
2557         Player_Physics(this);
2558
2559         if (sv_maxidle > 0)
2560         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2561         if (IS_REAL_CLIENT(this))
2562         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2563         {
2564                 int totalClients = 0;
2565                 if(sv_maxidle_slots > 0)
2566                 {
2567                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2568                         {
2569                                 ++totalClients;
2570                         });
2571                 }
2572
2573                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2574                 { /* do nothing */ }
2575                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2576                 {
2577                         if (this.idlekick_lasttimeleft)
2578                         {
2579                                 this.idlekick_lasttimeleft = 0;
2580                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2581                         }
2582                 }
2583                 else
2584                 {
2585                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2586                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2587                                 if (!this.idlekick_lasttimeleft)
2588                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2589                         }
2590                         if (timeleft <= 0) {
2591                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2592                                 dropclient(this);
2593                                 return;
2594                         }
2595                         else if (timeleft <= 10) {
2596                                 if (timeleft != this.idlekick_lasttimeleft) {
2597                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2598                 }
2599                                 this.idlekick_lasttimeleft = timeleft;
2600                         }
2601                 }
2602         }
2603
2604         CheatFrame(this);
2605
2606         //CheckPlayerJump();
2607
2608         if (IS_PLAYER(this)) {
2609                 DrownPlayer(this);
2610                 CheckRules_Player(this);
2611                 UpdateChatBubble(this);
2612                 if (this.impulse) ImpulseCommands(this);
2613                 if (intermission_running) return; // intermission or finale
2614                 GetPressedKeys(this);
2615         }
2616
2617         if (this.waypointsprite_attachedforcarrier) {
2618             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2619                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2620     }
2621
2622         playerdemo_write(this);
2623
2624         CSQCMODEL_AUTOUPDATE(this);
2625 }