qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if(GetResource(this, RES_HEALTH) >= 1)
 255                 {
 256                         // despawn effect
 257                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 258                 }
 259
 260                 // was a player, recount votes and ready status
 261                 if(IS_REAL_CLIENT(this))
 262                 {
 263                         if (vote_called) { VoteCount(false); }
 264                         ReadyCount();
 265                 }
 266                 entcs_update_players(this);
 267         }
 268
 269         entity spot = SelectSpawnPoint(this, true);
 270         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 271         this.angles = vec2(spot.angles);
 272         this.fixangle = true;
 273         // offset it so that the spectator spawns higher off the ground, looks better this way
 274         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         WaypointSprite_PlayerDead(this);
 308
 309         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 310                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321         STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.effects = 0;
 335         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 336         this.pauserotarmor_finished = 0;
 337         this.pauserothealth_finished = 0;
 338         this.pauseregen_finished = 0;
 339         this.damageforcescale = 0;
 340         this.death_time = 0;
 341         this.respawn_flags = 0;
 342         this.respawn_time = 0;
 343         STAT(RESPAWN_TIME, this) = 0;
 344         this.alpha = 0;
 345         this.scale = 0;
 346         this.fade_time = 0;
 347         this.pain_finished = 0;
 348         STAT(STRENGTH_FINISHED, this) = 0;
 349         STAT(INVINCIBLE_FINISHED, this) = 0;
 350         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.fire_endtime = -1;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void ResetPlayerResources(entity this)
 538 {
 539         if (warmup_stage) {
 540                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 541                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 542                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 543                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 544                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 545                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 546                 SetResource(this, RES_HEALTH, warmup_start_health);
 547                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 548                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 549         } else {
 550                 SetResource(this, RES_SHELLS, start_ammo_shells);
 551                 SetResource(this, RES_BULLETS, start_ammo_nails);
 552                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 553                 SetResource(this, RES_CELLS, start_ammo_cells);
 554                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 555                 SetResource(this, RES_FUEL, start_ammo_fuel);
 556                 SetResource(this, RES_HEALTH, start_health);
 557                 SetResource(this, RES_ARMOR, start_armorvalue);
 558                 STAT(WEAPONS, this) = start_weapons;
 559                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 560                 {
 561                         GiveRandomWeapons(this, random_start_weapons_count,
 562                                 autocvar_g_random_start_weapons, random_start_ammo);
 563                 }
 564         }
 565 }
 566
 567 void PutPlayerInServer(entity this)
 568 {
 569         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 570
 571         PlayerState_attach(this);
 572         accuracy_resend(this);
 573
 574         if (this.team < 0)
 575                 TeamBalance_JoinBestTeam(this);
 576
 577         entity spot = SelectSpawnPoint(this, false);
 578         if (!spot) {
 579                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 580                 return; // spawn failed
 581         }
 582
 583         TRANSMUTE(Player, this);
 584
 585         CS(this).wasplayer = true;
 586         this.iscreature = true;
 587         this.teleportable = TELEPORT_NORMAL;
 588         if(!this.damagedbycontents)
 589                 IL_PUSH(g_damagedbycontents, this);
 590         this.damagedbycontents = true;
 591         set_movetype(this, MOVETYPE_WALK);
 592         this.solid = SOLID_SLIDEBOX;
 593         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 594         if (autocvar_g_playerclip_collisions)
 595                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 596         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 597                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 598         this.frags = FRAGS_PLAYER;
 599         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 600         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 601         if (autocvar__notarget)
 602                 this.flags |= FL_NOTARGET;
 603         this.takedamage = DAMAGE_AIM;
 604         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 605
 606         ResetPlayerResources(this);
 607
 608         SetSpectatee_status(this, 0);
 609
 610         PS(this).dual_weapons = '0 0 0';
 611
 612         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 613
 614         this.items = start_items;
 615
 616         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 617         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 618         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 619         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 620         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 621         if (!sv_ready_restart_after_countdown && time < game_starttime)
 622         {
 623                 float f = game_starttime - time;
 624                 this.spawnshieldtime += f;
 625                 this.pauserotarmor_finished += f;
 626                 this.pauserothealth_finished += f;
 627                 this.pauseregen_finished += f;
 628         }
 629
 630         this.damageforcescale = autocvar_g_player_damageforcescale;
 631         this.death_time = 0;
 632         this.respawn_flags = 0;
 633         this.respawn_time = 0;
 634         STAT(RESPAWN_TIME, this) = 0;
 635         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 636         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(STRENGTH_FINISHED, this) = 0;
 661         STAT(INVINCIBLE_FINISHED, this) = 0;
 662         this.fire_endtime = -1;
 663         STAT(REVIVE_PROGRESS, this) = 0;
 664         this.revival_time = 0;
 665
 666         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 667         STAT(BUFFS, this) = 0;
 668         STAT(BUFF_TIME, this) = 0;
 669
 670         STAT(AIR_FINISHED, this) = 0;
 671         this.waterlevel = WATERLEVEL_NONE;
 672         this.watertype = CONTENT_EMPTY;
 673
 674         entity spawnevent = new_pure(spawnevent);
 675         spawnevent.owner = this;
 676         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 677
 678         // Cut off any still running player sounds.
 679         stopsound(this, CH_PLAYER_SINGLE);
 680
 681         this.model = "";
 682         FixPlayermodel(this);
 683         this.drawonlytoclient = NULL;
 684
 685         this.viewloc = NULL;
 686
 687         for(int slot = 0; slot < MAX_AXH; ++slot)
 688         {
 689                 entity axh = this.(AuxiliaryXhair[slot]);
 690                 this.(AuxiliaryXhair[slot]) = NULL;
 691
 692                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 693                         delete(axh);
 694         }
 695
 696         this.spawnpoint_targ = NULL;
 697
 698         UNSET_DUCKED(this);
 699         this.view_ofs = STAT(PL_VIEW_OFS, this);
 700         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 701         this.spawnorigin = spot.origin;
 702         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 703         // don't reset back to last position, even if new position is stuck in solid
 704         this.oldorigin = this.origin;
 705         if(this.conveyor)
 706                 IL_REMOVE(g_conveyed, this);
 707         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 708         if(this.swampslug)
 709                 IL_REMOVE(g_swamped, this);
 710         this.swampslug = NULL;
 711         this.swamp_interval = 0;
 712         if(this.ladder_entity)
 713                 IL_REMOVE(g_ladderents, this);
 714         this.ladder_entity = NULL;
 715         IL_EACH(g_counters, it.realowner == this,
 716         {
 717                 delete(it);
 718         });
 719         STAT(HUD, this) = HUD_NORMAL;
 720
 721         this.event_damage = PlayerDamage;
 722         this.event_heal = PlayerHeal;
 723
 724         this.draggable = func_null;
 725
 726         if(!this.bot_attack)
 727                 IL_PUSH(g_bot_targets, this);
 728         this.bot_attack = true;
 729         if(!this.monster_attack)
 730                 IL_PUSH(g_monster_targets, this);
 731         this.monster_attack = true;
 732         navigation_dynamicgoal_init(this, false);
 733
 734         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 735
 736         // player was spectator
 737         if (CS(this).killcount == FRAGS_SPECTATOR) {
 738                 PlayerScore_Clear(this);
 739                 CS(this).killcount = 0;
 740                 CS(this).startplaytime = time;
 741         }
 742
 743         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 CL_SpawnWeaponentity(this, weaponentity);
 747         }
 748         this.alpha = default_player_alpha;
 749         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 750         this.exteriorweaponentity.alpha = default_weapon_alpha;
 751
 752         this.speedrunning = false;
 753
 754         this.counter_cnt = 0;
 755         this.fragsfilter_cnt = 0;
 756
 757         target_voicescript_clear(this);
 758
 759         // reset fields the weapons may use
 760         FOREACH(Weapons, true, {
 761                 it.wr_resetplayer(it, this);
 762                         // reload all reloadable weapons
 763                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 764                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765                         {
 766                                 .entity weaponentity = weaponentities[slot];
 767                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 768                         }
 769                 }
 770         });
 771
 772         {
 773                 string s = spot.target;
 774                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 775                         spot.target = string_null;
 776                 SUB_UseTargets(spot, this, NULL);
 777                 if(g_assault || g_race)
 778                         spot.target = s;
 779         }
 780
 781         Unfreeze(this, false);
 782
 783         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 784
 785         if (autocvar_spawn_debug)
 786         {
 787                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 788                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 789         }
 790
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 entity w_ent = this.(weaponentity);
 795                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 796                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 797                 else
 798                         w_ent.m_switchweapon = WEP_Null;
 799                 w_ent.m_weapon = WEP_Null;
 800                 w_ent.weaponname = "";
 801                 w_ent.m_switchingweapon = WEP_Null;
 802                 w_ent.cnt = -1;
 803         }
 804
 805         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 806
 807         if (CS(this).impulse) ImpulseCommands(this);
 808
 809         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 810         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811         {
 812                 .entity weaponentity = weaponentities[slot];
 813                 W_WeaponFrame(this, weaponentity);
 814         }
 815
 816         if (!warmup_stage && !this.alivetime)
 817                 this.alivetime = time;
 818
 819         antilag_clear(this, CS(this));
 820 }
 821
 822 /** Called when a client spawns in the server */
 823 void PutClientInServer(entity this)
 824 {
 825         if (IS_BOT_CLIENT(this)) {
 826                 TRANSMUTE(Player, this);
 827         } else if (IS_REAL_CLIENT(this)) {
 828                 msg_entity = this;
 829                 WriteByte(MSG_ONE, SVC_SETVIEW);
 830                 WriteEntity(MSG_ONE, this);
 831         }
 832         if (game_stopped)
 833                 TRANSMUTE(Observer, this);
 834
 835         SetSpectatee(this, NULL);
 836
 837         // reset player keys
 838         if(PS(this))
 839                 PS(this).itemkeys = 0;
 840
 841         MUTATOR_CALLHOOK(PutClientInServer, this);
 842
 843         if (IS_OBSERVER(this)) {
 844                 PutObserverInServer(this);
 845         } else if (IS_PLAYER(this)) {
 846                 PutPlayerInServer(this);
 847         }
 848         // send team names
 849         if(teamplay && IS_REAL_CLIENT(this))
 850                 send_TeamNames(MSG_ONE, this);
 851         bot_relinkplayerlist();
 852 }
 853
 854 // TODO do we need all these fields, or should we stop autodetecting runtime
 855 // changes and just have a console command to update this?
 856 bool ClientInit_SendEntity(entity this, entity to, int sf)
 857 {
 858         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 859         return = true;
 860         msg_entity = to;
 861         // MSG_INIT replacement
 862         // TODO: make easier to use
 863         Registry_send_all();
 864         W_PROP_reload(MSG_ONE, to);
 865         ClientInit_misc(this);
 866         MUTATOR_CALLHOOK(Ent_Init);
 867 }
 868 void ClientInit_misc(entity this)
 869 {
 870         int channel = MSG_ONE;
 871         WriteHeader(channel, ENT_CLIENT_INIT);
 872         WriteByte(channel, g_nexball_meter_period * 32);
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 875         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 876         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 879         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 880         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 881
 882         if(autocvar_sv_foginterval && world.fog != "")
 883                 WriteString(channel, world.fog);
 884         else
 885                 WriteString(channel, "");
 886         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 887         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 888         WriteByte(channel, serverflags);
 889         WriteCoord(channel, autocvar_g_trueaim_minrange);
 890
 891         // z411 send full hostname
 892         WriteString(channel, (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname));
 893         WriteString(channel, autocvar_sv_motd_permanent);
 894 }
 895
 896 void ClientInit_CheckUpdate(entity this)
 897 {
 898         this.nextthink = time;
 899         if(this.count != autocvar_g_balance_armor_blockpercent)
 900         {
 901                 this.count = autocvar_g_balance_armor_blockpercent;
 902                 this.SendFlags |= 1;
 903         }
 904         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 905         {
 906                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 907                 this.SendFlags |= 1;
 908         }
 909 }
 910
 911 void ClientInit_Spawn()
 912 {
 913         entity e = new_pure(clientinit);
 914         setthink(e, ClientInit_CheckUpdate);
 915         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 916
 917         ClientInit_CheckUpdate(e);
 918 }
 919
 920 /*
 921 =============
 922 SetNewParms
 923 =============
 924 */
 925 void SetNewParms ()
 926 {
 927         // initialize parms for a new player
 928         parm1 = -(86400 * 366);
 929
 930         MUTATOR_CALLHOOK(SetNewParms);
 931 }
 932
 933 /*
 934 =============
 935 SetChangeParms
 936 =============
 937 */
 938 void SetChangeParms (entity this)
 939 {
 940         // save parms for level change
 941         parm1 = CS(this).parm_idlesince - time;
 942
 943         MUTATOR_CALLHOOK(SetChangeParms);
 944 }
 945
 946 /*
 947 =============
 948 DecodeLevelParms
 949 =============
 950 */
 951 void DecodeLevelParms(entity this)
 952 {
 953         // load parms
 954         CS(this).parm_idlesince = parm1;
 955         if (CS(this).parm_idlesince == -(86400 * 366))
 956                 CS(this).parm_idlesince = time;
 957
 958         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 959         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 960
 961         MUTATOR_CALLHOOK(DecodeLevelParms);
 962 }
 963
 964 void FixClientCvars(entity e)
 965 {
 966         // send prediction settings to the client
 967         stuffcmd(e, "\nin_bindmap 0 0\n");
 968         if(autocvar_g_antilag == 3) // client side hitscan
 969                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 970         if(autocvar_sv_gentle)
 971                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 972
 973         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 974         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 975
 976         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 977
 978         MUTATOR_CALLHOOK(FixClientCvars, e);
 979 }
 980
 981 bool findinlist_abbrev(string tofind, string list)
 982 {
 983         if(list == "" || tofind == "")
 984                 return false; // empty list or search, just return
 985
 986         // this function allows abbreviated strings!
 987         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 988         {
 989                 return true;
 990         });
 991
 992         return false;
 993 }
 994
 995 bool PlayerInIPList(entity p, string iplist)
 996 {
 997         // some safety checks (never allow local?)
 998         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 999                 return false;
1000
1001         return findinlist_abbrev(p.netaddress, iplist);
1002 }
1003
1004 bool PlayerInIDList(entity p, string idlist)
1005 {
1006         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1007         if(!p.crypto_idfp)
1008                 return false;
1009
1010         return findinlist_abbrev(p.crypto_idfp, idlist);
1011 }
1012
1013 bool PlayerInList(entity player, string list)
1014 {
1015         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1016 }
1017
1018 #ifdef DP_EXT_PRECONNECT
1019 /*
1020 =============
1021 ClientPreConnect
1022
1023 Called once (not at each match start) when a client begins a connection to the server
1024 =============
1025 */
1026 void ClientPreConnect(entity this)
1027 {
1028         if(autocvar_sv_eventlog)
1029         {
1030                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1031                         this.playerid,
1032                         etof(this),
1033                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1034                 ));
1035         }
1036 }
1037 #endif
1038
1039 string GetClientVersionMessage(entity this)
1040 {
1041         if (CS(this).version_mismatch) {
1042                 if(CS(this).version < autocvar_gameversion) {
1043                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1044                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1045                 } else {
1046                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1047                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1048                 }
1049         } else {
1050                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1051         }
1052 }
1053
1054 string getwelcomemessage(entity this)
1055 {
1056         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1057         string modifications = M_ARGV(0, string);
1058
1059         if(g_weaponarena)
1060         {
1061                 if(g_weaponarena_random)
1062                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1063                 else
1064                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1065         }
1066         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1067                 modifications = strcat(modifications, ", No start weapons");
1068         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1069                 modifications = strcat(modifications, ", Low gravity");
1070         if(g_weapon_stay && !g_cts)
1071                 modifications = strcat(modifications, ", Weapons stay");
1072         if(autocvar_g_jetpack)
1073                 modifications = strcat(modifications, ", Jet pack");
1074         if(autocvar_g_powerups == 0)
1075                 modifications = strcat(modifications, ", No powerups");
1076         if(autocvar_g_powerups > 0)
1077                 modifications = strcat(modifications, ", Powerups");
1078         modifications = substring(modifications, 2, strlen(modifications) - 2);
1079
1080         //string versionmessage = GetClientVersionMessage(this);
1081         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1082         //string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1083         string s = (autocvar_hostname_full != "" ? autocvar_hostname_full : autocvar_hostname);
1084
1085         s = strcat(s, "^8\n^7", gamemode_name);
1086
1087         if(modifications != "")
1088                 s = strcat(s, "^7 | ^3", modifications);
1089
1090         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1091         {
1092                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1093                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1094         }
1095
1096         if (cache_mutatormsg != "") {
1097                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1098         }
1099
1100         string mutator_msg = "";
1101         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1102         mutator_msg = M_ARGV(0, string);
1103
1104         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1105
1106         string motd = autocvar_sv_motd;
1107         if (motd != "") {
1108                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1109         }
1110         return s;
1111 }
1112
1113 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1114
1115 /**
1116 =============
1117 ClientConnect
1118
1119 Called when a client connects to the server
1120 =============
1121 */
1122 void ClientConnect(entity this)
1123 {
1124         if (Ban_MaybeEnforceBanOnce(this)) return;
1125         assert(!IS_CLIENT(this), return);
1126         this.flags |= FL_CLIENT;
1127         assert(player_count >= 0, player_count = 0);
1128
1129         TRANSMUTE(Client, this);
1130         CS(this).version_nagtime = time + 10 + random() * 10;
1131
1132         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1133
1134         bot_clientconnect(this);
1135
1136         Player_DetermineForcedTeam(this);
1137
1138         TRANSMUTE(Observer, this);
1139
1140         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1141
1142         // always track bots, don't ask for cl_allow_uidtracking
1143         if (IS_BOT_CLIENT(this))
1144                 PlayerStats_GameReport_AddPlayer(this);
1145         else
1146                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1147
1148         if (autocvar_sv_eventlog)
1149                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1150
1151         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1152
1153         stuffcmd(this, clientstuff, "\n");
1154         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1155
1156         FixClientCvars(this);
1157
1158         // get version info from player
1159         stuffcmd(this, "cmd clientversion $gameversion\n");
1160
1161         // notify about available teams
1162         if (teamplay)
1163         {
1164                 entity balance = TeamBalance_CheckAllowedTeams(this);
1165                 int t = TeamBalance_GetAllowedTeams(balance);
1166                 TeamBalance_Destroy(balance);
1167                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1168         }
1169         else
1170         {
1171                 stuffcmd(this, "set _teams_available 0\n");
1172         }
1173
1174         bot_relinkplayerlist();
1175
1176         CS(this).spectatortime = time;
1177         if (blockSpectators)
1178         {
1179                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1180         }
1181
1182         CS(this).jointime = time;
1183
1184         if (IS_REAL_CLIENT(this))
1185         {
1186                 if (g_weaponarena_weapons == WEPSET(TUBA))
1187                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1188         }
1189
1190         if (!autocvar_sv_foginterval && world.fog != "")
1191                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1192
1193         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1194                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1195                         send_CSQC_teamnagger();
1196
1197         CSQCMODEL_AUTOINIT(this);
1198
1199         CS(this).model_randomizer = random();
1200
1201         if (IS_REAL_CLIENT(this))
1202                 sv_notice_join(this);
1203
1204         this.move_qcphysics = autocvar_sv_qcphysics;
1205
1206         // update physics stats (players can spawn before physics runs)
1207         Physics_UpdateStats(this);
1208
1209         IL_EACH(g_initforplayer, it.init_for_player, {
1210                 it.init_for_player(it, this);
1211         });
1212
1213         Handicap_Initialize(this);
1214
1215         MUTATOR_CALLHOOK(ClientConnect, this);
1216
1217         if (IS_REAL_CLIENT(this))
1218         {
1219                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1220                 {
1221                         CS(this).motd_actived_time = -1;
1222                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1223                 }
1224         }
1225 }
1226 /*
1227 =============
1228 ClientDisconnect
1229
1230 Called when a client disconnects from the server
1231 =============
1232 */
1233 .entity chatbubbleentity;
1234 void player_powerups_remove_all(entity this);
1235
1236 void ClientDisconnect(entity this)
1237 {
1238         assert(IS_CLIENT(this), return);
1239
1240         PlayerStats_GameReport_FinalizePlayer(this);
1241         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1242         if (CS(this).active_minigame) part_minigame(this);
1243         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1244
1245         if (autocvar_sv_eventlog)
1246                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1247
1248         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1249
1250         if(IS_SPEC(this))
1251                 SetSpectatee(this, NULL);
1252
1253         MUTATOR_CALLHOOK(ClientDisconnect, this);
1254
1255         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1256         strfree(CS_CVAR(this).weaponorder_byimpulse);
1257         ClientState_detach(this);
1258
1259         Portal_ClearAll(this);
1260
1261         Unfreeze(this, false);
1262
1263         RemoveGrapplingHooks(this);
1264
1265         // Here, everything has been done that requires this player to be a client.
1266
1267         this.flags &= ~FL_CLIENT;
1268
1269         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1270         if (this.killindicator) delete(this.killindicator);
1271
1272         IL_EACH(g_counters, it.realowner == this,
1273         {
1274                 delete(it);
1275         });
1276
1277         WaypointSprite_PlayerGone(this);
1278
1279         bot_relinkplayerlist();
1280
1281         strfree(this.clientstatus);
1282         if (this.personal) delete(this.personal);
1283
1284         this.playerid = 0;
1285         ReadyCount();
1286         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1287
1288         player_powerups_remove_all(this); // stop powerup sound
1289
1290         ONREMOVE(this);
1291 }
1292
1293 void ChatBubbleThink(entity this)
1294 {
1295         this.nextthink = time;
1296         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1297         {
1298                 if(this.owner) // but why can that ever be NULL?
1299                         this.owner.chatbubbleentity = NULL;
1300                 delete(this);
1301                 return;
1302         }
1303
1304         this.mdl = "";
1305
1306         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1307         {
1308                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1309                         this.mdl = "models/sprites/minigame_busy.iqm";
1310                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1311                         this.mdl = "models/misc/chatbubble.spr";
1312         }
1313
1314         if ( this.model != this.mdl )
1315                 _setmodel(this, this.mdl);
1316
1317 }
1318
1319 void UpdateChatBubble(entity this)
1320 {
1321         if (this.alpha < 0)
1322                 return;
1323         // spawn a chatbubble entity if needed
1324         if (!this.chatbubbleentity)
1325         {
1326                 this.chatbubbleentity = new(chatbubbleentity);
1327                 this.chatbubbleentity.owner = this;
1328                 this.chatbubbleentity.exteriormodeltoclient = this;
1329                 setthink(this.chatbubbleentity, ChatBubbleThink);
1330                 this.chatbubbleentity.nextthink = time;
1331                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1332                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1333                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1334                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1335                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1336                 //this.chatbubbleentity.model = "";
1337                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1338         }
1339 }
1340
1341 void calculate_player_respawn_time(entity this)
1342 {
1343         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1344                 return;
1345
1346         float gametype_setting_tmp;
1347         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1348         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1349         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1350         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1351         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1352         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1353
1354         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1355         if (teamplay)
1356         {
1357                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1358                         if(it.team == this.team)
1359                                 ++pcount;
1360                 });
1361                 if (sdelay_small_count == 0)
1362                         sdelay_small_count = 1;
1363                 if (sdelay_large_count == 0)
1364                         sdelay_large_count = 1;
1365         }
1366         else
1367         {
1368                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1369                         ++pcount;
1370                 });
1371                 if (sdelay_small_count == 0)
1372                 {
1373                         if (IS_INDEPENDENT_PLAYER(this))
1374                         {
1375                                 // Players play independently. No point in requiring enemies.
1376                                 sdelay_small_count = 1;
1377                         }
1378                         else
1379                         {
1380                                 // Players play AGAINST each other. Enemies required.
1381                                 sdelay_small_count = 2;
1382                         }
1383                 }
1384                 if (sdelay_large_count == 0)
1385                 {
1386                         if (IS_INDEPENDENT_PLAYER(this))
1387                         {
1388                                 // Players play independently. No point in requiring enemies.
1389                                 sdelay_large_count = 1;
1390                         }
1391                         else
1392                         {
1393                                 // Players play AGAINST each other. Enemies required.
1394                                 sdelay_large_count = 2;
1395                         }
1396                 }
1397         }
1398
1399         float sdelay;
1400
1401         if (pcount <= sdelay_small_count)
1402                 sdelay = sdelay_small;
1403         else if (pcount >= sdelay_large_count)
1404                 sdelay = sdelay_large;
1405         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1406                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1407
1408         if(waves)
1409                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1410         else
1411                 this.respawn_time = time + sdelay;
1412
1413         if(sdelay < sdelay_max)
1414                 this.respawn_time_max = time + sdelay_max;
1415         else
1416                 this.respawn_time_max = this.respawn_time;
1417
1418         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1419                 this.respawn_countdown = 10; // first number to count down from is 10
1420         else
1421                 this.respawn_countdown = -1; // do not count down
1422
1423         if(autocvar_g_forced_respawn)
1424                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1425 }
1426
1427 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1428 // added to the model skins
1429 /*void UpdateColorModHack()
1430 {
1431         float c;
1432         c = this.clientcolors & 15;
1433         // LordHavoc: only bothering to support white, green, red, yellow, blue
1434              if (!teamplay) this.colormod = '0 0 0';
1435         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1436         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1437         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1438         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1439         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1440         else this.colormod = '1 1 1';
1441 }*/
1442
1443 void respawn(entity this)
1444 {
1445         bool damagedbycontents_prev = this.damagedbycontents;
1446         if(this.alpha >= 0)
1447         {
1448                 if(autocvar_g_respawn_ghosts)
1449                 {
1450                         this.solid = SOLID_NOT;
1451                         this.takedamage = DAMAGE_NO;
1452                         this.damagedbycontents = false;
1453                         set_movetype(this, MOVETYPE_FLY);
1454                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1455                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1456                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1457                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1458                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1459                         if(autocvar_g_respawn_ghosts_time > 0)
1460                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1461                 }
1462                 else
1463                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1464         }
1465
1466         CopyBody(this, 1);
1467         this.damagedbycontents = damagedbycontents_prev;
1468
1469         this.effects |= EF_NODRAW; // prevent another CopyBody
1470         PutClientInServer(this);
1471 }
1472
1473 void play_countdown(entity this, float finished, Sound samp)
1474 {
1475         TC(Sound, samp);
1476         if(IS_REAL_CLIENT(this))
1477                 if(floor(finished - time - frametime) != floor(finished - time))
1478                         if(finished - time < 6)
1479                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1480 }
1481
1482 void player_powerups_remove_all(entity this)
1483 {
1484         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1485         {
1486                 // don't play the poweroff sound when the game restarts or the player disconnects
1487                 if (time > game_starttime + 1 && IS_CLIENT(this))
1488                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1489                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1490                 this.items &= ~ITEM_Strength.m_itemid;
1491                 this.items &= ~ITEM_Shield.m_itemid;
1492                 this.items -= (this.items & IT_SUPERWEAPON);
1493         }
1494 }
1495
1496 void player_powerups(entity this)
1497 {
1498         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1499                 this.modelflags |= MF_ROCKET;
1500         else
1501                 this.modelflags &= ~MF_ROCKET;
1502
1503         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1504
1505         if (IS_DEAD(this))
1506                 player_powerups_remove_all(this);
1507
1508         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1509                 return;
1510
1511         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1512         int items_prev = this.items;
1513
1514         Fire_ApplyDamage(this);
1515         Fire_ApplyEffect(this);
1516
1517         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1518         {
1519                 if (this.items & ITEM_Strength.m_itemid)
1520                 {
1521                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1522                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1523                         if (time > STAT(STRENGTH_FINISHED, this))
1524                         {
1525                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1526                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1527                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1528                         }
1529                 }
1530                 else
1531                 {
1532                         if (time < STAT(STRENGTH_FINISHED, this))
1533                         {
1534                                 this.items = this.items | ITEM_Strength.m_itemid;
1535                                 if(!g_cts)
1536                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1537                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1538                         }
1539                 }
1540                 if (this.items & ITEM_Shield.m_itemid)
1541                 {
1542                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1543                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1544                         if (time > STAT(INVINCIBLE_FINISHED, this))
1545                         {
1546                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1547                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1548                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1549                         }
1550                 }
1551                 else
1552                 {
1553                         if (time < STAT(INVINCIBLE_FINISHED, this))
1554                         {
1555                                 this.items = this.items | ITEM_Shield.m_itemid;
1556                                 if(!g_cts)
1557                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1558                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1559                         }
1560                 }
1561                 if (this.items & IT_SUPERWEAPON)
1562                 {
1563                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1564                         {
1565                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1566                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1567                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1568                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1569                         }
1570                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1571                         {
1572                                 // don't let them run out
1573                         }
1574                         else
1575                         {
1576                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1577                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1578                                 {
1579                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1580                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1581                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1582                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1583                                 }
1584                         }
1585                 }
1586                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1587                 {
1588                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1589                         {
1590                                 this.items = this.items | IT_SUPERWEAPON;
1591                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1592                                 {
1593                                         if(!g_cts)
1594                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1595                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1596                                 }
1597                         }
1598                         else
1599                         {
1600                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1601                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1602                         }
1603                 }
1604                 else
1605                 {
1606                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1607                 }
1608         }
1609
1610         if(autocvar_g_nodepthtestplayers)
1611                 this.effects = this.effects | EF_NODEPTHTEST;
1612
1613         if(autocvar_g_fullbrightplayers)
1614                 this.effects = this.effects | EF_FULLBRIGHT;
1615
1616         if (time >= game_starttime)
1617         if (time < this.spawnshieldtime)
1618                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1619
1620         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1621 }
1622
1623 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1624 {
1625         if(current > stable)
1626                 return current;
1627         else if(current > stable - 0.25) // when close enough, "snap"
1628                 return stable;
1629         else
1630                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1631 }
1632
1633 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1634 {
1635         if(current < stable)
1636                 return current;
1637         else if(current < stable + 0.25) // when close enough, "snap"
1638                 return stable;
1639         else
1640                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1641 }
1642
1643 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1644 {
1645         float old = GetResource(this, res);
1646         float current = old;
1647         if(current > rotstable)
1648         {
1649                 if(rotframetime > 0)
1650                 {
1651                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1652                         current = max(rotstable, current - rotlinear * rotframetime);
1653                 }
1654         }
1655         else if(current < regenstable)
1656         {
1657                 if(regenframetime > 0)
1658                 {
1659                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1660                         current = min(regenstable, current + regenlinear * regenframetime);
1661                 }
1662         }
1663
1664         float limit = GetResourceLimit(this, res) * limit_mod;
1665         if(current > limit)
1666                 current = limit;
1667
1668         if (current != old)
1669                 SetResource(this, res, current);
1670 }
1671
1672 void player_regen(entity this)
1673 {
1674         float max_mod, regen_mod, rot_mod, limit_mod;
1675         max_mod = regen_mod = rot_mod = limit_mod = 1;
1676
1677         float regen_health = autocvar_g_balance_health_regen;
1678         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1679         float regen_health_rot = autocvar_g_balance_health_rot;
1680         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1681         float regen_health_stable = autocvar_g_balance_health_regenstable;
1682         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1683         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1684                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1685         max_mod = M_ARGV(1, float);
1686         regen_mod = M_ARGV(2, float);
1687         rot_mod = M_ARGV(3, float);
1688         limit_mod = M_ARGV(4, float);
1689         regen_health = M_ARGV(5, float);
1690         regen_health_linear = M_ARGV(6, float);
1691         regen_health_rot = M_ARGV(7, float);
1692         regen_health_rotlinear = M_ARGV(8, float);
1693         regen_health_stable = M_ARGV(9, float);
1694         regen_health_rotstable = M_ARGV(10, float);
1695
1696         if(!mutator_returnvalue)
1697         if(!STAT(FROZEN, this))
1698         {
1699                 float maxa = autocvar_g_balance_armor_rotstable;
1700                 float mina = autocvar_g_balance_armor_regenstable;
1701
1702                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1703                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1704                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1705
1706                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1707                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1708                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1709         }
1710
1711         // if player rotted to death...  die!
1712         // check this outside above checks, as player may still be able to rot to death
1713         if(GetResource(this, RES_HEALTH) < 1)
1714         {
1715                 if(this.vehicle)
1716                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1717                 if(this.event_damage)
1718                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1719         }
1720
1721         if (!(this.items & IT_UNLIMITED_AMMO))
1722         {
1723                 float maxf = autocvar_g_balance_fuel_rotstable;
1724                 float minf = autocvar_g_balance_fuel_regenstable;
1725
1726                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1727                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1728                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1729         }
1730 }
1731
1732 bool zoomstate_set;
1733 void SetZoomState(entity this, float newzoom)
1734 {
1735         if(newzoom != CS(this).zoomstate)
1736         {
1737                 CS(this).zoomstate = newzoom;
1738                 ClientData_Touch(this);
1739         }
1740         zoomstate_set = true;
1741 }
1742
1743 void GetPressedKeys(entity this)
1744 {
1745         MUTATOR_CALLHOOK(GetPressedKeys, this);
1746         if (game_stopped)
1747         {
1748                 CS(this).pressedkeys = 0;
1749                 STAT(PRESSED_KEYS, this) = 0;
1750                 return;
1751         }
1752
1753         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1754         int keys = STAT(PRESSED_KEYS, this);
1755         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1756         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1757         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1758         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1759
1760         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1761         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1762         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1763         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1764         CS(this).pressedkeys = keys; // store for other users
1765
1766         STAT(PRESSED_KEYS, this) = keys;
1767 }
1768
1769 /*
1770 ======================
1771 spectate mode routines
1772 ======================
1773 */
1774
1775 void SpectateCopy(entity this, entity spectatee)
1776 {
1777         TC(Client, this); TC(Client, spectatee);
1778
1779         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1780         PS(this) = PS(spectatee);
1781         this.armortype = spectatee.armortype;
1782         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1783         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1784         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1785         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1786         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1787         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1788         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1789         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1790         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1791         CS(this).impulse = 0;
1792         this.disableclientprediction = 1; // no need to run prediction on a spectator
1793         this.items = spectatee.items;
1794         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1795         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1796         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1797         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1798         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1799         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1800         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1801         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1802         this.punchangle = spectatee.punchangle;
1803         this.view_ofs = spectatee.view_ofs;
1804         this.velocity = spectatee.velocity;
1805         this.dmg_take = spectatee.dmg_take;
1806         this.dmg_save = spectatee.dmg_save;
1807         this.dmg_inflictor = spectatee.dmg_inflictor;
1808         this.v_angle = spectatee.v_angle;
1809         this.angles = spectatee.v_angle;
1810         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1811         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1812         this.viewloc = spectatee.viewloc;
1813         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1814                 this.fixangle = true;
1815         setorigin(this, spectatee.origin);
1816         setsize(this, spectatee.mins, spectatee.maxs);
1817         SetZoomState(this, CS(spectatee).zoomstate);
1818
1819     anticheat_spectatecopy(this, spectatee);
1820         STAT(HUD, this) = STAT(HUD, spectatee);
1821         if(spectatee.vehicle)
1822     {
1823         this.angles = spectatee.v_angle;
1824
1825         //this.fixangle = false;
1826         //this.velocity = spectatee.vehicle.velocity;
1827         this.vehicle_health = spectatee.vehicle_health;
1828         this.vehicle_shield = spectatee.vehicle_shield;
1829         this.vehicle_energy = spectatee.vehicle_energy;
1830         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1831         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1832         this.vehicle_reload1 = spectatee.vehicle_reload1;
1833         this.vehicle_reload2 = spectatee.vehicle_reload2;
1834
1835         //msg_entity = this;
1836
1837        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1838             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1839            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1840            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1841
1842         //WriteByte (MSG_ONE, SVC_SETVIEW);
1843         //    WriteEntity(MSG_ONE, this);
1844         //makevectors(spectatee.v_angle);
1845         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1846     }
1847 }
1848
1849 bool SpectateUpdate(entity this)
1850 {
1851         if(!this.enemy)
1852                 return false;
1853
1854         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1855         {
1856                 SetSpectatee(this, NULL);
1857                 return false;
1858         }
1859
1860         SpectateCopy(this, this.enemy);
1861
1862         return true;
1863 }
1864
1865 bool SpectateSet(entity this)
1866 {
1867         if(!IS_PLAYER(this.enemy))
1868                 return false;
1869
1870         ClientData_Touch(this.enemy);
1871
1872         msg_entity = this;
1873         WriteByte(MSG_ONE, SVC_SETVIEW);
1874         WriteEntity(MSG_ONE, this.enemy);
1875         set_movetype(this, MOVETYPE_NONE);
1876         accuracy_resend(this);
1877
1878         if(!SpectateUpdate(this))
1879                 PutObserverInServer(this);
1880
1881         return true;
1882 }
1883
1884 void SetSpectatee_status(entity this, int spectatee_num)
1885 {
1886         int oldspectatee_status = CS(this).spectatee_status;
1887         CS(this).spectatee_status = spectatee_num;
1888
1889         if (CS(this).spectatee_status != oldspectatee_status)
1890         {
1891                 if (STAT(PRESSED_KEYS, this))
1892                 {
1893                         CS(this).pressedkeys = 0;
1894                         STAT(PRESSED_KEYS, this) = 0;
1895                 }
1896                 ClientData_Touch(this);
1897                 if (g_race || g_cts) race_InitSpectator();
1898         }
1899 }
1900
1901 void SetSpectatee(entity this, entity spectatee)
1902 {
1903         if(IS_BOT_CLIENT(this))
1904                 return; // bots abuse .enemy, this code is useless to them
1905
1906         entity old_spectatee = this.enemy;
1907
1908         this.enemy = spectatee;
1909
1910         // WEAPONTODO
1911         // these are required to fix the spectator bug with arc
1912         if(old_spectatee)
1913         {
1914                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1915                 {
1916                         .entity weaponentity = weaponentities[slot];
1917                         if(old_spectatee.(weaponentity).arc_beam)
1918                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1919                 }
1920         }
1921         if(this.enemy)
1922         {
1923                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1924                 {
1925                         .entity weaponentity = weaponentities[slot];
1926                         if(this.enemy.(weaponentity).arc_beam)
1927                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1928                 }
1929         }
1930
1931         if (this.enemy)
1932                 SetSpectatee_status(this, etof(this.enemy));
1933
1934         // needed to update spectator list
1935         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1936 }
1937
1938 bool Spectate(entity this, entity pl)
1939 {
1940         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1941                 return false;
1942         pl = M_ARGV(1, entity);
1943
1944         SetSpectatee(this, pl);
1945         return SpectateSet(this);
1946 }
1947
1948 bool SpectateNext(entity this)
1949 {
1950         entity ent = find(this.enemy, classname, STR_PLAYER);
1951
1952         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1953                 ent = M_ARGV(1, entity);
1954         else if (!ent)
1955                 ent = find(ent, classname, STR_PLAYER);
1956
1957         if(ent) { SetSpectatee(this, ent); }
1958
1959         return SpectateSet(this);
1960 }
1961
1962 bool SpectatePrev(entity this)
1963 {
1964         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1965         entity ent = findchain(classname, STR_PLAYER);
1966         if (!ent) // no player
1967                 return false;
1968
1969         entity first = ent;
1970         // skip players until current spectated player
1971         if(this.enemy)
1972         while(ent && ent != this.enemy)
1973                 ent = ent.chain;
1974
1975         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1976         {
1977                 case MUT_SPECPREV_FOUND:
1978                         ent = M_ARGV(1, entity);
1979                         break;
1980                 case MUT_SPECPREV_RETURN:
1981                         return true;
1982                 case MUT_SPECPREV_CONTINUE:
1983                 default:
1984                 {
1985                         if(ent.chain)
1986                                 ent = ent.chain;
1987                         else
1988                                 ent = first;
1989                         break;
1990                 }
1991         }
1992
1993         SetSpectatee(this, ent);
1994         return SpectateSet(this);
1995 }
1996
1997 /*
1998 =============
1999 ShowRespawnCountdown()
2000
2001 Update a respawn countdown display.
2002 =============
2003 */
2004 void ShowRespawnCountdown(entity this)
2005 {
2006         float number;
2007         if(!IS_DEAD(this)) // just respawned?
2008                 return;
2009         else
2010         {
2011                 number = ceil(this.respawn_time - time);
2012                 if(number <= 0)
2013                         return;
2014                 if(number <= this.respawn_countdown)
2015                 {
2016                         this.respawn_countdown = number - 1;
2017                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2018                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2019                 }
2020         }
2021 }
2022
2023 .bool team_selected;
2024 bool ShowTeamSelection(entity this)
2025 {
2026         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2027                 return false;
2028         stuffcmd(this, "menu_showteamselect\n");
2029         return true;
2030 }
2031 void Join(entity this)
2032 {
2033         TRANSMUTE(Player, this);
2034
2035         if(!this.team_selected)
2036         if(autocvar_g_campaign || autocvar_g_balance_teams)
2037                 TeamBalance_JoinBestTeam(this);
2038
2039         if(autocvar_g_campaign)
2040                 campaign_bots_may_start = true;
2041
2042         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2043
2044         PutClientInServer(this);
2045
2046         if(IS_PLAYER(this))
2047         if(teamplay && this.team != -1)
2048         {
2049         }
2050         else
2051                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2052         this.team_selected = false;
2053
2054         // z411
2055         // send constant ready notification
2056         if(warmup_stage)
2057                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2058 }
2059
2060 int GetPlayerLimit()
2061 {
2062         if(g_duel)
2063                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2064         int player_limit = autocvar_g_maxplayers;
2065         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2066         player_limit = M_ARGV(0, int);
2067         return player_limit;
2068 }
2069
2070 /**
2071  * Determines whether the player is allowed to join. This depends on cvar
2072  * g_maxplayers, if it isn't used this function always return true, otherwise
2073  * it checks whether the number of currently playing players exceeds g_maxplayers.
2074  * @return int number of free slots for players, 0 if none
2075  */
2076 int nJoinAllowed(entity this, entity ignore)
2077 {
2078         if(!ignore)
2079         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2080         // so report 0 free slots if restricted
2081         {
2082                 if(autocvar_g_forced_team_otherwise == "spectate")
2083                         return 0;
2084                 if(autocvar_g_forced_team_otherwise == "spectator")
2085                         return 0;
2086         }
2087
2088         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2089                 return 0; // forced spectators can never join
2090
2091         // TODO simplify this
2092         int totalClients = 0;
2093         int currentlyPlaying = 0;
2094         FOREACH_CLIENT(true, {
2095                 if(it != ignore)
2096                         ++totalClients;
2097                 if(IS_REAL_CLIENT(it))
2098                 if(IS_PLAYER(it) || it.caplayer)
2099                         ++currentlyPlaying;
2100         });
2101
2102         int player_limit = GetPlayerLimit();
2103
2104         int free_slots = 0;
2105         if (!player_limit)
2106                 free_slots = maxclients - totalClients;
2107         else if(player_limit > 0 && currentlyPlaying < player_limit)
2108                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2109
2110         static float msg_time = 0;
2111         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2112         {
2113                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2114                 msg_time = time + 0.5;
2115         }
2116
2117         return free_slots;
2118 }
2119
2120 void PrintWelcomeMessage(entity this)
2121 {
2122         if(CS(this).motd_actived_time == 0)
2123         {
2124                 if (autocvar_g_campaign) {
2125                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2126                                 CS(this).motd_actived_time = time;
2127                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2128                         }
2129                 } else {
2130                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2131                                 CS(this).motd_actived_time = time;
2132                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2133                         }
2134                 }
2135         }
2136         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2137         {
2138                 if (autocvar_g_campaign) {
2139                         if (PHYS_INPUT_BUTTON_INFO(this))
2140                                 CS(this).motd_actived_time = time;
2141                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2142                                 CS(this).motd_actived_time = 0;
2143                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2144                         }
2145                 } else {
2146                         if (PHYS_INPUT_BUTTON_INFO(this))
2147                                 CS(this).motd_actived_time = time;
2148                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2149                                 CS(this).motd_actived_time = 0;
2150                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2151                         }
2152                 }
2153         }
2154         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2155         {
2156                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2157                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2158                 else if (CS(this).motd_actived_time == -2)
2159                 {
2160                         // instantly hide MOTD
2161                         CS(this).motd_actived_time = 0;
2162                         if (autocvar_g_campaign)
2163                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2164                         else
2165                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2166                 }
2167                 else if (IS_PLAYER(this) || IS_SPEC(this))
2168                 {
2169                         // FIXME occasionally for some reason MOTD never goes away
2170                         // delay MOTD removal a little bit in the hope it fixes this bug
2171                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2172                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2173                         else //if (CS(this).motd_actived_time < -2)
2174                                 CS(this).motd_actived_time++;
2175                 }
2176         }
2177 }
2178
2179 bool joinAllowed(entity this)
2180 {
2181         if (CS(this).version_mismatch) return false;
2182         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2183         if (!nJoinAllowed(this, this)) return false;
2184         if (teamplay && lockteams) return false;
2185         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2186         if (ShowTeamSelection(this)) return false;
2187         return true;
2188 }
2189
2190 .string shootfromfixedorigin;
2191 .bool dualwielding_prev;
2192 bool PlayerThink(entity this)
2193 {
2194         if (game_stopped || intermission_running) {
2195                 this.modelflags &= ~MF_ROCKET;
2196                 if(intermission_running)
2197                         IntermissionThink(this);
2198                 return false;
2199         }
2200
2201         if (game_timeout) {
2202         // don't allow the player to turn around while game is paused
2203                 // FIXME turn this into CSQC stuff
2204                 this.v_angle = this.lastV_angle;
2205                 this.angles = this.lastV_angle;
2206                 this.fixangle = true;
2207                 return false;
2208         }
2209
2210         if (frametime) player_powerups(this);
2211
2212         if (IS_DEAD(this)) {
2213                 if (this.personal && g_race_qualifying) {
2214                         if (time > this.respawn_time) {
2215                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2216                                 respawn(this);
2217                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2218                         }
2219                 } else {
2220                         if (frametime) player_anim(this);
2221
2222                         if (this.respawn_flags & RESPAWN_DENY)
2223                         {
2224                                 STAT(RESPAWN_TIME, this) = 0;
2225                                 return false;
2226                         }
2227
2228                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2229
2230                         switch(this.deadflag)
2231                         {
2232                                 case DEAD_DYING:
2233                                 {
2234                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2235                                                 this.deadflag = DEAD_RESPAWNING;
2236                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2237                                                 this.deadflag = DEAD_DEAD;
2238                                         break;
2239                                 }
2240                                 case DEAD_DEAD:
2241                                 {
2242                                         if (button_pressed)
2243                                                 this.deadflag = DEAD_RESPAWNABLE;
2244                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2245                                                 this.deadflag = DEAD_RESPAWNING;
2246                                         break;
2247                                 }
2248                                 case DEAD_RESPAWNABLE:
2249                                 {
2250                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2251                                                 this.deadflag = DEAD_RESPAWNING;
2252                                         break;
2253                                 }
2254                                 case DEAD_RESPAWNING:
2255                                 {
2256                                         if (time > this.respawn_time)
2257                                         {
2258                                                 this.respawn_time = time + 1; // only retry once a second
2259                                                 this.respawn_time_max = this.respawn_time;
2260                                                 respawn(this);
2261                                         }
2262                                         break;
2263                                 }
2264                         }
2265
2266                         ShowRespawnCountdown(this);
2267
2268                         if (this.respawn_flags & RESPAWN_SILENT)
2269                                 STAT(RESPAWN_TIME, this) = 0;
2270                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2271                         {
2272                                 if (time < this.respawn_time)
2273                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2274                                 else if (this.deadflag != DEAD_RESPAWNING)
2275                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2276                         }
2277                         else
2278                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2279                 }
2280
2281                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2282                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2283                         STAT(RESPAWN_TIME, this) *= -1;
2284
2285                 return false;
2286         }
2287
2288         FixPlayermodel(this);
2289
2290         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2291                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2292                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2293         }
2294
2295         // reset gun alignment when dual wielding status changes
2296         // to ensure guns are always aligned right and left
2297         bool dualwielding = W_DualWielding(this);
2298         if(this.dualwielding_prev != dualwielding)
2299         {
2300                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2301                 this.dualwielding_prev = dualwielding;
2302         }
2303
2304         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2305         //if(frametime)
2306         {
2307                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2308                 {
2309                         .entity weaponentity = weaponentities[slot];
2310                         if(WEP_CVAR(vortex, charge_always))
2311                                 W_Vortex_Charge(this, weaponentity, frametime);
2312                         W_WeaponFrame(this, weaponentity);
2313                 }
2314         }
2315
2316         if (frametime)
2317         {
2318                 // WEAPONTODO: Add a weapon request for this
2319                 // rot vortex charge to the charge limit
2320                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2321                 {
2322                         .entity weaponentity = weaponentities[slot];
2323                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2324                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2325                 }
2326
2327                 player_regen(this);
2328                 player_anim(this);
2329                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2330         }
2331
2332         monsters_setstatus(this);
2333
2334         return true;
2335 }
2336
2337 .bool would_spectate;
2338 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2339 void ObserverOrSpectatorThink(entity this)
2340 {
2341         bool is_spec = IS_SPEC(this);
2342         if ( CS(this).impulse )
2343         {
2344                 int r = MinigameImpulse(this, CS(this).impulse);
2345                 if (!is_spec || r)
2346                         CS(this).impulse = 0;
2347
2348                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2349                 {
2350                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2351                         CS(this).impulse = 0;
2352                         return;
2353                 }
2354         }
2355
2356         if (this.flags & FL_JUMPRELEASED) {
2357                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2358                         this.flags &= ~FL_JUMPRELEASED;
2359                         this.flags |= FL_SPAWNING;
2360                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2361                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2362                         this.flags &= ~FL_JUMPRELEASED;
2363                         if(SpectateNext(this)) {
2364                                 TRANSMUTE(Spectator, this);
2365                         } else if (is_spec) {
2366                                 TRANSMUTE(Observer, this);
2367                                 PutClientInServer(this);
2368                         }
2369                         else
2370                                 this.would_spectate = false; // unable to spectate anyone
2371                         if (is_spec)
2372                                 CS(this).impulse = 0;
2373                 } else if (is_spec) {
2374                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2375                                 this.flags &= ~FL_JUMPRELEASED;
2376                                 if(SpectatePrev(this)) {
2377                                         TRANSMUTE(Spectator, this);
2378                                 } else {
2379                                         TRANSMUTE(Observer, this);
2380                                         PutClientInServer(this);
2381                                 }
2382                                 CS(this).impulse = 0;
2383                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2384                                 this.would_spectate = false;
2385                                 this.flags &= ~FL_JUMPRELEASED;
2386                                 TRANSMUTE(Observer, this);
2387                                 PutClientInServer(this);
2388                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2389                                 PutObserverInServer(this);
2390                                 this.would_spectate = true;
2391                         }
2392                 }
2393                 else {
2394                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2395                         if (PHYS_INPUT_BUTTON_USE(this))
2396                                 wouldclip = !wouldclip;
2397                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2398                         set_movetype(this, preferred_movetype);
2399                 }
2400         } else { // jump pressed
2401                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2402                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2403                         this.flags |= FL_JUMPRELEASED;
2404                         if(this.flags & FL_SPAWNING)
2405                         {
2406                                 this.flags &= ~FL_SPAWNING;
2407                                 if(joinAllowed(this))
2408                                         Join(this);
2409                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2410                                         CS(this).autojoin_checked = -1;
2411                                 return;
2412                         }
2413                 }
2414                 if(is_spec && !SpectateUpdate(this))
2415                         PutObserverInServer(this);
2416         }
2417         if (is_spec)
2418                 this.flags |= FL_CLIENT | FL_NOTARGET;
2419 }
2420
2421 void PlayerUseKey(entity this)
2422 {
2423         if (!IS_PLAYER(this))
2424                 return;
2425
2426         if(this.vehicle)
2427         {
2428                 if(!game_stopped)
2429                 {
2430                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2431                         return;
2432                 }
2433         }
2434         else if(autocvar_g_vehicles_enter)
2435         {
2436                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2437                 {
2438                         entity head, closest_target = NULL;
2439                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2440
2441                         while(head) // find the closest acceptable target to enter
2442                         {
2443                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2444                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2445                                 {
2446                                         if(closest_target)
2447                                         {
2448                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2449                                                 { closest_target = head; }
2450                                         }
2451                                         else { closest_target = head; }
2452                                 }
2453
2454                                 head = head.chain;
2455                         }
2456
2457                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2458                 }
2459         }
2460
2461         // a use key was pressed; call handlers
2462         MUTATOR_CALLHOOK(PlayerUseKey, this);
2463 }
2464
2465
2466 /*
2467 =============
2468 PlayerPreThink
2469
2470 Called every frame for each client before the physics are run
2471 =============
2472 */
2473 .float last_vehiclecheck;
2474 void PlayerPreThink (entity this)
2475 {
2476         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2477         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2478
2479         WarpZone_PlayerPhysics_FixVAngle(this);
2480
2481         if (frametime) {
2482                 // physics frames: update anticheat stuff
2483                 anticheat_prethink(this);
2484
2485                 // WORKAROUND: only use dropclient in server frames (frametime set).
2486                 // Never use it in cl_movement frames (frametime zero).
2487                 if (blockSpectators && IS_REAL_CLIENT(this)
2488                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2489                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2490                 {
2491                         if (dropclient_schedule(this))
2492                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2493                 }
2494         }
2495
2496         zoomstate_set = false;
2497
2498         // Check for nameless players
2499         if (this.netname == "" || this.netname != CS(this).netname_previous)
2500         {
2501                 bool assume_unchanged = (CS(this).netname_previous == "");
2502                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2503                 {
2504                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2505                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2506                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2507                         assume_unchanged = false;
2508                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2509                 }
2510                 if (isInvisibleString(this.netname))
2511                 {
2512                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2513                         sprint(this, "Warning: invisible names are not allowed.\n");
2514                         assume_unchanged = false;
2515                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2516                 }
2517                 if (!assume_unchanged && autocvar_sv_eventlog)
2518                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2519                 strcpy(CS(this).netname_previous, this.netname);
2520         }
2521
2522         // version nagging
2523         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2524         CS(this).version_nagtime = 0;
2525         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2526             // git client
2527         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2528             // git server
2529             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2530         } else {
2531             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2532             if (r < 0) { // old client
2533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2534             } else if (r > 0) { // old server
2535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2536             }
2537         }
2538     }
2539
2540         // GOD MODE info
2541         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2542         {
2543                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2544                 this.max_armorvalue = 0;
2545         }
2546
2547         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2548         {
2549                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2550                 {
2551                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2552                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2553                         if (this.iceblock)
2554                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2555
2556                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2557                                 Unfreeze(this, false);
2558                 }
2559                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2560                 {
2561                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2562                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2563
2564                         if (GetResource(this, RES_HEALTH) < 1)
2565                         {
2566                                 if (this.vehicle)
2567                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2568                                 if(this.event_damage)
2569                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2570                         }
2571                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2572                                 Unfreeze(this, false);
2573                 }
2574         }
2575
2576         MUTATOR_CALLHOOK(PlayerPreThink, this);
2577
2578         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2579         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2580         {
2581                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2582                 {
2583                         if(!it.owner)
2584                         {
2585                                 if(!it.team || SAME_TEAM(this, it))
2586                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2587                                 else if(autocvar_g_vehicles_steal)
2588                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2589                         }
2590                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2591                         {
2592                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2593                         }
2594                 });
2595
2596                 this.last_vehiclecheck = time + 1;
2597         }
2598
2599         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2600         {
2601                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2602                         PlayerUseKey(this);
2603                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2604         }
2605
2606         if (IS_REAL_CLIENT(this))
2607                 PrintWelcomeMessage(this);
2608
2609         if (IS_PLAYER(this)) {
2610                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2611                         error("Client can't be spawned as player on connection!");
2612                 if(!PlayerThink(this))
2613                         return;
2614         }
2615         else if (game_stopped || intermission_running) {
2616                 if(intermission_running)
2617                         IntermissionThink(this);
2618                 return;
2619         }
2620         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2621         {
2622                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2623                 CS(this).autojoin_checked = 1;
2624                 // don't do this in ClientConnect
2625                 // many things can go wrong if a client is spawned as player on connection
2626                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2627                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2628                                 && (!teamplay || autocvar_g_balance_teams)))
2629                 {
2630                         campaign_bots_may_start = true;
2631                         if(joinAllowed(this))
2632                                 Join(this);
2633                         return;
2634                 }
2635         }
2636         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2637                 ObserverOrSpectatorThink(this);
2638         }
2639
2640         // WEAPONTODO: Add weapon request for this
2641         if (!zoomstate_set) {
2642                 bool wep_zoomed = false;
2643                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2644                 {
2645                         .entity weaponentity = weaponentities[slot];
2646                         Weapon thiswep = this.(weaponentity).m_weapon;
2647                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2648                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2649                 }
2650                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2651         }
2652
2653         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2654         {
2655                 CS(this).teamkill_soundtime = 0;
2656
2657                 entity e = CS(this).teamkill_soundsource;
2658                 entity oldpusher = e.pusher;
2659                 e.pusher = this;
2660                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2661                 e.pusher = oldpusher;
2662         }
2663
2664         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2665                 CS(this).taunt_soundtime = 0;
2666                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2667         }
2668
2669         target_voicescript_next(this);
2670 }
2671
2672 void DrownPlayer(entity this)
2673 {
2674         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2675                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2676         {
2677                 STAT(AIR_FINISHED, this) = 0;
2678                 return;
2679         }
2680
2681         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2682         {
2683                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2684                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2685                 STAT(AIR_FINISHED, this) = 0;
2686         }
2687         else
2688         {
2689                 if (!STAT(AIR_FINISHED, this))
2690                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2691                 if (STAT(AIR_FINISHED, this) < time)
2692                 {       // drown!
2693                         if (this.pain_finished < time)
2694                         {
2695                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2696                                 this.pain_finished = time + 0.5;
2697                         }
2698                 }
2699         }
2700 }
2701
2702 .bool move_qcphysics;
2703
2704 void Player_Physics(entity this)
2705 {
2706         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2707
2708         if(!this.move_qcphysics)
2709                 return;
2710
2711         if(!frametime && !CS(this).pm_frametime)
2712                 return;
2713
2714         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2715
2716         CS(this).pm_frametime = 0;
2717 }
2718
2719 /*
2720 =============
2721 PlayerPostThink
2722
2723 Called every frame for each client after the physics are run
2724 =============
2725 */
2726 void PlayerPostThink (entity this)
2727 {
2728         Player_Physics(this);
2729
2730         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2731         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2732         if (IS_REAL_CLIENT(this))
2733         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2734         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2735         {
2736                 int totalClients = 0;
2737                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2738                 {
2739                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2740                         {
2741                                 ++totalClients;
2742                         });
2743                 }
2744
2745                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2746                 { /* do nothing */ }
2747                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2748                 {
2749                         if (CS(this).idlekick_lasttimeleft)
2750                         {
2751                                 CS(this).idlekick_lasttimeleft = 0;
2752                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2753                         }
2754                 }
2755                 else
2756                 {
2757                         float maxidle_time = autocvar_sv_maxidle;
2758                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2759                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2760                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2761                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2762                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2763                         {
2764                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2765                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2766                                 else
2767                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2768                         }
2769                         if (timeleft <= 0) {
2770                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2771                                 {
2772                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2773                                         if (this.caplayer)
2774                                                 this.caplayer = 0;
2775                                         PutObserverInServer(this);
2776                                 }
2777                                 else
2778                                 {
2779                                         if (dropclient_schedule(this))
2780                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2781                                 }
2782                                 return;
2783                         }
2784                         else if (timeleft <= countdown_time) {
2785                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2786                                         play2(this, SND(TALK2));
2787                                 CS(this).idlekick_lasttimeleft = timeleft;
2788                         }
2789                 }
2790         }
2791
2792         CheatFrame(this);
2793
2794         if (game_stopped)
2795         {
2796                 this.solid = SOLID_NOT;
2797                 this.takedamage = DAMAGE_NO;
2798                 set_movetype(this, MOVETYPE_NONE);
2799                 CS(this).teamkill_complain = 0;
2800                 CS(this).teamkill_soundtime = 0;
2801                 CS(this).teamkill_soundsource = NULL;
2802         }
2803
2804         if (IS_PLAYER(this)) {
2805                 if(this.death_time == time && IS_DEAD(this))
2806                 {
2807                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2808                         // once all the damage events of this frame have been processed with normal size
2809                         this.maxs.z = 5;
2810                         setsize(this, this.mins, this.maxs);
2811                 }
2812                 DrownPlayer(this);
2813                 UpdateChatBubble(this);
2814                 if (CS(this).impulse) ImpulseCommands(this);
2815                 GetPressedKeys(this);
2816                 if (game_stopped)
2817                 {
2818                         CSQCMODEL_AUTOUPDATE(this);
2819                         return;
2820                 }
2821         }
2822         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2823         {
2824                 CS(this).pressedkeys = 0;
2825                 STAT(PRESSED_KEYS, this) = 0;
2826         }
2827
2828         if (this.waypointsprite_attachedforcarrier) {
2829                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2830                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2831         }
2832
2833         CSQCMODEL_AUTOUPDATE(this);
2834 }
2835
2836 // hack to copy the button fields from the client entity to the Client State
2837 void PM_UpdateButtons(entity this, entity store)
2838 {
2839         if(this.impulse)
2840                 store.impulse = this.impulse;
2841         this.impulse = 0;
2842
2843         bool typing = this.buttonchat || this.button12;
2844
2845         store.button0 = (typing) ? 0 : this.button0;
2846         //button1?!
2847         store.button2 = (typing) ? 0 : this.button2;
2848         store.button3 = (typing) ? 0 : this.button3;
2849         store.button4 = this.button4;
2850         store.button5 = (typing) ? 0 : this.button5;
2851         store.button6 = this.button6;
2852         store.button7 = this.button7;
2853         store.button8 = this.button8;
2854         store.button9 = this.button9;
2855         store.button10 = this.button10;
2856         store.button11 = this.button11;
2857         store.button12 = this.button12;
2858         store.button13 = this.button13;
2859         store.button14 = this.button14;
2860         store.button15 = this.button15;
2861         store.button16 = this.button16;
2862         store.buttonuse = this.buttonuse;
2863         store.buttonchat = this.buttonchat;
2864
2865         store.cursor_active = this.cursor_active;
2866         store.cursor_screen = this.cursor_screen;
2867         store.cursor_trace_start = this.cursor_trace_start;
2868         store.cursor_trace_endpos = this.cursor_trace_endpos;
2869         store.cursor_trace_ent = this.cursor_trace_ent;
2870
2871         store.ping = this.ping;
2872         store.ping_packetloss = this.ping_packetloss;
2873         store.ping_movementloss = this.ping_movementloss;
2874
2875         store.v_angle = this.v_angle;
2876         store.movement = this.movement;
2877 }
2878
2879 NET_HANDLE(fpsreport, bool)
2880 {
2881         int fps = ReadShort();
2882         PlayerScore_Set(sender, SP_FPS, fps);
2883         return true;
2884 }