qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/func/conveyor.qh"
  31 #include "../common/triggers/teleporters.qh"
  32
  33 #include "../common/vehicles/all.qh"
  34
  35 #include "weapons/hitplot.qh"
  36 #include "weapons/weaponsystem.qh"
  37
  38 #include "../common/net_notice.qh"
  39 #include "../common/physics/player.qh"
  40
  41 #include "../common/items/_mod.qh"
  42
  43 #include "../common/mutators/mutator/waypoints/all.qh"
  44
  45 #include "../common/triggers/subs.qh"
  46 #include "../common/triggers/triggers.qh"
  47 #include "../common/triggers/trigger/secret.qh"
  48
  49 #include "../common/minigames/sv_minigames.qh"
  50
  51 #include "../common/items/inventory.qh"
  52
  53 #include "../common/monsters/sv_monsters.qh"
  54
  55 #include "../lib/warpzone/server.qh"
  56
  57 STATIC_METHOD(Client, Add, void(Client this, int _team))
  58 {
  59     ClientConnect(this);
  60     TRANSMUTE(Player, this);
  61     this.frame = 12; // 7
  62     this.team = _team;
  63     PutClientInServer(this);
  64 }
  65
  66 void PutObserverInServer(entity this);
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     PutClientInServer(this);
  72     ClientDisconnect(this);
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 int CountSpectators(entity player, entity to)
  80 {
  81         if(!player) { return 0; } // not sure how, but best to be safe
  82
  83         int spec_count = 0;
  84
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  86         {
  87                 spec_count++;
  88         });
  89
  90         return spec_count;
  91 }
  92
  93 void WriteSpectators(entity player, entity to)
  94 {
  95         if(!player) { return; } // not sure how, but best to be safe
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 WriteByte(MSG_ENTITY, num_for_edict(it));
 100         });
 101 }
 102
 103 bool ClientData_Send(entity this, entity to, int sf)
 104 {
 105         assert(to == this.owner, return false);
 106
 107         entity e = to;
 108         if (IS_SPEC(e)) e = e.enemy;
 109
 110         sf = 0;
 111         if (e.race_completed)       sf |= 1; // forced scoreboard
 112         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 113         if (e.zoomstate)            sf |= 4; // zoomed
 114         if (e.porto_v_angle_held)   sf |= 8; // angles held
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124         if (sf & 8)
 125         {
 126                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 127                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 128         }
 129
 130         if(sf & 16)
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         this.clientdata.drawonlytoclient = this;
 144         this.clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(this.clientdata);
 150         this.clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         e.clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 159 }
 160
 161 .string netname_previous;
 162
 163 void SetSpectatee(entity this, entity spectatee);
 164 void SetSpectatee_status(entity this, int spectatee_num);
 165
 166
 167 /*
 168 =============
 169 CheckPlayerModel
 170
 171 Checks if the argument string can be a valid playermodel.
 172 Returns a valid one in doubt.
 173 =============
 174 */
 175 string FallbackPlayerModel;
 176 string CheckPlayerModel(string plyermodel) {
 177         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 178         {
 179                 // note: we cannot summon Don Strunzone here, some player may
 180                 // still have the model string set. In case anyone manages how
 181                 // to change a cvar default, we'll have a small leak here.
 182                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 183         }
 184         // only in right path
 185         if( substring(plyermodel,0,14) != "models/player/")
 186                 return FallbackPlayerModel;
 187         // only good file extensions
 188         if(substring(plyermodel,-4,4) != ".zym")
 189         if(substring(plyermodel,-4,4) != ".dpm")
 190         if(substring(plyermodel,-4,4) != ".iqm")
 191         if(substring(plyermodel,-4,4) != ".md3")
 192         if(substring(plyermodel,-4,4) != ".psk")
 193                 return FallbackPlayerModel;
 194         // forbid the LOD models
 195         if(substring(plyermodel, -9,5) == "_lod1")
 196                 return FallbackPlayerModel;
 197         if(substring(plyermodel, -9,5) == "_lod2")
 198                 return FallbackPlayerModel;
 199         if(plyermodel != strtolower(plyermodel))
 200                 return FallbackPlayerModel;
 201         // also, restrict to server models
 202         if(autocvar_sv_servermodelsonly)
 203         {
 204                 if(!fexists(plyermodel))
 205                         return FallbackPlayerModel;
 206         }
 207         return plyermodel;
 208 }
 209
 210 void setplayermodel(entity e, string modelname)
 211 {
 212         precache_model(modelname);
 213         _setmodel(e, modelname);
 214         player_setupanimsformodel(e);
 215         if(!autocvar_g_debug_globalsounds)
 216                 UpdatePlayerSounds(e);
 217 }
 218
 219 void FixPlayermodel(entity player);
 220 /** putting a client as observer in the server */
 221 void PutObserverInServer(entity this)
 222 {
 223     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 224         PlayerState_detach(this);
 225
 226         if (IS_PLAYER(this) && this.health >= 1) {
 227         // despawn effect
 228                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229     }
 230
 231     {
 232         entity spot = SelectSpawnPoint(this, true);
 233         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 234         this.angles = spot.angles;
 235         this.angles_z = 0;
 236         this.fixangle = true;
 237         // offset it so that the spectator spawns higher off the ground, looks better this way
 238         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 239         this.prevorigin = this.origin;
 240         if (IS_REAL_CLIENT(this))
 241         {
 242             msg_entity = this;
 243             WriteByte(MSG_ONE, SVC_SETVIEW);
 244             WriteEntity(MSG_ONE, this);
 245         }
 246         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 247         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 248         if(!autocvar_g_debug_globalsounds)
 249         {
 250                 // needed for player sounds
 251                 this.model = "";
 252                 FixPlayermodel(this);
 253         }
 254         setmodel(this, MDL_Null);
 255         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 256         this.view_ofs = '0 0 0';
 257     }
 258
 259     RemoveGrapplingHook(this);
 260         Portal_ClearAll(this);
 261         Unfreeze(this);
 262         SetSpectatee(this, NULL);
 263
 264         if (this.alivetime)
 265         {
 266                 if (!warmup_stage)
 267                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 268                 this.alivetime = 0;
 269         }
 270
 271         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 272
 273         WaypointSprite_PlayerDead(this);
 274
 275         if (mutator_returnvalue) {
 276             // mutator prevents resetting teams+score
 277         } else {
 278                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 279         this.frags = FRAGS_SPECTATOR;
 280         PlayerScore_Clear(this);  // clear scores when needed
 281     }
 282
 283         if (this.killcount != FRAGS_SPECTATOR)
 284         {
 285                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 286                 if(!intermission_running)
 287                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 288                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 289
 290                 if(this.just_joined == false) {
 291                         LogTeamchange(this.playerid, -1, 4);
 292                 } else
 293                         this.just_joined = false;
 294         }
 295
 296         accuracy_resend(this);
 297
 298         this.spectatortime = time;
 299         if(this.bot_attack)
 300                 IL_REMOVE(g_bot_targets, this);
 301         this.bot_attack = false;
 302     this.hud = HUD_NORMAL;
 303         TRANSMUTE(Observer, this);
 304         this.iscreature = false;
 305         this.teleportable = TELEPORT_SIMPLE;
 306         this.damagedbycontents = false;
 307         this.health = FRAGS_SPECTATOR;
 308         SetSpectatee_status(this, etof(this));
 309         this.takedamage = DAMAGE_NO;
 310         this.solid = SOLID_NOT;
 311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 312         this.flags = FL_CLIENT | FL_NOTARGET;
 313         this.armorvalue = 666;
 314         this.effects = 0;
 315         this.armorvalue = autocvar_g_balance_armor_start;
 316         this.pauserotarmor_finished = 0;
 317         this.pauserothealth_finished = 0;
 318         this.pauseregen_finished = 0;
 319         this.damageforcescale = 0;
 320         this.death_time = 0;
 321         this.respawn_flags = 0;
 322         this.respawn_time = 0;
 323         this.stat_respawn_time = 0;
 324         this.alpha = 0;
 325         this.scale = 0;
 326         this.fade_time = 0;
 327         this.pain_frame = 0;
 328         this.pain_finished = 0;
 329         this.strength_finished = 0;
 330         this.invincible_finished = 0;
 331         this.superweapons_finished = 0;
 332         this.pushltime = 0;
 333         this.istypefrag = 0;
 334         setthink(this, func_null);
 335         this.nextthink = 0;
 336         this.hook_time = 0;
 337         this.deadflag = DEAD_NO;
 338         this.crouch = false;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.drawonlytoclient = this;
 344
 345         this.weaponname = "";
 346         this.weaponmodel = "";
 347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 348         {
 349                 this.weaponentities[slot] = NULL;
 350         }
 351         this.exteriorweaponentity = NULL;
 352         this.killcount = FRAGS_SPECTATOR;
 353         this.velocity = '0 0 0';
 354         this.avelocity = '0 0 0';
 355         this.punchangle = '0 0 0';
 356         this.punchvector = '0 0 0';
 357         this.oldvelocity = this.velocity;
 358         this.fire_endtime = -1;
 359         this.event_damage = func_null;
 360
 361         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 362         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 363         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 364 }
 365
 366 int player_getspecies(entity this)
 367 {
 368         get_model_parameters(this.model, this.skin);
 369         int s = get_model_parameters_species;
 370         get_model_parameters(string_null, 0);
 371         if (s < 0) return SPECIES_HUMAN;
 372         return s;
 373 }
 374
 375 .float model_randomizer;
 376 void FixPlayermodel(entity player)
 377 {
 378         string defaultmodel = "";
 379         int defaultskin = 0;
 380         if(autocvar_sv_defaultcharacter)
 381         {
 382                 if(teamplay)
 383                 {
 384                         string s = Static_Team_ColorName_Lower(player.team);
 385                         if (s != "neutral")
 386                         {
 387                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 388                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * player.model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         string s = Static_Team_ColorName_Lower(player.team);
 420                         if (s != "neutral")
 421                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 422                 }
 423
 424                 if(!defaultskin)
 425                         defaultskin = autocvar_sv_defaultplayerskin;
 426         }
 427
 428         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 429         defaultmodel = M_ARGV(0, string);
 430         defaultskin = M_ARGV(1, int);
 431
 432         bool chmdl = false;
 433         int oldskin;
 434         if(defaultmodel != "")
 435         {
 436                 if (defaultmodel != player.model)
 437                 {
 438                         vector m1 = player.mins;
 439                         vector m2 = player.maxs;
 440                         setplayermodel (player, defaultmodel);
 441                         setsize (player, m1, m2);
 442                         chmdl = true;
 443                 }
 444
 445                 oldskin = player.skin;
 446                 player.skin = defaultskin;
 447         } else {
 448                 if (player.playermodel != player.model || player.playermodel == "")
 449                 {
 450                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 451                         vector m1 = player.mins;
 452                         vector m2 = player.maxs;
 453                         setplayermodel (player, player.playermodel);
 454                         setsize (player, m1, m2);
 455                         chmdl = true;
 456                 }
 457
 458                 if(!autocvar_sv_defaultcharacterskin)
 459                 {
 460                         oldskin = player.skin;
 461                         player.skin = stof(player.playerskin);
 462                 }
 463                 else
 464                 {
 465                         oldskin = player.skin;
 466                         player.skin = defaultskin;
 467                 }
 468         }
 469
 470         if(chmdl || oldskin != player.skin) // model or skin has changed
 471         {
 472                 player.species = player_getspecies(player); // update species
 473                 if(!autocvar_g_debug_globalsounds)
 474                         UpdatePlayerSounds(player); // update skin sounds
 475         }
 476
 477         if(!teamplay)
 478                 if(strlen(autocvar_sv_defaultplayercolors))
 479                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 480                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 481 }
 482
 483
 484 /** Called when a client spawns in the server */
 485 void PutClientInServer(entity this)
 486 {
 487         if (IS_BOT_CLIENT(this)) {
 488                 TRANSMUTE(Player, this);
 489         } else if (IS_REAL_CLIENT(this)) {
 490                 msg_entity = this;
 491                 WriteByte(MSG_ONE, SVC_SETVIEW);
 492                 WriteEntity(MSG_ONE, this);
 493         }
 494         if (gameover) {
 495                 TRANSMUTE(Observer, this);
 496         }
 497
 498         SetSpectatee(this, NULL);
 499
 500         // reset player keys
 501         this.itemkeys = 0;
 502
 503         MUTATOR_CALLHOOK(PutClientInServer, this);
 504
 505         if (IS_OBSERVER(this)) {
 506                 PutObserverInServer(this);
 507         } else if (IS_PLAYER(this)) {
 508                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 509
 510                 PlayerState_attach(this);
 511                 accuracy_resend(this);
 512
 513                 if (this.team < 0)
 514                         JoinBestTeam(this, false, true);
 515
 516                 entity spot = SelectSpawnPoint(this, false);
 517                 if (!spot) {
 518                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 519                         return; // spawn failed
 520                 }
 521
 522                 TRANSMUTE(Player, this);
 523
 524                 this.wasplayer = true;
 525                 this.iscreature = true;
 526                 this.teleportable = TELEPORT_NORMAL;
 527                 this.damagedbycontents = true;
 528                 set_movetype(this, MOVETYPE_WALK);
 529                 this.solid = SOLID_SLIDEBOX;
 530                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 531                 if (autocvar_g_playerclip_collisions)
 532                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 533                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 534                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 535                 this.frags = FRAGS_PLAYER;
 536                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 537                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 538                 if (autocvar__notarget)
 539                         this.flags |= FL_NOTARGET;
 540                 this.takedamage = DAMAGE_AIM;
 541                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 542                 this.dmg = 2; // WTF
 543
 544                 if (warmup_stage) {
 545                         this.ammo_shells = warmup_start_ammo_shells;
 546                         this.ammo_nails = warmup_start_ammo_nails;
 547                         this.ammo_rockets = warmup_start_ammo_rockets;
 548                         this.ammo_cells = warmup_start_ammo_cells;
 549                         this.ammo_plasma = warmup_start_ammo_plasma;
 550                         this.ammo_fuel = warmup_start_ammo_fuel;
 551                         this.health = warmup_start_health;
 552                         this.armorvalue = warmup_start_armorvalue;
 553                         this.weapons = WARMUP_START_WEAPONS;
 554                 } else {
 555                         this.ammo_shells = start_ammo_shells;
 556                         this.ammo_nails = start_ammo_nails;
 557                         this.ammo_rockets = start_ammo_rockets;
 558                         this.ammo_cells = start_ammo_cells;
 559                         this.ammo_plasma = start_ammo_plasma;
 560                         this.ammo_fuel = start_ammo_fuel;
 561                         this.health = start_health;
 562                         this.armorvalue = start_armorvalue;
 563                         this.weapons = start_weapons;
 564                 }
 565                 SetSpectatee_status(this, 0);
 566
 567                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 568
 569                 this.items = start_items;
 570
 571                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 572                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 573                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 574                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 575                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 576                 // extend the pause of rotting if client was reset at the beginning of the countdown
 577                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 578                         float f = game_starttime - time;
 579                         this.spawnshieldtime += f;
 580                         this.pauserotarmor_finished += f;
 581                         this.pauserothealth_finished += f;
 582                         this.pauseregen_finished += f;
 583                 }
 584                 this.damageforcescale = 2;
 585                 this.death_time = 0;
 586                 this.respawn_flags = 0;
 587                 this.respawn_time = 0;
 588                 this.stat_respawn_time = 0;
 589                 this.scale = autocvar_sv_player_scale;
 590                 this.fade_time = 0;
 591                 this.pain_frame = 0;
 592                 this.pain_finished = 0;
 593                 this.pushltime = 0;
 594                 setthink(this, func_null); // players have no think function
 595                 this.nextthink = 0;
 596                 this.dmg_team = 0;
 597                 this.ballistics_density = autocvar_g_ballistics_density_player;
 598
 599                 this.deadflag = DEAD_NO;
 600
 601                 this.angles = spot.angles;
 602                 this.angles_z = 0; // never spawn tilted even if the spot says to
 603                 if (IS_BOT_CLIENT(this))
 604                         this.v_angle = this.angles;
 605                 this.fixangle = true; // turn this way immediately
 606                 this.oldvelocity = this.velocity = '0 0 0';
 607                 this.avelocity = '0 0 0';
 608                 this.punchangle = '0 0 0';
 609                 this.punchvector = '0 0 0';
 610
 611                 this.strength_finished = 0;
 612                 this.invincible_finished = 0;
 613                 this.fire_endtime = -1;
 614                 this.revival_time = 0;
 615                 this.air_finished = time + 12;
 616
 617                 entity spawnevent = new_pure(spawnevent);
 618                 spawnevent.owner = this;
 619                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 620
 621                 // Cut off any still running player sounds.
 622                 stopsound(this, CH_PLAYER_SINGLE);
 623
 624                 this.model = "";
 625                 FixPlayermodel(this);
 626                 this.drawonlytoclient = NULL;
 627
 628                 this.crouch = false;
 629                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 630                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 631                 this.spawnorigin = spot.origin;
 632                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 633                 // don't reset back to last position, even if new position is stuck in solid
 634                 this.oldorigin = this.origin;
 635                 this.prevorigin = this.origin;
 636                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 637                 if(this.conveyor)
 638                         IL_REMOVE(g_conveyed, this);
 639                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 640                 this.hud = HUD_NORMAL;
 641
 642                 this.event_damage = PlayerDamage;
 643
 644                 if(!this.bot_attack)
 645                         IL_PUSH(g_bot_targets, this);
 646                 this.bot_attack = true;
 647                 this.monster_attack = true;
 648
 649                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 650
 651                 if (this.killcount == FRAGS_SPECTATOR) {
 652                         PlayerScore_Clear(this);
 653                         this.killcount = 0;
 654                 }
 655
 656                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                 {
 658                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 659                 }
 660                 this.alpha = default_player_alpha;
 661                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 662                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 663
 664                 this.speedrunning = false;
 665
 666                 target_voicescript_clear(this);
 667
 668                 // reset fields the weapons may use
 669                 FOREACH(Weapons, true, LAMBDA(
 670                         it.wr_resetplayer(it, this);
 671                         // reload all reloadable weapons
 672                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 673                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 674                         }
 675                 ));
 676
 677                 {
 678                         string s = spot.target;
 679                         spot.target = string_null;
 680                         SUB_UseTargets(spot, this, NULL);
 681                         spot.target = s;
 682                 }
 683
 684                 Unfreeze(this);
 685
 686                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 687
 688                 if (autocvar_spawn_debug)
 689                 {
 690                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 691                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 692                 }
 693
 694                 PS(this).m_switchweapon = w_getbestweapon(this);
 695                 this.cnt = -1; // W_LastWeapon will not complain
 696                 PS(this).m_weapon = WEP_Null;
 697                 this.weaponname = "";
 698                 PS(this).m_switchingweapon = WEP_Null;
 699
 700                 if (!warmup_stage && !this.alivetime)
 701                         this.alivetime = time;
 702
 703                 antilag_clear(this, CS(this));
 704         }
 705 }
 706
 707 void ClientInit_misc(entity this);
 708
 709 .float ebouncefactor, ebouncestop; // electro's values
 710 // TODO do we need all these fields, or should we stop autodetecting runtime
 711 // changes and just have a console command to update this?
 712 bool ClientInit_SendEntity(entity this, entity to, int sf)
 713 {
 714         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 715         return = true;
 716         msg_entity = to;
 717         // MSG_INIT replacement
 718         // TODO: make easier to use
 719         Registry_send_all();
 720         W_PROP_reload(MSG_ONE, to);
 721         ClientInit_misc(this);
 722         MUTATOR_CALLHOOK(Ent_Init);
 723 }
 724 void ClientInit_misc(entity this)
 725 {
 726         int channel = MSG_ONE;
 727         WriteHeader(channel, ENT_CLIENT_INIT);
 728         WriteByte(channel, g_nexball_meter_period * 32);
 729         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 730         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 731         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 732         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 733         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 734         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 735         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 736         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 737
 738         if(sv_foginterval && world.fog != "")
 739                 WriteString(channel, world.fog);
 740         else
 741                 WriteString(channel, "");
 742         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 743         WriteByte(channel, serverflags);
 744         WriteCoord(channel, autocvar_g_trueaim_minrange);
 745 }
 746
 747 void ClientInit_CheckUpdate(entity this)
 748 {
 749         this.nextthink = time;
 750         if(this.count != autocvar_g_balance_armor_blockpercent)
 751         {
 752                 this.count = autocvar_g_balance_armor_blockpercent;
 753                 this.SendFlags |= 1;
 754         }
 755 }
 756
 757 void ClientInit_Spawn()
 758 {
 759         entity e = new_pure(clientinit);
 760         setthink(e, ClientInit_CheckUpdate);
 761         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 762
 763         ClientInit_CheckUpdate(e);
 764 }
 765
 766 /*
 767 =============
 768 SetNewParms
 769 =============
 770 */
 771 void SetNewParms ()
 772 {
 773         // initialize parms for a new player
 774         parm1 = -(86400 * 366);
 775
 776         MUTATOR_CALLHOOK(SetNewParms);
 777 }
 778
 779 /*
 780 =============
 781 SetChangeParms
 782 =============
 783 */
 784 void SetChangeParms (entity this)
 785 {
 786         // save parms for level change
 787         parm1 = this.parm_idlesince - time;
 788
 789         MUTATOR_CALLHOOK(SetChangeParms);
 790 }
 791
 792 /*
 793 =============
 794 DecodeLevelParms
 795 =============
 796 */
 797 void DecodeLevelParms(entity this)
 798 {
 799         // load parms
 800         this.parm_idlesince = parm1;
 801         if (this.parm_idlesince == -(86400 * 366))
 802                 this.parm_idlesince = time;
 803
 804         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 805         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 806
 807         MUTATOR_CALLHOOK(DecodeLevelParms);
 808 }
 809
 810 /*
 811 =============
 812 ClientKill
 813
 814 Called when a client types 'kill' in the console
 815 =============
 816 */
 817
 818 .float clientkill_nexttime;
 819 void ClientKill_Now_TeamChange(entity this)
 820 {
 821         if(this.killindicator_teamchange == -1)
 822         {
 823                 JoinBestTeam( this, false, true );
 824         }
 825         else if(this.killindicator_teamchange == -2)
 826         {
 827                 if(blockSpectators)
 828                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 829                 PutObserverInServer(this);
 830         }
 831         else
 832                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 833         this.killindicator_teamchange = 0;
 834 }
 835
 836 void ClientKill_Now(entity this)
 837 {
 838         if(this.vehicle)
 839         {
 840             vehicles_exit(this.vehicle, VHEF_RELEASE);
 841             if(!this.killindicator_teamchange)
 842             {
 843             this.vehicle_health = -1;
 844             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 845             }
 846         }
 847
 848         if(this.killindicator && !wasfreed(this.killindicator))
 849                 delete(this.killindicator);
 850
 851         this.killindicator = NULL;
 852
 853         if(this.killindicator_teamchange)
 854                 ClientKill_Now_TeamChange(this);
 855
 856         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 857                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 858
 859         // now I am sure the player IS dead
 860 }
 861 void KillIndicator_Think(entity this)
 862 {
 863         if (gameover)
 864         {
 865                 this.owner.killindicator = NULL;
 866                 delete(this);
 867                 return;
 868         }
 869
 870         if (this.owner.alpha < 0 && !this.owner.vehicle)
 871         {
 872                 this.owner.killindicator = NULL;
 873                 delete(this);
 874                 return;
 875         }
 876
 877         if(this.cnt <= 0)
 878         {
 879                 ClientKill_Now(this.owner);
 880                 return;
 881         }
 882     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 883     {
 884         this.nextthink = time + 1;
 885         this.cnt -= 1;
 886     }
 887         else
 888         {
 889                 if(this.cnt <= 10)
 890                         setmodel(this, MDL_NUM(this.cnt));
 891                 if(IS_REAL_CLIENT(this.owner))
 892                 {
 893                         if(this.cnt <= 10)
 894                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 895                 }
 896                 this.nextthink = time + 1;
 897                 this.cnt -= 1;
 898         }
 899 }
 900
 901 float clientkilltime;
 902 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 903 {
 904         float killtime;
 905         float starttime;
 906
 907         if (gameover)
 908                 return;
 909
 910         killtime = autocvar_g_balance_kill_delay;
 911
 912         if(g_race_qualifying || g_cts)
 913                 killtime = 0;
 914
 915     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 916         return;
 917
 918         this.killindicator_teamchange = targetteam;
 919
 920     if(!this.killindicator)
 921         {
 922                 if(!IS_DEAD(this))
 923                 {
 924                         killtime = max(killtime, this.clientkill_nexttime - time);
 925                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 926                 }
 927
 928                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 929                 {
 930                         ClientKill_Now(this);
 931                 }
 932                 else
 933                 {
 934                         starttime = max(time, clientkilltime);
 935
 936                         this.killindicator = spawn();
 937                         this.killindicator.owner = this;
 938                         this.killindicator.scale = 0.5;
 939                         setattachment(this.killindicator, this, "");
 940                         setorigin(this.killindicator, '0 0 52');
 941                         setthink(this.killindicator, KillIndicator_Think);
 942                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 943                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 944                         this.killindicator.cnt = ceil(killtime);
 945                         this.killindicator.count = bound(0, ceil(killtime), 10);
 946                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 947
 948                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 949                         {
 950                                 it.killindicator = spawn();
 951                                 it.killindicator.owner = it;
 952                                 it.killindicator.scale = 0.5;
 953                                 setattachment(it.killindicator, it, "");
 954                                 setorigin(it.killindicator, '0 0 52');
 955                                 setthink(it.killindicator, KillIndicator_Think);
 956                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 957                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 958                                 it.killindicator.cnt = ceil(killtime);
 959                         });
 960                         this.lip = 0;
 961                 }
 962         }
 963         if(this.killindicator)
 964         {
 965                 if(targetteam == 0) // just die
 966                 {
 967                         this.killindicator.colormod = '0 0 0';
 968                         if(IS_REAL_CLIENT(this))
 969                         if(this.killindicator.cnt > 0)
 970                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 971                 }
 972                 else if(targetteam == -1) // auto
 973                 {
 974                         this.killindicator.colormod = '0 1 0';
 975                         if(IS_REAL_CLIENT(this))
 976                         if(this.killindicator.cnt > 0)
 977                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 978                 }
 979                 else if(targetteam == -2) // spectate
 980                 {
 981                         this.killindicator.colormod = '0.5 0.5 0.5';
 982                         if(IS_REAL_CLIENT(this))
 983                         if(this.killindicator.cnt > 0)
 984                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 985                 }
 986                 else
 987                 {
 988                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 989                         if(IS_REAL_CLIENT(this))
 990                         if(this.killindicator.cnt > 0)
 991                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 992                 }
 993         }
 994
 995 }
 996
 997 void ClientKill (entity this)
 998 {
 999         if(gameover) return;
1000         if(this.player_blocked) return;
1001         if(STAT(FROZEN, this)) return;
1002
1003         ClientKill_TeamChange(this, 0);
1004 }
1005
1006 void FixClientCvars(entity e)
1007 {
1008         // send prediction settings to the client
1009         stuffcmd(e, "\nin_bindmap 0 0\n");
1010         if(autocvar_g_antilag == 3) // client side hitscan
1011                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1012         if(autocvar_sv_gentle)
1013                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1014
1015         MUTATOR_CALLHOOK(FixClientCvars, e);
1016 }
1017
1018 float PlayerInIDList(entity p, string idlist)
1019 {
1020         float n, i;
1021         string s;
1022
1023         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1024         if (!p.crypto_idfp)
1025                 return 0;
1026
1027         // this function allows abbreviated player IDs too!
1028         n = tokenize_console(idlist);
1029         for(i = 0; i < n; ++i)
1030         {
1031                 s = argv(i);
1032                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1033                         return 1;
1034         }
1035
1036         return 0;
1037 }
1038
1039 #ifdef DP_EXT_PRECONNECT
1040 /*
1041 =============
1042 ClientPreConnect
1043
1044 Called once (not at each match start) when a client begins a connection to the server
1045 =============
1046 */
1047 void ClientPreConnect ()
1048 {ENGINE_EVENT();
1049         if(autocvar_sv_eventlog)
1050         {
1051                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1052                         this.playerid,
1053                         etof(this),
1054                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1055                 ));
1056         }
1057 }
1058 #endif
1059
1060 /**
1061 =============
1062 ClientConnect
1063
1064 Called when a client connects to the server
1065 =============
1066 */
1067 void ClientConnect(entity this)
1068 {
1069         if (Ban_MaybeEnforceBanOnce(this)) return;
1070         assert(!IS_CLIENT(this), return);
1071         this.flags |= FL_CLIENT;
1072         assert(player_count >= 0, player_count = 0);
1073
1074 #ifdef WATERMARK
1075         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1076 #endif
1077         this.version_nagtime = time + 10 + random() * 10;
1078         TRANSMUTE(Client, this);
1079
1080         // identify the right forced team
1081         if (autocvar_g_campaign)
1082         {
1083                 if (IS_REAL_CLIENT(this)) // only players, not bots
1084                 {
1085                         switch (autocvar_g_campaign_forceteam)
1086                         {
1087                                 case 1: this.team_forced = NUM_TEAM_1; break;
1088                                 case 2: this.team_forced = NUM_TEAM_2; break;
1089                                 case 3: this.team_forced = NUM_TEAM_3; break;
1090                                 case 4: this.team_forced = NUM_TEAM_4; break;
1091                                 default: this.team_forced = 0;
1092                         }
1093                 }
1094         }
1095         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1096         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1097         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1098         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1099         else switch (autocvar_g_forced_team_otherwise)
1100         {
1101                 default: this.team_forced = 0; break;
1102                 case "red": this.team_forced = NUM_TEAM_1; break;
1103                 case "blue": this.team_forced = NUM_TEAM_2; break;
1104                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1105                 case "pink": this.team_forced = NUM_TEAM_4; break;
1106                 case "spectate":
1107                 case "spectator":
1108                         this.team_forced = -1;
1109                         break;
1110         }
1111         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1112
1113     {
1114         int id = this.playerid;
1115         this.playerid = 0; // silent
1116             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1117             this.playerid = id;
1118     }
1119
1120         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1121                 TRANSMUTE(Observer, this);
1122         } else {
1123                 if (!teamplay || autocvar_g_balance_teams) {
1124                         TRANSMUTE(Player, this);
1125                         campaign_bots_may_start = true;
1126                 } else {
1127                         TRANSMUTE(Observer, this); // do it anyway
1128                 }
1129         }
1130
1131         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1132
1133         // always track bots, don't ask for cl_allow_uidtracking
1134     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1135
1136         if (autocvar_sv_eventlog)
1137                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1138
1139         LogTeamchange(this.playerid, this.team, 1);
1140
1141         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1142
1143         this.netname_previous = strzone(this.netname);
1144
1145         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1146
1147         stuffcmd(this, clientstuff, "\n");
1148         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1149
1150         FixClientCvars(this);
1151
1152         // get version info from player
1153         stuffcmd(this, "cmd clientversion $gameversion\n");
1154
1155         // notify about available teams
1156         if (teamplay)
1157         {
1158                 CheckAllowedTeams(this);
1159                 int t = 0;
1160                 if (c1 >= 0) t |= BIT(0);
1161                 if (c2 >= 0) t |= BIT(1);
1162                 if (c3 >= 0) t |= BIT(2);
1163                 if (c4 >= 0) t |= BIT(3);
1164                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1165         }
1166         else
1167         {
1168                 stuffcmd(this, "set _teams_available 0\n");
1169         }
1170
1171         bot_relinkplayerlist();
1172
1173         this.spectatortime = time;
1174         if (blockSpectators)
1175         {
1176                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1177         }
1178
1179         this.jointime = time;
1180         this.allowed_timeouts = autocvar_sv_timeout_number;
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (!autocvar_g_campaign)
1185                 {
1186                         this.motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1188                 }
1189
1190                 if (g_weaponarena_weapons == WEPSET(TUBA))
1191                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1192         }
1193
1194         if (!sv_foginterval && world.fog != "")
1195                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1196
1197         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1198                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1199                         send_CSQC_teamnagger();
1200
1201         CSQCMODEL_AUTOINIT(this);
1202
1203         this.model_randomizer = random();
1204
1205         if (IS_REAL_CLIENT(this))
1206                 sv_notice_join(this);
1207
1208         IL_EACH(g_initforplayer, it.init_for_player, {
1209                 it.init_for_player(it, this);
1210         });
1211
1212         MUTATOR_CALLHOOK(ClientConnect, this);
1213 }
1214 /*
1215 =============
1216 ClientDisconnect
1217
1218 Called when a client disconnects from the server
1219 =============
1220 */
1221 .entity chatbubbleentity;
1222 void ReadyCount();
1223 void ClientDisconnect(entity this)
1224 {
1225         assert(IS_CLIENT(this), return);
1226
1227         PlayerStats_GameReport_FinalizePlayer(this);
1228         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1229         if (this.active_minigame) part_minigame(this);
1230         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1231
1232         if (autocvar_sv_eventlog)
1233                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1234
1235         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1236
1237         SetSpectatee(this, NULL);
1238
1239     MUTATOR_CALLHOOK(ClientDisconnect, this);
1240
1241         ClientState_detach(this);
1242
1243         Portal_ClearAll(this);
1244
1245         Unfreeze(this);
1246
1247         RemoveGrapplingHook(this);
1248
1249         // Here, everything has been done that requires this player to be a client.
1250
1251         this.flags &= ~FL_CLIENT;
1252
1253         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1254         if (this.killindicator) delete(this.killindicator);
1255
1256         WaypointSprite_PlayerGone(this);
1257
1258         bot_relinkplayerlist();
1259
1260         if (this.netname_previous) strunzone(this.netname_previous);
1261         if (this.clientstatus) strunzone(this.clientstatus);
1262         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1263         if (this.personal) delete(this.personal);
1264
1265         this.playerid = 0;
1266         ReadyCount();
1267         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1268 }
1269
1270 void ChatBubbleThink(entity this)
1271 {
1272         this.nextthink = time;
1273         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1274         {
1275                 if(this.owner) // but why can that ever be NULL?
1276                         this.owner.chatbubbleentity = NULL;
1277                 delete(this);
1278                 return;
1279         }
1280
1281         this.mdl = "";
1282
1283         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1284         {
1285                 if ( this.owner.active_minigame )
1286                         this.mdl = "models/sprites/minigame_busy.iqm";
1287                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1288                         this.mdl = "models/misc/chatbubble.spr";
1289         }
1290
1291         if ( this.model != this.mdl )
1292                 _setmodel(this, this.mdl);
1293
1294 }
1295
1296 void UpdateChatBubble(entity this)
1297 {
1298         if (this.alpha < 0)
1299                 return;
1300         // spawn a chatbubble entity if needed
1301         if (!this.chatbubbleentity)
1302         {
1303                 this.chatbubbleentity = new(chatbubbleentity);
1304                 this.chatbubbleentity.owner = this;
1305                 this.chatbubbleentity.exteriormodeltoclient = this;
1306                 setthink(this.chatbubbleentity, ChatBubbleThink);
1307                 this.chatbubbleentity.nextthink = time;
1308                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1309                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1310                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1311                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1312                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1313                 //this.chatbubbleentity.model = "";
1314                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1315         }
1316 }
1317
1318
1319 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1320 // added to the model skins
1321 /*void UpdateColorModHack()
1322 {
1323         float c;
1324         c = this.clientcolors & 15;
1325         // LordHavoc: only bothering to support white, green, red, yellow, blue
1326              if (!teamplay) this.colormod = '0 0 0';
1327         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1328         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1329         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1330         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1331         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1332         else this.colormod = '1 1 1';
1333 }*/
1334
1335 void respawn(entity this)
1336 {
1337         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1338         {
1339                 this.solid = SOLID_NOT;
1340                 this.takedamage = DAMAGE_NO;
1341                 set_movetype(this, MOVETYPE_FLY);
1342                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1343                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1344                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1345                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1346                 if(autocvar_g_respawn_ghosts_maxtime)
1347                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1348         }
1349
1350         CopyBody(this, 1);
1351
1352         this.effects |= EF_NODRAW; // prevent another CopyBody
1353         PutClientInServer(this);
1354 }
1355
1356 void play_countdown(entity this, float finished, Sound samp)
1357 {
1358     TC(Sound, samp);
1359         if(IS_REAL_CLIENT(this))
1360                 if(floor(finished - time - frametime) != floor(finished - time))
1361                         if(finished - time < 6)
1362                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1363 }
1364
1365 void player_powerups(entity this)
1366 {
1367         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1368         int items_prev = this.items;
1369
1370         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1371                 this.modelflags |= MF_ROCKET;
1372         else
1373                 this.modelflags &= ~MF_ROCKET;
1374
1375         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1376
1377         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1378                 return;
1379
1380         Fire_ApplyDamage(this);
1381         Fire_ApplyEffect(this);
1382
1383         if (!g_instagib)
1384         {
1385                 if (this.items & ITEM_Strength.m_itemid)
1386                 {
1387                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1388                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1389                         if (time > this.strength_finished)
1390                         {
1391                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1392                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1393                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1394                         }
1395                 }
1396                 else
1397                 {
1398                         if (time < this.strength_finished)
1399                         {
1400                                 this.items = this.items | ITEM_Strength.m_itemid;
1401                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1402                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1403                         }
1404                 }
1405                 if (this.items & ITEM_Shield.m_itemid)
1406                 {
1407                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1408                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1409                         if (time > this.invincible_finished)
1410                         {
1411                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1412                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1413                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1414                         }
1415                 }
1416                 else
1417                 {
1418                         if (time < this.invincible_finished)
1419                         {
1420                                 this.items = this.items | ITEM_Shield.m_itemid;
1421                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1422                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1423                         }
1424                 }
1425                 if (this.items & IT_SUPERWEAPON)
1426                 {
1427                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1428                         {
1429                                 this.superweapons_finished = 0;
1430                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1431                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1432                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1433                         }
1434                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1435                         {
1436                                 // don't let them run out
1437                         }
1438                         else
1439                         {
1440                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1441                                 if (time > this.superweapons_finished)
1442                                 {
1443                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1444                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1445                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1446                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1447                                 }
1448                         }
1449                 }
1450                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1451                 {
1452                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1453                         {
1454                                 this.items = this.items | IT_SUPERWEAPON;
1455                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1457                         }
1458                         else
1459                         {
1460                                 this.superweapons_finished = 0;
1461                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1462                         }
1463                 }
1464                 else
1465                 {
1466                         this.superweapons_finished = 0;
1467                 }
1468         }
1469
1470         if(autocvar_g_nodepthtestplayers)
1471                 this.effects = this.effects | EF_NODEPTHTEST;
1472
1473         if(autocvar_g_fullbrightplayers)
1474                 this.effects = this.effects | EF_FULLBRIGHT;
1475
1476         if (time >= game_starttime)
1477         if (time < this.spawnshieldtime)
1478                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1479
1480         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1481 }
1482
1483 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1484 {
1485         if(current > stable)
1486                 return current;
1487         else if(current > stable - 0.25) // when close enough, "snap"
1488                 return stable;
1489         else
1490                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1491 }
1492
1493 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1494 {
1495         if(current < stable)
1496                 return current;
1497         else if(current < stable + 0.25) // when close enough, "snap"
1498                 return stable;
1499         else
1500                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1501 }
1502
1503 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1504 {
1505         if(current > rotstable)
1506         {
1507                 if(rotframetime > 0)
1508                 {
1509                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1510                         current = max(rotstable, current - rotlinear * rotframetime);
1511                 }
1512         }
1513         else if(current < regenstable)
1514         {
1515                 if(regenframetime > 0)
1516                 {
1517                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1518                         current = min(regenstable, current + regenlinear * regenframetime);
1519                 }
1520         }
1521
1522         if(current > limit)
1523                 current = limit;
1524
1525         return current;
1526 }
1527
1528 void player_regen(entity this)
1529 {
1530         float max_mod, regen_mod, rot_mod, limit_mod;
1531         max_mod = regen_mod = rot_mod = limit_mod = 1;
1532
1533         float regen_health = autocvar_g_balance_health_regen;
1534         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1535         float regen_health_rot = autocvar_g_balance_health_rot;
1536         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1537         float regen_health_stable = autocvar_g_balance_health_regenstable;
1538         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1539         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1540                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1541         max_mod = M_ARGV(1, float);
1542         regen_mod = M_ARGV(2, float);
1543         rot_mod = M_ARGV(3, float);
1544         limit_mod = M_ARGV(4, float);
1545         regen_health = M_ARGV(5, float);
1546         regen_health_linear = M_ARGV(6, float);
1547         regen_health_rot = M_ARGV(7, float);
1548         regen_health_rotlinear = M_ARGV(8, float);
1549         regen_health_stable = M_ARGV(9, float);
1550         regen_health_rotstable = M_ARGV(10, float);
1551
1552
1553         if(!mutator_returnvalue)
1554         if(!STAT(FROZEN, this))
1555         {
1556                 float mina, maxa, limith, limita;
1557                 maxa = autocvar_g_balance_armor_rotstable;
1558                 mina = autocvar_g_balance_armor_regenstable;
1559                 limith = autocvar_g_balance_health_limit;
1560                 limita = autocvar_g_balance_armor_limit;
1561
1562                 regen_health_rotstable = regen_health_rotstable * max_mod;
1563                 regen_health_stable = regen_health_stable * max_mod;
1564                 limith = limith * limit_mod;
1565                 limita = limita * limit_mod;
1566
1567                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1568                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1569         }
1570
1571         // if player rotted to death...  die!
1572         // check this outside above checks, as player may still be able to rot to death
1573         if(this.health < 1)
1574         {
1575                 if(this.vehicle)
1576                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1577                 if(this.event_damage)
1578                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1579         }
1580
1581         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1582         {
1583                 float minf, maxf, limitf;
1584
1585                 maxf = autocvar_g_balance_fuel_rotstable;
1586                 minf = autocvar_g_balance_fuel_regenstable;
1587                 limitf = autocvar_g_balance_fuel_limit;
1588
1589                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1590         }
1591 }
1592
1593 bool zoomstate_set;
1594 void SetZoomState(entity this, float z)
1595 {
1596         if(z != this.zoomstate)
1597         {
1598                 this.zoomstate = z;
1599                 ClientData_Touch(this);
1600         }
1601         zoomstate_set = true;
1602 }
1603
1604 void GetPressedKeys(entity this)
1605 {
1606         MUTATOR_CALLHOOK(GetPressedKeys, this);
1607         int keys = this.pressedkeys;
1608         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1609         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1610         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1611         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1612
1613         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1614         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1615         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1616         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1617         this.pressedkeys = keys;
1618 }
1619
1620 /*
1621 ======================
1622 spectate mode routines
1623 ======================
1624 */
1625
1626 void SpectateCopy(entity this, entity spectatee)
1627 {
1628     TC(Client, this); TC(Client, spectatee);
1629
1630         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1631         PS(this) = PS(spectatee);
1632         this.armortype = spectatee.armortype;
1633         this.armorvalue = spectatee.armorvalue;
1634         this.ammo_cells = spectatee.ammo_cells;
1635         this.ammo_plasma = spectatee.ammo_plasma;
1636         this.ammo_shells = spectatee.ammo_shells;
1637         this.ammo_nails = spectatee.ammo_nails;
1638         this.ammo_rockets = spectatee.ammo_rockets;
1639         this.ammo_fuel = spectatee.ammo_fuel;
1640         this.clip_load = spectatee.clip_load;
1641         this.clip_size = spectatee.clip_size;
1642         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1643         this.health = spectatee.health;
1644         this.impulse = 0;
1645         this.items = spectatee.items;
1646         this.last_pickup = spectatee.last_pickup;
1647         this.hit_time = spectatee.hit_time;
1648         this.strength_finished = spectatee.strength_finished;
1649         this.invincible_finished = spectatee.invincible_finished;
1650         this.pressedkeys = spectatee.pressedkeys;
1651         this.weapons = spectatee.weapons;
1652         this.vortex_charge = spectatee.vortex_charge;
1653         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1654         this.hagar_load = spectatee.hagar_load;
1655         this.arc_heat_percent = spectatee.arc_heat_percent;
1656         this.minelayer_mines = spectatee.minelayer_mines;
1657         this.punchangle = spectatee.punchangle;
1658         this.view_ofs = spectatee.view_ofs;
1659         this.velocity = spectatee.velocity;
1660         this.dmg_take = spectatee.dmg_take;
1661         this.dmg_save = spectatee.dmg_save;
1662         this.dmg_inflictor = spectatee.dmg_inflictor;
1663         this.v_angle = spectatee.v_angle;
1664         this.angles = spectatee.v_angle;
1665         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1666         this.revive_progress = spectatee.revive_progress;
1667         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1668                 this.fixangle = true;
1669         setorigin(this, spectatee.origin);
1670         setsize(this, spectatee.mins, spectatee.maxs);
1671         SetZoomState(this, spectatee.zoomstate);
1672
1673     anticheat_spectatecopy(this, spectatee);
1674         this.hud = spectatee.hud;
1675         if(spectatee.vehicle)
1676     {
1677         this.angles = spectatee.v_angle;
1678
1679         //this.fixangle = false;
1680         //this.velocity = spectatee.vehicle.velocity;
1681         this.vehicle_health = spectatee.vehicle_health;
1682         this.vehicle_shield = spectatee.vehicle_shield;
1683         this.vehicle_energy = spectatee.vehicle_energy;
1684         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1685         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1686         this.vehicle_reload1 = spectatee.vehicle_reload1;
1687         this.vehicle_reload2 = spectatee.vehicle_reload2;
1688
1689         //msg_entity = this;
1690
1691        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1692             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1693            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1694            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1695
1696         //WriteByte (MSG_ONE, SVC_SETVIEW);
1697         //    WriteEntity(MSG_ONE, this);
1698         //makevectors(spectatee.v_angle);
1699         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1700     }
1701 }
1702
1703 bool SpectateUpdate(entity this)
1704 {
1705         if(!this.enemy)
1706                 return false;
1707
1708         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1709         {
1710                 SetSpectatee(this, NULL);
1711                 return false;
1712         }
1713
1714         SpectateCopy(this, this.enemy);
1715
1716         return true;
1717 }
1718
1719 bool SpectateSet(entity this)
1720 {
1721         if(!IS_PLAYER(this.enemy))
1722                 return false;
1723
1724         ClientData_Touch(this.enemy);
1725
1726         msg_entity = this;
1727         WriteByte(MSG_ONE, SVC_SETVIEW);
1728         WriteEntity(MSG_ONE, this.enemy);
1729         set_movetype(this, MOVETYPE_NONE);
1730         accuracy_resend(this);
1731
1732         if(!SpectateUpdate(this))
1733                 PutObserverInServer(this);
1734
1735         return true;
1736 }
1737
1738 void SetSpectatee_status(entity this, int spectatee_num)
1739 {
1740         int oldspectatee_status = this.spectatee_status;
1741         this.spectatee_status = spectatee_num;
1742
1743         if (this.spectatee_status != oldspectatee_status)
1744         {
1745                 ClientData_Touch(this);
1746                 if (g_race || g_cts) race_InitSpectator();
1747         }
1748 }
1749
1750 void SetSpectatee(entity this, entity spectatee)
1751 {
1752         entity old_spectatee = this.enemy;
1753
1754         this.enemy = spectatee;
1755
1756         // WEAPONTODO
1757         // these are required to fix the spectator bug with arc
1758         if(old_spectatee)
1759         {
1760                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1761                 {
1762                         .entity weaponentity = weaponentities[slot];
1763                         if(old_spectatee.(weaponentity).arc_beam)
1764                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1765                 }
1766         }
1767         if(this.enemy)
1768         {
1769                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1770                 {
1771                         .entity weaponentity = weaponentities[slot];
1772                         if(this.enemy.(weaponentity).arc_beam)
1773                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1774                 }
1775         }
1776
1777         if (this.enemy)
1778                 SetSpectatee_status(this, etof(this.enemy));
1779
1780         // needed to update spectator list
1781         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1782 }
1783
1784 bool Spectate(entity this, entity pl)
1785 {
1786         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1787                 return false;
1788         pl = M_ARGV(1, entity);
1789
1790         SetSpectatee(this, pl);
1791         return SpectateSet(this);
1792 }
1793
1794 bool SpectateNext(entity this)
1795 {
1796         entity ent = find(this.enemy, classname, STR_PLAYER);
1797
1798         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1799                 ent = M_ARGV(1, entity);
1800         else if (!ent)
1801                 ent = find(ent, classname, STR_PLAYER);
1802
1803         if(ent) { SetSpectatee(this, ent); }
1804
1805         return SpectateSet(this);
1806 }
1807
1808 bool SpectatePrev(entity this)
1809 {
1810         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1811         entity ent = findchain(classname, STR_PLAYER);
1812         if (!ent) // no player
1813                 return false;
1814
1815         entity first = ent;
1816         // skip players until current spectated player
1817         if(this.enemy)
1818         while(ent && ent != this.enemy)
1819                 ent = ent.chain;
1820
1821         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1822         {
1823                 case MUT_SPECPREV_FOUND:
1824                     ent = M_ARGV(1, entity);
1825                     break;
1826                 case MUT_SPECPREV_RETURN:
1827                     return true;
1828                 case MUT_SPECPREV_CONTINUE:
1829                 default:
1830                 {
1831                         if(ent.chain)
1832                                 ent = ent.chain;
1833                         else
1834                                 ent = first;
1835                         break;
1836                 }
1837         }
1838
1839         SetSpectatee(this, ent);
1840         return SpectateSet(this);
1841 }
1842
1843 /*
1844 =============
1845 ShowRespawnCountdown()
1846
1847 Update a respawn countdown display.
1848 =============
1849 */
1850 void ShowRespawnCountdown(entity this)
1851 {
1852         float number;
1853         if(!IS_DEAD(this)) // just respawned?
1854                 return;
1855         else
1856         {
1857                 number = ceil(this.respawn_time - time);
1858                 if(number <= 0)
1859                         return;
1860                 if(number <= this.respawn_countdown)
1861                 {
1862                         this.respawn_countdown = number - 1;
1863                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1864                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1865                 }
1866         }
1867 }
1868
1869 .int team_selected;
1870 void JoinOrShowTeamSelection(entity this)
1871 {
1872         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1873         {
1874                 TRANSMUTE(Player, this);
1875
1876                 SetSpectatee(this, NULL);
1877
1878                 if(autocvar_g_campaign || autocvar_g_balance_teams)
1879                         JoinBestTeam(this, false, true);
1880
1881                 if(autocvar_g_campaign)
1882                         campaign_bots_may_start = true;
1883
1884                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1885
1886                 PutClientInServer(this);
1887                 PlayerScore_Clear(this);
1888
1889                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname);
1890                 this.team_selected = false;
1891         }
1892         else
1893                 stuffcmd(this, "menu_showteamselect\n");
1894 }
1895
1896 /**
1897  * Determines whether the player is allowed to join. This depends on cvar
1898  * g_maxplayers, if it isn't used this function always return true, otherwise
1899  * it checks whether the number of currently playing players exceeds g_maxplayers.
1900  * @return int number of free slots for players, 0 if none
1901  */
1902 int nJoinAllowed(entity this, entity ignore)
1903 {
1904         if(!ignore)
1905         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1906         // so report 0 free slots if restricted
1907         {
1908                 if(autocvar_g_forced_team_otherwise == "spectate")
1909                         return 0;
1910                 if(autocvar_g_forced_team_otherwise == "spectator")
1911                         return 0;
1912         }
1913
1914         if(this && this.team_forced < 0)
1915                 return 0; // forced spectators can never join
1916
1917         // TODO simplify this
1918         int totalClients = 0;
1919         int currentlyPlaying = 0;
1920         FOREACH_CLIENT(true, LAMBDA(
1921                 if(it != ignore)
1922                         ++totalClients;
1923                 if(IS_REAL_CLIENT(it))
1924                 if(IS_PLAYER(it) || it.caplayer)
1925                         ++currentlyPlaying;
1926         ));
1927
1928         float free_slots = 0;
1929         if (!autocvar_g_maxplayers)
1930                 free_slots = maxclients - totalClients;
1931         else if(currentlyPlaying < autocvar_g_maxplayers)
1932                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1933
1934         static float join_prevent_msg_time = 0;
1935         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1936         {
1937                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1938                 join_prevent_msg_time = time + 3;
1939         }
1940
1941         return free_slots;
1942 }
1943
1944 /**
1945  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1946  * g_maxplayers_spectator_blocktime seconds
1947  */
1948 void checkSpectatorBlock(entity this)
1949 {
1950         if(IS_SPEC(this) || IS_OBSERVER(this))
1951         if(!this.caplayer)
1952         if(IS_REAL_CLIENT(this))
1953         {
1954                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1955                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1956                         dropclient(this);
1957                 }
1958         }
1959 }
1960
1961 void PrintWelcomeMessage(entity this)
1962 {
1963         if(this.motd_actived_time == 0)
1964         {
1965                 if (autocvar_g_campaign) {
1966                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1967                                 this.motd_actived_time = time;
1968                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1969                         }
1970                 } else {
1971                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1972                                 this.motd_actived_time = time;
1973                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1974                         }
1975                 }
1976         }
1977         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1978         {
1979                 if (autocvar_g_campaign) {
1980                         if (PHYS_INPUT_BUTTON_INFO(this))
1981                                 this.motd_actived_time = time;
1982                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1983                                 this.motd_actived_time = 0;
1984                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1985                         }
1986                 } else {
1987                         if (PHYS_INPUT_BUTTON_INFO(this))
1988                                 this.motd_actived_time = time;
1989                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1990                                 this.motd_actived_time = 0;
1991                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1992                         }
1993                 }
1994         }
1995         else //if(this.motd_actived_time < 0) // just connected, motd is active
1996         {
1997                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1998                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1999                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2000                 {
2001                         // instanctly hide MOTD
2002                         this.motd_actived_time = 0;
2003                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2004                 }
2005         }
2006 }
2007
2008 bool spawnAllowed(entity this)
2009 {
2010         if (this.version_mismatch) return false;
2011         if (teamplay && lockteams) return false;
2012         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2013         if (!nJoinAllowed(this, this)) return false;
2014         return true;
2015 }
2016
2017 void ObserverThink(entity this)
2018 {
2019         if ( this.impulse )
2020         {
2021                 MinigameImpulse(this, this.impulse);
2022                 this.impulse = 0;
2023         }
2024
2025         if (this.flags & FL_JUMPRELEASED) {
2026                 if (PHYS_INPUT_BUTTON_JUMP(this) && spawnAllowed(this)) {
2027                         this.flags &= ~FL_JUMPRELEASED;
2028                         this.flags |= FL_SPAWNING;
2029                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2030                         this.flags &= ~FL_JUMPRELEASED;
2031                         if(SpectateNext(this)) {
2032                                 TRANSMUTE(Spectator, this);
2033                         }
2034                 } else {
2035                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2036                         set_movetype(this, preferred_movetype);
2037                 }
2038         } else {
2039                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2040                         this.flags |= FL_JUMPRELEASED;
2041                         if(this.flags & FL_SPAWNING)
2042                         {
2043                                 this.flags &= ~FL_SPAWNING;
2044                                 JoinOrShowTeamSelection(this);
2045                                 return;
2046                         }
2047                 }
2048         }
2049 }
2050
2051 void SpectatorThink(entity this)
2052 {
2053         if ( this.impulse )
2054         {
2055                 if(MinigameImpulse(this, this.impulse))
2056                         this.impulse = 0;
2057
2058                 if (this.impulse == IMP_weapon_drop.impulse)
2059                 {
2060                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2061                         this.impulse = 0;
2062                         return;
2063                 }
2064         }
2065
2066         if (this.flags & FL_JUMPRELEASED) {
2067                 if (PHYS_INPUT_BUTTON_JUMP(this) && spawnAllowed(this)) {
2068                         this.flags &= ~FL_JUMPRELEASED;
2069                         this.flags |= FL_SPAWNING;
2070                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2071                         this.flags &= ~FL_JUMPRELEASED;
2072                         if(SpectateNext(this)) {
2073                                 TRANSMUTE(Spectator, this);
2074                         } else {
2075                                 TRANSMUTE(Observer, this);
2076                                 PutClientInServer(this);
2077                         }
2078                         this.impulse = 0;
2079                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2080                         this.flags &= ~FL_JUMPRELEASED;
2081                         if(SpectatePrev(this)) {
2082                                 TRANSMUTE(Spectator, this);
2083                         } else {
2084                                 TRANSMUTE(Observer, this);
2085                                 PutClientInServer(this);
2086                         }
2087                         this.impulse = 0;
2088                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2089                         this.flags &= ~FL_JUMPRELEASED;
2090                         TRANSMUTE(Observer, this);
2091                         PutClientInServer(this);
2092                 } else {
2093                         if(!SpectateUpdate(this))
2094                                 PutObserverInServer(this);
2095                 }
2096         } else {
2097                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2098                         this.flags |= FL_JUMPRELEASED;
2099                         if(this.flags & FL_SPAWNING)
2100                         {
2101                                 this.flags &= ~FL_SPAWNING;
2102                                 JoinOrShowTeamSelection(this);
2103                                 return;
2104                         }
2105                 }
2106                 if(!SpectateUpdate(this))
2107                         PutObserverInServer(this);
2108         }
2109
2110         this.flags |= FL_CLIENT | FL_NOTARGET;
2111 }
2112
2113 void vehicles_enter (entity pl, entity veh);
2114 void PlayerUseKey(entity this)
2115 {
2116         if (!IS_PLAYER(this))
2117                 return;
2118
2119         if(this.vehicle)
2120         {
2121                 if(!gameover)
2122                 {
2123                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2124                         return;
2125                 }
2126         }
2127         else if(autocvar_g_vehicles_enter)
2128         {
2129                 if(!STAT(FROZEN, this))
2130                 if(!IS_DEAD(this))
2131                 if(!gameover)
2132                 {
2133                         entity head, closest_target = NULL;
2134                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2135
2136                         while(head) // find the closest acceptable target to enter
2137                         {
2138                                 if(IS_VEHICLE(head))
2139                                 if(!IS_DEAD(head))
2140                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2141                                 if(head.takedamage != DAMAGE_NO)
2142                                 {
2143                                         if(closest_target)
2144                                         {
2145                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2146                                                 { closest_target = head; }
2147                                         }
2148                                         else { closest_target = head; }
2149                                 }
2150
2151                                 head = head.chain;
2152                         }
2153
2154                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2155                 }
2156         }
2157
2158         // a use key was pressed; call handlers
2159         MUTATOR_CALLHOOK(PlayerUseKey, this);
2160 }
2161
2162
2163 /*
2164 =============
2165 PlayerPreThink
2166
2167 Called every frame for each client before the physics are run
2168 =============
2169 */
2170 .float usekeypressed;
2171 .float last_vehiclecheck;
2172 .int items_added;
2173 void PlayerPreThink (entity this)
2174 {
2175         WarpZone_PlayerPhysics_FixVAngle(this);
2176
2177     STAT(GAMESTARTTIME, this) = game_starttime;
2178         STAT(ROUNDSTARTTIME, this) = round_starttime;
2179         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2180         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2181
2182         STAT(WEAPONSINMAP, this) = weaponsInMap;
2183
2184         if (frametime) {
2185                 // physics frames: update anticheat stuff
2186                 anticheat_prethink(this);
2187         }
2188
2189         if (blockSpectators && frametime) {
2190                 // WORKAROUND: only use dropclient in server frames (frametime set).
2191                 // Never use it in cl_movement frames (frametime zero).
2192                 checkSpectatorBlock(this);
2193     }
2194
2195         zoomstate_set = false;
2196
2197         // Check for nameless players
2198         if (isInvisibleString(this.netname)) {
2199                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2200                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2201         }
2202         if (this.netname != this.netname_previous) {
2203                 if (autocvar_sv_eventlog) {
2204                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2205         }
2206                 if (this.netname_previous) strunzone(this.netname_previous);
2207                 this.netname_previous = strzone(this.netname);
2208         }
2209
2210         // version nagging
2211         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2212         this.version_nagtime = 0;
2213         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2214             // git client
2215         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2216             // git server
2217             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2218         } else {
2219             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2220             if (r < 0) { // old client
2221                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2222             } else if (r > 0) { // old server
2223                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2224             }
2225         }
2226     }
2227
2228         // GOD MODE info
2229         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2230         {
2231                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2232                 this.max_armorvalue = 0;
2233         }
2234
2235         if (STAT(FROZEN, this) == 2)
2236         {
2237                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2238                 this.health = max(1, this.revive_progress * start_health);
2239                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2240
2241                 if (this.revive_progress >= 1)
2242                         Unfreeze(this);
2243         }
2244         else if (STAT(FROZEN, this) == 3)
2245         {
2246                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2247                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2248
2249                 if (this.health < 1)
2250                 {
2251                         if (this.vehicle)
2252                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2253                         if(this.event_damage)
2254                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2255                 }
2256                 else if (this.revive_progress <= 0)
2257                         Unfreeze(this);
2258         }
2259
2260         MUTATOR_CALLHOOK(PlayerPreThink, this);
2261
2262         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2263         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2264         {
2265                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2266                 {
2267                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2268                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2269                         {
2270                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2271                         }
2272                         else if(!it.owner)
2273                         {
2274                                 if(!it.team || SAME_TEAM(this, it))
2275                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2276                                 else if(autocvar_g_vehicles_steal)
2277                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2278                         }
2279                 });
2280
2281                 this.last_vehiclecheck = time + 1;
2282         }
2283
2284         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2285         {
2286                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2287                         PlayerUseKey(this);
2288                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2289         }
2290
2291         if (IS_REAL_CLIENT(this))
2292                 PrintWelcomeMessage(this);
2293
2294         if (IS_PLAYER(this)) {
2295                 CheckRules_Player(this);
2296
2297                 if (intermission_running) {
2298                         IntermissionThink(this);
2299                         return;
2300                 }
2301
2302                 if (timeout_status == TIMEOUT_ACTIVE) {
2303             // don't allow the player to turn around while game is paused
2304                         // FIXME turn this into CSQC stuff
2305                         this.v_angle = this.lastV_angle;
2306                         this.angles = this.lastV_angle;
2307                         this.fixangle = true;
2308                 }
2309
2310                 if (frametime) player_powerups(this);
2311
2312                 if (IS_DEAD(this)) {
2313                         if (this.personal && g_race_qualifying) {
2314                                 if (time > this.respawn_time) {
2315                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2316                                         respawn(this);
2317                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2318                                 }
2319                         } else {
2320                                 if (frametime) player_anim(this);
2321                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2322
2323                                 switch(this.deadflag)
2324                                 {
2325                                         case DEAD_DYING:
2326                                         {
2327                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2328                                                         this.deadflag = DEAD_RESPAWNING;
2329                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2330                                                         this.deadflag = DEAD_DEAD;
2331                                                 break;
2332                                         }
2333                                         case DEAD_DEAD:
2334                                         {
2335                                                 if (button_pressed)
2336                                                         this.deadflag = DEAD_RESPAWNABLE;
2337                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2338                                                         this.deadflag = DEAD_RESPAWNING;
2339                                                 break;
2340                                         }
2341                                         case DEAD_RESPAWNABLE:
2342                                         {
2343                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2344                                                         this.deadflag = DEAD_RESPAWNING;
2345                                                 break;
2346                                         }
2347                                         case DEAD_RESPAWNING:
2348                                         {
2349                                                 if (time > this.respawn_time)
2350                                                 {
2351                                                         this.respawn_time = time + 1; // only retry once a second
2352                                                         this.respawn_time_max = this.respawn_time;
2353                                                         respawn(this);
2354                                                 }
2355                                                 break;
2356                                         }
2357                                 }
2358
2359                                 ShowRespawnCountdown(this);
2360
2361                                 if (this.respawn_flags & RESPAWN_SILENT)
2362                                         STAT(RESPAWN_TIME, this) = 0;
2363                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2364                                 {
2365                                         if (time < this.respawn_time)
2366                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2367                                         else if (this.deadflag != DEAD_RESPAWNING)
2368                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2369                                 }
2370                                 else
2371                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2372                         }
2373
2374                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2375                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2376                                 STAT(RESPAWN_TIME, this) *= -1;
2377
2378                         return;
2379                 }
2380
2381                 this.prevorigin = this.origin;
2382
2383                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2384                 if (this.hook.state) {
2385                         do_crouch = false;
2386                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2387                         do_crouch = false;
2388                 } else if (this.vehicle) {
2389                         do_crouch = false;
2390                 } else if (STAT(FROZEN, this)) {
2391                         do_crouch = false;
2392         }
2393
2394                 if (do_crouch) {
2395                         if (!this.crouch) {
2396                                 this.crouch = true;
2397                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2398                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2399                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2400                         }
2401                 } else if (this.crouch) {
2402             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2403             if (!trace_startsolid) {
2404                 this.crouch = false;
2405                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2406                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2407             }
2408                 }
2409
2410                 FixPlayermodel(this);
2411
2412                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2413                 //if(frametime)
2414                 {
2415                         this.items &= ~this.items_added;
2416
2417                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2418                         //{
2419                                 //.entity weaponentity = weaponentities[slot];
2420                                 //W_WeaponFrame(this, weaponentity);
2421                         //}
2422                         .entity weaponentity = weaponentities[0]; // TODO
2423                         W_WeaponFrame(this, weaponentity);
2424
2425                         this.items_added = 0;
2426                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2427                 this.items_added |= IT_FUEL;
2428
2429                         this.items |= this.items_added;
2430                 }
2431
2432                 player_regen(this);
2433
2434                 // WEAPONTODO: Add a weapon request for this
2435                 // rot vortex charge to the charge limit
2436                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2437                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2438
2439                 if (frametime) player_anim(this);
2440
2441                 // secret status
2442                 secrets_setstatus(this);
2443
2444                 // monsters status
2445                 monsters_setstatus(this);
2446
2447                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2448         }
2449         else if (gameover) {
2450                 if (intermission_running) IntermissionThink(this);
2451                 return;
2452         }
2453         else if (IS_OBSERVER(this)) {
2454                 ObserverThink(this);
2455         }
2456         else if (IS_SPEC(this)) {
2457                 SpectatorThink(this);
2458         }
2459
2460         // WEAPONTODO: Add weapon request for this
2461         if (!zoomstate_set) {
2462                 SetZoomState(this,
2463                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2464                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2465                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2466                 );
2467     }
2468
2469         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2470         {
2471                 this.teamkill_soundtime = 0;
2472
2473                 entity e = this.teamkill_soundsource;
2474                 entity oldpusher = e.pusher;
2475                 e.pusher = this;
2476                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2477                 e.pusher = oldpusher;
2478         }
2479
2480         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2481                 this.taunt_soundtime = 0;
2482                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2483         }
2484
2485         target_voicescript_next(this);
2486
2487         // WEAPONTODO: Move into weaponsystem somehow
2488         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2489         if (PS(this).m_weapon == WEP_Null)
2490                 this.clip_load = this.clip_size = 0;
2491 }
2492
2493 void DrownPlayer(entity this)
2494 {
2495         if(IS_DEAD(this))
2496                 return;
2497
2498         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2499         {
2500                 if(this.air_finished < time)
2501                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2502                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2503                 this.dmg = 2;
2504         }
2505         else if (this.air_finished < time)
2506         {       // drown!
2507                 if (this.pain_finished < time)
2508                 {
2509                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2510                         this.pain_finished = time + 0.5;
2511                 }
2512         }
2513 }
2514
2515 .bool move_qcphysics;
2516
2517 void Player_Physics(entity this)
2518 {
2519         set_movetype(this, this.move_movetype);
2520
2521         if(!this.move_qcphysics)
2522                 return;
2523
2524         if(!frametime && !this.pm_frametime)
2525                 return;
2526
2527         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2528
2529         this.pm_frametime = 0;
2530 }
2531
2532 /*
2533 =============
2534 PlayerPostThink
2535
2536 Called every frame for each client after the physics are run
2537 =============
2538 */
2539 .float idlekick_lasttimeleft;
2540 void PlayerPostThink (entity this)
2541 {
2542         Player_Physics(this);
2543
2544         if (sv_maxidle > 0)
2545         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2546         if (IS_REAL_CLIENT(this))
2547         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2548         {
2549                 int totalClients = 0;
2550                 if(sv_maxidle_slots > 0)
2551                 {
2552                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2553                         {
2554                                 ++totalClients;
2555                         });
2556                 }
2557
2558                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2559                 { /* do nothing */ }
2560                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2561                 {
2562                         if (this.idlekick_lasttimeleft)
2563                         {
2564                                 this.idlekick_lasttimeleft = 0;
2565                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2566                         }
2567                 }
2568                 else
2569                 {
2570                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2571                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2572                                 if (!this.idlekick_lasttimeleft)
2573                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2574                         }
2575                         if (timeleft <= 0) {
2576                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2577                                 dropclient(this);
2578                                 return;
2579                         }
2580                         else if (timeleft <= 10) {
2581                                 if (timeleft != this.idlekick_lasttimeleft) {
2582                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2583                 }
2584                                 this.idlekick_lasttimeleft = timeleft;
2585                         }
2586                 }
2587         }
2588
2589         CheatFrame(this);
2590
2591         //CheckPlayerJump();
2592
2593         if (IS_PLAYER(this)) {
2594                 DrownPlayer(this);
2595                 CheckRules_Player(this);
2596                 UpdateChatBubble(this);
2597                 if (this.impulse) ImpulseCommands(this);
2598                 if (intermission_running) return; // intermission or finale
2599                 GetPressedKeys(this);
2600         }
2601
2602         if (this.waypointsprite_attachedforcarrier) {
2603             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2604                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2605     }
2606
2607         playerdemo_write(this);
2608
2609         CSQCMODEL_AUTOUPDATE(this);
2610 }