qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 void send_TeamNames(int channel, entity to) {
 102         msg_entity = to;
 103
 104         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 105         WriteString(channel, autocvar_g_teamnames_red);
 106         WriteString(channel, autocvar_g_teamnames_blue);
 107         WriteString(channel, autocvar_g_teamnames_yellow);
 108         WriteString(channel, autocvar_g_teamnames_pink);
 109 }
 110
 111 int CountSpectators(entity player, entity to)
 112 {
 113         if(!player) { return 0; } // not sure how, but best to be safe
 114
 115         int spec_count = 0;
 116
 117         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 118         {
 119                 spec_count++;
 120         });
 121
 122         return spec_count;
 123 }
 124
 125 void WriteSpectators(entity player, entity to)
 126 {
 127         if(!player) { return; } // not sure how, but best to be safe
 128
 129         int spec_count = 0;
 130         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 131         {
 132                 if(spec_count >= MAX_SPECTATORS)
 133                         break;
 134                 WriteByte(MSG_ENTITY, num_for_edict(it));
 135                 ++spec_count;
 136         });
 137 }
 138
 139 bool ClientData_Send(entity this, entity to, int sf)
 140 {
 141         assert(to == this.owner, return false);
 142
 143         entity e = to;
 144         if (IS_SPEC(e)) e = e.enemy;
 145
 146         sf = 0;
 147         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 148         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 149         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 150         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 151
 152         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 153         WriteByte(MSG_ENTITY, sf);
 154
 155         if (sf & BIT(1))
 156                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 157
 158         if(sf & BIT(4))
 159         {
 160                 float specs = CountSpectators(e, to);
 161                 WriteByte(MSG_ENTITY, specs);
 162                 WriteSpectators(e, to);
 163         }
 164
 165         return true;
 166 }
 167
 168 void ClientData_Attach(entity this)
 169 {
 170         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 171         CS(this).clientdata.drawonlytoclient = this;
 172         CS(this).clientdata.owner = this;
 173 }
 174
 175 void ClientData_Detach(entity this)
 176 {
 177         delete(CS(this).clientdata);
 178         CS(this).clientdata = NULL;
 179 }
 180
 181 void ClientData_Touch(entity e)
 182 {
 183         entity cd = CS(e).clientdata;
 184         if (cd) { cd.SendFlags = 1; }
 185
 186         // make it spectatable
 187         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 188         {
 189                 entity cd = CS(it).clientdata;
 190                 if (cd) { cd.SendFlags = 1; }
 191         });
 192 }
 193
 194
 195 /*
 196 =============
 197 CheckPlayerModel
 198
 199 Checks if the argument string can be a valid playermodel.
 200 Returns a valid one in doubt.
 201 =============
 202 */
 203 string FallbackPlayerModel;
 204 string CheckPlayerModel(string plyermodel) {
 205         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 206         {
 207                 // note: we cannot summon Don Strunzone here, some player may
 208                 // still have the model string set. In case anyone manages how
 209                 // to change a cvar default, we'll have a small leak here.
 210                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 211         }
 212         // only in right path
 213         if(substring(plyermodel, 0, 14) != "models/player/")
 214                 return FallbackPlayerModel;
 215         // only good file extensions
 216         if(substring(plyermodel, -4, 4) != ".iqm"
 217                 && substring(plyermodel, -4, 4) != ".zym"
 218                 && substring(plyermodel, -4, 4) != ".dpm"
 219                 && substring(plyermodel, -4, 4) != ".md3"
 220                 && substring(plyermodel, -4, 4) != ".psk")
 221         {
 222                 return FallbackPlayerModel;
 223         }
 224         // forbid the LOD models
 225         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 226                 return FallbackPlayerModel;
 227         if(plyermodel != strtolower(plyermodel))
 228                 return FallbackPlayerModel;
 229         // also, restrict to server models
 230         if(autocvar_sv_servermodelsonly)
 231         {
 232                 if(!fexists(plyermodel))
 233                         return FallbackPlayerModel;
 234         }
 235         return plyermodel;
 236 }
 237
 238 void setplayermodel(entity e, string modelname)
 239 {
 240         precache_model(modelname);
 241         _setmodel(e, modelname);
 242         player_setupanimsformodel(e);
 243         if(!autocvar_g_debug_globalsounds)
 244                 UpdatePlayerSounds(e);
 245 }
 246
 247 /** putting a client as observer in the server */
 248 void PutObserverInServer(entity this, bool is_forced)
 249 {
 250         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 251         PlayerState_detach(this);
 252
 253         if (IS_PLAYER(this))
 254         {
 255                 if(GetResource(this, RES_HEALTH) >= 1)
 256                 {
 257                         // despawn effect
 258                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 259                 }
 260
 261                 // was a player, recount votes and ready status
 262                 if(IS_REAL_CLIENT(this))
 263                 {
 264                         if (vote_called) { VoteCount(false); }
 265                         ReadyCount();
 266                 }
 267                 entcs_update_players(this);
 268         }
 269
 270         entity spot = SelectSpawnPoint(this, true);
 271         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 272         this.angles = vec2(spot.angles);
 273         this.fixangle = true;
 274         // offset it so that the spectator spawns higher off the ground, looks better this way
 275         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         WaypointSprite_PlayerDead(this);
 309
 310         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 311                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 312
 313         accuracy_resend(this);
 314
 315         CS(this).spectatortime = time;
 316         if(this.bot_attack)
 317                 IL_REMOVE(g_bot_targets, this);
 318         this.bot_attack = false;
 319         if(this.monster_attack)
 320                 IL_REMOVE(g_monster_targets, this);
 321         this.monster_attack = false;
 322         STAT(HUD, this) = HUD_NORMAL;
 323         TRANSMUTE(Observer, this);
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         this.items = 0;
 365         STAT(WEAPONS, this) = '0 0 0';
 366         this.drawonlytoclient = this;
 367
 368         this.viewloc = NULL;
 369
 370         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 371
 372         this.weaponmodel = "";
 373         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 374         {
 375                 this.weaponentities[slot] = NULL;
 376         }
 377         this.exteriorweaponentity = NULL;
 378         CS(this).killcount = FRAGS_SPECTATOR;
 379         this.velocity = '0 0 0';
 380         this.avelocity = '0 0 0';
 381         this.punchangle = '0 0 0';
 382         this.punchvector = '0 0 0';
 383         this.oldvelocity = this.velocity;
 384         this.event_damage = func_null;
 385         this.event_heal = func_null;
 386
 387         for(int slot = 0; slot < MAX_AXH; ++slot)
 388         {
 389                 entity axh = this.(AuxiliaryXhair[slot]);
 390                 this.(AuxiliaryXhair[slot]) = NULL;
 391
 392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 393                         delete(axh);
 394         }
 395
 396         if (mutator_returnvalue)
 397         {
 398                 // mutator prevents resetting teams+score
 399         }
 400         else
 401         {
 402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 403                 this.frags = FRAGS_SPECTATOR;
 404         }
 405
 406         bot_relinkplayerlist();
 407
 408         if (CS(this).just_joined)
 409                 CS(this).just_joined = false;
 410 }
 411
 412 int player_getspecies(entity this)
 413 {
 414         get_model_parameters(this.model, this.skin);
 415         int s = get_model_parameters_species;
 416         get_model_parameters(string_null, 0);
 417         if (s < 0) return SPECIES_HUMAN;
 418         return s;
 419 }
 420
 421 .float model_randomizer;
 422 void FixPlayermodel(entity player)
 423 {
 424         string defaultmodel = "";
 425         int defaultskin = 0;
 426         if(autocvar_sv_defaultcharacter)
 427         {
 428                 if(teamplay)
 429                 {
 430                         switch(player.team)
 431                         {
 432                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 433                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 434                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 435                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 436                         }
 437                 }
 438
 439                 if(defaultmodel == "")
 440                 {
 441                         defaultmodel = autocvar_sv_defaultplayermodel;
 442                         defaultskin = autocvar_sv_defaultplayerskin;
 443                 }
 444
 445                 int n = tokenize_console(defaultmodel);
 446                 if(n > 0)
 447                 {
 448                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 449                         // However, do NOT randomize if the player-selected model is in the list.
 450                         for (int i = 0; i < n; ++i)
 451                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 452                                         defaultmodel = argv(i);
 453                 }
 454
 455                 int i = strstrofs(defaultmodel, ":", 0);
 456                 if(i >= 0)
 457                 {
 458                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 459                         defaultmodel = substring(defaultmodel, 0, i);
 460                 }
 461         }
 462         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 463         {
 464                 if(teamplay)
 465                 {
 466                         switch(player.team)
 467                         {
 468                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 469                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 470                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 471                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 472                         }
 473                 }
 474
 475                 if(!defaultskin)
 476                         defaultskin = autocvar_sv_defaultplayerskin;
 477         }
 478
 479         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 480         defaultmodel = M_ARGV(0, string);
 481         defaultskin = M_ARGV(1, int);
 482
 483         bool chmdl = false;
 484         int oldskin;
 485         if(defaultmodel != "")
 486         {
 487                 if (defaultmodel != player.model)
 488                 {
 489                         vector m1 = player.mins;
 490                         vector m2 = player.maxs;
 491                         setplayermodel (player, defaultmodel);
 492                         setsize (player, m1, m2);
 493                         chmdl = true;
 494                 }
 495
 496                 oldskin = player.skin;
 497                 player.skin = defaultskin;
 498         } else {
 499                 if (player.playermodel != player.model || player.playermodel == "")
 500                 {
 501                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 502                         vector m1 = player.mins;
 503                         vector m2 = player.maxs;
 504                         setplayermodel (player, player.playermodel);
 505                         setsize (player, m1, m2);
 506                         chmdl = true;
 507                 }
 508
 509                 if(!autocvar_sv_defaultcharacterskin)
 510                 {
 511                         oldskin = player.skin;
 512                         player.skin = stof(player.playerskin);
 513                 }
 514                 else
 515                 {
 516                         oldskin = player.skin;
 517                         player.skin = defaultskin;
 518                 }
 519         }
 520
 521         if(chmdl || oldskin != player.skin) // model or skin has changed
 522         {
 523                 player.species = player_getspecies(player); // update species
 524                 if(!autocvar_g_debug_globalsounds)
 525                         UpdatePlayerSounds(player); // update skin sounds
 526         }
 527
 528         if(!teamplay)
 529                 if(strlen(autocvar_sv_defaultplayercolors))
 530                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 531                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 532 }
 533
 534 void ResetPlayerResources(entity this)
 535 {
 536         if (warmup_stage) {
 537                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 538                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 539                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 540                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 541                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 542                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 543                 SetResource(this, RES_HEALTH, warmup_start_health);
 544                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 545                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 546         } else {
 547                 SetResource(this, RES_SHELLS, start_ammo_shells);
 548                 SetResource(this, RES_BULLETS, start_ammo_nails);
 549                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 550                 SetResource(this, RES_CELLS, start_ammo_cells);
 551                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 552                 SetResource(this, RES_FUEL, start_ammo_fuel);
 553                 SetResource(this, RES_HEALTH, start_health);
 554                 SetResource(this, RES_ARMOR, start_armorvalue);
 555                 STAT(WEAPONS, this) = start_weapons;
 556                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 557                 {
 558                         GiveRandomWeapons(this, random_start_weapons_count,
 559                                 autocvar_g_random_start_weapons, random_start_ammo);
 560                 }
 561         }
 562 }
 563
 564 void PutPlayerInServer(entity this)
 565 {
 566         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 567
 568         PlayerState_attach(this);
 569         accuracy_resend(this);
 570
 571         if (this.team < 0)
 572                 TeamBalance_JoinBestTeam(this);
 573
 574         entity spot = SelectSpawnPoint(this, false);
 575         if (!spot) {
 576                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 577                 return; // spawn failed
 578         }
 579
 580         TRANSMUTE(Player, this);
 581
 582         CS(this).wasplayer = true;
 583         this.iscreature = true;
 584         this.teleportable = TELEPORT_NORMAL;
 585         if(!this.damagedbycontents)
 586                 IL_PUSH(g_damagedbycontents, this);
 587         this.damagedbycontents = true;
 588         set_movetype(this, MOVETYPE_WALK);
 589         this.solid = SOLID_SLIDEBOX;
 590         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 591         if (autocvar_g_playerclip_collisions)
 592                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 593         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 594                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 595         this.frags = FRAGS_PLAYER;
 596         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 597         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 598         if (autocvar__notarget)
 599                 this.flags |= FL_NOTARGET;
 600         this.takedamage = DAMAGE_AIM;
 601         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 602
 603         ResetPlayerResources(this);
 604
 605         SetSpectatee_status(this, 0);
 606
 607         PS(this).dual_weapons = '0 0 0';
 608
 609         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 610                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 611
 612         this.items = start_items;
 613
 614         float shieldtime = time + autocvar_g_spawnshieldtime;
 615
 616         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 617         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 618         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 619         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 620         if (!sv_ready_restart_after_countdown && time < game_starttime)
 621         {
 622                 float f = game_starttime - time;
 623                 shieldtime += f;
 624                 this.pauserotarmor_finished += f;
 625                 this.pauserothealth_finished += f;
 626                 this.pauseregen_finished += f;
 627         }
 628
 629         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 630
 631         this.damageforcescale = autocvar_g_player_damageforcescale;
 632         this.death_time = 0;
 633         this.respawn_flags = 0;
 634         this.respawn_time = 0;
 635         STAT(RESPAWN_TIME, this) = 0;
 636         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(REVIVE_PROGRESS, this) = 0;
 661         this.revival_time = 0;
 662
 663         STAT(AIR_FINISHED, this) = 0;
 664         this.waterlevel = WATERLEVEL_NONE;
 665         this.watertype = CONTENT_EMPTY;
 666
 667         entity spawnevent = new_pure(spawnevent);
 668         spawnevent.owner = this;
 669         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 670
 671         // Cut off any still running player sounds.
 672         stopsound(this, CH_PLAYER_SINGLE);
 673
 674         this.model = "";
 675         FixPlayermodel(this);
 676         this.drawonlytoclient = NULL;
 677
 678         this.viewloc = NULL;
 679
 680         for(int slot = 0; slot < MAX_AXH; ++slot)
 681         {
 682                 entity axh = this.(AuxiliaryXhair[slot]);
 683                 this.(AuxiliaryXhair[slot]) = NULL;
 684
 685                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 686                         delete(axh);
 687         }
 688
 689         this.spawnpoint_targ = NULL;
 690
 691         UNSET_DUCKED(this);
 692         this.view_ofs = STAT(PL_VIEW_OFS, this);
 693         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 694         this.spawnorigin = spot.origin;
 695         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 696         // don't reset back to last position, even if new position is stuck in solid
 697         this.oldorigin = this.origin;
 698         if(this.conveyor)
 699                 IL_REMOVE(g_conveyed, this);
 700         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 701         if(this.swampslug)
 702                 IL_REMOVE(g_swamped, this);
 703         this.swampslug = NULL;
 704         this.swamp_interval = 0;
 705         if(this.ladder_entity)
 706                 IL_REMOVE(g_ladderents, this);
 707         this.ladder_entity = NULL;
 708         IL_EACH(g_counters, it.realowner == this,
 709         {
 710                 delete(it);
 711         });
 712         STAT(HUD, this) = HUD_NORMAL;
 713
 714         this.event_damage = PlayerDamage;
 715         this.event_heal = PlayerHeal;
 716
 717         this.draggable = func_null;
 718
 719         if(!this.bot_attack)
 720                 IL_PUSH(g_bot_targets, this);
 721         this.bot_attack = true;
 722         if(!this.monster_attack)
 723                 IL_PUSH(g_monster_targets, this);
 724         this.monster_attack = true;
 725         navigation_dynamicgoal_init(this, false);
 726
 727         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 728
 729         // player was spectator
 730         if (CS(this).killcount == FRAGS_SPECTATOR) {
 731                 PlayerScore_Clear(this);
 732                 CS(this).killcount = 0;
 733                 CS(this).startplaytime = time;
 734         }
 735
 736         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 CL_SpawnWeaponentity(this, weaponentity);
 740         }
 741         this.alpha = default_player_alpha;
 742         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 743         this.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745         this.speedrunning = false;
 746
 747         this.counter_cnt = 0;
 748         this.fragsfilter_cnt = 0;
 749
 750         target_voicescript_clear(this);
 751
 752         // reset fields the weapons may use
 753         FOREACH(Weapons, true, {
 754                 it.wr_resetplayer(it, this);
 755                         // reload all reloadable weapons
 756                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 757                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758                         {
 759                                 .entity weaponentity = weaponentities[slot];
 760                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 761                         }
 762                 }
 763         });
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768
 769         {
 770                 string s = spot.target;
 771                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 772                         spot.target = string_null;
 773                 SUB_UseTargets(spot, this, NULL);
 774                 if(g_assault || g_race)
 775                         spot.target = s;
 776         }
 777
 778         if (autocvar_spawn_debug)
 779         {
 780                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 781                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 782         }
 783
 784         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 785         {
 786                 .entity weaponentity = weaponentities[slot];
 787                 entity w_ent = this.(weaponentity);
 788                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 789                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 790                 else
 791                         w_ent.m_switchweapon = WEP_Null;
 792                 w_ent.m_weapon = WEP_Null;
 793                 w_ent.weaponname = "";
 794                 w_ent.m_switchingweapon = WEP_Null;
 795                 w_ent.cnt = -1;
 796         }
 797
 798         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 799
 800         if (CS(this).impulse) ImpulseCommands(this);
 801
 802         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 803         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 804         {
 805                 .entity weaponentity = weaponentities[slot];
 806                 W_WeaponFrame(this, weaponentity);
 807         }
 808
 809         if (!warmup_stage && !this.alivetime)
 810                 this.alivetime = time;
 811
 812         antilag_clear(this, CS(this));
 813 }
 814
 815 /** Called when a client spawns in the server */
 816 void PutClientInServer(entity this)
 817 {
 818         if (IS_BOT_CLIENT(this)) {
 819                 TRANSMUTE(Player, this);
 820         } else if (IS_REAL_CLIENT(this)) {
 821                 msg_entity = this;
 822                 WriteByte(MSG_ONE, SVC_SETVIEW);
 823                 WriteEntity(MSG_ONE, this);
 824         }
 825         if (game_stopped)
 826                 TRANSMUTE(Observer, this);
 827
 828         SetSpectatee(this, NULL);
 829
 830         // reset player keys
 831         if(PS(this))
 832                 PS(this).itemkeys = 0;
 833
 834         MUTATOR_CALLHOOK(PutClientInServer, this);
 835
 836         if (IS_OBSERVER(this)) {
 837                 PutObserverInServer(this, false);
 838         } else if (IS_PLAYER(this)) {
 839                 PutPlayerInServer(this);
 840         }
 841         // send team names
 842         if(teamplay && IS_REAL_CLIENT(this))
 843                 send_TeamNames(MSG_ONE, this);
 844         bot_relinkplayerlist();
 845 }
 846
 847 // TODO do we need all these fields, or should we stop autodetecting runtime
 848 // changes and just have a console command to update this?
 849 bool ClientInit_SendEntity(entity this, entity to, int sf)
 850 {
 851         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 852         return = true;
 853         msg_entity = to;
 854         // MSG_INIT replacement
 855         // TODO: make easier to use
 856         Registry_send_all();
 857         W_PROP_reload(MSG_ONE, to);
 858         ClientInit_misc(this);
 859         MUTATOR_CALLHOOK(Ent_Init);
 860 }
 861 void ClientInit_misc(entity this)
 862 {
 863         int channel = MSG_ONE;
 864         WriteHeader(channel, ENT_CLIENT_INIT);
 865         WriteByte(channel, g_nexball_meter_period * 32);
 866         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 869         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 870         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 873         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 874
 875         if(autocvar_sv_foginterval && world.fog != "")
 876                 WriteString(channel, world.fog);
 877         else
 878                 WriteString(channel, "");
 879         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 880         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 881         WriteByte(channel, serverflags);
 882         WriteCoord(channel, autocvar_g_trueaim_minrange);
 883
 884         // z411 send full hostname
 885         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 886         WriteString(channel, autocvar_sv_motd_permanent);
 887 }
 888
 889 void ClientInit_CheckUpdate(entity this)
 890 {
 891         this.nextthink = time;
 892         if(this.count != autocvar_g_balance_armor_blockpercent)
 893         {
 894                 this.count = autocvar_g_balance_armor_blockpercent;
 895                 this.SendFlags |= 1;
 896         }
 897         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 898         {
 899                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 900                 this.SendFlags |= 1;
 901         }
 902 }
 903
 904 void ClientInit_Spawn()
 905 {
 906         entity e = new_pure(clientinit);
 907         setthink(e, ClientInit_CheckUpdate);
 908         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 909
 910         ClientInit_CheckUpdate(e);
 911 }
 912
 913 /*
 914 =============
 915 SetNewParms
 916 =============
 917 */
 918 void SetNewParms ()
 919 {
 920         // initialize parms for a new player
 921         parm1 = -(86400 * 366);
 922
 923         MUTATOR_CALLHOOK(SetNewParms);
 924 }
 925
 926 /*
 927 =============
 928 SetChangeParms
 929 =============
 930 */
 931 void SetChangeParms (entity this)
 932 {
 933         // save parms for level change
 934         parm1 = CS(this).parm_idlesince - time;
 935
 936         MUTATOR_CALLHOOK(SetChangeParms);
 937 }
 938
 939 /*
 940 =============
 941 DecodeLevelParms
 942 =============
 943 */
 944 void DecodeLevelParms(entity this)
 945 {
 946         // load parms
 947         CS(this).parm_idlesince = parm1;
 948         if (CS(this).parm_idlesince == -(86400 * 366))
 949                 CS(this).parm_idlesince = time;
 950
 951         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 952         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 953
 954         MUTATOR_CALLHOOK(DecodeLevelParms);
 955 }
 956
 957 void FixClientCvars(entity e)
 958 {
 959         // send prediction settings to the client
 960         stuffcmd(e, "\nin_bindmap 0 0\n");
 961         if(autocvar_g_antilag == 3) // client side hitscan
 962                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 963         if(autocvar_sv_gentle)
 964                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 965
 966         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 967         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 968
 969         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 970
 971         MUTATOR_CALLHOOK(FixClientCvars, e);
 972 }
 973
 974 bool findinlist_abbrev(string tofind, string list)
 975 {
 976         if(list == "" || tofind == "")
 977                 return false; // empty list or search, just return
 978
 979         // this function allows abbreviated strings!
 980         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 981         {
 982                 return true;
 983         });
 984
 985         return false;
 986 }
 987
 988 bool PlayerInIPList(entity p, string iplist)
 989 {
 990         // some safety checks (never allow local?)
 991         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 992                 return false;
 993
 994         return findinlist_abbrev(p.netaddress, iplist);
 995 }
 996
 997 bool PlayerInIDList(entity p, string idlist)
 998 {
 999         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1000         if(!p.crypto_idfp)
1001                 return false;
1002
1003         return findinlist_abbrev(p.crypto_idfp, idlist);
1004 }
1005
1006 bool PlayerInList(entity player, string list)
1007 {
1008         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1009 }
1010
1011 #ifdef DP_EXT_PRECONNECT
1012 /*
1013 =============
1014 ClientPreConnect
1015
1016 Called once (not at each match start) when a client begins a connection to the server
1017 =============
1018 */
1019 void ClientPreConnect(entity this)
1020 {
1021         if(autocvar_sv_eventlog)
1022         {
1023                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1024                         this.playerid,
1025                         etof(this),
1026                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1027                 ));
1028         }
1029 }
1030 #endif
1031
1032 string GetClientVersionMessage(entity this)
1033 {
1034         if (CS(this).version_mismatch) {
1035                 if(CS(this).version < autocvar_gameversion) {
1036                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1037                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1038                 } else {
1039                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1040                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1041                 }
1042         } else {
1043                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1044         }
1045 }
1046
1047 string getwelcomemessage(entity this)
1048 {
1049         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1050         string modifications = M_ARGV(0, string);
1051
1052         if(g_weaponarena)
1053         {
1054                 if(g_weaponarena_random)
1055                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1056                 else
1057                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1058         }
1059         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1060                 modifications = strcat(modifications, ", No start weapons");
1061         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1062                 modifications = strcat(modifications, ", Low gravity");
1063         if(g_weapon_stay && !g_cts)
1064                 modifications = strcat(modifications, ", Weapons stay");
1065         if(autocvar_g_jetpack)
1066                 modifications = strcat(modifications, ", Jet pack");
1067         modifications = substring(modifications, 2, strlen(modifications) - 2);
1068
1069         //string versionmessage = GetClientVersionMessage(this);
1070         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1071         //string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1072         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1073
1074         s = strcat(s, "^8\n^7", gamemode_name);
1075
1076         if(modifications != "")
1077                 s = strcat(s, "^7 | ^3", modifications);
1078
1079         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1080         {
1081                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1082                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1083         }
1084
1085         if (cache_mutatormsg != "") {
1086                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1087         }
1088
1089         string mutator_msg = "";
1090         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1091         mutator_msg = M_ARGV(0, string);
1092
1093         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1094
1095         string motd = autocvar_sv_motd;
1096         if (motd != "") {
1097                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1098         }
1099         return s;
1100 }
1101
1102 /**
1103 =============
1104 ClientConnect
1105
1106 Called when a client connects to the server
1107 =============
1108 */
1109 void ClientConnect(entity this)
1110 {
1111         if (Ban_MaybeEnforceBanOnce(this)) return;
1112         assert(!IS_CLIENT(this), return);
1113         this.flags |= FL_CLIENT;
1114         assert(player_count >= 0, player_count = 0);
1115
1116         TRANSMUTE(Client, this);
1117         CS(this).version_nagtime = time + 10 + random() * 10;
1118
1119         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1120
1121         bot_clientconnect(this);
1122
1123         Player_DetermineForcedTeam(this);
1124
1125         TRANSMUTE(Observer, this);
1126
1127         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1128
1129         // always track bots, don't ask for cl_allow_uidtracking
1130         if (IS_BOT_CLIENT(this))
1131                 PlayerStats_GameReport_AddPlayer(this);
1132         else
1133                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1134
1135         if (autocvar_sv_eventlog)
1136                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1137
1138         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1139
1140         stuffcmd(this, clientstuff, "\n");
1141         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1142
1143         FixClientCvars(this);
1144
1145         // get version info from player
1146         stuffcmd(this, "cmd clientversion $gameversion\n");
1147
1148         // notify about available teams
1149         if (teamplay)
1150         {
1151                 entity balance = TeamBalance_CheckAllowedTeams(this);
1152                 int t = TeamBalance_GetAllowedTeams(balance);
1153                 TeamBalance_Destroy(balance);
1154                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1155         }
1156         else
1157         {
1158                 stuffcmd(this, "set _teams_available 0\n");
1159         }
1160
1161         bot_relinkplayerlist();
1162
1163         CS(this).spectatortime = time;
1164         if (blockSpectators)
1165         {
1166                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1167         }
1168
1169         CS(this).jointime = time;
1170
1171         if (IS_REAL_CLIENT(this))
1172         {
1173                 if (g_weaponarena_weapons == WEPSET(TUBA))
1174                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1175         }
1176
1177         if (!autocvar_sv_foginterval && world.fog != "")
1178                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1179
1180         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1181                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1182                         send_CSQC_teamnagger();
1183
1184         CSQCMODEL_AUTOINIT(this);
1185
1186         CS(this).model_randomizer = random();
1187
1188         if (IS_REAL_CLIENT(this))
1189                 sv_notice_join(this);
1190
1191         this.move_qcphysics = autocvar_sv_qcphysics;
1192
1193         // update physics stats (players can spawn before physics runs)
1194         Physics_UpdateStats(this);
1195
1196         IL_EACH(g_initforplayer, it.init_for_player, {
1197                 it.init_for_player(it, this);
1198         });
1199
1200         Handicap_Initialize(this);
1201
1202         MUTATOR_CALLHOOK(ClientConnect, this);
1203
1204         if (IS_REAL_CLIENT(this))
1205         {
1206                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1207                 {
1208                         CS(this).motd_actived_time = -1;
1209                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1210                 }
1211         }
1212 }
1213 /*
1214 =============
1215 ClientDisconnect
1216
1217 Called when a client disconnects from the server
1218 =============
1219 */
1220 .entity chatbubbleentity;
1221 void player_powerups_remove_all(entity this);
1222
1223 void ClientDisconnect(entity this)
1224 {
1225         assert(IS_CLIENT(this), return);
1226
1227         PlayerStats_GameReport_FinalizePlayer(this);
1228         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1229         if (CS(this).active_minigame) part_minigame(this);
1230         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1231
1232         if (autocvar_sv_eventlog)
1233                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1234
1235         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1236
1237         if(IS_SPEC(this))
1238                 SetSpectatee(this, NULL);
1239
1240         MUTATOR_CALLHOOK(ClientDisconnect, this);
1241
1242         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1243         strfree(CS_CVAR(this).weaponorder_byimpulse);
1244         ClientState_detach(this);
1245
1246         Portal_ClearAll(this);
1247
1248         Unfreeze(this, false);
1249
1250         RemoveGrapplingHooks(this);
1251
1252         // Here, everything has been done that requires this player to be a client.
1253
1254         this.flags &= ~FL_CLIENT;
1255
1256         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1257         if (this.killindicator) delete(this.killindicator);
1258
1259         IL_EACH(g_counters, it.realowner == this,
1260         {
1261                 delete(it);
1262         });
1263
1264         WaypointSprite_PlayerGone(this);
1265
1266         bot_relinkplayerlist();
1267
1268         strfree(this.clientstatus);
1269         if (this.personal) delete(this.personal);
1270
1271         this.playerid = 0;
1272         ReadyCount();
1273         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1274
1275         player_powerups_remove_all(this); // stop powerup sound
1276
1277         ONREMOVE(this);
1278 }
1279
1280 void ChatBubbleThink(entity this)
1281 {
1282         this.nextthink = time;
1283         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1284         {
1285                 if(this.owner) // but why can that ever be NULL?
1286                         this.owner.chatbubbleentity = NULL;
1287                 delete(this);
1288                 return;
1289         }
1290
1291         this.mdl = "";
1292
1293         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1294         {
1295                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1296                         this.mdl = "models/sprites/minigame_busy.iqm";
1297                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1298                         this.mdl = "models/misc/chatbubble.spr";
1299         }
1300
1301         if ( this.model != this.mdl )
1302                 _setmodel(this, this.mdl);
1303
1304 }
1305
1306 void UpdateChatBubble(entity this)
1307 {
1308         if (this.alpha < 0)
1309                 return;
1310         // spawn a chatbubble entity if needed
1311         if (!this.chatbubbleentity)
1312         {
1313                 this.chatbubbleentity = new(chatbubbleentity);
1314                 this.chatbubbleentity.owner = this;
1315                 this.chatbubbleentity.exteriormodeltoclient = this;
1316                 setthink(this.chatbubbleentity, ChatBubbleThink);
1317                 this.chatbubbleentity.nextthink = time;
1318                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1319                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1320                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1321                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1322                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1323                 //this.chatbubbleentity.model = "";
1324                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1325         }
1326 }
1327
1328 void calculate_player_respawn_time(entity this)
1329 {
1330         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1331                 return;
1332
1333         float gametype_setting_tmp;
1334         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1335         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1336         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1337         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1338         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1339         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1340
1341         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1342         if (teamplay)
1343         {
1344                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1345                         if(it.team == this.team)
1346                                 ++pcount;
1347                 });
1348                 if (sdelay_small_count == 0)
1349                         sdelay_small_count = 1;
1350                 if (sdelay_large_count == 0)
1351                         sdelay_large_count = 1;
1352         }
1353         else
1354         {
1355                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1356                         ++pcount;
1357                 });
1358                 if (sdelay_small_count == 0)
1359                 {
1360                         if (IS_INDEPENDENT_PLAYER(this))
1361                         {
1362                                 // Players play independently. No point in requiring enemies.
1363                                 sdelay_small_count = 1;
1364                         }
1365                         else
1366                         {
1367                                 // Players play AGAINST each other. Enemies required.
1368                                 sdelay_small_count = 2;
1369                         }
1370                 }
1371                 if (sdelay_large_count == 0)
1372                 {
1373                         if (IS_INDEPENDENT_PLAYER(this))
1374                         {
1375                                 // Players play independently. No point in requiring enemies.
1376                                 sdelay_large_count = 1;
1377                         }
1378                         else
1379                         {
1380                                 // Players play AGAINST each other. Enemies required.
1381                                 sdelay_large_count = 2;
1382                         }
1383                 }
1384         }
1385
1386         float sdelay;
1387
1388         if (pcount <= sdelay_small_count)
1389                 sdelay = sdelay_small;
1390         else if (pcount >= sdelay_large_count)
1391                 sdelay = sdelay_large;
1392         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1393                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1394
1395         if(waves)
1396                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1397         else
1398                 this.respawn_time = time + sdelay;
1399
1400         if(sdelay < sdelay_max)
1401                 this.respawn_time_max = time + sdelay_max;
1402         else
1403                 this.respawn_time_max = this.respawn_time;
1404
1405         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1406                 this.respawn_countdown = 10; // first number to count down from is 10
1407         else
1408                 this.respawn_countdown = -1; // do not count down
1409
1410         if(autocvar_g_forced_respawn)
1411                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1412 }
1413
1414 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1415 // added to the model skins
1416 /*void UpdateColorModHack()
1417 {
1418         float c;
1419         c = this.clientcolors & 15;
1420         // LordHavoc: only bothering to support white, green, red, yellow, blue
1421              if (!teamplay) this.colormod = '0 0 0';
1422         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1423         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1424         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1425         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1426         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1427         else this.colormod = '1 1 1';
1428 }*/
1429
1430 void respawn(entity this)
1431 {
1432         bool damagedbycontents_prev = this.damagedbycontents;
1433         if(this.alpha >= 0)
1434         {
1435                 if(autocvar_g_respawn_ghosts)
1436                 {
1437                         this.solid = SOLID_NOT;
1438                         this.takedamage = DAMAGE_NO;
1439                         this.damagedbycontents = false;
1440                         set_movetype(this, MOVETYPE_FLY);
1441                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1442                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1443                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1444                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1445                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1446                         if(autocvar_g_respawn_ghosts_time > 0)
1447                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1448                 }
1449                 else
1450                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1451         }
1452
1453         CopyBody(this, 1);
1454         this.damagedbycontents = damagedbycontents_prev;
1455
1456         this.effects |= EF_NODRAW; // prevent another CopyBody
1457         PutClientInServer(this);
1458 }
1459
1460 void play_countdown(entity this, float finished, Sound samp)
1461 {
1462         TC(Sound, samp);
1463         if(IS_REAL_CLIENT(this))
1464                 if(floor(finished - time - frametime) != floor(finished - time))
1465                         if(finished - time < 6)
1466                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1467 }
1468
1469 void player_powerups_remove_all(entity this)
1470 {
1471         if (this.items & IT_SUPERWEAPON)
1472         {
1473                 // don't play the poweroff sound when the game restarts or the player disconnects
1474                 if (time > game_starttime + 1 && IS_CLIENT(this))
1475                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1476                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1477                 this.items -= (this.items & IT_SUPERWEAPON);
1478         }
1479 }
1480
1481 void player_powerups(entity this)
1482 {
1483         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1484                 this.modelflags |= MF_ROCKET;
1485         else
1486                 this.modelflags &= ~MF_ROCKET;
1487
1488         this.effects &= ~EF_NODEPTHTEST;
1489
1490         if (IS_DEAD(this))
1491                 player_powerups_remove_all(this);
1492
1493         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1494                 return;
1495
1496         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1497         int items_prev = this.items;
1498
1499         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1500         {
1501                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1502                 if (this.items & IT_SUPERWEAPON)
1503                 {
1504                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1505                         {
1506                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1507                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1508                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1509                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1510                         }
1511                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1512                         {
1513                                 // don't let them run out
1514                         }
1515                         else
1516                         {
1517                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1518                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1519                                 {
1520                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1521                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1522                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1524                                 }
1525                         }
1526                 }
1527                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1528                 {
1529                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1530                         {
1531                                 this.items = this.items | IT_SUPERWEAPON;
1532                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1533                                 {
1534                                         if(!g_cts)
1535                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1536                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1537                                 }
1538                         }
1539                         else
1540                         {
1541                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1542                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1543                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1544                         }
1545                 }
1546                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1547                 {
1548                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1549                 }
1550         }
1551
1552         if(autocvar_g_nodepthtestplayers)
1553                 this.effects = this.effects | EF_NODEPTHTEST;
1554
1555         if(autocvar_g_fullbrightplayers)
1556                 this.effects = this.effects | EF_FULLBRIGHT;
1557
1558         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1559 }
1560
1561 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1562 {
1563         if(current > stable)
1564                 return current;
1565         else if(current > stable - 0.25) // when close enough, "snap"
1566                 return stable;
1567         else
1568                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1569 }
1570
1571 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1572 {
1573         if(current < stable)
1574                 return current;
1575         else if(current < stable + 0.25) // when close enough, "snap"
1576                 return stable;
1577         else
1578                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1579 }
1580
1581 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1582 {
1583         float old = GetResource(this, res);
1584         float current = old;
1585         if(current > rotstable)
1586         {
1587                 if(rotframetime > 0)
1588                 {
1589                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1590                         current = max(rotstable, current - rotlinear * rotframetime);
1591                 }
1592         }
1593         else if(current < regenstable)
1594         {
1595                 if(regenframetime > 0)
1596                 {
1597                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1598                         current = min(regenstable, current + regenlinear * regenframetime);
1599                 }
1600         }
1601
1602         float limit = GetResourceLimit(this, res) * limit_mod;
1603         if(current > limit)
1604                 current = limit;
1605
1606         if (current != old)
1607                 SetResource(this, res, current);
1608 }
1609
1610 void player_regen(entity this)
1611 {
1612         float max_mod, regen_mod, rot_mod, limit_mod;
1613         max_mod = regen_mod = rot_mod = limit_mod = 1;
1614
1615         float regen_health = autocvar_g_balance_health_regen;
1616         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1617         float regen_health_rot = autocvar_g_balance_health_rot;
1618         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1619         float regen_health_stable = autocvar_g_balance_health_regenstable;
1620         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1621         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1622                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1623         max_mod = M_ARGV(1, float);
1624         regen_mod = M_ARGV(2, float);
1625         rot_mod = M_ARGV(3, float);
1626         limit_mod = M_ARGV(4, float);
1627         regen_health = M_ARGV(5, float);
1628         regen_health_linear = M_ARGV(6, float);
1629         regen_health_rot = M_ARGV(7, float);
1630         regen_health_rotlinear = M_ARGV(8, float);
1631         regen_health_stable = M_ARGV(9, float);
1632         regen_health_rotstable = M_ARGV(10, float);
1633
1634         if(!mutator_returnvalue)
1635         if(!STAT(FROZEN, this))
1636         {
1637                 float maxa = autocvar_g_balance_armor_rotstable;
1638                 float mina = autocvar_g_balance_armor_regenstable;
1639
1640                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1641                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1642                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1643
1644                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1645                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1646                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1647         }
1648
1649         // if player rotted to death...  die!
1650         // check this outside above checks, as player may still be able to rot to death
1651         if(GetResource(this, RES_HEALTH) < 1)
1652         {
1653                 if(this.vehicle)
1654                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1655                 if(this.event_damage)
1656                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1657         }
1658
1659         if (!(this.items & IT_UNLIMITED_AMMO))
1660         {
1661                 float maxf = autocvar_g_balance_fuel_rotstable;
1662                 float minf = autocvar_g_balance_fuel_regenstable;
1663
1664                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1665                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1666                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1667         }
1668 }
1669
1670 bool zoomstate_set;
1671 void SetZoomState(entity this, float newzoom)
1672 {
1673         if(newzoom != CS(this).zoomstate)
1674         {
1675                 CS(this).zoomstate = newzoom;
1676                 ClientData_Touch(this);
1677         }
1678         zoomstate_set = true;
1679 }
1680
1681 void GetPressedKeys(entity this)
1682 {
1683         MUTATOR_CALLHOOK(GetPressedKeys, this);
1684         if (game_stopped)
1685         {
1686                 CS(this).pressedkeys = 0;
1687                 STAT(PRESSED_KEYS, this) = 0;
1688                 return;
1689         }
1690
1691         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1692         int keys = STAT(PRESSED_KEYS, this);
1693         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1694         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1695         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1696         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1697
1698         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1699         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1700         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1701         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1702         CS(this).pressedkeys = keys; // store for other users
1703
1704         STAT(PRESSED_KEYS, this) = keys;
1705 }
1706
1707 /*
1708 ======================
1709 spectate mode routines
1710 ======================
1711 */
1712
1713 void SpectateCopy(entity this, entity spectatee)
1714 {
1715         TC(Client, this); TC(Client, spectatee);
1716
1717         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1718         PS(this) = PS(spectatee);
1719         this.armortype = spectatee.armortype;
1720         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1721         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1722         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1723         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1724         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1725         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1726         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1727         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1728         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1729         CS(this).impulse = 0;
1730         this.disableclientprediction = 1; // no need to run prediction on a spectator
1731         this.items = spectatee.items;
1732         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1733         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1734         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1735         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1736         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1737         this.punchangle = spectatee.punchangle;
1738         this.view_ofs = spectatee.view_ofs;
1739         this.velocity = spectatee.velocity;
1740         this.dmg_take = spectatee.dmg_take;
1741         this.dmg_save = spectatee.dmg_save;
1742         this.dmg_inflictor = spectatee.dmg_inflictor;
1743         this.v_angle = spectatee.v_angle;
1744         this.angles = spectatee.v_angle;
1745         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1746         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1747         this.viewloc = spectatee.viewloc;
1748         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1749                 this.fixangle = true;
1750         setorigin(this, spectatee.origin);
1751         setsize(this, spectatee.mins, spectatee.maxs);
1752         SetZoomState(this, CS(spectatee).zoomstate);
1753
1754     anticheat_spectatecopy(this, spectatee);
1755         STAT(HUD, this) = STAT(HUD, spectatee);
1756         if(spectatee.vehicle)
1757     {
1758         this.angles = spectatee.v_angle;
1759
1760         //this.fixangle = false;
1761         //this.velocity = spectatee.vehicle.velocity;
1762         this.vehicle_health = spectatee.vehicle_health;
1763         this.vehicle_shield = spectatee.vehicle_shield;
1764         this.vehicle_energy = spectatee.vehicle_energy;
1765         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1766         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1767         this.vehicle_reload1 = spectatee.vehicle_reload1;
1768         this.vehicle_reload2 = spectatee.vehicle_reload2;
1769
1770         //msg_entity = this;
1771
1772        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1773             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1774            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1775            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1776
1777         //WriteByte (MSG_ONE, SVC_SETVIEW);
1778         //    WriteEntity(MSG_ONE, this);
1779         //makevectors(spectatee.v_angle);
1780         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1781     }
1782 }
1783
1784 bool SpectateUpdate(entity this)
1785 {
1786         if(!this.enemy)
1787                 return false;
1788
1789         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1790         {
1791                 SetSpectatee(this, NULL);
1792                 return false;
1793         }
1794
1795         SpectateCopy(this, this.enemy);
1796
1797         return true;
1798 }
1799
1800 bool SpectateSet(entity this)
1801 {
1802         if(!IS_PLAYER(this.enemy))
1803                 return false;
1804
1805         ClientData_Touch(this.enemy);
1806
1807         msg_entity = this;
1808         WriteByte(MSG_ONE, SVC_SETVIEW);
1809         WriteEntity(MSG_ONE, this.enemy);
1810         set_movetype(this, MOVETYPE_NONE);
1811         accuracy_resend(this);
1812
1813         if(!SpectateUpdate(this))
1814                 PutObserverInServer(this, false);
1815
1816         return true;
1817 }
1818
1819 void SetSpectatee_status(entity this, int spectatee_num)
1820 {
1821         int oldspectatee_status = CS(this).spectatee_status;
1822         CS(this).spectatee_status = spectatee_num;
1823
1824         if (CS(this).spectatee_status != oldspectatee_status)
1825         {
1826                 if (STAT(PRESSED_KEYS, this))
1827                 {
1828                         CS(this).pressedkeys = 0;
1829                         STAT(PRESSED_KEYS, this) = 0;
1830                 }
1831                 ClientData_Touch(this);
1832                 if (g_race || g_cts) race_InitSpectator();
1833         }
1834 }
1835
1836 void SetSpectatee(entity this, entity spectatee)
1837 {
1838         if(IS_BOT_CLIENT(this))
1839                 return; // bots abuse .enemy, this code is useless to them
1840
1841         entity old_spectatee = this.enemy;
1842
1843         this.enemy = spectatee;
1844
1845         // WEAPONTODO
1846         // these are required to fix the spectator bug with arc
1847         if(old_spectatee)
1848         {
1849                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1850                 {
1851                         .entity weaponentity = weaponentities[slot];
1852                         if(old_spectatee.(weaponentity).arc_beam)
1853                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1854                 }
1855         }
1856         if(this.enemy)
1857         {
1858                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1859                 {
1860                         .entity weaponentity = weaponentities[slot];
1861                         if(this.enemy.(weaponentity).arc_beam)
1862                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1863                 }
1864         }
1865
1866         if (this.enemy)
1867                 SetSpectatee_status(this, etof(this.enemy));
1868
1869         // needed to update spectator list
1870         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1871 }
1872
1873 bool Spectate(entity this, entity pl)
1874 {
1875         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1876                 return false;
1877         pl = M_ARGV(1, entity);
1878
1879         SetSpectatee(this, pl);
1880         return SpectateSet(this);
1881 }
1882
1883 bool SpectateNext(entity this)
1884 {
1885         entity ent = find(this.enemy, classname, STR_PLAYER);
1886
1887         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1888                 ent = M_ARGV(1, entity);
1889         else if (!ent)
1890                 ent = find(ent, classname, STR_PLAYER);
1891
1892         if(ent) { SetSpectatee(this, ent); }
1893
1894         return SpectateSet(this);
1895 }
1896
1897 bool SpectatePrev(entity this)
1898 {
1899         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1900         entity ent = findchain(classname, STR_PLAYER);
1901         if (!ent) // no player
1902                 return false;
1903
1904         entity first = ent;
1905         // skip players until current spectated player
1906         if(this.enemy)
1907         while(ent && ent != this.enemy)
1908                 ent = ent.chain;
1909
1910         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1911         {
1912                 case MUT_SPECPREV_FOUND:
1913                         ent = M_ARGV(1, entity);
1914                         break;
1915                 case MUT_SPECPREV_RETURN:
1916                         return true;
1917                 case MUT_SPECPREV_CONTINUE:
1918                 default:
1919                 {
1920                         if(ent.chain)
1921                                 ent = ent.chain;
1922                         else
1923                                 ent = first;
1924                         break;
1925                 }
1926         }
1927
1928         SetSpectatee(this, ent);
1929         return SpectateSet(this);
1930 }
1931
1932 /*
1933 =============
1934 ShowRespawnCountdown()
1935
1936 Update a respawn countdown display.
1937 =============
1938 */
1939 void ShowRespawnCountdown(entity this)
1940 {
1941         float number;
1942         if(!IS_DEAD(this)) // just respawned?
1943                 return;
1944         else
1945         {
1946                 number = ceil(this.respawn_time - time);
1947                 if(number <= 0)
1948                         return;
1949                 if(number <= this.respawn_countdown)
1950                 {
1951                         this.respawn_countdown = number - 1;
1952                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1953                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1954                 }
1955         }
1956 }
1957
1958 .bool team_selected;
1959 bool ShowTeamSelection(entity this)
1960 {
1961         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1962                 return false;
1963         stuffcmd(this, "menu_showteamselect\n");
1964         return true;
1965 }
1966 void Join(entity this)
1967 {
1968         TRANSMUTE(Player, this);
1969
1970         if(!this.team_selected)
1971         if(autocvar_g_campaign || autocvar_g_balance_teams)
1972                 TeamBalance_JoinBestTeam(this);
1973
1974         if(autocvar_g_campaign)
1975                 campaign_bots_may_start = true;
1976
1977         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1978
1979         PutClientInServer(this);
1980
1981         if(IS_PLAYER(this))
1982         if(teamplay && this.team != -1)
1983         {
1984         }
1985         else
1986                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1987         this.team_selected = false;
1988
1989         // z411
1990         // send constant ready notification
1991         if(warmup_stage)
1992                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
1993 }
1994
1995 int GetPlayerLimit()
1996 {
1997         if(g_duel)
1998                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1999         int player_limit = autocvar_g_maxplayers;
2000         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2001         player_limit = M_ARGV(0, int);
2002         return player_limit;
2003 }
2004
2005 /**
2006  * Determines whether the player is allowed to join. This depends on cvar
2007  * g_maxplayers, if it isn't used this function always return true, otherwise
2008  * it checks whether the number of currently playing players exceeds g_maxplayers.
2009  * @return int number of free slots for players, 0 if none
2010  */
2011 int nJoinAllowed(entity this, entity ignore)
2012 {
2013         if(!ignore)
2014         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2015         // so report 0 free slots if restricted
2016         {
2017                 if(autocvar_g_forced_team_otherwise == "spectate")
2018                         return 0;
2019                 if(autocvar_g_forced_team_otherwise == "spectator")
2020                         return 0;
2021         }
2022
2023         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2024                 return 0; // forced spectators can never join
2025
2026         // TODO simplify this
2027         int totalClients = 0;
2028         int currentlyPlaying = 0;
2029         FOREACH_CLIENT(true, {
2030                 if(it != ignore)
2031                         ++totalClients;
2032                 if(IS_REAL_CLIENT(it))
2033                 if(IS_PLAYER(it) || it.caplayer)
2034                         ++currentlyPlaying;
2035         });
2036
2037         int player_limit = GetPlayerLimit();
2038
2039         int free_slots = 0;
2040         if (!player_limit)
2041                 free_slots = maxclients - totalClients;
2042         else if(player_limit > 0 && currentlyPlaying < player_limit)
2043                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2044
2045         static float msg_time = 0;
2046         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2047         {
2048                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2049                 msg_time = time + 0.5;
2050         }
2051
2052         return free_slots;
2053 }
2054
2055 void PrintWelcomeMessage(entity this)
2056 {
2057         if(CS(this).motd_actived_time == 0)
2058         {
2059                 if (autocvar_g_campaign) {
2060                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2061                                 CS(this).motd_actived_time = time;
2062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2063                         }
2064                 } else {
2065                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2066                                 CS(this).motd_actived_time = time;
2067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2068                         }
2069                 }
2070         }
2071         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2072         {
2073                 if (autocvar_g_campaign) {
2074                         if (PHYS_INPUT_BUTTON_INFO(this))
2075                                 CS(this).motd_actived_time = time;
2076                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2077                                 CS(this).motd_actived_time = 0;
2078                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2079                         }
2080                 } else {
2081                         if (PHYS_INPUT_BUTTON_INFO(this))
2082                                 CS(this).motd_actived_time = time;
2083                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2084                                 CS(this).motd_actived_time = 0;
2085                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2086                         }
2087                 }
2088         }
2089         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2090         {
2091                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2092                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2093                 else if (CS(this).motd_actived_time == -2)
2094                 {
2095                         // instantly hide MOTD
2096                         CS(this).motd_actived_time = 0;
2097                         if (autocvar_g_campaign)
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2099                         else
2100                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2101                 }
2102                 else if (IS_PLAYER(this) || IS_SPEC(this))
2103                 {
2104                         // FIXME occasionally for some reason MOTD never goes away
2105                         // delay MOTD removal a little bit in the hope it fixes this bug
2106                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2107                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2108                         else //if (CS(this).motd_actived_time < -2)
2109                                 CS(this).motd_actived_time++;
2110                 }
2111         }
2112 }
2113
2114 bool joinAllowed(entity this)
2115 {
2116         if (CS(this).version_mismatch) return false;
2117         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2118         if (!nJoinAllowed(this, this)) return false;
2119         if (teamplay && lockteams) return false;
2120         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2121         if (ShowTeamSelection(this)) return false;
2122         return true;
2123 }
2124
2125 .string shootfromfixedorigin;
2126 .bool dualwielding_prev;
2127 bool PlayerThink(entity this)
2128 {
2129         if (game_stopped || intermission_running) {
2130                 this.modelflags &= ~MF_ROCKET;
2131                 if(intermission_running)
2132                         IntermissionThink(this);
2133                 return false;
2134         }
2135
2136         if (game_timeout) {
2137         // don't allow the player to turn around while game is paused
2138                 // FIXME turn this into CSQC stuff
2139                 this.v_angle = this.lastV_angle;
2140                 this.angles = this.lastV_angle;
2141                 this.fixangle = true;
2142                 return false;
2143         }
2144
2145         if (frametime) player_powerups(this);
2146
2147         if (IS_DEAD(this)) {
2148                 if (this.personal && g_race_qualifying) {
2149                         if (time > this.respawn_time) {
2150                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2151                                 respawn(this);
2152                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2153                         }
2154                 } else {
2155                         if (frametime) player_anim(this);
2156
2157                         if (this.respawn_flags & RESPAWN_DENY)
2158                         {
2159                                 STAT(RESPAWN_TIME, this) = 0;
2160                                 return false;
2161                         }
2162
2163                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2164
2165                         switch(this.deadflag)
2166                         {
2167                                 case DEAD_DYING:
2168                                 {
2169                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2170                                                 this.deadflag = DEAD_RESPAWNING;
2171                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2172                                                 this.deadflag = DEAD_DEAD;
2173                                         break;
2174                                 }
2175                                 case DEAD_DEAD:
2176                                 {
2177                                         if (button_pressed)
2178                                                 this.deadflag = DEAD_RESPAWNABLE;
2179                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2180                                                 this.deadflag = DEAD_RESPAWNING;
2181                                         break;
2182                                 }
2183                                 case DEAD_RESPAWNABLE:
2184                                 {
2185                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2186                                                 this.deadflag = DEAD_RESPAWNING;
2187                                         break;
2188                                 }
2189                                 case DEAD_RESPAWNING:
2190                                 {
2191                                         if (time > this.respawn_time)
2192                                         {
2193                                                 this.respawn_time = time + 1; // only retry once a second
2194                                                 this.respawn_time_max = this.respawn_time;
2195                                                 respawn(this);
2196                                         }
2197                                         break;
2198                                 }
2199                         }
2200
2201                         ShowRespawnCountdown(this);
2202
2203                         if (this.respawn_flags & RESPAWN_SILENT)
2204                                 STAT(RESPAWN_TIME, this) = 0;
2205                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2206                         {
2207                                 if (time < this.respawn_time)
2208                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2209                                 else if (this.deadflag != DEAD_RESPAWNING)
2210                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2211                         }
2212                         else
2213                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2214                 }
2215
2216                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2217                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2218                         STAT(RESPAWN_TIME, this) *= -1;
2219
2220                 return false;
2221         }
2222
2223         FixPlayermodel(this);
2224
2225         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2226                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2227                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2228         }
2229
2230         // reset gun alignment when dual wielding status changes
2231         // to ensure guns are always aligned right and left
2232         bool dualwielding = W_DualWielding(this);
2233         if(this.dualwielding_prev != dualwielding)
2234         {
2235                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2236                 this.dualwielding_prev = dualwielding;
2237         }
2238
2239         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2240         //if(frametime)
2241         {
2242                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2243                 {
2244                         .entity weaponentity = weaponentities[slot];
2245                         if(WEP_CVAR(vortex, charge_always))
2246                                 W_Vortex_Charge(this, weaponentity, frametime);
2247                         W_WeaponFrame(this, weaponentity);
2248                 }
2249         }
2250
2251         if (frametime)
2252         {
2253                 // WEAPONTODO: Add a weapon request for this
2254                 // rot vortex charge to the charge limit
2255                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2256                 {
2257                         .entity weaponentity = weaponentities[slot];
2258                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2259                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2260                 }
2261
2262                 player_regen(this);
2263                 player_anim(this);
2264                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2265         }
2266
2267         monsters_setstatus(this);
2268
2269         return true;
2270 }
2271
2272 .bool would_spectate;
2273 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2274 void ObserverOrSpectatorThink(entity this)
2275 {
2276         bool is_spec = IS_SPEC(this);
2277         if ( CS(this).impulse )
2278         {
2279                 int r = MinigameImpulse(this, CS(this).impulse);
2280                 if (!is_spec || r)
2281                         CS(this).impulse = 0;
2282
2283                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2284                 {
2285                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2286                         CS(this).impulse = 0;
2287                         return;
2288                 }
2289         }
2290
2291         if (this.flags & FL_JUMPRELEASED) {
2292                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2293                         this.flags &= ~FL_JUMPRELEASED;
2294                         this.flags |= FL_SPAWNING;
2295                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2296                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2297                         this.flags &= ~FL_JUMPRELEASED;
2298                         if(SpectateNext(this)) {
2299                                 TRANSMUTE(Spectator, this);
2300                         } else if (is_spec) {
2301                                 TRANSMUTE(Observer, this);
2302                                 PutClientInServer(this);
2303                         }
2304                         else
2305                                 this.would_spectate = false; // unable to spectate anyone
2306                         if (is_spec)
2307                                 CS(this).impulse = 0;
2308                 } else if (is_spec) {
2309                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2310                                 this.flags &= ~FL_JUMPRELEASED;
2311                                 if(SpectatePrev(this)) {
2312                                         TRANSMUTE(Spectator, this);
2313                                 } else {
2314                                         TRANSMUTE(Observer, this);
2315                                         PutClientInServer(this);
2316                                 }
2317                                 CS(this).impulse = 0;
2318                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2319                                 this.would_spectate = false;
2320                                 this.flags &= ~FL_JUMPRELEASED;
2321                                 TRANSMUTE(Observer, this);
2322                                 PutClientInServer(this);
2323                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2324                                 PutObserverInServer(this, false);
2325                                 this.would_spectate = true;
2326                         }
2327                 }
2328                 else {
2329                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2330                         if (PHYS_INPUT_BUTTON_USE(this))
2331                                 wouldclip = !wouldclip;
2332                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2333                         set_movetype(this, preferred_movetype);
2334                 }
2335         } else { // jump pressed
2336                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2337                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2338                         this.flags |= FL_JUMPRELEASED;
2339                         if(this.flags & FL_SPAWNING)
2340                         {
2341                                 this.flags &= ~FL_SPAWNING;
2342                                 if(joinAllowed(this))
2343                                         Join(this);
2344                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2345                                         CS(this).autojoin_checked = -1;
2346                                 return;
2347                         }
2348                 }
2349                 if(is_spec && !SpectateUpdate(this))
2350                         PutObserverInServer(this, false);
2351         }
2352         if (is_spec)
2353                 this.flags |= FL_CLIENT | FL_NOTARGET;
2354 }
2355
2356 void PlayerUseKey(entity this)
2357 {
2358         if (!IS_PLAYER(this))
2359                 return;
2360
2361         if(this.vehicle)
2362         {
2363                 if(!game_stopped)
2364                 {
2365                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2366                         return;
2367                 }
2368         }
2369         else if(autocvar_g_vehicles_enter)
2370         {
2371                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2372                 {
2373                         entity head, closest_target = NULL;
2374                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2375
2376                         while(head) // find the closest acceptable target to enter
2377                         {
2378                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2379                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2380                                 {
2381                                         if(closest_target)
2382                                         {
2383                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2384                                                 { closest_target = head; }
2385                                         }
2386                                         else { closest_target = head; }
2387                                 }
2388
2389                                 head = head.chain;
2390                         }
2391
2392                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2393                 }
2394         }
2395
2396         // a use key was pressed; call handlers
2397         MUTATOR_CALLHOOK(PlayerUseKey, this);
2398 }
2399
2400
2401 /*
2402 =============
2403 PlayerPreThink
2404
2405 Called every frame for each client before the physics are run
2406 =============
2407 */
2408 .float last_vehiclecheck;
2409 void PlayerPreThink (entity this)
2410 {
2411         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2412         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2413
2414         WarpZone_PlayerPhysics_FixVAngle(this);
2415
2416         if (frametime) {
2417                 // physics frames: update anticheat stuff
2418                 anticheat_prethink(this);
2419
2420                 // WORKAROUND: only use dropclient in server frames (frametime set).
2421                 // Never use it in cl_movement frames (frametime zero).
2422                 if (blockSpectators && IS_REAL_CLIENT(this)
2423                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2424                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2425                 {
2426                         if (dropclient_schedule(this))
2427                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2428                 }
2429         }
2430
2431         zoomstate_set = false;
2432
2433         // Check for nameless players
2434         if (this.netname == "" || this.netname != CS(this).netname_previous)
2435         {
2436                 bool assume_unchanged = (CS(this).netname_previous == "");
2437                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2438                 {
2439                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2440                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2441                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2442                         assume_unchanged = false;
2443                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2444                 }
2445                 if (isInvisibleString(this.netname))
2446                 {
2447                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2448                         sprint(this, "Warning: invisible names are not allowed.\n");
2449                         assume_unchanged = false;
2450                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2451                 }
2452                 if (!assume_unchanged && autocvar_sv_eventlog)
2453                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2454                 strcpy(CS(this).netname_previous, this.netname);
2455         }
2456
2457         // version nagging
2458         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2459         CS(this).version_nagtime = 0;
2460         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2461             // git client
2462         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2463             // git server
2464             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2465         } else {
2466             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2467             if (r < 0) { // old client
2468                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2469             } else if (r > 0) { // old server
2470                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2471             }
2472         }
2473     }
2474
2475         // GOD MODE info
2476         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2477         {
2478                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2479                 this.max_armorvalue = 0;
2480         }
2481
2482         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2483         {
2484                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2485                 {
2486                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2487                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2488                         if (this.iceblock)
2489                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2490
2491                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2492                                 Unfreeze(this, false);
2493                 }
2494                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2495                 {
2496                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2497                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2498
2499                         if (GetResource(this, RES_HEALTH) < 1)
2500                         {
2501                                 if (this.vehicle)
2502                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2503                                 if(this.event_damage)
2504                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2505                         }
2506                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2507                                 Unfreeze(this, false);
2508                 }
2509         }
2510
2511         MUTATOR_CALLHOOK(PlayerPreThink, this);
2512
2513         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2514         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2515         {
2516                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2517                 {
2518                         if(!it.owner)
2519                         {
2520                                 if(!it.team || SAME_TEAM(this, it))
2521                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2522                                 else if(autocvar_g_vehicles_steal)
2523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2524                         }
2525                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2526                         {
2527                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2528                         }
2529                 });
2530
2531                 this.last_vehiclecheck = time + 1;
2532         }
2533
2534         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2535         {
2536                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2537                         PlayerUseKey(this);
2538                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2539         }
2540
2541         if (IS_REAL_CLIENT(this))
2542                 PrintWelcomeMessage(this);
2543
2544         if (IS_PLAYER(this)) {
2545                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2546                         error("Client can't be spawned as player on connection!");
2547                 if(!PlayerThink(this))
2548                         return;
2549         }
2550         else if (game_stopped || intermission_running) {
2551                 if(intermission_running)
2552                         IntermissionThink(this);
2553                 return;
2554         }
2555         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2556         {
2557                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2558                 CS(this).autojoin_checked = 1;
2559                 // don't do this in ClientConnect
2560                 // many things can go wrong if a client is spawned as player on connection
2561                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2562                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2563                                 && (!teamplay || autocvar_g_balance_teams)))
2564                 {
2565                         campaign_bots_may_start = true;
2566                         if(joinAllowed(this))
2567                                 Join(this);
2568                         return;
2569                 }
2570         }
2571         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2572                 ObserverOrSpectatorThink(this);
2573         }
2574
2575         // WEAPONTODO: Add weapon request for this
2576         if (!zoomstate_set) {
2577                 bool wep_zoomed = false;
2578                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2579                 {
2580                         .entity weaponentity = weaponentities[slot];
2581                         Weapon thiswep = this.(weaponentity).m_weapon;
2582                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2583                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2584                 }
2585                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2586         }
2587
2588         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2589         {
2590                 CS(this).teamkill_soundtime = 0;
2591
2592                 entity e = CS(this).teamkill_soundsource;
2593                 entity oldpusher = e.pusher;
2594                 e.pusher = this;
2595                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2596                 e.pusher = oldpusher;
2597         }
2598
2599         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2600                 CS(this).taunt_soundtime = 0;
2601                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2602         }
2603
2604         target_voicescript_next(this);
2605 }
2606
2607 void DrownPlayer(entity this)
2608 {
2609         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2610                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2611         {
2612                 STAT(AIR_FINISHED, this) = 0;
2613                 return;
2614         }
2615
2616         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2617         {
2618                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2619                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2620                 STAT(AIR_FINISHED, this) = 0;
2621         }
2622         else
2623         {
2624                 if (!STAT(AIR_FINISHED, this))
2625                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2626                 if (STAT(AIR_FINISHED, this) < time)
2627                 {       // drown!
2628                         if (this.pain_finished < time)
2629                         {
2630                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2631                                 this.pain_finished = time + 0.5;
2632                         }
2633                 }
2634         }
2635 }
2636
2637 .bool move_qcphysics;
2638
2639 void Player_Physics(entity this)
2640 {
2641         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2642
2643         if(!this.move_qcphysics)
2644                 return;
2645
2646         if(!frametime && !CS(this).pm_frametime)
2647                 return;
2648
2649         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2650
2651         CS(this).pm_frametime = 0;
2652 }
2653
2654 /*
2655 =============
2656 PlayerPostThink
2657
2658 Called every frame for each client after the physics are run
2659 =============
2660 */
2661 void PlayerPostThink (entity this)
2662 {
2663         Player_Physics(this);
2664
2665         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2666         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2667         if (IS_REAL_CLIENT(this))
2668         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2669         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2670         {
2671                 int totalClients = 0;
2672                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2673                 {
2674                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2675                         if (server_is_dedicated)
2676                         {
2677                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2678                                 {
2679                                         ++totalClients;
2680                                 });
2681                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2682                                         totalClients = 0;
2683                         }
2684                 }
2685                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2686                 {
2687                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2688                         {
2689                                 ++totalClients;
2690                         });
2691                 }
2692
2693                 if (totalClients < autocvar_sv_maxidle_minplayers)
2694                 {
2695                         // idle kick disabled
2696                         CS(this).parm_idlesince = time;
2697                 }
2698                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2699                 {
2700                         if (CS(this).idlekick_lasttimeleft)
2701                         {
2702                                 CS(this).idlekick_lasttimeleft = 0;
2703                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2704                         }
2705                 }
2706                 else
2707                 {
2708                         float maxidle_time = autocvar_sv_maxidle;
2709                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2710                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2711                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2712                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2713                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2714                         {
2715                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2716                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2717                                 else
2718                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2719                         }
2720                         if (timeleft <= 0) {
2721                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2722                                 {
2723                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2724                                         PutObserverInServer(this, true);
2725                                 }
2726                                 else
2727                                 {
2728                                         if (dropclient_schedule(this))
2729                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2730                                 }
2731                                 return;
2732                         }
2733                         else if (timeleft <= countdown_time) {
2734                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2735                                         play2(this, SND(TALK2));
2736                                 CS(this).idlekick_lasttimeleft = timeleft;
2737                         }
2738                 }
2739         }
2740
2741         CheatFrame(this);
2742
2743         if (game_stopped)
2744         {
2745                 this.solid = SOLID_NOT;
2746                 this.takedamage = DAMAGE_NO;
2747                 set_movetype(this, MOVETYPE_NONE);
2748                 CS(this).teamkill_complain = 0;
2749                 CS(this).teamkill_soundtime = 0;
2750                 CS(this).teamkill_soundsource = NULL;
2751         }
2752
2753         if (IS_PLAYER(this)) {
2754                 if(this.death_time == time && IS_DEAD(this))
2755                 {
2756                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2757                         // once all the damage events of this frame have been processed with normal size
2758                         this.maxs.z = 5;
2759                         setsize(this, this.mins, this.maxs);
2760                 }
2761                 DrownPlayer(this);
2762                 UpdateChatBubble(this);
2763                 if (CS(this).impulse) ImpulseCommands(this);
2764                 GetPressedKeys(this);
2765                 if (game_stopped)
2766                 {
2767                         CSQCMODEL_AUTOUPDATE(this);
2768                         return;
2769                 }
2770         }
2771         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2772         {
2773                 CS(this).pressedkeys = 0;
2774                 STAT(PRESSED_KEYS, this) = 0;
2775         }
2776
2777         if (this.waypointsprite_attachedforcarrier) {
2778                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2779                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2780         }
2781
2782         CSQCMODEL_AUTOUPDATE(this);
2783 }
2784
2785 // hack to copy the button fields from the client entity to the Client State
2786 void PM_UpdateButtons(entity this, entity store)
2787 {
2788         if(this.impulse)
2789                 store.impulse = this.impulse;
2790         this.impulse = 0;
2791
2792         bool typing = this.buttonchat || this.button12;
2793
2794         store.button0 = (typing) ? 0 : this.button0;
2795         //button1?!
2796         store.button2 = (typing) ? 0 : this.button2;
2797         store.button3 = (typing) ? 0 : this.button3;
2798         store.button4 = this.button4;
2799         store.button5 = (typing) ? 0 : this.button5;
2800         store.button6 = this.button6;
2801         store.button7 = this.button7;
2802         store.button8 = this.button8;
2803         store.button9 = this.button9;
2804         store.button10 = this.button10;
2805         store.button11 = this.button11;
2806         store.button12 = this.button12;
2807         store.button13 = this.button13;
2808         store.button14 = this.button14;
2809         store.button15 = this.button15;
2810         store.button16 = this.button16;
2811         store.buttonuse = this.buttonuse;
2812         store.buttonchat = this.buttonchat;
2813
2814         store.cursor_active = this.cursor_active;
2815         store.cursor_screen = this.cursor_screen;
2816         store.cursor_trace_start = this.cursor_trace_start;
2817         store.cursor_trace_endpos = this.cursor_trace_endpos;
2818         store.cursor_trace_ent = this.cursor_trace_ent;
2819
2820         store.ping = this.ping;
2821         store.ping_packetloss = this.ping_packetloss;
2822         store.ping_movementloss = this.ping_movementloss;
2823
2824         store.v_angle = this.v_angle;
2825         store.movement = this.movement;
2826 }
2827
2828 NET_HANDLE(fpsreport, bool)
2829 {
2830         int fps = ReadShort();
2831         PlayerScore_Set(sender, SP_FPS, fps);
2832         return true;
2833 }