qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/world.qh>
  28
  29 //  used by GameCommand_make_mapinfo()
  30 void make_mapinfo_Think(entity this)
  31 {
  32         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  33         {
  34                 LOG_INFO("Done rebuiling mapinfos.");
  35                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  36                 delete(this);
  37         }
  38         else
  39         {
  40                 setthink(this, make_mapinfo_Think);
  41                 this.nextthink = time;
  42         }
  43 }
  44
  45 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  46 void changematchtime(float delta, float mi, float ma)
  47 {
  48         float cur;
  49         float update;
  50         float lim;
  51
  52         if (delta == 0) return;
  53         if (autocvar_timelimit < 0) return;
  54
  55         if (mi <= 10) mi = 10;  // at least ten sec in the future
  56         cur = time - game_starttime;
  57         if (cur > 0) mi += cur; // from current time!
  58
  59         lim = autocvar_timelimit * 60;
  60
  61         if (delta > 0)
  62         {
  63                 if (lim == 0) return; // cannot increase any further
  64                 else if (lim < ma) update = min(ma, lim + delta);
  65                 else                  // already above maximum: FAIL
  66                         return;
  67         }
  68         else
  69         {
  70                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  71                         update = max(mi, ma);
  72                 else if (lim > mi) // above minimum: decrease
  73                         update = max(mi, lim + delta);
  74                 else               // already below minimum: FAIL
  75                         return;
  76         }
  77
  78         cvar_set("timelimit", ftos(update / 60));
  79 }
  80
  81
  82 // =======================
  83 //  Command Sub-Functions
  84 // =======================
  85
  86 void GameCommand_adminmsg(int request, int argc)
  87 {
  88         switch (request)
  89         {
  90                 case CMD_REQUEST_COMMAND:
  91                 {
  92                         entity client;
  93                         float accepted;
  94
  95                         string targets = strreplace(",", " ", argv(1));
  96                         string original_targets = strreplace(" ", ", ", targets);
  97                         string admin_message = argv(2);
  98                         float infobartime = stof(argv(3));
  99
 100                         string successful, t;
 101                         successful = string_null;
 102
 103                         if ((targets) && (admin_message))
 104                         {
 105                                 for ( ; targets; )
 106                                 {
 107                                         t = car(targets);
 108                                         targets = cdr(targets);
 109
 110                                         // Check to see if the player is a valid target
 111                                         client = GetFilteredEntity(t);
 112                                         accepted = VerifyClientEntity(client, true, false);
 113
 114                                         if (accepted <= 0)
 115                                         {
 116                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 117                                                 continue;
 118                                         }
 119
 120                                         // send the centerprint/console print or infomessage
 121                                         if (infobartime)
 122                                         {
 123                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 124                                         }
 125                                         else
 126                                         {
 127                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 128                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 129                                         }
 130
 131                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 132                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 133                                         continue;
 134                                 }
 135
 136                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 137                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 138
 139                                 return;
 140                         }
 141                 }
 142
 143                 default:
 144                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 145                 case CMD_REQUEST_USAGE:
 146                 {
 147                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 148                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 149                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 150                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 151                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 152                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 153                         return;
 154                 }
 155         }
 156 }
 157
 158 void GameCommand_allready(int request)
 159 {
 160         switch (request)
 161         {
 162                 case CMD_REQUEST_COMMAND:
 163                 {
 164                         ReadyRestart();
 165                         return;
 166                 }
 167
 168                 default:
 169                 case CMD_REQUEST_USAGE:
 170                 {
 171                         LOG_HELP("Usage:^3 sv_cmd allready");
 172                         LOG_HELP("  No arguments required.");
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 void GameCommand_allspec(int request, int argc)
 179 {
 180         switch (request)
 181         {
 182                 case CMD_REQUEST_COMMAND:
 183                 {
 184                         string reason = argv(1);
 185                         int n = 0;
 186                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 187                                 if (it.caplayer) it.caplayer = 0;
 188                                 PutObserverInServer(it);
 189                                 ++n;
 190                         });
 191                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 192                         else   LOG_INFO("No players found to spectate.");
 193                         return;
 194                 }
 195
 196                 default:
 197                 case CMD_REQUEST_USAGE:
 198                 {
 199                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 200                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 201                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 202                         return;
 203                 }
 204         }
 205 }
 206
 207 void GameCommand_anticheat(int request, int argc)
 208 {
 209         switch (request)
 210         {
 211                 case CMD_REQUEST_COMMAND:
 212                 {
 213                         entity client = GetIndexedEntity(argc, 1);
 214                         float accepted = VerifyClientEntity(client, false, false);
 215
 216                         if (accepted > 0)
 217                         {
 218                                 anticheat_report_to_eventlog(client);
 219                                 return;
 220                         }
 221                         else
 222                         {
 223                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 224                         }
 225                 }
 226
 227                 default:
 228                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 229                 case CMD_REQUEST_USAGE:
 230                 {
 231                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 232                         LOG_HELP("  <client> is the entity number or name of the player.");
 233                         return;
 234                 }
 235         }
 236 }
 237
 238 void GameCommand_bbox(int request)
 239 {
 240         switch (request)
 241         {
 242                 case CMD_REQUEST_COMMAND:
 243                 {
 244                         vector size_min = '0 0 0';
 245                         vector size_max = '0 0 0';
 246                         tracebox('1 0 0' * world.absmin.x,
 247                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 248                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 249                                 '1 0 0' * world.absmax.x,
 250                                 MOVE_WORLDONLY,
 251                                 NULL);
 252                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 253
 254                         tracebox('0 1 0' * world.absmin.y,
 255                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 256                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 257                                 '0 1 0' * world.absmax.y,
 258                                 MOVE_WORLDONLY,
 259                                 NULL);
 260                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 261
 262                         tracebox('0 0 1' * world.absmin.z,
 263                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 264                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 265                                 '0 0 1' * world.absmax.z,
 266                                 MOVE_WORLDONLY,
 267                                 NULL);
 268                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 269
 270                         tracebox('1 0 0' * world.absmax.x,
 271                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 272                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 273                                 '1 0 0' * world.absmin.x,
 274                                 MOVE_WORLDONLY,
 275                                 NULL);
 276                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 277
 278                         tracebox('0 1 0' * world.absmax.y,
 279                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 280                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 281                                 '0 1 0' * world.absmin.y,
 282                                 MOVE_WORLDONLY,
 283                                 NULL);
 284                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 285
 286                         tracebox('0 0 1' * world.absmax.z,
 287                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 288                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 289                                 '0 0 1' * world.absmin.z,
 290                                 MOVE_WORLDONLY,
 291                                 NULL);
 292                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 293
 294                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 295                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 296                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 297                         return;
 298                 }
 299
 300                 default:
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         LOG_HELP("Usage:^3 sv_cmd bbox");
 304                         LOG_HELP("  No arguments required.");
 305                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 306                         return;
 307                 }
 308         }
 309 }
 310
 311 void GameCommand_bot_cmd(int request, int argc, string command)
 312 {
 313         switch (request)
 314         {
 315                 case CMD_REQUEST_COMMAND:
 316                 {
 317                         entity bot;
 318
 319                         if (argv(1) == "reset")
 320                         {
 321                                 bot_resetqueues();
 322                                 return;
 323                         }
 324                         else if (argv(1) == "setbots")
 325                         {
 326                                 cvar_settemp("bot_vs_human", "0");
 327                                 cvar_settemp("minplayers", "0");
 328                                 cvar_settemp("minplayers_per_team", "0");
 329                                 cvar_settemp("bot_number", "0");
 330                                 bot_fixcount();
 331                                 cvar_settemp("bot_number", argv(2));
 332                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 333                                 return;
 334                         }
 335                         else if (argv(1) == "load" && argc == 3)
 336                         {
 337                                 float fh, i;
 338                                 string s;
 339                                 fh = fopen(argv(2), FILE_READ);
 340                                 if (fh < 0)
 341                                 {
 342                                         LOG_INFO("cannot open the file");
 343                                         return;
 344                                 }
 345
 346                                 i = 0;
 347                                 while ((s = fgets(fh)))
 348                                 {
 349                                         argc = tokenize_console(s);
 350
 351                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 352                                         {
 353                                                 if (argv(2) == "reset")
 354                                                 {
 355                                                         bot_resetqueues();
 356                                                 }
 357                                                 else if (argv(2) == "setbots")
 358                                                 {
 359                                                         cvar_settemp("bot_vs_human", "0");
 360                                                         cvar_settemp("minplayers", "0");
 361                                                         cvar_settemp("minplayers_per_team", "0");
 362                                                         cvar_settemp("bot_number", "0");
 363                                                         bot_fixcount();
 364                                                         cvar_settemp("bot_number", argv(3));
 365                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 366                                                 }
 367                                                 else
 368                                                 {
 369                                                         if(argv(2) == "*" || argv(2) == "all")
 370                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 371                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 372                                                                 });
 373                                                         else
 374                                                         {
 375                                                                 bot = find_bot_by_number(stof(argv(2)));
 376                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 377                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 378                                                         }
 379                                                 }
 380                                         }
 381                                         else
 382                                         {
 383                                                 localcmd(strcat(s, "\n"));
 384                                         }
 385
 386                                         ++i;
 387                                 }
 388                                 LOG_INFO(ftos(i), " commands read");
 389                                 fclose(fh);
 390                                 return;
 391                         }
 392                         else if (argv(1) == "help")
 393                         {
 394                                 if (argv(2)) bot_cmdhelp(argv(2));
 395                                 else bot_list_commands();
 396                                 return;
 397                         }
 398                         else if (argc >= 3)  // this comes last
 399                         {
 400                                 if(argv(1) == "*" || argv(1) == "all")
 401                                 {
 402                                         int bot_num = 0;
 403                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 404                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 405                                                 bot_num++;
 406                                         });
 407                                         if(bot_num)
 408                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 409                                         return;
 410                                 }
 411                                 else
 412                                 {
 413                                         bot = find_bot_by_number(stof(argv(1)));
 414                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 415                                         if (bot)
 416                                         {
 417                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 418                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 419                                                 return;
 420                                         }
 421                                         else
 422                                         {
 423                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 424                                         }
 425                                 }
 426                         }
 427                 }
 428
 429                 default:
 430                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 434                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 435                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 436                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 437                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 438                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 439                         LOG_HELP("          sv_cmd bot_cmd * pause");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void GameCommand_cointoss(int request, int argc)
 446 {
 447         switch (request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 452                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 453                         string choice = ((random() > 0.5) ? result1 : result2);
 454
 455                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 456                         return;
 457                 }
 458
 459                 default:
 460                 case CMD_REQUEST_USAGE:
 461                 {
 462                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 463                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 464                         return;
 465                 }
 466         }
 467 }
 468
 469 void GameCommand_database(int request, int argc)
 470 {
 471         switch (request)
 472         {
 473                 case CMD_REQUEST_COMMAND:
 474                 {
 475                         if (argc == 3)
 476                         {
 477                                 if (argv(1) == "save")
 478                                 {
 479                                         db_save(ServerProgsDB, argv(2));
 480                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 481                                         return;
 482                                 }
 483                                 else if (argv(1) == "dump")
 484                                 {
 485                                         db_dump(ServerProgsDB, argv(2));
 486                                         LOG_INFO("DB dumped.");  // wtf does this do?
 487                                         return;
 488                                 }
 489                                 else if (argv(1) == "load")
 490                                 {
 491                                         db_close(ServerProgsDB);
 492                                         ServerProgsDB = db_load(argv(2));
 493                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 494                                         return;
 495                                 }
 496                         }
 497                 }
 498
 499                 default:
 500                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 504                         LOG_HELP("  Where <action> is the command to complete,");
 505                         LOG_HELP("  and <filename> is what it acts upon.");
 506                         LOG_HELP("  Full list of commands here: save, dump, load.");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void GameCommand_defer_clear(int request, int argc)
 513 {
 514         switch (request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         entity client;
 519                         float accepted;
 520
 521                         if (argc >= 2)
 522                         {
 523                                 client = GetIndexedEntity(argc, 1);
 524                                 accepted = VerifyClientEntity(client, true, false);
 525
 526                                 if (accepted > 0)
 527                                 {
 528                                         stuffcmd(client, "defer clear\n");
 529                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 530                                 }
 531                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 532
 533                                 return;
 534                         }
 535                 }
 536
 537                 default:
 538                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 539                 case CMD_REQUEST_USAGE:
 540                 {
 541                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 542                         LOG_HELP("  <client> is the entity number or name of the player.");
 543                         LOG_HELP("See also: ^2defer_clear_all^7");
 544                         return;
 545                 }
 546         }
 547 }
 548
 549 void GameCommand_defer_clear_all(int request)
 550 {
 551         switch (request)
 552         {
 553                 case CMD_REQUEST_COMMAND:
 554                 {
 555                         int n = 0;
 556                         int argc;
 557
 558                         FOREACH_CLIENT(true, {
 559                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 560                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 561                                 ++n;
 562                         });
 563                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 564                         return;
 565                 }
 566
 567                 default:
 568                 case CMD_REQUEST_USAGE:
 569                 {
 570                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 571                         LOG_HELP("  No arguments required.");
 572                         LOG_HELP("See also: ^2defer_clear^7");
 573                         return;
 574                 }
 575         }
 576 }
 577
 578 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 579 {
 580         switch (request)
 581         {
 582                 case CMD_REQUEST_COMMAND:
 583                 {
 584                         if (argv(1))
 585                         {
 586                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 587                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 588                                 return;
 589                         }
 590                 }
 591
 592                 default:
 593                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 594                 case CMD_REQUEST_USAGE:
 595                 {
 596                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 597                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 598                         LOG_HELP("  it will clear all records up to nth place.");
 599                         LOG_HELP("  if <map> is not provided it will use current map.");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void print_Effect_Index(int d, string effect_name)
 606 {
 607         // this is inside a function to avoid expanding it on compilation everytime
 608         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 609         db_put(d, effect_name, "1");
 610 }
 611
 612 void GameCommand_effectindexdump(int request)
 613 {
 614         switch (request)
 615         {
 616                 case CMD_REQUEST_COMMAND:
 617                 {
 618                         float fh, d;
 619                         string s;
 620
 621                         d = db_create();
 622                         LOG_INFO("begin of effects list");
 623
 624                         print_Effect_Index(d, "TE_GUNSHOT");
 625                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 626                         print_Effect_Index(d, "TE_SPIKE");
 627                         print_Effect_Index(d, "TE_SPIKEQUAD");
 628                         print_Effect_Index(d, "TE_SUPERSPIKE");
 629                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 630                         print_Effect_Index(d, "TE_WIZSPIKE");
 631                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 632                         print_Effect_Index(d, "TE_EXPLOSION");
 633                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 634                         print_Effect_Index(d, "TE_TAREXPLOSION");
 635                         print_Effect_Index(d, "TE_TELEPORT");
 636                         print_Effect_Index(d, "TE_LAVASPLASH");
 637                         print_Effect_Index(d, "TE_SMALLFLASH");
 638                         print_Effect_Index(d, "TE_FLAMEJET");
 639                         print_Effect_Index(d, "EF_FLAME");
 640                         print_Effect_Index(d, "TE_BLOOD");
 641                         print_Effect_Index(d, "TE_SPARK");
 642                         print_Effect_Index(d, "TE_PLASMABURN");
 643                         print_Effect_Index(d, "TE_TEI_G3");
 644                         print_Effect_Index(d, "TE_TEI_SMOKE");
 645                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 646                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 647                         print_Effect_Index(d, "EF_STARDUST");
 648                         print_Effect_Index(d, "TR_ROCKET");
 649                         print_Effect_Index(d, "TR_GRENADE");
 650                         print_Effect_Index(d, "TR_BLOOD");
 651                         print_Effect_Index(d, "TR_WIZSPIKE");
 652                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 653                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 654                         print_Effect_Index(d, "TR_VORESPIKE");
 655                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 656                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 657                         print_Effect_Index(d, "TR_GLOWTRAIL");
 658                         print_Effect_Index(d, "TR_SEEKER");
 659                         print_Effect_Index(d, "SVC_PARTICLE");
 660
 661                         fh = fopen("effectinfo.txt", FILE_READ);
 662                         while ((s = fgets(fh)))
 663                         {
 664                                 tokenize_console(s);
 665                                 if (argv(0) == "effect")
 666                                 {
 667                                         if (db_get(d, argv(1)) != "1")
 668                                         {
 669                                                 int i = _particleeffectnum(argv(1));
 670                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 671                                                 db_put(d, argv(1), "1");
 672                                         }
 673                                 }
 674                         }
 675                         LOG_INFO("end of effects list");
 676
 677                         db_close(d);
 678                         return;
 679                 }
 680
 681                 default:
 682                 case CMD_REQUEST_USAGE:
 683                 {
 684                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 685                         LOG_HELP("  No arguments required.");
 686                         return;
 687                 }
 688         }
 689 }
 690
 691 void GameCommand_extendmatchtime(int request)
 692 {
 693         switch (request)
 694         {
 695                 case CMD_REQUEST_COMMAND:
 696                 {
 697                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 698                         return;
 699                 }
 700
 701                 default:
 702                 case CMD_REQUEST_USAGE:
 703                 {
 704                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 705                         LOG_HELP("  No arguments required.");
 706                         LOG_HELP("See also: ^2reducematchtime^7");
 707                         return;
 708                 }
 709         }
 710 }
 711
 712 void GameCommand_gametype(int request, int argc)
 713 {
 714         switch (request)
 715         {
 716                 case CMD_REQUEST_COMMAND:
 717                 {
 718                         if (argv(1) != "")
 719                         {
 720                                 string s = argv(1);
 721                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 722
 723                                 if (t)
 724                                 {
 725                                         MapInfo_SwitchGameType(t);
 726                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 727                                         if (MapInfo_count > 0)
 728                                         {
 729                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 730                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 731                                                 lsmaps_reply = strzone(getlsmaps());
 732                                                 bprint("Game type successfully switched to ", s, "\n");
 733                                         }
 734                                         else
 735                                         {
 736                                                 bprint("Cannot use this game type: no map for it found\n");
 737                                                 MapInfo_SwitchGameType(tsave);
 738                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 739                                         }
 740                                 }
 741                                 else
 742                                 {
 743                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 744                                 }
 745
 746                                 return;
 747                         }
 748                 }
 749
 750                 default:
 751                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 752                 case CMD_REQUEST_USAGE:
 753                 {
 754                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 755                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 756                         LOG_HELP("See also: ^2gotomap^7");
 757                         return;
 758                 }
 759         }
 760 }
 761
 762 void GameCommand_gettaginfo(int request, int argc)
 763 {
 764         switch (request)
 765         {
 766                 case CMD_REQUEST_COMMAND:
 767                 {
 768                         entity tmp_entity;
 769                         float i;
 770                         vector v;
 771
 772                         if (argc >= 4)
 773                         {
 774                                 tmp_entity = spawn();
 775                                 if (argv(1) == "w")
 776                                 {
 777                                         .entity weaponentity = weaponentities[0];
 778                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 779                                 }
 780                                 else
 781                                 {
 782                                         precache_model(argv(1));
 783                                         _setmodel(tmp_entity, argv(1));
 784                                 }
 785                                 tmp_entity.frame = stof(argv(2));
 786                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 787                                 else i = gettagindex(tmp_entity, argv(3));
 788                                 if (i)
 789                                 {
 790                                         v = gettaginfo(tmp_entity, i);
 791                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 792                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 793                                         );
 794                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 795                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 796                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 797                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 798                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 799                                         if (argc >= 6)
 800                                         {
 801                                                 v.y = -v.y;
 802                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 803                                         }
 804                                 }
 805                                 else
 806                                 {
 807                                         LOG_INFO("bone not found");
 808                                 }
 809
 810                                 delete(tmp_entity);
 811                                 return;
 812                         }
 813                 }
 814
 815                 default:
 816                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 817                 case CMD_REQUEST_USAGE:
 818                 {
 819                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 820                         LOG_HELP("See also: ^2bbox, trace^7");
 821                         return;
 822                 }
 823         }
 824 }
 825
 826 void GameCommand_animbench(int request, int argc)
 827 {
 828         switch (request)
 829         {
 830                 case CMD_REQUEST_COMMAND:
 831                 {
 832                         entity tmp_entity;
 833
 834                         if (argc >= 4)
 835                         {
 836                                 tmp_entity = spawn();
 837                                 if (argv(1) == "w")
 838                                 {
 839                                         .entity weaponentity = weaponentities[0];
 840                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 841                                 }
 842                                 else
 843                                 {
 844                                         precache_model(argv(1));
 845                                         _setmodel(tmp_entity, argv(1));
 846                                 }
 847                                 float f1 = stof(argv(2));
 848                                 float f2 = stof(argv(3));
 849                                 float t0;
 850                                 float t1 = 0;
 851                                 float t2 = 0;
 852                                 float n = 0;
 853
 854                                 while (t1 + t2 < 1)
 855                                 {
 856                                         tmp_entity.frame = f1;
 857                                         t0 = gettime(GETTIME_HIRES);
 858                                         getsurfacepoint(tmp_entity, 0, 0);
 859                                         t1 += gettime(GETTIME_HIRES) - t0;
 860                                         tmp_entity.frame = f2;
 861                                         t0 = gettime(GETTIME_HIRES);
 862                                         getsurfacepoint(tmp_entity, 0, 0);
 863                                         t2 += gettime(GETTIME_HIRES) - t0;
 864                                         n += 1;
 865                                 }
 866                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 867                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 868
 869                                 delete(tmp_entity);
 870                                 return;
 871                         }
 872                 }
 873
 874                 default:
 875                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 876                 case CMD_REQUEST_USAGE:
 877                 {
 878                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 879                         LOG_HELP("See also: ^2bbox, trace^7");
 880                         return;
 881                 }
 882         }
 883 }
 884
 885 void GameCommand_gotomap(int request, int argc)
 886 {
 887         switch (request)
 888         {
 889                 case CMD_REQUEST_COMMAND:
 890                 {
 891                         if (argv(1))
 892                         {
 893                                 LOG_INFO(GotoMap(argv(1)));
 894                                 return;
 895                         }
 896                 }
 897
 898                 default:
 899                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 900                 case CMD_REQUEST_USAGE:
 901                 {
 902                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 903                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 904                         LOG_HELP("See also: ^2gametype^7");
 905                         return;
 906                 }
 907         }
 908 }
 909
 910 void GameCommand_lockteams(int request)
 911 {
 912         switch (request)
 913         {
 914                 case CMD_REQUEST_COMMAND:
 915                 {
 916                         if (teamplay)
 917                         {
 918                                 lockteams = 1;
 919                                 bprint("^1The teams are now locked.\n");
 920                         }
 921                         else
 922                         {
 923                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 924                         }
 925                         return;
 926                 }
 927
 928                 default:
 929                 case CMD_REQUEST_USAGE:
 930                 {
 931                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 932                         LOG_HELP("  No arguments required.");
 933                         LOG_HELP("See also: ^2unlockteams^7");
 934                         return;
 935                 }
 936         }
 937 }
 938
 939 void GameCommand_make_mapinfo(int request)
 940 {
 941         switch (request)
 942         {
 943                 case CMD_REQUEST_COMMAND:
 944                 {
 945                         entity tmp_entity;
 946
 947                         tmp_entity = new(make_mapinfo);
 948                         setthink(tmp_entity, make_mapinfo_Think);
 949                         tmp_entity.nextthink = time;
 950                         MapInfo_Enumerate();
 951                         return;
 952                 }
 953
 954                 default:
 955                 case CMD_REQUEST_USAGE:
 956                 {
 957                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
 958                         LOG_HELP("  No arguments required.");
 959                         LOG_HELP("See also: ^2radarmap^7");
 960                         return;
 961                 }
 962         }
 963 }
 964
 965 void GameCommand_moveplayer(int request, int argc)
 966 {
 967         switch (request)
 968         {
 969                 case CMD_REQUEST_COMMAND:
 970                 {
 971                         float accepted;
 972                         entity client;
 973
 974                         string targets = strreplace(",", " ", argv(1));
 975                         string original_targets = strreplace(" ", ", ", targets);
 976                         string destination = argv(2);
 977
 978                         string successful, t;
 979                         successful = string_null;
 980
 981                         // lets see if the target(s) even actually exist.
 982                         if ((targets) && (destination))
 983                         {
 984                                 for ( ; targets; )
 985                                 {
 986                                         t = car(targets);
 987                                         targets = cdr(targets);
 988
 989                                         // Check to see if the player is a valid target
 990                                         client = GetFilteredEntity(t);
 991                                         accepted = VerifyClientEntity(client, false, false);
 992
 993                                         if (accepted <= 0)
 994                                         {
 995                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 996                                                 continue;
 997                                         }
 998
 999                                         // Where are we putting this player?
1000                                         if (destination == "spec" || destination == "spectator")
1001                                         {
1002                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1003                                                 {
1004                                                         if (client.caplayer) client.caplayer = 0;
1005                                                         PutObserverInServer(client);
1006
1007                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
1008                                                 }
1009                                                 else
1010                                                 {
1011                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client.netname, client.team, false), ") is already spectating.");
1012                                                 }
1013                                                 continue;
1014                                         }
1015                                         else
1016                                         {
1017                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1018                                                 {
1019                                                         if (teamplay)
1020                                                         {
1021                                                                 // set up
1022                                                                 int save = Player_GetForcedTeamIndex(client);
1023                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1024
1025                                                                 // find the team to move the player to
1026                                                                 int team_num = Team_ColorToTeam(destination);
1027                                                                 entity balance;
1028                                                                 if (team_num == client.team)  // already on the destination team
1029                                                                 {
1030                                                                         // keep the forcing undone
1031                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client.netname, client.team, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1032                                                                         continue;
1033                                                                 }
1034                                                                 else if (team_num == 0)  // auto team
1035                                                                 {
1036                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1037                                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1038                                                                 }
1039                                                                 else
1040                                                                 {
1041                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1042                                                                 }
1043                                                                 Player_SetForcedTeamIndex(client, save);
1044
1045                                                                 // Check to see if the destination team is even available
1046                                                                 int team_id = Team_TeamToIndex(team_num);
1047                                                                 if (team_id == -1)
1048                                                                 {
1049                                                                         LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1050                                                                         TeamBalance_Destroy(balance);
1051                                                                         return;
1052                                                                 }
1053                                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1054                                                                 {
1055                                                                         LOG_INFOF("Sorry, can't move player to %s team if it doesn't exist.", destination);
1056                                                                         TeamBalance_Destroy(balance);
1057                                                                         return;
1058                                                                 }
1059                                                                 TeamBalance_Destroy(balance);
1060
1061                                                                 // If so, lets continue and finally move the player
1062                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1063                                                                 if (MoveToTeam(client, team_id, 6))
1064                                                                 {
1065                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
1066                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client.netname, client.team, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1067                                                                 }
1068                                                                 else
1069                                                                 {
1070                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client.netname, client.team, false), ")");
1071                                                                 }
1072                                                                 continue;
1073                                                         }
1074                                                         else
1075                                                         {
1076                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1077                                                                 return;
1078                                                         }
1079                                                 }
1080                                                 else
1081                                                 {
1082                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1083                                                         return;
1084                                                 }
1085                                         }
1086                                 }
1087
1088                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1089                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1090
1091                                 return;  // still correct parameters so return to avoid usage print
1092                         }
1093                 }
1094
1095                 default:
1096                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1097                 case CMD_REQUEST_USAGE:
1098                 {
1099                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1100                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1101                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1102                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1103                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1104                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1105                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1106                         return;
1107                 }
1108         }
1109 }
1110
1111 void GameCommand_nospectators(int request)
1112 {
1113         switch (request)
1114         {
1115                 case CMD_REQUEST_COMMAND:
1116                 {
1117                         blockSpectators = 1;
1118                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1119                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1120                                 if(!it.caplayer)
1121                                 {
1122                                         CS(it).spectatortime = time;
1123                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1124                                 }
1125                         });
1126                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1127                         return;
1128                 }
1129
1130                 default:
1131                 case CMD_REQUEST_USAGE:
1132                 {
1133                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1134                         LOG_HELP("  No arguments required.");
1135                         return;
1136                 }
1137         }
1138 }
1139
1140 void GameCommand_printstats(int request)
1141 {
1142         switch (request)
1143         {
1144                 case CMD_REQUEST_COMMAND:
1145                 {
1146                         DumpStats(false);
1147                         LOG_INFO("stats dumped.");
1148                         return;
1149                 }
1150
1151                 default:
1152                 case CMD_REQUEST_USAGE:
1153                 {
1154                         LOG_HELP("Usage:^3 sv_cmd printstats");
1155                         LOG_HELP("  No arguments required.");
1156                         return;
1157                 }
1158         }
1159 }
1160
1161 void GameCommand_radarmap(int request, int argc)
1162 {
1163         switch (request)
1164         {
1165                 case CMD_REQUEST_COMMAND:
1166                 {
1167                         if (RadarMap_Make(argc)) return;
1168                 }
1169
1170                 default:
1171                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1172                 case CMD_REQUEST_USAGE:
1173                 {
1174                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1175                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1176                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1177                         LOG_HELP("See also: ^2make_mapinfo^7");
1178                         return;
1179                 }
1180         }
1181 }
1182
1183 void GameCommand_reducematchtime(int request)
1184 {
1185         switch (request)
1186         {
1187                 case CMD_REQUEST_COMMAND:
1188                 {
1189                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1190                         return;
1191                 }
1192
1193                 default:
1194                 case CMD_REQUEST_USAGE:
1195                 {
1196                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1197                         LOG_HELP("  No arguments required.");
1198                         LOG_HELP("See also: ^2extendmatchtime^7");
1199                         return;
1200                 }
1201         }
1202 }
1203
1204 void GameCommand_setbots(int request, int argc)
1205 {
1206         switch (request)
1207         {
1208                 case CMD_REQUEST_COMMAND:
1209                 {
1210                         if (argc >= 2)
1211                         {
1212                                 cvar_settemp("minplayers", "0");
1213                                 cvar_settemp("minplayers_per_team", "0");
1214                                 cvar_settemp("bot_number", argv(1));
1215                                 bot_fixcount();
1216                                 return;
1217                         }
1218                 }
1219
1220                 default:
1221                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1222                 case CMD_REQUEST_USAGE:
1223                 {
1224                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1225                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1226                         LOG_HELP("See also: ^2bot_cmd^7");
1227                         return;
1228                 }
1229         }
1230 }
1231
1232 void shuffleteams()
1233 {
1234         if (!teamplay)
1235         {
1236                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1237                 return;
1238         }
1239
1240         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1241                 if (Player_HasRealForcedTeam(it)) {
1242                         // we could theoretically assign forced players to their teams
1243                         // and shuffle the rest to fill the empty spots but in practise
1244                         // either all players or none are gonna have forced teams
1245                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1246                         return;
1247                 }
1248         });
1249
1250         int number_of_teams = 0;
1251         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1252         for (int i = 1; i <= NUM_TEAMS; ++i)
1253         {
1254                 if (TeamBalance_IsTeamAllowed(balance, i))
1255                 {
1256                         number_of_teams = max(i, number_of_teams);
1257                 }
1258         }
1259         TeamBalance_Destroy(balance);
1260
1261         int team_index = 0;
1262         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1263                 int target_team_index = team_index + 1;
1264                 if (Entity_GetTeamIndex(it) != target_team_index)
1265                 {
1266                         MoveToTeam(it, target_team_index, 6);
1267                 }
1268                 team_index = (team_index + 1) % number_of_teams;
1269         });
1270
1271         bprint("Successfully shuffled the players around randomly.\n");
1272 }
1273
1274 void GameCommand_shuffleteams(int request)
1275 {
1276         switch (request)
1277         {
1278                 case CMD_REQUEST_COMMAND:
1279                 {
1280                         if (shuffleteams_on_reset_map)
1281                         {
1282                                 bprint("Players will be shuffled when this round is over.\n");
1283                                 shuffleteams_on_reset_map = true;
1284                         }
1285                         else
1286                                 shuffleteams();
1287                         return;
1288                 }
1289
1290                 default:
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1294                         LOG_HELP("  No arguments required.");
1295                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1296                         return;
1297                 }
1298         }
1299 }
1300
1301 void GameCommand_stuffto(int request, int argc)
1302 {
1303         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1304         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1305         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1306
1307 #ifdef STUFFTO_ENABLED
1308                 switch (request)
1309                 {
1310                         case CMD_REQUEST_COMMAND:
1311                         {
1312                                 if (argv(2))
1313                                 {
1314                                         entity client = GetIndexedEntity(argc, 1);
1315                                         float accepted = VerifyClientEntity(client, true, false);
1316
1317                                         if (accepted > 0)
1318                                         {
1319                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1320                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1321                                         }
1322                                         else
1323                                         {
1324                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1325                                         }
1326
1327                                         return;
1328                                 }
1329                         }
1330
1331                         default:
1332                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1333                         case CMD_REQUEST_USAGE:
1334                         {
1335                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1336                                 LOG_HELP("  <client> is the entity number or name of the player,");
1337                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1338                                 return;
1339                         }
1340                 }
1341 #else
1342                 if (request)
1343                 {
1344                         LOG_HELP("stuffto command is not enabled on this server.");
1345                         return;
1346                 }
1347 #endif
1348 }
1349
1350 void GameCommand_trace(int request, int argc)
1351 {
1352         switch (request)
1353         {
1354                 case CMD_REQUEST_COMMAND:
1355                 {
1356                         entity e;
1357                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1358                         float i, f, safe, unsafe, dq, dqf;
1359
1360                         switch (argv(1))
1361                         {
1362                                 case "debug":
1363                                 {
1364                                         float hitcount = 0;
1365                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1366                                         float worst_endpos_bug = 0;
1367                                         for ( ; ; )
1368                                         {
1369                                                 org = world.mins;
1370                                                 delta = world.maxs - world.mins;
1371
1372                                                 start.x = org.x + random() * delta.x;
1373                                                 start.y = org.y + random() * delta.y;
1374                                                 start.z = org.z + random() * delta.z;
1375
1376                                                 end.x = org.x + random() * delta.x;
1377                                                 end.y = org.y + random() * delta.y;
1378                                                 end.z = org.z + random() * delta.z;
1379
1380                                                 start = stov(vtos(start));
1381                                                 end = stov(vtos(end));
1382
1383                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1384                                                 if (!trace_startsolid && trace_fraction < 1)
1385                                                 {
1386                                                         p = trace_endpos;
1387                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1388                                                         if (trace_startsolid)
1389                                                         {
1390                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1391                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1392
1393                                                                 // how much do we need to back off?
1394                                                                 safe = 1;
1395                                                                 unsafe = 0;
1396                                                                 for ( ; ; )
1397                                                                 {
1398                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1399                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1400                                                                         if (trace_startsolid)
1401                                                                         {
1402                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1403                                                                                 unsafe = (safe + unsafe) * 0.5;
1404                                                                         }
1405                                                                         else
1406                                                                         {
1407                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1408                                                                                 safe = (safe + unsafe) * 0.5;
1409                                                                         }
1410                                                                 }
1411
1412                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1413                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1414
1415                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1416                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1417                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1418                                                                 if (++hitcount >= 10) break;
1419                                                         }
1420                                                         else
1421                                                         {
1422                                                                 q0 = p;
1423                                                                 dq = 0;
1424                                                                 dqf = 1;
1425                                                                 for ( ; ; )
1426                                                                 {
1427                                                                         q = p + normalize(end - p) * (dq + dqf);
1428                                                                         if (q == q0) break;
1429                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1430                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1431                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1432                                                                         dqf *= 0.5;
1433                                                                         q0 = q;
1434                                                                 }
1435                                                                 if (dq > worst_endpos_bug)
1436                                                                 {
1437                                                                         worst_endpos_bug = dq;
1438                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1439                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1440                                                                         if (++hitcount >= 10) break;
1441                                                                 }
1442                                                         }
1443                                                 }
1444                                         }
1445                                         return;
1446                                 }
1447
1448                                 case "debug2":
1449                                 {
1450                                         e = nextent(NULL);
1451                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1452                                         vv = trace_endpos;
1453                                         if (trace_fraction == 1)
1454                                         {
1455                                                 LOG_INFO("not above ground, aborting");
1456                                                 return;
1457                                         }
1458                                         f = 0;
1459                                         for (i = 0; i < 100000; ++i)
1460                                         {
1461                                                 dv = randomvec();
1462                                                 if (dv.z > 0) dv = -1 * dv;
1463                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1464                                                 if (trace_startsolid) LOG_INFO("bug 1");
1465                                                 if (trace_fraction == 1)
1466                                                 {
1467                                                         if (dv.z < f)
1468                                                         {
1469                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1470                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1471                                                                 f = dv.z;
1472                                                         }
1473                                                 }
1474                                         }
1475                                         LOG_INFO("highest possible dist: ", ftos(f));
1476                                         return;
1477                                 }
1478
1479                                 case "walk":
1480                                 {
1481                                         if (argc == 4 || argc == 5)
1482                                         {
1483                                                 e = nextent(NULL);
1484                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1485                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1486                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1487                                                         LOG_INFO("can walk");
1488                                                 else
1489                                                         LOG_INFO("cannot walk");
1490                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1491                                                 return;
1492                                         }
1493                                 }
1494
1495                                 case "showline":
1496                                 {
1497                                         if (argc == 4)
1498                                         {
1499                                                 vv = stov(argv(2));
1500                                                 dv = stov(argv(3));
1501                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1502                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1503                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1504                                                 return;
1505                                         }
1506                                 }
1507
1508                                 // no default case, just go straight to invalid
1509                         }
1510                 }
1511
1512                 default:
1513                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1514                 case CMD_REQUEST_USAGE:
1515                 {
1516                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1517                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1518                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1519                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1520                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1521                         return;
1522                 }
1523         }
1524 }
1525
1526 void GameCommand_unlockteams(int request)
1527 {
1528         switch (request)
1529         {
1530                 case CMD_REQUEST_COMMAND:
1531                 {
1532                         if (teamplay)
1533                         {
1534                                 lockteams = 0;
1535                                 bprint("^1The teams are now unlocked.\n");
1536                         }
1537                         else
1538                         {
1539                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1540                         }
1541                         return;
1542                 }
1543
1544                 default:
1545                 case CMD_REQUEST_USAGE:
1546                 {
1547                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1548                         LOG_HELP("  No arguments required.");
1549                         LOG_HELP("See also: ^2lockteams^7");
1550                         return;
1551                 }
1552         }
1553 }
1554
1555 void GameCommand_warp(int request, int argc)
1556 {
1557         switch (request)
1558         {
1559                 case CMD_REQUEST_COMMAND:
1560                 {
1561                         if (autocvar_g_campaign)
1562                         {
1563                                 if (argc >= 2)
1564                                 {
1565                                         CampaignLevelWarp(stof(argv(1)));
1566                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1567                                 }
1568                                 else
1569                                 {
1570                                         CampaignLevelWarp(-1);
1571                                         LOG_INFO("Successfully warped to next campaign level.");
1572                                 }
1573                         }
1574                         else
1575                         {
1576                                 LOG_INFO("Not in campaign, can't level warp");
1577                         }
1578                         return;
1579                 }
1580
1581                 default:
1582                 case CMD_REQUEST_USAGE:
1583                 {
1584                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1585                         LOG_HELP("  <level> is the level to change campaign mode to.");
1586                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1587                         return;
1588                 }
1589         }
1590 }
1591
1592 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1593 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1594 void GameCommand_(int request)
1595 {
1596     switch(request)
1597     {
1598         case CMD_REQUEST_COMMAND:
1599         {
1600
1601             return;
1602         }
1603
1604         default:
1605         case CMD_REQUEST_USAGE:
1606         {
1607             LOG_HELP("Usage:^3 sv_cmd ");
1608             LOG_HELP("  No arguments required.");
1609             return;
1610         }
1611     }
1612 }
1613 */
1614
1615
1616 // ==================================
1617 //  Macro system for server commands
1618 // ==================================
1619
1620 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1621 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1622 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1623 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1624 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1625 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1626 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1627 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1628 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1629 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1630 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1631 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1632 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1633 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1634 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1635 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1636 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1637 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1638 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1639 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1640 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1641 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1642 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1643 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1644 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1645 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1646 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1647 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1648 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1649 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1650 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1651
1652 void GameCommand_macro_help()
1653 {
1654         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1655 }
1656
1657 float GameCommand_macro_command(int argc, string command)
1658 {
1659         string c = strtolower(argv(0));
1660         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1661                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1662                 return true;
1663         });
1664         return false;
1665 }
1666
1667 float GameCommand_macro_usage(int argc)
1668 {
1669         string c = strtolower(argv(1));
1670         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1671                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1672                 return true;
1673         });
1674         return false;
1675 }
1676
1677 void GameCommand_macro_write_aliases(float fh)
1678 {
1679         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1680 }
1681
1682
1683 // =========================================
1684 //  Main Function Called By Engine (sv_cmd)
1685 // =========================================
1686 // If this function exists, game code handles gamecommand instead of the engine code.
1687
1688 void GameCommand(string command)
1689 {
1690         int argc = tokenize_console(command);
1691
1692         // Guide for working with argc arguments by example:
1693         // argc:   1    - 2      - 3     - 4
1694         // argv:   0    - 1      - 2     - 3
1695         // cmd     vote - master - login - password
1696
1697         if (strtolower(argv(0)) == "help")
1698         {
1699                 if (argc == 1)
1700                 {
1701                         LOG_HELP("Server console commands:");
1702                         GameCommand_macro_help();
1703
1704                         LOG_HELP("\nBanning commands:");
1705                         BanCommand_macro_help();
1706
1707                         LOG_HELP("\nCommon networked commands:");
1708                         CommonCommand_macro_help(NULL);
1709
1710                         LOG_HELP("\nGeneric commands shared by all programs:");
1711                         GenericCommand_macro_help();
1712
1713                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1714                                 "For help about a specific command, type sv_cmd help <command>");
1715
1716                         return;
1717                 }
1718                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1719                 {
1720                         return;
1721                 }
1722                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1723                 {
1724                         return;
1725                 }
1726                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1727                 {
1728                         return;
1729                 }
1730                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1731                 {
1732                         return;
1733                 }
1734         }
1735         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1736         {
1737                 return;  // handled by a mutator
1738         }
1739         else if (BanCommand(command))
1740         {
1741                 return;  // handled by server/command/ipban.qc
1742         }
1743         else if (CommonCommand_macro_command(argc, NULL, command))
1744         {
1745                 return;  // handled by server/command/common.qc
1746         }
1747         else if (GenericCommand(command))
1748         {
1749                 return;                                        // handled by common/command/generic.qc
1750         }
1751         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1752         {
1753                 return;                                        // handled by one of the above GameCommand_* functions
1754         }
1755
1756         // nothing above caught the command, must be invalid
1757         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1758 }