qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if(GetResource(this, RES_HEALTH) >= 1)
 255                 {
 256                         // despawn effect
 257                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 258                 }
 259
 260                 // was a player, recount votes and ready status
 261                 if(IS_REAL_CLIENT(this))
 262                 {
 263                         if (vote_called) { VoteCount(false); }
 264                         ReadyCount();
 265                 }
 266                 entcs_update_players(this);
 267         }
 268
 269         entity spot = SelectSpawnPoint(this, true);
 270         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 271         this.angles = vec2(spot.angles);
 272         this.fixangle = true;
 273         // offset it so that the spectator spawns higher off the ground, looks better this way
 274         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         WaypointSprite_PlayerDead(this);
 308
 309         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 310                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321         STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.effects = 0;
 335         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 336         this.pauserotarmor_finished = 0;
 337         this.pauserothealth_finished = 0;
 338         this.pauseregen_finished = 0;
 339         this.damageforcescale = 0;
 340         this.death_time = 0;
 341         this.respawn_flags = 0;
 342         this.respawn_time = 0;
 343         STAT(RESPAWN_TIME, this) = 0;
 344         this.alpha = 0;
 345         this.scale = 0;
 346         this.fade_time = 0;
 347         this.pain_finished = 0;
 348         STAT(STRENGTH_FINISHED, this) = 0;
 349         STAT(INVINCIBLE_FINISHED, this) = 0;
 350         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.fire_endtime = -1;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void ResetPlayerResources(entity this)
 538 {
 539         if (warmup_stage) {
 540                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 541                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 542                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 543                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 544                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 545                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 546                 SetResource(this, RES_HEALTH, warmup_start_health);
 547                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 548                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 549         } else {
 550                 SetResource(this, RES_SHELLS, start_ammo_shells);
 551                 SetResource(this, RES_BULLETS, start_ammo_nails);
 552                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 553                 SetResource(this, RES_CELLS, start_ammo_cells);
 554                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 555                 SetResource(this, RES_FUEL, start_ammo_fuel);
 556                 SetResource(this, RES_HEALTH, start_health);
 557                 SetResource(this, RES_ARMOR, start_armorvalue);
 558                 STAT(WEAPONS, this) = start_weapons;
 559                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 560                 {
 561                         GiveRandomWeapons(this, random_start_weapons_count,
 562                                 autocvar_g_random_start_weapons, random_start_ammo);
 563                 }
 564         }
 565 }
 566
 567 void PutPlayerInServer(entity this)
 568 {
 569         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 570
 571         PlayerState_attach(this);
 572         accuracy_resend(this);
 573
 574         if (this.team < 0)
 575                 TeamBalance_JoinBestTeam(this);
 576
 577         entity spot = SelectSpawnPoint(this, false);
 578         if (!spot) {
 579                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 580                 return; // spawn failed
 581         }
 582
 583         TRANSMUTE(Player, this);
 584
 585         CS(this).wasplayer = true;
 586         this.iscreature = true;
 587         this.teleportable = TELEPORT_NORMAL;
 588         if(!this.damagedbycontents)
 589                 IL_PUSH(g_damagedbycontents, this);
 590         this.damagedbycontents = true;
 591         set_movetype(this, MOVETYPE_WALK);
 592         this.solid = SOLID_SLIDEBOX;
 593         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 594         if (autocvar_g_playerclip_collisions)
 595                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 596         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 597                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 598         this.frags = FRAGS_PLAYER;
 599         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 600         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 601         if (autocvar__notarget)
 602                 this.flags |= FL_NOTARGET;
 603         this.takedamage = DAMAGE_AIM;
 604         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 605
 606         ResetPlayerResources(this);
 607
 608         SetSpectatee_status(this, 0);
 609
 610         PS(this).dual_weapons = '0 0 0';
 611
 612         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 613
 614         this.items = start_items;
 615
 616         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 617         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 618         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 619         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 620         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 621         if (!sv_ready_restart_after_countdown && time < game_starttime)
 622         {
 623                 float f = game_starttime - time;
 624                 this.spawnshieldtime += f;
 625                 this.pauserotarmor_finished += f;
 626                 this.pauserothealth_finished += f;
 627                 this.pauseregen_finished += f;
 628         }
 629
 630         this.damageforcescale = autocvar_g_player_damageforcescale;
 631         this.death_time = 0;
 632         this.respawn_flags = 0;
 633         this.respawn_time = 0;
 634         STAT(RESPAWN_TIME, this) = 0;
 635         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 636         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(STRENGTH_FINISHED, this) = 0;
 661         STAT(INVINCIBLE_FINISHED, this) = 0;
 662         this.fire_endtime = -1;
 663         STAT(REVIVE_PROGRESS, this) = 0;
 664         this.revival_time = 0;
 665
 666         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 667         STAT(BUFFS, this) = 0;
 668         STAT(BUFF_TIME, this) = 0;
 669
 670         STAT(AIR_FINISHED, this) = 0;
 671         this.waterlevel = WATERLEVEL_NONE;
 672         this.watertype = CONTENT_EMPTY;
 673
 674         entity spawnevent = new_pure(spawnevent);
 675         spawnevent.owner = this;
 676         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 677
 678         // Cut off any still running player sounds.
 679         stopsound(this, CH_PLAYER_SINGLE);
 680
 681         this.model = "";
 682         FixPlayermodel(this);
 683         this.drawonlytoclient = NULL;
 684
 685         this.viewloc = NULL;
 686
 687         for(int slot = 0; slot < MAX_AXH; ++slot)
 688         {
 689                 entity axh = this.(AuxiliaryXhair[slot]);
 690                 this.(AuxiliaryXhair[slot]) = NULL;
 691
 692                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 693                         delete(axh);
 694         }
 695
 696         this.spawnpoint_targ = NULL;
 697
 698         UNSET_DUCKED(this);
 699         this.view_ofs = STAT(PL_VIEW_OFS, this);
 700         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 701         this.spawnorigin = spot.origin;
 702         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 703         // don't reset back to last position, even if new position is stuck in solid
 704         this.oldorigin = this.origin;
 705         if(this.conveyor)
 706                 IL_REMOVE(g_conveyed, this);
 707         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 708         if(this.swampslug)
 709                 IL_REMOVE(g_swamped, this);
 710         this.swampslug = NULL;
 711         this.swamp_interval = 0;
 712         if(this.ladder_entity)
 713                 IL_REMOVE(g_ladderents, this);
 714         this.ladder_entity = NULL;
 715         IL_EACH(g_counters, it.realowner == this,
 716         {
 717                 delete(it);
 718         });
 719         STAT(HUD, this) = HUD_NORMAL;
 720
 721         this.event_damage = PlayerDamage;
 722         this.event_heal = PlayerHeal;
 723
 724         this.draggable = func_null;
 725
 726         if(!this.bot_attack)
 727                 IL_PUSH(g_bot_targets, this);
 728         this.bot_attack = true;
 729         if(!this.monster_attack)
 730                 IL_PUSH(g_monster_targets, this);
 731         this.monster_attack = true;
 732         navigation_dynamicgoal_init(this, false);
 733
 734         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 735
 736         // player was spectator
 737         if (CS(this).killcount == FRAGS_SPECTATOR) {
 738                 PlayerScore_Clear(this);
 739                 CS(this).killcount = 0;
 740                 CS(this).startplaytime = time;
 741         }
 742
 743         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 CL_SpawnWeaponentity(this, weaponentity);
 747         }
 748         this.alpha = default_player_alpha;
 749         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 750         this.exteriorweaponentity.alpha = default_weapon_alpha;
 751
 752         this.speedrunning = false;
 753
 754         this.counter_cnt = 0;
 755         this.fragsfilter_cnt = 0;
 756
 757         target_voicescript_clear(this);
 758
 759         // reset fields the weapons may use
 760         FOREACH(Weapons, true, {
 761                 it.wr_resetplayer(it, this);
 762                         // reload all reloadable weapons
 763                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 764                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765                         {
 766                                 .entity weaponentity = weaponentities[slot];
 767                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 768                         }
 769                 }
 770         });
 771
 772         {
 773                 string s = spot.target;
 774                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 775                         spot.target = string_null;
 776                 SUB_UseTargets(spot, this, NULL);
 777                 if(g_assault || g_race)
 778                         spot.target = s;
 779         }
 780
 781         Unfreeze(this, false);
 782
 783         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 784
 785         if (autocvar_spawn_debug)
 786         {
 787                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 788                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 789         }
 790
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 entity w_ent = this.(weaponentity);
 795                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 796                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 797                 else
 798                         w_ent.m_switchweapon = WEP_Null;
 799                 w_ent.m_weapon = WEP_Null;
 800                 w_ent.weaponname = "";
 801                 w_ent.m_switchingweapon = WEP_Null;
 802                 w_ent.cnt = -1;
 803         }
 804
 805         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 806
 807         if (CS(this).impulse) ImpulseCommands(this);
 808
 809         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 810         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811         {
 812                 .entity weaponentity = weaponentities[slot];
 813                 W_WeaponFrame(this, weaponentity);
 814         }
 815
 816         if (!warmup_stage && !this.alivetime)
 817                 this.alivetime = time;
 818
 819         antilag_clear(this, CS(this));
 820 }
 821
 822 /** Called when a client spawns in the server */
 823 void PutClientInServer(entity this)
 824 {
 825         if (IS_BOT_CLIENT(this)) {
 826                 TRANSMUTE(Player, this);
 827         } else if (IS_REAL_CLIENT(this)) {
 828                 msg_entity = this;
 829                 WriteByte(MSG_ONE, SVC_SETVIEW);
 830                 WriteEntity(MSG_ONE, this);
 831         }
 832         if (game_stopped)
 833                 TRANSMUTE(Observer, this);
 834
 835         SetSpectatee(this, NULL);
 836
 837         // reset player keys
 838         if(PS(this))
 839                 PS(this).itemkeys = 0;
 840
 841         MUTATOR_CALLHOOK(PutClientInServer, this);
 842
 843         if (IS_OBSERVER(this)) {
 844                 PutObserverInServer(this);
 845         } else if (IS_PLAYER(this)) {
 846                 PutPlayerInServer(this);
 847         }
 848         // send team names
 849         if(teamplay && IS_REAL_CLIENT(this))
 850                 send_TeamNames(MSG_ONE, this);
 851         bot_relinkplayerlist();
 852 }
 853
 854 // TODO do we need all these fields, or should we stop autodetecting runtime
 855 // changes and just have a console command to update this?
 856 bool ClientInit_SendEntity(entity this, entity to, int sf)
 857 {
 858         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 859         return = true;
 860         msg_entity = to;
 861         // MSG_INIT replacement
 862         // TODO: make easier to use
 863         Registry_send_all();
 864         W_PROP_reload(MSG_ONE, to);
 865         ClientInit_misc(this);
 866         MUTATOR_CALLHOOK(Ent_Init);
 867 }
 868 void ClientInit_misc(entity this)
 869 {
 870         int channel = MSG_ONE;
 871         WriteHeader(channel, ENT_CLIENT_INIT);
 872         WriteByte(channel, g_nexball_meter_period * 32);
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 881
 882         if(autocvar_sv_foginterval && world.fog != "")
 883                 WriteString(channel, world.fog);
 884         else
 885                 WriteString(channel, "");
 886         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 887         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 888         WriteByte(channel, serverflags);
 889         WriteCoord(channel, autocvar_g_trueaim_minrange);
 890
 891         // z411 send full hostname
 892         WriteString(channel, (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
 893 }
 894
 895 void ClientInit_CheckUpdate(entity this)
 896 {
 897         this.nextthink = time;
 898         if(this.count != autocvar_g_balance_armor_blockpercent)
 899         {
 900                 this.count = autocvar_g_balance_armor_blockpercent;
 901                 this.SendFlags |= 1;
 902         }
 903         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 904         {
 905                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 906                 this.SendFlags |= 1;
 907         }
 908 }
 909
 910 void ClientInit_Spawn()
 911 {
 912         entity e = new_pure(clientinit);
 913         setthink(e, ClientInit_CheckUpdate);
 914         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 915
 916         ClientInit_CheckUpdate(e);
 917 }
 918
 919 /*
 920 =============
 921 SetNewParms
 922 =============
 923 */
 924 void SetNewParms ()
 925 {
 926         // initialize parms for a new player
 927         parm1 = -(86400 * 366);
 928
 929         MUTATOR_CALLHOOK(SetNewParms);
 930 }
 931
 932 /*
 933 =============
 934 SetChangeParms
 935 =============
 936 */
 937 void SetChangeParms (entity this)
 938 {
 939         // save parms for level change
 940         parm1 = CS(this).parm_idlesince - time;
 941
 942         MUTATOR_CALLHOOK(SetChangeParms);
 943 }
 944
 945 /*
 946 =============
 947 DecodeLevelParms
 948 =============
 949 */
 950 void DecodeLevelParms(entity this)
 951 {
 952         // load parms
 953         CS(this).parm_idlesince = parm1;
 954         if (CS(this).parm_idlesince == -(86400 * 366))
 955                 CS(this).parm_idlesince = time;
 956
 957         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 958         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 959
 960         MUTATOR_CALLHOOK(DecodeLevelParms);
 961 }
 962
 963 void FixClientCvars(entity e)
 964 {
 965         // send prediction settings to the client
 966         stuffcmd(e, "\nin_bindmap 0 0\n");
 967         if(autocvar_g_antilag == 3) // client side hitscan
 968                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 969         if(autocvar_sv_gentle)
 970                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 971
 972         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 973         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 974
 975         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 976
 977         MUTATOR_CALLHOOK(FixClientCvars, e);
 978 }
 979
 980 bool findinlist_abbrev(string tofind, string list)
 981 {
 982         if(list == "" || tofind == "")
 983                 return false; // empty list or search, just return
 984
 985         // this function allows abbreviated strings!
 986         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 987         {
 988                 return true;
 989         });
 990
 991         return false;
 992 }
 993
 994 bool PlayerInIPList(entity p, string iplist)
 995 {
 996         // some safety checks (never allow local?)
 997         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 998                 return false;
 999
1000         return findinlist_abbrev(p.netaddress, iplist);
1001 }
1002
1003 bool PlayerInIDList(entity p, string idlist)
1004 {
1005         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1006         if(!p.crypto_idfp)
1007                 return false;
1008
1009         return findinlist_abbrev(p.crypto_idfp, idlist);
1010 }
1011
1012 bool PlayerInList(entity player, string list)
1013 {
1014         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1015 }
1016
1017 #ifdef DP_EXT_PRECONNECT
1018 /*
1019 =============
1020 ClientPreConnect
1021
1022 Called once (not at each match start) when a client begins a connection to the server
1023 =============
1024 */
1025 void ClientPreConnect(entity this)
1026 {
1027         if(autocvar_sv_eventlog)
1028         {
1029                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1030                         this.playerid,
1031                         etof(this),
1032                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1033                 ));
1034         }
1035 }
1036 #endif
1037
1038 string GetClientVersionMessage(entity this)
1039 {
1040         if (CS(this).version_mismatch) {
1041                 if(CS(this).version < autocvar_gameversion) {
1042                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1043                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1044                 } else {
1045                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1046                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1047                 }
1048         } else {
1049                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1050         }
1051 }
1052
1053 string getwelcomemessage(entity this)
1054 {
1055         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1056         string modifications = M_ARGV(0, string);
1057
1058         if(g_weaponarena)
1059         {
1060                 if(g_weaponarena_random)
1061                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1062                 else
1063                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1064         }
1065         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1066                 modifications = strcat(modifications, ", No start weapons");
1067         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1068                 modifications = strcat(modifications, ", Low gravity");
1069         if(g_weapon_stay && !g_cts)
1070                 modifications = strcat(modifications, ", Weapons stay");
1071         if(autocvar_g_jetpack)
1072                 modifications = strcat(modifications, ", Jet pack");
1073         if(autocvar_g_powerups == 0)
1074                 modifications = strcat(modifications, ", No powerups");
1075         if(autocvar_g_powerups > 0)
1076                 modifications = strcat(modifications, ", Powerups");
1077         modifications = substring(modifications, 2, strlen(modifications) - 2);
1078
1079         //string versionmessage = GetClientVersionMessage(this);
1080         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1081         string s = (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname);
1082
1083         s = strcat(s, "^8\n^7", gamemode_name);
1084
1085         if(modifications != "")
1086                 s = strcat(s, "^7 | ^3", modifications);
1087
1088         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1089         {
1090                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1091                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1092         }
1093
1094         if (cache_mutatormsg != "") {
1095                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1096         }
1097
1098         string mutator_msg = "";
1099         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1100         mutator_msg = M_ARGV(0, string);
1101
1102         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1103
1104         string motd = autocvar_sv_motd;
1105         if (motd != "") {
1106                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1107         }
1108         return s;
1109 }
1110
1111 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1112
1113 /**
1114 =============
1115 ClientConnect
1116
1117 Called when a client connects to the server
1118 =============
1119 */
1120 void ClientConnect(entity this)
1121 {
1122         if (Ban_MaybeEnforceBanOnce(this)) return;
1123         assert(!IS_CLIENT(this), return);
1124         this.flags |= FL_CLIENT;
1125         assert(player_count >= 0, player_count = 0);
1126
1127         TRANSMUTE(Client, this);
1128         CS(this).version_nagtime = time + 10 + random() * 10;
1129
1130         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1131
1132         bot_clientconnect(this);
1133
1134         Player_DetermineForcedTeam(this);
1135
1136         TRANSMUTE(Observer, this);
1137
1138         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1139
1140         // always track bots, don't ask for cl_allow_uidtracking
1141         if (IS_BOT_CLIENT(this))
1142                 PlayerStats_GameReport_AddPlayer(this);
1143         else
1144                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1145
1146         if (autocvar_sv_eventlog)
1147                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1148
1149         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1150
1151         stuffcmd(this, clientstuff, "\n");
1152         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1153
1154         FixClientCvars(this);
1155
1156         // get version info from player
1157         stuffcmd(this, "cmd clientversion $gameversion\n");
1158
1159         // notify about available teams
1160         if (teamplay)
1161         {
1162                 entity balance = TeamBalance_CheckAllowedTeams(this);
1163                 int t = TeamBalance_GetAllowedTeams(balance);
1164                 TeamBalance_Destroy(balance);
1165                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1166         }
1167         else
1168         {
1169                 stuffcmd(this, "set _teams_available 0\n");
1170         }
1171
1172         bot_relinkplayerlist();
1173
1174         CS(this).spectatortime = time;
1175         if (blockSpectators)
1176         {
1177                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1178         }
1179
1180         CS(this).jointime = time;
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (g_weaponarena_weapons == WEPSET(TUBA))
1185                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1186         }
1187
1188         if (!autocvar_sv_foginterval && world.fog != "")
1189                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1190
1191         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1192                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1193                         send_CSQC_teamnagger();
1194
1195         CSQCMODEL_AUTOINIT(this);
1196
1197         CS(this).model_randomizer = random();
1198
1199         if (IS_REAL_CLIENT(this))
1200                 sv_notice_join(this);
1201
1202         this.move_qcphysics = autocvar_sv_qcphysics;
1203
1204         // update physics stats (players can spawn before physics runs)
1205         Physics_UpdateStats(this);
1206
1207         IL_EACH(g_initforplayer, it.init_for_player, {
1208                 it.init_for_player(it, this);
1209         });
1210
1211         Handicap_Initialize(this);
1212
1213         MUTATOR_CALLHOOK(ClientConnect, this);
1214
1215         if (IS_REAL_CLIENT(this))
1216         {
1217                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1218                 {
1219                         CS(this).motd_actived_time = -1;
1220                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1221                 }
1222         }
1223 }
1224 /*
1225 =============
1226 ClientDisconnect
1227
1228 Called when a client disconnects from the server
1229 =============
1230 */
1231 .entity chatbubbleentity;
1232 void player_powerups_remove_all(entity this);
1233
1234 void ClientDisconnect(entity this)
1235 {
1236         assert(IS_CLIENT(this), return);
1237
1238         PlayerStats_GameReport_FinalizePlayer(this);
1239         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1240         if (CS(this).active_minigame) part_minigame(this);
1241         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1242
1243         if (autocvar_sv_eventlog)
1244                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1245
1246         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1247
1248         if(IS_SPEC(this))
1249                 SetSpectatee(this, NULL);
1250
1251         MUTATOR_CALLHOOK(ClientDisconnect, this);
1252
1253         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1254         strfree(CS_CVAR(this).weaponorder_byimpulse);
1255         ClientState_detach(this);
1256
1257         Portal_ClearAll(this);
1258
1259         Unfreeze(this, false);
1260
1261         RemoveGrapplingHooks(this);
1262
1263         // Here, everything has been done that requires this player to be a client.
1264
1265         this.flags &= ~FL_CLIENT;
1266
1267         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1268         if (this.killindicator) delete(this.killindicator);
1269
1270         IL_EACH(g_counters, it.realowner == this,
1271         {
1272                 delete(it);
1273         });
1274
1275         WaypointSprite_PlayerGone(this);
1276
1277         bot_relinkplayerlist();
1278
1279         strfree(this.clientstatus);
1280         if (this.personal) delete(this.personal);
1281
1282         this.playerid = 0;
1283         ReadyCount();
1284         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1285
1286         player_powerups_remove_all(this); // stop powerup sound
1287
1288         ONREMOVE(this);
1289 }
1290
1291 void ChatBubbleThink(entity this)
1292 {
1293         this.nextthink = time;
1294         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1295         {
1296                 if(this.owner) // but why can that ever be NULL?
1297                         this.owner.chatbubbleentity = NULL;
1298                 delete(this);
1299                 return;
1300         }
1301
1302         this.mdl = "";
1303
1304         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1305         {
1306                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1307                         this.mdl = "models/sprites/minigame_busy.iqm";
1308                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1309                         this.mdl = "models/misc/chatbubble.spr";
1310         }
1311
1312         if ( this.model != this.mdl )
1313                 _setmodel(this, this.mdl);
1314
1315 }
1316
1317 void UpdateChatBubble(entity this)
1318 {
1319         if (this.alpha < 0)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!this.chatbubbleentity)
1323         {
1324                 this.chatbubbleentity = new(chatbubbleentity);
1325                 this.chatbubbleentity.owner = this;
1326                 this.chatbubbleentity.exteriormodeltoclient = this;
1327                 setthink(this.chatbubbleentity, ChatBubbleThink);
1328                 this.chatbubbleentity.nextthink = time;
1329                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1330                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1331                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1332                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1333                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1334                 //this.chatbubbleentity.model = "";
1335                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1336         }
1337 }
1338
1339 void calculate_player_respawn_time(entity this)
1340 {
1341         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1342                 return;
1343
1344         float gametype_setting_tmp;
1345         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1346         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1347         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1348         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1349         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1350         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1351
1352         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1353         if (teamplay)
1354         {
1355                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1356                         if(it.team == this.team)
1357                                 ++pcount;
1358                 });
1359                 if (sdelay_small_count == 0)
1360                         sdelay_small_count = 1;
1361                 if (sdelay_large_count == 0)
1362                         sdelay_large_count = 1;
1363         }
1364         else
1365         {
1366                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1367                         ++pcount;
1368                 });
1369                 if (sdelay_small_count == 0)
1370                 {
1371                         if (IS_INDEPENDENT_PLAYER(this))
1372                         {
1373                                 // Players play independently. No point in requiring enemies.
1374                                 sdelay_small_count = 1;
1375                         }
1376                         else
1377                         {
1378                                 // Players play AGAINST each other. Enemies required.
1379                                 sdelay_small_count = 2;
1380                         }
1381                 }
1382                 if (sdelay_large_count == 0)
1383                 {
1384                         if (IS_INDEPENDENT_PLAYER(this))
1385                         {
1386                                 // Players play independently. No point in requiring enemies.
1387                                 sdelay_large_count = 1;
1388                         }
1389                         else
1390                         {
1391                                 // Players play AGAINST each other. Enemies required.
1392                                 sdelay_large_count = 2;
1393                         }
1394                 }
1395         }
1396
1397         float sdelay;
1398
1399         if (pcount <= sdelay_small_count)
1400                 sdelay = sdelay_small;
1401         else if (pcount >= sdelay_large_count)
1402                 sdelay = sdelay_large;
1403         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1404                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1405
1406         if(waves)
1407                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1408         else
1409                 this.respawn_time = time + sdelay;
1410
1411         if(sdelay < sdelay_max)
1412                 this.respawn_time_max = time + sdelay_max;
1413         else
1414                 this.respawn_time_max = this.respawn_time;
1415
1416         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1417                 this.respawn_countdown = 10; // first number to count down from is 10
1418         else
1419                 this.respawn_countdown = -1; // do not count down
1420
1421         if(autocvar_g_forced_respawn)
1422                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1423 }
1424
1425 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1426 // added to the model skins
1427 /*void UpdateColorModHack()
1428 {
1429         float c;
1430         c = this.clientcolors & 15;
1431         // LordHavoc: only bothering to support white, green, red, yellow, blue
1432              if (!teamplay) this.colormod = '0 0 0';
1433         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1434         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1435         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1436         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1437         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1438         else this.colormod = '1 1 1';
1439 }*/
1440
1441 void respawn(entity this)
1442 {
1443         bool damagedbycontents_prev = this.damagedbycontents;
1444         if(this.alpha >= 0)
1445         {
1446                 if(autocvar_g_respawn_ghosts)
1447                 {
1448                         this.solid = SOLID_NOT;
1449                         this.takedamage = DAMAGE_NO;
1450                         this.damagedbycontents = false;
1451                         set_movetype(this, MOVETYPE_FLY);
1452                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1453                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1454                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1455                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1456                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1457                         if(autocvar_g_respawn_ghosts_time > 0)
1458                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1459                 }
1460                 else
1461                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1462         }
1463
1464         CopyBody(this, 1);
1465         this.damagedbycontents = damagedbycontents_prev;
1466
1467         this.effects |= EF_NODRAW; // prevent another CopyBody
1468         PutClientInServer(this);
1469 }
1470
1471 void play_countdown(entity this, float finished, Sound samp)
1472 {
1473         TC(Sound, samp);
1474         if(IS_REAL_CLIENT(this))
1475                 if(floor(finished - time - frametime) != floor(finished - time))
1476                         if(finished - time < 6)
1477                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1478 }
1479
1480 void player_powerups_remove_all(entity this)
1481 {
1482         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1483         {
1484                 // don't play the poweroff sound when the game restarts or the player disconnects
1485                 if (time > game_starttime + 1 && IS_CLIENT(this))
1486                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1487                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1488                 this.items &= ~ITEM_Strength.m_itemid;
1489                 this.items &= ~ITEM_Shield.m_itemid;
1490                 this.items -= (this.items & IT_SUPERWEAPON);
1491         }
1492 }
1493
1494 void player_powerups(entity this)
1495 {
1496         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1497                 this.modelflags |= MF_ROCKET;
1498         else
1499                 this.modelflags &= ~MF_ROCKET;
1500
1501         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1502
1503         if (IS_DEAD(this))
1504                 player_powerups_remove_all(this);
1505
1506         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1507                 return;
1508
1509         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1510         int items_prev = this.items;
1511
1512         Fire_ApplyDamage(this);
1513         Fire_ApplyEffect(this);
1514
1515         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1516         {
1517                 if (this.items & ITEM_Strength.m_itemid)
1518                 {
1519                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1520                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1521                         if (time > STAT(STRENGTH_FINISHED, this))
1522                         {
1523                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1524                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1525                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1526                         }
1527                 }
1528                 else
1529                 {
1530                         if (time < STAT(STRENGTH_FINISHED, this))
1531                         {
1532                                 this.items = this.items | ITEM_Strength.m_itemid;
1533                                 if(!g_cts)
1534                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1535                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1536                         }
1537                 }
1538                 if (this.items & ITEM_Shield.m_itemid)
1539                 {
1540                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1541                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1542                         if (time > STAT(INVINCIBLE_FINISHED, this))
1543                         {
1544                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1545                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1547                         }
1548                 }
1549                 else
1550                 {
1551                         if (time < STAT(INVINCIBLE_FINISHED, this))
1552                         {
1553                                 this.items = this.items | ITEM_Shield.m_itemid;
1554                                 if(!g_cts)
1555                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1556                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1557                         }
1558                 }
1559                 if (this.items & IT_SUPERWEAPON)
1560                 {
1561                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1562                         {
1563                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1564                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1565                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1566                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1567                         }
1568                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1569                         {
1570                                 // don't let them run out
1571                         }
1572                         else
1573                         {
1574                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1575                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1576                                 {
1577                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1578                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1579                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1580                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1581                                 }
1582                         }
1583                 }
1584                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1585                 {
1586                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1587                         {
1588                                 this.items = this.items | IT_SUPERWEAPON;
1589                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1590                                 {
1591                                         if(!g_cts)
1592                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1593                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1594                                 }
1595                         }
1596                         else
1597                         {
1598                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1599                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1600                         }
1601                 }
1602                 else
1603                 {
1604                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1605                 }
1606         }
1607
1608         if(autocvar_g_nodepthtestplayers)
1609                 this.effects = this.effects | EF_NODEPTHTEST;
1610
1611         if(autocvar_g_fullbrightplayers)
1612                 this.effects = this.effects | EF_FULLBRIGHT;
1613
1614         if (time >= game_starttime)
1615         if (time < this.spawnshieldtime)
1616                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1617
1618         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1619 }
1620
1621 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1622 {
1623         if(current > stable)
1624                 return current;
1625         else if(current > stable - 0.25) // when close enough, "snap"
1626                 return stable;
1627         else
1628                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1629 }
1630
1631 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1632 {
1633         if(current < stable)
1634                 return current;
1635         else if(current < stable + 0.25) // when close enough, "snap"
1636                 return stable;
1637         else
1638                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1639 }
1640
1641 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1642 {
1643         float old = GetResource(this, res);
1644         float current = old;
1645         if(current > rotstable)
1646         {
1647                 if(rotframetime > 0)
1648                 {
1649                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1650                         current = max(rotstable, current - rotlinear * rotframetime);
1651                 }
1652         }
1653         else if(current < regenstable)
1654         {
1655                 if(regenframetime > 0)
1656                 {
1657                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1658                         current = min(regenstable, current + regenlinear * regenframetime);
1659                 }
1660         }
1661
1662         float limit = GetResourceLimit(this, res) * limit_mod;
1663         if(current > limit)
1664                 current = limit;
1665
1666         if (current != old)
1667                 SetResource(this, res, current);
1668 }
1669
1670 void player_regen(entity this)
1671 {
1672         float max_mod, regen_mod, rot_mod, limit_mod;
1673         max_mod = regen_mod = rot_mod = limit_mod = 1;
1674
1675         float regen_health = autocvar_g_balance_health_regen;
1676         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1677         float regen_health_rot = autocvar_g_balance_health_rot;
1678         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1679         float regen_health_stable = autocvar_g_balance_health_regenstable;
1680         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1681         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1682                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1683         max_mod = M_ARGV(1, float);
1684         regen_mod = M_ARGV(2, float);
1685         rot_mod = M_ARGV(3, float);
1686         limit_mod = M_ARGV(4, float);
1687         regen_health = M_ARGV(5, float);
1688         regen_health_linear = M_ARGV(6, float);
1689         regen_health_rot = M_ARGV(7, float);
1690         regen_health_rotlinear = M_ARGV(8, float);
1691         regen_health_stable = M_ARGV(9, float);
1692         regen_health_rotstable = M_ARGV(10, float);
1693
1694         if(!mutator_returnvalue)
1695         if(!STAT(FROZEN, this))
1696         {
1697                 float maxa = autocvar_g_balance_armor_rotstable;
1698                 float mina = autocvar_g_balance_armor_regenstable;
1699
1700                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1701                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1702                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1703
1704                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1705                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1706                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1707         }
1708
1709         // if player rotted to death...  die!
1710         // check this outside above checks, as player may still be able to rot to death
1711         if(GetResource(this, RES_HEALTH) < 1)
1712         {
1713                 if(this.vehicle)
1714                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1715                 if(this.event_damage)
1716                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1717         }
1718
1719         if (!(this.items & IT_UNLIMITED_AMMO))
1720         {
1721                 float maxf = autocvar_g_balance_fuel_rotstable;
1722                 float minf = autocvar_g_balance_fuel_regenstable;
1723
1724                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1725                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1726                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1727         }
1728 }
1729
1730 bool zoomstate_set;
1731 void SetZoomState(entity this, float newzoom)
1732 {
1733         if(newzoom != CS(this).zoomstate)
1734         {
1735                 CS(this).zoomstate = newzoom;
1736                 ClientData_Touch(this);
1737         }
1738         zoomstate_set = true;
1739 }
1740
1741 void GetPressedKeys(entity this)
1742 {
1743         MUTATOR_CALLHOOK(GetPressedKeys, this);
1744         if (game_stopped)
1745         {
1746                 CS(this).pressedkeys = 0;
1747                 STAT(PRESSED_KEYS, this) = 0;
1748                 return;
1749         }
1750
1751         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1752         int keys = STAT(PRESSED_KEYS, this);
1753         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1754         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1755         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1756         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1757
1758         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1759         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1760         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1761         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1762         CS(this).pressedkeys = keys; // store for other users
1763
1764         STAT(PRESSED_KEYS, this) = keys;
1765 }
1766
1767 /*
1768 ======================
1769 spectate mode routines
1770 ======================
1771 */
1772
1773 void SpectateCopy(entity this, entity spectatee)
1774 {
1775         TC(Client, this); TC(Client, spectatee);
1776
1777         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1778         PS(this) = PS(spectatee);
1779         this.armortype = spectatee.armortype;
1780         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1781         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1782         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1783         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1784         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1785         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1786         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1787         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1788         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1789         CS(this).impulse = 0;
1790         this.disableclientprediction = 1; // no need to run prediction on a spectator
1791         this.items = spectatee.items;
1792         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1793         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1794         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1795         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1796         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1797         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1798         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1799         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1800         this.punchangle = spectatee.punchangle;
1801         this.view_ofs = spectatee.view_ofs;
1802         this.velocity = spectatee.velocity;
1803         this.dmg_take = spectatee.dmg_take;
1804         this.dmg_save = spectatee.dmg_save;
1805         this.dmg_inflictor = spectatee.dmg_inflictor;
1806         this.v_angle = spectatee.v_angle;
1807         this.angles = spectatee.v_angle;
1808         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1809         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1810         this.viewloc = spectatee.viewloc;
1811         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1812                 this.fixangle = true;
1813         setorigin(this, spectatee.origin);
1814         setsize(this, spectatee.mins, spectatee.maxs);
1815         SetZoomState(this, CS(spectatee).zoomstate);
1816
1817     anticheat_spectatecopy(this, spectatee);
1818         STAT(HUD, this) = STAT(HUD, spectatee);
1819         if(spectatee.vehicle)
1820     {
1821         this.angles = spectatee.v_angle;
1822
1823         //this.fixangle = false;
1824         //this.velocity = spectatee.vehicle.velocity;
1825         this.vehicle_health = spectatee.vehicle_health;
1826         this.vehicle_shield = spectatee.vehicle_shield;
1827         this.vehicle_energy = spectatee.vehicle_energy;
1828         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1829         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1830         this.vehicle_reload1 = spectatee.vehicle_reload1;
1831         this.vehicle_reload2 = spectatee.vehicle_reload2;
1832
1833         //msg_entity = this;
1834
1835        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1836             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1837            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1838            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1839
1840         //WriteByte (MSG_ONE, SVC_SETVIEW);
1841         //    WriteEntity(MSG_ONE, this);
1842         //makevectors(spectatee.v_angle);
1843         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1844     }
1845 }
1846
1847 bool SpectateUpdate(entity this)
1848 {
1849         if(!this.enemy)
1850                 return false;
1851
1852         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1853         {
1854                 SetSpectatee(this, NULL);
1855                 return false;
1856         }
1857
1858         SpectateCopy(this, this.enemy);
1859
1860         return true;
1861 }
1862
1863 bool SpectateSet(entity this)
1864 {
1865         if(!IS_PLAYER(this.enemy))
1866                 return false;
1867
1868         ClientData_Touch(this.enemy);
1869
1870         msg_entity = this;
1871         WriteByte(MSG_ONE, SVC_SETVIEW);
1872         WriteEntity(MSG_ONE, this.enemy);
1873         set_movetype(this, MOVETYPE_NONE);
1874         accuracy_resend(this);
1875
1876         if(!SpectateUpdate(this))
1877                 PutObserverInServer(this);
1878
1879         return true;
1880 }
1881
1882 void SetSpectatee_status(entity this, int spectatee_num)
1883 {
1884         int oldspectatee_status = CS(this).spectatee_status;
1885         CS(this).spectatee_status = spectatee_num;
1886
1887         if (CS(this).spectatee_status != oldspectatee_status)
1888         {
1889                 if (STAT(PRESSED_KEYS, this))
1890                 {
1891                         CS(this).pressedkeys = 0;
1892                         STAT(PRESSED_KEYS, this) = 0;
1893                 }
1894                 ClientData_Touch(this);
1895                 if (g_race || g_cts) race_InitSpectator();
1896         }
1897 }
1898
1899 void SetSpectatee(entity this, entity spectatee)
1900 {
1901         if(IS_BOT_CLIENT(this))
1902                 return; // bots abuse .enemy, this code is useless to them
1903
1904         entity old_spectatee = this.enemy;
1905
1906         this.enemy = spectatee;
1907
1908         // WEAPONTODO
1909         // these are required to fix the spectator bug with arc
1910         if(old_spectatee)
1911         {
1912                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1913                 {
1914                         .entity weaponentity = weaponentities[slot];
1915                         if(old_spectatee.(weaponentity).arc_beam)
1916                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1917                 }
1918         }
1919         if(this.enemy)
1920         {
1921                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1922                 {
1923                         .entity weaponentity = weaponentities[slot];
1924                         if(this.enemy.(weaponentity).arc_beam)
1925                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1926                 }
1927         }
1928
1929         if (this.enemy)
1930                 SetSpectatee_status(this, etof(this.enemy));
1931
1932         // needed to update spectator list
1933         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1934 }
1935
1936 bool Spectate(entity this, entity pl)
1937 {
1938         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1939                 return false;
1940         pl = M_ARGV(1, entity);
1941
1942         SetSpectatee(this, pl);
1943         return SpectateSet(this);
1944 }
1945
1946 bool SpectateNext(entity this)
1947 {
1948         entity ent = find(this.enemy, classname, STR_PLAYER);
1949
1950         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1951                 ent = M_ARGV(1, entity);
1952         else if (!ent)
1953                 ent = find(ent, classname, STR_PLAYER);
1954
1955         if(ent) { SetSpectatee(this, ent); }
1956
1957         return SpectateSet(this);
1958 }
1959
1960 bool SpectatePrev(entity this)
1961 {
1962         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1963         entity ent = findchain(classname, STR_PLAYER);
1964         if (!ent) // no player
1965                 return false;
1966
1967         entity first = ent;
1968         // skip players until current spectated player
1969         if(this.enemy)
1970         while(ent && ent != this.enemy)
1971                 ent = ent.chain;
1972
1973         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1974         {
1975                 case MUT_SPECPREV_FOUND:
1976                         ent = M_ARGV(1, entity);
1977                         break;
1978                 case MUT_SPECPREV_RETURN:
1979                         return true;
1980                 case MUT_SPECPREV_CONTINUE:
1981                 default:
1982                 {
1983                         if(ent.chain)
1984                                 ent = ent.chain;
1985                         else
1986                                 ent = first;
1987                         break;
1988                 }
1989         }
1990
1991         SetSpectatee(this, ent);
1992         return SpectateSet(this);
1993 }
1994
1995 /*
1996 =============
1997 ShowRespawnCountdown()
1998
1999 Update a respawn countdown display.
2000 =============
2001 */
2002 void ShowRespawnCountdown(entity this)
2003 {
2004         float number;
2005         if(!IS_DEAD(this)) // just respawned?
2006                 return;
2007         else
2008         {
2009                 number = ceil(this.respawn_time - time);
2010                 if(number <= 0)
2011                         return;
2012                 if(number <= this.respawn_countdown)
2013                 {
2014                         this.respawn_countdown = number - 1;
2015                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2016                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2017                 }
2018         }
2019 }
2020
2021 .bool team_selected;
2022 bool ShowTeamSelection(entity this)
2023 {
2024         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2025                 return false;
2026         stuffcmd(this, "menu_showteamselect\n");
2027         return true;
2028 }
2029 void Join(entity this)
2030 {
2031         TRANSMUTE(Player, this);
2032
2033         if(!this.team_selected)
2034         if(autocvar_g_campaign || autocvar_g_balance_teams)
2035                 TeamBalance_JoinBestTeam(this);
2036
2037         if(autocvar_g_campaign)
2038                 campaign_bots_may_start = true;
2039
2040         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2041
2042         PutClientInServer(this);
2043
2044         if(IS_PLAYER(this))
2045         if(teamplay && this.team != -1)
2046         {
2047         }
2048         else
2049                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2050         this.team_selected = false;
2051
2052         // z411
2053         // send constant ready notification
2054         if(warmup_stage)
2055                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2056 }
2057
2058 int GetPlayerLimit()
2059 {
2060         if(g_duel)
2061                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2062         int player_limit = autocvar_g_maxplayers;
2063         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2064         player_limit = M_ARGV(0, int);
2065         return player_limit;
2066 }
2067
2068 /**
2069  * Determines whether the player is allowed to join. This depends on cvar
2070  * g_maxplayers, if it isn't used this function always return true, otherwise
2071  * it checks whether the number of currently playing players exceeds g_maxplayers.
2072  * @return int number of free slots for players, 0 if none
2073  */
2074 int nJoinAllowed(entity this, entity ignore)
2075 {
2076         if(!ignore)
2077         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2078         // so report 0 free slots if restricted
2079         {
2080                 if(autocvar_g_forced_team_otherwise == "spectate")
2081                         return 0;
2082                 if(autocvar_g_forced_team_otherwise == "spectator")
2083                         return 0;
2084         }
2085
2086         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2087                 return 0; // forced spectators can never join
2088
2089         // TODO simplify this
2090         int totalClients = 0;
2091         int currentlyPlaying = 0;
2092         FOREACH_CLIENT(true, {
2093                 if(it != ignore)
2094                         ++totalClients;
2095                 if(IS_REAL_CLIENT(it))
2096                 if(IS_PLAYER(it) || it.caplayer)
2097                         ++currentlyPlaying;
2098         });
2099
2100         int player_limit = GetPlayerLimit();
2101
2102         int free_slots = 0;
2103         if (!player_limit)
2104                 free_slots = maxclients - totalClients;
2105         else if(player_limit > 0 && currentlyPlaying < player_limit)
2106                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2107
2108         static float msg_time = 0;
2109         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2110         {
2111                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2112                 msg_time = time + 0.5;
2113         }
2114
2115         return free_slots;
2116 }
2117
2118 /**
2119  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2120  * g_maxplayers_spectator_blocktime seconds
2121  */
2122 void checkSpectatorBlock(entity this)
2123 {
2124         if(IS_SPEC(this) || IS_OBSERVER(this))
2125         if(!this.caplayer)
2126         if(IS_REAL_CLIENT(this))
2127         {
2128                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2129                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2130                         dropclient(this);
2131                 }
2132         }
2133 }
2134
2135 void PrintWelcomeMessage(entity this)
2136 {
2137         if(CS(this).motd_actived_time == 0)
2138         {
2139                 if (autocvar_g_campaign) {
2140                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2141                                 CS(this).motd_actived_time = time;
2142                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2143                         }
2144                 } else {
2145                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2146                                 CS(this).motd_actived_time = time;
2147                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2148                         }
2149                 }
2150         }
2151         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2152         {
2153                 if (autocvar_g_campaign) {
2154                         if (PHYS_INPUT_BUTTON_INFO(this))
2155                                 CS(this).motd_actived_time = time;
2156                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2157                                 CS(this).motd_actived_time = 0;
2158                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2159                         }
2160                 } else {
2161                         if (PHYS_INPUT_BUTTON_INFO(this))
2162                                 CS(this).motd_actived_time = time;
2163                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2164                                 CS(this).motd_actived_time = 0;
2165                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2166                         }
2167                 }
2168         }
2169         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2170         {
2171                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2172                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2173                 else if (CS(this).motd_actived_time == -2)
2174                 {
2175                         // instantly hide MOTD
2176                         CS(this).motd_actived_time = 0;
2177                         if (autocvar_g_campaign)
2178                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2179                         else
2180                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2181                 }
2182                 else if (IS_PLAYER(this) || IS_SPEC(this))
2183                 {
2184                         // FIXME occasionally for some reason MOTD never goes away
2185                         // delay MOTD removal a little bit in the hope it fixes this bug
2186                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2187                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2188                         else //if (CS(this).motd_actived_time < -2)
2189                                 CS(this).motd_actived_time++;
2190                 }
2191         }
2192 }
2193
2194 bool joinAllowed(entity this)
2195 {
2196         if (CS(this).version_mismatch) return false;
2197         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2198         if (!nJoinAllowed(this, this)) return false;
2199         if (teamplay && lockteams) return false;
2200         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2201         if (ShowTeamSelection(this)) return false;
2202         return true;
2203 }
2204
2205 .string shootfromfixedorigin;
2206 .bool dualwielding_prev;
2207 bool PlayerThink(entity this)
2208 {
2209         if (game_stopped || intermission_running) {
2210                 this.modelflags &= ~MF_ROCKET;
2211                 if(intermission_running)
2212                         IntermissionThink(this);
2213                 return false;
2214         }
2215
2216         if (game_timeout) {
2217         // don't allow the player to turn around while game is paused
2218                 // FIXME turn this into CSQC stuff
2219                 this.v_angle = this.lastV_angle;
2220                 this.angles = this.lastV_angle;
2221                 this.fixangle = true;
2222                 return false;
2223         }
2224
2225         if (frametime) player_powerups(this);
2226
2227         if (IS_DEAD(this)) {
2228                 if (this.personal && g_race_qualifying) {
2229                         if (time > this.respawn_time) {
2230                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2231                                 respawn(this);
2232                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2233                         }
2234                 } else {
2235                         if (frametime) player_anim(this);
2236
2237                         if (this.respawn_flags & RESPAWN_DENY)
2238                         {
2239                                 STAT(RESPAWN_TIME, this) = 0;
2240                                 return false;
2241                         }
2242
2243                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2244
2245                         switch(this.deadflag)
2246                         {
2247                                 case DEAD_DYING:
2248                                 {
2249                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2250                                                 this.deadflag = DEAD_RESPAWNING;
2251                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2252                                                 this.deadflag = DEAD_DEAD;
2253                                         break;
2254                                 }
2255                                 case DEAD_DEAD:
2256                                 {
2257                                         if (button_pressed)
2258                                                 this.deadflag = DEAD_RESPAWNABLE;
2259                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2260                                                 this.deadflag = DEAD_RESPAWNING;
2261                                         break;
2262                                 }
2263                                 case DEAD_RESPAWNABLE:
2264                                 {
2265                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2266                                                 this.deadflag = DEAD_RESPAWNING;
2267                                         break;
2268                                 }
2269                                 case DEAD_RESPAWNING:
2270                                 {
2271                                         if (time > this.respawn_time)
2272                                         {
2273                                                 this.respawn_time = time + 1; // only retry once a second
2274                                                 this.respawn_time_max = this.respawn_time;
2275                                                 respawn(this);
2276                                         }
2277                                         break;
2278                                 }
2279                         }
2280
2281                         ShowRespawnCountdown(this);
2282
2283                         if (this.respawn_flags & RESPAWN_SILENT)
2284                                 STAT(RESPAWN_TIME, this) = 0;
2285                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2286                         {
2287                                 if (time < this.respawn_time)
2288                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2289                                 else if (this.deadflag != DEAD_RESPAWNING)
2290                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2291                         }
2292                         else
2293                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2294                 }
2295
2296                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2297                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2298                         STAT(RESPAWN_TIME, this) *= -1;
2299
2300                 return false;
2301         }
2302
2303         FixPlayermodel(this);
2304
2305         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2306                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2307                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2308         }
2309
2310         // reset gun alignment when dual wielding status changes
2311         // to ensure guns are always aligned right and left
2312         bool dualwielding = W_DualWielding(this);
2313         if(this.dualwielding_prev != dualwielding)
2314         {
2315                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2316                 this.dualwielding_prev = dualwielding;
2317         }
2318
2319         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2320         //if(frametime)
2321         {
2322                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2323                 {
2324                         .entity weaponentity = weaponentities[slot];
2325                         if(WEP_CVAR(vortex, charge_always))
2326                                 W_Vortex_Charge(this, weaponentity, frametime);
2327                         W_WeaponFrame(this, weaponentity);
2328                 }
2329         }
2330
2331         if (frametime)
2332         {
2333                 // WEAPONTODO: Add a weapon request for this
2334                 // rot vortex charge to the charge limit
2335                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2336                 {
2337                         .entity weaponentity = weaponentities[slot];
2338                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2339                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2340                 }
2341
2342                 player_regen(this);
2343                 player_anim(this);
2344                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2345         }
2346
2347         monsters_setstatus(this);
2348
2349         return true;
2350 }
2351
2352 .bool would_spectate;
2353 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2354 void ObserverOrSpectatorThink(entity this)
2355 {
2356         bool is_spec = IS_SPEC(this);
2357         if ( CS(this).impulse )
2358         {
2359                 int r = MinigameImpulse(this, CS(this).impulse);
2360                 if (!is_spec || r)
2361                         CS(this).impulse = 0;
2362
2363                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2364                 {
2365                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2366                         CS(this).impulse = 0;
2367                         return;
2368                 }
2369         }
2370
2371         if (this.flags & FL_JUMPRELEASED) {
2372                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2373                         this.flags &= ~FL_JUMPRELEASED;
2374                         this.flags |= FL_SPAWNING;
2375                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2376                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2377                         this.flags &= ~FL_JUMPRELEASED;
2378                         if(SpectateNext(this)) {
2379                                 TRANSMUTE(Spectator, this);
2380                         } else if (is_spec) {
2381                                 TRANSMUTE(Observer, this);
2382                                 PutClientInServer(this);
2383                         }
2384                         else
2385                                 this.would_spectate = false; // unable to spectate anyone
2386                         if (is_spec)
2387                                 CS(this).impulse = 0;
2388                 } else if (is_spec) {
2389                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2390                                 this.flags &= ~FL_JUMPRELEASED;
2391                                 if(SpectatePrev(this)) {
2392                                         TRANSMUTE(Spectator, this);
2393                                 } else {
2394                                         TRANSMUTE(Observer, this);
2395                                         PutClientInServer(this);
2396                                 }
2397                                 CS(this).impulse = 0;
2398                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2399                                 this.would_spectate = false;
2400                                 this.flags &= ~FL_JUMPRELEASED;
2401                                 TRANSMUTE(Observer, this);
2402                                 PutClientInServer(this);
2403                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2404                                 PutObserverInServer(this);
2405                                 this.would_spectate = true;
2406                         }
2407                 }
2408                 else {
2409                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2410                         if (PHYS_INPUT_BUTTON_USE(this))
2411                                 wouldclip = !wouldclip;
2412                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2413                         set_movetype(this, preferred_movetype);
2414                 }
2415         } else { // jump pressed
2416                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2417                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2418                         this.flags |= FL_JUMPRELEASED;
2419                         if(this.flags & FL_SPAWNING)
2420                         {
2421                                 this.flags &= ~FL_SPAWNING;
2422                                 if(joinAllowed(this))
2423                                         Join(this);
2424                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2425                                         CS(this).autojoin_checked = -1;
2426                                 return;
2427                         }
2428                 }
2429                 if(is_spec && !SpectateUpdate(this))
2430                         PutObserverInServer(this);
2431         }
2432         if (is_spec)
2433                 this.flags |= FL_CLIENT | FL_NOTARGET;
2434 }
2435
2436 void PlayerUseKey(entity this)
2437 {
2438         if (!IS_PLAYER(this))
2439                 return;
2440
2441         if(this.vehicle)
2442         {
2443                 if(!game_stopped)
2444                 {
2445                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2446                         return;
2447                 }
2448         }
2449         else if(autocvar_g_vehicles_enter)
2450         {
2451                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2452                 {
2453                         entity head, closest_target = NULL;
2454                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2455
2456                         while(head) // find the closest acceptable target to enter
2457                         {
2458                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2459                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2460                                 {
2461                                         if(closest_target)
2462                                         {
2463                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2464                                                 { closest_target = head; }
2465                                         }
2466                                         else { closest_target = head; }
2467                                 }
2468
2469                                 head = head.chain;
2470                         }
2471
2472                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2473                 }
2474         }
2475
2476         // a use key was pressed; call handlers
2477         MUTATOR_CALLHOOK(PlayerUseKey, this);
2478 }
2479
2480
2481 /*
2482 =============
2483 PlayerPreThink
2484
2485 Called every frame for each client before the physics are run
2486 =============
2487 */
2488 .float last_vehiclecheck;
2489 void PlayerPreThink (entity this)
2490 {
2491         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2492         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2493
2494         WarpZone_PlayerPhysics_FixVAngle(this);
2495
2496         if (frametime) {
2497                 // physics frames: update anticheat stuff
2498                 anticheat_prethink(this);
2499         }
2500
2501         if (blockSpectators && frametime) {
2502                 // WORKAROUND: only use dropclient in server frames (frametime set).
2503                 // Never use it in cl_movement frames (frametime zero).
2504                 checkSpectatorBlock(this);
2505         }
2506
2507         zoomstate_set = false;
2508
2509         // Check for nameless players
2510         if (this.netname == "" || this.netname != CS(this).netname_previous)
2511         {
2512                 bool assume_unchanged = (CS(this).netname_previous == "");
2513                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2514                 {
2515                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2516                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2517                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2518                         assume_unchanged = false;
2519                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2520                 }
2521                 if (isInvisibleString(this.netname))
2522                 {
2523                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2524                         sprint(this, "Warning: invisible names are not allowed.\n");
2525                         assume_unchanged = false;
2526                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2527                 }
2528                 if (!assume_unchanged && autocvar_sv_eventlog)
2529                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2530                 strcpy(CS(this).netname_previous, this.netname);
2531         }
2532
2533         // version nagging
2534         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2535         CS(this).version_nagtime = 0;
2536         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2537             // git client
2538         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2539             // git server
2540             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2541         } else {
2542             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2543             if (r < 0) { // old client
2544                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2545             } else if (r > 0) { // old server
2546                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2547             }
2548         }
2549     }
2550
2551         // GOD MODE info
2552         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2553         {
2554                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2555                 this.max_armorvalue = 0;
2556         }
2557
2558         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2559         {
2560                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2561                 {
2562                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2563                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2564                         if (this.iceblock)
2565                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2566
2567                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2568                                 Unfreeze(this, false);
2569                 }
2570                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2571                 {
2572                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2573                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2574
2575                         if (GetResource(this, RES_HEALTH) < 1)
2576                         {
2577                                 if (this.vehicle)
2578                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2579                                 if(this.event_damage)
2580                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2581                         }
2582                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2583                                 Unfreeze(this, false);
2584                 }
2585         }
2586
2587         MUTATOR_CALLHOOK(PlayerPreThink, this);
2588
2589         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2590         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2591         {
2592                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2593                 {
2594                         if(!it.owner)
2595                         {
2596                                 if(!it.team || SAME_TEAM(this, it))
2597                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2598                                 else if(autocvar_g_vehicles_steal)
2599                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2600                         }
2601                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2602                         {
2603                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2604                         }
2605                 });
2606
2607                 this.last_vehiclecheck = time + 1;
2608         }
2609
2610         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2611         {
2612                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2613                         PlayerUseKey(this);
2614                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2615         }
2616
2617         if (IS_REAL_CLIENT(this))
2618                 PrintWelcomeMessage(this);
2619
2620         if (IS_PLAYER(this)) {
2621                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2622                         error("Client can't be spawned as player on connection!");
2623                 if(!PlayerThink(this))
2624                         return;
2625         }
2626         else if (game_stopped || intermission_running) {
2627                 if(intermission_running)
2628                         IntermissionThink(this);
2629                 return;
2630         }
2631         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2632         {
2633                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2634                 CS(this).autojoin_checked = 1;
2635                 // don't do this in ClientConnect
2636                 // many things can go wrong if a client is spawned as player on connection
2637                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2638                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2639                                 && (!teamplay || autocvar_g_balance_teams)))
2640                 {
2641                         campaign_bots_may_start = true;
2642                         if(joinAllowed(this))
2643                                 Join(this);
2644                         return;
2645                 }
2646         }
2647         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2648                 ObserverOrSpectatorThink(this);
2649         }
2650
2651         // WEAPONTODO: Add weapon request for this
2652         if (!zoomstate_set) {
2653                 bool wep_zoomed = false;
2654                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2655                 {
2656                         .entity weaponentity = weaponentities[slot];
2657                         Weapon thiswep = this.(weaponentity).m_weapon;
2658                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2659                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2660                 }
2661                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2662         }
2663
2664         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2665         {
2666                 CS(this).teamkill_soundtime = 0;
2667
2668                 entity e = CS(this).teamkill_soundsource;
2669                 entity oldpusher = e.pusher;
2670                 e.pusher = this;
2671                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2672                 e.pusher = oldpusher;
2673         }
2674
2675         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2676                 CS(this).taunt_soundtime = 0;
2677                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2678         }
2679
2680         target_voicescript_next(this);
2681 }
2682
2683 void DrownPlayer(entity this)
2684 {
2685         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2686                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2687         {
2688                 STAT(AIR_FINISHED, this) = 0;
2689                 return;
2690         }
2691
2692         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2693         {
2694                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2695                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2696                 STAT(AIR_FINISHED, this) = 0;
2697         }
2698         else
2699         {
2700                 if (!STAT(AIR_FINISHED, this))
2701                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2702                 if (STAT(AIR_FINISHED, this) < time)
2703                 {       // drown!
2704                         if (this.pain_finished < time)
2705                         {
2706                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2707                                 this.pain_finished = time + 0.5;
2708                         }
2709                 }
2710         }
2711 }
2712
2713 .bool move_qcphysics;
2714
2715 void Player_Physics(entity this)
2716 {
2717         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2718
2719         if(!this.move_qcphysics)
2720                 return;
2721
2722         if(!frametime && !CS(this).pm_frametime)
2723                 return;
2724
2725         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2726
2727         CS(this).pm_frametime = 0;
2728 }
2729
2730 /*
2731 =============
2732 PlayerPostThink
2733
2734 Called every frame for each client after the physics are run
2735 =============
2736 */
2737 void PlayerPostThink (entity this)
2738 {
2739         Player_Physics(this);
2740
2741         if (autocvar_sv_maxidle > 0)
2742         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2743         if (IS_REAL_CLIENT(this))
2744         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2745         {
2746                 int totalClients = 0;
2747                 if(autocvar_sv_maxidle_slots > 0)
2748                 {
2749                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2750                         {
2751                                 ++totalClients;
2752                         });
2753                 }
2754
2755                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2756                 { /* do nothing */ }
2757                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2758                 {
2759                         if (CS(this).idlekick_lasttimeleft)
2760                         {
2761                                 CS(this).idlekick_lasttimeleft = 0;
2762                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2763                         }
2764                 }
2765                 else
2766                 {
2767                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2768                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2769                                 if (!CS(this).idlekick_lasttimeleft)
2770                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2771                         }
2772                         if (timeleft <= 0) {
2773                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2774                                 dropclient(this);
2775                                 return;
2776                         }
2777                         else if (timeleft <= 10) {
2778                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2779                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2780                                 CS(this).idlekick_lasttimeleft = timeleft;
2781                         }
2782                 }
2783         }
2784
2785         CheatFrame(this);
2786
2787         if (game_stopped)
2788         {
2789                 this.solid = SOLID_NOT;
2790                 this.takedamage = DAMAGE_NO;
2791                 set_movetype(this, MOVETYPE_NONE);
2792                 CS(this).teamkill_complain = 0;
2793                 CS(this).teamkill_soundtime = 0;
2794                 CS(this).teamkill_soundsource = NULL;
2795         }
2796
2797         if (IS_PLAYER(this)) {
2798                 if(this.death_time == time && IS_DEAD(this))
2799                 {
2800                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2801                         // once all the damage events of this frame have been processed with normal size
2802                         this.maxs.z = 5;
2803                         setsize(this, this.mins, this.maxs);
2804                 }
2805                 DrownPlayer(this);
2806                 UpdateChatBubble(this);
2807                 if (CS(this).impulse) ImpulseCommands(this);
2808                 GetPressedKeys(this);
2809                 if (game_stopped)
2810                 {
2811                         CSQCMODEL_AUTOUPDATE(this);
2812                         return;
2813                 }
2814         }
2815         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2816         {
2817                 CS(this).pressedkeys = 0;
2818                 STAT(PRESSED_KEYS, this) = 0;
2819         }
2820
2821         if (this.waypointsprite_attachedforcarrier) {
2822                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2823                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2824         }
2825
2826         CSQCMODEL_AUTOUPDATE(this);
2827 }
2828
2829 // hack to copy the button fields from the client entity to the Client State
2830 void PM_UpdateButtons(entity this, entity store)
2831 {
2832         if(this.impulse)
2833                 store.impulse = this.impulse;
2834         this.impulse = 0;
2835
2836         bool typing = this.buttonchat || this.button12;
2837
2838         store.button0 = (typing) ? 0 : this.button0;
2839         //button1?!
2840         store.button2 = (typing) ? 0 : this.button2;
2841         store.button3 = (typing) ? 0 : this.button3;
2842         store.button4 = this.button4;
2843         store.button5 = (typing) ? 0 : this.button5;
2844         store.button6 = this.button6;
2845         store.button7 = this.button7;
2846         store.button8 = this.button8;
2847         store.button9 = this.button9;
2848         store.button10 = this.button10;
2849         store.button11 = this.button11;
2850         store.button12 = this.button12;
2851         store.button13 = this.button13;
2852         store.button14 = this.button14;
2853         store.button15 = this.button15;
2854         store.button16 = this.button16;
2855         store.buttonuse = this.buttonuse;
2856         store.buttonchat = this.buttonchat;
2857
2858         store.cursor_active = this.cursor_active;
2859         store.cursor_screen = this.cursor_screen;
2860         store.cursor_trace_start = this.cursor_trace_start;
2861         store.cursor_trace_endpos = this.cursor_trace_endpos;
2862         store.cursor_trace_ent = this.cursor_trace_ent;
2863
2864         store.ping = this.ping;
2865         store.ping_packetloss = this.ping_packetloss;
2866         store.ping_movementloss = this.ping_movementloss;
2867
2868         store.v_angle = this.v_angle;
2869         store.movement = this.movement;
2870 }
2871
2872 NET_HANDLE(fpsreport, bool)
2873 {
2874         int fps = ReadShort();
2875         PlayerScore_Set(sender, SP_FPS, fps);
2876         return true;
2877 }