qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/effects/all.qh>
   4 #include <common/effects/qc/globalsound.qh>
   5 #include <common/ent_cs.qh>
   6 #include <common/gamemodes/_mod.qh>
   7 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
   8 #include <common/items/_mod.qh>
   9 #include <common/items/inventory.qh>
  10 #include <common/mapobjects/func/conveyor.qh>
  11 #include <common/mapobjects/func/ladder.qh>
  12 #include <common/mapobjects/subs.qh>
  13 #include <common/mapobjects/target/spawnpoint.qh>
  14 #include <common/mapobjects/teleporters.qh>
  15 #include <common/mapobjects/trigger/counter.qh>
  16 #include <common/mapobjects/trigger/secret.qh>
  17 #include <common/mapobjects/trigger/swamp.qh>
  18 #include <common/mapobjects/triggers.qh>
  19 #include <common/minigames/sv_minigames.qh>
  20 #include <common/monsters/sv_monsters.qh>
  21 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  22 #include <common/mutators/mutator/overkill/oknex.qh>
  23 #include <common/mutators/mutator/waypoints/all.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/physics/player.qh>
  27 #include <common/state.qh>
  28 #include <common/stats.qh>
  29 #include <common/vehicles/all.qh>
  30 #include <common/vehicles/sv_vehicles.qh>
  31 #include <common/weapons/_all.qh>
  32 #include <common/weapons/weapon/vortex.qh>
  33 #include <common/wepent.qh>
  34 #include <lib/warpzone/server.qh>
  35 #include <server/anticheat.qh>
  36 #include <server/antilag.qh>
  37 #include <server/bot/api.qh>
  38 #include <server/campaign.qh>
  39 #include <server/chat.qh>
  40 #include <server/cheats.qh>
  41 #include <server/clientkill.qh>
  42 #include <server/command/common.qh>
  43 #include <server/command/common.qh>
  44 #include <server/command/vote.qh>
  45 #include <server/compat/quake3.qh>
  46 #include <server/damage.qh>
  47 #include <server/gamelog.qh>
  48 #include <server/handicap.qh>
  49 #include <server/hook.qh>
  50 #include <server/impulse.qh>
  51 #include <server/intermission.qh>
  52 #include <server/ipban.qh>
  53 #include <server/main.qh>
  54 #include <server/mutators/_mod.qh>
  55 #include <server/player.qh>
  56 #include <server/portals.qh>
  57 #include <server/race.qh>
  58 #include <server/resources.qh>
  59 #include <server/scores_rules.qh>
  60 #include <server/spawnpoints.qh>
  61 #include <server/teamplay.qh>
  62 #include <server/weapons/common.qh>
  63 #include <server/weapons/hitplot.qh>
  64 #include <server/weapons/selection.qh>
  65 #include <server/weapons/weaponsystem.qh>
  66 #include <server/world.qh>
  67
  68 STATIC_METHOD(Client, Add, void(Client this, int _team))
  69 {
  70     ClientConnect(this);
  71     TRANSMUTE(Player, this);
  72     this.frame = 12; // 7
  73     this.team = _team;
  74     PutClientInServer(this);
  75 }
  76
  77 STATIC_METHOD(Client, Remove, void(Client this))
  78 {
  79     TRANSMUTE(Observer, this);
  80     PutClientInServer(this);
  81     ClientDisconnect(this);
  82 }
  83
  84 void send_CSQC_teamnagger() {
  85         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  86 }
  87
  88 int CountSpectators(entity player, entity to)
  89 {
  90         if(!player) { return 0; } // not sure how, but best to be safe
  91
  92         int spec_count = 0;
  93
  94         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  95         {
  96                 spec_count++;
  97         });
  98
  99         return spec_count;
 100 }
 101
 102 void WriteSpectators(entity player, entity to)
 103 {
 104         if(!player) { return; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 if(spec_count >= MAX_SPECTATORS)
 110                         break;
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112                 ++spec_count;
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResource(this, RES_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244         }
 245
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254                 msg_entity = this;
 255                 WriteByte(MSG_ONE, SVC_SETVIEW);
 256                 WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269
 270         RemoveGrapplingHooks(this);
 271         Portal_ClearAll(this);
 272         Unfreeze(this, false);
 273         SetSpectatee(this, NULL);
 274
 275         if (this.alivetime)
 276         {
 277                 if (!warmup_stage)
 278                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 279                 this.alivetime = 0;
 280         }
 281
 282         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 283
 284         WaypointSprite_PlayerDead(this);
 285
 286         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 287                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 288
 289         accuracy_resend(this);
 290
 291         CS(this).spectatortime = time;
 292         if(this.bot_attack)
 293                 IL_REMOVE(g_bot_targets, this);
 294         this.bot_attack = false;
 295         if(this.monster_attack)
 296                 IL_REMOVE(g_monster_targets, this);
 297         this.monster_attack = false;
 298         STAT(HUD, this) = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.effects = 0;
 312         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 313         this.pauserotarmor_finished = 0;
 314         this.pauserothealth_finished = 0;
 315         this.pauseregen_finished = 0;
 316         this.damageforcescale = 0;
 317         this.death_time = 0;
 318         this.respawn_flags = 0;
 319         this.respawn_time = 0;
 320         STAT(RESPAWN_TIME, this) = 0;
 321         this.alpha = 0;
 322         this.scale = 0;
 323         this.fade_time = 0;
 324         this.pain_finished = 0;
 325         STAT(STRENGTH_FINISHED, this) = 0;
 326         STAT(INVINCIBLE_FINISHED, this) = 0;
 327         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 328         STAT(AIR_FINISHED, this) = 0;
 329         //this.dphitcontentsmask = 0;
 330         this.dphitcontentsmask = DPCONTENTS_SOLID;
 331         if (autocvar_g_playerclip_collisions)
 332                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 333         this.pushltime = 0;
 334         this.istypefrag = 0;
 335         setthink(this, func_null);
 336         this.nextthink = 0;
 337         this.deadflag = DEAD_NO;
 338         UNSET_DUCKED(this);
 339         STAT(REVIVE_PROGRESS, this) = 0;
 340         this.revival_time = 0;
 341         this.draggable = drag_undraggable;
 342
 343         this.items = 0;
 344         STAT(WEAPONS, this) = '0 0 0';
 345         this.drawonlytoclient = this;
 346
 347         this.viewloc = NULL;
 348
 349         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 350
 351         this.weaponmodel = "";
 352         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 353         {
 354                 this.weaponentities[slot] = NULL;
 355         }
 356         this.exteriorweaponentity = NULL;
 357         CS(this).killcount = FRAGS_SPECTATOR;
 358         this.velocity = '0 0 0';
 359         this.avelocity = '0 0 0';
 360         this.punchangle = '0 0 0';
 361         this.punchvector = '0 0 0';
 362         this.oldvelocity = this.velocity;
 363         this.fire_endtime = -1;
 364         this.event_damage = func_null;
 365         this.event_heal = func_null;
 366
 367         for(int slot = 0; slot < MAX_AXH; ++slot)
 368         {
 369                 entity axh = this.(AuxiliaryXhair[slot]);
 370                 this.(AuxiliaryXhair[slot]) = NULL;
 371
 372                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 373                         delete(axh);
 374         }
 375
 376         if (mutator_returnvalue)
 377         {
 378                 // mutator prevents resetting teams+score
 379         }
 380         else
 381         {
 382                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 383                 this.frags = FRAGS_SPECTATOR;
 384         }
 385         if (CS(this).just_joined)
 386                 CS(this).just_joined = false;
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 TeamBalance_JoinBestTeam(this);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 552                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 553                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 554                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 555                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 556                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 557                 SetResource(this, RES_HEALTH, warmup_start_health);
 558                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 559                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 560         } else {
 561                 SetResource(this, RES_SHELLS, start_ammo_shells);
 562                 SetResource(this, RES_BULLETS, start_ammo_nails);
 563                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 564                 SetResource(this, RES_CELLS, start_ammo_cells);
 565                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 566                 SetResource(this, RES_FUEL, start_ammo_fuel);
 567                 SetResource(this, RES_HEALTH, start_health);
 568                 SetResource(this, RES_ARMOR, start_armorvalue);
 569                 STAT(WEAPONS, this) = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = autocvar_g_player_damageforcescale;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 604         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 605         this.fade_time = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618         {
 619                 this.v_angle = this.angles;
 620                 bot_aim_reset(this);
 621         }
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         STAT(STRENGTH_FINISHED, this) = 0;
 629         STAT(INVINCIBLE_FINISHED, this) = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 635         STAT(BUFFS, this) = 0;
 636         STAT(BUFF_TIME, this) = 0;
 637
 638         STAT(AIR_FINISHED, this) = 0;
 639         this.waterlevel = WATERLEVEL_NONE;
 640         this.watertype = CONTENT_EMPTY;
 641
 642         entity spawnevent = new_pure(spawnevent);
 643         spawnevent.owner = this;
 644         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 645
 646         // Cut off any still running player sounds.
 647         stopsound(this, CH_PLAYER_SINGLE);
 648
 649         this.model = "";
 650         FixPlayermodel(this);
 651         this.drawonlytoclient = NULL;
 652
 653         this.viewloc = NULL;
 654
 655         for(int slot = 0; slot < MAX_AXH; ++slot)
 656         {
 657                 entity axh = this.(AuxiliaryXhair[slot]);
 658                 this.(AuxiliaryXhair[slot]) = NULL;
 659
 660                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 661                         delete(axh);
 662         }
 663
 664         this.spawnpoint_targ = NULL;
 665
 666         UNSET_DUCKED(this);
 667         this.view_ofs = STAT(PL_VIEW_OFS, this);
 668         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 669         this.spawnorigin = spot.origin;
 670         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 671         // don't reset back to last position, even if new position is stuck in solid
 672         this.oldorigin = this.origin;
 673         if(this.conveyor)
 674                 IL_REMOVE(g_conveyed, this);
 675         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 676         if(this.swampslug)
 677                 IL_REMOVE(g_swamped, this);
 678         this.swampslug = NULL;
 679         this.swamp_interval = 0;
 680         if(this.ladder_entity)
 681                 IL_REMOVE(g_ladderents, this);
 682         this.ladder_entity = NULL;
 683         IL_EACH(g_counters, it.realowner == this,
 684         {
 685                 delete(it);
 686         });
 687         STAT(HUD, this) = HUD_NORMAL;
 688
 689         this.event_damage = PlayerDamage;
 690         this.event_heal = PlayerHeal;
 691
 692         this.draggable = func_null;
 693
 694         if(!this.bot_attack)
 695                 IL_PUSH(g_bot_targets, this);
 696         this.bot_attack = true;
 697         if(!this.monster_attack)
 698                 IL_PUSH(g_monster_targets, this);
 699         this.monster_attack = true;
 700         navigation_dynamicgoal_init(this, false);
 701
 702         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 703
 704         // player was spectator
 705         if (CS(this).killcount == FRAGS_SPECTATOR) {
 706                 PlayerScore_Clear(this);
 707                 CS(this).killcount = 0;
 708                 CS(this).startplaytime = time;
 709         }
 710
 711         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712         {
 713                 .entity weaponentity = weaponentities[slot];
 714                 CL_SpawnWeaponentity(this, weaponentity);
 715         }
 716         this.alpha = default_player_alpha;
 717         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 718         this.exteriorweaponentity.alpha = default_weapon_alpha;
 719
 720         this.speedrunning = false;
 721
 722         this.counter_cnt = 0;
 723         this.fragsfilter_cnt = 0;
 724
 725         target_voicescript_clear(this);
 726
 727         // reset fields the weapons may use
 728         FOREACH(Weapons, true, {
 729                 it.wr_resetplayer(it, this);
 730                         // reload all reloadable weapons
 731                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 732                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 733                         {
 734                                 .entity weaponentity = weaponentities[slot];
 735                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 736                         }
 737                 }
 738         });
 739
 740         {
 741                 string s = spot.target;
 742                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 743                         spot.target = string_null;
 744                 SUB_UseTargets(spot, this, NULL);
 745                 if(g_assault || g_race)
 746                         spot.target = s;
 747         }
 748
 749         Unfreeze(this, false);
 750
 751         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 752
 753         if (autocvar_spawn_debug)
 754         {
 755                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 756                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 757         }
 758
 759         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 760         {
 761                 .entity weaponentity = weaponentities[slot];
 762                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 763                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 764                 else
 765                         this.(weaponentity).m_switchweapon = WEP_Null;
 766                 this.(weaponentity).m_weapon = WEP_Null;
 767                 this.(weaponentity).weaponname = "";
 768                 this.(weaponentity).m_switchingweapon = WEP_Null;
 769                 this.(weaponentity).cnt = -1;
 770         }
 771
 772         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 773
 774         if (CS(this).impulse) ImpulseCommands(this);
 775
 776         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 777         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 778         {
 779                 .entity weaponentity = weaponentities[slot];
 780                 W_WeaponFrame(this, weaponentity);
 781         }
 782
 783         if (!warmup_stage && !this.alivetime)
 784                 this.alivetime = time;
 785
 786         antilag_clear(this, CS(this));
 787 }
 788
 789 /** Called when a client spawns in the server */
 790 void PutClientInServer(entity this)
 791 {
 792         if (IS_BOT_CLIENT(this)) {
 793                 TRANSMUTE(Player, this);
 794         } else if (IS_REAL_CLIENT(this)) {
 795                 msg_entity = this;
 796                 WriteByte(MSG_ONE, SVC_SETVIEW);
 797                 WriteEntity(MSG_ONE, this);
 798         }
 799         if (game_stopped)
 800                 TRANSMUTE(Observer, this);
 801
 802         SetSpectatee(this, NULL);
 803
 804         // reset player keys
 805         if(PS(this))
 806                 PS(this).itemkeys = 0;
 807
 808         MUTATOR_CALLHOOK(PutClientInServer, this);
 809
 810         if (IS_OBSERVER(this)) {
 811                 PutObserverInServer(this);
 812         } else if (IS_PLAYER(this)) {
 813                 PutPlayerInServer(this);
 814         }
 815 }
 816
 817 // TODO do we need all these fields, or should we stop autodetecting runtime
 818 // changes and just have a console command to update this?
 819 bool ClientInit_SendEntity(entity this, entity to, int sf)
 820 {
 821         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 822         return = true;
 823         msg_entity = to;
 824         // MSG_INIT replacement
 825         // TODO: make easier to use
 826         Registry_send_all();
 827         W_PROP_reload(MSG_ONE, to);
 828         ClientInit_misc(this);
 829         MUTATOR_CALLHOOK(Ent_Init);
 830 }
 831 void ClientInit_misc(entity this)
 832 {
 833         int channel = MSG_ONE;
 834         WriteHeader(channel, ENT_CLIENT_INIT);
 835         WriteByte(channel, g_nexball_meter_period * 32);
 836         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 837         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 838         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 839         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 840         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 841         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 842         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 843         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 844
 845         if(autocvar_sv_foginterval && world.fog != "")
 846                 WriteString(channel, world.fog);
 847         else
 848                 WriteString(channel, "");
 849         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 850         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 851         WriteByte(channel, serverflags);
 852         WriteCoord(channel, autocvar_g_trueaim_minrange);
 853 }
 854
 855 void ClientInit_CheckUpdate(entity this)
 856 {
 857         this.nextthink = time;
 858         if(this.count != autocvar_g_balance_armor_blockpercent)
 859         {
 860                 this.count = autocvar_g_balance_armor_blockpercent;
 861                 this.SendFlags |= 1;
 862         }
 863         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 864         {
 865                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 866                 this.SendFlags |= 1;
 867         }
 868 }
 869
 870 void ClientInit_Spawn()
 871 {
 872         entity e = new_pure(clientinit);
 873         setthink(e, ClientInit_CheckUpdate);
 874         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 875
 876         ClientInit_CheckUpdate(e);
 877 }
 878
 879 /*
 880 =============
 881 SetNewParms
 882 =============
 883 */
 884 void SetNewParms ()
 885 {
 886         // initialize parms for a new player
 887         parm1 = -(86400 * 366);
 888
 889         MUTATOR_CALLHOOK(SetNewParms);
 890 }
 891
 892 /*
 893 =============
 894 SetChangeParms
 895 =============
 896 */
 897 void SetChangeParms (entity this)
 898 {
 899         // save parms for level change
 900         parm1 = CS(this).parm_idlesince - time;
 901
 902         MUTATOR_CALLHOOK(SetChangeParms);
 903 }
 904
 905 /*
 906 =============
 907 DecodeLevelParms
 908 =============
 909 */
 910 void DecodeLevelParms(entity this)
 911 {
 912         // load parms
 913         CS(this).parm_idlesince = parm1;
 914         if (CS(this).parm_idlesince == -(86400 * 366))
 915                 CS(this).parm_idlesince = time;
 916
 917         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 918         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 919
 920         MUTATOR_CALLHOOK(DecodeLevelParms);
 921 }
 922
 923 void FixClientCvars(entity e)
 924 {
 925         // send prediction settings to the client
 926         stuffcmd(e, "\nin_bindmap 0 0\n");
 927         if(autocvar_g_antilag == 3) // client side hitscan
 928                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 929         if(autocvar_sv_gentle)
 930                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 931
 932         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 933         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 934
 935         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 936
 937         MUTATOR_CALLHOOK(FixClientCvars, e);
 938 }
 939
 940 bool findinlist_abbrev(string tofind, string list)
 941 {
 942         if(list == "" || tofind == "")
 943                 return false; // empty list or search, just return
 944
 945         // this function allows abbreviated strings!
 946         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 947         {
 948                 return true;
 949         });
 950
 951         return false;
 952 }
 953
 954 bool PlayerInIPList(entity p, string iplist)
 955 {
 956         // some safety checks (never allow local?)
 957         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 958                 return false;
 959
 960         return findinlist_abbrev(p.netaddress, iplist);
 961 }
 962
 963 bool PlayerInIDList(entity p, string idlist)
 964 {
 965         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 966         if(!p.crypto_idfp)
 967                 return false;
 968
 969         return findinlist_abbrev(p.crypto_idfp, idlist);
 970 }
 971
 972 bool PlayerInList(entity player, string list)
 973 {
 974         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 975 }
 976
 977 #ifdef DP_EXT_PRECONNECT
 978 /*
 979 =============
 980 ClientPreConnect
 981
 982 Called once (not at each match start) when a client begins a connection to the server
 983 =============
 984 */
 985 void ClientPreConnect(entity this)
 986 {
 987         if(autocvar_sv_eventlog)
 988         {
 989                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 990                         this.playerid,
 991                         etof(this),
 992                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 993                 ));
 994         }
 995 }
 996 #endif
 997
 998 string GetClientVersionMessage(entity this)
 999 {
1000         if (CS(this).version_mismatch) {
1001                 if(CS(this).version < autocvar_gameversion) {
1002                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1003                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1004                 } else {
1005                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1006                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1007                 }
1008         } else {
1009                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1010         }
1011 }
1012
1013 string getwelcomemessage(entity this)
1014 {
1015         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1016         string modifications = M_ARGV(0, string);
1017
1018         if(g_weaponarena)
1019         {
1020                 if(g_weaponarena_random)
1021                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1022                 else
1023                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1024         }
1025         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1026                 modifications = strcat(modifications, ", No start weapons");
1027         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1028                 modifications = strcat(modifications, ", Low gravity");
1029         if(g_weapon_stay && !g_cts)
1030                 modifications = strcat(modifications, ", Weapons stay");
1031         if(autocvar_g_jetpack)
1032                 modifications = strcat(modifications, ", Jet pack");
1033         if(autocvar_g_powerups == 0)
1034                 modifications = strcat(modifications, ", No powerups");
1035         if(autocvar_g_powerups > 0)
1036                 modifications = strcat(modifications, ", Powerups");
1037         modifications = substring(modifications, 2, strlen(modifications) - 2);
1038
1039         string versionmessage = GetClientVersionMessage(this);
1040         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1041
1042         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1043
1044         if(modifications != "")
1045                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1046
1047         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1048         {
1049                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1050                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1051         }
1052
1053         if (cache_mutatormsg != "") {
1054                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1055         }
1056
1057         string mutator_msg = "";
1058         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1059         mutator_msg = M_ARGV(0, string);
1060
1061         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1062
1063         string motd = autocvar_sv_motd;
1064         if (motd != "") {
1065                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1066         }
1067         return s;
1068 }
1069
1070 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1071
1072 /**
1073 =============
1074 ClientConnect
1075
1076 Called when a client connects to the server
1077 =============
1078 */
1079 void ClientConnect(entity this)
1080 {
1081         if (Ban_MaybeEnforceBanOnce(this)) return;
1082         assert(!IS_CLIENT(this), return);
1083         this.flags |= FL_CLIENT;
1084         assert(player_count >= 0, player_count = 0);
1085
1086         TRANSMUTE(Client, this);
1087         CS(this).version_nagtime = time + 10 + random() * 10;
1088
1089         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1090
1091         bot_clientconnect(this);
1092
1093         Player_DetermineForcedTeam(this);
1094
1095         TRANSMUTE(Observer, this);
1096
1097         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1098
1099         // always track bots, don't ask for cl_allow_uidtracking
1100         if (IS_BOT_CLIENT(this))
1101                 PlayerStats_GameReport_AddPlayer(this);
1102         else
1103                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1104
1105         if (autocvar_sv_eventlog)
1106                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1107
1108         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1109
1110         stuffcmd(this, clientstuff, "\n");
1111         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1112
1113         FixClientCvars(this);
1114
1115         // get version info from player
1116         stuffcmd(this, "cmd clientversion $gameversion\n");
1117
1118         // notify about available teams
1119         if (teamplay)
1120         {
1121                 entity balance = TeamBalance_CheckAllowedTeams(this);
1122                 int t = TeamBalance_GetAllowedTeams(balance);
1123                 TeamBalance_Destroy(balance);
1124                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1125         }
1126         else
1127         {
1128                 stuffcmd(this, "set _teams_available 0\n");
1129         }
1130
1131         bot_relinkplayerlist();
1132
1133         CS(this).spectatortime = time;
1134         if (blockSpectators)
1135         {
1136                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1137         }
1138
1139         CS(this).jointime = time;
1140
1141         if (IS_REAL_CLIENT(this))
1142         {
1143                 if (g_weaponarena_weapons == WEPSET(TUBA))
1144                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1145         }
1146
1147         if (!autocvar_sv_foginterval && world.fog != "")
1148                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1149
1150         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1151                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1152                         send_CSQC_teamnagger();
1153
1154         CSQCMODEL_AUTOINIT(this);
1155
1156         CS(this).model_randomizer = random();
1157
1158         if (IS_REAL_CLIENT(this))
1159                 sv_notice_join(this);
1160
1161         this.move_qcphysics = autocvar_sv_qcphysics;
1162
1163         // update physics stats (players can spawn before physics runs)
1164         Physics_UpdateStats(this);
1165
1166         IL_EACH(g_initforplayer, it.init_for_player, {
1167                 it.init_for_player(it, this);
1168         });
1169
1170         Handicap_Initialize(this);
1171
1172         MUTATOR_CALLHOOK(ClientConnect, this);
1173
1174         if (IS_REAL_CLIENT(this))
1175         {
1176                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1177                 {
1178                         CS(this).motd_actived_time = -1;
1179                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1180                 }
1181         }
1182 }
1183 /*
1184 =============
1185 ClientDisconnect
1186
1187 Called when a client disconnects from the server
1188 =============
1189 */
1190 .entity chatbubbleentity;
1191 void ClientDisconnect(entity this)
1192 {
1193         assert(IS_CLIENT(this), return);
1194
1195         PlayerStats_GameReport_FinalizePlayer(this);
1196         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1197         if (CS(this).active_minigame) part_minigame(this);
1198         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1199
1200         if (autocvar_sv_eventlog)
1201                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1202
1203         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1204
1205         if(IS_SPEC(this))
1206                 SetSpectatee(this, NULL);
1207
1208         MUTATOR_CALLHOOK(ClientDisconnect, this);
1209
1210         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1211         strfree(CS(this).weaponorder_byimpulse);
1212         ClientState_detach(this);
1213
1214         Portal_ClearAll(this);
1215
1216         Unfreeze(this, false);
1217
1218         RemoveGrapplingHooks(this);
1219
1220         // Here, everything has been done that requires this player to be a client.
1221
1222         this.flags &= ~FL_CLIENT;
1223
1224         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1225         if (this.killindicator) delete(this.killindicator);
1226
1227         IL_EACH(g_counters, it.realowner == this,
1228         {
1229                 delete(it);
1230         });
1231
1232         WaypointSprite_PlayerGone(this);
1233
1234         bot_relinkplayerlist();
1235
1236         strfree(this.clientstatus);
1237         if (this.personal) delete(this.personal);
1238
1239         this.playerid = 0;
1240         ReadyCount();
1241         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1242
1243         ONREMOVE(this);
1244 }
1245
1246 void ChatBubbleThink(entity this)
1247 {
1248         this.nextthink = time;
1249         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1250         {
1251                 if(this.owner) // but why can that ever be NULL?
1252                         this.owner.chatbubbleentity = NULL;
1253                 delete(this);
1254                 return;
1255         }
1256
1257         this.mdl = "";
1258
1259         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1260         {
1261                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1262                         this.mdl = "models/sprites/minigame_busy.iqm";
1263                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1264                         this.mdl = "models/misc/chatbubble.spr";
1265         }
1266
1267         if ( this.model != this.mdl )
1268                 _setmodel(this, this.mdl);
1269
1270 }
1271
1272 void UpdateChatBubble(entity this)
1273 {
1274         if (this.alpha < 0)
1275                 return;
1276         // spawn a chatbubble entity if needed
1277         if (!this.chatbubbleentity)
1278         {
1279                 this.chatbubbleentity = new(chatbubbleentity);
1280                 this.chatbubbleentity.owner = this;
1281                 this.chatbubbleentity.exteriormodeltoclient = this;
1282                 setthink(this.chatbubbleentity, ChatBubbleThink);
1283                 this.chatbubbleentity.nextthink = time;
1284                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1285                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1286                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1287                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1288                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1289                 //this.chatbubbleentity.model = "";
1290                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1291         }
1292 }
1293
1294 void calculate_player_respawn_time(entity this)
1295 {
1296         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1297                 return;
1298
1299         float gametype_setting_tmp;
1300         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1301         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1302         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1303         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1304         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1305         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1306
1307         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1308         if (teamplay)
1309         {
1310                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1311                         if(it.team == this.team)
1312                                 ++pcount;
1313                 });
1314                 if (sdelay_small_count == 0)
1315                         sdelay_small_count = 1;
1316                 if (sdelay_large_count == 0)
1317                         sdelay_large_count = 1;
1318         }
1319         else
1320         {
1321                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1322                         ++pcount;
1323                 });
1324                 if (sdelay_small_count == 0)
1325                 {
1326                         if (IS_INDEPENDENT_PLAYER(this))
1327                         {
1328                                 // Players play independently. No point in requiring enemies.
1329                                 sdelay_small_count = 1;
1330                         }
1331                         else
1332                         {
1333                                 // Players play AGAINST each other. Enemies required.
1334                                 sdelay_small_count = 2;
1335                         }
1336                 }
1337                 if (sdelay_large_count == 0)
1338                 {
1339                         if (IS_INDEPENDENT_PLAYER(this))
1340                         {
1341                                 // Players play independently. No point in requiring enemies.
1342                                 sdelay_large_count = 1;
1343                         }
1344                         else
1345                         {
1346                                 // Players play AGAINST each other. Enemies required.
1347                                 sdelay_large_count = 2;
1348                         }
1349                 }
1350         }
1351
1352         float sdelay;
1353
1354         if (pcount <= sdelay_small_count)
1355                 sdelay = sdelay_small;
1356         else if (pcount >= sdelay_large_count)
1357                 sdelay = sdelay_large;
1358         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1359                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1360
1361         if(waves)
1362                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1363         else
1364                 this.respawn_time = time + sdelay;
1365
1366         if(sdelay < sdelay_max)
1367                 this.respawn_time_max = time + sdelay_max;
1368         else
1369                 this.respawn_time_max = this.respawn_time;
1370
1371         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1372                 this.respawn_countdown = 10; // first number to count down from is 10
1373         else
1374                 this.respawn_countdown = -1; // do not count down
1375
1376         if(autocvar_g_forced_respawn)
1377                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1378 }
1379
1380 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1381 // added to the model skins
1382 /*void UpdateColorModHack()
1383 {
1384         float c;
1385         c = this.clientcolors & 15;
1386         // LordHavoc: only bothering to support white, green, red, yellow, blue
1387              if (!teamplay) this.colormod = '0 0 0';
1388         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1389         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1390         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1391         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1392         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1393         else this.colormod = '1 1 1';
1394 }*/
1395
1396 void respawn(entity this)
1397 {
1398         bool damagedbycontents_prev = this.damagedbycontents;
1399         if(this.alpha >= 0)
1400         {
1401                 if(autocvar_g_respawn_ghosts)
1402                 {
1403                         this.solid = SOLID_NOT;
1404                         this.takedamage = DAMAGE_NO;
1405                         this.damagedbycontents = false;
1406                         set_movetype(this, MOVETYPE_FLY);
1407                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1408                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1409                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1410                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1411                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1412                         if(autocvar_g_respawn_ghosts_time > 0)
1413                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1414                 }
1415                 else
1416                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1417         }
1418
1419         CopyBody(this, 1);
1420         this.damagedbycontents = damagedbycontents_prev;
1421
1422         this.effects |= EF_NODRAW; // prevent another CopyBody
1423         PutClientInServer(this);
1424 }
1425
1426 void play_countdown(entity this, float finished, Sound samp)
1427 {
1428         TC(Sound, samp);
1429         if(IS_REAL_CLIENT(this))
1430                 if(floor(finished - time - frametime) != floor(finished - time))
1431                         if(finished - time < 6)
1432                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1433 }
1434
1435 void player_powerups(entity this)
1436 {
1437         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1438                 this.modelflags |= MF_ROCKET;
1439         else
1440                 this.modelflags &= ~MF_ROCKET;
1441
1442         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1443
1444         if (IS_DEAD(this))
1445         {
1446                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1447                 {
1448                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1449                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1450                         this.items &= ~ITEM_Strength.m_itemid;
1451                         this.items &= ~ITEM_Shield.m_itemid;
1452                         this.items -= (this.items & IT_SUPERWEAPON);
1453                 }
1454         }
1455
1456         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1457                 return;
1458
1459         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1460         int items_prev = this.items;
1461
1462         Fire_ApplyDamage(this);
1463         Fire_ApplyEffect(this);
1464
1465         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1466         {
1467                 if (this.items & ITEM_Strength.m_itemid)
1468                 {
1469                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1470                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1471                         if (time > STAT(STRENGTH_FINISHED, this))
1472                         {
1473                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1474                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1476                         }
1477                 }
1478                 else
1479                 {
1480                         if (time < STAT(STRENGTH_FINISHED, this))
1481                         {
1482                                 this.items = this.items | ITEM_Strength.m_itemid;
1483                                 if(!g_cts)
1484                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1486                         }
1487                 }
1488                 if (this.items & ITEM_Shield.m_itemid)
1489                 {
1490                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1491                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1492                         if (time > STAT(INVINCIBLE_FINISHED, this))
1493                         {
1494                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1495                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1496                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1497                         }
1498                 }
1499                 else
1500                 {
1501                         if (time < STAT(INVINCIBLE_FINISHED, this))
1502                         {
1503                                 this.items = this.items | ITEM_Shield.m_itemid;
1504                                 if(!g_cts)
1505                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1506                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1507                         }
1508                 }
1509                 if (this.items & IT_SUPERWEAPON)
1510                 {
1511                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1512                         {
1513                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1514                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1515                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1516                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1517                         }
1518                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1519                         {
1520                                 // don't let them run out
1521                         }
1522                         else
1523                         {
1524                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1525                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1526                                 {
1527                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1528                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1529                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1530                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1531                                 }
1532                         }
1533                 }
1534                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1535                 {
1536                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1537                         {
1538                                 this.items = this.items | IT_SUPERWEAPON;
1539                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1540                                 {
1541                                         if(!g_cts)
1542                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1543                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1544                                 }
1545                         }
1546                         else
1547                         {
1548                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1549                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1550                         }
1551                 }
1552                 else
1553                 {
1554                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1555                 }
1556         }
1557
1558         if(autocvar_g_nodepthtestplayers)
1559                 this.effects = this.effects | EF_NODEPTHTEST;
1560
1561         if(autocvar_g_fullbrightplayers)
1562                 this.effects = this.effects | EF_FULLBRIGHT;
1563
1564         if (time >= game_starttime)
1565         if (time < this.spawnshieldtime)
1566                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1567
1568         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1569 }
1570
1571 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1572 {
1573         if(current > stable)
1574                 return current;
1575         else if(current > stable - 0.25) // when close enough, "snap"
1576                 return stable;
1577         else
1578                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1579 }
1580
1581 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1582 {
1583         if(current < stable)
1584                 return current;
1585         else if(current < stable + 0.25) // when close enough, "snap"
1586                 return stable;
1587         else
1588                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1589 }
1590
1591 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1592 {
1593         float old = GetResource(this, res);
1594         float current = old;
1595         if(current > rotstable)
1596         {
1597                 if(rotframetime > 0)
1598                 {
1599                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1600                         current = max(rotstable, current - rotlinear * rotframetime);
1601                 }
1602         }
1603         else if(current < regenstable)
1604         {
1605                 if(regenframetime > 0)
1606                 {
1607                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1608                         current = min(regenstable, current + regenlinear * regenframetime);
1609                 }
1610         }
1611
1612         float limit = GetResourceLimit(this, res) * limit_mod;
1613         if(current > limit)
1614                 current = limit;
1615
1616         if (current != old)
1617                 SetResource(this, res, current);
1618 }
1619
1620 void player_regen(entity this)
1621 {
1622         float max_mod, regen_mod, rot_mod, limit_mod;
1623         max_mod = regen_mod = rot_mod = limit_mod = 1;
1624
1625         float regen_health = autocvar_g_balance_health_regen;
1626         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1627         float regen_health_rot = autocvar_g_balance_health_rot;
1628         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1629         float regen_health_stable = autocvar_g_balance_health_regenstable;
1630         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1631         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1632                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1633         max_mod = M_ARGV(1, float);
1634         regen_mod = M_ARGV(2, float);
1635         rot_mod = M_ARGV(3, float);
1636         limit_mod = M_ARGV(4, float);
1637         regen_health = M_ARGV(5, float);
1638         regen_health_linear = M_ARGV(6, float);
1639         regen_health_rot = M_ARGV(7, float);
1640         regen_health_rotlinear = M_ARGV(8, float);
1641         regen_health_stable = M_ARGV(9, float);
1642         regen_health_rotstable = M_ARGV(10, float);
1643
1644         if(!mutator_returnvalue)
1645         if(!STAT(FROZEN, this))
1646         {
1647                 float maxa = autocvar_g_balance_armor_rotstable;
1648                 float mina = autocvar_g_balance_armor_regenstable;
1649
1650                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1651                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1652                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1653
1654                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1655                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1656                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1657         }
1658
1659         // if player rotted to death...  die!
1660         // check this outside above checks, as player may still be able to rot to death
1661         if(GetResource(this, RES_HEALTH) < 1)
1662         {
1663                 if(this.vehicle)
1664                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1665                 if(this.event_damage)
1666                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1667         }
1668
1669         if (!(this.items & IT_UNLIMITED_AMMO))
1670         {
1671                 float maxf = autocvar_g_balance_fuel_rotstable;
1672                 float minf = autocvar_g_balance_fuel_regenstable;
1673
1674                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1675                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1676                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1677         }
1678 }
1679
1680 bool zoomstate_set;
1681 void SetZoomState(entity this, float newzoom)
1682 {
1683         if(newzoom != CS(this).zoomstate)
1684         {
1685                 CS(this).zoomstate = newzoom;
1686                 ClientData_Touch(this);
1687         }
1688         zoomstate_set = true;
1689 }
1690
1691 void GetPressedKeys(entity this)
1692 {
1693         MUTATOR_CALLHOOK(GetPressedKeys, this);
1694         int keys = STAT(PRESSED_KEYS, this);
1695         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1696         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1697         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1698         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1699
1700         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1701         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1702         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1703         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1704         CS(this).pressedkeys = keys; // store for other users
1705
1706         STAT(PRESSED_KEYS, this) = keys;
1707 }
1708
1709 /*
1710 ======================
1711 spectate mode routines
1712 ======================
1713 */
1714
1715 void SpectateCopy(entity this, entity spectatee)
1716 {
1717         TC(Client, this); TC(Client, spectatee);
1718
1719         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1720         PS(this) = PS(spectatee);
1721         this.armortype = spectatee.armortype;
1722         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1723         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1724         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1725         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1726         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1727         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1728         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1729         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1730         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1731         CS(this).impulse = 0;
1732         this.disableclientprediction = 1; // no need to run prediction on a spectator
1733         this.items = spectatee.items;
1734         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1735         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1736         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1737         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1738         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1739         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1740         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1741         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1742         this.punchangle = spectatee.punchangle;
1743         this.view_ofs = spectatee.view_ofs;
1744         this.velocity = spectatee.velocity;
1745         this.dmg_take = spectatee.dmg_take;
1746         this.dmg_save = spectatee.dmg_save;
1747         this.dmg_inflictor = spectatee.dmg_inflictor;
1748         this.v_angle = spectatee.v_angle;
1749         this.angles = spectatee.v_angle;
1750         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1751         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1752         this.viewloc = spectatee.viewloc;
1753         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1754                 this.fixangle = true;
1755         setorigin(this, spectatee.origin);
1756         setsize(this, spectatee.mins, spectatee.maxs);
1757         SetZoomState(this, CS(spectatee).zoomstate);
1758
1759     anticheat_spectatecopy(this, spectatee);
1760         STAT(HUD, this) = STAT(HUD, spectatee);
1761         if(spectatee.vehicle)
1762     {
1763         this.angles = spectatee.v_angle;
1764
1765         //this.fixangle = false;
1766         //this.velocity = spectatee.vehicle.velocity;
1767         this.vehicle_health = spectatee.vehicle_health;
1768         this.vehicle_shield = spectatee.vehicle_shield;
1769         this.vehicle_energy = spectatee.vehicle_energy;
1770         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1771         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1772         this.vehicle_reload1 = spectatee.vehicle_reload1;
1773         this.vehicle_reload2 = spectatee.vehicle_reload2;
1774
1775         //msg_entity = this;
1776
1777        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1778             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1779            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1780            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1781
1782         //WriteByte (MSG_ONE, SVC_SETVIEW);
1783         //    WriteEntity(MSG_ONE, this);
1784         //makevectors(spectatee.v_angle);
1785         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1786     }
1787 }
1788
1789 bool SpectateUpdate(entity this)
1790 {
1791         if(!this.enemy)
1792                 return false;
1793
1794         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1795         {
1796                 SetSpectatee(this, NULL);
1797                 return false;
1798         }
1799
1800         SpectateCopy(this, this.enemy);
1801
1802         return true;
1803 }
1804
1805 bool SpectateSet(entity this)
1806 {
1807         if(!IS_PLAYER(this.enemy))
1808                 return false;
1809
1810         ClientData_Touch(this.enemy);
1811
1812         msg_entity = this;
1813         WriteByte(MSG_ONE, SVC_SETVIEW);
1814         WriteEntity(MSG_ONE, this.enemy);
1815         set_movetype(this, MOVETYPE_NONE);
1816         accuracy_resend(this);
1817
1818         if(!SpectateUpdate(this))
1819                 PutObserverInServer(this);
1820
1821         return true;
1822 }
1823
1824 void SetSpectatee_status(entity this, int spectatee_num)
1825 {
1826         int oldspectatee_status = CS(this).spectatee_status;
1827         CS(this).spectatee_status = spectatee_num;
1828
1829         if (CS(this).spectatee_status != oldspectatee_status)
1830         {
1831                 if (STAT(PRESSED_KEYS, this))
1832                 {
1833                         CS(this).pressedkeys = 0;
1834                         STAT(PRESSED_KEYS, this) = 0;
1835                 }
1836                 ClientData_Touch(this);
1837                 if (g_race || g_cts) race_InitSpectator();
1838         }
1839 }
1840
1841 void SetSpectatee(entity this, entity spectatee)
1842 {
1843         if(IS_BOT_CLIENT(this))
1844                 return; // bots abuse .enemy, this code is useless to them
1845
1846         entity old_spectatee = this.enemy;
1847
1848         this.enemy = spectatee;
1849
1850         // WEAPONTODO
1851         // these are required to fix the spectator bug with arc
1852         if(old_spectatee)
1853         {
1854                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1855                 {
1856                         .entity weaponentity = weaponentities[slot];
1857                         if(old_spectatee.(weaponentity).arc_beam)
1858                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1859                 }
1860         }
1861         if(this.enemy)
1862         {
1863                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1864                 {
1865                         .entity weaponentity = weaponentities[slot];
1866                         if(this.enemy.(weaponentity).arc_beam)
1867                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1868                 }
1869         }
1870
1871         if (this.enemy)
1872                 SetSpectatee_status(this, etof(this.enemy));
1873
1874         // needed to update spectator list
1875         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1876 }
1877
1878 bool Spectate(entity this, entity pl)
1879 {
1880         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1881                 return false;
1882         pl = M_ARGV(1, entity);
1883
1884         SetSpectatee(this, pl);
1885         return SpectateSet(this);
1886 }
1887
1888 bool SpectateNext(entity this)
1889 {
1890         entity ent = find(this.enemy, classname, STR_PLAYER);
1891
1892         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1893                 ent = M_ARGV(1, entity);
1894         else if (!ent)
1895                 ent = find(ent, classname, STR_PLAYER);
1896
1897         if(ent) { SetSpectatee(this, ent); }
1898
1899         return SpectateSet(this);
1900 }
1901
1902 bool SpectatePrev(entity this)
1903 {
1904         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1905         entity ent = findchain(classname, STR_PLAYER);
1906         if (!ent) // no player
1907                 return false;
1908
1909         entity first = ent;
1910         // skip players until current spectated player
1911         if(this.enemy)
1912         while(ent && ent != this.enemy)
1913                 ent = ent.chain;
1914
1915         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1916         {
1917                 case MUT_SPECPREV_FOUND:
1918                         ent = M_ARGV(1, entity);
1919                         break;
1920                 case MUT_SPECPREV_RETURN:
1921                         return true;
1922                 case MUT_SPECPREV_CONTINUE:
1923                 default:
1924                 {
1925                         if(ent.chain)
1926                                 ent = ent.chain;
1927                         else
1928                                 ent = first;
1929                         break;
1930                 }
1931         }
1932
1933         SetSpectatee(this, ent);
1934         return SpectateSet(this);
1935 }
1936
1937 /*
1938 =============
1939 ShowRespawnCountdown()
1940
1941 Update a respawn countdown display.
1942 =============
1943 */
1944 void ShowRespawnCountdown(entity this)
1945 {
1946         float number;
1947         if(!IS_DEAD(this)) // just respawned?
1948                 return;
1949         else
1950         {
1951                 number = ceil(this.respawn_time - time);
1952                 if(number <= 0)
1953                         return;
1954                 if(number <= this.respawn_countdown)
1955                 {
1956                         this.respawn_countdown = number - 1;
1957                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1958                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1959                 }
1960         }
1961 }
1962
1963 .bool team_selected;
1964 bool ShowTeamSelection(entity this)
1965 {
1966         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1967                 return false;
1968         stuffcmd(this, "menu_showteamselect\n");
1969         return true;
1970 }
1971 void Join(entity this)
1972 {
1973         TRANSMUTE(Player, this);
1974
1975         if(!this.team_selected)
1976         if(autocvar_g_campaign || autocvar_g_balance_teams)
1977                 TeamBalance_JoinBestTeam(this);
1978
1979         if(autocvar_g_campaign)
1980                 campaign_bots_may_start = true;
1981
1982         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1983
1984         PutClientInServer(this);
1985
1986         if(IS_PLAYER(this))
1987         if(teamplay && this.team != -1)
1988         {
1989         }
1990         else
1991                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1992         this.team_selected = false;
1993 }
1994
1995 int GetPlayerLimit()
1996 {
1997         if(g_duel)
1998                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1999         int player_limit = autocvar_g_maxplayers;
2000         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2001         player_limit = M_ARGV(0, int);
2002         return player_limit;
2003 }
2004
2005 /**
2006  * Determines whether the player is allowed to join. This depends on cvar
2007  * g_maxplayers, if it isn't used this function always return true, otherwise
2008  * it checks whether the number of currently playing players exceeds g_maxplayers.
2009  * @return int number of free slots for players, 0 if none
2010  */
2011 int nJoinAllowed(entity this, entity ignore)
2012 {
2013         if(!ignore)
2014         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2015         // so report 0 free slots if restricted
2016         {
2017                 if(autocvar_g_forced_team_otherwise == "spectate")
2018                         return 0;
2019                 if(autocvar_g_forced_team_otherwise == "spectator")
2020                         return 0;
2021         }
2022
2023         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2024                 return 0; // forced spectators can never join
2025
2026         // TODO simplify this
2027         int totalClients = 0;
2028         int currentlyPlaying = 0;
2029         FOREACH_CLIENT(true, {
2030                 if(it != ignore)
2031                         ++totalClients;
2032                 if(IS_REAL_CLIENT(it))
2033                 if(IS_PLAYER(it) || it.caplayer)
2034                         ++currentlyPlaying;
2035         });
2036
2037         int player_limit = GetPlayerLimit();
2038
2039         int free_slots = 0;
2040         if (!player_limit)
2041                 free_slots = maxclients - totalClients;
2042         else if(player_limit > 0 && currentlyPlaying < player_limit)
2043                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2044
2045         static float msg_time = 0;
2046         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2047         {
2048                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2049                 msg_time = time + 0.5;
2050         }
2051
2052         return free_slots;
2053 }
2054
2055 /**
2056  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2057  * g_maxplayers_spectator_blocktime seconds
2058  */
2059 void checkSpectatorBlock(entity this)
2060 {
2061         if(IS_SPEC(this) || IS_OBSERVER(this))
2062         if(!this.caplayer)
2063         if(IS_REAL_CLIENT(this))
2064         {
2065                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2066                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2067                         dropclient(this);
2068                 }
2069         }
2070 }
2071
2072 void PrintWelcomeMessage(entity this)
2073 {
2074         if(CS(this).motd_actived_time == 0)
2075         {
2076                 if (autocvar_g_campaign) {
2077                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2078                                 CS(this).motd_actived_time = time;
2079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2080                         }
2081                 } else {
2082                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2083                                 CS(this).motd_actived_time = time;
2084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2085                         }
2086                 }
2087         }
2088         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2089         {
2090                 if (autocvar_g_campaign) {
2091                         if (PHYS_INPUT_BUTTON_INFO(this))
2092                                 CS(this).motd_actived_time = time;
2093                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2094                                 CS(this).motd_actived_time = 0;
2095                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2096                         }
2097                 } else {
2098                         if (PHYS_INPUT_BUTTON_INFO(this))
2099                                 CS(this).motd_actived_time = time;
2100                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2101                                 CS(this).motd_actived_time = 0;
2102                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2103                         }
2104                 }
2105         }
2106         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2107         {
2108                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2109                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2110                 else if (CS(this).motd_actived_time == -2)
2111                 {
2112                         // instantly hide MOTD
2113                         CS(this).motd_actived_time = 0;
2114                         if (autocvar_g_campaign)
2115                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2116                         else
2117                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2118                 }
2119                 else if (IS_PLAYER(this) || IS_SPEC(this))
2120                 {
2121                         // FIXME occasionally for some reason MOTD never goes away
2122                         // delay MOTD removal a little bit in the hope it fixes this bug
2123                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2124                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2125                         else //if (CS(this).motd_actived_time < -2)
2126                                 CS(this).motd_actived_time++;
2127                 }
2128         }
2129 }
2130
2131 bool joinAllowed(entity this)
2132 {
2133         if (CS(this).version_mismatch) return false;
2134         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2135         if (!nJoinAllowed(this, this)) return false;
2136         if (teamplay && lockteams) return false;
2137         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2138         if (ShowTeamSelection(this)) return false;
2139         return true;
2140 }
2141
2142 .string shootfromfixedorigin;
2143 .bool dualwielding_prev;
2144 bool PlayerThink(entity this)
2145 {
2146         if (game_stopped || intermission_running) {
2147                 this.modelflags &= ~MF_ROCKET;
2148                 if(intermission_running)
2149                         IntermissionThink(this);
2150                 return false;
2151         }
2152
2153         if (timeout_status == TIMEOUT_ACTIVE) {
2154                 // don't allow the player to turn around while game is paused
2155                 // FIXME turn this into CSQC stuff
2156                 this.v_angle = this.lastV_angle;
2157                 this.angles = this.lastV_angle;
2158                 this.fixangle = true;
2159         }
2160
2161         if (frametime) player_powerups(this);
2162
2163         if (IS_DEAD(this)) {
2164                 if (this.personal && g_race_qualifying) {
2165                         if (time > this.respawn_time) {
2166                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2167                                 respawn(this);
2168                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2169                         }
2170                 } else {
2171                         if (frametime) player_anim(this);
2172
2173                         if (this.respawn_flags & RESPAWN_DENY)
2174                         {
2175                                 STAT(RESPAWN_TIME, this) = 0;
2176                                 return false;
2177                         }
2178
2179                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2180
2181                         switch(this.deadflag)
2182                         {
2183                                 case DEAD_DYING:
2184                                 {
2185                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2186                                                 this.deadflag = DEAD_RESPAWNING;
2187                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2188                                                 this.deadflag = DEAD_DEAD;
2189                                         break;
2190                                 }
2191                                 case DEAD_DEAD:
2192                                 {
2193                                         if (button_pressed)
2194                                                 this.deadflag = DEAD_RESPAWNABLE;
2195                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2196                                                 this.deadflag = DEAD_RESPAWNING;
2197                                         break;
2198                                 }
2199                                 case DEAD_RESPAWNABLE:
2200                                 {
2201                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2202                                                 this.deadflag = DEAD_RESPAWNING;
2203                                         break;
2204                                 }
2205                                 case DEAD_RESPAWNING:
2206                                 {
2207                                         if (time > this.respawn_time)
2208                                         {
2209                                                 this.respawn_time = time + 1; // only retry once a second
2210                                                 this.respawn_time_max = this.respawn_time;
2211                                                 respawn(this);
2212                                         }
2213                                         break;
2214                                 }
2215                         }
2216
2217                         ShowRespawnCountdown(this);
2218
2219                         if (this.respawn_flags & RESPAWN_SILENT)
2220                                 STAT(RESPAWN_TIME, this) = 0;
2221                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2222                         {
2223                                 if (time < this.respawn_time)
2224                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2225                                 else if (this.deadflag != DEAD_RESPAWNING)
2226                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2227                         }
2228                         else
2229                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2230                 }
2231
2232                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2233                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2234                         STAT(RESPAWN_TIME, this) *= -1;
2235
2236                 return false;
2237         }
2238
2239         FixPlayermodel(this);
2240
2241         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2242                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2243                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2244         }
2245
2246         // reset gun alignment when dual wielding status changes
2247         // to ensure guns are always aligned right and left
2248         bool dualwielding = W_DualWielding(this);
2249         if(this.dualwielding_prev != dualwielding)
2250         {
2251                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2252                 this.dualwielding_prev = dualwielding;
2253         }
2254
2255         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2256         //if(frametime)
2257         {
2258                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2259                 {
2260                         .entity weaponentity = weaponentities[slot];
2261                         if(WEP_CVAR(vortex, charge_always))
2262                                 W_Vortex_Charge(this, weaponentity, frametime);
2263                         W_WeaponFrame(this, weaponentity);
2264                 }
2265         }
2266
2267         if (frametime)
2268         {
2269                 // WEAPONTODO: Add a weapon request for this
2270                 // rot vortex charge to the charge limit
2271                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2272                 {
2273                         .entity weaponentity = weaponentities[slot];
2274                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2275                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2276                 }
2277
2278                 player_regen(this);
2279                 player_anim(this);
2280                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2281         }
2282
2283         monsters_setstatus(this);
2284
2285         return true;
2286 }
2287
2288 .bool would_spectate;
2289 void ObserverOrSpectatorThink(entity this)
2290 {
2291         bool is_spec = IS_SPEC(this);
2292         if ( CS(this).impulse )
2293         {
2294                 int r = MinigameImpulse(this, CS(this).impulse);
2295                 if (!is_spec || r)
2296                         CS(this).impulse = 0;
2297
2298                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2299                 {
2300                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2301                         CS(this).impulse = 0;
2302                         return;
2303                 }
2304         }
2305
2306         if (this.flags & FL_JUMPRELEASED) {
2307                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2308                         this.flags &= ~FL_JUMPRELEASED;
2309                         this.flags |= FL_SPAWNING;
2310                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2311                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2312                         this.flags &= ~FL_JUMPRELEASED;
2313                         if(SpectateNext(this)) {
2314                                 TRANSMUTE(Spectator, this);
2315                         } else if (is_spec) {
2316                                 TRANSMUTE(Observer, this);
2317                                 PutClientInServer(this);
2318                         }
2319                         if (is_spec)
2320                                 CS(this).impulse = 0;
2321                 } else if (is_spec) {
2322                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2323                                 this.flags &= ~FL_JUMPRELEASED;
2324                                 if(SpectatePrev(this)) {
2325                                         TRANSMUTE(Spectator, this);
2326                                 } else {
2327                                         TRANSMUTE(Observer, this);
2328                                         PutClientInServer(this);
2329                                 }
2330                                 CS(this).impulse = 0;
2331                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2332                                 this.would_spectate = false;
2333                                 this.flags &= ~FL_JUMPRELEASED;
2334                                 TRANSMUTE(Observer, this);
2335                                 PutClientInServer(this);
2336                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2337                                 PutObserverInServer(this);
2338                                 this.would_spectate = true;
2339                         }
2340                 }
2341                 else {
2342                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2343                         set_movetype(this, preferred_movetype);
2344                 }
2345         } else {
2346                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2347                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2348                         this.flags |= FL_JUMPRELEASED;
2349                         if(this.flags & FL_SPAWNING)
2350                         {
2351                                 this.flags &= ~FL_SPAWNING;
2352                                 if(joinAllowed(this))
2353                                         Join(this);
2354                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2355                                         CS(this).autojoin_checked = -1;
2356                                 return;
2357                         }
2358                 }
2359                 if(is_spec && !SpectateUpdate(this))
2360                         PutObserverInServer(this);
2361         }
2362         if (is_spec)
2363                 this.flags |= FL_CLIENT | FL_NOTARGET;
2364 }
2365
2366 void PlayerUseKey(entity this)
2367 {
2368         if (!IS_PLAYER(this))
2369                 return;
2370
2371         if(this.vehicle)
2372         {
2373                 if(!game_stopped)
2374                 {
2375                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2376                         return;
2377                 }
2378         }
2379         else if(autocvar_g_vehicles_enter)
2380         {
2381                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2382                 {
2383                         entity head, closest_target = NULL;
2384                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2385
2386                         while(head) // find the closest acceptable target to enter
2387                         {
2388                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2389                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2390                                 {
2391                                         if(closest_target)
2392                                         {
2393                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2394                                                 { closest_target = head; }
2395                                         }
2396                                         else { closest_target = head; }
2397                                 }
2398
2399                                 head = head.chain;
2400                         }
2401
2402                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2403                 }
2404         }
2405
2406         // a use key was pressed; call handlers
2407         MUTATOR_CALLHOOK(PlayerUseKey, this);
2408 }
2409
2410
2411 /*
2412 =============
2413 PlayerPreThink
2414
2415 Called every frame for each client before the physics are run
2416 =============
2417 */
2418 .float last_vehiclecheck;
2419 void PlayerPreThink (entity this)
2420 {
2421         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2422         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2423
2424         WarpZone_PlayerPhysics_FixVAngle(this);
2425
2426         if (frametime) {
2427                 // physics frames: update anticheat stuff
2428                 anticheat_prethink(this);
2429         }
2430
2431         if (blockSpectators && frametime) {
2432                 // WORKAROUND: only use dropclient in server frames (frametime set).
2433                 // Never use it in cl_movement frames (frametime zero).
2434                 checkSpectatorBlock(this);
2435         }
2436
2437         zoomstate_set = false;
2438
2439         // Check for nameless players
2440         if (this.netname == "" || this.netname != CS(this).netname_previous)
2441         {
2442                 bool assume_unchanged = (CS(this).netname_previous == "");
2443                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2444                 {
2445                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2446                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2447                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2448                         assume_unchanged = false;
2449                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2450                 }
2451                 if (isInvisibleString(this.netname))
2452                 {
2453                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2454                         sprint(this, "Warning: invisible names are not allowed.\n");
2455                         assume_unchanged = false;
2456                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2457                 }
2458                 if (!assume_unchanged && autocvar_sv_eventlog)
2459                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2460                 strcpy(CS(this).netname_previous, this.netname);
2461         }
2462
2463         // version nagging
2464         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2465         CS(this).version_nagtime = 0;
2466         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2467             // git client
2468         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2469             // git server
2470             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2471         } else {
2472             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2473             if (r < 0) { // old client
2474                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2475             } else if (r > 0) { // old server
2476                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2477             }
2478         }
2479     }
2480
2481         // GOD MODE info
2482         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2483         {
2484                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2485                 this.max_armorvalue = 0;
2486         }
2487
2488         if (frametime && IS_PLAYER(this))
2489         {
2490                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2491                 {
2492                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2493                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2494                         if (this.iceblock)
2495                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2496
2497                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2498                                 Unfreeze(this, false);
2499                 }
2500                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2501                 {
2502                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2503                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2504
2505                         if (GetResource(this, RES_HEALTH) < 1)
2506                         {
2507                                 if (this.vehicle)
2508                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2509                                 if(this.event_damage)
2510                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2511                         }
2512                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2513                                 Unfreeze(this, false);
2514                 }
2515         }
2516
2517         MUTATOR_CALLHOOK(PlayerPreThink, this);
2518
2519         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2520         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2521         {
2522                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2523                 {
2524                         if(!it.owner)
2525                         {
2526                                 if(!it.team || SAME_TEAM(this, it))
2527                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2528                                 else if(autocvar_g_vehicles_steal)
2529                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2530                         }
2531                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2532                         {
2533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2534                         }
2535                 });
2536
2537                 this.last_vehiclecheck = time + 1;
2538         }
2539
2540         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2541         {
2542                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2543                         PlayerUseKey(this);
2544                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2545         }
2546
2547         if (IS_REAL_CLIENT(this))
2548                 PrintWelcomeMessage(this);
2549
2550         if (IS_PLAYER(this)) {
2551                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2552                         error("Client can't be spawned as player on connection!");
2553                 if(!PlayerThink(this))
2554                         return;
2555         }
2556         else if (game_stopped || intermission_running) {
2557                 if(intermission_running)
2558                         IntermissionThink(this);
2559                 return;
2560         }
2561         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2562         {
2563                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2564                 CS(this).autojoin_checked = 1;
2565                 // don't do this in ClientConnect
2566                 // many things can go wrong if a client is spawned as player on connection
2567                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2568                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2569                                 && (!teamplay || autocvar_g_balance_teams)))
2570                 {
2571                         campaign_bots_may_start = true;
2572                         if(joinAllowed(this))
2573                                 Join(this);
2574                         return;
2575                 }
2576         }
2577         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2578                 ObserverOrSpectatorThink(this);
2579         }
2580
2581         // WEAPONTODO: Add weapon request for this
2582         if (!zoomstate_set) {
2583                 bool wep_zoomed = false;
2584                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2585                 {
2586                         .entity weaponentity = weaponentities[slot];
2587                         Weapon thiswep = this.(weaponentity).m_weapon;
2588                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2589                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2590                 }
2591                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2592         }
2593
2594         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2595         {
2596                 CS(this).teamkill_soundtime = 0;
2597
2598                 entity e = CS(this).teamkill_soundsource;
2599                 entity oldpusher = e.pusher;
2600                 e.pusher = this;
2601                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2602                 e.pusher = oldpusher;
2603         }
2604
2605         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2606                 CS(this).taunt_soundtime = 0;
2607                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2608         }
2609
2610         target_voicescript_next(this);
2611
2612         // WEAPONTODO: Move into weaponsystem somehow
2613         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2614         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2615         {
2616                 .entity weaponentity = weaponentities[slot];
2617                 if(this.(weaponentity).m_weapon == WEP_Null)
2618                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2619         }
2620 }
2621
2622 void DrownPlayer(entity this)
2623 {
2624         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2625                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2626         {
2627                 STAT(AIR_FINISHED, this) = 0;
2628                 return;
2629         }
2630
2631         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2632         {
2633                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2634                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2635                 STAT(AIR_FINISHED, this) = 0;
2636         }
2637         else
2638         {
2639                 if (!STAT(AIR_FINISHED, this))
2640                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2641                 if (STAT(AIR_FINISHED, this) < time)
2642                 {       // drown!
2643                         if (this.pain_finished < time)
2644                         {
2645                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2646                                 this.pain_finished = time + 0.5;
2647                         }
2648                 }
2649         }
2650 }
2651
2652 .bool move_qcphysics;
2653
2654 void Player_Physics(entity this)
2655 {
2656         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2657
2658         if(!this.move_qcphysics)
2659                 return;
2660
2661         if(!frametime && !CS(this).pm_frametime)
2662                 return;
2663
2664         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2665
2666         CS(this).pm_frametime = 0;
2667 }
2668
2669 /*
2670 =============
2671 PlayerPostThink
2672
2673 Called every frame for each client after the physics are run
2674 =============
2675 */
2676 void PlayerPostThink (entity this)
2677 {
2678         Player_Physics(this);
2679
2680         if (autocvar_sv_maxidle > 0)
2681         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2682         if (IS_REAL_CLIENT(this))
2683         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2684         {
2685                 int totalClients = 0;
2686                 if(autocvar_sv_maxidle_slots > 0)
2687                 {
2688                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2689                         {
2690                                 ++totalClients;
2691                         });
2692                 }
2693
2694                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2695                 { /* do nothing */ }
2696                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2697                 {
2698                         if (CS(this).idlekick_lasttimeleft)
2699                         {
2700                                 CS(this).idlekick_lasttimeleft = 0;
2701                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2702                         }
2703                 }
2704                 else
2705                 {
2706                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2707                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2708                                 if (!CS(this).idlekick_lasttimeleft)
2709                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2710                         }
2711                         if (timeleft <= 0) {
2712                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2713                                 dropclient(this);
2714                                 return;
2715                         }
2716                         else if (timeleft <= 10) {
2717                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2718                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2719                                 CS(this).idlekick_lasttimeleft = timeleft;
2720                         }
2721                 }
2722         }
2723
2724         CheatFrame(this);
2725
2726         if (game_stopped)
2727         {
2728                 this.solid = SOLID_NOT;
2729                 this.takedamage = DAMAGE_NO;
2730                 set_movetype(this, MOVETYPE_NONE);
2731                 CS(this).teamkill_complain = 0;
2732                 CS(this).teamkill_soundtime = 0;
2733                 CS(this).teamkill_soundsource = NULL;
2734         }
2735
2736         if (IS_PLAYER(this)) {
2737                 if(this.death_time == time && IS_DEAD(this))
2738                 {
2739                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2740                         // once all the damage events of this frame have been processed with normal size
2741                         this.maxs.z = 5;
2742                         setsize(this, this.mins, this.maxs);
2743                 }
2744                 DrownPlayer(this);
2745                 UpdateChatBubble(this);
2746                 if (CS(this).impulse) ImpulseCommands(this);
2747                 if (game_stopped)
2748                 {
2749                         CSQCMODEL_AUTOUPDATE(this);
2750                         return;
2751                 }
2752                 GetPressedKeys(this);
2753         }
2754         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2755         {
2756                 CS(this).pressedkeys = 0;
2757                 STAT(PRESSED_KEYS, this) = 0;
2758         }
2759
2760         if (this.waypointsprite_attachedforcarrier) {
2761                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2762                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2763         }
2764
2765         CSQCMODEL_AUTOUPDATE(this);
2766 }
2767
2768 // hack to copy the button fields from the client entity to the Client State
2769 void PM_UpdateButtons(entity this, entity store)
2770 {
2771         if(this.impulse)
2772                 store.impulse = this.impulse;
2773         this.impulse = 0;
2774
2775         bool typing = this.buttonchat || this.button12;
2776
2777         store.button0 = (typing) ? 0 : this.button0;
2778         //button1?!
2779         store.button2 = (typing) ? 0 : this.button2;
2780         store.button3 = (typing) ? 0 : this.button3;
2781         store.button4 = this.button4;
2782         store.button5 = (typing) ? 0 : this.button5;
2783         store.button6 = this.button6;
2784         store.button7 = this.button7;
2785         store.button8 = this.button8;
2786         store.button9 = this.button9;
2787         store.button10 = this.button10;
2788         store.button11 = this.button11;
2789         store.button12 = this.button12;
2790         store.button13 = this.button13;
2791         store.button14 = this.button14;
2792         store.button15 = this.button15;
2793         store.button16 = this.button16;
2794         store.buttonuse = this.buttonuse;
2795         store.buttonchat = this.buttonchat;
2796
2797         store.cursor_active = this.cursor_active;
2798         store.cursor_screen = this.cursor_screen;
2799         store.cursor_trace_start = this.cursor_trace_start;
2800         store.cursor_trace_endpos = this.cursor_trace_endpos;
2801         store.cursor_trace_ent = this.cursor_trace_ent;
2802
2803         store.ping = this.ping;
2804         store.ping_packetloss = this.ping_packetloss;
2805         store.ping_movementloss = this.ping_movementloss;
2806
2807         store.v_angle = this.v_angle;
2808         store.movement = this.movement;
2809 }
2810
2811 NET_HANDLE(fpsreport, bool)
2812 {
2813         int fps = ReadShort();
2814         PlayerScore_Set(sender, SP_FPS, fps);
2815         return true;
2816 }