qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../g_world.qh"
  17 #include "../ipban.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/api.qh"
  21
  22 #include <server/mutators/_mod.qh>
  23 #include <common/gamemodes/_mod.qh>
  24
  25 #include <common/constants.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/mapinfo.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/teams.qh>
  30 #include <common/util.qh>
  31
  32 #include <common/monsters/sv_monsters.qh>
  33
  34 //  used by GameCommand_make_mapinfo()
  35 void make_mapinfo_Think(entity this)
  36 {
  37         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  38         {
  39                 LOG_INFO("Done rebuiling mapinfos.");
  40                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  41                 delete(this);
  42         }
  43         else
  44         {
  45                 setthink(this, make_mapinfo_Think);
  46                 this.nextthink = time;
  47         }
  48 }
  49
  50 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  51 void changematchtime(float delta, float mi, float ma)
  52 {
  53         float cur;
  54         float update;
  55         float lim;
  56
  57         if (delta == 0) return;
  58         if (autocvar_timelimit < 0) return;
  59
  60         if (mi <= 10) mi = 10;  // at least ten sec in the future
  61         cur = time - game_starttime;
  62         if (cur > 0) mi += cur; // from current time!
  63
  64         lim = autocvar_timelimit * 60;
  65
  66         if (delta > 0)
  67         {
  68                 if (lim == 0) return; // cannot increase any further
  69                 else if (lim < ma) update = min(ma, lim + delta);
  70                 else                  // already above maximum: FAIL
  71                         return;
  72         }
  73         else
  74         {
  75                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  76                         update = max(mi, ma);
  77                 else if (lim > mi) // above minimum: decrease
  78                         update = max(mi, lim + delta);
  79                 else               // already below minimum: FAIL
  80                         return;
  81         }
  82
  83         cvar_set("timelimit", ftos(update / 60));
  84 }
  85
  86
  87 // =======================
  88 //  Command Sub-Functions
  89 // =======================
  90
  91 void GameCommand_adminmsg(int request, int argc)
  92 {
  93         switch (request)
  94         {
  95                 case CMD_REQUEST_COMMAND:
  96                 {
  97                         entity client;
  98                         float accepted;
  99
 100                         string targets = strreplace(",", " ", argv(1));
 101                         string original_targets = strreplace(" ", ", ", targets);
 102                         string admin_message = argv(2);
 103                         float infobartime = stof(argv(3));
 104
 105                         string successful, t;
 106                         successful = string_null;
 107
 108                         if ((targets) && (admin_message))
 109                         {
 110                                 for ( ; targets; )
 111                                 {
 112                                         t = car(targets);
 113                                         targets = cdr(targets);
 114
 115                                         // Check to see if the player is a valid target
 116                                         client = GetFilteredEntity(t);
 117                                         accepted = VerifyClientEntity(client, true, false);
 118
 119                                         if (accepted <= 0)
 120                                         {
 121                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 122                                                 continue;
 123                                         }
 124
 125                                         // send the centerprint/console print or infomessage
 126                                         if (infobartime)
 127                                         {
 128                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 129                                         }
 130                                         else
 131                                         {
 132                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 133                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 134                                         }
 135
 136                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 137                                         LOG_TRACE("Message sent to ", playername(client, false));
 138                                         continue;
 139                                 }
 140
 141                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 142                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 143
 144                                 return;
 145                         }
 146                 }
 147
 148                 default:
 149                         LOG_INFO("Incorrect parameters for ^2adminmsg^7");
 150                 case CMD_REQUEST_USAGE:
 151                 {
 152                         LOG_INFO("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 153                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 154                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.");
 155                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.");
 156                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 157                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"");
 158                         return;
 159                 }
 160         }
 161 }
 162
 163 void GameCommand_allready(int request)
 164 {
 165         switch (request)
 166         {
 167                 case CMD_REQUEST_COMMAND:
 168                 {
 169                         ReadyRestart();
 170                         return;
 171                 }
 172
 173                 default:
 174                 case CMD_REQUEST_USAGE:
 175                 {
 176                         LOG_INFO("Usage:^3 sv_cmd allready");
 177                         LOG_INFO("  No arguments required.");
 178                         return;
 179                 }
 180         }
 181 }
 182
 183 void GameCommand_allspec(int request, int argc)
 184 {
 185         switch (request)
 186         {
 187                 case CMD_REQUEST_COMMAND:
 188                 {
 189                         string reason = argv(1);
 190                         int n = 0;
 191                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 192                                 if (it.caplayer) it.caplayer = 0;
 193                                 PutObserverInServer(it);
 194                                 ++n;
 195                         });
 196                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 197                         else   LOG_INFO("No players found to spectate.");
 198                         return;
 199                 }
 200
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         LOG_INFO("Usage:^3 sv_cmd allspec [reason]");
 205                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.");
 206                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7");
 207                         return;
 208                 }
 209         }
 210 }
 211
 212 void GameCommand_anticheat(int request, int argc)
 213 {
 214         switch (request)
 215         {
 216                 case CMD_REQUEST_COMMAND:
 217                 {
 218                         entity client = GetIndexedEntity(argc, 1);
 219                         float accepted = VerifyClientEntity(client, false, false);
 220
 221                         if (accepted > 0)
 222                         {
 223                                 anticheat_report_to_eventlog(client);
 224                                 return;
 225                         }
 226                         else
 227                         {
 228                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 229                         }
 230                 }
 231
 232                 default:
 233                         LOG_INFO("Incorrect parameters for ^2anticheat^7");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         LOG_INFO("Usage:^3 sv_cmd anticheat client");
 237                         LOG_INFO("  'client' is the entity number or name of the player.");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void GameCommand_bbox(int request)
 244 {
 245         switch (request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         vector size_min = '0 0 0';
 250                         vector size_max = '0 0 0';
 251                         tracebox('1 0 0' * world.absmin.x,
 252                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 253                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 254                                 '1 0 0' * world.absmax.x,
 255                                 MOVE_WORLDONLY,
 256                                 NULL);
 257                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 258
 259                         tracebox('0 1 0' * world.absmin.y,
 260                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 261                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 262                                 '0 1 0' * world.absmax.y,
 263                                 MOVE_WORLDONLY,
 264                                 NULL);
 265                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 266
 267                         tracebox('0 0 1' * world.absmin.z,
 268                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 269                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 270                                 '0 0 1' * world.absmax.z,
 271                                 MOVE_WORLDONLY,
 272                                 NULL);
 273                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 274
 275                         tracebox('1 0 0' * world.absmax.x,
 276                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 277                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 278                                 '1 0 0' * world.absmin.x,
 279                                 MOVE_WORLDONLY,
 280                                 NULL);
 281                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 282
 283                         tracebox('0 1 0' * world.absmax.y,
 284                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 285                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 286                                 '0 1 0' * world.absmin.y,
 287                                 MOVE_WORLDONLY,
 288                                 NULL);
 289                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 290
 291                         tracebox('0 0 1' * world.absmax.z,
 292                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 293                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 294                                 '0 0 1' * world.absmin.z,
 295                                 MOVE_WORLDONLY,
 296                                 NULL);
 297                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 298
 299                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 300                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 301                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 302                         return;
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         LOG_INFO("Usage:^3 sv_cmd bbox");
 309                         LOG_INFO("  No arguments required.");
 310                         LOG_INFO("See also: ^2gettaginfo, trace^7");
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 void GameCommand_bot_cmd(int request, int argc, string command)
 317 {
 318         switch (request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         entity bot;
 323
 324                         if (argv(1) == "reset")
 325                         {
 326                                 bot_resetqueues();
 327                                 return;
 328                         }
 329                         else if (argv(1) == "setbots")
 330                         {
 331                                 cvar_settemp("bot_vs_human", "0");
 332                                 cvar_settemp("minplayers", "0");
 333                                 cvar_settemp("bot_number", "0");
 334                                 bot_fixcount();
 335                                 cvar_settemp("bot_number", argv(2));
 336                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 337                                 return;
 338                         }
 339                         else if (argv(1) == "load" && argc == 3)
 340                         {
 341                                 float fh, i;
 342                                 string s;
 343                                 fh = fopen(argv(2), FILE_READ);
 344                                 if (fh < 0)
 345                                 {
 346                                         LOG_INFO("cannot open the file");
 347                                         return;
 348                                 }
 349
 350                                 i = 0;
 351                                 while ((s = fgets(fh)))
 352                                 {
 353                                         argc = tokenize_console(s);
 354
 355                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 356                                         {
 357                                                 if (argv(2) == "reset")
 358                                                 {
 359                                                         bot_resetqueues();
 360                                                 }
 361                                                 else if (argv(2) == "setbots")
 362                                                 {
 363                                                         cvar_settemp("bot_vs_human", "0");
 364                                                         cvar_settemp("minplayers", "0");
 365                                                         cvar_settemp("bot_number", "0");
 366                                                         bot_fixcount();
 367                                                         cvar_settemp("bot_number", argv(3));
 368                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 369                                                 }
 370                                                 else
 371                                                 {
 372                                                         if(argv(2) == "*" || argv(2) == "all")
 373                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 374                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 375                                                                 });
 376                                                         else
 377                                                         {
 378                                                                 bot = find_bot_by_number(stof(argv(2)));
 379                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 380                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 381                                                         }
 382                                                 }
 383                                         }
 384                                         else
 385                                         {
 386                                                 localcmd(strcat(s, "\n"));
 387                                         }
 388
 389                                         ++i;
 390                                 }
 391                                 LOG_INFO(ftos(i), " commands read");
 392                                 fclose(fh);
 393                                 return;
 394                         }
 395                         else if (argv(1) == "help")
 396                         {
 397                                 if (argv(2)) bot_cmdhelp(argv(2));
 398                                 else bot_list_commands();
 399                                 return;
 400                         }
 401                         else if (argc >= 3)  // this comes last
 402                         {
 403                                 if(argv(1) == "*" || argv(1) == "all")
 404                                 {
 405                                         int bot_num = 0;
 406                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 407                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 408                                                 bot_num++;
 409                                         });
 410                                         if(bot_num)
 411                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 412                                         return;
 413                                 }
 414                                 else
 415                                 {
 416                                         bot = find_bot_by_number(stof(argv(1)));
 417                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 418                                         if (bot)
 419                                         {
 420                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 421                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 422                                                 return;
 423                                         }
 424                                         else
 425                                         {
 426                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 427                                         }
 428                                 }
 429                         }
 430                 }
 431
 432                 default:
 433                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7");
 434                 case CMD_REQUEST_USAGE:
 435                 {
 436                         LOG_INFO("Usage:^3 sv_cmd bot_cmd client command [argument]");
 437                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 438                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots");
 439                         LOG_INFO("  For full list of commands, see bot_cmd help [command].");
 440                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 441                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump");
 442                         LOG_INFO("          sv_cmd bot_cmd * pause");
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 void GameCommand_cointoss(int request, int argc)
 449 {
 450         switch (request)
 451         {
 452                 case CMD_REQUEST_COMMAND:
 453                 {
 454                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 455                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 456                         string choice = ((random() > 0.5) ? result1 : result2);
 457
 458                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 459                         return;
 460                 }
 461
 462                 default:
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         LOG_INFO("Usage:^3 sv_cmd cointoss [result1 result2]");
 466                         LOG_INFO("  Where 'result1' and 'result2' are user created options.");
 467                         return;
 468                 }
 469         }
 470 }
 471
 472 void GameCommand_database(int request, int argc)
 473 {
 474         switch (request)
 475         {
 476                 case CMD_REQUEST_COMMAND:
 477                 {
 478                         if (argc == 3)
 479                         {
 480                                 if (argv(1) == "save")
 481                                 {
 482                                         db_save(ServerProgsDB, argv(2));
 483                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 484                                         return;
 485                                 }
 486                                 else if (argv(1) == "dump")
 487                                 {
 488                                         db_dump(ServerProgsDB, argv(2));
 489                                         LOG_INFO("DB dumped.");  // wtf does this do?
 490                                         return;
 491                                 }
 492                                 else if (argv(1) == "load")
 493                                 {
 494                                         db_close(ServerProgsDB);
 495                                         ServerProgsDB = db_load(argv(2));
 496                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 497                                         return;
 498                                 }
 499                         }
 500                 }
 501
 502                 default:
 503                         LOG_INFO("Incorrect parameters for ^2database^7");
 504                 case CMD_REQUEST_USAGE:
 505                 {
 506                         LOG_INFO("Usage:^3 sv_cmd database action filename");
 507                         LOG_INFO("  Where 'action' is the command to complete,");
 508                         LOG_INFO("  and 'filename' is what it acts upon.");
 509                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"");
 510                         return;
 511                 }
 512         }
 513 }
 514
 515 void GameCommand_defer_clear(int request, int argc)
 516 {
 517         switch (request)
 518         {
 519                 case CMD_REQUEST_COMMAND:
 520                 {
 521                         entity client;
 522                         float accepted;
 523
 524                         if (argc >= 2)
 525                         {
 526                                 client = GetIndexedEntity(argc, 1);
 527                                 accepted = VerifyClientEntity(client, true, false);
 528
 529                                 if (accepted > 0)
 530                                 {
 531                                         stuffcmd(client, "defer clear\n");
 532                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 533                                 }
 534                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 535
 536                                 return;
 537                         }
 538                 }
 539
 540                 default:
 541                         LOG_INFO("Incorrect parameters for ^2defer_clear^7");
 542                 case CMD_REQUEST_USAGE:
 543                 {
 544                         LOG_INFO("Usage:^3 sv_cmd defer_clear client");
 545                         LOG_INFO("  'client' is the entity number or name of the player.");
 546                         LOG_INFO("See also: ^2defer_clear_all^7");
 547                         return;
 548                 }
 549         }
 550 }
 551
 552 void GameCommand_defer_clear_all(int request)
 553 {
 554         switch (request)
 555         {
 556                 case CMD_REQUEST_COMMAND:
 557                 {
 558                         int n = 0;
 559                         int argc;
 560
 561                         FOREACH_CLIENT(true, {
 562                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 563                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 564                                 ++n;
 565                         });
 566                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 567                         return;
 568                 }
 569
 570                 default:
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         LOG_INFO("Usage:^3 sv_cmd defer_clear_all");
 574                         LOG_INFO("  No arguments required.");
 575                         LOG_INFO("See also: ^2defer_clear^7");
 576                         return;
 577                 }
 578         }
 579 }
 580
 581 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 582 {
 583         switch (request)
 584         {
 585                 case CMD_REQUEST_COMMAND:
 586                 {
 587                         if (argv(1))
 588                         {
 589                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 590                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 591                                 return;
 592                         }
 593                 }
 594
 595                 default:
 596                         LOG_INFO("Incorrect parameters for ^2delrec^7");
 597                 case CMD_REQUEST_USAGE:
 598                 {
 599                         LOG_INFO("Usage:^3 sv_cmd delrec ranking [map]");
 600                         LOG_INFO("  'ranking' is which ranking level to clear up to, ");
 601                         LOG_INFO("  it will clear all records up to nth place.");
 602                         LOG_INFO("  if 'map' is not provided it will use current map.");
 603                         return;
 604                 }
 605         }
 606 }
 607
 608 void print_Effect_Index(int d, string effect_name)
 609 {
 610         // this is inside a function to avoid expanding it on compilation everytime
 611         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 612         db_put(d, effect_name, "1");
 613 }
 614
 615 void GameCommand_effectindexdump(int request)
 616 {
 617         switch (request)
 618         {
 619                 case CMD_REQUEST_COMMAND:
 620                 {
 621                         float fh, d;
 622                         string s;
 623
 624                         d = db_create();
 625                         LOG_INFO("begin of effects list");
 626
 627                         print_Effect_Index(d, "TE_GUNSHOT");
 628                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 629                         print_Effect_Index(d, "TE_SPIKE");
 630                         print_Effect_Index(d, "TE_SPIKEQUAD");
 631                         print_Effect_Index(d, "TE_SUPERSPIKE");
 632                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 633                         print_Effect_Index(d, "TE_WIZSPIKE");
 634                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 635                         print_Effect_Index(d, "TE_EXPLOSION");
 636                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 637                         print_Effect_Index(d, "TE_TAREXPLOSION");
 638                         print_Effect_Index(d, "TE_TELEPORT");
 639                         print_Effect_Index(d, "TE_LAVASPLASH");
 640                         print_Effect_Index(d, "TE_SMALLFLASH");
 641                         print_Effect_Index(d, "TE_FLAMEJET");
 642                         print_Effect_Index(d, "EF_FLAME");
 643                         print_Effect_Index(d, "TE_BLOOD");
 644                         print_Effect_Index(d, "TE_SPARK");
 645                         print_Effect_Index(d, "TE_PLASMABURN");
 646                         print_Effect_Index(d, "TE_TEI_G3");
 647                         print_Effect_Index(d, "TE_TEI_SMOKE");
 648                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 649                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 650                         print_Effect_Index(d, "EF_STARDUST");
 651                         print_Effect_Index(d, "TR_ROCKET");
 652                         print_Effect_Index(d, "TR_GRENADE");
 653                         print_Effect_Index(d, "TR_BLOOD");
 654                         print_Effect_Index(d, "TR_WIZSPIKE");
 655                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 656                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 657                         print_Effect_Index(d, "TR_VORESPIKE");
 658                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 659                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 660                         print_Effect_Index(d, "TR_GLOWTRAIL");
 661                         print_Effect_Index(d, "TR_SEEKER");
 662                         print_Effect_Index(d, "SVC_PARTICLE");
 663
 664                         fh = fopen("effectinfo.txt", FILE_READ);
 665                         while ((s = fgets(fh)))
 666                         {
 667                                 tokenize_console(s);
 668                                 if (argv(0) == "effect")
 669                                 {
 670                                         if (db_get(d, argv(1)) != "1")
 671                                         {
 672                                                 int i = _particleeffectnum(argv(1));
 673                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 674                                                 db_put(d, argv(1), "1");
 675                                         }
 676                                 }
 677                         }
 678                         LOG_INFO("end of effects list");
 679
 680                         db_close(d);
 681                         return;
 682                 }
 683
 684                 default:
 685                 case CMD_REQUEST_USAGE:
 686                 {
 687                         LOG_INFO("Usage:^3 sv_cmd effectindexdump");
 688                         LOG_INFO("  No arguments required.");
 689                         return;
 690                 }
 691         }
 692 }
 693
 694 void GameCommand_extendmatchtime(int request)
 695 {
 696         switch (request)
 697         {
 698                 case CMD_REQUEST_COMMAND:
 699                 {
 700                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 701                         return;
 702                 }
 703
 704                 default:
 705                 case CMD_REQUEST_USAGE:
 706                 {
 707                         LOG_INFO("Usage:^3 sv_cmd extendmatchtime");
 708                         LOG_INFO("  No arguments required.");
 709                         LOG_INFO("See also: ^2reducematchtime^7");
 710                         return;
 711                 }
 712         }
 713 }
 714
 715 void GameCommand_gametype(int request, int argc)
 716 {
 717         switch (request)
 718         {
 719                 case CMD_REQUEST_COMMAND:
 720                 {
 721                         if (argv(1) != "")
 722                         {
 723                                 string s = argv(1);
 724                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 725
 726                                 if (t)
 727                                 {
 728                                         MapInfo_SwitchGameType(t);
 729                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 730                                         if (MapInfo_count > 0)
 731                                         {
 732                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 733                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 734                                                 lsmaps_reply = strzone(getlsmaps());
 735                                                 bprint("Game type successfully switched to ", s, "\n");
 736                                         }
 737                                         else
 738                                         {
 739                                                 bprint("Cannot use this game type: no map for it found\n");
 740                                                 MapInfo_SwitchGameType(tsave);
 741                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 742                                         }
 743                                 }
 744                                 else
 745                                 {
 746                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 747                                 }
 748
 749                                 return;
 750                         }
 751                 }
 752
 753                 default:
 754                         LOG_INFO("Incorrect parameters for ^2gametype^7");
 755                 case CMD_REQUEST_USAGE:
 756                 {
 757                         LOG_INFO("Usage:^3 sv_cmd gametype mode");
 758                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.");
 759                         LOG_INFO("See also: ^2gotomap^7");
 760                         return;
 761                 }
 762         }
 763 }
 764
 765 void GameCommand_gettaginfo(int request, int argc)
 766 {
 767         switch (request)
 768         {
 769                 case CMD_REQUEST_COMMAND:
 770                 {
 771                         entity tmp_entity;
 772                         float i;
 773                         vector v;
 774
 775                         if (argc >= 4)
 776                         {
 777                                 tmp_entity = spawn();
 778                                 if (argv(1) == "w")
 779                                 {
 780                                         .entity weaponentity = weaponentities[0];
 781                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 782                                 }
 783                                 else
 784                                 {
 785                                         precache_model(argv(1));
 786                                         _setmodel(tmp_entity, argv(1));
 787                                 }
 788                                 tmp_entity.frame = stof(argv(2));
 789                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 790                                 else i = gettagindex(tmp_entity, argv(3));
 791                                 if (i)
 792                                 {
 793                                         v = gettaginfo(tmp_entity, i);
 794                                         LOG_INFOF(
 795                                             "model %s frame %s tag %s index %s parent %s",
 796                                             tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 797                                         );
 798                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 799                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 800                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 801                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 802                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 803                                         if (argc >= 6)
 804                                         {
 805                                                 v.y = -v.y;
 806                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 807                                         }
 808                                 }
 809                                 else
 810                                 {
 811                                         LOG_INFO("bone not found");
 812                                 }
 813
 814                                 delete(tmp_entity);
 815                                 return;
 816                         }
 817                 }
 818
 819                 default:
 820                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 821                 case CMD_REQUEST_USAGE:
 822                 {
 823                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 824                         LOG_INFO("See also: ^2bbox, trace^7");
 825                         return;
 826                 }
 827         }
 828 }
 829
 830 void GameCommand_animbench(int request, int argc)
 831 {
 832         switch (request)
 833         {
 834                 case CMD_REQUEST_COMMAND:
 835                 {
 836                         entity tmp_entity;
 837
 838                         if (argc >= 4)
 839                         {
 840                                 tmp_entity = spawn();
 841                                 if (argv(1) == "w")
 842                                 {
 843                                         .entity weaponentity = weaponentities[0];
 844                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 845                                 }
 846                                 else
 847                                 {
 848                                         precache_model(argv(1));
 849                                         _setmodel(tmp_entity, argv(1));
 850                                 }
 851                                 float f1 = stof(argv(2));
 852                                 float f2 = stof(argv(3));
 853                                 float t0;
 854                                 float t1 = 0;
 855                                 float t2 = 0;
 856                                 float n = 0;
 857
 858                                 while (t1 + t2 < 1)
 859                                 {
 860                                         tmp_entity.frame = f1;
 861                                         t0 = gettime(GETTIME_HIRES);
 862                                         getsurfacepoint(tmp_entity, 0, 0);
 863                                         t1 += gettime(GETTIME_HIRES) - t0;
 864                                         tmp_entity.frame = f2;
 865                                         t0 = gettime(GETTIME_HIRES);
 866                                         getsurfacepoint(tmp_entity, 0, 0);
 867                                         t2 += gettime(GETTIME_HIRES) - t0;
 868                                         n += 1;
 869                                 }
 870                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 871                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 872
 873                                 delete(tmp_entity);
 874                                 return;
 875                         }
 876                 }
 877
 878                 default:
 879                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 880                 case CMD_REQUEST_USAGE:
 881                 {
 882                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 883                         LOG_INFO("See also: ^2bbox, trace^7");
 884                         return;
 885                 }
 886         }
 887 }
 888
 889 void GameCommand_gotomap(int request, int argc)
 890 {
 891         switch (request)
 892         {
 893                 case CMD_REQUEST_COMMAND:
 894                 {
 895                         if (argv(1))
 896                         {
 897                                 LOG_INFO(GotoMap(argv(1)));
 898                                 return;
 899                         }
 900                 }
 901
 902                 default:
 903                         LOG_INFO("Incorrect parameters for ^2gotomap^7");
 904                 case CMD_REQUEST_USAGE:
 905                 {
 906                         LOG_INFO("Usage:^3 sv_cmd gotomap map");
 907                         LOG_INFO("  Where 'map' is the *.bsp file to change to.");
 908                         LOG_INFO("See also: ^2gametype^7");
 909                         return;
 910                 }
 911         }
 912 }
 913
 914 void GameCommand_lockteams(int request)
 915 {
 916         switch (request)
 917         {
 918                 case CMD_REQUEST_COMMAND:
 919                 {
 920                         if (teamplay)
 921                         {
 922                                 lockteams = 1;
 923                                 bprint("^1The teams are now locked.\n");
 924                         }
 925                         else
 926                         {
 927                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 928                         }
 929                         return;
 930                 }
 931
 932                 default:
 933                 case CMD_REQUEST_USAGE:
 934                 {
 935                         LOG_INFO("Usage:^3 sv_cmd lockteams");
 936                         LOG_INFO("  No arguments required.");
 937                         LOG_INFO("See also: ^2unlockteams^7");
 938                         return;
 939                 }
 940         }
 941 }
 942
 943 void GameCommand_make_mapinfo(int request)
 944 {
 945         switch (request)
 946         {
 947                 case CMD_REQUEST_COMMAND:
 948                 {
 949                         entity tmp_entity;
 950
 951                         tmp_entity = new(make_mapinfo);
 952                         setthink(tmp_entity, make_mapinfo_Think);
 953                         tmp_entity.nextthink = time;
 954                         MapInfo_Enumerate();
 955                         return;
 956                 }
 957
 958                 default:
 959                 case CMD_REQUEST_USAGE:
 960                 {
 961                         LOG_INFO("Usage:^3 sv_cmd make_mapinfo");
 962                         LOG_INFO("  No arguments required.");
 963                         LOG_INFO("See also: ^2radarmap^7");
 964                         return;
 965                 }
 966         }
 967 }
 968
 969 void GameCommand_moveplayer(int request, int argc)
 970 {
 971         switch (request)
 972         {
 973                 case CMD_REQUEST_COMMAND:
 974                 {
 975                         float accepted;
 976                         entity client;
 977
 978                         string targets = strreplace(",", " ", argv(1));
 979                         string original_targets = strreplace(" ", ", ", targets);
 980                         string destination = argv(2);
 981
 982                         string successful, t;
 983                         successful = string_null;
 984
 985                         // lets see if the target(s) even actually exist.
 986                         if ((targets) && (destination))
 987                         {
 988                                 for ( ; targets; )
 989                                 {
 990                                         t = car(targets);
 991                                         targets = cdr(targets);
 992
 993                                         // Check to see if the player is a valid target
 994                                         client = GetFilteredEntity(t);
 995                                         accepted = VerifyClientEntity(client, false, false);
 996
 997                                         if (accepted <= 0)
 998                                         {
 999                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1000                                                 continue;
1001                                         }
1002
1003                                         // Where are we putting this player?
1004                                         if (destination == "spec" || destination == "spectator")
1005                                         {
1006                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1007                                                 {
1008                                                         if (client.caplayer) client.caplayer = 0;
1009                                                         PutObserverInServer(client);
1010
1011                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1012                                                 }
1013                                                 else
1014                                                 {
1015                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1016                                                 }
1017                                                 continue;
1018                                         }
1019                                         else
1020                                         {
1021                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1022                                                 {
1023                                                         if (teamplay)
1024                                                         {
1025                                                                 // set up
1026                                                                 float team_id;
1027                                                                 int save = Player_GetForcedTeamIndex(client);
1028                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1029
1030                                                                 // find the team to move the player to
1031                                                                 team_id = Team_ColorToTeam(destination);
1032                                                                 entity balance;
1033                                                                 if (team_id == client.team)  // already on the destination team
1034                                                                 {
1035                                                                         // keep the forcing undone
1036                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1037                                                                         continue;
1038                                                                 }
1039                                                                 else if (team_id == 0)  // auto team
1040                                                                 {
1041                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1042                                                                         team_id = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1043                                                                 }
1044                                                                 else
1045                                                                 {
1046                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1047                                                                 }
1048                                                                 Player_SetForcedTeamIndex(client, save);
1049
1050                                                                 // Check to see if the destination team is even available
1051                                                                 switch (team_id)
1052                                                                 {
1053                                                                         case NUM_TEAM_1:
1054                                                                         {
1055                                                                                 if (!TeamBalance_IsTeamAllowed(balance, 1))
1056                                                                                 {
1057                                                                                         LOG_INFO("Sorry, can't move player to red team if it doesn't exist.");
1058                                                                                         TeamBalance_Destroy(balance);
1059                                                                                         return;
1060                                                                                 }
1061                                                                                 TeamBalance_Destroy(balance);
1062                                                                                 break;
1063                                                                         }
1064                                                                         case NUM_TEAM_2:
1065                                                                         {
1066                                                                                 if (!TeamBalance_IsTeamAllowed(balance, 2))
1067                                                                                 {
1068                                                                                         LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.");
1069                                                                                         TeamBalance_Destroy(balance);
1070                                                                                         return;
1071                                                                                 }
1072                                                                                 TeamBalance_Destroy(balance);
1073                                                                                 break;
1074                                                                         }
1075                                                                         case NUM_TEAM_3:
1076                                                                         {
1077                                                                                 if (!TeamBalance_IsTeamAllowed(balance, 3))
1078                                                                                 {
1079                                                                                         LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.");
1080                                                                                         TeamBalance_Destroy(balance);
1081                                                                                         return;
1082                                                                                 }
1083                                                                                 TeamBalance_Destroy(balance);
1084                                                                                 break;
1085                                                                         }
1086                                                                         case NUM_TEAM_4:
1087                                                                         {
1088                                                                                 if (!TeamBalance_IsTeamAllowed(balance, 4))
1089                                                                                 {
1090                                                                                         LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.");
1091                                                                                         TeamBalance_Destroy(balance);
1092                                                                                         return;
1093                                                                                 }
1094                                                                                 TeamBalance_Destroy(balance);
1095                                                                                 break;
1096                                                                         }
1097                                                                         default:
1098                                                                         {
1099                                                                                 LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1100                                                                                 return;
1101                                                                         }
1102                                                                 }
1103
1104                                                                 // If so, lets continue and finally move the player
1105                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1106                                                                 if (MoveToTeam(client, Team_TeamToIndex(team_id), 6))
1107                                                                 {
1108                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1109                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1110                                                                 }
1111                                                                 else
1112                                                                 {
1113                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1114                                                                 }
1115                                                                 continue;
1116                                                         }
1117                                                         else
1118                                                         {
1119                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1120                                                                 return;
1121                                                         }
1122                                                 }
1123                                                 else
1124                                                 {
1125                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1126                                                         return;
1127                                                 }
1128                                         }
1129                                 }
1130
1131                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1132                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1133
1134                                 return;  // still correct parameters so return to avoid usage print
1135                         }
1136                 }
1137
1138                 default:
1139                         LOG_INFO("Incorrect parameters for ^2moveplayer^7");
1140                 case CMD_REQUEST_USAGE:
1141                 {
1142                         LOG_INFO("Usage:^3 sv_cmd moveplayer clients destination");
1143                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1144                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating");
1145                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1146                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3");
1147                         LOG_INFO("          sv_cmd moveplayer 2 spec ");
1148                         LOG_INFO("See also: ^2allspec, shuffleteams^7");
1149                         return;
1150                 }
1151         }
1152 }
1153
1154 void GameCommand_nospectators(int request)
1155 {
1156         switch (request)
1157         {
1158                 case CMD_REQUEST_COMMAND:
1159                 {
1160                         blockSpectators = 1;
1161                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1162                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1163                                 if(!it.caplayer)
1164                                 {
1165                                         CS(it).spectatortime = time;
1166                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1167                                 }
1168                         });
1169                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1170                         return;
1171                 }
1172
1173                 default:
1174                 case CMD_REQUEST_USAGE:
1175                 {
1176                         LOG_INFO("Usage:^3 sv_cmd nospectators");
1177                         LOG_INFO("  No arguments required.");
1178                         return;
1179                 }
1180         }
1181 }
1182
1183 void GameCommand_printstats(int request)
1184 {
1185         switch (request)
1186         {
1187                 case CMD_REQUEST_COMMAND:
1188                 {
1189                         DumpStats(false);
1190                         LOG_INFO("stats dumped.");
1191                         return;
1192                 }
1193
1194                 default:
1195                 case CMD_REQUEST_USAGE:
1196                 {
1197                         LOG_INFO("Usage:^3 sv_cmd printstats");
1198                         LOG_INFO("  No arguments required.");
1199                         return;
1200                 }
1201         }
1202 }
1203
1204 void GameCommand_radarmap(int request, int argc)
1205 {
1206         switch (request)
1207         {
1208                 case CMD_REQUEST_COMMAND:
1209                 {
1210                         if (RadarMap_Make(argc)) return;
1211                 }
1212
1213                 default:
1214                         LOG_INFO("Incorrect parameters for ^2radarmap^7");
1215                 case CMD_REQUEST_USAGE:
1216                 {
1217                         LOG_INFO("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1218                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.");
1219                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1220                         LOG_INFO("See also: ^2make_mapinfo^7");
1221                         return;
1222                 }
1223         }
1224 }
1225
1226 void GameCommand_reducematchtime(int request)
1227 {
1228         switch (request)
1229         {
1230                 case CMD_REQUEST_COMMAND:
1231                 {
1232                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1233                         return;
1234                 }
1235
1236                 default:
1237                 case CMD_REQUEST_USAGE:
1238                 {
1239                         LOG_INFO("Usage:^3 sv_cmd reducematchtime");
1240                         LOG_INFO("  No arguments required.");
1241                         LOG_INFO("See also: ^2extendmatchtime^7");
1242                         return;
1243                 }
1244         }
1245 }
1246
1247 void GameCommand_setbots(int request, int argc)
1248 {
1249         switch (request)
1250         {
1251                 case CMD_REQUEST_COMMAND:
1252                 {
1253                         if (argc >= 2)
1254                         {
1255                                 cvar_settemp("minplayers", "0");
1256                                 cvar_settemp("bot_number", argv(1));
1257                                 bot_fixcount();
1258                                 return;
1259                         }
1260                 }
1261
1262                 default:
1263                         LOG_INFO("Incorrect parameters for ^2setbots^7");
1264                 case CMD_REQUEST_USAGE:
1265                 {
1266                         LOG_INFO("Usage:^3 sv_cmd setbots botnumber");
1267                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1268                         LOG_INFO("See also: ^2bot_cmd^7");
1269                         return;
1270                 }
1271         }
1272 }
1273
1274 void GameCommand_shuffleteams(int request)
1275 {
1276         switch (request)
1277         {
1278                 case CMD_REQUEST_COMMAND:
1279                 {
1280                         if (!teamplay)
1281                         {
1282                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1283                                 return;
1284                         }
1285
1286                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1287                                 if (Player_HasRealForcedTeam(it)) {
1288                                         // we could theoretically assign forced players to their teams
1289                                         // and shuffle the rest to fill the empty spots but in practise
1290                                         // either all players or none are gonna have forced teams
1291                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1292                                         return;
1293                                 }
1294                         });
1295
1296                         int number_of_teams = 0;
1297                         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1298                         for (int i = 1; i <= NUM_TEAMS; ++i)
1299                         {
1300                                 if (TeamBalance_IsTeamAllowed(balance, i))
1301                                 {
1302                                         number_of_teams = max(i, number_of_teams);
1303                                 }
1304                         }
1305                         TeamBalance_Destroy(balance);
1306
1307                         int team_index = 0;
1308                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1309                                 int target_team_index = team_index + 1;
1310                                 if (Entity_GetTeamIndex(it) != target_team_index)
1311                                 {
1312                                         MoveToTeam(it, target_team_index, 6);
1313                                 }
1314                                 team_index = (team_index + 1) % number_of_teams;
1315                         });
1316
1317                         bprint("Successfully shuffled the players around randomly.\n");
1318                         return;
1319                 }
1320
1321                 default:
1322                 case CMD_REQUEST_USAGE:
1323                 {
1324                         LOG_INFO("Usage:^3 sv_cmd shuffleteams");
1325                         LOG_INFO("  No arguments required.");
1326                         LOG_INFO("See also: ^2moveplayer, allspec^7");
1327                         return;
1328                 }
1329         }
1330 }
1331
1332 void GameCommand_stuffto(int request, int argc)
1333 {
1334         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1335         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1336         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1337
1338 #ifdef STUFFTO_ENABLED
1339                 switch (request)
1340                 {
1341                         case CMD_REQUEST_COMMAND:
1342                         {
1343                                 if (argv(2))
1344                                 {
1345                                         entity client = GetIndexedEntity(argc, 1);
1346                                         float accepted = VerifyClientEntity(client, true, false);
1347
1348                                         if (accepted > 0)
1349                                         {
1350                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1351                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1352                                         }
1353                                         else
1354                                         {
1355                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1356                                         }
1357
1358                                         return;
1359                                 }
1360                         }
1361
1362                         default:
1363                                 LOG_INFO("Incorrect parameters for ^2stuffto^7");
1364                         case CMD_REQUEST_USAGE:
1365                         {
1366                                 LOG_INFO("Usage:^3 sv_cmd stuffto client \"command\"");
1367                                 LOG_INFO("  'client' is the entity number or name of the player,");
1368                                 LOG_INFO("  and 'command' is the command to be sent to that player.");
1369                                 return;
1370                         }
1371                 }
1372 #else
1373                 if (request)
1374                 {
1375                         LOG_INFO("stuffto command is not enabled on this server.");
1376                         return;
1377                 }
1378 #endif
1379 }
1380
1381 void GameCommand_trace(int request, int argc)
1382 {
1383         switch (request)
1384         {
1385                 case CMD_REQUEST_COMMAND:
1386                 {
1387                         entity e;
1388                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1389                         float i, f, safe, unsafe, dq, dqf;
1390
1391                         switch (argv(1))
1392                         {
1393                                 case "debug":
1394                                 {
1395                                         float hitcount = 0;
1396                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1397                                         float worst_endpos_bug = 0;
1398                                         for ( ; ; )
1399                                         {
1400                                                 org = world.mins;
1401                                                 delta = world.maxs - world.mins;
1402
1403                                                 start.x = org.x + random() * delta.x;
1404                                                 start.y = org.y + random() * delta.y;
1405                                                 start.z = org.z + random() * delta.z;
1406
1407                                                 end.x = org.x + random() * delta.x;
1408                                                 end.y = org.y + random() * delta.y;
1409                                                 end.z = org.z + random() * delta.z;
1410
1411                                                 start = stov(vtos(start));
1412                                                 end = stov(vtos(end));
1413
1414                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1415                                                 if (!trace_startsolid && trace_fraction < 1)
1416                                                 {
1417                                                         p = trace_endpos;
1418                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1419                                                         if (trace_startsolid)
1420                                                         {
1421                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1422                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1423
1424                                                                 // how much do we need to back off?
1425                                                                 safe = 1;
1426                                                                 unsafe = 0;
1427                                                                 for ( ; ; )
1428                                                                 {
1429                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1430                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1431                                                                         if (trace_startsolid)
1432                                                                         {
1433                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1434                                                                                 unsafe = (safe + unsafe) * 0.5;
1435                                                                         }
1436                                                                         else
1437                                                                         {
1438                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1439                                                                                 safe = (safe + unsafe) * 0.5;
1440                                                                         }
1441                                                                 }
1442
1443                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1444                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1445
1446                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1447                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1448                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1449                                                                 if (++hitcount >= 10) break;
1450                                                         }
1451                                                         else
1452                                                         {
1453                                                                 q0 = p;
1454                                                                 dq = 0;
1455                                                                 dqf = 1;
1456                                                                 for ( ; ; )
1457                                                                 {
1458                                                                         q = p + normalize(end - p) * (dq + dqf);
1459                                                                         if (q == q0) break;
1460                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1461                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1462                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1463                                                                         dqf *= 0.5;
1464                                                                         q0 = q;
1465                                                                 }
1466                                                                 if (dq > worst_endpos_bug)
1467                                                                 {
1468                                                                         worst_endpos_bug = dq;
1469                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1470                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1471                                                                         if (++hitcount >= 10) break;
1472                                                                 }
1473                                                         }
1474                                                 }
1475                                         }
1476                                         return;
1477                                 }
1478
1479                                 case "debug2":
1480                                 {
1481                                         e = nextent(NULL);
1482                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1483                                         vv = trace_endpos;
1484                                         if (trace_fraction == 1)
1485                                         {
1486                                                 LOG_INFO("not above ground, aborting");
1487                                                 return;
1488                                         }
1489                                         f = 0;
1490                                         for (i = 0; i < 100000; ++i)
1491                                         {
1492                                                 dv = randomvec();
1493                                                 if (dv.z > 0) dv = -1 * dv;
1494                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1495                                                 if (trace_startsolid) LOG_INFO("bug 1");
1496                                                 if (trace_fraction == 1)
1497                                                 {
1498                                                         if (dv.z < f)
1499                                                         {
1500                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1501                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1502                                                                 f = dv.z;
1503                                                         }
1504                                                 }
1505                                         }
1506                                         LOG_INFO("highest possible dist: ", ftos(f));
1507                                         return;
1508                                 }
1509
1510                                 case "walk":
1511                                 {
1512                                         if (argc == 4 || argc == 5)
1513                                         {
1514                                                 e = nextent(NULL);
1515                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1516                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1517                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1518                                                         LOG_INFO("can walk");
1519                                                 else
1520                                                         LOG_INFO("cannot walk");
1521                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1522                                                 return;
1523                                         }
1524                                 }
1525
1526                                 case "showline":
1527                                 {
1528                                         if (argc == 4)
1529                                         {
1530                                                 vv = stov(argv(2));
1531                                                 dv = stov(argv(3));
1532                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1533                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1534                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1535                                                 return;
1536                                         }
1537                                 }
1538
1539                                         // no default case, just go straight to invalid
1540                         }
1541                 }
1542
1543                 default:
1544                         LOG_INFO("Incorrect parameters for ^2trace^7");
1545                 case CMD_REQUEST_USAGE:
1546                 {
1547                         LOG_INFO("Usage:^3 sv_cmd trace command [startpos endpos] [endpos_height]");
1548                         LOG_INFO("  Where startpos and endpos are parameters for 'walk' and 'showline' commands,");
1549                         LOG_INFO("  'endpos_height' is an optional parameter for 'walk' command,");
1550                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1551                         LOG_INFO("See also: ^2bbox, gettaginfo^7");
1552                         return;
1553                 }
1554         }
1555 }
1556
1557 void GameCommand_unlockteams(int request)
1558 {
1559         switch (request)
1560         {
1561                 case CMD_REQUEST_COMMAND:
1562                 {
1563                         if (teamplay)
1564                         {
1565                                 lockteams = 0;
1566                                 bprint("^1The teams are now unlocked.\n");
1567                         }
1568                         else
1569                         {
1570                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1571                         }
1572                         return;
1573                 }
1574
1575                 default:
1576                 case CMD_REQUEST_USAGE:
1577                 {
1578                         LOG_INFO("Usage:^3 sv_cmd unlockteams");
1579                         LOG_INFO("  No arguments required.");
1580                         LOG_INFO("See also: ^2lockteams^7");
1581                         return;
1582                 }
1583         }
1584 }
1585
1586 void GameCommand_warp(int request, int argc)
1587 {
1588         switch (request)
1589         {
1590                 case CMD_REQUEST_COMMAND:
1591                 {
1592                         if (autocvar_g_campaign)
1593                         {
1594                                 if (argc >= 2)
1595                                 {
1596                                         CampaignLevelWarp(stof(argv(1)));
1597                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1598                                 }
1599                                 else
1600                                 {
1601                                         CampaignLevelWarp(-1);
1602                                         LOG_INFO("Successfully warped to next campaign level.");
1603                                 }
1604                         }
1605                         else
1606                         {
1607                                 LOG_INFO("Not in campaign, can't level warp");
1608                         }
1609                         return;
1610                 }
1611
1612                 default:
1613                 case CMD_REQUEST_USAGE:
1614                 {
1615                         LOG_INFO("Usage:^3 sv_cmd warp [level]");
1616                         LOG_INFO("  'level' is the level to change campaign mode to.");
1617                         LOG_INFO("  if 'level' is not provided it will change to the next level.");
1618                         return;
1619                 }
1620         }
1621 }
1622
1623 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1624 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1625 void GameCommand_(int request)
1626 {
1627     switch(request)
1628     {
1629         case CMD_REQUEST_COMMAND:
1630         {
1631
1632             return;
1633         }
1634
1635         default:
1636         case CMD_REQUEST_USAGE:
1637         {
1638             print("\nUsage:^3 sv_cmd \n");
1639             print("  No arguments required.\n");
1640             return;
1641         }
1642     }
1643 }
1644 */
1645
1646
1647 // ==================================
1648 //  Macro system for server commands
1649 // ==================================
1650
1651 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1652 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1653 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1654 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1655 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1656 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1657 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1658 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1659 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1660 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1661 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1662 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1663 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1664 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1665 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1666 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1667 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1668 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1669 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1670 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1671 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1672 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1673 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1674 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1675 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1676 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1677 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1678 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1679 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1680 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1681 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1682
1683 void GameCommand_macro_help()
1684 {
1685         FOREACH(SERVER_COMMANDS, true, { LOG_INFOF("  ^2%s^7: %s", it.m_name, it.m_description); });
1686 }
1687
1688 float GameCommand_macro_command(int argc, string command)
1689 {
1690         string c = strtolower(argv(0));
1691         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1692                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1693                 return true;
1694         });
1695         return false;
1696 }
1697
1698 float GameCommand_macro_usage(int argc)
1699 {
1700         string c = strtolower(argv(1));
1701         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1702                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1703                 return true;
1704         });
1705         return false;
1706 }
1707
1708 void GameCommand_macro_write_aliases(float fh)
1709 {
1710         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1711 }
1712
1713
1714 // =========================================
1715 //  Main Function Called By Engine (sv_cmd)
1716 // =========================================
1717 // If this function exists, game code handles gamecommand instead of the engine code.
1718
1719 void GameCommand(string command)
1720 {
1721         int argc = tokenize_console(command);
1722
1723         // Guide for working with argc arguments by example:
1724         // argc:   1    - 2      - 3     - 4
1725         // argv:   0    - 1      - 2     - 3
1726         // cmd     vote - master - login - password
1727
1728         if (strtolower(argv(0)) == "help")
1729         {
1730                 if (argc == 1)
1731                 {
1732                         LOG_INFO("Server console commands:");
1733                         GameCommand_macro_help();
1734
1735                         LOG_INFO("\nBanning commands:");
1736                         BanCommand_macro_help();
1737
1738                         LOG_INFO("\nCommon networked commands:");
1739                         CommonCommand_macro_help(NULL);
1740
1741                         LOG_INFO("\nGeneric commands shared by all programs:");
1742                         GenericCommand_macro_help();
1743
1744                         LOG_INFO(
1745                             "\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1746                 "For help about a specific command, type sv_cmd help COMMAND"
1747             );
1748
1749                         return;
1750                 }
1751                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1752                 {
1753                         return;
1754                 }
1755                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1756                 {
1757                         return;
1758                 }
1759                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1760                 {
1761                         return;
1762                 }
1763                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1764                 {
1765                         return;
1766                 }
1767         }
1768         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1769         {
1770                 return;  // handled by a mutator
1771         }
1772         else if (BanCommand(command))
1773         {
1774                 return;  // handled by server/command/ipban.qc
1775         }
1776         else if (CommonCommand_macro_command(argc, NULL, command))
1777         {
1778                 return;  // handled by server/command/common.qc
1779         }
1780         else if (GenericCommand(command))
1781         {
1782                 return;                                        // handled by common/command/generic.qc
1783         }
1784         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1785         {
1786                 return;                                        // handled by one of the above GameCommand_* functions
1787         }
1788
1789         // nothing above caught the command, must be invalid
1790         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1791 }