qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/overkill/oknex.qh>
  25 #include <common/mutators/mutator/waypoints/all.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/physics/player.qh>
  30 #include <common/playerstats.qh>
  31 #include <common/state.qh>
  32 #include <common/stats.qh>
  33 #include <common/vehicles/all.qh>
  34 #include <common/vehicles/sv_vehicles.qh>
  35 #include <common/viewloc.qh>
  36 #include <common/weapons/_all.qh>
  37 #include <common/weapons/weapon/vortex.qh>
  38 #include <common/wepent.qh>
  39 #include <lib/csqcmodel/sv_model.qh>
  40 #include <lib/warpzone/common.qh>
  41 #include <lib/warpzone/server.qh>
  42 #include <server/anticheat.qh>
  43 #include <server/antilag.qh>
  44 #include <server/bot/api.qh>
  45 #include <server/campaign.qh>
  46 #include <server/chat.qh>
  47 #include <server/cheats.qh>
  48 #include <server/clientkill.qh>
  49 #include <server/command/common.qh>
  50 #include <server/command/common.qh>
  51 #include <server/command/vote.qh>
  52 #include <server/compat/quake3.qh>
  53 #include <server/damage.qh>
  54 #include <server/gamelog.qh>
  55 #include <server/handicap.qh>
  56 #include <server/hook.qh>
  57 #include <server/impulse.qh>
  58 #include <server/intermission.qh>
  59 #include <server/ipban.qh>
  60 #include <server/main.qh>
  61 #include <server/mutators/_mod.qh>
  62 #include <server/player.qh>
  63 #include <server/portals.qh>
  64 #include <server/race.qh>
  65 #include <server/resources.qh>
  66 #include <server/scores.qh>
  67 #include <server/scores_rules.qh>
  68 #include <server/spawnpoints.qh>
  69 #include <server/teamplay.qh>
  70 #include <server/weapons/accuracy.qh>
  71 #include <server/weapons/common.qh>
  72 #include <server/weapons/hitplot.qh>
  73 #include <server/weapons/selection.qh>
  74 #include <server/weapons/weaponsystem.qh>
  75 #include <server/world.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         int spec_count = 0;
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 if(spec_count >= MAX_SPECTATORS)
 119                         break;
 120                 WriteByte(MSG_ENTITY, num_for_edict(it));
 121                 ++spec_count;
 122         });
 123 }
 124
 125 bool ClientData_Send(entity this, entity to, int sf)
 126 {
 127         assert(to == this.owner, return false);
 128
 129         entity e = to;
 130         if (IS_SPEC(e)) e = e.enemy;
 131
 132         sf = 0;
 133         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 134         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 135         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 136         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 137
 138         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 139         WriteByte(MSG_ENTITY, sf);
 140
 141         if (sf & BIT(1))
 142                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 143
 144         if(sf & BIT(4))
 145         {
 146                 float specs = CountSpectators(e, to);
 147                 WriteByte(MSG_ENTITY, specs);
 148                 WriteSpectators(e, to);
 149         }
 150
 151         return true;
 152 }
 153
 154 void ClientData_Attach(entity this)
 155 {
 156         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 157         CS(this).clientdata.drawonlytoclient = this;
 158         CS(this).clientdata.owner = this;
 159 }
 160
 161 void ClientData_Detach(entity this)
 162 {
 163         delete(CS(this).clientdata);
 164         CS(this).clientdata = NULL;
 165 }
 166
 167 void ClientData_Touch(entity e)
 168 {
 169         entity cd = CS(e).clientdata;
 170         if (cd) { cd.SendFlags = 1; }
 171
 172         // make it spectatable
 173         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 174         {
 175                 entity cd = CS(it).clientdata;
 176                 if (cd) { cd.SendFlags = 1; }
 177         });
 178 }
 179
 180
 181 /*
 182 =============
 183 CheckPlayerModel
 184
 185 Checks if the argument string can be a valid playermodel.
 186 Returns a valid one in doubt.
 187 =============
 188 */
 189 string FallbackPlayerModel;
 190 string CheckPlayerModel(string plyermodel) {
 191         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 192         {
 193                 // note: we cannot summon Don Strunzone here, some player may
 194                 // still have the model string set. In case anyone manages how
 195                 // to change a cvar default, we'll have a small leak here.
 196                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 197         }
 198         // only in right path
 199         if( substring(plyermodel,0,14) != "models/player/")
 200                 return FallbackPlayerModel;
 201         // only good file extensions
 202         if(substring(plyermodel,-4,4) != ".zym")
 203         if(substring(plyermodel,-4,4) != ".dpm")
 204         if(substring(plyermodel,-4,4) != ".iqm")
 205         if(substring(plyermodel,-4,4) != ".md3")
 206         if(substring(plyermodel,-4,4) != ".psk")
 207                 return FallbackPlayerModel;
 208         // forbid the LOD models
 209         if(substring(plyermodel, -9,5) == "_lod1")
 210                 return FallbackPlayerModel;
 211         if(substring(plyermodel, -9,5) == "_lod2")
 212                 return FallbackPlayerModel;
 213         if(plyermodel != strtolower(plyermodel))
 214                 return FallbackPlayerModel;
 215         // also, restrict to server models
 216         if(autocvar_sv_servermodelsonly)
 217         {
 218                 if(!fexists(plyermodel))
 219                         return FallbackPlayerModel;
 220         }
 221         return plyermodel;
 222 }
 223
 224 void setplayermodel(entity e, string modelname)
 225 {
 226         precache_model(modelname);
 227         _setmodel(e, modelname);
 228         player_setupanimsformodel(e);
 229         if(!autocvar_g_debug_globalsounds)
 230                 UpdatePlayerSounds(e);
 231 }
 232
 233 /** putting a client as observer in the server */
 234 void PutObserverInServer(entity this)
 235 {
 236         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 237         PlayerState_detach(this);
 238
 239         if (IS_PLAYER(this))
 240         {
 241                 if(GetResource(this, RES_HEALTH) >= 1)
 242                 {
 243                         // despawn effect
 244                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 245                 }
 246
 247                 // was a player, recount votes and ready status
 248                 if(IS_REAL_CLIENT(this))
 249                 {
 250                         if (vote_called) { VoteCount(false); }
 251                         ReadyCount();
 252                 }
 253         }
 254
 255         entity spot = SelectSpawnPoint(this, true);
 256         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 257         this.angles = vec2(spot.angles);
 258         this.fixangle = true;
 259         // offset it so that the spectator spawns higher off the ground, looks better this way
 260         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 261         if (IS_REAL_CLIENT(this))
 262         {
 263                 msg_entity = this;
 264                 WriteByte(MSG_ONE, SVC_SETVIEW);
 265                 WriteEntity(MSG_ONE, this);
 266         }
 267         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 268         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 269         if(!autocvar_g_debug_globalsounds)
 270         {
 271                 // needed for player sounds
 272                 this.model = "";
 273                 FixPlayermodel(this);
 274         }
 275         setmodel(this, MDL_Null);
 276         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 277         this.view_ofs = '0 0 0';
 278
 279         RemoveGrapplingHooks(this);
 280         Portal_ClearAll(this);
 281         Unfreeze(this, false);
 282         SetSpectatee(this, NULL);
 283
 284         if (this.alivetime)
 285         {
 286                 if (!warmup_stage)
 287                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 288                 this.alivetime = 0;
 289         }
 290
 291         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 292
 293         WaypointSprite_PlayerDead(this);
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 296                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307         STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_finished = 0;
 334         STAT(STRENGTH_FINISHED, this) = 0;
 335         STAT(INVINCIBLE_FINISHED, this) = 0;
 336         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 337         STAT(AIR_FINISHED, this) = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         UNSET_DUCKED(this);
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350         this.draggable = drag_undraggable;
 351
 352         this.items = 0;
 353         STAT(WEAPONS, this) = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374         this.event_heal = func_null;
 375
 376         for(int slot = 0; slot < MAX_AXH; ++slot)
 377         {
 378                 entity axh = this.(AuxiliaryXhair[slot]);
 379                 this.(AuxiliaryXhair[slot]) = NULL;
 380
 381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 382                         delete(axh);
 383         }
 384
 385         if (mutator_returnvalue)
 386         {
 387                 // mutator prevents resetting teams+score
 388         }
 389         else
 390         {
 391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 392                 this.frags = FRAGS_SPECTATOR;
 393         }
 394         if (CS(this).just_joined)
 395                 CS(this).just_joined = false;
 396 }
 397
 398 int player_getspecies(entity this)
 399 {
 400         get_model_parameters(this.model, this.skin);
 401         int s = get_model_parameters_species;
 402         get_model_parameters(string_null, 0);
 403         if (s < 0) return SPECIES_HUMAN;
 404         return s;
 405 }
 406
 407 .float model_randomizer;
 408 void FixPlayermodel(entity player)
 409 {
 410         string defaultmodel = "";
 411         int defaultskin = 0;
 412         if(autocvar_sv_defaultcharacter)
 413         {
 414                 if(teamplay)
 415                 {
 416                         switch(player.team)
 417                         {
 418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 422                         }
 423                 }
 424
 425                 if(defaultmodel == "")
 426                 {
 427                         defaultmodel = autocvar_sv_defaultplayermodel;
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429                 }
 430
 431                 int n = tokenize_console(defaultmodel);
 432                 if(n > 0)
 433                 {
 434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 435                         // However, do NOT randomize if the player-selected model is in the list.
 436                         for (int i = 0; i < n; ++i)
 437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 438                                         defaultmodel = argv(i);
 439                 }
 440
 441                 int i = strstrofs(defaultmodel, ":", 0);
 442                 if(i >= 0)
 443                 {
 444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 445                         defaultmodel = substring(defaultmodel, 0, i);
 446                 }
 447         }
 448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 449         {
 450                 if(teamplay)
 451                 {
 452                         switch(player.team)
 453                         {
 454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 458                         }
 459                 }
 460
 461                 if(!defaultskin)
 462                         defaultskin = autocvar_sv_defaultplayerskin;
 463         }
 464
 465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 466         defaultmodel = M_ARGV(0, string);
 467         defaultskin = M_ARGV(1, int);
 468
 469         bool chmdl = false;
 470         int oldskin;
 471         if(defaultmodel != "")
 472         {
 473                 if (defaultmodel != player.model)
 474                 {
 475                         vector m1 = player.mins;
 476                         vector m2 = player.maxs;
 477                         setplayermodel (player, defaultmodel);
 478                         setsize (player, m1, m2);
 479                         chmdl = true;
 480                 }
 481
 482                 oldskin = player.skin;
 483                 player.skin = defaultskin;
 484         } else {
 485                 if (player.playermodel != player.model || player.playermodel == "")
 486                 {
 487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, player.playermodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 if(!autocvar_sv_defaultcharacterskin)
 496                 {
 497                         oldskin = player.skin;
 498                         player.skin = stof(player.playerskin);
 499                 }
 500                 else
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = defaultskin;
 504                 }
 505         }
 506
 507         if(chmdl || oldskin != player.skin) // model or skin has changed
 508         {
 509                 player.species = player_getspecies(player); // update species
 510                 if(!autocvar_g_debug_globalsounds)
 511                         UpdatePlayerSounds(player); // update skin sounds
 512         }
 513
 514         if(!teamplay)
 515                 if(strlen(autocvar_sv_defaultplayercolors))
 516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 518 }
 519
 520 void PutPlayerInServer(entity this)
 521 {
 522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 523
 524         PlayerState_attach(this);
 525         accuracy_resend(this);
 526
 527         if (this.team < 0)
 528                 TeamBalance_JoinBestTeam(this);
 529
 530         entity spot = SelectSpawnPoint(this, false);
 531         if (!spot) {
 532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 533                 return; // spawn failed
 534         }
 535
 536         TRANSMUTE(Player, this);
 537
 538         CS(this).wasplayer = true;
 539         this.iscreature = true;
 540         this.teleportable = TELEPORT_NORMAL;
 541         if(!this.damagedbycontents)
 542                 IL_PUSH(g_damagedbycontents, this);
 543         this.damagedbycontents = true;
 544         set_movetype(this, MOVETYPE_WALK);
 545         this.solid = SOLID_SLIDEBOX;
 546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 547         if (autocvar_g_playerclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 551         this.frags = FRAGS_PLAYER;
 552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 554         if (autocvar__notarget)
 555                 this.flags |= FL_NOTARGET;
 556         this.takedamage = DAMAGE_AIM;
 557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 558
 559         if (warmup_stage) {
 560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 566                 SetResource(this, RES_HEALTH, warmup_start_health);
 567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 569         } else {
 570                 SetResource(this, RES_SHELLS, start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, start_health);
 577                 SetResource(this, RES_ARMOR, start_armorvalue);
 578                 STAT(WEAPONS, this) = start_weapons;
 579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 580                 {
 581                         GiveRandomWeapons(this, random_start_weapons_count,
 582                                 autocvar_g_random_start_weapons, random_start_ammo);
 583                 }
 584         }
 585         SetSpectatee_status(this, 0);
 586
 587         PS(this).dual_weapons = '0 0 0';
 588
 589         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 590
 591         this.items = start_items;
 592
 593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 598         if (!sv_ready_restart_after_countdown && time < game_starttime)
 599         {
 600                 float f = game_starttime - time;
 601                 this.spawnshieldtime += f;
 602                 this.pauserotarmor_finished += f;
 603                 this.pauserothealth_finished += f;
 604                 this.pauseregen_finished += f;
 605         }
 606
 607         this.damageforcescale = autocvar_g_player_damageforcescale;
 608         this.death_time = 0;
 609         this.respawn_flags = 0;
 610         this.respawn_time = 0;
 611         STAT(RESPAWN_TIME, this) = 0;
 612         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 613         this.fade_time = 0;
 614         this.pain_finished = 0;
 615         this.pushltime = 0;
 616         setthink(this, func_null); // players have no think function
 617         this.nextthink = 0;
 618         this.dmg_team = 0;
 619         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 620
 621         this.deadflag = DEAD_NO;
 622
 623         this.angles = spot.angles;
 624         this.angles_z = 0; // never spawn tilted even if the spot says to
 625         if (IS_BOT_CLIENT(this))
 626         {
 627                 this.v_angle = this.angles;
 628                 bot_aim_reset(this);
 629         }
 630         this.fixangle = true; // turn this way immediately
 631         this.oldvelocity = this.velocity = '0 0 0';
 632         this.avelocity = '0 0 0';
 633         this.punchangle = '0 0 0';
 634         this.punchvector = '0 0 0';
 635
 636         STAT(STRENGTH_FINISHED, this) = 0;
 637         STAT(INVINCIBLE_FINISHED, this) = 0;
 638         this.fire_endtime = -1;
 639         STAT(REVIVE_PROGRESS, this) = 0;
 640         this.revival_time = 0;
 641
 642         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 643         STAT(BUFFS, this) = 0;
 644         STAT(BUFF_TIME, this) = 0;
 645
 646         STAT(AIR_FINISHED, this) = 0;
 647         this.waterlevel = WATERLEVEL_NONE;
 648         this.watertype = CONTENT_EMPTY;
 649
 650         entity spawnevent = new_pure(spawnevent);
 651         spawnevent.owner = this;
 652         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 653
 654         // Cut off any still running player sounds.
 655         stopsound(this, CH_PLAYER_SINGLE);
 656
 657         this.model = "";
 658         FixPlayermodel(this);
 659         this.drawonlytoclient = NULL;
 660
 661         this.viewloc = NULL;
 662
 663         for(int slot = 0; slot < MAX_AXH; ++slot)
 664         {
 665                 entity axh = this.(AuxiliaryXhair[slot]);
 666                 this.(AuxiliaryXhair[slot]) = NULL;
 667
 668                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 669                         delete(axh);
 670         }
 671
 672         this.spawnpoint_targ = NULL;
 673
 674         UNSET_DUCKED(this);
 675         this.view_ofs = STAT(PL_VIEW_OFS, this);
 676         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 677         this.spawnorigin = spot.origin;
 678         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 679         // don't reset back to last position, even if new position is stuck in solid
 680         this.oldorigin = this.origin;
 681         if(this.conveyor)
 682                 IL_REMOVE(g_conveyed, this);
 683         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 684         if(this.swampslug)
 685                 IL_REMOVE(g_swamped, this);
 686         this.swampslug = NULL;
 687         this.swamp_interval = 0;
 688         if(this.ladder_entity)
 689                 IL_REMOVE(g_ladderents, this);
 690         this.ladder_entity = NULL;
 691         IL_EACH(g_counters, it.realowner == this,
 692         {
 693                 delete(it);
 694         });
 695         STAT(HUD, this) = HUD_NORMAL;
 696
 697         this.event_damage = PlayerDamage;
 698         this.event_heal = PlayerHeal;
 699
 700         this.draggable = func_null;
 701
 702         if(!this.bot_attack)
 703                 IL_PUSH(g_bot_targets, this);
 704         this.bot_attack = true;
 705         if(!this.monster_attack)
 706                 IL_PUSH(g_monster_targets, this);
 707         this.monster_attack = true;
 708         navigation_dynamicgoal_init(this, false);
 709
 710         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 711
 712         // player was spectator
 713         if (CS(this).killcount == FRAGS_SPECTATOR) {
 714                 PlayerScore_Clear(this);
 715                 CS(this).killcount = 0;
 716                 CS(this).startplaytime = time;
 717         }
 718
 719         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 720         {
 721                 .entity weaponentity = weaponentities[slot];
 722                 CL_SpawnWeaponentity(this, weaponentity);
 723         }
 724         this.alpha = default_player_alpha;
 725         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 726         this.exteriorweaponentity.alpha = default_weapon_alpha;
 727
 728         this.speedrunning = false;
 729
 730         this.counter_cnt = 0;
 731         this.fragsfilter_cnt = 0;
 732
 733         target_voicescript_clear(this);
 734
 735         // reset fields the weapons may use
 736         FOREACH(Weapons, true, {
 737                 it.wr_resetplayer(it, this);
 738                         // reload all reloadable weapons
 739                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 740                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741                         {
 742                                 .entity weaponentity = weaponentities[slot];
 743                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 744                         }
 745                 }
 746         });
 747
 748         {
 749                 string s = spot.target;
 750                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 751                         spot.target = string_null;
 752                 SUB_UseTargets(spot, this, NULL);
 753                 if(g_assault || g_race)
 754                         spot.target = s;
 755         }
 756
 757         Unfreeze(this, false);
 758
 759         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 760
 761         if (autocvar_spawn_debug)
 762         {
 763                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 764                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 765         }
 766
 767         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 768         {
 769                 .entity weaponentity = weaponentities[slot];
 770                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 771                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 772                 else
 773                         this.(weaponentity).m_switchweapon = WEP_Null;
 774                 this.(weaponentity).m_weapon = WEP_Null;
 775                 this.(weaponentity).weaponname = "";
 776                 this.(weaponentity).m_switchingweapon = WEP_Null;
 777                 this.(weaponentity).cnt = -1;
 778         }
 779
 780         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 781
 782         if (CS(this).impulse) ImpulseCommands(this);
 783
 784         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 785         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 786         {
 787                 .entity weaponentity = weaponentities[slot];
 788                 W_WeaponFrame(this, weaponentity);
 789         }
 790
 791         if (!warmup_stage && !this.alivetime)
 792                 this.alivetime = time;
 793
 794         antilag_clear(this, CS(this));
 795 }
 796
 797 /** Called when a client spawns in the server */
 798 void PutClientInServer(entity this)
 799 {
 800         if (IS_BOT_CLIENT(this)) {
 801                 TRANSMUTE(Player, this);
 802         } else if (IS_REAL_CLIENT(this)) {
 803                 msg_entity = this;
 804                 WriteByte(MSG_ONE, SVC_SETVIEW);
 805                 WriteEntity(MSG_ONE, this);
 806         }
 807         if (game_stopped)
 808                 TRANSMUTE(Observer, this);
 809
 810         SetSpectatee(this, NULL);
 811
 812         // reset player keys
 813         if(PS(this))
 814                 PS(this).itemkeys = 0;
 815
 816         MUTATOR_CALLHOOK(PutClientInServer, this);
 817
 818         if (IS_OBSERVER(this)) {
 819                 PutObserverInServer(this);
 820         } else if (IS_PLAYER(this)) {
 821                 PutPlayerInServer(this);
 822         }
 823 }
 824
 825 // TODO do we need all these fields, or should we stop autodetecting runtime
 826 // changes and just have a console command to update this?
 827 bool ClientInit_SendEntity(entity this, entity to, int sf)
 828 {
 829         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 830         return = true;
 831         msg_entity = to;
 832         // MSG_INIT replacement
 833         // TODO: make easier to use
 834         Registry_send_all();
 835         W_PROP_reload(MSG_ONE, to);
 836         ClientInit_misc(this);
 837         MUTATOR_CALLHOOK(Ent_Init);
 838 }
 839 void ClientInit_misc(entity this)
 840 {
 841         int channel = MSG_ONE;
 842         WriteHeader(channel, ENT_CLIENT_INIT);
 843         WriteByte(channel, g_nexball_meter_period * 32);
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 845         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 852
 853         if(autocvar_sv_foginterval && world.fog != "")
 854                 WriteString(channel, world.fog);
 855         else
 856                 WriteString(channel, "");
 857         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 858         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 859         WriteByte(channel, serverflags);
 860         WriteCoord(channel, autocvar_g_trueaim_minrange);
 861 }
 862
 863 void ClientInit_CheckUpdate(entity this)
 864 {
 865         this.nextthink = time;
 866         if(this.count != autocvar_g_balance_armor_blockpercent)
 867         {
 868                 this.count = autocvar_g_balance_armor_blockpercent;
 869                 this.SendFlags |= 1;
 870         }
 871         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 872         {
 873                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 874                 this.SendFlags |= 1;
 875         }
 876 }
 877
 878 void ClientInit_Spawn()
 879 {
 880         entity e = new_pure(clientinit);
 881         setthink(e, ClientInit_CheckUpdate);
 882         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 883
 884         ClientInit_CheckUpdate(e);
 885 }
 886
 887 /*
 888 =============
 889 SetNewParms
 890 =============
 891 */
 892 void SetNewParms ()
 893 {
 894         // initialize parms for a new player
 895         parm1 = -(86400 * 366);
 896
 897         MUTATOR_CALLHOOK(SetNewParms);
 898 }
 899
 900 /*
 901 =============
 902 SetChangeParms
 903 =============
 904 */
 905 void SetChangeParms (entity this)
 906 {
 907         // save parms for level change
 908         parm1 = CS(this).parm_idlesince - time;
 909
 910         MUTATOR_CALLHOOK(SetChangeParms);
 911 }
 912
 913 /*
 914 =============
 915 DecodeLevelParms
 916 =============
 917 */
 918 void DecodeLevelParms(entity this)
 919 {
 920         // load parms
 921         CS(this).parm_idlesince = parm1;
 922         if (CS(this).parm_idlesince == -(86400 * 366))
 923                 CS(this).parm_idlesince = time;
 924
 925         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 926         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 927
 928         MUTATOR_CALLHOOK(DecodeLevelParms);
 929 }
 930
 931 void FixClientCvars(entity e)
 932 {
 933         // send prediction settings to the client
 934         stuffcmd(e, "\nin_bindmap 0 0\n");
 935         if(autocvar_g_antilag == 3) // client side hitscan
 936                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 937         if(autocvar_sv_gentle)
 938                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 939
 940         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 941         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 942
 943         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 944
 945         MUTATOR_CALLHOOK(FixClientCvars, e);
 946 }
 947
 948 bool findinlist_abbrev(string tofind, string list)
 949 {
 950         if(list == "" || tofind == "")
 951                 return false; // empty list or search, just return
 952
 953         // this function allows abbreviated strings!
 954         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 955         {
 956                 return true;
 957         });
 958
 959         return false;
 960 }
 961
 962 bool PlayerInIPList(entity p, string iplist)
 963 {
 964         // some safety checks (never allow local?)
 965         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 966                 return false;
 967
 968         return findinlist_abbrev(p.netaddress, iplist);
 969 }
 970
 971 bool PlayerInIDList(entity p, string idlist)
 972 {
 973         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 974         if(!p.crypto_idfp)
 975                 return false;
 976
 977         return findinlist_abbrev(p.crypto_idfp, idlist);
 978 }
 979
 980 bool PlayerInList(entity player, string list)
 981 {
 982         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 983 }
 984
 985 #ifdef DP_EXT_PRECONNECT
 986 /*
 987 =============
 988 ClientPreConnect
 989
 990 Called once (not at each match start) when a client begins a connection to the server
 991 =============
 992 */
 993 void ClientPreConnect(entity this)
 994 {
 995         if(autocvar_sv_eventlog)
 996         {
 997                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 998                         this.playerid,
 999                         etof(this),
1000                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1001                 ));
1002         }
1003 }
1004 #endif
1005
1006 string GetClientVersionMessage(entity this)
1007 {
1008         if (CS(this).version_mismatch) {
1009                 if(CS(this).version < autocvar_gameversion) {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1012                 } else {
1013                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1014                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1015                 }
1016         } else {
1017                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1018         }
1019 }
1020
1021 string getwelcomemessage(entity this)
1022 {
1023         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1024         string modifications = M_ARGV(0, string);
1025
1026         if(g_weaponarena)
1027         {
1028                 if(g_weaponarena_random)
1029                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1030                 else
1031                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1032         }
1033         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1034                 modifications = strcat(modifications, ", No start weapons");
1035         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1036                 modifications = strcat(modifications, ", Low gravity");
1037         if(g_weapon_stay && !g_cts)
1038                 modifications = strcat(modifications, ", Weapons stay");
1039         if(autocvar_g_jetpack)
1040                 modifications = strcat(modifications, ", Jet pack");
1041         if(autocvar_g_powerups == 0)
1042                 modifications = strcat(modifications, ", No powerups");
1043         if(autocvar_g_powerups > 0)
1044                 modifications = strcat(modifications, ", Powerups");
1045         modifications = substring(modifications, 2, strlen(modifications) - 2);
1046
1047         string versionmessage = GetClientVersionMessage(this);
1048         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1049
1050         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1051
1052         if(modifications != "")
1053                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1054
1055         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1056         {
1057                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1058                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1059         }
1060
1061         if (cache_mutatormsg != "") {
1062                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1063         }
1064
1065         string mutator_msg = "";
1066         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1067         mutator_msg = M_ARGV(0, string);
1068
1069         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1070
1071         string motd = autocvar_sv_motd;
1072         if (motd != "") {
1073                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1074         }
1075         return s;
1076 }
1077
1078 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1079
1080 /**
1081 =============
1082 ClientConnect
1083
1084 Called when a client connects to the server
1085 =============
1086 */
1087 void ClientConnect(entity this)
1088 {
1089         if (Ban_MaybeEnforceBanOnce(this)) return;
1090         assert(!IS_CLIENT(this), return);
1091         this.flags |= FL_CLIENT;
1092         assert(player_count >= 0, player_count = 0);
1093
1094         TRANSMUTE(Client, this);
1095         CS(this).version_nagtime = time + 10 + random() * 10;
1096
1097         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1098
1099         bot_clientconnect(this);
1100
1101         Player_DetermineForcedTeam(this);
1102
1103         TRANSMUTE(Observer, this);
1104
1105         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1106
1107         // always track bots, don't ask for cl_allow_uidtracking
1108         if (IS_BOT_CLIENT(this))
1109                 PlayerStats_GameReport_AddPlayer(this);
1110         else
1111                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1112
1113         if (autocvar_sv_eventlog)
1114                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1115
1116         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1117
1118         stuffcmd(this, clientstuff, "\n");
1119         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1120
1121         FixClientCvars(this);
1122
1123         // get version info from player
1124         stuffcmd(this, "cmd clientversion $gameversion\n");
1125
1126         // notify about available teams
1127         if (teamplay)
1128         {
1129                 entity balance = TeamBalance_CheckAllowedTeams(this);
1130                 int t = TeamBalance_GetAllowedTeams(balance);
1131                 TeamBalance_Destroy(balance);
1132                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1133         }
1134         else
1135         {
1136                 stuffcmd(this, "set _teams_available 0\n");
1137         }
1138
1139         bot_relinkplayerlist();
1140
1141         CS(this).spectatortime = time;
1142         if (blockSpectators)
1143         {
1144                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1145         }
1146
1147         CS(this).jointime = time;
1148
1149         if (IS_REAL_CLIENT(this))
1150         {
1151                 if (g_weaponarena_weapons == WEPSET(TUBA))
1152                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1153         }
1154
1155         if (!autocvar_sv_foginterval && world.fog != "")
1156                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1157
1158         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1159                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1160                         send_CSQC_teamnagger();
1161
1162         CSQCMODEL_AUTOINIT(this);
1163
1164         CS(this).model_randomizer = random();
1165
1166         if (IS_REAL_CLIENT(this))
1167                 sv_notice_join(this);
1168
1169         this.move_qcphysics = autocvar_sv_qcphysics;
1170
1171         // update physics stats (players can spawn before physics runs)
1172         Physics_UpdateStats(this);
1173
1174         IL_EACH(g_initforplayer, it.init_for_player, {
1175                 it.init_for_player(it, this);
1176         });
1177
1178         Handicap_Initialize(this);
1179
1180         MUTATOR_CALLHOOK(ClientConnect, this);
1181
1182         if (IS_REAL_CLIENT(this))
1183         {
1184                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1185                 {
1186                         CS(this).motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1188                 }
1189         }
1190 }
1191 /*
1192 =============
1193 ClientDisconnect
1194
1195 Called when a client disconnects from the server
1196 =============
1197 */
1198 .entity chatbubbleentity;
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216         MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         IL_EACH(g_counters, it.realowner == this,
1236         {
1237                 delete(it);
1238         });
1239
1240         WaypointSprite_PlayerGone(this);
1241
1242         bot_relinkplayerlist();
1243
1244         strfree(this.clientstatus);
1245         if (this.personal) delete(this.personal);
1246
1247         this.playerid = 0;
1248         ReadyCount();
1249         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1250
1251         ONREMOVE(this);
1252 }
1253
1254 void ChatBubbleThink(entity this)
1255 {
1256         this.nextthink = time;
1257         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1258         {
1259                 if(this.owner) // but why can that ever be NULL?
1260                         this.owner.chatbubbleentity = NULL;
1261                 delete(this);
1262                 return;
1263         }
1264
1265         this.mdl = "";
1266
1267         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1268         {
1269                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1270                         this.mdl = "models/sprites/minigame_busy.iqm";
1271                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1272                         this.mdl = "models/misc/chatbubble.spr";
1273         }
1274
1275         if ( this.model != this.mdl )
1276                 _setmodel(this, this.mdl);
1277
1278 }
1279
1280 void UpdateChatBubble(entity this)
1281 {
1282         if (this.alpha < 0)
1283                 return;
1284         // spawn a chatbubble entity if needed
1285         if (!this.chatbubbleentity)
1286         {
1287                 this.chatbubbleentity = new(chatbubbleentity);
1288                 this.chatbubbleentity.owner = this;
1289                 this.chatbubbleentity.exteriormodeltoclient = this;
1290                 setthink(this.chatbubbleentity, ChatBubbleThink);
1291                 this.chatbubbleentity.nextthink = time;
1292                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1293                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1294                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1295                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1296                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1297                 //this.chatbubbleentity.model = "";
1298                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1299         }
1300 }
1301
1302 void calculate_player_respawn_time(entity this)
1303 {
1304         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1305                 return;
1306
1307         float gametype_setting_tmp;
1308         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1309         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1310         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1311         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1312         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1313         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1314
1315         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1316         if (teamplay)
1317         {
1318                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1319                         if(it.team == this.team)
1320                                 ++pcount;
1321                 });
1322                 if (sdelay_small_count == 0)
1323                         sdelay_small_count = 1;
1324                 if (sdelay_large_count == 0)
1325                         sdelay_large_count = 1;
1326         }
1327         else
1328         {
1329                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1330                         ++pcount;
1331                 });
1332                 if (sdelay_small_count == 0)
1333                 {
1334                         if (IS_INDEPENDENT_PLAYER(this))
1335                         {
1336                                 // Players play independently. No point in requiring enemies.
1337                                 sdelay_small_count = 1;
1338                         }
1339                         else
1340                         {
1341                                 // Players play AGAINST each other. Enemies required.
1342                                 sdelay_small_count = 2;
1343                         }
1344                 }
1345                 if (sdelay_large_count == 0)
1346                 {
1347                         if (IS_INDEPENDENT_PLAYER(this))
1348                         {
1349                                 // Players play independently. No point in requiring enemies.
1350                                 sdelay_large_count = 1;
1351                         }
1352                         else
1353                         {
1354                                 // Players play AGAINST each other. Enemies required.
1355                                 sdelay_large_count = 2;
1356                         }
1357                 }
1358         }
1359
1360         float sdelay;
1361
1362         if (pcount <= sdelay_small_count)
1363                 sdelay = sdelay_small;
1364         else if (pcount >= sdelay_large_count)
1365                 sdelay = sdelay_large;
1366         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1367                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1368
1369         if(waves)
1370                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1371         else
1372                 this.respawn_time = time + sdelay;
1373
1374         if(sdelay < sdelay_max)
1375                 this.respawn_time_max = time + sdelay_max;
1376         else
1377                 this.respawn_time_max = this.respawn_time;
1378
1379         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1380                 this.respawn_countdown = 10; // first number to count down from is 10
1381         else
1382                 this.respawn_countdown = -1; // do not count down
1383
1384         if(autocvar_g_forced_respawn)
1385                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1386 }
1387
1388 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1389 // added to the model skins
1390 /*void UpdateColorModHack()
1391 {
1392         float c;
1393         c = this.clientcolors & 15;
1394         // LordHavoc: only bothering to support white, green, red, yellow, blue
1395              if (!teamplay) this.colormod = '0 0 0';
1396         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1397         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1398         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1399         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1400         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1401         else this.colormod = '1 1 1';
1402 }*/
1403
1404 void respawn(entity this)
1405 {
1406         bool damagedbycontents_prev = this.damagedbycontents;
1407         if(this.alpha >= 0)
1408         {
1409                 if(autocvar_g_respawn_ghosts)
1410                 {
1411                         this.solid = SOLID_NOT;
1412                         this.takedamage = DAMAGE_NO;
1413                         this.damagedbycontents = false;
1414                         set_movetype(this, MOVETYPE_FLY);
1415                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1416                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1417                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1418                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1419                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1420                         if(autocvar_g_respawn_ghosts_time > 0)
1421                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1422                 }
1423                 else
1424                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1425         }
1426
1427         CopyBody(this, 1);
1428         this.damagedbycontents = damagedbycontents_prev;
1429
1430         this.effects |= EF_NODRAW; // prevent another CopyBody
1431         PutClientInServer(this);
1432 }
1433
1434 void play_countdown(entity this, float finished, Sound samp)
1435 {
1436         TC(Sound, samp);
1437         if(IS_REAL_CLIENT(this))
1438                 if(floor(finished - time - frametime) != floor(finished - time))
1439                         if(finished - time < 6)
1440                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1441 }
1442
1443 void player_powerups(entity this)
1444 {
1445         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1446                 this.modelflags |= MF_ROCKET;
1447         else
1448                 this.modelflags &= ~MF_ROCKET;
1449
1450         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1451
1452         if (IS_DEAD(this))
1453         {
1454                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1455                 {
1456                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1457                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1458                         this.items &= ~ITEM_Strength.m_itemid;
1459                         this.items &= ~ITEM_Shield.m_itemid;
1460                         this.items -= (this.items & IT_SUPERWEAPON);
1461                 }
1462         }
1463
1464         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1465                 return;
1466
1467         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1468         int items_prev = this.items;
1469
1470         Fire_ApplyDamage(this);
1471         Fire_ApplyEffect(this);
1472
1473         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1474         {
1475                 if (this.items & ITEM_Strength.m_itemid)
1476                 {
1477                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1478                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1479                         if (time > STAT(STRENGTH_FINISHED, this))
1480                         {
1481                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1482                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1483                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1484                         }
1485                 }
1486                 else
1487                 {
1488                         if (time < STAT(STRENGTH_FINISHED, this))
1489                         {
1490                                 this.items = this.items | ITEM_Strength.m_itemid;
1491                                 if(!g_cts)
1492                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1493                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1494                         }
1495                 }
1496                 if (this.items & ITEM_Shield.m_itemid)
1497                 {
1498                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1499                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1500                         if (time > STAT(INVINCIBLE_FINISHED, this))
1501                         {
1502                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1503                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1505                         }
1506                 }
1507                 else
1508                 {
1509                         if (time < STAT(INVINCIBLE_FINISHED, this))
1510                         {
1511                                 this.items = this.items | ITEM_Shield.m_itemid;
1512                                 if(!g_cts)
1513                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1514                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1515                         }
1516                 }
1517                 if (this.items & IT_SUPERWEAPON)
1518                 {
1519                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1520                         {
1521                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1522                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1523                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1525                         }
1526                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1527                         {
1528                                 // don't let them run out
1529                         }
1530                         else
1531                         {
1532                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1533                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1534                                 {
1535                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1536                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1537                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1538                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1539                                 }
1540                         }
1541                 }
1542                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1543                 {
1544                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1545                         {
1546                                 this.items = this.items | IT_SUPERWEAPON;
1547                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1548                                 {
1549                                         if(!g_cts)
1550                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1551                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1552                                 }
1553                         }
1554                         else
1555                         {
1556                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1557                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1558                         }
1559                 }
1560                 else
1561                 {
1562                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1563                 }
1564         }
1565
1566         if(autocvar_g_nodepthtestplayers)
1567                 this.effects = this.effects | EF_NODEPTHTEST;
1568
1569         if(autocvar_g_fullbrightplayers)
1570                 this.effects = this.effects | EF_FULLBRIGHT;
1571
1572         if (time >= game_starttime)
1573         if (time < this.spawnshieldtime)
1574                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1575
1576         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1577 }
1578
1579 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1580 {
1581         if(current > stable)
1582                 return current;
1583         else if(current > stable - 0.25) // when close enough, "snap"
1584                 return stable;
1585         else
1586                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1587 }
1588
1589 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1590 {
1591         if(current < stable)
1592                 return current;
1593         else if(current < stable + 0.25) // when close enough, "snap"
1594                 return stable;
1595         else
1596                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1597 }
1598
1599 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1600 {
1601         float old = GetResource(this, res);
1602         float current = old;
1603         if(current > rotstable)
1604         {
1605                 if(rotframetime > 0)
1606                 {
1607                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1608                         current = max(rotstable, current - rotlinear * rotframetime);
1609                 }
1610         }
1611         else if(current < regenstable)
1612         {
1613                 if(regenframetime > 0)
1614                 {
1615                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1616                         current = min(regenstable, current + regenlinear * regenframetime);
1617                 }
1618         }
1619
1620         float limit = GetResourceLimit(this, res) * limit_mod;
1621         if(current > limit)
1622                 current = limit;
1623
1624         if (current != old)
1625                 SetResource(this, res, current);
1626 }
1627
1628 void player_regen(entity this)
1629 {
1630         float max_mod, regen_mod, rot_mod, limit_mod;
1631         max_mod = regen_mod = rot_mod = limit_mod = 1;
1632
1633         float regen_health = autocvar_g_balance_health_regen;
1634         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1635         float regen_health_rot = autocvar_g_balance_health_rot;
1636         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1637         float regen_health_stable = autocvar_g_balance_health_regenstable;
1638         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1639         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1640                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1641         max_mod = M_ARGV(1, float);
1642         regen_mod = M_ARGV(2, float);
1643         rot_mod = M_ARGV(3, float);
1644         limit_mod = M_ARGV(4, float);
1645         regen_health = M_ARGV(5, float);
1646         regen_health_linear = M_ARGV(6, float);
1647         regen_health_rot = M_ARGV(7, float);
1648         regen_health_rotlinear = M_ARGV(8, float);
1649         regen_health_stable = M_ARGV(9, float);
1650         regen_health_rotstable = M_ARGV(10, float);
1651
1652         if(!mutator_returnvalue)
1653         if(!STAT(FROZEN, this))
1654         {
1655                 float maxa = autocvar_g_balance_armor_rotstable;
1656                 float mina = autocvar_g_balance_armor_regenstable;
1657
1658                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1659                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1660                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1661
1662                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1663                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1664                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1665         }
1666
1667         // if player rotted to death...  die!
1668         // check this outside above checks, as player may still be able to rot to death
1669         if(GetResource(this, RES_HEALTH) < 1)
1670         {
1671                 if(this.vehicle)
1672                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1673                 if(this.event_damage)
1674                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1675         }
1676
1677         if (!(this.items & IT_UNLIMITED_AMMO))
1678         {
1679                 float maxf = autocvar_g_balance_fuel_rotstable;
1680                 float minf = autocvar_g_balance_fuel_regenstable;
1681
1682                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1683                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1684                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1685         }
1686 }
1687
1688 bool zoomstate_set;
1689 void SetZoomState(entity this, float newzoom)
1690 {
1691         if(newzoom != CS(this).zoomstate)
1692         {
1693                 CS(this).zoomstate = newzoom;
1694                 ClientData_Touch(this);
1695         }
1696         zoomstate_set = true;
1697 }
1698
1699 void GetPressedKeys(entity this)
1700 {
1701         MUTATOR_CALLHOOK(GetPressedKeys, this);
1702         int keys = STAT(PRESSED_KEYS, this);
1703         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1704         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1705         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1706         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1707
1708         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1709         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1710         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1711         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1712         CS(this).pressedkeys = keys; // store for other users
1713
1714         STAT(PRESSED_KEYS, this) = keys;
1715 }
1716
1717 /*
1718 ======================
1719 spectate mode routines
1720 ======================
1721 */
1722
1723 void SpectateCopy(entity this, entity spectatee)
1724 {
1725         TC(Client, this); TC(Client, spectatee);
1726
1727         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1728         PS(this) = PS(spectatee);
1729         this.armortype = spectatee.armortype;
1730         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1731         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1732         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1733         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1734         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1735         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1736         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1737         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1738         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1739         CS(this).impulse = 0;
1740         this.disableclientprediction = 1; // no need to run prediction on a spectator
1741         this.items = spectatee.items;
1742         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1743         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1744         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1745         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1746         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1747         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1748         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1749         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1750         this.punchangle = spectatee.punchangle;
1751         this.view_ofs = spectatee.view_ofs;
1752         this.velocity = spectatee.velocity;
1753         this.dmg_take = spectatee.dmg_take;
1754         this.dmg_save = spectatee.dmg_save;
1755         this.dmg_inflictor = spectatee.dmg_inflictor;
1756         this.v_angle = spectatee.v_angle;
1757         this.angles = spectatee.v_angle;
1758         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1759         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1760         this.viewloc = spectatee.viewloc;
1761         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1762                 this.fixangle = true;
1763         setorigin(this, spectatee.origin);
1764         setsize(this, spectatee.mins, spectatee.maxs);
1765         SetZoomState(this, CS(spectatee).zoomstate);
1766
1767     anticheat_spectatecopy(this, spectatee);
1768         STAT(HUD, this) = STAT(HUD, spectatee);
1769         if(spectatee.vehicle)
1770     {
1771         this.angles = spectatee.v_angle;
1772
1773         //this.fixangle = false;
1774         //this.velocity = spectatee.vehicle.velocity;
1775         this.vehicle_health = spectatee.vehicle_health;
1776         this.vehicle_shield = spectatee.vehicle_shield;
1777         this.vehicle_energy = spectatee.vehicle_energy;
1778         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1779         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1780         this.vehicle_reload1 = spectatee.vehicle_reload1;
1781         this.vehicle_reload2 = spectatee.vehicle_reload2;
1782
1783         //msg_entity = this;
1784
1785        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1786             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1787            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1788            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1789
1790         //WriteByte (MSG_ONE, SVC_SETVIEW);
1791         //    WriteEntity(MSG_ONE, this);
1792         //makevectors(spectatee.v_angle);
1793         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1794     }
1795 }
1796
1797 bool SpectateUpdate(entity this)
1798 {
1799         if(!this.enemy)
1800                 return false;
1801
1802         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1803         {
1804                 SetSpectatee(this, NULL);
1805                 return false;
1806         }
1807
1808         SpectateCopy(this, this.enemy);
1809
1810         return true;
1811 }
1812
1813 bool SpectateSet(entity this)
1814 {
1815         if(!IS_PLAYER(this.enemy))
1816                 return false;
1817
1818         ClientData_Touch(this.enemy);
1819
1820         msg_entity = this;
1821         WriteByte(MSG_ONE, SVC_SETVIEW);
1822         WriteEntity(MSG_ONE, this.enemy);
1823         set_movetype(this, MOVETYPE_NONE);
1824         accuracy_resend(this);
1825
1826         if(!SpectateUpdate(this))
1827                 PutObserverInServer(this);
1828
1829         return true;
1830 }
1831
1832 void SetSpectatee_status(entity this, int spectatee_num)
1833 {
1834         int oldspectatee_status = CS(this).spectatee_status;
1835         CS(this).spectatee_status = spectatee_num;
1836
1837         if (CS(this).spectatee_status != oldspectatee_status)
1838         {
1839                 if (STAT(PRESSED_KEYS, this))
1840                 {
1841                         CS(this).pressedkeys = 0;
1842                         STAT(PRESSED_KEYS, this) = 0;
1843                 }
1844                 ClientData_Touch(this);
1845                 if (g_race || g_cts) race_InitSpectator();
1846         }
1847 }
1848
1849 void SetSpectatee(entity this, entity spectatee)
1850 {
1851         if(IS_BOT_CLIENT(this))
1852                 return; // bots abuse .enemy, this code is useless to them
1853
1854         entity old_spectatee = this.enemy;
1855
1856         this.enemy = spectatee;
1857
1858         // WEAPONTODO
1859         // these are required to fix the spectator bug with arc
1860         if(old_spectatee)
1861         {
1862                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863                 {
1864                         .entity weaponentity = weaponentities[slot];
1865                         if(old_spectatee.(weaponentity).arc_beam)
1866                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1867                 }
1868         }
1869         if(this.enemy)
1870         {
1871                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1872                 {
1873                         .entity weaponentity = weaponentities[slot];
1874                         if(this.enemy.(weaponentity).arc_beam)
1875                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1876                 }
1877         }
1878
1879         if (this.enemy)
1880                 SetSpectatee_status(this, etof(this.enemy));
1881
1882         // needed to update spectator list
1883         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1884 }
1885
1886 bool Spectate(entity this, entity pl)
1887 {
1888         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1889                 return false;
1890         pl = M_ARGV(1, entity);
1891
1892         SetSpectatee(this, pl);
1893         return SpectateSet(this);
1894 }
1895
1896 bool SpectateNext(entity this)
1897 {
1898         entity ent = find(this.enemy, classname, STR_PLAYER);
1899
1900         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1901                 ent = M_ARGV(1, entity);
1902         else if (!ent)
1903                 ent = find(ent, classname, STR_PLAYER);
1904
1905         if(ent) { SetSpectatee(this, ent); }
1906
1907         return SpectateSet(this);
1908 }
1909
1910 bool SpectatePrev(entity this)
1911 {
1912         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1913         entity ent = findchain(classname, STR_PLAYER);
1914         if (!ent) // no player
1915                 return false;
1916
1917         entity first = ent;
1918         // skip players until current spectated player
1919         if(this.enemy)
1920         while(ent && ent != this.enemy)
1921                 ent = ent.chain;
1922
1923         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1924         {
1925                 case MUT_SPECPREV_FOUND:
1926                         ent = M_ARGV(1, entity);
1927                         break;
1928                 case MUT_SPECPREV_RETURN:
1929                         return true;
1930                 case MUT_SPECPREV_CONTINUE:
1931                 default:
1932                 {
1933                         if(ent.chain)
1934                                 ent = ent.chain;
1935                         else
1936                                 ent = first;
1937                         break;
1938                 }
1939         }
1940
1941         SetSpectatee(this, ent);
1942         return SpectateSet(this);
1943 }
1944
1945 /*
1946 =============
1947 ShowRespawnCountdown()
1948
1949 Update a respawn countdown display.
1950 =============
1951 */
1952 void ShowRespawnCountdown(entity this)
1953 {
1954         float number;
1955         if(!IS_DEAD(this)) // just respawned?
1956                 return;
1957         else
1958         {
1959                 number = ceil(this.respawn_time - time);
1960                 if(number <= 0)
1961                         return;
1962                 if(number <= this.respawn_countdown)
1963                 {
1964                         this.respawn_countdown = number - 1;
1965                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1966                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1967                 }
1968         }
1969 }
1970
1971 .bool team_selected;
1972 bool ShowTeamSelection(entity this)
1973 {
1974         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1975                 return false;
1976         stuffcmd(this, "menu_showteamselect\n");
1977         return true;
1978 }
1979 void Join(entity this)
1980 {
1981         TRANSMUTE(Player, this);
1982
1983         if(!this.team_selected)
1984         if(autocvar_g_campaign || autocvar_g_balance_teams)
1985                 TeamBalance_JoinBestTeam(this);
1986
1987         if(autocvar_g_campaign)
1988                 campaign_bots_may_start = true;
1989
1990         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1991
1992         PutClientInServer(this);
1993
1994         if(IS_PLAYER(this))
1995         if(teamplay && this.team != -1)
1996         {
1997         }
1998         else
1999                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2000         this.team_selected = false;
2001 }
2002
2003 int GetPlayerLimit()
2004 {
2005         if(g_duel)
2006                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2007         int player_limit = autocvar_g_maxplayers;
2008         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2009         player_limit = M_ARGV(0, int);
2010         return player_limit;
2011 }
2012
2013 /**
2014  * Determines whether the player is allowed to join. This depends on cvar
2015  * g_maxplayers, if it isn't used this function always return true, otherwise
2016  * it checks whether the number of currently playing players exceeds g_maxplayers.
2017  * @return int number of free slots for players, 0 if none
2018  */
2019 int nJoinAllowed(entity this, entity ignore)
2020 {
2021         if(!ignore)
2022         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2023         // so report 0 free slots if restricted
2024         {
2025                 if(autocvar_g_forced_team_otherwise == "spectate")
2026                         return 0;
2027                 if(autocvar_g_forced_team_otherwise == "spectator")
2028                         return 0;
2029         }
2030
2031         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2032                 return 0; // forced spectators can never join
2033
2034         // TODO simplify this
2035         int totalClients = 0;
2036         int currentlyPlaying = 0;
2037         FOREACH_CLIENT(true, {
2038                 if(it != ignore)
2039                         ++totalClients;
2040                 if(IS_REAL_CLIENT(it))
2041                 if(IS_PLAYER(it) || it.caplayer)
2042                         ++currentlyPlaying;
2043         });
2044
2045         int player_limit = GetPlayerLimit();
2046
2047         int free_slots = 0;
2048         if (!player_limit)
2049                 free_slots = maxclients - totalClients;
2050         else if(player_limit > 0 && currentlyPlaying < player_limit)
2051                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2052
2053         static float msg_time = 0;
2054         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2055         {
2056                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2057                 msg_time = time + 0.5;
2058         }
2059
2060         return free_slots;
2061 }
2062
2063 /**
2064  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2065  * g_maxplayers_spectator_blocktime seconds
2066  */
2067 void checkSpectatorBlock(entity this)
2068 {
2069         if(IS_SPEC(this) || IS_OBSERVER(this))
2070         if(!this.caplayer)
2071         if(IS_REAL_CLIENT(this))
2072         {
2073                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2074                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2075                         dropclient(this);
2076                 }
2077         }
2078 }
2079
2080 void PrintWelcomeMessage(entity this)
2081 {
2082         if(CS(this).motd_actived_time == 0)
2083         {
2084                 if (autocvar_g_campaign) {
2085                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2086                                 CS(this).motd_actived_time = time;
2087                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2088                         }
2089                 } else {
2090                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2091                                 CS(this).motd_actived_time = time;
2092                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2093                         }
2094                 }
2095         }
2096         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2097         {
2098                 if (autocvar_g_campaign) {
2099                         if (PHYS_INPUT_BUTTON_INFO(this))
2100                                 CS(this).motd_actived_time = time;
2101                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2102                                 CS(this).motd_actived_time = 0;
2103                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2104                         }
2105                 } else {
2106                         if (PHYS_INPUT_BUTTON_INFO(this))
2107                                 CS(this).motd_actived_time = time;
2108                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2109                                 CS(this).motd_actived_time = 0;
2110                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2111                         }
2112                 }
2113         }
2114         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2115         {
2116                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2117                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2118                 else if (CS(this).motd_actived_time == -2)
2119                 {
2120                         // instantly hide MOTD
2121                         CS(this).motd_actived_time = 0;
2122                         if (autocvar_g_campaign)
2123                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2124                         else
2125                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2126                 }
2127                 else if (IS_PLAYER(this) || IS_SPEC(this))
2128                 {
2129                         // FIXME occasionally for some reason MOTD never goes away
2130                         // delay MOTD removal a little bit in the hope it fixes this bug
2131                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2132                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2133                         else //if (CS(this).motd_actived_time < -2)
2134                                 CS(this).motd_actived_time++;
2135                 }
2136         }
2137 }
2138
2139 bool joinAllowed(entity this)
2140 {
2141         if (CS(this).version_mismatch) return false;
2142         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2143         if (!nJoinAllowed(this, this)) return false;
2144         if (teamplay && lockteams) return false;
2145         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2146         if (ShowTeamSelection(this)) return false;
2147         return true;
2148 }
2149
2150 .string shootfromfixedorigin;
2151 .bool dualwielding_prev;
2152 bool PlayerThink(entity this)
2153 {
2154         if (game_stopped || intermission_running) {
2155                 this.modelflags &= ~MF_ROCKET;
2156                 if(intermission_running)
2157                         IntermissionThink(this);
2158                 return false;
2159         }
2160
2161         if (timeout_status == TIMEOUT_ACTIVE) {
2162                 // don't allow the player to turn around while game is paused
2163                 // FIXME turn this into CSQC stuff
2164                 this.v_angle = this.lastV_angle;
2165                 this.angles = this.lastV_angle;
2166                 this.fixangle = true;
2167         }
2168
2169         if (frametime) player_powerups(this);
2170
2171         if (IS_DEAD(this)) {
2172                 if (this.personal && g_race_qualifying) {
2173                         if (time > this.respawn_time) {
2174                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2175                                 respawn(this);
2176                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2177                         }
2178                 } else {
2179                         if (frametime) player_anim(this);
2180
2181                         if (this.respawn_flags & RESPAWN_DENY)
2182                         {
2183                                 STAT(RESPAWN_TIME, this) = 0;
2184                                 return false;
2185                         }
2186
2187                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2188
2189                         switch(this.deadflag)
2190                         {
2191                                 case DEAD_DYING:
2192                                 {
2193                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2194                                                 this.deadflag = DEAD_RESPAWNING;
2195                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2196                                                 this.deadflag = DEAD_DEAD;
2197                                         break;
2198                                 }
2199                                 case DEAD_DEAD:
2200                                 {
2201                                         if (button_pressed)
2202                                                 this.deadflag = DEAD_RESPAWNABLE;
2203                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2204                                                 this.deadflag = DEAD_RESPAWNING;
2205                                         break;
2206                                 }
2207                                 case DEAD_RESPAWNABLE:
2208                                 {
2209                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2210                                                 this.deadflag = DEAD_RESPAWNING;
2211                                         break;
2212                                 }
2213                                 case DEAD_RESPAWNING:
2214                                 {
2215                                         if (time > this.respawn_time)
2216                                         {
2217                                                 this.respawn_time = time + 1; // only retry once a second
2218                                                 this.respawn_time_max = this.respawn_time;
2219                                                 respawn(this);
2220                                         }
2221                                         break;
2222                                 }
2223                         }
2224
2225                         ShowRespawnCountdown(this);
2226
2227                         if (this.respawn_flags & RESPAWN_SILENT)
2228                                 STAT(RESPAWN_TIME, this) = 0;
2229                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2230                         {
2231                                 if (time < this.respawn_time)
2232                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2233                                 else if (this.deadflag != DEAD_RESPAWNING)
2234                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2235                         }
2236                         else
2237                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2238                 }
2239
2240                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2241                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2242                         STAT(RESPAWN_TIME, this) *= -1;
2243
2244                 return false;
2245         }
2246
2247         FixPlayermodel(this);
2248
2249         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2250                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2251                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2252         }
2253
2254         // reset gun alignment when dual wielding status changes
2255         // to ensure guns are always aligned right and left
2256         bool dualwielding = W_DualWielding(this);
2257         if(this.dualwielding_prev != dualwielding)
2258         {
2259                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2260                 this.dualwielding_prev = dualwielding;
2261         }
2262
2263         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2264         //if(frametime)
2265         {
2266                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2267                 {
2268                         .entity weaponentity = weaponentities[slot];
2269                         if(WEP_CVAR(vortex, charge_always))
2270                                 W_Vortex_Charge(this, weaponentity, frametime);
2271                         W_WeaponFrame(this, weaponentity);
2272                 }
2273         }
2274
2275         if (frametime)
2276         {
2277                 // WEAPONTODO: Add a weapon request for this
2278                 // rot vortex charge to the charge limit
2279                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2280                 {
2281                         .entity weaponentity = weaponentities[slot];
2282                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2283                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2284                 }
2285
2286                 player_regen(this);
2287                 player_anim(this);
2288                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2289         }
2290
2291         monsters_setstatus(this);
2292
2293         return true;
2294 }
2295
2296 .bool would_spectate;
2297 void ObserverOrSpectatorThink(entity this)
2298 {
2299         bool is_spec = IS_SPEC(this);
2300         if ( CS(this).impulse )
2301         {
2302                 int r = MinigameImpulse(this, CS(this).impulse);
2303                 if (!is_spec || r)
2304                         CS(this).impulse = 0;
2305
2306                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2307                 {
2308                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2309                         CS(this).impulse = 0;
2310                         return;
2311                 }
2312         }
2313
2314         if (this.flags & FL_JUMPRELEASED) {
2315                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2316                         this.flags &= ~FL_JUMPRELEASED;
2317                         this.flags |= FL_SPAWNING;
2318                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2319                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2320                         this.flags &= ~FL_JUMPRELEASED;
2321                         if(SpectateNext(this)) {
2322                                 TRANSMUTE(Spectator, this);
2323                         } else if (is_spec) {
2324                                 TRANSMUTE(Observer, this);
2325                                 PutClientInServer(this);
2326                         }
2327                         if (is_spec)
2328                                 CS(this).impulse = 0;
2329                 } else if (is_spec) {
2330                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2331                                 this.flags &= ~FL_JUMPRELEASED;
2332                                 if(SpectatePrev(this)) {
2333                                         TRANSMUTE(Spectator, this);
2334                                 } else {
2335                                         TRANSMUTE(Observer, this);
2336                                         PutClientInServer(this);
2337                                 }
2338                                 CS(this).impulse = 0;
2339                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2340                                 this.would_spectate = false;
2341                                 this.flags &= ~FL_JUMPRELEASED;
2342                                 TRANSMUTE(Observer, this);
2343                                 PutClientInServer(this);
2344                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2345                                 PutObserverInServer(this);
2346                                 this.would_spectate = true;
2347                         }
2348                 }
2349                 else {
2350                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2351                         set_movetype(this, preferred_movetype);
2352                 }
2353         } else {
2354                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2355                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2356                         this.flags |= FL_JUMPRELEASED;
2357                         if(this.flags & FL_SPAWNING)
2358                         {
2359                                 this.flags &= ~FL_SPAWNING;
2360                                 if(joinAllowed(this))
2361                                         Join(this);
2362                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2363                                         CS(this).autojoin_checked = -1;
2364                                 return;
2365                         }
2366                 }
2367                 if(is_spec && !SpectateUpdate(this))
2368                         PutObserverInServer(this);
2369         }
2370         if (is_spec)
2371                 this.flags |= FL_CLIENT | FL_NOTARGET;
2372 }
2373
2374 void PlayerUseKey(entity this)
2375 {
2376         if (!IS_PLAYER(this))
2377                 return;
2378
2379         if(this.vehicle)
2380         {
2381                 if(!game_stopped)
2382                 {
2383                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2384                         return;
2385                 }
2386         }
2387         else if(autocvar_g_vehicles_enter)
2388         {
2389                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2390                 {
2391                         entity head, closest_target = NULL;
2392                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2393
2394                         while(head) // find the closest acceptable target to enter
2395                         {
2396                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2397                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2398                                 {
2399                                         if(closest_target)
2400                                         {
2401                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2402                                                 { closest_target = head; }
2403                                         }
2404                                         else { closest_target = head; }
2405                                 }
2406
2407                                 head = head.chain;
2408                         }
2409
2410                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2411                 }
2412         }
2413
2414         // a use key was pressed; call handlers
2415         MUTATOR_CALLHOOK(PlayerUseKey, this);
2416 }
2417
2418
2419 /*
2420 =============
2421 PlayerPreThink
2422
2423 Called every frame for each client before the physics are run
2424 =============
2425 */
2426 .float last_vehiclecheck;
2427 void PlayerPreThink (entity this)
2428 {
2429         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2430         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2431
2432         WarpZone_PlayerPhysics_FixVAngle(this);
2433
2434         if (frametime) {
2435                 // physics frames: update anticheat stuff
2436                 anticheat_prethink(this);
2437         }
2438
2439         if (blockSpectators && frametime) {
2440                 // WORKAROUND: only use dropclient in server frames (frametime set).
2441                 // Never use it in cl_movement frames (frametime zero).
2442                 checkSpectatorBlock(this);
2443         }
2444
2445         zoomstate_set = false;
2446
2447         // Check for nameless players
2448         if (this.netname == "" || this.netname != CS(this).netname_previous)
2449         {
2450                 bool assume_unchanged = (CS(this).netname_previous == "");
2451                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2452                 {
2453                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2454                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2455                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2456                         assume_unchanged = false;
2457                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2458                 }
2459                 if (isInvisibleString(this.netname))
2460                 {
2461                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2462                         sprint(this, "Warning: invisible names are not allowed.\n");
2463                         assume_unchanged = false;
2464                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2465                 }
2466                 if (!assume_unchanged && autocvar_sv_eventlog)
2467                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2468                 strcpy(CS(this).netname_previous, this.netname);
2469         }
2470
2471         // version nagging
2472         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2473         CS(this).version_nagtime = 0;
2474         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2475             // git client
2476         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2477             // git server
2478             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2479         } else {
2480             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2481             if (r < 0) { // old client
2482                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2483             } else if (r > 0) { // old server
2484                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2485             }
2486         }
2487     }
2488
2489         // GOD MODE info
2490         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2491         {
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2493                 this.max_armorvalue = 0;
2494         }
2495
2496         if (frametime && IS_PLAYER(this))
2497         {
2498                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2499                 {
2500                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2501                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2502                         if (this.iceblock)
2503                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2504
2505                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2506                                 Unfreeze(this, false);
2507                 }
2508                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2509                 {
2510                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2511                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2512
2513                         if (GetResource(this, RES_HEALTH) < 1)
2514                         {
2515                                 if (this.vehicle)
2516                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2517                                 if(this.event_damage)
2518                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2519                         }
2520                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2521                                 Unfreeze(this, false);
2522                 }
2523         }
2524
2525         MUTATOR_CALLHOOK(PlayerPreThink, this);
2526
2527         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2528         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2529         {
2530                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2531                 {
2532                         if(!it.owner)
2533                         {
2534                                 if(!it.team || SAME_TEAM(this, it))
2535                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2536                                 else if(autocvar_g_vehicles_steal)
2537                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2538                         }
2539                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2540                         {
2541                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2542                         }
2543                 });
2544
2545                 this.last_vehiclecheck = time + 1;
2546         }
2547
2548         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2549         {
2550                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2551                         PlayerUseKey(this);
2552                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2553         }
2554
2555         if (IS_REAL_CLIENT(this))
2556                 PrintWelcomeMessage(this);
2557
2558         if (IS_PLAYER(this)) {
2559                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2560                         error("Client can't be spawned as player on connection!");
2561                 if(!PlayerThink(this))
2562                         return;
2563         }
2564         else if (game_stopped || intermission_running) {
2565                 if(intermission_running)
2566                         IntermissionThink(this);
2567                 return;
2568         }
2569         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2570         {
2571                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2572                 CS(this).autojoin_checked = 1;
2573                 // don't do this in ClientConnect
2574                 // many things can go wrong if a client is spawned as player on connection
2575                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2576                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2577                                 && (!teamplay || autocvar_g_balance_teams)))
2578                 {
2579                         campaign_bots_may_start = true;
2580                         if(joinAllowed(this))
2581                                 Join(this);
2582                         return;
2583                 }
2584         }
2585         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2586                 ObserverOrSpectatorThink(this);
2587         }
2588
2589         // WEAPONTODO: Add weapon request for this
2590         if (!zoomstate_set) {
2591                 bool wep_zoomed = false;
2592                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2593                 {
2594                         .entity weaponentity = weaponentities[slot];
2595                         Weapon thiswep = this.(weaponentity).m_weapon;
2596                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2597                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2598                 }
2599                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2600         }
2601
2602         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2603         {
2604                 CS(this).teamkill_soundtime = 0;
2605
2606                 entity e = CS(this).teamkill_soundsource;
2607                 entity oldpusher = e.pusher;
2608                 e.pusher = this;
2609                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2610                 e.pusher = oldpusher;
2611         }
2612
2613         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2614                 CS(this).taunt_soundtime = 0;
2615                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2616         }
2617
2618         target_voicescript_next(this);
2619
2620         // WEAPONTODO: Move into weaponsystem somehow
2621         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2622         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2623         {
2624                 .entity weaponentity = weaponentities[slot];
2625                 if(this.(weaponentity).m_weapon == WEP_Null)
2626                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2627         }
2628 }
2629
2630 void DrownPlayer(entity this)
2631 {
2632         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2633                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2634         {
2635                 STAT(AIR_FINISHED, this) = 0;
2636                 return;
2637         }
2638
2639         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2640         {
2641                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2642                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2643                 STAT(AIR_FINISHED, this) = 0;
2644         }
2645         else
2646         {
2647                 if (!STAT(AIR_FINISHED, this))
2648                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2649                 if (STAT(AIR_FINISHED, this) < time)
2650                 {       // drown!
2651                         if (this.pain_finished < time)
2652                         {
2653                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2654                                 this.pain_finished = time + 0.5;
2655                         }
2656                 }
2657         }
2658 }
2659
2660 .bool move_qcphysics;
2661
2662 void Player_Physics(entity this)
2663 {
2664         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2665
2666         if(!this.move_qcphysics)
2667                 return;
2668
2669         if(!frametime && !CS(this).pm_frametime)
2670                 return;
2671
2672         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2673
2674         CS(this).pm_frametime = 0;
2675 }
2676
2677 /*
2678 =============
2679 PlayerPostThink
2680
2681 Called every frame for each client after the physics are run
2682 =============
2683 */
2684 void PlayerPostThink (entity this)
2685 {
2686         Player_Physics(this);
2687
2688         if (autocvar_sv_maxidle > 0)
2689         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2690         if (IS_REAL_CLIENT(this))
2691         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2692         {
2693                 int totalClients = 0;
2694                 if(autocvar_sv_maxidle_slots > 0)
2695                 {
2696                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2697                         {
2698                                 ++totalClients;
2699                         });
2700                 }
2701
2702                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2703                 { /* do nothing */ }
2704                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2705                 {
2706                         if (CS(this).idlekick_lasttimeleft)
2707                         {
2708                                 CS(this).idlekick_lasttimeleft = 0;
2709                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2710                         }
2711                 }
2712                 else
2713                 {
2714                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2715                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2716                                 if (!CS(this).idlekick_lasttimeleft)
2717                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2718                         }
2719                         if (timeleft <= 0) {
2720                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2721                                 dropclient(this);
2722                                 return;
2723                         }
2724                         else if (timeleft <= 10) {
2725                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2726                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2727                                 CS(this).idlekick_lasttimeleft = timeleft;
2728                         }
2729                 }
2730         }
2731
2732         CheatFrame(this);
2733
2734         if (game_stopped)
2735         {
2736                 this.solid = SOLID_NOT;
2737                 this.takedamage = DAMAGE_NO;
2738                 set_movetype(this, MOVETYPE_NONE);
2739                 CS(this).teamkill_complain = 0;
2740                 CS(this).teamkill_soundtime = 0;
2741                 CS(this).teamkill_soundsource = NULL;
2742         }
2743
2744         if (IS_PLAYER(this)) {
2745                 if(this.death_time == time && IS_DEAD(this))
2746                 {
2747                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2748                         // once all the damage events of this frame have been processed with normal size
2749                         this.maxs.z = 5;
2750                         setsize(this, this.mins, this.maxs);
2751                 }
2752                 DrownPlayer(this);
2753                 UpdateChatBubble(this);
2754                 if (CS(this).impulse) ImpulseCommands(this);
2755                 if (game_stopped)
2756                 {
2757                         CSQCMODEL_AUTOUPDATE(this);
2758                         return;
2759                 }
2760                 GetPressedKeys(this);
2761         }
2762         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2763         {
2764                 CS(this).pressedkeys = 0;
2765                 STAT(PRESSED_KEYS, this) = 0;
2766         }
2767
2768         if (this.waypointsprite_attachedforcarrier) {
2769                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2770                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2771         }
2772
2773         CSQCMODEL_AUTOUPDATE(this);
2774 }
2775
2776 // hack to copy the button fields from the client entity to the Client State
2777 void PM_UpdateButtons(entity this, entity store)
2778 {
2779         if(this.impulse)
2780                 store.impulse = this.impulse;
2781         this.impulse = 0;
2782
2783         bool typing = this.buttonchat || this.button12;
2784
2785         store.button0 = (typing) ? 0 : this.button0;
2786         //button1?!
2787         store.button2 = (typing) ? 0 : this.button2;
2788         store.button3 = (typing) ? 0 : this.button3;
2789         store.button4 = this.button4;
2790         store.button5 = (typing) ? 0 : this.button5;
2791         store.button6 = this.button6;
2792         store.button7 = this.button7;
2793         store.button8 = this.button8;
2794         store.button9 = this.button9;
2795         store.button10 = this.button10;
2796         store.button11 = this.button11;
2797         store.button12 = this.button12;
2798         store.button13 = this.button13;
2799         store.button14 = this.button14;
2800         store.button15 = this.button15;
2801         store.button16 = this.button16;
2802         store.buttonuse = this.buttonuse;
2803         store.buttonchat = this.buttonchat;
2804
2805         store.cursor_active = this.cursor_active;
2806         store.cursor_screen = this.cursor_screen;
2807         store.cursor_trace_start = this.cursor_trace_start;
2808         store.cursor_trace_endpos = this.cursor_trace_endpos;
2809         store.cursor_trace_ent = this.cursor_trace_ent;
2810
2811         store.ping = this.ping;
2812         store.ping_packetloss = this.ping_packetloss;
2813         store.ping_movementloss = this.ping_movementloss;
2814
2815         store.v_angle = this.v_angle;
2816         store.movement = this.movement;
2817 }
2818
2819 NET_HANDLE(fpsreport, bool)
2820 {
2821         int fps = ReadShort();
2822         PlayerScore_Set(sender, SP_FPS, fps);
2823         return true;
2824 }