qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         if (!IS_PLAYER(caller))
 188                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 189                                         else
 190                                                 waypoint_spawn_fromeditor(caller, (argv(2) == "crosshair"), (argv(2) == "jump"));
 191                                         return;
 192                                 }
 193                                 else if (argv(1) == "remove")
 194                                 {
 195                                         if (!IS_PLAYER(caller))
 196                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 197                                         else
 198                                                 waypoint_remove_fromeditor(caller);
 199                                         return;
 200                                 }
 201                                 else if (argv(1) == "unreachable")
 202                                 {
 203                                         if (!IS_PLAYER(caller))
 204                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 205                                         else
 206                                                 waypoint_unreachable(caller);
 207                                         return;
 208                                 }
 209                                 else if (argv(1) == "saveall")
 210                                 {
 211                                         waypoint_saveall();
 212                                         return;
 213                                 }
 214                                 else if (argv(1) == "relinkall")
 215                                 {
 216                                         waypoint_schedulerelinkall();
 217                                         return;
 218                                 }
 219                                 else if (argv(1) == "symaxis")
 220                                 {
 221                                         if (argv(2) == "set" || argv(2) == "get")
 222                                         {
 223                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 224                                                 return;
 225                                         }
 226                                 }
 227                                 else if (argv(1) == "symorigin")
 228                                 {
 229                                         if (argv(2) == "set" || argv(2) == "get")
 230                                         {
 231                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 232                                                 return;
 233                                         }
 234                                 }
 235                         }
 236                 }
 237
 238                 default:
 239                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 240                 case CMD_REQUEST_USAGE:
 241                 {
 242                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 243                         sprint(caller, "  Where 'action' can be:\n");
 244                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 245                         sprint(caller, "   ^5remove^7: remove player's nearest waypoint\n");
 246                         sprint(caller, "   ^5unreachable^7: useful to reveal waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 247                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 248                         sprint(caller, "   ^5relinkall^7: relink all waypoints as if they were respawned\n");
 249                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position (useful to spawn custom jumppad waypoints)\n");
 250                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint\n");
 251                         sprint(caller, "   ^5symorigin get|set\n");
 252                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 253                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 254                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical");
 255                         sprint(caller, "   ^7 so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 256                         return;
 257                 }
 258         }
 259 }
 260
 261 void ClientCommand_join(entity caller, int request)
 262 {
 263         switch (request)
 264         {
 265                 case CMD_REQUEST_COMMAND:
 266                 {
 267                         if (!game_stopped)
 268                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 269                         if (joinAllowed(caller))
 270                                 Join(caller);
 271
 272                         return;  // never fall through to usage
 273                 }
 274
 275                 default:
 276                 case CMD_REQUEST_USAGE:
 277                 {
 278                         sprint(caller, "\nUsage:^3 cmd join\n");
 279                         sprint(caller, "  No arguments required.\n");
 280                         return;
 281                 }
 282         }
 283 }
 284
 285 void ClientCommand_kill(entity caller, int request)
 286 {
 287         switch (request)
 288         {
 289                 case CMD_REQUEST_COMMAND:
 290                 {
 291                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 292                                 return; // no point warning about this, command does nothing
 293
 294                         if(GetResource(caller, RES_HEALTH) <= 0)
 295                         {
 296                                 sprint(caller, "Can't die - you are already dead!\n");
 297                                 return;
 298                         }
 299
 300                         ClientKill(caller);
 301
 302                         return;  // never fall through to usage
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         sprint(caller, "\nUsage:^3 cmd kill\n");
 309                         sprint(caller, "  No arguments required.\n");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 void ClientCommand_physics(entity caller, int request, int argc)
 316 {
 317         switch (request)
 318         {
 319                 case CMD_REQUEST_COMMAND:
 320                 {
 321                         string command = strtolower(argv(1));
 322
 323                         if (!autocvar_g_physics_clientselect)
 324                         {
 325                                 sprint(caller, "Client physics selection is currently disabled.\n");
 326                                 return;
 327                         }
 328
 329                         if (command == "list" || command == "help")
 330                         {
 331                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 332                                 return;
 333                         }
 334
 335                         if (Physics_Valid(command) || command == "default")
 336                         {
 337                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 338                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 339                                 return;
 340                         }
 341                 }
 342
 343                 default:
 344                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 345                 case CMD_REQUEST_USAGE:
 346                 {
 347                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 348                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 349                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 356 {
 357         switch (request)
 358         {
 359                 case CMD_REQUEST_COMMAND:
 360                 {
 361                         if (IS_CLIENT(caller))
 362                         {
 363                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 364                                 {
 365                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 366                                         {
 367                                                 if (time < game_starttime) // game is already restarting
 368                                                         return;
 369                                                 if (caller.ready)            // toggle
 370                                                 {
 371                                                         caller.ready = false;
 372                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 373                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 374                                                 }
 375                                                 else
 376                                                 {
 377                                                         caller.ready = true;
 378                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 379                                                                 bprint(playername(caller, false), "^2 is ready\n");
 380                                                 }
 381
 382                                                 // cannot reset the game while a timeout is active!
 383                                                 if (!timeout_status) ReadyCount();
 384                                         }
 385                                         else
 386                                         {
 387                                                 sprint(caller, "^1Game has already been restarted\n");
 388                                         }
 389                                 }
 390                         }
 391                         return;  // never fall through to usage
 392                 }
 393
 394                 default:
 395                 case CMD_REQUEST_USAGE:
 396                 {
 397                         sprint(caller, "\nUsage:^3 cmd ready\n");
 398                         sprint(caller, "  No arguments required.\n");
 399                         return;
 400                 }
 401         }
 402 }
 403
 404 void ClientCommand_say(entity caller, int request, int argc, string command)
 405 {
 406         switch (request)
 407         {
 408                 case CMD_REQUEST_COMMAND:
 409                 {
 410                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 411                         return;  // never fall through to usage
 412                 }
 413
 414                 default:
 415                 case CMD_REQUEST_USAGE:
 416                 {
 417                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 418                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 419                         return;
 420                 }
 421         }
 422 }
 423
 424 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 425 {
 426         switch (request)
 427         {
 428                 case CMD_REQUEST_COMMAND:
 429                 {
 430                         if (argc >= 2)
 431                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 432                         return;  // never fall through to usage
 433                 }
 434
 435                 default:
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 439                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 .bool team_selected;
 446 void ClientCommand_selectteam(entity caller, int request, int argc)
 447 {
 448         switch (request)
 449         {
 450                 case CMD_REQUEST_COMMAND:
 451                 {
 452                         if (argv(1) == "")
 453                         {
 454                                 return;
 455                         }
 456                         if (!IS_CLIENT(caller))
 457                         {
 458                                 return;
 459                         }
 460                         if (!teamplay)
 461                         {
 462                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 463                                 return;
 464                         }
 465                         if (Player_GetForcedTeamIndex(caller) > 0)
 466                         {
 467                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 468                                 return;
 469                         }
 470                         if (lockteams)
 471                         {
 472                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 473                                 return;
 474                         }
 475                         float selection;
 476                         switch (argv(1))
 477                         {
 478                                 case "red":
 479                                 {
 480                                         selection = NUM_TEAM_1;
 481                                         break;
 482                                 }
 483                                 case "blue":
 484                                 {
 485                                         selection = NUM_TEAM_2;
 486                                         break;
 487                                 }
 488                                 case "yellow":
 489                                 {
 490                                         selection = NUM_TEAM_3;
 491                                         break;
 492                                 }
 493                                 case "pink":
 494                                 {
 495                                         selection = NUM_TEAM_4;
 496                                         break;
 497                                 }
 498                                 case "auto":
 499                                 {
 500                                         selection = (-1);
 501                                         break;
 502                                 }
 503                                 default:
 504                                 {
 505                                         return;
 506                                 }
 507                         }
 508                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 509                         {
 510                                 sprint(caller, "^7You already are on that team.\n");
 511                                 return;
 512                         }
 513                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 514                         {
 515                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 516                                 return;
 517                         }
 518                         if ((selection != -1) && autocvar_g_balance_teams &&
 519                                 autocvar_g_balance_teams_prevent_imbalance)
 520                         {
 521                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 522                                 TeamBalance_GetTeamCounts(balance, caller);
 523                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 524                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 525                                 {
 526                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 527                                         TeamBalance_Destroy(balance);
 528                                         return;
 529                                 }
 530                                 TeamBalance_Destroy(balance);
 531                         }
 532                         ClientKill_TeamChange(caller, selection);
 533                         if (!IS_PLAYER(caller))
 534                         {
 535                                 caller.team_selected = true; // avoids asking again for team selection on join
 536                         }
 537                         return;
 538                 }
 539                 default:
 540                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 541                 case CMD_REQUEST_USAGE:
 542                 {
 543                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 544                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 545                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 546                         return;
 547                 }
 548         }
 549 }
 550
 551 void ClientCommand_selfstuff(entity caller, int request, string command)
 552 {
 553         switch (request)
 554         {
 555                 case CMD_REQUEST_COMMAND:
 556                 {
 557                         if (argv(1) != "")
 558                         {
 559                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 560                                 return;
 561                         }
 562                 }
 563
 564                 default:
 565                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 566                 case CMD_REQUEST_USAGE:
 567                 {
 568                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 569                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 570                         return;
 571                 }
 572         }
 573 }
 574
 575 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 576 {
 577         switch (request)
 578         {
 579                 case CMD_REQUEST_COMMAND:
 580                 {
 581                         if (argv(1) != "")
 582                         {
 583                                 // float tokens;
 584                                 string s;
 585
 586                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 587                                 {
 588                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 589                                         tokenize_console(s);
 590                                 }
 591
 592                                 GetCvars(caller, CS(caller), 1);
 593
 594                                 return;
 595                         }
 596                 }
 597
 598                 default:
 599                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 600                 case CMD_REQUEST_USAGE:
 601                 {
 602                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 603                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 void ClientCommand_spectate(entity caller, int request)
 610 {
 611         switch (request)
 612         {
 613                 case CMD_REQUEST_COMMAND:
 614                 {
 615                         if (!intermission_running && IS_CLIENT(caller))
 616                         {
 617                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 618                                 {
 619                                         entity client = GetFilteredEntity(argv(1));
 620                                         int spec_accepted = VerifyClientEntity(client, false, false);
 621                                         if(spec_accepted > 0 && IS_PLAYER(client))
 622                                         {
 623                                                 if(Spectate(caller, client))
 624                                                         return; // fall back to regular handling
 625                                         }
 626                                 }
 627
 628                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 629
 630                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 631
 632                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 633                                 if (autocvar_sv_spectate == 1)
 634                                         ClientKill_TeamChange(caller, -2); // observe
 635                         }
 636                         return; // never fall through to usage
 637                 }
 638
 639                 default:
 640                 case CMD_REQUEST_USAGE:
 641                 {
 642                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 643                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 644                         return;
 645                 }
 646         }
 647 }
 648
 649 void ClientCommand_suggestmap(entity caller, int request, int argc)
 650 {
 651         switch (request)
 652         {
 653                 case CMD_REQUEST_COMMAND:
 654                 {
 655                         if (argv(1) != "")
 656                         {
 657                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 658                                 return;
 659                         }
 660                 }
 661
 662                 default:
 663                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 664                 case CMD_REQUEST_USAGE:
 665                 {
 666                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 667                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 668                         return;
 669                 }
 670         }
 671 }
 672
 673 void ClientCommand_tell(entity caller, int request, int argc, string command)
 674 {
 675         switch (request)
 676         {
 677                 case CMD_REQUEST_COMMAND:
 678                 {
 679                         if (argc >= 3)
 680                         {
 681                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 682                                 {
 683                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 684                                         return;
 685                                 }
 686
 687                                 entity tell_to = GetIndexedEntity(argc, 1);
 688                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 689
 690                                 if (tell_accepted > 0)   // the target is a real client
 691                                 {
 692                                         if (tell_to != caller) // and we're allowed to send to them :D
 693                                         {
 694                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 695                                                 // In this case when the player name contains utf8 chars
 696                                                 // the message gets partially trimmed in the beginning.
 697                                                 // Potentially this bug affects any substring call that uses
 698                                                 // argv_start_index and argv_end_index.
 699
 700                                                 string utf8_enable_save = cvar_string("utf8_enable");
 701                                                 cvar_set("utf8_enable", "0");
 702                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 703                                                 cvar_set("utf8_enable", utf8_enable_save);
 704
 705                                                 Say(caller, false, tell_to, msg, true);
 706                                                 return;
 707                                         }
 708                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 709                                 }
 710                                 else if (argv(1) == "#0")
 711                                 {
 712                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 713                                         return;
 714                                 }
 715                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 716                         }
 717                 }
 718
 719                 default:
 720                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 721                 case CMD_REQUEST_USAGE:
 722                 {
 723                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 724                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 725                         return;
 726                 }
 727         }
 728 }
 729
 730 void ClientCommand_voice(entity caller, int request, int argc, string command)
 731 {
 732         switch (request)
 733         {
 734                 case CMD_REQUEST_COMMAND:
 735                 {
 736                         if (argv(1) != "")
 737                         {
 738                                 entity e = GetVoiceMessage(argv(1));
 739                                 if (!e)
 740                                 {
 741                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 742                                         return;
 743                                 }
 744                                 string msg = "";
 745                                 if (argc >= 3)
 746                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 747                                 VoiceMessage(caller, e, msg);
 748
 749                                 return;
 750                         }
 751                 }
 752
 753                 default:
 754                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 755                 case CMD_REQUEST_USAGE:
 756                 {
 757                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 758                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 759                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 760                         return;
 761                 }
 762         }
 763 }
 764
 765 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 766 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 767 void ClientCommand_(entity caller, int request)
 768 {
 769     switch(request)
 770     {
 771         case CMD_REQUEST_COMMAND:
 772         {
 773
 774             return; // never fall through to usage
 775         }
 776
 777         default:
 778         case CMD_REQUEST_USAGE:
 779         {
 780             sprint(caller, "\nUsage:^3 cmd \n");
 781             sprint(caller, "  No arguments required.\n");
 782             return;
 783         }
 784     }
 785 }
 786 */
 787
 788
 789 // =====================================
 790 //  Macro system for networked commands
 791 // =====================================
 792
 793 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 794 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 795         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 796         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 797         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 798         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 799         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 800         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 801         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 802         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 803         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 804         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 805         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 806         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 807         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 808         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 809         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 810         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 811         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 812         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 813         /* nothing */
 814
 815 void ClientCommand_macro_help(entity caller)
 816 {
 817         #define CLIENT_COMMAND(name, function, description) \
 818                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 819
 820         CLIENT_COMMANDS(NULL, 0, 0, "");
 821 #undef CLIENT_COMMAND
 822 }
 823
 824 float ClientCommand_macro_command(int argc, entity caller, string command)
 825 {
 826         #define CLIENT_COMMAND(name, function, description) \
 827                 { if (name == strtolower(argv(0))) { function; return true; } }
 828
 829         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 830 #undef CLIENT_COMMAND
 831
 832         return false;
 833 }
 834
 835 float ClientCommand_macro_usage(int argc, entity caller)
 836 {
 837         #define CLIENT_COMMAND(name, function, description) \
 838                 { if (name == strtolower(argv(1))) { function; return true; } }
 839
 840         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 841 #undef CLIENT_COMMAND
 842
 843         return false;
 844 }
 845
 846 void ClientCommand_macro_write_aliases(float fh)
 847 {
 848         #define CLIENT_COMMAND(name, function, description) \
 849                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 850
 851         CLIENT_COMMANDS(NULL, 0, 0, "");
 852 #undef CLIENT_COMMAND
 853 }
 854
 855 // ======================================
 856 //  Main Function Called By Engine (cmd)
 857 // ======================================
 858 // If this function exists, server game code parses clientcommand before the engine code gets it.
 859
 860 void SV_ParseClientCommand(entity this, string command)
 861 {
 862         // If invalid UTF-8, don't even parse it
 863         string command2 = "";
 864         float len = strlen(command);
 865         float i;
 866         for (i = 0; i < len; ++i)
 867                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 868         if (command != command2) return;
 869
 870         // if we're banned, don't even parse the command
 871         if (Ban_MaybeEnforceBanOnce(this)) return;
 872
 873         int argc = tokenize_console(command);
 874
 875         // Guide for working with argc arguments by example:
 876         // argc:   1    - 2      - 3     - 4
 877         // argv:   0    - 1      - 2     - 3
 878         // cmd     vote - master - login - password
 879
 880         // for floodcheck
 881         switch (strtolower(argv(0)))
 882         {
 883                 // exempt commands which are not subject to floodcheck
 884                 case "begin": break;                               // handled by engine in host_cmd.c
 885                 case "download": break;                            // handled by engine in cl_parse.c
 886                 case "mv_getpicture": break;                       // handled by server in this file
 887                 case "wpeditor": break;                            // handled by server in this file
 888                 case "pause": break;                               // handled by engine in host_cmd.c
 889                 case "prespawn": break;                            // handled by engine in host_cmd.c
 890                 case "sentcvar": break;                            // handled by server in this file
 891                 case "spawn": break;                               // handled by engine in host_cmd.c
 892                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 893
 894                 default:
 895                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 896                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 897         }
 898
 899         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 900         if (argv(0) == "help")
 901         {
 902                 if (argc == 1)
 903                 {
 904                         sprint(this, "\nClient networked commands:\n");
 905                         ClientCommand_macro_help(this);
 906
 907                         sprint(this, "\nCommon networked commands:\n");
 908                         CommonCommand_macro_help(this);
 909
 910                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 911                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 912                         return;
 913                 }
 914                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 915                 {
 916                         return;
 917                 }
 918                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 919                 {
 920                         return;
 921                 }
 922         }
 923         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 924         {
 925                 return;  // handled by a mutator
 926         }
 927         else if (CheatCommand(this, argc))
 928         {
 929                 return;  // handled by server/cheats.qc
 930         }
 931         else if (CommonCommand_macro_command(argc, this, command))
 932         {
 933                 return;                                          // handled by server/command/common.qc
 934         }
 935         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 936         {
 937                 return;                                          // handled by one of the above ClientCommand_* functions
 938         }
 939         else
 940         {
 941                 clientcommand(this, command);
 942         }
 943 }