qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/chat.qh>
   4 #include <server/world.qh>
   5 #include <server/miscfunctions.qh>
   6
   7 #include <common/command/_mod.qh>
   8
   9 #include "common.qh"
  10 #include "getreplies.qh"
  11 #include "vote.qh"
  12
  13 #include "../bot/api.qh"
  14
  15 #include "../campaign.qh"
  16 #include "../cheats.qh"
  17 #include "../client.qh"
  18 #include "../clientkill.qh"
  19 #include "../player.qh"
  20 #include "../ipban.qh"
  21 #include "../mapvoting.qh"
  22 #include "../scores.qh"
  23 #include "../teamplay.qh"
  24
  25 #include <server/mutators/_mod.qh>
  26 #include <common/gamemodes/_mod.qh>
  27
  28 #ifdef SVQC
  29         #include <common/vehicles/all.qh>
  30 #endif
  31
  32 #include <common/constants.qh>
  33 #include <common/deathtypes/all.qh>
  34 #include <common/effects/all.qh>
  35 #include <common/mapinfo.qh>
  36 #include <common/notifications/all.qh>
  37 #include <common/physics/player.qh>
  38 #include <common/teams.qh>
  39 #include <common/util.qh>
  40 #include <common/mapobjects/triggers.qh>
  41
  42 #include <common/minigames/sv_minigames.qh>
  43
  44 #include <common/monsters/_mod.qh>
  45 #include <common/monsters/sv_spawn.qh>
  46 #include <common/monsters/sv_monsters.qh>
  47
  48 #include <lib/warpzone/common.qh>
  49
  50 // =========================================================
  51 //  Server side networked commands code, reworked by Samual
  52 //  Last updated: December 28th, 2011
  53 // =========================================================
  54
  55 bool SV_ParseClientCommand_floodcheck(entity this)
  56 {
  57         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  58
  59         if (!timeout_status)  // not while paused
  60         {
  61                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  62                 {
  63                         store.cmd_floodcount += 1;
  64                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  65                 }
  66                 else
  67                 {
  68                         store.cmd_floodtime = time;
  69                         store.cmd_floodcount = 1;
  70                 }
  71         }
  72         return true;  // continue, as we're not flooding yet
  73 }
  74
  75
  76 // =======================
  77 //  Command Sub-Functions
  78 // =======================
  79
  80 void ClientCommand_autoswitch(entity caller, int request, int argc)
  81 {
  82         switch (request)
  83         {
  84                 case CMD_REQUEST_COMMAND:
  85                 {
  86                         if (argv(1) != "")
  87                         {
  88                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  89                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  90                                 return;
  91                         }
  92                 }
  93
  94                 default:
  95                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  96                 case CMD_REQUEST_USAGE:
  97                 {
  98                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  99                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
 100                         return;
 101                 }
 102         }
 103 }
 104
 105 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 106 {
 107         switch (request)
 108         {
 109                 case CMD_REQUEST_COMMAND:
 110                 {
 111                         if (argv(1) != "")
 112                         {
 113                                 if (IS_CLIENT(caller))
 114                                 {
 115                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 116
 117                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 118                                         {
 119                                                 CS(caller).version_mismatch = true;
 120                                                 ClientKill_TeamChange(caller, -2);  // observe
 121                                         }
 122                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 123                                         {
 124                                                 // JoinBestTeam(caller, false, true);
 125                                         }
 126                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 127                                         {
 128                                                 TRANSMUTE(Observer, caller);  // really?
 129                                                 stuffcmd(caller, "menu_showteamselect\n");
 130                                         }
 131                                 }
 132
 133                                 return;
 134                         }
 135                 }
 136
 137                 default:
 138                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 139                 case CMD_REQUEST_USAGE:
 140                 {
 141                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 142                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 143                         return;
 144                 }
 145         }
 146 }
 147
 148 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 149 {
 150         switch (request)
 151         {
 152                 case CMD_REQUEST_COMMAND:
 153                 {
 154                         if (argv(1) != "")
 155                         {
 156                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 157
 158                                 return;
 159                         }
 160                 }
 161
 162                 default:
 163                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 164                 case CMD_REQUEST_USAGE:
 165                 {
 166                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 167                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 168                         return;
 169                 }
 170         }
 171 }
 172
 173 void ClientCommand_wpeditor(entity caller, int request, int argc)
 174 {
 175         switch (request)
 176         {
 177                 case CMD_REQUEST_COMMAND:
 178                 {
 179                         if (!autocvar_g_waypointeditor)
 180                         {
 181                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 182                                 return;
 183                         }
 184
 185                         if (argv(1) != "")
 186                         {
 187                                 if (argv(1) == "spawn")
 188                                 {
 189                                         string s = argv(2);
 190                                         if (!IS_PLAYER(caller))
 191                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 192                                         else
 193                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 194                                         return;
 195                                 }
 196                                 else if (argv(1) == "remove")
 197                                 {
 198                                         if (!IS_PLAYER(caller))
 199                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 200                                         else
 201                                                 waypoint_remove_fromeditor(caller);
 202                                         return;
 203                                 }
 204                                 else if (argv(1) == "hardwire")
 205                                 {
 206                                         string s = argv(2);
 207                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 208                                         return;
 209                                 }
 210                                 else if (argv(1) == "lock")
 211                                 {
 212                                         waypoint_lock(caller);
 213                                         return;
 214                                 }
 215                                 else if (argv(1) == "unreachable")
 216                                 {
 217                                         if (!IS_PLAYER(caller))
 218                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 219                                         else
 220                                                 waypoint_unreachable(caller);
 221                                         return;
 222                                 }
 223                                 else if (argv(1) == "saveall")
 224                                 {
 225                                         waypoint_saveall();
 226                                         return;
 227                                 }
 228                                 else if (argv(1) == "relinkall")
 229                                 {
 230                                         waypoint_schedulerelinkall();
 231                                         return;
 232                                 }
 233                                 else if (argv(1) == "symaxis")
 234                                 {
 235                                         if (argv(2) == "set" || argv(2) == "get")
 236                                         {
 237                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 238                                                 return;
 239                                         }
 240                                 }
 241                                 else if (argv(1) == "symorigin")
 242                                 {
 243                                         if (argv(2) == "set" || argv(2) == "get")
 244                                         {
 245                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 246                                                 return;
 247                                         }
 248                                 }
 249                         }
 250                 }
 251
 252                 default:
 253                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 254                 case CMD_REQUEST_USAGE:
 255                 {
 256                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 257                         sprint(caller, "  Where 'action' can be:\n");
 258                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 259                         sprint(caller, "   ^5remove^7: removes player's nearest waypoint\n");
 260                         sprint(caller, "   ^5unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 261                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 262                         sprint(caller, "   ^5relinkall^7: relinks all waypoints as if they were respawned\n");
 263                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 264                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 265                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 266                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 267                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 268                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 269                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 270                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 271                         sprint(caller, "   ^5hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 272                         sprint(caller, "   ^5lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 273                         sprint(caller, "   ^5symorigin get|set\n");
 274                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 275                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 276                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 277                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 278                         sprint(caller, "  See 'wpeditor_menu' for a selectable list of various commands and useful settings to edit waypoints.\n");
 279                         return;
 280                 }
 281         }
 282 }
 283
 284 void ClientCommand_join(entity caller, int request)
 285 {
 286         switch (request)
 287         {
 288                 case CMD_REQUEST_COMMAND:
 289                 {
 290                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 291                         {
 292                                 if (joinAllowed(caller))
 293                                         Join(caller);
 294                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 295                                         CS(caller).autojoin_checked = -1;
 296                         }
 297
 298                         return;  // never fall through to usage
 299                 }
 300
 301                 default:
 302                 case CMD_REQUEST_USAGE:
 303                 {
 304                         sprint(caller, "\nUsage:^3 cmd join\n");
 305                         sprint(caller, "  No arguments required.\n");
 306                         return;
 307                 }
 308         }
 309 }
 310
 311 void ClientCommand_kill(entity caller, int request)
 312 {
 313         switch (request)
 314         {
 315                 case CMD_REQUEST_COMMAND:
 316                 {
 317                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 318                                 return; // no point warning about this, command does nothing
 319
 320                         if(GetResource(caller, RES_HEALTH) <= 0)
 321                         {
 322                                 sprint(caller, "Can't die - you are already dead!\n");
 323                                 return;
 324                         }
 325
 326                         ClientKill(caller);
 327
 328                         return;  // never fall through to usage
 329                 }
 330
 331                 default:
 332                 case CMD_REQUEST_USAGE:
 333                 {
 334                         sprint(caller, "\nUsage:^3 cmd kill\n");
 335                         sprint(caller, "  No arguments required.\n");
 336                         return;
 337                 }
 338         }
 339 }
 340
 341 void ClientCommand_physics(entity caller, int request, int argc)
 342 {
 343         switch (request)
 344         {
 345                 case CMD_REQUEST_COMMAND:
 346                 {
 347                         string command = strtolower(argv(1));
 348
 349                         if (!autocvar_g_physics_clientselect)
 350                         {
 351                                 sprint(caller, "Client physics selection is currently disabled.\n");
 352                                 return;
 353                         }
 354
 355                         if (command == "list" || command == "help")
 356                         {
 357                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 358                                 return;
 359                         }
 360
 361                         if (Physics_Valid(command) || command == "default")
 362                         {
 363                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 364                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 365                                 return;
 366                         }
 367                 }
 368
 369                 default:
 370                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 371                 case CMD_REQUEST_USAGE:
 372                 {
 373                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 374                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 375                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 382 {
 383         switch (request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if (IS_CLIENT(caller))
 388                         {
 389                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 390                                 {
 391                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 392                                         {
 393                                                 if (time < game_starttime) // game is already restarting
 394                                                         return;
 395                                                 if (caller.ready)            // toggle
 396                                                 {
 397                                                         caller.ready = false;
 398                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 399                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 400                                                 }
 401                                                 else
 402                                                 {
 403                                                         caller.ready = true;
 404                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 405                                                                 bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 406                                                 }
 407
 408                                                 // cannot reset the game while a timeout is active!
 409                                                 if (!timeout_status) ReadyCount();
 410                                         }
 411                                         else
 412                                         {
 413                                                 sprint(caller, "^1Game has already been restarted\n");
 414                                         }
 415                                 }
 416                         }
 417                         return;  // never fall through to usage
 418                 }
 419
 420                 default:
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         sprint(caller, "\nUsage:^3 cmd ready\n");
 424                         sprint(caller, "  No arguments required.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void ClientCommand_say(entity caller, int request, int argc, string command)
 431 {
 432         switch (request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 437                         return;  // never fall through to usage
 438                 }
 439
 440                 default:
 441                 case CMD_REQUEST_USAGE:
 442                 {
 443                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 444                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 451 {
 452         switch (request)
 453         {
 454                 case CMD_REQUEST_COMMAND:
 455                 {
 456                         if (argc >= 2)
 457                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 458                         return;  // never fall through to usage
 459                 }
 460
 461                 default:
 462                 case CMD_REQUEST_USAGE:
 463                 {
 464                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 465                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 466                         return;
 467                 }
 468         }
 469 }
 470
 471 .bool team_selected;
 472 void ClientCommand_selectteam(entity caller, int request, int argc)
 473 {
 474         switch (request)
 475         {
 476                 case CMD_REQUEST_COMMAND:
 477                 {
 478                         if (argv(1) == "")
 479                         {
 480                                 return;
 481                         }
 482                         if (!IS_CLIENT(caller))
 483                         {
 484                                 return;
 485                         }
 486                         if (!teamplay)
 487                         {
 488                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 489                                 return;
 490                         }
 491                         if (Player_GetForcedTeamIndex(caller) > 0)
 492                         {
 493                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 494                                 return;
 495                         }
 496                         if (lockteams)
 497                         {
 498                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 499                                 return;
 500                         }
 501                         float selection;
 502                         switch (argv(1))
 503                         {
 504                                 case "red":
 505                                 {
 506                                         selection = NUM_TEAM_1;
 507                                         break;
 508                                 }
 509                                 case "blue":
 510                                 {
 511                                         selection = NUM_TEAM_2;
 512                                         break;
 513                                 }
 514                                 case "yellow":
 515                                 {
 516                                         selection = NUM_TEAM_3;
 517                                         break;
 518                                 }
 519                                 case "pink":
 520                                 {
 521                                         selection = NUM_TEAM_4;
 522                                         break;
 523                                 }
 524                                 case "auto":
 525                                 {
 526                                         selection = (-1);
 527                                         break;
 528                                 }
 529                                 default:
 530                                 {
 531                                         return;
 532                                 }
 533                         }
 534                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 535                         {
 536                                 sprint(caller, "^7You already are on that team.\n");
 537                                 return;
 538                         }
 539                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 540                         {
 541                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 542                                 return;
 543                         }
 544                         if ((selection != -1) && autocvar_g_balance_teams &&
 545                                 autocvar_g_balance_teams_prevent_imbalance)
 546                         {
 547                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 548                                 TeamBalance_GetTeamCounts(balance, caller);
 549                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 550                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 551                                 {
 552                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 553                                         TeamBalance_Destroy(balance);
 554                                         return;
 555                                 }
 556                                 TeamBalance_Destroy(balance);
 557                         }
 558                         ClientKill_TeamChange(caller, selection);
 559                         if (!IS_PLAYER(caller))
 560                         {
 561                                 caller.team_selected = true; // avoids asking again for team selection on join
 562                         }
 563                         return;
 564                 }
 565                 default:
 566                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 567                 case CMD_REQUEST_USAGE:
 568                 {
 569                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 570                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 571                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 572                         return;
 573                 }
 574         }
 575 }
 576
 577 void ClientCommand_selfstuff(entity caller, int request, string command)
 578 {
 579         switch (request)
 580         {
 581                 case CMD_REQUEST_COMMAND:
 582                 {
 583                         if (argv(1) != "")
 584                         {
 585                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 586                                 return;
 587                         }
 588                 }
 589
 590                 default:
 591                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 592                 case CMD_REQUEST_USAGE:
 593                 {
 594                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 595                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 596                         return;
 597                 }
 598         }
 599 }
 600
 601 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 602 {
 603         switch (request)
 604         {
 605                 case CMD_REQUEST_COMMAND:
 606                 {
 607                         if (argv(1) != "")
 608                         {
 609                                 // float tokens;
 610                                 string s;
 611
 612                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 613                                 {
 614                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 615                                         tokenize_console(s);
 616                                 }
 617
 618                                 GetCvars(caller, CS(caller), 1);
 619
 620                                 return;
 621                         }
 622                 }
 623
 624                 default:
 625                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 626                 case CMD_REQUEST_USAGE:
 627                 {
 628                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 629                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 630                         return;
 631                 }
 632         }
 633 }
 634
 635 void ClientCommand_spectate(entity caller, int request)
 636 {
 637         switch (request)
 638         {
 639                 case CMD_REQUEST_COMMAND:
 640                 {
 641                         if (!intermission_running && IS_CLIENT(caller))
 642                         {
 643                                 if(argv(1) != "")
 644                                 {
 645                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 646                                         {
 647                                                 entity client = GetFilteredEntity(argv(1));
 648                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 649                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 650                                                 {
 651                                                         Spectate(caller, client);
 652                                                 }
 653                                                 else
 654                                                         sprint(caller, "can't spectate ", argv(1), "^7\n");
 655                                         }
 656                                         else
 657                                                 sprint(caller, "cmd spectate client only works when you are spectator/observer\n");
 658                                         return;
 659                                 }
 660
 661                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 662
 663                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 664
 665                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 666                                 if (autocvar_sv_spectate == 1)
 667                                         ClientKill_TeamChange(caller, -2); // observe
 668                         }
 669                         return; // never fall through to usage
 670                 }
 671
 672                 default:
 673                 case CMD_REQUEST_USAGE:
 674                 {
 675                         sprint(caller, "\nUsage:^3 cmd spectate [client]\n");
 676                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 677                         return;
 678                 }
 679         }
 680 }
 681
 682 void ClientCommand_suggestmap(entity caller, int request, int argc)
 683 {
 684         switch (request)
 685         {
 686                 case CMD_REQUEST_COMMAND:
 687                 {
 688                         if (argv(1) != "")
 689                         {
 690                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 691                                 return;
 692                         }
 693                 }
 694
 695                 default:
 696                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 697                 case CMD_REQUEST_USAGE:
 698                 {
 699                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 700                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 701                         return;
 702                 }
 703         }
 704 }
 705
 706 void ClientCommand_tell(entity caller, int request, int argc, string command)
 707 {
 708         switch (request)
 709         {
 710                 case CMD_REQUEST_COMMAND:
 711                 {
 712                         if (argc >= 3)
 713                         {
 714                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 715                                 {
 716                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 717                                         return;
 718                                 }
 719
 720                                 entity tell_to = GetIndexedEntity(argc, 1);
 721                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 722
 723                                 if (tell_accepted > 0)   // the target is a real client
 724                                 {
 725                                         if (tell_to != caller) // and we're allowed to send to them :D
 726                                         {
 727                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 728                                                 // In this case when the player name contains utf8 chars
 729                                                 // the message gets partially trimmed in the beginning.
 730                                                 // Potentially this bug affects any substring call that uses
 731                                                 // argv_start_index and argv_end_index.
 732
 733                                                 string utf8_enable_save = cvar_string("utf8_enable");
 734                                                 cvar_set("utf8_enable", "0");
 735                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 736                                                 cvar_set("utf8_enable", utf8_enable_save);
 737
 738                                                 Say(caller, false, tell_to, msg, true);
 739                                                 return;
 740                                         }
 741                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 742                                 }
 743                                 else if (argv(1) == "#0")
 744                                 {
 745                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 746                                         return;
 747                                 }
 748                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 749                         }
 750                 }
 751
 752                 default:
 753                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 754                 case CMD_REQUEST_USAGE:
 755                 {
 756                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 757                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 758                         return;
 759                 }
 760         }
 761 }
 762
 763 void ClientCommand_voice(entity caller, int request, int argc, string command)
 764 {
 765         switch (request)
 766         {
 767                 case CMD_REQUEST_COMMAND:
 768                 {
 769                         if (argv(1) != "")
 770                         {
 771                                 entity e = GetVoiceMessage(argv(1));
 772                                 if (!e)
 773                                 {
 774                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 775                                         return;
 776                                 }
 777                                 if (IS_DEAD(caller))
 778                                 {
 779                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 780                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 781                                         return;
 782                                 }
 783                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 784                                 {
 785                                         // observers/spectators have no player model of their own to play taunts from
 786                                         // again, allow them to see warnings
 787                                         return;
 788                                 }
 789                                 string msg = "";
 790                                 if (argc >= 3)
 791                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 792                                 VoiceMessage(caller, e, msg);
 793
 794                                 return;
 795                         }
 796                 }
 797
 798                 default:
 799                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 800                 case CMD_REQUEST_USAGE:
 801                 {
 802                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 803                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 804                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 805                         return;
 806                 }
 807         }
 808 }
 809
 810 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 811 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 812 void ClientCommand_(entity caller, int request)
 813 {
 814     switch(request)
 815     {
 816         case CMD_REQUEST_COMMAND:
 817         {
 818
 819             return; // never fall through to usage
 820         }
 821
 822         default:
 823         case CMD_REQUEST_USAGE:
 824         {
 825             sprint(caller, "\nUsage:^3 cmd \n");
 826             sprint(caller, "  No arguments required.\n");
 827             return;
 828         }
 829     }
 830 }
 831 */
 832
 833
 834 // =====================================
 835 //  Macro system for networked commands
 836 // =====================================
 837
 838 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 839 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 840         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 841         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 842         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 843         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 844         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 845         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 846         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 847         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 848         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 849         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 850         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 851         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 852         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 853         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 854         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 855         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 856         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 857         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 858         /* nothing */
 859
 860 void ClientCommand_macro_help(entity caller)
 861 {
 862         #define CLIENT_COMMAND(name, function, description) \
 863                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 864
 865         CLIENT_COMMANDS(NULL, 0, 0, "");
 866 #undef CLIENT_COMMAND
 867 }
 868
 869 float ClientCommand_macro_command(int argc, entity caller, string command)
 870 {
 871         #define CLIENT_COMMAND(name, function, description) \
 872                 { if (name == strtolower(argv(0))) { function; return true; } }
 873
 874         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 875 #undef CLIENT_COMMAND
 876
 877         return false;
 878 }
 879
 880 float ClientCommand_macro_usage(int argc, entity caller)
 881 {
 882         #define CLIENT_COMMAND(name, function, description) \
 883                 { if (name == strtolower(argv(1))) { function; return true; } }
 884
 885         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 886 #undef CLIENT_COMMAND
 887
 888         return false;
 889 }
 890
 891 void ClientCommand_macro_write_aliases(float fh)
 892 {
 893         #define CLIENT_COMMAND(name, function, description) \
 894                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 895
 896         CLIENT_COMMANDS(NULL, 0, 0, "");
 897 #undef CLIENT_COMMAND
 898 }
 899
 900 // ======================================
 901 //  Main Function Called By Engine (cmd)
 902 // ======================================
 903 // If this function exists, server game code parses clientcommand before the engine code gets it.
 904
 905 void SV_ParseClientCommand(entity this, string command)
 906 {
 907         // If invalid UTF-8, don't even parse it
 908         string command2 = "";
 909         float len = strlen(command);
 910         float i;
 911         for (i = 0; i < len; ++i)
 912                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 913         if (command != command2) return;
 914
 915         // if we're banned, don't even parse the command
 916         if (Ban_MaybeEnforceBanOnce(this)) return;
 917
 918         int argc = tokenize_console(command);
 919
 920         // Guide for working with argc arguments by example:
 921         // argc:   1    - 2      - 3     - 4
 922         // argv:   0    - 1      - 2     - 3
 923         // cmd     vote - master - login - password
 924
 925         // for floodcheck
 926         switch (strtolower(argv(0)))
 927         {
 928                 // exempt commands which are not subject to floodcheck
 929                 case "begin": break;                               // handled by engine in host_cmd.c
 930                 case "download": break;                            // handled by engine in cl_parse.c
 931                 case "mv_getpicture": break;                       // handled by server in this file
 932                 case "wpeditor": break;                            // handled by server in this file
 933                 case "pause": break;                               // handled by engine in host_cmd.c
 934                 case "prespawn": break;                            // handled by engine in host_cmd.c
 935                 case "sentcvar": break;                            // handled by server in this file
 936                 case "spawn": break;                               // handled by engine in host_cmd.c
 937                 case "color": case "topcolor": case "bottomcolor": if(teamplay) return; else break; // handled by engine in host_cmd.c
 938                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 939
 940                 default:
 941                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 942                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 943         }
 944
 945         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 946         if (argv(0) == "help")
 947         {
 948                 if (argc == 1)
 949                 {
 950                         sprint(this, "\nClient networked commands:\n");
 951                         ClientCommand_macro_help(this);
 952
 953                         sprint(this, "\nCommon networked commands:\n");
 954                         CommonCommand_macro_help(this);
 955
 956                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 957                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 958                         return;
 959                 }
 960                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 961                 {
 962                         return;
 963                 }
 964                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 965                 {
 966                         return;
 967                 }
 968         }
 969         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 970         {
 971                 return;  // handled by a mutator
 972         }
 973         else if (CheatCommand(this, argc))
 974         {
 975                 return;  // handled by server/cheats.qc
 976         }
 977         else if (CommonCommand_macro_command(argc, this, command))
 978         {
 979                 return;                                          // handled by server/command/common.qc
 980         }
 981         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 982         {
 983                 return;                                          // handled by one of the above ClientCommand_* functions
 984         }
 985         else
 986         {
 987                 clientcommand(this, command);
 988         }
 989 }