qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 141                                         sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 bool SpectateNext(entity this);
 239
 240 /** putting a client as observer in the server */
 241 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 242 {
 243         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 244         bool recount_ready = false;
 245         PlayerState_detach(this);
 246
 247         if (IS_PLAYER(this))
 248         {
 249                 if(GetResource(this, RES_HEALTH) >= 1)
 250                 {
 251                         // despawn effect
 252                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 253                 }
 254
 255                 // was a player, recount votes and ready status
 256                 if(IS_REAL_CLIENT(this))
 257                 {
 258                         if (vote_called) { VoteCount(false); }
 259                         this.ready = false;
 260                         recount_ready = true;
 261                 }
 262                 entcs_update_players(this);
 263         }
 264
 265         if (use_spawnpoint)
 266         {
 267                 entity spot = SelectSpawnPoint(this, true);
 268                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 269                 this.angles = vec2(spot.angles);
 270                 // offset it so that the spectator spawns higher off the ground, looks better this way
 271                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 272         }
 273         else // change origin to restore previous view origin
 274                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 275         this.fixangle = true;
 276
 277         if (IS_REAL_CLIENT(this))
 278         {
 279                 msg_entity = this;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, this);
 282         }
 283         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 284         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 285         if(!autocvar_g_debug_globalsounds)
 286         {
 287                 // needed for player sounds
 288                 this.model = "";
 289                 FixPlayermodel(this);
 290         }
 291         setmodel(this, MDL_Null);
 292         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 293         this.view_ofs = '0 0 0';
 294
 295         RemoveGrapplingHooks(this);
 296         Portal_ClearAll(this);
 297         Unfreeze(this, false);
 298         SetSpectatee(this, NULL);
 299
 300         if (this.alivetime)
 301         {
 302                 if (!warmup_stage)
 303                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 304                 this.alivetime = 0;
 305         }
 306
 307         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 308
 309         TRANSMUTE(Observer, this);
 310
 311         if(recount_ready) ReadyCount();
 312
 313         WaypointSprite_PlayerDead(this);
 314         accuracy_resend(this);
 315
 316         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 317                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 318
 319         CS(this).spectatortime = time;
 320         if(this.bot_attack)
 321                 IL_REMOVE(g_bot_targets, this);
 322         this.bot_attack = false;
 323         if(this.monster_attack)
 324                 IL_REMOVE(g_monster_targets, this);
 325         this.monster_attack = false;
 326         STAT(HUD, this) = HUD_NORMAL;
 327         this.iscreature = false;
 328         this.teleportable = TELEPORT_SIMPLE;
 329         if(this.damagedbycontents)
 330                 IL_REMOVE(g_damagedbycontents, this);
 331         this.damagedbycontents = false;
 332         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 333         SetSpectatee_status(this, etof(this));
 334         this.takedamage = DAMAGE_NO;
 335         this.solid = SOLID_NOT;
 336         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 337         this.flags = FL_CLIENT | FL_NOTARGET;
 338         this.effects = 0;
 339         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 340         this.pauserotarmor_finished = 0;
 341         this.pauserothealth_finished = 0;
 342         this.pauseregen_finished = 0;
 343         this.damageforcescale = 0;
 344         this.death_time = 0;
 345         this.respawn_flags = 0;
 346         this.respawn_time = 0;
 347         STAT(RESPAWN_TIME, this) = 0;
 348         this.alpha = 0;
 349         this.scale = 0;
 350         this.fade_time = 0;
 351         this.pain_finished = 0;
 352         STAT(AIR_FINISHED, this) = 0;
 353         //this.dphitcontentsmask = 0;
 354         this.dphitcontentsmask = DPCONTENTS_SOLID;
 355         if (autocvar_g_playerclip_collisions)
 356                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 357         this.pushltime = 0;
 358         this.istypefrag = 0;
 359         setthink(this, func_null);
 360         this.nextthink = 0;
 361         this.deadflag = DEAD_NO;
 362         UNSET_DUCKED(this);
 363         STAT(REVIVE_PROGRESS, this) = 0;
 364         this.revival_time = 0;
 365         this.draggable = drag_undraggable;
 366
 367         player_powerups_remove_all(this);
 368         this.items = 0;
 369         STAT(WEAPONS, this) = '0 0 0';
 370         this.drawonlytoclient = this;
 371
 372         this.viewloc = NULL;
 373
 374         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 375
 376         this.weaponmodel = "";
 377         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 378         {
 379                 this.weaponentities[slot] = NULL;
 380         }
 381         this.exteriorweaponentity = NULL;
 382         CS(this).killcount = FRAGS_SPECTATOR;
 383         this.velocity = '0 0 0';
 384         this.avelocity = '0 0 0';
 385         this.punchangle = '0 0 0';
 386         this.punchvector = '0 0 0';
 387         this.oldvelocity = this.velocity;
 388         this.event_damage = func_null;
 389         this.event_heal = func_null;
 390
 391         for(int slot = 0; slot < MAX_AXH; ++slot)
 392         {
 393                 entity axh = this.(AuxiliaryXhair[slot]);
 394                 this.(AuxiliaryXhair[slot]) = NULL;
 395
 396                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 397                         delete(axh);
 398         }
 399
 400         if (mutator_returnvalue)
 401         {
 402                 // mutator prevents resetting teams+score
 403         }
 404         else
 405         {
 406                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 407                 this.frags = FRAGS_SPECTATOR;
 408         }
 409
 410         bot_relinkplayerlist();
 411
 412         if (CS(this).just_joined)
 413                 CS(this).just_joined = false;
 414
 415         // force members of alive squads to spectate another squadmate
 416         if(IS_REAL_CLIENT(this) && IN_SQUAD(this) && !this.br_squad.br_squad_dead)
 417         {
 418                 SpectateNext(this);
 419                 TRANSMUTE(Spectator, this);
 420         }
 421 }
 422
 423 int player_getspecies(entity this)
 424 {
 425         get_model_parameters(this.model, this.skin);
 426         int s = get_model_parameters_species;
 427         get_model_parameters(string_null, 0);
 428         if (s < 0) return SPECIES_HUMAN;
 429         return s;
 430 }
 431
 432 .float model_randomizer;
 433 void FixPlayermodel(entity player)
 434 {
 435         string defaultmodel = "";
 436         int defaultskin = 0;
 437         if(autocvar_sv_defaultcharacter)
 438         {
 439                 if(teamplay)
 440                 {
 441                         switch(player.team)
 442                         {
 443                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 444                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 445                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 446                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 447                         }
 448                 }
 449
 450                 if(defaultmodel == "")
 451                 {
 452                         defaultmodel = autocvar_sv_defaultplayermodel;
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454                 }
 455
 456                 int n = tokenize_console(defaultmodel);
 457                 if(n > 0)
 458                 {
 459                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 460                         // However, do NOT randomize if the player-selected model is in the list.
 461                         for (int i = 0; i < n; ++i)
 462                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 463                                         defaultmodel = argv(i);
 464                 }
 465
 466                 int i = strstrofs(defaultmodel, ":", 0);
 467                 if(i >= 0)
 468                 {
 469                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 470                         defaultmodel = substring(defaultmodel, 0, i);
 471                 }
 472         }
 473         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 474         {
 475                 if(teamplay)
 476                 {
 477                         switch(player.team)
 478                         {
 479                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 480                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 481                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 482                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 483                         }
 484                 }
 485
 486                 if(!defaultskin)
 487                         defaultskin = autocvar_sv_defaultplayerskin;
 488         }
 489
 490         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 491         defaultmodel = M_ARGV(0, string);
 492         defaultskin = M_ARGV(1, int);
 493
 494         bool chmdl = false;
 495         int oldskin;
 496         if(defaultmodel != "")
 497         {
 498                 if (defaultmodel != player.model)
 499                 {
 500                         vector m1 = player.mins;
 501                         vector m2 = player.maxs;
 502                         setplayermodel (player, defaultmodel);
 503                         setsize (player, m1, m2);
 504                         chmdl = true;
 505                 }
 506
 507                 oldskin = player.skin;
 508                 player.skin = defaultskin;
 509         } else {
 510                 if (player.playermodel != player.model || player.playermodel == "")
 511                 {
 512                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 513                         vector m1 = player.mins;
 514                         vector m2 = player.maxs;
 515                         setplayermodel (player, player.playermodel);
 516                         setsize (player, m1, m2);
 517                         chmdl = true;
 518                 }
 519
 520                 if(!autocvar_sv_defaultcharacterskin)
 521                 {
 522                         oldskin = player.skin;
 523                         player.skin = stof(player.playerskin);
 524                 }
 525                 else
 526                 {
 527                         oldskin = player.skin;
 528                         player.skin = defaultskin;
 529                 }
 530         }
 531
 532         if(chmdl || oldskin != player.skin) // model or skin has changed
 533         {
 534                 player.species = player_getspecies(player); // update species
 535                 if(!autocvar_g_debug_globalsounds)
 536                         UpdatePlayerSounds(player); // update skin sounds
 537         }
 538
 539         if(!teamplay)
 540                 if(strlen(autocvar_sv_defaultplayercolors))
 541                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 542                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 543 }
 544
 545 void PutPlayerInServer(entity this)
 546 {
 547         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 548
 549         PlayerState_attach(this);
 550         accuracy_resend(this);
 551
 552         if (teamplay && this.bot_forced_team)
 553                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 554
 555         if (this.team < 0)
 556                 TeamBalance_JoinBestTeam(this);
 557
 558         entity spot = SelectSpawnPoint(this, false);
 559         if (!spot) {
 560                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 561                 return; // spawn failed
 562         }
 563
 564         TRANSMUTE(Player, this);
 565
 566         CS(this).wasplayer = true;
 567         this.iscreature = true;
 568         this.teleportable = TELEPORT_NORMAL;
 569         if(!this.damagedbycontents)
 570                 IL_PUSH(g_damagedbycontents, this);
 571         this.damagedbycontents = true;
 572         set_movetype(this, MOVETYPE_WALK);
 573         this.solid = SOLID_SLIDEBOX;
 574         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 575         if (autocvar_g_playerclip_collisions)
 576                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 577         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 578                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 579         this.frags = FRAGS_PLAYER;
 580         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 581         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 582         if (autocvar__notarget)
 583                 this.flags |= FL_NOTARGET;
 584         this.takedamage = DAMAGE_AIM;
 585         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 586
 587         if (warmup_stage) {
 588                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 589                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 590                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 591                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 592                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 593                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 594                 SetResource(this, RES_HEALTH, warmup_start_health);
 595                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 596                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 597         } else {
 598                 SetResource(this, RES_SHELLS, start_ammo_shells);
 599                 SetResource(this, RES_BULLETS, start_ammo_nails);
 600                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 601                 SetResource(this, RES_CELLS, start_ammo_cells);
 602                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 603                 SetResource(this, RES_FUEL, start_ammo_fuel);
 604                 SetResource(this, RES_HEALTH, start_health);
 605                 SetResource(this, RES_ARMOR, start_armorvalue);
 606                 STAT(WEAPONS, this) = start_weapons;
 607                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 608                 {
 609                         GiveRandomWeapons(this, random_start_weapons_count,
 610                                 autocvar_g_random_start_weapons, random_start_ammo);
 611                 }
 612         }
 613         SetSpectatee_status(this, 0);
 614
 615         PS(this).dual_weapons = '0 0 0';
 616
 617         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 618                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 619
 620         this.items = start_items;
 621
 622         float shieldtime = time + autocvar_g_spawnshieldtime;
 623
 624         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 625         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 626         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 627         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 628         if (!sv_ready_restart_after_countdown && time < game_starttime)
 629         {
 630                 float f = game_starttime - time;
 631                 shieldtime += f;
 632                 this.pauserotarmor_finished += f;
 633                 this.pauserothealth_finished += f;
 634                 this.pauseregen_finished += f;
 635         }
 636
 637         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 638
 639         this.damageforcescale = autocvar_g_player_damageforcescale;
 640         this.death_time = 0;
 641         this.respawn_flags = 0;
 642         this.respawn_time = 0;
 643         STAT(RESPAWN_TIME, this) = 0;
 644         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 645         this.fade_time = 0;
 646         this.pain_finished = 0;
 647         this.pushltime = 0;
 648         setthink(this, func_null); // players have no think function
 649         this.nextthink = 0;
 650         this.dmg_team = 0;
 651         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 652
 653         this.deadflag = DEAD_NO;
 654
 655         this.angles = spot.angles;
 656         this.angles_z = 0; // never spawn tilted even if the spot says to
 657         if (IS_BOT_CLIENT(this))
 658         {
 659                 this.v_angle = this.angles;
 660                 bot_aim_reset(this);
 661         }
 662         this.fixangle = true; // turn this way immediately
 663         this.oldvelocity = this.velocity = '0 0 0';
 664         this.avelocity = '0 0 0';
 665         this.punchangle = '0 0 0';
 666         this.punchvector = '0 0 0';
 667
 668         STAT(REVIVE_PROGRESS, this) = 0;
 669         this.revival_time = 0;
 670
 671         STAT(AIR_FINISHED, this) = 0;
 672         this.waterlevel = WATERLEVEL_NONE;
 673         this.watertype = CONTENT_EMPTY;
 674
 675         if(STAT(DROP, this) != DROP_TRANSPORT)
 676         {
 677                 entity spawnevent = new_pure(spawnevent);
 678                 spawnevent.owner = this;
 679                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 680         }
 681
 682         // Cut off any still running player sounds.
 683         stopsound(this, CH_PLAYER_SINGLE);
 684
 685         this.model = "";
 686         FixPlayermodel(this);
 687         this.drawonlytoclient = NULL;
 688
 689         this.viewloc = NULL;
 690
 691         for(int slot = 0; slot < MAX_AXH; ++slot)
 692         {
 693                 entity axh = this.(AuxiliaryXhair[slot]);
 694                 this.(AuxiliaryXhair[slot]) = NULL;
 695
 696                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 697                         delete(axh);
 698         }
 699
 700         this.spawnpoint_targ = NULL;
 701
 702         UNSET_DUCKED(this);
 703         this.view_ofs = STAT(PL_VIEW_OFS, this);
 704         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 705         this.spawnorigin = spot.origin;
 706         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 707         // don't reset back to last position, even if new position is stuck in solid
 708         this.oldorigin = this.origin;
 709         if(this.conveyor)
 710                 IL_REMOVE(g_conveyed, this);
 711         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 712         if(this.swampslug)
 713                 IL_REMOVE(g_swamped, this);
 714         this.swampslug = NULL;
 715         this.swamp_interval = 0;
 716         if(this.ladder_entity)
 717                 IL_REMOVE(g_ladderents, this);
 718         this.ladder_entity = NULL;
 719         IL_EACH(g_counters, it.realowner == this,
 720         {
 721                 delete(it);
 722         });
 723         STAT(HUD, this) = HUD_NORMAL;
 724
 725         this.event_damage = PlayerDamage;
 726         this.event_heal = PlayerHeal;
 727
 728         this.draggable = func_null;
 729
 730         if(!this.bot_attack)
 731                 IL_PUSH(g_bot_targets, this);
 732         this.bot_attack = true;
 733         if(!this.monster_attack)
 734                 IL_PUSH(g_monster_targets, this);
 735         this.monster_attack = true;
 736         navigation_dynamicgoal_init(this, false);
 737
 738         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 739
 740         // player was spectator
 741         if (CS(this).killcount == FRAGS_SPECTATOR) {
 742                 PlayerScore_Clear(this);
 743                 CS(this).killcount = 0;
 744                 CS(this).startplaytime = time;
 745         }
 746
 747         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 748         {
 749                 .entity weaponentity = weaponentities[slot];
 750                 CL_SpawnWeaponentity(this, weaponentity);
 751         }
 752         this.alpha = default_player_alpha;
 753         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 754         this.exteriorweaponentity.alpha = default_weapon_alpha;
 755
 756         this.speedrunning = false;
 757
 758         this.counter_cnt = 0;
 759         this.fragsfilter_cnt = 0;
 760
 761         target_voicescript_clear(this);
 762
 763         // reset fields the weapons may use
 764         FOREACH(Weapons, true, {
 765                 it.wr_resetplayer(it, this);
 766                         // reload all reloadable weapons
 767                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 768                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 769                         {
 770                                 .entity weaponentity = weaponentities[slot];
 771                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 772                         }
 773                 }
 774         });
 775
 776         Unfreeze(this, false);
 777
 778         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 779         {
 780                 string s = spot.target;
 781                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 782                         spot.target = string_null;
 783                 SUB_UseTargets(spot, this, NULL);
 784                 if(g_assault || g_race)
 785                         spot.target = s;
 786         }
 787
 788         if (autocvar_spawn_debug)
 789         {
 790                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 791                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 792         }
 793
 794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795         {
 796                 .entity weaponentity = weaponentities[slot];
 797                 entity w_ent = this.(weaponentity);
 798                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 799                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 800                 else
 801                         w_ent.m_switchweapon = WEP_Null;
 802                 w_ent.m_weapon = WEP_Null;
 803                 w_ent.weaponname = "";
 804                 w_ent.m_switchingweapon = WEP_Null;
 805                 w_ent.cnt = -1;
 806         }
 807
 808         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 809
 810         if (CS(this).impulse) ImpulseCommands(this);
 811
 812         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 813         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 814         {
 815                 .entity weaponentity = weaponentities[slot];
 816                 W_WeaponFrame(this, weaponentity);
 817         }
 818
 819         if (!warmup_stage && !this.alivetime)
 820                 this.alivetime = time;
 821
 822         antilag_clear(this, CS(this));
 823 }
 824
 825 /** Called when a client spawns in the server */
 826 void PutClientInServer(entity this)
 827 {
 828         if (IS_REAL_CLIENT(this)) {
 829                 msg_entity = this;
 830                 WriteByte(MSG_ONE, SVC_SETVIEW);
 831                 WriteEntity(MSG_ONE, this);
 832         }
 833         if (game_stopped)
 834                 TRANSMUTE(Observer, this);
 835
 836         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 837         SetSpectatee(this, NULL);
 838
 839         // reset player keys
 840         if(PS(this))
 841                 PS(this).itemkeys = 0;
 842
 843         MUTATOR_CALLHOOK(PutClientInServer, this);
 844
 845         if (IS_OBSERVER(this)) {
 846                 PutObserverInServer(this, false, use_spawnpoint);
 847         } else if (IS_PLAYER(this)) {
 848                 PutPlayerInServer(this);
 849         }
 850
 851         bot_relinkplayerlist();
 852 }
 853
 854 // TODO do we need all these fields, or should we stop autodetecting runtime
 855 // changes and just have a console command to update this?
 856 bool ClientInit_SendEntity(entity this, entity to, int sf)
 857 {
 858         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 859         return = true;
 860         msg_entity = to;
 861         // MSG_INIT replacement
 862         // TODO: make easier to use
 863         Registry_send_all();
 864         W_PROP_reload(MSG_ONE, to);
 865         ClientInit_misc(this);
 866         MUTATOR_CALLHOOK(Ent_Init);
 867 }
 868 void ClientInit_misc(entity this)
 869 {
 870         int channel = MSG_ONE;
 871         WriteHeader(channel, ENT_CLIENT_INIT);
 872         WriteByte(channel, g_nexball_meter_period * 32);
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 881
 882         if(autocvar_sv_foginterval && world.fog != "")
 883                 WriteString(channel, world.fog);
 884         else
 885                 WriteString(channel, "");
 886         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 887         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 888         WriteByte(channel, serverflags);
 889         WriteCoord(channel, autocvar_g_trueaim_minrange);
 890 }
 891
 892 void ClientInit_CheckUpdate(entity this)
 893 {
 894         this.nextthink = time;
 895         if(this.count != autocvar_g_balance_armor_blockpercent)
 896         {
 897                 this.count = autocvar_g_balance_armor_blockpercent;
 898                 this.SendFlags |= 1;
 899         }
 900         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 901         {
 902                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 903                 this.SendFlags |= 1;
 904         }
 905 }
 906
 907 void ClientInit_Spawn()
 908 {
 909         entity e = new_pure(clientinit);
 910         setthink(e, ClientInit_CheckUpdate);
 911         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 912
 913         ClientInit_CheckUpdate(e);
 914 }
 915
 916 /*
 917 =============
 918 SetNewParms
 919 =============
 920 */
 921 void SetNewParms ()
 922 {
 923         // initialize parms for a new player
 924         parm1 = -(86400 * 366);
 925
 926         MUTATOR_CALLHOOK(SetNewParms);
 927 }
 928
 929 /*
 930 =============
 931 SetChangeParms
 932 =============
 933 */
 934 void SetChangeParms (entity this)
 935 {
 936         // save parms for level change
 937         parm1 = CS(this).parm_idlesince - time;
 938
 939         MUTATOR_CALLHOOK(SetChangeParms);
 940 }
 941
 942 /*
 943 =============
 944 DecodeLevelParms
 945 =============
 946 */
 947 void DecodeLevelParms(entity this)
 948 {
 949         // load parms
 950         CS(this).parm_idlesince = parm1;
 951         if (CS(this).parm_idlesince == -(86400 * 366))
 952                 CS(this).parm_idlesince = time;
 953
 954         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 955         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 956
 957         MUTATOR_CALLHOOK(DecodeLevelParms);
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         if(autocvar_g_antilag == 3) // client side hitscan
 964                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 965         if(autocvar_sv_gentle)
 966                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 967
 968         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 969         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 970
 971         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 972
 973         MUTATOR_CALLHOOK(FixClientCvars, e);
 974 }
 975
 976 bool findinlist_abbrev(string tofind, string list)
 977 {
 978         if(list == "" || tofind == "")
 979                 return false; // empty list or search, just return
 980
 981         // this function allows abbreviated strings!
 982         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 983         {
 984                 return true;
 985         });
 986
 987         return false;
 988 }
 989
 990 bool PlayerInIPList(entity p, string iplist)
 991 {
 992         // some safety checks (never allow local?)
 993         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 994                 return false;
 995
 996         return findinlist_abbrev(p.netaddress, iplist);
 997 }
 998
 999 bool PlayerInIDList(entity p, string idlist)
