qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 #include <common/mutators/mutator/overkill/okvortex.qh>
  60
  61 STATIC_METHOD(Client, Add, void(Client this, int _team))
  62 {
  63     ClientConnect(this);
  64     TRANSMUTE(Player, this);
  65     this.frame = 12; // 7
  66     this.team = _team;
  67     PutClientInServer(this);
  68 }
  69
  70 void PutObserverInServer(entity this);
  71
  72 STATIC_METHOD(Client, Remove, void(Client this))
  73 {
  74     TRANSMUTE(Observer, this);
  75     PutClientInServer(this);
  76     ClientDisconnect(this);
  77 }
  78
  79 void send_CSQC_teamnagger() {
  80         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  81 }
  82
  83 int CountSpectators(entity player, entity to)
  84 {
  85         if(!player) { return 0; } // not sure how, but best to be safe
  86
  87         int spec_count = 0;
  88
  89         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  90         {
  91                 spec_count++;
  92         });
  93
  94         return spec_count;
  95 }
  96
  97 void WriteSpectators(entity player, entity to)
  98 {
  99         if(!player) { return; } // not sure how, but best to be safe
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 WriteByte(MSG_ENTITY, num_for_edict(it));
 104         });
 105 }
 106
 107 bool ClientData_Send(entity this, entity to, int sf)
 108 {
 109         assert(to == this.owner, return false);
 110
 111         entity e = to;
 112         if (IS_SPEC(e)) e = e.enemy;
 113
 114         sf = 0;
 115         if (e.race_completed)       sf |= 1; // forced scoreboard
 116         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 117         if (e.zoomstate)            sf |= 4; // zoomed
 118         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 119
 120         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 121         WriteByte(MSG_ENTITY, sf);
 122
 123         if (sf & 2)
 124         {
 125                 WriteByte(MSG_ENTITY, to.spectatee_status);
 126         }
 127
 128         if(sf & 16)
 129         {
 130                 float specs = CountSpectators(e, to);
 131                 WriteByte(MSG_ENTITY, specs);
 132                 WriteSpectators(e, to);
 133         }
 134
 135         return true;
 136 }
 137
 138 void ClientData_Attach(entity this)
 139 {
 140         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 141         this.clientdata.drawonlytoclient = this;
 142         this.clientdata.owner = this;
 143 }
 144
 145 void ClientData_Detach(entity this)
 146 {
 147         delete(this.clientdata);
 148         this.clientdata = NULL;
 149 }
 150
 151 void ClientData_Touch(entity e)
 152 {
 153         e.clientdata.SendFlags = 1;
 154
 155         // make it spectatable
 156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 157 }
 158
 159 .string netname_previous;
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = spot.angles;
 233         this.angles_z = 0;
 234         this.fixangle = true;
 235         // offset it so that the spectator spawns higher off the ground, looks better this way
 236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 237         this.prevorigin = this.origin;
 238         if (IS_REAL_CLIENT(this))
 239         {
 240             msg_entity = this;
 241             WriteByte(MSG_ONE, SVC_SETVIEW);
 242             WriteEntity(MSG_ONE, this);
 243         }
 244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 246         if(!autocvar_g_debug_globalsounds)
 247         {
 248                 // needed for player sounds
 249                 this.model = "";
 250                 FixPlayermodel(this);
 251         }
 252         setmodel(this, MDL_Null);
 253         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 254         this.view_ofs = '0 0 0';
 255     }
 256
 257     RemoveGrapplingHooks(this);
 258         Portal_ClearAll(this);
 259         Unfreeze(this);
 260         SetSpectatee(this, NULL);
 261
 262         if (this.alivetime)
 263         {
 264                 if (!warmup_stage)
 265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 266                 this.alivetime = 0;
 267         }
 268
 269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 270
 271         WaypointSprite_PlayerDead(this);
 272
 273         if (mutator_returnvalue) {
 274             // mutator prevents resetting teams+score
 275         } else {
 276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 277         this.frags = FRAGS_SPECTATOR;
 278         PlayerScore_Clear(this);  // clear scores when needed
 279     }
 280
 281         if (this.killcount != FRAGS_SPECTATOR)
 282         {
 283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 284                 if(!game_stopped)
 285                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 287
 288                 if(this.just_joined == false) {
 289                         LogTeamchange(this.playerid, -1, 4);
 290                 } else
 291                         this.just_joined = false;
 292         }
 293
 294         accuracy_resend(this);
 295
 296         this.spectatortime = time;
 297         if(this.bot_attack)
 298                 IL_REMOVE(g_bot_targets, this);
 299         this.bot_attack = false;
 300     this.hud = HUD_NORMAL;
 301         TRANSMUTE(Observer, this);
 302         this.iscreature = false;
 303         this.teleportable = TELEPORT_SIMPLE;
 304         if(this.damagedbycontents)
 305                 IL_REMOVE(g_damagedbycontents, this);
 306         this.damagedbycontents = false;
 307         this.health = FRAGS_SPECTATOR;
 308         SetSpectatee_status(this, etof(this));
 309         this.takedamage = DAMAGE_NO;
 310         this.solid = SOLID_NOT;
 311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 312         this.flags = FL_CLIENT | FL_NOTARGET;
 313         this.armorvalue = 666;
 314         this.effects = 0;
 315         this.armorvalue = autocvar_g_balance_armor_start;
 316         this.pauserotarmor_finished = 0;
 317         this.pauserothealth_finished = 0;
 318         this.pauseregen_finished = 0;
 319         this.damageforcescale = 0;
 320         this.death_time = 0;
 321         this.respawn_flags = 0;
 322         this.respawn_time = 0;
 323         this.stat_respawn_time = 0;
 324         this.alpha = 0;
 325         this.scale = 0;
 326         this.fade_time = 0;
 327         this.pain_frame = 0;
 328         this.pain_finished = 0;
 329         this.strength_finished = 0;
 330         this.invincible_finished = 0;
 331         this.superweapons_finished = 0;
 332         this.pushltime = 0;
 333         this.istypefrag = 0;
 334         setthink(this, func_null);
 335         this.nextthink = 0;
 336         this.deadflag = DEAD_NO;
 337         this.crouch = false;
 338         this.revive_progress = 0;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.dual_weapons = '0 0 0';
 344         this.drawonlytoclient = this;
 345
 346         this.weaponmodel = "";
 347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 348         {
 349                 this.weaponentities[slot] = NULL;
 350         }
 351         this.exteriorweaponentity = NULL;
 352         this.killcount = FRAGS_SPECTATOR;
 353         this.velocity = '0 0 0';
 354         this.avelocity = '0 0 0';
 355         this.punchangle = '0 0 0';
 356         this.punchvector = '0 0 0';
 357         this.oldvelocity = this.velocity;
 358         this.fire_endtime = -1;
 359         this.event_damage = func_null;
 360
 361         for(int slot = 0; slot < MAX_AXH; ++slot)
 362         {
 363                 entity axh = this.(AuxiliaryXhair[slot]);
 364                 this.(AuxiliaryXhair[slot]) = NULL;
 365
 366                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 367                         delete(axh);
 368         }
 369 }
 370
 371 int player_getspecies(entity this)
 372 {
 373         get_model_parameters(this.model, this.skin);
 374         int s = get_model_parameters_species;
 375         get_model_parameters(string_null, 0);
 376         if (s < 0) return SPECIES_HUMAN;
 377         return s;
 378 }
 379
 380 .float model_randomizer;
 381 void FixPlayermodel(entity player)
 382 {
 383         string defaultmodel = "";
 384         int defaultskin = 0;
 385         if(autocvar_sv_defaultcharacter)
 386         {
 387                 if(teamplay)
 388                 {
 389                         switch(player.team)
 390                         {
 391                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 392                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 393                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 394                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 395                         }
 396                 }
 397
 398                 if(defaultmodel == "")
 399                 {
 400                         defaultmodel = autocvar_sv_defaultplayermodel;
 401                         defaultskin = autocvar_sv_defaultplayerskin;
 402                 }
 403
 404                 int n = tokenize_console(defaultmodel);
 405                 if(n > 0)
 406                 {
 407                         defaultmodel = argv(floor(n * player.model_randomizer));
 408                         // However, do NOT randomize if the player-selected model is in the list.
 409                         for (int i = 0; i < n; ++i)
 410                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 411                                         defaultmodel = argv(i);
 412                 }
 413
 414                 int i = strstrofs(defaultmodel, ":", 0);
 415                 if(i >= 0)
 416                 {
 417                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 418                         defaultmodel = substring(defaultmodel, 0, i);
 419                 }
 420         }
 421         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 422         {
 423                 if(teamplay)
 424                 {
 425                         switch(player.team)
 426                         {
 427                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 428                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 429                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 430                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 431                         }
 432                 }
 433
 434                 if(!defaultskin)
 435                         defaultskin = autocvar_sv_defaultplayerskin;
 436         }
 437
 438         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 439         defaultmodel = M_ARGV(0, string);
 440         defaultskin = M_ARGV(1, int);
 441
 442         bool chmdl = false;
 443         int oldskin;
 444         if(defaultmodel != "")
 445         {
 446                 if (defaultmodel != player.model)
 447                 {
 448                         vector m1 = player.mins;
 449                         vector m2 = player.maxs;
 450                         setplayermodel (player, defaultmodel);
 451                         setsize (player, m1, m2);
 452                         chmdl = true;
 453                 }
 454
 455                 oldskin = player.skin;
 456                 player.skin = defaultskin;
 457         } else {
 458                 if (player.playermodel != player.model || player.playermodel == "")
 459                 {
 460                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 461                         vector m1 = player.mins;
 462                         vector m2 = player.maxs;
 463                         setplayermodel (player, player.playermodel);
 464                         setsize (player, m1, m2);
 465                         chmdl = true;
 466                 }
 467
 468                 if(!autocvar_sv_defaultcharacterskin)
 469                 {
 470                         oldskin = player.skin;
 471                         player.skin = stof(player.playerskin);
 472                 }
 473                 else
 474                 {
 475                         oldskin = player.skin;
 476                         player.skin = defaultskin;
 477                 }
 478         }
 479
 480         if(chmdl || oldskin != player.skin) // model or skin has changed
 481         {
 482                 player.species = player_getspecies(player); // update species
 483                 if(!autocvar_g_debug_globalsounds)
 484                         UpdatePlayerSounds(player); // update skin sounds
 485         }
 486
 487         if(!teamplay)
 488                 if(strlen(autocvar_sv_defaultplayercolors))
 489                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 490                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 491 }
 492
 493
 494 /** Called when a client spawns in the server */
 495 void PutClientInServer(entity this)
 496 {
 497         if (IS_BOT_CLIENT(this)) {
 498                 TRANSMUTE(Player, this);
 499         } else if (IS_REAL_CLIENT(this)) {
 500                 msg_entity = this;
 501                 WriteByte(MSG_ONE, SVC_SETVIEW);
 502                 WriteEntity(MSG_ONE, this);
 503         }
 504         if (game_stopped)
 505                 TRANSMUTE(Observer, this);
 506
 507         SetSpectatee(this, NULL);
 508
 509         // reset player keys
 510         this.itemkeys = 0;
 511
 512         MUTATOR_CALLHOOK(PutClientInServer, this);
 513
 514         if (IS_OBSERVER(this)) {
 515                 PutObserverInServer(this);
 516         } else if (IS_PLAYER(this)) {
 517                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 518
 519                 PlayerState_attach(this);
 520                 accuracy_resend(this);
 521
 522                 if (this.team < 0)
 523                         JoinBestTeam(this, false, true);
 524
 525                 entity spot = SelectSpawnPoint(this, false);
 526                 if (!spot) {
 527                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 528                         return; // spawn failed
 529                 }
 530
 531                 TRANSMUTE(Player, this);
 532
 533                 this.wasplayer = true;
 534                 this.iscreature = true;
 535                 this.teleportable = TELEPORT_NORMAL;
 536                 if(!this.damagedbycontents)
 537                         IL_PUSH(g_damagedbycontents, this);
 538                 this.damagedbycontents = true;
 539                 set_movetype(this, MOVETYPE_WALK);
 540                 this.solid = SOLID_SLIDEBOX;
 541                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 542                 if (autocvar_g_playerclip_collisions)
 543                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 544                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 545                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 546                 this.frags = FRAGS_PLAYER;
 547                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 548                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 549                 if (autocvar__notarget)
 550                         this.flags |= FL_NOTARGET;
 551                 this.takedamage = DAMAGE_AIM;
 552                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 553                 this.dmg = 2; // WTF
 554
 555                 if (warmup_stage) {
 556                         this.ammo_shells = warmup_start_ammo_shells;
 557                         this.ammo_nails = warmup_start_ammo_nails;
 558                         this.ammo_rockets = warmup_start_ammo_rockets;
 559                         this.ammo_cells = warmup_start_ammo_cells;
 560                         this.ammo_plasma = warmup_start_ammo_plasma;
 561                         this.ammo_fuel = warmup_start_ammo_fuel;
 562                         this.health = warmup_start_health;
 563                         this.armorvalue = warmup_start_armorvalue;
 564                         this.weapons = WARMUP_START_WEAPONS;
 565                 } else {
 566                         this.ammo_shells = start_ammo_shells;
 567                         this.ammo_nails = start_ammo_nails;
 568                         this.ammo_rockets = start_ammo_rockets;
 569                         this.ammo_cells = start_ammo_cells;
 570                         this.ammo_plasma = start_ammo_plasma;
 571                         this.ammo_fuel = start_ammo_fuel;
 572                         this.health = start_health;
 573                         this.armorvalue = start_armorvalue;
 574                         this.weapons = start_weapons;
 575                 }
 576                 SetSpectatee_status(this, 0);
 577
 578                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 579
 580                 this.items = start_items;
 581
 582                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 583                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 584                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 585                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 586                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 587                 // extend the pause of rotting if client was reset at the beginning of the countdown
 588                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 589                         float f = game_starttime - time;
 590                         this.spawnshieldtime += f;
 591                         this.pauserotarmor_finished += f;
 592                         this.pauserothealth_finished += f;
 593                         this.pauseregen_finished += f;
 594                 }
 595                 this.damageforcescale = 2;
 596                 this.death_time = 0;
 597                 this.respawn_flags = 0;
 598                 this.respawn_time = 0;
 599                 this.stat_respawn_time = 0;
 600                 this.scale = autocvar_sv_player_scale;
 601                 this.fade_time = 0;
 602                 this.pain_frame = 0;
 603                 this.pain_finished = 0;
 604                 this.pushltime = 0;
 605                 setthink(this, func_null); // players have no think function
 606                 this.nextthink = 0;
 607                 this.dmg_team = 0;
 608                 this.ballistics_density = autocvar_g_ballistics_density_player;
 609
 610                 this.deadflag = DEAD_NO;
 611
 612                 this.angles = spot.angles;
 613                 this.angles_z = 0; // never spawn tilted even if the spot says to
 614                 if (IS_BOT_CLIENT(this))
 615                         this.v_angle = this.angles;
 616                 this.fixangle = true; // turn this way immediately
 617                 this.oldvelocity = this.velocity = '0 0 0';
 618                 this.avelocity = '0 0 0';
 619                 this.punchangle = '0 0 0';
 620                 this.punchvector = '0 0 0';
 621
 622                 this.strength_finished = 0;
 623                 this.invincible_finished = 0;
 624                 this.fire_endtime = -1;
 625                 this.revive_progress = 0;
 626                 this.revival_time = 0;
 627                 this.air_finished = time + 12;
 628
 629                 entity spawnevent = new_pure(spawnevent);
 630                 spawnevent.owner = this;
 631                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 632
 633                 // Cut off any still running player sounds.
 634                 stopsound(this, CH_PLAYER_SINGLE);
 635
 636                 this.model = "";
 637                 FixPlayermodel(this);
 638                 this.drawonlytoclient = NULL;
 639
 640                 this.viewloc = NULL;
 641
 642                 this.crouch = false;
 643                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 644                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 645                 this.spawnorigin = spot.origin;
 646                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 647                 // don't reset back to last position, even if new position is stuck in solid
 648                 this.oldorigin = this.origin;
 649                 this.prevorigin = this.origin;
 650                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 651                 if(this.conveyor)
 652                         IL_REMOVE(g_conveyed, this);
 653                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 654                 this.hud = HUD_NORMAL;
 655
 656                 this.event_damage = PlayerDamage;
 657
 658                 if(!this.bot_attack)
 659                         IL_PUSH(g_bot_targets, this);
 660                 this.bot_attack = true;
 661                 this.monster_attack = true;
 662                 navigation_dynamicgoal_init(this, false);
 663
 664                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 665
 666                 if (this.killcount == FRAGS_SPECTATOR) {
 667                         PlayerScore_Clear(this);
 668                         this.killcount = 0;
 669                 }
 670
 671                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 672                 {
 673                         .entity weaponentity = weaponentities[slot];
 674                         entity oldwep = this.(weaponentity);
 675                         CL_SpawnWeaponentity(this, weaponentity);
 676                         if(oldwep && oldwep.owner == this)
 677                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 678                 }
 679                 this.alpha = default_player_alpha;
 680                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 681                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 682
 683                 this.speedrunning = false;
 684
 685                 target_voicescript_clear(this);
 686
 687                 // reset fields the weapons may use
 688                 FOREACH(Weapons, true, LAMBDA(
 689                         it.wr_resetplayer(it, this);
 690                         // reload all reloadable weapons
 691                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 692                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693                                 {
 694                                         .entity weaponentity = weaponentities[slot];
 695                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 696                                 }
 697                         }
 698                 ));
 699
 700                 {
 701                         string s = spot.target;
 702                         spot.target = string_null;
 703                         SUB_UseTargets(spot, this, NULL);
 704                         spot.target = s;
 705                 }
 706
 707                 Unfreeze(this);
 708
 709                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 710
 711                 if (autocvar_spawn_debug)
 712                 {
 713                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 714                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 715                 }
 716
 717                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718                 {
 719                         .entity weaponentity = weaponentities[slot];
 720                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 721                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 722                         else
 723                                 this.(weaponentity).m_switchweapon = WEP_Null;
 724                         this.(weaponentity).m_weapon = WEP_Null;
 725                         this.(weaponentity).weaponname = "";
 726                         this.(weaponentity).m_switchingweapon = WEP_Null;
 727                         this.(weaponentity).cnt = -1;
 728                 }
 729
 730                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 731
 732                 if (!warmup_stage && !this.alivetime)
 733                         this.alivetime = time;
 734
 735                 antilag_clear(this, CS(this));
 736         }
 737 }
 738
 739 void ClientInit_misc(entity this);
 740
 741 // TODO do we need all these fields, or should we stop autodetecting runtime
 742 // changes and just have a console command to update this?
 743 bool ClientInit_SendEntity(entity this, entity to, int sf)
 744 {
 745         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 746         return = true;
 747         msg_entity = to;
 748         // MSG_INIT replacement
 749         // TODO: make easier to use
 750         Registry_send_all();
 751         W_PROP_reload(MSG_ONE, to);
 752         ClientInit_misc(this);
 753         MUTATOR_CALLHOOK(Ent_Init);
 754 }
 755 void ClientInit_misc(entity this)
 756 {
 757         int channel = MSG_ONE;
 758         WriteHeader(channel, ENT_CLIENT_INIT);
 759         WriteByte(channel, g_nexball_meter_period * 32);
 760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 768
 769         if(sv_foginterval && world.fog != "")
 770                 WriteString(channel, world.fog);
 771         else
 772                 WriteString(channel, "");
 773         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 774         WriteByte(channel, serverflags);
 775         WriteCoord(channel, autocvar_g_trueaim_minrange);
 776 }
 777
 778 void ClientInit_CheckUpdate(entity this)
 779 {
 780         this.nextthink = time;
 781         if(this.count != autocvar_g_balance_armor_blockpercent)
 782         {
 783                 this.count = autocvar_g_balance_armor_blockpercent;
 784                 this.SendFlags |= 1;
 785         }
 786 }
 787
 788 void ClientInit_Spawn()
 789 {
 790         entity e = new_pure(clientinit);
 791         setthink(e, ClientInit_CheckUpdate);
 792         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 793
 794         ClientInit_CheckUpdate(e);
 795 }
 796
 797 /*
 798 =============
 799 SetNewParms
 800 =============
 801 */
 802 void SetNewParms ()
 803 {
 804         // initialize parms for a new player
 805         parm1 = -(86400 * 366);
 806
 807         MUTATOR_CALLHOOK(SetNewParms);
 808 }
 809
 810 /*
 811 =============
 812 SetChangeParms
 813 =============
 814 */
 815 void SetChangeParms (entity this)
 816 {
 817         // save parms for level change
 818         parm1 = this.parm_idlesince - time;
 819
 820         MUTATOR_CALLHOOK(SetChangeParms);
 821 }
 822
 823 /*
 824 =============
 825 DecodeLevelParms
 826 =============
 827 */
 828 void DecodeLevelParms(entity this)
 829 {
 830         // load parms
 831         this.parm_idlesince = parm1;
 832         if (this.parm_idlesince == -(86400 * 366))
 833                 this.parm_idlesince = time;
 834
 835         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 836         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 837
 838         MUTATOR_CALLHOOK(DecodeLevelParms);
 839 }
 840
 841 /*
 842 =============
 843 ClientKill
 844
 845 Called when a client types 'kill' in the console
 846 =============
 847 */
 848
 849 .float clientkill_nexttime;
 850 void ClientKill_Now_TeamChange(entity this)
 851 {
 852         if(this.killindicator_teamchange == -1)
 853         {
 854                 JoinBestTeam( this, false, true );
 855         }
 856         else if(this.killindicator_teamchange == -2)
 857         {
 858                 if(blockSpectators)
 859                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 860                 PutObserverInServer(this);
 861         }
 862         else
 863                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 864         this.killindicator_teamchange = 0;
 865 }
 866
 867 void ClientKill_Now(entity this)
 868 {
 869         if(this.vehicle)
 870         {
 871             vehicles_exit(this.vehicle, VHEF_RELEASE);
 872             if(!this.killindicator_teamchange)
 873             {
 874             this.vehicle_health = -1;
 875             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 876             }
 877         }
 878
 879         if(this.killindicator && !wasfreed(this.killindicator))
 880                 delete(this.killindicator);
 881
 882         this.killindicator = NULL;
 883
 884         if(this.killindicator_teamchange)
 885                 ClientKill_Now_TeamChange(this);
 886
 887         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 888                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 889
 890         // now I am sure the player IS dead
 891 }
 892 void KillIndicator_Think(entity this)
 893 {
 894         if (game_stopped)
 895         {
 896                 this.owner.killindicator = NULL;
 897                 delete(this);
 898                 return;
 899         }
 900
 901         if (this.owner.alpha < 0 && !this.owner.vehicle)
 902         {
 903                 this.owner.killindicator = NULL;
 904                 delete(this);
 905                 return;
 906         }
 907
 908         if(this.cnt <= 0)
 909         {
 910                 ClientKill_Now(this.owner);
 911                 return;
 912         }
 913     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 914     {
 915         this.nextthink = time + 1;
 916         this.cnt -= 1;
 917     }
 918         else
 919         {
 920                 if(this.cnt <= 10)
 921                         setmodel(this, MDL_NUM(this.cnt));
 922                 if(IS_REAL_CLIENT(this.owner))
 923                 {
 924                         if(this.cnt <= 10)
 925                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 926                 }
 927                 this.nextthink = time + 1;
 928                 this.cnt -= 1;
 929         }
 930 }
 931
 932 float clientkilltime;
 933 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 934 {
 935         float killtime;
 936         float starttime;
 937
 938         if (game_stopped)
 939                 return;
 940
 941         killtime = autocvar_g_balance_kill_delay;
 942
 943         if(g_race_qualifying || g_cts)
 944                 killtime = 0;
 945
 946     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 947         return;
 948
 949         this.killindicator_teamchange = targetteam;
 950
 951     if(!this.killindicator)
 952         {
 953                 if(!IS_DEAD(this))
 954                 {
 955                         killtime = max(killtime, this.clientkill_nexttime - time);
 956                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 957                 }
 958
 959                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 960                 {
 961                         ClientKill_Now(this);
 962                 }
 963                 else
 964                 {
 965                         starttime = max(time, clientkilltime);
 966
 967                         this.killindicator = spawn();
 968                         this.killindicator.owner = this;
 969                         this.killindicator.scale = 0.5;
 970                         setattachment(this.killindicator, this, "");
 971                         setorigin(this.killindicator, '0 0 52');
 972                         setthink(this.killindicator, KillIndicator_Think);
 973                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 974                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 975                         this.killindicator.cnt = ceil(killtime);
 976                         this.killindicator.count = bound(0, ceil(killtime), 10);
 977                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 978
 979                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 980                         {
 981                                 it.killindicator = spawn();
 982                                 it.killindicator.owner = it;
 983                                 it.killindicator.scale = 0.5;
 984                                 setattachment(it.killindicator, it, "");
 985                                 setorigin(it.killindicator, '0 0 52');
 986                                 setthink(it.killindicator, KillIndicator_Think);
 987                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 988                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 989                                 it.killindicator.cnt = ceil(killtime);
 990                         });
 991                         this.lip = 0;
 992                 }
 993         }
 994         if(this.killindicator)
 995         {
 996                 if(targetteam == 0) // just die
 997                 {
 998                         this.killindicator.colormod = '0 0 0';
 999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1002                 }
1003                 else if(targetteam == -1) // auto
1004                 {
1005                         this.killindicator.colormod = '0 1 0';
1006                         if(IS_REAL_CLIENT(this))
1007                         if(this.killindicator.cnt > 0)
1008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1009                 }
1010                 else if(targetteam == -2) // spectate
1011                 {
1012                         this.killindicator.colormod = '0.5 0.5 0.5';
1013                         if(IS_REAL_CLIENT(this))
1014                         if(this.killindicator.cnt > 0)
1015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1016                 }
1017                 else
1018                 {
1019                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1020                         if(IS_REAL_CLIENT(this))
1021                         if(this.killindicator.cnt > 0)
1022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1023                 }
1024         }
1025
1026 }
1027
1028 void ClientKill (entity this)
1029 {
1030         if(game_stopped) return;
1031         if(this.player_blocked) return;
1032         if(STAT(FROZEN, this)) return;
1033
1034         ClientKill_TeamChange(this, 0);
1035 }
1036
1037 void FixClientCvars(entity e)
1038 {
1039         // send prediction settings to the client
1040         stuffcmd(e, "\nin_bindmap 0 0\n");
1041         if(autocvar_g_antilag == 3) // client side hitscan
1042                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1043         if(autocvar_sv_gentle)
1044                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1045
1046         MUTATOR_CALLHOOK(FixClientCvars, e);
1047 }
1048
1049 float PlayerInIDList(entity p, string idlist)
1050 {
1051         float n, i;
1052         string s;
1053
1054         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1055         if (!p.crypto_idfp)
1056                 return 0;
1057
1058         // this function allows abbreviated player IDs too!
1059         n = tokenize_console(idlist);
1060         for(i = 0; i < n; ++i)
1061         {
1062                 s = argv(i);
1063                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1064                         return 1;
1065         }
1066
1067         return 0;
1068 }
1069
1070 #ifdef DP_EXT_PRECONNECT
1071 /*
1072 =============
1073 ClientPreConnect
1074
1075 Called once (not at each match start) when a client begins a connection to the server
1076 =============
1077 */
1078 void ClientPreConnect(entity this)
1079 {
1080         if(autocvar_sv_eventlog)
1081         {
1082                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1083                         this.playerid,
1084                         etof(this),
1085                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1086                 ));
1087         }
1088 }
1089 #endif
1090
1091 /**
1092 =============
1093 ClientConnect
1094
1095 Called when a client connects to the server
1096 =============
1097 */
1098 void ClientConnect(entity this)
1099 {
1100         if (Ban_MaybeEnforceBanOnce(this)) return;
1101         assert(!IS_CLIENT(this), return);
1102         this.flags |= FL_CLIENT;
1103         assert(player_count >= 0, player_count = 0);
1104
1105 #ifdef WATERMARK
1106         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1107 #endif
1108         this.version_nagtime = time + 10 + random() * 10;
1109         TRANSMUTE(Client, this);
1110
1111         // identify the right forced team
1112         if (autocvar_g_campaign)
1113         {
1114                 if (IS_REAL_CLIENT(this)) // only players, not bots
1115                 {
1116                         switch (autocvar_g_campaign_forceteam)
1117                         {
1118                                 case 1: this.team_forced = NUM_TEAM_1; break;
1119                                 case 2: this.team_forced = NUM_TEAM_2; break;
1120                                 case 3: this.team_forced = NUM_TEAM_3; break;
1121                                 case 4: this.team_forced = NUM_TEAM_4; break;
1122                                 default: this.team_forced = 0;
1123                         }
1124                 }
1125         }
1126         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1127         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1128         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1130         else switch (autocvar_g_forced_team_otherwise)
1131         {
1132                 default: this.team_forced = 0; break;
1133                 case "red": this.team_forced = NUM_TEAM_1; break;
1134                 case "blue": this.team_forced = NUM_TEAM_2; break;
1135                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1136                 case "pink": this.team_forced = NUM_TEAM_4; break;
1137                 case "spectate":
1138                 case "spectator":
1139                         this.team_forced = -1;
1140                         break;
1141         }
1142         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1143
1144     {
1145         int id = this.playerid;
1146         this.playerid = 0; // silent
1147             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1148             this.playerid = id;
1149     }
1150
1151         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1152                 TRANSMUTE(Observer, this);
1153         } else {
1154                 if (!teamplay || autocvar_g_balance_teams) {
1155                         TRANSMUTE(Player, this);
1156                         campaign_bots_may_start = true;
1157                 } else {
1158                         TRANSMUTE(Observer, this); // do it anyway
1159                 }
1160         }
1161
1162         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1163
1164         // always track bots, don't ask for cl_allow_uidtracking
1165     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1166
1167         if (autocvar_sv_eventlog)
1168                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1169
1170         LogTeamchange(this.playerid, this.team, 1);
1171
1172         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1173
1174         this.netname_previous = strzone(this.netname);
1175
1176         if(teamplay && IS_PLAYER(this))
1177                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1178         else
1179                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1180
1181         stuffcmd(this, clientstuff, "\n");
1182         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1183
1184         FixClientCvars(this);
1185
1186         // get version info from player
1187         stuffcmd(this, "cmd clientversion $gameversion\n");
1188
1189         // notify about available teams
1190         if (teamplay)
1191         {
1192                 CheckAllowedTeams(this);
1193                 int t = 0;
1194                 if (c1 >= 0) t |= BIT(0);
1195                 if (c2 >= 0) t |= BIT(1);
1196                 if (c3 >= 0) t |= BIT(2);
1197                 if (c4 >= 0) t |= BIT(3);
1198                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1199         }
1200         else
1201         {
1202                 stuffcmd(this, "set _teams_available 0\n");
1203         }
1204
1205         bot_relinkplayerlist();
1206
1207         this.spectatortime = time;
1208         if (blockSpectators)
1209         {
1210                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1211         }
1212
1213         this.jointime = time;
1214         this.allowed_timeouts = autocvar_sv_timeout_number;
1215
1216         if (IS_REAL_CLIENT(this))
1217         {
1218                 if (g_weaponarena_weapons == WEPSET(TUBA))
1219                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1220         }
1221
1222         if (!sv_foginterval && world.fog != "")
1223                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1224
1225         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1226                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1227                         send_CSQC_teamnagger();
1228
1229         CSQCMODEL_AUTOINIT(this);
1230
1231         this.model_randomizer = random();
1232
1233         if (IS_REAL_CLIENT(this))
1234                 sv_notice_join(this);
1235
1236         // update physics stats (players can spawn before physics runs)
1237         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1238         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1239         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1240
1241         IL_EACH(g_initforplayer, it.init_for_player, {
1242                 it.init_for_player(it, this);
1243         });
1244
1245         MUTATOR_CALLHOOK(ClientConnect, this);
1246
1247         if (IS_REAL_CLIENT(this))
1248         {
1249                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1250                 {
1251                         this.motd_actived_time = -1;
1252                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1253                 }
1254         }
1255 }
1256 /*
1257 =============
1258 ClientDisconnect
1259
1260 Called when a client disconnects from the server
1261 =============
1262 */
1263 .entity chatbubbleentity;
1264 void ReadyCount();
1265 void ClientDisconnect(entity this)
1266 {
1267         assert(IS_CLIENT(this), return);
1268
1269         PlayerStats_GameReport_FinalizePlayer(this);
1270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1271         if (this.active_minigame) part_minigame(this);
1272         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1273
1274         if (autocvar_sv_eventlog)
1275                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1276
1277         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1278
1279         if(IS_SPEC(this))
1280                 SetSpectatee(this, NULL);
1281
1282     MUTATOR_CALLHOOK(ClientDisconnect, this);
1283
1284         ClientState_detach(this);
1285
1286         Portal_ClearAll(this);
1287
1288         Unfreeze(this);
1289
1290         RemoveGrapplingHooks(this);
1291
1292         // Here, everything has been done that requires this player to be a client.
1293
1294         this.flags &= ~FL_CLIENT;
1295
1296         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1297         if (this.killindicator) delete(this.killindicator);
1298
1299         WaypointSprite_PlayerGone(this);
1300
1301         bot_relinkplayerlist();
1302
1303         if (this.netname_previous) strunzone(this.netname_previous);
1304         if (this.clientstatus) strunzone(this.clientstatus);
1305         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1306         if (this.personal) delete(this.personal);
1307
1308         this.playerid = 0;
1309         ReadyCount();
1310         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1311
1312         ONREMOVE(this);
1313 }
1314
1315 void ChatBubbleThink(entity this)
1316 {
1317         this.nextthink = time;
1318         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1319         {
1320                 if(this.owner) // but why can that ever be NULL?
1321                         this.owner.chatbubbleentity = NULL;
1322                 delete(this);
1323                 return;
1324         }
1325
1326         this.mdl = "";
1327
1328         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1329         {
1330                 if ( this.owner.active_minigame )
1331                         this.mdl = "models/sprites/minigame_busy.iqm";
1332                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1333                         this.mdl = "models/misc/chatbubble.spr";
1334         }
1335
1336         if ( this.model != this.mdl )
1337                 _setmodel(this, this.mdl);
1338
1339 }
1340
1341 void UpdateChatBubble(entity this)
1342 {
1343         if (this.alpha < 0)
1344                 return;
1345         // spawn a chatbubble entity if needed
1346         if (!this.chatbubbleentity)
1347         {
1348                 this.chatbubbleentity = new(chatbubbleentity);
1349                 this.chatbubbleentity.owner = this;
1350                 this.chatbubbleentity.exteriormodeltoclient = this;
1351                 setthink(this.chatbubbleentity, ChatBubbleThink);
1352                 this.chatbubbleentity.nextthink = time;
1353                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1354                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1355                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1356                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1357                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1358                 //this.chatbubbleentity.model = "";
1359                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1360         }
1361 }
1362
1363
1364 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1365 // added to the model skins
1366 /*void UpdateColorModHack()
1367 {
1368         float c;
1369         c = this.clientcolors & 15;
1370         // LordHavoc: only bothering to support white, green, red, yellow, blue
1371              if (!teamplay) this.colormod = '0 0 0';
1372         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1373         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1374         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1375         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1376         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1377         else this.colormod = '1 1 1';
1378 }*/
1379
1380 void respawn(entity this)
1381 {
1382         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1383         {
1384                 this.solid = SOLID_NOT;
1385                 this.takedamage = DAMAGE_NO;
1386                 set_movetype(this, MOVETYPE_FLY);
1387                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1388                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1389                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1390                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1391                 if(autocvar_g_respawn_ghosts_maxtime)
1392                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1393         }
1394
1395         CopyBody(this, 1);
1396
1397         this.effects |= EF_NODRAW; // prevent another CopyBody
1398         PutClientInServer(this);
1399 }
1400
1401 void play_countdown(entity this, float finished, Sound samp)
1402 {
1403     TC(Sound, samp);
1404         if(IS_REAL_CLIENT(this))
1405                 if(floor(finished - time - frametime) != floor(finished - time))
1406                         if(finished - time < 6)
1407                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1408 }
1409
1410 void player_powerups(entity this)
1411 {
1412         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1413         int items_prev = this.items;
1414
1415         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1416                 this.modelflags |= MF_ROCKET;
1417         else
1418                 this.modelflags &= ~MF_ROCKET;
1419
1420         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1421
1422         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1423                 return;
1424
1425         Fire_ApplyDamage(this);
1426         Fire_ApplyEffect(this);
1427
1428         if (!g_instagib)
1429         {
1430                 if (this.items & ITEM_Strength.m_itemid)
1431                 {
1432                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1433                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1434                         if (time > this.strength_finished)
1435                         {
1436                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1437                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1439                         }
1440                 }
1441                 else
1442                 {
1443                         if (time < this.strength_finished)
1444                         {
1445                                 this.items = this.items | ITEM_Strength.m_itemid;
1446                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1448                         }
1449                 }
1450                 if (this.items & ITEM_Shield.m_itemid)
1451                 {
1452                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1453                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > this.invincible_finished)
1455                         {
1456                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1457                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < this.invincible_finished)
1464                         {
1465                                 this.items = this.items | ITEM_Shield.m_itemid;
1466                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1468                         }
1469                 }
1470                 if (this.items & IT_SUPERWEAPON)
1471                 {
1472                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1473                         {
1474                                 this.superweapons_finished = 0;
1475                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1478                         }
1479                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1480                         {
1481                                 // don't let them run out
1482                         }
1483                         else
1484                         {
1485                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1486                                 if (time > this.superweapons_finished)
1487                                 {
1488                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1489                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1490                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1492                                 }
1493                         }
1494                 }
1495                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1496                 {
1497                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1498                         {
1499                                 this.items = this.items | IT_SUPERWEAPON;
1500                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1502                         }
1503                         else
1504                         {
1505                                 this.superweapons_finished = 0;
1506                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1507                         }
1508                 }
1509                 else
1510                 {
1511                         this.superweapons_finished = 0;
1512                 }
1513         }
1514
1515         if(autocvar_g_nodepthtestplayers)
1516                 this.effects = this.effects | EF_NODEPTHTEST;
1517
1518         if(autocvar_g_fullbrightplayers)
1519                 this.effects = this.effects | EF_FULLBRIGHT;
1520
1521         if (time >= game_starttime)
1522         if (time < this.spawnshieldtime)
1523                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1524
1525         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1526 }
1527
1528 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1529 {
1530         if(current > stable)
1531                 return current;
1532         else if(current > stable - 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1536 }
1537
1538 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1539 {
1540         if(current < stable)
1541                 return current;
1542         else if(current < stable + 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1546 }
1547
1548 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1549 {
1550         if(current > rotstable)
1551         {
1552                 if(rotframetime > 0)
1553                 {
1554                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1555                         current = max(rotstable, current - rotlinear * rotframetime);
1556                 }
1557         }
1558         else if(current < regenstable)
1559         {
1560                 if(regenframetime > 0)
1561                 {
1562                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1563                         current = min(regenstable, current + regenlinear * regenframetime);
1564                 }
1565         }
1566
1567         if(current > limit)
1568                 current = limit;
1569
1570         return current;
1571 }
1572
1573 void player_regen(entity this)
1574 {
1575         float max_mod, regen_mod, rot_mod, limit_mod;
1576         max_mod = regen_mod = rot_mod = limit_mod = 1;
1577
1578         float regen_health = autocvar_g_balance_health_regen;
1579         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1580         float regen_health_rot = autocvar_g_balance_health_rot;
1581         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1582         float regen_health_stable = autocvar_g_balance_health_regenstable;
1583         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1584         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1585                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1586         max_mod = M_ARGV(1, float);
1587         regen_mod = M_ARGV(2, float);
1588         rot_mod = M_ARGV(3, float);
1589         limit_mod = M_ARGV(4, float);
1590         regen_health = M_ARGV(5, float);
1591         regen_health_linear = M_ARGV(6, float);
1592         regen_health_rot = M_ARGV(7, float);
1593         regen_health_rotlinear = M_ARGV(8, float);
1594         regen_health_stable = M_ARGV(9, float);
1595         regen_health_rotstable = M_ARGV(10, float);
1596
1597
1598         if(!mutator_returnvalue)
1599         if(!STAT(FROZEN, this))
1600         {
1601                 float mina, maxa, limith, limita;
1602                 maxa = autocvar_g_balance_armor_rotstable;
1603                 mina = autocvar_g_balance_armor_regenstable;
1604                 limith = autocvar_g_balance_health_limit;
1605                 limita = autocvar_g_balance_armor_limit;
1606
1607                 regen_health_rotstable = regen_health_rotstable * max_mod;
1608                 regen_health_stable = regen_health_stable * max_mod;
1609                 limith = limith * limit_mod;
1610                 limita = limita * limit_mod;
1611
1612                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1613                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1614         }
1615
1616         // if player rotted to death...  die!
1617         // check this outside above checks, as player may still be able to rot to death
1618         if(this.health < 1)
1619         {
1620                 if(this.vehicle)
1621                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1622                 if(this.event_damage)
1623                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1624         }
1625
1626         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1627         {
1628                 float minf, maxf, limitf;
1629
1630                 maxf = autocvar_g_balance_fuel_rotstable;
1631                 minf = autocvar_g_balance_fuel_regenstable;
1632                 limitf = autocvar_g_balance_fuel_limit;
1633
1634                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1635         }
1636 }
1637
1638 bool zoomstate_set;
1639 void SetZoomState(entity this, float newzoom)
1640 {
1641         if(newzoom != this.zoomstate)
1642         {
1643                 this.zoomstate = newzoom;
1644                 ClientData_Touch(this);
1645         }
1646         zoomstate_set = true;
1647 }
1648
1649 void GetPressedKeys(entity this)
1650 {
1651         MUTATOR_CALLHOOK(GetPressedKeys, this);
1652         int keys = STAT(PRESSED_KEYS, this);
1653         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1654         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1655         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1656         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1657
1658         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1659         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1660         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1661         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1662         this.pressedkeys = keys; // store for other users
1663
1664         STAT(PRESSED_KEYS, this) = keys;
1665 }
1666
1667 /*
1668 ======================
1669 spectate mode routines
1670 ======================
1671 */
1672
1673 void SpectateCopy(entity this, entity spectatee)
1674 {
1675     TC(Client, this); TC(Client, spectatee);
1676
1677         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1678         PS(this) = PS(spectatee);
1679         this.armortype = spectatee.armortype;
1680         this.armorvalue = spectatee.armorvalue;
1681         this.ammo_cells = spectatee.ammo_cells;
1682         this.ammo_plasma = spectatee.ammo_plasma;
1683         this.ammo_shells = spectatee.ammo_shells;
1684         this.ammo_nails = spectatee.ammo_nails;
1685         this.ammo_rockets = spectatee.ammo_rockets;
1686         this.ammo_fuel = spectatee.ammo_fuel;
1687         this.clip_load = spectatee.clip_load;
1688         this.clip_size = spectatee.clip_size;
1689         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1690         this.health = spectatee.health;
1691         this.impulse = 0;
1692         this.items = spectatee.items;
1693         this.last_pickup = spectatee.last_pickup;
1694         this.hit_time = spectatee.hit_time;
1695         this.strength_finished = spectatee.strength_finished;
1696         this.invincible_finished = spectatee.invincible_finished;
1697         this.superweapons_finished = spectatee.superweapons_finished;
1698         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1699         this.weapons = spectatee.weapons;
1700         this.dual_weapons = spectatee.dual_weapons;
1701         this.vortex_charge = spectatee.vortex_charge;
1702         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1703         this.okvortex_charge = spectatee.okvortex_charge;
1704         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1705         this.hagar_load = spectatee.hagar_load;
1706         this.arc_heat_percent = spectatee.arc_heat_percent;
1707         this.minelayer_mines = spectatee.minelayer_mines;
1708         this.punchangle = spectatee.punchangle;
1709         this.view_ofs = spectatee.view_ofs;
1710         this.velocity = spectatee.velocity;
1711         this.dmg_take = spectatee.dmg_take;
1712         this.dmg_save = spectatee.dmg_save;
1713         this.dmg_inflictor = spectatee.dmg_inflictor;
1714         this.v_angle = spectatee.v_angle;
1715         this.angles = spectatee.v_angle;
1716         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1717         this.revive_progress = spectatee.revive_progress;
1718         this.viewloc = spectatee.viewloc;
1719         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1720                 this.fixangle = true;
1721         setorigin(this, spectatee.origin);
1722         setsize(this, spectatee.mins, spectatee.maxs);
1723         SetZoomState(this, spectatee.zoomstate);
1724
1725         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1726         {
1727                 .entity weaponentity = weaponentities[slot];
1728                 this.(weaponentity) = spectatee.(weaponentity);
1729         }
1730
1731         for(int slot = 0; slot < MAX_AXH; ++slot)
1732         {
1733                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1734         }
1735
1736     anticheat_spectatecopy(this, spectatee);
1737         this.hud = spectatee.hud;
1738         if(spectatee.vehicle)
1739     {
1740         this.angles = spectatee.v_angle;
1741
1742         //this.fixangle = false;
1743         //this.velocity = spectatee.vehicle.velocity;
1744         this.vehicle_health = spectatee.vehicle_health;
1745         this.vehicle_shield = spectatee.vehicle_shield;
1746         this.vehicle_energy = spectatee.vehicle_energy;
1747         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1748         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1749         this.vehicle_reload1 = spectatee.vehicle_reload1;
1750         this.vehicle_reload2 = spectatee.vehicle_reload2;
1751
1752         //msg_entity = this;
1753
1754        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1755             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1756            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1757            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1758
1759         //WriteByte (MSG_ONE, SVC_SETVIEW);
1760         //    WriteEntity(MSG_ONE, this);
1761         //makevectors(spectatee.v_angle);
1762         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1763     }
1764 }
1765
1766 bool SpectateUpdate(entity this)
1767 {
1768         if(!this.enemy)
1769                 return false;
1770
1771         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1772         {
1773                 SetSpectatee(this, NULL);
1774                 return false;
1775         }
1776
1777         SpectateCopy(this, this.enemy);
1778
1779         return true;
1780 }
1781
1782 bool SpectateSet(entity this)
1783 {
1784         if(!IS_PLAYER(this.enemy))
1785                 return false;
1786
1787         ClientData_Touch(this.enemy);
1788
1789         msg_entity = this;
1790         WriteByte(MSG_ONE, SVC_SETVIEW);
1791         WriteEntity(MSG_ONE, this.enemy);
1792         set_movetype(this, MOVETYPE_NONE);
1793         accuracy_resend(this);
1794
1795         if(!SpectateUpdate(this))
1796                 PutObserverInServer(this);
1797
1798         return true;
1799 }
1800
1801 void SetSpectatee_status(entity this, int spectatee_num)
1802 {
1803         int oldspectatee_status = this.spectatee_status;
1804         this.spectatee_status = spectatee_num;
1805
1806         if (this.spectatee_status != oldspectatee_status)
1807         {
1808                 ClientData_Touch(this);
1809                 if (g_race || g_cts) race_InitSpectator();
1810         }
1811 }
1812
1813 void SetSpectatee(entity this, entity spectatee)
1814 {
1815         entity old_spectatee = this.enemy;
1816
1817         this.enemy = spectatee;
1818
1819         // WEAPONTODO
1820         // these are required to fix the spectator bug with arc
1821         if(old_spectatee)
1822         {
1823                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1824                 {
1825                         .entity weaponentity = weaponentities[slot];
1826                         if(old_spectatee.(weaponentity).arc_beam)
1827                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1828                 }
1829         }
1830         if(this.enemy)
1831         {
1832                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1833                 {
1834                         .entity weaponentity = weaponentities[slot];
1835                         if(this.enemy.(weaponentity).arc_beam)
1836                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1837                 }
1838         }
1839
1840         if (this.enemy)
1841                 SetSpectatee_status(this, etof(this.enemy));
1842
1843         // needed to update spectator list
1844         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1845 }
1846
1847 bool Spectate(entity this, entity pl)
1848 {
1849         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1850                 return false;
1851         pl = M_ARGV(1, entity);
1852
1853         SetSpectatee(this, pl);
1854         return SpectateSet(this);
1855 }
1856
1857 bool SpectateNext(entity this)
1858 {
1859         entity ent = find(this.enemy, classname, STR_PLAYER);
1860
1861         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1862                 ent = M_ARGV(1, entity);
1863         else if (!ent)
1864                 ent = find(ent, classname, STR_PLAYER);
1865
1866         if(ent) { SetSpectatee(this, ent); }
1867
1868         return SpectateSet(this);
1869 }
1870
1871 bool SpectatePrev(entity this)
1872 {
1873         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1874         entity ent = findchain(classname, STR_PLAYER);
1875         if (!ent) // no player
1876                 return false;
1877
1878         entity first = ent;
1879         // skip players until current spectated player
1880         if(this.enemy)
1881         while(ent && ent != this.enemy)
1882                 ent = ent.chain;
1883
1884         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1885         {
1886                 case MUT_SPECPREV_FOUND:
1887                     ent = M_ARGV(1, entity);
1888                     break;
1889                 case MUT_SPECPREV_RETURN:
1890                     return true;
1891                 case MUT_SPECPREV_CONTINUE:
1892                 default:
1893                 {
1894                         if(ent.chain)
1895                                 ent = ent.chain;
1896                         else
1897                                 ent = first;
1898                         break;
1899                 }
1900         }
1901
1902         SetSpectatee(this, ent);
1903         return SpectateSet(this);
1904 }
1905
1906 /*
1907 =============
1908 ShowRespawnCountdown()
1909
1910 Update a respawn countdown display.
1911 =============
1912 */
1913 void ShowRespawnCountdown(entity this)
1914 {
1915         float number;
1916         if(!IS_DEAD(this)) // just respawned?
1917                 return;
1918         else
1919         {
1920                 number = ceil(this.respawn_time - time);
1921                 if(number <= 0)
1922                         return;
1923                 if(number <= this.respawn_countdown)
1924                 {
1925                         this.respawn_countdown = number - 1;
1926                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1927                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1928                 }
1929         }
1930 }
1931
1932 .bool team_selected;
1933 bool ShowTeamSelection(entity this)
1934 {
1935         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1936                 return false;
1937         stuffcmd(this, "menu_showteamselect\n");
1938         return true;
1939 }
1940 void Join(entity this)
1941 {
1942         TRANSMUTE(Player, this);
1943
1944         if(!this.team_selected)
1945         if(autocvar_g_campaign || autocvar_g_balance_teams)
1946                 JoinBestTeam(this, false, true);
1947
1948         if(autocvar_g_campaign)
1949                 campaign_bots_may_start = true;
1950
1951         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1952
1953         PutClientInServer(this);
1954
1955         if(teamplay && this.team != -1)
1956                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1957         else
1958                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1959         this.team_selected = false;
1960 }
1961
1962 /**
1963  * Determines whether the player is allowed to join. This depends on cvar
1964  * g_maxplayers, if it isn't used this function always return true, otherwise
1965  * it checks whether the number of currently playing players exceeds g_maxplayers.
1966  * @return int number of free slots for players, 0 if none
1967  */
1968 int nJoinAllowed(entity this, entity ignore)
1969 {
1970         if(!ignore)
1971         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1972         // so report 0 free slots if restricted
1973         {
1974                 if(autocvar_g_forced_team_otherwise == "spectate")
1975                         return 0;
1976                 if(autocvar_g_forced_team_otherwise == "spectator")
1977                         return 0;
1978         }
1979
1980         if(this && this.team_forced < 0)
1981                 return 0; // forced spectators can never join
1982
1983         // TODO simplify this
1984         int totalClients = 0;
1985         int currentlyPlaying = 0;
1986         FOREACH_CLIENT(true, LAMBDA(
1987                 if(it != ignore)
1988                         ++totalClients;
1989                 if(IS_REAL_CLIENT(it))
1990                 if(IS_PLAYER(it) || it.caplayer)
1991                         ++currentlyPlaying;
1992         ));
1993
1994         float free_slots = 0;
1995         if (!autocvar_g_maxplayers)
1996                 free_slots = maxclients - totalClients;
1997         else if(currentlyPlaying < autocvar_g_maxplayers)
1998                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1999
2000         static float join_prevent_msg_time = 0;
2001         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2002         {
2003                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2004                 join_prevent_msg_time = time + 3;
2005         }
2006
2007         return free_slots;
2008 }
2009
2010 /**
2011  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2012  * g_maxplayers_spectator_blocktime seconds
2013  */
2014 void checkSpectatorBlock(entity this)
2015 {
2016         if(IS_SPEC(this) || IS_OBSERVER(this))
2017         if(!this.caplayer)
2018         if(IS_REAL_CLIENT(this))
2019         {
2020                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2021                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2022                         dropclient(this);
2023                 }
2024         }
2025 }
2026
2027 void PrintWelcomeMessage(entity this)
2028 {
2029         if(this.motd_actived_time == 0)
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2033                                 this.motd_actived_time = time;
2034                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2035                         }
2036                 } else {
2037                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2038                                 this.motd_actived_time = time;
2039                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2040                         }
2041                 }
2042         }
2043         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2044         {
2045                 if (autocvar_g_campaign) {
2046                         if (PHYS_INPUT_BUTTON_INFO(this))
2047                                 this.motd_actived_time = time;
2048                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2049                                 this.motd_actived_time = 0;
2050                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2051                         }
2052                 } else {
2053                         if (PHYS_INPUT_BUTTON_INFO(this))
2054                                 this.motd_actived_time = time;
2055                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2056                                 this.motd_actived_time = 0;
2057                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2058                         }
2059                 }
2060         }
2061         else //if(this.motd_actived_time < 0) // just connected, motd is active
2062         {
2063                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2064                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2065                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2066                 {
2067                         // instanctly hide MOTD
2068                         this.motd_actived_time = 0;
2069                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2070                 }
2071         }
2072 }
2073
2074 bool joinAllowed(entity this)
2075 {
2076         if (this.version_mismatch) return false;
2077         if (!nJoinAllowed(this, this)) return false;
2078         if (teamplay && lockteams) return false;
2079         if (ShowTeamSelection(this)) return false;
2080         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2081         return true;
2082 }
2083
2084 void ObserverThink(entity this)
2085 {
2086         if ( this.impulse )
2087         {
2088                 MinigameImpulse(this, this.impulse);
2089                 this.impulse = 0;
2090         }
2091
2092         if (this.flags & FL_JUMPRELEASED) {
2093                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2094                         this.flags &= ~FL_JUMPRELEASED;
2095                         this.flags |= FL_SPAWNING;
2096                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2097                         this.flags &= ~FL_JUMPRELEASED;
2098                         if(SpectateNext(this)) {
2099                                 TRANSMUTE(Spectator, this);
2100                         }
2101                 } else {
2102                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2103                         set_movetype(this, preferred_movetype);
2104                 }
2105         } else {
2106                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2107                         this.flags |= FL_JUMPRELEASED;
2108                         if(this.flags & FL_SPAWNING)
2109                         {
2110                                 this.flags &= ~FL_SPAWNING;
2111                                 Join(this);
2112                                 return;
2113                         }
2114                 }
2115         }
2116 }
2117
2118 void SpectatorThink(entity this)
2119 {
2120         if ( this.impulse )
2121         {
2122                 if(MinigameImpulse(this, this.impulse))
2123                         this.impulse = 0;
2124
2125                 if (this.impulse == IMP_weapon_drop.impulse)
2126                 {
2127                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2128                         this.impulse = 0;
2129                         return;
2130                 }
2131         }
2132
2133         if (this.flags & FL_JUMPRELEASED) {
2134                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2135                         this.flags &= ~FL_JUMPRELEASED;
2136                         this.flags |= FL_SPAWNING;
2137                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2138                         this.flags &= ~FL_JUMPRELEASED;
2139                         if(SpectateNext(this)) {
2140                                 TRANSMUTE(Spectator, this);
2141                         } else {
2142                                 TRANSMUTE(Observer, this);
2143                                 PutClientInServer(this);
2144                         }
2145                         this.impulse = 0;
2146                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2147                         this.flags &= ~FL_JUMPRELEASED;
2148                         if(SpectatePrev(this)) {
2149                                 TRANSMUTE(Spectator, this);
2150                         } else {
2151                                 TRANSMUTE(Observer, this);
2152                                 PutClientInServer(this);
2153                         }
2154                         this.impulse = 0;
2155                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2156                         this.flags &= ~FL_JUMPRELEASED;
2157                         TRANSMUTE(Observer, this);
2158                         PutClientInServer(this);
2159                 } else {
2160                         if(!SpectateUpdate(this))
2161                                 PutObserverInServer(this);
2162                 }
2163         } else {
2164                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2165                         this.flags |= FL_JUMPRELEASED;
2166                         if(this.flags & FL_SPAWNING)
2167                         {
2168                                 this.flags &= ~FL_SPAWNING;
2169                                 Join(this);
2170                                 return;
2171                         }
2172                 }
2173                 if(!SpectateUpdate(this))
2174                         PutObserverInServer(this);
2175         }
2176
2177         this.flags |= FL_CLIENT | FL_NOTARGET;
2178 }
2179
2180 void vehicles_enter (entity pl, entity veh);
2181 void PlayerUseKey(entity this)
2182 {
2183         if (!IS_PLAYER(this))
2184                 return;
2185
2186         if(this.vehicle)
2187         {
2188                 if(!game_stopped)
2189                 {
2190                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2191                         return;
2192                 }
2193         }
2194         else if(autocvar_g_vehicles_enter)
2195         {
2196                 if(!STAT(FROZEN, this))
2197                 if(!IS_DEAD(this))
2198                 if(!game_stopped)
2199                 {
2200                         entity head, closest_target = NULL;
2201                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2202
2203                         while(head) // find the closest acceptable target to enter
2204                         {
2205                                 if(IS_VEHICLE(head))
2206                                 if(!IS_DEAD(head))
2207                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2208                                 if(head.takedamage != DAMAGE_NO)
2209                                 {
2210                                         if(closest_target)
2211                                         {
2212                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2213                                                 { closest_target = head; }
2214                                         }
2215                                         else { closest_target = head; }
2216                                 }
2217
2218                                 head = head.chain;
2219                         }
2220
2221                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2222                 }
2223         }
2224
2225         // a use key was pressed; call handlers
2226         MUTATOR_CALLHOOK(PlayerUseKey, this);
2227 }
2228
2229
2230 /*
2231 =============
2232 PlayerPreThink
2233
2234 Called every frame for each client before the physics are run
2235 =============
2236 */
2237 .float usekeypressed;
2238 .float last_vehiclecheck;
2239 .int items_added;
2240 void PlayerPreThink (entity this)
2241 {
2242         WarpZone_PlayerPhysics_FixVAngle(this);
2243
2244     STAT(GAMESTARTTIME, this) = game_starttime;
2245         STAT(ROUNDSTARTTIME, this) = round_starttime;
2246         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2247         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2248
2249         STAT(WEAPONSINMAP, this) = weaponsInMap;
2250
2251         if (frametime) {
2252                 // physics frames: update anticheat stuff
2253                 anticheat_prethink(this);
2254         }
2255
2256         if (blockSpectators && frametime) {
2257                 // WORKAROUND: only use dropclient in server frames (frametime set).
2258                 // Never use it in cl_movement frames (frametime zero).
2259                 checkSpectatorBlock(this);
2260     }
2261
2262         zoomstate_set = false;
2263
2264         // Check for nameless players
2265         if (isInvisibleString(this.netname)) {
2266                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2267                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2268         }
2269         if (this.netname != this.netname_previous) {
2270                 if (autocvar_sv_eventlog) {
2271                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2272         }
2273                 if (this.netname_previous) strunzone(this.netname_previous);
2274                 this.netname_previous = strzone(this.netname);
2275         }
2276
2277         // version nagging
2278         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2279         this.version_nagtime = 0;
2280         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2281             // git client
2282         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2283             // git server
2284             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2285         } else {
2286             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2287             if (r < 0) { // old client
2288                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2289             } else if (r > 0) { // old server
2290                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2291             }
2292         }
2293     }
2294
2295         // GOD MODE info
2296         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2297         {
2298                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2299                 this.max_armorvalue = 0;
2300         }
2301
2302         if (STAT(FROZEN, this) == 2)
2303         {
2304                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2305                 this.health = max(1, this.revive_progress * start_health);
2306                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2307
2308                 if (this.revive_progress >= 1)
2309                         Unfreeze(this);
2310         }
2311         else if (STAT(FROZEN, this) == 3)
2312         {
2313                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2314                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2315
2316                 if (this.health < 1)
2317                 {
2318                         if (this.vehicle)
2319                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2320                         if(this.event_damage)
2321                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2322                 }
2323                 else if (this.revive_progress <= 0)
2324                         Unfreeze(this);
2325         }
2326
2327         MUTATOR_CALLHOOK(PlayerPreThink, this);
2328
2329         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2330         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2331         {
2332                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2333                 {
2334                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2335                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2336                         {
2337                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2338                         }
2339                         else if(!it.owner)
2340                         {
2341                                 if(!it.team || SAME_TEAM(this, it))
2342                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2343                                 else if(autocvar_g_vehicles_steal)
2344                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2345                         }
2346                 });
2347
2348                 this.last_vehiclecheck = time + 1;
2349         }
2350
2351         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2352         {
2353                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2354                         PlayerUseKey(this);
2355                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2356         }
2357
2358         if (IS_REAL_CLIENT(this))
2359                 PrintWelcomeMessage(this);
2360
2361         if (IS_PLAYER(this)) {
2362                 CheckRules_Player(this);
2363
2364                 if (game_stopped || intermission_running) {
2365                         this.modelflags &= ~MF_ROCKET;
2366                         if(intermission_running)
2367                                 IntermissionThink(this);
2368                         return;
2369                 }
2370
2371                 if (timeout_status == TIMEOUT_ACTIVE) {
2372             // don't allow the player to turn around while game is paused
2373                         // FIXME turn this into CSQC stuff
2374                         this.v_angle = this.lastV_angle;
2375                         this.angles = this.lastV_angle;
2376                         this.fixangle = true;
2377                 }
2378
2379                 if (frametime) player_powerups(this);
2380
2381                 if (IS_DEAD(this)) {
2382                         if (this.personal && g_race_qualifying) {
2383                                 if (time > this.respawn_time) {
2384                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2385                                         respawn(this);
2386                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2387                                 }
2388                         } else {
2389                                 if (frametime) player_anim(this);
2390
2391                                 if (this.respawn_flags & RESPAWN_DENY)
2392                                 {
2393                                         STAT(RESPAWN_TIME, this) = 0;
2394                                         return;
2395                                 }
2396
2397                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2398
2399                                 switch(this.deadflag)
2400                                 {
2401                                         case DEAD_DYING:
2402                                         {
2403                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2404                                                         this.deadflag = DEAD_RESPAWNING;
2405                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2406                                                         this.deadflag = DEAD_DEAD;
2407                                                 break;
2408                                         }
2409                                         case DEAD_DEAD:
2410                                         {
2411                                                 if (button_pressed)
2412                                                         this.deadflag = DEAD_RESPAWNABLE;
2413                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2414                                                         this.deadflag = DEAD_RESPAWNING;
2415                                                 break;
2416                                         }
2417                                         case DEAD_RESPAWNABLE:
2418                                         {
2419                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2420                                                         this.deadflag = DEAD_RESPAWNING;
2421                                                 break;
2422                                         }
2423                                         case DEAD_RESPAWNING:
2424                                         {
2425                                                 if (time > this.respawn_time)
2426                                                 {
2427                                                         this.respawn_time = time + 1; // only retry once a second
2428                                                         this.respawn_time_max = this.respawn_time;
2429                                                         respawn(this);
2430                                                 }
2431                                                 break;
2432                                         }
2433                                 }
2434
2435                                 ShowRespawnCountdown(this);
2436
2437                                 if (this.respawn_flags & RESPAWN_SILENT)
2438                                         STAT(RESPAWN_TIME, this) = 0;
2439                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2440                                 {
2441                                         if (time < this.respawn_time)
2442                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2443                                         else if (this.deadflag != DEAD_RESPAWNING)
2444                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2445                                 }
2446                                 else
2447                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2448                         }
2449
2450                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2451                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2452                                 STAT(RESPAWN_TIME, this) *= -1;
2453
2454                         return;
2455                 }
2456
2457                 this.prevorigin = this.origin;
2458
2459                 bool have_hook = false;
2460                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2461                 {
2462                         .entity weaponentity = weaponentities[slot];
2463                         if(this.(weaponentity).hook.state)
2464                         {
2465                                 have_hook = true;
2466                                 break;
2467                         }
2468                 }
2469                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2470                 if (have_hook) {
2471                         do_crouch = false;
2472                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2473                         do_crouch = false;
2474                 } else if (this.vehicle) {
2475                         do_crouch = false;
2476                 } else if (STAT(FROZEN, this)) {
2477                         do_crouch = false;
2478         }
2479
2480                 if (do_crouch) {
2481                         if (!this.crouch) {
2482                                 this.crouch = true;
2483                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2484                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2485                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2486                         }
2487                 } else if (this.crouch) {
2488             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2489             if (!trace_startsolid) {
2490                 this.crouch = false;
2491                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2492                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2493             }
2494                 }
2495
2496                 FixPlayermodel(this);
2497
2498                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2499                 //if(frametime)
2500                 {
2501                         this.items &= ~this.items_added;
2502
2503                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2504                         {
2505                                 .entity weaponentity = weaponentities[slot];
2506                                 W_WeaponFrame(this, weaponentity);
2507
2508                                 if(slot == 0)
2509                                 {
2510                                         this.clip_load = this.(weaponentity).clip_load;
2511                                         this.clip_size = this.(weaponentity).clip_size;
2512                                 }
2513                         }
2514
2515                         this.items_added = 0;
2516                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2517                 this.items_added |= IT_FUEL;
2518
2519                         this.items |= this.items_added;
2520                 }
2521
2522                 player_regen(this);
2523
2524                 // WEAPONTODO: Add a weapon request for this
2525                 // rot vortex charge to the charge limit
2526                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2527                 {
2528                         .entity weaponentity = weaponentities[slot];
2529                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2530                         {
2531                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2532                         }
2533                         if (WEP_CVAR(okvortex, charge_rot_rate) && this.(weaponentity).okvortex_charge > WEP_CVAR(okvortex, charge_limit) && this.(weaponentity).okvortex_charge_rottime < time)
2534                         {
2535                                 this.(weaponentity).okvortex_charge = bound(WEP_CVAR(okvortex, charge_limit), this.(weaponentity).okvortex_charge - WEP_CVAR(okvortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2536                         }
2537                 }
2538
2539                 if (frametime) player_anim(this);
2540
2541                 // secret status
2542                 secrets_setstatus(this);
2543
2544                 // monsters status
2545                 monsters_setstatus(this);
2546
2547                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2548         }
2549         else if (game_stopped || intermission_running) {
2550                 if(intermission_running)
2551                         IntermissionThink(this);
2552                 return;
2553         }
2554         else if (IS_OBSERVER(this)) {
2555                 ObserverThink(this);
2556         }
2557         else if (IS_SPEC(this)) {
2558                 SpectatorThink(this);
2559         }
2560
2561         // WEAPONTODO: Add weapon request for this
2562         if (!zoomstate_set) {
2563                 bool wep_zoomed = false;
2564                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2565                 {
2566                         .entity weaponentity = weaponentities[slot];
2567                         Weapon thiswep = this.(weaponentity).m_weapon;
2568                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2569                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2570                 }
2571                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2572     }
2573
2574         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2575         {
2576                 this.teamkill_soundtime = 0;
2577
2578                 entity e = this.teamkill_soundsource;
2579                 entity oldpusher = e.pusher;
2580                 e.pusher = this;
2581                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2582                 e.pusher = oldpusher;
2583         }
2584
2585         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2586                 this.taunt_soundtime = 0;
2587                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2588         }
2589
2590         target_voicescript_next(this);
2591
2592         // WEAPONTODO: Move into weaponsystem somehow
2593         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2594         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2595         {
2596                 .entity weaponentity = weaponentities[slot];
2597                 if(this.(weaponentity).m_weapon == WEP_Null)
2598                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2599         }
2600 }
2601
2602 void DrownPlayer(entity this)
2603 {
2604         if(IS_DEAD(this))
2605                 return;
2606
2607         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2608         {
2609                 if(this.air_finished < time)
2610                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2611                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2612                 this.dmg = 2;
2613         }
2614         else if (this.air_finished < time)
2615         {       // drown!
2616                 if (this.pain_finished < time)
2617                 {
2618                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2619                         this.pain_finished = time + 0.5;
2620                 }
2621         }
2622 }
2623
2624 .bool move_qcphysics;
2625
2626 void Player_Physics(entity this)
2627 {
2628         set_movetype(this, this.move_movetype);
2629
2630         if(!this.move_qcphysics)
2631                 return;
2632
2633         if(!frametime && !this.pm_frametime)
2634                 return;
2635
2636         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2637
2638         this.pm_frametime = 0;
2639 }
2640
2641 /*
2642 =============
2643 PlayerPostThink
2644
2645 Called every frame for each client after the physics are run
2646 =============
2647 */
2648 .float idlekick_lasttimeleft;
2649 void PlayerPostThink (entity this)
2650 {
2651         Player_Physics(this);
2652
2653         if (sv_maxidle > 0)
2654         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2655         if (IS_REAL_CLIENT(this))
2656         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2657         {
2658                 int totalClients = 0;
2659                 if(sv_maxidle_slots > 0)
2660                 {
2661                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2662                         {
2663                                 ++totalClients;
2664                         });
2665                 }
2666
2667                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2668                 { /* do nothing */ }
2669                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2670                 {
2671                         if (this.idlekick_lasttimeleft)
2672                         {
2673                                 this.idlekick_lasttimeleft = 0;
2674                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2675                         }
2676                 }
2677                 else
2678                 {
2679                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2680                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2681                                 if (!this.idlekick_lasttimeleft)
2682                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2683                         }
2684                         if (timeleft <= 0) {
2685                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2686                                 dropclient(this);
2687                                 return;
2688                         }
2689                         else if (timeleft <= 10) {
2690                                 if (timeleft != this.idlekick_lasttimeleft) {
2691                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2692                 }
2693                                 this.idlekick_lasttimeleft = timeleft;
2694                         }
2695                 }
2696         }
2697
2698         CheatFrame(this);
2699
2700         //CheckPlayerJump();
2701         if (game_stopped)
2702         {
2703                 this.solid = SOLID_NOT;
2704                 this.takedamage = DAMAGE_NO;
2705                 set_movetype(this, MOVETYPE_NONE);
2706         }
2707
2708         if (IS_PLAYER(this)) {
2709                 DrownPlayer(this);
2710                 CheckRules_Player(this);
2711                 UpdateChatBubble(this);
2712                 if (this.impulse) ImpulseCommands(this);
2713                 if (game_stopped)
2714                 {
2715                         CSQCMODEL_AUTOUPDATE(this);
2716                         return;
2717                 }
2718                 GetPressedKeys(this);
2719         }
2720
2721         if (this.waypointsprite_attachedforcarrier) {
2722             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2723                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2724     }
2725
2726         playerdemo_write(this);
2727
2728         CSQCMODEL_AUTOUPDATE(this);
2729 }