qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/chat.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "damage.qh"
  16 #include "handicap.qh"
  17 #include "hook.qh"
  18 #include <server/intermission.qh>
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "clientkill.qh"
  22 #include "cheats.qh"
  23 #include "world.qh"
  24 #include <server/gamelog.qh>
  25 #include "race.qh"
  26 #include <server/main.qh>
  27 #include <server/mutators/_mod.qh>
  28 #include "antilag.qh"
  29 #include "campaign.qh"
  30 #include "command/common.qh"
  31 #include "scores_rules.qh"
  32 #include "weapons/common.qh"
  33
  34 #include "bot/api.qh"
  35
  36 #include "../common/ent_cs.qh"
  37 #include "../common/wepent.qh"
  38 #include <common/state.qh>
  39
  40 #include "compat/quake3.qh"
  41
  42 #include <common/effects/qc/globalsound.qh>
  43
  44 #include "../common/mapobjects/func/conveyor.qh"
  45 #include <common/mapobjects/func/ladder.qh>
  46 #include "../common/mapobjects/teleporters.qh"
  47 #include "../common/mapobjects/target/spawnpoint.qh"
  48 #include <common/mapobjects/trigger/counter.qh>
  49 #include <common/mapobjects/trigger/swamp.qh>
  50
  51 #include "../common/vehicles/all.qh"
  52
  53 #include "weapons/hitplot.qh"
  54 #include "weapons/selection.qh"
  55 #include "weapons/weaponsystem.qh"
  56
  57 #include "../common/net_notice.qh"
  58 #include "../common/net_linked.qh"
  59 #include "../common/physics/player.qh"
  60
  61 #include <common/vehicles/sv_vehicles.qh>
  62
  63 #include "../common/items/_mod.qh"
  64
  65 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  66
  67 #include "../common/mutators/mutator/waypoints/all.qh"
  68 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  69 #include <common/gamemodes/_mod.qh>
  70
  71 #include "../common/mapobjects/subs.qh"
  72 #include "../common/mapobjects/triggers.qh"
  73 #include "../common/mapobjects/trigger/secret.qh"
  74
  75 #include "../common/minigames/sv_minigames.qh"
  76
  77 #include "../common/items/inventory.qh"
  78
  79 #include "../common/monsters/sv_monsters.qh"
  80
  81 #include "../lib/warpzone/server.qh"
  82
  83 #include <common/mutators/mutator/overkill/oknex.qh>
  84
  85 #include <common/weapons/weapon/vortex.qh>
  86
  87 STATIC_METHOD(Client, Add, void(Client this, int _team))
  88 {
  89     ClientConnect(this);
  90     TRANSMUTE(Player, this);
  91     this.frame = 12; // 7
  92     this.team = _team;
  93     PutClientInServer(this);
  94 }
  95
  96 STATIC_METHOD(Client, Remove, void(Client this))
  97 {
  98     TRANSMUTE(Observer, this);
  99     PutClientInServer(this);
 100     ClientDisconnect(this);
 101 }
 102
 103 void send_CSQC_teamnagger() {
 104         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 105 }
 106
 107 int CountSpectators(entity player, entity to)
 108 {
 109         if(!player) { return 0; } // not sure how, but best to be safe
 110
 111         int spec_count = 0;
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 spec_count++;
 116         });
 117
 118         return spec_count;
 119 }
 120
 121 void WriteSpectators(entity player, entity to)
 122 {
 123         if(!player) { return; } // not sure how, but best to be safe
 124
 125         int spec_count = 0;
 126         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 127         {
 128                 if(spec_count >= MAX_SPECTATORS)
 129                         break;
 130                 WriteByte(MSG_ENTITY, num_for_edict(it));
 131                 ++spec_count;
 132         });
 133 }
 134
 135 bool ClientData_Send(entity this, entity to, int sf)
 136 {
 137         assert(to == this.owner, return false);
 138
 139         entity e = to;
 140         if (IS_SPEC(e)) e = e.enemy;
 141
 142         sf = 0;
 143         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 144         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 145         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 146         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 147
 148         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 149         WriteByte(MSG_ENTITY, sf);
 150
 151         if (sf & BIT(1))
 152                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 153
 154         if(sf & BIT(4))
 155         {
 156                 float specs = CountSpectators(e, to);
 157                 WriteByte(MSG_ENTITY, specs);
 158                 WriteSpectators(e, to);
 159         }
 160
 161         return true;
 162 }
 163
 164 void ClientData_Attach(entity this)
 165 {
 166         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 167         CS(this).clientdata.drawonlytoclient = this;
 168         CS(this).clientdata.owner = this;
 169 }
 170
 171 void ClientData_Detach(entity this)
 172 {
 173         delete(CS(this).clientdata);
 174         CS(this).clientdata = NULL;
 175 }
 176
 177 void ClientData_Touch(entity e)
 178 {
 179         entity cd = CS(e).clientdata;
 180         if (cd) { cd.SendFlags = 1; }
 181
 182         // make it spectatable
 183         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 184         {
 185                 entity cd = CS(it).clientdata;
 186                 if (cd) { cd.SendFlags = 1; }
 187         });
 188 }
 189
 190
 191 /*
 192 =============
 193 CheckPlayerModel
 194
 195 Checks if the argument string can be a valid playermodel.
 196 Returns a valid one in doubt.
 197 =============
 198 */
 199 string FallbackPlayerModel;
 200 string CheckPlayerModel(string plyermodel) {
 201         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 202         {
 203                 // note: we cannot summon Don Strunzone here, some player may
 204                 // still have the model string set. In case anyone manages how
 205                 // to change a cvar default, we'll have a small leak here.
 206                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 207         }
 208         // only in right path
 209         if( substring(plyermodel,0,14) != "models/player/")
 210                 return FallbackPlayerModel;
 211         // only good file extensions
 212         if(substring(plyermodel,-4,4) != ".zym")
 213         if(substring(plyermodel,-4,4) != ".dpm")
 214         if(substring(plyermodel,-4,4) != ".iqm")
 215         if(substring(plyermodel,-4,4) != ".md3")
 216         if(substring(plyermodel,-4,4) != ".psk")
 217                 return FallbackPlayerModel;
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9,5) == "_lod1")
 220                 return FallbackPlayerModel;
 221         if(substring(plyermodel, -9,5) == "_lod2")
 222                 return FallbackPlayerModel;
 223         if(plyermodel != strtolower(plyermodel))
 224                 return FallbackPlayerModel;
 225         // also, restrict to server models
 226         if(autocvar_sv_servermodelsonly)
 227         {
 228                 if(!fexists(plyermodel))
 229                         return FallbackPlayerModel;
 230         }
 231         return plyermodel;
 232 }
 233
 234 void setplayermodel(entity e, string modelname)
 235 {
 236         precache_model(modelname);
 237         _setmodel(e, modelname);
 238         player_setupanimsformodel(e);
 239         if(!autocvar_g_debug_globalsounds)
 240                 UpdatePlayerSounds(e);
 241 }
 242
 243 /** putting a client as observer in the server */
 244 void PutObserverInServer(entity this)
 245 {
 246         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 247         PlayerState_detach(this);
 248
 249         if (IS_PLAYER(this))
 250         {
 251                 if(GetResource(this, RES_HEALTH) >= 1)
 252                 {
 253                         // despawn effect
 254                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 255                 }
 256
 257                 // was a player, recount votes and ready status
 258                 if(IS_REAL_CLIENT(this))
 259                 {
 260                         if (vote_called) { VoteCount(false); }
 261                         ReadyCount();
 262                 }
 263         }
 264
 265         entity spot = SelectSpawnPoint(this, true);
 266         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267         this.angles = vec2(spot.angles);
 268         this.fixangle = true;
 269         // offset it so that the spectator spawns higher off the ground, looks better this way
 270         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         if (IS_REAL_CLIENT(this))
 272         {
 273                 msg_entity = this;
 274                 WriteByte(MSG_ONE, SVC_SETVIEW);
 275                 WriteEntity(MSG_ONE, this);
 276         }
 277         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 278         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 279         if(!autocvar_g_debug_globalsounds)
 280         {
 281                 // needed for player sounds
 282                 this.model = "";
 283                 FixPlayermodel(this);
 284         }
 285         setmodel(this, MDL_Null);
 286         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 287         this.view_ofs = '0 0 0';
 288
 289         RemoveGrapplingHooks(this);
 290         Portal_ClearAll(this);
 291         Unfreeze(this, false);
 292         SetSpectatee(this, NULL);
 293
 294         if (this.alivetime)
 295         {
 296                 if (!warmup_stage)
 297                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 298                 this.alivetime = 0;
 299         }
 300
 301         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 302
 303         WaypointSprite_PlayerDead(this);
 304
 305         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 306                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317         STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_finished = 0;
 344         STAT(STRENGTH_FINISHED, this) = 0;
 345         STAT(INVINCIBLE_FINISHED, this) = 0;
 346         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 347         STAT(AIR_FINISHED, this) = 0;
 348         //this.dphitcontentsmask = 0;
 349         this.dphitcontentsmask = DPCONTENTS_SOLID;
 350         if (autocvar_g_playerclip_collisions)
 351                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         UNSET_DUCKED(this);
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360         this.draggable = drag_undraggable;
 361
 362         this.items = 0;
 363         STAT(WEAPONS, this) = '0 0 0';
 364         this.drawonlytoclient = this;
 365
 366         this.viewloc = NULL;
 367
 368         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 369
 370         this.weaponmodel = "";
 371         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 372         {
 373                 this.weaponentities[slot] = NULL;
 374         }
 375         this.exteriorweaponentity = NULL;
 376         CS(this).killcount = FRAGS_SPECTATOR;
 377         this.velocity = '0 0 0';
 378         this.avelocity = '0 0 0';
 379         this.punchangle = '0 0 0';
 380         this.punchvector = '0 0 0';
 381         this.oldvelocity = this.velocity;
 382         this.fire_endtime = -1;
 383         this.event_damage = func_null;
 384         this.event_heal = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394
 395         if (mutator_returnvalue)
 396         {
 397                 // mutator prevents resetting teams+score
 398         }
 399         else
 400         {
 401                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 402                 this.frags = FRAGS_SPECTATOR;
 403         }
 404         if (CS(this).just_joined)
 405                 CS(this).just_joined = false;
 406 }
 407
 408 int player_getspecies(entity this)
 409 {
 410         get_model_parameters(this.model, this.skin);
 411         int s = get_model_parameters_species;
 412         get_model_parameters(string_null, 0);
 413         if (s < 0) return SPECIES_HUMAN;
 414         return s;
 415 }
 416
 417 .float model_randomizer;
 418 void FixPlayermodel(entity player)
 419 {
 420         string defaultmodel = "";
 421         int defaultskin = 0;
 422         if(autocvar_sv_defaultcharacter)
 423         {
 424                 if(teamplay)
 425                 {
 426                         switch(player.team)
 427                         {
 428                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 429                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 430                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 431                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 432                         }
 433                 }
 434
 435                 if(defaultmodel == "")
 436                 {
 437                         defaultmodel = autocvar_sv_defaultplayermodel;
 438                         defaultskin = autocvar_sv_defaultplayerskin;
 439                 }
 440
 441                 int n = tokenize_console(defaultmodel);
 442                 if(n > 0)
 443                 {
 444                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 445                         // However, do NOT randomize if the player-selected model is in the list.
 446                         for (int i = 0; i < n; ++i)
 447                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 448                                         defaultmodel = argv(i);
 449                 }
 450
 451                 int i = strstrofs(defaultmodel, ":", 0);
 452                 if(i >= 0)
 453                 {
 454                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 455                         defaultmodel = substring(defaultmodel, 0, i);
 456                 }
 457         }
 458         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 459         {
 460                 if(teamplay)
 461                 {
 462                         switch(player.team)
 463                         {
 464                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 465                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 466                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 467                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 468                         }
 469                 }
 470
 471                 if(!defaultskin)
 472                         defaultskin = autocvar_sv_defaultplayerskin;
 473         }
 474
 475         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 476         defaultmodel = M_ARGV(0, string);
 477         defaultskin = M_ARGV(1, int);
 478
 479         bool chmdl = false;
 480         int oldskin;
 481         if(defaultmodel != "")
 482         {
 483                 if (defaultmodel != player.model)
 484                 {
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, defaultmodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 oldskin = player.skin;
 493                 player.skin = defaultskin;
 494         } else {
 495                 if (player.playermodel != player.model || player.playermodel == "")
 496                 {
 497                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 498                         vector m1 = player.mins;
 499                         vector m2 = player.maxs;
 500                         setplayermodel (player, player.playermodel);
 501                         setsize (player, m1, m2);
 502                         chmdl = true;
 503                 }
 504
 505                 if(!autocvar_sv_defaultcharacterskin)
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = stof(player.playerskin);
 509                 }
 510                 else
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = defaultskin;
 514                 }
 515         }
 516
 517         if(chmdl || oldskin != player.skin) // model or skin has changed
 518         {
 519                 player.species = player_getspecies(player); // update species
 520                 if(!autocvar_g_debug_globalsounds)
 521                         UpdatePlayerSounds(player); // update skin sounds
 522         }
 523
 524         if(!teamplay)
 525                 if(strlen(autocvar_sv_defaultplayercolors))
 526                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 527                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 528 }
 529
 530 void PutPlayerInServer(entity this)
 531 {
 532         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 533
 534         PlayerState_attach(this);
 535         accuracy_resend(this);
 536
 537         if (this.team < 0)
 538                 TeamBalance_JoinBestTeam(this);
 539
 540         entity spot = SelectSpawnPoint(this, false);
 541         if (!spot) {
 542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 543                 return; // spawn failed
 544         }
 545
 546         TRANSMUTE(Player, this);
 547
 548         CS(this).wasplayer = true;
 549         this.iscreature = true;
 550         this.teleportable = TELEPORT_NORMAL;
 551         if(!this.damagedbycontents)
 552                 IL_PUSH(g_damagedbycontents, this);
 553         this.damagedbycontents = true;
 554         set_movetype(this, MOVETYPE_WALK);
 555         this.solid = SOLID_SLIDEBOX;
 556         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 557         if (autocvar_g_playerclip_collisions)
 558                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 559         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 560                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 561         this.frags = FRAGS_PLAYER;
 562         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 563         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 564         if (autocvar__notarget)
 565                 this.flags |= FL_NOTARGET;
 566         this.takedamage = DAMAGE_AIM;
 567         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 568
 569         if (warmup_stage) {
 570                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, warmup_start_health);
 577                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 578                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 579         } else {
 580                 SetResource(this, RES_SHELLS, start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, start_health);
 587                 SetResource(this, RES_ARMOR, start_armorvalue);
 588                 STAT(WEAPONS, this) = start_weapons;
 589                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 590                 {
 591                         GiveRandomWeapons(this, random_start_weapons_count,
 592                                 autocvar_g_random_start_weapons, random_start_ammo);
 593                 }
 594         }
 595         SetSpectatee_status(this, 0);
 596
 597         PS(this).dual_weapons = '0 0 0';
 598
 599         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 600
 601         this.items = start_items;
 602
 603         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 604         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 605         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 606         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 607         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 608         if (!sv_ready_restart_after_countdown && time < game_starttime)
 609         {
 610                 float f = game_starttime - time;
 611                 this.spawnshieldtime += f;
 612                 this.pauserotarmor_finished += f;
 613                 this.pauserothealth_finished += f;
 614                 this.pauseregen_finished += f;
 615         }
 616
 617         this.damageforcescale = autocvar_g_player_damageforcescale;
 618         this.death_time = 0;
 619         this.respawn_flags = 0;
 620         this.respawn_time = 0;
 621         STAT(RESPAWN_TIME, this) = 0;
 622         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 623         this.fade_time = 0;
 624         this.pain_finished = 0;
 625         this.pushltime = 0;
 626         setthink(this, func_null); // players have no think function
 627         this.nextthink = 0;
 628         this.dmg_team = 0;
 629         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 630
 631         this.deadflag = DEAD_NO;
 632
 633         this.angles = spot.angles;
 634         this.angles_z = 0; // never spawn tilted even if the spot says to
 635         if (IS_BOT_CLIENT(this))
 636         {
 637                 this.v_angle = this.angles;
 638                 bot_aim_reset(this);
 639         }
 640         this.fixangle = true; // turn this way immediately
 641         this.oldvelocity = this.velocity = '0 0 0';
 642         this.avelocity = '0 0 0';
 643         this.punchangle = '0 0 0';
 644         this.punchvector = '0 0 0';
 645
 646         STAT(STRENGTH_FINISHED, this) = 0;
 647         STAT(INVINCIBLE_FINISHED, this) = 0;
 648         this.fire_endtime = -1;
 649         STAT(REVIVE_PROGRESS, this) = 0;
 650         this.revival_time = 0;
 651
 652         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 653         STAT(BUFFS, this) = 0;
 654         STAT(BUFF_TIME, this) = 0;
 655
 656         STAT(AIR_FINISHED, this) = 0;
 657         this.waterlevel = WATERLEVEL_NONE;
 658         this.watertype = CONTENT_EMPTY;
 659
 660         entity spawnevent = new_pure(spawnevent);
 661         spawnevent.owner = this;
 662         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 663
 664         // Cut off any still running player sounds.
 665         stopsound(this, CH_PLAYER_SINGLE);
 666
 667         this.model = "";
 668         FixPlayermodel(this);
 669         this.drawonlytoclient = NULL;
 670
 671         this.viewloc = NULL;
 672
 673         for(int slot = 0; slot < MAX_AXH; ++slot)
 674         {
 675                 entity axh = this.(AuxiliaryXhair[slot]);
 676                 this.(AuxiliaryXhair[slot]) = NULL;
 677
 678                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 679                         delete(axh);
 680         }
 681
 682         this.spawnpoint_targ = NULL;
 683
 684         UNSET_DUCKED(this);
 685         this.view_ofs = STAT(PL_VIEW_OFS, this);
 686         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 687         this.spawnorigin = spot.origin;
 688         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 689         // don't reset back to last position, even if new position is stuck in solid
 690         this.oldorigin = this.origin;
 691         if(this.conveyor)
 692                 IL_REMOVE(g_conveyed, this);
 693         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 694         if(this.swampslug)
 695                 IL_REMOVE(g_swamped, this);
 696         this.swampslug = NULL;
 697         this.swamp_interval = 0;
 698         if(this.ladder_entity)
 699                 IL_REMOVE(g_ladderents, this);
 700         this.ladder_entity = NULL;
 701         IL_EACH(g_counters, it.realowner == this,
 702         {
 703                 delete(it);
 704         });
 705         STAT(HUD, this) = HUD_NORMAL;
 706
 707         this.event_damage = PlayerDamage;
 708         this.event_heal = PlayerHeal;
 709
 710         this.draggable = func_null;
 711
 712         if(!this.bot_attack)
 713                 IL_PUSH(g_bot_targets, this);
 714         this.bot_attack = true;
 715         if(!this.monster_attack)
 716                 IL_PUSH(g_monster_targets, this);
 717         this.monster_attack = true;
 718         navigation_dynamicgoal_init(this, false);
 719
 720         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 721
 722         // player was spectator
 723         if (CS(this).killcount == FRAGS_SPECTATOR) {
 724                 PlayerScore_Clear(this);
 725                 CS(this).killcount = 0;
 726                 CS(this).startplaytime = time;
 727         }
 728
 729         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 730         {
 731                 .entity weaponentity = weaponentities[slot];
 732                 CL_SpawnWeaponentity(this, weaponentity);
 733         }
 734         this.alpha = default_player_alpha;
 735         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 736         this.exteriorweaponentity.alpha = default_weapon_alpha;
 737
 738         this.speedrunning = false;
 739
 740         this.counter_cnt = 0;
 741         this.fragsfilter_cnt = 0;
 742
 743         target_voicescript_clear(this);
 744
 745         // reset fields the weapons may use
 746         FOREACH(Weapons, true, {
 747                 it.wr_resetplayer(it, this);
 748                         // reload all reloadable weapons
 749                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 750                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 751                         {
 752                                 .entity weaponentity = weaponentities[slot];
 753                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 754                         }
 755                 }
 756         });
 757
 758         {
 759                 string s = spot.target;
 760                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 761                         spot.target = string_null;
 762                 SUB_UseTargets(spot, this, NULL);
 763                 if(g_assault || g_race)
 764                         spot.target = s;
 765         }
 766
 767         Unfreeze(this, false);
 768
 769         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 770
 771         if (autocvar_spawn_debug)
 772         {
 773                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 774                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 775         }
 776
 777         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 778         {
 779                 .entity weaponentity = weaponentities[slot];
 780                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 781                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 782                 else
 783                         this.(weaponentity).m_switchweapon = WEP_Null;
 784                 this.(weaponentity).m_weapon = WEP_Null;
 785                 this.(weaponentity).weaponname = "";
 786                 this.(weaponentity).m_switchingweapon = WEP_Null;
 787                 this.(weaponentity).cnt = -1;
 788         }
 789
 790         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 791
 792         if (CS(this).impulse) ImpulseCommands(this);
 793
 794         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 795         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 796         {
 797                 .entity weaponentity = weaponentities[slot];
 798                 W_WeaponFrame(this, weaponentity);
 799         }
 800
 801         if (!warmup_stage && !this.alivetime)
 802                 this.alivetime = time;
 803
 804         antilag_clear(this, CS(this));
 805 }
 806
 807 /** Called when a client spawns in the server */
 808 void PutClientInServer(entity this)
 809 {
 810         if (IS_BOT_CLIENT(this)) {
 811                 TRANSMUTE(Player, this);
 812         } else if (IS_REAL_CLIENT(this)) {
 813                 msg_entity = this;
 814                 WriteByte(MSG_ONE, SVC_SETVIEW);
 815                 WriteEntity(MSG_ONE, this);
 816         }
 817         if (game_stopped)
 818                 TRANSMUTE(Observer, this);
 819
 820         SetSpectatee(this, NULL);
 821
 822         // reset player keys
 823         if(PS(this))
 824                 PS(this).itemkeys = 0;
 825
 826         MUTATOR_CALLHOOK(PutClientInServer, this);
 827
 828         if (IS_OBSERVER(this)) {
 829                 PutObserverInServer(this);
 830         } else if (IS_PLAYER(this)) {
 831                 PutPlayerInServer(this);
 832         }
 833 }
 834
 835 // TODO do we need all these fields, or should we stop autodetecting runtime
 836 // changes and just have a console command to update this?
 837 bool ClientInit_SendEntity(entity this, entity to, int sf)
 838 {
 839         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 840         return = true;
 841         msg_entity = to;
 842         // MSG_INIT replacement
 843         // TODO: make easier to use
 844         Registry_send_all();
 845         W_PROP_reload(MSG_ONE, to);
 846         ClientInit_misc(this);
 847         MUTATOR_CALLHOOK(Ent_Init);
 848 }
 849 void ClientInit_misc(entity this)
 850 {
 851         int channel = MSG_ONE;
 852         WriteHeader(channel, ENT_CLIENT_INIT);
 853         WriteByte(channel, g_nexball_meter_period * 32);
 854         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 855         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 858         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 859         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 862
 863         if(autocvar_sv_foginterval && world.fog != "")
 864                 WriteString(channel, world.fog);
 865         else
 866                 WriteString(channel, "");
 867         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 868         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 869         WriteByte(channel, serverflags);
 870         WriteCoord(channel, autocvar_g_trueaim_minrange);
 871 }
 872
 873 void ClientInit_CheckUpdate(entity this)
 874 {
 875         this.nextthink = time;
 876         if(this.count != autocvar_g_balance_armor_blockpercent)
 877         {
 878                 this.count = autocvar_g_balance_armor_blockpercent;
 879                 this.SendFlags |= 1;
 880         }
 881         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 882         {
 883                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 884                 this.SendFlags |= 1;
 885         }
 886 }
 887
 888 void ClientInit_Spawn()
 889 {
 890         entity e = new_pure(clientinit);
 891         setthink(e, ClientInit_CheckUpdate);
 892         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 893
 894         ClientInit_CheckUpdate(e);
 895 }
 896
 897 /*
 898 =============
 899 SetNewParms
 900 =============
 901 */
 902 void SetNewParms ()
 903 {
 904         // initialize parms for a new player
 905         parm1 = -(86400 * 366);
 906
 907         MUTATOR_CALLHOOK(SetNewParms);
 908 }
 909
 910 /*
 911 =============
 912 SetChangeParms
 913 =============
 914 */
 915 void SetChangeParms (entity this)
 916 {
 917         // save parms for level change
 918         parm1 = CS(this).parm_idlesince - time;
 919
 920         MUTATOR_CALLHOOK(SetChangeParms);
 921 }
 922
 923 /*
 924 =============
 925 DecodeLevelParms
 926 =============
 927 */
 928 void DecodeLevelParms(entity this)
 929 {
 930         // load parms
 931         CS(this).parm_idlesince = parm1;
 932         if (CS(this).parm_idlesince == -(86400 * 366))
 933                 CS(this).parm_idlesince = time;
 934
 935         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 936         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 937
 938         MUTATOR_CALLHOOK(DecodeLevelParms);
 939 }
 940
 941 void FixClientCvars(entity e)
 942 {
 943         // send prediction settings to the client
 944         stuffcmd(e, "\nin_bindmap 0 0\n");
 945         if(autocvar_g_antilag == 3) // client side hitscan
 946                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 947         if(autocvar_sv_gentle)
 948                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 949
 950         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 951         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 952
 953         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 954
 955         MUTATOR_CALLHOOK(FixClientCvars, e);
 956 }
 957
 958 bool findinlist_abbrev(string tofind, string list)
 959 {
 960         if(list == "" || tofind == "")
 961                 return false; // empty list or search, just return
 962
 963         // this function allows abbreviated strings!
 964         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 965         {
 966                 return true;
 967         });
 968
 969         return false;
 970 }
 971
 972 bool PlayerInIPList(entity p, string iplist)
 973 {
 974         // some safety checks (never allow local?)
 975         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 976                 return false;
 977
 978         return findinlist_abbrev(p.netaddress, iplist);
 979 }
 980
 981 bool PlayerInIDList(entity p, string idlist)
 982 {
 983         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 984         if(!p.crypto_idfp)
 985                 return false;
 986
 987         return findinlist_abbrev(p.crypto_idfp, idlist);
 988 }
 989
 990 bool PlayerInList(entity player, string list)
 991 {
 992         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 993 }
 994
 995 #ifdef DP_EXT_PRECONNECT
 996 /*
 997 =============
 998 ClientPreConnect
 999
1000 Called once (not at each match start) when a client begins a connection to the server
1001 =============
1002 */
1003 void ClientPreConnect(entity this)
1004 {
1005         if(autocvar_sv_eventlog)
1006         {
1007                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1008                         this.playerid,
1009                         etof(this),
1010                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1011                 ));
1012         }
1013 }
1014 #endif
1015
1016 string GetClientVersionMessage(entity this)
1017 {
1018         if (CS(this).version_mismatch) {
1019                 if(CS(this).version < autocvar_gameversion) {
1020                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1021                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1022                 } else {
1023                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1024                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1025                 }
1026         } else {
1027                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1028         }
1029 }
1030
1031 string getwelcomemessage(entity this)
1032 {
1033         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1034         string modifications = M_ARGV(0, string);
1035
1036         if(g_weaponarena)
1037         {
1038                 if(g_weaponarena_random)
1039                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1040                 else
1041                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1042         }
1043         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1044                 modifications = strcat(modifications, ", No start weapons");
1045         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1046                 modifications = strcat(modifications, ", Low gravity");
1047         if(g_weapon_stay && !g_cts)
1048                 modifications = strcat(modifications, ", Weapons stay");
1049         if(autocvar_g_jetpack)
1050                 modifications = strcat(modifications, ", Jet pack");
1051         if(autocvar_g_powerups == 0)
1052                 modifications = strcat(modifications, ", No powerups");
1053         if(autocvar_g_powerups > 0)
1054                 modifications = strcat(modifications, ", Powerups");
1055         modifications = substring(modifications, 2, strlen(modifications) - 2);
1056
1057         string versionmessage = GetClientVersionMessage(this);
1058         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1059
1060         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1061
1062         if(modifications != "")
1063                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         if (cache_mutatormsg != "") {
1072                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1073         }
1074
1075         string mutator_msg = "";
1076         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1077         mutator_msg = M_ARGV(0, string);
1078
1079         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1080
1081         string motd = autocvar_sv_motd;
1082         if (motd != "") {
1083                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1084         }
1085         return s;
1086 }
1087
1088 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1089
1090 /**
1091 =============
1092 ClientConnect
1093
1094 Called when a client connects to the server
1095 =============
1096 */
1097 void ClientConnect(entity this)
1098 {
1099         if (Ban_MaybeEnforceBanOnce(this)) return;
1100         assert(!IS_CLIENT(this), return);
1101         this.flags |= FL_CLIENT;
1102         assert(player_count >= 0, player_count = 0);
1103
1104         TRANSMUTE(Client, this);
1105         CS(this).version_nagtime = time + 10 + random() * 10;
1106
1107         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1108
1109         bot_clientconnect(this);
1110
1111         Player_DetermineForcedTeam(this);
1112
1113         TRANSMUTE(Observer, this);
1114
1115         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1116
1117         // always track bots, don't ask for cl_allow_uidtracking
1118         if (IS_BOT_CLIENT(this))
1119                 PlayerStats_GameReport_AddPlayer(this);
1120         else
1121                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1125
1126         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1127
1128         stuffcmd(this, clientstuff, "\n");
1129         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1130
1131         FixClientCvars(this);
1132
1133         // get version info from player
1134         stuffcmd(this, "cmd clientversion $gameversion\n");
1135
1136         // notify about available teams
1137         if (teamplay)
1138         {
1139                 entity balance = TeamBalance_CheckAllowedTeams(this);
1140                 int t = TeamBalance_GetAllowedTeams(balance);
1141                 TeamBalance_Destroy(balance);
1142                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1143         }
1144         else
1145         {
1146                 stuffcmd(this, "set _teams_available 0\n");
1147         }
1148
1149         bot_relinkplayerlist();
1150
1151         CS(this).spectatortime = time;
1152         if (blockSpectators)
1153         {
1154                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1155         }
1156
1157         CS(this).jointime = time;
1158
1159         if (IS_REAL_CLIENT(this))
1160         {
1161                 if (g_weaponarena_weapons == WEPSET(TUBA))
1162                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1163         }
1164
1165         if (!autocvar_sv_foginterval && world.fog != "")
1166                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1167
1168         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1169                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1170                         send_CSQC_teamnagger();
1171
1172         CSQCMODEL_AUTOINIT(this);
1173
1174         CS(this).model_randomizer = random();
1175
1176         if (IS_REAL_CLIENT(this))
1177                 sv_notice_join(this);
1178
1179         this.move_qcphysics = autocvar_sv_qcphysics;
1180
1181         // update physics stats (players can spawn before physics runs)
1182         Physics_UpdateStats(this);
1183
1184         IL_EACH(g_initforplayer, it.init_for_player, {
1185                 it.init_for_player(it, this);
1186         });
1187
1188         Handicap_Initialize(this);
1189
1190         MUTATOR_CALLHOOK(ClientConnect, this);
1191
1192         if (IS_REAL_CLIENT(this))
1193         {
1194                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1195                 {
1196                         CS(this).motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1198                 }
1199         }
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void ClientDisconnect(entity this)
1210 {
1211         assert(IS_CLIENT(this), return);
1212
1213         PlayerStats_GameReport_FinalizePlayer(this);
1214         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1215         if (CS(this).active_minigame) part_minigame(this);
1216         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1217
1218         if (autocvar_sv_eventlog)
1219                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1220
1221         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1222
1223         if(IS_SPEC(this))
1224                 SetSpectatee(this, NULL);
1225
1226         MUTATOR_CALLHOOK(ClientDisconnect, this);
1227
1228         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1229         strfree(CS(this).weaponorder_byimpulse);
1230         ClientState_detach(this);
1231
1232         Portal_ClearAll(this);
1233
1234         Unfreeze(this, false);
1235
1236         RemoveGrapplingHooks(this);
1237
1238         // Here, everything has been done that requires this player to be a client.
1239
1240         this.flags &= ~FL_CLIENT;
1241
1242         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1243         if (this.killindicator) delete(this.killindicator);
1244
1245         IL_EACH(g_counters, it.realowner == this,
1246         {
1247                 delete(it);
1248         });
1249
1250         WaypointSprite_PlayerGone(this);
1251
1252         bot_relinkplayerlist();
1253
1254         strfree(this.clientstatus);
1255         if (this.personal) delete(this.personal);
1256
1257         this.playerid = 0;
1258         ReadyCount();
1259         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1260
1261         ONREMOVE(this);
1262 }
1263
1264 void ChatBubbleThink(entity this)
1265 {
1266         this.nextthink = time;
1267         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1268         {
1269                 if(this.owner) // but why can that ever be NULL?
1270                         this.owner.chatbubbleentity = NULL;
1271                 delete(this);
1272                 return;
1273         }
1274
1275         this.mdl = "";
1276
1277         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1278         {
1279                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1280                         this.mdl = "models/sprites/minigame_busy.iqm";
1281                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1282                         this.mdl = "models/misc/chatbubble.spr";
1283         }
1284
1285         if ( this.model != this.mdl )
1286                 _setmodel(this, this.mdl);
1287
1288 }
1289
1290 void UpdateChatBubble(entity this)
1291 {
1292         if (this.alpha < 0)
1293                 return;
1294         // spawn a chatbubble entity if needed
1295         if (!this.chatbubbleentity)
1296         {
1297                 this.chatbubbleentity = new(chatbubbleentity);
1298                 this.chatbubbleentity.owner = this;
1299                 this.chatbubbleentity.exteriormodeltoclient = this;
1300                 setthink(this.chatbubbleentity, ChatBubbleThink);
1301                 this.chatbubbleentity.nextthink = time;
1302                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1303                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1304                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1305                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1306                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1307                 //this.chatbubbleentity.model = "";
1308                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1309         }
1310 }
1311
1312 void calculate_player_respawn_time(entity this)
1313 {
1314         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1315                 return;
1316
1317         float gametype_setting_tmp;
1318         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1319         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1320         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1321         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1322         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1323         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1324
1325         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1326         if (teamplay)
1327         {
1328                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1329                         if(it.team == this.team)
1330                                 ++pcount;
1331                 });
1332                 if (sdelay_small_count == 0)
1333                         sdelay_small_count = 1;
1334                 if (sdelay_large_count == 0)
1335                         sdelay_large_count = 1;
1336         }
1337         else
1338         {
1339                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1340                         ++pcount;
1341                 });
1342                 if (sdelay_small_count == 0)
1343                 {
1344                         if (IS_INDEPENDENT_PLAYER(this))
1345                         {
1346                                 // Players play independently. No point in requiring enemies.
1347                                 sdelay_small_count = 1;
1348                         }
1349                         else
1350                         {
1351                                 // Players play AGAINST each other. Enemies required.
1352                                 sdelay_small_count = 2;
1353                         }
1354                 }
1355                 if (sdelay_large_count == 0)
1356                 {
1357                         if (IS_INDEPENDENT_PLAYER(this))
1358                         {
1359                                 // Players play independently. No point in requiring enemies.
1360                                 sdelay_large_count = 1;
1361                         }
1362                         else
1363                         {
1364                                 // Players play AGAINST each other. Enemies required.
1365                                 sdelay_large_count = 2;
1366                         }
1367                 }
1368         }
1369
1370         float sdelay;
1371
1372         if (pcount <= sdelay_small_count)
1373                 sdelay = sdelay_small;
1374         else if (pcount >= sdelay_large_count)
1375                 sdelay = sdelay_large;
1376         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1377                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1378
1379         if(waves)
1380                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1381         else
1382                 this.respawn_time = time + sdelay;
1383
1384         if(sdelay < sdelay_max)
1385                 this.respawn_time_max = time + sdelay_max;
1386         else
1387                 this.respawn_time_max = this.respawn_time;
1388
1389         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1390                 this.respawn_countdown = 10; // first number to count down from is 10
1391         else
1392                 this.respawn_countdown = -1; // do not count down
1393
1394         if(autocvar_g_forced_respawn)
1395                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1396 }
1397
1398 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1399 // added to the model skins
1400 /*void UpdateColorModHack()
1401 {
1402         float c;
1403         c = this.clientcolors & 15;
1404         // LordHavoc: only bothering to support white, green, red, yellow, blue
1405              if (!teamplay) this.colormod = '0 0 0';
1406         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1407         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1408         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1409         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1410         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1411         else this.colormod = '1 1 1';
1412 }*/
1413
1414 void respawn(entity this)
1415 {
1416         bool damagedbycontents_prev = this.damagedbycontents;
1417         if(this.alpha >= 0)
1418         {
1419                 if(autocvar_g_respawn_ghosts)
1420                 {
1421                         this.solid = SOLID_NOT;
1422                         this.takedamage = DAMAGE_NO;
1423                         this.damagedbycontents = false;
1424                         set_movetype(this, MOVETYPE_FLY);
1425                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1426                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1427                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1428                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1429                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1430                         if(autocvar_g_respawn_ghosts_time > 0)
1431                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1432                 }
1433                 else
1434                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1435         }
1436
1437         CopyBody(this, 1);
1438         this.damagedbycontents = damagedbycontents_prev;
1439
1440         this.effects |= EF_NODRAW; // prevent another CopyBody
1441         PutClientInServer(this);
1442 }
1443
1444 void play_countdown(entity this, float finished, Sound samp)
1445 {
1446         TC(Sound, samp);
1447         if(IS_REAL_CLIENT(this))
1448                 if(floor(finished - time - frametime) != floor(finished - time))
1449                         if(finished - time < 6)
1450                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1451 }
1452
1453 void player_powerups(entity this)
1454 {
1455         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1456                 this.modelflags |= MF_ROCKET;
1457         else
1458                 this.modelflags &= ~MF_ROCKET;
1459
1460         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1461
1462         if (IS_DEAD(this))
1463         {
1464                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1465                 {
1466                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1467                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1468                         this.items &= ~ITEM_Strength.m_itemid;
1469                         this.items &= ~ITEM_Shield.m_itemid;
1470                         this.items -= (this.items & IT_SUPERWEAPON);
1471                 }
1472         }
1473
1474         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1475                 return;
1476
1477         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1478         int items_prev = this.items;
1479
1480         Fire_ApplyDamage(this);
1481         Fire_ApplyEffect(this);
1482
1483         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1484         {
1485                 if (this.items & ITEM_Strength.m_itemid)
1486                 {
1487                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1488                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1489                         if (time > STAT(STRENGTH_FINISHED, this))
1490                         {
1491                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1492                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1493                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1494                         }
1495                 }
1496                 else
1497                 {
1498                         if (time < STAT(STRENGTH_FINISHED, this))
1499                         {
1500                                 this.items = this.items | ITEM_Strength.m_itemid;
1501                                 if(!g_cts)
1502                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1503                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1504                         }
1505                 }
1506                 if (this.items & ITEM_Shield.m_itemid)
1507                 {
1508                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1509                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1510                         if (time > STAT(INVINCIBLE_FINISHED, this))
1511                         {
1512                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1513                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1514                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1515                         }
1516                 }
1517                 else
1518                 {
1519                         if (time < STAT(INVINCIBLE_FINISHED, this))
1520                         {
1521                                 this.items = this.items | ITEM_Shield.m_itemid;
1522                                 if(!g_cts)
1523                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1525                         }
1526                 }
1527                 if (this.items & IT_SUPERWEAPON)
1528                 {
1529                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1530                         {
1531                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1532                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1533                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1534                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1535                         }
1536                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1537                         {
1538                                 // don't let them run out
1539                         }
1540                         else
1541                         {
1542                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1543                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1544                                 {
1545                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1546                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1547                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1548                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1549                                 }
1550                         }
1551                 }
1552                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1553                 {
1554                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1555                         {
1556                                 this.items = this.items | IT_SUPERWEAPON;
1557                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1558                                 {
1559                                         if(!g_cts)
1560                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1561                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1562                                 }
1563                         }
1564                         else
1565                         {
1566                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1567                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1568                         }
1569                 }
1570                 else
1571                 {
1572                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1573                 }
1574         }
1575
1576         if(autocvar_g_nodepthtestplayers)
1577                 this.effects = this.effects | EF_NODEPTHTEST;
1578
1579         if(autocvar_g_fullbrightplayers)
1580                 this.effects = this.effects | EF_FULLBRIGHT;
1581
1582         if (time >= game_starttime)
1583         if (time < this.spawnshieldtime)
1584                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1585
1586         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1587 }
1588
1589 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1590 {
1591         if(current > stable)
1592                 return current;
1593         else if(current > stable - 0.25) // when close enough, "snap"
1594                 return stable;
1595         else
1596                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1597 }
1598
1599 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1600 {
1601         if(current < stable)
1602                 return current;
1603         else if(current < stable + 0.25) // when close enough, "snap"
1604                 return stable;
1605         else
1606                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1607 }
1608
1609 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1610 {
1611         float old = GetResource(this, res);
1612         float current = old;
1613         if(current > rotstable)
1614         {
1615                 if(rotframetime > 0)
1616                 {
1617                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1618                         current = max(rotstable, current - rotlinear * rotframetime);
1619                 }
1620         }
1621         else if(current < regenstable)
1622         {
1623                 if(regenframetime > 0)
1624                 {
1625                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1626                         current = min(regenstable, current + regenlinear * regenframetime);
1627                 }
1628         }
1629
1630         float limit = GetResourceLimit(this, res) * limit_mod;
1631         if(current > limit)
1632                 current = limit;
1633
1634         if (current != old)
1635                 SetResource(this, res, current);
1636 }
1637
1638 void player_regen(entity this)
1639 {
1640         float max_mod, regen_mod, rot_mod, limit_mod;
1641         max_mod = regen_mod = rot_mod = limit_mod = 1;
1642
1643         float regen_health = autocvar_g_balance_health_regen;
1644         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1645         float regen_health_rot = autocvar_g_balance_health_rot;
1646         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1647         float regen_health_stable = autocvar_g_balance_health_regenstable;
1648         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1649         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1650                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1651         max_mod = M_ARGV(1, float);
1652         regen_mod = M_ARGV(2, float);
1653         rot_mod = M_ARGV(3, float);
1654         limit_mod = M_ARGV(4, float);
1655         regen_health = M_ARGV(5, float);
1656         regen_health_linear = M_ARGV(6, float);
1657         regen_health_rot = M_ARGV(7, float);
1658         regen_health_rotlinear = M_ARGV(8, float);
1659         regen_health_stable = M_ARGV(9, float);
1660         regen_health_rotstable = M_ARGV(10, float);
1661
1662         if(!mutator_returnvalue)
1663         if(!STAT(FROZEN, this))
1664         {
1665                 float maxa = autocvar_g_balance_armor_rotstable;
1666                 float mina = autocvar_g_balance_armor_regenstable;
1667
1668                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1669                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1670                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1671
1672                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1673                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1674                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1675         }
1676
1677         // if player rotted to death...  die!
1678         // check this outside above checks, as player may still be able to rot to death
1679         if(GetResource(this, RES_HEALTH) < 1)
1680         {
1681                 if(this.vehicle)
1682                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1683                 if(this.event_damage)
1684                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1685         }
1686
1687         if (!(this.items & IT_UNLIMITED_AMMO))
1688         {
1689                 float maxf = autocvar_g_balance_fuel_rotstable;
1690                 float minf = autocvar_g_balance_fuel_regenstable;
1691
1692                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1693                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1694                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1695         }
1696 }
1697
1698 bool zoomstate_set;
1699 void SetZoomState(entity this, float newzoom)
1700 {
1701         if(newzoom != CS(this).zoomstate)
1702         {
1703                 CS(this).zoomstate = newzoom;
1704                 ClientData_Touch(this);
1705         }
1706         zoomstate_set = true;
1707 }
1708
1709 void GetPressedKeys(entity this)
1710 {
1711         MUTATOR_CALLHOOK(GetPressedKeys, this);
1712         int keys = STAT(PRESSED_KEYS, this);
1713         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1714         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1715         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1716         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1717
1718         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1719         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1720         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1721         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1722         CS(this).pressedkeys = keys; // store for other users
1723
1724         STAT(PRESSED_KEYS, this) = keys;
1725 }
1726
1727 /*
1728 ======================
1729 spectate mode routines
1730 ======================
1731 */
1732
1733 void SpectateCopy(entity this, entity spectatee)
1734 {
1735         TC(Client, this); TC(Client, spectatee);
1736
1737         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1738         PS(this) = PS(spectatee);
1739         this.armortype = spectatee.armortype;
1740         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1741         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1742         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1743         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1744         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1745         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1746         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1747         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1748         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1749         CS(this).impulse = 0;
1750         this.disableclientprediction = 1; // no need to run prediction on a spectator
1751         this.items = spectatee.items;
1752         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1753         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1754         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1755         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1756         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1757         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1758         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1759         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1760         this.punchangle = spectatee.punchangle;
1761         this.view_ofs = spectatee.view_ofs;
1762         this.velocity = spectatee.velocity;
1763         this.dmg_take = spectatee.dmg_take;
1764         this.dmg_save = spectatee.dmg_save;
1765         this.dmg_inflictor = spectatee.dmg_inflictor;
1766         this.v_angle = spectatee.v_angle;
1767         this.angles = spectatee.v_angle;
1768         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1769         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1770         this.viewloc = spectatee.viewloc;
1771         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1772                 this.fixangle = true;
1773         setorigin(this, spectatee.origin);
1774         setsize(this, spectatee.mins, spectatee.maxs);
1775         SetZoomState(this, CS(spectatee).zoomstate);
1776
1777     anticheat_spectatecopy(this, spectatee);
1778         STAT(HUD, this) = STAT(HUD, spectatee);
1779         if(spectatee.vehicle)
1780     {
1781         this.angles = spectatee.v_angle;
1782
1783         //this.fixangle = false;
1784         //this.velocity = spectatee.vehicle.velocity;
1785         this.vehicle_health = spectatee.vehicle_health;
1786         this.vehicle_shield = spectatee.vehicle_shield;
1787         this.vehicle_energy = spectatee.vehicle_energy;
1788         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1789         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1790         this.vehicle_reload1 = spectatee.vehicle_reload1;
1791         this.vehicle_reload2 = spectatee.vehicle_reload2;
1792
1793         //msg_entity = this;
1794
1795        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1796             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1797            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1798            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1799
1800         //WriteByte (MSG_ONE, SVC_SETVIEW);
1801         //    WriteEntity(MSG_ONE, this);
1802         //makevectors(spectatee.v_angle);
1803         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1804     }
1805 }
1806
1807 bool SpectateUpdate(entity this)
1808 {
1809         if(!this.enemy)
1810                 return false;
1811
1812         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1813         {
1814                 SetSpectatee(this, NULL);
1815                 return false;
1816         }
1817
1818         SpectateCopy(this, this.enemy);
1819
1820         return true;
1821 }
1822
1823 bool SpectateSet(entity this)
1824 {
1825         if(!IS_PLAYER(this.enemy))
1826                 return false;
1827
1828         ClientData_Touch(this.enemy);
1829
1830         msg_entity = this;
1831         WriteByte(MSG_ONE, SVC_SETVIEW);
1832         WriteEntity(MSG_ONE, this.enemy);
1833         set_movetype(this, MOVETYPE_NONE);
1834         accuracy_resend(this);
1835
1836         if(!SpectateUpdate(this))
1837                 PutObserverInServer(this);
1838
1839         return true;
1840 }
1841
1842 void SetSpectatee_status(entity this, int spectatee_num)
1843 {
1844         int oldspectatee_status = CS(this).spectatee_status;
1845         CS(this).spectatee_status = spectatee_num;
1846
1847         if (CS(this).spectatee_status != oldspectatee_status)
1848         {
1849                 if (STAT(PRESSED_KEYS, this))
1850                 {
1851                         CS(this).pressedkeys = 0;
1852                         STAT(PRESSED_KEYS, this) = 0;
1853                 }
1854                 ClientData_Touch(this);
1855                 if (g_race || g_cts) race_InitSpectator();
1856         }
1857 }
1858
1859 void SetSpectatee(entity this, entity spectatee)
1860 {
1861         if(IS_BOT_CLIENT(this))
1862                 return; // bots abuse .enemy, this code is useless to them
1863
1864         entity old_spectatee = this.enemy;
1865
1866         this.enemy = spectatee;
1867
1868         // WEAPONTODO
1869         // these are required to fix the spectator bug with arc
1870         if(old_spectatee)
1871         {
1872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1873                 {
1874                         .entity weaponentity = weaponentities[slot];
1875                         if(old_spectatee.(weaponentity).arc_beam)
1876                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1877                 }
1878         }
1879         if(this.enemy)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(this.enemy.(weaponentity).arc_beam)
1885                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1886                 }
1887         }
1888
1889         if (this.enemy)
1890                 SetSpectatee_status(this, etof(this.enemy));
1891
1892         // needed to update spectator list
1893         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1894 }
1895
1896 bool Spectate(entity this, entity pl)
1897 {
1898         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1899                 return false;
1900         pl = M_ARGV(1, entity);
1901
1902         SetSpectatee(this, pl);
1903         return SpectateSet(this);
1904 }
1905
1906 bool SpectateNext(entity this)
1907 {
1908         entity ent = find(this.enemy, classname, STR_PLAYER);
1909
1910         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1911                 ent = M_ARGV(1, entity);
1912         else if (!ent)
1913                 ent = find(ent, classname, STR_PLAYER);
1914
1915         if(ent) { SetSpectatee(this, ent); }
1916
1917         return SpectateSet(this);
1918 }
1919
1920 bool SpectatePrev(entity this)
1921 {
1922         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1923         entity ent = findchain(classname, STR_PLAYER);
1924         if (!ent) // no player
1925                 return false;
1926
1927         entity first = ent;
1928         // skip players until current spectated player
1929         if(this.enemy)
1930         while(ent && ent != this.enemy)
1931                 ent = ent.chain;
1932
1933         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1934         {
1935                 case MUT_SPECPREV_FOUND:
1936                         ent = M_ARGV(1, entity);
1937                         break;
1938                 case MUT_SPECPREV_RETURN:
1939                         return true;
1940                 case MUT_SPECPREV_CONTINUE:
1941                 default:
1942                 {
1943                         if(ent.chain)
1944                                 ent = ent.chain;
1945                         else
1946                                 ent = first;
1947                         break;
1948                 }
1949         }
1950
1951         SetSpectatee(this, ent);
1952         return SpectateSet(this);
1953 }
1954
1955 /*
1956 =============
1957 ShowRespawnCountdown()
1958
1959 Update a respawn countdown display.
1960 =============
1961 */
1962 void ShowRespawnCountdown(entity this)
1963 {
1964         float number;
1965         if(!IS_DEAD(this)) // just respawned?
1966                 return;
1967         else
1968         {
1969                 number = ceil(this.respawn_time - time);
1970                 if(number <= 0)
1971                         return;
1972                 if(number <= this.respawn_countdown)
1973                 {
1974                         this.respawn_countdown = number - 1;
1975                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1976                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1977                 }
1978         }
1979 }
1980
1981 .bool team_selected;
1982 bool ShowTeamSelection(entity this)
1983 {
1984         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1985                 return false;
1986         stuffcmd(this, "menu_showteamselect\n");
1987         return true;
1988 }
1989 void Join(entity this)
1990 {
1991         TRANSMUTE(Player, this);
1992
1993         if(!this.team_selected)
1994         if(autocvar_g_campaign || autocvar_g_balance_teams)
1995                 TeamBalance_JoinBestTeam(this);
1996
1997         if(autocvar_g_campaign)
1998                 campaign_bots_may_start = true;
1999
2000         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2001
2002         PutClientInServer(this);
2003
2004         if(IS_PLAYER(this))
2005         if(teamplay && this.team != -1)
2006         {
2007         }
2008         else
2009                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2010         this.team_selected = false;
2011 }
2012
2013 int GetPlayerLimit()
2014 {
2015         if(g_duel)
2016                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2017         int player_limit = autocvar_g_maxplayers;
2018         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2019         player_limit = M_ARGV(0, int);
2020         return player_limit;
2021 }
2022
2023 /**
2024  * Determines whether the player is allowed to join. This depends on cvar
2025  * g_maxplayers, if it isn't used this function always return true, otherwise
2026  * it checks whether the number of currently playing players exceeds g_maxplayers.
2027  * @return int number of free slots for players, 0 if none
2028  */
2029 int nJoinAllowed(entity this, entity ignore)
2030 {
2031         if(!ignore)
2032         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2033         // so report 0 free slots if restricted
2034         {
2035                 if(autocvar_g_forced_team_otherwise == "spectate")
2036                         return 0;
2037                 if(autocvar_g_forced_team_otherwise == "spectator")
2038                         return 0;
2039         }
2040
2041         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2042                 return 0; // forced spectators can never join
2043
2044         // TODO simplify this
2045         int totalClients = 0;
2046         int currentlyPlaying = 0;
2047         FOREACH_CLIENT(true, {
2048                 if(it != ignore)
2049                         ++totalClients;
2050                 if(IS_REAL_CLIENT(it))
2051                 if(IS_PLAYER(it) || it.caplayer)
2052                         ++currentlyPlaying;
2053         });
2054
2055         int player_limit = GetPlayerLimit();
2056
2057         int free_slots = 0;
2058         if (!player_limit)
2059                 free_slots = maxclients - totalClients;
2060         else if(player_limit > 0 && currentlyPlaying < player_limit)
2061                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2062
2063         static float msg_time = 0;
2064         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2065         {
2066                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2067                 msg_time = time + 0.5;
2068         }
2069
2070         return free_slots;
2071 }
2072
2073 /**
2074  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2075  * g_maxplayers_spectator_blocktime seconds
2076  */
2077 void checkSpectatorBlock(entity this)
2078 {
2079         if(IS_SPEC(this) || IS_OBSERVER(this))
2080         if(!this.caplayer)
2081         if(IS_REAL_CLIENT(this))
2082         {
2083                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2084                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2085                         dropclient(this);
2086                 }
2087         }
2088 }
2089
2090 void PrintWelcomeMessage(entity this)
2091 {
2092         if(CS(this).motd_actived_time == 0)
2093         {
2094                 if (autocvar_g_campaign) {
2095                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2096                                 CS(this).motd_actived_time = time;
2097                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2098                         }
2099                 } else {
2100                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2101                                 CS(this).motd_actived_time = time;
2102                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2103                         }
2104                 }
2105         }
2106         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2107         {
2108                 if (autocvar_g_campaign) {
2109                         if (PHYS_INPUT_BUTTON_INFO(this))
2110                                 CS(this).motd_actived_time = time;
2111                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2112                                 CS(this).motd_actived_time = 0;
2113                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2114                         }
2115                 } else {
2116                         if (PHYS_INPUT_BUTTON_INFO(this))
2117                                 CS(this).motd_actived_time = time;
2118                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2119                                 CS(this).motd_actived_time = 0;
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2121                         }
2122                 }
2123         }
2124         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2125         {
2126                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2127                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2128                 else if (CS(this).motd_actived_time == -2)
2129                 {
2130                         // instantly hide MOTD
2131                         CS(this).motd_actived_time = 0;
2132                         if (autocvar_g_campaign)
2133                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2134                         else
2135                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2136                 }
2137                 else if (IS_PLAYER(this) || IS_SPEC(this))
2138                 {
2139                         // FIXME occasionally for some reason MOTD never goes away
2140                         // delay MOTD removal a little bit in the hope it fixes this bug
2141                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2142                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2143                         else //if (CS(this).motd_actived_time < -2)
2144                                 CS(this).motd_actived_time++;
2145                 }
2146         }
2147 }
2148
2149 bool joinAllowed(entity this)
2150 {
2151         if (CS(this).version_mismatch) return false;
2152         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2153         if (!nJoinAllowed(this, this)) return false;
2154         if (teamplay && lockteams) return false;
2155         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2156         if (ShowTeamSelection(this)) return false;
2157         return true;
2158 }
2159
2160 .string shootfromfixedorigin;
2161 .bool dualwielding_prev;
2162 bool PlayerThink(entity this)
2163 {
2164         if (game_stopped || intermission_running) {
2165                 this.modelflags &= ~MF_ROCKET;
2166                 if(intermission_running)
2167                         IntermissionThink(this);
2168                 return false;
2169         }
2170
2171         if (timeout_status == TIMEOUT_ACTIVE) {
2172                 // don't allow the player to turn around while game is paused
2173                 // FIXME turn this into CSQC stuff
2174                 this.v_angle = this.lastV_angle;
2175                 this.angles = this.lastV_angle;
2176                 this.fixangle = true;
2177         }
2178
2179         if (frametime) player_powerups(this);
2180
2181         if (IS_DEAD(this)) {
2182                 if (this.personal && g_race_qualifying) {
2183                         if (time > this.respawn_time) {
2184                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2185                                 respawn(this);
2186                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2187                         }
2188                 } else {
2189                         if (frametime) player_anim(this);
2190
2191                         if (this.respawn_flags & RESPAWN_DENY)
2192                         {
2193                                 STAT(RESPAWN_TIME, this) = 0;
2194                                 return false;
2195                         }
2196
2197                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2198
2199                         switch(this.deadflag)
2200                         {
2201                                 case DEAD_DYING:
2202                                 {
2203                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2204                                                 this.deadflag = DEAD_RESPAWNING;
2205                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2206                                                 this.deadflag = DEAD_DEAD;
2207                                         break;
2208                                 }
2209                                 case DEAD_DEAD:
2210                                 {
2211                                         if (button_pressed)
2212                                                 this.deadflag = DEAD_RESPAWNABLE;
2213                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2214                                                 this.deadflag = DEAD_RESPAWNING;
2215                                         break;
2216                                 }
2217                                 case DEAD_RESPAWNABLE:
2218                                 {
2219                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2220                                                 this.deadflag = DEAD_RESPAWNING;
2221                                         break;
2222                                 }
2223                                 case DEAD_RESPAWNING:
2224                                 {
2225                                         if (time > this.respawn_time)
2226                                         {
2227                                                 this.respawn_time = time + 1; // only retry once a second
2228                                                 this.respawn_time_max = this.respawn_time;
2229                                                 respawn(this);
2230                                         }
2231                                         break;
2232                                 }
2233                         }
2234
2235                         ShowRespawnCountdown(this);
2236
2237                         if (this.respawn_flags & RESPAWN_SILENT)
2238                                 STAT(RESPAWN_TIME, this) = 0;
2239                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2240                         {
2241                                 if (time < this.respawn_time)
2242                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2243                                 else if (this.deadflag != DEAD_RESPAWNING)
2244                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2245                         }
2246                         else
2247                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2248                 }
2249
2250                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2251                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2252                         STAT(RESPAWN_TIME, this) *= -1;
2253
2254                 return false;
2255         }
2256
2257         FixPlayermodel(this);
2258
2259         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2260                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2261                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2262         }
2263
2264         // reset gun alignment when dual wielding status changes
2265         // to ensure guns are always aligned right and left
2266         bool dualwielding = W_DualWielding(this);
2267         if(this.dualwielding_prev != dualwielding)
2268         {
2269                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2270                 this.dualwielding_prev = dualwielding;
2271         }
2272
2273         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2274         //if(frametime)
2275         {
2276                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2277                 {
2278                         .entity weaponentity = weaponentities[slot];
2279                         if(WEP_CVAR(vortex, charge_always))
2280                                 W_Vortex_Charge(this, weaponentity, frametime);
2281                         W_WeaponFrame(this, weaponentity);
2282                 }
2283         }
2284
2285         if (frametime)
2286         {
2287                 // WEAPONTODO: Add a weapon request for this
2288                 // rot vortex charge to the charge limit
2289                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2290                 {
2291                         .entity weaponentity = weaponentities[slot];
2292                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2293                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2294                 }
2295
2296                 player_regen(this);
2297                 player_anim(this);
2298                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2299         }
2300
2301         monsters_setstatus(this);
2302
2303         return true;
2304 }
2305
2306 .bool would_spectate;
2307 void ObserverOrSpectatorThink(entity this)
2308 {
2309         bool is_spec = IS_SPEC(this);
2310         if ( CS(this).impulse )
2311         {
2312                 int r = MinigameImpulse(this, CS(this).impulse);
2313                 if (!is_spec || r)
2314                         CS(this).impulse = 0;
2315
2316                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2317                 {
2318                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2319                         CS(this).impulse = 0;
2320                         return;
2321                 }
2322         }
2323
2324         if (this.flags & FL_JUMPRELEASED) {
2325                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2326                         this.flags &= ~FL_JUMPRELEASED;
2327                         this.flags |= FL_SPAWNING;
2328                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2329                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2330                         this.flags &= ~FL_JUMPRELEASED;
2331                         if(SpectateNext(this)) {
2332                                 TRANSMUTE(Spectator, this);
2333                         } else if (is_spec) {
2334                                 TRANSMUTE(Observer, this);
2335                                 PutClientInServer(this);
2336                         }
2337                         if (is_spec)
2338                                 CS(this).impulse = 0;
2339                 } else if (is_spec) {
2340                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2341                                 this.flags &= ~FL_JUMPRELEASED;
2342                                 if(SpectatePrev(this)) {
2343                                         TRANSMUTE(Spectator, this);
2344                                 } else {
2345                                         TRANSMUTE(Observer, this);
2346                                         PutClientInServer(this);
2347                                 }
2348                                 CS(this).impulse = 0;
2349                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2350                                 this.would_spectate = false;
2351                                 this.flags &= ~FL_JUMPRELEASED;
2352                                 TRANSMUTE(Observer, this);
2353                                 PutClientInServer(this);
2354                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2355                                 PutObserverInServer(this);
2356                                 this.would_spectate = true;
2357                         }
2358                 }
2359                 else {
2360                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2361                         set_movetype(this, preferred_movetype);
2362                 }
2363         } else {
2364                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2365                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2366                         this.flags |= FL_JUMPRELEASED;
2367                         if(this.flags & FL_SPAWNING)
2368                         {
2369                                 this.flags &= ~FL_SPAWNING;
2370                                 if(joinAllowed(this))
2371                                         Join(this);
2372                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2373                                         CS(this).autojoin_checked = -1;
2374                                 return;
2375                         }
2376                 }
2377                 if(is_spec && !SpectateUpdate(this))
2378                         PutObserverInServer(this);
2379         }
2380         if (is_spec)
2381                 this.flags |= FL_CLIENT | FL_NOTARGET;
2382 }
2383
2384 void PlayerUseKey(entity this)
2385 {
2386         if (!IS_PLAYER(this))
2387                 return;
2388
2389         if(this.vehicle)
2390         {
2391                 if(!game_stopped)
2392                 {
2393                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2394                         return;
2395                 }
2396         }
2397         else if(autocvar_g_vehicles_enter)
2398         {
2399                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2400                 {
2401                         entity head, closest_target = NULL;
2402                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2403
2404                         while(head) // find the closest acceptable target to enter
2405                         {
2406                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2407                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2408                                 {
2409                                         if(closest_target)
2410                                         {
2411                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2412                                                 { closest_target = head; }
2413                                         }
2414                                         else { closest_target = head; }
2415                                 }
2416
2417                                 head = head.chain;
2418                         }
2419
2420                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2421                 }
2422         }
2423
2424         // a use key was pressed; call handlers
2425         MUTATOR_CALLHOOK(PlayerUseKey, this);
2426 }
2427
2428
2429 /*
2430 =============
2431 PlayerPreThink
2432
2433 Called every frame for each client before the physics are run
2434 =============
2435 */
2436 .float last_vehiclecheck;
2437 void PlayerPreThink (entity this)
2438 {
2439         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2440         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2441
2442         WarpZone_PlayerPhysics_FixVAngle(this);
2443
2444         if (frametime) {
2445                 // physics frames: update anticheat stuff
2446                 anticheat_prethink(this);
2447         }
2448
2449         if (blockSpectators && frametime) {
2450                 // WORKAROUND: only use dropclient in server frames (frametime set).
2451                 // Never use it in cl_movement frames (frametime zero).
2452                 checkSpectatorBlock(this);
2453         }
2454
2455         zoomstate_set = false;
2456
2457         // Check for nameless players
2458         if (this.netname == "" || this.netname != CS(this).netname_previous)
2459         {
2460                 bool assume_unchanged = (CS(this).netname_previous == "");
2461                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2462                 {
2463                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2464                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2465                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2466                         assume_unchanged = false;
2467                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2468                 }
2469                 if (isInvisibleString(this.netname))
2470                 {
2471                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2472                         sprint(this, "Warning: invisible names are not allowed.\n");
2473                         assume_unchanged = false;
2474                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2475                 }
2476                 if (!assume_unchanged && autocvar_sv_eventlog)
2477                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2478                 strcpy(CS(this).netname_previous, this.netname);
2479         }
2480
2481         // version nagging
2482         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2483         CS(this).version_nagtime = 0;
2484         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2485             // git client
2486         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2487             // git server
2488             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2489         } else {
2490             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2491             if (r < 0) { // old client
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2493             } else if (r > 0) { // old server
2494                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2495             }
2496         }
2497     }
2498
2499         // GOD MODE info
2500         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2501         {
2502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2503                 this.max_armorvalue = 0;
2504         }
2505
2506         if (frametime && IS_PLAYER(this))
2507         {
2508                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2509                 {
2510                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2511                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2512                         if (this.iceblock)
2513                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2514
2515                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2516                                 Unfreeze(this, false);
2517                 }
2518                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2519                 {
2520                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2521                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2522
2523                         if (GetResource(this, RES_HEALTH) < 1)
2524                         {
2525                                 if (this.vehicle)
2526                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2527                                 if(this.event_damage)
2528                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2529                         }
2530                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2531                                 Unfreeze(this, false);
2532                 }
2533         }
2534
2535         MUTATOR_CALLHOOK(PlayerPreThink, this);
2536
2537         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2538         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2539         {
2540                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2541                 {
2542                         if(!it.owner)
2543                         {
2544                                 if(!it.team || SAME_TEAM(this, it))
2545                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2546                                 else if(autocvar_g_vehicles_steal)
2547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2548                         }
2549                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2550                         {
2551                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2552                         }
2553                 });
2554
2555                 this.last_vehiclecheck = time + 1;
2556         }
2557
2558         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2559         {
2560                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2561                         PlayerUseKey(this);
2562                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2563         }
2564
2565         if (IS_REAL_CLIENT(this))
2566                 PrintWelcomeMessage(this);
2567
2568         if (IS_PLAYER(this)) {
2569                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2570                         error("Client can't be spawned as player on connection!");
2571                 if(!PlayerThink(this))
2572                         return;
2573         }
2574         else if (game_stopped || intermission_running) {
2575                 if(intermission_running)
2576                         IntermissionThink(this);
2577                 return;
2578         }
2579         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2580         {
2581                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2582                 CS(this).autojoin_checked = 1;
2583                 // don't do this in ClientConnect
2584                 // many things can go wrong if a client is spawned as player on connection
2585                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2586                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2587                                 && (!teamplay || autocvar_g_balance_teams)))
2588                 {
2589                         campaign_bots_may_start = true;
2590                         if(joinAllowed(this))
2591                                 Join(this);
2592                         return;
2593                 }
2594         }
2595         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2596                 ObserverOrSpectatorThink(this);
2597         }
2598
2599         // WEAPONTODO: Add weapon request for this
2600         if (!zoomstate_set) {
2601                 bool wep_zoomed = false;
2602                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2603                 {
2604                         .entity weaponentity = weaponentities[slot];
2605                         Weapon thiswep = this.(weaponentity).m_weapon;
2606                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2607                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2608                 }
2609                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2610         }
2611
2612         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2613         {
2614                 CS(this).teamkill_soundtime = 0;
2615
2616                 entity e = CS(this).teamkill_soundsource;
2617                 entity oldpusher = e.pusher;
2618                 e.pusher = this;
2619                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2620                 e.pusher = oldpusher;
2621         }
2622
2623         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2624                 CS(this).taunt_soundtime = 0;
2625                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2626         }
2627
2628         target_voicescript_next(this);
2629
2630         // WEAPONTODO: Move into weaponsystem somehow
2631         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2632         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2633         {
2634                 .entity weaponentity = weaponentities[slot];
2635                 if(this.(weaponentity).m_weapon == WEP_Null)
2636                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2637         }
2638 }
2639
2640 void DrownPlayer(entity this)
2641 {
2642         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2643                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2644         {
2645                 STAT(AIR_FINISHED, this) = 0;
2646                 return;
2647         }
2648
2649         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2650         {
2651                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2652                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2653                 STAT(AIR_FINISHED, this) = 0;
2654         }
2655         else
2656         {
2657                 if (!STAT(AIR_FINISHED, this))
2658                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2659                 if (STAT(AIR_FINISHED, this) < time)
2660                 {       // drown!
2661                         if (this.pain_finished < time)
2662                         {
2663                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2664                                 this.pain_finished = time + 0.5;
2665                         }
2666                 }
2667         }
2668 }
2669
2670 .bool move_qcphysics;
2671
2672 void Player_Physics(entity this)
2673 {
2674         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2675
2676         if(!this.move_qcphysics)
2677                 return;
2678
2679         if(!frametime && !CS(this).pm_frametime)
2680                 return;
2681
2682         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2683
2684         CS(this).pm_frametime = 0;
2685 }
2686
2687 /*
2688 =============
2689 PlayerPostThink
2690
2691 Called every frame for each client after the physics are run
2692 =============
2693 */
2694 void PlayerPostThink (entity this)
2695 {
2696         Player_Physics(this);
2697
2698         if (autocvar_sv_maxidle > 0)
2699         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2700         if (IS_REAL_CLIENT(this))
2701         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2702         {
2703                 int totalClients = 0;
2704                 if(autocvar_sv_maxidle_slots > 0)
2705                 {
2706                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2707                         {
2708                                 ++totalClients;
2709                         });
2710                 }
2711
2712                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2713                 { /* do nothing */ }
2714                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2715                 {
2716                         if (CS(this).idlekick_lasttimeleft)
2717                         {
2718                                 CS(this).idlekick_lasttimeleft = 0;
2719                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2720                         }
2721                 }
2722                 else
2723                 {
2724                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2725                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2726                                 if (!CS(this).idlekick_lasttimeleft)
2727                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2728                         }
2729                         if (timeleft <= 0) {
2730                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2731                                 dropclient(this);
2732                                 return;
2733                         }
2734                         else if (timeleft <= 10) {
2735                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2736                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2737                                 CS(this).idlekick_lasttimeleft = timeleft;
2738                         }
2739                 }
2740         }
2741
2742         CheatFrame(this);
2743
2744         if (game_stopped)
2745         {
2746                 this.solid = SOLID_NOT;
2747                 this.takedamage = DAMAGE_NO;
2748                 set_movetype(this, MOVETYPE_NONE);
2749                 CS(this).teamkill_complain = 0;
2750                 CS(this).teamkill_soundtime = 0;
2751                 CS(this).teamkill_soundsource = NULL;
2752         }
2753
2754         if (IS_PLAYER(this)) {
2755                 if(this.death_time == time && IS_DEAD(this))
2756                 {
2757                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2758                         // once all the damage events of this frame have been processed with normal size
2759                         this.maxs.z = 5;
2760                         setsize(this, this.mins, this.maxs);
2761                 }
2762                 DrownPlayer(this);
2763                 UpdateChatBubble(this);
2764                 if (CS(this).impulse) ImpulseCommands(this);
2765                 if (game_stopped)
2766                 {
2767                         CSQCMODEL_AUTOUPDATE(this);
2768                         return;
2769                 }
2770                 GetPressedKeys(this);
2771         }
2772         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2773         {
2774                 CS(this).pressedkeys = 0;
2775                 STAT(PRESSED_KEYS, this) = 0;
2776         }
2777
2778         if (this.waypointsprite_attachedforcarrier) {
2779                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2780                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2781         }
2782
2783         CSQCMODEL_AUTOUPDATE(this);
2784 }
2785
2786 // hack to copy the button fields from the client entity to the Client State
2787 void PM_UpdateButtons(entity this, entity store)
2788 {
2789         if(this.impulse)
2790                 store.impulse = this.impulse;
2791         this.impulse = 0;
2792
2793         bool typing = this.buttonchat || this.button12;
2794
2795         store.button0 = (typing) ? 0 : this.button0;
2796         //button1?!
2797         store.button2 = (typing) ? 0 : this.button2;
2798         store.button3 = (typing) ? 0 : this.button3;
2799         store.button4 = this.button4;
2800         store.button5 = (typing) ? 0 : this.button5;
2801         store.button6 = this.button6;
2802         store.button7 = this.button7;
2803         store.button8 = this.button8;
2804         store.button9 = this.button9;
2805         store.button10 = this.button10;
2806         store.button11 = this.button11;
2807         store.button12 = this.button12;
2808         store.button13 = this.button13;
2809         store.button14 = this.button14;
2810         store.button15 = this.button15;
2811         store.button16 = this.button16;
2812         store.buttonuse = this.buttonuse;
2813         store.buttonchat = this.buttonchat;
2814
2815         store.cursor_active = this.cursor_active;
2816         store.cursor_screen = this.cursor_screen;
2817         store.cursor_trace_start = this.cursor_trace_start;
2818         store.cursor_trace_endpos = this.cursor_trace_endpos;
2819         store.cursor_trace_ent = this.cursor_trace_ent;
2820
2821         store.ping = this.ping;
2822         store.ping_packetloss = this.ping_packetloss;
2823         store.ping_movementloss = this.ping_movementloss;
2824
2825         store.v_angle = this.v_angle;
2826         store.movement = this.movement;
2827 }
2828
2829 NET_HANDLE(fpsreport, bool)
2830 {
2831         int fps = ReadShort();
2832         PlayerScore_Set(sender, SP_FPS, fps);
2833         return true;
2834 }