qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/lms/sv_lms.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/resources.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 void send_TeamNames(int channel, entity to) {
 103         msg_entity = to;
 104
 105         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 106         WriteString(channel, autocvar_g_teamnames_red);
 107         WriteString(channel, autocvar_g_teamnames_blue);
 108         WriteString(channel, autocvar_g_teamnames_yellow);
 109         WriteString(channel, autocvar_g_teamnames_pink);
 110 }
 111
 112 int CountSpectators(entity player, entity to)
 113 {
 114         if(!player) { return 0; } // not sure how, but best to be safe
 115
 116         int spec_count = 0;
 117
 118         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 119         {
 120                 spec_count++;
 121         });
 122
 123         return spec_count;
 124 }
 125
 126 void WriteSpectators(entity player, entity to)
 127 {
 128         if(!player) { return; } // not sure how, but best to be safe
 129
 130         int spec_count = 0;
 131         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 132         {
 133                 if(spec_count >= MAX_SPECTATORS)
 134                         break;
 135                 WriteByte(MSG_ENTITY, num_for_edict(it));
 136                 ++spec_count;
 137         });
 138 }
 139
 140 bool ClientData_Send(entity this, entity to, int sf)
 141 {
 142         assert(to == this.owner, return false);
 143
 144         entity e = to;
 145         if (IS_SPEC(e)) e = e.enemy;
 146
 147         sf = 0;
 148         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 149         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 150         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 151         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 152
 153         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 154         WriteByte(MSG_ENTITY, sf);
 155
 156         if (sf & BIT(1))
 157                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 158
 159         if(sf & BIT(4))
 160         {
 161                 float specs = CountSpectators(e, to);
 162                 WriteByte(MSG_ENTITY, specs);
 163                 WriteSpectators(e, to);
 164         }
 165
 166         return true;
 167 }
 168
 169 void ClientData_Attach(entity this)
 170 {
 171         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 172         CS(this).clientdata.drawonlytoclient = this;
 173         CS(this).clientdata.owner = this;
 174 }
 175
 176 void ClientData_Detach(entity this)
 177 {
 178         delete(CS(this).clientdata);
 179         CS(this).clientdata = NULL;
 180 }
 181
 182 void ClientData_Touch(entity e)
 183 {
 184         entity cd = CS(e).clientdata;
 185         if (cd) { cd.SendFlags = 1; }
 186
 187         // make it spectatable
 188         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 189         {
 190                 entity cd = CS(it).clientdata;
 191                 if (cd) { cd.SendFlags = 1; }
 192         });
 193 }
 194
 195
 196 /*
 197 =============
 198 CheckPlayerModel
 199
 200 Checks if the argument string can be a valid playermodel.
 201 Returns a valid one in doubt.
 202 =============
 203 */
 204 string FallbackPlayerModel;
 205 string CheckPlayerModel(string plyermodel) {
 206         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 207         {
 208                 // note: we cannot summon Don Strunzone here, some player may
 209                 // still have the model string set. In case anyone manages how
 210                 // to change a cvar default, we'll have a small leak here.
 211                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 212         }
 213         // only in right path
 214         if(substring(plyermodel, 0, 14) != "models/player/")
 215                 return FallbackPlayerModel;
 216         // only good file extensions
 217         if(substring(plyermodel, -4, 4) != ".iqm"
 218                 && substring(plyermodel, -4, 4) != ".zym"
 219                 && substring(plyermodel, -4, 4) != ".dpm"
 220                 && substring(plyermodel, -4, 4) != ".md3"
 221                 && substring(plyermodel, -4, 4) != ".psk")
 222         {
 223                 return FallbackPlayerModel;
 224         }
 225         // forbid the LOD models
 226         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 227                 return FallbackPlayerModel;
 228         if(plyermodel != strtolower(plyermodel))
 229                 return FallbackPlayerModel;
 230         // also, restrict to server models
 231         if(autocvar_sv_servermodelsonly)
 232         {
 233                 if(!fexists(plyermodel))
 234                         return FallbackPlayerModel;
 235         }
 236         return plyermodel;
 237 }
 238
 239 void setplayermodel(entity e, string modelname)
 240 {
 241         precache_model(modelname);
 242         _setmodel(e, modelname);
 243         player_setupanimsformodel(e);
 244         if(!autocvar_g_debug_globalsounds)
 245                 UpdatePlayerSounds(e);
 246 }
 247
 248 /** putting a client as observer in the server */
 249 void PutObserverInServer(entity this)
 250 {
 251         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 252         PlayerState_detach(this);
 253
 254         if (IS_PLAYER(this))
 255         {
 256                 if(GetResource(this, RES_HEALTH) >= 1)
 257                 {
 258                         // despawn effect
 259                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 260                 }
 261
 262                 // was a player, recount votes and ready status
 263                 if(IS_REAL_CLIENT(this))
 264                 {
 265                         if (vote_called) { VoteCount(false); }
 266                         ReadyCount();
 267                 }
 268                 entcs_update_players(this);
 269         }
 270
 271         entity spot = SelectSpawnPoint(this, true);
 272         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 273         this.angles = vec2(spot.angles);
 274         this.fixangle = true;
 275         // offset it so that the spectator spawns higher off the ground, looks better this way
 276         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 277         if (IS_REAL_CLIENT(this))
 278         {
 279                 msg_entity = this;
 280                 WriteByte(MSG_ONE, SVC_SETVIEW);
 281                 WriteEntity(MSG_ONE, this);
 282         }
 283         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 284         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 285         if(!autocvar_g_debug_globalsounds)
 286         {
 287                 // needed for player sounds
 288                 this.model = "";
 289                 FixPlayermodel(this);
 290         }
 291         setmodel(this, MDL_Null);
 292         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 293         this.view_ofs = '0 0 0';
 294
 295         RemoveGrapplingHooks(this);
 296         Portal_ClearAll(this);
 297         Unfreeze(this, false);
 298         SetSpectatee(this, NULL);
 299
 300         if (this.alivetime)
 301         {
 302                 if (!warmup_stage)
 303                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 304                 this.alivetime = 0;
 305         }
 306
 307         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 308
 309         WaypointSprite_PlayerDead(this);
 310
 311         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 312                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 313
 314         accuracy_resend(this);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         TRANSMUTE(Observer, this);
 325         this.iscreature = false;
 326         this.teleportable = TELEPORT_SIMPLE;
 327         if(this.damagedbycontents)
 328                 IL_REMOVE(g_damagedbycontents, this);
 329         this.damagedbycontents = false;
 330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 331         SetSpectatee_status(this, etof(this));
 332         this.takedamage = DAMAGE_NO;
 333         this.solid = SOLID_NOT;
 334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 335         this.flags = FL_CLIENT | FL_NOTARGET;
 336         this.effects = 0;
 337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 338         this.pauserotarmor_finished = 0;
 339         this.pauserothealth_finished = 0;
 340         this.pauseregen_finished = 0;
 341         this.damageforcescale = 0;
 342         this.death_time = 0;
 343         this.respawn_flags = 0;
 344         this.respawn_time = 0;
 345         STAT(RESPAWN_TIME, this) = 0;
 346         this.alpha = 0;
 347         this.scale = 0;
 348         this.fade_time = 0;
 349         this.pain_finished = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void ResetPlayerResources(entity this)
 536 {
 537         if (warmup_stage) {
 538                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 539                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 540                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 541                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 542                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 543                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 544                 SetResource(this, RES_HEALTH, warmup_start_health);
 545                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 546                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 547         } else {
 548                 SetResource(this, RES_SHELLS, start_ammo_shells);
 549                 SetResource(this, RES_BULLETS, start_ammo_nails);
 550                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 551                 SetResource(this, RES_CELLS, start_ammo_cells);
 552                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 553                 SetResource(this, RES_FUEL, start_ammo_fuel);
 554                 SetResource(this, RES_HEALTH, start_health);
 555                 SetResource(this, RES_ARMOR, start_armorvalue);
 556                 STAT(WEAPONS, this) = start_weapons;
 557                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 558                 {
 559                         GiveRandomWeapons(this, random_start_weapons_count,
 560                                 autocvar_g_random_start_weapons, random_start_ammo);
 561                 }
 562         }
 563 }
 564
 565 void PutPlayerInServer(entity this)
 566 {
 567         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 568
 569         PlayerState_attach(this);
 570         accuracy_resend(this);
 571
 572         if (this.team < 0)
 573                 TeamBalance_JoinBestTeam(this);
 574
 575         entity spot = SelectSpawnPoint(this, false);
 576         if (!spot) {
 577                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 578                 return; // spawn failed
 579         }
 580
 581         TRANSMUTE(Player, this);
 582
 583         CS(this).wasplayer = true;
 584         this.iscreature = true;
 585         this.teleportable = TELEPORT_NORMAL;
 586         if(!this.damagedbycontents)
 587                 IL_PUSH(g_damagedbycontents, this);
 588         this.damagedbycontents = true;
 589         set_movetype(this, MOVETYPE_WALK);
 590         this.solid = SOLID_SLIDEBOX;
 591         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 592         if (autocvar_g_playerclip_collisions)
 593                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 594         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 595                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 596         this.frags = FRAGS_PLAYER;
 597         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 598         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 599         if (autocvar__notarget)
 600                 this.flags |= FL_NOTARGET;
 601         this.takedamage = DAMAGE_AIM;
 602         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 603
 604         ResetPlayerResources(this);
 605
 606         SetSpectatee_status(this, 0);
 607
 608         PS(this).dual_weapons = '0 0 0';
 609
 610         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 611                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 612
 613         this.items = start_items;
 614
 615         float shieldtime = time + autocvar_g_spawnshieldtime;
 616
 617         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 618         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 619         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 620         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 621         if (!sv_ready_restart_after_countdown && time < game_starttime)
 622         {
 623                 float f = game_starttime - time;
 624                 shieldtime += f;
 625                 this.pauserotarmor_finished += f;
 626                 this.pauserothealth_finished += f;
 627                 this.pauseregen_finished += f;
 628         }
 629
 630         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 631
 632         this.damageforcescale = autocvar_g_player_damageforcescale;
 633         this.death_time = 0;
 634         this.respawn_flags = 0;
 635         this.respawn_time = 0;
 636         STAT(RESPAWN_TIME, this) = 0;
 637         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 638         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 639         this.fade_time = 0;
 640         this.pain_finished = 0;
 641         this.pushltime = 0;
 642         setthink(this, func_null); // players have no think function
 643         this.nextthink = 0;
 644         this.dmg_team = 0;
 645         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 646
 647         this.deadflag = DEAD_NO;
 648
 649         this.angles = spot.angles;
 650         this.angles_z = 0; // never spawn tilted even if the spot says to
 651         if (IS_BOT_CLIENT(this))
 652         {
 653                 this.v_angle = this.angles;
 654                 bot_aim_reset(this);
 655         }
 656         this.fixangle = true; // turn this way immediately
 657         this.oldvelocity = this.velocity = '0 0 0';
 658         this.avelocity = '0 0 0';
 659         this.punchangle = '0 0 0';
 660         this.punchvector = '0 0 0';
 661
 662         STAT(REVIVE_PROGRESS, this) = 0;
 663         this.revival_time = 0;
 664
 665         STAT(AIR_FINISHED, this) = 0;
 666         this.waterlevel = WATERLEVEL_NONE;
 667         this.watertype = CONTENT_EMPTY;
 668
 669         entity spawnevent = new_pure(spawnevent);
 670         spawnevent.owner = this;
 671         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 672
 673         // Cut off any still running player sounds.
 674         stopsound(this, CH_PLAYER_SINGLE);
 675
 676         this.model = "";
 677         FixPlayermodel(this);
 678         this.drawonlytoclient = NULL;
 679
 680         this.viewloc = NULL;
 681
 682         for(int slot = 0; slot < MAX_AXH; ++slot)
 683         {
 684                 entity axh = this.(AuxiliaryXhair[slot]);
 685                 this.(AuxiliaryXhair[slot]) = NULL;
 686
 687                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 688                         delete(axh);
 689         }
 690
 691         this.spawnpoint_targ = NULL;
 692
 693         UNSET_DUCKED(this);
 694         this.view_ofs = STAT(PL_VIEW_OFS, this);
 695         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 696         this.spawnorigin = spot.origin;
 697         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 698         // don't reset back to last position, even if new position is stuck in solid
 699         this.oldorigin = this.origin;
 700         if(this.conveyor)
 701                 IL_REMOVE(g_conveyed, this);
 702         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 703         if(this.swampslug)
 704                 IL_REMOVE(g_swamped, this);
 705         this.swampslug = NULL;
 706         this.swamp_interval = 0;
 707         if(this.ladder_entity)
 708                 IL_REMOVE(g_ladderents, this);
 709         this.ladder_entity = NULL;
 710         IL_EACH(g_counters, it.realowner == this,
 711         {
 712                 delete(it);
 713         });
 714         STAT(HUD, this) = HUD_NORMAL;
 715
 716         this.event_damage = PlayerDamage;
 717         this.event_heal = PlayerHeal;
 718
 719         this.draggable = func_null;
 720
 721         if(!this.bot_attack)
 722                 IL_PUSH(g_bot_targets, this);
 723         this.bot_attack = true;
 724         if(!this.monster_attack)
 725                 IL_PUSH(g_monster_targets, this);
 726         this.monster_attack = true;
 727         navigation_dynamicgoal_init(this, false);
 728
 729         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 730
 731         // player was spectator
 732         if (CS(this).killcount == FRAGS_SPECTATOR) {
 733                 PlayerScore_Clear(this);
 734                 CS(this).killcount = 0;
 735                 CS(this).startplaytime = time;
 736         }
 737
 738         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 739         {
 740                 .entity weaponentity = weaponentities[slot];
 741                 CL_SpawnWeaponentity(this, weaponentity);
 742         }
 743         this.alpha = default_player_alpha;
 744         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 745         this.exteriorweaponentity.alpha = default_weapon_alpha;
 746
 747         this.speedrunning = false;
 748
 749         this.counter_cnt = 0;
 750         this.fragsfilter_cnt = 0;
 751
 752         target_voicescript_clear(this);
 753
 754         // reset fields the weapons may use
 755         FOREACH(Weapons, true, {
 756                 it.wr_resetplayer(it, this);
 757                         // reload all reloadable weapons
 758                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 759                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 760                         {
 761                                 .entity weaponentity = weaponentities[slot];
 762                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 763                         }
 764                 }
 765         });
 766
 767         Unfreeze(this, false);
 768
 769         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 770
 771         {
 772                 string s = spot.target;
 773                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 774                         spot.target = string_null;
 775                 SUB_UseTargets(spot, this, NULL);
 776                 if(g_assault || g_race)
 777                         spot.target = s;
 778         }
 779
 780         if (autocvar_spawn_debug)
 781         {
 782                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 783                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 784         }
 785
 786         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 787         {
 788                 .entity weaponentity = weaponentities[slot];
 789                 entity w_ent = this.(weaponentity);
 790                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 791                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 792                 else
 793                         w_ent.m_switchweapon = WEP_Null;
 794                 w_ent.m_weapon = WEP_Null;
 795                 w_ent.weaponname = "";
 796                 w_ent.m_switchingweapon = WEP_Null;
 797                 w_ent.cnt = -1;
 798         }
 799
 800         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 801
 802         if (CS(this).impulse) ImpulseCommands(this);
 803
 804         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 805         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 806         {
 807                 .entity weaponentity = weaponentities[slot];
 808                 W_WeaponFrame(this, weaponentity);
 809         }
 810
 811         if (!warmup_stage && !this.alivetime)
 812                 this.alivetime = time;
 813
 814         antilag_clear(this, CS(this));
 815 }
 816
 817 /** Called when a client spawns in the server */
 818 void PutClientInServer(entity this)
 819 {
 820         if (IS_BOT_CLIENT(this)) {
 821                 TRANSMUTE(Player, this);
 822         } else if (IS_REAL_CLIENT(this)) {
 823                 msg_entity = this;
 824                 WriteByte(MSG_ONE, SVC_SETVIEW);
 825                 WriteEntity(MSG_ONE, this);
 826         }
 827         if (game_stopped)
 828                 TRANSMUTE(Observer, this);
 829
 830         SetSpectatee(this, NULL);
 831
 832         // reset player keys
 833         if(PS(this))
 834                 PS(this).itemkeys = 0;
 835
 836         MUTATOR_CALLHOOK(PutClientInServer, this);
 837
 838         if (IS_OBSERVER(this)) {
 839                 PutObserverInServer(this);
 840         } else if (IS_PLAYER(this)) {
 841                 PutPlayerInServer(this);
 842         }
 843         // send team names
 844         if(teamplay && IS_REAL_CLIENT(this))
 845                 send_TeamNames(MSG_ONE, this);
 846         bot_relinkplayerlist();
 847 }
 848
 849 // TODO do we need all these fields, or should we stop autodetecting runtime
 850 // changes and just have a console command to update this?
 851 bool ClientInit_SendEntity(entity this, entity to, int sf)
 852 {
 853         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 854         return = true;
 855         msg_entity = to;
 856         // MSG_INIT replacement
 857         // TODO: make easier to use
 858         Registry_send_all();
 859         W_PROP_reload(MSG_ONE, to);
 860         ClientInit_misc(this);
 861         MUTATOR_CALLHOOK(Ent_Init);
 862 }
 863 void ClientInit_misc(entity this)
 864 {
 865         int channel = MSG_ONE;
 866         WriteHeader(channel, ENT_CLIENT_INIT);
 867         WriteByte(channel, g_nexball_meter_period * 32);
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 869         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 870         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 871         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 873         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 874         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 875         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 876
 877         if(autocvar_sv_foginterval && world.fog != "")
 878                 WriteString(channel, world.fog);
 879         else
 880                 WriteString(channel, "");
 881         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 882         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 883         WriteByte(channel, serverflags);
 884         WriteCoord(channel, autocvar_g_trueaim_minrange);
 885
 886         // z411 send full hostname
 887         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 888         WriteString(channel, autocvar_sv_motd_permanent);
 889 }
 890
 891 void ClientInit_CheckUpdate(entity this)
 892 {
 893         this.nextthink = time;
 894         if(this.count != autocvar_g_balance_armor_blockpercent)
 895         {
 896                 this.count = autocvar_g_balance_armor_blockpercent;
 897                 this.SendFlags |= 1;
 898         }
 899         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 900         {
 901                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 902                 this.SendFlags |= 1;
 903         }
 904 }
 905
 906 void ClientInit_Spawn()
 907 {
 908         entity e = new_pure(clientinit);
 909         setthink(e, ClientInit_CheckUpdate);
 910         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 911
 912         ClientInit_CheckUpdate(e);
 913 }
 914
 915 /*
 916 =============
 917 SetNewParms
 918 =============
 919 */
 920 void SetNewParms ()
 921 {
 922         // initialize parms for a new player
 923         parm1 = -(86400 * 366);
 924
 925         MUTATOR_CALLHOOK(SetNewParms);
 926 }
 927
 928 /*
 929 =============
 930 SetChangeParms
 931 =============
 932 */
 933 void SetChangeParms (entity this)
 934 {
 935         // save parms for level change
 936         parm1 = CS(this).parm_idlesince - time;
 937
 938         MUTATOR_CALLHOOK(SetChangeParms);
 939 }
 940
 941 /*
 942 =============
 943 DecodeLevelParms
 944 =============
 945 */
 946 void DecodeLevelParms(entity this)
 947 {
 948         // load parms
 949         CS(this).parm_idlesince = parm1;
 950         if (CS(this).parm_idlesince == -(86400 * 366))
 951                 CS(this).parm_idlesince = time;
 952
 953         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 954         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 955
 956         MUTATOR_CALLHOOK(DecodeLevelParms);
 957 }
 958
 959 void FixClientCvars(entity e)
 960 {
 961         // send prediction settings to the client
 962         stuffcmd(e, "\nin_bindmap 0 0\n");
 963         if(autocvar_g_antilag == 3) // client side hitscan
 964                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 965         if(autocvar_sv_gentle)
 966                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 967
 968         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 969         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 970
 971         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 972
 973         MUTATOR_CALLHOOK(FixClientCvars, e);
 974 }
 975
 976 bool findinlist_abbrev(string tofind, string list)
 977 {
 978         if(list == "" || tofind == "")
 979                 return false; // empty list or search, just return
 980
 981         // this function allows abbreviated strings!
 982         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 983         {
 984                 return true;
 985         });
 986
 987         return false;
 988 }
 989
 990 bool PlayerInIPList(entity p, string iplist)
 991 {
 992         // some safety checks (never allow local?)
 993         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 994                 return false;
 995
 996         return findinlist_abbrev(p.netaddress, iplist);
 997 }
 998
 999 bool PlayerInIDList(entity p, string idlist)
