qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 void send_TeamNames(int channel, entity to) {
 101         msg_entity = to;
 102
 103         WriteHeader(channel, TE_CSQC_TEAMNAMES);
 104         WriteString(channel, autocvar_g_teamnames_red);
 105         WriteString(channel, autocvar_g_teamnames_blue);
 106         WriteString(channel, autocvar_g_teamnames_yellow);
 107         WriteString(channel, autocvar_g_teamnames_pink);
 108 }
 109
 110 int CountSpectators(entity player, entity to)
 111 {
 112         if(!player) { return 0; } // not sure how, but best to be safe
 113
 114         int spec_count = 0;
 115
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 spec_count++;
 119         });
 120
 121         return spec_count;
 122 }
 123
 124 void WriteSpectators(entity player, entity to)
 125 {
 126         if(!player) { return; } // not sure how, but best to be safe
 127
 128         int spec_count = 0;
 129         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 130         {
 131                 if(spec_count >= MAX_SPECTATORS)
 132                         break;
 133                 WriteByte(MSG_ENTITY, num_for_edict(it));
 134                 ++spec_count;
 135         });
 136 }
 137
 138 bool ClientData_Send(entity this, entity to, int sf)
 139 {
 140         assert(to == this.owner, return false);
 141
 142         entity e = to;
 143         if (IS_SPEC(e)) e = e.enemy;
 144
 145         sf = 0;
 146         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 147         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 148         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 149         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 150
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 152         WriteByte(MSG_ENTITY, sf);
 153
 154         if (sf & BIT(1))
 155                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 156
 157         if(sf & BIT(4))
 158         {
 159                 float specs = CountSpectators(e, to);
 160                 WriteByte(MSG_ENTITY, specs);
 161                 WriteSpectators(e, to);
 162         }
 163
 164         return true;
 165 }
 166
 167 void ClientData_Attach(entity this)
 168 {
 169         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 170         CS(this).clientdata.drawonlytoclient = this;
 171         CS(this).clientdata.owner = this;
 172 }
 173
 174 void ClientData_Detach(entity this)
 175 {
 176         delete(CS(this).clientdata);
 177         CS(this).clientdata = NULL;
 178 }
 179
 180 void ClientData_Touch(entity e)
 181 {
 182         entity cd = CS(e).clientdata;
 183         if (cd) { cd.SendFlags = 1; }
 184
 185         // make it spectatable
 186         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 187         {
 188                 entity cd = CS(it).clientdata;
 189                 if (cd) { cd.SendFlags = 1; }
 190         });
 191 }
 192
 193
 194 /*
 195 =============
 196 CheckPlayerModel
 197
 198 Checks if the argument string can be a valid playermodel.
 199 Returns a valid one in doubt.
 200 =============
 201 */
 202 string FallbackPlayerModel;
 203 string CheckPlayerModel(string plyermodel) {
 204         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 205         {
 206                 // note: we cannot summon Don Strunzone here, some player may
 207                 // still have the model string set. In case anyone manages how
 208                 // to change a cvar default, we'll have a small leak here.
 209                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 210         }
 211         // only in right path
 212         if(substring(plyermodel, 0, 14) != "models/player/")
 213                 return FallbackPlayerModel;
 214         // only good file extensions
 215         if(substring(plyermodel, -4, 4) != ".iqm"
 216                 && substring(plyermodel, -4, 4) != ".zym"
 217                 && substring(plyermodel, -4, 4) != ".dpm"
 218                 && substring(plyermodel, -4, 4) != ".md3"
 219                 && substring(plyermodel, -4, 4) != ".psk")
 220         {
 221                 return FallbackPlayerModel;
 222         }
 223         // forbid the LOD models
 224         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 225                 return FallbackPlayerModel;
 226         if(plyermodel != strtolower(plyermodel))
 227                 return FallbackPlayerModel;
 228         // also, restrict to server models
 229         if(autocvar_sv_servermodelsonly)
 230         {
 231                 if(!fexists(plyermodel))
 232                         return FallbackPlayerModel;
 233         }
 234         return plyermodel;
 235 }
 236
 237 void setplayermodel(entity e, string modelname)
 238 {
 239         precache_model(modelname);
 240         _setmodel(e, modelname);
 241         player_setupanimsformodel(e);
 242         if(!autocvar_g_debug_globalsounds)
 243                 UpdatePlayerSounds(e);
 244 }
 245
 246 /** putting a client as observer in the server */
 247 void PutObserverInServer(entity this)
 248 {
 249         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 250         PlayerState_detach(this);
 251
 252         if (IS_PLAYER(this))
 253         {
 254                 if(GetResource(this, RES_HEALTH) >= 1)
 255                 {
 256                         // despawn effect
 257                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 258                 }
 259
 260                 // was a player, recount votes and ready status
 261                 if(IS_REAL_CLIENT(this))
 262                 {
 263                         if (vote_called) { VoteCount(false); }
 264                         ReadyCount();
 265                 }
 266                 entcs_update_players(this);
 267         }
 268
 269         entity spot = SelectSpawnPoint(this, true);
 270         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 271         this.angles = vec2(spot.angles);
 272         this.fixangle = true;
 273         // offset it so that the spectator spawns higher off the ground, looks better this way
 274         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         WaypointSprite_PlayerDead(this);
 308
 309         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 310                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321         STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.effects = 0;
 335         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 336         this.pauserotarmor_finished = 0;
 337         this.pauserothealth_finished = 0;
 338         this.pauseregen_finished = 0;
 339         this.damageforcescale = 0;
 340         this.death_time = 0;
 341         this.respawn_flags = 0;
 342         this.respawn_time = 0;
 343         STAT(RESPAWN_TIME, this) = 0;
 344         this.alpha = 0;
 345         this.scale = 0;
 346         this.fade_time = 0;
 347         this.pain_finished = 0;
 348         STAT(STRENGTH_FINISHED, this) = 0;
 349         STAT(INVINCIBLE_FINISHED, this) = 0;
 350         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.fire_endtime = -1;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void ResetPlayerResources(entity this)
 538 {
 539         if (warmup_stage) {
 540                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 541                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 542                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 543                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 544                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 545                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 546                 SetResource(this, RES_HEALTH, warmup_start_health);
 547                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 548                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 549         } else {
 550                 SetResource(this, RES_SHELLS, start_ammo_shells);
 551                 SetResource(this, RES_BULLETS, start_ammo_nails);
 552                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 553                 SetResource(this, RES_CELLS, start_ammo_cells);
 554                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 555                 SetResource(this, RES_FUEL, start_ammo_fuel);
 556                 SetResource(this, RES_HEALTH, start_health);
 557                 SetResource(this, RES_ARMOR, start_armorvalue);
 558                 STAT(WEAPONS, this) = start_weapons;
 559                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 560                 {
 561                         GiveRandomWeapons(this, random_start_weapons_count,
 562                                 autocvar_g_random_start_weapons, random_start_ammo);
 563                 }
 564         }
 565 }
 566
 567 void PutPlayerInServer(entity this)
 568 {
 569         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 570
 571         PlayerState_attach(this);
 572         accuracy_resend(this);
 573
 574         if (this.team < 0)
 575                 TeamBalance_JoinBestTeam(this);
 576
 577         entity spot = SelectSpawnPoint(this, false);
 578         if (!spot) {
 579                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 580                 return; // spawn failed
 581         }
 582
 583         TRANSMUTE(Player, this);
 584
 585         CS(this).wasplayer = true;
 586         this.iscreature = true;
 587         this.teleportable = TELEPORT_NORMAL;
 588         if(!this.damagedbycontents)
 589                 IL_PUSH(g_damagedbycontents, this);
 590         this.damagedbycontents = true;
 591         set_movetype(this, MOVETYPE_WALK);
 592         this.solid = SOLID_SLIDEBOX;
 593         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 594         if (autocvar_g_playerclip_collisions)
 595                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 596         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 597                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 598         this.frags = FRAGS_PLAYER;
 599         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 600         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 601         if (autocvar__notarget)
 602                 this.flags |= FL_NOTARGET;
 603         this.takedamage = DAMAGE_AIM;
 604         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 605
 606         ResetPlayerResources(this);
 607
 608         SetSpectatee_status(this, 0);
 609
 610         PS(this).dual_weapons = '0 0 0';
 611
 612         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 613
 614         this.items = start_items;
 615
 616         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 617         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 618         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 619         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 620         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 621         if (!sv_ready_restart_after_countdown && time < game_starttime)
 622         {
 623                 float f = game_starttime - time;
 624                 this.spawnshieldtime += f;
 625                 this.pauserotarmor_finished += f;
 626                 this.pauserothealth_finished += f;
 627                 this.pauseregen_finished += f;
 628         }
 629
 630         this.damageforcescale = autocvar_g_player_damageforcescale;
 631         this.death_time = 0;
 632         this.respawn_flags = 0;
 633         this.respawn_time = 0;
 634         STAT(RESPAWN_TIME, this) = 0;
 635         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 636         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(STRENGTH_FINISHED, this) = 0;
 661         STAT(INVINCIBLE_FINISHED, this) = 0;
 662         this.fire_endtime = -1;
 663         STAT(REVIVE_PROGRESS, this) = 0;
 664         this.revival_time = 0;
 665
 666         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 667         STAT(BUFFS, this) = 0;
 668         STAT(BUFF_TIME, this) = 0;
 669
 670         STAT(AIR_FINISHED, this) = 0;
 671         this.waterlevel = WATERLEVEL_NONE;
 672         this.watertype = CONTENT_EMPTY;
 673
 674         entity spawnevent = new_pure(spawnevent);
 675         spawnevent.owner = this;
 676         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 677
 678         // Cut off any still running player sounds.
 679         stopsound(this, CH_PLAYER_SINGLE);
 680
 681         this.model = "";
 682         FixPlayermodel(this);
 683         this.drawonlytoclient = NULL;
 684
 685         this.viewloc = NULL;
 686
 687         for(int slot = 0; slot < MAX_AXH; ++slot)
 688         {
 689                 entity axh = this.(AuxiliaryXhair[slot]);
 690                 this.(AuxiliaryXhair[slot]) = NULL;
 691
 692                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 693                         delete(axh);
 694         }
 695
 696         this.spawnpoint_targ = NULL;
 697
 698         UNSET_DUCKED(this);
 699         this.view_ofs = STAT(PL_VIEW_OFS, this);
 700         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 701         this.spawnorigin = spot.origin;
 702         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 703         // don't reset back to last position, even if new position is stuck in solid
 704         this.oldorigin = this.origin;
 705         if(this.conveyor)
 706                 IL_REMOVE(g_conveyed, this);
 707         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 708         if(this.swampslug)
 709                 IL_REMOVE(g_swamped, this);
 710         this.swampslug = NULL;
 711         this.swamp_interval = 0;
 712         if(this.ladder_entity)
 713                 IL_REMOVE(g_ladderents, this);
 714         this.ladder_entity = NULL;
 715         IL_EACH(g_counters, it.realowner == this,
 716         {
 717                 delete(it);
 718         });
 719         STAT(HUD, this) = HUD_NORMAL;
 720
 721         this.event_damage = PlayerDamage;
 722         this.event_heal = PlayerHeal;
 723
 724         this.draggable = func_null;
 725
 726         if(!this.bot_attack)
 727                 IL_PUSH(g_bot_targets, this);
 728         this.bot_attack = true;
 729         if(!this.monster_attack)
 730                 IL_PUSH(g_monster_targets, this);
 731         this.monster_attack = true;
 732         navigation_dynamicgoal_init(this, false);
 733
 734         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 735
 736         // player was spectator
 737         if (CS(this).killcount == FRAGS_SPECTATOR) {
 738                 PlayerScore_Clear(this);
 739                 CS(this).killcount = 0;
 740                 CS(this).startplaytime = time;
 741         }
 742
 743         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 CL_SpawnWeaponentity(this, weaponentity);
 747         }
 748         this.alpha = default_player_alpha;
 749         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 750         this.exteriorweaponentity.alpha = default_weapon_alpha;
 751
 752         this.speedrunning = false;
 753
 754         this.counter_cnt = 0;
 755         this.fragsfilter_cnt = 0;
 756
 757         target_voicescript_clear(this);
 758
 759         // reset fields the weapons may use
 760         FOREACH(Weapons, true, {
 761                 it.wr_resetplayer(it, this);
 762                         // reload all reloadable weapons
 763                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 764                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765                         {
 766                                 .entity weaponentity = weaponentities[slot];
 767                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 768                         }
 769                 }
 770         });
 771
 772         {
 773                 string s = spot.target;
 774                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 775                         spot.target = string_null;
 776                 SUB_UseTargets(spot, this, NULL);
 777                 if(g_assault || g_race)
 778                         spot.target = s;
 779         }
 780
 781         Unfreeze(this, false);
 782
 783         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 784
 785         if (autocvar_spawn_debug)
 786         {
 787                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 788                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 789         }
 790
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 entity w_ent = this.(weaponentity);
 795                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 796                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 797                 else
 798                         w_ent.m_switchweapon = WEP_Null;
 799                 w_ent.m_weapon = WEP_Null;
 800                 w_ent.weaponname = "";
 801                 w_ent.m_switchingweapon = WEP_Null;
 802                 w_ent.cnt = -1;
 803         }
 804
 805         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 806
 807         if (CS(this).impulse) ImpulseCommands(this);
 808
 809         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 810         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811         {
 812                 .entity weaponentity = weaponentities[slot];
 813                 W_WeaponFrame(this, weaponentity);
 814         }
 815
 816         if (!warmup_stage && !this.alivetime)
 817                 this.alivetime = time;
 818
 819         antilag_clear(this, CS(this));
 820 }
 821
 822 /** Called when a client spawns in the server */
 823 void PutClientInServer(entity this)
 824 {
 825         if (IS_BOT_CLIENT(this)) {
 826                 TRANSMUTE(Player, this);
 827         } else if (IS_REAL_CLIENT(this)) {
 828                 msg_entity = this;
 829                 WriteByte(MSG_ONE, SVC_SETVIEW);
 830                 WriteEntity(MSG_ONE, this);
 831         }
 832         if (game_stopped)
 833                 TRANSMUTE(Observer, this);
 834
 835         SetSpectatee(this, NULL);
 836
 837         // reset player keys
 838         if(PS(this))
 839                 PS(this).itemkeys = 0;
 840
 841         MUTATOR_CALLHOOK(PutClientInServer, this);
 842
 843         if (IS_OBSERVER(this)) {
 844                 PutObserverInServer(this);
 845         } else if (IS_PLAYER(this)) {
 846                 PutPlayerInServer(this);
 847         }
 848
 849         bot_relinkplayerlist();
 850 }
 851
 852 // TODO do we need all these fields, or should we stop autodetecting runtime
 853 // changes and just have a console command to update this?
 854 bool ClientInit_SendEntity(entity this, entity to, int sf)
 855 {
 856         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 857         return = true;
 858         msg_entity = to;
 859         // MSG_INIT replacement
 860         // TODO: make easier to use
 861         Registry_send_all();
 862         W_PROP_reload(MSG_ONE, to);
 863         ClientInit_misc(this);
 864         MUTATOR_CALLHOOK(Ent_Init);
 865 }
 866 void ClientInit_misc(entity this)
 867 {
 868         int channel = MSG_ONE;
 869         WriteHeader(channel, ENT_CLIENT_INIT);
 870         WriteByte(channel, g_nexball_meter_period * 32);
 871         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 872         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 873         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 874         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 875         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 876         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 877         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 878         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 879
 880         if(autocvar_sv_foginterval && world.fog != "")
 881                 WriteString(channel, world.fog);
 882         else
 883                 WriteString(channel, "");
 884         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 885         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 886         WriteByte(channel, serverflags);
 887         WriteCoord(channel, autocvar_g_trueaim_minrange);
 888
 889         // z411 send full hostname
 890         WriteString(channel, (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
 891 }
 892
 893 void ClientInit_CheckUpdate(entity this)
 894 {
 895         this.nextthink = time;
 896         if(this.count != autocvar_g_balance_armor_blockpercent)
 897         {
 898                 this.count = autocvar_g_balance_armor_blockpercent;
 899                 this.SendFlags |= 1;
 900         }
 901         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 902         {
 903                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 904                 this.SendFlags |= 1;
 905         }
 906 }
 907
 908 void ClientInit_Spawn()
 909 {
 910         entity e = new_pure(clientinit);
 911         setthink(e, ClientInit_CheckUpdate);
 912         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 913
 914         ClientInit_CheckUpdate(e);
 915 }
 916
 917 /*
 918 =============
 919 SetNewParms
 920 =============
 921 */
 922 void SetNewParms ()
 923 {
 924         // initialize parms for a new player
 925         parm1 = -(86400 * 366);
 926
 927         MUTATOR_CALLHOOK(SetNewParms);
 928 }
 929
 930 /*
 931 =============
 932 SetChangeParms
 933 =============
 934 */
 935 void SetChangeParms (entity this)
 936 {
 937         // save parms for level change
 938         parm1 = CS(this).parm_idlesince - time;
 939
 940         MUTATOR_CALLHOOK(SetChangeParms);
 941 }
 942
 943 /*
 944 =============
 945 DecodeLevelParms
 946 =============
 947 */
 948 void DecodeLevelParms(entity this)
 949 {
 950         // load parms
 951         CS(this).parm_idlesince = parm1;
 952         if (CS(this).parm_idlesince == -(86400 * 366))
 953                 CS(this).parm_idlesince = time;
 954
 955         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 956         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 957
 958         MUTATOR_CALLHOOK(DecodeLevelParms);
 959 }
 960
 961 void FixClientCvars(entity e)
 962 {
 963         // send prediction settings to the client
 964         stuffcmd(e, "\nin_bindmap 0 0\n");
 965         if(autocvar_g_antilag == 3) // client side hitscan
 966                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 967         if(autocvar_sv_gentle)
 968                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 969
 970         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 971         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 972
 973         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 974
 975         MUTATOR_CALLHOOK(FixClientCvars, e);
 976 }
 977
 978 bool findinlist_abbrev(string tofind, string list)
 979 {
 980         if(list == "" || tofind == "")
 981                 return false; // empty list or search, just return
 982
 983         // this function allows abbreviated strings!
 984         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 985         {
 986                 return true;
 987         });
 988
 989         return false;
 990 }
 991
 992 bool PlayerInIPList(entity p, string iplist)
 993 {
 994         // some safety checks (never allow local?)
 995         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 996                 return false;
 997
 998         return findinlist_abbrev(p.netaddress, iplist);
 999 }
1000
1001 bool PlayerInIDList(entity p, string idlist)
1002 {
1003         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1004         if(!p.crypto_idfp)
1005                 return false;
1006
1007         return findinlist_abbrev(p.crypto_idfp, idlist);
1008 }
1009
1010 bool PlayerInList(entity player, string list)
1011 {
1012         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1013 }
1014
1015 #ifdef DP_EXT_PRECONNECT
1016 /*
1017 =============
1018 ClientPreConnect
1019
1020 Called once (not at each match start) when a client begins a connection to the server
1021 =============
1022 */
1023 void ClientPreConnect(entity this)
1024 {
1025         if(autocvar_sv_eventlog)
1026         {
1027                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1028                         this.playerid,
1029                         etof(this),
1030                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1031                 ));
1032         }
1033 }
1034 #endif
1035
1036 string GetClientVersionMessage(entity this)
1037 {
1038         if (CS(this).version_mismatch) {
1039                 if(CS(this).version < autocvar_gameversion) {
1040                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1041                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1042                 } else {
1043                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1044                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1045                 }
1046         } else {
1047                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1048         }
1049 }
1050
1051 string getwelcomemessage(entity this)
1052 {
1053         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1054         string modifications = M_ARGV(0, string);
1055
1056         if(g_weaponarena)
1057         {
1058                 if(g_weaponarena_random)
1059                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1060                 else
1061                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1062         }
1063         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1064                 modifications = strcat(modifications, ", No start weapons");
1065         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1066                 modifications = strcat(modifications, ", Low gravity");
1067         if(g_weapon_stay && !g_cts)
1068                 modifications = strcat(modifications, ", Weapons stay");
1069         if(autocvar_g_jetpack)
1070                 modifications = strcat(modifications, ", Jet pack");
1071         if(autocvar_g_powerups == 0)
1072                 modifications = strcat(modifications, ", No powerups");
1073         if(autocvar_g_powerups > 0)
1074                 modifications = strcat(modifications, ", Powerups");
1075         modifications = substring(modifications, 2, strlen(modifications) - 2);
1076
1077         //string versionmessage = GetClientVersionMessage(this);
1078         //string s = strcat(versionmessage, "^8\n^9", (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname));
1079         string s = (autocvar_hostname_full ? autocvar_hostname_full : autocvar_hostname);
1080
1081         s = strcat(s, "^8\n^7", gamemode_name);
1082
1083         if(modifications != "")
1084                 s = strcat(s, "^7 | ^3", modifications);
1085
1086         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1087         {
1088                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1089                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1090         }
1091
1092         if (cache_mutatormsg != "") {
1093                 s = strcat(s, "\n^8tips: ^7", cache_mutatormsg);
1094         }
1095
1096         string mutator_msg = "";
1097         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1098         mutator_msg = M_ARGV(0, string);
1099
1100         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1101
1102         string motd = autocvar_sv_motd;
1103         if (motd != "") {
1104                 s = strcat(s, "\n\n^7", strreplace("\\n", "\n", motd));
1105         }
1106         return s;
1107 }
1108
1109 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1110
1111 /**
1112 =============
1113 ClientConnect
1114
1115 Called when a client connects to the server
1116 =============
1117 */
1118 void ClientConnect(entity this)
1119 {
1120         if (Ban_MaybeEnforceBanOnce(this)) return;
1121         assert(!IS_CLIENT(this), return);
1122         this.flags |= FL_CLIENT;
1123         assert(player_count >= 0, player_count = 0);
1124
1125         TRANSMUTE(Client, this);
1126         CS(this).version_nagtime = time + 10 + random() * 10;
1127
1128         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1129
1130         bot_clientconnect(this);
1131
1132         Player_DetermineForcedTeam(this);
1133
1134         TRANSMUTE(Observer, this);
1135
1136         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1137
1138         // always track bots, don't ask for cl_allow_uidtracking
1139         if (IS_BOT_CLIENT(this))
1140                 PlayerStats_GameReport_AddPlayer(this);
1141         else
1142                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1143
1144         if (autocvar_sv_eventlog)
1145                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1146
1147         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1148
1149         stuffcmd(this, clientstuff, "\n");
1150         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1151
1152         FixClientCvars(this);
1153
1154         // get version info from player
1155         stuffcmd(this, "cmd clientversion $gameversion\n");
1156
1157         // notify about available teams
1158         if (teamplay)
1159         {
1160                 entity balance = TeamBalance_CheckAllowedTeams(this);
1161                 int t = TeamBalance_GetAllowedTeams(balance);
1162                 TeamBalance_Destroy(balance);
1163                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1164         }
1165         else
1166         {
1167                 stuffcmd(this, "set _teams_available 0\n");
1168         }
1169
1170         bot_relinkplayerlist();
1171
1172         CS(this).spectatortime = time;
1173         if (blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         CS(this).jointime = time;
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (g_weaponarena_weapons == WEPSET(TUBA))
1183                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1184         }
1185
1186         if (!autocvar_sv_foginterval && world.fog != "")
1187                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1188
1189         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1190                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1191                         send_CSQC_teamnagger();
1192
1193         CSQCMODEL_AUTOINIT(this);
1194
1195         CS(this).model_randomizer = random();
1196
1197         if (IS_REAL_CLIENT(this))
1198                 sv_notice_join(this);
1199
1200         this.move_qcphysics = autocvar_sv_qcphysics;
1201
1202         // update physics stats (players can spawn before physics runs)
1203         Physics_UpdateStats(this);
1204
1205         IL_EACH(g_initforplayer, it.init_for_player, {
1206                 it.init_for_player(it, this);
1207         });
1208
1209         Handicap_Initialize(this);
1210
1211         MUTATOR_CALLHOOK(ClientConnect, this);
1212
1213         if (IS_REAL_CLIENT(this))
1214         {
1215                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1216                 {
1217                         CS(this).motd_actived_time = -1;
1218                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1219                 }
1220         }
1221 }
1222 /*
1223 =============
1224 ClientDisconnect
1225
1226 Called when a client disconnects from the server
1227 =============
1228 */
1229 .entity chatbubbleentity;
1230 void player_powerups_remove_all(entity this);
1231
1232 void ClientDisconnect(entity this)
1233 {
1234         assert(IS_CLIENT(this), return);
1235
1236         PlayerStats_GameReport_FinalizePlayer(this);
1237         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1238         if (CS(this).active_minigame) part_minigame(this);
1239         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1243
1244         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1245
1246         if(IS_SPEC(this))
1247                 SetSpectatee(this, NULL);
1248
1249         MUTATOR_CALLHOOK(ClientDisconnect, this);
1250
1251         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1252         strfree(CS_CVAR(this).weaponorder_byimpulse);
1253         ClientState_detach(this);
1254
1255         Portal_ClearAll(this);
1256
1257         Unfreeze(this, false);
1258
1259         RemoveGrapplingHooks(this);
1260
1261         // Here, everything has been done that requires this player to be a client.
1262
1263         this.flags &= ~FL_CLIENT;
1264
1265         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1266         if (this.killindicator) delete(this.killindicator);
1267
1268         IL_EACH(g_counters, it.realowner == this,
1269         {
1270                 delete(it);
1271         });
1272
1273         WaypointSprite_PlayerGone(this);
1274
1275         bot_relinkplayerlist();
1276
1277         strfree(this.clientstatus);
1278         if (this.personal) delete(this.personal);
1279
1280         this.playerid = 0;
1281         ReadyCount();
1282         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1283
1284         player_powerups_remove_all(this); // stop powerup sound
1285
1286         ONREMOVE(this);
1287 }
1288
1289 void ChatBubbleThink(entity this)
1290 {
1291         this.nextthink = time;
1292         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1293         {
1294                 if(this.owner) // but why can that ever be NULL?
1295                         this.owner.chatbubbleentity = NULL;
1296                 delete(this);
1297                 return;
1298         }
1299
1300         this.mdl = "";
1301
1302         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1303         {
1304                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1305                         this.mdl = "models/sprites/minigame_busy.iqm";
1306                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1307                         this.mdl = "models/misc/chatbubble.spr";
1308         }
1309
1310         if ( this.model != this.mdl )
1311                 _setmodel(this, this.mdl);
1312
1313 }
1314
1315 void UpdateChatBubble(entity this)
1316 {
1317         if (this.alpha < 0)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!this.chatbubbleentity)
1321         {
1322                 this.chatbubbleentity = new(chatbubbleentity);
1323                 this.chatbubbleentity.owner = this;
1324                 this.chatbubbleentity.exteriormodeltoclient = this;
1325                 setthink(this.chatbubbleentity, ChatBubbleThink);
1326                 this.chatbubbleentity.nextthink = time;
1327                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1328                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1329                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1330                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1331                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1332                 //this.chatbubbleentity.model = "";
1333                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337 void calculate_player_respawn_time(entity this)
1338 {
1339         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1340                 return;
1341
1342         float gametype_setting_tmp;
1343         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1344         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1345         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1346         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1347         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1348         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1349
1350         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1351         if (teamplay)
1352         {
1353                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1354                         if(it.team == this.team)
1355                                 ++pcount;
1356                 });
1357                 if (sdelay_small_count == 0)
1358                         sdelay_small_count = 1;
1359                 if (sdelay_large_count == 0)
1360                         sdelay_large_count = 1;
1361         }
1362         else
1363         {
1364                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1365                         ++pcount;
1366                 });
1367                 if (sdelay_small_count == 0)
1368                 {
1369                         if (IS_INDEPENDENT_PLAYER(this))
1370                         {
1371                                 // Players play independently. No point in requiring enemies.
1372                                 sdelay_small_count = 1;
1373                         }
1374                         else
1375                         {
1376                                 // Players play AGAINST each other. Enemies required.
1377                                 sdelay_small_count = 2;
1378                         }
1379                 }
1380                 if (sdelay_large_count == 0)
1381                 {
1382                         if (IS_INDEPENDENT_PLAYER(this))
1383                         {
1384                                 // Players play independently. No point in requiring enemies.
1385                                 sdelay_large_count = 1;
1386                         }
1387                         else
1388                         {
1389                                 // Players play AGAINST each other. Enemies required.
1390                                 sdelay_large_count = 2;
1391                         }
1392                 }
1393         }
1394
1395         float sdelay;
1396
1397         if (pcount <= sdelay_small_count)
1398                 sdelay = sdelay_small;
1399         else if (pcount >= sdelay_large_count)
1400                 sdelay = sdelay_large;
1401         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1402                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1403
1404         if(waves)
1405                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1406         else
1407                 this.respawn_time = time + sdelay;
1408
1409         if(sdelay < sdelay_max)
1410                 this.respawn_time_max = time + sdelay_max;
1411         else
1412                 this.respawn_time_max = this.respawn_time;
1413
1414         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1415                 this.respawn_countdown = 10; // first number to count down from is 10
1416         else
1417                 this.respawn_countdown = -1; // do not count down
1418
1419         if(autocvar_g_forced_respawn)
1420                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1421 }
1422
1423 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1424 // added to the model skins
1425 /*void UpdateColorModHack()
1426 {
1427         float c;
1428         c = this.clientcolors & 15;
1429         // LordHavoc: only bothering to support white, green, red, yellow, blue
1430              if (!teamplay) this.colormod = '0 0 0';
1431         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1432         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1433         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1434         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1435         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1436         else this.colormod = '1 1 1';
1437 }*/
1438
1439 void respawn(entity this)
1440 {
1441         bool damagedbycontents_prev = this.damagedbycontents;
1442         if(this.alpha >= 0)
1443         {
1444                 if(autocvar_g_respawn_ghosts)
1445                 {
1446                         this.solid = SOLID_NOT;
1447                         this.takedamage = DAMAGE_NO;
1448                         this.damagedbycontents = false;
1449                         set_movetype(this, MOVETYPE_FLY);
1450                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1451                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1452                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1453                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1454                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1455                         if(autocvar_g_respawn_ghosts_time > 0)
1456                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1457                 }
1458                 else
1459                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1460         }
1461
1462         CopyBody(this, 1);
1463         this.damagedbycontents = damagedbycontents_prev;
1464
1465         this.effects |= EF_NODRAW; // prevent another CopyBody
1466         PutClientInServer(this);
1467 }
1468
1469 void play_countdown(entity this, float finished, Sound samp)
1470 {
1471         TC(Sound, samp);
1472         if(IS_REAL_CLIENT(this))
1473                 if(floor(finished - time - frametime) != floor(finished - time))
1474                         if(finished - time < 6)
1475                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1476 }
1477
1478 void player_powerups_remove_all(entity this)
1479 {
1480         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1481         {
1482                 // don't play the poweroff sound when the game restarts or the player disconnects
1483                 if (time > game_starttime + 1 && IS_CLIENT(this))
1484                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1485                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1486                 this.items &= ~ITEM_Strength.m_itemid;
1487                 this.items &= ~ITEM_Shield.m_itemid;
1488                 this.items -= (this.items & IT_SUPERWEAPON);
1489         }
1490 }
1491
1492 void player_powerups(entity this)
1493 {
1494         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1495                 this.modelflags |= MF_ROCKET;
1496         else
1497                 this.modelflags &= ~MF_ROCKET;
1498
1499         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1500
1501         if (IS_DEAD(this))
1502                 player_powerups_remove_all(this);
1503
1504         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1505                 return;
1506
1507         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1508         int items_prev = this.items;
1509
1510         Fire_ApplyDamage(this);
1511         Fire_ApplyEffect(this);
1512
1513         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1514         {
1515                 if (this.items & ITEM_Strength.m_itemid)
1516                 {
1517                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1518                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1519                         if (time > STAT(STRENGTH_FINISHED, this))
1520                         {
1521                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1522                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1524                         }
1525                 }
1526                 else
1527                 {
1528                         if (time < STAT(STRENGTH_FINISHED, this))
1529                         {
1530                                 this.items = this.items | ITEM_Strength.m_itemid;
1531                                 if(!g_cts)
1532                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1533                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1534                         }
1535                 }
1536                 if (this.items & ITEM_Shield.m_itemid)
1537                 {
1538                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1539                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1540                         if (time > STAT(INVINCIBLE_FINISHED, this))
1541                         {
1542                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1543                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1544                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1545                         }
1546                 }
1547                 else
1548                 {
1549                         if (time < STAT(INVINCIBLE_FINISHED, this))
1550                         {
1551                                 this.items = this.items | ITEM_Shield.m_itemid;
1552                                 if(!g_cts)
1553                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1554                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1555                         }
1556                 }
1557                 if (this.items & IT_SUPERWEAPON)
1558                 {
1559                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1560                         {
1561                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1562                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1563                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1564                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1565                         }
1566                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1567                         {
1568                                 // don't let them run out
1569                         }
1570                         else
1571                         {
1572                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1573                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1574                                 {
1575                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1576                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1577                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1578                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1579                                 }
1580                         }
1581                 }
1582                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1583                 {
1584                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1585                         {
1586                                 this.items = this.items | IT_SUPERWEAPON;
1587                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1588                                 {
1589                                         if(!g_cts)
1590                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1591                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1592                                 }
1593                         }
1594                         else
1595                         {
1596                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1597                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1598                         }
1599                 }
1600                 else
1601                 {
1602                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1603                 }
1604         }
1605
1606         if(autocvar_g_nodepthtestplayers)
1607                 this.effects = this.effects | EF_NODEPTHTEST;
1608
1609         if(autocvar_g_fullbrightplayers)
1610                 this.effects = this.effects | EF_FULLBRIGHT;
1611
1612         if (time >= game_starttime)
1613         if (time < this.spawnshieldtime)
1614                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1615
1616         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1617 }
1618
1619 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1620 {
1621         if(current > stable)
1622                 return current;
1623         else if(current > stable - 0.25) // when close enough, "snap"
1624                 return stable;
1625         else
1626                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1627 }
1628
1629 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1630 {
1631         if(current < stable)
1632                 return current;
1633         else if(current < stable + 0.25) // when close enough, "snap"
1634                 return stable;
1635         else
1636                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1637 }
1638
1639 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1640 {
1641         float old = GetResource(this, res);
1642         float current = old;
1643         if(current > rotstable)
1644         {
1645                 if(rotframetime > 0)
1646                 {
1647                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1648                         current = max(rotstable, current - rotlinear * rotframetime);
1649                 }
1650         }
1651         else if(current < regenstable)
1652         {
1653                 if(regenframetime > 0)
1654                 {
1655                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1656                         current = min(regenstable, current + regenlinear * regenframetime);
1657                 }
1658         }
1659
1660         float limit = GetResourceLimit(this, res) * limit_mod;
1661         if(current > limit)
1662                 current = limit;
1663
1664         if (current != old)
1665                 SetResource(this, res, current);
1666 }
1667
1668 void player_regen(entity this)
1669 {
1670         float max_mod, regen_mod, rot_mod, limit_mod;
1671         max_mod = regen_mod = rot_mod = limit_mod = 1;
1672
1673         float regen_health = autocvar_g_balance_health_regen;
1674         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1675         float regen_health_rot = autocvar_g_balance_health_rot;
1676         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1677         float regen_health_stable = autocvar_g_balance_health_regenstable;
1678         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1679         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1680                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1681         max_mod = M_ARGV(1, float);
1682         regen_mod = M_ARGV(2, float);
1683         rot_mod = M_ARGV(3, float);
1684         limit_mod = M_ARGV(4, float);
1685         regen_health = M_ARGV(5, float);
1686         regen_health_linear = M_ARGV(6, float);
1687         regen_health_rot = M_ARGV(7, float);
1688         regen_health_rotlinear = M_ARGV(8, float);
1689         regen_health_stable = M_ARGV(9, float);
1690         regen_health_rotstable = M_ARGV(10, float);
1691
1692         if(!mutator_returnvalue)
1693         if(!STAT(FROZEN, this))
1694         {
1695                 float maxa = autocvar_g_balance_armor_rotstable;
1696                 float mina = autocvar_g_balance_armor_regenstable;
1697
1698                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1699                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1700                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1701
1702                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1703                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1704                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1705         }
1706
1707         // if player rotted to death...  die!
1708         // check this outside above checks, as player may still be able to rot to death
1709         if(GetResource(this, RES_HEALTH) < 1)
1710         {
1711                 if(this.vehicle)
1712                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1713                 if(this.event_damage)
1714                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1715         }
1716
1717         if (!(this.items & IT_UNLIMITED_AMMO))
1718         {
1719                 float maxf = autocvar_g_balance_fuel_rotstable;
1720                 float minf = autocvar_g_balance_fuel_regenstable;
1721
1722                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1723                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1724                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1725         }
1726 }
1727
1728 bool zoomstate_set;
1729 void SetZoomState(entity this, float newzoom)
1730 {
1731         if(newzoom != CS(this).zoomstate)
1732         {
1733                 CS(this).zoomstate = newzoom;
1734                 ClientData_Touch(this);
1735         }
1736         zoomstate_set = true;
1737 }
1738
1739 void GetPressedKeys(entity this)
1740 {
1741         MUTATOR_CALLHOOK(GetPressedKeys, this);
1742         if (game_stopped)
1743         {
1744                 CS(this).pressedkeys = 0;
1745                 STAT(PRESSED_KEYS, this) = 0;
1746                 return;
1747         }
1748
1749         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1750         int keys = STAT(PRESSED_KEYS, this);
1751         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1752         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1753         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1754         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1755
1756         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1757         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1758         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1759         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1760         CS(this).pressedkeys = keys; // store for other users
1761
1762         STAT(PRESSED_KEYS, this) = keys;
1763 }
1764
1765 /*
1766 ======================
1767 spectate mode routines
1768 ======================
1769 */
1770
1771 void SpectateCopy(entity this, entity spectatee)
1772 {
1773         TC(Client, this); TC(Client, spectatee);
1774
1775         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1776         PS(this) = PS(spectatee);
1777         this.armortype = spectatee.armortype;
1778         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1779         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1780         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1781         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1782         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1783         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1784         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1785         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1786         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1787         CS(this).impulse = 0;
1788         this.disableclientprediction = 1; // no need to run prediction on a spectator
1789         this.items = spectatee.items;
1790         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1791         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1792         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1793         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1794         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1795         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1796         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1797         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1798         this.punchangle = spectatee.punchangle;
1799         this.view_ofs = spectatee.view_ofs;
1800         this.velocity = spectatee.velocity;
1801         this.dmg_take = spectatee.dmg_take;
1802         this.dmg_save = spectatee.dmg_save;
1803         this.dmg_inflictor = spectatee.dmg_inflictor;
1804         this.v_angle = spectatee.v_angle;
1805         this.angles = spectatee.v_angle;
1806         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1807         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1808         this.viewloc = spectatee.viewloc;
1809         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1810                 this.fixangle = true;
1811         setorigin(this, spectatee.origin);
1812         setsize(this, spectatee.mins, spectatee.maxs);
1813         SetZoomState(this, CS(spectatee).zoomstate);
1814
1815     anticheat_spectatecopy(this, spectatee);
1816         STAT(HUD, this) = STAT(HUD, spectatee);
1817         if(spectatee.vehicle)
1818     {
1819         this.angles = spectatee.v_angle;
1820
1821         //this.fixangle = false;
1822         //this.velocity = spectatee.vehicle.velocity;
1823         this.vehicle_health = spectatee.vehicle_health;
1824         this.vehicle_shield = spectatee.vehicle_shield;
1825         this.vehicle_energy = spectatee.vehicle_energy;
1826         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1827         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1828         this.vehicle_reload1 = spectatee.vehicle_reload1;
1829         this.vehicle_reload2 = spectatee.vehicle_reload2;
1830
1831         //msg_entity = this;
1832
1833        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1834             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1835            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1836            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1837
1838         //WriteByte (MSG_ONE, SVC_SETVIEW);
1839         //    WriteEntity(MSG_ONE, this);
1840         //makevectors(spectatee.v_angle);
1841         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1842     }
1843 }
1844
1845 bool SpectateUpdate(entity this)
1846 {
1847         if(!this.enemy)
1848                 return false;
1849
1850         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1851         {
1852                 SetSpectatee(this, NULL);
1853                 return false;
1854         }
1855
1856         SpectateCopy(this, this.enemy);
1857
1858         return true;
1859 }
1860
1861 bool SpectateSet(entity this)
1862 {
1863         if(!IS_PLAYER(this.enemy))
1864                 return false;
1865
1866         ClientData_Touch(this.enemy);
1867
1868         msg_entity = this;
1869         WriteByte(MSG_ONE, SVC_SETVIEW);
1870         WriteEntity(MSG_ONE, this.enemy);
1871         set_movetype(this, MOVETYPE_NONE);
1872         accuracy_resend(this);
1873
1874         if(!SpectateUpdate(this))
1875                 PutObserverInServer(this);
1876
1877         return true;
1878 }
1879
1880 void SetSpectatee_status(entity this, int spectatee_num)
1881 {
1882         int oldspectatee_status = CS(this).spectatee_status;
1883         CS(this).spectatee_status = spectatee_num;
1884
1885         if (CS(this).spectatee_status != oldspectatee_status)
1886         {
1887                 if (STAT(PRESSED_KEYS, this))
1888                 {
1889                         CS(this).pressedkeys = 0;
1890                         STAT(PRESSED_KEYS, this) = 0;
1891                 }
1892                 ClientData_Touch(this);
1893                 if (g_race || g_cts) race_InitSpectator();
1894         }
1895 }
1896
1897 void SetSpectatee(entity this, entity spectatee)
1898 {
1899         if(IS_BOT_CLIENT(this))
1900                 return; // bots abuse .enemy, this code is useless to them
1901
1902         entity old_spectatee = this.enemy;
1903
1904         this.enemy = spectatee;
1905
1906         // WEAPONTODO
1907         // these are required to fix the spectator bug with arc
1908         if(old_spectatee)
1909         {
1910                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1911                 {
1912                         .entity weaponentity = weaponentities[slot];
1913                         if(old_spectatee.(weaponentity).arc_beam)
1914                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1915                 }
1916         }
1917         if(this.enemy)
1918         {
1919                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1920                 {
1921                         .entity weaponentity = weaponentities[slot];
1922                         if(this.enemy.(weaponentity).arc_beam)
1923                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1924                 }
1925         }
1926
1927         if (this.enemy)
1928                 SetSpectatee_status(this, etof(this.enemy));
1929
1930         // needed to update spectator list
1931         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1932 }
1933
1934 bool Spectate(entity this, entity pl)
1935 {
1936         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1937                 return false;
1938         pl = M_ARGV(1, entity);
1939
1940         SetSpectatee(this, pl);
1941         return SpectateSet(this);
1942 }
1943
1944 bool SpectateNext(entity this)
1945 {
1946         entity ent = find(this.enemy, classname, STR_PLAYER);
1947
1948         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1949                 ent = M_ARGV(1, entity);
1950         else if (!ent)
1951                 ent = find(ent, classname, STR_PLAYER);
1952
1953         if(ent) { SetSpectatee(this, ent); }
1954
1955         return SpectateSet(this);
1956 }
1957
1958 bool SpectatePrev(entity this)
1959 {
1960         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1961         entity ent = findchain(classname, STR_PLAYER);
1962         if (!ent) // no player
1963                 return false;
1964
1965         entity first = ent;
1966         // skip players until current spectated player
1967         if(this.enemy)
1968         while(ent && ent != this.enemy)
1969                 ent = ent.chain;
1970
1971         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1972         {
1973                 case MUT_SPECPREV_FOUND:
1974                         ent = M_ARGV(1, entity);
1975                         break;
1976                 case MUT_SPECPREV_RETURN:
1977                         return true;
1978                 case MUT_SPECPREV_CONTINUE:
1979                 default:
1980                 {
1981                         if(ent.chain)
1982                                 ent = ent.chain;
1983                         else
1984                                 ent = first;
1985                         break;
1986                 }
1987         }
1988
1989         SetSpectatee(this, ent);
1990         return SpectateSet(this);
1991 }
1992
1993 /*
1994 =============
1995 ShowRespawnCountdown()
1996
1997 Update a respawn countdown display.
1998 =============
1999 */
2000 void ShowRespawnCountdown(entity this)
2001 {
2002         float number;
2003         if(!IS_DEAD(this)) // just respawned?
2004                 return;
2005         else
2006         {
2007                 number = ceil(this.respawn_time - time);
2008                 if(number <= 0)
2009                         return;
2010                 if(number <= this.respawn_countdown)
2011                 {
2012                         this.respawn_countdown = number - 1;
2013                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2014                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2015                 }
2016         }
2017 }
2018
2019 .bool team_selected;
2020 bool ShowTeamSelection(entity this)
2021 {
2022         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2023                 return false;
2024         stuffcmd(this, "menu_showteamselect\n");
2025         return true;
2026 }
2027 void Join(entity this)
2028 {
2029         TRANSMUTE(Player, this);
2030
2031         if(!this.team_selected)
2032         if(autocvar_g_campaign || autocvar_g_balance_teams)
2033                 TeamBalance_JoinBestTeam(this);
2034
2035         if(autocvar_g_campaign)
2036                 campaign_bots_may_start = true;
2037
2038         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2039
2040         PutClientInServer(this);
2041
2042         if(IS_PLAYER(this))
2043         if(teamplay && this.team != -1)
2044         {
2045         }
2046         else
2047                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2048         this.team_selected = false;
2049
2050         // z411
2051         // send constant ready notification
2052         if(warmup_stage)
2053                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MISSING_READY);
2054 }
2055
2056 int GetPlayerLimit()
2057 {
2058         if(g_duel)
2059                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2060         int player_limit = autocvar_g_maxplayers;
2061         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2062         player_limit = M_ARGV(0, int);
2063         return player_limit;
2064 }
2065
2066 /**
2067  * Determines whether the player is allowed to join. This depends on cvar
2068  * g_maxplayers, if it isn't used this function always return true, otherwise
2069  * it checks whether the number of currently playing players exceeds g_maxplayers.
2070  * @return int number of free slots for players, 0 if none
2071  */
2072 int nJoinAllowed(entity this, entity ignore)
2073 {
2074         if(!ignore)
2075         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2076         // so report 0 free slots if restricted
2077         {
2078                 if(autocvar_g_forced_team_otherwise == "spectate")
2079                         return 0;
2080                 if(autocvar_g_forced_team_otherwise == "spectator")
2081                         return 0;
2082         }
2083
2084         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2085                 return 0; // forced spectators can never join
2086
2087         // TODO simplify this
2088         int totalClients = 0;
2089         int currentlyPlaying = 0;
2090         FOREACH_CLIENT(true, {
2091                 if(it != ignore)
2092                         ++totalClients;
2093                 if(IS_REAL_CLIENT(it))
2094                 if(IS_PLAYER(it) || it.caplayer)
2095                         ++currentlyPlaying;
2096         });
2097
2098         int player_limit = GetPlayerLimit();
2099
2100         int free_slots = 0;
2101         if (!player_limit)
2102                 free_slots = maxclients - totalClients;
2103         else if(player_limit > 0 && currentlyPlaying < player_limit)
2104                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2105
2106         static float msg_time = 0;
2107         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2108         {
2109                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2110                 msg_time = time + 0.5;
2111         }
2112
2113         return free_slots;
2114 }
2115
2116 /**
2117  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2118  * g_maxplayers_spectator_blocktime seconds
2119  */
2120 void checkSpectatorBlock(entity this)
2121 {
2122         if(IS_SPEC(this) || IS_OBSERVER(this))
2123         if(!this.caplayer)
2124         if(IS_REAL_CLIENT(this))
2125         {
2126                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2127                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2128                         dropclient(this);
2129                 }
2130         }
2131 }
2132
2133 void PrintWelcomeMessage(entity this)
2134 {
2135         if(CS(this).motd_actived_time == 0)
2136         {
2137                 if (autocvar_g_campaign) {
2138                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2139                                 CS(this).motd_actived_time = time;
2140                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2141                         }
2142                 } else {
2143                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2144                                 CS(this).motd_actived_time = time;
2145                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2146                         }
2147                 }
2148         }
2149         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2150         {
2151                 if (autocvar_g_campaign) {
2152                         if (PHYS_INPUT_BUTTON_INFO(this))
2153                                 CS(this).motd_actived_time = time;
2154                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2155                                 CS(this).motd_actived_time = 0;
2156                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2157                         }
2158                 } else {
2159                         if (PHYS_INPUT_BUTTON_INFO(this))
2160                                 CS(this).motd_actived_time = time;
2161                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2162                                 CS(this).motd_actived_time = 0;
2163                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2164                         }
2165                 }
2166         }
2167         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2168         {
2169                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2170                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2171                 else if (CS(this).motd_actived_time == -2)
2172                 {
2173                         // instantly hide MOTD
2174                         CS(this).motd_actived_time = 0;
2175                         if (autocvar_g_campaign)
2176                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2177                         else
2178                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2179                 }
2180                 else if (IS_PLAYER(this) || IS_SPEC(this))
2181                 {
2182                         // FIXME occasionally for some reason MOTD never goes away
2183                         // delay MOTD removal a little bit in the hope it fixes this bug
2184                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2185                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2186                         else //if (CS(this).motd_actived_time < -2)
2187                                 CS(this).motd_actived_time++;
2188                 }
2189         }
2190 }
2191
2192 bool joinAllowed(entity this)
2193 {
2194         if (CS(this).version_mismatch) return false;
2195         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2196         if (!nJoinAllowed(this, this)) return false;
2197         if (teamplay && lockteams) return false;
2198         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2199         if (ShowTeamSelection(this)) return false;
2200         return true;
2201 }
2202
2203 .string shootfromfixedorigin;
2204 .bool dualwielding_prev;
2205 bool PlayerThink(entity this)
2206 {
2207         if (game_stopped || intermission_running) {
2208                 this.modelflags &= ~MF_ROCKET;
2209                 if(intermission_running)
2210                         IntermissionThink(this);
2211                 return false;
2212         }
2213
2214         if (game_timeout) {
2215         // don't allow the player to turn around while game is paused
2216                 // FIXME turn this into CSQC stuff
2217                 this.v_angle = this.lastV_angle;
2218                 this.angles = this.lastV_angle;
2219                 this.fixangle = true;
2220                 return false;
2221         }
2222
2223         if (frametime) player_powerups(this);
2224
2225         if (IS_DEAD(this)) {
2226                 if (this.personal && g_race_qualifying) {
2227                         if (time > this.respawn_time) {
2228                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2229                                 respawn(this);
2230                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2231                         }
2232                 } else {
2233                         if (frametime) player_anim(this);
2234
2235                         if (this.respawn_flags & RESPAWN_DENY)
2236                         {
2237                                 STAT(RESPAWN_TIME, this) = 0;
2238                                 return false;
2239                         }
2240
2241                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2242
2243                         switch(this.deadflag)
2244                         {
2245                                 case DEAD_DYING:
2246                                 {
2247                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2248                                                 this.deadflag = DEAD_RESPAWNING;
2249                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2250                                                 this.deadflag = DEAD_DEAD;
2251                                         break;
2252                                 }
2253                                 case DEAD_DEAD:
2254                                 {
2255                                         if (button_pressed)
2256                                                 this.deadflag = DEAD_RESPAWNABLE;
2257                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2258                                                 this.deadflag = DEAD_RESPAWNING;
2259                                         break;
2260                                 }
2261                                 case DEAD_RESPAWNABLE:
2262                                 {
2263                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2264                                                 this.deadflag = DEAD_RESPAWNING;
2265                                         break;
2266                                 }
2267                                 case DEAD_RESPAWNING:
2268                                 {
2269                                         if (time > this.respawn_time)
2270                                         {
2271                                                 this.respawn_time = time + 1; // only retry once a second
2272                                                 this.respawn_time_max = this.respawn_time;
2273                                                 respawn(this);
2274                                         }
2275                                         break;
2276                                 }
2277                         }
2278
2279                         ShowRespawnCountdown(this);
2280
2281                         if (this.respawn_flags & RESPAWN_SILENT)
2282                                 STAT(RESPAWN_TIME, this) = 0;
2283                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2284                         {
2285                                 if (time < this.respawn_time)
2286                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2287                                 else if (this.deadflag != DEAD_RESPAWNING)
2288                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2289                         }
2290                         else
2291                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2292                 }
2293
2294                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2295                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2296                         STAT(RESPAWN_TIME, this) *= -1;
2297
2298                 return false;
2299         }
2300
2301         FixPlayermodel(this);
2302
2303         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2304                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2305                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2306         }
2307
2308         // reset gun alignment when dual wielding status changes
2309         // to ensure guns are always aligned right and left
2310         bool dualwielding = W_DualWielding(this);
2311         if(this.dualwielding_prev != dualwielding)
2312         {
2313                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2314                 this.dualwielding_prev = dualwielding;
2315         }
2316
2317         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2318         //if(frametime)
2319         {
2320                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2321                 {
2322                         .entity weaponentity = weaponentities[slot];
2323                         if(WEP_CVAR(vortex, charge_always))
2324                                 W_Vortex_Charge(this, weaponentity, frametime);
2325                         W_WeaponFrame(this, weaponentity);
2326                 }
2327         }
2328
2329         if (frametime)
2330         {
2331                 // WEAPONTODO: Add a weapon request for this
2332                 // rot vortex charge to the charge limit
2333                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2334                 {
2335                         .entity weaponentity = weaponentities[slot];
2336                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2337                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2338                 }
2339
2340                 player_regen(this);
2341                 player_anim(this);
2342                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2343         }
2344
2345         monsters_setstatus(this);
2346
2347         return true;
2348 }
2349
2350 .bool would_spectate;
2351 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2352 void ObserverOrSpectatorThink(entity this)
2353 {
2354         bool is_spec = IS_SPEC(this);
2355         if ( CS(this).impulse )
2356         {
2357                 int r = MinigameImpulse(this, CS(this).impulse);
2358                 if (!is_spec || r)
2359                         CS(this).impulse = 0;
2360
2361                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2362                 {
2363                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2364                         CS(this).impulse = 0;
2365                         return;
2366                 }
2367         }
2368
2369         if (this.flags & FL_JUMPRELEASED) {
2370                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2371                         this.flags &= ~FL_JUMPRELEASED;
2372                         this.flags |= FL_SPAWNING;
2373                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2374                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2375                         this.flags &= ~FL_JUMPRELEASED;
2376                         if(SpectateNext(this)) {
2377                                 TRANSMUTE(Spectator, this);
2378                         } else if (is_spec) {
2379                                 TRANSMUTE(Observer, this);
2380                                 PutClientInServer(this);
2381                         }
2382                         else
2383                                 this.would_spectate = false; // unable to spectate anyone
2384                         if (is_spec)
2385                                 CS(this).impulse = 0;
2386                 } else if (is_spec) {
2387                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2388                                 this.flags &= ~FL_JUMPRELEASED;
2389                                 if(SpectatePrev(this)) {
2390                                         TRANSMUTE(Spectator, this);
2391                                 } else {
2392                                         TRANSMUTE(Observer, this);
2393                                         PutClientInServer(this);
2394                                 }
2395                                 CS(this).impulse = 0;
2396                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2397                                 this.would_spectate = false;
2398                                 this.flags &= ~FL_JUMPRELEASED;
2399                                 TRANSMUTE(Observer, this);
2400                                 PutClientInServer(this);
2401                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2402                                 PutObserverInServer(this);
2403                                 this.would_spectate = true;
2404                         }
2405                 }
2406                 else {
2407                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2408                         if (PHYS_INPUT_BUTTON_USE(this))
2409                                 wouldclip = !wouldclip;
2410                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2411                         set_movetype(this, preferred_movetype);
2412                 }
2413         } else { // jump pressed
2414                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2415                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2416                         this.flags |= FL_JUMPRELEASED;
2417                         if(this.flags & FL_SPAWNING)
2418                         {
2419                                 this.flags &= ~FL_SPAWNING;
2420                                 if(joinAllowed(this))
2421                                         Join(this);
2422                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2423                                         CS(this).autojoin_checked = -1;
2424                                 return;
2425                         }
2426                 }
2427                 if(is_spec && !SpectateUpdate(this))
2428                         PutObserverInServer(this);
2429         }
2430         if (is_spec)
2431                 this.flags |= FL_CLIENT | FL_NOTARGET;
2432 }
2433
2434 void PlayerUseKey(entity this)
2435 {
2436         if (!IS_PLAYER(this))
2437                 return;
2438
2439         if(this.vehicle)
2440         {
2441                 if(!game_stopped)
2442                 {
2443                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2444                         return;
2445                 }
2446         }
2447         else if(autocvar_g_vehicles_enter)
2448         {
2449                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2450                 {
2451                         entity head, closest_target = NULL;
2452                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2453
2454                         while(head) // find the closest acceptable target to enter
2455                         {
2456                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2457                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2458                                 {
2459                                         if(closest_target)
2460                                         {
2461                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2462                                                 { closest_target = head; }
2463                                         }
2464                                         else { closest_target = head; }
2465                                 }
2466
2467                                 head = head.chain;
2468                         }
2469
2470                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2471                 }
2472         }
2473
2474         // a use key was pressed; call handlers
2475         MUTATOR_CALLHOOK(PlayerUseKey, this);
2476 }
2477
2478
2479 /*
2480 =============
2481 PlayerPreThink
2482
2483 Called every frame for each client before the physics are run
2484 =============
2485 */
2486 .float last_vehiclecheck;
2487 void PlayerPreThink (entity this)
2488 {
2489         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2490         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2491
2492         WarpZone_PlayerPhysics_FixVAngle(this);
2493
2494         if (frametime) {
2495                 // physics frames: update anticheat stuff
2496                 anticheat_prethink(this);
2497         }
2498
2499         if (blockSpectators && frametime) {
2500                 // WORKAROUND: only use dropclient in server frames (frametime set).
2501                 // Never use it in cl_movement frames (frametime zero).
2502                 checkSpectatorBlock(this);
2503         }
2504
2505         zoomstate_set = false;
2506
2507         // Check for nameless players
2508         if (this.netname == "" || this.netname != CS(this).netname_previous)
2509         {
2510                 bool assume_unchanged = (CS(this).netname_previous == "");
2511                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2512                 {
2513                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2514                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2515                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2516                         assume_unchanged = false;
2517                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2518                 }
2519                 if (isInvisibleString(this.netname))
2520                 {
2521                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2522                         sprint(this, "Warning: invisible names are not allowed.\n");
2523                         assume_unchanged = false;
2524                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2525                 }
2526                 if (!assume_unchanged && autocvar_sv_eventlog)
2527                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2528                 strcpy(CS(this).netname_previous, this.netname);
2529         }
2530
2531         // version nagging
2532         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2533         CS(this).version_nagtime = 0;
2534         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2535             // git client
2536         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2537             // git server
2538             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2539         } else {
2540             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2541             if (r < 0) { // old client
2542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2543             } else if (r > 0) { // old server
2544                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2545             }
2546         }
2547     }
2548
2549         // GOD MODE info
2550         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2551         {
2552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2553                 this.max_armorvalue = 0;
2554         }
2555
2556         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2557         {
2558                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2559                 {
2560                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2561                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2562                         if (this.iceblock)
2563                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2564
2565                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2566                                 Unfreeze(this, false);
2567                 }
2568                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2569                 {
2570                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2571                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2572
2573                         if (GetResource(this, RES_HEALTH) < 1)
2574                         {
2575                                 if (this.vehicle)
2576                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2577                                 if(this.event_damage)
2578                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2579                         }
2580                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2581                                 Unfreeze(this, false);
2582                 }
2583         }
2584
2585         MUTATOR_CALLHOOK(PlayerPreThink, this);
2586
2587         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2588         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2589         {
2590                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2591                 {
2592                         if(!it.owner)
2593                         {
2594                                 if(!it.team || SAME_TEAM(this, it))
2595                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2596                                 else if(autocvar_g_vehicles_steal)
2597                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2598                         }
2599                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2600                         {
2601                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2602                         }
2603                 });
2604
2605                 this.last_vehiclecheck = time + 1;
2606         }
2607
2608         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2609         {
2610                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2611                         PlayerUseKey(this);
2612                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2613         }
2614
2615         if (IS_REAL_CLIENT(this))
2616                 PrintWelcomeMessage(this);
2617
2618         if (IS_PLAYER(this)) {
2619                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2620                         error("Client can't be spawned as player on connection!");
2621                 if(!PlayerThink(this))
2622                         return;
2623         }
2624         else if (game_stopped || intermission_running) {
2625                 if(intermission_running)
2626                         IntermissionThink(this);
2627                 return;
2628         }
2629         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2630         {
2631                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2632                 CS(this).autojoin_checked = 1;
2633                 // don't do this in ClientConnect
2634                 // many things can go wrong if a client is spawned as player on connection
2635                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2636                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2637                                 && (!teamplay || autocvar_g_balance_teams)))
2638                 {
2639                         campaign_bots_may_start = true;
2640                         if(joinAllowed(this))
2641                                 Join(this);
2642                         return;
2643                 }
2644         }
2645         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2646                 ObserverOrSpectatorThink(this);
2647         }
2648
2649         // WEAPONTODO: Add weapon request for this
2650         if (!zoomstate_set) {
2651                 bool wep_zoomed = false;
2652                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2653                 {
2654                         .entity weaponentity = weaponentities[slot];
2655                         Weapon thiswep = this.(weaponentity).m_weapon;
2656                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2657                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2658                 }
2659                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2660         }
2661
2662         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2663         {
2664                 CS(this).teamkill_soundtime = 0;
2665
2666                 entity e = CS(this).teamkill_soundsource;
2667                 entity oldpusher = e.pusher;
2668                 e.pusher = this;
2669                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2670                 e.pusher = oldpusher;
2671         }
2672
2673         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2674                 CS(this).taunt_soundtime = 0;
2675                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2676         }
2677
2678         target_voicescript_next(this);
2679 }
2680
2681 void DrownPlayer(entity this)
2682 {
2683         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2684                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2685         {
2686                 STAT(AIR_FINISHED, this) = 0;
2687                 return;
2688         }
2689
2690         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2691         {
2692                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2693                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2694                 STAT(AIR_FINISHED, this) = 0;
2695         }
2696         else
2697         {
2698                 if (!STAT(AIR_FINISHED, this))
2699                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2700                 if (STAT(AIR_FINISHED, this) < time)
2701                 {       // drown!
2702                         if (this.pain_finished < time)
2703                         {
2704                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2705                                 this.pain_finished = time + 0.5;
2706                         }
2707                 }
2708         }
2709 }
2710
2711 .bool move_qcphysics;
2712
2713 void Player_Physics(entity this)
2714 {
2715         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2716
2717         if(!this.move_qcphysics)
2718                 return;
2719
2720         if(!frametime && !CS(this).pm_frametime)
2721                 return;
2722
2723         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2724
2725         CS(this).pm_frametime = 0;
2726 }
2727
2728 /*
2729 =============
2730 PlayerPostThink
2731
2732 Called every frame for each client after the physics are run
2733 =============
2734 */
2735 void PlayerPostThink (entity this)
2736 {
2737         Player_Physics(this);
2738
2739         if (autocvar_sv_maxidle > 0)
2740         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2741         if (IS_REAL_CLIENT(this))
2742         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2743         {
2744                 int totalClients = 0;
2745                 if(autocvar_sv_maxidle_slots > 0)
2746                 {
2747                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2748                         {
2749                                 ++totalClients;
2750                         });
2751                 }
2752
2753                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2754                 { /* do nothing */ }
2755                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2756                 {
2757                         if (CS(this).idlekick_lasttimeleft)
2758                         {
2759                                 CS(this).idlekick_lasttimeleft = 0;
2760                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2761                         }
2762                 }
2763                 else
2764                 {
2765                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2766                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2767                                 if (!CS(this).idlekick_lasttimeleft)
2768                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2769                         }
2770                         if (timeleft <= 0) {
2771                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2772                                 dropclient(this);
2773                                 return;
2774                         }
2775                         else if (timeleft <= 10) {
2776                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2777                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2778                                 CS(this).idlekick_lasttimeleft = timeleft;
2779                         }
2780                 }
2781         }
2782
2783         CheatFrame(this);
2784
2785         if (game_stopped)
2786         {
2787                 this.solid = SOLID_NOT;
2788                 this.takedamage = DAMAGE_NO;
2789                 set_movetype(this, MOVETYPE_NONE);
2790                 CS(this).teamkill_complain = 0;
2791                 CS(this).teamkill_soundtime = 0;
2792                 CS(this).teamkill_soundsource = NULL;
2793         }
2794
2795         if (IS_PLAYER(this)) {
2796                 if(this.death_time == time && IS_DEAD(this))
2797                 {
2798                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2799                         // once all the damage events of this frame have been processed with normal size
2800                         this.maxs.z = 5;
2801                         setsize(this, this.mins, this.maxs);
2802                 }
2803                 DrownPlayer(this);
2804                 UpdateChatBubble(this);
2805                 if (CS(this).impulse) ImpulseCommands(this);
2806                 GetPressedKeys(this);
2807                 if (game_stopped)
2808                 {
2809                         CSQCMODEL_AUTOUPDATE(this);
2810                         return;
2811                 }
2812         }
2813         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2814         {
2815                 CS(this).pressedkeys = 0;
2816                 STAT(PRESSED_KEYS, this) = 0;
2817         }
2818
2819         if (this.waypointsprite_attachedforcarrier) {
2820                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2821                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2822         }
2823
2824         CSQCMODEL_AUTOUPDATE(this);
2825 }
2826
2827 // hack to copy the button fields from the client entity to the Client State
2828 void PM_UpdateButtons(entity this, entity store)
2829 {
2830         if(this.impulse)
2831                 store.impulse = this.impulse;
2832         this.impulse = 0;
2833
2834         bool typing = this.buttonchat || this.button12;
2835
2836         store.button0 = (typing) ? 0 : this.button0;
2837         //button1?!
2838         store.button2 = (typing) ? 0 : this.button2;
2839         store.button3 = (typing) ? 0 : this.button3;
2840         store.button4 = this.button4;
2841         store.button5 = (typing) ? 0 : this.button5;
2842         store.button6 = this.button6;
2843         store.button7 = this.button7;
2844         store.button8 = this.button8;
2845         store.button9 = this.button9;
2846         store.button10 = this.button10;
2847         store.button11 = this.button11;
2848         store.button12 = this.button12;
2849         store.button13 = this.button13;
2850         store.button14 = this.button14;
2851         store.button15 = this.button15;
2852         store.button16 = this.button16;
2853         store.buttonuse = this.buttonuse;
2854         store.buttonchat = this.buttonchat;
2855
2856         store.cursor_active = this.cursor_active;
2857         store.cursor_screen = this.cursor_screen;
2858         store.cursor_trace_start = this.cursor_trace_start;
2859         store.cursor_trace_endpos = this.cursor_trace_endpos;
2860         store.cursor_trace_ent = this.cursor_trace_ent;
2861
2862         store.ping = this.ping;
2863         store.ping_packetloss = this.ping_packetloss;
2864         store.ping_movementloss = this.ping_movementloss;
2865
2866         store.v_angle = this.v_angle;
2867         store.movement = this.movement;
2868 }
2869
2870 NET_HANDLE(fpsreport, bool)
2871 {
2872         int fps = ReadShort();
2873         PlayerScore_Set(sender, SP_FPS, fps);
2874         return true;
2875 }