qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/_mod.qh"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     ClientConnect(this);
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     PutClientInServer(this);
  63 }
  64
  65 void PutObserverInServer(entity this);
  66
  67 STATIC_METHOD(Client, Remove, void(Client this))
  68 {
  69     TRANSMUTE(Observer, this);
  70     PutClientInServer(this);
  71     ClientDisconnect(this);
  72 }
  73
  74 void send_CSQC_teamnagger() {
  75         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  76 }
  77
  78 int CountSpectators(entity player, entity to)
  79 {
  80         if(!player) { return 0; } // not sure how, but best to be safe
  81
  82         int spec_count = 0;
  83
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  85         {
  86                 spec_count++;
  87         });
  88
  89         return spec_count;
  90 }
  91
  92 void WriteSpectators(entity player, entity to)
  93 {
  94         if(!player) { return; } // not sure how, but best to be safe
  95
  96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  97         {
  98                 WriteByte(MSG_ENTITY, num_for_edict(it));
  99         });
 100 }
 101
 102 bool ClientData_Send(entity this, entity to, int sf)
 103 {
 104         assert(to == this.owner, return false);
 105
 106         entity e = to;
 107         if (IS_SPEC(e)) e = e.enemy;
 108
 109         sf = 0;
 110         if (e.race_completed)       sf |= 1; // forced scoreboard
 111         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 112         if (e.zoomstate)            sf |= 4; // zoomed
 113         if (e.porto_v_angle_held)   sf |= 8; // angles held
 114         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 115
 116         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 117         WriteByte(MSG_ENTITY, sf);
 118
 119         if (sf & 2)
 120         {
 121                 WriteByte(MSG_ENTITY, to.spectatee_status);
 122         }
 123         if (sf & 8)
 124         {
 125                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 126                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 127         }
 128
 129         if(sf & 16)
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         this.clientdata.drawonlytoclient = this;
 143         this.clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(this.clientdata);
 149         this.clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         e.clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 158 }
 159
 160 .string netname_previous;
 161
 162 void SetSpectatee(entity this, entity spectatee);
 163 void SetSpectatee_status(entity this, int spectatee_num);
 164
 165
 166 /*
 167 =============
 168 CheckPlayerModel
 169
 170 Checks if the argument string can be a valid playermodel.
 171 Returns a valid one in doubt.
 172 =============
 173 */
 174 string FallbackPlayerModel;
 175 string CheckPlayerModel(string plyermodel) {
 176         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 177         {
 178                 // note: we cannot summon Don Strunzone here, some player may
 179                 // still have the model string set. In case anyone manages how
 180                 // to change a cvar default, we'll have a small leak here.
 181                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 182         }
 183         // only in right path
 184         if( substring(plyermodel,0,14) != "models/player/")
 185                 return FallbackPlayerModel;
 186         // only good file extensions
 187         if(substring(plyermodel,-4,4) != ".zym")
 188         if(substring(plyermodel,-4,4) != ".dpm")
 189         if(substring(plyermodel,-4,4) != ".iqm")
 190         if(substring(plyermodel,-4,4) != ".md3")
 191         if(substring(plyermodel,-4,4) != ".psk")
 192                 return FallbackPlayerModel;
 193         // forbid the LOD models
 194         if(substring(plyermodel, -9,5) == "_lod1")
 195                 return FallbackPlayerModel;
 196         if(substring(plyermodel, -9,5) == "_lod2")
 197                 return FallbackPlayerModel;
 198         if(plyermodel != strtolower(plyermodel))
 199                 return FallbackPlayerModel;
 200         // also, restrict to server models
 201         if(autocvar_sv_servermodelsonly)
 202         {
 203                 if(!fexists(plyermodel))
 204                         return FallbackPlayerModel;
 205         }
 206         return plyermodel;
 207 }
 208
 209 void setplayermodel(entity e, string modelname)
 210 {
 211         precache_model(modelname);
 212         _setmodel(e, modelname);
 213         player_setupanimsformodel(e);
 214         if(!autocvar_g_debug_globalsounds)
 215                 UpdatePlayerSounds(e);
 216 }
 217
 218 void FixPlayermodel(entity player);
 219 /** putting a client as observer in the server */
 220 void PutObserverInServer(entity this)
 221 {
 222     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 223         PlayerState_detach(this);
 224
 225         if (IS_PLAYER(this) && this.health >= 1) {
 226         // despawn effect
 227                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 228     }
 229
 230     {
 231         entity spot = SelectSpawnPoint(this, true);
 232         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 233         this.angles = spot.angles;
 234         this.angles_z = 0;
 235         this.fixangle = true;
 236         // offset it so that the spectator spawns higher off the ground, looks better this way
 237         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 238         this.prevorigin = this.origin;
 239         if (IS_REAL_CLIENT(this))
 240         {
 241             msg_entity = this;
 242             WriteByte(MSG_ONE, SVC_SETVIEW);
 243             WriteEntity(MSG_ONE, this);
 244         }
 245         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247         if(!autocvar_g_debug_globalsounds)
 248         {
 249                 // needed for player sounds
 250                 this.model = "";
 251                 FixPlayermodel(this);
 252         }
 253         setmodel(this, MDL_Null);
 254         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 255         this.view_ofs = '0 0 0';
 256     }
 257
 258     RemoveGrapplingHook(this);
 259         Portal_ClearAll(this);
 260         Unfreeze(this);
 261         SetSpectatee(this, NULL);
 262
 263         if (this.alivetime)
 264         {
 265                 if (!warmup_stage)
 266                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 267                 this.alivetime = 0;
 268         }
 269
 270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 271
 272         WaypointSprite_PlayerDead(this);
 273
 274         if (mutator_returnvalue) {
 275             // mutator prevents resetting teams+score
 276         } else {
 277                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 278         this.frags = FRAGS_SPECTATOR;
 279         PlayerScore_Clear(this);  // clear scores when needed
 280     }
 281
 282         if (this.killcount != FRAGS_SPECTATOR)
 283         {
 284                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 285                 if(!intermission_running)
 286                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 287                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 288
 289                 if(this.just_joined == false) {
 290                         LogTeamchange(this.playerid, -1, 4);
 291                 } else
 292                         this.just_joined = false;
 293         }
 294
 295         accuracy_resend(this);
 296
 297         this.spectatortime = time;
 298         this.bot_attack = false;
 299     this.hud = HUD_NORMAL;
 300         TRANSMUTE(Observer, this);
 301         this.iscreature = false;
 302         this.teleportable = TELEPORT_SIMPLE;
 303         this.damagedbycontents = false;
 304         this.health = FRAGS_SPECTATOR;
 305         SetSpectatee_status(this, etof(this));
 306         this.takedamage = DAMAGE_NO;
 307         this.solid = SOLID_NOT;
 308         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 309         this.flags = FL_CLIENT | FL_NOTARGET;
 310         this.armorvalue = 666;
 311         this.effects = 0;
 312         this.armorvalue = autocvar_g_balance_armor_start;
 313         this.pauserotarmor_finished = 0;
 314         this.pauserothealth_finished = 0;
 315         this.pauseregen_finished = 0;
 316         this.damageforcescale = 0;
 317         this.death_time = 0;
 318         this.respawn_flags = 0;
 319         this.respawn_time = 0;
 320         this.stat_respawn_time = 0;
 321         this.alpha = 0;
 322         this.scale = 0;
 323         this.fade_time = 0;
 324         this.pain_frame = 0;
 325         this.pain_finished = 0;
 326         this.strength_finished = 0;
 327         this.invincible_finished = 0;
 328         this.superweapons_finished = 0;
 329         this.pushltime = 0;
 330         this.istypefrag = 0;
 331         setthink(this, func_null);
 332         this.nextthink = 0;
 333         this.hook_time = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revival_time = 0;
 337
 338         this.items = 0;
 339         this.weapons = '0 0 0';
 340         this.drawonlytoclient = this;
 341
 342         this.weaponname = "";
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 359         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 360         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 361 }
 362
 363 int player_getspecies(entity this)
 364 {
 365         get_model_parameters(this.model, this.skin);
 366         int s = get_model_parameters_species;
 367         get_model_parameters(string_null, 0);
 368         if (s < 0) return SPECIES_HUMAN;
 369         return s;
 370 }
 371
 372 .float model_randomizer;
 373 void FixPlayermodel(entity player)
 374 {
 375         string defaultmodel = "";
 376         int defaultskin = 0;
 377         if(autocvar_sv_defaultcharacter)
 378         {
 379                 if(teamplay)
 380                 {
 381                         string s = Static_Team_ColorName_Lower(player.team);
 382                         if (s != "neutral")
 383                         {
 384                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 385                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 386                         }
 387                 }
 388
 389                 if(defaultmodel == "")
 390                 {
 391                         defaultmodel = autocvar_sv_defaultplayermodel;
 392                         defaultskin = autocvar_sv_defaultplayerskin;
 393                 }
 394
 395                 int n = tokenize_console(defaultmodel);
 396                 if(n > 0)
 397                 {
 398                         defaultmodel = argv(floor(n * player.model_randomizer));
 399                         // However, do NOT randomize if the player-selected model is in the list.
 400                         for (int i = 0; i < n; ++i)
 401                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 402                                         defaultmodel = argv(i);
 403                 }
 404
 405                 int i = strstrofs(defaultmodel, ":", 0);
 406                 if(i >= 0)
 407                 {
 408                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 409                         defaultmodel = substring(defaultmodel, 0, i);
 410                 }
 411         }
 412         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 413         {
 414                 if(teamplay)
 415                 {
 416                         string s = Static_Team_ColorName_Lower(player.team);
 417                         if (s != "neutral")
 418                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 419                 }
 420
 421                 if(!defaultskin)
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423         }
 424
 425         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 426         defaultmodel = M_ARGV(0, string);
 427         defaultskin = M_ARGV(1, int);
 428
 429         bool chmdl = false;
 430         int oldskin;
 431         if(defaultmodel != "")
 432         {
 433                 if (defaultmodel != player.model)
 434                 {
 435                         vector m1 = player.mins;
 436                         vector m2 = player.maxs;
 437                         setplayermodel (player, defaultmodel);
 438                         setsize (player, m1, m2);
 439                         chmdl = true;
 440                 }
 441
 442                 oldskin = player.skin;
 443                 player.skin = defaultskin;
 444         } else {
 445                 if (player.playermodel != player.model || player.playermodel == "")
 446                 {
 447                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 448                         vector m1 = player.mins;
 449                         vector m2 = player.maxs;
 450                         setplayermodel (player, player.playermodel);
 451                         setsize (player, m1, m2);
 452                         chmdl = true;
 453                 }
 454
 455                 if(!autocvar_sv_defaultcharacterskin)
 456                 {
 457                         oldskin = player.skin;
 458                         player.skin = stof(player.playerskin);
 459                 }
 460                 else
 461                 {
 462                         oldskin = player.skin;
 463                         player.skin = defaultskin;
 464                 }
 465         }
 466
 467         if(chmdl || oldskin != player.skin) // model or skin has changed
 468         {
 469                 player.species = player_getspecies(player); // update species
 470                 if(!autocvar_g_debug_globalsounds)
 471                         UpdatePlayerSounds(player); // update skin sounds
 472         }
 473
 474         if(!teamplay)
 475                 if(strlen(autocvar_sv_defaultplayercolors))
 476                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 477                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 478 }
 479
 480
 481 /** Called when a client spawns in the server */
 482 void PutClientInServer(entity this)
 483 {
 484         if (IS_BOT_CLIENT(this)) {
 485                 TRANSMUTE(Player, this);
 486         } else if (IS_REAL_CLIENT(this)) {
 487                 msg_entity = this;
 488                 WriteByte(MSG_ONE, SVC_SETVIEW);
 489                 WriteEntity(MSG_ONE, this);
 490         }
 491         if (gameover) {
 492                 TRANSMUTE(Observer, this);
 493         }
 494
 495         SetSpectatee(this, NULL);
 496
 497         // reset player keys
 498         this.itemkeys = 0;
 499
 500         MUTATOR_CALLHOOK(PutClientInServer, this);
 501
 502         if (IS_OBSERVER(this)) {
 503                 PutObserverInServer(this);
 504         } else if (IS_PLAYER(this)) {
 505                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 506
 507                 PlayerState_attach(this);
 508                 accuracy_resend(this);
 509
 510                 if (this.team < 0)
 511                         JoinBestTeam(this, false, true);
 512
 513                 entity spot = SelectSpawnPoint(this, false);
 514                 if (!spot) {
 515                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 516                         return; // spawn failed
 517                 }
 518
 519                 TRANSMUTE(Player, this);
 520
 521                 this.wasplayer = true;
 522                 this.iscreature = true;
 523                 this.teleportable = TELEPORT_NORMAL;
 524                 this.damagedbycontents = true;
 525                 set_movetype(this, MOVETYPE_WALK);
 526                 this.solid = SOLID_SLIDEBOX;
 527                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 528                 if (autocvar_g_playerclip_collisions)
 529                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 530                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 531                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 532                 this.frags = FRAGS_PLAYER;
 533                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 534                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 535                 if (autocvar__notarget)
 536                         this.flags |= FL_NOTARGET;
 537                 this.takedamage = DAMAGE_AIM;
 538                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 539                 this.dmg = 2; // WTF
 540
 541                 if (warmup_stage) {
 542                         this.ammo_shells = warmup_start_ammo_shells;
 543                         this.ammo_nails = warmup_start_ammo_nails;
 544                         this.ammo_rockets = warmup_start_ammo_rockets;
 545                         this.ammo_cells = warmup_start_ammo_cells;
 546                         this.ammo_plasma = warmup_start_ammo_plasma;
 547                         this.ammo_fuel = warmup_start_ammo_fuel;
 548                         this.health = warmup_start_health;
 549                         this.armorvalue = warmup_start_armorvalue;
 550                         this.weapons = WARMUP_START_WEAPONS;
 551                 } else {
 552                         this.ammo_shells = start_ammo_shells;
 553                         this.ammo_nails = start_ammo_nails;
 554                         this.ammo_rockets = start_ammo_rockets;
 555                         this.ammo_cells = start_ammo_cells;
 556                         this.ammo_plasma = start_ammo_plasma;
 557                         this.ammo_fuel = start_ammo_fuel;
 558                         this.health = start_health;
 559                         this.armorvalue = start_armorvalue;
 560                         this.weapons = start_weapons;
 561                 }
 562                 SetSpectatee_status(this, 0);
 563
 564                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 565
 566                 this.items = start_items;
 567
 568                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 569                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 570                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 571                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 572                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 573                 // extend the pause of rotting if client was reset at the beginning of the countdown
 574                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 575                         float f = game_starttime - time;
 576                         this.spawnshieldtime += f;
 577                         this.pauserotarmor_finished += f;
 578                         this.pauserothealth_finished += f;
 579                         this.pauseregen_finished += f;
 580                 }
 581                 this.damageforcescale = 2;
 582                 this.death_time = 0;
 583                 this.respawn_flags = 0;
 584                 this.respawn_time = 0;
 585                 this.stat_respawn_time = 0;
 586                 this.scale = autocvar_sv_player_scale;
 587                 this.fade_time = 0;
 588                 this.pain_frame = 0;
 589                 this.pain_finished = 0;
 590                 this.pushltime = 0;
 591                 setthink(this, func_null); // players have no think function
 592                 this.nextthink = 0;
 593                 this.dmg_team = 0;
 594                 this.ballistics_density = autocvar_g_ballistics_density_player;
 595
 596                 this.deadflag = DEAD_NO;
 597
 598                 this.angles = spot.angles;
 599                 this.angles_z = 0; // never spawn tilted even if the spot says to
 600                 if (IS_BOT_CLIENT(this))
 601                         this.v_angle = this.angles;
 602                 this.fixangle = true; // turn this way immediately
 603                 this.oldvelocity = this.velocity = '0 0 0';
 604                 this.avelocity = '0 0 0';
 605                 this.punchangle = '0 0 0';
 606                 this.punchvector = '0 0 0';
 607
 608                 this.strength_finished = 0;
 609                 this.invincible_finished = 0;
 610                 this.fire_endtime = -1;
 611                 this.revival_time = 0;
 612                 this.air_finished = time + 12;
 613
 614                 entity spawnevent = new_pure(spawnevent);
 615                 spawnevent.owner = this;
 616                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 617
 618                 // Cut off any still running player sounds.
 619                 stopsound(this, CH_PLAYER_SINGLE);
 620
 621                 this.model = "";
 622                 FixPlayermodel(this);
 623                 this.drawonlytoclient = NULL;
 624
 625                 this.crouch = false;
 626                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 627                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 628                 this.spawnorigin = spot.origin;
 629                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 630                 // don't reset back to last position, even if new position is stuck in solid
 631                 this.oldorigin = this.origin;
 632                 this.prevorigin = this.origin;
 633                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 634                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 635                 this.hud = HUD_NORMAL;
 636
 637                 this.event_damage = PlayerDamage;
 638
 639                 this.bot_attack = true;
 640                 this.monster_attack = true;
 641
 642                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 643
 644                 if (this.killcount == FRAGS_SPECTATOR) {
 645                         PlayerScore_Clear(this);
 646                         this.killcount = 0;
 647                 }
 648
 649                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 650                 {
 651                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 652                 }
 653                 this.alpha = default_player_alpha;
 654                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 655                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 656
 657                 this.speedrunning = false;
 658
 659                 target_voicescript_clear(this);
 660
 661                 // reset fields the weapons may use
 662                 FOREACH(Weapons, true, LAMBDA(
 663                         it.wr_resetplayer(it, this);
 664                         // reload all reloadable weapons
 665                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 666                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 667                         }
 668                 ));
 669
 670                 {
 671                         string s = spot.target;
 672                         spot.target = string_null;
 673                         SUB_UseTargets(spot, this, NULL);
 674                         spot.target = s;
 675                 }
 676
 677                 Unfreeze(this);
 678
 679                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 680
 681                 if (autocvar_spawn_debug)
 682                 {
 683                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 684                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 685                 }
 686
 687                 PS(this).m_switchweapon = w_getbestweapon(this);
 688                 this.cnt = -1; // W_LastWeapon will not complain
 689                 PS(this).m_weapon = WEP_Null;
 690                 this.weaponname = "";
 691                 PS(this).m_switchingweapon = WEP_Null;
 692
 693                 if (!warmup_stage && !this.alivetime)
 694                         this.alivetime = time;
 695
 696                 antilag_clear(this, CS(this));
 697         }
 698 }
 699
 700 void ClientInit_misc(entity this);
 701
 702 .float ebouncefactor, ebouncestop; // electro's values
 703 // TODO do we need all these fields, or should we stop autodetecting runtime
 704 // changes and just have a console command to update this?
 705 bool ClientInit_SendEntity(entity this, entity to, int sf)
 706 {
 707         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 708         return = true;
 709         msg_entity = to;
 710         // MSG_INIT replacement
 711         // TODO: make easier to use
 712         Registry_send_all();
 713         W_PROP_reload(MSG_ONE, to);
 714         ClientInit_misc(this);
 715         MUTATOR_CALLHOOK(Ent_Init);
 716 }
 717 void ClientInit_misc(entity this)
 718 {
 719         int channel = MSG_ONE;
 720         WriteHeader(channel, ENT_CLIENT_INIT);
 721         WriteByte(channel, g_nexball_meter_period * 32);
 722         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 723         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 724         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 725         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 726         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 727         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 728         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 729         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 730
 731         if(sv_foginterval && world.fog != "")
 732                 WriteString(channel, world.fog);
 733         else
 734                 WriteString(channel, "");
 735         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 736         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 737         WriteCoord(channel, autocvar_g_trueaim_minrange);
 738 }
 739
 740 void ClientInit_CheckUpdate(entity this)
 741 {
 742         this.nextthink = time;
 743         if(this.count != autocvar_g_balance_armor_blockpercent)
 744         {
 745                 this.count = autocvar_g_balance_armor_blockpercent;
 746                 this.SendFlags |= 1;
 747         }
 748 }
 749
 750 void ClientInit_Spawn()
 751 {
 752         entity e = new_pure(clientinit);
 753         setthink(e, ClientInit_CheckUpdate);
 754         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 755
 756         ClientInit_CheckUpdate(e);
 757 }
 758
 759 /*
 760 =============
 761 SetNewParms
 762 =============
 763 */
 764 void SetNewParms ()
 765 {
 766         // initialize parms for a new player
 767         parm1 = -(86400 * 366);
 768
 769         MUTATOR_CALLHOOK(SetNewParms);
 770 }
 771
 772 /*
 773 =============
 774 SetChangeParms
 775 =============
 776 */
 777 void SetChangeParms (entity this)
 778 {
 779         // save parms for level change
 780         parm1 = this.parm_idlesince - time;
 781
 782         MUTATOR_CALLHOOK(SetChangeParms);
 783 }
 784
 785 /*
 786 =============
 787 DecodeLevelParms
 788 =============
 789 */
 790 void DecodeLevelParms(entity this)
 791 {
 792         // load parms
 793         this.parm_idlesince = parm1;
 794         if (this.parm_idlesince == -(86400 * 366))
 795                 this.parm_idlesince = time;
 796
 797         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 798         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 799
 800         MUTATOR_CALLHOOK(DecodeLevelParms);
 801 }
 802
 803 /*
 804 =============
 805 ClientKill
 806
 807 Called when a client types 'kill' in the console
 808 =============
 809 */
 810
 811 .float clientkill_nexttime;
 812 void ClientKill_Now_TeamChange(entity this)
 813 {
 814         if(this.killindicator_teamchange == -1)
 815         {
 816                 JoinBestTeam( this, false, true );
 817         }
 818         else if(this.killindicator_teamchange == -2)
 819         {
 820                 if(blockSpectators)
 821                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 822                 PutObserverInServer(this);
 823         }
 824         else
 825                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 826         this.killindicator_teamchange = 0;
 827 }
 828
 829 void ClientKill_Now(entity this)
 830 {
 831         if(this.vehicle)
 832         {
 833             vehicles_exit(this.vehicle, VHEF_RELEASE);
 834             if(!this.killindicator_teamchange)
 835             {
 836             this.vehicle_health = -1;
 837             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 838             }
 839         }
 840
 841         if(this.killindicator && !wasfreed(this.killindicator))
 842                 delete(this.killindicator);
 843
 844         this.killindicator = NULL;
 845
 846         if(this.killindicator_teamchange)
 847                 ClientKill_Now_TeamChange(this);
 848
 849         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 850                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 851
 852         // now I am sure the player IS dead
 853 }
 854 void KillIndicator_Think(entity this)
 855 {
 856         if (gameover)
 857         {
 858                 this.owner.killindicator = NULL;
 859                 delete(this);
 860                 return;
 861         }
 862
 863         if (this.owner.alpha < 0 && !this.owner.vehicle)
 864         {
 865                 this.owner.killindicator = NULL;
 866                 delete(this);
 867                 return;
 868         }
 869
 870         if(this.cnt <= 0)
 871         {
 872                 ClientKill_Now(this.owner);
 873                 return;
 874         }
 875     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 876     {
 877         this.nextthink = time + 1;
 878         this.cnt -= 1;
 879     }
 880         else
 881         {
 882                 if(this.cnt <= 10)
 883                         setmodel(this, MDL_NUM(this.cnt));
 884                 if(IS_REAL_CLIENT(this.owner))
 885                 {
 886                         if(this.cnt <= 10)
 887                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 888                 }
 889                 this.nextthink = time + 1;
 890                 this.cnt -= 1;
 891         }
 892 }
 893
 894 float clientkilltime;
 895 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 896 {
 897         float killtime;
 898         float starttime;
 899
 900         if (gameover)
 901                 return;
 902
 903         killtime = autocvar_g_balance_kill_delay;
 904
 905         if(g_race_qualifying || g_cts)
 906                 killtime = 0;
 907
 908     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 909         return;
 910
 911         this.killindicator_teamchange = targetteam;
 912
 913     if(!this.killindicator)
 914         {
 915                 if(!IS_DEAD(this))
 916                 {
 917                         killtime = max(killtime, this.clientkill_nexttime - time);
 918                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 919                 }
 920
 921                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 922                 {
 923                         ClientKill_Now(this);
 924                 }
 925                 else
 926                 {
 927                         starttime = max(time, clientkilltime);
 928
 929                         this.killindicator = spawn();
 930                         this.killindicator.owner = this;
 931                         this.killindicator.scale = 0.5;
 932                         setattachment(this.killindicator, this, "");
 933                         setorigin(this.killindicator, '0 0 52');
 934                         setthink(this.killindicator, KillIndicator_Think);
 935                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 936                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 937                         this.killindicator.cnt = ceil(killtime);
 938                         this.killindicator.count = bound(0, ceil(killtime), 10);
 939                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 940
 941                         FOREACH_ENTITY_ENT(enemy, this,
 942                         {
 943                                 if(it.classname != "body")
 944                                         continue;
 945                                 it.killindicator = spawn();
 946                                 it.killindicator.owner = it;
 947                                 it.killindicator.scale = 0.5;
 948                                 setattachment(it.killindicator, it, "");
 949                                 setorigin(it.killindicator, '0 0 52');
 950                                 setthink(it.killindicator, KillIndicator_Think);
 951                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 952                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 953                                 it.killindicator.cnt = ceil(killtime);
 954                         });
 955                         this.lip = 0;
 956                 }
 957         }
 958         if(this.killindicator)
 959         {
 960                 if(targetteam == 0) // just die
 961                 {
 962                         this.killindicator.colormod = '0 0 0';
 963                         if(IS_REAL_CLIENT(this))
 964                         if(this.killindicator.cnt > 0)
 965                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 966                 }
 967                 else if(targetteam == -1) // auto
 968                 {
 969                         this.killindicator.colormod = '0 1 0';
 970                         if(IS_REAL_CLIENT(this))
 971                         if(this.killindicator.cnt > 0)
 972                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 973                 }
 974                 else if(targetteam == -2) // spectate
 975                 {
 976                         this.killindicator.colormod = '0.5 0.5 0.5';
 977                         if(IS_REAL_CLIENT(this))
 978                         if(this.killindicator.cnt > 0)
 979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 980                 }
 981                 else
 982                 {
 983                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 984                         if(IS_REAL_CLIENT(this))
 985                         if(this.killindicator.cnt > 0)
 986                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 987                 }
 988         }
 989
 990 }
 991
 992 void ClientKill (entity this)
 993 {
 994         if(gameover) return;
 995         if(this.player_blocked) return;
 996         if(STAT(FROZEN, this)) return;
 997
 998         ClientKill_TeamChange(this, 0);
 999 }