1000 {
1001         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1002         if(!p.crypto_idfp)
1003                 return false;
1004
1005         return findinlist_abbrev(p.crypto_idfp, idlist);
1006 }
1007
1008 bool PlayerInList(entity player, string list)
1009 {
1010         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1011 }
1012
1013 #ifdef DP_EXT_PRECONNECT
1014 /*
1015 =============
1016 ClientPreConnect
1017
1018 Called once (not at each match start) when a client begins a connection to the server
1019 =============
1020 */
1021 void ClientPreConnect(entity this)
1022 {
1023         if(autocvar_sv_eventlog)
1024         {
1025                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1026                         this.playerid,
1027                         etof(this),
1028                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1029                 ));
1030         }
1031 }
1032 #endif
1033
1034 void SendWelcomemessage(entity this, bool force_centerprint)
1035 {
1036         msg_entity = this;
1037         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1038         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1039 }
1040
1041 // NOTE csqc uses the active mutators list sent by this function
1042 // to understand which mutators are enabled
1043 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1044 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1045 {
1046         WriteByte(msg_type, boolean(autocvar_g_campaign));
1047         if (boolean(autocvar_g_campaign))
1048         {
1049                 WriteString(msg_type, Campaign_GetTitle());
1050                 WriteByte(msg_type, Campaign_GetLevelNum());
1051                 WriteString(msg_type, Campaign_GetMessage());
1052                 return;
1053         }
1054         WriteByte(msg_type, force_centerprint);
1055         WriteString(msg_type, autocvar_hostname);
1056         WriteString(msg_type, autocvar_g_xonoticversion);
1057         WriteByte(msg_type, CS(this).version_mismatch);
1058         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1059
1060         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1061         string modifications = M_ARGV(0, string);
1062
1063         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1064                 modifications = strcat(modifications, ", No start weapons");
1065         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1066                 modifications = strcat(modifications, ", Low gravity");
1067         if(g_weapon_stay && !g_cts)
1068                 modifications = strcat(modifications, ", Weapons stay");
1069         if(autocvar_g_jetpack)
1070                 modifications = strcat(modifications, ", Jetpack");
1071         modifications = substring(modifications, 2, strlen(modifications) - 2);
1072
1073         WriteString(msg_type, modifications);
1074
1075         WriteString(msg_type, g_weaponarena_list);
1076
1077         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1078         {
1079                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1080                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1081         }
1082
1083         WriteString(msg_type, cache_mutatormsg);
1084
1085         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1086 }
1087
1088 /**
1089 =============
1090 ClientConnect
1091
1092 Called when a client connects to the server
1093 =============
1094 */
1095 void ClientConnect(entity this)
1096 {
1097         if (Ban_MaybeEnforceBanOnce(this)) return;
1098         assert(!IS_CLIENT(this), return);
1099         this.flags |= FL_CLIENT;
1100         assert(player_count >= 0, player_count = 0);
1101
1102         TRANSMUTE(Client, this);
1103         CS(this).version_nagtime = time + 10 + random() * 10;
1104
1105         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1106
1107         bot_clientconnect(this);
1108
1109         Player_DetermineForcedTeam(this);
1110
1111         TRANSMUTE(Observer, this);
1112
1113         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1114
1115         // always track bots, don't ask for cl_allow_uidtracking
1116         if (IS_BOT_CLIENT(this))
1117                 PlayerStats_GameReport_AddPlayer(this);
1118         else
1119                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1120
1121         if (autocvar_sv_eventlog)
1122                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1123
1124         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1125
1126         stuffcmd(this, clientstuff, "\n");
1127         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1128
1129         FixClientCvars(this);
1130
1131         // get version info from player
1132         stuffcmd(this, "cmd clientversion $gameversion\n");
1133
1134         // notify about available teams
1135         if (teamplay)
1136         {
1137                 entity balance = TeamBalance_CheckAllowedTeams(this);
1138                 int t = TeamBalance_GetAllowedTeams(balance);
1139                 TeamBalance_Destroy(balance);
1140                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1141         }
1142         else
1143         {
1144                 stuffcmd(this, "set _teams_available 0\n");
1145         }
1146
1147         bot_relinkplayerlist();
1148
1149         CS(this).spectatortime = time;
1150         if (blockSpectators)
1151         {
1152                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1153         }
1154
1155         CS(this).jointime = time;
1156
1157         if (IS_REAL_CLIENT(this))
1158         {
1159                 if (g_weaponarena_weapons == WEPSET(TUBA))
1160                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1161         }
1162
1163         if (!autocvar_sv_foginterval && world.fog != "")
1164                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1165
1166         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1167                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1168                         send_CSQC_teamnagger();
1169
1170         CSQCMODEL_AUTOINIT(this);
1171
1172         CS(this).model_randomizer = random();
1173
1174         if (IS_REAL_CLIENT(this))
1175                 sv_notice_join(this);
1176
1177         this.move_qcphysics = autocvar_sv_qcphysics;
1178
1179         // update physics stats (players can spawn before physics runs)
1180         Physics_UpdateStats(this);
1181
1182         IL_EACH(g_initforplayer, it.init_for_player, {
1183                 it.init_for_player(it, this);
1184         });
1185
1186         Handicap_Initialize(this);
1187
1188         MUTATOR_CALLHOOK(ClientConnect, this);
1189
1190         if (player_count == 1)
1191                 localcmd("\nsv_hook_firstjoin\n");
1192
1193         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1194                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void player_powerups_remove_all(entity this);
1205
1206 void ClientDisconnect(entity this)
1207 {
1208         assert(IS_CLIENT(this), return);
1209
1210         PlayerStats_GameReport_FinalizePlayer(this);
1211         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1212         if (CS(this).active_minigame) part_minigame(this);
1213         if (IS_PLAYER(this) && (STAT(DROP, this) != DROP_TRANSPORT)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1214
1215         if (autocvar_sv_eventlog)
1216                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1217
1218         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1219
1220         if(IS_SPEC(this))
1221                 SetSpectatee(this, NULL);
1222
1223         MUTATOR_CALLHOOK(ClientDisconnect, this);
1224
1225         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1226         strfree(CS_CVAR(this).weaponorder_byimpulse);
1227         ClientState_detach(this);
1228
1229         Portal_ClearAll(this);
1230
1231         Unfreeze(this, false);
1232
1233         RemoveGrapplingHooks(this);
1234
1235         // Here, everything has been done that requires this player to be a client.
1236
1237         this.flags &= ~FL_CLIENT;
1238
1239         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1240         if (this.killindicator) delete(this.killindicator);
1241
1242         IL_EACH(g_counters, it.realowner == this,
1243         {
1244                 delete(it);
1245         });
1246
1247         WaypointSprite_PlayerGone(this);
1248
1249         bot_relinkplayerlist();
1250
1251         strfree(this.clientstatus);
1252         if (this.personal) delete(this.personal);
1253
1254         this.playerid = 0;
1255         ReadyCount();
1256         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1257
1258         player_powerups_remove_all(this); // stop powerup sound
1259
1260         ONREMOVE(this);
1261
1262         if (player_count == 0)
1263                 localcmd("\nsv_hook_lastleave\n");
1264 }
1265
1266 void ChatBubbleThink(entity this)
1267 {
1268         this.nextthink = time;
1269         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1270         {
1271                 if(this.owner) // but why can that ever be NULL?
1272                         this.owner.chatbubbleentity = NULL;
1273                 delete(this);
1274                 return;
1275         }
1276
1277         this.mdl = "";
1278
1279         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1280         {
1281                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1282                         this.mdl = "models/sprites/minigame_busy.iqm";
1283                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1284                         this.mdl = "models/misc/chatbubble.spr";
1285         }
1286
1287         if ( this.model != this.mdl )
1288                 _setmodel(this, this.mdl);
1289
1290 }
1291
1292 void UpdateChatBubble(entity this)
1293 {
1294         if (this.alpha < 0)
1295                 return;
1296         // spawn a chatbubble entity if needed
1297         if (!this.chatbubbleentity)
1298         {
1299                 this.chatbubbleentity = new(chatbubbleentity);
1300                 this.chatbubbleentity.owner = this;
1301                 this.chatbubbleentity.exteriormodeltoclient = this;
1302                 setthink(this.chatbubbleentity, ChatBubbleThink);
1303                 this.chatbubbleentity.nextthink = time;
1304                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1305                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1306                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1307                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1308                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1309                 //this.chatbubbleentity.model = "";
1310                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1311         }
1312 }
1313
1314 void calculate_player_respawn_time(entity this)
1315 {
1316         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1317                 return;
1318
1319         float gametype_setting_tmp;
1320         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1321         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1322         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1323         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1324         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1325         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1326
1327         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1328         if (teamplay)
1329         {
1330                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1331                         if(it.team == this.team)
1332                                 ++pcount;
1333                 });
1334                 if (sdelay_small_count == 0)
1335                         sdelay_small_count = 1;
1336                 if (sdelay_large_count == 0)
1337                         sdelay_large_count = 1;
1338         }
1339         else
1340         {
1341                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1342                         ++pcount;
1343                 });
1344                 if (sdelay_small_count == 0)
1345                 {
1346                         if (IS_INDEPENDENT_PLAYER(this))
1347                         {
1348                                 // Players play independently. No point in requiring enemies.
1349                                 sdelay_small_count = 1;
1350                         }
1351                         else
1352                         {
1353                                 // Players play AGAINST each other. Enemies required.
1354                                 sdelay_small_count = 2;
1355                         }
1356                 }
1357                 if (sdelay_large_count == 0)
1358                 {
1359                         if (IS_INDEPENDENT_PLAYER(this))
1360                         {
1361                                 // Players play independently. No point in requiring enemies.
1362                                 sdelay_large_count = 1;
1363                         }
1364                         else
1365                         {
1366                                 // Players play AGAINST each other. Enemies required.
1367                                 sdelay_large_count = 2;
1368                         }
1369                 }
1370         }
1371
1372         float sdelay;
1373
1374         if (pcount <= sdelay_small_count)
1375                 sdelay = sdelay_small;
1376         else if (pcount >= sdelay_large_count)
1377                 sdelay = sdelay_large;
1378         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1379                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1380
1381         if(waves)
1382                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1383         else
1384                 this.respawn_time = time + sdelay;
1385
1386         if(sdelay < sdelay_max)
1387                 this.respawn_time_max = time + sdelay_max;
1388         else
1389                 this.respawn_time_max = this.respawn_time;
1390
1391         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1392                 this.respawn_countdown = 10; // first number to count down from is 10
1393         else
1394                 this.respawn_countdown = -1; // do not count down
1395
1396         if(autocvar_g_forced_respawn)
1397                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1398 }
1399
1400 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1401 // added to the model skins
1402 /*void UpdateColorModHack()
1403 {
1404         float c;
1405         c = this.clientcolors & 15;
1406         // LordHavoc: only bothering to support white, green, red, yellow, blue
1407              if (!teamplay) this.colormod = '0 0 0';
1408         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1409         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1410         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1411         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1412         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1413         else this.colormod = '1 1 1';
1414 }*/
1415
1416 void respawn(entity this)
1417 {
1418         bool damagedbycontents_prev = this.damagedbycontents;
1419         if(this.alpha >= 0)
1420         {
1421                 if(autocvar_g_respawn_ghosts)
1422                 {
1423                         this.solid = SOLID_NOT;
1424                         this.takedamage = DAMAGE_NO;
1425                         this.damagedbycontents = false;
1426                         set_movetype(this, MOVETYPE_FLY);
1427                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1428                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1429                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1430                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1431                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1432                         if(autocvar_g_respawn_ghosts_time > 0)
1433                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1434                 }
1435                 else
1436                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1437         }
1438
1439         CopyBody(this, 1);
1440         this.damagedbycontents = damagedbycontents_prev;
1441
1442         this.effects |= EF_NODRAW; // prevent another CopyBody
1443         PutClientInServer(this);
1444 }
1445
1446 void play_countdown(entity this, float finished, Sound samp)
1447 {
1448         TC(Sound, samp);
1449         float time_left = finished - time;
1450         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1451                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1452 }
1453
1454 // it removes special powerups not handled by StatusEffects
1455 void player_powerups_remove_all(entity this)
1456 {
1457         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1458         {
1459                 // don't play the poweroff sound when the game restarts or the player disconnects
1460                 if (time > game_starttime + 1 && IS_CLIENT(this)
1461                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1462                 {
1463                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1464                 }
1465                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1466                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1467                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1468         }
1469 }
1470
1471 void player_powerups(entity this)
1472 {
1473         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1474                 this.modelflags |= MF_ROCKET;
1475         else
1476                 this.modelflags &= ~MF_ROCKET;
1477
1478         this.effects &= ~EF_NODEPTHTEST;
1479
1480         if (IS_DEAD(this))
1481                 player_powerups_remove_all(this);
1482
1483         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1484                 return;
1485
1486         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1487         int items_prev = this.items;
1488
1489         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1490         {
1491                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1492                 if (this.items & IT_SUPERWEAPON)
1493                 {
1494                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1495                         {
1496                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1497                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1498                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1500                         }
1501                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1502                         {
1503                                 // don't let them run out
1504                         }
1505                         else
1506                         {
1507                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1508                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1509                                 {
1510                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1511                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1512                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1514                                 }
1515                         }
1516                 }
1517                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1518                 {
1519                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1520                         {
1521                                 this.items = this.items | IT_SUPERWEAPON;
1522                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1523                                 {
1524                                         if(!g_cts)
1525                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1526                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1527                                 }
1528                         }
1529                         else
1530                         {
1531                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1532                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1533                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1534                         }
1535                 }
1536                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1537                 {
1538                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1539                 }
1540         }
1541
1542         if(autocvar_g_nodepthtestplayers)
1543                 this.effects = this.effects | EF_NODEPTHTEST;
1544
1545         if(autocvar_g_fullbrightplayers)
1546                 this.effects = this.effects | EF_FULLBRIGHT;
1547
1548         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1549 }
1550
1551 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1552 {
1553         if(current > stable)
1554                 return current;
1555         else if(current > stable - 0.25) // when close enough, "snap"
1556                 return stable;
1557         else
1558                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1559 }
1560
1561 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1562 {
1563         if(current < stable)
1564                 return current;
1565         else if(current < stable + 0.25) // when close enough, "snap"
1566                 return stable;
1567         else
1568                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1569 }
1570
1571 void RotRegen(entity this, Resource res, float limit_mod,
1572         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1573         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1574 {
1575         float old = GetResource(this, res);
1576         float current = old;
1577         if(current > rotstable)
1578         {
1579                 if(rotframetime > 0)
1580                 {
1581                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1582                         current = max(rotstable, current - rotlinear * rotframetime);
1583                 }
1584         }
1585         else if(current < regenstable)
1586         {
1587                 if(regenframetime > 0)
1588                 {
1589                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1590                         current = min(regenstable, current + regenlinear * regenframetime);
1591                 }
1592         }
1593
1594         float limit = GetResourceLimit(this, res) * limit_mod;
1595         if(current > limit)
1596                 current = limit;
1597
1598         if (current != old)
1599                 SetResource(this, res, current);
1600 }
1601
1602 void player_regen(entity this)
1603 {
1604         float max_mod, regen_mod, rot_mod, limit_mod;
1605         max_mod = regen_mod = rot_mod = limit_mod = 1;
1606
1607         float regen_health = autocvar_g_balance_health_regen;
1608         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1609         float regen_health_rot = autocvar_g_balance_health_rot;
1610         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1611         float regen_health_stable = autocvar_g_balance_health_regenstable;
1612         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1613         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1614                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1615         max_mod = M_ARGV(1, float);
1616         regen_mod = M_ARGV(2, float);
1617         rot_mod = M_ARGV(3, float);
1618         limit_mod = M_ARGV(4, float);
1619         regen_health = M_ARGV(5, float);
1620         regen_health_linear = M_ARGV(6, float);
1621         regen_health_rot = M_ARGV(7, float);
1622         regen_health_rotlinear = M_ARGV(8, float);
1623         regen_health_stable = M_ARGV(9, float);
1624         regen_health_rotstable = M_ARGV(10, float);
1625
1626         float rotstable, regenstable, rotframetime, regenframetime;
1627
1628         if(!mutator_returnvalue)
1629         if(!STAT(FROZEN, this))
1630         {
1631                 regenstable = autocvar_g_balance_armor_regenstable;
1632                 rotstable = autocvar_g_balance_armor_rotstable;
1633                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1634                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1635                 RotRegen(this, RES_ARMOR, limit_mod,
1636                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1637                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1638
1639                 // NOTE: max_mod is only applied to health
1640                 regenstable = regen_health_stable * max_mod;
1641                 rotstable = regen_health_rotstable * max_mod;
1642                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1643                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1644                 RotRegen(this, RES_HEALTH, limit_mod,
1645                         regenstable, regen_health, regen_health_linear, regenframetime,
1646                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1647         }
1648
1649         // if player rotted to death...  die!
1650         // check this outside above checks, as player may still be able to rot to death
1651         if(GetResource(this, RES_HEALTH) < 1)
1652         {
1653                 if(this.vehicle)
1654                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1655                 if(this.event_damage)
1656                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1657         }
1658
1659         if (!(this.items & IT_UNLIMITED_AMMO))
1660         {
1661                 regenstable = autocvar_g_balance_fuel_regenstable;
1662                 rotstable = autocvar_g_balance_fuel_rotstable;
1663                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1664                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1665                 RotRegen(this, RES_FUEL, 1,
1666                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1667                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1668         }
1669 }
1670
1671 bool zoomstate_set;
1672 void SetZoomState(entity this, float newzoom)
1673 {
1674         if(newzoom != CS(this).zoomstate)
1675         {
1676                 CS(this).zoomstate = newzoom;
1677                 ClientData_Touch(this);
1678         }
1679         zoomstate_set = true;
1680 }
1681
1682 void GetPressedKeys(entity this)
1683 {
1684         MUTATOR_CALLHOOK(GetPressedKeys, this);
1685         if (game_stopped)
1686         {
1687                 CS(this).pressedkeys = 0;
1688                 STAT(PRESSED_KEYS, this) = 0;
1689                 return;
1690         }
1691
1692         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1693         int keys = STAT(PRESSED_KEYS, this);
1694         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1695         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1696         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1697         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1698
1699         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1700         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1701         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1702         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1703         CS(this).pressedkeys = keys; // store for other users
1704
1705         STAT(PRESSED_KEYS, this) = keys;
1706 }
1707
1708 /*
1709 ======================
1710 spectate mode routines
1711 ======================
1712 */
1713
1714 void SpectateCopy(entity this, entity spectatee)
1715 {
1716         TC(Client, this); TC(Client, spectatee);
1717
1718         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1719         PS(this) = PS(spectatee);
1720         this.armortype = spectatee.armortype;
1721         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1722         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1723         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1724         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1725         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1726         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1727         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1728         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1729         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1730         CS(this).impulse = 0;
1731         this.disableclientprediction = 1; // no need to run prediction on a spectator
1732         this.items = spectatee.items;
1733         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1734         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1735         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1736         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1737         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1738         this.punchangle = spectatee.punchangle;
1739         this.view_ofs = spectatee.view_ofs;
1740         this.velocity = spectatee.velocity;
1741         this.dmg_take = spectatee.dmg_take;
1742         this.dmg_save = spectatee.dmg_save;
1743         this.dmg_inflictor = spectatee.dmg_inflictor;
1744         this.v_angle = spectatee.v_angle;
1745         this.angles = spectatee.v_angle;
1746         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1747         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1748         this.viewloc = spectatee.viewloc;
1749         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1750                 this.fixangle = true;
1751         setorigin(this, spectatee.origin);
1752         setsize(this, spectatee.mins, spectatee.maxs);
1753         SetZoomState(this, CS(spectatee).zoomstate);
1754
1755     anticheat_spectatecopy(this, spectatee);
1756         STAT(HUD, this) = STAT(HUD, spectatee);
1757         if(spectatee.vehicle)
1758     {
1759         this.angles = spectatee.v_angle;
1760
1761         //this.fixangle = false;
1762         //this.velocity = spectatee.vehicle.velocity;
1763         this.vehicle_health = spectatee.vehicle_health;
1764         this.vehicle_shield = spectatee.vehicle_shield;
1765         this.vehicle_energy = spectatee.vehicle_energy;
1766         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1767         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1768         this.vehicle_reload1 = spectatee.vehicle_reload1;
1769         this.vehicle_reload2 = spectatee.vehicle_reload2;
1770
1771         //msg_entity = this;
1772
1773        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1774             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1775            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1776            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1777
1778         //WriteByte (MSG_ONE, SVC_SETVIEW);
1779         //    WriteEntity(MSG_ONE, this);
1780         //makevectors(spectatee.v_angle);
1781         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1782     }
1783 }
1784
1785 bool SpectateUpdate(entity this)
1786 {
1787         if(!this.enemy)
1788                 return false;
1789
1790         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1791         {
1792                 SetSpectatee(this, NULL);
1793                 return false;
1794         }
1795
1796         SpectateCopy(this, this.enemy);
1797
1798         return true;
1799 }
1800
1801 bool SpectateSet(entity this)
1802 {
1803         if(!IS_PLAYER(this.enemy))
1804                 return false;
1805
1806         ClientData_Touch(this.enemy);
1807
1808         msg_entity = this;
1809         WriteByte(MSG_ONE, SVC_SETVIEW);
1810         WriteEntity(MSG_ONE, this.enemy);
1811         set_movetype(this, MOVETYPE_NONE);
1812         accuracy_resend(this);
1813
1814         if(!SpectateUpdate(this))
1815                 PutObserverInServer(this, false, true);
1816
1817         return true;
1818 }
1819
1820 void SetSpectatee_status(entity this, int spectatee_num)
1821 {
1822         int oldspectatee_status = CS(this).spectatee_status;
1823         CS(this).spectatee_status = spectatee_num;
1824
1825         if (CS(this).spectatee_status != oldspectatee_status)
1826         {
1827                 if (STAT(PRESSED_KEYS, this))
1828                 {
1829                         CS(this).pressedkeys = 0;
1830                         STAT(PRESSED_KEYS, this) = 0;
1831                 }
1832                 ClientData_Touch(this);
1833                 if (g_race || g_cts) race_InitSpectator();
1834         }
1835 }
1836
1837 void SetSpectatee(entity this, entity spectatee)
1838 {
1839         if(IS_BOT_CLIENT(this))
1840                 return; // bots abuse .enemy, this code is useless to them
1841
1842         entity old_spectatee = this.enemy;
1843
1844         this.enemy = spectatee;
1845
1846         // WEAPONTODO
1847         // these are required to fix the spectator bug with arc
1848         if(old_spectatee)
1849         {
1850                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1851                 {
1852                         .entity weaponentity = weaponentities[slot];
1853                         if(old_spectatee.(weaponentity).arc_beam)
1854                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1855                 }
1856         }
1857         if(spectatee)
1858         {
1859                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1860                 {
1861                         .entity weaponentity = weaponentities[slot];
1862                         if(spectatee.(weaponentity).arc_beam)
1863                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1864                 }
1865         }
1866
1867         if (spectatee)
1868                 SetSpectatee_status(this, etof(spectatee));
1869
1870         // needed to update spectator list
1871         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1872 }
1873
1874 bool Spectate(entity this, entity pl)
1875 {
1876         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1877                 return false;
1878         pl = M_ARGV(1, entity);
1879
1880         SetSpectatee(this, pl);
1881         return SpectateSet(this);
1882 }
1883
1884 bool SpectateNext(entity this)
1885 {
1886         entity ent = find(this.enemy, classname, STR_PLAYER);
1887
1888         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1889                 ent = M_ARGV(1, entity);
1890         else if (!ent)
1891                 ent = find(ent, classname, STR_PLAYER);
1892
1893         if(ent) { SetSpectatee(this, ent); }
1894
1895         return SpectateSet(this);
1896 }
1897
1898 bool SpectatePrev(entity this)
1899 {
1900         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1901         entity ent = findchain(classname, STR_PLAYER);
1902         if (!ent) // no player
1903                 return false;
1904
1905         entity first = ent;
1906         // skip players until current spectated player
1907         if(this.enemy)
1908         while(ent && ent != this.enemy)
1909                 ent = ent.chain;
1910
1911         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1912         {
1913                 case MUT_SPECPREV_FOUND:
1914                         ent = M_ARGV(1, entity);
1915                         break;
1916                 case MUT_SPECPREV_RETURN:
1917                         return true;
1918                 case MUT_SPECPREV_CONTINUE:
1919                 default:
1920                 {
1921                         if(ent.chain)
1922                                 ent = ent.chain;
1923                         else
1924                                 ent = first;
1925                         break;
1926                 }
1927         }
1928
1929         SetSpectatee(this, ent);
1930         return SpectateSet(this);
1931 }
1932
1933 /*
1934 =============
1935 ShowRespawnCountdown()
1936
1937 Update a respawn countdown display.
1938 =============
1939 */
1940 void ShowRespawnCountdown(entity this)
1941 {
1942         float number;
1943         if(!IS_DEAD(this)) // just respawned?
1944                 return;
1945         else
1946         {
1947                 number = ceil(this.respawn_time - time);
1948                 if(number <= 0)
1949                         return;
1950                 if(number <= this.respawn_countdown)
1951                 {
1952                         this.respawn_countdown = number - 1;
1953                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1954                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1955                 }
1956         }
1957 }
1958
1959 .bool team_selected;
1960 bool ShowTeamSelection(entity this)
1961 {
1962         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1963                 return false;
1964         stuffcmd(this, "menu_showteamselect\n");
1965         return true;
1966 }
1967 void Join(entity this)
1968 {
1969         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1970                 ReadyRestart(true);
1971
1972         TRANSMUTE(Player, this);
1973
1974         if(!this.team_selected)
1975         if(autocvar_g_campaign || autocvar_g_balance_teams)
1976                 TeamBalance_JoinBestTeam(this);
1977
1978         if(autocvar_g_campaign)
1979                 campaign_bots_may_start = true;
1980
1981         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1982
1983         PutClientInServer(this);
1984
1985         if(IS_PLAYER(this))
1986         if(teamplay && this.team != -1)
1987         {
1988         }
1989         else
1990                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1991         this.team_selected = false;
1992 }
1993
1994 int GetPlayerLimit()
1995 {
1996         if(g_duel)
1997                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1998         int player_limit = autocvar_g_maxplayers;
1999         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2000         player_limit = M_ARGV(0, int);
2001         return player_limit;
2002 }
2003
2004 /**
2005  * Determines whether the player is allowed to join. This depends on cvar
2006  * g_maxplayers, if it isn't used this function always return true, otherwise
2007  * it checks whether the number of currently playing players exceeds g_maxplayers.
2008  * @return int number of free slots for players, 0 if none
2009  */
2010 int nJoinAllowed(entity this, entity ignore)
2011 {
2012         if(!ignore)
2013         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2014         // so report 0 free slots if restricted
2015         {
2016                 if(autocvar_g_forced_team_otherwise == "spectate")
2017                         return 0;
2018                 if(autocvar_g_forced_team_otherwise == "spectator")
2019                         return 0;
2020         }
2021
2022         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2023                 return 0; // forced spectators can never join
2024
2025         // TODO simplify this
2026         int totalClients = 0;
2027         int currentlyPlaying = 0;
2028         FOREACH_CLIENT(true, {
2029                 if(it != ignore)
2030                         ++totalClients;
2031                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2032                         ++currentlyPlaying;
2033         });
2034
2035         int player_limit = GetPlayerLimit();
2036
2037         int free_slots = 0;
2038         if (!player_limit)
2039                 free_slots = maxclients - totalClients;
2040         else if(player_limit > 0 && currentlyPlaying < player_limit)
2041                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2042
2043         static float msg_time = 0;
2044         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2045         {
2046                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2047                 msg_time = time + 0.5;
2048         }
2049
2050         return free_slots;
2051 }
2052
2053 void PrintWelcomeMessage(entity this)
2054 {
2055         if(CS(this).motd_actived_time == 0)
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2059                                 CS(this).motd_actived_time = time;
2060                                 SendWelcomemessage(this, false);
2061                         }
2062                 } else {
2063                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2064                                 CS(this).motd_actived_time = time;
2065                                 SendWelcomemessage(this, true);
2066                         }
2067                 }
2068         }
2069         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2077                         }
2078                 } else {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 }
2086         }
2087         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2088         {
2089                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2090                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2091                 else if (CS(this).motd_actived_time == -2)
2092                 {
2093                         // instantly hide MOTD
2094                         CS(this).motd_actived_time = 0;
2095                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2096                 }
2097                 else if (IS_PLAYER(this) || IS_SPEC(this))
2098                 {
2099                         // FIXME occasionally for some reason MOTD never goes away
2100                         // delay MOTD removal a little bit in the hope it fixes this bug
2101                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2102                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2103                         else //if (CS(this).motd_actived_time < -2)
2104                                 CS(this).motd_actived_time++;
2105                 }
2106         }
2107 }
2108
2109 bool joinAllowed(entity this)
2110 {
2111         if (CS(this).version_mismatch) return false;
2112         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2113         if (!nJoinAllowed(this, this)) return false;
2114         if (teamplay && lockteams) return false;
2115         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2116         if (ShowTeamSelection(this)) return false;
2117         return true;
2118 }
2119
2120 .string shootfromfixedorigin;
2121 .bool dualwielding_prev;
2122 bool PlayerThink(entity this)
2123 {
2124         if (game_stopped || intermission_running) {
2125                 this.modelflags &= ~MF_ROCKET;
2126                 if(intermission_running)
2127                         IntermissionThink(this);
2128                 return false;
2129         }
2130
2131         if (timeout_status == TIMEOUT_ACTIVE) {
2132                 // don't allow the player to turn around while game is paused
2133                 // FIXME turn this into CSQC stuff
2134                 this.v_angle = this.lastV_angle;
2135                 this.angles = this.lastV_angle;
2136                 this.fixangle = true;
2137         }
2138
2139         if (frametime) player_powerups(this);
2140
2141         if (IS_DEAD(this)) {
2142                 if (this.personal && g_race_qualifying) {
2143                         if (time > this.respawn_time) {
2144                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2145                                 respawn(this);
2146                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2147                         }
2148                 } else {
2149                         if (frametime) player_anim(this);
2150
2151                         if (this.respawn_flags & RESPAWN_DENY)
2152                         {
2153                                 STAT(RESPAWN_TIME, this) = 0;
2154                                 return false;
2155                         }
2156
2157                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2158
2159                         switch(this.deadflag)
2160                         {
2161                                 case DEAD_DYING:
2162                                 {
2163                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2164                                                 this.deadflag = DEAD_RESPAWNING;
2165                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2166                                                 this.deadflag = DEAD_DEAD;
2167                                         break;
2168                                 }
2169                                 case DEAD_DEAD:
2170                                 {
2171                                         if (button_pressed)
2172                                                 this.deadflag = DEAD_RESPAWNABLE;
2173                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2174                                                 this.deadflag = DEAD_RESPAWNING;
2175                                         break;
2176                                 }
2177                                 case DEAD_RESPAWNABLE:
2178                                 {
2179                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2180                                                 this.deadflag = DEAD_RESPAWNING;
2181                                         break;
2182                                 }
2183                                 case DEAD_RESPAWNING:
2184                                 {
2185                                         if (time > this.respawn_time)
2186                                         {
2187                                                 this.respawn_time = time + 1; // only retry once a second
2188                                                 this.respawn_time_max = this.respawn_time;
2189                                                 respawn(this);
2190                                         }
2191                                         break;
2192                                 }
2193                         }
2194
2195                         ShowRespawnCountdown(this);
2196
2197                         if (this.respawn_flags & RESPAWN_SILENT)
2198                                 STAT(RESPAWN_TIME, this) = 0;
2199                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2200                         {
2201                                 if (time < this.respawn_time)
2202                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2203                                 else if (this.deadflag != DEAD_RESPAWNING)
2204                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2205                         }
2206                         else
2207                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2208                 }
2209
2210                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2211                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2212                         STAT(RESPAWN_TIME, this) *= -1;
2213
2214                 return false;
2215         }
2216
2217         FixPlayermodel(this);
2218
2219         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2220                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2221                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2222         }
2223
2224         // reset gun alignment when dual wielding status changes
2225         // to ensure guns are always aligned right and left
2226         bool dualwielding = W_DualWielding(this);
2227         if(this.dualwielding_prev != dualwielding)
2228         {
2229                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2230                 this.dualwielding_prev = dualwielding;
2231         }
2232
2233         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2234         //if(frametime)
2235         {
2236                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2237                 {
2238                         .entity weaponentity = weaponentities[slot];
2239                         if(WEP_CVAR(vortex, charge_always))
2240                                 W_Vortex_Charge(this, weaponentity, frametime);
2241                         W_WeaponFrame(this, weaponentity);
2242                 }
2243         }
2244
2245         if (frametime)
2246         {
2247                 // WEAPONTODO: Add a weapon request for this
2248                 // rot vortex charge to the charge limit
2249                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2250                 {
2251                         .entity weaponentity = weaponentities[slot];
2252                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2253                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2254                 }
2255
2256                 player_regen(this);
2257                 player_anim(this);
2258                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2259         }
2260
2261         monsters_setstatus(this);
2262
2263         return true;
2264 }
2265
2266 .bool would_spectate;
2267 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2268 void ObserverOrSpectatorThink(entity this)
2269 {
2270         bool is_spec = IS_SPEC(this);
2271         if ( CS(this).impulse )
2272         {
2273                 int r = MinigameImpulse(this, CS(this).impulse);
2274                 if (!is_spec || r)
2275                         CS(this).impulse = 0;
2276
2277                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2278                 {
2279                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2280                         CS(this).impulse = 0;
2281                         return;
2282                 }
2283         }
2284
2285         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2286         {
2287                 CS(this).autojoin_checked = true;
2288                 TRANSMUTE(Player, this);
2289                 PutClientInServer(this);
2290                 return;
2291         }
2292
2293         if (this.flags & FL_JUMPRELEASED) {
2294                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2295                         this.flags &= ~FL_JUMPRELEASED;
2296                         this.flags |= FL_SPAWNING;
2297                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2298                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         if(SpectateNext(this)) {
2301                                 TRANSMUTE(Spectator, this);
2302                         } else if (is_spec) {
2303                                 TRANSMUTE(Observer, this);
2304                                 PutClientInServer(this);
2305                         }
2306                         else
2307                                 this.would_spectate = false; // unable to spectate anyone
2308                         if (is_spec)
2309                                 CS(this).impulse = 0;
2310                 } else if (is_spec) {
2311                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2312                                 this.flags &= ~FL_JUMPRELEASED;
2313                                 if(SpectatePrev(this)) {
2314                                         TRANSMUTE(Spectator, this);
2315                                 } else {
2316                                         TRANSMUTE(Observer, this);
2317                                         PutClientInServer(this);
2318                                 }
2319                                 CS(this).impulse = 0;
2320                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2321                                 this.would_spectate = false;
2322                                 this.flags &= ~FL_JUMPRELEASED;
2323                                 TRANSMUTE(Observer, this);
2324                                 PutClientInServer(this);
2325                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2326                                 PutObserverInServer(this, false, true);
2327                                 this.would_spectate = true;
2328                         }
2329                 }
2330                 else {
2331                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2332                         if (PHYS_INPUT_BUTTON_USE(this))
2333                                 wouldclip = !wouldclip;
2334                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2335                         set_movetype(this, preferred_movetype);
2336                 }
2337         } else { // jump pressed
2338                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2339                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2340                         this.flags |= FL_JUMPRELEASED;
2341                         if(this.flags & FL_SPAWNING)
2342                         {
2343                                 this.flags &= ~FL_SPAWNING;
2344                                 if(joinAllowed(this))
2345                                         Join(this);
2346                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2347                                         CS(this).autojoin_checked = -1;
2348                                 return;
2349                         }
2350                 }
2351                 if(is_spec && !SpectateUpdate(this))
2352                         PutObserverInServer(this, false, true);
2353         }
2354         if (is_spec)
2355                 this.flags |= FL_CLIENT | FL_NOTARGET;
2356 }
2357
2358 void PlayerUseKey(entity this)
2359 {
2360         if (!IS_PLAYER(this))
2361                 return;
2362
2363         if(this.vehicle)
2364         {
2365                 if(!game_stopped)
2366                 {
2367                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2368                         return;
2369                 }
2370         }
2371         else if(autocvar_g_vehicles_enter)
2372         {
2373                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2374                 {
2375                         entity head, closest_target = NULL;
2376                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2377
2378                         while(head) // find the closest acceptable target to enter
2379                         {
2380                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2381                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2382                                 {
2383                                         if(closest_target)
2384                                         {
2385                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2386                                                 { closest_target = head; }
2387                                         }
2388                                         else { closest_target = head; }
2389                                 }
2390
2391                                 head = head.chain;
2392                         }
2393
2394                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2395                 }
2396         }
2397
2398         // a use key was pressed; call handlers
2399         MUTATOR_CALLHOOK(PlayerUseKey, this);
2400 }
2401
2402
2403 /*
2404 =============
2405 PlayerPreThink
2406
2407 Called every frame for each client before the physics are run
2408 =============
2409 */
2410 .float last_vehiclecheck;
2411 void PlayerPreThink (entity this)
2412 {
2413         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2414         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2415
2416         WarpZone_PlayerPhysics_FixVAngle(this);
2417
2418         if (frametime) {
2419                 // physics frames: update anticheat stuff
2420                 anticheat_prethink(this);
2421
2422                 // WORKAROUND: only use dropclient in server frames (frametime set).
2423                 // Never use it in cl_movement frames (frametime zero).
2424                 if (blockSpectators && IS_REAL_CLIENT(this)
2425                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2426                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2427                 {
2428                         if (dropclient_schedule(this))
2429                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2430                 }
2431         }
2432
2433         zoomstate_set = false;
2434
2435         // Check for nameless players
2436         if (this.netname == "" || this.netname != CS(this).netname_previous)
2437         {
2438                 bool assume_unchanged = (CS(this).netname_previous == "");
2439                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2440                 {
2441                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2442                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2443                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2444                         assume_unchanged = false;
2445                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2446                 }
2447                 if (isInvisibleString(this.netname))
2448                 {
2449                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2450                         sprint(this, "Warning: invisible names are not allowed.\n");
2451                         assume_unchanged = false;
2452                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2453                 }
2454                 if (!assume_unchanged && autocvar_sv_eventlog)
2455                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2456                 strcpy(CS(this).netname_previous, this.netname);
2457         }
2458
2459         // version nagging
2460         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2461         CS(this).version_nagtime = 0;
2462         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2463             // git client
2464         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2465             // git server
2466             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2467         } else {
2468             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2469             if (r < 0) { // old client
2470                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2471             } else if (r > 0) { // old server
2472                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2473             }
2474         }
2475     }
2476
2477         // GOD MODE info
2478         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2479         {
2480                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2481                 this.max_armorvalue = 0;
2482         }
2483
2484         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2485         {
2486                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2487                 {
2488                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2489                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2490                         if (this.iceblock)
2491                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2492
2493                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2494                                 Unfreeze(this, false);
2495                 }
2496                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2497                 {
2498                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2499                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2500
2501                         if (GetResource(this, RES_HEALTH) < 1)
2502                         {
2503                                 if (this.vehicle)
2504                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2505                                 if(this.event_damage)
2506                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2507                         }
2508                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2509                                 Unfreeze(this, false);
2510                 }
2511         }
2512
2513         MUTATOR_CALLHOOK(PlayerPreThink, this);
2514
2515         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2516         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2517         {
2518                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2519                 {
2520                         if(!it.owner)
2521                         {
2522                                 if(!it.team || SAME_TEAM(this, it))
2523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2524                                 else if(autocvar_g_vehicles_steal)
2525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2526                         }
2527                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2528                         {
2529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2530                         }
2531                 });
2532
2533                 this.last_vehiclecheck = time + 1;
2534         }
2535
2536         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2537                 PlayerUseKey(this);
2538         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2539
2540         if (IS_REAL_CLIENT(this))
2541                 PrintWelcomeMessage(this);
2542
2543         if (IS_PLAYER(this)) {
2544                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2545                         error("Client can't be spawned as player on connection!");
2546                 if(!PlayerThink(this))
2547                         return;
2548         }
2549         else if (game_stopped || intermission_running) {
2550                 if(intermission_running)
2551                         IntermissionThink(this);
2552                 return;
2553         }
2554         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2555         {
2556                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2557                 CS(this).autojoin_checked = 1;
2558                 // don't do this in ClientConnect
2559                 // many things can go wrong if a client is spawned as player on connection
2560                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2561                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2562                                 && (!teamplay || autocvar_g_balance_teams)))
2563                 {
2564                         if(joinAllowed(this))
2565                                 Join(this);
2566                         return;
2567                 }
2568         }
2569         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2570                 ObserverOrSpectatorThink(this);
2571         }
2572
2573         // WEAPONTODO: Add weapon request for this
2574         if (!zoomstate_set) {
2575                 bool wep_zoomed = false;
2576                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2577                 {
2578                         .entity weaponentity = weaponentities[slot];
2579                         Weapon thiswep = this.(weaponentity).m_weapon;
2580                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2581                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2582                 }
2583                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2584         }
2585
2586         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2587         {
2588                 CS(this).teamkill_soundtime = 0;
2589
2590                 entity e = CS(this).teamkill_soundsource;
2591                 entity oldpusher = e.pusher;
2592                 e.pusher = this;
2593                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2594                 e.pusher = oldpusher;
2595         }
2596
2597         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2598                 CS(this).taunt_soundtime = 0;
2599                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2600         }
2601
2602         target_voicescript_next(this);
2603 }
2604
2605 void DrownPlayer(entity this)
2606 {
2607         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2608                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2609         {
2610                 STAT(AIR_FINISHED, this) = 0;
2611                 return;
2612         }
2613
2614         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2615         {
2616                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2617                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2618                 STAT(AIR_FINISHED, this) = 0;
2619         }
2620         else
2621         {
2622                 if (!STAT(AIR_FINISHED, this))
2623                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2624                 if (STAT(AIR_FINISHED, this) < time)
2625                 {       // drown!
2626                         if (this.pain_finished < time)
2627                         {
2628                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2629                                 this.pain_finished = time + 0.5;
2630                         }
2631                 }
2632         }
2633 }
2634
2635 .bool move_qcphysics;
2636
2637 void Player_Physics(entity this)
2638 {
2639         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2640
2641         if(!this.move_qcphysics)
2642                 return;
2643
2644         if(!frametime && !CS(this).pm_frametime)
2645                 return;
2646
2647         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2648
2649         CS(this).pm_frametime = 0;
2650 }
2651
2652 /*
2653 =============
2654 PlayerPostThink
2655
2656 Called every frame for each client after the physics are run
2657 =============
2658 */
2659 void PlayerPostThink (entity this)
2660 {
2661         Player_Physics(this);
2662
2663         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2664         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2665         if (IS_REAL_CLIENT(this))
2666         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2667         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2668         {
2669                 int totalClients = 0;
2670                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2671                 {
2672                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2673                         if (server_is_dedicated)
2674                         {
2675                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2676                                 {
2677                                         ++totalClients;
2678                                 });
2679                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2680                                         totalClients = 0;
2681                         }
2682                 }
2683                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2684                 {
2685                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2686                         {
2687                                 ++totalClients;
2688                         });
2689                 }
2690
2691                 if ((totalClients < autocvar_sv_maxidle_minplayers) || IS_GAMETYPE(BR))
2692                 {
2693                         // idle kick disabled
2694                         CS(this).parm_idlesince = time;
2695                 }
2696                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2697                 {
2698                         if (CS(this).idlekick_lasttimeleft)
2699                         {
2700                                 CS(this).idlekick_lasttimeleft = 0;
2701                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2702                         }
2703                 }
2704                 else
2705                 {
2706                         float maxidle_time = autocvar_sv_maxidle;
2707                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2708                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2709                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2710                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2711                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2712                         {
2713                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2714                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2715                                 else
2716                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2717                         }
2718                         if (timeleft <= 0) {
2719                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2720                                 {
2721                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2722                                         PutObserverInServer(this, true, true);
2723                                 }
2724                                 else
2725                                 {
2726                                         if (dropclient_schedule(this))
2727                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2728                                 }
2729                                 return;
2730                         }
2731                         else if (timeleft <= countdown_time) {
2732                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2733                                         play2(this, SND(TALK2));
2734                                 CS(this).idlekick_lasttimeleft = timeleft;
2735                         }
2736                 }
2737         }
2738
2739         CheatFrame(this);
2740
2741         if (game_stopped)
2742         {
2743                 this.solid = SOLID_NOT;
2744                 this.takedamage = DAMAGE_NO;
2745                 set_movetype(this, MOVETYPE_NONE);
2746                 CS(this).teamkill_complain = 0;
2747                 CS(this).teamkill_soundtime = 0;
2748                 CS(this).teamkill_soundsource = NULL;
2749         }
2750
2751         if (IS_PLAYER(this)) {
2752                 if(this.death_time == time && IS_DEAD(this))
2753                 {
2754                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2755                         // once all the damage events of this frame have been processed with normal size
2756                         this.maxs.z = 5;
2757                         setsize(this, this.mins, this.maxs);
2758                 }
2759                 DrownPlayer(this);
2760                 UpdateChatBubble(this);
2761                 if (CS(this).impulse) ImpulseCommands(this);
2762                 GetPressedKeys(this);
2763                 if (game_stopped)
2764                 {
2765                         CSQCMODEL_AUTOUPDATE(this);
2766                         return;
2767                 }
2768         }
2769         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2770         {
2771                 CS(this).pressedkeys = 0;
2772                 STAT(PRESSED_KEYS, this) = 0;
2773         }
2774
2775         if (this.waypointsprite_attachedforcarrier) {
2776                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2777                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2778         }
2779
2780         CSQCMODEL_AUTOUPDATE(this);
2781 }
2782
2783 // hack to copy the button fields from the client entity to the Client State
2784 void PM_UpdateButtons(entity this, entity store)
2785 {
2786         if(this.impulse)
2787                 store.impulse = this.impulse;
2788         this.impulse = 0;
2789
2790         bool typing = this.buttonchat || this.button12;
2791
2792         store.button0 = (typing) ? 0 : this.button0;
2793         //button1?!
2794         store.button2 = (typing) ? 0 : this.button2;
2795         store.button3 = (typing) ? 0 : this.button3;
2796         store.button4 = this.button4;
2797         store.button5 = (typing) ? 0 : this.button5;
2798         store.button6 = this.button6;
2799         store.button7 = this.button7;
2800         store.button8 = this.button8;
2801         store.button9 = this.button9;
2802         store.button10 = this.button10;
2803         store.button11 = this.button11;
2804         store.button12 = this.button12;
2805         store.button13 = this.button13;
2806         store.button14 = this.button14;
2807         store.button15 = this.button15;
2808         store.button16 = this.button16;
2809         store.buttonuse = this.buttonuse;
2810         store.buttonchat = this.buttonchat;
2811
2812         store.cursor_active = this.cursor_active;
2813         store.cursor_screen = this.cursor_screen;
2814         store.cursor_trace_start = this.cursor_trace_start;
2815         store.cursor_trace_endpos = this.cursor_trace_endpos;
2816         store.cursor_trace_ent = this.cursor_trace_ent;
2817
2818         store.ping = this.ping;
2819         store.ping_packetloss = this.ping_packetloss;
2820         store.ping_movementloss = this.ping_movementloss;
2821
2822         store.v_angle = this.v_angle;
2823         store.movement = this.movement;
2824 }
2825
2826 NET_HANDLE(fpsreport, bool)
2827 {
2828         int fps = ReadShort();
2829         PlayerScore_Set(sender, SP_FPS, fps);
2830         return true;
2831 }