qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 centerprint(self, PREVENT_JOIN_TEXT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobspawn(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         entity e;
 192                         string tospawn, mname;
 193                         float moveflag;
 194
 195                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 196                         tospawn = argv(1);
 197                         mname = argv(3);
 198
 199                         if(tospawn == "list")
 200                         {
 201                                 sprint(self, "Available monsters:\n");
 202                                 sprint(self, strcat(monsterlist(), "\n"));
 203                                 return;
 204                         }
 205
 206                         if(self.classname != STR_PLAYER) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 207                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); }
 208                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 209                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 210                         else
 211                         {
 212                                 // all worked out, so continue
 213                                 self.monstercount += 1;
 214                                 totalspawned += 1;
 215
 216                                 makevectors(self.v_angle);
 217                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 218
 219                                 e = spawnmonster(tospawn, self, self, trace_endpos, FALSE, moveflag);
 220                                 if(mname != "") e.netname = strzone(mname);
 221
 222                                 sprint(self, strcat("Spawned 1 ", tospawn, "\n"));
 223                         }
 224
 225                         return;
 226                 }
 227
 228                 default:
 229                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 230                 case CMD_REQUEST_USAGE:
 231                 {
 232                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 233                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 234                         return;
 235                 }
 236         }
 237 }
 238
 239 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 240 {
 241         switch(request)
 242         {
 243                 case CMD_REQUEST_COMMAND:
 244                 {
 245                         if(self.flags & FL_CLIENT)
 246                         {
 247                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 248                                 {
 249                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 250                                         {
 251                                                 if (self.ready) // toggle
 252                                                 {
 253                                                         self.ready = FALSE;
 254                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 255                                                 }
 256                                                 else
 257                                                 {
 258                                                         self.ready = TRUE;
 259                                                         bprint(self.netname, "^2 is ready\n");
 260                                                 }
 261
 262                                                 // cannot reset the game while a timeout is active!
 263                                                 if not(timeout_status)
 264                                                         ReadyCount();
 265                                         } else {
 266                                                 sprint(self, "^1Game has already been restarted\n");
 267                                         }
 268                                 }
 269                         }
 270                         return; // never fall through to usage
 271                 }
 272
 273                 default:
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         sprint(self, "\nUsage:^3 cmd ready\n");
 277                         sprint(self, "  No arguments required.\n");
 278                         return;
 279                 }
 280         }
 281 }
 282
 283 void ClientCommand_say(float request, float argc, string command)
 284 {
 285         switch(request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 290                         return; // never fall through to usage
 291                 }
 292
 293                 default:
 294                 case CMD_REQUEST_USAGE:
 295                 {
 296                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 297                         sprint(self, "  Where 'message' is the string of text to say.\n");
 298                         return;
 299                 }
 300         }
 301 }
 302
 303 void ClientCommand_say_team(float request, float argc, string command)
 304 {
 305         switch(request)
 306         {
 307                 case CMD_REQUEST_COMMAND:
 308                 {
 309                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 310                         return; // never fall through to usage
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 317                         sprint(self, "  Where 'message' is the string of text to say.\n");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void ClientCommand_selectteam(float request, float argc)
 324 {
 325         switch(request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         if(argv(1) != "")
 330                         {
 331                                 if(self.flags & FL_CLIENT)
 332                                 {
 333                                         if(teamplay)
 334                                                 if not(self.team_forced > 0)
 335                                                         if not(lockteams)
 336                                                         {
 337                                                                 float selection;
 338
 339                                                                 switch(argv(1))
 340                                                                 {
 341                                                                         case "red": selection = COLOR_TEAM1; break;
 342                                                                         case "blue": selection = COLOR_TEAM2; break;
 343                                                                         case "yellow": selection = COLOR_TEAM3; break;
 344                                                                         case "pink": selection = COLOR_TEAM4; break;
 345                                                                         case "auto": selection = (-1); break;
 346
 347                                                                         default: selection = 0; break;
 348                                                                 }
 349
 350                                                                 if(selection)
 351                                                                 {
 352                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 353                                                                                 sprint(self, "^7You already are on that team.\n");
 354                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 355                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 356                                                                         else
 357                                                                                 ClientKill_TeamChange(selection);
 358                                                                 }
 359                                                         }
 360                                                         else
 361                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 362                                                 else
 363                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 364                                         else
 365                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 366                                 }
 367                                 return;
 368                         }
 369                 }
 370
 371                 default:
 372                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 373                 case CMD_REQUEST_USAGE:
 374                 {
 375                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 376                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 377                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 378                         return;
 379                 }
 380         }
 381 }
 382
 383 void ClientCommand_selfstuff(float request, string command)
 384 {
 385         switch(request)
 386         {
 387                 case CMD_REQUEST_COMMAND:
 388                 {
 389                         if(argv(1) != "")
 390                         {
 391                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 392                                 return;
 393                         }
 394                 }
 395
 396                 default:
 397                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 398                 case CMD_REQUEST_USAGE:
 399                 {
 400                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 401                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 402                         return;
 403                 }
 404         }
 405 }
 406
 407 void ClientCommand_sentcvar(float request, float argc, string command)
 408 {
 409         switch(request)
 410         {
 411                 case CMD_REQUEST_COMMAND:
 412                 {
 413                         if(argv(1) != "")
 414                         {
 415                                 //float tokens;
 416                                 string s;
 417
 418                                 if(argc == 2) // undefined cvar: use the default value on the server then
 419                                 {
 420                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 421                                         tokenize_console(s);
 422                                 }
 423
 424                                 GetCvars(1);
 425
 426                                 return;
 427                         }
 428                 }
 429
 430                 default:
 431                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 432                 case CMD_REQUEST_USAGE:
 433                 {
 434                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 435                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 436                         return;
 437                 }
 438         }
 439 }
 440
 441 void ClientCommand_spectate(float request)
 442 {
 443         switch(request)
 444         {
 445                 case CMD_REQUEST_COMMAND:
 446                 {
 447                         if(self.flags & FL_CLIENT)
 448                         {
 449                                 if(g_arena) { return; }
 450                                 if(g_lms)
 451                                 {
 452                                         if(self.lms_spectate_warning)
 453                                         {
 454                                                 // mark player as spectator
 455                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 456                                         }
 457                                         else
 458                                         {
 459                                                 self.lms_spectate_warning = 1;
 460                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 461                                                 return;
 462                                         }
 463                                 }
 464
 465                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 466                                         ClientKill_TeamChange(-2); // observe
 467
 468                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 469                                 // note: if arena game mode is ever done properly, this needs to be removed.
 470                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 471                                 {
 472                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 473                                         self.caplayer = 0;
 474                                 }
 475                         }
 476                         return; // never fall through to usage
 477                 }
 478
 479                 default:
 480                 case CMD_REQUEST_USAGE:
 481                 {
 482                         sprint(self, "\nUsage:^3 cmd spectate\n");
 483                         sprint(self, "  No arguments required.\n");
 484                         return;
 485                 }
 486         }
 487 }
 488
 489 void ClientCommand_suggestmap(float request, float argc)
 490 {
 491         switch(request)
 492         {
 493                 case CMD_REQUEST_COMMAND:
 494                 {
 495                         if(argv(1) != "")
 496                         {
 497                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 498                                 return;
 499                         }
 500                 }
 501
 502                 default:
 503                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 504                 case CMD_REQUEST_USAGE:
 505                 {
 506                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 507                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 508                         return;
 509                 }
 510         }
 511 }
 512
 513 void ClientCommand_tell(float request, float argc, string command)
 514 {
 515         switch(request)
 516         {
 517                 case CMD_REQUEST_COMMAND:
 518                 {
 519                         if(argc >= 3)
 520                         {
 521                                 entity tell_to = GetIndexedEntity(argc, 1);
 522                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 523
 524                                 if(tell_accepted > 0) // the target is a real client
 525                                 {
 526                                         if(tell_to != self) // and we're allowed to send to them :D
 527                                         {
 528                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 529                                                 return;
 530                                         }
 531                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 532                                 }
 533                                 else if(argv(1) == "#0")
 534                                 {
 535                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 536                                         return;
 537                                 }
 538                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 539                         }
 540                 }
 541
 542                 default:
 543                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 547                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void ClientCommand_voice(float request, float argc, string command)
 554 {
 555         switch(request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         if(argv(1) != "")
 560                         {
 561                                 if(argc >= 3)
 562                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 563                                 else
 564                                         VoiceMessage(argv(1), "");
 565
 566                                 return;
 567                         }
 568                 }
 569
 570                 default:
 571                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 572                 case CMD_REQUEST_USAGE:
 573                 {
 574                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 575                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 576                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 577                         return;
 578                 }
 579         }
 580 }
 581
 582 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 583 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 584 void ClientCommand_(float request)
 585 {
 586         switch(request)
 587         {
 588                 case CMD_REQUEST_COMMAND:
 589                 {
 590
 591                         return; // never fall through to usage
 592                 }
 593
 594                 default:
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         sprint(self, "\nUsage:^3 cmd \n");
 598                         sprint(self, "  No arguments required.\n");
 599                         return;
 600                 }
 601         }
 602 }
 603 */
 604
 605
 606 // =====================================
 607 //  Macro system for networked commands
 608 // =====================================
 609
 610 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 611 #define CLIENT_COMMANDS(request,arguments,command) \
 612         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 613         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 614         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 615         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 616         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 617         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 618         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 619         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 620         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 621         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 622         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 623         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 624         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 625         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 626         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 627         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 628         /* nothing */
 629
 630 void ClientCommand_macro_help()
 631 {
 632         #define CLIENT_COMMAND(name,function,description) \
 633                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 634
 635         CLIENT_COMMANDS(0, 0, "")
 636         #undef CLIENT_COMMAND
 637
 638         return;
 639 }
 640
 641 float ClientCommand_macro_command(float argc, string command)
 642 {
 643         #define CLIENT_COMMAND(name,function,description) \
 644                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 645
 646         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 647         #undef CLIENT_COMMAND
 648
 649         return FALSE;
 650 }
 651
 652 float ClientCommand_macro_usage(float argc)
 653 {
 654         #define CLIENT_COMMAND(name,function,description) \
 655                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 656
 657         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 658         #undef CLIENT_COMMAND
 659
 660         return FALSE;
 661 }
 662
 663 void ClientCommand_macro_write_aliases(float fh)
 664 {
 665         #define CLIENT_COMMAND(name,function,description) \
 666                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 667
 668         CLIENT_COMMANDS(0, 0, "")
 669         #undef CLIENT_COMMAND
 670
 671         return;
 672 }
 673
 674 // ======================================
 675 //  Main Function Called By Engine (cmd)
 676 // ======================================
 677 // If this function exists, server game code parses clientcommand before the engine code gets it.
 678
 679 void SV_ParseClientCommand(string command)
 680 {
 681         // if we're banned, don't even parse the command
 682         if(Ban_MaybeEnforceBanOnce(self))
 683                 return;
 684
 685         float argc = tokenize_console(command);
 686
 687         // for the mutator hook system
 688         cmd_name = strtolower(argv(0));
 689         cmd_argc = argc;
 690         cmd_string = command;
 691
 692         // Guide for working with argc arguments by example:
 693         // argc:   1    - 2      - 3     - 4
 694         // argv:   0    - 1      - 2     - 3
 695         // cmd     vote - master - login - password
 696
 697         // for floodcheck
 698         switch(strtolower(argv(0)))
 699         {
 700                 // exempt commands which are not subject to floodcheck
 701                 case "begin": break; // handled by engine in host_cmd.c
 702                 case "download": break; // handled by engine in cl_parse.c
 703                 case "mv_getpicture": break; // handled by server in this file
 704                 case "pause": break; // handled by engine in host_cmd.c
 705                 case "prespawn": break; // handled by engine in host_cmd.c
 706                 case "sentcvar": break; // handled by server in this file
 707                 case "spawn": break; // handled by engine in host_cmd.c
 708
 709                 default:
 710                         if(SV_ParseClientCommand_floodcheck())
 711                                 break; // "TRUE": continue, as we're not flooding yet
 712                         else
 713                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 714         }
 715
 716         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 717         if(argv(0) == "help")
 718         {
 719                 if(argc == 1)
 720                 {
 721                         sprint(self, "\nClient networked commands:\n");
 722                         ClientCommand_macro_help();
 723
 724                         sprint(self, "\nCommon networked commands:\n");
 725                         CommonCommand_macro_help(self);
 726
 727                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 728                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 729                         return;
 730                 }
 731                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 732                 {
 733                         return;
 734                 }
 735                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 736                 {
 737                         return;
 738                 }
 739         }
 740         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 741         {
 742                 return; // handled by a mutator
 743         }
 744         else if(CheatCommand(argc))
 745         {
 746                 return; // handled by server/cheats.qc
 747         }
 748         else if(CommonCommand_macro_command(argc, self, command))
 749         {
 750                 return; // handled by server/command/common.qc
 751         }
 752         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 753         {
 754                 return; // handled by one of the above ClientCommand_* functions
 755         }
 756         else
 757                 clientcommand(self, command);
 758 }