qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if (autocvar_sv_maxidle_playertospectator > 0 && CS(this).idlekick_lasttimeleft)
 245                 {
 246                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
 247                         CS(this).idlekick_lasttimeleft = 0;
 248                         CS(this).parm_idlesince = time;
 249                 }
 250
 251                 if(GetResource(this, RES_HEALTH) >= 1)
 252                 {
 253                         // despawn effect
 254                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 255                 }
 256
 257                 // was a player, recount votes and ready status
 258                 if(IS_REAL_CLIENT(this))
 259                 {
 260                         if (vote_called) { VoteCount(false); }
 261                         ReadyCount();
 262                 }
 263                 entcs_update_players(this);
 264         }
 265
 266         entity spot = SelectSpawnPoint(this, true);
 267         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268         this.angles = vec2(spot.angles);
 269         this.fixangle = true;
 270         // offset it so that the spectator spawns higher off the ground, looks better this way
 271         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 272         if (IS_REAL_CLIENT(this))
 273         {
 274                 msg_entity = this;
 275                 WriteByte(MSG_ONE, SVC_SETVIEW);
 276                 WriteEntity(MSG_ONE, this);
 277         }
 278         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 279         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 280         if(!autocvar_g_debug_globalsounds)
 281         {
 282                 // needed for player sounds
 283                 this.model = "";
 284                 FixPlayermodel(this);
 285         }
 286         setmodel(this, MDL_Null);
 287         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 288         this.view_ofs = '0 0 0';
 289
 290         RemoveGrapplingHooks(this);
 291         Portal_ClearAll(this);
 292         Unfreeze(this, false);
 293         SetSpectatee(this, NULL);
 294
 295         if (this.alivetime)
 296         {
 297                 if (!warmup_stage)
 298                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 299                 this.alivetime = 0;
 300         }
 301
 302         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 303
 304         WaypointSprite_PlayerDead(this);
 305
 306         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 307                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 308
 309         accuracy_resend(this);
 310
 311         CS(this).spectatortime = time;
 312         if(this.bot_attack)
 313                 IL_REMOVE(g_bot_targets, this);
 314         this.bot_attack = false;
 315         if(this.monster_attack)
 316                 IL_REMOVE(g_monster_targets, this);
 317         this.monster_attack = false;
 318         STAT(HUD, this) = HUD_NORMAL;
 319         TRANSMUTE(Observer, this);
 320         this.iscreature = false;
 321         this.teleportable = TELEPORT_SIMPLE;
 322         if(this.damagedbycontents)
 323                 IL_REMOVE(g_damagedbycontents, this);
 324         this.damagedbycontents = false;
 325         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 326         SetSpectatee_status(this, etof(this));
 327         this.takedamage = DAMAGE_NO;
 328         this.solid = SOLID_NOT;
 329         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 330         this.flags = FL_CLIENT | FL_NOTARGET;
 331         this.effects = 0;
 332         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 333         this.pauserotarmor_finished = 0;
 334         this.pauserothealth_finished = 0;
 335         this.pauseregen_finished = 0;
 336         this.damageforcescale = 0;
 337         this.death_time = 0;
 338         this.respawn_flags = 0;
 339         this.respawn_time = 0;
 340         STAT(RESPAWN_TIME, this) = 0;
 341         this.alpha = 0;
 342         this.scale = 0;
 343         this.fade_time = 0;
 344         this.pain_finished = 0;
 345         STAT(STRENGTH_FINISHED, this) = 0;
 346         STAT(INVINCIBLE_FINISHED, this) = 0;
 347         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 348         STAT(AIR_FINISHED, this) = 0;
 349         //this.dphitcontentsmask = 0;
 350         this.dphitcontentsmask = DPCONTENTS_SOLID;
 351         if (autocvar_g_playerclip_collisions)
 352                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 353         this.pushltime = 0;
 354         this.istypefrag = 0;
 355         setthink(this, func_null);
 356         this.nextthink = 0;
 357         this.deadflag = DEAD_NO;
 358         UNSET_DUCKED(this);
 359         STAT(REVIVE_PROGRESS, this) = 0;
 360         this.revival_time = 0;
 361         this.draggable = drag_undraggable;
 362
 363         this.items = 0;
 364         STAT(WEAPONS, this) = '0 0 0';
 365         this.drawonlytoclient = this;
 366
 367         this.viewloc = NULL;
 368
 369         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 370
 371         this.weaponmodel = "";
 372         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         {
 374                 this.weaponentities[slot] = NULL;
 375         }
 376         this.exteriorweaponentity = NULL;
 377         CS(this).killcount = FRAGS_SPECTATOR;
 378         this.velocity = '0 0 0';
 379         this.avelocity = '0 0 0';
 380         this.punchangle = '0 0 0';
 381         this.punchvector = '0 0 0';
 382         this.oldvelocity = this.velocity;
 383         this.fire_endtime = -1;
 384         this.event_damage = func_null;
 385         this.event_heal = func_null;
 386
 387         for(int slot = 0; slot < MAX_AXH; ++slot)
 388         {
 389                 entity axh = this.(AuxiliaryXhair[slot]);
 390                 this.(AuxiliaryXhair[slot]) = NULL;
 391
 392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 393                         delete(axh);
 394         }
 395
 396         if (mutator_returnvalue)
 397         {
 398                 // mutator prevents resetting teams+score
 399         }
 400         else
 401         {
 402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 403                 this.frags = FRAGS_SPECTATOR;
 404         }
 405
 406         bot_relinkplayerlist();
 407
 408         if (CS(this).just_joined)
 409                 CS(this).just_joined = false;
 410 }
 411
 412 int player_getspecies(entity this)
 413 {
 414         get_model_parameters(this.model, this.skin);
 415         int s = get_model_parameters_species;
 416         get_model_parameters(string_null, 0);
 417         if (s < 0) return SPECIES_HUMAN;
 418         return s;
 419 }
 420
 421 .float model_randomizer;
 422 void FixPlayermodel(entity player)
 423 {
 424         string defaultmodel = "";
 425         int defaultskin = 0;
 426         if(autocvar_sv_defaultcharacter)
 427         {
 428                 if(teamplay)
 429                 {
 430                         switch(player.team)
 431                         {
 432                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 433                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 434                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 435                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 436                         }
 437                 }
 438
 439                 if(defaultmodel == "")
 440                 {
 441                         defaultmodel = autocvar_sv_defaultplayermodel;
 442                         defaultskin = autocvar_sv_defaultplayerskin;
 443                 }
 444
 445                 int n = tokenize_console(defaultmodel);
 446                 if(n > 0)
 447                 {
 448                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 449                         // However, do NOT randomize if the player-selected model is in the list.
 450                         for (int i = 0; i < n; ++i)
 451                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 452                                         defaultmodel = argv(i);
 453                 }
 454
 455                 int i = strstrofs(defaultmodel, ":", 0);
 456                 if(i >= 0)
 457                 {
 458                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 459                         defaultmodel = substring(defaultmodel, 0, i);
 460                 }
 461         }
 462         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 463         {
 464                 if(teamplay)
 465                 {
 466                         switch(player.team)
 467                         {
 468                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 469                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 470                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 471                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 472                         }
 473                 }
 474
 475                 if(!defaultskin)
 476                         defaultskin = autocvar_sv_defaultplayerskin;
 477         }
 478
 479         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 480         defaultmodel = M_ARGV(0, string);
 481         defaultskin = M_ARGV(1, int);
 482
 483         bool chmdl = false;
 484         int oldskin;
 485         if(defaultmodel != "")
 486         {
 487                 if (defaultmodel != player.model)
 488                 {
 489                         vector m1 = player.mins;
 490                         vector m2 = player.maxs;
 491                         setplayermodel (player, defaultmodel);
 492                         setsize (player, m1, m2);
 493                         chmdl = true;
 494                 }
 495
 496                 oldskin = player.skin;
 497                 player.skin = defaultskin;
 498         } else {
 499                 if (player.playermodel != player.model || player.playermodel == "")
 500                 {
 501                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 502                         vector m1 = player.mins;
 503                         vector m2 = player.maxs;
 504                         setplayermodel (player, player.playermodel);
 505                         setsize (player, m1, m2);
 506                         chmdl = true;
 507                 }
 508
 509                 if(!autocvar_sv_defaultcharacterskin)
 510                 {
 511                         oldskin = player.skin;
 512                         player.skin = stof(player.playerskin);
 513                 }
 514                 else
 515                 {
 516                         oldskin = player.skin;
 517                         player.skin = defaultskin;
 518                 }
 519         }
 520
 521         if(chmdl || oldskin != player.skin) // model or skin has changed
 522         {
 523                 player.species = player_getspecies(player); // update species
 524                 if(!autocvar_g_debug_globalsounds)
 525                         UpdatePlayerSounds(player); // update skin sounds
 526         }
 527
 528         if(!teamplay)
 529                 if(strlen(autocvar_sv_defaultplayercolors))
 530                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 531                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 532 }
 533
 534 void PutPlayerInServer(entity this)
 535 {
 536         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 537
 538         PlayerState_attach(this);
 539         accuracy_resend(this);
 540
 541         if (this.team < 0)
 542                 TeamBalance_JoinBestTeam(this);
 543
 544         entity spot = SelectSpawnPoint(this, false);
 545         if (!spot) {
 546                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 547                 return; // spawn failed
 548         }
 549
 550         TRANSMUTE(Player, this);
 551
 552         CS(this).wasplayer = true;
 553         this.iscreature = true;
 554         this.teleportable = TELEPORT_NORMAL;
 555         if(!this.damagedbycontents)
 556                 IL_PUSH(g_damagedbycontents, this);
 557         this.damagedbycontents = true;
 558         set_movetype(this, MOVETYPE_WALK);
 559         this.solid = SOLID_SLIDEBOX;
 560         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 561         if (autocvar_g_playerclip_collisions)
 562                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 563         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 564                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 565         this.frags = FRAGS_PLAYER;
 566         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 567         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 568         if (autocvar__notarget)
 569                 this.flags |= FL_NOTARGET;
 570         this.takedamage = DAMAGE_AIM;
 571         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 572
 573         if (warmup_stage) {
 574                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, warmup_start_health);
 581                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 582                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 583         } else {
 584                 SetResource(this, RES_SHELLS, start_ammo_shells);
 585                 SetResource(this, RES_BULLETS, start_ammo_nails);
 586                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 587                 SetResource(this, RES_CELLS, start_ammo_cells);
 588                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 589                 SetResource(this, RES_FUEL, start_ammo_fuel);
 590                 SetResource(this, RES_HEALTH, start_health);
 591                 SetResource(this, RES_ARMOR, start_armorvalue);
 592                 STAT(WEAPONS, this) = start_weapons;
 593                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 594                 {
 595                         GiveRandomWeapons(this, random_start_weapons_count,
 596                                 autocvar_g_random_start_weapons, random_start_ammo);
 597                 }
 598         }
 599         SetSpectatee_status(this, 0);
 600
 601         PS(this).dual_weapons = '0 0 0';
 602
 603         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 604
 605         this.items = start_items;
 606
 607         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 608         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 609         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 610         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 611         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 612         if (!sv_ready_restart_after_countdown && time < game_starttime)
 613         {
 614                 float f = game_starttime - time;
 615                 this.spawnshieldtime += f;
 616                 this.pauserotarmor_finished += f;
 617                 this.pauserothealth_finished += f;
 618                 this.pauseregen_finished += f;
 619         }
 620
 621         this.damageforcescale = autocvar_g_player_damageforcescale;
 622         this.death_time = 0;
 623         this.respawn_flags = 0;
 624         this.respawn_time = 0;
 625         STAT(RESPAWN_TIME, this) = 0;
 626         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 627         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 628         this.fade_time = 0;
 629         this.pain_finished = 0;
 630         this.pushltime = 0;
 631         setthink(this, func_null); // players have no think function
 632         this.nextthink = 0;
 633         this.dmg_team = 0;
 634         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 635
 636         this.deadflag = DEAD_NO;
 637
 638         this.angles = spot.angles;
 639         this.angles_z = 0; // never spawn tilted even if the spot says to
 640         if (IS_BOT_CLIENT(this))
 641         {
 642                 this.v_angle = this.angles;
 643                 bot_aim_reset(this);
 644         }
 645         this.fixangle = true; // turn this way immediately
 646         this.oldvelocity = this.velocity = '0 0 0';
 647         this.avelocity = '0 0 0';
 648         this.punchangle = '0 0 0';
 649         this.punchvector = '0 0 0';
 650
 651         STAT(STRENGTH_FINISHED, this) = 0;
 652         STAT(INVINCIBLE_FINISHED, this) = 0;
 653         this.fire_endtime = -1;
 654         STAT(REVIVE_PROGRESS, this) = 0;
 655         this.revival_time = 0;
 656
 657         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 658         STAT(BUFFS, this) = 0;
 659         STAT(BUFF_TIME, this) = 0;
 660
 661         STAT(AIR_FINISHED, this) = 0;
 662         this.waterlevel = WATERLEVEL_NONE;
 663         this.watertype = CONTENT_EMPTY;
 664
 665         entity spawnevent = new_pure(spawnevent);
 666         spawnevent.owner = this;
 667         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 668
 669         // Cut off any still running player sounds.
 670         stopsound(this, CH_PLAYER_SINGLE);
 671
 672         this.model = "";
 673         FixPlayermodel(this);
 674         this.drawonlytoclient = NULL;
 675
 676         this.viewloc = NULL;
 677
 678         for(int slot = 0; slot < MAX_AXH; ++slot)
 679         {
 680                 entity axh = this.(AuxiliaryXhair[slot]);
 681                 this.(AuxiliaryXhair[slot]) = NULL;
 682
 683                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 684                         delete(axh);
 685         }
 686
 687         this.spawnpoint_targ = NULL;
 688
 689         UNSET_DUCKED(this);
 690         this.view_ofs = STAT(PL_VIEW_OFS, this);
 691         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 692         this.spawnorigin = spot.origin;
 693         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 694         // don't reset back to last position, even if new position is stuck in solid
 695         this.oldorigin = this.origin;
 696         if(this.conveyor)
 697                 IL_REMOVE(g_conveyed, this);
 698         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 699         if(this.swampslug)
 700                 IL_REMOVE(g_swamped, this);
 701         this.swampslug = NULL;
 702         this.swamp_interval = 0;
 703         if(this.ladder_entity)
 704                 IL_REMOVE(g_ladderents, this);
 705         this.ladder_entity = NULL;
 706         IL_EACH(g_counters, it.realowner == this,
 707         {
 708                 delete(it);
 709         });
 710         STAT(HUD, this) = HUD_NORMAL;
 711
 712         this.event_damage = PlayerDamage;
 713         this.event_heal = PlayerHeal;
 714
 715         this.draggable = func_null;
 716
 717         if(!this.bot_attack)
 718                 IL_PUSH(g_bot_targets, this);
 719         this.bot_attack = true;
 720         if(!this.monster_attack)
 721                 IL_PUSH(g_monster_targets, this);
 722         this.monster_attack = true;
 723         navigation_dynamicgoal_init(this, false);
 724
 725         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 726
 727         // player was spectator
 728         if (CS(this).killcount == FRAGS_SPECTATOR) {
 729                 PlayerScore_Clear(this);
 730                 CS(this).killcount = 0;
 731                 CS(this).startplaytime = time;
 732         }
 733
 734         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 735         {
 736                 .entity weaponentity = weaponentities[slot];
 737                 CL_SpawnWeaponentity(this, weaponentity);
 738         }
 739         this.alpha = default_player_alpha;
 740         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 741         this.exteriorweaponentity.alpha = default_weapon_alpha;
 742
 743         this.speedrunning = false;
 744
 745         this.counter_cnt = 0;
 746         this.fragsfilter_cnt = 0;
 747
 748         target_voicescript_clear(this);
 749
 750         // reset fields the weapons may use
 751         FOREACH(Weapons, true, {
 752                 it.wr_resetplayer(it, this);
 753                         // reload all reloadable weapons
 754                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 755                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 756                         {
 757                                 .entity weaponentity = weaponentities[slot];
 758                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 759                         }
 760                 }
 761         });
 762
 763         {
 764                 string s = spot.target;
 765                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 766                         spot.target = string_null;
 767                 SUB_UseTargets(spot, this, NULL);
 768                 if(g_assault || g_race)
 769                         spot.target = s;
 770         }
 771
 772         Unfreeze(this, false);
 773
 774         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 775
 776         if (autocvar_spawn_debug)
 777         {
 778                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 779                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 780         }
 781
 782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783         {
 784                 .entity weaponentity = weaponentities[slot];
 785                 entity w_ent = this.(weaponentity);
 786                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 787                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 788                 else
 789                         w_ent.m_switchweapon = WEP_Null;
 790                 w_ent.m_weapon = WEP_Null;
 791                 w_ent.weaponname = "";
 792                 w_ent.m_switchingweapon = WEP_Null;
 793                 w_ent.cnt = -1;
 794         }
 795
 796         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 797
 798         if (CS(this).impulse) ImpulseCommands(this);
 799
 800         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 802         {
 803                 .entity weaponentity = weaponentities[slot];
 804                 W_WeaponFrame(this, weaponentity);
 805         }
 806
 807         if (!warmup_stage && !this.alivetime)
 808                 this.alivetime = time;
 809
 810         antilag_clear(this, CS(this));
 811 }
 812
 813 /** Called when a client spawns in the server */
 814 void PutClientInServer(entity this)
 815 {
 816         if (IS_BOT_CLIENT(this)) {
 817                 TRANSMUTE(Player, this);
 818         } else if (IS_REAL_CLIENT(this)) {
 819                 msg_entity = this;
 820                 WriteByte(MSG_ONE, SVC_SETVIEW);
 821                 WriteEntity(MSG_ONE, this);
 822         }
 823         if (game_stopped)
 824                 TRANSMUTE(Observer, this);
 825
 826         SetSpectatee(this, NULL);
 827
 828         // reset player keys
 829         if(PS(this))
 830                 PS(this).itemkeys = 0;
 831
 832         MUTATOR_CALLHOOK(PutClientInServer, this);
 833
 834         if (IS_OBSERVER(this)) {
 835                 PutObserverInServer(this);
 836         } else if (IS_PLAYER(this)) {
 837                 PutPlayerInServer(this);
 838         }
 839
 840         bot_relinkplayerlist();
 841 }
 842
 843 // TODO do we need all these fields, or should we stop autodetecting runtime
 844 // changes and just have a console command to update this?
 845 bool ClientInit_SendEntity(entity this, entity to, int sf)
 846 {
 847         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 848         return = true;
 849         msg_entity = to;
 850         // MSG_INIT replacement
 851         // TODO: make easier to use
 852         Registry_send_all();
 853         W_PROP_reload(MSG_ONE, to);
 854         ClientInit_misc(this);
 855         MUTATOR_CALLHOOK(Ent_Init);
 856 }
 857 void ClientInit_misc(entity this)
 858 {
 859         int channel = MSG_ONE;
 860         WriteHeader(channel, ENT_CLIENT_INIT);
 861         WriteByte(channel, g_nexball_meter_period * 32);
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 870
 871         if(autocvar_sv_foginterval && world.fog != "")
 872                 WriteString(channel, world.fog);
 873         else
 874                 WriteString(channel, "");
 875         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 876         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 877         WriteByte(channel, serverflags);
 878         WriteCoord(channel, autocvar_g_trueaim_minrange);
 879 }
 880
 881 void ClientInit_CheckUpdate(entity this)
 882 {
 883         this.nextthink = time;
 884         if(this.count != autocvar_g_balance_armor_blockpercent)
 885         {
 886                 this.count = autocvar_g_balance_armor_blockpercent;
 887                 this.SendFlags |= 1;
 888         }
 889         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 890         {
 891                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 892                 this.SendFlags |= 1;
 893         }
 894 }
 895
 896 void ClientInit_Spawn()
 897 {
 898         entity e = new_pure(clientinit);
 899         setthink(e, ClientInit_CheckUpdate);
 900         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 901
 902         ClientInit_CheckUpdate(e);
 903 }
 904
 905 /*
 906 =============
 907 SetNewParms
 908 =============
 909 */
 910 void SetNewParms ()
 911 {
 912         // initialize parms for a new player
 913         parm1 = -(86400 * 366);
 914
 915         MUTATOR_CALLHOOK(SetNewParms);
 916 }
 917
 918 /*
 919 =============
 920 SetChangeParms
 921 =============
 922 */
 923 void SetChangeParms (entity this)
 924 {
 925         // save parms for level change
 926         parm1 = CS(this).parm_idlesince - time;
 927
 928         MUTATOR_CALLHOOK(SetChangeParms);
 929 }
 930
 931 /*
 932 =============
 933 DecodeLevelParms
 934 =============
 935 */
 936 void DecodeLevelParms(entity this)
 937 {
 938         // load parms
 939         CS(this).parm_idlesince = parm1;
 940         if (CS(this).parm_idlesince == -(86400 * 366))
 941                 CS(this).parm_idlesince = time;
 942
 943         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 944         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 945
 946         MUTATOR_CALLHOOK(DecodeLevelParms);
 947 }
 948
 949 void FixClientCvars(entity e)
 950 {
 951         // send prediction settings to the client
 952         stuffcmd(e, "\nin_bindmap 0 0\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957
 958         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 959         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 960
 961         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 962
 963         MUTATOR_CALLHOOK(FixClientCvars, e);
 964 }
 965
 966 bool findinlist_abbrev(string tofind, string list)
 967 {
 968         if(list == "" || tofind == "")
 969                 return false; // empty list or search, just return
 970
 971         // this function allows abbreviated strings!
 972         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 973         {
 974                 return true;
 975         });
 976
 977         return false;
 978 }
 979
 980 bool PlayerInIPList(entity p, string iplist)
 981 {
 982         // some safety checks (never allow local?)
 983         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 984                 return false;
 985
 986         return findinlist_abbrev(p.netaddress, iplist);
 987 }
 988
 989 bool PlayerInIDList(entity p, string idlist)
 990 {
 991         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 992         if(!p.crypto_idfp)
 993                 return false;
 994
 995         return findinlist_abbrev(p.crypto_idfp, idlist);
 996 }
 997
 998 bool PlayerInList(entity player, string list)
 999 {
1000         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1001 }
1002
1003 #ifdef DP_EXT_PRECONNECT
1004 /*
1005 =============
1006 ClientPreConnect
1007
1008 Called once (not at each match start) when a client begins a connection to the server
1009 =============
1010 */
1011 void ClientPreConnect(entity this)
1012 {
1013         if(autocvar_sv_eventlog)
1014         {
1015                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1016                         this.playerid,
1017                         etof(this),
1018                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1019                 ));
1020         }
1021 }
1022 #endif
1023
1024 string GetClientVersionMessage(entity this)
1025 {
1026         if (CS(this).version_mismatch) {
1027                 if(CS(this).version < autocvar_gameversion) {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1030                 } else {
1031                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1032                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1033                 }
1034         } else {
1035                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1036         }
1037 }
1038
1039 string getwelcomemessage(entity this)
1040 {
1041         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1042         string modifications = M_ARGV(0, string);
1043
1044         if(g_weaponarena)
1045         {
1046                 if(g_weaponarena_random)
1047                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1048                 else
1049                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1050         }
1051         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(autocvar_g_jetpack)
1058                 modifications = strcat(modifications, ", Jet pack");
1059         if(autocvar_g_powerups == 0)
1060                 modifications = strcat(modifications, ", No powerups");
1061         if(autocvar_g_powerups > 0)
1062                 modifications = strcat(modifications, ", Powerups");
1063         modifications = substring(modifications, 2, strlen(modifications) - 2);
1064
1065         string versionmessage = GetClientVersionMessage(this);
1066         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1067
1068         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1069
1070         if(modifications != "")
1071                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1072
1073         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1074         {
1075                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1076                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1077         }
1078
1079         if (cache_mutatormsg != "") {
1080                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1081         }
1082
1083         string mutator_msg = "";
1084         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1085         mutator_msg = M_ARGV(0, string);
1086
1087         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1088
1089         string motd = autocvar_sv_motd;
1090         if (motd != "") {
1091                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1092         }
1093         return s;
1094 }
1095
1096 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1097
1098 /**
1099 =============
1100 ClientConnect
1101
1102 Called when a client connects to the server
1103 =============
1104 */
1105 void ClientConnect(entity this)
1106 {
1107         if (Ban_MaybeEnforceBanOnce(this)) return;
1108         assert(!IS_CLIENT(this), return);
1109         this.flags |= FL_CLIENT;
1110         assert(player_count >= 0, player_count = 0);
1111
1112         TRANSMUTE(Client, this);
1113         CS(this).version_nagtime = time + 10 + random() * 10;
1114
1115         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1116
1117         bot_clientconnect(this);
1118
1119         Player_DetermineForcedTeam(this);
1120
1121         TRANSMUTE(Observer, this);
1122
1123         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1124
1125         // always track bots, don't ask for cl_allow_uidtracking
1126         if (IS_BOT_CLIENT(this))
1127                 PlayerStats_GameReport_AddPlayer(this);
1128         else
1129                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1130
1131         if (autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1133
1134         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1135
1136         stuffcmd(this, clientstuff, "\n");
1137         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1138
1139         FixClientCvars(this);
1140
1141         // get version info from player
1142         stuffcmd(this, "cmd clientversion $gameversion\n");
1143
1144         // notify about available teams
1145         if (teamplay)
1146         {
1147                 entity balance = TeamBalance_CheckAllowedTeams(this);
1148                 int t = TeamBalance_GetAllowedTeams(balance);
1149                 TeamBalance_Destroy(balance);
1150                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1151         }
1152         else
1153         {
1154                 stuffcmd(this, "set _teams_available 0\n");
1155         }
1156
1157         bot_relinkplayerlist();
1158
1159         CS(this).spectatortime = time;
1160         if (blockSpectators)
1161         {
1162                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1163         }
1164
1165         CS(this).jointime = time;
1166
1167         if (IS_REAL_CLIENT(this))
1168         {
1169                 if (g_weaponarena_weapons == WEPSET(TUBA))
1170                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1171         }
1172
1173         if (!autocvar_sv_foginterval && world.fog != "")
1174                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1175
1176         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1177                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1178                         send_CSQC_teamnagger();
1179
1180         CSQCMODEL_AUTOINIT(this);
1181
1182         CS(this).model_randomizer = random();
1183
1184         if (IS_REAL_CLIENT(this))
1185                 sv_notice_join(this);
1186
1187         this.move_qcphysics = autocvar_sv_qcphysics;
1188
1189         // update physics stats (players can spawn before physics runs)
1190         Physics_UpdateStats(this);
1191
1192         IL_EACH(g_initforplayer, it.init_for_player, {
1193                 it.init_for_player(it, this);
1194         });
1195
1196         Handicap_Initialize(this);
1197
1198         MUTATOR_CALLHOOK(ClientConnect, this);
1199
1200         if (IS_REAL_CLIENT(this))
1201         {
1202                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1203                 {
1204                         CS(this).motd_actived_time = -1;
1205                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1206                 }
1207         }
1208 }
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 .entity chatbubbleentity;
1217 void player_powerups_remove_all(entity this);
1218
1219 void ClientDisconnect(entity this)
1220 {
1221         assert(IS_CLIENT(this), return);
1222
1223         PlayerStats_GameReport_FinalizePlayer(this);
1224         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1225         if (CS(this).active_minigame) part_minigame(this);
1226         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1227
1228         if (autocvar_sv_eventlog)
1229                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1230
1231         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1232
1233         if(IS_SPEC(this))
1234                 SetSpectatee(this, NULL);
1235
1236         MUTATOR_CALLHOOK(ClientDisconnect, this);
1237
1238         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1239         strfree(CS_CVAR(this).weaponorder_byimpulse);
1240         ClientState_detach(this);
1241
1242         Portal_ClearAll(this);
1243
1244         Unfreeze(this, false);
1245
1246         RemoveGrapplingHooks(this);
1247
1248         // Here, everything has been done that requires this player to be a client.
1249
1250         this.flags &= ~FL_CLIENT;
1251
1252         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1253         if (this.killindicator) delete(this.killindicator);
1254
1255         IL_EACH(g_counters, it.realowner == this,
1256         {
1257                 delete(it);
1258         });
1259
1260         WaypointSprite_PlayerGone(this);
1261
1262         bot_relinkplayerlist();
1263
1264         strfree(this.clientstatus);
1265         if (this.personal) delete(this.personal);
1266
1267         this.playerid = 0;
1268         ReadyCount();
1269         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1270
1271         player_powerups_remove_all(this); // stop powerup sound
1272
1273         ONREMOVE(this);
1274 }
1275
1276 void ChatBubbleThink(entity this)
1277 {
1278         this.nextthink = time;
1279         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1280         {
1281                 if(this.owner) // but why can that ever be NULL?
1282                         this.owner.chatbubbleentity = NULL;
1283                 delete(this);
1284                 return;
1285         }
1286
1287         this.mdl = "";
1288
1289         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1290         {
1291                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1292                         this.mdl = "models/sprites/minigame_busy.iqm";
1293                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1294                         this.mdl = "models/misc/chatbubble.spr";
1295         }
1296
1297         if ( this.model != this.mdl )
1298                 _setmodel(this, this.mdl);
1299
1300 }
1301
1302 void UpdateChatBubble(entity this)
1303 {
1304         if (this.alpha < 0)
1305                 return;
1306         // spawn a chatbubble entity if needed
1307         if (!this.chatbubbleentity)
1308         {
1309                 this.chatbubbleentity = new(chatbubbleentity);
1310                 this.chatbubbleentity.owner = this;
1311                 this.chatbubbleentity.exteriormodeltoclient = this;
1312                 setthink(this.chatbubbleentity, ChatBubbleThink);
1313                 this.chatbubbleentity.nextthink = time;
1314                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1315                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1316                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1317                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1318                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1319                 //this.chatbubbleentity.model = "";
1320                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1321         }
1322 }
1323
1324 void calculate_player_respawn_time(entity this)
1325 {
1326         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1327                 return;
1328
1329         float gametype_setting_tmp;
1330         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1331         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1332         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1333         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1334         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1335         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1336
1337         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1338         if (teamplay)
1339         {
1340                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1341                         if(it.team == this.team)
1342                                 ++pcount;
1343                 });
1344                 if (sdelay_small_count == 0)
1345                         sdelay_small_count = 1;
1346                 if (sdelay_large_count == 0)
1347                         sdelay_large_count = 1;
1348         }
1349         else
1350         {
1351                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1352                         ++pcount;
1353                 });
1354                 if (sdelay_small_count == 0)
1355                 {
1356                         if (IS_INDEPENDENT_PLAYER(this))
1357                         {
1358                                 // Players play independently. No point in requiring enemies.
1359                                 sdelay_small_count = 1;
1360                         }
1361                         else
1362                         {
1363                                 // Players play AGAINST each other. Enemies required.
1364                                 sdelay_small_count = 2;
1365                         }
1366                 }
1367                 if (sdelay_large_count == 0)
1368                 {
1369                         if (IS_INDEPENDENT_PLAYER(this))
1370                         {
1371                                 // Players play independently. No point in requiring enemies.
1372                                 sdelay_large_count = 1;
1373                         }
1374                         else
1375                         {
1376                                 // Players play AGAINST each other. Enemies required.
1377                                 sdelay_large_count = 2;
1378                         }
1379                 }
1380         }
1381
1382         float sdelay;
1383
1384         if (pcount <= sdelay_small_count)
1385                 sdelay = sdelay_small;
1386         else if (pcount >= sdelay_large_count)
1387                 sdelay = sdelay_large;
1388         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1389                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1390
1391         if(waves)
1392                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1393         else
1394                 this.respawn_time = time + sdelay;
1395
1396         if(sdelay < sdelay_max)
1397                 this.respawn_time_max = time + sdelay_max;
1398         else
1399                 this.respawn_time_max = this.respawn_time;
1400
1401         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1402                 this.respawn_countdown = 10; // first number to count down from is 10
1403         else
1404                 this.respawn_countdown = -1; // do not count down
1405
1406         if(autocvar_g_forced_respawn)
1407                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1408 }
1409
1410 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1411 // added to the model skins
1412 /*void UpdateColorModHack()
1413 {
1414         float c;
1415         c = this.clientcolors & 15;
1416         // LordHavoc: only bothering to support white, green, red, yellow, blue
1417              if (!teamplay) this.colormod = '0 0 0';
1418         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1419         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1420         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1421         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1422         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1423         else this.colormod = '1 1 1';
1424 }*/
1425
1426 void respawn(entity this)
1427 {
1428         bool damagedbycontents_prev = this.damagedbycontents;
1429         if(this.alpha >= 0)
1430         {
1431                 if(autocvar_g_respawn_ghosts)
1432                 {
1433                         this.solid = SOLID_NOT;
1434                         this.takedamage = DAMAGE_NO;
1435                         this.damagedbycontents = false;
1436                         set_movetype(this, MOVETYPE_FLY);
1437                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1438                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1439                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1440                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1441                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1442                         if(autocvar_g_respawn_ghosts_time > 0)
1443                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1444                 }
1445                 else
1446                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1447         }
1448
1449         CopyBody(this, 1);
1450         this.damagedbycontents = damagedbycontents_prev;
1451
1452         this.effects |= EF_NODRAW; // prevent another CopyBody
1453         PutClientInServer(this);
1454 }
1455
1456 void play_countdown(entity this, float finished, Sound samp)
1457 {
1458         TC(Sound, samp);
1459         if(IS_REAL_CLIENT(this))
1460                 if(floor(finished - time - frametime) != floor(finished - time))
1461                         if(finished - time < 6)
1462                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1463 }
1464
1465 void player_powerups_remove_all(entity this)
1466 {
1467         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1468         {
1469                 // don't play the poweroff sound when the game restarts or the player disconnects
1470                 if (time > game_starttime + 1 && IS_CLIENT(this))
1471                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1472                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1473                 this.items &= ~ITEM_Strength.m_itemid;
1474                 this.items &= ~ITEM_Shield.m_itemid;
1475                 this.items -= (this.items & IT_SUPERWEAPON);
1476         }
1477 }
1478
1479 void player_powerups(entity this)
1480 {
1481         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1482                 this.modelflags |= MF_ROCKET;
1483         else
1484                 this.modelflags &= ~MF_ROCKET;
1485
1486         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1487
1488         if (IS_DEAD(this))
1489                 player_powerups_remove_all(this);
1490
1491         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1492                 return;
1493
1494         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1495         int items_prev = this.items;
1496
1497         Fire_ApplyDamage(this);
1498         Fire_ApplyEffect(this);
1499
1500         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1501         {
1502                 if (this.items & ITEM_Strength.m_itemid)
1503                 {
1504                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1505                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1506                         if (time > STAT(STRENGTH_FINISHED, this))
1507                         {
1508                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1509                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1510                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1511                         }
1512                 }
1513                 else
1514                 {
1515                         if (time < STAT(STRENGTH_FINISHED, this))
1516                         {
1517                                 this.items = this.items | ITEM_Strength.m_itemid;
1518                                 if(!g_cts)
1519                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1521                         }
1522                 }
1523                 if (this.items & ITEM_Shield.m_itemid)
1524                 {
1525                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1526                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1527                         if (time > STAT(INVINCIBLE_FINISHED, this))
1528                         {
1529                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1530                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1531                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1532                         }
1533                 }
1534                 else
1535                 {
1536                         if (time < STAT(INVINCIBLE_FINISHED, this))
1537                         {
1538                                 this.items = this.items | ITEM_Shield.m_itemid;
1539                                 if(!g_cts)
1540                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1541                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1542                         }
1543                 }
1544                 if (this.items & IT_SUPERWEAPON)
1545                 {
1546                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1547                         {
1548                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1549                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1550                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1551                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1552                         }
1553                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1554                         {
1555                                 // don't let them run out
1556                         }
1557                         else
1558                         {
1559                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1560                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1561                                 {
1562                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1563                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1564                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1565                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1566                                 }
1567                         }
1568                 }
1569                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1570                 {
1571                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1572                         {
1573                                 this.items = this.items | IT_SUPERWEAPON;
1574                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1575                                 {
1576                                         if(!g_cts)
1577                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1578                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1579                                 }
1580                         }
1581                         else
1582                         {
1583                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1584                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1585                         }
1586                 }
1587                 else
1588                 {
1589                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1590                 }
1591         }
1592
1593         if(autocvar_g_nodepthtestplayers)
1594                 this.effects = this.effects | EF_NODEPTHTEST;
1595
1596         if(autocvar_g_fullbrightplayers)
1597                 this.effects = this.effects | EF_FULLBRIGHT;
1598
1599         if (time >= game_starttime)
1600         if (time < this.spawnshieldtime)
1601                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1602
1603         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1604 }
1605
1606 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1607 {
1608         if(current > stable)
1609                 return current;
1610         else if(current > stable - 0.25) // when close enough, "snap"
1611                 return stable;
1612         else
1613                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1614 }
1615
1616 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1617 {
1618         if(current < stable)
1619                 return current;
1620         else if(current < stable + 0.25) // when close enough, "snap"
1621                 return stable;
1622         else
1623                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1624 }
1625
1626 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1627 {
1628         float old = GetResource(this, res);
1629         float current = old;
1630         if(current > rotstable)
1631         {
1632                 if(rotframetime > 0)
1633                 {
1634                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1635                         current = max(rotstable, current - rotlinear * rotframetime);
1636                 }
1637         }
1638         else if(current < regenstable)
1639         {
1640                 if(regenframetime > 0)
1641                 {
1642                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1643                         current = min(regenstable, current + regenlinear * regenframetime);
1644                 }
1645         }
1646
1647         float limit = GetResourceLimit(this, res) * limit_mod;
1648         if(current > limit)
1649                 current = limit;
1650
1651         if (current != old)
1652                 SetResource(this, res, current);
1653 }
1654
1655 void player_regen(entity this)
1656 {
1657         float max_mod, regen_mod, rot_mod, limit_mod;
1658         max_mod = regen_mod = rot_mod = limit_mod = 1;
1659
1660         float regen_health = autocvar_g_balance_health_regen;
1661         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1662         float regen_health_rot = autocvar_g_balance_health_rot;
1663         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1664         float regen_health_stable = autocvar_g_balance_health_regenstable;
1665         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1666         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1667                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1668         max_mod = M_ARGV(1, float);
1669         regen_mod = M_ARGV(2, float);
1670         rot_mod = M_ARGV(3, float);
1671         limit_mod = M_ARGV(4, float);
1672         regen_health = M_ARGV(5, float);
1673         regen_health_linear = M_ARGV(6, float);
1674         regen_health_rot = M_ARGV(7, float);
1675         regen_health_rotlinear = M_ARGV(8, float);
1676         regen_health_stable = M_ARGV(9, float);
1677         regen_health_rotstable = M_ARGV(10, float);
1678
1679         if(!mutator_returnvalue)
1680         if(!STAT(FROZEN, this))
1681         {
1682                 float maxa = autocvar_g_balance_armor_rotstable;
1683                 float mina = autocvar_g_balance_armor_regenstable;
1684
1685                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1686                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1687                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1688
1689                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1690                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1691                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1692         }
1693
1694         // if player rotted to death...  die!
1695         // check this outside above checks, as player may still be able to rot to death
1696         if(GetResource(this, RES_HEALTH) < 1)
1697         {
1698                 if(this.vehicle)
1699                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1700                 if(this.event_damage)
1701                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1702         }
1703
1704         if (!(this.items & IT_UNLIMITED_AMMO))
1705         {
1706                 float maxf = autocvar_g_balance_fuel_rotstable;
1707                 float minf = autocvar_g_balance_fuel_regenstable;
1708
1709                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1710                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1711                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1712         }
1713 }
1714
1715 bool zoomstate_set;
1716 void SetZoomState(entity this, float newzoom)
1717 {
1718         if(newzoom != CS(this).zoomstate)
1719         {
1720                 CS(this).zoomstate = newzoom;
1721                 ClientData_Touch(this);
1722         }
1723         zoomstate_set = true;
1724 }
1725
1726 void GetPressedKeys(entity this)
1727 {
1728         MUTATOR_CALLHOOK(GetPressedKeys, this);
1729         if (game_stopped)
1730         {
1731                 CS(this).pressedkeys = 0;
1732                 STAT(PRESSED_KEYS, this) = 0;
1733                 return;
1734         }
1735
1736         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1737         int keys = STAT(PRESSED_KEYS, this);
1738         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1739         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1740         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1741         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1742
1743         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1744         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1745         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1746         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1747         CS(this).pressedkeys = keys; // store for other users
1748
1749         STAT(PRESSED_KEYS, this) = keys;
1750 }
1751
1752 /*
1753 ======================
1754 spectate mode routines
1755 ======================
1756 */
1757
1758 void SpectateCopy(entity this, entity spectatee)
1759 {
1760         TC(Client, this); TC(Client, spectatee);
1761
1762         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1763         PS(this) = PS(spectatee);
1764         this.armortype = spectatee.armortype;
1765         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1766         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1767         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1768         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1769         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1770         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1771         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1772         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1773         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1774         CS(this).impulse = 0;
1775         this.disableclientprediction = 1; // no need to run prediction on a spectator
1776         this.items = spectatee.items;
1777         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1778         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1779         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1780         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1781         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1782         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1783         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1784         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1785         this.punchangle = spectatee.punchangle;
1786         this.view_ofs = spectatee.view_ofs;
1787         this.velocity = spectatee.velocity;
1788         this.dmg_take = spectatee.dmg_take;
1789         this.dmg_save = spectatee.dmg_save;
1790         this.dmg_inflictor = spectatee.dmg_inflictor;
1791         this.v_angle = spectatee.v_angle;
1792         this.angles = spectatee.v_angle;
1793         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1794         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1795         this.viewloc = spectatee.viewloc;
1796         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1797                 this.fixangle = true;
1798         setorigin(this, spectatee.origin);
1799         setsize(this, spectatee.mins, spectatee.maxs);
1800         SetZoomState(this, CS(spectatee).zoomstate);
1801
1802     anticheat_spectatecopy(this, spectatee);
1803         STAT(HUD, this) = STAT(HUD, spectatee);
1804         if(spectatee.vehicle)
1805     {
1806         this.angles = spectatee.v_angle;
1807
1808         //this.fixangle = false;
1809         //this.velocity = spectatee.vehicle.velocity;
1810         this.vehicle_health = spectatee.vehicle_health;
1811         this.vehicle_shield = spectatee.vehicle_shield;
1812         this.vehicle_energy = spectatee.vehicle_energy;
1813         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1814         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1815         this.vehicle_reload1 = spectatee.vehicle_reload1;
1816         this.vehicle_reload2 = spectatee.vehicle_reload2;
1817
1818         //msg_entity = this;
1819
1820        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1821             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1822            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1823            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1824
1825         //WriteByte (MSG_ONE, SVC_SETVIEW);
1826         //    WriteEntity(MSG_ONE, this);
1827         //makevectors(spectatee.v_angle);
1828         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1829     }
1830 }
1831
1832 bool SpectateUpdate(entity this)
1833 {
1834         if(!this.enemy)
1835                 return false;
1836
1837         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1838         {
1839                 SetSpectatee(this, NULL);
1840                 return false;
1841         }
1842
1843         SpectateCopy(this, this.enemy);
1844
1845         return true;
1846 }
1847
1848 bool SpectateSet(entity this)
1849 {
1850         if(!IS_PLAYER(this.enemy))
1851                 return false;
1852
1853         ClientData_Touch(this.enemy);
1854
1855         msg_entity = this;
1856         WriteByte(MSG_ONE, SVC_SETVIEW);
1857         WriteEntity(MSG_ONE, this.enemy);
1858         set_movetype(this, MOVETYPE_NONE);
1859         accuracy_resend(this);
1860
1861         if(!SpectateUpdate(this))
1862                 PutObserverInServer(this);
1863
1864         return true;
1865 }
1866
1867 void SetSpectatee_status(entity this, int spectatee_num)
1868 {
1869         int oldspectatee_status = CS(this).spectatee_status;
1870         CS(this).spectatee_status = spectatee_num;
1871
1872         if (CS(this).spectatee_status != oldspectatee_status)
1873         {
1874                 if (STAT(PRESSED_KEYS, this))
1875                 {
1876                         CS(this).pressedkeys = 0;
1877                         STAT(PRESSED_KEYS, this) = 0;
1878                 }
1879                 ClientData_Touch(this);
1880                 if (g_race || g_cts) race_InitSpectator();
1881         }
1882 }
1883
1884 void SetSpectatee(entity this, entity spectatee)
1885 {
1886         if(IS_BOT_CLIENT(this))
1887                 return; // bots abuse .enemy, this code is useless to them
1888
1889         entity old_spectatee = this.enemy;
1890
1891         this.enemy = spectatee;
1892
1893         // WEAPONTODO
1894         // these are required to fix the spectator bug with arc
1895         if(old_spectatee)
1896         {
1897                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1898                 {
1899                         .entity weaponentity = weaponentities[slot];
1900                         if(old_spectatee.(weaponentity).arc_beam)
1901                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1902                 }
1903         }
1904         if(this.enemy)
1905         {
1906                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1907                 {
1908                         .entity weaponentity = weaponentities[slot];
1909                         if(this.enemy.(weaponentity).arc_beam)
1910                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1911                 }
1912         }
1913
1914         if (this.enemy)
1915                 SetSpectatee_status(this, etof(this.enemy));
1916
1917         // needed to update spectator list
1918         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1919 }
1920
1921 bool Spectate(entity this, entity pl)
1922 {
1923         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1924                 return false;
1925         pl = M_ARGV(1, entity);
1926
1927         SetSpectatee(this, pl);
1928         return SpectateSet(this);
1929 }
1930
1931 bool SpectateNext(entity this)
1932 {
1933         entity ent = find(this.enemy, classname, STR_PLAYER);
1934
1935         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1936                 ent = M_ARGV(1, entity);
1937         else if (!ent)
1938                 ent = find(ent, classname, STR_PLAYER);
1939
1940         if(ent) { SetSpectatee(this, ent); }
1941
1942         return SpectateSet(this);
1943 }
1944
1945 bool SpectatePrev(entity this)
1946 {
1947         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1948         entity ent = findchain(classname, STR_PLAYER);
1949         if (!ent) // no player
1950                 return false;
1951
1952         entity first = ent;
1953         // skip players until current spectated player
1954         if(this.enemy)
1955         while(ent && ent != this.enemy)
1956                 ent = ent.chain;
1957
1958         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1959         {
1960                 case MUT_SPECPREV_FOUND:
1961                         ent = M_ARGV(1, entity);
1962                         break;
1963                 case MUT_SPECPREV_RETURN:
1964                         return true;
1965                 case MUT_SPECPREV_CONTINUE:
1966                 default:
1967                 {
1968                         if(ent.chain)
1969                                 ent = ent.chain;
1970                         else
1971                                 ent = first;
1972                         break;
1973                 }
1974         }
1975
1976         SetSpectatee(this, ent);
1977         return SpectateSet(this);
1978 }
1979
1980 /*
1981 =============
1982 ShowRespawnCountdown()
1983
1984 Update a respawn countdown display.
1985 =============
1986 */
1987 void ShowRespawnCountdown(entity this)
1988 {
1989         float number;
1990         if(!IS_DEAD(this)) // just respawned?
1991                 return;
1992         else
1993         {
1994                 number = ceil(this.respawn_time - time);
1995                 if(number <= 0)
1996                         return;
1997                 if(number <= this.respawn_countdown)
1998                 {
1999                         this.respawn_countdown = number - 1;
2000                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2001                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2002                 }
2003         }
2004 }
2005
2006 .bool team_selected;
2007 bool ShowTeamSelection(entity this)
2008 {
2009         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2010                 return false;
2011         stuffcmd(this, "menu_showteamselect\n");
2012         return true;
2013 }
2014 void Join(entity this)
2015 {
2016         TRANSMUTE(Player, this);
2017
2018         if(!this.team_selected)
2019         if(autocvar_g_campaign || autocvar_g_balance_teams)
2020                 TeamBalance_JoinBestTeam(this);
2021
2022         if(autocvar_g_campaign)
2023                 campaign_bots_may_start = true;
2024
2025         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2026
2027         PutClientInServer(this);
2028
2029         if(IS_PLAYER(this))
2030         if(teamplay && this.team != -1)
2031         {
2032         }
2033         else
2034                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2035         this.team_selected = false;
2036 }
2037
2038 int GetPlayerLimit()
2039 {
2040         if(g_duel)
2041                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2042         int player_limit = autocvar_g_maxplayers;
2043         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2044         player_limit = M_ARGV(0, int);
2045         return player_limit;
2046 }
2047
2048 /**
2049  * Determines whether the player is allowed to join. This depends on cvar
2050  * g_maxplayers, if it isn't used this function always return true, otherwise
2051  * it checks whether the number of currently playing players exceeds g_maxplayers.
2052  * @return int number of free slots for players, 0 if none
2053  */
2054 int nJoinAllowed(entity this, entity ignore)
2055 {
2056         if(!ignore)
2057         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2058         // so report 0 free slots if restricted
2059         {
2060                 if(autocvar_g_forced_team_otherwise == "spectate")
2061                         return 0;
2062                 if(autocvar_g_forced_team_otherwise == "spectator")
2063                         return 0;
2064         }
2065
2066         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2067                 return 0; // forced spectators can never join
2068
2069         // TODO simplify this
2070         int totalClients = 0;
2071         int currentlyPlaying = 0;
2072         FOREACH_CLIENT(true, {
2073                 if(it != ignore)
2074                         ++totalClients;
2075                 if(IS_REAL_CLIENT(it))
2076                 if(IS_PLAYER(it) || it.caplayer)
2077                         ++currentlyPlaying;
2078         });
2079
2080         int player_limit = GetPlayerLimit();
2081
2082         int free_slots = 0;
2083         if (!player_limit)
2084                 free_slots = maxclients - totalClients;
2085         else if(player_limit > 0 && currentlyPlaying < player_limit)
2086                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2087
2088         static float msg_time = 0;
2089         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2090         {
2091                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2092                 msg_time = time + 0.5;
2093         }
2094
2095         return free_slots;
2096 }
2097
2098 void PrintWelcomeMessage(entity this)
2099 {
2100         if(CS(this).motd_actived_time == 0)
2101         {
2102                 if (autocvar_g_campaign) {
2103                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2104                                 CS(this).motd_actived_time = time;
2105                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2106                         }
2107                 } else {
2108                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2109                                 CS(this).motd_actived_time = time;
2110                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2111                         }
2112                 }
2113         }
2114         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2115         {
2116                 if (autocvar_g_campaign) {
2117                         if (PHYS_INPUT_BUTTON_INFO(this))
2118                                 CS(this).motd_actived_time = time;
2119                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2120                                 CS(this).motd_actived_time = 0;
2121                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2122                         }
2123                 } else {
2124                         if (PHYS_INPUT_BUTTON_INFO(this))
2125                                 CS(this).motd_actived_time = time;
2126                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2127                                 CS(this).motd_actived_time = 0;
2128                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2129                         }
2130                 }
2131         }
2132         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2133         {
2134                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2135                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2136                 else if (CS(this).motd_actived_time == -2)
2137                 {
2138                         // instantly hide MOTD
2139                         CS(this).motd_actived_time = 0;
2140                         if (autocvar_g_campaign)
2141                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2142                         else
2143                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2144                 }
2145                 else if (IS_PLAYER(this) || IS_SPEC(this))
2146                 {
2147                         // FIXME occasionally for some reason MOTD never goes away
2148                         // delay MOTD removal a little bit in the hope it fixes this bug
2149                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2150                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2151                         else //if (CS(this).motd_actived_time < -2)
2152                                 CS(this).motd_actived_time++;
2153                 }
2154         }
2155 }
2156
2157 bool joinAllowed(entity this)
2158 {
2159         if (CS(this).version_mismatch) return false;
2160         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2161         if (!nJoinAllowed(this, this)) return false;
2162         if (teamplay && lockteams) return false;
2163         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2164         if (ShowTeamSelection(this)) return false;
2165         return true;
2166 }
2167
2168 .string shootfromfixedorigin;
2169 .bool dualwielding_prev;
2170 bool PlayerThink(entity this)
2171 {
2172         if (game_stopped || intermission_running) {
2173                 this.modelflags &= ~MF_ROCKET;
2174                 if(intermission_running)
2175                         IntermissionThink(this);
2176                 return false;
2177         }
2178
2179         if (timeout_status == TIMEOUT_ACTIVE) {
2180                 // don't allow the player to turn around while game is paused
2181                 // FIXME turn this into CSQC stuff
2182                 this.v_angle = this.lastV_angle;
2183                 this.angles = this.lastV_angle;
2184                 this.fixangle = true;
2185         }
2186
2187         if (frametime) player_powerups(this);
2188
2189         if (IS_DEAD(this)) {
2190                 if (this.personal && g_race_qualifying) {
2191                         if (time > this.respawn_time) {
2192                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2193                                 respawn(this);
2194                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2195                         }
2196                 } else {
2197                         if (frametime) player_anim(this);
2198
2199                         if (this.respawn_flags & RESPAWN_DENY)
2200                         {
2201                                 STAT(RESPAWN_TIME, this) = 0;
2202                                 return false;
2203                         }
2204
2205                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2206
2207                         switch(this.deadflag)
2208                         {
2209                                 case DEAD_DYING:
2210                                 {
2211                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2212                                                 this.deadflag = DEAD_RESPAWNING;
2213                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2214                                                 this.deadflag = DEAD_DEAD;
2215                                         break;
2216                                 }
2217                                 case DEAD_DEAD:
2218                                 {
2219                                         if (button_pressed)
2220                                                 this.deadflag = DEAD_RESPAWNABLE;
2221                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2222                                                 this.deadflag = DEAD_RESPAWNING;
2223                                         break;
2224                                 }
2225                                 case DEAD_RESPAWNABLE:
2226                                 {
2227                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2228                                                 this.deadflag = DEAD_RESPAWNING;
2229                                         break;
2230                                 }
2231                                 case DEAD_RESPAWNING:
2232                                 {
2233                                         if (time > this.respawn_time)
2234                                         {
2235                                                 this.respawn_time = time + 1; // only retry once a second
2236                                                 this.respawn_time_max = this.respawn_time;
2237                                                 respawn(this);
2238                                         }
2239                                         break;
2240                                 }
2241                         }
2242
2243                         ShowRespawnCountdown(this);
2244
2245                         if (this.respawn_flags & RESPAWN_SILENT)
2246                                 STAT(RESPAWN_TIME, this) = 0;
2247                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2248                         {
2249                                 if (time < this.respawn_time)
2250                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2251                                 else if (this.deadflag != DEAD_RESPAWNING)
2252                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2253                         }
2254                         else
2255                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2256                 }
2257
2258                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2259                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2260                         STAT(RESPAWN_TIME, this) *= -1;
2261
2262                 return false;
2263         }
2264
2265         FixPlayermodel(this);
2266
2267         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2268                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2269                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2270         }
2271
2272         // reset gun alignment when dual wielding status changes
2273         // to ensure guns are always aligned right and left
2274         bool dualwielding = W_DualWielding(this);
2275         if(this.dualwielding_prev != dualwielding)
2276         {
2277                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2278                 this.dualwielding_prev = dualwielding;
2279         }
2280
2281         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2282         //if(frametime)
2283         {
2284                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2285                 {
2286                         .entity weaponentity = weaponentities[slot];
2287                         if(WEP_CVAR(vortex, charge_always))
2288                                 W_Vortex_Charge(this, weaponentity, frametime);
2289                         W_WeaponFrame(this, weaponentity);
2290                 }
2291         }
2292
2293         if (frametime)
2294         {
2295                 // WEAPONTODO: Add a weapon request for this
2296                 // rot vortex charge to the charge limit
2297                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2298                 {
2299                         .entity weaponentity = weaponentities[slot];
2300                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2301                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2302                 }
2303
2304                 player_regen(this);
2305                 player_anim(this);
2306                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2307         }
2308
2309         monsters_setstatus(this);
2310
2311         return true;
2312 }
2313
2314 .bool would_spectate;
2315 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2316 void ObserverOrSpectatorThink(entity this)
2317 {
2318         bool is_spec = IS_SPEC(this);
2319         if ( CS(this).impulse )
2320         {
2321                 int r = MinigameImpulse(this, CS(this).impulse);
2322                 if (!is_spec || r)
2323                         CS(this).impulse = 0;
2324
2325                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2326                 {
2327                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2328                         CS(this).impulse = 0;
2329                         return;
2330                 }
2331         }
2332
2333         if (this.flags & FL_JUMPRELEASED) {
2334                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2335                         this.flags &= ~FL_JUMPRELEASED;
2336                         this.flags |= FL_SPAWNING;
2337                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2338                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2339                         this.flags &= ~FL_JUMPRELEASED;
2340                         if(SpectateNext(this)) {
2341                                 TRANSMUTE(Spectator, this);
2342                         } else if (is_spec) {
2343                                 TRANSMUTE(Observer, this);
2344                                 PutClientInServer(this);
2345                         }
2346                         else
2347                                 this.would_spectate = false; // unable to spectate anyone
2348                         if (is_spec)
2349                                 CS(this).impulse = 0;
2350                 } else if (is_spec) {
2351                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2352                                 this.flags &= ~FL_JUMPRELEASED;
2353                                 if(SpectatePrev(this)) {
2354                                         TRANSMUTE(Spectator, this);
2355                                 } else {
2356                                         TRANSMUTE(Observer, this);
2357                                         PutClientInServer(this);
2358                                 }
2359                                 CS(this).impulse = 0;
2360                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2361                                 this.would_spectate = false;
2362                                 this.flags &= ~FL_JUMPRELEASED;
2363                                 TRANSMUTE(Observer, this);
2364                                 PutClientInServer(this);
2365                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2366                                 PutObserverInServer(this);
2367                                 this.would_spectate = true;
2368                         }
2369                 }
2370                 else {
2371                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2372                         if (PHYS_INPUT_BUTTON_USE(this))
2373                                 wouldclip = !wouldclip;
2374                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2375                         set_movetype(this, preferred_movetype);
2376                 }
2377         } else { // jump pressed
2378                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2379                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2380                         this.flags |= FL_JUMPRELEASED;
2381                         if(this.flags & FL_SPAWNING)
2382                         {
2383                                 this.flags &= ~FL_SPAWNING;
2384                                 if(joinAllowed(this))
2385                                         Join(this);
2386                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2387                                         CS(this).autojoin_checked = -1;
2388                                 return;
2389                         }
2390                 }
2391                 if(is_spec && !SpectateUpdate(this))
2392                         PutObserverInServer(this);
2393         }
2394         if (is_spec)
2395                 this.flags |= FL_CLIENT | FL_NOTARGET;
2396 }
2397
2398 void PlayerUseKey(entity this)
2399 {
2400         if (!IS_PLAYER(this))
2401                 return;
2402
2403         if(this.vehicle)
2404         {
2405                 if(!game_stopped)
2406                 {
2407                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2408                         return;
2409                 }
2410         }
2411         else if(autocvar_g_vehicles_enter)
2412         {
2413                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2414                 {
2415                         entity head, closest_target = NULL;
2416                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2417
2418                         while(head) // find the closest acceptable target to enter
2419                         {
2420                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2421                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2422                                 {
2423                                         if(closest_target)
2424                                         {
2425                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2426                                                 { closest_target = head; }
2427                                         }
2428                                         else { closest_target = head; }
2429                                 }
2430
2431                                 head = head.chain;
2432                         }
2433
2434                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2435                 }
2436         }
2437
2438         // a use key was pressed; call handlers
2439         MUTATOR_CALLHOOK(PlayerUseKey, this);
2440 }
2441
2442
2443 /*
2444 =============
2445 PlayerPreThink
2446
2447 Called every frame for each client before the physics are run
2448 =============
2449 */
2450 .float last_vehiclecheck;
2451 void PlayerPreThink (entity this)
2452 {
2453         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2454         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2455
2456         WarpZone_PlayerPhysics_FixVAngle(this);
2457
2458         if (frametime) {
2459                 // physics frames: update anticheat stuff
2460                 anticheat_prethink(this);
2461
2462                 // WORKAROUND: only use dropclient in server frames (frametime set).
2463                 // Never use it in cl_movement frames (frametime zero).
2464                 if (blockSpectators && IS_REAL_CLIENT(this)
2465                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2466                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2467                 {
2468                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2469                         dropclient(this);
2470                         return;
2471                 }
2472         }
2473
2474         zoomstate_set = false;
2475
2476         // Check for nameless players
2477         if (this.netname == "" || this.netname != CS(this).netname_previous)
2478         {
2479                 bool assume_unchanged = (CS(this).netname_previous == "");
2480                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2481                 {
2482                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2483                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2484                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2485                         assume_unchanged = false;
2486                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2487                 }
2488                 if (isInvisibleString(this.netname))
2489                 {
2490                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2491                         sprint(this, "Warning: invisible names are not allowed.\n");
2492                         assume_unchanged = false;
2493                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2494                 }
2495                 if (!assume_unchanged && autocvar_sv_eventlog)
2496                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2497                 strcpy(CS(this).netname_previous, this.netname);
2498         }
2499
2500         // version nagging
2501         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2502         CS(this).version_nagtime = 0;
2503         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2504             // git client
2505         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2506             // git server
2507             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2508         } else {
2509             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2510             if (r < 0) { // old client
2511                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2512             } else if (r > 0) { // old server
2513                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2514             }
2515         }
2516     }
2517
2518         // GOD MODE info
2519         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2520         {
2521                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2522                 this.max_armorvalue = 0;
2523         }
2524
2525         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2526         {
2527                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2528                 {
2529                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2530                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2531                         if (this.iceblock)
2532                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2533
2534                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2535                                 Unfreeze(this, false);
2536                 }
2537                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2538                 {
2539                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2540                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2541
2542                         if (GetResource(this, RES_HEALTH) < 1)
2543                         {
2544                                 if (this.vehicle)
2545                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2546                                 if(this.event_damage)
2547                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2548                         }
2549                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2550                                 Unfreeze(this, false);
2551                 }
2552         }
2553
2554         MUTATOR_CALLHOOK(PlayerPreThink, this);
2555
2556         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2557         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2558         {
2559                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2560                 {
2561                         if(!it.owner)
2562                         {
2563                                 if(!it.team || SAME_TEAM(this, it))
2564                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2565                                 else if(autocvar_g_vehicles_steal)
2566                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2567                         }
2568                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2569                         {
2570                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2571                         }
2572                 });
2573
2574                 this.last_vehiclecheck = time + 1;
2575         }
2576
2577         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2578         {
2579                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2580                         PlayerUseKey(this);
2581                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2582         }
2583
2584         if (IS_REAL_CLIENT(this))
2585                 PrintWelcomeMessage(this);
2586
2587         if (IS_PLAYER(this)) {
2588                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2589                         error("Client can't be spawned as player on connection!");
2590                 if(!PlayerThink(this))
2591                         return;
2592         }
2593         else if (game_stopped || intermission_running) {
2594                 if(intermission_running)
2595                         IntermissionThink(this);
2596                 return;
2597         }
2598         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2599         {
2600                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2601                 CS(this).autojoin_checked = 1;
2602                 // don't do this in ClientConnect
2603                 // many things can go wrong if a client is spawned as player on connection
2604                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2605                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2606                                 && (!teamplay || autocvar_g_balance_teams)))
2607                 {
2608                         campaign_bots_may_start = true;
2609                         if(joinAllowed(this))
2610                                 Join(this);
2611                         return;
2612                 }
2613         }
2614         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2615                 ObserverOrSpectatorThink(this);
2616         }
2617
2618         // WEAPONTODO: Add weapon request for this
2619         if (!zoomstate_set) {
2620                 bool wep_zoomed = false;
2621                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2622                 {
2623                         .entity weaponentity = weaponentities[slot];
2624                         Weapon thiswep = this.(weaponentity).m_weapon;
2625                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2626                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2627                 }
2628                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2629         }
2630
2631         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2632         {
2633                 CS(this).teamkill_soundtime = 0;
2634
2635                 entity e = CS(this).teamkill_soundsource;
2636                 entity oldpusher = e.pusher;
2637                 e.pusher = this;
2638                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2639                 e.pusher = oldpusher;
2640         }
2641
2642         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2643                 CS(this).taunt_soundtime = 0;
2644                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2645         }
2646
2647         target_voicescript_next(this);
2648 }
2649
2650 void DrownPlayer(entity this)
2651 {
2652         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2653                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2654         {
2655                 STAT(AIR_FINISHED, this) = 0;
2656                 return;
2657         }
2658
2659         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2660         {
2661                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2662                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2663                 STAT(AIR_FINISHED, this) = 0;
2664         }
2665         else
2666         {
2667                 if (!STAT(AIR_FINISHED, this))
2668                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2669                 if (STAT(AIR_FINISHED, this) < time)
2670                 {       // drown!
2671                         if (this.pain_finished < time)
2672                         {
2673                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2674                                 this.pain_finished = time + 0.5;
2675                         }
2676                 }
2677         }
2678 }
2679
2680 .bool move_qcphysics;
2681
2682 void Player_Physics(entity this)
2683 {
2684         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2685
2686         if(!this.move_qcphysics)
2687                 return;
2688
2689         if(!frametime && !CS(this).pm_frametime)
2690                 return;
2691
2692         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2693
2694         CS(this).pm_frametime = 0;
2695 }
2696
2697 /*
2698 =============
2699 PlayerPostThink
2700
2701 Called every frame for each client after the physics are run
2702 =============
2703 */
2704 void PlayerPostThink (entity this)
2705 {
2706         Player_Physics(this);
2707
2708         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2709         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2710         if (IS_REAL_CLIENT(this))
2711         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2712         {
2713                 int totalClients = 0;
2714                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2715                 {
2716                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2717                         {
2718                                 ++totalClients;
2719                         });
2720                 }
2721
2722                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2723                 { /* do nothing */ }
2724                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2725                 {
2726                         if (CS(this).idlekick_lasttimeleft)
2727                         {
2728                                 CS(this).idlekick_lasttimeleft = 0;
2729                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2730                         }
2731                 }
2732                 else
2733                 {
2734                         float maxidle_time = autocvar_sv_maxidle;
2735                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2736                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2737                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2738                         if (timeleft == min(10, maxidle_time - 1)) { // - 1 to support maxidle_time <= 10
2739                                 if (!CS(this).idlekick_lasttimeleft)
2740                                 {
2741                                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2742                                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2743                                         else
2744                                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2745                                 }
2746                         }
2747                         if (timeleft <= 0) {
2748                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2749                                 {
2750                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname);
2751                                         if (this.caplayer)
2752                                                 this.caplayer = 0;
2753                                         PutObserverInServer(this);
2754                                         CS(this).parm_idlesince = time;
2755                                 }
2756                                 else
2757                                 {
2758                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2759                                         dropclient(this);
2760                                 }
2761                                 return;
2762                         }
2763                         else if (timeleft <= 10) {
2764                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2765                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2766                                 CS(this).idlekick_lasttimeleft = timeleft;
2767                         }
2768                 }
2769         }
2770
2771         CheatFrame(this);
2772
2773         if (game_stopped)
2774         {
2775                 this.solid = SOLID_NOT;
2776                 this.takedamage = DAMAGE_NO;
2777                 set_movetype(this, MOVETYPE_NONE);
2778                 CS(this).teamkill_complain = 0;
2779                 CS(this).teamkill_soundtime = 0;
2780                 CS(this).teamkill_soundsource = NULL;
2781         }
2782
2783         if (IS_PLAYER(this)) {
2784                 if(this.death_time == time && IS_DEAD(this))
2785                 {
2786                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2787                         // once all the damage events of this frame have been processed with normal size
2788                         this.maxs.z = 5;
2789                         setsize(this, this.mins, this.maxs);
2790                 }
2791                 DrownPlayer(this);
2792                 UpdateChatBubble(this);
2793                 if (CS(this).impulse) ImpulseCommands(this);
2794                 GetPressedKeys(this);
2795                 if (game_stopped)
2796                 {
2797                         CSQCMODEL_AUTOUPDATE(this);
2798                         return;
2799                 }
2800         }
2801         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2802         {
2803                 CS(this).pressedkeys = 0;
2804                 STAT(PRESSED_KEYS, this) = 0;
2805         }
2806
2807         if (this.waypointsprite_attachedforcarrier) {
2808                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2809                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2810         }
2811
2812         CSQCMODEL_AUTOUPDATE(this);
2813 }
2814
2815 // hack to copy the button fields from the client entity to the Client State
2816 void PM_UpdateButtons(entity this, entity store)
2817 {
2818         if(this.impulse)
2819                 store.impulse = this.impulse;
2820         this.impulse = 0;
2821
2822         bool typing = this.buttonchat || this.button12;
2823
2824         store.button0 = (typing) ? 0 : this.button0;
2825         //button1?!
2826         store.button2 = (typing) ? 0 : this.button2;
2827         store.button3 = (typing) ? 0 : this.button3;
2828         store.button4 = this.button4;
2829         store.button5 = (typing) ? 0 : this.button5;
2830         store.button6 = this.button6;
2831         store.button7 = this.button7;
2832         store.button8 = this.button8;
2833         store.button9 = this.button9;
2834         store.button10 = this.button10;
2835         store.button11 = this.button11;
2836         store.button12 = this.button12;
2837         store.button13 = this.button13;
2838         store.button14 = this.button14;
2839         store.button15 = this.button15;
2840         store.button16 = this.button16;
2841         store.buttonuse = this.buttonuse;
2842         store.buttonchat = this.buttonchat;
2843
2844         store.cursor_active = this.cursor_active;
2845         store.cursor_screen = this.cursor_screen;
2846         store.cursor_trace_start = this.cursor_trace_start;
2847         store.cursor_trace_endpos = this.cursor_trace_endpos;
2848         store.cursor_trace_ent = this.cursor_trace_ent;
2849
2850         store.ping = this.ping;
2851         store.ping_packetloss = this.ping_packetloss;
2852         store.ping_movementloss = this.ping_movementloss;
2853
2854         store.v_angle = this.v_angle;
2855         store.movement = this.movement;
2856 }
2857
2858 NET_HANDLE(fpsreport, bool)
2859 {
2860         int fps = ReadShort();
2861         PlayerScore_Set(sender, SP_FPS, fps);
2862         return true;
2863 }