qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include <common/vehicles/sv_vehicles.qh>
  50
  51 #include "../common/items/_mod.qh"
  52
  53 #include "../common/mutators/mutator/waypoints/all.qh"
  54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  55 #include <common/gamemodes/_mod.qh>
  56
  57 #include "../common/mapobjects/subs.qh"
  58 #include "../common/mapobjects/triggers.qh"
  59 #include "../common/mapobjects/trigger/secret.qh"
  60
  61 #include "../common/minigames/sv_minigames.qh"
  62
  63 #include "../common/items/inventory.qh"
  64
  65 #include "../common/monsters/sv_monsters.qh"
  66
  67 #include "../lib/warpzone/server.qh"
  68
  69 #include <common/mutators/mutator/overkill/oknex.qh>
  70
  71 STATIC_METHOD(Client, Add, void(Client this, int _team))
  72 {
  73     ClientConnect(this);
  74     TRANSMUTE(Player, this);
  75     this.frame = 12; // 7
  76     this.team = _team;
  77     PutClientInServer(this);
  78 }
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170
 171 /*
 172 =============
 173 CheckPlayerModel
 174
 175 Checks if the argument string can be a valid playermodel.
 176 Returns a valid one in doubt.
 177 =============
 178 */
 179 string FallbackPlayerModel;
 180 string CheckPlayerModel(string plyermodel) {
 181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 182         {
 183                 // note: we cannot summon Don Strunzone here, some player may
 184                 // still have the model string set. In case anyone manages how
 185                 // to change a cvar default, we'll have a small leak here.
 186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 187         }
 188         // only in right path
 189         if( substring(plyermodel,0,14) != "models/player/")
 190                 return FallbackPlayerModel;
 191         // only good file extensions
 192         if(substring(plyermodel,-4,4) != ".zym")
 193         if(substring(plyermodel,-4,4) != ".dpm")
 194         if(substring(plyermodel,-4,4) != ".iqm")
 195         if(substring(plyermodel,-4,4) != ".md3")
 196         if(substring(plyermodel,-4,4) != ".psk")
 197                 return FallbackPlayerModel;
 198         // forbid the LOD models
 199         if(substring(plyermodel, -9,5) == "_lod1")
 200                 return FallbackPlayerModel;
 201         if(substring(plyermodel, -9,5) == "_lod2")
 202                 return FallbackPlayerModel;
 203         if(plyermodel != strtolower(plyermodel))
 204                 return FallbackPlayerModel;
 205         // also, restrict to server models
 206         if(autocvar_sv_servermodelsonly)
 207         {
 208                 if(!fexists(plyermodel))
 209                         return FallbackPlayerModel;
 210         }
 211         return plyermodel;
 212 }
 213
 214 void setplayermodel(entity e, string modelname)
 215 {
 216         precache_model(modelname);
 217         _setmodel(e, modelname);
 218         player_setupanimsformodel(e);
 219         if(!autocvar_g_debug_globalsounds)
 220                 UpdatePlayerSounds(e);
 221 }
 222
 223 /** putting a client as observer in the server */
 224 void PutObserverInServer(entity this)
 225 {
 226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 227         PlayerState_detach(this);
 228
 229         if (IS_PLAYER(this))
 230         {
 231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 232                 {
 233                         // despawn effect
 234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 235                 }
 236
 237                 // was a player, recount votes and ready status
 238                 if(IS_REAL_CLIENT(this))
 239                 {
 240                         if (vote_called) { VoteCount(false); }
 241                         ReadyCount();
 242                 }
 243     }
 244
 245     {
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254             msg_entity = this;
 255             WriteByte(MSG_ONE, SVC_SETVIEW);
 256             WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269     }
 270
 271     RemoveGrapplingHooks(this);
 272         Portal_ClearAll(this);
 273         Unfreeze(this);
 274         SetSpectatee(this, NULL);
 275
 276         if (this.alivetime)
 277         {
 278                 if (!warmup_stage)
 279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 280                 this.alivetime = 0;
 281         }
 282
 283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 284
 285         WaypointSprite_PlayerDead(this);
 286
 287         if (CS(this).killcount != FRAGS_SPECTATOR)
 288         {
 289                 if(!game_stopped)
 290                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 291                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 292
 293                 if(CS(this).just_joined)
 294                 {
 295                         CS(this).just_joined = false;
 296                 }
 297         }
 298
 299         accuracy_resend(this);
 300
 301         CS(this).spectatortime = time;
 302         if(this.bot_attack)
 303                 IL_REMOVE(g_bot_targets, this);
 304         this.bot_attack = false;
 305         if(this.monster_attack)
 306                 IL_REMOVE(g_monster_targets, this);
 307         this.monster_attack = false;
 308     STAT(HUD, this) = HUD_NORMAL;
 309         TRANSMUTE(Observer, this);
 310         this.iscreature = false;
 311         this.teleportable = TELEPORT_SIMPLE;
 312         if(this.damagedbycontents)
 313                 IL_REMOVE(g_damagedbycontents, this);
 314         this.damagedbycontents = false;
 315         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 316         SetSpectatee_status(this, etof(this));
 317         this.takedamage = DAMAGE_NO;
 318         this.solid = SOLID_NOT;
 319         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 320         this.flags = FL_CLIENT | FL_NOTARGET;
 321         this.effects = 0;
 322         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 323         this.pauserotarmor_finished = 0;
 324         this.pauserothealth_finished = 0;
 325         this.pauseregen_finished = 0;
 326         this.damageforcescale = 0;
 327         this.death_time = 0;
 328         this.respawn_flags = 0;
 329         this.respawn_time = 0;
 330         STAT(RESPAWN_TIME, this) = 0;
 331         this.alpha = 0;
 332         this.scale = 0;
 333         this.fade_time = 0;
 334         this.pain_frame = 0;
 335         this.pain_finished = 0;
 336         this.strength_finished = 0;
 337         this.invincible_finished = 0;
 338         this.superweapons_finished = 0;
 339         this.dphitcontentsmask = 0;
 340         this.pushltime = 0;
 341         this.istypefrag = 0;
 342         setthink(this, func_null);
 343         this.nextthink = 0;
 344         this.deadflag = DEAD_NO;
 345         this.crouch = false;
 346         STAT(REVIVE_PROGRESS, this) = 0;
 347         this.revival_time = 0;
 348
 349         this.items = 0;
 350         STAT(WEAPONS, this) = '0 0 0';
 351         this.drawonlytoclient = this;
 352
 353         this.viewloc = NULL;
 354
 355         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 356
 357         this.weaponmodel = "";
 358         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         {
 360                 this.weaponentities[slot] = NULL;
 361         }
 362         this.exteriorweaponentity = NULL;
 363         CS(this).killcount = FRAGS_SPECTATOR;
 364         this.velocity = '0 0 0';
 365         this.avelocity = '0 0 0';
 366         this.punchangle = '0 0 0';
 367         this.punchvector = '0 0 0';
 368         this.oldvelocity = this.velocity;
 369         this.fire_endtime = -1;
 370         this.event_damage = func_null;
 371         this.event_heal = func_null;
 372
 373         for(int slot = 0; slot < MAX_AXH; ++slot)
 374         {
 375                 entity axh = this.(AuxiliaryXhair[slot]);
 376                 this.(AuxiliaryXhair[slot]) = NULL;
 377
 378                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 379                         delete(axh);
 380         }
 381
 382         if (mutator_returnvalue)
 383         {
 384                 // mutator prevents resetting teams+score
 385         }
 386         else
 387         {
 388                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 389                 this.frags = FRAGS_SPECTATOR;
 390     }
 391 }
 392
 393 int player_getspecies(entity this)
 394 {
 395         get_model_parameters(this.model, this.skin);
 396         int s = get_model_parameters_species;
 397         get_model_parameters(string_null, 0);
 398         if (s < 0) return SPECIES_HUMAN;
 399         return s;
 400 }
 401
 402 .float model_randomizer;
 403 void FixPlayermodel(entity player)
 404 {
 405         string defaultmodel = "";
 406         int defaultskin = 0;
 407         if(autocvar_sv_defaultcharacter)
 408         {
 409                 if(teamplay)
 410                 {
 411                         switch(player.team)
 412                         {
 413                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 414                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 415                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 416                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 417                         }
 418                 }
 419
 420                 if(defaultmodel == "")
 421                 {
 422                         defaultmodel = autocvar_sv_defaultplayermodel;
 423                         defaultskin = autocvar_sv_defaultplayerskin;
 424                 }
 425
 426                 int n = tokenize_console(defaultmodel);
 427                 if(n > 0)
 428                 {
 429                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 430                         // However, do NOT randomize if the player-selected model is in the list.
 431                         for (int i = 0; i < n; ++i)
 432                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 433                                         defaultmodel = argv(i);
 434                 }
 435
 436                 int i = strstrofs(defaultmodel, ":", 0);
 437                 if(i >= 0)
 438                 {
 439                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 440                         defaultmodel = substring(defaultmodel, 0, i);
 441                 }
 442         }
 443         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 444         {
 445                 if(teamplay)
 446                 {
 447                         switch(player.team)
 448                         {
 449                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 450                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 451                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 452                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 453                         }
 454                 }
 455
 456                 if(!defaultskin)
 457                         defaultskin = autocvar_sv_defaultplayerskin;
 458         }
 459
 460         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 461         defaultmodel = M_ARGV(0, string);
 462         defaultskin = M_ARGV(1, int);
 463
 464         bool chmdl = false;
 465         int oldskin;
 466         if(defaultmodel != "")
 467         {
 468                 if (defaultmodel != player.model)
 469                 {
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, defaultmodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 oldskin = player.skin;
 478                 player.skin = defaultskin;
 479         } else {
 480                 if (player.playermodel != player.model || player.playermodel == "")
 481                 {
 482                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 483                         vector m1 = player.mins;
 484                         vector m2 = player.maxs;
 485                         setplayermodel (player, player.playermodel);
 486                         setsize (player, m1, m2);
 487                         chmdl = true;
 488                 }
 489
 490                 if(!autocvar_sv_defaultcharacterskin)
 491                 {
 492                         oldskin = player.skin;
 493                         player.skin = stof(player.playerskin);
 494                 }
 495                 else
 496                 {
 497                         oldskin = player.skin;
 498                         player.skin = defaultskin;
 499                 }
 500         }
 501
 502         if(chmdl || oldskin != player.skin) // model or skin has changed
 503         {
 504                 player.species = player_getspecies(player); // update species
 505                 if(!autocvar_g_debug_globalsounds)
 506                         UpdatePlayerSounds(player); // update skin sounds
 507         }
 508
 509         if(!teamplay)
 510                 if(strlen(autocvar_sv_defaultplayercolors))
 511                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 512                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 513 }
 514
 515 void PutPlayerInServer(entity this)
 516 {
 517         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 518
 519         PlayerState_attach(this);
 520         accuracy_resend(this);
 521
 522         if (this.team < 0)
 523                 TeamBalance_JoinBestTeam(this);
 524
 525         entity spot = SelectSpawnPoint(this, false);
 526         if (!spot) {
 527                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 528                 return; // spawn failed
 529         }
 530
 531         TRANSMUTE(Player, this);
 532
 533         CS(this).wasplayer = true;
 534         this.iscreature = true;
 535         this.teleportable = TELEPORT_NORMAL;
 536         if(!this.damagedbycontents)
 537                 IL_PUSH(g_damagedbycontents, this);
 538         this.damagedbycontents = true;
 539         set_movetype(this, MOVETYPE_WALK);
 540         this.solid = SOLID_SLIDEBOX;
 541         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 542         if (autocvar_g_playerclip_collisions)
 543                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 544         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 545                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 546         this.frags = FRAGS_PLAYER;
 547         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 548         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 549         if (autocvar__notarget)
 550                 this.flags |= FL_NOTARGET;
 551         this.takedamage = DAMAGE_AIM;
 552         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 553
 554         if (warmup_stage) {
 555                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 556                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 557                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 558                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 559                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 560                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 561                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 562                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 563                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 564         } else {
 565                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 566                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 567                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 568                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 569                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 570                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 571                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 572                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 573                 STAT(WEAPONS, this) = start_weapons;
 574                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 575                 {
 576                         GiveRandomWeapons(this, random_start_weapons_count,
 577                                 autocvar_g_random_start_weapons, random_start_ammo);
 578                 }
 579         }
 580         SetSpectatee_status(this, 0);
 581
 582         PS(this).dual_weapons = '0 0 0';
 583
 584         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 585
 586         this.items = start_items;
 587
 588         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 589         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 590         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 591         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 592         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 593         if (!sv_ready_restart_after_countdown && time < game_starttime)
 594         {
 595                 float f = game_starttime - time;
 596                 this.spawnshieldtime += f;
 597                 this.pauserotarmor_finished += f;
 598                 this.pauserothealth_finished += f;
 599                 this.pauseregen_finished += f;
 600         }
 601
 602         this.damageforcescale = 2;
 603         this.death_time = 0;
 604         this.respawn_flags = 0;
 605         this.respawn_time = 0;
 606         STAT(RESPAWN_TIME, this) = 0;
 607         this.scale = autocvar_sv_player_scale;
 608         this.fade_time = 0;
 609         this.pain_frame = 0;
 610         this.pain_finished = 0;
 611         this.pushltime = 0;
 612         setthink(this, func_null); // players have no think function
 613         this.nextthink = 0;
 614         this.dmg_team = 0;
 615         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 616
 617         this.deadflag = DEAD_NO;
 618
 619         this.angles = spot.angles;
 620         this.angles_z = 0; // never spawn tilted even if the spot says to
 621         if (IS_BOT_CLIENT(this))
 622                 this.v_angle = this.angles;
 623         this.fixangle = true; // turn this way immediately
 624         this.oldvelocity = this.velocity = '0 0 0';
 625         this.avelocity = '0 0 0';
 626         this.punchangle = '0 0 0';
 627         this.punchvector = '0 0 0';
 628
 629         this.strength_finished = 0;
 630         this.invincible_finished = 0;
 631         this.fire_endtime = -1;
 632         STAT(REVIVE_PROGRESS, this) = 0;
 633         this.revival_time = 0;
 634
 635         this.air_finished = time + 12;
 636         this.waterlevel = WATERLEVEL_NONE;
 637         this.watertype = CONTENT_EMPTY;
 638
 639         entity spawnevent = new_pure(spawnevent);
 640         spawnevent.owner = this;
 641         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 642
 643         // Cut off any still running player sounds.
 644         stopsound(this, CH_PLAYER_SINGLE);
 645
 646         this.model = "";
 647         FixPlayermodel(this);
 648         this.drawonlytoclient = NULL;
 649
 650         this.viewloc = NULL;
 651
 652         for(int slot = 0; slot < MAX_AXH; ++slot)
 653         {
 654                 entity axh = this.(AuxiliaryXhair[slot]);
 655                 this.(AuxiliaryXhair[slot]) = NULL;
 656
 657                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 658                         delete(axh);
 659         }
 660
 661         this.spawnpoint_targ = NULL;
 662
 663         this.crouch = false;
 664         this.view_ofs = STAT(PL_VIEW_OFS, this);
 665         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 666         this.spawnorigin = spot.origin;
 667         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 668         // don't reset back to last position, even if new position is stuck in solid
 669         this.oldorigin = this.origin;
 670         if(this.conveyor)
 671                 IL_REMOVE(g_conveyed, this);
 672         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 673         STAT(HUD, this) = HUD_NORMAL;
 674
 675         this.event_damage = PlayerDamage;
 676         this.event_heal = PlayerHeal;
 677
 678         if(!this.bot_attack)
 679                 IL_PUSH(g_bot_targets, this);
 680         this.bot_attack = true;
 681         if(!this.monster_attack)
 682                 IL_PUSH(g_monster_targets, this);
 683         this.monster_attack = true;
 684         navigation_dynamicgoal_init(this, false);
 685
 686         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 687
 688         // player was spectator
 689         if (CS(this).killcount == FRAGS_SPECTATOR) {
 690                 PlayerScore_Clear(this);
 691                 CS(this).killcount = 0;
 692                 CS(this).startplaytime = time;
 693         }
 694
 695         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696         {
 697                 .entity weaponentity = weaponentities[slot];
 698                 entity oldwep = this.(weaponentity);
 699                 CL_SpawnWeaponentity(this, weaponentity);
 700                 if(oldwep && oldwep.owner == this)
 701                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 702         }
 703         this.alpha = default_player_alpha;
 704         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 705         this.exteriorweaponentity.alpha = default_weapon_alpha;
 706
 707         this.speedrunning = false;
 708
 709         target_voicescript_clear(this);
 710
 711         // reset fields the weapons may use
 712         FOREACH(Weapons, true, {
 713                 it.wr_resetplayer(it, this);
 714                         // reload all reloadable weapons
 715                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 716                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717                         {
 718                                 .entity weaponentity = weaponentities[slot];
 719                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 720                         }
 721                 }
 722         });
 723
 724         {
 725                 string s = spot.target;
 726                 spot.target = string_null;
 727                 SUB_UseTargets(spot, this, NULL);
 728                 spot.target = s;
 729         }
 730
 731         Unfreeze(this);
 732
 733         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 734
 735         if (autocvar_spawn_debug)
 736         {
 737                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 738                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 739         }
 740
 741         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742         {
 743                 .entity weaponentity = weaponentities[slot];
 744                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 745                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 746                 else
 747                         this.(weaponentity).m_switchweapon = WEP_Null;
 748                 this.(weaponentity).m_weapon = WEP_Null;
 749                 this.(weaponentity).weaponname = "";
 750                 this.(weaponentity).m_switchingweapon = WEP_Null;
 751                 this.(weaponentity).cnt = -1;
 752         }
 753
 754         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 755
 756         if (CS(this).impulse) ImpulseCommands(this);
 757
 758         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 759         {
 760                 .entity weaponentity = weaponentities[slot];
 761                 W_WeaponFrame(this, weaponentity);
 762         }
 763
 764         if (!warmup_stage && !this.alivetime)
 765                 this.alivetime = time;
 766
 767         antilag_clear(this, CS(this));
 768 }
 769
 770 /** Called when a client spawns in the server */
 771 void PutClientInServer(entity this)
 772 {
 773         if (IS_BOT_CLIENT(this)) {
 774                 TRANSMUTE(Player, this);
 775         } else if (IS_REAL_CLIENT(this)) {
 776                 msg_entity = this;
 777                 WriteByte(MSG_ONE, SVC_SETVIEW);
 778                 WriteEntity(MSG_ONE, this);
 779         }
 780         if (game_stopped)
 781                 TRANSMUTE(Observer, this);
 782
 783         SetSpectatee(this, NULL);
 784
 785         // reset player keys
 786         if(PS(this))
 787                 PS(this).itemkeys = 0;
 788
 789         MUTATOR_CALLHOOK(PutClientInServer, this);
 790
 791         if (IS_OBSERVER(this)) {
 792                 PutObserverInServer(this);
 793         } else if (IS_PLAYER(this)) {
 794                 PutPlayerInServer(this);
 795         }
 796 }
 797
 798 // TODO do we need all these fields, or should we stop autodetecting runtime
 799 // changes and just have a console command to update this?
 800 bool ClientInit_SendEntity(entity this, entity to, int sf)
 801 {
 802         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 803         return = true;
 804         msg_entity = to;
 805         // MSG_INIT replacement
 806         // TODO: make easier to use
 807         Registry_send_all();
 808         W_PROP_reload(MSG_ONE, to);
 809         ClientInit_misc(this);
 810         MUTATOR_CALLHOOK(Ent_Init);
 811 }
 812 void ClientInit_misc(entity this)
 813 {
 814         int channel = MSG_ONE;
 815         WriteHeader(channel, ENT_CLIENT_INIT);
 816         WriteByte(channel, g_nexball_meter_period * 32);
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 820         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 824         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 825
 826         if(sv_foginterval && world.fog != "")
 827                 WriteString(channel, world.fog);
 828         else
 829                 WriteString(channel, "");
 830         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 831         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 832         WriteByte(channel, serverflags);
 833         WriteCoord(channel, autocvar_g_trueaim_minrange);
 834 }
 835
 836 void ClientInit_CheckUpdate(entity this)
 837 {
 838         this.nextthink = time;
 839         if(this.count != autocvar_g_balance_armor_blockpercent)
 840         {
 841                 this.count = autocvar_g_balance_armor_blockpercent;
 842                 this.SendFlags |= 1;
 843         }
 844         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 845         {
 846                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 847                 this.SendFlags |= 1;
 848         }
 849 }
 850
 851 void ClientInit_Spawn()
 852 {
 853         entity e = new_pure(clientinit);
 854         setthink(e, ClientInit_CheckUpdate);
 855         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 856
 857         ClientInit_CheckUpdate(e);
 858 }
 859
 860 /*
 861 =============
 862 SetNewParms
 863 =============
 864 */
 865 void SetNewParms ()
 866 {
 867         // initialize parms for a new player
 868         parm1 = -(86400 * 366);
 869
 870         MUTATOR_CALLHOOK(SetNewParms);
 871 }
 872
 873 /*
 874 =============
 875 SetChangeParms
 876 =============
 877 */
 878 void SetChangeParms (entity this)
 879 {
 880         // save parms for level change
 881         parm1 = CS(this).parm_idlesince - time;
 882
 883         MUTATOR_CALLHOOK(SetChangeParms);
 884 }
 885
 886 /*
 887 =============
 888 DecodeLevelParms
 889 =============
 890 */
 891 void DecodeLevelParms(entity this)
 892 {
 893         // load parms
 894         CS(this).parm_idlesince = parm1;
 895         if (CS(this).parm_idlesince == -(86400 * 366))
 896                 CS(this).parm_idlesince = time;
 897
 898         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 899         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 900
 901         MUTATOR_CALLHOOK(DecodeLevelParms);
 902 }
 903
 904 /*
 905 =============
 906 ClientKill
 907
 908 Called when a client types 'kill' in the console
 909 =============
 910 */
 911
 912 .float clientkill_nexttime;
 913 void ClientKill_Now_TeamChange(entity this)
 914 {
 915         if(this.killindicator_teamchange == -1)
 916         {
 917                 TeamBalance_JoinBestTeam(this);
 918         }
 919         else if(this.killindicator_teamchange == -2)
 920         {
 921                 if(blockSpectators)
 922                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 923                 PutObserverInServer(this);
 924         }
 925         else
 926         {
 927                 Player_SetTeamIndexChecked(this, Team_TeamToIndex(
 928                         this.killindicator_teamchange));
 929         }
 930         this.killindicator_teamchange = 0;
 931 }
 932
 933 void ClientKill_Now(entity this)
 934 {
 935         if(this.vehicle)
 936         {
 937             vehicles_exit(this.vehicle, VHEF_RELEASE);
 938             if(!this.killindicator_teamchange)
 939             {
 940             this.vehicle_health = -1;
 941             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942             }
 943         }
 944
 945         if(this.killindicator && !wasfreed(this.killindicator))
 946                 delete(this.killindicator);
 947
 948         this.killindicator = NULL;
 949
 950         if(this.killindicator_teamchange)
 951                 ClientKill_Now_TeamChange(this);
 952
 953         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 954         {
 955                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 956         }
 957
 958         // now I am sure the player IS dead
 959 }
 960 void KillIndicator_Think(entity this)
 961 {
 962         if (game_stopped)
 963         {
 964                 this.owner.killindicator = NULL;
 965                 delete(this);
 966                 return;
 967         }
 968
 969         if (this.owner.alpha < 0 && !this.owner.vehicle)
 970         {
 971                 this.owner.killindicator = NULL;
 972                 delete(this);
 973                 return;
 974         }
 975
 976         if(this.cnt <= 0)
 977         {
 978                 ClientKill_Now(this.owner);
 979                 return;
 980         }
 981     else if(this.count == 1) // count == 1 means that it's silent
 982     {
 983         this.nextthink = time + 1;
 984         this.cnt -= 1;
 985     }
 986         else
 987         {
 988                 if(this.cnt <= 10)
 989                         setmodel(this, MDL_NUM(this.cnt));
 990                 if(IS_REAL_CLIENT(this.owner))
 991                 {
 992                         if(this.cnt <= 10)
 993                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 994                 }
 995                 this.nextthink = time + 1;
 996                 this.cnt -= 1;
 997         }
 998 }
 999
