qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if(GetResource(this, RES_HEALTH) >= 1)
 255                 {
 256                         // despawn effect
 257                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 258                 }
 259
 260                 // was a player, recount votes and ready status
 261                 if(IS_REAL_CLIENT(this))
 262                 {
 263                         if (vote_called) { VoteCount(false); }
 264                         ReadyCount();
 265                 }
 266         }
 267
 268         entity spot = SelectSpawnPoint(this, true);
 269         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 270         this.angles = vec2(spot.angles);
 271         this.fixangle = true;
 272         // offset it so that the spectator spawns higher off the ground, looks better this way
 273         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         WaypointSprite_PlayerDead(this);
 307
 308         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 309                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 310
 311         accuracy_resend(this);
 312
 313         CS(this).spectatortime = time;
 314         if(this.bot_attack)
 315                 IL_REMOVE(g_bot_targets, this);
 316         this.bot_attack = false;
 317         if(this.monster_attack)
 318                 IL_REMOVE(g_monster_targets, this);
 319         this.monster_attack = false;
 320         STAT(HUD, this) = HUD_NORMAL;
 321         TRANSMUTE(Observer, this);
 322         this.iscreature = false;
 323         this.teleportable = TELEPORT_SIMPLE;
 324         if(this.damagedbycontents)
 325                 IL_REMOVE(g_damagedbycontents, this);
 326         this.damagedbycontents = false;
 327         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 328         SetSpectatee_status(this, etof(this));
 329         this.takedamage = DAMAGE_NO;
 330         this.solid = SOLID_NOT;
 331         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 332         this.flags = FL_CLIENT | FL_NOTARGET;
 333         this.effects = 0;
 334         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 335         this.pauserotarmor_finished = 0;
 336         this.pauserothealth_finished = 0;
 337         this.pauseregen_finished = 0;
 338         this.damageforcescale = 0;
 339         this.death_time = 0;
 340         this.respawn_flags = 0;
 341         this.respawn_time = 0;
 342         STAT(RESPAWN_TIME, this) = 0;
 343         this.alpha = 0;
 344         this.scale = 0;
 345         this.fade_time = 0;
 346         this.pain_finished = 0;
 347         STAT(STRENGTH_FINISHED, this) = 0;
 348         STAT(INVINCIBLE_FINISHED, this) = 0;
 349         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.fire_endtime = -1;
 386         this.event_damage = func_null;
 387         this.event_heal = func_null;
 388
 389         for(int slot = 0; slot < MAX_AXH; ++slot)
 390         {
 391                 entity axh = this.(AuxiliaryXhair[slot]);
 392                 this.(AuxiliaryXhair[slot]) = NULL;
 393
 394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 395                         delete(axh);
 396         }
 397
 398         if (mutator_returnvalue)
 399         {
 400                 // mutator prevents resetting teams+score
 401         }
 402         else
 403         {
 404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 405                 this.frags = FRAGS_SPECTATOR;
 406         }
 407         if (CS(this).just_joined)
 408                 CS(this).just_joined = false;
 409 }
 410
 411 int player_getspecies(entity this)
 412 {
 413         get_model_parameters(this.model, this.skin);
 414         int s = get_model_parameters_species;
 415         get_model_parameters(string_null, 0);
 416         if (s < 0) return SPECIES_HUMAN;
 417         return s;
 418 }
 419
 420 .float model_randomizer;
 421 void FixPlayermodel(entity player)
 422 {
 423         string defaultmodel = "";
 424         int defaultskin = 0;
 425         if(autocvar_sv_defaultcharacter)
 426         {
 427                 if(teamplay)
 428                 {
 429                         switch(player.team)
 430                         {
 431                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 432                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 433                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 434                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 435                         }
 436                 }
 437
 438                 if(defaultmodel == "")
 439                 {
 440                         defaultmodel = autocvar_sv_defaultplayermodel;
 441                         defaultskin = autocvar_sv_defaultplayerskin;
 442                 }
 443
 444                 int n = tokenize_console(defaultmodel);
 445                 if(n > 0)
 446                 {
 447                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 448                         // However, do NOT randomize if the player-selected model is in the list.
 449                         for (int i = 0; i < n; ++i)
 450                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 451                                         defaultmodel = argv(i);
 452                 }
 453
 454                 int i = strstrofs(defaultmodel, ":", 0);
 455                 if(i >= 0)
 456                 {
 457                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 458                         defaultmodel = substring(defaultmodel, 0, i);
 459                 }
 460         }
 461         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 462         {
 463                 if(teamplay)
 464                 {
 465                         switch(player.team)
 466                         {
 467                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 468                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 469                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 470                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 471                         }
 472                 }
 473
 474                 if(!defaultskin)
 475                         defaultskin = autocvar_sv_defaultplayerskin;
 476         }
 477
 478         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 479         defaultmodel = M_ARGV(0, string);
 480         defaultskin = M_ARGV(1, int);
 481
 482         bool chmdl = false;
 483         int oldskin;
 484         if(defaultmodel != "")
 485         {
 486                 if (defaultmodel != player.model)
 487                 {
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, defaultmodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 oldskin = player.skin;
 496                 player.skin = defaultskin;
 497         } else {
 498                 if (player.playermodel != player.model || player.playermodel == "")
 499                 {
 500                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 501                         vector m1 = player.mins;
 502                         vector m2 = player.maxs;
 503                         setplayermodel (player, player.playermodel);
 504                         setsize (player, m1, m2);
 505                         chmdl = true;
 506                 }
 507
 508                 if(!autocvar_sv_defaultcharacterskin)
 509                 {
 510                         oldskin = player.skin;
 511                         player.skin = stof(player.playerskin);
 512                 }
 513                 else
 514                 {
 515                         oldskin = player.skin;
 516                         player.skin = defaultskin;
 517                 }
 518         }
 519
 520         if(chmdl || oldskin != player.skin) // model or skin has changed
 521         {
 522                 player.species = player_getspecies(player); // update species
 523                 if(!autocvar_g_debug_globalsounds)
 524                         UpdatePlayerSounds(player); // update skin sounds
 525         }
 526
 527         if(!teamplay)
 528                 if(strlen(autocvar_sv_defaultplayercolors))
 529                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 530                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 531 }
 532
 533 void ResetPlayerResources(entity this)
 534 {
 535         if (warmup_stage) {
 536                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 537                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 538                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 539                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 540                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 541                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 542                 SetResource(this, RES_HEALTH, warmup_start_health);
 543                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 544                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 545         } else {
 546                 SetResource(this, RES_SHELLS, start_ammo_shells);
 547                 SetResource(this, RES_BULLETS, start_ammo_nails);
 548                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 549                 SetResource(this, RES_CELLS, start_ammo_cells);
 550                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 551                 SetResource(this, RES_FUEL, start_ammo_fuel);
 552                 SetResource(this, RES_HEALTH, start_health);
 553                 SetResource(this, RES_ARMOR, start_armorvalue);
 554                 STAT(WEAPONS, this) = start_weapons;
 555                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 556                 {
 557                         GiveRandomWeapons(this, random_start_weapons_count,
 558                                 autocvar_g_random_start_weapons, random_start_ammo);
 559                 }
 560         }
 561 }
 562
 563 void PutPlayerInServer(entity this)
 564 {
 565         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 566
 567         PlayerState_attach(this);
 568         accuracy_resend(this);
 569
 570         if (this.team < 0)
 571                 TeamBalance_JoinBestTeam(this);
 572
 573         entity spot = SelectSpawnPoint(this, false);
 574         if (!spot) {
 575                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 576                 return; // spawn failed
 577         }
 578
 579         TRANSMUTE(Player, this);
 580
 581         CS(this).wasplayer = true;
 582         this.iscreature = true;
 583         this.teleportable = TELEPORT_NORMAL;
 584         if(!this.damagedbycontents)
 585                 IL_PUSH(g_damagedbycontents, this);
 586         this.damagedbycontents = true;
 587         set_movetype(this, MOVETYPE_WALK);
 588         this.solid = SOLID_SLIDEBOX;
 589         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 590         if (autocvar_g_playerclip_collisions)
 591                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 592         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 593                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 594         this.frags = FRAGS_PLAYER;
 595         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 596         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 597         if (autocvar__notarget)
 598                 this.flags |= FL_NOTARGET;
 599         this.takedamage = DAMAGE_AIM;
 600         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 601
 602         ResetPlayerResources(this);
 603
 604         SetSpectatee_status(this, 0);
 605
 606         PS(this).dual_weapons = '0 0 0';
 607
 608         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 609
 610         this.items = start_items;
 611
 612         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 613         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 614         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 615         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 616         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 617         if (!sv_ready_restart_after_countdown && time < game_starttime)
 618         {
 619                 float f = game_starttime - time;
 620                 this.spawnshieldtime += f;
 621                 this.pauserotarmor_finished += f;
 622                 this.pauserothealth_finished += f;
 623                 this.pauseregen_finished += f;
 624         }
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 632         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 633         this.fade_time = 0;
 634         this.pain_finished = 0;
 635         this.pushltime = 0;
 636         setthink(this, func_null); // players have no think function
 637         this.nextthink = 0;
 638         this.dmg_team = 0;
 639         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 640
 641         this.deadflag = DEAD_NO;
 642
 643         this.angles = spot.angles;
 644         this.angles_z = 0; // never spawn tilted even if the spot says to
 645         if (IS_BOT_CLIENT(this))
 646         {
 647                 this.v_angle = this.angles;
 648                 bot_aim_reset(this);
 649         }
 650         this.fixangle = true; // turn this way immediately
 651         this.oldvelocity = this.velocity = '0 0 0';
 652         this.avelocity = '0 0 0';
 653         this.punchangle = '0 0 0';
 654         this.punchvector = '0 0 0';
 655
 656         STAT(STRENGTH_FINISHED, this) = 0;
 657         STAT(INVINCIBLE_FINISHED, this) = 0;
 658         this.fire_endtime = -1;
 659         STAT(REVIVE_PROGRESS, this) = 0;
 660         this.revival_time = 0;
 661
 662         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 663         STAT(BUFFS, this) = 0;
 664         STAT(BUFF_TIME, this) = 0;
 665
 666         STAT(AIR_FINISHED, this) = 0;
 667         this.waterlevel = WATERLEVEL_NONE;
 668         this.watertype = CONTENT_EMPTY;
 669
 670         entity spawnevent = new_pure(spawnevent);
 671         spawnevent.owner = this;
 672         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 673
 674         // Cut off any still running player sounds.
 675         stopsound(this, CH_PLAYER_SINGLE);
 676
 677         this.model = "";
 678         FixPlayermodel(this);
 679         this.drawonlytoclient = NULL;
 680
 681         this.viewloc = NULL;
 682
 683         for(int slot = 0; slot < MAX_AXH; ++slot)
 684         {
 685                 entity axh = this.(AuxiliaryXhair[slot]);
 686                 this.(AuxiliaryXhair[slot]) = NULL;
 687
 688                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 689                         delete(axh);
 690         }
 691
 692         this.spawnpoint_targ = NULL;
 693
 694         UNSET_DUCKED(this);
 695         this.view_ofs = STAT(PL_VIEW_OFS, this);
 696         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 697         this.spawnorigin = spot.origin;
 698         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 699         // don't reset back to last position, even if new position is stuck in solid
 700         this.oldorigin = this.origin;
 701         if(this.conveyor)
 702                 IL_REMOVE(g_conveyed, this);
 703         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 704         if(this.swampslug)
 705                 IL_REMOVE(g_swamped, this);
 706         this.swampslug = NULL;
 707         this.swamp_interval = 0;
 708         if(this.ladder_entity)
 709                 IL_REMOVE(g_ladderents, this);
 710         this.ladder_entity = NULL;
 711         IL_EACH(g_counters, it.realowner == this,
 712         {
 713                 delete(it);
 714         });
 715         STAT(HUD, this) = HUD_NORMAL;
 716
 717         this.event_damage = PlayerDamage;
 718         this.event_heal = PlayerHeal;
 719
 720         this.draggable = func_null;
 721
 722         if(!this.bot_attack)
 723                 IL_PUSH(g_bot_targets, this);
 724         this.bot_attack = true;
 725         if(!this.monster_attack)
 726                 IL_PUSH(g_monster_targets, this);
 727         this.monster_attack = true;
 728         navigation_dynamicgoal_init(this, false);
 729
 730         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 731
 732         // player was spectator
 733         if (CS(this).killcount == FRAGS_SPECTATOR) {
 734                 PlayerScore_Clear(this);
 735                 CS(this).killcount = 0;
 736                 CS(this).startplaytime = time;
 737         }
 738
 739         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 740         {
 741                 .entity weaponentity = weaponentities[slot];
 742                 CL_SpawnWeaponentity(this, weaponentity);
 743         }
 744         this.alpha = default_player_alpha;
 745         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 746         this.exteriorweaponentity.alpha = default_weapon_alpha;
 747
 748         this.speedrunning = false;
 749
 750         this.counter_cnt = 0;
 751         this.fragsfilter_cnt = 0;
 752
 753         target_voicescript_clear(this);
 754
 755         // reset fields the weapons may use
 756         FOREACH(Weapons, true, {
 757                 it.wr_resetplayer(it, this);
 758                         // reload all reloadable weapons
 759                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 760                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 761                         {
 762                                 .entity weaponentity = weaponentities[slot];
 763                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 764                         }
 765                 }
 766         });
 767
 768         {
 769                 string s = spot.target;
 770                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 771                         spot.target = string_null;
 772                 SUB_UseTargets(spot, this, NULL);
 773                 if(g_assault || g_race)
 774                         spot.target = s;
 775         }
 776
 777         Unfreeze(this, false);
 778
 779         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 780
 781         if (autocvar_spawn_debug)
 782         {
 783                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 784                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 785         }
 786
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 791                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 792                 else
 793                         this.(weaponentity).m_switchweapon = WEP_Null;
 794                 this.(weaponentity).m_weapon = WEP_Null;
 795                 this.(weaponentity).weaponname = "";
 796                 this.(weaponentity).m_switchingweapon = WEP_Null;
 797                 this.(weaponentity).cnt = -1;
 798         }
 799
 800         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 801
 802         if (CS(this).impulse) ImpulseCommands(this);
 803
 804         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 805         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 806         {
 807                 .entity weaponentity = weaponentities[slot];
 808                 W_WeaponFrame(this, weaponentity);
 809         }
 810
 811         if (!warmup_stage && !this.alivetime)
 812                 this.alivetime = time;
 813
 814         antilag_clear(this, CS(this));
 815 }
 816
 817 /** Called when a client spawns in the server */
 818 void PutClientInServer(entity this)
 819 {
 820         if (IS_BOT_CLIENT(this)) {
 821                 TRANSMUTE(Player, this);
 822         } else if (IS_REAL_CLIENT(this)) {
 823                 msg_entity = this;
 824                 WriteByte(MSG_ONE, SVC_SETVIEW);
 825                 WriteEntity(MSG_ONE, this);
 826         }
 827         if (game_stopped)
 828                 TRANSMUTE(Observer, this);
 829
 830         SetSpectatee(this, NULL);
 831
 832         // reset player keys
 833         if(PS(this))
 834                 PS(this).itemkeys = 0;
 835
 836         MUTATOR_CALLHOOK(PutClientInServer, this);
 837
 838         if (IS_OBSERVER(this)) {
 839                 PutObserverInServer(this);
 840         } else if (IS_PLAYER(this)) {
 841                 PutPlayerInServer(this);
 842         }
 843
 844         // send team names
 845         if(teamplay && IS_REAL_CLIENT(this))
 846                 send_TeamNames(MSG_ONE, this);
 847 }
 848
 849 // TODO do we need all these fields, or should we stop autodetecting runtime
 850 // changes and just have a console command to update this?
 851 bool ClientInit_SendEntity(entity this, entity to, int sf)
 852 {
 853         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 854         return = true;
 855         msg_entity = to;
 856         // MSG_INIT replacement
 857         // TODO: make easier to use
 858         Registry_send_all();
 859         W_PROP_reload(MSG_ONE, to);
 860         ClientInit_misc(this);
 861         MUTATOR_CALLHOOK(Ent_Init);
 862 }
 863 void ClientInit_misc(entity this)
 864 {
 865         int channel = MSG_ONE;
 866         WriteHeader(channel, ENT_CLIENT_INIT);
 867         WriteByte(channel, g_nexball_meter_period * 32);
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 869         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 870         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 871         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 873         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 874         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 875         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 876
 877         if(autocvar_sv_foginterval && world.fog != "")
 878                 WriteString(channel, world.fog);
 879         else
 880                 WriteString(channel, "");
 881         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 882         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 883         WriteByte(channel, serverflags);
 884         WriteCoord(channel, autocvar_g_trueaim_minrange);
 885
 886         // z411 send full hostname
 887         WriteString(channel, (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
 888 }
 889
 890 void ClientInit_CheckUpdate(entity this)
 891 {
 892         this.nextthink = time;
 893         if(this.count != autocvar_g_balance_armor_blockpercent)
 894         {
 895                 this.count = autocvar_g_balance_armor_blockpercent;
 896                 this.SendFlags |= 1;
 897         }
 898         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 899         {
 900                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 901                 this.SendFlags |= 1;
 902         }
 903 }
 904
 905 void ClientInit_Spawn()
 906 {
 907         entity e = new_pure(clientinit);
 908         setthink(e, ClientInit_CheckUpdate);
 909         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 910
 911         ClientInit_CheckUpdate(e);
 912 }
 913
 914 /*
 915 =============
 916 SetNewParms
 917 =============
 918 */
 919 void SetNewParms ()
 920 {
 921         // initialize parms for a new player
 922         parm1 = -(86400 * 366);
 923
 924         MUTATOR_CALLHOOK(SetNewParms);
 925 }
 926
 927 /*
 928 =============
 929 SetChangeParms
 930 =============
 931 */
 932 void SetChangeParms (entity this)
 933 {
 934         // save parms for level change
 935         parm1 = CS(this).parm_idlesince - time;
 936
 937         MUTATOR_CALLHOOK(SetChangeParms);
 938 }
 939
 940 /*
 941 =============
 942 DecodeLevelParms
 943 =============
 944 */
 945 void DecodeLevelParms(entity this)
 946 {
 947         // load parms
 948         CS(this).parm_idlesince = parm1;
 949         if (CS(this).parm_idlesince == -(86400 * 366))
 950                 CS(this).parm_idlesince = time;
 951
 952         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 953         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 954
 955         MUTATOR_CALLHOOK(DecodeLevelParms);
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         if(autocvar_g_antilag == 3) // client side hitscan
 963                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 964         if(autocvar_sv_gentle)
 965                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 966
 967         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 968         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 969
 970         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 971
 972         MUTATOR_CALLHOOK(FixClientCvars, e);
 973 }
 974
 975 bool findinlist_abbrev(string tofind, string list)
 976 {
 977         if(list == "" || tofind == "")
 978                 return false; // empty list or search, just return
 979
 980         // this function allows abbreviated strings!
 981         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 982         {
 983                 return true;
 984         });
 985
 986         return false;
 987 }
 988
 989 bool PlayerInIPList(entity p, string iplist)
 990 {
 991         // some safety checks (never allow local?)
 992         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 993                 return false;
 994
 995         return findinlist_abbrev(p.netaddress, iplist);
 996 }
 997
 998 bool PlayerInIDList(entity p, string idlist)
 999 {
1000         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1001         if(!p.crypto_idfp)
1002                 return false;
1003
1004         return findinlist_abbrev(p.crypto_idfp, idlist);
1005 }
1006
1007 bool PlayerInList(entity player, string list)
1008 {
1009         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1010 }
1011
1012 #ifdef DP_EXT_PRECONNECT
1013 /*
1014 =============
1015 ClientPreConnect
1016
1017 Called once (not at each match start) when a client begins a connection to the server
1018 =============
1019 */
1020 void ClientPreConnect(entity this)
1021 {
1022         if(autocvar_sv_eventlog)
1023         {
1024                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1025                         this.playerid,
1026                         etof(this),
1027                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1028                 ));
1029         }
1030 }
1031 #endif
1032
1033 string GetClientVersionMessage(entity this)
1034 {
1035         if (CS(this).version_mismatch) {
1036                 if(CS(this).version < autocvar_gameversion) {
1037                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1038                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1039                 } else {
1040                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1041                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1042                 }
1043         } else {
1044                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1045         }
1046 }
1047
1048 string getwelcomemessage(entity this)
1049 {
1050         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1051         string modifications = M_ARGV(0, string);
1052
1053         if(g_weaponarena)
1054         {
1055                 if(g_weaponarena_random)
1056                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1057                 else
1058                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1059         }
1060         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1061                 modifications = strcat(modifications, ", No start weapons");
1062         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1063                 modifications = strcat(modifications, ", Low gravity");
1064         if(g_weapon_stay && !g_cts)
1065                 modifications = strcat(modifications, ", Weapons stay");
1066         if(autocvar_g_jetpack)
1067                 modifications = strcat(modifications, ", Jet pack");
1068         if(autocvar_g_powerups == 0)
1069                 modifications = strcat(modifications, ", No powerups");
1070         if(autocvar_g_powerups > 0)
1071                 modifications = strcat(modifications, ", Powerups");
1072         modifications = substring(modifications, 2, strlen(modifications) - 2);
1073
1074         //string versionmessage = GetClientVersionMessage(this);
1075         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1076         string s = (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname);
1077
1078         s = strcat(s, "^8\n^7", gamemode_name);
1079
1080         if(modifications != "")
1081                 s = strcat(s, "^7 | ^3", modifications);
1082
1083         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1084         {
1085                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1086                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1087         }
1088
1089         if (cache_mutatormsg != "") {
1090                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1091         }
1092
1093         string mutator_msg = "";
1094         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1095         mutator_msg = M_ARGV(0, string);
1096
1097         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1098
1099         string motd = autocvar_sv_motd;
1100         if (motd != "") {
1101                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1102         }
1103         return s;
1104 }
1105
1106 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1107
1108 /**
1109 =============
1110 ClientConnect
1111
1112 Called when a client connects to the server
1113 =============
1114 */
1115 void ClientConnect(entity this)
1116 {
1117         if (Ban_MaybeEnforceBanOnce(this)) return;
1118         assert(!IS_CLIENT(this), return);
1119         this.flags |= FL_CLIENT;
1120         assert(player_count >= 0, player_count = 0);
1121
1122         TRANSMUTE(Client, this);
1123         CS(this).version_nagtime = time + 10 + random() * 10;
1124
1125         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1126
1127         bot_clientconnect(this);
1128
1129         Player_DetermineForcedTeam(this);
1130
1131         TRANSMUTE(Observer, this);
1132
1133         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1134
1135         // always track bots, don't ask for cl_allow_uidtracking
1136         if (IS_BOT_CLIENT(this))
1137                 PlayerStats_GameReport_AddPlayer(this);
1138         else
1139                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1140
1141         if (autocvar_sv_eventlog)
1142                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1143
1144         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1145
1146         stuffcmd(this, clientstuff, "\n");
1147         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1148
1149         FixClientCvars(this);
1150
1151         // get version info from player
1152         stuffcmd(this, "cmd clientversion $gameversion\n");
1153
1154         // notify about available teams
1155         if (teamplay)
1156         {
1157                 entity balance = TeamBalance_CheckAllowedTeams(this);
1158                 int t = TeamBalance_GetAllowedTeams(balance);
1159                 TeamBalance_Destroy(balance);
1160                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1161         }
1162         else
1163         {
1164                 stuffcmd(this, "set _teams_available 0\n");
1165         }
1166
1167         bot_relinkplayerlist();
1168
1169         CS(this).spectatortime = time;
1170         if (blockSpectators)
1171         {
1172                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1173         }
1174
1175         CS(this).jointime = time;
1176
1177         if (IS_REAL_CLIENT(this))
1178         {
1179                 if (g_weaponarena_weapons == WEPSET(TUBA))
1180                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1181         }
1182
1183         if (!autocvar_sv_foginterval && world.fog != "")
1184                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1185
1186         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1187                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1188                         send_CSQC_teamnagger();
1189
1190         CSQCMODEL_AUTOINIT(this);
1191
1192         CS(this).model_randomizer = random();
1193
1194         if (IS_REAL_CLIENT(this))
1195                 sv_notice_join(this);
1196
1197         this.move_qcphysics = autocvar_sv_qcphysics;
1198
1199         // update physics stats (players can spawn before physics runs)
1200         Physics_UpdateStats(this);
1201
1202         IL_EACH(g_initforplayer, it.init_for_player, {
1203                 it.init_for_player(it, this);
1204         });
1205
1206         Handicap_Initialize(this);
1207
1208         MUTATOR_CALLHOOK(ClientConnect, this);
1209
1210         if (IS_REAL_CLIENT(this))
1211         {
1212                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1213                 {
1214                         CS(this).motd_actived_time = -1;
1215                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1216                 }
1217         }
1218 }
1219 /*
1220 =============
1221 ClientDisconnect
1222
1223 Called when a client disconnects from the server
1224 =============
1225 */
1226 .entity chatbubbleentity;
1227 void ClientDisconnect(entity this)
1228 {
1229         assert(IS_CLIENT(this), return);
1230
1231         PlayerStats_GameReport_FinalizePlayer(this);
1232         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1233         if (CS(this).active_minigame) part_minigame(this);
1234         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1235
1236         if (autocvar_sv_eventlog)
1237                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1238
1239         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1240
1241         if(IS_SPEC(this))
1242                 SetSpectatee(this, NULL);
1243
1244         MUTATOR_CALLHOOK(ClientDisconnect, this);
1245
1246         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1247         strfree(CS_CVAR(this).weaponorder_byimpulse);
1248         ClientState_detach(this);
1249
1250         Portal_ClearAll(this);
1251
1252         Unfreeze(this, false);
1253
1254         RemoveGrapplingHooks(this);
1255
1256         // Here, everything has been done that requires this player to be a client.
1257
1258         this.flags &= ~FL_CLIENT;
1259
1260         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1261         if (this.killindicator) delete(this.killindicator);
1262
1263         IL_EACH(g_counters, it.realowner == this,
1264         {
1265                 delete(it);
1266         });
1267
1268         WaypointSprite_PlayerGone(this);
1269
1270         bot_relinkplayerlist();
1271
1272         strfree(this.clientstatus);
1273         if (this.personal) delete(this.personal);
1274
1275         this.playerid = 0;
1276         ReadyCount();
1277         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1278
1279         ONREMOVE(this);
1280 }
1281
1282 void ChatBubbleThink(entity this)
1283 {
1284         this.nextthink = time;
1285         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1286         {
1287                 if(this.owner) // but why can that ever be NULL?
1288                         this.owner.chatbubbleentity = NULL;
1289                 delete(this);
1290                 return;
1291         }
1292
1293         this.mdl = "";
1294
1295         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1296         {
1297                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1298                         this.mdl = "models/sprites/minigame_busy.iqm";
1299                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1300                         this.mdl = "models/misc/chatbubble.spr";
1301         }
1302
1303         if ( this.model != this.mdl )
1304                 _setmodel(this, this.mdl);
1305
1306 }
1307
1308 void UpdateChatBubble(entity this)
1309 {
1310         if (this.alpha < 0)
1311                 return;
1312         // spawn a chatbubble entity if needed
1313         if (!this.chatbubbleentity)
1314         {
1315                 this.chatbubbleentity = new(chatbubbleentity);
1316                 this.chatbubbleentity.owner = this;
1317                 this.chatbubbleentity.exteriormodeltoclient = this;
1318                 setthink(this.chatbubbleentity, ChatBubbleThink);
1319                 this.chatbubbleentity.nextthink = time;
1320                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1321                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1322                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1323                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1324                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1325                 //this.chatbubbleentity.model = "";
1326                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1327         }
1328 }
1329
1330 void calculate_player_respawn_time(entity this)
1331 {
1332         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1333                 return;
1334
1335         float gametype_setting_tmp;
1336         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1337         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1338         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1339         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1340         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1341         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1342
1343         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1344         if (teamplay)
1345         {
1346                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1347                         if(it.team == this.team)
1348                                 ++pcount;
1349                 });
1350                 if (sdelay_small_count == 0)
1351                         sdelay_small_count = 1;
1352                 if (sdelay_large_count == 0)
1353                         sdelay_large_count = 1;
1354         }
1355         else
1356         {
1357                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1358                         ++pcount;
1359                 });
1360                 if (sdelay_small_count == 0)
1361                 {
1362                         if (IS_INDEPENDENT_PLAYER(this))
1363                         {
1364                                 // Players play independently. No point in requiring enemies.
1365                                 sdelay_small_count = 1;
1366                         }
1367                         else
1368                         {
1369                                 // Players play AGAINST each other. Enemies required.
1370                                 sdelay_small_count = 2;
1371                         }
1372                 }
1373                 if (sdelay_large_count == 0)
1374                 {
1375                         if (IS_INDEPENDENT_PLAYER(this))
1376                         {
1377                                 // Players play independently. No point in requiring enemies.
1378                                 sdelay_large_count = 1;
1379                         }
1380                         else
1381                         {
1382                                 // Players play AGAINST each other. Enemies required.
1383                                 sdelay_large_count = 2;
1384                         }
1385                 }
1386         }
1387
1388         float sdelay;
1389
1390         if (pcount <= sdelay_small_count)
1391                 sdelay = sdelay_small;
1392         else if (pcount >= sdelay_large_count)
1393                 sdelay = sdelay_large;
1394         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1395                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1396
1397         if(waves)
1398                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1399         else
1400                 this.respawn_time = time + sdelay;
1401
1402         if(sdelay < sdelay_max)
1403                 this.respawn_time_max = time + sdelay_max;
1404         else
1405                 this.respawn_time_max = this.respawn_time;
1406
1407         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1408                 this.respawn_countdown = 10; // first number to count down from is 10
1409         else
1410                 this.respawn_countdown = -1; // do not count down
1411
1412         if(autocvar_g_forced_respawn)
1413                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1414 }
1415
1416 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1417 // added to the model skins
1418 /*void UpdateColorModHack()
1419 {
1420         float c;
1421         c = this.clientcolors & 15;
1422         // LordHavoc: only bothering to support white, green, red, yellow, blue
1423              if (!teamplay) this.colormod = '0 0 0';
1424         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1425         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1426         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1427         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1428         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1429         else this.colormod = '1 1 1';
1430 }*/
1431
1432 void respawn(entity this)
1433 {
1434         bool damagedbycontents_prev = this.damagedbycontents;
1435         if(this.alpha >= 0)
1436         {
1437                 if(autocvar_g_respawn_ghosts)
1438                 {
1439                         this.solid = SOLID_NOT;
1440                         this.takedamage = DAMAGE_NO;
1441                         this.damagedbycontents = false;
1442                         set_movetype(this, MOVETYPE_FLY);
1443                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1444                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1445                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1446                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1447                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1448                         if(autocvar_g_respawn_ghosts_time > 0)
1449                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1450                 }
1451                 else
1452                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1453         }
1454
1455         CopyBody(this, 1);
1456         this.damagedbycontents = damagedbycontents_prev;
1457
1458         this.effects |= EF_NODRAW; // prevent another CopyBody
1459         PutClientInServer(this);
1460 }
1461
1462 void play_countdown(entity this, float finished, Sound samp)
1463 {
1464         TC(Sound, samp);
1465         if(IS_REAL_CLIENT(this))
1466                 if(floor(finished - time - frametime) != floor(finished - time))
1467                         if(finished - time < 6)
1468                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1469 }
1470
1471 void player_powerups_remove_all(entity this)
1472 {
1473         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1474         {
1475                 if (time > game_starttime + 1)
1476                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1477                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1478                 this.items &= ~ITEM_Strength.m_itemid;
1479                 this.items &= ~ITEM_Shield.m_itemid;
1480                 this.items -= (this.items & IT_SUPERWEAPON);
1481         }
1482 }
1483
1484 void player_powerups(entity this)
1485 {
1486         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1487                 this.modelflags |= MF_ROCKET;
1488         else
1489                 this.modelflags &= ~MF_ROCKET;
1490
1491         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1492
1493         if (IS_DEAD(this))
1494                 player_powerups_remove_all(this);
1495
1496         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1497                 return;
1498
1499         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1500         int items_prev = this.items;
1501
1502         Fire_ApplyDamage(this);
1503         Fire_ApplyEffect(this);
1504
1505         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1506         {
1507                 if (this.items & ITEM_Strength.m_itemid)
1508                 {
1509                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1510                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1511                         if (time > STAT(STRENGTH_FINISHED, this))
1512                         {
1513                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1514                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1515                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1516                         }
1517                 }
1518                 else
1519                 {
1520                         if (time < STAT(STRENGTH_FINISHED, this))
1521                         {
1522                                 this.items = this.items | ITEM_Strength.m_itemid;
1523                                 if(!g_cts)
1524                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1525                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1526                         }
1527                 }
1528                 if (this.items & ITEM_Shield.m_itemid)
1529                 {
1530                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1531                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1532                         if (time > STAT(INVINCIBLE_FINISHED, this))
1533                         {
1534                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1535                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1536                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1537                         }
1538                 }
1539                 else
1540                 {
1541                         if (time < STAT(INVINCIBLE_FINISHED, this))
1542                         {
1543                                 this.items = this.items | ITEM_Shield.m_itemid;
1544                                 if(!g_cts)
1545                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1547                         }
1548                 }
1549                 if (this.items & IT_SUPERWEAPON)
1550                 {
1551                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1552                         {
1553                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1554                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1555                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1556                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1557                         }
1558                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1559                         {
1560                                 // don't let them run out
1561                         }
1562                         else
1563                         {
1564                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1565                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1566                                 {
1567                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1568                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1569                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1570                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1571                                 }
1572                         }
1573                 }
1574                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1575                 {
1576                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1577                         {
1578                                 this.items = this.items | IT_SUPERWEAPON;
1579                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1580                                 {
1581                                         if(!g_cts)
1582                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1583                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1584                                 }
1585                         }
1586                         else
1587                         {
1588                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1589                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1590                         }
1591                 }
1592                 else
1593                 {
1594                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1595                 }
1596         }
1597
1598         if(autocvar_g_nodepthtestplayers)
1599                 this.effects = this.effects | EF_NODEPTHTEST;
1600
1601         if(autocvar_g_fullbrightplayers)
1602                 this.effects = this.effects | EF_FULLBRIGHT;
1603
1604         if (time >= game_starttime)
1605         if (time < this.spawnshieldtime)
1606                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1607
1608         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1609 }
1610
1611 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1612 {
1613         if(current > stable)
1614                 return current;
1615         else if(current > stable - 0.25) // when close enough, "snap"
1616                 return stable;
1617         else
1618                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1619 }
1620
1621 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1622 {
1623         if(current < stable)
1624                 return current;
1625         else if(current < stable + 0.25) // when close enough, "snap"
1626                 return stable;
1627         else
1628                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1629 }
1630
1631 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1632 {
1633         float old = GetResource(this, res);
1634         float current = old;
1635         if(current > rotstable)
1636         {
1637                 if(rotframetime > 0)
1638                 {
1639                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1640                         current = max(rotstable, current - rotlinear * rotframetime);
1641                 }
1642         }
1643         else if(current < regenstable)
1644         {
1645                 if(regenframetime > 0)
1646                 {
1647                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1648                         current = min(regenstable, current + regenlinear * regenframetime);
1649                 }
1650         }
1651
1652         float limit = GetResourceLimit(this, res) * limit_mod;
1653         if(current > limit)
1654                 current = limit;
1655
1656         if (current != old)
1657                 SetResource(this, res, current);
1658 }
1659
1660 void player_regen(entity this)
1661 {
1662         float max_mod, regen_mod, rot_mod, limit_mod;
1663         max_mod = regen_mod = rot_mod = limit_mod = 1;
1664
1665         float regen_health = autocvar_g_balance_health_regen;
1666         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1667         float regen_health_rot = autocvar_g_balance_health_rot;
1668         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1669         float regen_health_stable = autocvar_g_balance_health_regenstable;
1670         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1671         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1672                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1673         max_mod = M_ARGV(1, float);
1674         regen_mod = M_ARGV(2, float);
1675         rot_mod = M_ARGV(3, float);
1676         limit_mod = M_ARGV(4, float);
1677         regen_health = M_ARGV(5, float);
1678         regen_health_linear = M_ARGV(6, float);
1679         regen_health_rot = M_ARGV(7, float);
1680         regen_health_rotlinear = M_ARGV(8, float);
1681         regen_health_stable = M_ARGV(9, float);
1682         regen_health_rotstable = M_ARGV(10, float);
1683
1684         if(!mutator_returnvalue)
1685         if(!STAT(FROZEN, this))
1686         {
1687                 float maxa = autocvar_g_balance_armor_rotstable;
1688                 float mina = autocvar_g_balance_armor_regenstable;
1689
1690                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1691                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1692                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1693
1694                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1695                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1696                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1697         }
1698
1699         // if player rotted to death...  die!
1700         // check this outside above checks, as player may still be able to rot to death
1701         if(GetResource(this, RES_HEALTH) < 1)
1702         {
1703                 if(this.vehicle)
1704                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1705                 if(this.event_damage)
1706                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1707         }
1708
1709         if (!(this.items & IT_UNLIMITED_AMMO))
1710         {
1711                 float maxf = autocvar_g_balance_fuel_rotstable;
1712                 float minf = autocvar_g_balance_fuel_regenstable;
1713
1714                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1715                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1716                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1717         }
1718 }
1719
1720 bool zoomstate_set;
1721 void SetZoomState(entity this, float newzoom)
1722 {
1723         if(newzoom != CS(this).zoomstate)
1724         {
1725                 CS(this).zoomstate = newzoom;
1726                 ClientData_Touch(this);
1727         }
1728         zoomstate_set = true;
1729 }
1730
1731 void GetPressedKeys(entity this)
1732 {
1733         MUTATOR_CALLHOOK(GetPressedKeys, this);
1734         if (game_stopped)
1735         {
1736                 CS(this).pressedkeys = 0;
1737                 STAT(PRESSED_KEYS, this) = 0;
1738                 return;
1739         }
1740
1741         int keys = STAT(PRESSED_KEYS, this);
1742         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1743         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1744         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1745         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1746
1747         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1748         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1749         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1750         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1751         CS(this).pressedkeys = keys; // store for other users
1752
1753         STAT(PRESSED_KEYS, this) = keys;
1754 }
1755
1756 /*
1757 ======================
1758 spectate mode routines
1759 ======================
1760 */
1761
1762 void SpectateCopy(entity this, entity spectatee)
1763 {
1764         TC(Client, this); TC(Client, spectatee);
1765
1766         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1767         PS(this) = PS(spectatee);
1768         this.armortype = spectatee.armortype;
1769         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1770         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1771         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1772         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1773         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1774         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1775         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1776         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1777         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1778         CS(this).impulse = 0;
1779         this.disableclientprediction = 1; // no need to run prediction on a spectator
1780         this.items = spectatee.items;
1781         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1782         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1783         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1784         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1785         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1786         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1787         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1788         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1789         this.punchangle = spectatee.punchangle;
1790         this.view_ofs = spectatee.view_ofs;
1791         this.velocity = spectatee.velocity;
1792         this.dmg_take = spectatee.dmg_take;
1793         this.dmg_save = spectatee.dmg_save;
1794         this.dmg_inflictor = spectatee.dmg_inflictor;
1795         this.v_angle = spectatee.v_angle;
1796         this.angles = spectatee.v_angle;
1797         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1798         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1799         this.viewloc = spectatee.viewloc;
1800         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1801                 this.fixangle = true;
1802         setorigin(this, spectatee.origin);
1803         setsize(this, spectatee.mins, spectatee.maxs);
1804         SetZoomState(this, CS(spectatee).zoomstate);
1805
1806     anticheat_spectatecopy(this, spectatee);
1807         STAT(HUD, this) = STAT(HUD, spectatee);
1808         if(spectatee.vehicle)
1809     {
1810         this.angles = spectatee.v_angle;
1811
1812         //this.fixangle = false;
1813         //this.velocity = spectatee.vehicle.velocity;
1814         this.vehicle_health = spectatee.vehicle_health;
1815         this.vehicle_shield = spectatee.vehicle_shield;
1816         this.vehicle_energy = spectatee.vehicle_energy;
1817         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1818         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1819         this.vehicle_reload1 = spectatee.vehicle_reload1;
1820         this.vehicle_reload2 = spectatee.vehicle_reload2;
1821
1822         //msg_entity = this;
1823
1824        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1825             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1826            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1827            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1828
1829         //WriteByte (MSG_ONE, SVC_SETVIEW);
1830         //    WriteEntity(MSG_ONE, this);
1831         //makevectors(spectatee.v_angle);
1832         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1833     }
1834 }
1835
1836 bool SpectateUpdate(entity this)
1837 {
1838         if(!this.enemy)
1839                 return false;
1840
1841         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1842         {
1843                 SetSpectatee(this, NULL);
1844                 return false;
1845         }
1846
1847         SpectateCopy(this, this.enemy);
1848
1849         return true;
1850 }
1851
1852 bool SpectateSet(entity this)
1853 {
1854         if(!IS_PLAYER(this.enemy))
1855                 return false;
1856
1857         ClientData_Touch(this.enemy);
1858
1859         msg_entity = this;
1860         WriteByte(MSG_ONE, SVC_SETVIEW);
1861         WriteEntity(MSG_ONE, this.enemy);
1862         set_movetype(this, MOVETYPE_NONE);
1863         accuracy_resend(this);
1864
1865         if(!SpectateUpdate(this))
1866                 PutObserverInServer(this);
1867
1868         return true;
1869 }
1870
1871 void SetSpectatee_status(entity this, int spectatee_num)
1872 {
1873         int oldspectatee_status = CS(this).spectatee_status;
1874         CS(this).spectatee_status = spectatee_num;
1875
1876         if (CS(this).spectatee_status != oldspectatee_status)
1877         {
1878                 if (STAT(PRESSED_KEYS, this))
1879                 {
1880                         CS(this).pressedkeys = 0;
1881                         STAT(PRESSED_KEYS, this) = 0;
1882                 }
1883                 ClientData_Touch(this);
1884                 if (g_race || g_cts) race_InitSpectator();
1885         }
1886 }
1887
1888 void SetSpectatee(entity this, entity spectatee)
1889 {
1890         if(IS_BOT_CLIENT(this))
1891                 return; // bots abuse .enemy, this code is useless to them
1892
1893         entity old_spectatee = this.enemy;
1894
1895         this.enemy = spectatee;
1896
1897         // WEAPONTODO
1898         // these are required to fix the spectator bug with arc
1899         if(old_spectatee)
1900         {
1901                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1902                 {
1903                         .entity weaponentity = weaponentities[slot];
1904                         if(old_spectatee.(weaponentity).arc_beam)
1905                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1906                 }
1907         }
1908         if(this.enemy)
1909         {
1910                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1911                 {
1912                         .entity weaponentity = weaponentities[slot];
1913                         if(this.enemy.(weaponentity).arc_beam)
1914                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1915                 }
1916         }
1917
1918         if (this.enemy)
1919                 SetSpectatee_status(this, etof(this.enemy));
1920
1921         // needed to update spectator list
1922         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1923 }
1924
1925 bool Spectate(entity this, entity pl)
1926 {
1927         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1928                 return false;
1929         pl = M_ARGV(1, entity);
1930
1931         SetSpectatee(this, pl);
1932         return SpectateSet(this);
1933 }
1934
1935 bool SpectateNext(entity this)
1936 {
1937         entity ent = find(this.enemy, classname, STR_PLAYER);
1938
1939         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1940                 ent = M_ARGV(1, entity);
1941         else if (!ent)
1942                 ent = find(ent, classname, STR_PLAYER);
1943
1944         if(ent) { SetSpectatee(this, ent); }
1945
1946         return SpectateSet(this);
1947 }
1948
1949 bool SpectatePrev(entity this)
1950 {
1951         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1952         entity ent = findchain(classname, STR_PLAYER);
1953         if (!ent) // no player
1954                 return false;
1955
1956         entity first = ent;
1957         // skip players until current spectated player
1958         if(this.enemy)
1959         while(ent && ent != this.enemy)
1960                 ent = ent.chain;
1961
1962         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1963         {
1964                 case MUT_SPECPREV_FOUND:
1965                         ent = M_ARGV(1, entity);
1966                         break;
1967                 case MUT_SPECPREV_RETURN:
1968                         return true;
1969                 case MUT_SPECPREV_CONTINUE:
1970                 default:
1971                 {
1972                         if(ent.chain)
1973                                 ent = ent.chain;
1974                         else
1975                                 ent = first;
1976                         break;
1977                 }
1978         }
1979
1980         SetSpectatee(this, ent);
1981         return SpectateSet(this);
1982 }
1983
1984 /*
1985 =============
1986 ShowRespawnCountdown()
1987
1988 Update a respawn countdown display.
1989 =============
1990 */
1991 void ShowRespawnCountdown(entity this)
1992 {
1993         float number;
1994         if(!IS_DEAD(this)) // just respawned?
1995                 return;
1996         else
1997         {
1998                 number = ceil(this.respawn_time - time);
1999                 if(number <= 0)
2000                         return;
2001                 if(number <= this.respawn_countdown)
2002                 {
2003                         this.respawn_countdown = number - 1;
2004                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2005                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2006                 }
2007         }
2008 }
2009
2010 .bool team_selected;
2011 bool ShowTeamSelection(entity this)
2012 {
2013         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2014                 return false;
2015         stuffcmd(this, "menu_showteamselect\n");
2016         return true;
2017 }
2018 void Join(entity this)
2019 {
2020         TRANSMUTE(Player, this);
2021
2022         if(!this.team_selected)
2023         if(autocvar_g_campaign || autocvar_g_balance_teams)
2024                 TeamBalance_JoinBestTeam(this);
2025
2026         if(autocvar_g_campaign)
2027                 campaign_bots_may_start = true;
2028
2029         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2030
2031         PutClientInServer(this);
2032
2033         if(IS_PLAYER(this))
2034         if(teamplay && this.team != -1)
2035         {
2036         }
2037         else
2038                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2039         this.team_selected = false;
2040
2041         // z411
2042         // send constant ready notification
2043         if(warmup_stage)
2044                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2045 }
2046
2047 int GetPlayerLimit()
2048 {
2049         if(g_duel)
2050                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2051         int player_limit = autocvar_g_maxplayers;
2052         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2053         player_limit = M_ARGV(0, int);
2054         return player_limit;
2055 }
2056
2057 /**
2058  * Determines whether the player is allowed to join. This depends on cvar
2059  * g_maxplayers, if it isn't used this function always return true, otherwise
2060  * it checks whether the number of currently playing players exceeds g_maxplayers.
2061  * @return int number of free slots for players, 0 if none
2062  */
2063 int nJoinAllowed(entity this, entity ignore)
2064 {
2065         if(!ignore)
2066         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2067         // so report 0 free slots if restricted
2068         {
2069                 if(autocvar_g_forced_team_otherwise == "spectate")
2070                         return 0;
2071                 if(autocvar_g_forced_team_otherwise == "spectator")
2072                         return 0;
2073         }
2074
2075         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2076                 return 0; // forced spectators can never join
2077
2078         // TODO simplify this
2079         int totalClients = 0;
2080         int currentlyPlaying = 0;
2081         FOREACH_CLIENT(true, {
2082                 if(it != ignore)
2083                         ++totalClients;
2084                 if(IS_REAL_CLIENT(it))
2085                 if(IS_PLAYER(it) || it.caplayer)
2086                         ++currentlyPlaying;
2087         });
2088
2089         int player_limit = GetPlayerLimit();
2090
2091         int free_slots = 0;
2092         if (!player_limit)
2093                 free_slots = maxclients - totalClients;
2094         else if(player_limit > 0 && currentlyPlaying < player_limit)
2095                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2096
2097         static float msg_time = 0;
2098         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2099         {
2100                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2101                 msg_time = time + 0.5;
2102         }
2103
2104         return free_slots;
2105 }
2106
2107 /**
2108  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2109  * g_maxplayers_spectator_blocktime seconds
2110  */
2111 void checkSpectatorBlock(entity this)
2112 {
2113         if(IS_SPEC(this) || IS_OBSERVER(this))
2114         if(!this.caplayer)
2115         if(IS_REAL_CLIENT(this))
2116         {
2117                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2118                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2119                         dropclient(this);
2120                 }
2121         }
2122 }
2123
2124 void PrintWelcomeMessage(entity this)
2125 {
2126         if(CS(this).motd_actived_time == 0)
2127         {
2128                 if (autocvar_g_campaign) {
2129                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2130                                 CS(this).motd_actived_time = time;
2131                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2132                         }
2133                 } else {
2134                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2135                                 CS(this).motd_actived_time = time;
2136                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2137                         }
2138                 }
2139         }
2140         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2141         {
2142                 if (autocvar_g_campaign) {
2143                         if (PHYS_INPUT_BUTTON_INFO(this))
2144                                 CS(this).motd_actived_time = time;
2145                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2146                                 CS(this).motd_actived_time = 0;
2147                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2148                         }
2149                 } else {
2150                         if (PHYS_INPUT_BUTTON_INFO(this))
2151                                 CS(this).motd_actived_time = time;
2152                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2153                                 CS(this).motd_actived_time = 0;
2154                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2155                         }
2156                 }
2157         }
2158         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2159         {
2160                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2161                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2162                 else if (CS(this).motd_actived_time == -2)
2163                 {
2164                         // instantly hide MOTD
2165                         CS(this).motd_actived_time = 0;
2166                         if (autocvar_g_campaign)
2167                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2168                         else
2169                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2170                 }
2171                 else if (IS_PLAYER(this) || IS_SPEC(this))
2172                 {
2173                         // FIXME occasionally for some reason MOTD never goes away
2174                         // delay MOTD removal a little bit in the hope it fixes this bug
2175                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2176                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2177                         else //if (CS(this).motd_actived_time < -2)
2178                                 CS(this).motd_actived_time++;
2179                 }
2180         }
2181 }
2182
2183 bool joinAllowed(entity this)
2184 {
2185         if (CS(this).version_mismatch) return false;
2186         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2187         if (!nJoinAllowed(this, this)) return false;
2188         if (teamplay && lockteams) return false;
2189         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2190         if (ShowTeamSelection(this)) return false;
2191         return true;
2192 }
2193
2194 .string shootfromfixedorigin;
2195 .bool dualwielding_prev;
2196 bool PlayerThink(entity this)
2197 {
2198         if (game_stopped || intermission_running) {
2199                 this.modelflags &= ~MF_ROCKET;
2200                 if(intermission_running)
2201                         IntermissionThink(this);
2202                 return false;
2203         }
2204
2205         if (game_timeout) {
2206         // don't allow the player to turn around while game is paused
2207                 // FIXME turn this into CSQC stuff
2208                 this.v_angle = this.lastV_angle;
2209                 this.angles = this.lastV_angle;
2210                 this.fixangle = true;
2211                 return false;
2212         }
2213
2214         if (frametime) player_powerups(this);
2215
2216         if (IS_DEAD(this)) {
2217                 if (this.personal && g_race_qualifying) {
2218                         if (time > this.respawn_time) {
2219                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2220                                 respawn(this);
2221                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2222                         }
2223                 } else {
2224                         if (frametime) player_anim(this);
2225
2226                         if (this.respawn_flags & RESPAWN_DENY)
2227                         {
2228                                 STAT(RESPAWN_TIME, this) = 0;
2229                                 return false;
2230                         }
2231
2232                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2233
2234                         switch(this.deadflag)
2235                         {
2236                                 case DEAD_DYING:
2237                                 {
2238                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2239                                                 this.deadflag = DEAD_RESPAWNING;
2240                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2241                                                 this.deadflag = DEAD_DEAD;
2242                                         break;
2243                                 }
2244                                 case DEAD_DEAD:
2245                                 {
2246                                         if (button_pressed)
2247                                                 this.deadflag = DEAD_RESPAWNABLE;
2248                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2249                                                 this.deadflag = DEAD_RESPAWNING;
2250                                         break;
2251                                 }
2252                                 case DEAD_RESPAWNABLE:
2253                                 {
2254                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2255                                                 this.deadflag = DEAD_RESPAWNING;
2256                                         break;
2257                                 }
2258                                 case DEAD_RESPAWNING:
2259                                 {
2260                                         if (time > this.respawn_time)
2261                                         {
2262                                                 this.respawn_time = time + 1; // only retry once a second
2263                                                 this.respawn_time_max = this.respawn_time;
2264                                                 respawn(this);
2265                                         }
2266                                         break;
2267                                 }
2268                         }
2269
2270                         ShowRespawnCountdown(this);
2271
2272                         if (this.respawn_flags & RESPAWN_SILENT)
2273                                 STAT(RESPAWN_TIME, this) = 0;
2274                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2275                         {
2276                                 if (time < this.respawn_time)
2277                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2278                                 else if (this.deadflag != DEAD_RESPAWNING)
2279                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2280                         }
2281                         else
2282                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2283                 }
2284
2285                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2286                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2287                         STAT(RESPAWN_TIME, this) *= -1;
2288
2289                 return false;
2290         }
2291
2292         FixPlayermodel(this);
2293
2294         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2295                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2296                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2297         }
2298
2299         // reset gun alignment when dual wielding status changes
2300         // to ensure guns are always aligned right and left
2301         bool dualwielding = W_DualWielding(this);
2302         if(this.dualwielding_prev != dualwielding)
2303         {
2304                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2305                 this.dualwielding_prev = dualwielding;
2306         }
2307
2308         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2309         //if(frametime)
2310         {
2311                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2312                 {
2313                         .entity weaponentity = weaponentities[slot];
2314                         if(WEP_CVAR(vortex, charge_always))
2315                                 W_Vortex_Charge(this, weaponentity, frametime);
2316                         W_WeaponFrame(this, weaponentity);
2317                 }
2318         }
2319
2320         if (frametime)
2321         {
2322                 // WEAPONTODO: Add a weapon request for this
2323                 // rot vortex charge to the charge limit
2324                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2325                 {
2326                         .entity weaponentity = weaponentities[slot];
2327                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2328                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2329                 }
2330
2331                 player_regen(this);
2332                 player_anim(this);
2333                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2334         }
2335
2336         monsters_setstatus(this);
2337
2338         return true;
2339 }
2340
2341 .bool would_spectate;
2342 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2343 void ObserverOrSpectatorThink(entity this)
2344 {
2345         bool is_spec = IS_SPEC(this);
2346         if ( CS(this).impulse )
2347         {
2348                 int r = MinigameImpulse(this, CS(this).impulse);
2349                 if (!is_spec || r)
2350                         CS(this).impulse = 0;
2351
2352                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2353                 {
2354                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2355                         CS(this).impulse = 0;
2356                         return;
2357                 }
2358         }
2359
2360         if (this.flags & FL_JUMPRELEASED) {
2361                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2362                         this.flags &= ~FL_JUMPRELEASED;
2363                         this.flags |= FL_SPAWNING;
2364                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2365                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2366                         this.flags &= ~FL_JUMPRELEASED;
2367                         if(SpectateNext(this)) {
2368                                 TRANSMUTE(Spectator, this);
2369                         } else if (is_spec) {
2370                                 TRANSMUTE(Observer, this);
2371                                 PutClientInServer(this);
2372                         }
2373                         if (is_spec)
2374                                 CS(this).impulse = 0;
2375                 } else if (is_spec) {
2376                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2377                                 this.flags &= ~FL_JUMPRELEASED;
2378                                 if(SpectatePrev(this)) {
2379                                         TRANSMUTE(Spectator, this);
2380                                 } else {
2381                                         TRANSMUTE(Observer, this);
2382                                         PutClientInServer(this);
2383                                 }
2384                                 CS(this).impulse = 0;
2385                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2386                                 this.would_spectate = false;
2387                                 this.flags &= ~FL_JUMPRELEASED;
2388                                 TRANSMUTE(Observer, this);
2389                                 PutClientInServer(this);
2390                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2391                                 PutObserverInServer(this);
2392                                 this.would_spectate = true;
2393                         }
2394                 }
2395                 else {
2396                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS_CVAR(this).cvar_cl_clippedspectating : !CS_CVAR(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2397                         set_movetype(this, preferred_movetype);
2398                 }
2399         } else { // jump pressed
2400                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2401                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2402                         this.flags |= FL_JUMPRELEASED;
2403                         if(this.flags & FL_SPAWNING)
2404                         {
2405                                 this.flags &= ~FL_SPAWNING;
2406                                 if(joinAllowed(this))
2407                                         Join(this);
2408                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2409                                         CS(this).autojoin_checked = -1;
2410                                 return;
2411                         }
2412                 }
2413                 if(is_spec && !SpectateUpdate(this))
2414                         PutObserverInServer(this);
2415         }
2416         if (is_spec)
2417                 this.flags |= FL_CLIENT | FL_NOTARGET;
2418 }
2419
2420 void PlayerUseKey(entity this)
2421 {
2422         if (!IS_PLAYER(this))
2423                 return;
2424
2425         if(this.vehicle)
2426         {
2427                 if(!game_stopped)
2428                 {
2429                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2430                         return;
2431                 }
2432         }
2433         else if(autocvar_g_vehicles_enter)
2434         {
2435                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2436                 {
2437                         entity head, closest_target = NULL;
2438                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2439
2440                         while(head) // find the closest acceptable target to enter
2441                         {
2442                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2443                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2444                                 {
2445                                         if(closest_target)
2446                                         {
2447                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2448                                                 { closest_target = head; }
2449                                         }
2450                                         else { closest_target = head; }
2451                                 }
2452
2453                                 head = head.chain;
2454                         }
2455
2456                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2457                 }
2458         }
2459
2460         // a use key was pressed; call handlers
2461         MUTATOR_CALLHOOK(PlayerUseKey, this);
2462 }
2463
2464
2465 /*
2466 =============
2467 PlayerPreThink
2468
2469 Called every frame for each client before the physics are run
2470 =============
2471 */
2472 .float last_vehiclecheck;
2473 void PlayerPreThink (entity this)
2474 {
2475         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2476         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2477
2478         WarpZone_PlayerPhysics_FixVAngle(this);
2479
2480         if (frametime) {
2481                 // physics frames: update anticheat stuff
2482                 anticheat_prethink(this);
2483         }
2484
2485         if (blockSpectators && frametime) {
2486                 // WORKAROUND: only use dropclient in server frames (frametime set).
2487                 // Never use it in cl_movement frames (frametime zero).
2488                 checkSpectatorBlock(this);
2489         }
2490
2491         zoomstate_set = false;
2492
2493         // Check for nameless players
2494         if (this.netname == "" || this.netname != CS(this).netname_previous)
2495         {
2496                 bool assume_unchanged = (CS(this).netname_previous == "");
2497                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2498                 {
2499                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2500                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2501                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2502                         assume_unchanged = false;
2503                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2504                 }
2505                 if (isInvisibleString(this.netname))
2506                 {
2507                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2508                         sprint(this, "Warning: invisible names are not allowed.\n");
2509                         assume_unchanged = false;
2510                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2511                 }
2512                 if (!assume_unchanged && autocvar_sv_eventlog)
2513                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2514                 strcpy(CS(this).netname_previous, this.netname);
2515         }
2516
2517         // version nagging
2518         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2519         CS(this).version_nagtime = 0;
2520         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2521             // git client
2522         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2523             // git server
2524             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2525         } else {
2526             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2527             if (r < 0) { // old client
2528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2529             } else if (r > 0) { // old server
2530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2531             }
2532         }
2533     }
2534
2535         // GOD MODE info
2536         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2537         {
2538                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2539                 this.max_armorvalue = 0;
2540         }
2541
2542         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2543         {
2544                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2545                 {
2546                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2547                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2548                         if (this.iceblock)
2549                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2550
2551                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2552                                 Unfreeze(this, false);
2553                 }
2554                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2555                 {
2556                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2557                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2558
2559                         if (GetResource(this, RES_HEALTH) < 1)
2560                         {
2561                                 if (this.vehicle)
2562                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2563                                 if(this.event_damage)
2564                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2565                         }
2566                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2567                                 Unfreeze(this, false);
2568                 }
2569         }
2570
2571         MUTATOR_CALLHOOK(PlayerPreThink, this);
2572
2573         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2574         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2575         {
2576                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2577                 {
2578                         if(!it.owner)
2579                         {
2580                                 if(!it.team || SAME_TEAM(this, it))
2581                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2582                                 else if(autocvar_g_vehicles_steal)
2583                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2584                         }
2585                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2586                         {
2587                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2588                         }
2589                 });
2590
2591                 this.last_vehiclecheck = time + 1;
2592         }
2593
2594         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2595         {
2596                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2597                         PlayerUseKey(this);
2598                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2599         }
2600
2601         if (IS_REAL_CLIENT(this))
2602                 PrintWelcomeMessage(this);
2603
2604         if (IS_PLAYER(this)) {
2605                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2606                         error("Client can't be spawned as player on connection!");
2607                 if(!PlayerThink(this))
2608                         return;
2609         }
2610         else if (game_stopped || intermission_running) {
2611                 if(intermission_running)
2612                         IntermissionThink(this);
2613                 return;
2614         }
2615         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2616         {
2617                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2618                 CS(this).autojoin_checked = 1;
2619                 // don't do this in ClientConnect
2620                 // many things can go wrong if a client is spawned as player on connection
2621                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2622                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2623                                 && (!teamplay || autocvar_g_balance_teams)))
2624                 {
2625                         campaign_bots_may_start = true;
2626                         if(joinAllowed(this))
2627                                 Join(this);
2628                         return;
2629                 }
2630         }
2631         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2632                 ObserverOrSpectatorThink(this);
2633         }
2634
2635         // WEAPONTODO: Add weapon request for this
2636         if (!zoomstate_set) {
2637                 bool wep_zoomed = false;
2638                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2639                 {
2640                         .entity weaponentity = weaponentities[slot];
2641                         Weapon thiswep = this.(weaponentity).m_weapon;
2642                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2643                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2644                 }
2645                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2646         }
2647
2648         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2649         {
2650                 CS(this).teamkill_soundtime = 0;
2651
2652                 entity e = CS(this).teamkill_soundsource;
2653                 entity oldpusher = e.pusher;
2654                 e.pusher = this;
2655                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2656                 e.pusher = oldpusher;
2657         }
2658
2659         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2660                 CS(this).taunt_soundtime = 0;
2661                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2662         }
2663
2664         target_voicescript_next(this);
2665
2666         // WEAPONTODO: Move into weaponsystem somehow
2667         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2668         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2669         {
2670                 .entity weaponentity = weaponentities[slot];
2671                 if(this.(weaponentity).m_weapon == WEP_Null)
2672                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2673         }
2674 }
2675
2676 void DrownPlayer(entity this)
2677 {
2678         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2679                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2680         {
2681                 STAT(AIR_FINISHED, this) = 0;
2682                 return;
2683         }
2684
2685         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2686         {
2687                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2688                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2689                 STAT(AIR_FINISHED, this) = 0;
2690         }
2691         else
2692         {
2693                 if (!STAT(AIR_FINISHED, this))
2694                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2695                 if (STAT(AIR_FINISHED, this) < time)
2696                 {       // drown!
2697                         if (this.pain_finished < time)
2698                         {
2699                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2700                                 this.pain_finished = time + 0.5;
2701                         }
2702                 }
2703         }
2704 }
2705
2706 .bool move_qcphysics;
2707
2708 void Player_Physics(entity this)
2709 {
2710         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2711
2712         if(!this.move_qcphysics)
2713                 return;
2714
2715         if(!frametime && !CS(this).pm_frametime)
2716                 return;
2717
2718         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2719
2720         CS(this).pm_frametime = 0;
2721 }
2722
2723 /*
2724 =============
2725 PlayerPostThink
2726
2727 Called every frame for each client after the physics are run
2728 =============
2729 */
2730 void PlayerPostThink (entity this)
2731 {
2732         Player_Physics(this);
2733
2734         if (autocvar_sv_maxidle > 0)
2735         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2736         if (IS_REAL_CLIENT(this))
2737         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2738         {
2739                 int totalClients = 0;
2740                 if(autocvar_sv_maxidle_slots > 0)
2741                 {
2742                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2743                         {
2744                                 ++totalClients;
2745                         });
2746                 }
2747
2748                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2749                 { /* do nothing */ }
2750                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2751                 {
2752                         if (CS(this).idlekick_lasttimeleft)
2753                         {
2754                                 CS(this).idlekick_lasttimeleft = 0;
2755                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2756                         }
2757                 }
2758                 else
2759                 {
2760                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2761                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2762                                 if (!CS(this).idlekick_lasttimeleft)
2763                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2764                         }
2765                         if (timeleft <= 0) {
2766                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2767                                 dropclient(this);
2768                                 return;
2769                         }
2770                         else if (timeleft <= 10) {
2771                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2772                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2773                                 CS(this).idlekick_lasttimeleft = timeleft;
2774                         }
2775                 }
2776         }
2777
2778         CheatFrame(this);
2779
2780         if (game_stopped)
2781         {
2782                 this.solid = SOLID_NOT;
2783                 this.takedamage = DAMAGE_NO;
2784                 set_movetype(this, MOVETYPE_NONE);
2785                 CS(this).teamkill_complain = 0;
2786                 CS(this).teamkill_soundtime = 0;
2787                 CS(this).teamkill_soundsource = NULL;
2788         }
2789
2790         if (IS_PLAYER(this)) {
2791                 if(this.death_time == time && IS_DEAD(this))
2792                 {
2793                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2794                         // once all the damage events of this frame have been processed with normal size
2795                         this.maxs.z = 5;
2796                         setsize(this, this.mins, this.maxs);
2797                 }
2798                 DrownPlayer(this);
2799                 UpdateChatBubble(this);
2800                 if (CS(this).impulse) ImpulseCommands(this);
2801                 GetPressedKeys(this);
2802                 if (game_stopped)
2803                 {
2804                         CSQCMODEL_AUTOUPDATE(this);
2805                         return;
2806                 }
2807         }
2808         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2809         {
2810                 CS(this).pressedkeys = 0;
2811                 STAT(PRESSED_KEYS, this) = 0;
2812         }
2813
2814         if (this.waypointsprite_attachedforcarrier) {
2815                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2816                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2817         }
2818
2819         CSQCMODEL_AUTOUPDATE(this);
2820 }
2821
2822 // hack to copy the button fields from the client entity to the Client State
2823 void PM_UpdateButtons(entity this, entity store)
2824 {
2825         if(this.impulse)
2826                 store.impulse = this.impulse;
2827         this.impulse = 0;
2828
2829         bool typing = this.buttonchat || this.button12;
2830
2831         store.button0 = (typing) ? 0 : this.button0;
2832         //button1?!
2833         store.button2 = (typing) ? 0 : this.button2;
2834         store.button3 = (typing) ? 0 : this.button3;
2835         store.button4 = this.button4;
2836         store.button5 = (typing) ? 0 : this.button5;
2837         store.button6 = this.button6;
2838         store.button7 = this.button7;
2839         store.button8 = this.button8;
2840         store.button9 = this.button9;
2841         store.button10 = this.button10;
2842         store.button11 = this.button11;
2843         store.button12 = this.button12;
2844         store.button13 = this.button13;
2845         store.button14 = this.button14;
2846         store.button15 = this.button15;
2847         store.button16 = this.button16;
2848         store.buttonuse = this.buttonuse;
2849         store.buttonchat = this.buttonchat;
2850
2851         store.cursor_active = this.cursor_active;
2852         store.cursor_screen = this.cursor_screen;
2853         store.cursor_trace_start = this.cursor_trace_start;
2854         store.cursor_trace_endpos = this.cursor_trace_endpos;
2855         store.cursor_trace_ent = this.cursor_trace_ent;
2856
2857         store.ping = this.ping;
2858         store.ping_packetloss = this.ping_packetloss;
2859         store.ping_movementloss = this.ping_movementloss;
2860
2861         store.v_angle = this.v_angle;
2862         store.movement = this.movement;
2863 }
2864
2865 NET_HANDLE(fpsreport, bool)
2866 {
2867         int fps = ReadShort();
2868         PlayerScore_Set(sender, SP_FPS, fps);
2869         return true;
2870 }