qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/scores_rules.qh>
  27 #include <server/teamplay.qh>
  28 #include <server/world.qh>
  29
  30 //  used by GameCommand_make_mapinfo()
  31 void make_mapinfo_Think(entity this)
  32 {
  33         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  34         {
  35                 LOG_INFO("Done rebuiling mapinfos.");
  36                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  37                 delete(this);
  38         }
  39         else
  40         {
  41                 setthink(this, make_mapinfo_Think);
  42                 this.nextthink = time;
  43         }
  44 }
  45
  46 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  47 void changematchtime(float delta, float mi, float ma)
  48 {
  49         float cur;
  50         float update;
  51         float lim;
  52
  53         if (delta == 0) return;
  54         if (autocvar_timelimit < 0) return;
  55
  56         if (mi <= 10) mi = 10;  // at least ten sec in the future
  57         cur = time - game_starttime;
  58         if (cur > 0) mi += cur; // from current time!
  59
  60         lim = autocvar_timelimit * 60;
  61
  62         if (delta > 0)
  63         {
  64                 if (lim == 0) return; // cannot increase any further
  65                 else if (lim < ma) update = min(ma, lim + delta);
  66                 else                  // already above maximum: FAIL
  67                         return;
  68         }
  69         else
  70         {
  71                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  72                         update = max(mi, ma);
  73                 else if (lim > mi) // above minimum: decrease
  74                         update = max(mi, lim + delta);
  75                 else               // already below minimum: FAIL
  76                         return;
  77         }
  78
  79         cvar_set("timelimit", ftos(update / 60));
  80 }
  81
  82
  83 // =======================
  84 //  Command Sub-Functions
  85 // =======================
  86
  87 void GameCommand_adminmsg(int request, int argc)
  88 {
  89         switch (request)
  90         {
  91                 case CMD_REQUEST_COMMAND:
  92                 {
  93                         entity client;
  94                         float accepted;
  95
  96                         string targets = strreplace(",", " ", argv(1));
  97                         string original_targets = strreplace(" ", ", ", targets);
  98                         string admin_message = argv(2);
  99                         float infobartime = stof(argv(3));
 100
 101                         string successful, t;
 102                         successful = string_null;
 103
 104                         if ((targets) && (admin_message))
 105                         {
 106                                 for ( ; targets; )
 107                                 {
 108                                         t = car(targets);
 109                                         targets = cdr(targets);
 110
 111                                         // Check to see if the player is a valid target
 112                                         client = GetFilteredEntity(t);
 113                                         accepted = VerifyClientEntity(client, true, false);
 114
 115                                         if (accepted <= 0)
 116                                         {
 117                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 118                                                 continue;
 119                                         }
 120
 121                                         // send the centerprint/console print or infomessage
 122                                         if (infobartime)
 123                                         {
 124                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 125                                         }
 126                                         else
 127                                         {
 128                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 129                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 130                                         }
 131
 132                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 133                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 134                                         continue;
 135                                 }
 136
 137                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 138                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 139
 140                                 return;
 141                         }
 142                 }
 143
 144                 default:
 145                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 146                 case CMD_REQUEST_USAGE:
 147                 {
 148                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 149                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 150                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 151                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 152                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 153                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 154                         return;
 155                 }
 156         }
 157 }
 158
 159 void GameCommand_teamname(int request, int argc)
 160 {
 161         switch (request)
 162         {
 163                 case CMD_REQUEST_COMMAND:
 164                 {
 165                         if (argv(1) == "")
 166                         {
 167                                 return;
 168                         }
 169                         if (!teamplay)
 170                         {
 171                                 LOG_INFO("selectteam can only be used in teamgames");
 172                                 return;
 173                         }
 174
 175                         switch (argv(1))
 176                         {
 177                                 case "red":
 178                                 case "blue":
 179                                 case "yellow":
 180                                 case "pink":
 181                                 {
 182                                         int tm = Team_ColorToTeam(argv(1));
 183                                         if(argv(2) != "") {
 184                                                 cvar_set(strcat("g_teamnames_", argv(1)), argv(2));
 185                                                 bprintf("\{1}%s%s^7 team is now known as %s^7\n", Team_ColorCode(tm), Team_ColorName(tm), argv(2));
 186                                         } else {
 187                                                 cvar_set(strcat("g_teamnames_", argv(1)), "");
 188                                                 bprintf("\{1}%s%s^7 team now doesn't have a team name\n", Team_ColorCode(tm), Team_ColorName(tm), argv(2));
 189                                         }
 190
 191                                         break;
 192                                 }
 193                                 default:
 194                                 {
 195                                         return;
 196                                 }
 197                         }
 198
 199                         send_TeamNames(MSG_BROADCAST, NULL);
 200                         return;
 201                 }
 202
 203                 default:
 204                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 205                 case CMD_REQUEST_USAGE:
 206                 {
 207                         LOG_HELP("Usage:^3 sv_cmd sendteams");
 208                         LOG_HELP("  No arguments required.");
 209                         return;
 210                 }
 211         }
 212 }
 213
 214 void GameCommand_allready(int request)
 215 {
 216         switch (request)
 217         {
 218                 case CMD_REQUEST_COMMAND:
 219                 {
 220                         if(warmup_stage)
 221                         {
 222                                 ReadyRestart(true);
 223                         }
 224                         else
 225                                 LOG_INFO("Not in warmup.");
 226
 227                         return;
 228                 }
 229
 230                 default:
 231                 case CMD_REQUEST_USAGE:
 232                 {
 233                         LOG_HELP("Usage:^3 sv_cmd allready");
 234                         LOG_HELP("  No arguments required.");
 235                         return;
 236                 }
 237         }
 238 }
 239
 240 void GameCommand_allspec(int request, int argc)
 241 {
 242         switch (request)
 243         {
 244                 case CMD_REQUEST_COMMAND:
 245                 {
 246                         string reason = argv(1);
 247                         int n = 0;
 248                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 249                                 PutObserverInServer(it, true, true);
 250                                 ++n;
 251                         });
 252                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 253                         else   LOG_INFO("No players found to spectate.");
 254                         return;
 255                 }
 256
 257                 default:
 258                 case CMD_REQUEST_USAGE:
 259                 {
 260                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 261                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 262                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void GameCommand_anticheat(int request, int argc)
 269 {
 270         switch (request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         entity client = GetIndexedEntity(argc, 1);
 275                         float accepted = VerifyClientEntity(client, false, false);
 276
 277                         if (accepted > 0)
 278                         {
 279                                 anticheat_report_to_eventlog(client);
 280                                 return;
 281                         }
 282                         else
 283                         {
 284                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 285                         }
 286                 }
 287
 288                 default:
 289                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 293                         LOG_HELP("  <client> is the entity number or name of the player.");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void GameCommand_bbox(int request)
 300 {
 301         switch (request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         vector size_min = '0 0 0';
 306                         vector size_max = '0 0 0';
 307                         tracebox('1 0 0' * world.absmin.x,
 308                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 309                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 310                                 '1 0 0' * world.absmax.x,
 311                                 MOVE_WORLDONLY,
 312                                 NULL);
 313                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 314
 315                         tracebox('0 1 0' * world.absmin.y,
 316                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 317                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 318                                 '0 1 0' * world.absmax.y,
 319                                 MOVE_WORLDONLY,
 320                                 NULL);
 321                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 322
 323                         tracebox('0 0 1' * world.absmin.z,
 324                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 325                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 326                                 '0 0 1' * world.absmax.z,
 327                                 MOVE_WORLDONLY,
 328                                 NULL);
 329                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 330
 331                         tracebox('1 0 0' * world.absmax.x,
 332                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 333                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 334                                 '1 0 0' * world.absmin.x,
 335                                 MOVE_WORLDONLY,
 336                                 NULL);
 337                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 338
 339                         tracebox('0 1 0' * world.absmax.y,
 340                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 341                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 342                                 '0 1 0' * world.absmin.y,
 343                                 MOVE_WORLDONLY,
 344                                 NULL);
 345                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 346
 347                         tracebox('0 0 1' * world.absmax.z,
 348                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 349                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 350                                 '0 0 1' * world.absmin.z,
 351                                 MOVE_WORLDONLY,
 352                                 NULL);
 353                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 354
 355                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 356                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 357                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 358                         return;
 359                 }
 360
 361                 default:
 362                 case CMD_REQUEST_USAGE:
 363                 {
 364                         LOG_HELP("Usage:^3 sv_cmd bbox");
 365                         LOG_HELP("  No arguments required.");
 366                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 367                         return;
 368                 }
 369         }
 370 }
 371
 372 void GameCommand_bot_cmd(int request, int argc, string command)
 373 {
 374         switch (request)
 375         {
 376                 case CMD_REQUEST_COMMAND:
 377                 {
 378                         entity bot;
 379
 380                         if (argv(1) == "reset")
 381                         {
 382                                 bot_resetqueues();
 383                                 return;
 384                         }
 385                         else if (argv(1) == "setbots")
 386                         {
 387                                 cvar_settemp("bot_vs_human", "0");
 388                                 cvar_settemp("minplayers", "0");
 389                                 cvar_settemp("minplayers_per_team", "0");
 390                                 cvar_settemp("bot_number", "0");
 391                                 bot_fixcount(false);  // Kill all bots.
 392                                 cvar_settemp("bot_number", argv(2));
 393                                 if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 394                                 return;
 395                         }
 396                         else if (argv(1) == "load" && argc == 3)
 397                         {
 398                                 float fh, i;
 399                                 string s;
 400                                 fh = fopen(argv(2), FILE_READ);
 401                                 if (fh < 0)
 402                                 {
 403                                         LOG_INFO("cannot open the file");
 404                                         return;
 405                                 }
 406
 407                                 i = 0;
 408                                 while ((s = fgets(fh)))
 409                                 {
 410                                         argc = tokenize_console(s);
 411
 412                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 413                                         {
 414                                                 if (argv(2) == "reset")
 415                                                 {
 416                                                         bot_resetqueues();
 417                                                 }
 418                                                 else if (argv(2) == "setbots")
 419                                                 {
 420                                                         cvar_settemp("bot_vs_human", "0");
 421                                                         cvar_settemp("minplayers", "0");
 422                                                         cvar_settemp("minplayers_per_team", "0");
 423                                                         cvar_settemp("bot_number", "0");
 424                                                         bot_fixcount(false);  // Kill all bots.
 425                                                         cvar_settemp("bot_number", argv(3));
 426                                                         if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 427                                                 }
 428                                                 else
 429                                                 {
 430                                                         if(argv(2) == "*" || argv(2) == "all")
 431                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 432                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 433                                                                 });
 434                                                         else
 435                                                         {
 436                                                                 bot = find_bot_by_number(stof(argv(2)));
 437                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 438                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 439                                                         }
 440                                                 }
 441                                         }
 442                                         else
 443                                         {
 444                                                 localcmd(strcat(s, "\n"));
 445                                         }
 446
 447                                         ++i;
 448                                 }
 449                                 LOG_INFO(ftos(i), " commands read");
 450                                 fclose(fh);
 451                                 return;
 452                         }
 453                         else if (argv(1) == "help")
 454                         {
 455                                 if (argv(2)) bot_cmdhelp(argv(2));
 456                                 else bot_list_commands();
 457                                 return;
 458                         }
 459                         else if (argc >= 3)  // this comes last
 460                         {
 461                                 if(argv(1) == "*" || argv(1) == "all")
 462                                 {
 463                                         int bot_num = 0;
 464                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 465                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 466                                                 bot_num++;
 467                                         });
 468                                         if(bot_num)
 469                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 470                                         return;
 471                                 }
 472                                 else
 473                                 {
 474                                         bot = find_bot_by_number(stof(argv(1)));
 475                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 476                                         if (bot)
 477                                         {
 478                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 479                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 480                                                 return;
 481                                         }
 482                                         else
 483                                         {
 484                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 485                                         }
 486                                 }
 487                         }
 488                 }
 489
 490                 default:
 491                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 492                 case CMD_REQUEST_USAGE:
 493                 {
 494                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 495                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 496                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 497                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 498                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 499                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 500                         LOG_HELP("          sv_cmd bot_cmd * pause");
 501                         return;
 502                 }
 503         }
 504 }
 505
 506 void GameCommand_cointoss(int request, int argc)
 507 {
 508         switch (request)
 509         {
 510                 case CMD_REQUEST_COMMAND:
 511                 {
 512                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 513                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 514                         string choice = ((random() > 0.5) ? result1 : result2);
 515
 516                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 517                         return;
 518                 }
 519
 520                 default:
 521                 case CMD_REQUEST_USAGE:
 522                 {
 523                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 524                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 525                         return;
 526                 }
 527         }
 528 }
 529
 530 void GameCommand_database(int request, int argc)
 531 {
 532         switch (request)
 533         {
 534                 case CMD_REQUEST_COMMAND:
 535                 {
 536                         if (argc == 3)
 537                         {
 538                                 if (argv(1) == "save")
 539                                 {
 540                                         db_save(ServerProgsDB, argv(2));
 541                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 542                                         return;
 543                                 }
 544                                 else if (argv(1) == "dump")
 545                                 {
 546                                         db_dump(ServerProgsDB, argv(2));
 547                                         LOG_INFO("DB dumped.");  // wtf does this do?
 548                                         return;
 549                                 }
 550                                 else if (argv(1) == "load")
 551                                 {
 552                                         db_close(ServerProgsDB);
 553                                         ServerProgsDB = db_load(argv(2));
 554                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 555                                         return;
 556                                 }
 557                         }
 558                 }
 559
 560                 default:
 561                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 562                 case CMD_REQUEST_USAGE:
 563                 {
 564                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 565                         LOG_HELP("  Where <action> is the command to complete,");
 566                         LOG_HELP("  and <filename> is what it acts upon.");
 567                         LOG_HELP("  Full list of commands here: save, dump, load.");
 568                         return;
 569                 }
 570         }
 571 }
 572
 573 void GameCommand_defer_clear(int request, int argc)
 574 {
 575         switch (request)
 576         {
 577                 case CMD_REQUEST_COMMAND:
 578                 {
 579                         entity client;
 580                         float accepted;
 581
 582                         if (argc >= 2)
 583                         {
 584                                 client = GetIndexedEntity(argc, 1);
 585                                 accepted = VerifyClientEntity(client, true, false);
 586
 587                                 if (accepted > 0)
 588                                 {
 589                                         stuffcmd(client, "defer clear\n");
 590                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 591                                 }
 592                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 593
 594                                 return;
 595                         }
 596                 }
 597
 598                 default:
 599                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 600                 case CMD_REQUEST_USAGE:
 601                 {
 602                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 603                         LOG_HELP("  <client> is the entity number or name of the player.");
 604                         LOG_HELP("See also: ^2defer_clear_all^7");
 605                         return;
 606                 }
 607         }
 608 }
 609
 610 void GameCommand_defer_clear_all(int request)
 611 {
 612         switch (request)
 613         {
 614                 case CMD_REQUEST_COMMAND:
 615                 {
 616                         int n = 0;
 617                         int argc;
 618
 619                         FOREACH_CLIENT(true, {
 620                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 621                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 622                                 ++n;
 623                         });
 624                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 625                         return;
 626                 }
 627
 628                 default:
 629                 case CMD_REQUEST_USAGE:
 630                 {
 631                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 632                         LOG_HELP("  No arguments required.");
 633                         LOG_HELP("See also: ^2defer_clear^7");
 634                         return;
 635                 }
 636         }
 637 }
 638
 639 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 640 {
 641         switch (request)
 642         {
 643                 case CMD_REQUEST_COMMAND:
 644                 {
 645                         if (argv(1))
 646                         {
 647                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 648                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 649                                 return;
 650                         }
 651                 }
 652
 653                 default:
 654                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 655                 case CMD_REQUEST_USAGE:
 656                 {
 657                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 658                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 659                         LOG_HELP("  it will clear all records up to nth place.");
 660                         LOG_HELP("  if <map> is not provided it will use current map.");
 661                         return;
 662                 }
 663         }
 664 }
 665
 666 void print_Effect_Index(int d, string effect_name)
 667 {
 668         // this is inside a function to avoid expanding it on compilation everytime
 669         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 670         db_put(d, effect_name, "1");
 671 }
 672
 673 void GameCommand_effectindexdump(int request)
 674 {
 675         switch (request)
 676         {
 677                 case CMD_REQUEST_COMMAND:
 678                 {
 679                         float fh, d;
 680                         string s;
 681
 682                         d = db_create();
 683                         LOG_INFO("begin of effects list");
 684
 685                         print_Effect_Index(d, "TE_GUNSHOT");
 686                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 687                         print_Effect_Index(d, "TE_SPIKE");
 688                         print_Effect_Index(d, "TE_SPIKEQUAD");
 689                         print_Effect_Index(d, "TE_SUPERSPIKE");
 690                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 691                         print_Effect_Index(d, "TE_WIZSPIKE");
 692                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 693                         print_Effect_Index(d, "TE_EXPLOSION");
 694                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 695                         print_Effect_Index(d, "TE_TAREXPLOSION");
 696                         print_Effect_Index(d, "TE_TELEPORT");
 697                         print_Effect_Index(d, "TE_LAVASPLASH");
 698                         print_Effect_Index(d, "TE_SMALLFLASH");
 699                         print_Effect_Index(d, "TE_FLAMEJET");
 700                         print_Effect_Index(d, "EF_FLAME");
 701                         print_Effect_Index(d, "TE_BLOOD");
 702                         print_Effect_Index(d, "TE_SPARK");
 703                         print_Effect_Index(d, "TE_PLASMABURN");
 704                         print_Effect_Index(d, "TE_TEI_G3");
 705                         print_Effect_Index(d, "TE_TEI_SMOKE");
 706                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 707                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 708                         print_Effect_Index(d, "EF_STARDUST");
 709                         print_Effect_Index(d, "TR_ROCKET");
 710                         print_Effect_Index(d, "TR_GRENADE");
 711                         print_Effect_Index(d, "TR_BLOOD");
 712                         print_Effect_Index(d, "TR_WIZSPIKE");
 713                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 714                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 715                         print_Effect_Index(d, "TR_VORESPIKE");
 716                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 717                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 718                         print_Effect_Index(d, "TR_GLOWTRAIL");
 719                         print_Effect_Index(d, "TR_SEEKER");
 720                         print_Effect_Index(d, "SVC_PARTICLE");
 721
 722                         fh = fopen("effectinfo.txt", FILE_READ);
 723                         while ((s = fgets(fh)))
 724                         {
 725                                 tokenize_console(s);
 726                                 if (argv(0) == "effect")
 727                                 {
 728                                         if (db_get(d, argv(1)) != "1")
 729                                         {
 730                                                 int i = _particleeffectnum(argv(1));
 731                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 732                                                 db_put(d, argv(1), "1");
 733                                         }
 734                                 }
 735                         }
 736                         LOG_INFO("end of effects list");
 737
 738                         db_close(d);
 739                         return;
 740                 }
 741
 742                 default:
 743                 case CMD_REQUEST_USAGE:
 744                 {
 745                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 746                         LOG_HELP("  No arguments required.");
 747                         return;
 748                 }
 749         }
 750 }
 751
 752 void GameCommand_extendmatchtime(int request)
 753 {
 754         switch (request)
 755         {
 756                 case CMD_REQUEST_COMMAND:
 757                 {
 758                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 759                         return;
 760                 }
 761
 762                 default:
 763                 case CMD_REQUEST_USAGE:
 764                 {
 765                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 766                         LOG_HELP("  No arguments required.");
 767                         LOG_HELP("See also: ^2reducematchtime^7");
 768                         return;
 769                 }
 770         }
 771 }
 772
 773 void GameCommand_gametype(int request, int argc)
 774 {
 775         switch (request)
 776         {
 777                 case CMD_REQUEST_COMMAND:
 778                 {
 779                         if (!world_initialized)
 780                         {
 781                                 LOG_INFOF("This command works only when the server is running.");
 782                                 return;
 783                         }
 784                         if (argv(1) != "")
 785                         {
 786                                 string s = argv(1);
 787                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 788
 789                                 if (t)
 790                                 {
 791                                         MapInfo_SwitchGameType(t);
 792                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 793                                         if (MapInfo_count > 0)
 794                                         {
 795                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 796                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 797                                                 lsmaps_reply = strzone(getlsmaps());
 798                                                 bprint("Game type successfully switched to ", s, "\n");
 799                                         }
 800                                         else
 801                                         {
 802                                                 bprint("Cannot use this game type: no map for it found\n");
 803                                                 MapInfo_SwitchGameType(tsave);
 804                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 805                                         }
 806                                 }
 807                                 else
 808                                 {
 809                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
 810                                 }
 811
 812                                 return;
 813                         }
 814                 }
 815
 816                 default:
 817                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 818                 case CMD_REQUEST_USAGE:
 819                 {
 820                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 821                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 822                         LOG_HELP("See also: ^2gotomap^7");
 823                         return;
 824                 }
 825         }
 826 }
 827
 828 void GameCommand_gettaginfo(int request, int argc)
 829 {
 830         switch (request)
 831         {
 832                 case CMD_REQUEST_COMMAND:
 833                 {
 834                         entity tmp_entity;
 835                         float i;
 836                         vector v;
 837
 838                         if (argc >= 4)
 839                         {
 840                                 tmp_entity = spawn();
 841                                 if (argv(1) == "w")
 842                                 {
 843                                         .entity weaponentity = weaponentities[0];
 844                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 845                                 }
 846                                 else
 847                                 {
 848                                         precache_model(argv(1));
 849                                         _setmodel(tmp_entity, argv(1));
 850                                 }
 851                                 tmp_entity.frame = stof(argv(2));
 852                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 853                                 else i = gettagindex(tmp_entity, argv(3));
 854                                 if (i)
 855                                 {
 856                                         v = gettaginfo(tmp_entity, i);
 857                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 858                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 859                                         );
 860                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 861                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 862                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 863                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 864                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 865                                         if (argc >= 6)
 866                                         {
 867                                                 v.y = -v.y;
 868                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 869                                         }
 870                                 }
 871                                 else
 872                                 {
 873                                         LOG_INFO("bone not found");
 874                                 }
 875
 876                                 delete(tmp_entity);
 877                                 return;
 878                         }
 879                 }
 880
 881                 default:
 882                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 883                 case CMD_REQUEST_USAGE:
 884                 {
 885                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 886                         LOG_HELP("See also: ^2bbox, trace^7");
 887                         return;
 888                 }
 889         }
 890 }
 891
 892 void GameCommand_animbench(int request, int argc)
 893 {
 894         switch (request)
 895         {
 896                 case CMD_REQUEST_COMMAND:
 897                 {
 898                         entity tmp_entity;
 899
 900                         if (argc >= 4)
 901                         {
 902                                 tmp_entity = spawn();
 903                                 if (argv(1) == "w")
 904                                 {
 905                                         .entity weaponentity = weaponentities[0];
 906                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 907                                 }
 908                                 else
 909                                 {
 910                                         precache_model(argv(1));
 911                                         _setmodel(tmp_entity, argv(1));
 912                                 }
 913                                 float f1 = stof(argv(2));
 914                                 float f2 = stof(argv(3));
 915                                 float t0;
 916                                 float t1 = 0;
 917                                 float t2 = 0;
 918                                 float n = 0;
 919
 920                                 while (t1 + t2 < 1)
 921                                 {
 922                                         tmp_entity.frame = f1;
 923                                         t0 = gettime(GETTIME_HIRES);
 924                                         getsurfacepoint(tmp_entity, 0, 0);
 925                                         t1 += gettime(GETTIME_HIRES) - t0;
 926                                         tmp_entity.frame = f2;
 927                                         t0 = gettime(GETTIME_HIRES);
 928                                         getsurfacepoint(tmp_entity, 0, 0);
 929                                         t2 += gettime(GETTIME_HIRES) - t0;
 930                                         n += 1;
 931                                 }
 932                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 933                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 934
 935                                 delete(tmp_entity);
 936                                 return;
 937                         }
 938                 }
 939
 940                 default:
 941                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 942                 case CMD_REQUEST_USAGE:
 943                 {
 944                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 945                         LOG_HELP("See also: ^2bbox, trace^7");
 946                         return;
 947                 }
 948         }
 949 }
 950
 951 void GameCommand_gotomap(int request, int argc)
 952 {
 953         switch (request)
 954         {
 955                 case CMD_REQUEST_COMMAND:
 956                 {
 957                         if (!world_initialized)
 958                         {
 959                                 LOG_INFOF("This command works only when the server is running.");
 960                                 return;
 961                         }
 962                         if (argv(1))
 963                         {
 964                                 LOG_INFO(GotoMap(argv(1)));
 965                                 return;
 966                         }
 967                 }
 968
 969                 default:
 970                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 971                 case CMD_REQUEST_USAGE:
 972                 {
 973                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 974                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 975                         LOG_HELP("See also: ^2gametype^7");
 976                         return;
 977                 }
 978         }
 979 }
 980
 981 void GameCommand_ircmsg(int request, int argc, string command)
 982 {
 983         /* IRCSay from the SMB Modpack */
 984         switch (request)
 985         {
 986                 case CMD_REQUEST_COMMAND:
 987                 {
 988                         string msgstr = substring(command, strlen(argv(0))+1, strlen(command));
 989
 990                         if(msgstr == "")
 991                                 return;
 992
 993                         string prefix;
 994                         if(substring(msgstr, 0, 3) == "^4*") // actions
 995                                         prefix = "\{3}";
 996                         else
 997                                         prefix = "\{1}";
 998
 999                         msgstr = strcat(prefix, strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
1000
1001                         FOREACH_CLIENTSLOT(true,
1002                         {
1003                                         if(!intermission_running)
1004                                         if((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || game_stopped)))
1005                                         if(IS_PLAYER(it))
1006                                                 continue;
1007                                         if(IS_REAL_CLIENT(it))
1008                                                 sprint(it, msgstr);
1009                         });
1010                 }
1011
1012                 default:
1013                 case CMD_REQUEST_USAGE:
1014                 {
1015                         LOG_HELP("Usage:^3 sv_cmd ircmsg message");
1016                         return;
1017                 }
1018         }
1019 }
1020
1021 void GameCommand_lockteams(int request)
1022 {
1023         switch (request)
1024         {
1025                 case CMD_REQUEST_COMMAND:
1026                 {
1027                         if (teamplay)
1028                         {
1029                                 lockteams = 1;
1030                                 bprint("\{1}^1The teams are now locked.\n");
1031                         }
1032                         else
1033                         {
1034                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
1035                         }
1036                         return;
1037                 }
1038
1039                 default:
1040                 case CMD_REQUEST_USAGE:
1041                 {
1042                         LOG_HELP("Usage:^3 sv_cmd lockteams");
1043                         LOG_HELP("  No arguments required.");
1044                         LOG_HELP("See also: ^2unlockteams^7");
1045                         return;
1046                 }
1047         }
1048 }
1049
1050 void GameCommand_make_mapinfo(int request)
1051 {
1052         switch (request)
1053         {
1054                 case CMD_REQUEST_COMMAND:
1055                 {
1056                         entity tmp_entity;
1057
1058                         tmp_entity = new(make_mapinfo);
1059                         setthink(tmp_entity, make_mapinfo_Think);
1060                         tmp_entity.nextthink = time;
1061                         MapInfo_Enumerate();
1062                         return;
1063                 }
1064
1065                 default:
1066                 case CMD_REQUEST_USAGE:
1067                 {
1068                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
1069                         LOG_HELP("  No arguments required.");
1070                         LOG_HELP("See also: ^2radarmap^7");
1071                         return;
1072                 }
1073         }
1074 }
1075
1076 void GameCommand_setflag(int request, int argc)
1077 {
1078         switch (request)
1079         {
1080                 case CMD_REQUEST_COMMAND:
1081                 {
1082                         entity client;
1083                         float accepted;
1084
1085                         client = GetFilteredEntity(argv(1));
1086                         accepted = VerifyClientEntity(client, false, false);
1087
1088                         if (accepted <= 0)
1089                         {
1090                                 LOG_INFO("^1ERROR^7: Couldn't set country flag");
1091                                 LOG_HELP("Usage:^3 sv_cmd setflag #client_id countrycode[0-249]");
1092                                 return;
1093                         }
1094
1095                         client.countrycode = stof(argv(2));
1096                         LOG_INFO("^2SUCCESS^7: Country flag set!");
1097                         return;
1098                 }
1099                 default:
1100                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1101                 case CMD_REQUEST_USAGE:
1102                 {
1103                         LOG_HELP("Usage:^3 sv_cmd setflag #client_id countrycode[0-249]");
1104                         return;
1105                 }
1106         }
1107 }
1108
1109 void GameCommand_setrank(int request, int argc)
1110 {
1111         switch (request)
1112         {
1113                 case CMD_REQUEST_COMMAND:
1114                 {
1115                         entity client;
1116                         float accepted;
1117
1118                         client = GetFilteredEntity(argv(1));
1119                         accepted = VerifyClientEntity(client, false, false);
1120
1121                         if (accepted <= 0)
1122                         {
1123                                 LOG_INFO("^1ERROR^7: Couldn't set player rank");
1124                                 LOG_HELP("Usage:^3 sv_cmd setrank #client_id rank");
1125                                 return;
1126                         }
1127
1128                         client.rank = strzone(argv(2));
1129                         LOG_INFO("^2SUCCESS^7: Player rank set!");
1130                         return;
1131                 }
1132                 default:
1133                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1134                 case CMD_REQUEST_USAGE:
1135                 {
1136                         LOG_HELP("Usage:^3 sv_cmd setrank #client_id #rank");
1137                         return;
1138                 }
1139         }
1140 }
1141
1142 void GameCommand_moveplayer(int request, int argc)
1143 {
1144         switch (request)
1145         {
1146                 case CMD_REQUEST_COMMAND:
1147                 {
1148                         float accepted;
1149                         entity client;
1150
1151                         string targets = strreplace(",", " ", argv(1));
1152                         string original_targets = strreplace(" ", ", ", targets);
1153                         string destination = argv(2);
1154                         if (destination == "spec")
1155                                 destination = "spectator";
1156
1157                         if ((targets) && (destination))
1158                         {
1159                                 string successful = string_null;
1160                                 string t;
1161                                 for ( ; targets; )
1162                                 {
1163                                         t = car(targets);
1164                                         targets = cdr(targets);
1165
1166                                         // Check to see if the player is a valid target
1167                                         client = GetFilteredEntity(t);
1168                                         accepted = VerifyClientEntity(client, false, false);
1169                                         string client_num_str = ftos(etof(client));
1170
1171                                         if (accepted <= 0)
1172                                         {
1173                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1174                                         }
1175                                         else if (destination == "spectator")
1176                                         {
1177                                                 string pl_name = playername(client.netname, client.team, false);
1178                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1179                                                 {
1180                                                         PutObserverInServer(client, true, true);
1181
1182                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1183                                                 }
1184                                                 else
1185                                                 {
1186                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already spectating.");
1187                                                 }
1188                                         }
1189                                         else
1190                                         {
1191                                                 if (!teamplay)
1192                                                 {
1193                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1194                                                         return;
1195                                                 }
1196
1197                                                 string pl_name = playername(client.netname, client.team, false);
1198                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1199                                                 {
1200                                                         // well technically we could, but should we allow that? :P
1201                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not in the game.");
1202                                                         continue;
1203                                                 }
1204
1205                                                 // set up
1206                                                 int save = Player_GetForcedTeamIndex(client);
1207                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1208
1209                                                 // find the team to move the player to
1210                                                 int team_num = Team_ColorToTeam(destination);
1211                                                 entity balance;
1212                                                 if (team_num == client.team)  // already on the destination team
1213                                                 {
1214                                                         // keep the forcing undone
1215                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), "^7.");
1216                                                         continue;
1217                                                 }
1218                                                 else if (team_num == 0)  // auto team
1219                                                 {
1220                                                         balance = TeamBalance_CheckAllowedTeams(client);
1221                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1222                                                 }
1223                                                 else
1224                                                 {
1225                                                         balance = TeamBalance_CheckAllowedTeams(client);
1226                                                 }
1227                                                 Player_SetForcedTeamIndex(client, save);
1228
1229                                                 // Check to see if the destination team is even available
1230                                                 int team_id = Team_TeamToIndex(team_num);
1231                                                 if (team_id == -1)
1232                                                 {
1233                                                         LOG_INFO("Can't move player to ", destination, " team because it doesn't exist.");
1234                                                         TeamBalance_Destroy(balance);
1235                                                         return;
1236                                                 }
1237                                                 if (!IsTeamAvailable(team_num))
1238                                                 {
1239                                                         LOG_INFO("Can't move player to ", destination, " team because it isn't available.");
1240                                                         TeamBalance_Destroy(balance);
1241                                                         return;
1242                                                 }
1243                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1244                                                 {
1245                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not allowed to join the ", Team_ColoredFullName(team_num), "^7.");
1246                                                         TeamBalance_Destroy(balance);
1247                                                         continue;
1248                                                 }
1249                                                 TeamBalance_Destroy(balance);
1250
1251                                                 // If so, lets continue and finally move the player
1252                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1253                                                 if (MoveToTeam(client, team_id, 6))
1254                                                 {
1255                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1256                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1257                                                 }
1258                                                 else
1259                                                 {
1260                                                         LOG_INFO("Unable to move player #", client_num_str, " (", pl_name, ")");
1261                                                 }
1262                                         }
1263                                 } // loop end
1264
1265                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1266                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1267
1268                                 return;  // still correct parameters so return to avoid usage print
1269                         }
1270                 }
1271
1272                 default:
1273                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1274                 case CMD_REQUEST_USAGE:
1275                 {
1276                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1277                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1278                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1279                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1280                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1281                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1282                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1283                         return;
1284                 }
1285         }
1286 }
1287
1288 void GameCommand_nospectators(int request)
1289 {
1290         switch (request)
1291         {
1292                 case CMD_REQUEST_COMMAND:
1293                 {
1294                         blockSpectators = 1;
1295                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1296                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !INGAME(it), {
1297                                 CS(it).spectatortime = time;
1298                                 Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1299                         });
1300                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1301                         return;
1302                 }
1303
1304                 default:
1305                 case CMD_REQUEST_USAGE:
1306                 {
1307                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1308                         LOG_HELP("  No arguments required.");
1309                         return;
1310                 }
1311         }
1312 }
1313
1314 void GameCommand_printstats(int request)
1315 {
1316         switch (request)
1317         {
1318                 case CMD_REQUEST_COMMAND:
1319                 {
1320                         DumpStats(false);
1321                         LOG_INFO("stats dumped.");
1322                         return;
1323                 }
1324
1325                 default:
1326                 case CMD_REQUEST_USAGE:
1327                 {
1328                         LOG_HELP("Usage:^3 sv_cmd printstats");
1329                         LOG_HELP("  No arguments required.");
1330                         return;
1331                 }
1332         }
1333 }
1334
1335 void GameCommand_radarmap(int request, int argc)
1336 {
1337         switch (request)
1338         {
1339                 case CMD_REQUEST_COMMAND:
1340                 {
1341                         if (RadarMap_Make(argc)) return;
1342                 }
1343
1344                 default:
1345                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1346                 case CMD_REQUEST_USAGE:
1347                 {
1348                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1349                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1350                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1351                         LOG_HELP("See also: ^2make_mapinfo^7");
1352                         return;
1353                 }
1354         }
1355 }
1356
1357 void GameCommand_reducematchtime(int request)
1358 {
1359         switch (request)
1360         {
1361                 case CMD_REQUEST_COMMAND:
1362                 {
1363                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1364                         return;
1365                 }
1366
1367                 default:
1368                 case CMD_REQUEST_USAGE:
1369                 {
1370                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1371                         LOG_HELP("  No arguments required.");
1372                         LOG_HELP("See also: ^2extendmatchtime^7");
1373                         return;
1374                 }
1375         }
1376 }
1377
1378 void GameCommand_setbots(int request, int argc)
1379 {
1380         switch (request)
1381         {
1382                 case CMD_REQUEST_COMMAND:
1383                 {
1384                         if (argc >= 2)
1385                         {
1386                                 cvar_settemp("minplayers", "0");
1387                                 cvar_settemp("minplayers_per_team", "0");
1388                                 cvar_settemp("bot_number", argv(1));
1389                                 bot_fixcount(true);
1390                                 return;
1391                         }
1392                 }
1393
1394                 default:
1395                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1396                 case CMD_REQUEST_USAGE:
1397                 {
1398                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1399                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1400                         LOG_HELP("See also: ^2bot_cmd^7");
1401                         return;
1402                 }
1403         }
1404 }
1405
1406 void shuffleteams()
1407 {
1408         if (!teamplay)
1409         {
1410                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1411                 return;
1412         }
1413
1414         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1415                 if (Player_HasRealForcedTeam(it)) {
1416                         // we could theoretically assign forced players to their teams
1417                         // and shuffle the rest to fill the empty spots but in practise
1418                         // either all players or none are gonna have forced teams
1419                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1420                         return;
1421                 }
1422         });
1423
1424         int number_of_teams = 0;
1425         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1426         for (int i = 1; i <= NUM_TEAMS; ++i)
1427         {
1428                 if (TeamBalance_IsTeamAllowed(balance, i))
1429                 {
1430                         number_of_teams = max(i, number_of_teams);
1431                 }
1432         }
1433         TeamBalance_Destroy(balance);
1434
1435         int team_index = 0;
1436         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || INGAME(it), {
1437                 int target_team_index = team_index + 1;
1438                 if (Entity_GetTeamIndex(it) != target_team_index)
1439                 {
1440                         MoveToTeam(it, target_team_index, 6);
1441                 }
1442                 team_index = (team_index + 1) % number_of_teams;
1443         });
1444
1445         bprint("Successfully shuffled the players around randomly.\n");
1446 }
1447
1448 void GameCommand_shuffleteams(int request)
1449 {
1450         switch (request)
1451         {
1452                 case CMD_REQUEST_COMMAND:
1453                 {
1454                         if (shuffleteams_on_reset_map)
1455                         {
1456                                 bprint("Players will be shuffled when this round is over.\n");
1457                                 shuffleteams_on_reset_map = true;
1458                         }
1459                         else
1460                                 shuffleteams();
1461                         return;
1462                 }
1463
1464                 default:
1465                 case CMD_REQUEST_USAGE:
1466                 {
1467                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1468                         LOG_HELP("  No arguments required.");
1469                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1470                         return;
1471                 }
1472         }
1473 }
1474
1475 void GameCommand_resetmatch(int request)
1476 {
1477         switch (request)
1478         {
1479                 case CMD_REQUEST_COMMAND:
1480                 {
1481                         ReadyRestart(false);
1482                         return;
1483                 }
1484
1485                 default:
1486                 case CMD_REQUEST_USAGE:
1487                 {
1488                         LOG_HELP("Usage:^3 sv_cmd resetmatch");
1489                         LOG_HELP("  No arguments required.");
1490                         return;
1491                 }
1492         }
1493 }
1494
1495 void GameCommand_stuffto(int request, int argc)
1496 {
1497         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1498         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1499         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1500
1501 #ifdef STUFFTO_ENABLED
1502                 switch (request)
1503                 {
1504                         case CMD_REQUEST_COMMAND:
1505                         {
1506                                 if (argv(2))
1507                                 {
1508                                         entity client = GetIndexedEntity(argc, 1);
1509                                         float accepted = VerifyClientEntity(client, true, false);
1510
1511                                         if (accepted > 0)
1512                                         {
1513                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1514                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1515                                         }
1516                                         else
1517                                         {
1518                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1519                                         }
1520
1521                                         return;
1522                                 }
1523                         }
1524
1525                         default:
1526                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1527                         case CMD_REQUEST_USAGE:
1528                         {
1529                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1530                                 LOG_HELP("  <client> is the entity number or name of the player,");
1531                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1532                                 return;
1533                         }
1534                 }
1535 #else
1536                 if (request)
1537                 {
1538                         LOG_HELP("stuffto command is not enabled on this server.");
1539                         return;
1540                 }
1541 #endif
1542 }
1543
1544 void GameCommand_trace(int request, int argc)
1545 {
1546         switch (request)
1547         {
1548                 case CMD_REQUEST_COMMAND:
1549                 {
1550                         entity e;
1551                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1552                         float i, f, safe, unsafe, dq, dqf;
1553
1554                         switch (argv(1))
1555                         {
1556                                 case "debug":
1557                                 {
1558                                         float hitcount = 0;
1559                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1560                                         float worst_endpos_bug = 0;
1561                                         for ( ; ; )
1562                                         {
1563                                                 org = world.mins;
1564                                                 delta = world.maxs - world.mins;
1565
1566                                                 start.x = org.x + random() * delta.x;
1567                                                 start.y = org.y + random() * delta.y;
1568                                                 start.z = org.z + random() * delta.z;
1569
1570                                                 end.x = org.x + random() * delta.x;
1571                                                 end.y = org.y + random() * delta.y;
1572                                                 end.z = org.z + random() * delta.z;
1573
1574                                                 start = stov(vtos(start));
1575                                                 end = stov(vtos(end));
1576
1577                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1578                                                 if (!trace_startsolid && trace_fraction < 1)
1579                                                 {
1580                                                         p = trace_endpos;
1581                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1582                                                         if (trace_startsolid)
1583                                                         {
1584                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1585                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1586
1587                                                                 // how much do we need to back off?
1588                                                                 safe = 1;
1589                                                                 unsafe = 0;
1590                                                                 for ( ; ; )
1591                                                                 {
1592                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1593                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1594                                                                         if (trace_startsolid)
1595                                                                         {
1596                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1597                                                                                 unsafe = (safe + unsafe) * 0.5;
1598                                                                         }
1599                                                                         else
1600                                                                         {
1601                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1602                                                                                 safe = (safe + unsafe) * 0.5;
1603                                                                         }
1604                                                                 }
1605
1606                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1607                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1608
1609                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1610                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1611                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1612                                                                 if (++hitcount >= 10) break;
1613                                                         }
1614                                                         else
1615                                                         {
1616                                                                 q0 = p;
1617                                                                 dq = 0;
1618                                                                 dqf = 1;
1619                                                                 for ( ; ; )
1620                                                                 {
1621                                                                         q = p + normalize(end - p) * (dq + dqf);
1622                                                                         if (q == q0) break;
1623                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1624                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1625                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1626                                                                         dqf *= 0.5;
1627                                                                         q0 = q;
1628                                                                 }
1629                                                                 if (dq > worst_endpos_bug)
1630                                                                 {
1631                                                                         worst_endpos_bug = dq;
1632                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1633                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1634                                                                         if (++hitcount >= 10) break;
1635                                                                 }
1636                                                         }
1637                                                 }
1638                                         }
1639                                         return;
1640                                 }
1641
1642                                 case "debug2":
1643                                 {
1644                                         e = nextent(NULL);
1645                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1646                                         vv = trace_endpos;
1647                                         if (trace_fraction == 1)
1648                                         {
1649                                                 LOG_INFO("not above ground, aborting");
1650                                                 return;
1651                                         }
1652                                         f = 0;
1653                                         for (i = 0; i < 100000; ++i)
1654                                         {
1655                                                 dv = randomvec();
1656                                                 if (dv.z > 0) dv = -1 * dv;
1657                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1658                                                 if (trace_startsolid) LOG_INFO("bug 1");
1659                                                 if (trace_fraction == 1)
1660                                                 {
1661                                                         if (dv.z < f)
1662                                                         {
1663                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1664                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1665                                                                 f = dv.z;
1666                                                         }
1667                                                 }
1668                                         }
1669                                         LOG_INFO("highest possible dist: ", ftos(f));
1670                                         return;
1671                                 }
1672
1673                                 case "walk":
1674                                 {
1675                                         if (argc == 4 || argc == 5)
1676                                         {
1677                                                 e = nextent(NULL);
1678                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1679                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1680                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1681                                                         LOG_INFO("can walk");
1682                                                 else
1683                                                         LOG_INFO("cannot walk");
1684                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1685                                                 return;
1686                                         }
1687                                 }
1688
1689                                 case "showline":
1690                                 {
1691                                         if (argc == 4)
1692                                         {
1693                                                 vv = stov(argv(2));
1694                                                 dv = stov(argv(3));
1695                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1696                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1697                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1698                                                 return;
1699                                         }
1700                                 }
1701
1702                                 // no default case, just go straight to invalid
1703                         }
1704                 }
1705
1706                 default:
1707                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1708                 case CMD_REQUEST_USAGE:
1709                 {
1710                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1711                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1712                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1713                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1714                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1715                         return;
1716                 }
1717         }
1718 }
1719
1720 void GameCommand_unlockteams(int request)
1721 {
1722         switch (request)
1723         {
1724                 case CMD_REQUEST_COMMAND:
1725                 {
1726                         if (teamplay)
1727                         {
1728                                 lockteams = 0;
1729                                 bprint("\{1}^1The teams are now unlocked.\n");
1730                         }
1731                         else
1732                         {
1733                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1734                         }
1735                         return;
1736                 }
1737
1738                 default:
1739                 case CMD_REQUEST_USAGE:
1740                 {
1741                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1742                         LOG_HELP("  No arguments required.");
1743                         LOG_HELP("See also: ^2lockteams^7");
1744                         return;
1745                 }
1746         }
1747 }
1748
1749 void GameCommand_warp(int request, int argc)
1750 {
1751         switch (request)
1752         {
1753                 case CMD_REQUEST_COMMAND:
1754                 {
1755                         if (autocvar_g_campaign)
1756                         {
1757                                 if (argc >= 2)
1758                                 {
1759                                         CampaignLevelWarp(stof(argv(1)));
1760                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1761                                 }
1762                                 else
1763                                 {
1764                                         CampaignLevelWarp(-1);
1765                                         LOG_INFO("Successfully warped to next campaign level.");
1766                                 }
1767                         }
1768                         else
1769                         {
1770                                 LOG_INFO("Not in campaign, can't level warp");
1771                         }
1772                         return;
1773                 }
1774
1775                 default:
1776                 case CMD_REQUEST_USAGE:
1777                 {
1778                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1779                         LOG_HELP("  <level> is the level to change campaign mode to.");
1780                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1781                         return;
1782                 }
1783         }
1784 }
1785
1786 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1787 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1788 void GameCommand_(int request)
1789 {
1790     switch(request)
1791     {
1792         case CMD_REQUEST_COMMAND:
1793         {
1794
1795             return;
1796         }
1797
1798         default:
1799         case CMD_REQUEST_USAGE:
1800         {
1801             LOG_HELP("Usage:^3 sv_cmd ");
1802             LOG_HELP("  No arguments required.");
1803             return;
1804         }
1805     }
1806 }
1807 */
1808
1809
1810 // ==================================
1811 //  Macro system for server commands
1812 // ==================================
1813
1814 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1815 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1816 SERVER_COMMAND(allready, "Ends warmup and starts the match") { GameCommand_allready(request); }
1817 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1818 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1819 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1820 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1821 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1822 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1823 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1824 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1825 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1826 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1827 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1828 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1829 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1830 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1831 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1832 SERVER_COMMAND(ircmsg, "Chat message to be sent by IRC bots") { GameCommand_ircmsg(request, arguments, command); }
1833 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1834 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1835 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1836 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1837 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1838 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1839 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1840 SERVER_COMMAND(resetmatch, "Soft restart the game without changing teams; goes back to warmup if enabled") { GameCommand_resetmatch(request); }
1841 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1842 SERVER_COMMAND(setflag, "Set client flag") { GameCommand_setflag(request, arguments); }
1843 SERVER_COMMAND(setrank, "Set client rank") { GameCommand_setrank(request, arguments); }
1844 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1845 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1846 SERVER_COMMAND(teamname, "Set team name") { GameCommand_teamname(request, arguments); }
1847 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1848 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1849 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1850
1851 void GameCommand_macro_help()
1852 {
1853         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1854 }
1855
1856 float GameCommand_macro_command(int argc, string command)
1857 {
1858         string c = strtolower(argv(0));
1859         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1860                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1861                 return true;
1862         });
1863         return false;
1864 }
1865
1866 float GameCommand_macro_usage(int argc)
1867 {
1868         string c = strtolower(argv(1));
1869         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1870                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1871                 return true;
1872         });
1873         return false;
1874 }
1875
1876 void GameCommand_macro_write_aliases(float fh)
1877 {
1878         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1879 }
1880
1881
1882 // =========================================
1883 //  Main Function Called By Engine (sv_cmd)
1884 // =========================================
1885 // If this function exists, game code handles gamecommand instead of the engine code.
1886
1887 void GameCommand(string command)
1888 {
1889         int argc = tokenize_console(command);
1890
1891         // Guide for working with argc arguments by example:
1892         // argc:   1    - 2      - 3     - 4
1893         // argv:   0    - 1      - 2     - 3
1894         // cmd     vote - master - login - password
1895
1896         if (strtolower(argv(0)) == "help")
1897         {
1898                 if (argc == 1)
1899                 {
1900                         LOG_HELP("Server console commands:");
1901                         GameCommand_macro_help();
1902
1903                         LOG_HELP("\nBanning commands:");
1904                         BanCommand_macro_help();
1905
1906                         LOG_HELP("\nCommon networked commands:");
1907                         CommonCommand_macro_help(NULL);
1908
1909                         LOG_HELP("\nGeneric commands shared by all programs:");
1910                         GenericCommand_macro_help();
1911
1912                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1913                                 "For help about a specific command, type sv_cmd help <command>");
1914
1915                         return;
1916                 }
1917                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1918                 {
1919                         return;
1920                 }
1921                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1922                 {
1923                         return;
1924                 }
1925                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1926                 {
1927                         return;
1928                 }
1929                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1930                 {
1931                         return;
1932                 }
1933         }
1934         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1935         {
1936                 return;  // handled by a mutator
1937         }
1938         else if (BanCommand(command))
1939         {
1940                 return;  // handled by server/command/ipban.qc
1941         }
1942         else if (CommonCommand_macro_command(argc, NULL, command))
1943         {
1944                 return;  // handled by server/command/common.qc
1945         }
1946         else if (GenericCommand(command))
1947         {
1948                 return;                                        // handled by common/command/generic.qc
1949         }
1950         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1951         {
1952                 return;                                        // handled by one of the above GameCommand_* functions
1953         }
1954
1955         // nothing above caught the command, must be invalid
1956         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1957 }