]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/command/common.qc
Various fixes
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / common.qc
1 #include "common.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5
6 #include <common/command/_mod.qh>
7 #include "common.qh"
8
9 #include "../scores.qh"
10
11 #include <common/monsters/_mod.qh>
12 #include <common/notifications/all.qh>
13 #include <lib/warpzone/common.qh>
14
15
16 // ====================================================
17 //  Shared code for server commands, written by Samual
18 //  Last updated: December 27th, 2011
19 // ====================================================
20
21 // select the proper prefix for usage and other messages
22 string GetCommandPrefix(entity caller)
23 {
24         if (caller) return "cmd";
25         else return "sv_cmd";
26 }
27
28 // if client return player nickname, or if server return admin nickname
29 string GetCallerName(entity caller)
30 {
31         if (caller) return playername(caller, false);
32         else return ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : "SERVER ADMIN"); // autocvar_hostname
33 }
34
35 // verify that the client provided is acceptable for kicking
36 float VerifyKickableEntity(entity client)
37 {
38         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
39         return CLIENT_ACCEPTABLE;
40 }
41
42 // verify that the client provided is acceptable for use
43 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
44 {
45         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
46         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
47         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
48
49         return CLIENT_ACCEPTABLE;
50 }
51
52 // if the client is not acceptable, return a string to be used for error messages
53 string GetClientErrorString_color(float clienterror, string original_input, string col)
54 {
55         switch (clienterror)
56         {
57                 case CLIENT_DOESNT_EXIST:
58                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
59                 }
60                 case CLIENT_NOT_REAL:
61                 { return strcat(col, "Client '", original_input, col, "' is not real");
62                 }
63                 case CLIENT_NOT_BOT:
64                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
65                 }
66                 default:
67                 { return "Incorrect usage of GetClientErrorString";
68                 }
69         }
70 }
71
72 // is this entity number even in the possible range of entities?
73 float VerifyClientNumber(float tmp_number)
74 {
75         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
76         else return true;
77 }
78
79 entity GetIndexedEntity(int argc, float start_index)
80 {
81         entity selection;
82         float tmp_number, index;
83         string tmp_string;
84
85         next_token = -1;
86         index = start_index;
87         selection = NULL;
88
89         if (argc > start_index)
90         {
91                 if (substring(argv(index), 0, 1) == "#")
92                 {
93                         tmp_string = substring(argv(index), 1, -1);
94                         ++index;
95
96                         if (tmp_string != "")  // is it all one token? like #1
97                         {
98                                 tmp_number = stof(tmp_string);
99                         }
100                         else if (argc > index)  // no, it's two tokens? # 1
101                         {
102                                 tmp_number = stof(argv(index));
103                                 ++index;
104                         }
105                         else
106                         {
107                                 tmp_number = 0;
108                         }
109                 }
110                 else  // maybe it's ONLY a number?
111                 {
112                         tmp_number = stof(argv(index));
113                         ++index;
114                 }
115
116                 if (VerifyClientNumber(tmp_number))
117                 {
118                         selection = edict_num(tmp_number);  // yes, it was a number
119                 }
120                 else  // no, maybe it's a name?
121                 {
122                         FOREACH_CLIENT(true, {
123                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
124                                 {
125                                         selection = it;
126                                         break; // no reason to keep looking
127                                 }
128                         });
129
130                         index = (start_index + 1);
131                 }
132         }
133
134         next_token = index;
135         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
136         return selection;
137 }
138
139 // find a player which matches the input string, and return their entity
140 entity GetFilteredEntity(string input)
141 {
142         entity selection;
143         float tmp_number;
144
145         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
146         else tmp_number = stof(input);
147
148         if (VerifyClientNumber(tmp_number))
149         {
150                 selection = edict_num(tmp_number);
151         }
152         else
153         {
154                 selection = NULL;
155                 FOREACH_CLIENT(true, {
156                         if(strdecolorize(it.netname) == strdecolorize(input))
157                         {
158                                 selection = it;
159                                 break; // no reason to keep looking
160                         }
161                 });
162         }
163
164         return selection;
165 }
166
167 // same thing, but instead return their edict number
168 float GetFilteredNumber(string input)
169 {
170         entity selection = GetFilteredEntity(input);
171         float output;
172
173         output = etof(selection);
174
175         return output;
176 }
177
178 // switch between sprint and print depending on whether the receiver is the server or a player
179 void print_to(entity to, string input)
180 {
181         if (to) sprint(to, strcat(input, "\n"));
182         else print(input, "\n");
183 }
184
185 // ==========================================
186 //  Supporting functions for common commands
187 // ==========================================
188
189 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
190 void timeout_handler_reset(entity this)
191 {
192         timeout_caller = NULL;
193         timeout_time = 0;
194         timeout_leadtime = 0;
195
196         delete(this);
197 }
198
199 void timeout_handler_think(entity this)
200 {
201         switch (timeout_status)
202         {
203                 case TIMEOUT_ACTIVE:
204                 {
205                         if (timeout_time > 0)  // countdown is still going
206                         {
207                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
208
209                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
210                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
211
212                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
213                                 timeout_time -= 1;                                  // decrease the time counter
214                         }
215                         else  // time to end the timeout
216                         {
217                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
218                                 timeout_status = TIMEOUT_INACTIVE;
219
220                                 // reset the slowmo value back to normal
221                                 cvar_set("slowmo", ftos(orig_slowmo));
222
223                                 // unlock the view for players so they can move around again
224                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
225                                         it.fixangle = false;
226                                 });
227
228                                 timeout_handler_reset(this);
229                         }
230
231                         return;
232                 }
233
234                 case TIMEOUT_LEADTIME:
235                 {
236                         if (timeout_leadtime > 0)  // countdown is still going
237                         {
238                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
239
240                                 this.nextthink = time + 1; // think again in one second
241                                 timeout_leadtime -= 1;     // decrease the time counter
242                         }
243                         else  // time to begin the timeout
244                         {
245                                 timeout_status = TIMEOUT_ACTIVE;
246
247                                 // set the slowmo value to the timeout default slowmo value
248                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
249                                 sound(NULL, CH_INFO, SND_TIMEOUT, VOL_BASE, ATTN_NONE);
250
251                                 // reset all the flood variables
252                                 FOREACH_CLIENT(true, {
253                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
254                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
255                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
256                                 });
257
258                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
259                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
260                                         it.lastV_angle = it.v_angle;
261                                 });
262
263                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
264                         }
265
266                         return;
267                 }
268
269
270                 case TIMEOUT_INACTIVE:
271                 default:
272                 {
273                         timeout_handler_reset(this);
274                         return;
275                 }
276         }
277 }
278
279
280 // ===================================================
281 //  Common commands used in both sv_cmd.qc and cmd.qc
282 // ===================================================
283
284 void CommonCommand_cvar_changes(int request, entity caller)
285 {
286         switch (request)
287         {
288                 case CMD_REQUEST_COMMAND:
289                 {
290                         print_to(caller, cvar_changes);
291                         return;  // never fall through to usage
292                 }
293
294                 default:
295                 case CMD_REQUEST_USAGE:
296                 {
297                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
298                         print_to(caller, "  No arguments required.");
299                         print_to(caller, "See also: ^2cvar_purechanges^7");
300                         return;
301                 }
302         }
303 }
304
305 void CommonCommand_cvar_purechanges(int request, entity caller)
306 {
307         switch (request)
308         {
309                 case CMD_REQUEST_COMMAND:
310                 {
311                         print_to(caller, cvar_purechanges);
312                         return;  // never fall through to usage
313                 }
314
315                 default:
316                 case CMD_REQUEST_USAGE:
317                 {
318                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
319                         print_to(caller, "  No arguments required.");
320                         print_to(caller, "See also: ^2cvar_changes^7");
321                         return;
322                 }
323         }
324 }
325
326 void CommonCommand_editmob(int request, entity caller, int argc)
327 {
328         switch (request)
329         {
330                 case CMD_REQUEST_COMMAND:
331                 {
332                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
333                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
334
335                         if (caller)
336                         {
337                                 makevectors(caller.v_angle);
338                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
339                         }
340
341                         entity mon = trace_ent;
342                         bool is_visible = IS_MONSTER(mon);
343                         string argument = argv(2);
344
345                         switch (argv(1))
346                         {
347                                 case "name":
348                                 {
349                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
350                                         if (!argument)   break;  // escape to usage
351                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
352                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
353                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
354
355                                         string mon_oldname = mon.monster_name;
356
357                                         mon.monster_name = argument;
358                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
359                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
360                                         return;
361                                 }
362                                 case "spawn":
363                                 {
364                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
365                                         if (!argv(2))   break;  // escape to usage
366
367                                         int moveflag, tmp_moncount = 0;
368                                         string arg_lower = strtolower(argument);
369                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
370
371                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
372
373                                         IL_EACH(g_monsters, it.realowner == caller,
374                                         {
375                                                 ++tmp_moncount;
376                                         });
377
378                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
379                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
380                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
381                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
382                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
383                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
384                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
385                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
386                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
387
388                                         bool found = false;
389                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
390                                         {
391                                                 found = true;
392                                                 break;
393                                         });
394
395                                         if (!found && arg_lower != "random" && arg_lower != "anyrandom") { print_to(caller, "Invalid monster"); return; }
396
397                                         totalspawned += 1;
398                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
399                                         mon = spawnmonster(spawn(), arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
400                                         print_to(caller, strcat("Spawned ", mon.monster_name));
401                                         return;
402                                 }
403                                 case "kill":
404                                 {
405                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
406                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
407                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
408
409                                         Damage(mon, NULL, NULL, GetResource(mon, RES_HEALTH) + mon.max_health + 200, DEATH_KILL.m_id, DMG_NOWEP, mon.origin, '0 0 0');
410                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
411                                         return;
412                                 }
413                                 case "skin":
414                                 {
415                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
416                                         if (!argument)   break;  // escape to usage
417                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
418                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
419                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
420                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
421
422                                         mon.skin = stof(argument);
423                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
424                                         return;
425                                 }
426                                 case "movetarget":
427                                 {
428                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
429                                         if (!argument)   break;  // escape to usage
430                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
431                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
432                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
433
434                                         mon.monster_moveflags = stof(argument);
435                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
436                                         return;
437                                 }
438                                 case "butcher":
439                                 {
440                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
441                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string)); return; }
442
443                                         int tmp_remcount = 0;
444
445                                         IL_EACH(g_monsters, true,
446                                         {
447                                                 Monster_Remove(it);
448                                                 ++tmp_remcount;
449                                         });
450                                         IL_CLEAR(g_monsters);
451
452                                         monsters_total = monsters_killed = totalspawned = 0;
453
454                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
455                                         return;
456                                 }
457                         }
458                 }
459
460                 default:
461                 case CMD_REQUEST_USAGE:
462                 {
463                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
464                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
465                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
466                         print_to(caller, "  spawn also takes arguments list and random");
467                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
468                         return;
469                 }
470         }
471 }
472
473 void CommonCommand_info(int request, entity caller, int argc)
474 {
475         switch (request)
476         {
477                 case CMD_REQUEST_COMMAND:
478                 {
479                         string command = cvar_string(strcat("sv_info_", argv(1)));
480
481                         if (command) wordwrap_sprint(caller, command, 1000);
482                         else print_to(caller, "ERROR: unsupported info command");
483
484                         return;  // never fall through to usage
485                 }
486
487                 default:
488                 case CMD_REQUEST_USAGE:
489                 {
490                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
491                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
492                         return;
493                 }
494         }
495 }
496
497 void CommonCommand_ladder(int request, entity caller)
498 {
499         switch (request)
500         {
501                 case CMD_REQUEST_COMMAND:
502                 {
503                         print_to(caller, ladder_reply);
504                         return;  // never fall through to usage
505                 }
506
507                 default:
508                 case CMD_REQUEST_USAGE:
509                 {
510                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
511                         print_to(caller, "  No arguments required.");
512                         return;
513                 }
514         }
515 }
516
517 void CommonCommand_lsmaps(int request, entity caller)
518 {
519         switch (request)
520         {
521                 case CMD_REQUEST_COMMAND:
522                 {
523                         print_to(caller, lsmaps_reply);
524                         return;  // never fall through to usage
525                 }
526
527                 default:
528                 case CMD_REQUEST_USAGE:
529                 {
530                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
531                         print_to(caller, "  No arguments required.");
532                         return;
533                 }
534         }
535 }
536
537 void CommonCommand_printmaplist(int request, entity caller)
538 {
539         switch (request)
540         {
541                 case CMD_REQUEST_COMMAND:
542                 {
543                         print_to(caller, maplist_reply);
544                         return;  // never fall through to usage
545                 }
546
547                 default:
548                 case CMD_REQUEST_USAGE:
549                 {
550                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
551                         print_to(caller, "  No arguments required.");
552                         return;
553                 }
554         }
555 }
556
557 void CommonCommand_rankings(int request, entity caller)
558 {
559         switch (request)
560         {
561                 case CMD_REQUEST_COMMAND:
562                 {
563                         print_to(caller, rankings_reply);
564                         return;  // never fall through to usage
565                 }
566
567                 default:
568                 case CMD_REQUEST_USAGE:
569                 {
570                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
571                         print_to(caller, "  No arguments required.");
572                         return;
573                 }
574         }
575 }
576
577 void CommonCommand_records(int request, entity caller)
578 {
579         switch (request)
580         {
581                 case CMD_REQUEST_COMMAND:
582                 {
583                         int num = stoi(argv(1));
584                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
585                                 print_to(caller, records_reply[num - 1]);
586                         else
587                         {
588                                 for (int i = 0; i < 10; ++i)
589                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
590                         }
591
592                         return;  // never fall through to usage
593                 }
594
595                 default:
596                 case CMD_REQUEST_USAGE:
597                 {
598                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
599                         print_to(caller, "  No arguments required.");
600                         return;
601                 }
602         }
603 }
604
605 void CommonCommand_teamstatus(int request, entity caller)
606 {
607         switch (request)
608         {
609                 case CMD_REQUEST_COMMAND:
610                 {
611                         Score_NicePrint(caller);
612                         return;  // never fall through to usage
613                 }
614
615                 default:
616                 case CMD_REQUEST_USAGE:
617                 {
618                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
619                         print_to(caller, "  No arguments required.");
620                         return;
621                 }
622         }
623 }
624
625 void CommonCommand_time(int request, entity caller)
626 {
627         switch (request)
628         {
629                 case CMD_REQUEST_COMMAND:
630                 {
631                         print_to(caller, strcat("time = ", ftos(time)));
632                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
633                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
634                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
635                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
636                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %d %H:%M:%S %Z %Y")));
637                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %d %H:%M:%S %Z %Y")));
638                         return;
639                 }
640
641                 default:
642                 case CMD_REQUEST_USAGE:
643                 {
644                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
645                         print_to(caller, "  No arguments required.");
646                         return;
647                 }
648         }
649 }
650
651 void CommonCommand_timein(int request, entity caller)
652 {
653         switch (request)
654         {
655                 case CMD_REQUEST_COMMAND:
656                 {
657                         if (!caller || autocvar_sv_timeout)
658                         {
659                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
660                                 else if (caller && (caller != timeout_caller))
661                                 {
662                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
663                                 }
664
665                                 else  // everything should be okay, continue aborting timeout
666                                 {
667                                         switch (timeout_status)
668                                         {
669                                                 case TIMEOUT_LEADTIME:
670                                                 {
671                                                         timeout_status = TIMEOUT_INACTIVE;
672                                                         timeout_time = 0;
673                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
674                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
675                                                         return;
676                                                 }
677
678                                                 case TIMEOUT_ACTIVE:
679                                                 {
680                                                         timeout_time = autocvar_sv_timeout_resumetime;
681                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
682                                                         bprint(strcat("\{1}^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
683                                                         return;
684                                                 }
685
686                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
687                                                         return;
688                                         }
689                                 }
690                         }
691                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
692
693                         return;  // never fall through to usage
694                 }
695
696                 default:
697                 case CMD_REQUEST_USAGE:
698                 {
699                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
700                         print_to(caller, "  No arguments required.");
701                         return;
702                 }
703         }
704 }
705
706 void CommonCommand_timeout(int request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
707 {
708         switch (request)
709         {
710                 case CMD_REQUEST_COMMAND:
711                 {
712                         if (!caller || autocvar_sv_timeout)
713                         {
714                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
715
716                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
717                                 else if (vote_called)
718                                 {
719                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
720                                 }
721                                 else if (warmup_stage && !g_warmup_allow_timeout)
722                                 {
723                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
724                                 }
725                                 else if (time < game_starttime)
726                                 {
727                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
728                                 }
729                                 else if (caller && (CS(caller).allowed_timeouts < 1))
730                                 {
731                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
732                                 }
733                                 else if (caller && !IS_PLAYER(caller))
734                                 {
735                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
736                                 }
737                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
738                                 {
739                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
740                                 }
741
742                                 else  // everything should be okay, proceed with starting the timeout
743                                 {
744                                         if (caller)   CS(caller).allowed_timeouts -= 1;
745                                         // write a bprint who started the timeout (and how many they have left)
746                                         bprint("\{1}", GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(CS(caller).allowed_timeouts), " timeout(s) left)") : ""), "!\n");
747
748                                         timeout_status = TIMEOUT_LEADTIME;
749                                         timeout_caller = caller;
750                                         timeout_time = autocvar_sv_timeout_length;
751                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
752
753                                         timeout_handler = spawn();
754                                         setthink(timeout_handler, timeout_handler_think);
755                                         timeout_handler.nextthink = time;  // always let the entity think asap
756                                         
757                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
758                                 }
759                         }
760                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
761
762                         return;  // never fall through to usage
763                 }
764
765                 default:
766                 case CMD_REQUEST_USAGE:
767                 {
768                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
769                         print_to(caller, "  No arguments required.");
770                         return;
771                 }
772         }
773 }
774
775 void CommonCommand_who(int request, entity caller, int argc)
776 {
777         switch (request)
778         {
779                 case CMD_REQUEST_COMMAND:
780                 {
781                         float total_listed_players, is_bot;
782
783                         float privacy = (caller && autocvar_sv_status_privacy);
784                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
785                         string tmp_netaddress, tmp_crypto_idfp;
786
787                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
788                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
789                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
790
791                         total_listed_players = 0;
792                         FOREACH_CLIENT(true, {
793                                 is_bot = (IS_BOT_CLIENT(it));
794
795                                 if (is_bot)
796                                 {
797                                         tmp_netaddress = "null/botclient";
798                                         tmp_crypto_idfp = "null/botclient";
799                                 }
800                                 else if (privacy)
801                                 {
802                                         tmp_netaddress = "hidden";
803                                         tmp_crypto_idfp = "hidden";
804                                 }
805                                 else
806                                 {
807                                         tmp_netaddress = it.netaddress;
808                                         tmp_crypto_idfp = it.crypto_idfp;
809                                 }
810
811                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
812                                         etof(it),
813                                         it.netname,
814                                         CS(it).ping,
815                                         CS(it).ping_packetloss,
816                                         process_time(1, time - CS(it).jointime),
817                                         tmp_netaddress,
818                                         tmp_crypto_idfp));
819
820                                 ++total_listed_players;
821                         });
822
823                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
824
825                         return;  // never fall through to usage
826                 }
827
828                 default:
829                 case CMD_REQUEST_USAGE:
830                 {
831                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
832                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
833                         return;
834                 }
835         }
836 }
837
838 /* use this when creating a new command, making sure to place it in alphabetical order... also,
839 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
840 void CommonCommand_(int request, entity caller)
841 {
842     switch(request)
843     {
844         case CMD_REQUEST_COMMAND:
845         {
846
847             return; // never fall through to usage
848         }
849
850         default:
851         case CMD_REQUEST_USAGE:
852         {
853             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
854             print_to(caller, "  No arguments required.");
855             return;
856         }
857     }
858 }
859 */