1000
1001 void FixClientCvars(entity e)
1002 {
1003         // send prediction settings to the client
1004         stuffcmd(e, "\nin_bindmap 0 0\n");
1005         if(autocvar_g_antilag == 3) // client side hitscan
1006                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1007         if(autocvar_sv_gentle)
1008                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1009
1010         MUTATOR_CALLHOOK(FixClientCvars, e);
1011 }
1012
1013 float PlayerInIDList(entity p, string idlist)
1014 {
1015         float n, i;
1016         string s;
1017
1018         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1019         if (!p.crypto_idfp)
1020                 return 0;
1021
1022         // this function allows abbreviated player IDs too!
1023         n = tokenize_console(idlist);
1024         for(i = 0; i < n; ++i)
1025         {
1026                 s = argv(i);
1027                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1028                         return 1;
1029         }
1030
1031         return 0;
1032 }
1033
1034 #ifdef DP_EXT_PRECONNECT
1035 /*
1036 =============
1037 ClientPreConnect
1038
1039 Called once (not at each match start) when a client begins a connection to the server
1040 =============
1041 */
1042 void ClientPreConnect ()
1043 {ENGINE_EVENT();
1044         if(autocvar_sv_eventlog)
1045         {
1046                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1047                         this.playerid,
1048                         etof(this),
1049                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1050                 ));
1051         }
1052 }
1053 #endif
1054
1055 /**
1056 =============
1057 ClientConnect
1058
1059 Called when a client connects to the server
1060 =============
1061 */
1062 void ClientConnect(entity this)
1063 {
1064         if (Ban_MaybeEnforceBanOnce(this)) return;
1065         assert(!IS_CLIENT(this), return);
1066         this.flags |= FL_CLIENT;
1067         assert(player_count >= 0, player_count = 0);
1068
1069 #ifdef WATERMARK
1070         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1071 #endif
1072         this.version_nagtime = time + 10 + random() * 10;
1073         TRANSMUTE(Client, this);
1074
1075         // identify the right forced team
1076         if (autocvar_g_campaign)
1077         {
1078                 if (IS_REAL_CLIENT(this)) // only players, not bots
1079                 {
1080                         switch (autocvar_g_campaign_forceteam)
1081                         {
1082                                 case 1: this.team_forced = NUM_TEAM_1; break;
1083                                 case 2: this.team_forced = NUM_TEAM_2; break;
1084                                 case 3: this.team_forced = NUM_TEAM_3; break;
1085                                 case 4: this.team_forced = NUM_TEAM_4; break;
1086                                 default: this.team_forced = 0;
1087                         }
1088                 }
1089         }
1090         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1091         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1092         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1093         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1094         else switch (autocvar_g_forced_team_otherwise)
1095         {
1096                 default: this.team_forced = 0; break;
1097                 case "red": this.team_forced = NUM_TEAM_1; break;
1098                 case "blue": this.team_forced = NUM_TEAM_2; break;
1099                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1100                 case "pink": this.team_forced = NUM_TEAM_4; break;
1101                 case "spectate":
1102                 case "spectator":
1103                         this.team_forced = -1;
1104                         break;
1105         }
1106         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1107
1108     {
1109         int id = this.playerid;
1110         this.playerid = 0; // silent
1111             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1112             this.playerid = id;
1113     }
1114
1115         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1116                 TRANSMUTE(Observer, this);
1117         } else {
1118                 if (!teamplay || autocvar_g_balance_teams) {
1119                         TRANSMUTE(Player, this);
1120                         campaign_bots_may_start = true;
1121                 } else {
1122                         TRANSMUTE(Observer, this); // do it anyway
1123                 }
1124         }
1125
1126         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1127
1128         // always track bots, don't ask for cl_allow_uidtracking
1129     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1130
1131         if (autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1133
1134         LogTeamchange(this.playerid, this.team, 1);
1135
1136         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1137
1138         this.netname_previous = strzone(this.netname);
1139
1140         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1141
1142         stuffcmd(this, clientstuff, "\n");
1143         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1144
1145         FixClientCvars(this);
1146
1147         // get version info from player
1148         stuffcmd(this, "cmd clientversion $gameversion\n");
1149
1150         // notify about available teams
1151         if (teamplay)
1152         {
1153                 CheckAllowedTeams(this);
1154                 int t = 0;
1155                 if (c1 >= 0) t |= BIT(0);
1156                 if (c2 >= 0) t |= BIT(1);
1157                 if (c3 >= 0) t |= BIT(2);
1158                 if (c4 >= 0) t |= BIT(3);
1159                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1160         }
1161         else
1162         {
1163                 stuffcmd(this, "set _teams_available 0\n");
1164         }
1165
1166         bot_relinkplayerlist();
1167
1168         this.spectatortime = time;
1169         if (blockSpectators)
1170         {
1171                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1172         }
1173
1174         this.jointime = time;
1175         this.allowed_timeouts = autocvar_sv_timeout_number;
1176
1177         if (IS_REAL_CLIENT(this))
1178         {
1179                 if (!autocvar_g_campaign)
1180                 {
1181                         this.motd_actived_time = -1;
1182                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1183                 }
1184
1185                 if (g_weaponarena_weapons == WEPSET(TUBA))
1186                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1187         }
1188
1189         if (!sv_foginterval && world.fog != "")
1190                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1191
1192         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1193                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1194                         send_CSQC_teamnagger();
1195
1196         CSQCMODEL_AUTOINIT(this);
1197
1198         this.model_randomizer = random();
1199
1200         if (IS_REAL_CLIENT(this))
1201                 sv_notice_join(this);
1202
1203         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1204                 it.init_for_player(it, this);
1205         });
1206
1207         MUTATOR_CALLHOOK(ClientConnect, this);
1208 }
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 .entity chatbubbleentity;
1217 void ReadyCount();
1218 void ClientDisconnect(entity this)
1219 {
1220         assert(IS_CLIENT(this), return);
1221
1222         PlayerStats_GameReport_FinalizePlayer(this);
1223         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1224         if (this.active_minigame) part_minigame(this);
1225         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1226
1227         if (autocvar_sv_eventlog)
1228                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1229
1230         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1231
1232         SetSpectatee(this, NULL);
1233
1234     MUTATOR_CALLHOOK(ClientDisconnect, this);
1235
1236         ClientState_detach(this);
1237
1238         Portal_ClearAll(this);
1239
1240         Unfreeze(this);
1241
1242         RemoveGrapplingHook(this);
1243
1244         // Here, everything has been done that requires this player to be a client.
1245
1246         this.flags &= ~FL_CLIENT;
1247
1248         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1249         if (this.killindicator) delete(this.killindicator);
1250
1251         WaypointSprite_PlayerGone(this);
1252
1253         bot_relinkplayerlist();
1254
1255         if (this.netname_previous) strunzone(this.netname_previous);
1256         if (this.clientstatus) strunzone(this.clientstatus);
1257         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1258         if (this.personal) delete(this.personal);
1259
1260         this.playerid = 0;
1261         ReadyCount();
1262         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1263 }
1264
1265 void ChatBubbleThink(entity this)
1266 {
1267         this.nextthink = time;
1268         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1269         {
1270                 if(this.owner) // but why can that ever be NULL?
1271                         this.owner.chatbubbleentity = NULL;
1272                 delete(this);
1273                 return;
1274         }
1275
1276         this.mdl = "";
1277
1278         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1279         {
1280                 if ( this.owner.active_minigame )
1281                         this.mdl = "models/sprites/minigame_busy.iqm";
1282                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1283                         this.mdl = "models/misc/chatbubble.spr";
1284         }
1285
1286         if ( this.model != this.mdl )
1287                 _setmodel(this, this.mdl);
1288
1289 }
1290
1291 void UpdateChatBubble(entity this)
1292 {
1293         if (this.alpha < 0)
1294                 return;
1295         // spawn a chatbubble entity if needed
1296         if (!this.chatbubbleentity)
1297         {
1298                 this.chatbubbleentity = new(chatbubbleentity);
1299                 this.chatbubbleentity.owner = this;
1300                 this.chatbubbleentity.exteriormodeltoclient = this;
1301                 setthink(this.chatbubbleentity, ChatBubbleThink);
1302                 this.chatbubbleentity.nextthink = time;
1303                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1304                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1305                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1306                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1307                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1308                 //this.chatbubbleentity.model = "";
1309                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1310         }
1311 }
1312
1313
1314 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1315 // added to the model skins
1316 /*void UpdateColorModHack()
1317 {
1318         float c;
1319         c = this.clientcolors & 15;
1320         // LordHavoc: only bothering to support white, green, red, yellow, blue
1321              if (!teamplay) this.colormod = '0 0 0';
1322         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1323         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1324         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1325         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1326         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1327         else this.colormod = '1 1 1';
1328 }*/
1329
1330 void respawn(entity this)
1331 {
1332         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1333         {
1334                 this.solid = SOLID_NOT;
1335                 this.takedamage = DAMAGE_NO;
1336                 set_movetype(this, MOVETYPE_FLY);
1337                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1338                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1339                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1340                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1341                 if(autocvar_g_respawn_ghosts_maxtime)
1342                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1343         }
1344
1345         CopyBody(this, 1);
1346
1347         this.effects |= EF_NODRAW; // prevent another CopyBody
1348         PutClientInServer(this);
1349 }
1350
1351 void play_countdown(entity this, float finished, Sound samp)
1352 {
1353     TC(Sound, samp);
1354         if(IS_REAL_CLIENT(this))
1355                 if(floor(finished - time - frametime) != floor(finished - time))
1356                         if(finished - time < 6)
1357                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1358 }
1359
1360 void player_powerups(entity this)
1361 {
1362         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1363         int items_prev = this.items;
1364
1365         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1366                 this.modelflags |= MF_ROCKET;
1367         else
1368                 this.modelflags &= ~MF_ROCKET;
1369
1370         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1371
1372         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1373                 return;
1374
1375         Fire_ApplyDamage(this);
1376         Fire_ApplyEffect(this);
1377
1378         if (!g_instagib)
1379         {
1380                 if (this.items & ITEM_Strength.m_itemid)
1381                 {
1382                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1383                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1384                         if (time > this.strength_finished)
1385                         {
1386                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1387                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1388                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1389                         }
1390                 }
1391                 else
1392                 {
1393                         if (time < this.strength_finished)
1394                         {
1395                                 this.items = this.items | ITEM_Strength.m_itemid;
1396                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1397                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1398                         }
1399                 }
1400                 if (this.items & ITEM_Shield.m_itemid)
1401                 {
1402                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1403                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1404                         if (time > this.invincible_finished)
1405                         {
1406                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1407                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1408                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1409                         }
1410                 }
1411                 else
1412                 {
1413                         if (time < this.invincible_finished)
1414                         {
1415                                 this.items = this.items | ITEM_Shield.m_itemid;
1416                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1417                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1418                         }
1419                 }
1420                 if (this.items & IT_SUPERWEAPON)
1421                 {
1422                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1423                         {
1424                                 this.superweapons_finished = 0;
1425                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1428                         }
1429                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1430                         {
1431                                 // don't let them run out
1432                         }
1433                         else
1434                         {
1435                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1436                                 if (time > this.superweapons_finished)
1437                                 {
1438                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1439                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1440                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1441                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1442                                 }
1443                         }
1444                 }
1445                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1446                 {
1447                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1448                         {
1449                                 this.items = this.items | IT_SUPERWEAPON;
1450                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1452                         }
1453                         else
1454                         {
1455                                 this.superweapons_finished = 0;
1456                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1457                         }
1458                 }
1459                 else
1460                 {
1461                         this.superweapons_finished = 0;
1462                 }
1463         }
1464
1465         if(autocvar_g_nodepthtestplayers)
1466                 this.effects = this.effects | EF_NODEPTHTEST;
1467
1468         if(autocvar_g_fullbrightplayers)
1469                 this.effects = this.effects | EF_FULLBRIGHT;
1470
1471         if (time >= game_starttime)
1472         if (time < this.spawnshieldtime)
1473                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1474
1475         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1476 }
1477
1478 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1479 {
1480         if(current > stable)
1481                 return current;
1482         else if(current > stable - 0.25) // when close enough, "snap"
1483                 return stable;
1484         else
1485                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1486 }
1487
1488 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1489 {
1490         if(current < stable)
1491                 return current;
1492         else if(current < stable + 0.25) // when close enough, "snap"
1493                 return stable;
1494         else
1495                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1496 }
1497
1498 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1499 {
1500         if(current > rotstable)
1501         {
1502                 if(rotframetime > 0)
1503                 {
1504                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1505                         current = max(rotstable, current - rotlinear * rotframetime);
1506                 }
1507         }
1508         else if(current < regenstable)
1509         {
1510                 if(regenframetime > 0)
1511                 {
1512                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1513                         current = min(regenstable, current + regenlinear * regenframetime);
1514                 }
1515         }
1516
1517         if(current > limit)
1518                 current = limit;
1519
1520         return current;
1521 }
1522
1523 void player_regen(entity this)
1524 {
1525         float max_mod, regen_mod, rot_mod, limit_mod;
1526         max_mod = regen_mod = rot_mod = limit_mod = 1;
1527
1528         float regen_health = autocvar_g_balance_health_regen;
1529         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1530         float regen_health_rot = autocvar_g_balance_health_rot;
1531         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1532         float regen_health_stable = autocvar_g_balance_health_regenstable;
1533         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1534         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1535                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1536         max_mod = M_ARGV(1, float);
1537         regen_mod = M_ARGV(2, float);
1538         rot_mod = M_ARGV(3, float);
1539         limit_mod = M_ARGV(4, float);
1540         regen_health = M_ARGV(5, float);
1541         regen_health_linear = M_ARGV(6, float);
1542         regen_health_rot = M_ARGV(7, float);
1543         regen_health_rotlinear = M_ARGV(8, float);
1544         regen_health_stable = M_ARGV(9, float);
1545         regen_health_rotstable = M_ARGV(10, float);
1546
1547
1548         if(!mutator_returnvalue)
1549         if(!STAT(FROZEN, this))
1550         {
1551                 float mina, maxa, limith, limita;
1552                 maxa = autocvar_g_balance_armor_rotstable;
1553                 mina = autocvar_g_balance_armor_regenstable;
1554                 limith = autocvar_g_balance_health_limit;
1555                 limita = autocvar_g_balance_armor_limit;
1556
1557                 regen_health_rotstable = regen_health_rotstable * max_mod;
1558                 regen_health_stable = regen_health_stable * max_mod;
1559                 limith = limith * limit_mod;
1560                 limita = limita * limit_mod;
1561
1562                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1563                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1564         }
1565
1566         // if player rotted to death...  die!
1567         // check this outside above checks, as player may still be able to rot to death
1568         if(this.health < 1)
1569         {
1570                 if(this.vehicle)
1571                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1572                 if(this.event_damage)
1573                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1574         }
1575
1576         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1577         {
1578                 float minf, maxf, limitf;
1579
1580                 maxf = autocvar_g_balance_fuel_rotstable;
1581                 minf = autocvar_g_balance_fuel_regenstable;
1582                 limitf = autocvar_g_balance_fuel_limit;
1583
1584                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1585         }
1586 }
1587
1588 bool zoomstate_set;
1589 void SetZoomState(entity this, float z)
1590 {
1591         if(z != this.zoomstate)
1592         {
1593                 this.zoomstate = z;
1594                 ClientData_Touch(this);
1595         }
1596         zoomstate_set = true;
1597 }
1598
1599 void GetPressedKeys(entity this)
1600 {
1601         MUTATOR_CALLHOOK(GetPressedKeys, this);
1602         int keys = this.pressedkeys;
1603         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1604         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1605         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1606         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1607
1608         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1609         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1610         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1611         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1612         this.pressedkeys = keys;
1613 }
1614
1615 /*
1616 ======================
1617 spectate mode routines
1618 ======================
1619 */
1620
1621 void SpectateCopy(entity this, entity spectatee)
1622 {
1623     TC(Client, this); TC(Client, spectatee);
1624
1625         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1626         PS(this) = PS(spectatee);
1627         this.armortype = spectatee.armortype;
1628         this.armorvalue = spectatee.armorvalue;
1629         this.ammo_cells = spectatee.ammo_cells;
1630         this.ammo_plasma = spectatee.ammo_plasma;
1631         this.ammo_shells = spectatee.ammo_shells;
1632         this.ammo_nails = spectatee.ammo_nails;
1633         this.ammo_rockets = spectatee.ammo_rockets;
1634         this.ammo_fuel = spectatee.ammo_fuel;
1635         this.clip_load = spectatee.clip_load;
1636         this.clip_size = spectatee.clip_size;
1637         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1638         this.health = spectatee.health;
1639         this.impulse = 0;
1640         this.items = spectatee.items;
1641         this.last_pickup = spectatee.last_pickup;
1642         this.hit_time = spectatee.hit_time;
1643         this.strength_finished = spectatee.strength_finished;
1644         this.invincible_finished = spectatee.invincible_finished;
1645         this.pressedkeys = spectatee.pressedkeys;
1646         this.weapons = spectatee.weapons;
1647         this.vortex_charge = spectatee.vortex_charge;
1648         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1649         this.hagar_load = spectatee.hagar_load;
1650         this.arc_heat_percent = spectatee.arc_heat_percent;
1651         this.minelayer_mines = spectatee.minelayer_mines;
1652         this.punchangle = spectatee.punchangle;
1653         this.view_ofs = spectatee.view_ofs;
1654         this.velocity = spectatee.velocity;
1655         this.dmg_take = spectatee.dmg_take;
1656         this.dmg_save = spectatee.dmg_save;
1657         this.dmg_inflictor = spectatee.dmg_inflictor;
1658         this.v_angle = spectatee.v_angle;
1659         this.angles = spectatee.v_angle;
1660         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1661         this.revive_progress = spectatee.revive_progress;
1662         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1663                 this.fixangle = true;
1664         setorigin(this, spectatee.origin);
1665         setsize(this, spectatee.mins, spectatee.maxs);
1666         SetZoomState(this, spectatee.zoomstate);
1667
1668     anticheat_spectatecopy(this, spectatee);
1669         this.hud = spectatee.hud;
1670         if(spectatee.vehicle)
1671     {
1672         this.angles = spectatee.v_angle;
1673
1674         //this.fixangle = false;
1675         //this.velocity = spectatee.vehicle.velocity;
1676         this.vehicle_health = spectatee.vehicle_health;
1677         this.vehicle_shield = spectatee.vehicle_shield;
1678         this.vehicle_energy = spectatee.vehicle_energy;
1679         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1680         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1681         this.vehicle_reload1 = spectatee.vehicle_reload1;
1682         this.vehicle_reload2 = spectatee.vehicle_reload2;
1683
1684         //msg_entity = this;
1685
1686        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1687             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1688            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1689            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1690
1691         //WriteByte (MSG_ONE, SVC_SETVIEW);
1692         //    WriteEntity(MSG_ONE, this);
1693         //makevectors(spectatee.v_angle);
1694         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1695     }
1696 }
1697
1698 bool SpectateUpdate(entity this)
1699 {
1700         if(!this.enemy)
1701             return false;
1702
1703         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1704         {
1705                 SetSpectatee(this, NULL);
1706                 return false;
1707         }
1708
1709         SpectateCopy(this, this.enemy);
1710
1711         return true;
1712 }
1713
1714 bool SpectateSet(entity this)
1715 {
1716         if(!IS_PLAYER(this.enemy))
1717                 return false;
1718
1719         ClientData_Touch(this.enemy);
1720
1721         msg_entity = this;
1722         WriteByte(MSG_ONE, SVC_SETVIEW);
1723         WriteEntity(MSG_ONE, this.enemy);
1724         set_movetype(this, MOVETYPE_NONE);
1725         accuracy_resend(this);
1726
1727         if(!SpectateUpdate(this))
1728                 PutObserverInServer(this);
1729
1730         return true;
1731 }
1732
1733 void SetSpectatee_status(entity this, int spectatee_num)
1734 {
1735         int oldspectatee_status = this.spectatee_status;
1736         this.spectatee_status = spectatee_num;
1737
1738         if (this.spectatee_status != oldspectatee_status)
1739         {
1740                 ClientData_Touch(this);
1741                 if (g_race || g_cts) race_InitSpectator();
1742         }
1743 }
1744
1745 void SetSpectatee(entity this, entity spectatee)
1746 {
1747         entity old_spectatee = this.enemy;
1748
1749         this.enemy = spectatee;
1750
1751         // WEAPONTODO
1752         // these are required to fix the spectator bug with arc
1753         if(old_spectatee)
1754         {
1755                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1756                 {
1757                         .entity weaponentity = weaponentities[slot];
1758                         if(old_spectatee.(weaponentity).arc_beam)
1759                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1760                 }
1761         }
1762         if(this.enemy)
1763         {
1764                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1765                 {
1766                         .entity weaponentity = weaponentities[slot];
1767                         if(this.enemy.(weaponentity).arc_beam)
1768                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1769                 }
1770         }
1771
1772         if (this.enemy)
1773                 SetSpectatee_status(this, etof(this.enemy));
1774
1775         // needed to update spectator list
1776         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1777 }
1778
1779 bool Spectate(entity this, entity pl)
1780 {
1781         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1782                 return false;
1783         pl = M_ARGV(1, entity);
1784
1785         SetSpectatee(this, pl);
1786         return SpectateSet(this);
1787 }
1788
1789 bool SpectateNext(entity this)
1790 {
1791         entity ent = find(this.enemy, classname, STR_PLAYER);
1792
1793         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1794                 ent = M_ARGV(1, entity);
1795         else if (!ent)
1796                 ent = find(ent, classname, STR_PLAYER);
1797
1798         if(ent) { SetSpectatee(this, ent); }
1799
1800         return SpectateSet(this);
1801 }
1802
1803 bool SpectatePrev(entity this)
1804 {
1805         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1806         entity ent = findchain(classname, STR_PLAYER);
1807         if (!ent) // no player
1808                 return false;
1809
1810         entity first = ent;
1811         // skip players until current spectated player
1812         if(this.enemy)
1813         while(ent && ent != this.enemy)
1814                 ent = ent.chain;
1815
1816         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1817         {
1818                 case MUT_SPECPREV_FOUND:
1819                     ent = M_ARGV(1, entity);
1820                     break;
1821                 case MUT_SPECPREV_RETURN:
1822                     return true;
1823                 case MUT_SPECPREV_CONTINUE:
1824                 default:
1825                 {
1826                         if(ent.chain)
1827                                 ent = ent.chain;
1828                         else
1829                                 ent = first;
1830                         break;
1831                 }
1832         }
1833
1834         SetSpectatee(this, ent);
1835         return SpectateSet(this);
1836 }
1837
1838 /*
1839 =============
1840 ShowRespawnCountdown()
1841
1842 Update a respawn countdown display.
1843 =============
1844 */
1845 void ShowRespawnCountdown(entity this)
1846 {
1847         float number;
1848         if(!IS_DEAD(this)) // just respawned?
1849                 return;
1850         else
1851         {
1852                 number = ceil(this.respawn_time - time);
1853                 if(number <= 0)
1854                         return;
1855                 if(number <= this.respawn_countdown)
1856                 {
1857                         this.respawn_countdown = number - 1;
1858                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1859                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1860                 }
1861         }
1862 }
1863
1864 .float caplayer;
1865
1866 void LeaveSpectatorMode(entity this)
1867 {
1868         if(this.caplayer)
1869                 return;
1870         if(nJoinAllowed(this, this))
1871         {
1872                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1873                 {
1874                         TRANSMUTE(Player, this);
1875
1876                         SetSpectatee(this, NULL);
1877
1878                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1879                                 { JoinBestTeam(this, false, true); }
1880
1881                         if(autocvar_g_campaign)
1882                                 { campaign_bots_may_start = true; }
1883
1884                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1885
1886                         PutClientInServer(this);
1887
1888                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1889                 }
1890                 else
1891                         stuffcmd(this, "menu_showteamselect\n");
1892         }
1893         else
1894         {
1895                 // Player may not join because g_maxplayers is set
1896                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1897         }
1898 }
1899
1900 /**
1901  * Determines whether the player is allowed to join. This depends on cvar
1902  * g_maxplayers, if it isn't used this function always return true, otherwise
1903  * it checks whether the number of currently playing players exceeds g_maxplayers.
1904  * @return int number of free slots for players, 0 if none
1905  */
1906 bool nJoinAllowed(entity this, entity ignore)
1907 {
1908         if(!ignore)
1909         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1910         // so report 0 free slots if restricted
1911         {
1912                 if(autocvar_g_forced_team_otherwise == "spectate")
1913                         return false;
1914                 if(autocvar_g_forced_team_otherwise == "spectator")
1915                         return false;
1916         }
1917
1918         if(this.team_forced < 0)
1919                 return false; // forced spectators can never join
1920
1921         // TODO simplify this
1922         int totalClients = 0;
1923         int currentlyPlaying = 0;
1924         FOREACH_CLIENT(true, LAMBDA(
1925                 if(it != ignore)
1926                         ++totalClients;
1927                 if(IS_REAL_CLIENT(it))
1928                 if(IS_PLAYER(it) || it.caplayer)
1929                         ++currentlyPlaying;
1930         ));
1931
1932         if (!autocvar_g_maxplayers)
1933                 return maxclients - totalClients;
1934
1935         if(currentlyPlaying < autocvar_g_maxplayers)
1936                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1937
1938         return false;
1939 }
1940
1941 /**
1942  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1943  * g_maxplayers_spectator_blocktime seconds
1944  */
1945 void checkSpectatorBlock(entity this)
1946 {
1947         if(IS_SPEC(this) || IS_OBSERVER(this))
1948         if(!this.caplayer)
1949         if(IS_REAL_CLIENT(this))
1950         {
1951                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1952                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1953                         dropclient(this);
1954                 }
1955         }
1956 }
1957
1958 void PrintWelcomeMessage(entity this)
1959 {
1960         if(this.motd_actived_time == 0)
1961         {
1962                 if (autocvar_g_campaign) {
1963                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1964                                 this.motd_actived_time = time;
1965                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1966                         }
1967                 } else {
1968                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1969                                 this.motd_actived_time = time;
1970                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1971                         }
1972                 }
1973         }
1974         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1975         {
1976                 if (autocvar_g_campaign) {
1977                         if (PHYS_INPUT_BUTTON_INFO(this))
1978                                 this.motd_actived_time = time;
1979                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1980                                 this.motd_actived_time = 0;
1981                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1982                         }
1983                 } else {
1984                         if (PHYS_INPUT_BUTTON_INFO(this))
1985                                 this.motd_actived_time = time;
1986                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1987                                 this.motd_actived_time = 0;
1988                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1989                         }
1990                 }
1991         }
1992         else //if(this.motd_actived_time < 0) // just connected, motd is active
1993         {
1994                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1995                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1996                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1997                 {
1998                         // instanctly hide MOTD
1999                         this.motd_actived_time = 0;
2000                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2001                 }
2002         }
2003 }
2004
2005 void ObserverThink(entity this)
2006 {
2007         if ( this.impulse )
2008         {
2009                 MinigameImpulse(this, this.impulse);
2010                 this.impulse = 0;
2011         }
2012         if (this.flags & FL_JUMPRELEASED) {
2013                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2014                         this.flags &= ~FL_JUMPRELEASED;
2015                         this.flags |= FL_SPAWNING;
2016                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2017                         this.flags &= ~FL_JUMPRELEASED;
2018                         if(SpectateNext(this)) {
2019                                 TRANSMUTE(Spectator, this);
2020                         }
2021                 } else {
2022                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2023                         set_movetype(this, preferred_movetype);
2024                 }
2025         } else {
2026                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2027                         this.flags |= FL_JUMPRELEASED;
2028                         if(this.flags & FL_SPAWNING)
2029                         {
2030                                 this.flags &= ~FL_SPAWNING;
2031                                 LeaveSpectatorMode(this);
2032                                 return;
2033                         }
2034                 }
2035         }
2036 }
2037
2038 void SpectatorThink(entity this)
2039 {
2040         if ( this.impulse )
2041         {
2042                 if(MinigameImpulse(this, this.impulse))
2043                         this.impulse = 0;
2044
2045                 if (this.impulse == IMP_weapon_drop.impulse)
2046                 {
2047                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2048                         this.impulse = 0;
2049                         return;
2050                 }
2051         }
2052         if (this.flags & FL_JUMPRELEASED) {
2053                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2054                         this.flags &= ~FL_JUMPRELEASED;
2055                         this.flags |= FL_SPAWNING;
2056                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2057                         this.flags &= ~FL_JUMPRELEASED;
2058                         if(SpectateNext(this)) {
2059                                 TRANSMUTE(Spectator, this);
2060                         } else {
2061                                 TRANSMUTE(Observer, this);
2062                                 PutClientInServer(this);
2063                         }
2064                         this.impulse = 0;
2065                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2066                         this.flags &= ~FL_JUMPRELEASED;
2067                         if(SpectatePrev(this)) {
2068                                 TRANSMUTE(Spectator, this);
2069                         } else {
2070                                 TRANSMUTE(Observer, this);
2071                                 PutClientInServer(this);
2072                         }
2073                         this.impulse = 0;
2074                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2075                         this.flags &= ~FL_JUMPRELEASED;
2076                         TRANSMUTE(Observer, this);
2077                         PutClientInServer(this);
2078                 } else {
2079                         if(!SpectateUpdate(this))
2080                                 PutObserverInServer(this);
2081                 }
2082         } else {
2083                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2084                         this.flags |= FL_JUMPRELEASED;
2085                         if(this.flags & FL_SPAWNING)
2086                         {
2087                                 this.flags &= ~FL_SPAWNING;
2088                                 LeaveSpectatorMode(this);
2089                                 return;
2090                         }
2091                 }
2092                 if(!SpectateUpdate(this))
2093                         PutObserverInServer(this);
2094         }
2095
2096         this.flags |= FL_CLIENT | FL_NOTARGET;
2097 }
2098
2099 void vehicles_enter (entity pl, entity veh);
2100 void PlayerUseKey(entity this)
2101 {
2102         if (!IS_PLAYER(this))
2103                 return;
2104
2105         if(this.vehicle)
2106         {
2107                 if(!gameover)
2108                 {
2109                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2110                         return;
2111                 }
2112         }
2113         else if(autocvar_g_vehicles_enter)
2114         {
2115                 if(!STAT(FROZEN, this))
2116                 if(!IS_DEAD(this))
2117                 if(!gameover)
2118                 {
2119                         entity head, closest_target = NULL;
2120                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2121
2122                         while(head) // find the closest acceptable target to enter
2123                         {
2124                                 if(IS_VEHICLE(head))
2125                                 if(!IS_DEAD(head))
2126                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2127                                 if(head.takedamage != DAMAGE_NO)
2128                                 {
2129                                         if(closest_target)
2130                                         {
2131                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2132                                                 { closest_target = head; }
2133                                         }
2134                                         else { closest_target = head; }
2135                                 }
2136
2137                                 head = head.chain;
2138                         }
2139
2140                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2141                 }
2142         }
2143
2144         // a use key was pressed; call handlers
2145         MUTATOR_CALLHOOK(PlayerUseKey, this);
2146 }
2147
2148
2149 /*
2150 =============
2151 PlayerPreThink
2152
2153 Called every frame for each client before the physics are run
2154 =============
2155 */
2156 .float usekeypressed;
2157 .float last_vehiclecheck;
2158 .int items_added;
2159 void PlayerPreThink (entity this)
2160 {
2161         WarpZone_PlayerPhysics_FixVAngle(this);
2162
2163     STAT(GAMESTARTTIME, this) = game_starttime;
2164         STAT(ROUNDSTARTTIME, this) = round_starttime;
2165         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2166         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2167
2168         STAT(WEAPONSINMAP, this) = weaponsInMap;
2169
2170         if (frametime) {
2171                 // physics frames: update anticheat stuff
2172                 anticheat_prethink(this);
2173         }
2174
2175         if (blockSpectators && frametime) {
2176                 // WORKAROUND: only use dropclient in server frames (frametime set).
2177                 // Never use it in cl_movement frames (frametime zero).
2178                 checkSpectatorBlock(this);
2179     }
2180
2181         zoomstate_set = false;
2182
2183         // Check for nameless players
2184         if (isInvisibleString(this.netname)) {
2185                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2186                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2187         }
2188         if (this.netname != this.netname_previous) {
2189                 if (autocvar_sv_eventlog) {
2190                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2191         }
2192                 if (this.netname_previous) strunzone(this.netname_previous);
2193                 this.netname_previous = strzone(this.netname);
2194         }
2195
2196         // version nagging
2197         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2198         this.version_nagtime = 0;
2199         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2200             // git client
2201         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2202             // git server
2203             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2204         } else {
2205             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2206             if (r < 0) { // old client
2207                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2208             } else if (r > 0) { // old server
2209                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2210             }
2211         }
2212     }
2213
2214         // GOD MODE info
2215         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2216         {
2217                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2218                 this.max_armorvalue = 0;
2219         }
2220
2221         if (STAT(FROZEN, this) == 2)
2222         {
2223                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2224                 this.health = max(1, this.revive_progress * start_health);
2225                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2226
2227                 if (this.revive_progress >= 1)
2228                         Unfreeze(this);
2229         }
2230         else if (STAT(FROZEN, this) == 3)
2231         {
2232                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2233                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2234
2235                 if (this.health < 1)
2236                 {
2237                         if (this.vehicle)
2238                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2239                         if(this.event_damage)
2240                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2241                 }
2242                 else if (this.revive_progress <= 0)
2243                         Unfreeze(this);
2244         }
2245
2246         MUTATOR_CALLHOOK(PlayerPreThink, this);
2247
2248         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2249         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2250         {
2251                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2252                 {
2253                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2254                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2255                         {
2256                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2257                         }
2258                         else if(!it.owner)
2259                         {
2260                                 if(!it.team || SAME_TEAM(this, it))
2261                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2262                                 else if(autocvar_g_vehicles_steal)
2263                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2264                         }
2265                 });
2266
2267                 this.last_vehiclecheck = time + 1;
2268         }
2269
2270         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2271         {
2272                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2273                         PlayerUseKey(this);
2274                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2275         }
2276
2277         if (IS_REAL_CLIENT(this))
2278                 PrintWelcomeMessage(this);
2279
2280         if (IS_PLAYER(this)) {
2281                 CheckRules_Player(this);
2282
2283                 if (intermission_running) {
2284                         IntermissionThink(this);
2285                         return;
2286                 }
2287
2288                 if (timeout_status == TIMEOUT_ACTIVE) {
2289             // don't allow the player to turn around while game is paused
2290                         // FIXME turn this into CSQC stuff
2291                         this.v_angle = this.lastV_angle;
2292                         this.angles = this.lastV_angle;
2293                         this.fixangle = true;
2294                 }
2295
2296                 if (frametime) player_powerups(this);
2297
2298                 if (IS_DEAD(this)) {
2299                         if (this.personal && g_race_qualifying) {
2300                                 if (time > this.respawn_time) {
2301                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2302                                         respawn(this);
2303                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2304                                 }
2305                         } else {
2306                                 if (frametime) player_anim(this);
2307                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2308
2309                                 switch(this.deadflag)
2310                                 {
2311                                         case DEAD_DYING:
2312                                         {
2313                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2314                                                         this.deadflag = DEAD_RESPAWNING;
2315                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2316                                                         this.deadflag = DEAD_DEAD;
2317                                                 break;
2318                                         }
2319                                         case DEAD_DEAD:
2320                                         {
2321                                                 if (button_pressed)
2322                                                         this.deadflag = DEAD_RESPAWNABLE;
2323                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2324                                                         this.deadflag = DEAD_RESPAWNING;
2325                                                 break;
2326                                         }
2327                                         case DEAD_RESPAWNABLE:
2328                                         {
2329                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2330                                                         this.deadflag = DEAD_RESPAWNING;
2331                                                 break;
2332                                         }
2333                                         case DEAD_RESPAWNING:
2334                                         {
2335                                                 if (time > this.respawn_time)
2336                                                 {
2337                                                         this.respawn_time = time + 1; // only retry once a second
2338                                                         this.respawn_time_max = this.respawn_time;
2339                                                         respawn(this);
2340                                                 }
2341                                                 break;
2342                                         }
2343                                 }
2344
2345                                 ShowRespawnCountdown(this);
2346
2347                                 if (this.respawn_flags & RESPAWN_SILENT)
2348                                         STAT(RESPAWN_TIME, this) = 0;
2349                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2350                                 {
2351                                         if (time < this.respawn_time)
2352                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2353                                         else if (this.deadflag != DEAD_RESPAWNING)
2354                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2355                                 }
2356                                 else
2357                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2358                         }
2359
2360                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2361                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2362                                 STAT(RESPAWN_TIME, this) *= -1;
2363
2364                         return;
2365                 }
2366
2367                 this.prevorigin = this.origin;
2368
2369                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2370                 if (this.hook.state) {
2371                         do_crouch = false;
2372                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2373                         do_crouch = false;
2374                 } else if (this.vehicle) {
2375                         do_crouch = false;
2376                 } else if (STAT(FROZEN, this)) {
2377                         do_crouch = false;
2378         }
2379
2380                 if (do_crouch) {
2381                         if (!this.crouch) {
2382                                 this.crouch = true;
2383                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2384                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2385                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2386                         }
2387                 } else if (this.crouch) {
2388             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2389             if (!trace_startsolid) {
2390                 this.crouch = false;
2391                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2392                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2393             }
2394                 }
2395
2396                 FixPlayermodel(this);
2397
2398                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2399                 //if(frametime)
2400                 {
2401                         this.items &= ~this.items_added;
2402
2403                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2404                         //{
2405                                 //.entity weaponentity = weaponentities[slot];
2406                                 //W_WeaponFrame(this, weaponentity);
2407                         //}
2408                         .entity weaponentity = weaponentities[0]; // TODO
2409                         W_WeaponFrame(this, weaponentity);
2410
2411                         this.items_added = 0;
2412                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2413                 this.items_added |= IT_FUEL;
2414
2415                         this.items |= this.items_added;
2416                 }
2417
2418                 player_regen(this);
2419
2420                 // WEAPONTODO: Add a weapon request for this
2421                 // rot vortex charge to the charge limit
2422                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2423                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2424
2425                 if (frametime) player_anim(this);
2426
2427                 // secret status
2428                 secrets_setstatus(this);
2429
2430                 // monsters status
2431                 monsters_setstatus(this);
2432
2433                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2434         }
2435         else if (gameover) {
2436                 if (intermission_running) IntermissionThink(this);
2437                 return;
2438         }
2439         else if (IS_OBSERVER(this)) {
2440                 ObserverThink(this);
2441         }
2442         else if (IS_SPEC(this)) {
2443                 SpectatorThink(this);
2444         }
2445
2446         // WEAPONTODO: Add weapon request for this
2447         if (!zoomstate_set) {
2448                 SetZoomState(this,
2449                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2450                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2451                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2452                 );
2453     }
2454
2455         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2456         {
2457                 this.teamkill_soundtime = 0;
2458
2459                 entity e = this.teamkill_soundsource;
2460                 entity oldpusher = e.pusher;
2461                 e.pusher = this;
2462                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2463                 e.pusher = oldpusher;
2464         }
2465
2466         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2467                 this.taunt_soundtime = 0;
2468                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2469         }
2470
2471         target_voicescript_next(this);
2472
2473         // WEAPONTODO: Move into weaponsystem somehow
2474         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2475         if (PS(this).m_weapon == WEP_Null)
2476                 this.clip_load = this.clip_size = 0;
2477 }
2478
2479 void DrownPlayer(entity this)
2480 {
2481         if(IS_DEAD(this))
2482                 return;
2483
2484         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2485         {
2486                 if(this.air_finished < time)
2487                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2488                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2489                 this.dmg = 2;
2490         }
2491         else if (this.air_finished < time)
2492         {       // drown!
2493                 if (this.pain_finished < time)
2494                 {
2495                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2496                         this.pain_finished = time + 0.5;
2497                 }
2498         }
2499 }
2500
2501 .bool move_qcphysics;
2502
2503 void Player_Physics(entity this)
2504 {
2505         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2506
2507         if(!this.move_qcphysics)
2508                 return;
2509
2510         int mt = this.move_movetype;
2511
2512         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2513         {
2514                 this.move_qcphysics = false;
2515                 set_movetype(this, mt);
2516                 return;
2517         }
2518
2519         if(!frametime && !this.pm_frametime)
2520                 return;
2521
2522         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2523
2524         this.pm_frametime = 0;
2525 }
2526
2527 /*
2528 =============
2529 PlayerPostThink
2530
2531 Called every frame for each client after the physics are run
2532 =============
2533 */
2534 .float idlekick_lasttimeleft;
2535 void PlayerPostThink (entity this)
2536 {
2537         Player_Physics(this);
2538
2539         if (sv_maxidle > 0)
2540         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2541         if (IS_REAL_CLIENT(this))
2542         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2543         {
2544                 int totalClients = 0;
2545                 if(sv_maxidle_slots > 0)
2546                 {
2547                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2548                         {
2549                                 ++totalClients;
2550                         });
2551                 }
2552
2553                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2554                 { /* do nothing */ }
2555                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2556                 {
2557                         if (this.idlekick_lasttimeleft)
2558                         {
2559                                 this.idlekick_lasttimeleft = 0;
2560                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2561                         }
2562                 }
2563                 else
2564                 {
2565                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2566                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2567                                 if (!this.idlekick_lasttimeleft)
2568                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2569                         }
2570                         if (timeleft <= 0) {
2571                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2572                                 dropclient(this);
2573                                 return;
2574                         }
2575                         else if (timeleft <= 10) {
2576                                 if (timeleft != this.idlekick_lasttimeleft) {
2577                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2578                 }
2579                                 this.idlekick_lasttimeleft = timeleft;
2580                         }
2581                 }
2582         }
2583
2584         CheatFrame(this);
2585
2586         //CheckPlayerJump();
2587
2588         if (IS_PLAYER(this)) {
2589                 DrownPlayer(this);
2590                 CheckRules_Player(this);
2591                 UpdateChatBubble(this);
2592                 if (this.impulse) ImpulseCommands(this);
2593                 if (intermission_running) return; // intermission or finale
2594                 GetPressedKeys(this);
2595         }
2596
2597         if (this.waypointsprite_attachedforcarrier) {
2598             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2599                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2600     }
2601
2602         playerdemo_write(this);
2603
2604         CSQCMODEL_AUTOUPDATE(this);
2605 }