1000 float clientkilltime;
1001 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1002 {
1003         float killtime;
1004         float starttime;
1005
1006         if (game_stopped)
1007                 return;
1008
1009         killtime = autocvar_g_balance_kill_delay;
1010
1011     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1012         return;
1013     killtime = M_ARGV(1, float);
1014
1015         this.killindicator_teamchange = targetteam;
1016
1017     if(!this.killindicator)
1018         {
1019                 if(!IS_DEAD(this))
1020                 {
1021                         killtime = max(killtime, this.clientkill_nexttime - time);
1022                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1023                 }
1024
1025                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1026                 {
1027                         ClientKill_Now(this);
1028                 }
1029                 else
1030                 {
1031                         starttime = max(time, clientkilltime);
1032
1033                         this.killindicator = spawn();
1034                         this.killindicator.owner = this;
1035                         this.killindicator.scale = 0.5;
1036                         setattachment(this.killindicator, this, "");
1037                         setorigin(this.killindicator, '0 0 52');
1038                         setthink(this.killindicator, KillIndicator_Think);
1039                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1040                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1041                         this.killindicator.cnt = ceil(killtime);
1042                         this.killindicator.count = bound(0, ceil(killtime), 10);
1043                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1044
1045                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1046                         {
1047                                 it.killindicator = spawn();
1048                                 it.killindicator.owner = it;
1049                                 it.killindicator.scale = 0.5;
1050                                 setattachment(it.killindicator, it, "");
1051                                 setorigin(it.killindicator, '0 0 52');
1052                                 setthink(it.killindicator, KillIndicator_Think);
1053                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1054                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1055                                 it.killindicator.cnt = ceil(killtime);
1056                         });
1057                         this.lip = 0;
1058                 }
1059         }
1060         if(this.killindicator)
1061         {
1062                 if(targetteam == 0) // just die
1063                 {
1064                         this.killindicator.colormod = '0 0 0';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1068                 }
1069                 else if(targetteam == -1) // auto
1070                 {
1071                         this.killindicator.colormod = '0 1 0';
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1075                 }
1076                 else if(targetteam == -2) // spectate
1077                 {
1078                         this.killindicator.colormod = '0.5 0.5 0.5';
1079                         if(IS_REAL_CLIENT(this))
1080                         if(this.killindicator.cnt > 0)
1081                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1082                 }
1083                 else
1084                 {
1085                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1086                         if(IS_REAL_CLIENT(this))
1087                         if(this.killindicator.cnt > 0)
1088                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1089                 }
1090         }
1091
1092 }
1093
1094 void ClientKill (entity this)
1095 {
1096         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1097
1098         if(game_stopped) return;
1099         if(this.player_blocked) return;
1100         if(STAT(FROZEN, this)) return;
1101
1102         ClientKill_TeamChange(this, 0);
1103 }
1104
1105 void FixClientCvars(entity e)
1106 {
1107         // send prediction settings to the client
1108         stuffcmd(e, "\nin_bindmap 0 0\n");
1109         if(autocvar_g_antilag == 3) // client side hitscan
1110                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1111         if(autocvar_sv_gentle)
1112                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1113
1114         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1115         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1116
1117         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1118
1119         MUTATOR_CALLHOOK(FixClientCvars, e);
1120 }
1121
1122 bool findinlist_abbrev(string tofind, string list)
1123 {
1124         if(list == "" || tofind == "")
1125                 return false; // empty list or search, just return
1126
1127         // this function allows abbreviated strings!
1128         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1129         {
1130                 return true;
1131         });
1132
1133         return false;
1134 }
1135
1136 bool PlayerInIPList(entity p, string iplist)
1137 {
1138         // some safety checks (never allow local?)
1139         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1140                 return false;
1141
1142         return findinlist_abbrev(p.netaddress, iplist);
1143 }
1144
1145 bool PlayerInIDList(entity p, string idlist)
1146 {
1147         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1148         if(!p.crypto_idfp)
1149                 return false;
1150
1151         return findinlist_abbrev(p.crypto_idfp, idlist);
1152 }
1153
1154 bool PlayerInList(entity player, string list)
1155 {
1156         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1157 }
1158
1159 #ifdef DP_EXT_PRECONNECT
1160 /*
1161 =============
1162 ClientPreConnect
1163
1164 Called once (not at each match start) when a client begins a connection to the server
1165 =============
1166 */
1167 void ClientPreConnect(entity this)
1168 {
1169         if(autocvar_sv_eventlog)
1170         {
1171                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1172                         this.playerid,
1173                         etof(this),
1174                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1175                 ));
1176         }
1177 }
1178 #endif
1179
1180 string GetClientVersionMessage(entity this)
1181 {
1182         if (CS(this).version_mismatch) {
1183                 if(CS(this).version < autocvar_gameversion) {
1184                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1185                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1186                 } else {
1187                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1188                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1189                 }
1190         } else {
1191                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1192         }
1193 }
1194
1195 string getwelcomemessage(entity this)
1196 {
1197         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1198         string modifications = M_ARGV(0, string);
1199
1200         if(g_weaponarena)
1201         {
1202                 if(g_weaponarena_random)
1203                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1204                 else
1205                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1206         }
1207         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1208                 modifications = strcat(modifications, ", No start weapons");
1209         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1210                 modifications = strcat(modifications, ", Low gravity");
1211         if(g_weapon_stay && !g_cts)
1212                 modifications = strcat(modifications, ", Weapons stay");
1213         if(g_jetpack)
1214                 modifications = strcat(modifications, ", Jet pack");
1215         if(autocvar_g_powerups == 0)
1216                 modifications = strcat(modifications, ", No powerups");
1217         if(autocvar_g_powerups > 0)
1218                 modifications = strcat(modifications, ", Powerups");
1219         modifications = substring(modifications, 2, strlen(modifications) - 2);
1220
1221         string versionmessage = GetClientVersionMessage(this);
1222         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1223
1224         if(modifications != "")
1225                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1226
1227         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1228         {
1229                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1230                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1231         }
1232
1233         if (cache_mutatormsg != "") {
1234                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1235         }
1236
1237         string mutator_msg = "";
1238         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1239         mutator_msg = M_ARGV(0, string);
1240
1241         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1242
1243         string motd = autocvar_sv_motd;
1244         if (motd != "") {
1245                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1246         }
1247         return s;
1248 }
1249
1250 /**
1251 =============
1252 ClientConnect
1253
1254 Called when a client connects to the server
1255 =============
1256 */
1257 void ClientConnect(entity this)
1258 {
1259         if (Ban_MaybeEnforceBanOnce(this)) return;
1260         assert(!IS_CLIENT(this), return);
1261         this.flags |= FL_CLIENT;
1262         assert(player_count >= 0, player_count = 0);
1263
1264 #ifdef WATERMARK
1265         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1266 #endif
1267         TRANSMUTE(Client, this);
1268         CS(this).version_nagtime = time + 10 + random() * 10;
1269
1270         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1271
1272         bot_clientconnect(this);
1273
1274         Player_DetermineForcedTeam(this);
1275
1276         TRANSMUTE(Observer, this);
1277
1278         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1279
1280         // always track bots, don't ask for cl_allow_uidtracking
1281         if (IS_BOT_CLIENT(this))
1282                 PlayerStats_GameReport_AddPlayer(this);
1283         else
1284                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1285
1286         if (autocvar_sv_eventlog)
1287                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1288
1289         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1290
1291         stuffcmd(this, clientstuff, "\n");
1292         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1293
1294         FixClientCvars(this);
1295
1296         // get version info from player
1297         stuffcmd(this, "cmd clientversion $gameversion\n");
1298
1299         // notify about available teams
1300         if (teamplay)
1301         {
1302                 entity balance = TeamBalance_CheckAllowedTeams(this);
1303                 int t = TeamBalance_GetAllowedTeams(balance);
1304                 TeamBalance_Destroy(balance);
1305                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1306         }
1307         else
1308         {
1309                 stuffcmd(this, "set _teams_available 0\n");
1310         }
1311
1312         bot_relinkplayerlist();
1313
1314         CS(this).spectatortime = time;
1315         if (blockSpectators)
1316         {
1317                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1318         }
1319
1320         CS(this).jointime = time;
1321
1322         if (IS_REAL_CLIENT(this))
1323         {
1324                 if (g_weaponarena_weapons == WEPSET(TUBA))
1325                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1326         }
1327
1328         if (!sv_foginterval && world.fog != "")
1329                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1330
1331         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1332                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1333                         send_CSQC_teamnagger();
1334
1335         CSQCMODEL_AUTOINIT(this);
1336
1337         CS(this).model_randomizer = random();
1338
1339         if (IS_REAL_CLIENT(this))
1340                 sv_notice_join(this);
1341
1342         // update physics stats (players can spawn before physics runs)
1343         Physics_UpdateStats(this);
1344
1345         IL_EACH(g_initforplayer, it.init_for_player, {
1346                 it.init_for_player(it, this);
1347         });
1348
1349         Handicap_Initialize(this);
1350
1351         MUTATOR_CALLHOOK(ClientConnect, this);
1352
1353         if (IS_REAL_CLIENT(this))
1354         {
1355                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1356                 {
1357                         CS(this).motd_actived_time = -1;
1358                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1359                 }
1360         }
1361 }
1362 /*
1363 =============
1364 ClientDisconnect
1365
1366 Called when a client disconnects from the server
1367 =============
1368 */
1369 .entity chatbubbleentity;
1370 void ClientDisconnect(entity this)
1371 {
1372         assert(IS_CLIENT(this), return);
1373
1374         PlayerStats_GameReport_FinalizePlayer(this);
1375         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1376         if (CS(this).active_minigame) part_minigame(this);
1377         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1378
1379         if (autocvar_sv_eventlog)
1380                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1381
1382         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1383
1384         if(IS_SPEC(this))
1385                 SetSpectatee(this, NULL);
1386
1387     MUTATOR_CALLHOOK(ClientDisconnect, this);
1388
1389         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1390         strfree(CS(this).weaponorder_byimpulse);
1391         ClientState_detach(this);
1392
1393         Portal_ClearAll(this);
1394
1395         Unfreeze(this);
1396
1397         RemoveGrapplingHooks(this);
1398
1399         // Here, everything has been done that requires this player to be a client.
1400
1401         this.flags &= ~FL_CLIENT;
1402
1403         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1404         if (this.killindicator) delete(this.killindicator);
1405
1406         WaypointSprite_PlayerGone(this);
1407
1408         bot_relinkplayerlist();
1409
1410         strfree(this.clientstatus);
1411         if (this.personal) delete(this.personal);
1412
1413         this.playerid = 0;
1414         ReadyCount();
1415         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1416
1417         ONREMOVE(this);
1418 }
1419
1420 void ChatBubbleThink(entity this)
1421 {
1422         this.nextthink = time;
1423         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1424         {
1425                 if(this.owner) // but why can that ever be NULL?
1426                         this.owner.chatbubbleentity = NULL;
1427                 delete(this);
1428                 return;
1429         }
1430
1431         this.mdl = "";
1432
1433         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1434         {
1435                 if ( CS(this.owner).active_minigame )
1436                         this.mdl = "models/sprites/minigame_busy.iqm";
1437                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1438                         this.mdl = "models/misc/chatbubble.spr";
1439         }
1440
1441         if ( this.model != this.mdl )
1442                 _setmodel(this, this.mdl);
1443
1444 }
1445
1446 void UpdateChatBubble(entity this)
1447 {
1448         if (this.alpha < 0)
1449                 return;
1450         // spawn a chatbubble entity if needed
1451         if (!this.chatbubbleentity)
1452         {
1453                 this.chatbubbleentity = new(chatbubbleentity);
1454                 this.chatbubbleentity.owner = this;
1455                 this.chatbubbleentity.exteriormodeltoclient = this;
1456                 setthink(this.chatbubbleentity, ChatBubbleThink);
1457                 this.chatbubbleentity.nextthink = time;
1458                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1459                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1460                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1461                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1462                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1463                 //this.chatbubbleentity.model = "";
1464                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1465         }
1466 }
1467
1468
1469 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1470 // added to the model skins
1471 /*void UpdateColorModHack()
1472 {
1473         float c;
1474         c = this.clientcolors & 15;
1475         // LordHavoc: only bothering to support white, green, red, yellow, blue
1476              if (!teamplay) this.colormod = '0 0 0';
1477         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1478         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1479         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1480         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1481         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1482         else this.colormod = '1 1 1';
1483 }*/
1484
1485 void respawn(entity this)
1486 {
1487         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1488         {
1489                 this.solid = SOLID_NOT;
1490                 this.takedamage = DAMAGE_NO;
1491                 set_movetype(this, MOVETYPE_FLY);
1492                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1493                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1494                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1495                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1496                 if(autocvar_g_respawn_ghosts_maxtime)
1497                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1498         }
1499
1500         CopyBody(this, 1);
1501
1502         this.effects |= EF_NODRAW; // prevent another CopyBody
1503         PutClientInServer(this);
1504 }
1505
1506 void PrintToChat(entity client, string text)
1507 {
1508         text = strcat("\{1}^7", text, "\n");
1509         sprint(client, text);
1510 }
1511
1512 void DebugPrintToChat(entity client, string text)
1513 {
1514         if (autocvar_developer)
1515         {
1516                 PrintToChat(client, text);
1517         }
1518 }
1519
1520 void PrintToChatAll(string text)
1521 {
1522         text = strcat("\{1}^7", text, "\n");
1523         bprint(text);
1524 }
1525
1526 void DebugPrintToChatAll(string text)
1527 {
1528         if (autocvar_developer)
1529         {
1530                 PrintToChatAll(text);
1531         }
1532 }
1533
1534 void PrintToChatTeam(int team_num, string text)
1535 {
1536         text = strcat("\{1}^7", text, "\n");
1537         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1538         {
1539                 if (it.team == team_num)
1540                 {
1541                         sprint(it, text);
1542                 }
1543         });
1544 }
1545
1546 void DebugPrintToChatTeam(int team_num, string text)
1547 {
1548         if (autocvar_developer)
1549         {
1550                 PrintToChatTeam(team_num, text);
1551         }
1552 }
1553
1554 void play_countdown(entity this, float finished, Sound samp)
1555 {
1556         TC(Sound, samp);
1557         if(IS_REAL_CLIENT(this))
1558                 if(floor(finished - time - frametime) != floor(finished - time))
1559                         if(finished - time < 6)
1560                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1561 }
1562
1563 void player_powerups(entity this)
1564 {
1565         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1566         int items_prev = this.items;
1567
1568         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1569                 this.modelflags |= MF_ROCKET;
1570         else
1571                 this.modelflags &= ~MF_ROCKET;
1572
1573         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1574
1575         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1576                 return;
1577
1578         Fire_ApplyDamage(this);
1579         Fire_ApplyEffect(this);
1580
1581         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1582         {
1583                 if (this.items & ITEM_Strength.m_itemid)
1584                 {
1585                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1586                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1587                         if (time > this.strength_finished)
1588                         {
1589                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1590                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1591                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1592                         }
1593                 }
1594                 else
1595                 {
1596                         if (time < this.strength_finished)
1597                         {
1598                                 this.items = this.items | ITEM_Strength.m_itemid;
1599                                 if(!g_cts)
1600                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1601                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1602                         }
1603                 }
1604                 if (this.items & ITEM_Shield.m_itemid)
1605                 {
1606                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1607                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1608                         if (time > this.invincible_finished)
1609                         {
1610                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1611                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1612                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1613                         }
1614                 }
1615                 else
1616                 {
1617                         if (time < this.invincible_finished)
1618                         {
1619                                 this.items = this.items | ITEM_Shield.m_itemid;
1620                                 if(!g_cts)
1621                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1622                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1623                         }
1624                 }
1625                 if (this.items & IT_SUPERWEAPON)
1626                 {
1627                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1628                         {
1629                                 this.superweapons_finished = 0;
1630                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1631                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1632                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1633                         }
1634                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1635                         {
1636                                 // don't let them run out
1637                         }
1638                         else
1639                         {
1640                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1641                                 if (time > this.superweapons_finished)
1642                                 {
1643                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1644                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1645                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1646                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1647                                 }
1648                         }
1649                 }
1650                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1651                 {
1652                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1653                         {
1654                                 this.items = this.items | IT_SUPERWEAPON;
1655                                 if(!g_cts)
1656                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1657                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1658                         }
1659                         else
1660                         {
1661                                 this.superweapons_finished = 0;
1662                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1663                         }
1664                 }
1665                 else
1666                 {
1667                         this.superweapons_finished = 0;
1668                 }
1669         }
1670
1671         if(autocvar_g_nodepthtestplayers)
1672                 this.effects = this.effects | EF_NODEPTHTEST;
1673
1674         if(autocvar_g_fullbrightplayers)
1675                 this.effects = this.effects | EF_FULLBRIGHT;
1676
1677         if (time >= game_starttime)
1678         if (time < this.spawnshieldtime)
1679                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1680
1681         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1682 }
1683
1684 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1685 {
1686         if(current > stable)
1687                 return current;
1688         else if(current > stable - 0.25) // when close enough, "snap"
1689                 return stable;
1690         else
1691                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1692 }
1693
1694 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1695 {
1696         if(current < stable)
1697                 return current;
1698         else if(current < stable + 0.25) // when close enough, "snap"
1699                 return stable;
1700         else
1701                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1702 }
1703
1704 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1705 {
1706         if(current > rotstable)
1707         {
1708                 if(rotframetime > 0)
1709                 {
1710                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1711                         current = max(rotstable, current - rotlinear * rotframetime);
1712                 }
1713         }
1714         else if(current < regenstable)
1715         {
1716                 if(regenframetime > 0)
1717                 {
1718                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1719                         current = min(regenstable, current + regenlinear * regenframetime);
1720                 }
1721         }
1722
1723         if(current > limit)
1724                 current = limit;
1725
1726         return current;
1727 }
1728
1729 void player_regen(entity this)
1730 {
1731         float max_mod, regen_mod, rot_mod, limit_mod;
1732         max_mod = regen_mod = rot_mod = limit_mod = 1;
1733
1734         float regen_health = autocvar_g_balance_health_regen;
1735         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1736         float regen_health_rot = autocvar_g_balance_health_rot;
1737         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1738         float regen_health_stable = autocvar_g_balance_health_regenstable;
1739         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1740         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1741                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1742         max_mod = M_ARGV(1, float);
1743         regen_mod = M_ARGV(2, float);
1744         rot_mod = M_ARGV(3, float);
1745         limit_mod = M_ARGV(4, float);
1746         regen_health = M_ARGV(5, float);
1747         regen_health_linear = M_ARGV(6, float);
1748         regen_health_rot = M_ARGV(7, float);
1749         regen_health_rotlinear = M_ARGV(8, float);
1750         regen_health_stable = M_ARGV(9, float);
1751         regen_health_rotstable = M_ARGV(10, float);
1752
1753         if(!mutator_returnvalue)
1754         if(!STAT(FROZEN, this))
1755         {
1756                 float mina, maxa, limith, limita;
1757                 maxa = autocvar_g_balance_armor_rotstable;
1758                 mina = autocvar_g_balance_armor_regenstable;
1759                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1760                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1761
1762                 regen_health_rotstable = regen_health_rotstable * max_mod;
1763                 regen_health_stable = regen_health_stable * max_mod;
1764                 limith = limith * limit_mod;
1765                 limita = limita * limit_mod;
1766
1767                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1768                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1769                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1770                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1771                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1772                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1773         }
1774
1775         // if player rotted to death...  die!
1776         // check this outside above checks, as player may still be able to rot to death
1777         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1778         {
1779                 if(this.vehicle)
1780                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1781                 if(this.event_damage)
1782                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1783         }
1784
1785         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1786         {
1787                 float minf, maxf, limitf;
1788
1789                 maxf = autocvar_g_balance_fuel_rotstable;
1790                 minf = autocvar_g_balance_fuel_regenstable;
1791                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1792
1793                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1794                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1795                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1796         }
1797 }
1798
1799 bool zoomstate_set;
1800 void SetZoomState(entity this, float newzoom)
1801 {
1802         if(newzoom != CS(this).zoomstate)
1803         {
1804                 CS(this).zoomstate = newzoom;
1805                 ClientData_Touch(this);
1806         }
1807         zoomstate_set = true;
1808 }
1809
1810 void GetPressedKeys(entity this)
1811 {
1812         MUTATOR_CALLHOOK(GetPressedKeys, this);
1813         int keys = STAT(PRESSED_KEYS, this);
1814         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1815         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1816         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1817         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1818
1819         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1820         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1821         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1822         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1823         CS(this).pressedkeys = keys; // store for other users
1824
1825         STAT(PRESSED_KEYS, this) = keys;
1826 }
1827
1828 /*
1829 ======================
1830 spectate mode routines
1831 ======================
1832 */
1833
1834 void SpectateCopy(entity this, entity spectatee)
1835 {
1836         TC(Client, this); TC(Client, spectatee);
1837
1838         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1839         PS(this) = PS(spectatee);
1840         this.armortype = spectatee.armortype;
1841         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1842         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1843         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1844         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1845         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1846         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1847         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1848         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1849         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1850         CS(this).impulse = 0;
1851         this.items = spectatee.items;
1852         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1853         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1854         this.strength_finished = spectatee.strength_finished;
1855         this.invincible_finished = spectatee.invincible_finished;
1856         this.superweapons_finished = spectatee.superweapons_finished;
1857         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1858         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1859         this.punchangle = spectatee.punchangle;
1860         this.view_ofs = spectatee.view_ofs;
1861         this.velocity = spectatee.velocity;
1862         this.dmg_take = spectatee.dmg_take;
1863         this.dmg_save = spectatee.dmg_save;
1864         this.dmg_inflictor = spectatee.dmg_inflictor;
1865         this.v_angle = spectatee.v_angle;
1866         this.angles = spectatee.v_angle;
1867         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1868         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1869         this.viewloc = spectatee.viewloc;
1870         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1871                 this.fixangle = true;
1872         setorigin(this, spectatee.origin);
1873         setsize(this, spectatee.mins, spectatee.maxs);
1874         SetZoomState(this, CS(spectatee).zoomstate);
1875
1876     anticheat_spectatecopy(this, spectatee);
1877         STAT(HUD, this) = STAT(HUD, spectatee);
1878         if(spectatee.vehicle)
1879     {
1880         this.angles = spectatee.v_angle;
1881
1882         //this.fixangle = false;
1883         //this.velocity = spectatee.vehicle.velocity;
1884         this.vehicle_health = spectatee.vehicle_health;
1885         this.vehicle_shield = spectatee.vehicle_shield;
1886         this.vehicle_energy = spectatee.vehicle_energy;
1887         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1888         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1889         this.vehicle_reload1 = spectatee.vehicle_reload1;
1890         this.vehicle_reload2 = spectatee.vehicle_reload2;
1891
1892         //msg_entity = this;
1893
1894        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1895             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1896            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1897            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1898
1899         //WriteByte (MSG_ONE, SVC_SETVIEW);
1900         //    WriteEntity(MSG_ONE, this);
1901         //makevectors(spectatee.v_angle);
1902         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1903     }
1904 }
1905
1906 bool SpectateUpdate(entity this)
1907 {
1908         if(!this.enemy)
1909                 return false;
1910
1911         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1912         {
1913                 SetSpectatee(this, NULL);
1914                 return false;
1915         }
1916
1917         SpectateCopy(this, this.enemy);
1918
1919         return true;
1920 }
1921
1922 bool SpectateSet(entity this)
1923 {
1924         if(!IS_PLAYER(this.enemy))
1925                 return false;
1926
1927         ClientData_Touch(this.enemy);
1928
1929         msg_entity = this;
1930         WriteByte(MSG_ONE, SVC_SETVIEW);
1931         WriteEntity(MSG_ONE, this.enemy);
1932         set_movetype(this, MOVETYPE_NONE);
1933         accuracy_resend(this);
1934
1935         if(!SpectateUpdate(this))
1936                 PutObserverInServer(this);
1937
1938         return true;
1939 }
1940
1941 void SetSpectatee_status(entity this, int spectatee_num)
1942 {
1943         int oldspectatee_status = CS(this).spectatee_status;
1944         CS(this).spectatee_status = spectatee_num;
1945
1946         if (CS(this).spectatee_status != oldspectatee_status)
1947         {
1948                 ClientData_Touch(this);
1949                 if (g_race || g_cts) race_InitSpectator();
1950         }
1951 }
1952
1953 void SetSpectatee(entity this, entity spectatee)
1954 {
1955         if(IS_BOT_CLIENT(this))
1956                 return; // bots abuse .enemy, this code is useless to them
1957
1958         entity old_spectatee = this.enemy;
1959
1960         this.enemy = spectatee;
1961
1962         // WEAPONTODO
1963         // these are required to fix the spectator bug with arc
1964         if(old_spectatee)
1965         {
1966                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1967                 {
1968                         .entity weaponentity = weaponentities[slot];
1969                         if(old_spectatee.(weaponentity).arc_beam)
1970                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1971                 }
1972         }
1973         if(this.enemy)
1974         {
1975                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1976                 {
1977                         .entity weaponentity = weaponentities[slot];
1978                         if(this.enemy.(weaponentity).arc_beam)
1979                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1980                 }
1981         }
1982
1983         if (this.enemy)
1984                 SetSpectatee_status(this, etof(this.enemy));
1985
1986         // needed to update spectator list
1987         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1988 }
1989
1990 bool Spectate(entity this, entity pl)
1991 {
1992         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1993                 return false;
1994         pl = M_ARGV(1, entity);
1995
1996         SetSpectatee(this, pl);
1997         return SpectateSet(this);
1998 }
1999
2000 bool SpectateNext(entity this)
2001 {
2002         entity ent = find(this.enemy, classname, STR_PLAYER);
2003
2004         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2005                 ent = M_ARGV(1, entity);
2006         else if (!ent)
2007                 ent = find(ent, classname, STR_PLAYER);
2008
2009         if(ent) { SetSpectatee(this, ent); }
2010
2011         return SpectateSet(this);
2012 }
2013
2014 bool SpectatePrev(entity this)
2015 {
2016         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2017         entity ent = findchain(classname, STR_PLAYER);
2018         if (!ent) // no player
2019                 return false;
2020
2021         entity first = ent;
2022         // skip players until current spectated player
2023         if(this.enemy)
2024         while(ent && ent != this.enemy)
2025                 ent = ent.chain;
2026
2027         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2028         {
2029                 case MUT_SPECPREV_FOUND:
2030                     ent = M_ARGV(1, entity);
2031                     break;
2032                 case MUT_SPECPREV_RETURN:
2033                     return true;
2034                 case MUT_SPECPREV_CONTINUE:
2035                 default:
2036                 {
2037                         if(ent.chain)
2038                                 ent = ent.chain;
2039                         else
2040                                 ent = first;
2041                         break;
2042                 }
2043         }
2044
2045         SetSpectatee(this, ent);
2046         return SpectateSet(this);
2047 }
2048
2049 /*
2050 =============
2051 ShowRespawnCountdown()
2052
2053 Update a respawn countdown display.
2054 =============
2055 */
2056 void ShowRespawnCountdown(entity this)
2057 {
2058         float number;
2059         if(!IS_DEAD(this)) // just respawned?
2060                 return;
2061         else
2062         {
2063                 number = ceil(this.respawn_time - time);
2064                 if(number <= 0)
2065                         return;
2066                 if(number <= this.respawn_countdown)
2067                 {
2068                         this.respawn_countdown = number - 1;
2069                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2070                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2071                 }
2072         }
2073 }
2074
2075 .bool team_selected;
2076 bool ShowTeamSelection(entity this)
2077 {
2078         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2079                 return false;
2080         stuffcmd(this, "menu_showteamselect\n");
2081         return true;
2082 }
2083 void Join(entity this)
2084 {
2085         TRANSMUTE(Player, this);
2086
2087         if(!this.team_selected)
2088         if(autocvar_g_campaign || autocvar_g_balance_teams)
2089                 TeamBalance_JoinBestTeam(this);
2090
2091         if(autocvar_g_campaign)
2092                 campaign_bots_may_start = true;
2093
2094         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2095
2096         PutClientInServer(this);
2097
2098         if(IS_PLAYER(this))
2099         if(teamplay && this.team != -1)
2100         {
2101         }
2102         else
2103                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2104         this.team_selected = false;
2105 }
2106
2107 /**
2108  * Determines whether the player is allowed to join. This depends on cvar
2109  * g_maxplayers, if it isn't used this function always return true, otherwise
2110  * it checks whether the number of currently playing players exceeds g_maxplayers.
2111  * @return int number of free slots for players, 0 if none
2112  */
2113 int nJoinAllowed(entity this, entity ignore)
2114 {
2115         if(!ignore)
2116         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2117         // so report 0 free slots if restricted
2118         {
2119                 if(autocvar_g_forced_team_otherwise == "spectate")
2120                         return 0;
2121                 if(autocvar_g_forced_team_otherwise == "spectator")
2122                         return 0;
2123         }
2124
2125         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2126                 return 0; // forced spectators can never join
2127
2128         // TODO simplify this
2129         int totalClients = 0;
2130         int currentlyPlaying = 0;
2131         FOREACH_CLIENT(true, {
2132                 if(it != ignore)
2133                         ++totalClients;
2134                 if(IS_REAL_CLIENT(it))
2135                 if(IS_PLAYER(it) || it.caplayer)
2136                         ++currentlyPlaying;
2137         });
2138
2139         float free_slots = 0;
2140         if (!autocvar_g_maxplayers)
2141                 free_slots = maxclients - totalClients;
2142         else if(currentlyPlaying < autocvar_g_maxplayers)
2143                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2144
2145         static float join_prevent_msg_time = 0;
2146         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2147         {
2148                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2149                 join_prevent_msg_time = time + 3;
2150         }
2151
2152         return free_slots;
2153 }
2154
2155 /**
2156  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2157  * g_maxplayers_spectator_blocktime seconds
2158  */
2159 void checkSpectatorBlock(entity this)
2160 {
2161         if(IS_SPEC(this) || IS_OBSERVER(this))
2162         if(!this.caplayer)
2163         if(IS_REAL_CLIENT(this))
2164         {
2165                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2166                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2167                         dropclient(this);
2168                 }
2169         }
2170 }
2171
2172 void PrintWelcomeMessage(entity this)
2173 {
2174         if(CS(this).motd_actived_time == 0)
2175         {
2176                 if (autocvar_g_campaign) {
2177                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2178                                 CS(this).motd_actived_time = time;
2179                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2180                         }
2181                 } else {
2182                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2183                                 CS(this).motd_actived_time = time;
2184                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2185                         }
2186                 }
2187         }
2188         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2189         {
2190                 if (autocvar_g_campaign) {
2191                         if (PHYS_INPUT_BUTTON_INFO(this))
2192                                 CS(this).motd_actived_time = time;
2193                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2194                                 CS(this).motd_actived_time = 0;
2195                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2196                         }
2197                 } else {
2198                         if (PHYS_INPUT_BUTTON_INFO(this))
2199                                 CS(this).motd_actived_time = time;
2200                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2201                                 CS(this).motd_actived_time = 0;
2202                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2203                         }
2204                 }
2205         }
2206         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2207         {
2208                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2209                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2210                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2211                 {
2212                         // instanctly hide MOTD
2213                         CS(this).motd_actived_time = 0;
2214                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2215                 }
2216         }
2217 }
2218
2219 const int MIN_SPEC_TIME = 1;
2220 bool joinAllowed(entity this)
2221 {
2222         if (CS(this).version_mismatch) return false;
2223         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2224         if (!nJoinAllowed(this, this)) return false;
2225         if (teamplay && lockteams) return false;
2226         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2227         if (ShowTeamSelection(this)) return false;
2228         return true;
2229 }
2230
2231 .int items_added;
2232 .string shootfromfixedorigin;
2233 bool PlayerThink(entity this)
2234 {
2235         if (game_stopped || intermission_running) {
2236                 this.modelflags &= ~MF_ROCKET;
2237                 if(intermission_running)
2238                         IntermissionThink(this);
2239                 return false;
2240         }
2241
2242         if (timeout_status == TIMEOUT_ACTIVE) {
2243         // don't allow the player to turn around while game is paused
2244                 // FIXME turn this into CSQC stuff
2245                 this.v_angle = this.lastV_angle;
2246                 this.angles = this.lastV_angle;
2247                 this.fixangle = true;
2248         }
2249
2250         if (frametime) player_powerups(this);
2251
2252         if (IS_DEAD(this)) {
2253                 if (this.personal && g_race_qualifying) {
2254                         if (time > this.respawn_time) {
2255                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2256                                 respawn(this);
2257                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2258                         }
2259                 } else {
2260                         if (frametime) player_anim(this);
2261
2262                         if (this.respawn_flags & RESPAWN_DENY)
2263                         {
2264                                 STAT(RESPAWN_TIME, this) = 0;
2265                                 return false;
2266                         }
2267
2268                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2269
2270                         switch(this.deadflag)
2271                         {
2272                                 case DEAD_DYING:
2273                                 {
2274                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2275                                                 this.deadflag = DEAD_RESPAWNING;
2276                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2277                                                 this.deadflag = DEAD_DEAD;
2278                                         break;
2279                                 }
2280                                 case DEAD_DEAD:
2281                                 {
2282                                         if (button_pressed)
2283                                                 this.deadflag = DEAD_RESPAWNABLE;
2284                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2285                                                 this.deadflag = DEAD_RESPAWNING;
2286                                         break;
2287                                 }
2288                                 case DEAD_RESPAWNABLE:
2289                                 {
2290                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2291                                                 this.deadflag = DEAD_RESPAWNING;
2292                                         break;
2293                                 }
2294                                 case DEAD_RESPAWNING:
2295                                 {
2296                                         if (time > this.respawn_time)
2297                                         {
2298                                                 this.respawn_time = time + 1; // only retry once a second
2299                                                 this.respawn_time_max = this.respawn_time;
2300                                                 respawn(this);
2301                                         }
2302                                         break;
2303                                 }
2304                         }
2305
2306                         ShowRespawnCountdown(this);
2307
2308                         if (this.respawn_flags & RESPAWN_SILENT)
2309                                 STAT(RESPAWN_TIME, this) = 0;
2310                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2311                         {
2312                                 if (time < this.respawn_time)
2313                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2314                                 else if (this.deadflag != DEAD_RESPAWNING)
2315                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2316                         }
2317                         else
2318                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2319                 }
2320
2321                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2322                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2323                         STAT(RESPAWN_TIME, this) *= -1;
2324
2325                 return false;
2326         }
2327
2328         FixPlayermodel(this);
2329
2330         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2331                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2332                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2333         }
2334
2335         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2336         //if(frametime)
2337         {
2338                 this.items &= ~this.items_added;
2339
2340                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2341                 {
2342                         .entity weaponentity = weaponentities[slot];
2343                         W_WeaponFrame(this, weaponentity);
2344                 }
2345
2346                 this.items_added = 0;
2347                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2348             this.items_added |= IT_FUEL;
2349
2350                 this.items |= this.items_added;
2351         }
2352
2353         player_regen(this);
2354
2355         // WEAPONTODO: Add a weapon request for this
2356         // rot vortex charge to the charge limit
2357         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2358         {
2359                 .entity weaponentity = weaponentities[slot];
2360                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2361                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2362         }
2363
2364         if (frametime) player_anim(this);
2365
2366         // secret status
2367         secrets_setstatus(this);
2368
2369         // monsters status
2370         monsters_setstatus(this);
2371
2372         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2373
2374         return true;
2375 }
2376
2377 .bool would_spectate;
2378 void ObserverThink(entity this)
2379 {
2380         if ( CS(this).impulse )
2381         {
2382                 MinigameImpulse(this, CS(this).impulse);
2383                 CS(this).impulse = 0;
2384         }
2385
2386         if (this.flags & FL_JUMPRELEASED) {
2387                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         this.flags |= FL_SPAWNING;
2390                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2391                         this.flags &= ~FL_JUMPRELEASED;
2392                         if(SpectateNext(this)) {
2393                                 TRANSMUTE(Spectator, this);
2394                         }
2395                 } else {
2396                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2397                         set_movetype(this, preferred_movetype);
2398                 }
2399         } else {
2400                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2401                         this.flags |= FL_JUMPRELEASED;
2402                         if(this.flags & FL_SPAWNING)
2403                         {
2404                                 this.flags &= ~FL_SPAWNING;
2405                                 Join(this);
2406                                 return;
2407                         }
2408                 }
2409         }
2410 }
2411
2412 void SpectatorThink(entity this)
2413 {
2414         if ( CS(this).impulse )
2415         {
2416                 if(MinigameImpulse(this, CS(this).impulse))
2417                         CS(this).impulse = 0;
2418
2419                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2420                 {
2421                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2422                         CS(this).impulse = 0;
2423                         return;
2424                 }
2425         }
2426
2427         if (this.flags & FL_JUMPRELEASED) {
2428                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2429                         this.flags &= ~FL_JUMPRELEASED;
2430                         this.flags |= FL_SPAWNING;
2431                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2432                         this.flags &= ~FL_JUMPRELEASED;
2433                         if(SpectateNext(this)) {
2434                                 TRANSMUTE(Spectator, this);
2435                         } else {
2436                                 TRANSMUTE(Observer, this);
2437                                 PutClientInServer(this);
2438                         }
2439                         CS(this).impulse = 0;
2440                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2441                         this.flags &= ~FL_JUMPRELEASED;
2442                         if(SpectatePrev(this)) {
2443                                 TRANSMUTE(Spectator, this);
2444                         } else {
2445                                 TRANSMUTE(Observer, this);
2446                                 PutClientInServer(this);
2447                         }
2448                         CS(this).impulse = 0;
2449                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2450                         this.would_spectate = false;
2451                         this.flags &= ~FL_JUMPRELEASED;
2452                         TRANSMUTE(Observer, this);
2453                         PutClientInServer(this);
2454                 } else {
2455                         if(!SpectateUpdate(this))
2456                         {
2457                                 if(!SpectateNext(this))
2458                                 {
2459                                         PutObserverInServer(this);
2460                                         this.would_spectate = true;
2461                                 }
2462                         }
2463                 }
2464         } else {
2465                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2466                         this.flags |= FL_JUMPRELEASED;
2467                         if(this.flags & FL_SPAWNING)
2468                         {
2469                                 this.flags &= ~FL_SPAWNING;
2470                                 Join(this);
2471                                 return;
2472                         }
2473                 }
2474                 if(!SpectateUpdate(this))
2475                         PutObserverInServer(this);
2476         }
2477
2478         this.flags |= FL_CLIENT | FL_NOTARGET;
2479 }
2480
2481 void PlayerUseKey(entity this)
2482 {
2483         if (!IS_PLAYER(this))
2484                 return;
2485
2486         if(this.vehicle)
2487         {
2488                 if(!game_stopped)
2489                 {
2490                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2491                         return;
2492                 }
2493         }
2494         else if(autocvar_g_vehicles_enter)
2495         {
2496                 if(!STAT(FROZEN, this))
2497                 if(!IS_DEAD(this))
2498                 if(!game_stopped)
2499                 {
2500                         entity head, closest_target = NULL;
2501                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2502
2503                         while(head) // find the closest acceptable target to enter
2504                         {
2505                                 if(IS_VEHICLE(head))
2506                                 if(!IS_DEAD(head))
2507                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2508                                 if(head.takedamage != DAMAGE_NO)
2509                                 {
2510                                         if(closest_target)
2511                                         {
2512                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2513                                                 { closest_target = head; }
2514                                         }
2515                                         else { closest_target = head; }
2516                                 }
2517
2518                                 head = head.chain;
2519                         }
2520
2521                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2522                 }
2523         }
2524
2525         // a use key was pressed; call handlers
2526         MUTATOR_CALLHOOK(PlayerUseKey, this);
2527 }
2528
2529
2530 /*
2531 =============
2532 PlayerPreThink
2533
2534 Called every frame for each client before the physics are run
2535 =============
2536 */
2537 .float last_vehiclecheck;
2538 void PlayerPreThink (entity this)
2539 {
2540         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2541         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2542
2543         WarpZone_PlayerPhysics_FixVAngle(this);
2544
2545         if (frametime) {
2546                 // physics frames: update anticheat stuff
2547                 anticheat_prethink(this);
2548         }
2549
2550         if (blockSpectators && frametime) {
2551                 // WORKAROUND: only use dropclient in server frames (frametime set).
2552                 // Never use it in cl_movement frames (frametime zero).
2553                 checkSpectatorBlock(this);
2554         }
2555
2556         zoomstate_set = false;
2557
2558         // Check for nameless players
2559         if (this.netname == "" || this.netname != CS(this).netname_previous)
2560         {
2561                 bool assume_unchanged = (CS(this).netname_previous == "");
2562                 if (isInvisibleString(this.netname))
2563                 {
2564                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2565                         assume_unchanged = false;
2566                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2567                 }
2568                 if (!assume_unchanged && autocvar_sv_eventlog)
2569                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2570                 strcpy(CS(this).netname_previous, this.netname);
2571         }
2572
2573         // version nagging
2574         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2575         CS(this).version_nagtime = 0;
2576         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2577             // git client
2578         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2579             // git server
2580             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2581         } else {
2582             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2583             if (r < 0) { // old client
2584                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2585             } else if (r > 0) { // old server
2586                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2587             }
2588         }
2589     }
2590
2591         // GOD MODE info
2592         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2593         {
2594                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2595                 this.max_armorvalue = 0;
2596         }
2597
2598         if(IS_PLAYER(this))
2599         {
2600                 if (STAT(FROZEN, this) == 2)
2601                 {
2602                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2603                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2604                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2605
2606                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2607                                 Unfreeze(this);
2608                 }
2609                 else if (STAT(FROZEN, this) == 3)
2610                 {
2611                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2612                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2613
2614                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2615                         {
2616                                 if (this.vehicle)
2617                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2618                                 if(this.event_damage)
2619                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2620                         }
2621                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2622                                 Unfreeze(this);
2623                 }
2624         }
2625
2626         MUTATOR_CALLHOOK(PlayerPreThink, this);
2627
2628         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2629         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2630         {
2631                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2632                 {
2633                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2634                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2635                         {
2636                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2637                         }
2638                         else if(!it.owner)
2639                         {
2640                                 if(!it.team || SAME_TEAM(this, it))
2641                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2642                                 else if(autocvar_g_vehicles_steal)
2643                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2644                         }
2645                 });
2646
2647                 this.last_vehiclecheck = time + 1;
2648         }
2649
2650         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2651         {
2652                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2653                         PlayerUseKey(this);
2654                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2655         }
2656
2657         if (IS_REAL_CLIENT(this))
2658                 PrintWelcomeMessage(this);
2659
2660         if (IS_PLAYER(this)) {
2661                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2662                         error("Client can't be spawned as player on connection!");
2663                 if(!PlayerThink(this))
2664                         return;
2665         }
2666         else if (game_stopped || intermission_running) {
2667                 if(intermission_running)
2668                         IntermissionThink(this);
2669                 return;
2670         }
2671         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2672         {
2673                 CS(this).autojoin_checked = true;
2674                 // don't do this in ClientConnect
2675                 // many things can go wrong if a client is spawned as player on connection
2676                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2677                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2678                                 && (!teamplay || autocvar_g_balance_teams)))
2679                 {
2680                         campaign_bots_may_start = true;
2681                         Join(this);
2682                         return;
2683                 }
2684         }
2685         else if (IS_OBSERVER(this)) {
2686                 ObserverThink(this);
2687         }
2688         else if (IS_SPEC(this)) {
2689                 SpectatorThink(this);
2690         }
2691
2692         // WEAPONTODO: Add weapon request for this
2693         if (!zoomstate_set) {
2694                 bool wep_zoomed = false;
2695                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2696                 {
2697                         .entity weaponentity = weaponentities[slot];
2698                         Weapon thiswep = this.(weaponentity).m_weapon;
2699                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2700                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2701                 }
2702                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2703     }
2704
2705         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2706         {
2707                 CS(this).teamkill_soundtime = 0;
2708
2709                 entity e = CS(this).teamkill_soundsource;
2710                 entity oldpusher = e.pusher;
2711                 e.pusher = this;
2712                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2713                 e.pusher = oldpusher;
2714         }
2715
2716         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2717                 CS(this).taunt_soundtime = 0;
2718                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2719         }
2720
2721         target_voicescript_next(this);
2722
2723         // WEAPONTODO: Move into weaponsystem somehow
2724         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2725         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2726         {
2727                 .entity weaponentity = weaponentities[slot];
2728                 if(this.(weaponentity).m_weapon == WEP_Null)
2729                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2730         }
2731 }
2732
2733 void DrownPlayer(entity this)
2734 {
2735         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2736                 return;
2737
2738         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2739         {
2740                 if(this.air_finished < time)
2741                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2742                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2743         }
2744         else if (this.air_finished < time)
2745         {       // drown!
2746                 if (this.pain_finished < time)
2747                 {
2748                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2749                         this.pain_finished = time + 0.5;
2750                 }
2751         }
2752 }
2753
2754 .bool move_qcphysics;
2755
2756 void Player_Physics(entity this)
2757 {
2758         set_movetype(this, this.move_movetype);
2759
2760         if(!this.move_qcphysics)
2761                 return;
2762
2763         if(!frametime && !CS(this).pm_frametime)
2764                 return;
2765
2766         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2767
2768         CS(this).pm_frametime = 0;
2769 }
2770
2771 /*
2772 =============
2773 PlayerPostThink
2774
2775 Called every frame for each client after the physics are run
2776 =============
2777 */
2778 void PlayerPostThink (entity this)
2779 {
2780         Player_Physics(this);
2781
2782         if (sv_maxidle > 0)
2783         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2784         if (IS_REAL_CLIENT(this))
2785         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2786         {
2787                 int totalClients = 0;
2788                 if(sv_maxidle_slots > 0)
2789                 {
2790                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2791                         {
2792                                 ++totalClients;
2793                         });
2794                 }
2795
2796                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2797                 { /* do nothing */ }
2798                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2799                 {
2800                         if (CS(this).idlekick_lasttimeleft)
2801                         {
2802                                 CS(this).idlekick_lasttimeleft = 0;
2803                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2804                         }
2805                 }
2806                 else
2807                 {
2808                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2809                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2810                                 if (!CS(this).idlekick_lasttimeleft)
2811                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2812                         }
2813                         if (timeleft <= 0) {
2814                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2815                                 dropclient(this);
2816                                 return;
2817                         }
2818                         else if (timeleft <= 10) {
2819                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2820                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2821                 }
2822                                 CS(this).idlekick_lasttimeleft = timeleft;
2823                         }
2824                 }
2825         }
2826
2827         CheatFrame(this);
2828
2829         if (game_stopped)
2830         {
2831                 this.solid = SOLID_NOT;
2832                 this.takedamage = DAMAGE_NO;
2833                 set_movetype(this, MOVETYPE_NONE);
2834         }
2835
2836         if (IS_PLAYER(this)) {
2837                 if(this.death_time == time && IS_DEAD(this))
2838                 {
2839                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2840                         // once all the damage events of this frame have been processed with normal size
2841                         this.maxs.z = 5;
2842                         setsize(this, this.mins, this.maxs);
2843                 }
2844                 DrownPlayer(this);
2845                 UpdateChatBubble(this);
2846                 if (CS(this).impulse) ImpulseCommands(this);
2847                 if (game_stopped)
2848                 {
2849                         CSQCMODEL_AUTOUPDATE(this);
2850                         return;
2851                 }
2852                 GetPressedKeys(this);
2853         }
2854
2855         if (this.waypointsprite_attachedforcarrier) {
2856             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2857                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2858     }
2859
2860         CSQCMODEL_AUTOUPDATE(this);
2861 }
2862
2863 // hack to copy the button fields from the client entity to the Client State
2864 void PM_UpdateButtons(entity this, entity store)
2865 {
2866         if(this.impulse)
2867                 store.impulse = this.impulse;
2868         this.impulse = 0;
2869
2870         bool typing = this.buttonchat;
2871
2872         store.button0 = (typing) ? 0 : this.button0;
2873         //button1?!
2874         store.button2 = (typing) ? 0 : this.button2;
2875         store.button3 = (typing) ? 0 : this.button3;
2876         store.button4 = this.button4;
2877         store.button5 = (typing) ? 0 : this.button5;
2878         store.button6 = this.button6;
2879         store.button7 = this.button7;
2880         store.button8 = this.button8;
2881         store.button9 = this.button9;
2882         store.button10 = this.button10;
2883         store.button11 = this.button11;
2884         store.button12 = this.button12;
2885         store.button13 = this.button13;
2886         store.button14 = this.button14;
2887         store.button15 = this.button15;
2888         store.button16 = this.button16;
2889         store.buttonuse = this.buttonuse;
2890         store.buttonchat = this.buttonchat;
2891
2892         store.cursor_active = this.cursor_active;
2893         store.cursor_screen = this.cursor_screen;
2894         store.cursor_trace_start = this.cursor_trace_start;
2895         store.cursor_trace_endpos = this.cursor_trace_endpos;
2896         store.cursor_trace_ent = this.cursor_trace_ent;
2897
2898         store.ping = this.ping;
2899         store.ping_packetloss = this.ping_packetloss;
2900         store.ping_movementloss = this.ping_movementloss;
2901
2902         store.v_angle = this.v_angle;
2903         store.movement = (typing) ? '0 0 0' : this.movement;
2904 }
2905
2906 NET_HANDLE(fpsreport, bool)
2907 {
2908         int fps = ReadShort();
2909         PlayerScore_Set(sender, SP_FPS, fps);
2910         return true;
2911 }