qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_allready(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         ReadyRestart();
 149                         return;
 150                 }
 151
 152                 default:
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         print("\nUsage:^3 sv_cmd allready\n");
 156                         print("  No arguments required.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void GameCommand_allspec(float request, float argc)
 163 {
 164         switch(request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         entity client;
 169                         string reason = argv(1);
 170                         float i = 0;
 171
 172                         FOR_EACH_REALPLAYER(client)
 173                         {
 174                                 self = client;
 175                                 PutObserverInServer();
 176                                 ++i;
 177                         }
 178                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 179                         else { print("No players found to spectate.\n"); }
 180                         return;
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 187                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 188                         print("See also: ^2moveplayer, shuffleteams^7\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void GameCommand_anticheat(float request, float argc)
 195 {
 196         switch(request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         entity client = GetIndexedEntity(argc, 1);
 201                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 202
 203                         if(accepted > 0)
 204                         {
 205                                 self = client;
 206                                 anticheat_report();
 207                                 return;
 208                         }
 209                         else
 210                         {
 211                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 212                         }
 213                 }
 214
 215                 default:
 216                         print("Incorrect parameters for ^2anticheat^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd anticheat client\n");
 220                         print("  'client' is the entity number or name of the player.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void GameCommand_bbox(float request)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 233                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 234                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 235                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 236                         print("Solid bounding box size:");
 237
 238                         tracebox('1 0 0' * world.absmin_x,
 239                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 240                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 241                                                         '1 0 0' * world.absmax_x,
 242                                         MOVE_WORLDONLY,
 243                                         world);
 244                         if(trace_startsolid)
 245                                 print(" ", ftos(world.absmin_x));
 246                         else
 247                                 print(" ", ftos(trace_endpos_x));
 248
 249                         tracebox('0 1 0' * world.absmin_y,
 250                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 251                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 252                                                         '0 1 0' * world.absmax_y,
 253                                         MOVE_WORLDONLY,
 254                                         world);
 255                         if(trace_startsolid)
 256                                 print(" ", ftos(world.absmin_y));
 257                         else
 258                                 print(" ", ftos(trace_endpos_y));
 259
 260                         tracebox('0 0 1' * world.absmin_z,
 261                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 262                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 263                                                         '0 0 1' * world.absmax_z,
 264                                         MOVE_WORLDONLY,
 265                                         world);
 266                         if(trace_startsolid)
 267                                 print(" ", ftos(world.absmin_z));
 268                         else
 269                                 print(" ", ftos(trace_endpos_z));
 270
 271                         tracebox('1 0 0' * world.absmax_x,
 272                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 273                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 274                                                         '1 0 0' * world.absmin_x,
 275                                         MOVE_WORLDONLY,
 276                                         world);
 277                         if(trace_startsolid)
 278                                 print(" ", ftos(world.absmax_x));
 279                         else
 280                                 print(" ", ftos(trace_endpos_x));
 281
 282                         tracebox('0 1 0' * world.absmax_y,
 283                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 284                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 285                                                         '0 1 0' * world.absmin_y,
 286                                         MOVE_WORLDONLY,
 287                                         world);
 288                         if(trace_startsolid)
 289                                 print(" ", ftos(world.absmax_y));
 290                         else
 291                                 print(" ", ftos(trace_endpos_y));
 292
 293                         tracebox('0 0 1' * world.absmax_z,
 294                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 295                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 296                                                         '0 0 1' * world.absmin_z,
 297                                         MOVE_WORLDONLY,
 298                                         world);
 299                         if(trace_startsolid)
 300                                 print(" ", ftos(world.absmax_z));
 301                         else
 302                                 print(" ", ftos(trace_endpos_z));
 303
 304                         print("\n");
 305                         return;
 306                 }
 307
 308                 default:
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print("\nUsage:^3 sv_cmd bbox\n");
 312                         print("  No arguments required.\n");
 313                         print("See also: ^2gettaginfo, trace^7\n");
 314                         return;
 315                 }
 316         }
 317 }
 318
 319 void GameCommand_bot_cmd(float request, float argc, string command)
 320 {
 321         switch(request)
 322         {
 323                 case CMD_REQUEST_COMMAND:
 324                 {
 325                         entity bot;
 326
 327                         if(argv(1) == "reset")
 328                         {
 329                                 bot_resetqueues();
 330                                 return;
 331                         }
 332                         else if(argv(1) == "setbots")
 333                         {
 334                                 cvar_settemp("bot_vs_human", "0");
 335                                 cvar_settemp("minplayers", "0");
 336                                 cvar_settemp("bot_number", "0");
 337                                 bot_fixcount();
 338                                 cvar_settemp("bot_number", argv(2));
 339                                 if(!bot_fixcount())
 340                                         print("Sorry, could not set requested bot count\n");
 341                                 return;
 342                         }
 343                         else if(argv(1) == "load" && argc == 3)
 344                         {
 345                                 float fh, i;
 346                                 string s;
 347                                 fh = fopen(argv(2), FILE_READ);
 348                                 if(fh < 0)
 349                                 {
 350                                         print("cannot open the file\n");
 351                                         return;
 352                                 }
 353
 354                                 i = 0;
 355                                 while((s = fgets(fh)))
 356                                 {
 357                                         argc = tokenize_console(s);
 358
 359                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 360                                         {
 361                                                 if(argv(2) == "reset")
 362                                                 {
 363                                                         bot_resetqueues();
 364                                                 }
 365                                                 else if(argv(2) == "setbots")
 366                                                 {
 367                                                         cvar_settemp("bot_vs_human", "0");
 368                                                         cvar_settemp("minplayers", "0");
 369                                                         cvar_settemp("bot_number", "0");
 370                                                         bot_fixcount();
 371                                                         cvar_settemp("bot_number", argv(3));
 372                                                         if(!bot_fixcount())
 373                                                                 print("Sorry, could not set requested bot count\n");
 374                                                 }
 375                                                 else
 376                                                 {
 377                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 378                                                         bot = find_bot_by_number(stof(argv(2)));
 379                                                         if(bot == world)
 380                                                                 bot = find_bot_by_name(argv(2));
 381                                                         if(bot)
 382                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 383                                                 }
 384                                         }
 385                                         else
 386                                                 localcmd(strcat(s, "\n"));
 387
 388                                         ++i;
 389                                 }
 390                                 print(ftos(i), " commands read\n");
 391                                 fclose(fh);
 392                                 return;
 393                         }
 394                         else if(argv(1) == "help")
 395                         {
 396                                 if(argv(2))
 397                                         bot_cmdhelp(argv(2));
 398                                 else
 399                                         bot_list_commands();
 400                                 return;
 401                         }
 402                         else if(argc >= 3) // this comes last
 403                         {
 404                                 bot = find_bot_by_number(stof(argv(1)));
 405                                 if(bot == world)
 406                                         bot = find_bot_by_name(argv(1));
 407                                 if(bot)
 408                                 {
 409                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 410                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 411                                         return;
 412                                 }
 413                                 else
 414                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 415                         }
 416                 }
 417
 418                 default:
 419                         print("Incorrect parameters for ^2bot_cmd^7\n");
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 423                         print("  'client' can be either the name or entity id of the bot\n");
 424                         print("  For full list of commands, see bot_cmd help [command].\n");
 425                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 426                         print("          sv_cmd bot_cmd client presskey jump\n");
 427                         return;
 428                 }
 429         }
 430 }
 431
 432 void GameCommand_cointoss(float request, float argc)
 433 {
 434         switch(request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438                         entity client;
 439                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 440                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 441                         string choice = ((random() > 0.5) ? result1 : result2);
 442
 443                         FOR_EACH_CLIENT(client)
 444                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 445                         bprint(strcat("^3Throwing coin... Result: ", choice));
 446                         return;
 447                 }
 448
 449                 default:
 450                 case CMD_REQUEST_USAGE:
 451                 {
 452                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 453                         print("  Where 'result1' and 'result2' are user created options.\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 void GameCommand_database(float request, float argc)
 460 {
 461         switch(request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         if(argc == 3)
 466                         {
 467                                 if(argv(1) == "save")
 468                                 {
 469                                         db_save(ServerProgsDB, argv(2));
 470                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 471                                         return;
 472                                 }
 473                                 else if(argv(1) == "dump")
 474                                 {
 475                                         db_dump(ServerProgsDB, argv(2));
 476                                         print("DB dumped.\n"); // wtf does this do?
 477                                         return;
 478                                 }
 479                                 else if(argv(1) == "load")
 480                                 {
 481                                         db_close(ServerProgsDB);
 482                                         ServerProgsDB = db_load(argv(2));
 483                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 484                                         return;
 485                                 }
 486                         }
 487                 }
 488
 489                 default:
 490                         print("Incorrect parameters for ^2database^7\n");
 491                 case CMD_REQUEST_USAGE:
 492                 {
 493                         print("\nUsage:^3 sv_cmd database action filename\n");
 494                         print("  Where 'action' is the command to complete,\n");
 495                         print("  and 'filename' is what it acts upon.\n");
 496                         print("  Full list of commands here: \"save, dump, load.\"\n");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void GameCommand_defer_clear(float request, float argc)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         entity client;
 509                         float accepted;
 510
 511                         if(argc >= 2)
 512                         {
 513                                 client = GetIndexedEntity(argc, 1);
 514                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 515
 516                                 if(accepted > 0)
 517                                 {
 518                                         stuffcmd(client, "defer clear\n");
 519                                         print("defer clear stuffed to ", client.netname, "\n");
 520                                 }
 521                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 522
 523                                 return;
 524                         }
 525                 }
 526
 527                 default:
 528                         print("Incorrect parameters for ^2defer_clear^7\n");
 529                 case CMD_REQUEST_USAGE:
 530                 {
 531                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 532                         print("  'client' is the entity number or name of the player.\n");
 533                         print("See also: ^2defer_clear_all^7\n");
 534                         return;
 535                 }
 536         }
 537 }
 538
 539 void GameCommand_defer_clear_all(float request)
 540 {
 541         switch(request)
 542         {
 543                 case CMD_REQUEST_COMMAND:
 544                 {
 545                         entity client;
 546                         float i = 0;
 547                         float argc;
 548
 549                         FOR_EACH_CLIENT(client)
 550                         {
 551                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 552                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 553                                 ++i;
 554                         }
 555                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 556                         return;
 557                 }
 558
 559                 default:
 560                 case CMD_REQUEST_USAGE:
 561                 {
 562                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 563                         print("  No arguments required.\n");
 564                         print("See also: ^2defer_clear^7\n");
 565                         return;
 566                 }
 567         }
 568 }
 569
 570 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 571 {
 572         switch(request)
 573         {
 574                 case CMD_REQUEST_COMMAND:
 575                 {
 576                         if(argv(1))
 577                         {
 578                                 if(argv(2))
 579                                         race_deleteTime(argv(2), stof(argv(1)));
 580                                 else
 581                                         race_deleteTime(GetMapname(), stof(argv(1)));
 582                                 return;
 583                         }
 584                 }
 585
 586                 default:
 587                         print("Incorrect parameters for ^2delrec^7\n");
 588                 case CMD_REQUEST_USAGE:
 589                 {
 590                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 591                         print("  'ranking' is which ranking level to clear up to, \n");
 592                         print("  it will clear all records up to nth place.\n");
 593                         print("  if 'map' is not provided it will use current map.\n");
 594                         return;
 595                 }
 596         }
 597 }
 598
 599 void GameCommand_effectindexdump(float request)
 600 {
 601         switch(request)
 602         {
 603                 case CMD_REQUEST_COMMAND:
 604                 {
 605                         float fh, d;
 606                         string s;
 607
 608                         d = db_create();
 609                         print("begin of effects list\n");
 610                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 611                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 612                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 613                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 614                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 615                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 616                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 617                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 618                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 619                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 620                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 621                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 622                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 623                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 624                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 625                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 626                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 627                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 628                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 629                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 630                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 631                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 632                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 633                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 634                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 635                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 636                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 637                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 638                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 639                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 640                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 641                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 642                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 643                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 644                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 645                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 646
 647                         fh = fopen("effectinfo.txt", FILE_READ);
 648                         while((s = fgets(fh)))
 649                         {
 650                                 tokenize_console(s);
 651                                 if(argv(0) == "effect")
 652                                 {
 653                                         if(db_get(d, argv(1)) != "1")
 654                                         {
 655                                                 if(particleeffectnum(argv(1)) >= 0)
 656                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 657                                                 db_put(d, argv(1), "1");
 658                                         }
 659                                 }
 660                         }
 661                         print("end of effects list\n");
 662
 663                         db_close(d);
 664                         return;
 665                 }
 666
 667                 default:
 668                 case CMD_REQUEST_USAGE:
 669                 {
 670                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 671                         print("  No arguments required.\n");
 672                         return;
 673                 }
 674         }
 675 }
 676
 677 void GameCommand_extendmatchtime(float request)
 678 {
 679         switch(request)
 680         {
 681                 case CMD_REQUEST_COMMAND:
 682                 {
 683                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 684                         return;
 685                 }
 686
 687                 default:
 688                 case CMD_REQUEST_USAGE:
 689                 {
 690                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 691                         print("  No arguments required.\n");
 692                         print("See also: ^2reducematchtime^7\n");
 693                         return;
 694                 }
 695         }
 696 }
 697
 698 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 699 {
 700         switch(request)
 701         {
 702                 case CMD_REQUEST_COMMAND:
 703                 {
 704                         entity client;
 705
 706                         for(client = world; (client = find(client, classname, argv(1))); )
 707                                 print(etos(client), "\n");
 708
 709                         return;
 710                 }
 711
 712                 default:
 713                         print("Incorrect parameters for ^2find^7\n");
 714                 case CMD_REQUEST_USAGE:
 715                 {
 716                         print("\nUsage:^3 sv_cmd find classname\n");
 717                         print("  Where 'classname' is the classname to search for.\n");
 718                         return;
 719                 }
 720         }
 721 }
 722
 723 void GameCommand_gametype(float request, float argc)
 724 {
 725         switch(request)
 726         {
 727                 case CMD_REQUEST_COMMAND:
 728                 {
 729                         if(argv(1) != "")
 730                         {
 731                                 string s = argv(1);
 732                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 733
 734                                 if(t)
 735                                 {
 736                                         MapInfo_SwitchGameType(t);
 737                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 738                                         if(MapInfo_count > 0)
 739                                                 bprint("Game type successfully switched to ", s, "\n");
 740                                         else
 741                                         {
 742                                                 bprint("Cannot use this game type: no map for it found\n");
 743                                                 MapInfo_SwitchGameType(tsave);
 744                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 745                                         }
 746                                 }
 747                                 else
 748                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 749
 750                                 return;
 751                         }
 752                 }
 753
 754                 default:
 755                         print("Incorrect parameters for ^2gametype^7\n");
 756                 case CMD_REQUEST_USAGE:
 757                 {
 758                         print("\nUsage:^3 sv_cmd gametype mode\n");
 759                         print("  Where 'mode' is the gametype mode to switch to.\n");
 760                         print("See also: ^2gotomap^7\n");
 761                         return;
 762                 }
 763         }
 764 }
 765
 766 void GameCommand_gettaginfo(float request, float argc)
 767 {
 768         switch(request)
 769         {
 770                 case CMD_REQUEST_COMMAND:
 771                 {
 772                         entity tmp_entity;
 773                         float i;
 774                         vector v;
 775
 776                         if(argc >= 4)
 777                         {
 778                                 tmp_entity = spawn();
 779                                 if(argv(1) == "w")
 780                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 781                                 else
 782                                 {
 783                                         precache_model(argv(1));
 784                                         setmodel(tmp_entity, argv(1));
 785                                 }
 786                                 tmp_entity.frame = stof(argv(2));
 787                                 if(substring(argv(3), 0, 1) == "#")
 788                                         i = stof(substring(argv(3), 1, -1));
 789                                 else
 790                                         i = gettagindex(tmp_entity, argv(3));
 791                                 if(i)
 792                                 {
 793                                         v = gettaginfo(tmp_entity, i);
 794                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 795                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 796                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 797                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 798                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 799                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 800                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 801                                         if(argc >= 6)
 802                                         {
 803                                                 v_y = -v_y;
 804                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 805                                         }
 806                                 }
 807                                 else
 808                                         print("bone not found\n");
 809
 810                                 remove(tmp_entity);
 811                                 return;
 812                         }
 813                 }
 814
 815                 default:
 816                         print("Incorrect parameters for ^2gettaginfo^7\n");
 817                 case CMD_REQUEST_USAGE:
 818                 {
 819                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 820                         print("See also: ^2bbox, trace^7\n");
 821                         return;
 822                 }
 823         }
 824 }
 825
 826 void GameCommand_gotomap(float request, float argc)
 827 {
 828         switch(request)
 829         {
 830                 case CMD_REQUEST_COMMAND:
 831                 {
 832                         if(argv(1))
 833                         {
 834                                 print(GotoMap(argv(1)), "\n");
 835                                 return;
 836                         }
 837                 }
 838
 839                 default:
 840                         print("Incorrect parameters for ^2gotomap^7\n");
 841                 case CMD_REQUEST_USAGE:
 842                 {
 843                         print("\nUsage:^3 sv_cmd gotomap map\n");
 844                         print("  Where 'map' is the *.bsp file to change to.\n");
 845                         print("See also: ^2gametype^7\n");
 846                         return;
 847                 }
 848         }
 849 }
 850
 851 void GameCommand_lockteams(float request)
 852 {
 853         switch(request)
 854         {
 855                 case CMD_REQUEST_COMMAND:
 856                 {
 857                         if(teamplay)
 858                         {
 859                                 lockteams = 1;
 860                                 bprint("^1The teams are now locked.\n");
 861                         }
 862                         else
 863                         {
 864                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 865                         }
 866                         return;
 867                 }
 868
 869                 default:
 870                 case CMD_REQUEST_USAGE:
 871                 {
 872                         print("\nUsage:^3 sv_cmd lockteams\n");
 873                         print("  No arguments required.\n");
 874                         print("See also: ^2unlockteams^7\n");
 875                         return;
 876                 }
 877         }
 878 }
 879
 880 void GameCommand_make_mapinfo(float request)
 881 {
 882         switch(request)
 883         {
 884                 case CMD_REQUEST_COMMAND:
 885                 {
 886                         entity tmp_entity;
 887
 888                         tmp_entity = spawn();
 889                         tmp_entity.classname = "make_mapinfo";
 890                         tmp_entity.think = make_mapinfo_Think;
 891                         tmp_entity.nextthink = time;
 892                         MapInfo_Enumerate();
 893                         return;
 894                 }
 895
 896                 default:
 897                 case CMD_REQUEST_USAGE:
 898                 {
 899                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
 900                         print("  No arguments required.\n");
 901                         print("See also: ^2radarmap^7\n");
 902                         return;
 903                 }
 904         }
 905 }
 906
 907 void GameCommand_moveplayer(float request, float argc)
 908 {
 909         switch(request)
 910         {
 911                 case CMD_REQUEST_COMMAND:
 912                 {
 913                         float accepted;
 914                         entity client;
 915
 916                         string targets = strreplace(",", " ", argv(1));
 917                         string original_targets = strreplace(" ", ", ", targets);
 918                         string destination = argv(2);
 919                         string notify = argv(3);
 920
 921                         string successful, t;
 922                         successful = string_null;
 923
 924                         // lets see if the target(s) even actually exist.
 925                         if((targets) && (destination))
 926                         {
 927                                 for(;targets;)
 928                                 {
 929                                         t = car(targets); targets = cdr(targets);
 930
 931                                         // Check to see if the player is a valid target
 932                                         client = GetFilteredEntity(t);
 933                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
 934
 935                                         if not(accepted > 0)
 936                                         {
 937                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 938                                                 continue;
 939                                         }
 940
 941                                         // Where are we putting this player?
 942                                         if(destination == "spec" || destination == "spectator")
 943                                         {
 944                                                 if(client.classname != "spectator" && client.classname != "observer")
 945                                                 {
 946                                                         self = client;
 947                                                         PutObserverInServer();
 948
 949                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 950                                                 }
 951                                                 else
 952                                                 {
 953                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
 954                                                 }
 955                                                 continue;
 956                                         }
 957                                         else
 958                                         {
 959                                                 if(client.classname != "spectator" && client.classname != "observer")
 960                                                 {
 961                                                         if(teamplay)
 962                                                         {
 963                                                                 // set up
 964                                                                 float team_color;
 965                                                                 float save = client.team_forced;
 966                                                                 client.team_forced = 0;
 967
 968                                                                 // find the team to move the player to
 969                                                                 team_color = Team_ColorToNumber(destination);
 970                                                                 if(team_color == client.team) // already on the destination team
 971                                                                 {
 972                                                                         // keep the forcing undone
 973                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", ColoredTeamName(client.team), (targets ? ", skipping to next player.\n" : ".\n"));
 974                                                                         continue;
 975                                                                 }
 976                                                                 else if(team_color == 0)  // auto team
 977                                                                 {
 978                                                                         team_color = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
 979                                                                 }
 980                                                                 else
 981                                                                 {
 982                                                                         CheckAllowedTeams(client);
 983                                                                 }
 984                                                                 client.team_forced = save;
 985
 986                                                                 // Check to see if the destination team is even available
 987                                                                 switch(team_color)
 988                                                                 {
 989                                                                         case FL_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
 990                                                                         case FL_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
 991                                                                         case FL_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
 992                                                                         case FL_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
 993
 994                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
 995                                                                 }
 996
 997                                                                 // If so, lets continue and finally move the player
 998                                                                 client.team_forced = 0;
 999                                                                 MoveToTeam(client, team_color, 6, stof(notify));
1000                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1001                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", ColoredTeamName(team_color), ".\n");
1002                                                                 continue;
1003                                                         }
1004                                                         else
1005                                                         {
1006                                                                 print("Can't change teams when currently not playing a team game.\n");
1007                                                                 return;
1008                                                         }
1009                                                 }
1010                                                 else
1011                                                 {
1012                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1013                                                         return;
1014                                                 }
1015                                         }
1016                                 }
1017
1018                                 if(successful)
1019                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1020                                 else
1021                                         print("No players given (", original_targets, ") are able to move.\n");
1022
1023                                 return; // still correct parameters so return to avoid usage print
1024                         }
1025                 }
1026
1027                 default:
1028                         print("Incorrect parameters for ^2moveplayer^7\n");
1029                 case CMD_REQUEST_USAGE:
1030                 {
1031                         print("\nUsage:^3 sv_cmd moveplayer clients destination [notify]\n");
1032                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1033                         print("  'destination' is what to send the player to, be it team or spectating\n");
1034                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1035                         print("  'notify' is whether or not to send messages notifying of the move. Detail below.\n");
1036                         print("    0 (00) automove centerprint, admin message; 1 (01) automove centerprint, no admin message\n");
1037                         print("    2 (10) no centerprint, admin message; 3 (11) no centerprint, no admin message\n");
1038                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1039                         print("          sv_cmd moveplayer 2 spec \n");
1040                         print("See also: ^2allspec, shuffleteams^7\n");
1041                         return;
1042                 }
1043         }
1044 }
1045
1046 void GameCommand_nospectators(float request)
1047 {
1048         switch(request)
1049         {
1050                 case CMD_REQUEST_COMMAND:
1051                 {
1052                         blockSpectators = 1;
1053                         entity plr;
1054                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1055                         {
1056                                 if(plr.classname == "spectator" || plr.classname == "observer")
1057                                 {
1058                                         plr.spectatortime = time;
1059                                         sprint(plr, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1060                                 }
1061                         }
1062                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1063                         return;
1064                 }
1065
1066                 default:
1067                 case CMD_REQUEST_USAGE:
1068                 {
1069                         print("\nUsage:^3 sv_cmd nospectators\n");
1070                         print("  No arguments required.\n");
1071                         return;
1072                 }
1073         }
1074 }
1075
1076 void GameCommand_playerdemo(float request, float argc)
1077 {
1078         switch(request)
1079         {
1080                 case CMD_REQUEST_COMMAND:
1081                 {
1082                         if(argv(2) && argv(3))
1083                         {
1084                                 entity client;
1085                                 float i, n, accepted;
1086
1087                                 switch(argv(1))
1088                                 {
1089                                         case "read":
1090                                         {
1091                                                 client = GetIndexedEntity(argc, 2);
1092                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1093
1094                                                 if not(accepted > 0)
1095                                                 {
1096                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1097                                                         return;
1098                                                 }
1099
1100                                                 self = client;
1101                                                 playerdemo_open_read(argv(next_token));
1102                                                 return;
1103                                         }
1104
1105                                         case "write":
1106                                         {
1107                                                 client = GetIndexedEntity(argc, 2);
1108                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1109
1110                                                 if not(accepted > 0)
1111                                                 {
1112                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1113                                                         return;
1114                                                 }
1115
1116                                                 self = client;
1117                                                 playerdemo_open_write(argv(next_token));
1118                                                 return;
1119                                         }
1120
1121                                         case "auto_read_and_write":
1122                                         {
1123                                                 n = GetFilteredNumber(argv(3));
1124                                                 cvar_set("bot_number", ftos(n));
1125
1126                                                 localcmd("wait; wait; wait\n");
1127                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1128
1129                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1130                                                 return;
1131                                         }
1132
1133                                         case "auto_read":
1134                                         {
1135                                                 n = GetFilteredNumber(argv(3));
1136                                                 cvar_set("bot_number", ftos(n));
1137
1138                                                 localcmd("wait; wait; wait\n");
1139                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1140                                                 return;
1141                                         }
1142                                 }
1143                         }
1144                 }
1145
1146                 default:
1147                         print("Incorrect parameters for ^2playerdemo^7\n");
1148                 case CMD_REQUEST_USAGE:
1149                 {
1150                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1151                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1152                         return;
1153                 }
1154         }
1155 }
1156
1157 void GameCommand_printstats(float request)
1158 {
1159         switch(request)
1160         {
1161                 case CMD_REQUEST_COMMAND:
1162                 {
1163                         DumpStats(FALSE);
1164                         print("stats dumped.\n");
1165                         return;
1166                 }
1167
1168                 default:
1169                 case CMD_REQUEST_USAGE:
1170                 {
1171                         print("\nUsage:^3 sv_cmd printstats\n");
1172                         print("  No arguments required.\n");
1173                         return;
1174                 }
1175         }
1176 }
1177
1178 void GameCommand_radarmap(float request, float argc)
1179 {
1180         switch(request)
1181         {
1182                 case CMD_REQUEST_COMMAND:
1183                 {
1184                         if(RadarMap_Make(argc))
1185                                 return;
1186                 }
1187
1188                 default:
1189                         print("Incorrect parameters for ^2radarmap^7\n");
1190                 case CMD_REQUEST_USAGE:
1191                 {
1192                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1193                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1194                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1195                         print("See also: ^2make_mapinfo^7\n");
1196                         return;
1197                 }
1198         }
1199 }
1200
1201 void GameCommand_reducematchtime(float request)
1202 {
1203         switch(request)
1204         {
1205                 case CMD_REQUEST_COMMAND:
1206                 {
1207                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1208                         return;
1209                 }
1210
1211                 default:
1212                 case CMD_REQUEST_USAGE:
1213                 {
1214                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1215                         print("  No arguments required.\n");
1216                         print("See also: ^2extendmatchtime^7\n");
1217                         return;
1218                 }
1219         }
1220 }
1221
1222 void GameCommand_setbots(float request, float argc)
1223 {
1224         switch(request)
1225         {
1226                 case CMD_REQUEST_COMMAND:
1227                 {
1228                         if(argc >= 2)
1229                         {
1230                                 cvar_settemp("minplayers", "0");
1231                                 cvar_settemp("bot_number", argv(1));
1232                                 bot_fixcount();
1233                                 return;
1234                         }
1235                 }
1236
1237                 default:
1238                         print("Incorrect parameters for ^2setbots^7\n");
1239                 case CMD_REQUEST_USAGE:
1240                 {
1241                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1242                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1243                         print("See also: ^2bot_cmd^7\n");
1244                         return;
1245                 }
1246         }
1247 }
1248
1249 void GameCommand_shuffleteams(float request)
1250 {
1251         switch(request)
1252         {
1253                 case CMD_REQUEST_COMMAND:
1254                 {
1255                         if(teamplay)
1256                         {
1257                                 entity tmp_player;
1258                                 float i, x, z, t_teams, t_players, team_color;
1259
1260                                 // count the total amount of players and total amount of teams
1261                                 t_players = 0;
1262                                 t_teams = 0;
1263                                 FOR_EACH_PLAYER(tmp_player)
1264                                 {
1265                                         CheckAllowedTeams(tmp_player);
1266
1267                                         if(c1 >= 0) t_teams = max(1, t_teams);
1268                                         if(c2 >= 0) t_teams = max(2, t_teams);
1269                                         if(c3 >= 0) t_teams = max(3, t_teams);
1270                                         if(c4 >= 0) t_teams = max(4, t_teams);
1271
1272                                         ++t_players;
1273                                 }
1274
1275                                 // build a list of the players in a random order
1276                                 FOR_EACH_PLAYER(tmp_player)
1277                                 {
1278                                         for(;;)
1279                                         {
1280                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1281
1282                                                 if(shuffleteams_players[i])
1283                                                 {
1284                                                         continue; // a player is already assigned to this slot
1285                                                 }
1286                                                 else
1287                                                 {
1288                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1289                                                         break;
1290                                                 }
1291                                         }
1292                                 }
1293
1294                                 // finally, from the list made earlier, re-join the players in different order.
1295                                 for(i = 1; i <= t_teams; ++i)
1296                                 {
1297                                         // find out how many players to assign to this team
1298                                         x = (t_players / t_teams);
1299                                         x = ((i == 1) ? ceil(x) : floor(x));
1300
1301                                         team_color = Team_NumberToTeam(i);
1302
1303                                         // sort through the random list of players made earlier
1304                                         for(z = 1; z <= maxclients; ++z)
1305                                         {
1306                                                 if not(shuffleteams_teams[i] >= x)
1307                                                 {
1308                                                         if not(shuffleteams_players[z])
1309                                                                 continue; // not a player, move on to next random slot
1310
1311                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1312                                                                 self = edict_num(shuffleteams_players[z]);
1313
1314                                                         if(self.team != team_color)
1315                                                                 MoveToTeam(self, team_color, 6, 0);
1316
1317                                                         shuffleteams_players[z] = 0;
1318                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1319                                                 }
1320                                                 else
1321                                                 {
1322                                                         break; // move on to next team
1323                                                 }
1324                                         }
1325                                 }
1326
1327                                 bprint("Successfully shuffled the players around randomly.\n");
1328
1329                                 // clear the buffers now
1330                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1331                                         shuffleteams_players[i] = 0;
1332
1333                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1334                                         shuffleteams_teams[i] = 0;
1335                         }
1336                         else
1337                         {
1338                                 print("Can't shuffle teams when currently not playing a team game.\n");
1339                         }
1340
1341                         return;
1342                 }
1343
1344                 default:
1345                 case CMD_REQUEST_USAGE:
1346                 {
1347                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1348                         print("  No arguments required.\n");
1349                         print("See also: ^2moveplayer, allspec^7\n");
1350                         return;
1351                 }
1352         }
1353 }
1354
1355 void GameCommand_stuffto(float request, float argc)
1356 {
1357         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1358         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1359         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1360
1361         #ifdef STUFFTO_ENABLED
1362         switch(request)
1363         {
1364                 case CMD_REQUEST_COMMAND:
1365                 {
1366                         if(argv(2))
1367                         {
1368                                 entity client = GetIndexedEntity(argc, 1);
1369                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1370
1371                                 if(accepted > 0)
1372                                 {
1373                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1374                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1375                                 }
1376                                 else
1377                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1378
1379                                 return;
1380                         }
1381                 }
1382
1383                 default:
1384                         print("Incorrect parameters for ^2stuffto^7\n");
1385                 case CMD_REQUEST_USAGE:
1386                 {
1387                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1388                         print("  'client' is the entity number or name of the player,\n");
1389                         print("  and 'command' is the command to be sent to that player.\n");
1390                         return;
1391                 }
1392         }
1393         #else
1394         if(request)
1395         {
1396                 print("stuffto command is not enabled on this server.\n");
1397                 return;
1398         }
1399         #endif
1400 }
1401
1402 void GameCommand_trace(float request, float argc)
1403 {
1404         switch(request)
1405         {
1406                 case CMD_REQUEST_COMMAND:
1407                 {
1408                         entity e;
1409                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1410                         float i, f, safe, unsafe, dq, dqf;
1411
1412                         switch(argv(1))
1413                         {
1414                                 case "debug":
1415                                 {
1416                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1417                                         for(;;)
1418                                         {
1419                                                 org = world.mins;
1420                                                 delta = world.maxs - world.mins;
1421
1422                                                 start_x = org_x + random() * delta_x;
1423                                                 start_y = org_y + random() * delta_y;
1424                                                 start_z = org_z + random() * delta_z;
1425
1426                                                 end_x = org_x + random() * delta_x;
1427                                                 end_y = org_y + random() * delta_y;
1428                                                 end_z = org_z + random() * delta_z;
1429
1430                                                 start = stov(vtos(start));
1431                                                 end = stov(vtos(end));
1432
1433                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1434                                                 if(!trace_startsolid)
1435                                                 {
1436                                                         p = trace_endpos;
1437                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1438                                                         if(trace_startsolid || trace_fraction == 1)
1439                                                         {
1440                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1441                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1442
1443                                                                 if(trace_startsolid)
1444                                                                 {
1445                                                                         // how much do we need to back off?
1446                                                                         safe = 1;
1447                                                                         unsafe = 0;
1448                                                                         for(;;)
1449                                                                         {
1450                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1451                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1452                                                                                 if(trace_startsolid)
1453                                                                                 {
1454                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1455                                                                                                 break;
1456                                                                                         unsafe = (safe + unsafe) * 0.5;
1457                                                                                 }
1458                                                                                 else
1459                                                                                 {
1460                                                                                         if((safe + unsafe) * 0.5 == safe)
1461                                                                                                 break;
1462                                                                                         safe = (safe + unsafe) * 0.5;
1463                                                                                 }
1464                                                                         }
1465
1466                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1467                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1468
1469                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1470                                                                         if(trace_startsolid)
1471                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1472                                                                         else
1473                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1474                                                                         break;
1475                                                                 }
1476
1477                                                                 q0 = p;
1478                                                                 dq = 0;
1479                                                                 dqf = 1;
1480                                                                 for(;;)
1481                                                                 {
1482                                                                         q = p + normalize(end - p) * (dq + dqf);
1483                                                                         if(q == q0)
1484                                                                                 break;
1485                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1486                                                                         if(trace_startsolid)
1487                                                                                 error("THIS ONE cannot happen");
1488                                                                         if(trace_fraction > 0)
1489                                                                                 dq += dqf * trace_fraction;
1490                                                                         dqf *= 0.5;
1491                                                                         q0 = q;
1492                                                                 }
1493                                                                 if(dq > 0)
1494                                                                 {
1495                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1496                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1497                                                                         break;
1498                                                                 }
1499                                                         }
1500                                                 }
1501                                         }
1502                                         return;
1503                                 }
1504
1505                                 case "debug2":
1506                                 {
1507                                         e = nextent(world);
1508                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1509                                         vv = trace_endpos;
1510                                         if(trace_fraction == 1)
1511                                         {
1512                                                 print("not above ground, aborting\n");
1513                                                 return;
1514                                         }
1515                                         f = 0;
1516                                         for(i = 0; i < 100000; ++i)
1517                                         {
1518                                                 dv = randomvec();
1519                                                 if(dv_z > 0)
1520                                                         dv = -1 * dv;
1521                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1522                                                 if(trace_startsolid)
1523                                                         print("bug 1\n");
1524                                                 if(trace_fraction == 1)
1525                                                 if(dv_z < f)
1526                                                 {
1527                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1528                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1529                                                         f = dv_z;
1530                                                 }
1531                                         }
1532                                         print("highest possible dist: ", ftos(f), "\n");
1533                                         return;
1534                                 }
1535
1536                                 case "walk":
1537                                 {
1538                                         if(argc == 3)
1539                                         {
1540                                                 e = nextent(world);
1541                                                 if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
1542                                                         print("can walk\n");
1543                                                 else
1544                                                         print("cannot walk\n");
1545                                                 return;
1546                                         }
1547                                 }
1548
1549                                 case "showline":
1550                                 {
1551                                         if(argc == 3)
1552                                         {
1553                                                 vv = stov(argv(1));
1554                                                 dv = stov(argv(2));
1555                                                 traceline(vv, dv, MOVE_NORMAL, world);
1556                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1557                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1558                                                 return;
1559                                         }
1560                                 }
1561
1562                                 // no default case, just go straight to invalid
1563                         }
1564                 }
1565
1566                 default:
1567                         print("Incorrect parameters for ^2trace^7\n");
1568                 case CMD_REQUEST_USAGE:
1569                 {
1570                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1571                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1572                         print("See also: ^2bbox, gettaginfo^7\n");
1573                         return;
1574                 }
1575         }
1576 }
1577
1578 void GameCommand_unlockteams(float request)
1579 {
1580         switch(request)
1581         {
1582                 case CMD_REQUEST_COMMAND:
1583                 {
1584                         if(teamplay)
1585                         {
1586                                 lockteams = 0;
1587                                 bprint("^1The teams are now unlocked.\n");
1588                         }
1589                         else
1590                         {
1591                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1592                         }
1593                         return;
1594                 }
1595
1596                 default:
1597                 case CMD_REQUEST_USAGE:
1598                 {
1599                         print("\nUsage:^3 sv_cmd unlockteams\n");
1600                         print("  No arguments required.\n");
1601                         print("See also: ^2lockteams^7\n");
1602                         return;
1603                 }
1604         }
1605 }
1606
1607 void GameCommand_warp(float request, float argc)
1608 {
1609         switch (request)
1610         {
1611                 case CMD_REQUEST_COMMAND:
1612                 {
1613                         if(autocvar_g_campaign)
1614                         {
1615                                 if(argc >= 2)
1616                                 {
1617                                         CampaignLevelWarp(stof(argv(1)));
1618                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1619                                 }
1620                                 else
1621                                 {
1622                                         CampaignLevelWarp(-1);
1623                                         print("Successfully warped to next campaign level.\n");
1624                                 }
1625                         }
1626                         else
1627                                 print("Not in campaign, can't level warp\n");
1628                         return;
1629                 }
1630
1631                 default:
1632                 case CMD_REQUEST_USAGE:
1633                 {
1634                         print("\nUsage:^3 sv_cmd level\n");
1635                         print("  'level' is the level to change campaign mode to.\n");
1636                         return;
1637                 }
1638         }
1639 }
1640
1641 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1642 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1643 void GameCommand_(float request)
1644 {
1645         switch(request)
1646         {
1647                 case CMD_REQUEST_COMMAND:
1648                 {
1649
1650                         return;
1651                 }
1652
1653                 default:
1654                 case CMD_REQUEST_USAGE:
1655                 {
1656                         print("\nUsage:^3 sv_cmd \n");
1657                         print("  No arguments required.\n");
1658                         return;
1659                 }
1660         }
1661 }
1662 */
1663
1664
1665 // ==================================
1666 //  Macro system for server commands
1667 // ==================================
1668
1669 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1670 // Common commands have double indentation to separate them a bit.
1671 #define SERVER_COMMANDS(request,arguments,command) \
1672         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1673         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1674         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1675         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1676         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1677         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1678         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1679         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1680         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1681         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1682         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1683         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1684         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1685         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1686         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1687         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1688         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1689         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1690         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1691         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1692         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1693         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1694         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1695         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1696         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1697         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1698         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1699         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1700         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1701         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1702         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1703         /* nothing */
1704
1705 void GameCommand_macro_help()
1706 {
1707         #define SERVER_COMMAND(name,function,description) \
1708                 { print("  ^2", name, "^7: ", description, "\n"); }
1709
1710         SERVER_COMMANDS(0, 0, "")
1711         #undef SERVER_COMMAND
1712
1713         return;
1714 }
1715
1716 float GameCommand_macro_command(float argc, string command)
1717 {
1718         #define SERVER_COMMAND(name,function,description) \
1719                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1720
1721         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1722         #undef SERVER_COMMAND
1723
1724         return FALSE;
1725 }
1726
1727 float GameCommand_macro_usage(float argc)
1728 {
1729         #define SERVER_COMMAND(name,function,description) \
1730                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1731
1732         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1733         #undef SERVER_COMMAND
1734
1735         return FALSE;
1736 }
1737
1738 void GameCommand_macro_write_aliases(float fh)
1739 {
1740         #define SERVER_COMMAND(name,function,description) \
1741                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1742
1743         SERVER_COMMANDS(0, 0, "")
1744         #undef SERVER_COMMAND
1745
1746         return;
1747 }
1748
1749
1750 // =========================================
1751 //  Main Function Called By Engine (sv_cmd)
1752 // =========================================
1753 // If this function exists, game code handles gamecommand instead of the engine code.
1754
1755 void GameCommand(string command)
1756 {
1757         float argc = tokenize_console(command);
1758
1759         // Guide for working with argc arguments by example:
1760         // argc:   1    - 2      - 3     - 4
1761         // argv:   0    - 1      - 2     - 3
1762         // cmd     vote - master - login - password
1763
1764         if(strtolower(argv(0)) == "help")
1765         {
1766                 if(argc == 1)
1767                 {
1768                         print("\nServer console commands:\n");
1769                         GameCommand_macro_help();
1770
1771                         print("\nBanning commands:\n");
1772                         BanCommand_macro_help();
1773
1774                         print("\nCommon networked commands:\n");
1775                         CommonCommand_macro_help(world);
1776
1777                         print("\nGeneric commands shared by all programs:\n");
1778                         GenericCommand_macro_help();
1779
1780                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1781                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1782
1783                         return;
1784                 }
1785                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1786                 {
1787                         return;
1788                 }
1789                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1790                 {
1791                         return;
1792                 }
1793                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1794                 {
1795                         return;
1796                 }
1797                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1798                 {
1799                         return;
1800                 }
1801         }
1802         else if(BanCommand(command))
1803         {
1804                 return; // handled by server/command/ipban.qc
1805         }
1806         else if(CommonCommand_macro_command(argc, world, command))
1807         {
1808                 return; // handled by server/command/common.qc
1809         }
1810         else if(GenericCommand(command))
1811         {
1812                 return; // handled by common/command/generic.qc
1813         }
1814         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1815         {
1816                 return; // handled by one of the above GameCommand_* functions
1817         }
1818
1819         // nothing above caught the command, must be invalid
1820         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1821
1822         return;
1823 }