1000 {
1001         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1002         if(!p.crypto_idfp)
1003                 return false;
1004
1005         return findinlist_abbrev(p.crypto_idfp, idlist);
1006 }
1007
1008 bool PlayerInList(entity player, string list)
1009 {
1010         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1011 }
1012
1013 #ifdef DP_EXT_PRECONNECT
1014 /*
1015 =============
1016 ClientPreConnect
1017
1018 Called once (not at each match start) when a client begins a connection to the server
1019 =============
1020 */
1021 void ClientPreConnect(entity this)
1022 {
1023         if(autocvar_sv_eventlog)
1024         {
1025                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1026                         this.playerid,
1027                         etof(this),
1028                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1029                 ));
1030         }
1031 }
1032 #endif
1033
1034 string GetClientVersionMessage(entity this)
1035 {
1036         if (CS(this).version_mismatch) {
1037                 if(CS(this).version < autocvar_gameversion) {
1038                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1039                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1040                 } else {
1041                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1042                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1043                 }
1044         } else {
1045                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1046         }
1047 }
1048
1049 string getwelcomemessage(entity this)
1050 {
1051         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1052         string modifications = M_ARGV(0, string);
1053
1054         if(g_weaponarena)
1055         {
1056                 if(g_weaponarena_random)
1057                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1058                 else
1059                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1060         }
1061         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1062                 modifications = strcat(modifications, ", No start weapons");
1063         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1064                 modifications = strcat(modifications, ", Low gravity");
1065         if(g_weapon_stay && !g_cts)
1066                 modifications = strcat(modifications, ", Weapons stay");
1067         if(autocvar_g_jetpack)
1068                 modifications = strcat(modifications, ", Jet pack");
1069         modifications = substring(modifications, 2, strlen(modifications) - 2);
1070
1071         //string versionmessage = GetClientVersionMessage(this);
1072         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1073         //string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1074         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1075
1076         s = strcat(s, "^8\n^7", gamemode_name);
1077
1078         if(modifications != "")
1079                 s = strcat(s, "^7 | ^3", modifications);
1080
1081         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1082         {
1083                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1084                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1085         }
1086
1087         if (cache_mutatormsg != "") {
1088                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1089         }
1090
1091         string mutator_msg = "";
1092         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1093         mutator_msg = M_ARGV(0, string);
1094
1095         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1096
1097         string motd = autocvar_sv_motd;
1098         if (motd != "") {
1099                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1100         }
1101         return s;
1102 }
1103
1104 /**
1105 =============
1106 ClientConnect
1107
1108 Called when a client connects to the server
1109 =============
1110 */
1111 void ClientConnect(entity this)
1112 {
1113         if (Ban_MaybeEnforceBanOnce(this)) return;
1114         assert(!IS_CLIENT(this), return);
1115         this.flags |= FL_CLIENT;
1116         assert(player_count >= 0, player_count = 0);
1117
1118         TRANSMUTE(Client, this);
1119         CS(this).version_nagtime = time + 10 + random() * 10;
1120
1121         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1122
1123         bot_clientconnect(this);
1124
1125         Player_DetermineForcedTeam(this);
1126
1127         TRANSMUTE(Observer, this);
1128
1129         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1130
1131         // always track bots, don't ask for cl_allow_uidtracking
1132         if (IS_BOT_CLIENT(this))
1133                 PlayerStats_GameReport_AddPlayer(this);
1134         else
1135                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1136
1137         if (autocvar_sv_eventlog)
1138                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1139
1140         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1141
1142         stuffcmd(this, clientstuff, "\n");
1143         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1144
1145         FixClientCvars(this);
1146
1147         // get version info from player
1148         stuffcmd(this, "cmd clientversion $gameversion\n");
1149
1150         // notify about available teams
1151         if (teamplay)
1152         {
1153                 entity balance = TeamBalance_CheckAllowedTeams(this);
1154                 int t = TeamBalance_GetAllowedTeams(balance);
1155                 TeamBalance_Destroy(balance);
1156                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1157         }
1158         else
1159         {
1160                 stuffcmd(this, "set _teams_available 0\n");
1161         }
1162
1163         bot_relinkplayerlist();
1164
1165         CS(this).spectatortime = time;
1166         if (blockSpectators)
1167         {
1168                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1169         }
1170
1171         CS(this).jointime = time;
1172
1173         if (IS_REAL_CLIENT(this))
1174         {
1175                 if (g_weaponarena_weapons == WEPSET(TUBA))
1176                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1177         }
1178
1179         if (!autocvar_sv_foginterval && world.fog != "")
1180                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1181
1182         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1183                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1184                         send_CSQC_teamnagger();
1185
1186         CSQCMODEL_AUTOINIT(this);
1187
1188         CS(this).model_randomizer = random();
1189
1190         if (IS_REAL_CLIENT(this))
1191                 sv_notice_join(this);
1192
1193         this.move_qcphysics = autocvar_sv_qcphysics;
1194
1195         // update physics stats (players can spawn before physics runs)
1196         Physics_UpdateStats(this);
1197
1198         IL_EACH(g_initforplayer, it.init_for_player, {
1199                 it.init_for_player(it, this);
1200         });
1201
1202         Handicap_Initialize(this);
1203
1204         MUTATOR_CALLHOOK(ClientConnect, this);
1205
1206         if (IS_REAL_CLIENT(this))
1207         {
1208                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1209                 {
1210                         CS(this).motd_actived_time = -1;
1211                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1212                 }
1213         }
1214 }
1215 /*
1216 =============
1217 ClientDisconnect
1218
1219 Called when a client disconnects from the server
1220 =============
1221 */
1222 .entity chatbubbleentity;
1223 void player_powerups_remove_all(entity this);
1224
1225 void ClientDisconnect(entity this)
1226 {
1227         assert(IS_CLIENT(this), return);
1228
1229         PlayerStats_GameReport_FinalizePlayer(this);
1230         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1231         if (CS(this).active_minigame) part_minigame(this);
1232         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1233
1234         if (autocvar_sv_eventlog)
1235                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1236
1237         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1238
1239         if(IS_SPEC(this))
1240                 SetSpectatee(this, NULL);
1241
1242         MUTATOR_CALLHOOK(ClientDisconnect, this);
1243
1244         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1245         strfree(CS_CVAR(this).weaponorder_byimpulse);
1246         ClientState_detach(this);
1247
1248         Portal_ClearAll(this);
1249
1250         Unfreeze(this, false);
1251
1252         RemoveGrapplingHooks(this);
1253
1254         // Here, everything has been done that requires this player to be a client.
1255
1256         this.flags &= ~FL_CLIENT;
1257
1258         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1259         if (this.killindicator) delete(this.killindicator);
1260
1261         IL_EACH(g_counters, it.realowner == this,
1262         {
1263                 delete(it);
1264         });
1265
1266         WaypointSprite_PlayerGone(this);
1267
1268         bot_relinkplayerlist();
1269
1270         strfree(this.clientstatus);
1271         if (this.personal) delete(this.personal);
1272
1273         this.playerid = 0;
1274         ReadyCount();
1275         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1276
1277         player_powerups_remove_all(this); // stop powerup sound
1278
1279         ONREMOVE(this);
1280 }
1281
1282 void ChatBubbleThink(entity this)
1283 {
1284         this.nextthink = time;
1285         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1286         {
1287                 if(this.owner) // but why can that ever be NULL?
1288                         this.owner.chatbubbleentity = NULL;
1289                 delete(this);
1290                 return;
1291         }
1292
1293         this.mdl = "";
1294
1295         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1296         {
1297                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1298                         this.mdl = "models/sprites/minigame_busy.iqm";
1299                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1300                         this.mdl = "models/misc/chatbubble.spr";
1301         }
1302
1303         if ( this.model != this.mdl )
1304                 _setmodel(this, this.mdl);
1305
1306 }
1307
1308 void UpdateChatBubble(entity this)
1309 {
1310         if (this.alpha < 0)
1311                 return;
1312         // spawn a chatbubble entity if needed
1313         if (!this.chatbubbleentity)
1314         {
1315                 this.chatbubbleentity = new(chatbubbleentity);
1316                 this.chatbubbleentity.owner = this;
1317                 this.chatbubbleentity.exteriormodeltoclient = this;
1318                 setthink(this.chatbubbleentity, ChatBubbleThink);
1319                 this.chatbubbleentity.nextthink = time;
1320                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1321                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1322                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1323                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1324                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1325                 //this.chatbubbleentity.model = "";
1326                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1327         }
1328 }
1329
1330 void calculate_player_respawn_time(entity this)
1331 {
1332         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1333                 return;
1334
1335         float gametype_setting_tmp;
1336         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1337         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1338         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1339         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1340         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1341         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1342
1343         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1344         if (teamplay)
1345         {
1346                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1347                         if(it.team == this.team)
1348                                 ++pcount;
1349                 });
1350                 if (sdelay_small_count == 0)
1351                         sdelay_small_count = 1;
1352                 if (sdelay_large_count == 0)
1353                         sdelay_large_count = 1;
1354         }
1355         else
1356         {
1357                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1358                         ++pcount;
1359                 });
1360                 if (sdelay_small_count == 0)
1361                 {
1362                         if (IS_INDEPENDENT_PLAYER(this))
1363                         {
1364                                 // Players play independently. No point in requiring enemies.
1365                                 sdelay_small_count = 1;
1366                         }
1367                         else
1368                         {
1369                                 // Players play AGAINST each other. Enemies required.
1370                                 sdelay_small_count = 2;
1371                         }
1372                 }
1373                 if (sdelay_large_count == 0)
1374                 {
1375                         if (IS_INDEPENDENT_PLAYER(this))
1376                         {
1377                                 // Players play independently. No point in requiring enemies.
1378                                 sdelay_large_count = 1;
1379                         }
1380                         else
1381                         {
1382                                 // Players play AGAINST each other. Enemies required.
1383                                 sdelay_large_count = 2;
1384                         }
1385                 }
1386         }
1387
1388         float sdelay;
1389
1390         if (pcount <= sdelay_small_count)
1391                 sdelay = sdelay_small;
1392         else if (pcount >= sdelay_large_count)
1393                 sdelay = sdelay_large;
1394         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1395                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1396
1397         if(waves)
1398                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1399         else
1400                 this.respawn_time = time + sdelay;
1401
1402         if(sdelay < sdelay_max)
1403                 this.respawn_time_max = time + sdelay_max;
1404         else
1405                 this.respawn_time_max = this.respawn_time;
1406
1407         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1408                 this.respawn_countdown = 10; // first number to count down from is 10
1409         else
1410                 this.respawn_countdown = -1; // do not count down
1411
1412         if(autocvar_g_forced_respawn)
1413                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1414 }
1415
1416 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1417 // added to the model skins
1418 /*void UpdateColorModHack()
1419 {
1420         float c;
1421         c = this.clientcolors & 15;
1422         // LordHavoc: only bothering to support white, green, red, yellow, blue
1423              if (!teamplay) this.colormod = '0 0 0';
1424         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1425         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1426         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1427         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1428         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1429         else this.colormod = '1 1 1';
1430 }*/
1431
1432 void respawn(entity this)
1433 {
1434         bool damagedbycontents_prev = this.damagedbycontents;
1435         if(this.alpha >= 0)
1436         {
1437                 if(autocvar_g_respawn_ghosts)
1438                 {
1439                         this.solid = SOLID_NOT;
1440                         this.takedamage = DAMAGE_NO;
1441                         this.damagedbycontents = false;
1442                         set_movetype(this, MOVETYPE_FLY);
1443                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1444                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1445                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1446                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1447                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1448                         if(autocvar_g_respawn_ghosts_time > 0)
1449                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1450                 }
1451                 else
1452                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1453         }
1454
1455         CopyBody(this, 1);
1456         this.damagedbycontents = damagedbycontents_prev;
1457
1458         this.effects |= EF_NODRAW; // prevent another CopyBody
1459         PutClientInServer(this);
1460 }
1461
1462 void play_countdown(entity this, float finished, Sound samp)
1463 {
1464         TC(Sound, samp);
1465         if(IS_REAL_CLIENT(this))
1466                 if(floor(finished - time - frametime) != floor(finished - time))
1467                         if(finished - time < 6)
1468                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1469 }
1470
1471 void player_powerups_remove_all(entity this)
1472 {
1473         if (this.items & IT_SUPERWEAPON)
1474         {
1475                 // don't play the poweroff sound when the game restarts or the player disconnects
1476                 if (time > game_starttime + 1 && IS_CLIENT(this))
1477                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1478                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1479                 this.items -= (this.items & IT_SUPERWEAPON);
1480         }
1481 }
1482
1483 void player_powerups(entity this)
1484 {
1485         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1486                 this.modelflags |= MF_ROCKET;
1487         else
1488                 this.modelflags &= ~MF_ROCKET;
1489
1490         this.effects &= ~EF_NODEPTHTEST;
1491
1492         if (IS_DEAD(this))
1493                 player_powerups_remove_all(this);
1494
1495         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1496                 return;
1497
1498         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1499         int items_prev = this.items;
1500
1501         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1502         {
1503                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1504                 if (this.items & IT_SUPERWEAPON)
1505                 {
1506                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1507                         {
1508                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1509                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1510                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1511                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1512                         }
1513                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1514                         {
1515                                 // don't let them run out
1516                         }
1517                         else
1518                         {
1519                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1520                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1521                                 {
1522                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1523                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1524                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1526                                 }
1527                         }
1528                 }
1529                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1530                 {
1531                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1532                         {
1533                                 this.items = this.items | IT_SUPERWEAPON;
1534                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1535                                 {
1536                                         if(!g_cts)
1537                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1538                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1539                                 }
1540                         }
1541                         else
1542                         {
1543                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1544                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1545                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1546                         }
1547                 }
1548                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1549                 {
1550                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1551                 }
1552         }
1553
1554         if(autocvar_g_nodepthtestplayers)
1555                 this.effects = this.effects | EF_NODEPTHTEST;
1556
1557         if(autocvar_g_fullbrightplayers)
1558                 this.effects = this.effects | EF_FULLBRIGHT;
1559
1560         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1561 }
1562
1563 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1564 {
1565         if(current > stable)
1566                 return current;
1567         else if(current > stable - 0.25) // when close enough, "snap"
1568                 return stable;
1569         else
1570                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1571 }
1572
1573 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1574 {
1575         if(current < stable)
1576                 return current;
1577         else if(current < stable + 0.25) // when close enough, "snap"
1578                 return stable;
1579         else
1580                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1581 }
1582
1583 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1584 {
1585         float old = GetResource(this, res);
1586         float current = old;
1587         if(current > rotstable)
1588         {
1589                 if(rotframetime > 0)
1590                 {
1591                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1592                         current = max(rotstable, current - rotlinear * rotframetime);
1593                 }
1594         }
1595         else if(current < regenstable)
1596         {
1597                 if(regenframetime > 0)
1598                 {
1599                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1600                         current = min(regenstable, current + regenlinear * regenframetime);
1601                 }
1602         }
1603
1604         float limit = GetResourceLimit(this, res) * limit_mod;
1605         if(current > limit)
1606                 current = limit;
1607
1608         if (current != old)
1609                 SetResource(this, res, current);
1610 }
1611
1612 void player_regen(entity this)
1613 {
1614         float max_mod, regen_mod, rot_mod, limit_mod;
1615         max_mod = regen_mod = rot_mod = limit_mod = 1;
1616
1617         float regen_health = autocvar_g_balance_health_regen;
1618         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1619         float regen_health_rot = autocvar_g_balance_health_rot;
1620         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1621         float regen_health_stable = autocvar_g_balance_health_regenstable;
1622         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1623         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1624                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1625         max_mod = M_ARGV(1, float);
1626         regen_mod = M_ARGV(2, float);
1627         rot_mod = M_ARGV(3, float);
1628         limit_mod = M_ARGV(4, float);
1629         regen_health = M_ARGV(5, float);
1630         regen_health_linear = M_ARGV(6, float);
1631         regen_health_rot = M_ARGV(7, float);
1632         regen_health_rotlinear = M_ARGV(8, float);
1633         regen_health_stable = M_ARGV(9, float);
1634         regen_health_rotstable = M_ARGV(10, float);
1635
1636         if(!mutator_returnvalue)
1637         if(!STAT(FROZEN, this))
1638         {
1639                 float maxa = autocvar_g_balance_armor_rotstable;
1640                 float mina = autocvar_g_balance_armor_regenstable;
1641
1642                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1643                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1644                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1645
1646                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1647                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1648                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1649         }
1650
1651         // if player rotted to death...  die!
1652         // check this outside above checks, as player may still be able to rot to death
1653         if(GetResource(this, RES_HEALTH) < 1)
1654         {
1655                 if(this.vehicle)
1656                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1657                 if(this.event_damage)
1658                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1659         }
1660
1661         if (!(this.items & IT_UNLIMITED_AMMO))
1662         {
1663                 float maxf = autocvar_g_balance_fuel_rotstable;
1664                 float minf = autocvar_g_balance_fuel_regenstable;
1665
1666                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1667                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1668                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1669         }
1670 }
1671
1672 bool zoomstate_set;
1673 void SetZoomState(entity this, float newzoom)
1674 {
1675         if(newzoom != CS(this).zoomstate)
1676         {
1677                 CS(this).zoomstate = newzoom;
1678                 ClientData_Touch(this);
1679         }
1680         zoomstate_set = true;
1681 }
1682
1683 void GetPressedKeys(entity this)
1684 {
1685         MUTATOR_CALLHOOK(GetPressedKeys, this);
1686         if (game_stopped)
1687         {
1688                 CS(this).pressedkeys = 0;
1689                 STAT(PRESSED_KEYS, this) = 0;
1690                 return;
1691         }
1692
1693         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1694         int keys = STAT(PRESSED_KEYS, this);
1695         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1696         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1697         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1698         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1699
1700         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1701         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1702         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1703         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1704         CS(this).pressedkeys = keys; // store for other users
1705
1706         STAT(PRESSED_KEYS, this) = keys;
1707 }
1708
1709 /*
1710 ======================
1711 spectate mode routines
1712 ======================
1713 */
1714
1715 void SpectateCopy(entity this, entity spectatee)
1716 {
1717         TC(Client, this); TC(Client, spectatee);
1718
1719         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1720         PS(this) = PS(spectatee);
1721         this.armortype = spectatee.armortype;
1722         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1723         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1724         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1725         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1726         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1727         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1728         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1729         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1730         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1731         CS(this).impulse = 0;
1732         this.disableclientprediction = 1; // no need to run prediction on a spectator
1733         this.items = spectatee.items;
1734         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1735         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1736         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1737         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1738         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1739         this.punchangle = spectatee.punchangle;
1740         this.view_ofs = spectatee.view_ofs;
1741         this.velocity = spectatee.velocity;
1742         this.dmg_take = spectatee.dmg_take;
1743         this.dmg_save = spectatee.dmg_save;
1744         this.dmg_inflictor = spectatee.dmg_inflictor;
1745         this.v_angle = spectatee.v_angle;
1746         this.angles = spectatee.v_angle;
1747         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1748         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1749         this.viewloc = spectatee.viewloc;
1750         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1751                 this.fixangle = true;
1752         setorigin(this, spectatee.origin);
1753         setsize(this, spectatee.mins, spectatee.maxs);
1754         SetZoomState(this, CS(spectatee).zoomstate);
1755
1756     anticheat_spectatecopy(this, spectatee);
1757         STAT(HUD, this) = STAT(HUD, spectatee);
1758         if(spectatee.vehicle)
1759     {
1760         this.angles = spectatee.v_angle;
1761
1762         //this.fixangle = false;
1763         //this.velocity = spectatee.vehicle.velocity;
1764         this.vehicle_health = spectatee.vehicle_health;
1765         this.vehicle_shield = spectatee.vehicle_shield;
1766         this.vehicle_energy = spectatee.vehicle_energy;
1767         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1768         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1769         this.vehicle_reload1 = spectatee.vehicle_reload1;
1770         this.vehicle_reload2 = spectatee.vehicle_reload2;
1771
1772         //msg_entity = this;
1773
1774        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1775             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1776            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1777            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1778
1779         //WriteByte (MSG_ONE, SVC_SETVIEW);
1780         //    WriteEntity(MSG_ONE, this);
1781         //makevectors(spectatee.v_angle);
1782         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1783     }
1784 }
1785
1786 bool SpectateUpdate(entity this)
1787 {
1788         if(!this.enemy)
1789                 return false;
1790
1791         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1792         {
1793                 SetSpectatee(this, NULL);
1794                 return false;
1795         }
1796
1797         SpectateCopy(this, this.enemy);
1798
1799         return true;
1800 }
1801
1802 bool SpectateSet(entity this)
1803 {
1804         if(!IS_PLAYER(this.enemy))
1805                 return false;
1806
1807         ClientData_Touch(this.enemy);
1808
1809         msg_entity = this;
1810         WriteByte(MSG_ONE, SVC_SETVIEW);
1811         WriteEntity(MSG_ONE, this.enemy);
1812         set_movetype(this, MOVETYPE_NONE);
1813         accuracy_resend(this);
1814
1815         if(!SpectateUpdate(this))
1816                 PutObserverInServer(this);
1817
1818         return true;
1819 }
1820
1821 void SetSpectatee_status(entity this, int spectatee_num)
1822 {
1823         int oldspectatee_status = CS(this).spectatee_status;
1824         CS(this).spectatee_status = spectatee_num;
1825
1826         if (CS(this).spectatee_status != oldspectatee_status)
1827         {
1828                 if (STAT(PRESSED_KEYS, this))
1829                 {
1830                         CS(this).pressedkeys = 0;
1831                         STAT(PRESSED_KEYS, this) = 0;
1832                 }
1833                 ClientData_Touch(this);
1834                 if (g_race || g_cts) race_InitSpectator();
1835         }
1836 }
1837
1838 void SetSpectatee(entity this, entity spectatee)
1839 {
1840         if(IS_BOT_CLIENT(this))
1841                 return; // bots abuse .enemy, this code is useless to them
1842
1843         entity old_spectatee = this.enemy;
1844
1845         this.enemy = spectatee;
1846
1847         // WEAPONTODO
1848         // these are required to fix the spectator bug with arc
1849         if(old_spectatee)
1850         {
1851                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1852                 {
1853                         .entity weaponentity = weaponentities[slot];
1854                         if(old_spectatee.(weaponentity).arc_beam)
1855                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1856                 }
1857         }
1858         if(this.enemy)
1859         {
1860                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1861                 {
1862                         .entity weaponentity = weaponentities[slot];
1863                         if(this.enemy.(weaponentity).arc_beam)
1864                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1865                 }
1866         }
1867
1868         if (this.enemy)
1869                 SetSpectatee_status(this, etof(this.enemy));
1870
1871         // needed to update spectator list
1872         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1873 }
1874
1875 bool Spectate(entity this, entity pl)
1876 {
1877         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1878                 return false;
1879         pl = M_ARGV(1, entity);
1880
1881         SetSpectatee(this, pl);
1882         return SpectateSet(this);
1883 }
1884
1885 bool SpectateNext(entity this)
1886 {
1887         entity ent = find(this.enemy, classname, STR_PLAYER);
1888
1889         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1890                 ent = M_ARGV(1, entity);
1891         else if (!ent)
1892                 ent = find(ent, classname, STR_PLAYER);
1893
1894         if(ent) { SetSpectatee(this, ent); }
1895
1896         return SpectateSet(this);
1897 }
1898
1899 bool SpectatePrev(entity this)
1900 {
1901         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1902         entity ent = findchain(classname, STR_PLAYER);
1903         if (!ent) // no player
1904                 return false;
1905
1906         entity first = ent;
1907         // skip players until current spectated player
1908         if(this.enemy)
1909         while(ent && ent != this.enemy)
1910                 ent = ent.chain;
1911
1912         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1913         {
1914                 case MUT_SPECPREV_FOUND:
1915                         ent = M_ARGV(1, entity);
1916                         break;
1917                 case MUT_SPECPREV_RETURN:
1918                         return true;
1919                 case MUT_SPECPREV_CONTINUE:
1920                 default:
1921                 {
1922                         if(ent.chain)
1923                                 ent = ent.chain;
1924                         else
1925                                 ent = first;
1926                         break;
1927                 }
1928         }
1929
1930         SetSpectatee(this, ent);
1931         return SpectateSet(this);
1932 }
1933
1934 /*
1935 =============
1936 ShowRespawnCountdown()
1937
1938 Update a respawn countdown display.
1939 =============
1940 */
1941 void ShowRespawnCountdown(entity this)
1942 {
1943         float number;
1944         if(!IS_DEAD(this)) // just respawned?
1945                 return;
1946         else
1947         {
1948                 number = ceil(this.respawn_time - time);
1949                 if(number <= 0)
1950                         return;
1951                 if(number <= this.respawn_countdown)
1952                 {
1953                         this.respawn_countdown = number - 1;
1954                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1955                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1956                 }
1957         }
1958 }
1959
1960 .bool team_selected;
1961 bool ShowTeamSelection(entity this)
1962 {
1963         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1964                 return false;
1965         stuffcmd(this, "menu_showteamselect\n");
1966         return true;
1967 }
1968 void Join(entity this)
1969 {
1970         TRANSMUTE(Player, this);
1971
1972         if(!this.team_selected)
1973         if(autocvar_g_campaign || autocvar_g_balance_teams)
1974                 TeamBalance_JoinBestTeam(this);
1975
1976         if(autocvar_g_campaign)
1977                 campaign_bots_may_start = true;
1978
1979         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1980
1981         PutClientInServer(this);
1982
1983         if(IS_PLAYER(this))
1984         if(teamplay && this.team != -1)
1985         {
1986         }
1987         else
1988                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1989         this.team_selected = false;
1990
1991         // z411
1992         // send constant ready notification
1993         if(warmup_stage)
1994                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
1995 }
1996
1997 int GetPlayerLimit()
1998 {
1999         if(g_duel)
2000                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2001         int player_limit = autocvar_g_maxplayers;
2002         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2003         player_limit = M_ARGV(0, int);
2004         return player_limit;
2005 }
2006
2007 /**
2008  * Determines whether the player is allowed to join. This depends on cvar
2009  * g_maxplayers, if it isn't used this function always return true, otherwise
2010  * it checks whether the number of currently playing players exceeds g_maxplayers.
2011  * @return int number of free slots for players, 0 if none
2012  */
2013 int nJoinAllowed(entity this, entity ignore)
2014 {
2015         if(!ignore)
2016         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2017         // so report 0 free slots if restricted
2018         {
2019                 if(autocvar_g_forced_team_otherwise == "spectate")
2020                         return 0;
2021                 if(autocvar_g_forced_team_otherwise == "spectator")
2022                         return 0;
2023         }
2024
2025         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2026                 return 0; // forced spectators can never join
2027
2028         // TODO simplify this
2029         int totalClients = 0;
2030         int currentlyPlaying = 0;
2031         FOREACH_CLIENT(true, {
2032                 if(it != ignore)
2033                         ++totalClients;
2034                 if(IS_REAL_CLIENT(it))
2035                 if(IS_PLAYER(it) || it.caplayer)
2036                         ++currentlyPlaying;
2037         });
2038
2039         int player_limit = GetPlayerLimit();
2040
2041         int free_slots = 0;
2042         if (!player_limit)
2043                 free_slots = maxclients - totalClients;
2044         else if(player_limit > 0 && currentlyPlaying < player_limit)
2045                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2046
2047         static float msg_time = 0;
2048         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2049         {
2050                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2051                 msg_time = time + 0.5;
2052         }
2053
2054         return free_slots;
2055 }
2056
2057 void PrintWelcomeMessage(entity this)
2058 {
2059         if(CS(this).motd_actived_time == 0)
2060         {
2061                 if (autocvar_g_campaign) {
2062                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2063                                 CS(this).motd_actived_time = time;
2064                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2065                         }
2066                 } else {
2067                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2068                                 CS(this).motd_actived_time = time;
2069                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2070                         }
2071                 }
2072         }
2073         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2074         {
2075                 if (autocvar_g_campaign) {
2076                         if (PHYS_INPUT_BUTTON_INFO(this))
2077                                 CS(this).motd_actived_time = time;
2078                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2079                                 CS(this).motd_actived_time = 0;
2080                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2081                         }
2082                 } else {
2083                         if (PHYS_INPUT_BUTTON_INFO(this))
2084                                 CS(this).motd_actived_time = time;
2085                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2086                                 CS(this).motd_actived_time = 0;
2087                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2088                         }
2089                 }
2090         }
2091         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2092         {
2093                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2094                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2095                 else if (CS(this).motd_actived_time == -2)
2096                 {
2097                         // instantly hide MOTD
2098                         CS(this).motd_actived_time = 0;
2099                         if (autocvar_g_campaign)
2100                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2101                         else
2102                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2103                 }
2104                 else if (IS_PLAYER(this) || IS_SPEC(this))
2105                 {
2106                         // FIXME occasionally for some reason MOTD never goes away
2107                         // delay MOTD removal a little bit in the hope it fixes this bug
2108                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2109                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2110                         else //if (CS(this).motd_actived_time < -2)
2111                                 CS(this).motd_actived_time++;
2112                 }
2113         }
2114 }
2115
2116 bool joinAllowed(entity this)
2117 {
2118         if (CS(this).version_mismatch) return false;
2119         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2120         if (!nJoinAllowed(this, this)) return false;
2121         if (teamplay && lockteams) return false;
2122         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2123         if (ShowTeamSelection(this)) return false;
2124         return true;
2125 }
2126
2127 .string shootfromfixedorigin;
2128 .bool dualwielding_prev;
2129 bool PlayerThink(entity this)
2130 {
2131         if (game_stopped || intermission_running) {
2132                 this.modelflags &= ~MF_ROCKET;
2133                 if(intermission_running)
2134                         IntermissionThink(this);
2135                 return false;
2136         }
2137
2138         if (game_timeout) {
2139         // don't allow the player to turn around while game is paused
2140                 // FIXME turn this into CSQC stuff
2141                 this.v_angle = this.lastV_angle;
2142                 this.angles = this.lastV_angle;
2143                 this.fixangle = true;
2144                 return false;
2145         }
2146
2147         if (frametime) player_powerups(this);
2148
2149         if (IS_DEAD(this)) {
2150                 if (this.personal && g_race_qualifying) {
2151                         if (time > this.respawn_time) {
2152                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2153                                 respawn(this);
2154                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2155                         }
2156                 } else {
2157                         if (frametime) player_anim(this);
2158
2159                         if (this.respawn_flags & RESPAWN_DENY)
2160                         {
2161                                 STAT(RESPAWN_TIME, this) = 0;
2162                                 return false;
2163                         }
2164
2165                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2166
2167                         switch(this.deadflag)
2168                         {
2169                                 case DEAD_DYING:
2170                                 {
2171                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2172                                                 this.deadflag = DEAD_RESPAWNING;
2173                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2174                                                 this.deadflag = DEAD_DEAD;
2175                                         break;
2176                                 }
2177                                 case DEAD_DEAD:
2178                                 {
2179                                         if (button_pressed)
2180                                                 this.deadflag = DEAD_RESPAWNABLE;
2181                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2182                                                 this.deadflag = DEAD_RESPAWNING;
2183                                         break;
2184                                 }
2185                                 case DEAD_RESPAWNABLE:
2186                                 {
2187                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2188                                                 this.deadflag = DEAD_RESPAWNING;
2189                                         break;
2190                                 }
2191                                 case DEAD_RESPAWNING:
2192                                 {
2193                                         if (time > this.respawn_time)
2194                                         {
2195                                                 this.respawn_time = time + 1; // only retry once a second
2196                                                 this.respawn_time_max = this.respawn_time;
2197                                                 respawn(this);
2198                                         }
2199                                         break;
2200                                 }
2201                         }
2202
2203                         ShowRespawnCountdown(this);
2204
2205                         if (this.respawn_flags & RESPAWN_SILENT)
2206                                 STAT(RESPAWN_TIME, this) = 0;
2207                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2208                         {
2209                                 if (time < this.respawn_time)
2210                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2211                                 else if (this.deadflag != DEAD_RESPAWNING)
2212                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2213                         }
2214                         else
2215                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2216                 }
2217
2218                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2219                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2220                         STAT(RESPAWN_TIME, this) *= -1;
2221
2222                 return false;
2223         }
2224
2225         FixPlayermodel(this);
2226
2227         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2228                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2229                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2230         }
2231
2232         // reset gun alignment when dual wielding status changes
2233         // to ensure guns are always aligned right and left
2234         bool dualwielding = W_DualWielding(this);
2235         if(this.dualwielding_prev != dualwielding)
2236         {
2237                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2238                 this.dualwielding_prev = dualwielding;
2239         }
2240
2241         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2242         //if(frametime)
2243         {
2244                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2245                 {
2246                         .entity weaponentity = weaponentities[slot];
2247                         if(WEP_CVAR(vortex, charge_always))
2248                                 W_Vortex_Charge(this, weaponentity, frametime);
2249                         W_WeaponFrame(this, weaponentity);
2250                 }
2251         }
2252
2253         if (frametime)
2254         {
2255                 // WEAPONTODO: Add a weapon request for this
2256                 // rot vortex charge to the charge limit
2257                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2258                 {
2259                         .entity weaponentity = weaponentities[slot];
2260                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2261                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2262                 }
2263
2264                 player_regen(this);
2265                 player_anim(this);
2266                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2267         }
2268
2269         monsters_setstatus(this);
2270
2271         return true;
2272 }
2273
2274 .bool would_spectate;
2275 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2276 void ObserverOrSpectatorThink(entity this)
2277 {
2278         bool is_spec = IS_SPEC(this);
2279         if ( CS(this).impulse )
2280         {
2281                 int r = MinigameImpulse(this, CS(this).impulse);
2282                 if (!is_spec || r)
2283                         CS(this).impulse = 0;
2284
2285                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2286                 {
2287                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2288                         CS(this).impulse = 0;
2289                         return;
2290                 }
2291         }
2292
2293         if (this.flags & FL_JUMPRELEASED) {
2294                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2295                         this.flags &= ~FL_JUMPRELEASED;
2296                         this.flags |= FL_SPAWNING;
2297                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2298                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         if(SpectateNext(this)) {
2301                                 TRANSMUTE(Spectator, this);
2302                         } else if (is_spec) {
2303                                 TRANSMUTE(Observer, this);
2304                                 PutClientInServer(this);
2305                         }
2306                         else
2307                                 this.would_spectate = false; // unable to spectate anyone
2308                         if (is_spec)
2309                                 CS(this).impulse = 0;
2310                 } else if (is_spec) {
2311                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2312                                 this.flags &= ~FL_JUMPRELEASED;
2313                                 if(SpectatePrev(this)) {
2314                                         TRANSMUTE(Spectator, this);
2315                                 } else {
2316                                         TRANSMUTE(Observer, this);
2317                                         PutClientInServer(this);
2318                                 }
2319                                 CS(this).impulse = 0;
2320                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2321                                 this.would_spectate = false;
2322                                 this.flags &= ~FL_JUMPRELEASED;
2323                                 TRANSMUTE(Observer, this);
2324                                 PutClientInServer(this);
2325                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2326                                 PutObserverInServer(this);
2327                                 this.would_spectate = true;
2328                         }
2329                 }
2330                 else {
2331                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2332                         if (PHYS_INPUT_BUTTON_USE(this))
2333                                 wouldclip = !wouldclip;
2334                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2335                         set_movetype(this, preferred_movetype);
2336                 }
2337         } else { // jump pressed
2338                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2339                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2340                         this.flags |= FL_JUMPRELEASED;
2341                         if(this.flags & FL_SPAWNING)
2342                         {
2343                                 this.flags &= ~FL_SPAWNING;
2344                                 if(joinAllowed(this))
2345                                         Join(this);
2346                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2347                                         CS(this).autojoin_checked = -1;
2348                                 return;
2349                         }
2350                 }
2351                 if(is_spec && !SpectateUpdate(this))
2352                         PutObserverInServer(this);
2353         }
2354         if (is_spec)
2355                 this.flags |= FL_CLIENT | FL_NOTARGET;
2356 }
2357
2358 void PlayerUseKey(entity this)
2359 {
2360         if (!IS_PLAYER(this))
2361                 return;
2362
2363         if(this.vehicle)
2364         {
2365                 if(!game_stopped)
2366                 {
2367                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2368                         return;
2369                 }
2370         }
2371         else if(autocvar_g_vehicles_enter)
2372         {
2373                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2374                 {
2375                         entity head, closest_target = NULL;
2376                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2377
2378                         while(head) // find the closest acceptable target to enter
2379                         {
2380                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2381                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2382                                 {
2383                                         if(closest_target)
2384                                         {
2385                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2386                                                 { closest_target = head; }
2387                                         }
2388                                         else { closest_target = head; }
2389                                 }
2390
2391                                 head = head.chain;
2392                         }
2393
2394                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2395                 }
2396         }
2397
2398         // a use key was pressed; call handlers
2399         MUTATOR_CALLHOOK(PlayerUseKey, this);
2400 }
2401
2402
2403 /*
2404 =============
2405 PlayerPreThink
2406
2407 Called every frame for each client before the physics are run
2408 =============
2409 */
2410 .float last_vehiclecheck;
2411 void PlayerPreThink (entity this)
2412 {
2413         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2414         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2415
2416         WarpZone_PlayerPhysics_FixVAngle(this);
2417
2418         if (frametime) {
2419                 // physics frames: update anticheat stuff
2420                 anticheat_prethink(this);
2421
2422                 // WORKAROUND: only use dropclient in server frames (frametime set).
2423                 // Never use it in cl_movement frames (frametime zero).
2424                 if (blockSpectators && IS_REAL_CLIENT(this)
2425                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2426                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2427                 {
2428                         if (dropclient_schedule(this))
2429                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2430                 }
2431         }
2432
2433         zoomstate_set = false;
2434
2435         // Check for nameless players
2436         if (this.netname == "" || this.netname != CS(this).netname_previous)
2437         {
2438                 bool assume_unchanged = (CS(this).netname_previous == "");
2439                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2440                 {
2441                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2442                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2443                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2444                         assume_unchanged = false;
2445                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2446                 }
2447                 if (isInvisibleString(this.netname))
2448                 {
2449                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2450                         sprint(this, "Warning: invisible names are not allowed.\n");
2451                         assume_unchanged = false;
2452                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2453                 }
2454                 if (!assume_unchanged && autocvar_sv_eventlog)
2455                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2456                 strcpy(CS(this).netname_previous, this.netname);
2457         }
2458
2459         // version nagging
2460         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2461         CS(this).version_nagtime = 0;
2462         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2463             // git client
2464         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2465             // git server
2466             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2467         } else {
2468             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2469             if (r < 0) { // old client
2470                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2471             } else if (r > 0) { // old server
2472                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2473             }
2474         }
2475     }
2476
2477         // GOD MODE info
2478         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2479         {
2480                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2481                 this.max_armorvalue = 0;
2482         }
2483
2484         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2485         {
2486                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2487                 {
2488                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2489                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2490                         if (this.iceblock)
2491                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2492
2493                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2494                                 Unfreeze(this, false);
2495                 }
2496                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2497                 {
2498                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2499                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2500
2501                         if (GetResource(this, RES_HEALTH) < 1)
2502                         {
2503                                 if (this.vehicle)
2504                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2505                                 if(this.event_damage)
2506                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2507                         }
2508                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2509                                 Unfreeze(this, false);
2510                 }
2511         }
2512
2513         MUTATOR_CALLHOOK(PlayerPreThink, this);
2514
2515         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2516         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2517         {
2518                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2519                 {
2520                         if(!it.owner)
2521                         {
2522                                 if(!it.team || SAME_TEAM(this, it))
2523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2524                                 else if(autocvar_g_vehicles_steal)
2525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2526                         }
2527                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2528                         {
2529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2530                         }
2531                 });
2532
2533                 this.last_vehiclecheck = time + 1;
2534         }
2535
2536         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2537         {
2538                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2539                         PlayerUseKey(this);
2540                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2541         }
2542
2543         if (IS_REAL_CLIENT(this))
2544                 PrintWelcomeMessage(this);
2545
2546         if (IS_PLAYER(this)) {
2547                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2548                         error("Client can't be spawned as player on connection!");
2549                 if(!PlayerThink(this))
2550                         return;
2551         }
2552         else if (game_stopped || intermission_running) {
2553                 if(intermission_running)
2554                         IntermissionThink(this);
2555                 return;
2556         }
2557         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2558         {
2559                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2560                 CS(this).autojoin_checked = 1;
2561                 // don't do this in ClientConnect
2562                 // many things can go wrong if a client is spawned as player on connection
2563                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2564                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2565                                 && (!teamplay || autocvar_g_balance_teams)))
2566                 {
2567                         campaign_bots_may_start = true;
2568                         if(joinAllowed(this))
2569                                 Join(this);
2570                         return;
2571                 }
2572         }
2573         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2574                 ObserverOrSpectatorThink(this);
2575         }
2576
2577         // WEAPONTODO: Add weapon request for this
2578         if (!zoomstate_set) {
2579                 bool wep_zoomed = false;
2580                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2581                 {
2582                         .entity weaponentity = weaponentities[slot];
2583                         Weapon thiswep = this.(weaponentity).m_weapon;
2584                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2585                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2586                 }
2587                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2588         }
2589
2590         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2591         {
2592                 CS(this).teamkill_soundtime = 0;
2593
2594                 entity e = CS(this).teamkill_soundsource;
2595                 entity oldpusher = e.pusher;
2596                 e.pusher = this;
2597                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2598                 e.pusher = oldpusher;
2599         }
2600
2601         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2602                 CS(this).taunt_soundtime = 0;
2603                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2604         }
2605
2606         target_voicescript_next(this);
2607 }
2608
2609 void DrownPlayer(entity this)
2610 {
2611         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2612                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2613         {
2614                 STAT(AIR_FINISHED, this) = 0;
2615                 return;
2616         }
2617
2618         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2619         {
2620                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2621                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2622                 STAT(AIR_FINISHED, this) = 0;
2623         }
2624         else
2625         {
2626                 if (!STAT(AIR_FINISHED, this))
2627                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2628                 if (STAT(AIR_FINISHED, this) < time)
2629                 {       // drown!
2630                         if (this.pain_finished < time)
2631                         {
2632                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2633                                 this.pain_finished = time + 0.5;
2634                         }
2635                 }
2636         }
2637 }
2638
2639 .bool move_qcphysics;
2640
2641 void Player_Physics(entity this)
2642 {
2643         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2644
2645         if(!this.move_qcphysics)
2646                 return;
2647
2648         if(!frametime && !CS(this).pm_frametime)
2649                 return;
2650
2651         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2652
2653         CS(this).pm_frametime = 0;
2654 }
2655
2656 /*
2657 =============
2658 PlayerPostThink
2659
2660 Called every frame for each client after the physics are run
2661 =============
2662 */
2663 void PlayerPostThink (entity this)
2664 {
2665         Player_Physics(this);
2666
2667         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2668         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2669         if (IS_REAL_CLIENT(this))
2670         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2671         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2672         {
2673                 int totalClients = 0;
2674                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2675                 {
2676                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2677                         {
2678                                 ++totalClients;
2679                         });
2680                 }
2681
2682                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2683                 { /* do nothing */ }
2684                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2685                 {
2686                         if (CS(this).idlekick_lasttimeleft)
2687                         {
2688                                 CS(this).idlekick_lasttimeleft = 0;
2689                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2690                         }
2691                 }
2692                 else
2693                 {
2694                         float maxidle_time = autocvar_sv_maxidle;
2695                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2696                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2697                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2698                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2699                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2700                         {
2701                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2702                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2703                                 else
2704                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2705                         }
2706                         if (timeleft <= 0) {
2707                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2708                                 {
2709                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2710                                         if (this.caplayer)
2711                                                 this.caplayer = 0;
2712                                         this.lms_spectate_warning = 2; // TODO: mutator hook for players forcibly moved to spectator?
2713                                         PutObserverInServer(this);
2714                                 }
2715                                 else
2716                                 {
2717                                         if (dropclient_schedule(this))
2718                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2719                                 }
2720                                 return;
2721                         }
2722                         else if (timeleft <= countdown_time) {
2723                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2724                                         play2(this, SND(TALK2));
2725                                 CS(this).idlekick_lasttimeleft = timeleft;
2726                         }
2727                 }
2728         }
2729
2730         CheatFrame(this);
2731
2732         if (game_stopped)
2733         {
2734                 this.solid = SOLID_NOT;
2735                 this.takedamage = DAMAGE_NO;
2736                 set_movetype(this, MOVETYPE_NONE);
2737                 CS(this).teamkill_complain = 0;
2738                 CS(this).teamkill_soundtime = 0;
2739                 CS(this).teamkill_soundsource = NULL;
2740         }
2741
2742         if (IS_PLAYER(this)) {
2743                 if(this.death_time == time && IS_DEAD(this))
2744                 {
2745                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2746                         // once all the damage events of this frame have been processed with normal size
2747                         this.maxs.z = 5;
2748                         setsize(this, this.mins, this.maxs);
2749                 }
2750                 DrownPlayer(this);
2751                 UpdateChatBubble(this);
2752                 if (CS(this).impulse) ImpulseCommands(this);
2753                 GetPressedKeys(this);
2754                 if (game_stopped)
2755                 {
2756                         CSQCMODEL_AUTOUPDATE(this);
2757                         return;
2758                 }
2759         }
2760         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2761         {
2762                 CS(this).pressedkeys = 0;
2763                 STAT(PRESSED_KEYS, this) = 0;
2764         }
2765
2766         if (this.waypointsprite_attachedforcarrier) {
2767                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2768                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2769         }
2770
2771         CSQCMODEL_AUTOUPDATE(this);
2772 }
2773
2774 // hack to copy the button fields from the client entity to the Client State
2775 void PM_UpdateButtons(entity this, entity store)
2776 {
2777         if(this.impulse)
2778                 store.impulse = this.impulse;
2779         this.impulse = 0;
2780
2781         bool typing = this.buttonchat || this.button12;
2782
2783         store.button0 = (typing) ? 0 : this.button0;
2784         //button1?!
2785         store.button2 = (typing) ? 0 : this.button2;
2786         store.button3 = (typing) ? 0 : this.button3;
2787         store.button4 = this.button4;
2788         store.button5 = (typing) ? 0 : this.button5;
2789         store.button6 = this.button6;
2790         store.button7 = this.button7;
2791         store.button8 = this.button8;
2792         store.button9 = this.button9;
2793         store.button10 = this.button10;
2794         store.button11 = this.button11;
2795         store.button12 = this.button12;
2796         store.button13 = this.button13;
2797         store.button14 = this.button14;
2798         store.button15 = this.button15;
2799         store.button16 = this.button16;
2800         store.buttonuse = this.buttonuse;
2801         store.buttonchat = this.buttonchat;
2802
2803         store.cursor_active = this.cursor_active;
2804         store.cursor_screen = this.cursor_screen;
2805         store.cursor_trace_start = this.cursor_trace_start;
2806         store.cursor_trace_endpos = this.cursor_trace_endpos;
2807         store.cursor_trace_ent = this.cursor_trace_ent;
2808
2809         store.ping = this.ping;
2810         store.ping_packetloss = this.ping_packetloss;
2811         store.ping_movementloss = this.ping_movementloss;
2812
2813         store.v_angle = this.v_angle;
2814         store.movement = this.movement;
2815 }
2816
2817 NET_HANDLE(fpsreport, bool)
2818 {
2819         int fps = ReadShort();
2820         PlayerScore_Set(sender, SP_FPS, fps);
2821         return true;
2822 }