qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if (autocvar_sv_maxidle_playertospectator > 0 && CS(this).idlekick_lasttimeleft)
 255                 {
 256                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
 257                         CS(this).idlekick_lasttimeleft = 0;
 258                         CS(this).parm_idlesince = time;
 259                 }
 260
 261                 if(GetResource(this, RES_HEALTH) >= 1)
 262                 {
 263                         // despawn effect
 264                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 265                 }
 266
 267                 // was a player, recount votes and ready status
 268                 if(IS_REAL_CLIENT(this))
 269                 {
 270                         if (vote_called) { VoteCount(false); }
 271                         ReadyCount();
 272                 }
 273                 entcs_update_players(this);
 274         }
 275
 276         entity spot = SelectSpawnPoint(this, true);
 277         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 278         this.angles = vec2(spot.angles);
 279         this.fixangle = true;
 280         // offset it so that the spectator spawns higher off the ground, looks better this way
 281         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 282         if (IS_REAL_CLIENT(this))
 283         {
 284                 msg_entity = this;
 285                 WriteByte(MSG_ONE, SVC_SETVIEW);
 286                 WriteEntity(MSG_ONE, this);
 287         }
 288         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 289         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 290         if(!autocvar_g_debug_globalsounds)
 291         {
 292                 // needed for player sounds
 293                 this.model = "";
 294                 FixPlayermodel(this);
 295         }
 296         setmodel(this, MDL_Null);
 297         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 298         this.view_ofs = '0 0 0';
 299
 300         RemoveGrapplingHooks(this);
 301         Portal_ClearAll(this);
 302         Unfreeze(this, false);
 303         SetSpectatee(this, NULL);
 304
 305         if (this.alivetime)
 306         {
 307                 if (!warmup_stage)
 308                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 309                 this.alivetime = 0;
 310         }
 311
 312         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 313
 314         WaypointSprite_PlayerDead(this);
 315
 316         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 317                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 318
 319         accuracy_resend(this);
 320
 321         CS(this).spectatortime = time;
 322         if(this.bot_attack)
 323                 IL_REMOVE(g_bot_targets, this);
 324         this.bot_attack = false;
 325         if(this.monster_attack)
 326                 IL_REMOVE(g_monster_targets, this);
 327         this.monster_attack = false;
 328         STAT(HUD, this) = HUD_NORMAL;
 329         TRANSMUTE(Observer, this);
 330         this.iscreature = false;
 331         this.teleportable = TELEPORT_SIMPLE;
 332         if(this.damagedbycontents)
 333                 IL_REMOVE(g_damagedbycontents, this);
 334         this.damagedbycontents = false;
 335         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 336         SetSpectatee_status(this, etof(this));
 337         this.takedamage = DAMAGE_NO;
 338         this.solid = SOLID_NOT;
 339         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 340         this.flags = FL_CLIENT | FL_NOTARGET;
 341         this.effects = 0;
 342         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 343         this.pauserotarmor_finished = 0;
 344         this.pauserothealth_finished = 0;
 345         this.pauseregen_finished = 0;
 346         this.damageforcescale = 0;
 347         this.death_time = 0;
 348         this.respawn_flags = 0;
 349         this.respawn_time = 0;
 350         STAT(RESPAWN_TIME, this) = 0;
 351         this.alpha = 0;
 352         this.scale = 0;
 353         this.fade_time = 0;
 354         this.pain_finished = 0;
 355         STAT(STRENGTH_FINISHED, this) = 0;
 356         STAT(INVINCIBLE_FINISHED, this) = 0;
 357         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 358         STAT(AIR_FINISHED, this) = 0;
 359         //this.dphitcontentsmask = 0;
 360         this.dphitcontentsmask = DPCONTENTS_SOLID;
 361         if (autocvar_g_playerclip_collisions)
 362                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 363         this.pushltime = 0;
 364         this.istypefrag = 0;
 365         setthink(this, func_null);
 366         this.nextthink = 0;
 367         this.deadflag = DEAD_NO;
 368         UNSET_DUCKED(this);
 369         STAT(REVIVE_PROGRESS, this) = 0;
 370         this.revival_time = 0;
 371         this.draggable = drag_undraggable;
 372
 373         this.items = 0;
 374         STAT(WEAPONS, this) = '0 0 0';
 375         this.drawonlytoclient = this;
 376
 377         this.viewloc = NULL;
 378
 379         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 380
 381         this.weaponmodel = "";
 382         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 383         {
 384                 this.weaponentities[slot] = NULL;
 385         }
 386         this.exteriorweaponentity = NULL;
 387         CS(this).killcount = FRAGS_SPECTATOR;
 388         this.velocity = '0 0 0';
 389         this.avelocity = '0 0 0';
 390         this.punchangle = '0 0 0';
 391         this.punchvector = '0 0 0';
 392         this.oldvelocity = this.velocity;
 393         this.fire_endtime = -1;
 394         this.event_damage = func_null;
 395         this.event_heal = func_null;
 396
 397         for(int slot = 0; slot < MAX_AXH; ++slot)
 398         {
 399                 entity axh = this.(AuxiliaryXhair[slot]);
 400                 this.(AuxiliaryXhair[slot]) = NULL;
 401
 402                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 403                         delete(axh);
 404         }
 405
 406         if (mutator_returnvalue)
 407         {
 408                 // mutator prevents resetting teams+score
 409         }
 410         else
 411         {
 412                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 413                 this.frags = FRAGS_SPECTATOR;
 414         }
 415
 416         bot_relinkplayerlist();
 417
 418         if (CS(this).just_joined)
 419                 CS(this).just_joined = false;
 420 }
 421
 422 int player_getspecies(entity this)
 423 {
 424         get_model_parameters(this.model, this.skin);
 425         int s = get_model_parameters_species;
 426         get_model_parameters(string_null, 0);
 427         if (s < 0) return SPECIES_HUMAN;
 428         return s;
 429 }
 430
 431 .float model_randomizer;
 432 void FixPlayermodel(entity player)
 433 {
 434         string defaultmodel = "";
 435         int defaultskin = 0;
 436         if(autocvar_sv_defaultcharacter)
 437         {
 438                 if(teamplay)
 439                 {
 440                         switch(player.team)
 441                         {
 442                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 443                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 444                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 445                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 446                         }
 447                 }
 448
 449                 if(defaultmodel == "")
 450                 {
 451                         defaultmodel = autocvar_sv_defaultplayermodel;
 452                         defaultskin = autocvar_sv_defaultplayerskin;
 453                 }
 454
 455                 int n = tokenize_console(defaultmodel);
 456                 if(n > 0)
 457                 {
 458                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 459                         // However, do NOT randomize if the player-selected model is in the list.
 460                         for (int i = 0; i < n; ++i)
 461                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 462                                         defaultmodel = argv(i);
 463                 }
 464
 465                 int i = strstrofs(defaultmodel, ":", 0);
 466                 if(i >= 0)
 467                 {
 468                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 469                         defaultmodel = substring(defaultmodel, 0, i);
 470                 }
 471         }
 472         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 473         {
 474                 if(teamplay)
 475                 {
 476                         switch(player.team)
 477                         {
 478                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 479                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 480                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 481                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 482                         }
 483                 }
 484
 485                 if(!defaultskin)
 486                         defaultskin = autocvar_sv_defaultplayerskin;
 487         }
 488
 489         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 490         defaultmodel = M_ARGV(0, string);
 491         defaultskin = M_ARGV(1, int);
 492
 493         bool chmdl = false;
 494         int oldskin;
 495         if(defaultmodel != "")
 496         {
 497                 if (defaultmodel != player.model)
 498                 {
 499                         vector m1 = player.mins;
 500                         vector m2 = player.maxs;
 501                         setplayermodel (player, defaultmodel);
 502                         setsize (player, m1, m2);
 503                         chmdl = true;
 504                 }
 505
 506                 oldskin = player.skin;
 507                 player.skin = defaultskin;
 508         } else {
 509                 if (player.playermodel != player.model || player.playermodel == "")
 510                 {
 511                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 512                         vector m1 = player.mins;
 513                         vector m2 = player.maxs;
 514                         setplayermodel (player, player.playermodel);
 515                         setsize (player, m1, m2);
 516                         chmdl = true;
 517                 }
 518
 519                 if(!autocvar_sv_defaultcharacterskin)
 520                 {
 521                         oldskin = player.skin;
 522                         player.skin = stof(player.playerskin);
 523                 }
 524                 else
 525                 {
 526                         oldskin = player.skin;
 527                         player.skin = defaultskin;
 528                 }
 529         }
 530
 531         if(chmdl || oldskin != player.skin) // model or skin has changed
 532         {
 533                 player.species = player_getspecies(player); // update species
 534                 if(!autocvar_g_debug_globalsounds)
 535                         UpdatePlayerSounds(player); // update skin sounds
 536         }
 537
 538         if(!teamplay)
 539                 if(strlen(autocvar_sv_defaultplayercolors))
 540                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 541                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 542 }
 543
 544 void ResetPlayerResources(entity this)
 545 {
 546         if (warmup_stage) {
 547                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 548                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 549                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 550                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 551                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 552                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 553                 SetResource(this, RES_HEALTH, warmup_start_health);
 554                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 555                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 556         } else {
 557                 SetResource(this, RES_SHELLS, start_ammo_shells);
 558                 SetResource(this, RES_BULLETS, start_ammo_nails);
 559                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 560                 SetResource(this, RES_CELLS, start_ammo_cells);
 561                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 562                 SetResource(this, RES_FUEL, start_ammo_fuel);
 563                 SetResource(this, RES_HEALTH, start_health);
 564                 SetResource(this, RES_ARMOR, start_armorvalue);
 565                 STAT(WEAPONS, this) = start_weapons;
 566                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 567                 {
 568                         GiveRandomWeapons(this, random_start_weapons_count,
 569                                 autocvar_g_random_start_weapons, random_start_ammo);
 570                 }
 571         }
 572 }
 573
 574 void PutPlayerInServer(entity this)
 575 {
 576         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 577
 578         PlayerState_attach(this);
 579         accuracy_resend(this);
 580
 581         if (this.team < 0)
 582                 TeamBalance_JoinBestTeam(this);
 583
 584         entity spot = SelectSpawnPoint(this, false);
 585         if (!spot) {
 586                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 587                 return; // spawn failed
 588         }
 589
 590         TRANSMUTE(Player, this);
 591
 592         CS(this).wasplayer = true;
 593         this.iscreature = true;
 594         this.teleportable = TELEPORT_NORMAL;
 595         if(!this.damagedbycontents)
 596                 IL_PUSH(g_damagedbycontents, this);
 597         this.damagedbycontents = true;
 598         set_movetype(this, MOVETYPE_WALK);
 599         this.solid = SOLID_SLIDEBOX;
 600         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 601         if (autocvar_g_playerclip_collisions)
 602                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 603         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 604                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 605         this.frags = FRAGS_PLAYER;
 606         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 607         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 608         if (autocvar__notarget)
 609                 this.flags |= FL_NOTARGET;
 610         this.takedamage = DAMAGE_AIM;
 611         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 612
 613         ResetPlayerResources(this);
 614
 615         SetSpectatee_status(this, 0);
 616
 617         PS(this).dual_weapons = '0 0 0';
 618
 619         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 620
 621         this.items = start_items;
 622
 623         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 624         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 625         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 626         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 627         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 628         if (!sv_ready_restart_after_countdown && time < game_starttime)
 629         {
 630                 float f = game_starttime - time;
 631                 this.spawnshieldtime += f;
 632                 this.pauserotarmor_finished += f;
 633                 this.pauserothealth_finished += f;
 634                 this.pauseregen_finished += f;
 635         }
 636
 637         this.damageforcescale = autocvar_g_player_damageforcescale;
 638         this.death_time = 0;
 639         this.respawn_flags = 0;
 640         this.respawn_time = 0;
 641         STAT(RESPAWN_TIME, this) = 0;
 642         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 643         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 644         this.fade_time = 0;
 645         this.pain_finished = 0;
 646         this.pushltime = 0;
 647         setthink(this, func_null); // players have no think function
 648         this.nextthink = 0;
 649         this.dmg_team = 0;
 650         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 651
 652         this.deadflag = DEAD_NO;
 653
 654         this.angles = spot.angles;
 655         this.angles_z = 0; // never spawn tilted even if the spot says to
 656         if (IS_BOT_CLIENT(this))
 657         {
 658                 this.v_angle = this.angles;
 659                 bot_aim_reset(this);
 660         }
 661         this.fixangle = true; // turn this way immediately
 662         this.oldvelocity = this.velocity = '0 0 0';
 663         this.avelocity = '0 0 0';
 664         this.punchangle = '0 0 0';
 665         this.punchvector = '0 0 0';
 666
 667         STAT(STRENGTH_FINISHED, this) = 0;
 668         STAT(INVINCIBLE_FINISHED, this) = 0;
 669         this.fire_endtime = -1;
 670         STAT(REVIVE_PROGRESS, this) = 0;
 671         this.revival_time = 0;
 672
 673         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 674         STAT(BUFFS, this) = 0;
 675         STAT(BUFF_TIME, this) = 0;
 676
 677         STAT(AIR_FINISHED, this) = 0;
 678         this.waterlevel = WATERLEVEL_NONE;
 679         this.watertype = CONTENT_EMPTY;
 680
 681         entity spawnevent = new_pure(spawnevent);
 682         spawnevent.owner = this;
 683         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 684
 685         // Cut off any still running player sounds.
 686         stopsound(this, CH_PLAYER_SINGLE);
 687
 688         this.model = "";
 689         FixPlayermodel(this);
 690         this.drawonlytoclient = NULL;
 691
 692         this.viewloc = NULL;
 693
 694         for(int slot = 0; slot < MAX_AXH; ++slot)
 695         {
 696                 entity axh = this.(AuxiliaryXhair[slot]);
 697                 this.(AuxiliaryXhair[slot]) = NULL;
 698
 699                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 700                         delete(axh);
 701         }
 702
 703         this.spawnpoint_targ = NULL;
 704
 705         UNSET_DUCKED(this);
 706         this.view_ofs = STAT(PL_VIEW_OFS, this);
 707         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 708         this.spawnorigin = spot.origin;
 709         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 710         // don't reset back to last position, even if new position is stuck in solid
 711         this.oldorigin = this.origin;
 712         if(this.conveyor)
 713                 IL_REMOVE(g_conveyed, this);
 714         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 715         if(this.swampslug)
 716                 IL_REMOVE(g_swamped, this);
 717         this.swampslug = NULL;
 718         this.swamp_interval = 0;
 719         if(this.ladder_entity)
 720                 IL_REMOVE(g_ladderents, this);
 721         this.ladder_entity = NULL;
 722         IL_EACH(g_counters, it.realowner == this,
 723         {
 724                 delete(it);
 725         });
 726         STAT(HUD, this) = HUD_NORMAL;
 727
 728         this.event_damage = PlayerDamage;
 729         this.event_heal = PlayerHeal;
 730
 731         this.draggable = func_null;
 732
 733         if(!this.bot_attack)
 734                 IL_PUSH(g_bot_targets, this);
 735         this.bot_attack = true;
 736         if(!this.monster_attack)
 737                 IL_PUSH(g_monster_targets, this);
 738         this.monster_attack = true;
 739         navigation_dynamicgoal_init(this, false);
 740
 741         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 742
 743         // player was spectator
 744         if (CS(this).killcount == FRAGS_SPECTATOR) {
 745                 PlayerScore_Clear(this);
 746                 CS(this).killcount = 0;
 747                 CS(this).startplaytime = time;
 748         }
 749
 750         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 751         {
 752                 .entity weaponentity = weaponentities[slot];
 753                 CL_SpawnWeaponentity(this, weaponentity);
 754         }
 755         this.alpha = default_player_alpha;
 756         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 757         this.exteriorweaponentity.alpha = default_weapon_alpha;
 758
 759         this.speedrunning = false;
 760
 761         this.counter_cnt = 0;
 762         this.fragsfilter_cnt = 0;
 763
 764         target_voicescript_clear(this);
 765
 766         // reset fields the weapons may use
 767         FOREACH(Weapons, true, {
 768                 it.wr_resetplayer(it, this);
 769                         // reload all reloadable weapons
 770                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 771                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 772                         {
 773                                 .entity weaponentity = weaponentities[slot];
 774                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 775                         }
 776                 }
 777         });
 778
 779         {
 780                 string s = spot.target;
 781                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 782                         spot.target = string_null;
 783                 SUB_UseTargets(spot, this, NULL);
 784                 if(g_assault || g_race)
 785                         spot.target = s;
 786         }
 787
 788         Unfreeze(this, false);
 789
 790         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 791
 792         if (autocvar_spawn_debug)
 793         {
 794                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 795                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 796         }
 797
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 entity w_ent = this.(weaponentity);
 802                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 803                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 804                 else
 805                         w_ent.m_switchweapon = WEP_Null;
 806                 w_ent.m_weapon = WEP_Null;
 807                 w_ent.weaponname = "";
 808                 w_ent.m_switchingweapon = WEP_Null;
 809                 w_ent.cnt = -1;
 810         }
 811
 812         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 813
 814         if (CS(this).impulse) ImpulseCommands(this);
 815
 816         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 817         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 818         {
 819                 .entity weaponentity = weaponentities[slot];
 820                 W_WeaponFrame(this, weaponentity);
 821         }
 822
 823         if (!warmup_stage && !this.alivetime)
 824                 this.alivetime = time;
 825
 826         antilag_clear(this, CS(this));
 827 }
 828
 829 /** Called when a client spawns in the server */
 830 void PutClientInServer(entity this)
 831 {
 832         if (IS_BOT_CLIENT(this)) {
 833                 TRANSMUTE(Player, this);
 834         } else if (IS_REAL_CLIENT(this)) {
 835                 msg_entity = this;
 836                 WriteByte(MSG_ONE, SVC_SETVIEW);
 837                 WriteEntity(MSG_ONE, this);
 838         }
 839         if (game_stopped)
 840                 TRANSMUTE(Observer, this);
 841
 842         SetSpectatee(this, NULL);
 843
 844         // reset player keys
 845         if(PS(this))
 846                 PS(this).itemkeys = 0;
 847
 848         MUTATOR_CALLHOOK(PutClientInServer, this);
 849
 850         if (IS_OBSERVER(this)) {
 851                 PutObserverInServer(this);
 852         } else if (IS_PLAYER(this)) {
 853                 PutPlayerInServer(this);
 854         }
 855         // send team names
 856         if(teamplay && IS_REAL_CLIENT(this))
 857                 send_TeamNames(MSG_ONE, this);
 858         bot_relinkplayerlist();
 859 }
 860
 861 // TODO do we need all these fields, or should we stop autodetecting runtime
 862 // changes and just have a console command to update this?
 863 bool ClientInit_SendEntity(entity this, entity to, int sf)
 864 {
 865         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 866         return = true;
 867         msg_entity = to;
 868         // MSG_INIT replacement
 869         // TODO: make easier to use
 870         Registry_send_all();
 871         W_PROP_reload(MSG_ONE, to);
 872         ClientInit_misc(this);
 873         MUTATOR_CALLHOOK(Ent_Init);
 874 }
 875 void ClientInit_misc(entity this)
 876 {
 877         int channel = MSG_ONE;
 878         WriteHeader(channel, ENT_CLIENT_INIT);
 879         WriteByte(channel, g_nexball_meter_period * 32);
 880         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 881         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 882         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 883         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 884         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 885         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 886         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 887         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 888
 889         if(autocvar_sv_foginterval && world.fog != "")
 890                 WriteString(channel, world.fog);
 891         else
 892                 WriteString(channel, "");
 893         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 894         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 895         WriteByte(channel, serverflags);
 896         WriteCoord(channel, autocvar_g_trueaim_minrange);
 897
 898         // z411 send full hostname
 899         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 900         WriteString(channel, autocvar_sv_motd_permanent);
 901 }
 902
 903 void ClientInit_CheckUpdate(entity this)
 904 {
 905         this.nextthink = time;
 906         if(this.count != autocvar_g_balance_armor_blockpercent)
 907         {
 908                 this.count = autocvar_g_balance_armor_blockpercent;
 909                 this.SendFlags |= 1;
 910         }
 911         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 912         {
 913                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 914                 this.SendFlags |= 1;
 915         }
 916 }
 917
 918 void ClientInit_Spawn()
 919 {
 920         entity e = new_pure(clientinit);
 921         setthink(e, ClientInit_CheckUpdate);
 922         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 923
 924         ClientInit_CheckUpdate(e);
 925 }
 926
 927 /*
 928 =============
 929 SetNewParms
 930 =============
 931 */
 932 void SetNewParms ()
 933 {
 934         // initialize parms for a new player
 935         parm1 = -(86400 * 366);
 936
 937         MUTATOR_CALLHOOK(SetNewParms);
 938 }
 939
 940 /*
 941 =============
 942 SetChangeParms
 943 =============
 944 */
 945 void SetChangeParms (entity this)
 946 {
 947         // save parms for level change
 948         parm1 = CS(this).parm_idlesince - time;
 949
 950         MUTATOR_CALLHOOK(SetChangeParms);
 951 }
 952
 953 /*
 954 =============
 955 DecodeLevelParms
 956 =============
 957 */
 958 void DecodeLevelParms(entity this)
 959 {
 960         // load parms
 961         CS(this).parm_idlesince = parm1;
 962         if (CS(this).parm_idlesince == -(86400 * 366))
 963                 CS(this).parm_idlesince = time;
 964
 965         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 966         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 967
 968         MUTATOR_CALLHOOK(DecodeLevelParms);
 969 }
 970
 971 void FixClientCvars(entity e)
 972 {
 973         // send prediction settings to the client
 974         stuffcmd(e, "\nin_bindmap 0 0\n");
 975         if(autocvar_g_antilag == 3) // client side hitscan
 976                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 977         if(autocvar_sv_gentle)
 978                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 979
 980         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 981         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 982
 983         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 984
 985         MUTATOR_CALLHOOK(FixClientCvars, e);
 986 }
 987
 988 bool findinlist_abbrev(string tofind, string list)
 989 {
 990         if(list == "" || tofind == "")
 991                 return false; // empty list or search, just return
 992
 993         // this function allows abbreviated strings!
 994         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 995         {
 996                 return true;
 997         });
 998
 999         return false;
