qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/_mod.qh"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     ClientConnect(this);
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     PutClientInServer(this);
  63 }
  64
  65 void PutObserverInServer(entity this);
  66
  67 STATIC_METHOD(Client, Remove, void(Client this))
  68 {
  69     TRANSMUTE(Observer, this);
  70     PutClientInServer(this);
  71     ClientDisconnect(this);
  72 }
  73
  74 void send_CSQC_teamnagger() {
  75         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  76 }
  77
  78 int CountSpectators(entity player, entity to)
  79 {
  80         if(!player) { return 0; } // not sure how, but best to be safe
  81
  82         int spec_count = 0;
  83
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  85         {
  86                 spec_count++;
  87         });
  88
  89         return spec_count;
  90 }
  91
  92 void WriteSpectators(entity player, entity to)
  93 {
  94         if(!player) { return; } // not sure how, but best to be safe
  95
  96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  97         {
  98                 WriteByte(MSG_ENTITY, num_for_edict(it));
  99         });
 100 }
 101
 102 bool ClientData_Send(entity this, entity to, int sf)
 103 {
 104         assert(to == this.owner, return false);
 105
 106         entity e = to;
 107         if (IS_SPEC(e)) e = e.enemy;
 108
 109         sf = 0;
 110         if (e.race_completed)       sf |= 1; // forced scoreboard
 111         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 112         if (e.zoomstate)            sf |= 4; // zoomed
 113         if (e.porto_v_angle_held)   sf |= 8; // angles held
 114         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 115
 116         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 117         WriteByte(MSG_ENTITY, sf);
 118
 119         if (sf & 2)
 120         {
 121                 WriteByte(MSG_ENTITY, to.spectatee_status);
 122         }
 123         if (sf & 8)
 124         {
 125                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 126                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 127         }
 128
 129         if(sf & 16)
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         this.clientdata.drawonlytoclient = this;
 143         this.clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(this.clientdata);
 149         this.clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         e.clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 158 }
 159
 160 .string netname_previous;
 161
 162 void SetSpectatee(entity this, entity spectatee);
 163 void SetSpectatee_status(entity this, int spectatee_num);
 164
 165
 166 /*
 167 =============
 168 CheckPlayerModel
 169
 170 Checks if the argument string can be a valid playermodel.
 171 Returns a valid one in doubt.
 172 =============
 173 */
 174 string FallbackPlayerModel;
 175 string CheckPlayerModel(string plyermodel) {
 176         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 177         {
 178                 // note: we cannot summon Don Strunzone here, some player may
 179                 // still have the model string set. In case anyone manages how
 180                 // to change a cvar default, we'll have a small leak here.
 181                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 182         }
 183         // only in right path
 184         if( substring(plyermodel,0,14) != "models/player/")
 185                 return FallbackPlayerModel;
 186         // only good file extensions
 187         if(substring(plyermodel,-4,4) != ".zym")
 188         if(substring(plyermodel,-4,4) != ".dpm")
 189         if(substring(plyermodel,-4,4) != ".iqm")
 190         if(substring(plyermodel,-4,4) != ".md3")
 191         if(substring(plyermodel,-4,4) != ".psk")
 192                 return FallbackPlayerModel;
 193         // forbid the LOD models
 194         if(substring(plyermodel, -9,5) == "_lod1")
 195                 return FallbackPlayerModel;
 196         if(substring(plyermodel, -9,5) == "_lod2")
 197                 return FallbackPlayerModel;
 198         if(plyermodel != strtolower(plyermodel))
 199                 return FallbackPlayerModel;
 200         // also, restrict to server models
 201         if(autocvar_sv_servermodelsonly)
 202         {
 203                 if(!fexists(plyermodel))
 204                         return FallbackPlayerModel;
 205         }
 206         return plyermodel;
 207 }
 208
 209 void setplayermodel(entity e, string modelname)
 210 {
 211         precache_model(modelname);
 212         _setmodel(e, modelname);
 213         player_setupanimsformodel(e);
 214         if(!autocvar_g_debug_globalsounds)
 215                 UpdatePlayerSounds(e);
 216 }
 217
 218 void FixPlayermodel(entity player);
 219 /** putting a client as observer in the server */
 220 void PutObserverInServer(entity this)
 221 {
 222     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 223         PlayerState_detach(this);
 224
 225         if (IS_PLAYER(this) && this.health >= 1) {
 226         // despawn effect
 227                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 228     }
 229
 230     {
 231         entity spot = SelectSpawnPoint(this, true);
 232         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 233         this.angles = spot.angles;
 234         this.angles_z = 0;
 235         this.fixangle = true;
 236         // offset it so that the spectator spawns higher off the ground, looks better this way
 237         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 238         this.prevorigin = this.origin;
 239         if (IS_REAL_CLIENT(this))
 240         {
 241             msg_entity = this;
 242             WriteByte(MSG_ONE, SVC_SETVIEW);
 243             WriteEntity(MSG_ONE, this);
 244         }
 245         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247         if(!autocvar_g_debug_globalsounds)
 248         {
 249                 // needed for player sounds
 250                 this.model = "";
 251                 FixPlayermodel(this);
 252         }
 253         setmodel(this, MDL_Null);
 254         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 255         this.view_ofs = '0 0 0';
 256     }
 257
 258     RemoveGrapplingHook(this);
 259         Portal_ClearAll(this);
 260         Unfreeze(this);
 261         SetSpectatee(this, NULL);
 262
 263         if (this.alivetime)
 264         {
 265                 if (!warmup_stage)
 266                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 267                 this.alivetime = 0;
 268         }
 269
 270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 271
 272         WaypointSprite_PlayerDead(this);
 273
 274         if (mutator_returnvalue) {
 275             // mutator prevents resetting teams+score
 276         } else {
 277                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 278         this.frags = FRAGS_SPECTATOR;
 279         PlayerScore_Clear(this);  // clear scores when needed
 280     }
 281
 282         if (this.killcount != FRAGS_SPECTATOR)
 283         {
 284                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 285                 if(!intermission_running)
 286                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 287                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 288
 289                 if(this.just_joined == false) {
 290                         LogTeamchange(this.playerid, -1, 4);
 291                 } else
 292                         this.just_joined = false;
 293         }
 294
 295         accuracy_resend(this);
 296
 297         this.spectatortime = time;
 298         this.bot_attack = false;
 299     this.hud = HUD_NORMAL;
 300         TRANSMUTE(Observer, this);
 301         this.iscreature = false;
 302         this.teleportable = TELEPORT_SIMPLE;
 303         if(this.damagedbycontents)
 304                 IL_REMOVE(g_damagedbycontents, this);
 305         this.damagedbycontents = false;
 306         this.health = FRAGS_SPECTATOR;
 307         SetSpectatee_status(this, etof(this));
 308         this.takedamage = DAMAGE_NO;
 309         this.solid = SOLID_NOT;
 310         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 311         this.flags = FL_CLIENT | FL_NOTARGET;
 312         this.armorvalue = 666;
 313         this.effects = 0;
 314         this.armorvalue = autocvar_g_balance_armor_start;
 315         this.pauserotarmor_finished = 0;
 316         this.pauserothealth_finished = 0;
 317         this.pauseregen_finished = 0;
 318         this.damageforcescale = 0;
 319         this.death_time = 0;
 320         this.respawn_flags = 0;
 321         this.respawn_time = 0;
 322         this.stat_respawn_time = 0;
 323         this.alpha = 0;
 324         this.scale = 0;
 325         this.fade_time = 0;
 326         this.pain_frame = 0;
 327         this.pain_finished = 0;
 328         this.strength_finished = 0;
 329         this.invincible_finished = 0;
 330         this.superweapons_finished = 0;
 331         this.pushltime = 0;
 332         this.istypefrag = 0;
 333         setthink(this, func_null);
 334         this.nextthink = 0;
 335         this.hook_time = 0;
 336         this.deadflag = DEAD_NO;
 337         this.crouch = false;
 338         this.revival_time = 0;
 339
 340         this.items = 0;
 341         this.weapons = '0 0 0';
 342         this.drawonlytoclient = this;
 343
 344         this.weaponname = "";
 345         this.weaponmodel = "";
 346         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 347         {
 348                 this.weaponentities[slot] = NULL;
 349         }
 350         this.exteriorweaponentity = NULL;
 351         this.killcount = FRAGS_SPECTATOR;
 352         this.velocity = '0 0 0';
 353         this.avelocity = '0 0 0';
 354         this.punchangle = '0 0 0';
 355         this.punchvector = '0 0 0';
 356         this.oldvelocity = this.velocity;
 357         this.fire_endtime = -1;
 358         this.event_damage = func_null;
 359
 360         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 361         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 362         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 363 }
 364
 365 int player_getspecies(entity this)
 366 {
 367         get_model_parameters(this.model, this.skin);
 368         int s = get_model_parameters_species;
 369         get_model_parameters(string_null, 0);
 370         if (s < 0) return SPECIES_HUMAN;
 371         return s;
 372 }
 373
 374 .float model_randomizer;
 375 void FixPlayermodel(entity player)
 376 {
 377         string defaultmodel = "";
 378         int defaultskin = 0;
 379         if(autocvar_sv_defaultcharacter)
 380         {
 381                 if(teamplay)
 382                 {
 383                         string s = Static_Team_ColorName_Lower(player.team);
 384                         if (s != "neutral")
 385                         {
 386                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 387                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 388                         }
 389                 }
 390
 391                 if(defaultmodel == "")
 392                 {
 393                         defaultmodel = autocvar_sv_defaultplayermodel;
 394                         defaultskin = autocvar_sv_defaultplayerskin;
 395                 }
 396
 397                 int n = tokenize_console(defaultmodel);
 398                 if(n > 0)
 399                 {
 400                         defaultmodel = argv(floor(n * player.model_randomizer));
 401                         // However, do NOT randomize if the player-selected model is in the list.
 402                         for (int i = 0; i < n; ++i)
 403                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 404                                         defaultmodel = argv(i);
 405                 }
 406
 407                 int i = strstrofs(defaultmodel, ":", 0);
 408                 if(i >= 0)
 409                 {
 410                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 411                         defaultmodel = substring(defaultmodel, 0, i);
 412                 }
 413         }
 414         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 415         {
 416                 if(teamplay)
 417                 {
 418                         string s = Static_Team_ColorName_Lower(player.team);
 419                         if (s != "neutral")
 420                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 421                 }
 422
 423                 if(!defaultskin)
 424                         defaultskin = autocvar_sv_defaultplayerskin;
 425         }
 426
 427         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 428         defaultmodel = M_ARGV(0, string);
 429         defaultskin = M_ARGV(1, int);
 430
 431         bool chmdl = false;
 432         int oldskin;
 433         if(defaultmodel != "")
 434         {
 435                 if (defaultmodel != player.model)
 436                 {
 437                         vector m1 = player.mins;
 438                         vector m2 = player.maxs;
 439                         setplayermodel (player, defaultmodel);
 440                         setsize (player, m1, m2);
 441                         chmdl = true;
 442                 }
 443
 444                 oldskin = player.skin;
 445                 player.skin = defaultskin;
 446         } else {
 447                 if (player.playermodel != player.model || player.playermodel == "")
 448                 {
 449                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 450                         vector m1 = player.mins;
 451                         vector m2 = player.maxs;
 452                         setplayermodel (player, player.playermodel);
 453                         setsize (player, m1, m2);
 454                         chmdl = true;
 455                 }
 456
 457                 if(!autocvar_sv_defaultcharacterskin)
 458                 {
 459                         oldskin = player.skin;
 460                         player.skin = stof(player.playerskin);
 461                 }
 462                 else
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = defaultskin;
 466                 }
 467         }
 468
 469         if(chmdl || oldskin != player.skin) // model or skin has changed
 470         {
 471                 player.species = player_getspecies(player); // update species
 472                 if(!autocvar_g_debug_globalsounds)
 473                         UpdatePlayerSounds(player); // update skin sounds
 474         }
 475
 476         if(!teamplay)
 477                 if(strlen(autocvar_sv_defaultplayercolors))
 478                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 479                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 480 }
 481
 482
 483 /** Called when a client spawns in the server */
 484 void PutClientInServer(entity this)
 485 {
 486         if (IS_BOT_CLIENT(this)) {
 487                 TRANSMUTE(Player, this);
 488         } else if (IS_REAL_CLIENT(this)) {
 489                 msg_entity = this;
 490                 WriteByte(MSG_ONE, SVC_SETVIEW);
 491                 WriteEntity(MSG_ONE, this);
 492         }
 493         if (gameover) {
 494                 TRANSMUTE(Observer, this);
 495         }
 496
 497         SetSpectatee(this, NULL);
 498
 499         // reset player keys
 500         this.itemkeys = 0;
 501
 502         MUTATOR_CALLHOOK(PutClientInServer, this);
 503
 504         if (IS_OBSERVER(this)) {
 505                 PutObserverInServer(this);
 506         } else if (IS_PLAYER(this)) {
 507                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 508
 509                 PlayerState_attach(this);
 510                 accuracy_resend(this);
 511
 512                 if (this.team < 0)
 513                         JoinBestTeam(this, false, true);
 514
 515                 entity spot = SelectSpawnPoint(this, false);
 516                 if (!spot) {
 517                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 518                         return; // spawn failed
 519                 }
 520
 521                 TRANSMUTE(Player, this);
 522
 523                 this.wasplayer = true;
 524                 this.iscreature = true;
 525                 this.teleportable = TELEPORT_NORMAL;
 526                 if(!this.damagedbycontents)
 527                         IL_PUSH(g_damagedbycontents, this);
 528                 this.damagedbycontents = true;
 529                 set_movetype(this, MOVETYPE_WALK);
 530                 this.solid = SOLID_SLIDEBOX;
 531                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 532                 if (autocvar_g_playerclip_collisions)
 533                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 534                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 535                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 536                 this.frags = FRAGS_PLAYER;
 537                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 538                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 539                 if (autocvar__notarget)
 540                         this.flags |= FL_NOTARGET;
 541                 this.takedamage = DAMAGE_AIM;
 542                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 543                 this.dmg = 2; // WTF
 544
 545                 if (warmup_stage) {
 546                         this.ammo_shells = warmup_start_ammo_shells;
 547                         this.ammo_nails = warmup_start_ammo_nails;
 548                         this.ammo_rockets = warmup_start_ammo_rockets;
 549                         this.ammo_cells = warmup_start_ammo_cells;
 550                         this.ammo_plasma = warmup_start_ammo_plasma;
 551                         this.ammo_fuel = warmup_start_ammo_fuel;
 552                         this.health = warmup_start_health;
 553                         this.armorvalue = warmup_start_armorvalue;
 554                         this.weapons = WARMUP_START_WEAPONS;
 555                 } else {
 556                         this.ammo_shells = start_ammo_shells;
 557                         this.ammo_nails = start_ammo_nails;
 558                         this.ammo_rockets = start_ammo_rockets;
 559                         this.ammo_cells = start_ammo_cells;
 560                         this.ammo_plasma = start_ammo_plasma;
 561                         this.ammo_fuel = start_ammo_fuel;
 562                         this.health = start_health;
 563                         this.armorvalue = start_armorvalue;
 564                         this.weapons = start_weapons;
 565                 }
 566                 SetSpectatee_status(this, 0);
 567
 568                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 569
 570                 this.items = start_items;
 571
 572                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 573                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 574                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 575                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 576                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 577                 // extend the pause of rotting if client was reset at the beginning of the countdown
 578                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 579                         float f = game_starttime - time;
 580                         this.spawnshieldtime += f;
 581                         this.pauserotarmor_finished += f;
 582                         this.pauserothealth_finished += f;
 583                         this.pauseregen_finished += f;
 584                 }
 585                 this.damageforcescale = 2;
 586                 this.death_time = 0;
 587                 this.respawn_flags = 0;
 588                 this.respawn_time = 0;
 589                 this.stat_respawn_time = 0;
 590                 this.scale = autocvar_sv_player_scale;
 591                 this.fade_time = 0;
 592                 this.pain_frame = 0;
 593                 this.pain_finished = 0;
 594                 this.pushltime = 0;
 595                 setthink(this, func_null); // players have no think function
 596                 this.nextthink = 0;
 597                 this.dmg_team = 0;
 598                 this.ballistics_density = autocvar_g_ballistics_density_player;
 599
 600                 this.deadflag = DEAD_NO;
 601
 602                 this.angles = spot.angles;
 603                 this.angles_z = 0; // never spawn tilted even if the spot says to
 604                 if (IS_BOT_CLIENT(this))
 605                         this.v_angle = this.angles;
 606                 this.fixangle = true; // turn this way immediately
 607                 this.oldvelocity = this.velocity = '0 0 0';
 608                 this.avelocity = '0 0 0';
 609                 this.punchangle = '0 0 0';
 610                 this.punchvector = '0 0 0';
 611
 612                 this.strength_finished = 0;
 613                 this.invincible_finished = 0;
 614                 this.fire_endtime = -1;
 615                 this.revival_time = 0;
 616                 this.air_finished = time + 12;
 617
 618                 entity spawnevent = new_pure(spawnevent);
 619                 spawnevent.owner = this;
 620                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 621
 622                 // Cut off any still running player sounds.
 623                 stopsound(this, CH_PLAYER_SINGLE);
 624
 625                 this.model = "";
 626                 FixPlayermodel(this);
 627                 this.drawonlytoclient = NULL;
 628
 629                 this.crouch = false;
 630                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 631                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 632                 this.spawnorigin = spot.origin;
 633                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 634                 // don't reset back to last position, even if new position is stuck in solid
 635                 this.oldorigin = this.origin;
 636                 this.prevorigin = this.origin;
 637                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 638                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 639                 this.hud = HUD_NORMAL;
 640
 641                 this.event_damage = PlayerDamage;
 642
 643                 this.bot_attack = true;
 644                 this.monster_attack = true;
 645
 646                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 647
 648                 if (this.killcount == FRAGS_SPECTATOR) {
 649                         PlayerScore_Clear(this);
 650                         this.killcount = 0;
 651                 }
 652
 653                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 654                 {
 655                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 656                 }
 657                 this.alpha = default_player_alpha;
 658                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 659                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 660
 661                 this.speedrunning = false;
 662
 663                 target_voicescript_clear(this);
 664
 665                 // reset fields the weapons may use
 666                 FOREACH(Weapons, true, LAMBDA(
 667                         it.wr_resetplayer(it, this);
 668                         // reload all reloadable weapons
 669                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 670                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 671                         }
 672                 ));
 673
 674                 {
 675                         string s = spot.target;
 676                         spot.target = string_null;
 677                         SUB_UseTargets(spot, this, NULL);
 678                         spot.target = s;
 679                 }
 680
 681                 Unfreeze(this);
 682
 683                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 684
 685                 if (autocvar_spawn_debug)
 686                 {
 687                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 688                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 689                 }
 690
 691                 PS(this).m_switchweapon = w_getbestweapon(this);
 692                 this.cnt = -1; // W_LastWeapon will not complain
 693                 PS(this).m_weapon = WEP_Null;
 694                 this.weaponname = "";
 695                 PS(this).m_switchingweapon = WEP_Null;
 696
 697                 if (!warmup_stage && !this.alivetime)
 698                         this.alivetime = time;
 699
 700                 antilag_clear(this, CS(this));
 701         }
 702 }
 703
 704 void ClientInit_misc(entity this);
 705
 706 .float ebouncefactor, ebouncestop; // electro's values
 707 // TODO do we need all these fields, or should we stop autodetecting runtime
 708 // changes and just have a console command to update this?
 709 bool ClientInit_SendEntity(entity this, entity to, int sf)
 710 {
 711         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 712         return = true;
 713         msg_entity = to;
 714         // MSG_INIT replacement
 715         // TODO: make easier to use
 716         Registry_send_all();
 717         W_PROP_reload(MSG_ONE, to);
 718         ClientInit_misc(this);
 719         MUTATOR_CALLHOOK(Ent_Init);
 720 }
 721 void ClientInit_misc(entity this)
 722 {
 723         int channel = MSG_ONE;
 724         WriteHeader(channel, ENT_CLIENT_INIT);
 725         WriteByte(channel, g_nexball_meter_period * 32);
 726         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 727         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 728         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 729         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 730         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 731         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 732         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 733         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 734
 735         if(sv_foginterval && world.fog != "")
 736                 WriteString(channel, world.fog);
 737         else
 738                 WriteString(channel, "");
 739         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 740         WriteByte(channel, serverflags);
 741         WriteCoord(channel, autocvar_g_trueaim_minrange);
 742 }
 743
 744 void ClientInit_CheckUpdate(entity this)
 745 {
 746         this.nextthink = time;
 747         if(this.count != autocvar_g_balance_armor_blockpercent)
 748         {
 749                 this.count = autocvar_g_balance_armor_blockpercent;
 750                 this.SendFlags |= 1;
 751         }
 752 }
 753
 754 void ClientInit_Spawn()
 755 {
 756         entity e = new_pure(clientinit);
 757         setthink(e, ClientInit_CheckUpdate);
 758         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 759
 760         ClientInit_CheckUpdate(e);
 761 }
 762
 763 /*
 764 =============
 765 SetNewParms
 766 =============
 767 */
 768 void SetNewParms ()
 769 {
 770         // initialize parms for a new player
 771         parm1 = -(86400 * 366);
 772
 773         MUTATOR_CALLHOOK(SetNewParms);
 774 }
 775
 776 /*
 777 =============
 778 SetChangeParms
 779 =============
 780 */
 781 void SetChangeParms (entity this)
 782 {
 783         // save parms for level change
 784         parm1 = this.parm_idlesince - time;
 785
 786         MUTATOR_CALLHOOK(SetChangeParms);
 787 }
 788
 789 /*
 790 =============
 791 DecodeLevelParms
 792 =============
 793 */
 794 void DecodeLevelParms(entity this)
 795 {
 796         // load parms
 797         this.parm_idlesince = parm1;
 798         if (this.parm_idlesince == -(86400 * 366))
 799                 this.parm_idlesince = time;
 800
 801         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 802         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 803
 804         MUTATOR_CALLHOOK(DecodeLevelParms);
 805 }
 806
 807 /*
 808 =============
 809 ClientKill
 810
 811 Called when a client types 'kill' in the console
 812 =============
 813 */
 814
 815 .float clientkill_nexttime;
 816 void ClientKill_Now_TeamChange(entity this)
 817 {
 818         if(this.killindicator_teamchange == -1)
 819         {
 820                 JoinBestTeam( this, false, true );
 821         }
 822         else if(this.killindicator_teamchange == -2)
 823         {
 824                 if(blockSpectators)
 825                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 826                 PutObserverInServer(this);
 827         }
 828         else
 829                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 830         this.killindicator_teamchange = 0;
 831 }
 832
 833 void ClientKill_Now(entity this)
 834 {
 835         if(this.vehicle)
 836         {
 837             vehicles_exit(this.vehicle, VHEF_RELEASE);
 838             if(!this.killindicator_teamchange)
 839             {
 840             this.vehicle_health = -1;
 841             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 842             }
 843         }
 844
 845         if(this.killindicator && !wasfreed(this.killindicator))
 846                 delete(this.killindicator);
 847
 848         this.killindicator = NULL;
 849
 850         if(this.killindicator_teamchange)
 851                 ClientKill_Now_TeamChange(this);
 852
 853         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 854                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 855
 856         // now I am sure the player IS dead
 857 }
 858 void KillIndicator_Think(entity this)
 859 {
 860         if (gameover)
 861         {
 862                 this.owner.killindicator = NULL;
 863                 delete(this);
 864                 return;
 865         }
 866
 867         if (this.owner.alpha < 0 && !this.owner.vehicle)
 868         {
 869                 this.owner.killindicator = NULL;
 870                 delete(this);
 871                 return;
 872         }
 873
 874         if(this.cnt <= 0)
 875         {
 876                 ClientKill_Now(this.owner);
 877                 return;
 878         }
 879     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 880     {
 881         this.nextthink = time + 1;
 882         this.cnt -= 1;
 883     }
 884         else
 885         {
 886                 if(this.cnt <= 10)
 887                         setmodel(this, MDL_NUM(this.cnt));
 888                 if(IS_REAL_CLIENT(this.owner))
 889                 {
 890                         if(this.cnt <= 10)
 891                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 892                 }
 893                 this.nextthink = time + 1;
 894                 this.cnt -= 1;
 895         }
 896 }
 897
 898 float clientkilltime;
 899 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 900 {
 901         float killtime;
 902         float starttime;
 903
 904         if (gameover)
 905                 return;
 906
 907         killtime = autocvar_g_balance_kill_delay;
 908
 909         if(g_race_qualifying || g_cts)
 910                 killtime = 0;
 911
 912     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 913         return;
 914
 915         this.killindicator_teamchange = targetteam;
 916
 917     if(!this.killindicator)
 918         {
 919                 if(!IS_DEAD(this))
 920                 {
 921                         killtime = max(killtime, this.clientkill_nexttime - time);
 922                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 923                 }
 924
 925                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 926                 {
 927                         ClientKill_Now(this);
 928                 }
 929                 else
 930                 {
 931                         starttime = max(time, clientkilltime);
 932
 933                         this.killindicator = spawn();
 934                         this.killindicator.owner = this;
 935                         this.killindicator.scale = 0.5;
 936                         setattachment(this.killindicator, this, "");
 937                         setorigin(this.killindicator, '0 0 52');
 938                         setthink(this.killindicator, KillIndicator_Think);
 939                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 940                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 941                         this.killindicator.cnt = ceil(killtime);
 942                         this.killindicator.count = bound(0, ceil(killtime), 10);
 943                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 944
 945                         FOREACH_ENTITY_ENT(enemy, this,
 946                         {
 947                                 if(it.classname != "body")
 948                                         continue;
 949                                 it.killindicator = spawn();
 950                                 it.killindicator.owner = it;
 951                                 it.killindicator.scale = 0.5;
 952                                 setattachment(it.killindicator, it, "");
 953                                 setorigin(it.killindicator, '0 0 52');
 954                                 setthink(it.killindicator, KillIndicator_Think);
 955                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 956                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 957                                 it.killindicator.cnt = ceil(killtime);
 958                         });
 959                         this.lip = 0;
 960                 }
 961         }
 962         if(this.killindicator)
 963         {
 964                 if(targetteam == 0) // just die
 965                 {
 966                         this.killindicator.colormod = '0 0 0';
 967                         if(IS_REAL_CLIENT(this))
 968                         if(this.killindicator.cnt > 0)
 969                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 970                 }
 971                 else if(targetteam == -1) // auto
 972                 {
 973                         this.killindicator.colormod = '0 1 0';
 974                         if(IS_REAL_CLIENT(this))
 975                         if(this.killindicator.cnt > 0)
 976                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 977                 }
 978                 else if(targetteam == -2) // spectate
 979                 {
 980                         this.killindicator.colormod = '0.5 0.5 0.5';
 981                         if(IS_REAL_CLIENT(this))
 982                         if(this.killindicator.cnt > 0)
 983                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 984                 }
 985                 else
 986                 {
 987                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 988                         if(IS_REAL_CLIENT(this))
 989                         if(this.killindicator.cnt > 0)
 990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 991                 }
 992         }
 993
 994 }
 995
 996 void ClientKill (entity this)
 997 {
 998         if(gameover) return;
 999         if(this.player_blocked) return;
1000         if(STAT(FROZEN, this)) return;
1001
1002         ClientKill_TeamChange(this, 0);
1003 }
1004
1005 void FixClientCvars(entity e)
1006 {
1007         // send prediction settings to the client
1008         stuffcmd(e, "\nin_bindmap 0 0\n");
1009         if(autocvar_g_antilag == 3) // client side hitscan
1010                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1011         if(autocvar_sv_gentle)
1012                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1013
1014         MUTATOR_CALLHOOK(FixClientCvars, e);
1015 }
1016
1017 float PlayerInIDList(entity p, string idlist)
1018 {
1019         float n, i;
1020         string s;
1021
1022         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1023         if (!p.crypto_idfp)
1024                 return 0;
1025
1026         // this function allows abbreviated player IDs too!
1027         n = tokenize_console(idlist);
1028         for(i = 0; i < n; ++i)
1029         {
1030                 s = argv(i);
1031                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1032                         return 1;
1033         }
1034
1035         return 0;
1036 }
1037
1038 #ifdef DP_EXT_PRECONNECT
1039 /*
1040 =============
1041 ClientPreConnect
1042
1043 Called once (not at each match start) when a client begins a connection to the server
1044 =============
1045 */
1046 void ClientPreConnect ()
1047 {ENGINE_EVENT();
1048         if(autocvar_sv_eventlog)
1049         {
1050                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1051                         this.playerid,
1052                         etof(this),
1053                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1054                 ));
1055         }
1056 }
1057 #endif
1058
1059 /**
1060 =============
1061 ClientConnect
1062
1063 Called when a client connects to the server
1064 =============
1065 */
1066 void ClientConnect(entity this)
1067 {
1068         if (Ban_MaybeEnforceBanOnce(this)) return;
1069         assert(!IS_CLIENT(this), return);
1070         this.flags |= FL_CLIENT;
1071         assert(player_count >= 0, player_count = 0);
1072
1073 #ifdef WATERMARK
1074         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1075 #endif
1076         this.version_nagtime = time + 10 + random() * 10;
1077         TRANSMUTE(Client, this);
1078
1079         // identify the right forced team
1080         if (autocvar_g_campaign)
1081         {
1082                 if (IS_REAL_CLIENT(this)) // only players, not bots
1083                 {
1084                         switch (autocvar_g_campaign_forceteam)
1085                         {
1086                                 case 1: this.team_forced = NUM_TEAM_1; break;
1087                                 case 2: this.team_forced = NUM_TEAM_2; break;
1088                                 case 3: this.team_forced = NUM_TEAM_3; break;
1089                                 case 4: this.team_forced = NUM_TEAM_4; break;
1090                                 default: this.team_forced = 0;
1091                         }
1092                 }
1093         }
1094         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1095         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1096         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1097         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1098         else switch (autocvar_g_forced_team_otherwise)
1099         {
1100                 default: this.team_forced = 0; break;
1101                 case "red": this.team_forced = NUM_TEAM_1; break;
1102                 case "blue": this.team_forced = NUM_TEAM_2; break;
1103                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1104                 case "pink": this.team_forced = NUM_TEAM_4; break;
1105                 case "spectate":
1106                 case "spectator":
1107                         this.team_forced = -1;
1108                         break;
1109         }
1110         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1111
1112     {
1113         int id = this.playerid;
1114         this.playerid = 0; // silent
1115             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1116             this.playerid = id;
1117     }
1118
1119         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1120                 TRANSMUTE(Observer, this);
1121         } else {
1122                 if (!teamplay || autocvar_g_balance_teams) {
1123                         TRANSMUTE(Player, this);
1124                         campaign_bots_may_start = true;
1125                 } else {
1126                         TRANSMUTE(Observer, this); // do it anyway
1127                 }
1128         }
1129
1130         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1131
1132         // always track bots, don't ask for cl_allow_uidtracking
1133     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1134
1135         if (autocvar_sv_eventlog)
1136                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1137
1138         LogTeamchange(this.playerid, this.team, 1);
1139
1140         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1141
1142         this.netname_previous = strzone(this.netname);
1143
1144         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1145
1146         stuffcmd(this, clientstuff, "\n");
1147         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1148
1149         FixClientCvars(this);
1150
1151         // get version info from player
1152         stuffcmd(this, "cmd clientversion $gameversion\n");
1153
1154         // notify about available teams
1155         if (teamplay)
1156         {
1157                 CheckAllowedTeams(this);
1158                 int t = 0;
1159                 if (c1 >= 0) t |= BIT(0);
1160                 if (c2 >= 0) t |= BIT(1);
1161                 if (c3 >= 0) t |= BIT(2);
1162                 if (c4 >= 0) t |= BIT(3);
1163                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1164         }
1165         else
1166         {
1167                 stuffcmd(this, "set _teams_available 0\n");
1168         }
1169
1170         bot_relinkplayerlist();
1171
1172         this.spectatortime = time;
1173         if (blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         this.jointime = time;
1179         this.allowed_timeouts = autocvar_sv_timeout_number;
1180
1181         if (IS_REAL_CLIENT(this))
1182         {
1183                 if (!autocvar_g_campaign)
1184                 {
1185                         this.motd_actived_time = -1;
1186                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1187                 }
1188
1189                 if (g_weaponarena_weapons == WEPSET(TUBA))
1190                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1191         }
1192
1193         if (!sv_foginterval && world.fog != "")
1194                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1195
1196         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1197                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1198                         send_CSQC_teamnagger();
1199
1200         CSQCMODEL_AUTOINIT(this);
1201
1202         this.model_randomizer = random();
1203
1204         if (IS_REAL_CLIENT(this))
1205                 sv_notice_join(this);
1206
1207         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1208                 it.init_for_player(it, this);
1209         });
1210
1211         MUTATOR_CALLHOOK(ClientConnect, this);
1212 }
1213 /*
1214 =============
1215 ClientDisconnect
1216
1217 Called when a client disconnects from the server
1218 =============
1219 */
1220 .entity chatbubbleentity;
1221 void ReadyCount();
1222 void ClientDisconnect(entity this)
1223 {
1224         assert(IS_CLIENT(this), return);
1225
1226         PlayerStats_GameReport_FinalizePlayer(this);
1227         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1228         if (this.active_minigame) part_minigame(this);
1229         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1230
1231         if (autocvar_sv_eventlog)
1232                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1233
1234         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1235
1236         SetSpectatee(this, NULL);
1237
1238     MUTATOR_CALLHOOK(ClientDisconnect, this);
1239
1240         ClientState_detach(this);
1241
1242         Portal_ClearAll(this);
1243
1244         Unfreeze(this);
1245
1246         RemoveGrapplingHook(this);
1247
1248         // Here, everything has been done that requires this player to be a client.
1249
1250         this.flags &= ~FL_CLIENT;
1251
1252         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1253         if (this.killindicator) delete(this.killindicator);
1254
1255         WaypointSprite_PlayerGone(this);
1256
1257         bot_relinkplayerlist();
1258
1259         if (this.netname_previous) strunzone(this.netname_previous);
1260         if (this.clientstatus) strunzone(this.clientstatus);
1261         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1262         if (this.personal) delete(this.personal);
1263
1264         this.playerid = 0;
1265         ReadyCount();
1266         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1267 }
1268
1269 void ChatBubbleThink(entity this)
1270 {
1271         this.nextthink = time;
1272         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1273         {
1274                 if(this.owner) // but why can that ever be NULL?
1275                         this.owner.chatbubbleentity = NULL;
1276                 delete(this);
1277                 return;
1278         }
1279
1280         this.mdl = "";
1281
1282         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1283         {
1284                 if ( this.owner.active_minigame )
1285                         this.mdl = "models/sprites/minigame_busy.iqm";
1286                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1287                         this.mdl = "models/misc/chatbubble.spr";
1288         }
1289
1290         if ( this.model != this.mdl )
1291                 _setmodel(this, this.mdl);
1292
1293 }
1294
1295 void UpdateChatBubble(entity this)
1296 {
1297         if (this.alpha < 0)
1298                 return;
1299         // spawn a chatbubble entity if needed
1300         if (!this.chatbubbleentity)
1301         {
1302                 this.chatbubbleentity = new(chatbubbleentity);
1303                 this.chatbubbleentity.owner = this;
1304                 this.chatbubbleentity.exteriormodeltoclient = this;
1305                 setthink(this.chatbubbleentity, ChatBubbleThink);
1306                 this.chatbubbleentity.nextthink = time;
1307                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1308                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1309                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1310                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1311                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1312                 //this.chatbubbleentity.model = "";
1313                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1314         }
1315 }
1316
1317
1318 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1319 // added to the model skins
1320 /*void UpdateColorModHack()
1321 {
1322         float c;
1323         c = this.clientcolors & 15;
1324         // LordHavoc: only bothering to support white, green, red, yellow, blue
1325              if (!teamplay) this.colormod = '0 0 0';
1326         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1327         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1328         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1329         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1330         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1331         else this.colormod = '1 1 1';
1332 }*/
1333
1334 void respawn(entity this)
1335 {
1336         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1337         {
1338                 this.solid = SOLID_NOT;
1339                 this.takedamage = DAMAGE_NO;
1340                 set_movetype(this, MOVETYPE_FLY);
1341                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1342                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1343                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1344                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1345                 if(autocvar_g_respawn_ghosts_maxtime)
1346                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1347         }
1348
1349         CopyBody(this, 1);
1350
1351         this.effects |= EF_NODRAW; // prevent another CopyBody
1352         PutClientInServer(this);
1353 }
1354
1355 void play_countdown(entity this, float finished, Sound samp)
1356 {
1357     TC(Sound, samp);
1358         if(IS_REAL_CLIENT(this))
1359                 if(floor(finished - time - frametime) != floor(finished - time))
1360                         if(finished - time < 6)
1361                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1362 }
1363
1364 void player_powerups(entity this)
1365 {
1366         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1367         int items_prev = this.items;
1368
1369         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1370                 this.modelflags |= MF_ROCKET;
1371         else
1372                 this.modelflags &= ~MF_ROCKET;
1373
1374         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1375
1376         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1377                 return;
1378
1379         Fire_ApplyDamage(this);
1380         Fire_ApplyEffect(this);
1381
1382         if (!g_instagib)
1383         {
1384                 if (this.items & ITEM_Strength.m_itemid)
1385                 {
1386                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1387                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1388                         if (time > this.strength_finished)
1389                         {
1390                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1391                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1392                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1393                         }
1394                 }
1395                 else
1396                 {
1397                         if (time < this.strength_finished)
1398                         {
1399                                 this.items = this.items | ITEM_Strength.m_itemid;
1400                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1401                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1402                         }
1403                 }
1404                 if (this.items & ITEM_Shield.m_itemid)
1405                 {
1406                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1407                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1408                         if (time > this.invincible_finished)
1409                         {
1410                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1411                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1412                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1413                         }
1414                 }
1415                 else
1416                 {
1417                         if (time < this.invincible_finished)
1418                         {
1419                                 this.items = this.items | ITEM_Shield.m_itemid;
1420                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1422                         }
1423                 }
1424                 if (this.items & IT_SUPERWEAPON)
1425                 {
1426                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1427                         {
1428                                 this.superweapons_finished = 0;
1429                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1430                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1431                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1432                         }
1433                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1434                         {
1435                                 // don't let them run out
1436                         }
1437                         else
1438                         {
1439                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1440                                 if (time > this.superweapons_finished)
1441                                 {
1442                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1443                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1444                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1445                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1446                                 }
1447                         }
1448                 }
1449                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1450                 {
1451                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1452                         {
1453                                 this.items = this.items | IT_SUPERWEAPON;
1454                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1455                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1456                         }
1457                         else
1458                         {
1459                                 this.superweapons_finished = 0;
1460                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1461                         }
1462                 }
1463                 else
1464                 {
1465                         this.superweapons_finished = 0;
1466                 }
1467         }
1468
1469         if(autocvar_g_nodepthtestplayers)
1470                 this.effects = this.effects | EF_NODEPTHTEST;
1471
1472         if(autocvar_g_fullbrightplayers)
1473                 this.effects = this.effects | EF_FULLBRIGHT;
1474
1475         if (time >= game_starttime)
1476         if (time < this.spawnshieldtime)
1477                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1478
1479         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1480 }
1481
1482 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1483 {
1484         if(current > stable)
1485                 return current;
1486         else if(current > stable - 0.25) // when close enough, "snap"
1487                 return stable;
1488         else
1489                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1490 }
1491
1492 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1493 {
1494         if(current < stable)
1495                 return current;
1496         else if(current < stable + 0.25) // when close enough, "snap"
1497                 return stable;
1498         else
1499                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1500 }
1501
1502 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1503 {
1504         if(current > rotstable)
1505         {
1506                 if(rotframetime > 0)
1507                 {
1508                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1509                         current = max(rotstable, current - rotlinear * rotframetime);
1510                 }
1511         }
1512         else if(current < regenstable)
1513         {
1514                 if(regenframetime > 0)
1515                 {
1516                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1517                         current = min(regenstable, current + regenlinear * regenframetime);
1518                 }
1519         }
1520
1521         if(current > limit)
1522                 current = limit;
1523
1524         return current;
1525 }
1526
1527 void player_regen(entity this)
1528 {
1529         float max_mod, regen_mod, rot_mod, limit_mod;
1530         max_mod = regen_mod = rot_mod = limit_mod = 1;
1531
1532         float regen_health = autocvar_g_balance_health_regen;
1533         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1534         float regen_health_rot = autocvar_g_balance_health_rot;
1535         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1536         float regen_health_stable = autocvar_g_balance_health_regenstable;
1537         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1538         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1539                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1540         max_mod = M_ARGV(1, float);
1541         regen_mod = M_ARGV(2, float);
1542         rot_mod = M_ARGV(3, float);
1543         limit_mod = M_ARGV(4, float);
1544         regen_health = M_ARGV(5, float);
1545         regen_health_linear = M_ARGV(6, float);
1546         regen_health_rot = M_ARGV(7, float);
1547         regen_health_rotlinear = M_ARGV(8, float);
1548         regen_health_stable = M_ARGV(9, float);
1549         regen_health_rotstable = M_ARGV(10, float);
1550
1551
1552         if(!mutator_returnvalue)
1553         if(!STAT(FROZEN, this))
1554         {
1555                 float mina, maxa, limith, limita;
1556                 maxa = autocvar_g_balance_armor_rotstable;
1557                 mina = autocvar_g_balance_armor_regenstable;
1558                 limith = autocvar_g_balance_health_limit;
1559                 limita = autocvar_g_balance_armor_limit;
1560
1561                 regen_health_rotstable = regen_health_rotstable * max_mod;
1562                 regen_health_stable = regen_health_stable * max_mod;
1563                 limith = limith * limit_mod;
1564                 limita = limita * limit_mod;
1565
1566                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1567                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1568         }
1569
1570         // if player rotted to death...  die!
1571         // check this outside above checks, as player may still be able to rot to death
1572         if(this.health < 1)
1573         {
1574                 if(this.vehicle)
1575                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1576                 if(this.event_damage)
1577                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1578         }
1579
1580         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1581         {
1582                 float minf, maxf, limitf;
1583
1584                 maxf = autocvar_g_balance_fuel_rotstable;
1585                 minf = autocvar_g_balance_fuel_regenstable;
1586                 limitf = autocvar_g_balance_fuel_limit;
1587
1588                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1589         }
1590 }
1591
1592 bool zoomstate_set;
1593 void SetZoomState(entity this, float z)
1594 {
1595         if(z != this.zoomstate)
1596         {
1597                 this.zoomstate = z;
1598                 ClientData_Touch(this);
1599         }
1600         zoomstate_set = true;
1601 }
1602
1603 void GetPressedKeys(entity this)
1604 {
1605         MUTATOR_CALLHOOK(GetPressedKeys, this);
1606         int keys = this.pressedkeys;
1607         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1608         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1609         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1610         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1611
1612         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1613         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1614         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1615         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1616         this.pressedkeys = keys;
1617 }
1618
1619 /*
1620 ======================
1621 spectate mode routines
1622 ======================
1623 */
1624
1625 void SpectateCopy(entity this, entity spectatee)
1626 {
1627     TC(Client, this); TC(Client, spectatee);
1628
1629         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1630         PS(this) = PS(spectatee);
1631         this.armortype = spectatee.armortype;
1632         this.armorvalue = spectatee.armorvalue;
1633         this.ammo_cells = spectatee.ammo_cells;
1634         this.ammo_plasma = spectatee.ammo_plasma;
1635         this.ammo_shells = spectatee.ammo_shells;
1636         this.ammo_nails = spectatee.ammo_nails;
1637         this.ammo_rockets = spectatee.ammo_rockets;
1638         this.ammo_fuel = spectatee.ammo_fuel;
1639         this.clip_load = spectatee.clip_load;
1640         this.clip_size = spectatee.clip_size;
1641         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1642         this.health = spectatee.health;
1643         this.impulse = 0;
1644         this.items = spectatee.items;
1645         this.last_pickup = spectatee.last_pickup;
1646         this.hit_time = spectatee.hit_time;
1647         this.strength_finished = spectatee.strength_finished;
1648         this.invincible_finished = spectatee.invincible_finished;
1649         this.pressedkeys = spectatee.pressedkeys;
1650         this.weapons = spectatee.weapons;
1651         this.vortex_charge = spectatee.vortex_charge;
1652         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1653         this.hagar_load = spectatee.hagar_load;
1654         this.arc_heat_percent = spectatee.arc_heat_percent;
1655         this.minelayer_mines = spectatee.minelayer_mines;
1656         this.punchangle = spectatee.punchangle;
1657         this.view_ofs = spectatee.view_ofs;
1658         this.velocity = spectatee.velocity;
1659         this.dmg_take = spectatee.dmg_take;
1660         this.dmg_save = spectatee.dmg_save;
1661         this.dmg_inflictor = spectatee.dmg_inflictor;
1662         this.v_angle = spectatee.v_angle;
1663         this.angles = spectatee.v_angle;
1664         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1665         this.revive_progress = spectatee.revive_progress;
1666         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1667                 this.fixangle = true;
1668         setorigin(this, spectatee.origin);
1669         setsize(this, spectatee.mins, spectatee.maxs);
1670         SetZoomState(this, spectatee.zoomstate);
1671
1672     anticheat_spectatecopy(this, spectatee);
1673         this.hud = spectatee.hud;
1674         if(spectatee.vehicle)
1675     {
1676         this.angles = spectatee.v_angle;
1677
1678         //this.fixangle = false;
1679         //this.velocity = spectatee.vehicle.velocity;
1680         this.vehicle_health = spectatee.vehicle_health;
1681         this.vehicle_shield = spectatee.vehicle_shield;
1682         this.vehicle_energy = spectatee.vehicle_energy;
1683         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1684         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1685         this.vehicle_reload1 = spectatee.vehicle_reload1;
1686         this.vehicle_reload2 = spectatee.vehicle_reload2;
1687
1688         //msg_entity = this;
1689
1690        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1691             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1692            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1693            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1694
1695         //WriteByte (MSG_ONE, SVC_SETVIEW);
1696         //    WriteEntity(MSG_ONE, this);
1697         //makevectors(spectatee.v_angle);
1698         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1699     }
1700 }
1701
1702 bool SpectateUpdate(entity this)
1703 {
1704         if(!this.enemy)
1705             return false;
1706
1707         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1708         {
1709                 SetSpectatee(this, NULL);
1710                 return false;
1711         }
1712
1713         SpectateCopy(this, this.enemy);
1714
1715         return true;
1716 }
1717
1718 bool SpectateSet(entity this)
1719 {
1720         if(!IS_PLAYER(this.enemy))
1721                 return false;
1722
1723         ClientData_Touch(this.enemy);
1724
1725         msg_entity = this;
1726         WriteByte(MSG_ONE, SVC_SETVIEW);
1727         WriteEntity(MSG_ONE, this.enemy);
1728         set_movetype(this, MOVETYPE_NONE);
1729         accuracy_resend(this);
1730
1731         if(!SpectateUpdate(this))
1732                 PutObserverInServer(this);
1733
1734         return true;
1735 }
1736
1737 void SetSpectatee_status(entity this, int spectatee_num)
1738 {
1739         int oldspectatee_status = this.spectatee_status;
1740         this.spectatee_status = spectatee_num;
1741
1742         if (this.spectatee_status != oldspectatee_status)
1743         {
1744                 ClientData_Touch(this);
1745                 if (g_race || g_cts) race_InitSpectator();
1746         }
1747 }
1748
1749 void SetSpectatee(entity this, entity spectatee)
1750 {
1751         entity old_spectatee = this.enemy;
1752
1753         this.enemy = spectatee;
1754
1755         // WEAPONTODO
1756         // these are required to fix the spectator bug with arc
1757         if(old_spectatee)
1758         {
1759                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1760                 {
1761                         .entity weaponentity = weaponentities[slot];
1762                         if(old_spectatee.(weaponentity).arc_beam)
1763                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1764                 }
1765         }
1766         if(this.enemy)
1767         {
1768                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1769                 {
1770                         .entity weaponentity = weaponentities[slot];
1771                         if(this.enemy.(weaponentity).arc_beam)
1772                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1773                 }
1774         }
1775
1776         if (this.enemy)
1777                 SetSpectatee_status(this, etof(this.enemy));
1778
1779         // needed to update spectator list
1780         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1781 }
1782
1783 bool Spectate(entity this, entity pl)
1784 {
1785         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1786                 return false;
1787         pl = M_ARGV(1, entity);
1788
1789         SetSpectatee(this, pl);
1790         return SpectateSet(this);
1791 }
1792
1793 bool SpectateNext(entity this)
1794 {
1795         entity ent = find(this.enemy, classname, STR_PLAYER);
1796
1797         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1798                 ent = M_ARGV(1, entity);
1799         else if (!ent)
1800                 ent = find(ent, classname, STR_PLAYER);
1801
1802         if(ent) { SetSpectatee(this, ent); }
1803
1804         return SpectateSet(this);
1805 }
1806
1807 bool SpectatePrev(entity this)
1808 {
1809         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1810         entity ent = findchain(classname, STR_PLAYER);
1811         if (!ent) // no player
1812                 return false;
1813
1814         entity first = ent;
1815         // skip players until current spectated player
1816         if(this.enemy)
1817         while(ent && ent != this.enemy)
1818                 ent = ent.chain;
1819
1820         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1821         {
1822                 case MUT_SPECPREV_FOUND:
1823                     ent = M_ARGV(1, entity);
1824                     break;
1825                 case MUT_SPECPREV_RETURN:
1826                     return true;
1827                 case MUT_SPECPREV_CONTINUE:
1828                 default:
1829                 {
1830                         if(ent.chain)
1831                                 ent = ent.chain;
1832                         else
1833                                 ent = first;
1834                         break;
1835                 }
1836         }
1837
1838         SetSpectatee(this, ent);
1839         return SpectateSet(this);
1840 }
1841
1842 /*
1843 =============
1844 ShowRespawnCountdown()
1845
1846 Update a respawn countdown display.
1847 =============
1848 */
1849 void ShowRespawnCountdown(entity this)
1850 {
1851         float number;
1852         if(!IS_DEAD(this)) // just respawned?
1853                 return;
1854         else
1855         {
1856                 number = ceil(this.respawn_time - time);
1857                 if(number <= 0)
1858                         return;
1859                 if(number <= this.respawn_countdown)
1860                 {
1861                         this.respawn_countdown = number - 1;
1862                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1863                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1864                 }
1865         }
1866 }
1867
1868 .float caplayer;
1869
1870 void LeaveSpectatorMode(entity this)
1871 {
1872         if(this.caplayer)
1873                 return;
1874         if(nJoinAllowed(this, this))
1875         {
1876                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1877                 {
1878                         TRANSMUTE(Player, this);
1879
1880                         SetSpectatee(this, NULL);
1881
1882                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1883                                 { JoinBestTeam(this, false, true); }
1884
1885                         if(autocvar_g_campaign)
1886                                 { campaign_bots_may_start = true; }
1887
1888                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1889
1890                         PutClientInServer(this);
1891
1892                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1893                 }
1894                 else
1895                         stuffcmd(this, "menu_showteamselect\n");
1896         }
1897         else
1898         {
1899                 // Player may not join because g_maxplayers is set
1900                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1901         }
1902 }
1903
1904 /**
1905  * Determines whether the player is allowed to join. This depends on cvar
1906  * g_maxplayers, if it isn't used this function always return true, otherwise
1907  * it checks whether the number of currently playing players exceeds g_maxplayers.
1908  * @return int number of free slots for players, 0 if none
1909  */
1910 bool nJoinAllowed(entity this, entity ignore)
1911 {
1912         if(!ignore)
1913         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1914         // so report 0 free slots if restricted
1915         {
1916                 if(autocvar_g_forced_team_otherwise == "spectate")
1917                         return false;
1918                 if(autocvar_g_forced_team_otherwise == "spectator")
1919                         return false;
1920         }
1921
1922         if(this.team_forced < 0)
1923                 return false; // forced spectators can never join
1924
1925         // TODO simplify this
1926         int totalClients = 0;
1927         int currentlyPlaying = 0;
1928         FOREACH_CLIENT(true, LAMBDA(
1929                 if(it != ignore)
1930                         ++totalClients;
1931                 if(IS_REAL_CLIENT(it))
1932                 if(IS_PLAYER(it) || it.caplayer)
1933                         ++currentlyPlaying;
1934         ));
1935
1936         if (!autocvar_g_maxplayers)
1937                 return maxclients - totalClients;
1938
1939         if(currentlyPlaying < autocvar_g_maxplayers)
1940                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1941
1942         return false;
1943 }
1944
1945 /**
1946  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1947  * g_maxplayers_spectator_blocktime seconds
1948  */
1949 void checkSpectatorBlock(entity this)
1950 {
1951         if(IS_SPEC(this) || IS_OBSERVER(this))
1952         if(!this.caplayer)
1953         if(IS_REAL_CLIENT(this))
1954         {
1955                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1956                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1957                         dropclient(this);
1958                 }
1959         }
1960 }
1961
1962 void PrintWelcomeMessage(entity this)
1963 {
1964         if(this.motd_actived_time == 0)
1965         {
1966                 if (autocvar_g_campaign) {
1967                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1968                                 this.motd_actived_time = time;
1969                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1970                         }
1971                 } else {
1972                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1973                                 this.motd_actived_time = time;
1974                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1975                         }
1976                 }
1977         }
1978         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1979         {
1980                 if (autocvar_g_campaign) {
1981                         if (PHYS_INPUT_BUTTON_INFO(this))
1982                                 this.motd_actived_time = time;
1983                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1984                                 this.motd_actived_time = 0;
1985                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1986                         }
1987                 } else {
1988                         if (PHYS_INPUT_BUTTON_INFO(this))
1989                                 this.motd_actived_time = time;
1990                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1991                                 this.motd_actived_time = 0;
1992                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1993                         }
1994                 }
1995         }
1996         else //if(this.motd_actived_time < 0) // just connected, motd is active
1997         {
1998                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1999                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2000                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2001                 {
2002                         // instanctly hide MOTD
2003                         this.motd_actived_time = 0;
2004                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2005                 }
2006         }
2007 }
2008
2009 void ObserverThink(entity this)
2010 {
2011         if ( this.impulse )
2012         {
2013                 MinigameImpulse(this, this.impulse);
2014                 this.impulse = 0;
2015         }
2016         if (this.flags & FL_JUMPRELEASED) {
2017                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2018                         this.flags &= ~FL_JUMPRELEASED;
2019                         this.flags |= FL_SPAWNING;
2020                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2021                         this.flags &= ~FL_JUMPRELEASED;
2022                         if(SpectateNext(this)) {
2023                                 TRANSMUTE(Spectator, this);
2024                         }
2025                 } else {
2026                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2027                         set_movetype(this, preferred_movetype);
2028                 }
2029         } else {
2030                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2031                         this.flags |= FL_JUMPRELEASED;
2032                         if(this.flags & FL_SPAWNING)
2033                         {
2034                                 this.flags &= ~FL_SPAWNING;
2035                                 LeaveSpectatorMode(this);
2036                                 return;
2037                         }
2038                 }
2039         }
2040 }
2041
2042 void SpectatorThink(entity this)
2043 {
2044         if ( this.impulse )
2045         {
2046                 if(MinigameImpulse(this, this.impulse))
2047                         this.impulse = 0;
2048
2049                 if (this.impulse == IMP_weapon_drop.impulse)
2050                 {
2051                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2052                         this.impulse = 0;
2053                         return;
2054                 }
2055         }
2056         if (this.flags & FL_JUMPRELEASED) {
2057                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2058                         this.flags &= ~FL_JUMPRELEASED;
2059                         this.flags |= FL_SPAWNING;
2060                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2061                         this.flags &= ~FL_JUMPRELEASED;
2062                         if(SpectateNext(this)) {
2063                                 TRANSMUTE(Spectator, this);
2064                         } else {
2065                                 TRANSMUTE(Observer, this);
2066                                 PutClientInServer(this);
2067                         }
2068                         this.impulse = 0;
2069                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2070                         this.flags &= ~FL_JUMPRELEASED;
2071                         if(SpectatePrev(this)) {
2072                                 TRANSMUTE(Spectator, this);
2073                         } else {
2074                                 TRANSMUTE(Observer, this);
2075                                 PutClientInServer(this);
2076                         }
2077                         this.impulse = 0;
2078                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2079                         this.flags &= ~FL_JUMPRELEASED;
2080                         TRANSMUTE(Observer, this);
2081                         PutClientInServer(this);
2082                 } else {
2083                         if(!SpectateUpdate(this))
2084                                 PutObserverInServer(this);
2085                 }
2086         } else {
2087                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2088                         this.flags |= FL_JUMPRELEASED;
2089                         if(this.flags & FL_SPAWNING)
2090                         {
2091                                 this.flags &= ~FL_SPAWNING;
2092                                 LeaveSpectatorMode(this);
2093                                 return;
2094                         }
2095                 }
2096                 if(!SpectateUpdate(this))
2097                         PutObserverInServer(this);
2098         }
2099
2100         this.flags |= FL_CLIENT | FL_NOTARGET;
2101 }
2102
2103 void vehicles_enter (entity pl, entity veh);
2104 void PlayerUseKey(entity this)
2105 {
2106         if (!IS_PLAYER(this))
2107                 return;
2108
2109         if(this.vehicle)
2110         {
2111                 if(!gameover)
2112                 {
2113                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2114                         return;
2115                 }
2116         }
2117         else if(autocvar_g_vehicles_enter)
2118         {
2119                 if(!STAT(FROZEN, this))
2120                 if(!IS_DEAD(this))
2121                 if(!gameover)
2122                 {
2123                         entity head, closest_target = NULL;
2124                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2125
2126                         while(head) // find the closest acceptable target to enter
2127                         {
2128                                 if(IS_VEHICLE(head))
2129                                 if(!IS_DEAD(head))
2130                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2131                                 if(head.takedamage != DAMAGE_NO)
2132                                 {
2133                                         if(closest_target)
2134                                         {
2135                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2136                                                 { closest_target = head; }
2137                                         }
2138                                         else { closest_target = head; }
2139                                 }
2140
2141                                 head = head.chain;
2142                         }
2143
2144                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2145                 }
2146         }
2147
2148         // a use key was pressed; call handlers
2149         MUTATOR_CALLHOOK(PlayerUseKey, this);
2150 }
2151
2152
2153 /*
2154 =============
2155 PlayerPreThink
2156
2157 Called every frame for each client before the physics are run
2158 =============
2159 */
2160 .float usekeypressed;
2161 .float last_vehiclecheck;
2162 .int items_added;
2163 void PlayerPreThink (entity this)
2164 {
2165         WarpZone_PlayerPhysics_FixVAngle(this);
2166
2167     STAT(GAMESTARTTIME, this) = game_starttime;
2168         STAT(ROUNDSTARTTIME, this) = round_starttime;
2169         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2170         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2171
2172         STAT(WEAPONSINMAP, this) = weaponsInMap;
2173
2174         if (frametime) {
2175                 // physics frames: update anticheat stuff
2176                 anticheat_prethink(this);
2177         }
2178
2179         if (blockSpectators && frametime) {
2180                 // WORKAROUND: only use dropclient in server frames (frametime set).
2181                 // Never use it in cl_movement frames (frametime zero).
2182                 checkSpectatorBlock(this);
2183     }
2184
2185         zoomstate_set = false;
2186
2187         // Check for nameless players
2188         if (isInvisibleString(this.netname)) {
2189                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2190                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2191         }
2192         if (this.netname != this.netname_previous) {
2193                 if (autocvar_sv_eventlog) {
2194                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2195         }
2196                 if (this.netname_previous) strunzone(this.netname_previous);
2197                 this.netname_previous = strzone(this.netname);
2198         }
2199
2200         // version nagging
2201         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2202         this.version_nagtime = 0;
2203         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2204             // git client
2205         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2206             // git server
2207             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2208         } else {
2209             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2210             if (r < 0) { // old client
2211                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2212             } else if (r > 0) { // old server
2213                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2214             }
2215         }
2216     }
2217
2218         // GOD MODE info
2219         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2220         {
2221                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2222                 this.max_armorvalue = 0;
2223         }
2224
2225         if (STAT(FROZEN, this) == 2)
2226         {
2227                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2228                 this.health = max(1, this.revive_progress * start_health);
2229                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2230
2231                 if (this.revive_progress >= 1)
2232                         Unfreeze(this);
2233         }
2234         else if (STAT(FROZEN, this) == 3)
2235         {
2236                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2237                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2238
2239                 if (this.health < 1)
2240                 {
2241                         if (this.vehicle)
2242                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2243                         if(this.event_damage)
2244                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2245                 }
2246                 else if (this.revive_progress <= 0)
2247                         Unfreeze(this);
2248         }
2249
2250         MUTATOR_CALLHOOK(PlayerPreThink, this);
2251
2252         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2253         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2254         {
2255                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2256                 {
2257                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2258                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2259                         {
2260                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2261                         }
2262                         else if(!it.owner)
2263                         {
2264                                 if(!it.team || SAME_TEAM(this, it))
2265                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2266                                 else if(autocvar_g_vehicles_steal)
2267                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2268                         }
2269                 });
2270
2271                 this.last_vehiclecheck = time + 1;
2272         }
2273
2274         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2275         {
2276                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2277                         PlayerUseKey(this);
2278                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2279         }
2280
2281         if (IS_REAL_CLIENT(this))
2282                 PrintWelcomeMessage(this);
2283
2284         if (IS_PLAYER(this)) {
2285                 CheckRules_Player(this);
2286
2287                 if (intermission_running) {
2288                         IntermissionThink(this);
2289                         return;
2290                 }
2291
2292                 if (timeout_status == TIMEOUT_ACTIVE) {
2293             // don't allow the player to turn around while game is paused
2294                         // FIXME turn this into CSQC stuff
2295                         this.v_angle = this.lastV_angle;
2296                         this.angles = this.lastV_angle;
2297                         this.fixangle = true;
2298                 }
2299
2300                 if (frametime) player_powerups(this);
2301
2302                 if (IS_DEAD(this)) {
2303                         if (this.personal && g_race_qualifying) {
2304                                 if (time > this.respawn_time) {
2305                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2306                                         respawn(this);
2307                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2308                                 }
2309                         } else {
2310                                 if (frametime) player_anim(this);
2311                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2312
2313                                 switch(this.deadflag)
2314                                 {
2315                                         case DEAD_DYING:
2316                                         {
2317                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2318                                                         this.deadflag = DEAD_RESPAWNING;
2319                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2320                                                         this.deadflag = DEAD_DEAD;
2321                                                 break;
2322                                         }
2323                                         case DEAD_DEAD:
2324                                         {
2325                                                 if (button_pressed)
2326                                                         this.deadflag = DEAD_RESPAWNABLE;
2327                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2328                                                         this.deadflag = DEAD_RESPAWNING;
2329                                                 break;
2330                                         }
2331                                         case DEAD_RESPAWNABLE:
2332                                         {
2333                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2334                                                         this.deadflag = DEAD_RESPAWNING;
2335                                                 break;
2336                                         }
2337                                         case DEAD_RESPAWNING:
2338                                         {
2339                                                 if (time > this.respawn_time)
2340                                                 {
2341                                                         this.respawn_time = time + 1; // only retry once a second
2342                                                         this.respawn_time_max = this.respawn_time;
2343                                                         respawn(this);
2344                                                 }
2345                                                 break;
2346                                         }
2347                                 }
2348
2349                                 ShowRespawnCountdown(this);
2350
2351                                 if (this.respawn_flags & RESPAWN_SILENT)
2352                                         STAT(RESPAWN_TIME, this) = 0;
2353                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2354                                 {
2355                                         if (time < this.respawn_time)
2356                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2357                                         else if (this.deadflag != DEAD_RESPAWNING)
2358                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2359                                 }
2360                                 else
2361                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2362                         }
2363
2364                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2365                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2366                                 STAT(RESPAWN_TIME, this) *= -1;
2367
2368                         return;
2369                 }
2370
2371                 this.prevorigin = this.origin;
2372
2373                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2374                 if (this.hook.state) {
2375                         do_crouch = false;
2376                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2377                         do_crouch = false;
2378                 } else if (this.vehicle) {
2379                         do_crouch = false;
2380                 } else if (STAT(FROZEN, this)) {
2381                         do_crouch = false;
2382         }
2383
2384                 if (do_crouch) {
2385                         if (!this.crouch) {
2386                                 this.crouch = true;
2387                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2388                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2389                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2390                         }
2391                 } else if (this.crouch) {
2392             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2393             if (!trace_startsolid) {
2394                 this.crouch = false;
2395                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2396                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2397             }
2398                 }
2399
2400                 FixPlayermodel(this);
2401
2402                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2403                 //if(frametime)
2404                 {
2405                         this.items &= ~this.items_added;
2406
2407                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2408                         //{
2409                                 //.entity weaponentity = weaponentities[slot];
2410                                 //W_WeaponFrame(this, weaponentity);
2411                         //}
2412                         .entity weaponentity = weaponentities[0]; // TODO
2413                         W_WeaponFrame(this, weaponentity);
2414
2415                         this.items_added = 0;
2416                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2417                 this.items_added |= IT_FUEL;
2418
2419                         this.items |= this.items_added;
2420                 }
2421
2422                 player_regen(this);
2423
2424                 // WEAPONTODO: Add a weapon request for this
2425                 // rot vortex charge to the charge limit
2426                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2427                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2428
2429                 if (frametime) player_anim(this);
2430
2431                 // secret status
2432                 secrets_setstatus(this);
2433
2434                 // monsters status
2435                 monsters_setstatus(this);
2436
2437                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2438         }
2439         else if (gameover) {
2440                 if (intermission_running) IntermissionThink(this);
2441                 return;
2442         }
2443         else if (IS_OBSERVER(this)) {
2444                 ObserverThink(this);
2445         }
2446         else if (IS_SPEC(this)) {
2447                 SpectatorThink(this);
2448         }
2449
2450         // WEAPONTODO: Add weapon request for this
2451         if (!zoomstate_set) {
2452                 SetZoomState(this,
2453                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2454                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2455                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2456                 );
2457     }
2458
2459         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2460         {
2461                 this.teamkill_soundtime = 0;
2462
2463                 entity e = this.teamkill_soundsource;
2464                 entity oldpusher = e.pusher;
2465                 e.pusher = this;
2466                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2467                 e.pusher = oldpusher;
2468         }
2469
2470         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2471                 this.taunt_soundtime = 0;
2472                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2473         }
2474
2475         target_voicescript_next(this);
2476
2477         // WEAPONTODO: Move into weaponsystem somehow
2478         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2479         if (PS(this).m_weapon == WEP_Null)
2480                 this.clip_load = this.clip_size = 0;
2481 }
2482
2483 void DrownPlayer(entity this)
2484 {
2485         if(IS_DEAD(this))
2486                 return;
2487
2488         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2489         {
2490                 if(this.air_finished < time)
2491                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2492                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2493                 this.dmg = 2;
2494         }
2495         else if (this.air_finished < time)
2496         {       // drown!
2497                 if (this.pain_finished < time)
2498                 {
2499                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2500                         this.pain_finished = time + 0.5;
2501                 }
2502         }
2503 }
2504
2505 .bool move_qcphysics;
2506
2507 void Player_Physics(entity this)
2508 {
2509         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2510
2511         if(!this.move_qcphysics)
2512                 return;
2513
2514         int mt = this.move_movetype;
2515
2516         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2517         {
2518                 this.move_qcphysics = false;
2519                 set_movetype(this, mt);
2520                 return;
2521         }
2522
2523         if(!frametime && !this.pm_frametime)
2524                 return;
2525
2526         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2527
2528         this.pm_frametime = 0;
2529 }
2530
2531 /*
2532 =============
2533 PlayerPostThink
2534
2535 Called every frame for each client after the physics are run
2536 =============
2537 */
2538 .float idlekick_lasttimeleft;
2539 void PlayerPostThink (entity this)
2540 {
2541         Player_Physics(this);
2542
2543         if (sv_maxidle > 0)
2544         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2545         if (IS_REAL_CLIENT(this))
2546         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2547         {
2548                 int totalClients = 0;
2549                 if(sv_maxidle_slots > 0)
2550                 {
2551                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2552                         {
2553                                 ++totalClients;
2554                         });
2555                 }
2556
2557                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2558                 { /* do nothing */ }
2559                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2560                 {
2561                         if (this.idlekick_lasttimeleft)
2562                         {
2563                                 this.idlekick_lasttimeleft = 0;
2564                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2565                         }
2566                 }
2567                 else
2568                 {
2569                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2570                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2571                                 if (!this.idlekick_lasttimeleft)
2572                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2573                         }
2574                         if (timeleft <= 0) {
2575                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2576                                 dropclient(this);
2577                                 return;
2578                         }
2579                         else if (timeleft <= 10) {
2580                                 if (timeleft != this.idlekick_lasttimeleft) {
2581                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2582                 }
2583                                 this.idlekick_lasttimeleft = timeleft;
2584                         }
2585                 }
2586         }
2587
2588         CheatFrame(this);
2589
2590         //CheckPlayerJump();
2591
2592         if (IS_PLAYER(this)) {
2593                 DrownPlayer(this);
2594                 CheckRules_Player(this);
2595                 UpdateChatBubble(this);
2596                 if (this.impulse) ImpulseCommands(this);
2597                 if (intermission_running) return; // intermission or finale
2598                 GetPressedKeys(this);
2599         }
2600
2601         if (this.waypointsprite_attachedforcarrier) {
2602             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2603                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2604     }
2605
2606         playerdemo_write(this);
2607
2608         CSQCMODEL_AUTOUPDATE(this);
2609 }