qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if(GetResource(this, RES_HEALTH) >= 1)
 255                 {
 256                         // despawn effect
 257                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 258                 }
 259
 260                 // was a player, recount votes and ready status
 261                 if(IS_REAL_CLIENT(this))
 262                 {
 263                         if (vote_called) { VoteCount(false); }
 264                         ReadyCount();
 265                 }
 266                 entcs_update_players(this);
 267         }
 268
 269         entity spot = SelectSpawnPoint(this, true);
 270         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 271         this.angles = vec2(spot.angles);
 272         this.fixangle = true;
 273         // offset it so that the spectator spawns higher off the ground, looks better this way
 274         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         WaypointSprite_PlayerDead(this);
 308
 309         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 310                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321         STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.effects = 0;
 335         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 336         this.pauserotarmor_finished = 0;
 337         this.pauserothealth_finished = 0;
 338         this.pauseregen_finished = 0;
 339         this.damageforcescale = 0;
 340         this.death_time = 0;
 341         this.respawn_flags = 0;
 342         this.respawn_time = 0;
 343         STAT(RESPAWN_TIME, this) = 0;
 344         this.alpha = 0;
 345         this.scale = 0;
 346         this.fade_time = 0;
 347         this.pain_finished = 0;
 348         STAT(STRENGTH_FINISHED, this) = 0;
 349         STAT(INVINCIBLE_FINISHED, this) = 0;
 350         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.fire_endtime = -1;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void ResetPlayerResources(entity this)
 538 {
 539         if (warmup_stage) {
 540                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 541                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 542                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 543                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 544                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 545                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 546                 SetResource(this, RES_HEALTH, warmup_start_health);
 547                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 548                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 549         } else {
 550                 SetResource(this, RES_SHELLS, start_ammo_shells);
 551                 SetResource(this, RES_BULLETS, start_ammo_nails);
 552                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 553                 SetResource(this, RES_CELLS, start_ammo_cells);
 554                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 555                 SetResource(this, RES_FUEL, start_ammo_fuel);
 556                 SetResource(this, RES_HEALTH, start_health);
 557                 SetResource(this, RES_ARMOR, start_armorvalue);
 558                 STAT(WEAPONS, this) = start_weapons;
 559                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 560                 {
 561                         GiveRandomWeapons(this, random_start_weapons_count,
 562                                 autocvar_g_random_start_weapons, random_start_ammo);
 563                 }
 564         }
 565 }
 566
 567 void PutPlayerInServer(entity this)
 568 {
 569         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 570
 571         PlayerState_attach(this);
 572         accuracy_resend(this);
 573
 574         if (this.team < 0)
 575                 TeamBalance_JoinBestTeam(this);
 576
 577         entity spot = SelectSpawnPoint(this, false);
 578         if (!spot) {
 579                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 580                 return; // spawn failed
 581         }
 582
 583         TRANSMUTE(Player, this);
 584
 585         CS(this).wasplayer = true;
 586         this.iscreature = true;
 587         this.teleportable = TELEPORT_NORMAL;
 588         if(!this.damagedbycontents)
 589                 IL_PUSH(g_damagedbycontents, this);
 590         this.damagedbycontents = true;
 591         set_movetype(this, MOVETYPE_WALK);
 592         this.solid = SOLID_SLIDEBOX;
 593         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 594         if (autocvar_g_playerclip_collisions)
 595                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 596         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 597                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 598         this.frags = FRAGS_PLAYER;
 599         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 600         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 601         if (autocvar__notarget)
 602                 this.flags |= FL_NOTARGET;
 603         this.takedamage = DAMAGE_AIM;
 604         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 605
 606         ResetPlayerResources(this);
 607
 608         SetSpectatee_status(this, 0);
 609
 610         PS(this).dual_weapons = '0 0 0';
 611
 612         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 613
 614         this.items = start_items;
 615
 616         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 617         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 618         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 619         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 620         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 621         if (!sv_ready_restart_after_countdown && time < game_starttime)
 622         {
 623                 float f = game_starttime - time;
 624                 this.spawnshieldtime += f;
 625                 this.pauserotarmor_finished += f;
 626                 this.pauserothealth_finished += f;
 627                 this.pauseregen_finished += f;
 628         }
 629
 630         this.damageforcescale = autocvar_g_player_damageforcescale;
 631         this.death_time = 0;
 632         this.respawn_flags = 0;
 633         this.respawn_time = 0;
 634         STAT(RESPAWN_TIME, this) = 0;
 635         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 636         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(STRENGTH_FINISHED, this) = 0;
 661         STAT(INVINCIBLE_FINISHED, this) = 0;
 662         this.fire_endtime = -1;
 663         STAT(REVIVE_PROGRESS, this) = 0;
 664         this.revival_time = 0;
 665
 666         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 667         STAT(BUFFS, this) = 0;
 668         STAT(BUFF_TIME, this) = 0;
 669
 670         STAT(AIR_FINISHED, this) = 0;
 671         this.waterlevel = WATERLEVEL_NONE;
 672         this.watertype = CONTENT_EMPTY;
 673
 674         entity spawnevent = new_pure(spawnevent);
 675         spawnevent.owner = this;
 676         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 677
 678         // Cut off any still running player sounds.
 679         stopsound(this, CH_PLAYER_SINGLE);
 680
 681         this.model = "";
 682         FixPlayermodel(this);
 683         this.drawonlytoclient = NULL;
 684
 685         this.viewloc = NULL;
 686
 687         for(int slot = 0; slot < MAX_AXH; ++slot)
 688         {
 689                 entity axh = this.(AuxiliaryXhair[slot]);
 690                 this.(AuxiliaryXhair[slot]) = NULL;
 691
 692                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 693                         delete(axh);
 694         }
 695
 696         this.spawnpoint_targ = NULL;
 697
 698         UNSET_DUCKED(this);
 699         this.view_ofs = STAT(PL_VIEW_OFS, this);
 700         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 701         this.spawnorigin = spot.origin;
 702         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 703         // don't reset back to last position, even if new position is stuck in solid
 704         this.oldorigin = this.origin;
 705         if(this.conveyor)
 706                 IL_REMOVE(g_conveyed, this);
 707         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 708         if(this.swampslug)
 709                 IL_REMOVE(g_swamped, this);
 710         this.swampslug = NULL;
 711         this.swamp_interval = 0;
 712         if(this.ladder_entity)
 713                 IL_REMOVE(g_ladderents, this);
 714         this.ladder_entity = NULL;
 715         IL_EACH(g_counters, it.realowner == this,
 716         {
 717                 delete(it);
 718         });
 719         STAT(HUD, this) = HUD_NORMAL;
 720
 721         this.event_damage = PlayerDamage;
 722         this.event_heal = PlayerHeal;
 723
 724         this.draggable = func_null;
 725
 726         if(!this.bot_attack)
 727                 IL_PUSH(g_bot_targets, this);
 728         this.bot_attack = true;
 729         if(!this.monster_attack)
 730                 IL_PUSH(g_monster_targets, this);
 731         this.monster_attack = true;
 732         navigation_dynamicgoal_init(this, false);
 733
 734         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 735
 736         // player was spectator
 737         if (CS(this).killcount == FRAGS_SPECTATOR) {
 738                 PlayerScore_Clear(this);
 739                 CS(this).killcount = 0;
 740                 CS(this).startplaytime = time;
 741         }
 742
 743         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 CL_SpawnWeaponentity(this, weaponentity);
 747         }
 748         this.alpha = default_player_alpha;
 749         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 750         this.exteriorweaponentity.alpha = default_weapon_alpha;
 751
 752         this.speedrunning = false;
 753
 754         this.counter_cnt = 0;
 755         this.fragsfilter_cnt = 0;
 756
 757         target_voicescript_clear(this);
 758
 759         // reset fields the weapons may use
 760         FOREACH(Weapons, true, {
 761                 it.wr_resetplayer(it, this);
 762                         // reload all reloadable weapons
 763                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 764                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765                         {
 766                                 .entity weaponentity = weaponentities[slot];
 767                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 768                         }
 769                 }
 770         });
 771
 772         {
 773                 string s = spot.target;
 774                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 775                         spot.target = string_null;
 776                 SUB_UseTargets(spot, this, NULL);
 777                 if(g_assault || g_race)
 778                         spot.target = s;
 779         }
 780
 781         Unfreeze(this, false);
 782
 783         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 784
 785         if (autocvar_spawn_debug)
 786         {
 787                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 788                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 789         }
 790
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 entity w_ent = this.(weaponentity);
 795                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 796                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 797                 else
 798                         w_ent.m_switchweapon = WEP_Null;
 799                 w_ent.m_weapon = WEP_Null;
 800                 w_ent.weaponname = "";
 801                 w_ent.m_switchingweapon = WEP_Null;
 802                 w_ent.cnt = -1;
 803         }
 804
 805         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 806
 807         if (CS(this).impulse) ImpulseCommands(this);
 808
 809         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 810         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811         {
 812                 .entity weaponentity = weaponentities[slot];
 813                 W_WeaponFrame(this, weaponentity);
 814         }
 815
 816         if (!warmup_stage && !this.alivetime)
 817                 this.alivetime = time;
 818
 819         antilag_clear(this, CS(this));
 820 }
 821
 822 /** Called when a client spawns in the server */
 823 void PutClientInServer(entity this)
 824 {
 825         if (IS_BOT_CLIENT(this)) {
 826                 TRANSMUTE(Player, this);
 827         } else if (IS_REAL_CLIENT(this)) {
 828                 msg_entity = this;
 829                 WriteByte(MSG_ONE, SVC_SETVIEW);
 830                 WriteEntity(MSG_ONE, this);
 831         }
 832         if (game_stopped)
 833                 TRANSMUTE(Observer, this);
 834
 835         SetSpectatee(this, NULL);
 836
 837         // reset player keys
 838         if(PS(this))
 839                 PS(this).itemkeys = 0;
 840
 841         MUTATOR_CALLHOOK(PutClientInServer, this);
 842
 843         if (IS_OBSERVER(this)) {
 844                 PutObserverInServer(this);
 845         } else if (IS_PLAYER(this)) {
 846                 PutPlayerInServer(this);
 847         }
 848         // send team names
 849         if(teamplay && IS_REAL_CLIENT(this))
 850                 send_TeamNames(MSG_ONE, this);
 851         bot_relinkplayerlist();
 852 }
 853
 854 // TODO do we need all these fields, or should we stop autodetecting runtime
 855 // changes and just have a console command to update this?
 856 bool ClientInit_SendEntity(entity this, entity to, int sf)
 857 {
 858         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 859         return = true;
 860         msg_entity = to;
 861         // MSG_INIT replacement
 862         // TODO: make easier to use
 863         Registry_send_all();
 864         W_PROP_reload(MSG_ONE, to);
 865         ClientInit_misc(this);
 866         MUTATOR_CALLHOOK(Ent_Init);
 867 }
 868 void ClientInit_misc(entity this)
 869 {
 870         int channel = MSG_ONE;
 871         WriteHeader(channel, ENT_CLIENT_INIT);
 872         WriteByte(channel, g_nexball_meter_period * 32);
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 881
 882         if(autocvar_sv_foginterval && world.fog != "")
 883                 WriteString(channel, world.fog);
 884         else
 885                 WriteString(channel, "");
 886         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 887         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 888         WriteByte(channel, serverflags);
 889         WriteCoord(channel, autocvar_g_trueaim_minrange);
 890
 891         // z411 send full hostname
 892         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 893         WriteString(channel, autocvar_sv_motd_permanent);
 894 }
 895
 896 void ClientInit_CheckUpdate(entity this)
 897 {
 898         this.nextthink = time;
 899         if(this.count != autocvar_g_balance_armor_blockpercent)
 900         {
 901                 this.count = autocvar_g_balance_armor_blockpercent;
 902                 this.SendFlags |= 1;
 903         }
 904         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 905         {
 906                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 907                 this.SendFlags |= 1;
 908         }
 909 }
 910
 911 void ClientInit_Spawn()
 912 {
 913         entity e = new_pure(clientinit);
 914         setthink(e, ClientInit_CheckUpdate);
 915         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 916
 917         ClientInit_CheckUpdate(e);
 918 }
 919
 920 /*
 921 =============
 922 SetNewParms
 923 =============
 924 */
 925 void SetNewParms ()
 926 {
 927         // initialize parms for a new player
 928         parm1 = -(86400 * 366);
 929
 930         MUTATOR_CALLHOOK(SetNewParms);
 931 }
 932
 933 /*
 934 =============
 935 SetChangeParms
 936 =============
 937 */
 938 void SetChangeParms (entity this)
 939 {
 940         // save parms for level change
 941         parm1 = CS(this).parm_idlesince - time;
 942
 943         MUTATOR_CALLHOOK(SetChangeParms);
 944 }
 945
 946 /*
 947 =============
 948 DecodeLevelParms
 949 =============
 950 */
 951 void DecodeLevelParms(entity this)
 952 {
 953         // load parms
 954         CS(this).parm_idlesince = parm1;
 955         if (CS(this).parm_idlesince == -(86400 * 366))
 956                 CS(this).parm_idlesince = time;
 957
 958         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 959         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 960
 961         MUTATOR_CALLHOOK(DecodeLevelParms);
 962 }
 963
 964 void FixClientCvars(entity e)
 965 {
 966         // send prediction settings to the client
 967         stuffcmd(e, "\nin_bindmap 0 0\n");
 968         if(autocvar_g_antilag == 3) // client side hitscan
 969                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 970         if(autocvar_sv_gentle)
 971                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 972
 973         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 974         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 975
 976         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 977
 978         MUTATOR_CALLHOOK(FixClientCvars, e);
 979 }
 980
 981 bool findinlist_abbrev(string tofind, string list)
 982 {
 983         if(list == "" || tofind == "")
 984                 return false; // empty list or search, just return
 985
 986         // this function allows abbreviated strings!
 987         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 988         {
 989                 return true;
 990         });
 991
 992         return false;
 993 }
 994
 995 bool PlayerInIPList(entity p, string iplist)
 996 {
 997         // some safety checks (never allow local?)
 998         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 999                 return false;
1000
1001         return findinlist_abbrev(p.netaddress, iplist);
1002 }
1003
1004 bool PlayerInIDList(entity p, string idlist)
1005 {
1006         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1007         if(!p.crypto_idfp)
1008                 return false;
1009
1010         return findinlist_abbrev(p.crypto_idfp, idlist);
1011 }
1012
1013 bool PlayerInList(entity player, string list)
1014 {
1015         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1016 }
1017
1018 #ifdef DP_EXT_PRECONNECT
1019 /*
1020 =============
1021 ClientPreConnect
1022
1023 Called once (not at each match start) when a client begins a connection to the server
1024 =============
1025 */
1026 void ClientPreConnect(entity this)
1027 {
1028         if(autocvar_sv_eventlog)
1029         {
1030                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1031                         this.playerid,
1032                         etof(this),
1033                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1034                 ));
1035         }
1036 }
1037 #endif
1038
1039 string GetClientVersionMessage(entity this)
1040 {
1041         if (CS(this).version_mismatch) {
1042                 if(CS(this).version < autocvar_gameversion) {
1043                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1044                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1045                 } else {
1046                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1047                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1048                 }
1049         } else {
1050                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1051         }
1052 }
1053
1054 string getwelcomemessage(entity this)
1055 {
1056         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1057         string modifications = M_ARGV(0, string);
1058
1059         if(g_weaponarena)
1060         {
1061                 if(g_weaponarena_random)
1062                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1063                 else
1064                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1065         }
1066         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1067                 modifications = strcat(modifications, ", No start weapons");
1068         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1069                 modifications = strcat(modifications, ", Low gravity");
1070         if(g_weapon_stay && !g_cts)
1071                 modifications = strcat(modifications, ", Weapons stay");
1072         if(autocvar_g_jetpack)
1073                 modifications = strcat(modifications, ", Jet pack");
1074         if(autocvar_g_powerups == 0)
1075                 modifications = strcat(modifications, ", No powerups");
1076         if(autocvar_g_powerups > 0)
1077                 modifications = strcat(modifications, ", Powerups");
1078         modifications = substring(modifications, 2, strlen(modifications) - 2);
1079
1080         //string versionmessage = GetClientVersionMessage(this);
1081         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1082         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1083
1084         s = strcat(s, "^8\n^7", gamemode_name);
1085
1086         if(modifications != "")
1087                 s = strcat(s, "^7 | ^3", modifications);
1088
1089         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1090         {
1091                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1092                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1093         }
1094
1095         if (cache_mutatormsg != "") {
1096                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1097         }
1098
1099         string mutator_msg = "";
1100         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1101         mutator_msg = M_ARGV(0, string);
1102
1103         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1104
1105         string motd = autocvar_sv_motd;
1106         if (motd != "") {
1107                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1108         }
1109         return s;
1110 }
1111
1112 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1113
1114 /**
1115 =============
1116 ClientConnect
1117
1118 Called when a client connects to the server
1119 =============
1120 */
1121 void ClientConnect(entity this)
1122 {
1123         if (Ban_MaybeEnforceBanOnce(this)) return;
1124         assert(!IS_CLIENT(this), return);
1125         this.flags |= FL_CLIENT;
1126         assert(player_count >= 0, player_count = 0);
1127
1128         TRANSMUTE(Client, this);
1129         CS(this).version_nagtime = time + 10 + random() * 10;
1130
1131         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1132
1133         bot_clientconnect(this);
1134
1135         Player_DetermineForcedTeam(this);
1136
1137         TRANSMUTE(Observer, this);
1138
1139         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1140
1141         // always track bots, don't ask for cl_allow_uidtracking
1142         if (IS_BOT_CLIENT(this))
1143                 PlayerStats_GameReport_AddPlayer(this);
1144         else
1145                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1146
1147         if (autocvar_sv_eventlog)
1148                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1149
1150         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1151
1152         stuffcmd(this, clientstuff, "\n");
1153         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1154
1155         FixClientCvars(this);
1156
1157         // get version info from player
1158         stuffcmd(this, "cmd clientversion $gameversion\n");
1159
1160         // notify about available teams
1161         if (teamplay)
1162         {
1163                 entity balance = TeamBalance_CheckAllowedTeams(this);
1164                 int t = TeamBalance_GetAllowedTeams(balance);
1165                 TeamBalance_Destroy(balance);
1166                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1167         }
1168         else
1169         {
1170                 stuffcmd(this, "set _teams_available 0\n");
1171         }
1172
1173         bot_relinkplayerlist();
1174
1175         CS(this).spectatortime = time;
1176         if (blockSpectators)
1177         {
1178                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1179         }
1180
1181         CS(this).jointime = time;
1182
1183         if (IS_REAL_CLIENT(this))
1184         {
1185                 if (g_weaponarena_weapons == WEPSET(TUBA))
1186                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1187         }
1188
1189         if (!autocvar_sv_foginterval && world.fog != "")
1190                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1191
1192         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1193                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1194                         send_CSQC_teamnagger();
1195
1196         CSQCMODEL_AUTOINIT(this);
1197
1198         CS(this).model_randomizer = random();
1199
1200         if (IS_REAL_CLIENT(this))
1201                 sv_notice_join(this);
1202
1203         this.move_qcphysics = autocvar_sv_qcphysics;
1204
1205         // update physics stats (players can spawn before physics runs)
1206         Physics_UpdateStats(this);
1207
1208         IL_EACH(g_initforplayer, it.init_for_player, {
1209                 it.init_for_player(it, this);
1210         });
1211
1212         Handicap_Initialize(this);
1213
1214         MUTATOR_CALLHOOK(ClientConnect, this);
1215
1216         if (IS_REAL_CLIENT(this))
1217         {
1218                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1219                 {
1220                         CS(this).motd_actived_time = -1;
1221                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1222                 }
1223         }
1224 }
1225 /*
1226 =============
1227 ClientDisconnect
1228
1229 Called when a client disconnects from the server
1230 =============
1231 */
1232 .entity chatbubbleentity;
1233 void player_powerups_remove_all(entity this);
1234
1235 void ClientDisconnect(entity this)
1236 {
1237         assert(IS_CLIENT(this), return);
1238
1239         PlayerStats_GameReport_FinalizePlayer(this);
1240         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1241         if (CS(this).active_minigame) part_minigame(this);
1242         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1243
1244         if (autocvar_sv_eventlog)
1245                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1246
1247         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1248
1249         if(IS_SPEC(this))
1250                 SetSpectatee(this, NULL);
1251
1252         MUTATOR_CALLHOOK(ClientDisconnect, this);
1253
1254         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1255         strfree(CS_CVAR(this).weaponorder_byimpulse);
1256         ClientState_detach(this);
1257
1258         Portal_ClearAll(this);
1259
1260         Unfreeze(this, false);
1261
1262         RemoveGrapplingHooks(this);
1263
1264         // Here, everything has been done that requires this player to be a client.
1265
1266         this.flags &= ~FL_CLIENT;
1267
1268         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1269         if (this.killindicator) delete(this.killindicator);
1270
1271         IL_EACH(g_counters, it.realowner == this,
1272         {
1273                 delete(it);
1274         });
1275
1276         WaypointSprite_PlayerGone(this);
1277
1278         bot_relinkplayerlist();
1279
1280         strfree(this.clientstatus);
1281         if (this.personal) delete(this.personal);
1282
1283         this.playerid = 0;
1284         ReadyCount();
1285         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1286
1287         player_powerups_remove_all(this); // stop powerup sound
1288
1289         ONREMOVE(this);
1290 }
1291
1292 void ChatBubbleThink(entity this)
1293 {
1294         this.nextthink = time;
1295         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1296         {
1297                 if(this.owner) // but why can that ever be NULL?
1298                         this.owner.chatbubbleentity = NULL;
1299                 delete(this);
1300                 return;
1301         }
1302
1303         this.mdl = "";
1304
1305         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1306         {
1307                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1308                         this.mdl = "models/sprites/minigame_busy.iqm";
1309                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1310                         this.mdl = "models/misc/chatbubble.spr";
1311         }
1312
1313         if ( this.model != this.mdl )
1314                 _setmodel(this, this.mdl);
1315
1316 }
1317
1318 void UpdateChatBubble(entity this)
1319 {
1320         if (this.alpha < 0)
1321                 return;
1322         // spawn a chatbubble entity if needed
1323         if (!this.chatbubbleentity)
1324         {
1325                 this.chatbubbleentity = new(chatbubbleentity);
1326                 this.chatbubbleentity.owner = this;
1327                 this.chatbubbleentity.exteriormodeltoclient = this;
1328                 setthink(this.chatbubbleentity, ChatBubbleThink);
1329                 this.chatbubbleentity.nextthink = time;
1330                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1331                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1332                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1333                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1334                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1335                 //this.chatbubbleentity.model = "";
1336                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1337         }
1338 }
1339
1340 void calculate_player_respawn_time(entity this)
1341 {
1342         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1343                 return;
1344
1345         float gametype_setting_tmp;
1346         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1347         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1348         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1349         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1350         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1351         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1352
1353         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1354         if (teamplay)
1355         {
1356                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1357                         if(it.team == this.team)
1358                                 ++pcount;
1359                 });
1360                 if (sdelay_small_count == 0)
1361                         sdelay_small_count = 1;
1362                 if (sdelay_large_count == 0)
1363                         sdelay_large_count = 1;
1364         }
1365         else
1366         {
1367                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1368                         ++pcount;
1369                 });
1370                 if (sdelay_small_count == 0)
1371                 {
1372                         if (IS_INDEPENDENT_PLAYER(this))
1373                         {
1374                                 // Players play independently. No point in requiring enemies.
1375                                 sdelay_small_count = 1;
1376                         }
1377                         else
1378                         {
1379                                 // Players play AGAINST each other. Enemies required.
1380                                 sdelay_small_count = 2;
1381                         }
1382                 }
1383                 if (sdelay_large_count == 0)
1384                 {
1385                         if (IS_INDEPENDENT_PLAYER(this))
1386                         {
1387                                 // Players play independently. No point in requiring enemies.
1388                                 sdelay_large_count = 1;
1389                         }
1390                         else
1391                         {
1392                                 // Players play AGAINST each other. Enemies required.
1393                                 sdelay_large_count = 2;
1394                         }
1395                 }
1396         }
1397
1398         float sdelay;
1399
1400         if (pcount <= sdelay_small_count)
1401                 sdelay = sdelay_small;
1402         else if (pcount >= sdelay_large_count)
1403                 sdelay = sdelay_large;
1404         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1405                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1406
1407         if(waves)
1408                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1409         else
1410                 this.respawn_time = time + sdelay;
1411
1412         if(sdelay < sdelay_max)
1413                 this.respawn_time_max = time + sdelay_max;
1414         else
1415                 this.respawn_time_max = this.respawn_time;
1416
1417         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1418                 this.respawn_countdown = 10; // first number to count down from is 10
1419         else
1420                 this.respawn_countdown = -1; // do not count down
1421
1422         if(autocvar_g_forced_respawn)
1423                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1424 }
1425
1426 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1427 // added to the model skins
1428 /*void UpdateColorModHack()
1429 {
1430         float c;
1431         c = this.clientcolors & 15;
1432         // LordHavoc: only bothering to support white, green, red, yellow, blue
1433              if (!teamplay) this.colormod = '0 0 0';
1434         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1435         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1436         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1437         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1438         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1439         else this.colormod = '1 1 1';
1440 }*/
1441
1442 void respawn(entity this)
1443 {
1444         bool damagedbycontents_prev = this.damagedbycontents;
1445         if(this.alpha >= 0)
1446         {
1447                 if(autocvar_g_respawn_ghosts)
1448                 {
1449                         this.solid = SOLID_NOT;
1450                         this.takedamage = DAMAGE_NO;
1451                         this.damagedbycontents = false;
1452                         set_movetype(this, MOVETYPE_FLY);
1453                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1454                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1455                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1456                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1457                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1458                         if(autocvar_g_respawn_ghosts_time > 0)
1459                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1460                 }
1461                 else
1462                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1463         }
1464
1465         CopyBody(this, 1);
1466         this.damagedbycontents = damagedbycontents_prev;
1467
1468         this.effects |= EF_NODRAW; // prevent another CopyBody
1469         PutClientInServer(this);
1470 }
1471
1472 void play_countdown(entity this, float finished, Sound samp)
1473 {
1474         TC(Sound, samp);
1475         if(IS_REAL_CLIENT(this))
1476                 if(floor(finished - time - frametime) != floor(finished - time))
1477                         if(finished - time < 6)
1478                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1479 }
1480
1481 void player_powerups_remove_all(entity this)
1482 {
1483         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1484         {
1485                 // don't play the poweroff sound when the game restarts or the player disconnects
1486                 if (time > game_starttime + 1 && IS_CLIENT(this))
1487                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1488                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1489                 this.items &= ~ITEM_Strength.m_itemid;
1490                 this.items &= ~ITEM_Shield.m_itemid;
1491                 this.items -= (this.items & IT_SUPERWEAPON);
1492         }
1493 }
1494
1495 void player_powerups(entity this)
1496 {
1497         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1498                 this.modelflags |= MF_ROCKET;
1499         else
1500                 this.modelflags &= ~MF_ROCKET;
1501
1502         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1503
1504         if (IS_DEAD(this))
1505                 player_powerups_remove_all(this);
1506
1507         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1508                 return;
1509
1510         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1511         int items_prev = this.items;
1512
1513         Fire_ApplyDamage(this);
1514         Fire_ApplyEffect(this);
1515
1516         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1517         {
1518                 if (this.items & ITEM_Strength.m_itemid)
1519                 {
1520                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1521                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1522                         if (time > STAT(STRENGTH_FINISHED, this))
1523                         {
1524                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1525                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1527                         }
1528                 }
1529                 else
1530                 {
1531                         if (time < STAT(STRENGTH_FINISHED, this))
1532                         {
1533                                 this.items = this.items | ITEM_Strength.m_itemid;
1534                                 if(!g_cts)
1535                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1536                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1537                         }
1538                 }
1539                 if (this.items & ITEM_Shield.m_itemid)
1540                 {
1541                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1542                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1543                         if (time > STAT(INVINCIBLE_FINISHED, this))
1544                         {
1545                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1546                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1548                         }
1549                 }
1550                 else
1551                 {
1552                         if (time < STAT(INVINCIBLE_FINISHED, this))
1553                         {
1554                                 this.items = this.items | ITEM_Shield.m_itemid;
1555                                 if(!g_cts)
1556                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1557                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1558                         }
1559                 }
1560                 if (this.items & IT_SUPERWEAPON)
1561                 {
1562                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1563                         {
1564                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1565                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1566                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1567                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1568                         }
1569                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1570                         {
1571                                 // don't let them run out
1572                         }
1573                         else
1574                         {
1575                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1576                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1577                                 {
1578                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1579                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1580                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1581                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1582                                 }
1583                         }
1584                 }
1585                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1586                 {
1587                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1588                         {
1589                                 this.items = this.items | IT_SUPERWEAPON;
1590                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1591                                 {
1592                                         if(!g_cts)
1593                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1594                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1595                                 }
1596                         }
1597                         else
1598                         {
1599                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1600                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1601                         }
1602                 }
1603                 else
1604                 {
1605                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1606                 }
1607         }
1608
1609         if(autocvar_g_nodepthtestplayers)
1610                 this.effects = this.effects | EF_NODEPTHTEST;
1611
1612         if(autocvar_g_fullbrightplayers)
1613                 this.effects = this.effects | EF_FULLBRIGHT;
1614
1615         if (time >= game_starttime)
1616         if (time < this.spawnshieldtime)
1617                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1618
1619         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1620 }
1621
1622 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1623 {
1624         if(current > stable)
1625                 return current;
1626         else if(current > stable - 0.25) // when close enough, "snap"
1627                 return stable;
1628         else
1629                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1630 }
1631
1632 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1633 {
1634         if(current < stable)
1635                 return current;
1636         else if(current < stable + 0.25) // when close enough, "snap"
1637                 return stable;
1638         else
1639                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1640 }
1641
1642 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1643 {
1644         float old = GetResource(this, res);
1645         float current = old;
1646         if(current > rotstable)
1647         {
1648                 if(rotframetime > 0)
1649                 {
1650                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1651                         current = max(rotstable, current - rotlinear * rotframetime);
1652                 }
1653         }
1654         else if(current < regenstable)
1655         {
1656                 if(regenframetime > 0)
1657                 {
1658                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1659                         current = min(regenstable, current + regenlinear * regenframetime);
1660                 }
1661         }
1662
1663         float limit = GetResourceLimit(this, res) * limit_mod;
1664         if(current > limit)
1665                 current = limit;
1666
1667         if (current != old)
1668                 SetResource(this, res, current);
1669 }
1670
1671 void player_regen(entity this)
1672 {
1673         float max_mod, regen_mod, rot_mod, limit_mod;
1674         max_mod = regen_mod = rot_mod = limit_mod = 1;
1675
1676         float regen_health = autocvar_g_balance_health_regen;
1677         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1678         float regen_health_rot = autocvar_g_balance_health_rot;
1679         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1680         float regen_health_stable = autocvar_g_balance_health_regenstable;
1681         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1682         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1683                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1684         max_mod = M_ARGV(1, float);
1685         regen_mod = M_ARGV(2, float);
1686         rot_mod = M_ARGV(3, float);
1687         limit_mod = M_ARGV(4, float);
1688         regen_health = M_ARGV(5, float);
1689         regen_health_linear = M_ARGV(6, float);
1690         regen_health_rot = M_ARGV(7, float);
1691         regen_health_rotlinear = M_ARGV(8, float);
1692         regen_health_stable = M_ARGV(9, float);
1693         regen_health_rotstable = M_ARGV(10, float);
1694
1695         if(!mutator_returnvalue)
1696         if(!STAT(FROZEN, this))
1697         {
1698                 float maxa = autocvar_g_balance_armor_rotstable;
1699                 float mina = autocvar_g_balance_armor_regenstable;
1700
1701                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1702                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1703                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1704
1705                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1706                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1707                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1708         }
1709
1710         // if player rotted to death...  die!
1711         // check this outside above checks, as player may still be able to rot to death
1712         if(GetResource(this, RES_HEALTH) < 1)
1713         {
1714                 if(this.vehicle)
1715                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1716                 if(this.event_damage)
1717                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1718         }
1719
1720         if (!(this.items & IT_UNLIMITED_AMMO))
1721         {
1722                 float maxf = autocvar_g_balance_fuel_rotstable;
1723                 float minf = autocvar_g_balance_fuel_regenstable;
1724
1725                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1726                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1727                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1728         }
1729 }
1730
1731 bool zoomstate_set;
1732 void SetZoomState(entity this, float newzoom)
1733 {
1734         if(newzoom != CS(this).zoomstate)
1735         {
1736                 CS(this).zoomstate = newzoom;
1737                 ClientData_Touch(this);
1738         }
1739         zoomstate_set = true;
1740 }
1741
1742 void GetPressedKeys(entity this)
1743 {
1744         MUTATOR_CALLHOOK(GetPressedKeys, this);
1745         if (game_stopped)
1746         {
1747                 CS(this).pressedkeys = 0;
1748                 STAT(PRESSED_KEYS, this) = 0;
1749                 return;
1750         }
1751
1752         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1753         int keys = STAT(PRESSED_KEYS, this);
1754         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1755         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1756         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1757         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1758
1759         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1760         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1761         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1762         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1763         CS(this).pressedkeys = keys; // store for other users
1764
1765         STAT(PRESSED_KEYS, this) = keys;
1766 }
1767
1768 /*
1769 ======================
1770 spectate mode routines
1771 ======================
1772 */
1773
1774 void SpectateCopy(entity this, entity spectatee)
1775 {
1776         TC(Client, this); TC(Client, spectatee);
1777
1778         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1779         PS(this) = PS(spectatee);
1780         this.armortype = spectatee.armortype;
1781         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1782         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1783         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1784         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1785         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1786         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1787         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1788         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1789         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1790         CS(this).impulse = 0;
1791         this.disableclientprediction = 1; // no need to run prediction on a spectator
1792         this.items = spectatee.items;
1793         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1794         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1795         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1796         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1797         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1798         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1799         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1800         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1801         this.punchangle = spectatee.punchangle;
1802         this.view_ofs = spectatee.view_ofs;
1803         this.velocity = spectatee.velocity;
1804         this.dmg_take = spectatee.dmg_take;
1805         this.dmg_save = spectatee.dmg_save;
1806         this.dmg_inflictor = spectatee.dmg_inflictor;
1807         this.v_angle = spectatee.v_angle;
1808         this.angles = spectatee.v_angle;
1809         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1810         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1811         this.viewloc = spectatee.viewloc;
1812         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1813                 this.fixangle = true;
1814         setorigin(this, spectatee.origin);
1815         setsize(this, spectatee.mins, spectatee.maxs);
1816         SetZoomState(this, CS(spectatee).zoomstate);
1817
1818     anticheat_spectatecopy(this, spectatee);
1819         STAT(HUD, this) = STAT(HUD, spectatee);
1820         if(spectatee.vehicle)
1821     {
1822         this.angles = spectatee.v_angle;
1823
1824         //this.fixangle = false;
1825         //this.velocity = spectatee.vehicle.velocity;
1826         this.vehicle_health = spectatee.vehicle_health;
1827         this.vehicle_shield = spectatee.vehicle_shield;
1828         this.vehicle_energy = spectatee.vehicle_energy;
1829         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1830         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1831         this.vehicle_reload1 = spectatee.vehicle_reload1;
1832         this.vehicle_reload2 = spectatee.vehicle_reload2;
1833
1834         //msg_entity = this;
1835
1836        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1837             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1838            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1839            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1840
1841         //WriteByte (MSG_ONE, SVC_SETVIEW);
1842         //    WriteEntity(MSG_ONE, this);
1843         //makevectors(spectatee.v_angle);
1844         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1845     }
1846 }
1847
1848 bool SpectateUpdate(entity this)
1849 {
1850         if(!this.enemy)
1851                 return false;
1852
1853         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1854         {
1855                 SetSpectatee(this, NULL);
1856                 return false;
1857         }
1858
1859         SpectateCopy(this, this.enemy);
1860
1861         return true;
1862 }
1863
1864 bool SpectateSet(entity this)
1865 {
1866         if(!IS_PLAYER(this.enemy))
1867                 return false;
1868
1869         ClientData_Touch(this.enemy);
1870
1871         msg_entity = this;
1872         WriteByte(MSG_ONE, SVC_SETVIEW);
1873         WriteEntity(MSG_ONE, this.enemy);
1874         set_movetype(this, MOVETYPE_NONE);
1875         accuracy_resend(this);
1876
1877         if(!SpectateUpdate(this))
1878                 PutObserverInServer(this);
1879
1880         return true;
1881 }
1882
1883 void SetSpectatee_status(entity this, int spectatee_num)
1884 {
1885         int oldspectatee_status = CS(this).spectatee_status;
1886         CS(this).spectatee_status = spectatee_num;
1887
1888         if (CS(this).spectatee_status != oldspectatee_status)
1889         {
1890                 if (STAT(PRESSED_KEYS, this))
1891                 {
1892                         CS(this).pressedkeys = 0;
1893                         STAT(PRESSED_KEYS, this) = 0;
1894                 }
1895                 ClientData_Touch(this);
1896                 if (g_race || g_cts) race_InitSpectator();
1897         }
1898 }
1899
1900 void SetSpectatee(entity this, entity spectatee)
1901 {
1902         if(IS_BOT_CLIENT(this))
1903                 return; // bots abuse .enemy, this code is useless to them
1904
1905         entity old_spectatee = this.enemy;
1906
1907         this.enemy = spectatee;
1908
1909         // WEAPONTODO
1910         // these are required to fix the spectator bug with arc
1911         if(old_spectatee)
1912         {
1913                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1914                 {
1915                         .entity weaponentity = weaponentities[slot];
1916                         if(old_spectatee.(weaponentity).arc_beam)
1917                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1918                 }
1919         }
1920         if(this.enemy)
1921         {
1922                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1923                 {
1924                         .entity weaponentity = weaponentities[slot];
1925                         if(this.enemy.(weaponentity).arc_beam)
1926                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1927                 }
1928         }
1929
1930         if (this.enemy)
1931                 SetSpectatee_status(this, etof(this.enemy));
1932
1933         // needed to update spectator list
1934         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1935 }
1936
1937 bool Spectate(entity this, entity pl)
1938 {
1939         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1940                 return false;
1941         pl = M_ARGV(1, entity);
1942
1943         SetSpectatee(this, pl);
1944         return SpectateSet(this);
1945 }
1946
1947 bool SpectateNext(entity this)
1948 {
1949         entity ent = find(this.enemy, classname, STR_PLAYER);
1950
1951         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1952                 ent = M_ARGV(1, entity);
1953         else if (!ent)
1954                 ent = find(ent, classname, STR_PLAYER);
1955
1956         if(ent) { SetSpectatee(this, ent); }
1957
1958         return SpectateSet(this);
1959 }
1960
1961 bool SpectatePrev(entity this)
1962 {
1963         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1964         entity ent = findchain(classname, STR_PLAYER);
1965         if (!ent) // no player
1966                 return false;
1967
1968         entity first = ent;
1969         // skip players until current spectated player
1970         if(this.enemy)
1971         while(ent && ent != this.enemy)
1972                 ent = ent.chain;
1973
1974         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1975         {
1976                 case MUT_SPECPREV_FOUND:
1977                         ent = M_ARGV(1, entity);
1978                         break;
1979                 case MUT_SPECPREV_RETURN:
1980                         return true;
1981                 case MUT_SPECPREV_CONTINUE:
1982                 default:
1983                 {
1984                         if(ent.chain)
1985                                 ent = ent.chain;
1986                         else
1987                                 ent = first;
1988                         break;
1989                 }
1990         }
1991
1992         SetSpectatee(this, ent);
1993         return SpectateSet(this);
1994 }
1995
1996 /*
1997 =============
1998 ShowRespawnCountdown()
1999
2000 Update a respawn countdown display.
2001 =============
2002 */
2003 void ShowRespawnCountdown(entity this)
2004 {
2005         float number;
2006         if(!IS_DEAD(this)) // just respawned?
2007                 return;
2008         else
2009         {
2010                 number = ceil(this.respawn_time - time);
2011                 if(number <= 0)
2012                         return;
2013                 if(number <= this.respawn_countdown)
2014                 {
2015                         this.respawn_countdown = number - 1;
2016                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2017                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2018                 }
2019         }
2020 }
2021
2022 .bool team_selected;
2023 bool ShowTeamSelection(entity this)
2024 {
2025         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2026                 return false;
2027         stuffcmd(this, "menu_showteamselect\n");
2028         return true;
2029 }
2030 void Join(entity this)
2031 {
2032         TRANSMUTE(Player, this);
2033
2034         if(!this.team_selected)
2035         if(autocvar_g_campaign || autocvar_g_balance_teams)
2036                 TeamBalance_JoinBestTeam(this);
2037
2038         if(autocvar_g_campaign)
2039                 campaign_bots_may_start = true;
2040
2041         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2042
2043         PutClientInServer(this);
2044
2045         if(IS_PLAYER(this))
2046         if(teamplay && this.team != -1)
2047         {
2048         }
2049         else
2050                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2051         this.team_selected = false;
2052
2053         // z411
2054         // send constant ready notification
2055         if(warmup_stage)
2056                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2057 }
2058
2059 int GetPlayerLimit()
2060 {
2061         if(g_duel)
2062                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2063         int player_limit = autocvar_g_maxplayers;
2064         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2065         player_limit = M_ARGV(0, int);
2066         return player_limit;
2067 }
2068
2069 /**
2070  * Determines whether the player is allowed to join. This depends on cvar
2071  * g_maxplayers, if it isn't used this function always return true, otherwise
2072  * it checks whether the number of currently playing players exceeds g_maxplayers.
2073  * @return int number of free slots for players, 0 if none
2074  */
2075 int nJoinAllowed(entity this, entity ignore)
2076 {
2077         if(!ignore)
2078         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2079         // so report 0 free slots if restricted
2080         {
2081                 if(autocvar_g_forced_team_otherwise == "spectate")
2082                         return 0;
2083                 if(autocvar_g_forced_team_otherwise == "spectator")
2084                         return 0;
2085         }
2086
2087         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2088                 return 0; // forced spectators can never join
2089
2090         // TODO simplify this
2091         int totalClients = 0;
2092         int currentlyPlaying = 0;
2093         FOREACH_CLIENT(true, {
2094                 if(it != ignore)
2095                         ++totalClients;
2096                 if(IS_REAL_CLIENT(it))
2097                 if(IS_PLAYER(it) || it.caplayer)
2098                         ++currentlyPlaying;
2099         });
2100
2101         int player_limit = GetPlayerLimit();
2102
2103         int free_slots = 0;
2104         if (!player_limit)
2105                 free_slots = maxclients - totalClients;
2106         else if(player_limit > 0 && currentlyPlaying < player_limit)
2107                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2108
2109         static float msg_time = 0;
2110         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2111         {
2112                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2113                 msg_time = time + 0.5;
2114         }
2115
2116         return free_slots;
2117 }
2118
2119 void PrintWelcomeMessage(entity this)
2120 {
2121         if(CS(this).motd_actived_time == 0)
2122         {
2123                 if (autocvar_g_campaign) {
2124                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2125                                 CS(this).motd_actived_time = time;
2126                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2127                         }
2128                 } else {
2129                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2130                                 CS(this).motd_actived_time = time;
2131                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2132                         }
2133                 }
2134         }
2135         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2136         {
2137                 if (autocvar_g_campaign) {
2138                         if (PHYS_INPUT_BUTTON_INFO(this))
2139                                 CS(this).motd_actived_time = time;
2140                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2141                                 CS(this).motd_actived_time = 0;
2142                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2143                         }
2144                 } else {
2145                         if (PHYS_INPUT_BUTTON_INFO(this))
2146                                 CS(this).motd_actived_time = time;
2147                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2148                                 CS(this).motd_actived_time = 0;
2149                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2150                         }
2151                 }
2152         }
2153         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2154         {
2155                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2156                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2157                 else if (CS(this).motd_actived_time == -2)
2158                 {
2159                         // instantly hide MOTD
2160                         CS(this).motd_actived_time = 0;
2161                         if (autocvar_g_campaign)
2162                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2163                         else
2164                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2165                 }
2166                 else if (IS_PLAYER(this) || IS_SPEC(this))
2167                 {
2168                         // FIXME occasionally for some reason MOTD never goes away
2169                         // delay MOTD removal a little bit in the hope it fixes this bug
2170                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2171                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2172                         else //if (CS(this).motd_actived_time < -2)
2173                                 CS(this).motd_actived_time++;
2174                 }
2175         }
2176 }
2177
2178 bool joinAllowed(entity this)
2179 {
2180         if (CS(this).version_mismatch) return false;
2181         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2182         if (!nJoinAllowed(this, this)) return false;
2183         if (teamplay && lockteams) return false;
2184         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2185         if (ShowTeamSelection(this)) return false;
2186         return true;
2187 }
2188
2189 .string shootfromfixedorigin;
2190 .bool dualwielding_prev;
2191 bool PlayerThink(entity this)
2192 {
2193         if (game_stopped || intermission_running) {
2194                 this.modelflags &= ~MF_ROCKET;
2195                 if(intermission_running)
2196                         IntermissionThink(this);
2197                 return false;
2198         }
2199
2200         if (game_timeout) {
2201         // don't allow the player to turn around while game is paused
2202                 // FIXME turn this into CSQC stuff
2203                 this.v_angle = this.lastV_angle;
2204                 this.angles = this.lastV_angle;
2205                 this.fixangle = true;
2206                 return false;
2207         }
2208
2209         if (frametime) player_powerups(this);
2210
2211         if (IS_DEAD(this)) {
2212                 if (this.personal && g_race_qualifying) {
2213                         if (time > this.respawn_time) {
2214                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2215                                 respawn(this);
2216                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2217                         }
2218                 } else {
2219                         if (frametime) player_anim(this);
2220
2221                         if (this.respawn_flags & RESPAWN_DENY)
2222                         {
2223                                 STAT(RESPAWN_TIME, this) = 0;
2224                                 return false;
2225                         }
2226
2227                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2228
2229                         switch(this.deadflag)
2230                         {
2231                                 case DEAD_DYING:
2232                                 {
2233                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2234                                                 this.deadflag = DEAD_RESPAWNING;
2235                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2236                                                 this.deadflag = DEAD_DEAD;
2237                                         break;
2238                                 }
2239                                 case DEAD_DEAD:
2240                                 {
2241                                         if (button_pressed)
2242                                                 this.deadflag = DEAD_RESPAWNABLE;
2243                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2244                                                 this.deadflag = DEAD_RESPAWNING;
2245                                         break;
2246                                 }
2247                                 case DEAD_RESPAWNABLE:
2248                                 {
2249                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2250                                                 this.deadflag = DEAD_RESPAWNING;
2251                                         break;
2252                                 }
2253                                 case DEAD_RESPAWNING:
2254                                 {
2255                                         if (time > this.respawn_time)
2256                                         {
2257                                                 this.respawn_time = time + 1; // only retry once a second
2258                                                 this.respawn_time_max = this.respawn_time;
2259                                                 respawn(this);
2260                                         }
2261                                         break;
2262                                 }
2263                         }
2264
2265                         ShowRespawnCountdown(this);
2266
2267                         if (this.respawn_flags & RESPAWN_SILENT)
2268                                 STAT(RESPAWN_TIME, this) = 0;
2269                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2270                         {
2271                                 if (time < this.respawn_time)
2272                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2273                                 else if (this.deadflag != DEAD_RESPAWNING)
2274                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2275                         }
2276                         else
2277                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2278                 }
2279
2280                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2281                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2282                         STAT(RESPAWN_TIME, this) *= -1;
2283
2284                 return false;
2285         }
2286
2287         FixPlayermodel(this);
2288
2289         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2290                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2291                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2292         }
2293
2294         // reset gun alignment when dual wielding status changes
2295         // to ensure guns are always aligned right and left
2296         bool dualwielding = W_DualWielding(this);
2297         if(this.dualwielding_prev != dualwielding)
2298         {
2299                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2300                 this.dualwielding_prev = dualwielding;
2301         }
2302
2303         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2304         //if(frametime)
2305         {
2306                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2307                 {
2308                         .entity weaponentity = weaponentities[slot];
2309                         if(WEP_CVAR(vortex, charge_always))
2310                                 W_Vortex_Charge(this, weaponentity, frametime);
2311                         W_WeaponFrame(this, weaponentity);
2312                 }
2313         }
2314
2315         if (frametime)
2316         {
2317                 // WEAPONTODO: Add a weapon request for this
2318                 // rot vortex charge to the charge limit
2319                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2320                 {
2321                         .entity weaponentity = weaponentities[slot];
2322                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2323                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2324                 }
2325
2326                 player_regen(this);
2327                 player_anim(this);
2328                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2329         }
2330
2331         monsters_setstatus(this);
2332
2333         return true;
2334 }
2335
2336 .bool would_spectate;
2337 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2338 void ObserverOrSpectatorThink(entity this)
2339 {
2340         bool is_spec = IS_SPEC(this);
2341         if ( CS(this).impulse )
2342         {
2343                 int r = MinigameImpulse(this, CS(this).impulse);
2344                 if (!is_spec || r)
2345                         CS(this).impulse = 0;
2346
2347                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2348                 {
2349                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2350                         CS(this).impulse = 0;
2351                         return;
2352                 }
2353         }
2354
2355         if (this.flags & FL_JUMPRELEASED) {
2356                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2357                         this.flags &= ~FL_JUMPRELEASED;
2358                         this.flags |= FL_SPAWNING;
2359                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2360                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         if(SpectateNext(this)) {
2363                                 TRANSMUTE(Spectator, this);
2364                         } else if (is_spec) {
2365                                 TRANSMUTE(Observer, this);
2366                                 PutClientInServer(this);
2367                         }
2368                         else
2369                                 this.would_spectate = false; // unable to spectate anyone
2370                         if (is_spec)
2371                                 CS(this).impulse = 0;
2372                 } else if (is_spec) {
2373                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2374                                 this.flags &= ~FL_JUMPRELEASED;
2375                                 if(SpectatePrev(this)) {
2376                                         TRANSMUTE(Spectator, this);
2377                                 } else {
2378                                         TRANSMUTE(Observer, this);
2379                                         PutClientInServer(this);
2380                                 }
2381                                 CS(this).impulse = 0;
2382                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2383                                 this.would_spectate = false;
2384                                 this.flags &= ~FL_JUMPRELEASED;
2385                                 TRANSMUTE(Observer, this);
2386                                 PutClientInServer(this);
2387                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2388                                 PutObserverInServer(this);
2389                                 this.would_spectate = true;
2390                         }
2391                 }
2392                 else {
2393                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2394                         if (PHYS_INPUT_BUTTON_USE(this))
2395                                 wouldclip = !wouldclip;
2396                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2397                         set_movetype(this, preferred_movetype);
2398                 }
2399         } else { // jump pressed
2400                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2401                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2402                         this.flags |= FL_JUMPRELEASED;
2403                         if(this.flags & FL_SPAWNING)
2404                         {
2405                                 this.flags &= ~FL_SPAWNING;
2406                                 if(joinAllowed(this))
2407                                         Join(this);
2408                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2409                                         CS(this).autojoin_checked = -1;
2410                                 return;
2411                         }
2412                 }
2413                 if(is_spec && !SpectateUpdate(this))
2414                         PutObserverInServer(this);
2415         }
2416         if (is_spec)
2417                 this.flags |= FL_CLIENT | FL_NOTARGET;
2418 }
2419
2420 void PlayerUseKey(entity this)
2421 {
2422         if (!IS_PLAYER(this))
2423                 return;
2424
2425         if(this.vehicle)
2426         {
2427                 if(!game_stopped)
2428                 {
2429                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2430                         return;
2431                 }
2432         }
2433         else if(autocvar_g_vehicles_enter)
2434         {
2435                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2436                 {
2437                         entity head, closest_target = NULL;
2438                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2439
2440                         while(head) // find the closest acceptable target to enter
2441                         {
2442                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2443                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2444                                 {
2445                                         if(closest_target)
2446                                         {
2447                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2448                                                 { closest_target = head; }
2449                                         }
2450                                         else { closest_target = head; }
2451                                 }
2452
2453                                 head = head.chain;
2454                         }
2455
2456                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2457                 }
2458         }
2459
2460         // a use key was pressed; call handlers
2461         MUTATOR_CALLHOOK(PlayerUseKey, this);
2462 }
2463
2464
2465 /*
2466 =============
2467 PlayerPreThink
2468
2469 Called every frame for each client before the physics are run
2470 =============
2471 */
2472 .float last_vehiclecheck;
2473 void PlayerPreThink (entity this)
2474 {
2475         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2476         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2477
2478         WarpZone_PlayerPhysics_FixVAngle(this);
2479
2480         if (frametime) {
2481                 // physics frames: update anticheat stuff
2482                 anticheat_prethink(this);
2483
2484                 // WORKAROUND: only use dropclient in server frames (frametime set).
2485                 // Never use it in cl_movement frames (frametime zero).
2486                 if (blockSpectators && IS_REAL_CLIENT(this)
2487                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2488                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2489                 {
2490                         if (dropclient_schedule(this))
2491                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2492                 }
2493         }
2494
2495         zoomstate_set = false;
2496
2497         // Check for nameless players
2498         if (this.netname == "" || this.netname != CS(this).netname_previous)
2499         {
2500                 bool assume_unchanged = (CS(this).netname_previous == "");
2501                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2502                 {
2503                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2504                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2505                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2506                         assume_unchanged = false;
2507                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2508                 }
2509                 if (isInvisibleString(this.netname))
2510                 {
2511                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2512                         sprint(this, "Warning: invisible names are not allowed.\n");
2513                         assume_unchanged = false;
2514                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2515                 }
2516                 if (!assume_unchanged && autocvar_sv_eventlog)
2517                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2518                 strcpy(CS(this).netname_previous, this.netname);
2519         }
2520
2521         // version nagging
2522         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2523         CS(this).version_nagtime = 0;
2524         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2525             // git client
2526         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2527             // git server
2528             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2529         } else {
2530             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2531             if (r < 0) { // old client
2532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2533             } else if (r > 0) { // old server
2534                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2535             }
2536         }
2537     }
2538
2539         // GOD MODE info
2540         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2541         {
2542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2543                 this.max_armorvalue = 0;
2544         }
2545
2546         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2547         {
2548                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2549                 {
2550                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2551                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2552                         if (this.iceblock)
2553                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2554
2555                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2556                                 Unfreeze(this, false);
2557                 }
2558                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2559                 {
2560                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2561                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2562
2563                         if (GetResource(this, RES_HEALTH) < 1)
2564                         {
2565                                 if (this.vehicle)
2566                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2567                                 if(this.event_damage)
2568                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2569                         }
2570                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2571                                 Unfreeze(this, false);
2572                 }
2573         }
2574
2575         MUTATOR_CALLHOOK(PlayerPreThink, this);
2576
2577         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2578         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2579         {
2580                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2581                 {
2582                         if(!it.owner)
2583                         {
2584                                 if(!it.team || SAME_TEAM(this, it))
2585                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2586                                 else if(autocvar_g_vehicles_steal)
2587                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2588                         }
2589                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2590                         {
2591                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2592                         }
2593                 });
2594
2595                 this.last_vehiclecheck = time + 1;
2596         }
2597
2598         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2599         {
2600                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2601                         PlayerUseKey(this);
2602                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2603         }
2604
2605         if (IS_REAL_CLIENT(this))
2606                 PrintWelcomeMessage(this);
2607
2608         if (IS_PLAYER(this)) {
2609                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2610                         error("Client can't be spawned as player on connection!");
2611                 if(!PlayerThink(this))
2612                         return;
2613         }
2614         else if (game_stopped || intermission_running) {
2615                 if(intermission_running)
2616                         IntermissionThink(this);
2617                 return;
2618         }
2619         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2620         {
2621                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2622                 CS(this).autojoin_checked = 1;
2623                 // don't do this in ClientConnect
2624                 // many things can go wrong if a client is spawned as player on connection
2625                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2626                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2627                                 && (!teamplay || autocvar_g_balance_teams)))
2628                 {
2629                         campaign_bots_may_start = true;
2630                         if(joinAllowed(this))
2631                                 Join(this);
2632                         return;
2633                 }
2634         }
2635         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2636                 ObserverOrSpectatorThink(this);
2637         }
2638
2639         // WEAPONTODO: Add weapon request for this
2640         if (!zoomstate_set) {
2641                 bool wep_zoomed = false;
2642                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2643                 {
2644                         .entity weaponentity = weaponentities[slot];
2645                         Weapon thiswep = this.(weaponentity).m_weapon;
2646                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2647                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2648                 }
2649                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2650         }
2651
2652         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2653         {
2654                 CS(this).teamkill_soundtime = 0;
2655
2656                 entity e = CS(this).teamkill_soundsource;
2657                 entity oldpusher = e.pusher;
2658                 e.pusher = this;
2659                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2660                 e.pusher = oldpusher;
2661         }
2662
2663         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2664                 CS(this).taunt_soundtime = 0;
2665                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2666         }
2667
2668         target_voicescript_next(this);
2669 }
2670
2671 void DrownPlayer(entity this)
2672 {
2673         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2674                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2675         {
2676                 STAT(AIR_FINISHED, this) = 0;
2677                 return;
2678         }
2679
2680         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2681         {
2682                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2683                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2684                 STAT(AIR_FINISHED, this) = 0;
2685         }
2686         else
2687         {
2688                 if (!STAT(AIR_FINISHED, this))
2689                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2690                 if (STAT(AIR_FINISHED, this) < time)
2691                 {       // drown!
2692                         if (this.pain_finished < time)
2693                         {
2694                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2695                                 this.pain_finished = time + 0.5;
2696                         }
2697                 }
2698         }
2699 }
2700
2701 .bool move_qcphysics;
2702
2703 void Player_Physics(entity this)
2704 {
2705         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2706
2707         if(!this.move_qcphysics)
2708                 return;
2709
2710         if(!frametime && !CS(this).pm_frametime)
2711                 return;
2712
2713         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2714
2715         CS(this).pm_frametime = 0;
2716 }
2717
2718 /*
2719 =============
2720 PlayerPostThink
2721
2722 Called every frame for each client after the physics are run
2723 =============
2724 */
2725 void PlayerPostThink (entity this)
2726 {
2727         Player_Physics(this);
2728
2729         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2730         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2731         if (IS_REAL_CLIENT(this))
2732         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2733         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2734         {
2735                 int totalClients = 0;
2736                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2737                 {
2738                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2739                         {
2740                                 ++totalClients;
2741                         });
2742                 }
2743
2744                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2745                 { /* do nothing */ }
2746                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2747                 {
2748                         if (CS(this).idlekick_lasttimeleft)
2749                         {
2750                                 CS(this).idlekick_lasttimeleft = 0;
2751                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2752                         }
2753                 }
2754                 else
2755                 {
2756                         float maxidle_time = autocvar_sv_maxidle;
2757                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2758                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2759                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2760                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2761                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2762                         {
2763                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2764                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2765                                 else
2766                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2767                         }
2768                         if (timeleft <= 0) {
2769                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2770                                 {
2771                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2772                                         if (this.caplayer)
2773                                                 this.caplayer = 0;
2774                                         PutObserverInServer(this);
2775                                 }
2776                                 else
2777                                 {
2778                                         if (dropclient_schedule(this))
2779                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2780                                 }
2781                                 return;
2782                         }
2783                         else if (timeleft <= countdown_time) {
2784                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2785                                         play2(this, SND(TALK2));
2786                                 CS(this).idlekick_lasttimeleft = timeleft;
2787                         }
2788                 }
2789         }
2790
2791         CheatFrame(this);
2792
2793         if (game_stopped)
2794         {
2795                 this.solid = SOLID_NOT;
2796                 this.takedamage = DAMAGE_NO;
2797                 set_movetype(this, MOVETYPE_NONE);
2798                 CS(this).teamkill_complain = 0;
2799                 CS(this).teamkill_soundtime = 0;
2800                 CS(this).teamkill_soundsource = NULL;
2801         }
2802
2803         if (IS_PLAYER(this)) {
2804                 if(this.death_time == time && IS_DEAD(this))
2805                 {
2806                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2807                         // once all the damage events of this frame have been processed with normal size
2808                         this.maxs.z = 5;
2809                         setsize(this, this.mins, this.maxs);
2810                 }
2811                 DrownPlayer(this);
2812                 UpdateChatBubble(this);
2813                 if (CS(this).impulse) ImpulseCommands(this);
2814                 GetPressedKeys(this);
2815                 if (game_stopped)
2816                 {
2817                         CSQCMODEL_AUTOUPDATE(this);
2818                         return;
2819                 }
2820         }
2821         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2822         {
2823                 CS(this).pressedkeys = 0;
2824                 STAT(PRESSED_KEYS, this) = 0;
2825         }
2826
2827         if (this.waypointsprite_attachedforcarrier) {
2828                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2829                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2830         }
2831
2832         CSQCMODEL_AUTOUPDATE(this);
2833 }
2834
2835 // hack to copy the button fields from the client entity to the Client State
2836 void PM_UpdateButtons(entity this, entity store)
2837 {
2838         if(this.impulse)
2839                 store.impulse = this.impulse;
2840         this.impulse = 0;
2841
2842         bool typing = this.buttonchat || this.button12;
2843
2844         store.button0 = (typing) ? 0 : this.button0;
2845         //button1?!
2846         store.button2 = (typing) ? 0 : this.button2;
2847         store.button3 = (typing) ? 0 : this.button3;
2848         store.button4 = this.button4;
2849         store.button5 = (typing) ? 0 : this.button5;
2850         store.button6 = this.button6;
2851         store.button7 = this.button7;
2852         store.button8 = this.button8;
2853         store.button9 = this.button9;
2854         store.button10 = this.button10;
2855         store.button11 = this.button11;
2856         store.button12 = this.button12;
2857         store.button13 = this.button13;
2858         store.button14 = this.button14;
2859         store.button15 = this.button15;
2860         store.button16 = this.button16;
2861         store.buttonuse = this.buttonuse;
2862         store.buttonchat = this.buttonchat;
2863
2864         store.cursor_active = this.cursor_active;
2865         store.cursor_screen = this.cursor_screen;
2866         store.cursor_trace_start = this.cursor_trace_start;
2867         store.cursor_trace_endpos = this.cursor_trace_endpos;
2868         store.cursor_trace_ent = this.cursor_trace_ent;
2869
2870         store.ping = this.ping;
2871         store.ping_packetloss = this.ping_packetloss;
2872         store.ping_movementloss = this.ping_movementloss;
2873
2874         store.v_angle = this.v_angle;
2875         store.movement = this.movement;
2876 }
2877
2878 NET_HANDLE(fpsreport, bool)
2879 {
2880         int fps = ReadShort();
2881         PlayerScore_Set(sender, SP_FPS, fps);
2882         return true;
2883 }