1000 }
1001
1002 bool PlayerInIPList(entity p, string iplist)
1003 {
1004         // some safety checks (never allow local?)
1005         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1006                 return false;
1007
1008         return findinlist_abbrev(p.netaddress, iplist);
1009 }
1010
1011 bool PlayerInIDList(entity p, string idlist)
1012 {
1013         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1014         if(!p.crypto_idfp)
1015                 return false;
1016
1017         return findinlist_abbrev(p.crypto_idfp, idlist);
1018 }
1019
1020 bool PlayerInList(entity player, string list)
1021 {
1022         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1023 }
1024
1025 #ifdef DP_EXT_PRECONNECT
1026 /*
1027 =============
1028 ClientPreConnect
1029
1030 Called once (not at each match start) when a client begins a connection to the server
1031 =============
1032 */
1033 void ClientPreConnect(entity this)
1034 {
1035         if(autocvar_sv_eventlog)
1036         {
1037                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1038                         this.playerid,
1039                         etof(this),
1040                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1041                 ));
1042         }
1043 }
1044 #endif
1045
1046 string GetClientVersionMessage(entity this)
1047 {
1048         if (CS(this).version_mismatch) {
1049                 if(CS(this).version < autocvar_gameversion) {
1050                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1051                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1052                 } else {
1053                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1054                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1055                 }
1056         } else {
1057                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1058         }
1059 }
1060
1061 string getwelcomemessage(entity this)
1062 {
1063         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1064         string modifications = M_ARGV(0, string);
1065
1066         if(g_weaponarena)
1067         {
1068                 if(g_weaponarena_random)
1069                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1070                 else
1071                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1072         }
1073         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1074                 modifications = strcat(modifications, ", No start weapons");
1075         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1076                 modifications = strcat(modifications, ", Low gravity");
1077         if(g_weapon_stay && !g_cts)
1078                 modifications = strcat(modifications, ", Weapons stay");
1079         if(autocvar_g_jetpack)
1080                 modifications = strcat(modifications, ", Jet pack");
1081         if(autocvar_g_powerups == 0)
1082                 modifications = strcat(modifications, ", No powerups");
1083         if(autocvar_g_powerups > 0)
1084                 modifications = strcat(modifications, ", Powerups");
1085         modifications = substring(modifications, 2, strlen(modifications) - 2);
1086
1087         //string versionmessage = GetClientVersionMessage(this);
1088         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1089         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1090
1091         s = strcat(s, "^8\n^7", gamemode_name);
1092
1093         if(modifications != "")
1094                 s = strcat(s, "^7 | ^3", modifications);
1095
1096         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1097         {
1098                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1099                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1100         }
1101
1102         if (cache_mutatormsg != "") {
1103                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1104         }
1105
1106         string mutator_msg = "";
1107         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1108         mutator_msg = M_ARGV(0, string);
1109
1110         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1111
1112         string motd = autocvar_sv_motd;
1113         if (motd != "") {
1114                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1115         }
1116         return s;
1117 }
1118
1119 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1120
1121 /**
1122 =============
1123 ClientConnect
1124
1125 Called when a client connects to the server
1126 =============
1127 */
1128 void ClientConnect(entity this)
1129 {
1130         if (Ban_MaybeEnforceBanOnce(this)) return;
1131         assert(!IS_CLIENT(this), return);
1132         this.flags |= FL_CLIENT;
1133         assert(player_count >= 0, player_count = 0);
1134
1135         TRANSMUTE(Client, this);
1136         CS(this).version_nagtime = time + 10 + random() * 10;
1137
1138         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1139
1140         bot_clientconnect(this);
1141
1142         Player_DetermineForcedTeam(this);
1143
1144         TRANSMUTE(Observer, this);
1145
1146         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1147
1148         // always track bots, don't ask for cl_allow_uidtracking
1149         if (IS_BOT_CLIENT(this))
1150                 PlayerStats_GameReport_AddPlayer(this);
1151         else
1152                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1153
1154         if (autocvar_sv_eventlog)
1155                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1156
1157         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1158
1159         stuffcmd(this, clientstuff, "\n");
1160         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1161
1162         FixClientCvars(this);
1163
1164         // get version info from player
1165         stuffcmd(this, "cmd clientversion $gameversion\n");
1166
1167         // notify about available teams
1168         if (teamplay)
1169         {
1170                 entity balance = TeamBalance_CheckAllowedTeams(this);
1171                 int t = TeamBalance_GetAllowedTeams(balance);
1172                 TeamBalance_Destroy(balance);
1173                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1174         }
1175         else
1176         {
1177                 stuffcmd(this, "set _teams_available 0\n");
1178         }
1179
1180         bot_relinkplayerlist();
1181
1182         CS(this).spectatortime = time;
1183         if (blockSpectators)
1184         {
1185                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1186         }
1187
1188         CS(this).jointime = time;
1189
1190         if (IS_REAL_CLIENT(this))
1191         {
1192                 if (g_weaponarena_weapons == WEPSET(TUBA))
1193                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1194         }
1195
1196         if (!autocvar_sv_foginterval && world.fog != "")
1197                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1198
1199         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1200                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1201                         send_CSQC_teamnagger();
1202
1203         CSQCMODEL_AUTOINIT(this);
1204
1205         CS(this).model_randomizer = random();
1206
1207         if (IS_REAL_CLIENT(this))
1208                 sv_notice_join(this);
1209
1210         this.move_qcphysics = autocvar_sv_qcphysics;
1211
1212         // update physics stats (players can spawn before physics runs)
1213         Physics_UpdateStats(this);
1214
1215         IL_EACH(g_initforplayer, it.init_for_player, {
1216                 it.init_for_player(it, this);
1217         });
1218
1219         Handicap_Initialize(this);
1220
1221         MUTATOR_CALLHOOK(ClientConnect, this);
1222
1223         if (IS_REAL_CLIENT(this))
1224         {
1225                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1226                 {
1227                         CS(this).motd_actived_time = -1;
1228                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1229                 }
1230         }
1231 }
1232 /*
1233 =============
1234 ClientDisconnect
1235
1236 Called when a client disconnects from the server
1237 =============
1238 */
1239 .entity chatbubbleentity;
1240 void player_powerups_remove_all(entity this);
1241
1242 void ClientDisconnect(entity this)
1243 {
1244         assert(IS_CLIENT(this), return);
1245
1246         PlayerStats_GameReport_FinalizePlayer(this);
1247         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1248         if (CS(this).active_minigame) part_minigame(this);
1249         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1250
1251         if (autocvar_sv_eventlog)
1252                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1253
1254         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1255
1256         if(IS_SPEC(this))
1257                 SetSpectatee(this, NULL);
1258
1259         MUTATOR_CALLHOOK(ClientDisconnect, this);
1260
1261         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1262         strfree(CS_CVAR(this).weaponorder_byimpulse);
1263         ClientState_detach(this);
1264
1265         Portal_ClearAll(this);
1266
1267         Unfreeze(this, false);
1268
1269         RemoveGrapplingHooks(this);
1270
1271         // Here, everything has been done that requires this player to be a client.
1272
1273         this.flags &= ~FL_CLIENT;
1274
1275         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1276         if (this.killindicator) delete(this.killindicator);
1277
1278         IL_EACH(g_counters, it.realowner == this,
1279         {
1280                 delete(it);
1281         });
1282
1283         WaypointSprite_PlayerGone(this);
1284
1285         bot_relinkplayerlist();
1286
1287         strfree(this.clientstatus);
1288         if (this.personal) delete(this.personal);
1289
1290         this.playerid = 0;
1291         ReadyCount();
1292         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1293
1294         player_powerups_remove_all(this); // stop powerup sound
1295
1296         ONREMOVE(this);
1297 }
1298
1299 void ChatBubbleThink(entity this)
1300 {
1301         this.nextthink = time;
1302         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1303         {
1304                 if(this.owner) // but why can that ever be NULL?
1305                         this.owner.chatbubbleentity = NULL;
1306                 delete(this);
1307                 return;
1308         }
1309
1310         this.mdl = "";
1311
1312         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1313         {
1314                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1315                         this.mdl = "models/sprites/minigame_busy.iqm";
1316                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1317                         this.mdl = "models/misc/chatbubble.spr";
1318         }
1319
1320         if ( this.model != this.mdl )
1321                 _setmodel(this, this.mdl);
1322
1323 }
1324
1325 void UpdateChatBubble(entity this)
1326 {
1327         if (this.alpha < 0)
1328                 return;
1329         // spawn a chatbubble entity if needed
1330         if (!this.chatbubbleentity)
1331         {
1332                 this.chatbubbleentity = new(chatbubbleentity);
1333                 this.chatbubbleentity.owner = this;
1334                 this.chatbubbleentity.exteriormodeltoclient = this;
1335                 setthink(this.chatbubbleentity, ChatBubbleThink);
1336                 this.chatbubbleentity.nextthink = time;
1337                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1338                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1339                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1340                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1341                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1342                 //this.chatbubbleentity.model = "";
1343                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1344         }
1345 }
1346
1347 void calculate_player_respawn_time(entity this)
1348 {
1349         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1350                 return;
1351
1352         float gametype_setting_tmp;
1353         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1354         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1355         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1356         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1357         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1358         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1359
1360         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1361         if (teamplay)
1362         {
1363                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1364                         if(it.team == this.team)
1365                                 ++pcount;
1366                 });
1367                 if (sdelay_small_count == 0)
1368                         sdelay_small_count = 1;
1369                 if (sdelay_large_count == 0)
1370                         sdelay_large_count = 1;
1371         }
1372         else
1373         {
1374                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1375                         ++pcount;
1376                 });
1377                 if (sdelay_small_count == 0)
1378                 {
1379                         if (IS_INDEPENDENT_PLAYER(this))
1380                         {
1381                                 // Players play independently. No point in requiring enemies.
1382                                 sdelay_small_count = 1;
1383                         }
1384                         else
1385                         {
1386                                 // Players play AGAINST each other. Enemies required.
1387                                 sdelay_small_count = 2;
1388                         }
1389                 }
1390                 if (sdelay_large_count == 0)
1391                 {
1392                         if (IS_INDEPENDENT_PLAYER(this))
1393                         {
1394                                 // Players play independently. No point in requiring enemies.
1395                                 sdelay_large_count = 1;
1396                         }
1397                         else
1398                         {
1399                                 // Players play AGAINST each other. Enemies required.
1400                                 sdelay_large_count = 2;
1401                         }
1402                 }
1403         }
1404
1405         float sdelay;
1406
1407         if (pcount <= sdelay_small_count)
1408                 sdelay = sdelay_small;
1409         else if (pcount >= sdelay_large_count)
1410                 sdelay = sdelay_large;
1411         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1412                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1413
1414         if(waves)
1415                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1416         else
1417                 this.respawn_time = time + sdelay;
1418
1419         if(sdelay < sdelay_max)
1420                 this.respawn_time_max = time + sdelay_max;
1421         else
1422                 this.respawn_time_max = this.respawn_time;
1423
1424         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1425                 this.respawn_countdown = 10; // first number to count down from is 10
1426         else
1427                 this.respawn_countdown = -1; // do not count down
1428
1429         if(autocvar_g_forced_respawn)
1430                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1431 }
1432
1433 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1434 // added to the model skins
1435 /*void UpdateColorModHack()
1436 {
1437         float c;
1438         c = this.clientcolors & 15;
1439         // LordHavoc: only bothering to support white, green, red, yellow, blue
1440              if (!teamplay) this.colormod = '0 0 0';
1441         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1442         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1443         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1444         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1445         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1446         else this.colormod = '1 1 1';
1447 }*/
1448
1449 void respawn(entity this)
1450 {
1451         bool damagedbycontents_prev = this.damagedbycontents;
1452         if(this.alpha >= 0)
1453         {
1454                 if(autocvar_g_respawn_ghosts)
1455                 {
1456                         this.solid = SOLID_NOT;
1457                         this.takedamage = DAMAGE_NO;
1458                         this.damagedbycontents = false;
1459                         set_movetype(this, MOVETYPE_FLY);
1460                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1461                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1462                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1463                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1464                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1465                         if(autocvar_g_respawn_ghosts_time > 0)
1466                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1467                 }
1468                 else
1469                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1470         }
1471
1472         CopyBody(this, 1);
1473         this.damagedbycontents = damagedbycontents_prev;
1474
1475         this.effects |= EF_NODRAW; // prevent another CopyBody
1476         PutClientInServer(this);
1477 }
1478
1479 void play_countdown(entity this, float finished, Sound samp)
1480 {
1481         TC(Sound, samp);
1482         if(IS_REAL_CLIENT(this))
1483                 if(floor(finished - time - frametime) != floor(finished - time))
1484                         if(finished - time < 6)
1485                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1486 }
1487
1488 void player_powerups_remove_all(entity this)
1489 {
1490         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1491         {
1492                 // don't play the poweroff sound when the game restarts or the player disconnects
1493                 if (time > game_starttime + 1 && IS_CLIENT(this))
1494                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1495                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1496                 this.items &= ~ITEM_Strength.m_itemid;
1497                 this.items &= ~ITEM_Shield.m_itemid;
1498                 this.items -= (this.items & IT_SUPERWEAPON);
1499         }
1500 }
1501
1502 void player_powerups(entity this)
1503 {
1504         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1505                 this.modelflags |= MF_ROCKET;
1506         else
1507                 this.modelflags &= ~MF_ROCKET;
1508
1509         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1510
1511         if (IS_DEAD(this))
1512                 player_powerups_remove_all(this);
1513
1514         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1515                 return;
1516
1517         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1518         int items_prev = this.items;
1519
1520         Fire_ApplyDamage(this);
1521         Fire_ApplyEffect(this);
1522
1523         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1524         {
1525                 if (this.items & ITEM_Strength.m_itemid)
1526                 {
1527                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1528                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1529                         if (time > STAT(STRENGTH_FINISHED, this))
1530                         {
1531                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1532                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1534                         }
1535                 }
1536                 else
1537                 {
1538                         if (time < STAT(STRENGTH_FINISHED, this))
1539                         {
1540                                 this.items = this.items | ITEM_Strength.m_itemid;
1541                                 if(!g_cts)
1542                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1543                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1544                         }
1545                 }
1546                 if (this.items & ITEM_Shield.m_itemid)
1547                 {
1548                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1549                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1550                         if (time > STAT(INVINCIBLE_FINISHED, this))
1551                         {
1552                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1553                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1554                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1555                         }
1556                 }
1557                 else
1558                 {
1559                         if (time < STAT(INVINCIBLE_FINISHED, this))
1560                         {
1561                                 this.items = this.items | ITEM_Shield.m_itemid;
1562                                 if(!g_cts)
1563                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1564                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1565                         }
1566                 }
1567                 if (this.items & IT_SUPERWEAPON)
1568                 {
1569                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1570                         {
1571                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1572                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1573                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1574                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1575                         }
1576                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1577                         {
1578                                 // don't let them run out
1579                         }
1580                         else
1581                         {
1582                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1583                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1584                                 {
1585                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1586                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1587                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1588                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1589                                 }
1590                         }
1591                 }
1592                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1593                 {
1594                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1595                         {
1596                                 this.items = this.items | IT_SUPERWEAPON;
1597                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1598                                 {
1599                                         if(!g_cts)
1600                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1601                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1602                                 }
1603                         }
1604                         else
1605                         {
1606                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1607                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1608                         }
1609                 }
1610                 else
1611                 {
1612                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1613                 }
1614         }
1615
1616         if(autocvar_g_nodepthtestplayers)
1617                 this.effects = this.effects | EF_NODEPTHTEST;
1618
1619         if(autocvar_g_fullbrightplayers)
1620                 this.effects = this.effects | EF_FULLBRIGHT;
1621
1622         if (time >= game_starttime)
1623         if (time < this.spawnshieldtime)
1624                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1625
1626         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1627 }
1628
1629 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1630 {
1631         if(current > stable)
1632                 return current;
1633         else if(current > stable - 0.25) // when close enough, "snap"
1634                 return stable;
1635         else
1636                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1637 }
1638
1639 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1640 {
1641         if(current < stable)
1642                 return current;
1643         else if(current < stable + 0.25) // when close enough, "snap"
1644                 return stable;
1645         else
1646                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1647 }
1648
1649 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1650 {
1651         float old = GetResource(this, res);
1652         float current = old;
1653         if(current > rotstable)
1654         {
1655                 if(rotframetime > 0)
1656                 {
1657                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1658                         current = max(rotstable, current - rotlinear * rotframetime);
1659                 }
1660         }
1661         else if(current < regenstable)
1662         {
1663                 if(regenframetime > 0)
1664                 {
1665                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1666                         current = min(regenstable, current + regenlinear * regenframetime);
1667                 }
1668         }
1669
1670         float limit = GetResourceLimit(this, res) * limit_mod;
1671         if(current > limit)
1672                 current = limit;
1673
1674         if (current != old)
1675                 SetResource(this, res, current);
1676 }
1677
1678 void player_regen(entity this)
1679 {
1680         float max_mod, regen_mod, rot_mod, limit_mod;
1681         max_mod = regen_mod = rot_mod = limit_mod = 1;
1682
1683         float regen_health = autocvar_g_balance_health_regen;
1684         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1685         float regen_health_rot = autocvar_g_balance_health_rot;
1686         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1687         float regen_health_stable = autocvar_g_balance_health_regenstable;
1688         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1689         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1690                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1691         max_mod = M_ARGV(1, float);
1692         regen_mod = M_ARGV(2, float);
1693         rot_mod = M_ARGV(3, float);
1694         limit_mod = M_ARGV(4, float);
1695         regen_health = M_ARGV(5, float);
1696         regen_health_linear = M_ARGV(6, float);
1697         regen_health_rot = M_ARGV(7, float);
1698         regen_health_rotlinear = M_ARGV(8, float);
1699         regen_health_stable = M_ARGV(9, float);
1700         regen_health_rotstable = M_ARGV(10, float);
1701
1702         if(!mutator_returnvalue)
1703         if(!STAT(FROZEN, this))
1704         {
1705                 float maxa = autocvar_g_balance_armor_rotstable;
1706                 float mina = autocvar_g_balance_armor_regenstable;
1707
1708                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1709                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1710                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1711
1712                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1713                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1714                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1715         }
1716
1717         // if player rotted to death...  die!
1718         // check this outside above checks, as player may still be able to rot to death
1719         if(GetResource(this, RES_HEALTH) < 1)
1720         {
1721                 if(this.vehicle)
1722                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1723                 if(this.event_damage)
1724                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1725         }
1726
1727         if (!(this.items & IT_UNLIMITED_AMMO))
1728         {
1729                 float maxf = autocvar_g_balance_fuel_rotstable;
1730                 float minf = autocvar_g_balance_fuel_regenstable;
1731
1732                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1733                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1734                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1735         }
1736 }
1737
1738 bool zoomstate_set;
1739 void SetZoomState(entity this, float newzoom)
1740 {
1741         if(newzoom != CS(this).zoomstate)
1742         {
1743                 CS(this).zoomstate = newzoom;
1744                 ClientData_Touch(this);
1745         }
1746         zoomstate_set = true;
1747 }
1748
1749 void GetPressedKeys(entity this)
1750 {
1751         MUTATOR_CALLHOOK(GetPressedKeys, this);
1752         if (game_stopped)
1753         {
1754                 CS(this).pressedkeys = 0;
1755                 STAT(PRESSED_KEYS, this) = 0;
1756                 return;
1757         }
1758
1759         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1760         int keys = STAT(PRESSED_KEYS, this);
1761         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1762         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1763         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1764         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1765
1766         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1767         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1768         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1769         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1770         CS(this).pressedkeys = keys; // store for other users
1771
1772         STAT(PRESSED_KEYS, this) = keys;
1773 }
1774
1775 /*
1776 ======================
1777 spectate mode routines
1778 ======================
1779 */
1780
1781 void SpectateCopy(entity this, entity spectatee)
1782 {
1783         TC(Client, this); TC(Client, spectatee);
1784
1785         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1786         PS(this) = PS(spectatee);
1787         this.armortype = spectatee.armortype;
1788         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1789         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1790         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1791         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1792         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1793         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1794         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1795         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1796         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1797         CS(this).impulse = 0;
1798         this.disableclientprediction = 1; // no need to run prediction on a spectator
1799         this.items = spectatee.items;
1800         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1801         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1802         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1803         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1804         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1805         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1806         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1807         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1808         this.punchangle = spectatee.punchangle;
1809         this.view_ofs = spectatee.view_ofs;
1810         this.velocity = spectatee.velocity;
1811         this.dmg_take = spectatee.dmg_take;
1812         this.dmg_save = spectatee.dmg_save;
1813         this.dmg_inflictor = spectatee.dmg_inflictor;
1814         this.v_angle = spectatee.v_angle;
1815         this.angles = spectatee.v_angle;
1816         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1817         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1818         this.viewloc = spectatee.viewloc;
1819         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1820                 this.fixangle = true;
1821         setorigin(this, spectatee.origin);
1822         setsize(this, spectatee.mins, spectatee.maxs);
1823         SetZoomState(this, CS(spectatee).zoomstate);
1824
1825     anticheat_spectatecopy(this, spectatee);
1826         STAT(HUD, this) = STAT(HUD, spectatee);
1827         if(spectatee.vehicle)
1828     {
1829         this.angles = spectatee.v_angle;
1830
1831         //this.fixangle = false;
1832         //this.velocity = spectatee.vehicle.velocity;
1833         this.vehicle_health = spectatee.vehicle_health;
1834         this.vehicle_shield = spectatee.vehicle_shield;
1835         this.vehicle_energy = spectatee.vehicle_energy;
1836         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1837         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1838         this.vehicle_reload1 = spectatee.vehicle_reload1;
1839         this.vehicle_reload2 = spectatee.vehicle_reload2;
1840
1841         //msg_entity = this;
1842
1843        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1844             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1845            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1846            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1847
1848         //WriteByte (MSG_ONE, SVC_SETVIEW);
1849         //    WriteEntity(MSG_ONE, this);
1850         //makevectors(spectatee.v_angle);
1851         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1852     }
1853 }
1854
1855 bool SpectateUpdate(entity this)
1856 {
1857         if(!this.enemy)
1858                 return false;
1859
1860         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1861         {
1862                 SetSpectatee(this, NULL);
1863                 return false;
1864         }
1865
1866         SpectateCopy(this, this.enemy);
1867
1868         return true;
1869 }
1870
1871 bool SpectateSet(entity this)
1872 {
1873         if(!IS_PLAYER(this.enemy))
1874                 return false;
1875
1876         ClientData_Touch(this.enemy);
1877
1878         msg_entity = this;
1879         WriteByte(MSG_ONE, SVC_SETVIEW);
1880         WriteEntity(MSG_ONE, this.enemy);
1881         set_movetype(this, MOVETYPE_NONE);
1882         accuracy_resend(this);
1883
1884         if(!SpectateUpdate(this))
1885                 PutObserverInServer(this);
1886
1887         return true;
1888 }
1889
1890 void SetSpectatee_status(entity this, int spectatee_num)
1891 {
1892         int oldspectatee_status = CS(this).spectatee_status;
1893         CS(this).spectatee_status = spectatee_num;
1894
1895         if (CS(this).spectatee_status != oldspectatee_status)
1896         {
1897                 if (STAT(PRESSED_KEYS, this))
1898                 {
1899                         CS(this).pressedkeys = 0;
1900                         STAT(PRESSED_KEYS, this) = 0;
1901                 }
1902                 ClientData_Touch(this);
1903                 if (g_race || g_cts) race_InitSpectator();
1904         }
1905 }
1906
1907 void SetSpectatee(entity this, entity spectatee)
1908 {
1909         if(IS_BOT_CLIENT(this))
1910                 return; // bots abuse .enemy, this code is useless to them
1911
1912         entity old_spectatee = this.enemy;
1913
1914         this.enemy = spectatee;
1915
1916         // WEAPONTODO
1917         // these are required to fix the spectator bug with arc
1918         if(old_spectatee)
1919         {
1920                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1921                 {
1922                         .entity weaponentity = weaponentities[slot];
1923                         if(old_spectatee.(weaponentity).arc_beam)
1924                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1925                 }
1926         }
1927         if(this.enemy)
1928         {
1929                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1930                 {
1931                         .entity weaponentity = weaponentities[slot];
1932                         if(this.enemy.(weaponentity).arc_beam)
1933                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1934                 }
1935         }
1936
1937         if (this.enemy)
1938                 SetSpectatee_status(this, etof(this.enemy));
1939
1940         // needed to update spectator list
1941         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1942 }
1943
1944 bool Spectate(entity this, entity pl)
1945 {
1946         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1947                 return false;
1948         pl = M_ARGV(1, entity);
1949
1950         SetSpectatee(this, pl);
1951         return SpectateSet(this);
1952 }
1953
1954 bool SpectateNext(entity this)
1955 {
1956         entity ent = find(this.enemy, classname, STR_PLAYER);
1957
1958         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1959                 ent = M_ARGV(1, entity);
1960         else if (!ent)
1961                 ent = find(ent, classname, STR_PLAYER);
1962
1963         if(ent) { SetSpectatee(this, ent); }
1964
1965         return SpectateSet(this);
1966 }
1967
1968 bool SpectatePrev(entity this)
1969 {
1970         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1971         entity ent = findchain(classname, STR_PLAYER);
1972         if (!ent) // no player
1973                 return false;
1974
1975         entity first = ent;
1976         // skip players until current spectated player
1977         if(this.enemy)
1978         while(ent && ent != this.enemy)
1979                 ent = ent.chain;
1980
1981         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1982         {
1983                 case MUT_SPECPREV_FOUND:
1984                         ent = M_ARGV(1, entity);
1985                         break;
1986                 case MUT_SPECPREV_RETURN:
1987                         return true;
1988                 case MUT_SPECPREV_CONTINUE:
1989                 default:
1990                 {
1991                         if(ent.chain)
1992                                 ent = ent.chain;
1993                         else
1994                                 ent = first;
1995                         break;
1996                 }
1997         }
1998
1999         SetSpectatee(this, ent);
2000         return SpectateSet(this);
2001 }
2002
2003 /*
2004 =============
2005 ShowRespawnCountdown()
2006
2007 Update a respawn countdown display.
2008 =============
2009 */
2010 void ShowRespawnCountdown(entity this)
2011 {
2012         float number;
2013         if(!IS_DEAD(this)) // just respawned?
2014                 return;
2015         else
2016         {
2017                 number = ceil(this.respawn_time - time);
2018                 if(number <= 0)
2019                         return;
2020                 if(number <= this.respawn_countdown)
2021                 {
2022                         this.respawn_countdown = number - 1;
2023                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2024                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2025                 }
2026         }
2027 }
2028
2029 .bool team_selected;
2030 bool ShowTeamSelection(entity this)
2031 {
2032         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2033                 return false;
2034         stuffcmd(this, "menu_showteamselect\n");
2035         return true;
2036 }
2037 void Join(entity this)
2038 {
2039         TRANSMUTE(Player, this);
2040
2041         if(!this.team_selected)
2042         if(autocvar_g_campaign || autocvar_g_balance_teams)
2043                 TeamBalance_JoinBestTeam(this);
2044
2045         if(autocvar_g_campaign)
2046                 campaign_bots_may_start = true;
2047
2048         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2049
2050         PutClientInServer(this);
2051
2052         if(IS_PLAYER(this))
2053         if(teamplay && this.team != -1)
2054         {
2055         }
2056         else
2057                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2058         this.team_selected = false;
2059
2060         // z411
2061         // send constant ready notification
2062         if(warmup_stage)
2063                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2064 }
2065
2066 int GetPlayerLimit()
2067 {
2068         if(g_duel)
2069                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2070         int player_limit = autocvar_g_maxplayers;
2071         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2072         player_limit = M_ARGV(0, int);
2073         return player_limit;
2074 }
2075
2076 /**
2077  * Determines whether the player is allowed to join. This depends on cvar
2078  * g_maxplayers, if it isn't used this function always return true, otherwise
2079  * it checks whether the number of currently playing players exceeds g_maxplayers.
2080  * @return int number of free slots for players, 0 if none
2081  */
2082 int nJoinAllowed(entity this, entity ignore)
2083 {
2084         if(!ignore)
2085         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2086         // so report 0 free slots if restricted
2087         {
2088                 if(autocvar_g_forced_team_otherwise == "spectate")
2089                         return 0;
2090                 if(autocvar_g_forced_team_otherwise == "spectator")
2091                         return 0;
2092         }
2093
2094         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2095                 return 0; // forced spectators can never join
2096
2097         // TODO simplify this
2098         int totalClients = 0;
2099         int currentlyPlaying = 0;
2100         FOREACH_CLIENT(true, {
2101                 if(it != ignore)
2102                         ++totalClients;
2103                 if(IS_REAL_CLIENT(it))
2104                 if(IS_PLAYER(it) || it.caplayer)
2105                         ++currentlyPlaying;
2106         });
2107
2108         int player_limit = GetPlayerLimit();
2109
2110         int free_slots = 0;
2111         if (!player_limit)
2112                 free_slots = maxclients - totalClients;
2113         else if(player_limit > 0 && currentlyPlaying < player_limit)
2114                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2115
2116         static float msg_time = 0;
2117         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2118         {
2119                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2120                 msg_time = time + 0.5;
2121         }
2122
2123         return free_slots;
2124 }
2125
2126 void PrintWelcomeMessage(entity this)
2127 {
2128         if(CS(this).motd_actived_time == 0)
2129         {
2130                 if (autocvar_g_campaign) {
2131                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2132                                 CS(this).motd_actived_time = time;
2133                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2134                         }
2135                 } else {
2136                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2137                                 CS(this).motd_actived_time = time;
2138                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2139                         }
2140                 }
2141         }
2142         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2143         {
2144                 if (autocvar_g_campaign) {
2145                         if (PHYS_INPUT_BUTTON_INFO(this))
2146                                 CS(this).motd_actived_time = time;
2147                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2148                                 CS(this).motd_actived_time = 0;
2149                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2150                         }
2151                 } else {
2152                         if (PHYS_INPUT_BUTTON_INFO(this))
2153                                 CS(this).motd_actived_time = time;
2154                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2155                                 CS(this).motd_actived_time = 0;
2156                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2157                         }
2158                 }
2159         }
2160         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2161         {
2162                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2163                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2164                 else if (CS(this).motd_actived_time == -2)
2165                 {
2166                         // instantly hide MOTD
2167                         CS(this).motd_actived_time = 0;
2168                         if (autocvar_g_campaign)
2169                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2170                         else
2171                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2172                 }
2173                 else if (IS_PLAYER(this) || IS_SPEC(this))
2174                 {
2175                         // FIXME occasionally for some reason MOTD never goes away
2176                         // delay MOTD removal a little bit in the hope it fixes this bug
2177                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2178                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2179                         else //if (CS(this).motd_actived_time < -2)
2180                                 CS(this).motd_actived_time++;
2181                 }
2182         }
2183 }
2184
2185 bool joinAllowed(entity this)
2186 {
2187         if (CS(this).version_mismatch) return false;
2188         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2189         if (!nJoinAllowed(this, this)) return false;
2190         if (teamplay && lockteams) return false;
2191         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2192         if (ShowTeamSelection(this)) return false;
2193         return true;
2194 }
2195
2196 .string shootfromfixedorigin;
2197 .bool dualwielding_prev;
2198 bool PlayerThink(entity this)
2199 {
2200         if (game_stopped || intermission_running) {
2201                 this.modelflags &= ~MF_ROCKET;
2202                 if(intermission_running)
2203                         IntermissionThink(this);
2204                 return false;
2205         }
2206
2207         if (game_timeout) {
2208         // don't allow the player to turn around while game is paused
2209                 // FIXME turn this into CSQC stuff
2210                 this.v_angle = this.lastV_angle;
2211                 this.angles = this.lastV_angle;
2212                 this.fixangle = true;
2213                 return false;
2214         }
2215
2216         if (frametime) player_powerups(this);
2217
2218         if (IS_DEAD(this)) {
2219                 if (this.personal && g_race_qualifying) {
2220                         if (time > this.respawn_time) {
2221                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2222                                 respawn(this);
2223                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2224                         }
2225                 } else {
2226                         if (frametime) player_anim(this);
2227
2228                         if (this.respawn_flags & RESPAWN_DENY)
2229                         {
2230                                 STAT(RESPAWN_TIME, this) = 0;
2231                                 return false;
2232                         }
2233
2234                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2235
2236                         switch(this.deadflag)
2237                         {
2238                                 case DEAD_DYING:
2239                                 {
2240                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2241                                                 this.deadflag = DEAD_RESPAWNING;
2242                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2243                                                 this.deadflag = DEAD_DEAD;
2244                                         break;
2245                                 }
2246                                 case DEAD_DEAD:
2247                                 {
2248                                         if (button_pressed)
2249                                                 this.deadflag = DEAD_RESPAWNABLE;
2250                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2251                                                 this.deadflag = DEAD_RESPAWNING;
2252                                         break;
2253                                 }
2254                                 case DEAD_RESPAWNABLE:
2255                                 {
2256                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2257                                                 this.deadflag = DEAD_RESPAWNING;
2258                                         break;
2259                                 }
2260                                 case DEAD_RESPAWNING:
2261                                 {
2262                                         if (time > this.respawn_time)
2263                                         {
2264                                                 this.respawn_time = time + 1; // only retry once a second
2265                                                 this.respawn_time_max = this.respawn_time;
2266                                                 respawn(this);
2267                                         }
2268                                         break;
2269                                 }
2270                         }
2271
2272                         ShowRespawnCountdown(this);
2273
2274                         if (this.respawn_flags & RESPAWN_SILENT)
2275                                 STAT(RESPAWN_TIME, this) = 0;
2276                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2277                         {
2278                                 if (time < this.respawn_time)
2279                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2280                                 else if (this.deadflag != DEAD_RESPAWNING)
2281                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2282                         }
2283                         else
2284                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2285                 }
2286
2287                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2288                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2289                         STAT(RESPAWN_TIME, this) *= -1;
2290
2291                 return false;
2292         }
2293
2294         FixPlayermodel(this);
2295
2296         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2297                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2298                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2299         }
2300
2301         // reset gun alignment when dual wielding status changes
2302         // to ensure guns are always aligned right and left
2303         bool dualwielding = W_DualWielding(this);
2304         if(this.dualwielding_prev != dualwielding)
2305         {
2306                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2307                 this.dualwielding_prev = dualwielding;
2308         }
2309
2310         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2311         //if(frametime)
2312         {
2313                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2314                 {
2315                         .entity weaponentity = weaponentities[slot];
2316                         if(WEP_CVAR(vortex, charge_always))
2317                                 W_Vortex_Charge(this, weaponentity, frametime);
2318                         W_WeaponFrame(this, weaponentity);
2319                 }
2320         }
2321
2322         if (frametime)
2323         {
2324                 // WEAPONTODO: Add a weapon request for this
2325                 // rot vortex charge to the charge limit
2326                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2327                 {
2328                         .entity weaponentity = weaponentities[slot];
2329                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2330                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2331                 }
2332
2333                 player_regen(this);
2334                 player_anim(this);
2335                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2336         }
2337
2338         monsters_setstatus(this);
2339
2340         return true;
2341 }
2342
2343 .bool would_spectate;
2344 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2345 void ObserverOrSpectatorThink(entity this)
2346 {
2347         bool is_spec = IS_SPEC(this);
2348         if ( CS(this).impulse )
2349         {
2350                 int r = MinigameImpulse(this, CS(this).impulse);
2351                 if (!is_spec || r)
2352                         CS(this).impulse = 0;
2353
2354                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2355                 {
2356                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2357                         CS(this).impulse = 0;
2358                         return;
2359                 }
2360         }
2361
2362         if (this.flags & FL_JUMPRELEASED) {
2363                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2364                         this.flags &= ~FL_JUMPRELEASED;
2365                         this.flags |= FL_SPAWNING;
2366                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2367                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2368                         this.flags &= ~FL_JUMPRELEASED;
2369                         if(SpectateNext(this)) {
2370                                 TRANSMUTE(Spectator, this);
2371                         } else if (is_spec) {
2372                                 TRANSMUTE(Observer, this);
2373                                 PutClientInServer(this);
2374                         }
2375                         else
2376                                 this.would_spectate = false; // unable to spectate anyone
2377                         if (is_spec)
2378                                 CS(this).impulse = 0;
2379                 } else if (is_spec) {
2380                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2381                                 this.flags &= ~FL_JUMPRELEASED;
2382                                 if(SpectatePrev(this)) {
2383                                         TRANSMUTE(Spectator, this);
2384                                 } else {
2385                                         TRANSMUTE(Observer, this);
2386                                         PutClientInServer(this);
2387                                 }
2388                                 CS(this).impulse = 0;
2389                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2390                                 this.would_spectate = false;
2391                                 this.flags &= ~FL_JUMPRELEASED;
2392                                 TRANSMUTE(Observer, this);
2393                                 PutClientInServer(this);
2394                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2395                                 PutObserverInServer(this);
2396                                 this.would_spectate = true;
2397                         }
2398                 }
2399                 else {
2400                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2401                         if (PHYS_INPUT_BUTTON_USE(this))
2402                                 wouldclip = !wouldclip;
2403                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2404                         set_movetype(this, preferred_movetype);
2405                 }
2406         } else { // jump pressed
2407                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2408                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2409                         this.flags |= FL_JUMPRELEASED;
2410                         if(this.flags & FL_SPAWNING)
2411                         {
2412                                 this.flags &= ~FL_SPAWNING;
2413                                 if(joinAllowed(this))
2414                                         Join(this);
2415                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2416                                         CS(this).autojoin_checked = -1;
2417                                 return;
2418                         }
2419                 }
2420                 if(is_spec && !SpectateUpdate(this))
2421                         PutObserverInServer(this);
2422         }
2423         if (is_spec)
2424                 this.flags |= FL_CLIENT | FL_NOTARGET;
2425 }
2426
2427 void PlayerUseKey(entity this)
2428 {
2429         if (!IS_PLAYER(this))
2430                 return;
2431
2432         if(this.vehicle)
2433         {
2434                 if(!game_stopped)
2435                 {
2436                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2437                         return;
2438                 }
2439         }
2440         else if(autocvar_g_vehicles_enter)
2441         {
2442                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2443                 {
2444                         entity head, closest_target = NULL;
2445                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2446
2447                         while(head) // find the closest acceptable target to enter
2448                         {
2449                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2450                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2451                                 {
2452                                         if(closest_target)
2453                                         {
2454                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2455                                                 { closest_target = head; }
2456                                         }
2457                                         else { closest_target = head; }
2458                                 }
2459
2460                                 head = head.chain;
2461                         }
2462
2463                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2464                 }
2465         }
2466
2467         // a use key was pressed; call handlers
2468         MUTATOR_CALLHOOK(PlayerUseKey, this);
2469 }
2470
2471
2472 /*
2473 =============
2474 PlayerPreThink
2475
2476 Called every frame for each client before the physics are run
2477 =============
2478 */
2479 .float last_vehiclecheck;
2480 void PlayerPreThink (entity this)
2481 {
2482         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2483         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2484
2485         WarpZone_PlayerPhysics_FixVAngle(this);
2486
2487         if (frametime) {
2488                 // physics frames: update anticheat stuff
2489                 anticheat_prethink(this);
2490
2491                 // WORKAROUND: only use dropclient in server frames (frametime set).
2492                 // Never use it in cl_movement frames (frametime zero).
2493                 if (blockSpectators && IS_REAL_CLIENT(this)
2494                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2495                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2496                 {
2497                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2498                         dropclient(this);
2499                         return;
2500                 }
2501         }
2502
2503         zoomstate_set = false;
2504
2505         // Check for nameless players
2506         if (this.netname == "" || this.netname != CS(this).netname_previous)
2507         {
2508                 bool assume_unchanged = (CS(this).netname_previous == "");
2509                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2510                 {
2511                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2512                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2513                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2514                         assume_unchanged = false;
2515                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2516                 }
2517                 if (isInvisibleString(this.netname))
2518                 {
2519                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2520                         sprint(this, "Warning: invisible names are not allowed.\n");
2521                         assume_unchanged = false;
2522                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2523                 }
2524                 if (!assume_unchanged && autocvar_sv_eventlog)
2525                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2526                 strcpy(CS(this).netname_previous, this.netname);
2527         }
2528
2529         // version nagging
2530         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2531         CS(this).version_nagtime = 0;
2532         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2533             // git client
2534         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2535             // git server
2536             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2537         } else {
2538             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2539             if (r < 0) { // old client
2540                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2541             } else if (r > 0) { // old server
2542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2543             }
2544         }
2545     }
2546
2547         // GOD MODE info
2548         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2549         {
2550                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2551                 this.max_armorvalue = 0;
2552         }
2553
2554         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2555         {
2556                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2557                 {
2558                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2559                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2560                         if (this.iceblock)
2561                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2562
2563                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2564                                 Unfreeze(this, false);
2565                 }
2566                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2567                 {
2568                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2569                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2570
2571                         if (GetResource(this, RES_HEALTH) < 1)
2572                         {
2573                                 if (this.vehicle)
2574                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2575                                 if(this.event_damage)
2576                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2577                         }
2578                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2579                                 Unfreeze(this, false);
2580                 }
2581         }
2582
2583         MUTATOR_CALLHOOK(PlayerPreThink, this);
2584
2585         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2586         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2587         {
2588                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2589                 {
2590                         if(!it.owner)
2591                         {
2592                                 if(!it.team || SAME_TEAM(this, it))
2593                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2594                                 else if(autocvar_g_vehicles_steal)
2595                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2596                         }
2597                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2598                         {
2599                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2600                         }
2601                 });
2602
2603                 this.last_vehiclecheck = time + 1;
2604         }
2605
2606         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2607         {
2608                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2609                         PlayerUseKey(this);
2610                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2611         }
2612
2613         if (IS_REAL_CLIENT(this))
2614                 PrintWelcomeMessage(this);
2615
2616         if (IS_PLAYER(this)) {
2617                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2618                         error("Client can't be spawned as player on connection!");
2619                 if(!PlayerThink(this))
2620                         return;
2621         }
2622         else if (game_stopped || intermission_running) {
2623                 if(intermission_running)
2624                         IntermissionThink(this);
2625                 return;
2626         }
2627         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2628         {
2629                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2630                 CS(this).autojoin_checked = 1;
2631                 // don't do this in ClientConnect
2632                 // many things can go wrong if a client is spawned as player on connection
2633                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2634                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2635                                 && (!teamplay || autocvar_g_balance_teams)))
2636                 {
2637                         campaign_bots_may_start = true;
2638                         if(joinAllowed(this))
2639                                 Join(this);
2640                         return;
2641                 }
2642         }
2643         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2644                 ObserverOrSpectatorThink(this);
2645         }
2646
2647         // WEAPONTODO: Add weapon request for this
2648         if (!zoomstate_set) {
2649                 bool wep_zoomed = false;
2650                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2651                 {
2652                         .entity weaponentity = weaponentities[slot];
2653                         Weapon thiswep = this.(weaponentity).m_weapon;
2654                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2655                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2656                 }
2657                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2658         }
2659
2660         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2661         {
2662                 CS(this).teamkill_soundtime = 0;
2663
2664                 entity e = CS(this).teamkill_soundsource;
2665                 entity oldpusher = e.pusher;
2666                 e.pusher = this;
2667                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2668                 e.pusher = oldpusher;
2669         }
2670
2671         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2672                 CS(this).taunt_soundtime = 0;
2673                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2674         }
2675
2676         target_voicescript_next(this);
2677 }
2678
2679 void DrownPlayer(entity this)
2680 {
2681         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2682                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2683         {
2684                 STAT(AIR_FINISHED, this) = 0;
2685                 return;
2686         }
2687
2688         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2689         {
2690                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2691                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2692                 STAT(AIR_FINISHED, this) = 0;
2693         }
2694         else
2695         {
2696                 if (!STAT(AIR_FINISHED, this))
2697                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2698                 if (STAT(AIR_FINISHED, this) < time)
2699                 {       // drown!
2700                         if (this.pain_finished < time)
2701                         {
2702                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2703                                 this.pain_finished = time + 0.5;
2704                         }
2705                 }
2706         }
2707 }
2708
2709 .bool move_qcphysics;
2710
2711 void Player_Physics(entity this)
2712 {
2713         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2714
2715         if(!this.move_qcphysics)
2716                 return;
2717
2718         if(!frametime && !CS(this).pm_frametime)
2719                 return;
2720
2721         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2722
2723         CS(this).pm_frametime = 0;
2724 }
2725
2726 /*
2727 =============
2728 PlayerPostThink
2729
2730 Called every frame for each client after the physics are run
2731 =============
2732 */
2733 void PlayerPostThink (entity this)
2734 {
2735         Player_Physics(this);
2736
2737         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2738         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2739         if (IS_REAL_CLIENT(this))
2740         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2741         {
2742                 int totalClients = 0;
2743                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2744                 {
2745                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2746                         {
2747                                 ++totalClients;
2748                         });
2749                 }
2750
2751                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2752                 { /* do nothing */ }
2753                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2754                 {
2755                         if (CS(this).idlekick_lasttimeleft)
2756                         {
2757                                 CS(this).idlekick_lasttimeleft = 0;
2758                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2759                         }
2760                 }
2761                 else
2762                 {
2763                         float maxidle_time = autocvar_sv_maxidle;
2764                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2765                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2766                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2767                         if (timeleft == min(10, maxidle_time - 1)) { // - 1 to support maxidle_time <= 10
2768                                 if (!CS(this).idlekick_lasttimeleft)
2769                                 {
2770                                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2771                                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2772                                         else
2773                                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2774                                 }
2775                         }
2776                         if (timeleft <= 0) {
2777                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2778                                 {
2779                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname);
2780                                         if (this.caplayer)
2781                                                 this.caplayer = 0;
2782                                         PutObserverInServer(this);
2783                                         CS(this).parm_idlesince = time;
2784                                 }
2785                                 else
2786                                 {
2787                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2788                                         dropclient(this);
2789                                 }
2790                                 return;
2791                         }
2792                         else if (timeleft <= 10) {
2793                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2794                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2795                                 CS(this).idlekick_lasttimeleft = timeleft;
2796                         }
2797                 }
2798         }
2799
2800         CheatFrame(this);
2801
2802         if (game_stopped)
2803         {
2804                 this.solid = SOLID_NOT;
2805                 this.takedamage = DAMAGE_NO;
2806                 set_movetype(this, MOVETYPE_NONE);
2807                 CS(this).teamkill_complain = 0;
2808                 CS(this).teamkill_soundtime = 0;
2809                 CS(this).teamkill_soundsource = NULL;
2810         }
2811
2812         if (IS_PLAYER(this)) {
2813                 if(this.death_time == time && IS_DEAD(this))
2814                 {
2815                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2816                         // once all the damage events of this frame have been processed with normal size
2817                         this.maxs.z = 5;
2818                         setsize(this, this.mins, this.maxs);
2819                 }
2820                 DrownPlayer(this);
2821                 UpdateChatBubble(this);
2822                 if (CS(this).impulse) ImpulseCommands(this);
2823                 GetPressedKeys(this);
2824                 if (game_stopped)
2825                 {
2826                         CSQCMODEL_AUTOUPDATE(this);
2827                         return;
2828                 }
2829         }
2830         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2831         {
2832                 CS(this).pressedkeys = 0;
2833                 STAT(PRESSED_KEYS, this) = 0;
2834         }
2835
2836         if (this.waypointsprite_attachedforcarrier) {
2837                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2838                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2839         }
2840
2841         CSQCMODEL_AUTOUPDATE(this);
2842 }
2843
2844 // hack to copy the button fields from the client entity to the Client State
2845 void PM_UpdateButtons(entity this, entity store)
2846 {
2847         if(this.impulse)
2848                 store.impulse = this.impulse;
2849         this.impulse = 0;
2850
2851         bool typing = this.buttonchat || this.button12;
2852
2853         store.button0 = (typing) ? 0 : this.button0;
2854         //button1?!
2855         store.button2 = (typing) ? 0 : this.button2;
2856         store.button3 = (typing) ? 0 : this.button3;
2857         store.button4 = this.button4;
2858         store.button5 = (typing) ? 0 : this.button5;
2859         store.button6 = this.button6;
2860         store.button7 = this.button7;
2861         store.button8 = this.button8;
2862         store.button9 = this.button9;
2863         store.button10 = this.button10;
2864         store.button11 = this.button11;
2865         store.button12 = this.button12;
2866         store.button13 = this.button13;
2867         store.button14 = this.button14;
2868         store.button15 = this.button15;
2869         store.button16 = this.button16;
2870         store.buttonuse = this.buttonuse;
2871         store.buttonchat = this.buttonchat;
2872
2873         store.cursor_active = this.cursor_active;
2874         store.cursor_screen = this.cursor_screen;
2875         store.cursor_trace_start = this.cursor_trace_start;
2876         store.cursor_trace_endpos = this.cursor_trace_endpos;
2877         store.cursor_trace_ent = this.cursor_trace_ent;
2878
2879         store.ping = this.ping;
2880         store.ping_packetloss = this.ping_packetloss;
2881         store.ping_movementloss = this.ping_movementloss;
2882
2883         store.v_angle = this.v_angle;
2884         store.movement = this.movement;
2885 }
2886
2887 NET_HANDLE(fpsreport, bool)
2888 {
2889         int fps = ReadShort();
2890         PlayerScore_Set(sender, SP_FPS, fps);
2891         return true;
2892 }