qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include "banning.qh"
   5 #include "cmd.qh"
   6 #include "common.qh"
   7 #include "getreplies.qh"
   8 #include "radarmap.qh"
   9
  10 #include "../anticheat.qh"
  11 #include "../campaign.qh"
  12 #include "../client.qh"
  13 #include "../player.qh"
  14 #include "../g_world.qh"
  15 #include "../ipban.qh"
  16 #include "../playerdemo.qh"
  17 #include "../teamplay.qh"
  18
  19 #include "../bot/api.qh"
  20
  21 #include "../mutators/_mod.qh"
  22
  23 #include <common/constants.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/notifications/all.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29
  30 #include <common/monsters/sv_monsters.qh>
  31
  32
  33 void PutObserverInServer(entity this);
  34
  35 // =====================================================
  36 //  Server side game commands code, reworked by Samual
  37 // =====================================================
  38
  39 //  used by GameCommand_make_mapinfo()
  40 void make_mapinfo_Think(entity this)
  41 {
  42         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  43         {
  44                 LOG_INFO("Done rebuiling mapinfos.\n");
  45                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  46                 delete(this);
  47         }
  48         else
  49         {
  50                 setthink(this, make_mapinfo_Think);
  51                 this.nextthink = time;
  52         }
  53 }
  54
  55 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  56 void changematchtime(float delta, float mi, float ma)
  57 {
  58         float cur;
  59         float update;
  60         float lim;
  61
  62         if (delta == 0) return;
  63         if (autocvar_timelimit < 0) return;
  64
  65         if (mi <= 10) mi = 10;  // at least ten sec in the future
  66         cur = time - game_starttime;
  67         if (cur > 0) mi += cur; // from current time!
  68
  69         lim = autocvar_timelimit * 60;
  70
  71         if (delta > 0)
  72         {
  73                 if (lim == 0) return; // cannot increase any further
  74                 else if (lim < ma) update = min(ma, lim + delta);
  75                 else                  // already above maximum: FAIL
  76                         return;
  77         }
  78         else
  79         {
  80                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  81                         update = max(mi, ma);
  82                 else if (lim > mi) // above minimum: decrease
  83                         update = max(mi, lim + delta);
  84                 else               // already below minimum: FAIL
  85                         return;
  86         }
  87
  88         cvar_set("timelimit", ftos(update / 60));
  89 }
  90
  91
  92 // =======================
  93 //  Command Sub-Functions
  94 // =======================
  95
  96 void GameCommand_adminmsg(float request, float argc)
  97 {
  98         switch (request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         entity client;
 103                         float accepted;
 104
 105                         string targets = strreplace(",", " ", argv(1));
 106                         string original_targets = strreplace(" ", ", ", targets);
 107                         string admin_message = argv(2);
 108                         float infobartime = stof(argv(3));
 109
 110                         string successful, t;
 111                         successful = string_null;
 112
 113                         if ((targets) && (admin_message))
 114                         {
 115                                 for ( ; targets; )
 116                                 {
 117                                         t = car(targets);
 118                                         targets = cdr(targets);
 119
 120                                         // Check to see if the player is a valid target
 121                                         client = GetFilteredEntity(t);
 122                                         accepted = VerifyClientEntity(client, true, false);
 123
 124                                         if (accepted <= 0)
 125                                         {
 126                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 127                                                 continue;
 128                                         }
 129
 130                                         // send the centerprint/console print or infomessage
 131                                         if (infobartime)
 132                                         {
 133                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 134                                         }
 135                                         else
 136                                         {
 137                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 138                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 139                                         }
 140
 141                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 142                                         LOG_TRACE("Message sent to ", playername(client, false));
 143                                         continue;
 144                                 }
 145
 146                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 147                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.\n");
 148
 149                                 return;
 150                         }
 151                 }
 152
 153                 default:
 154                         LOG_INFO("Incorrect parameters for ^2adminmsg^7\n");
 155                 case CMD_REQUEST_USAGE:
 156                 {
 157                         LOG_INFO("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 158                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 159                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.\n");
 160                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.\n");
 161                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 162                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 void GameCommand_allready(float request)
 169 {
 170         switch (request)
 171         {
 172                 case CMD_REQUEST_COMMAND:
 173                 {
 174                         ReadyRestart();
 175                         return;
 176                 }
 177
 178                 default:
 179                 case CMD_REQUEST_USAGE:
 180                 {
 181                         LOG_INFO("\nUsage:^3 sv_cmd allready\n");
 182                         LOG_INFO("  No arguments required.\n");
 183                         return;
 184                 }
 185         }
 186 }
 187
 188 void GameCommand_allspec(float request, float argc)
 189 {
 190         switch (request)
 191         {
 192                 case CMD_REQUEST_COMMAND:
 193                 {
 194                         string reason = argv(1);
 195                         int n = 0;
 196                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 197                                 if (it.caplayer) it.caplayer = 0;
 198                                 PutObserverInServer(it);
 199                                 ++n;
 200                         ));
 201                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 202                         else   LOG_INFO("No players found to spectate.\n");
 203                         return;
 204                 }
 205
 206                 default:
 207                 case CMD_REQUEST_USAGE:
 208                 {
 209                         LOG_INFO("\nUsage:^3 sv_cmd allspec [reason]\n");
 210                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 211                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7\n");
 212                         return;
 213                 }
 214         }
 215 }
 216
 217 void GameCommand_anticheat(float request, float argc)
 218 {
 219         switch (request)
 220         {
 221                 case CMD_REQUEST_COMMAND:
 222                 {
 223                         entity client = GetIndexedEntity(argc, 1);
 224                         float accepted = VerifyClientEntity(client, false, false);
 225
 226                         if (accepted > 0)
 227                         {
 228                                 anticheat_report_to_eventlog(client);
 229                                 return;
 230                         }
 231                         else
 232                         {
 233                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 234                         }
 235                 }
 236
 237                 default:
 238                         LOG_INFO("Incorrect parameters for ^2anticheat^7\n");
 239                 case CMD_REQUEST_USAGE:
 240                 {
 241                         LOG_INFO("\nUsage:^3 sv_cmd anticheat client\n");
 242                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 243                         return;
 244                 }
 245         }
 246 }
 247
 248 void GameCommand_bbox(float request)
 249 {
 250         switch (request)
 251         {
 252                 case CMD_REQUEST_COMMAND:
 253                 {
 254                         LOG_INFO("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
 255                         LOG_INFO(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
 256                         LOG_INFO("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
 257                         LOG_INFO(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
 258                         LOG_INFO("Solid bounding box size:");
 259
 260                         tracebox('1 0 0' * world.absmin.x,
 261                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 262                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 263                                 '1 0 0' * world.absmax.x,
 264                                 MOVE_WORLDONLY,
 265                                 NULL);
 266                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.x));
 267                         else LOG_INFO(" ", ftos(trace_endpos.x));
 268
 269                         tracebox('0 1 0' * world.absmin.y,
 270                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 271                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 272                                 '0 1 0' * world.absmax.y,
 273                                 MOVE_WORLDONLY,
 274                                 NULL);
 275                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.y));
 276                         else LOG_INFO(" ", ftos(trace_endpos.y));
 277
 278                         tracebox('0 0 1' * world.absmin.z,
 279                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 280                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 281                                 '0 0 1' * world.absmax.z,
 282                                 MOVE_WORLDONLY,
 283                                 NULL);
 284                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.z));
 285                         else LOG_INFO(" ", ftos(trace_endpos.z));
 286
 287                         tracebox('1 0 0' * world.absmax.x,
 288                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 289                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 290                                 '1 0 0' * world.absmin.x,
 291                                 MOVE_WORLDONLY,
 292                                 NULL);
 293                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.x));
 294                         else LOG_INFO(" ", ftos(trace_endpos.x));
 295
 296                         tracebox('0 1 0' * world.absmax.y,
 297                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 298                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 299                                 '0 1 0' * world.absmin.y,
 300                                 MOVE_WORLDONLY,
 301                                 NULL);
 302                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.y));
 303                         else LOG_INFO(" ", ftos(trace_endpos.y));
 304
 305                         tracebox('0 0 1' * world.absmax.z,
 306                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 307                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 308                                 '0 0 1' * world.absmin.z,
 309                                 MOVE_WORLDONLY,
 310                                 NULL);
 311                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.z));
 312                         else LOG_INFO(" ", ftos(trace_endpos.z));
 313
 314                         LOG_INFO("\n");
 315                         return;
 316                 }
 317
 318                 default:
 319                 case CMD_REQUEST_USAGE:
 320                 {
 321                         LOG_INFO("\nUsage:^3 sv_cmd bbox\n");
 322                         LOG_INFO("  No arguments required.\n");
 323                         LOG_INFO("See also: ^2gettaginfo, trace^7\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void GameCommand_bot_cmd(float request, float argc, string command)
 330 {
 331         switch (request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         entity bot;
 336
 337                         if (argv(1) == "reset")
 338                         {
 339                                 bot_resetqueues();
 340                                 return;
 341                         }
 342                         else if (argv(1) == "setbots")
 343                         {
 344                                 cvar_settemp("bot_vs_human", "0");
 345                                 cvar_settemp("minplayers", "0");
 346                                 cvar_settemp("bot_number", "0");
 347                                 bot_fixcount();
 348                                 cvar_settemp("bot_number", argv(2));
 349                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
 350                                 return;
 351                         }
 352                         else if (argv(1) == "load" && argc == 3)
 353                         {
 354                                 float fh, i;
 355                                 string s;
 356                                 fh = fopen(argv(2), FILE_READ);
 357                                 if (fh < 0)
 358                                 {
 359                                         LOG_INFO("cannot open the file\n");
 360                                         return;
 361                                 }
 362
 363                                 i = 0;
 364                                 while ((s = fgets(fh)))
 365                                 {
 366                                         argc = tokenize_console(s);
 367
 368                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 369                                         {
 370                                                 if (argv(2) == "reset")
 371                                                 {
 372                                                         bot_resetqueues();
 373                                                 }
 374                                                 else if (argv(2) == "setbots")
 375                                                 {
 376                                                         cvar_settemp("bot_vs_human", "0");
 377                                                         cvar_settemp("minplayers", "0");
 378                                                         cvar_settemp("bot_number", "0");
 379                                                         bot_fixcount();
 380                                                         cvar_settemp("bot_number", argv(3));
 381                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
 382                                                 }
 383                                                 else
 384                                                 {
 385                                                         if(argv(2) == "*" || argv(2) == "all")
 386                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 387                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 388                                                                 });
 389                                                         else
 390                                                         {
 391                                                                 bot = find_bot_by_number(stof(argv(2)));
 392                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 393                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 394                                                         }
 395                                                 }
 396                                         }
 397                                         else
 398                                         {
 399                                                 localcmd(strcat(s, "\n"));
 400                                         }
 401
 402                                         ++i;
 403                                 }
 404                                 LOG_INFO(ftos(i), " commands read\n");
 405                                 fclose(fh);
 406                                 return;
 407                         }
 408                         else if (argv(1) == "help")
 409                         {
 410                                 if (argv(2)) bot_cmdhelp(argv(2));
 411                                 else bot_list_commands();
 412                                 return;
 413                         }
 414                         else if (argc >= 3)  // this comes last
 415                         {
 416                                 if(argv(1) == "*" || argv(1) == "all")
 417                                 {
 418                                         int bot_num = 0;
 419                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 420                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 421                                                 bot_num++;
 422                                         });
 423                                         if(bot_num)
 424                                                 LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")\n"));
 425                                         return;
 426                                 }
 427                                 else
 428                                 {
 429                                         bot = find_bot_by_number(stof(argv(1)));
 430                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 431                                         if (bot)
 432                                         {
 433                                                 LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 434                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 435                                                 return;
 436                                         }
 437                                         else
 438                                         {
 439                                                 LOG_INFO(strcat("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?\n"));  // don't return so that usage is shown
 440                                         }
 441                                 }
 442                         }
 443                 }
 444
 445                 default:
 446                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7\n");
 447                 case CMD_REQUEST_USAGE:
 448                 {
 449                         LOG_INFO("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 450                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)\n");
 451                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots\n");
 452                         LOG_INFO("  For full list of commands, see bot_cmd help [command].\n");
 453                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"\n");
 454                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump\n");
 455                         LOG_INFO("          sv_cmd bot_cmd * pause\n");
 456                         return;
 457                 }
 458         }
 459 }
 460
 461 void GameCommand_cointoss(float request, float argc)
 462 {
 463         switch (request)
 464         {
 465                 case CMD_REQUEST_COMMAND:
 466                 {
 467                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 468                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 469                         string choice = ((random() > 0.5) ? result1 : result2);
 470
 471                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 472                         return;
 473                 }
 474
 475                 default:
 476                 case CMD_REQUEST_USAGE:
 477                 {
 478                         LOG_INFO("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 479                         LOG_INFO("  Where 'result1' and 'result2' are user created options.\n");
 480                         return;
 481                 }
 482         }
 483 }
 484
 485 void GameCommand_database(float request, float argc)
 486 {
 487         switch (request)
 488         {
 489                 case CMD_REQUEST_COMMAND:
 490                 {
 491                         if (argc == 3)
 492                         {
 493                                 if (argv(1) == "save")
 494                                 {
 495                                         db_save(ServerProgsDB, argv(2));
 496                                         LOG_INFO(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 497                                         return;
 498                                 }
 499                                 else if (argv(1) == "dump")
 500                                 {
 501                                         db_dump(ServerProgsDB, argv(2));
 502                                         LOG_INFO("DB dumped.\n");  // wtf does this do?
 503                                         return;
 504                                 }
 505                                 else if (argv(1) == "load")
 506                                 {
 507                                         db_close(ServerProgsDB);
 508                                         ServerProgsDB = db_load(argv(2));
 509                                         LOG_INFO(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 510                                         return;
 511                                 }
 512                         }
 513                 }
 514
 515                 default:
 516                         LOG_INFO("Incorrect parameters for ^2database^7\n");
 517                 case CMD_REQUEST_USAGE:
 518                 {
 519                         LOG_INFO("\nUsage:^3 sv_cmd database action filename\n");
 520                         LOG_INFO("  Where 'action' is the command to complete,\n");
 521                         LOG_INFO("  and 'filename' is what it acts upon.\n");
 522                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"\n");
 523                         return;
 524                 }
 525         }
 526 }
 527
 528 void GameCommand_defer_clear(float request, float argc)
 529 {
 530         switch (request)
 531         {
 532                 case CMD_REQUEST_COMMAND:
 533                 {
 534                         entity client;
 535                         float accepted;
 536
 537                         if (argc >= 2)
 538                         {
 539                                 client = GetIndexedEntity(argc, 1);
 540                                 accepted = VerifyClientEntity(client, true, false);
 541
 542                                 if (accepted > 0)
 543                                 {
 544                                         stuffcmd(client, "defer clear\n");
 545                                         LOG_INFO("defer clear stuffed to ", playername(client, false), "\n");
 546                                 }
 547                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 548
 549                                 return;
 550                         }
 551                 }
 552
 553                 default:
 554                         LOG_INFO("Incorrect parameters for ^2defer_clear^7\n");
 555                 case CMD_REQUEST_USAGE:
 556                 {
 557                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear client\n");
 558                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 559                         LOG_INFO("See also: ^2defer_clear_all^7\n");
 560                         return;
 561                 }
 562         }
 563 }
 564
 565 void GameCommand_defer_clear_all(float request)
 566 {
 567         switch (request)
 568         {
 569                 case CMD_REQUEST_COMMAND:
 570                 {
 571                         int n = 0;
 572                         float argc;
 573
 574                         FOREACH_CLIENT(true, LAMBDA(
 575                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 576                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 577                                 ++n;
 578                         ));
 579                         if (n)   LOG_INFO(strcat("Successfully stuffed defer clear to all clients (", ftos(n), ")\n"));  // should a message be added if no players were found?
 580                         return;
 581                 }
 582
 583                 default:
 584                 case CMD_REQUEST_USAGE:
 585                 {
 586                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear_all\n");
 587                         LOG_INFO("  No arguments required.\n");
 588                         LOG_INFO("See also: ^2defer_clear^7\n");
 589                         return;
 590                 }
 591         }
 592 }
 593
 594 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 595 {
 596         switch (request)
 597         {
 598                 case CMD_REQUEST_COMMAND:
 599                 {
 600                         if (argv(1))
 601                         {
 602                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 603                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 604                                 return;
 605                         }
 606                 }
 607
 608                 default:
 609                         LOG_INFO("Incorrect parameters for ^2delrec^7\n");
 610                 case CMD_REQUEST_USAGE:
 611                 {
 612                         LOG_INFO("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 613                         LOG_INFO("  'ranking' is which ranking level to clear up to, \n");
 614                         LOG_INFO("  it will clear all records up to nth place.\n");
 615                         LOG_INFO("  if 'map' is not provided it will use current map.\n");
 616                         return;
 617                 }
 618         }
 619 }
 620
 621 void GameCommand_effectindexdump(float request)
 622 {
 623         switch (request)
 624         {
 625                 case CMD_REQUEST_COMMAND:
 626                 {
 627                         float fh, d;
 628                         string s;
 629
 630                         d = db_create();
 631                         LOG_INFO("begin of effects list\n");
 632                         db_put(d, "TE_GUNSHOT", "1");
 633                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")), "\n");
 634                         db_put(d, "TE_GUNSHOTQUAD", "1");
 635                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 636                         db_put(d, "TE_SPIKE", "1");
 637                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")), "\n");
 638                         db_put(d, "TE_SPIKEQUAD", "1");
 639                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")), "\n");
 640                         db_put(d, "TE_SUPERSPIKE", "1");
 641                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")), "\n");
 642                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 643                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 644                         db_put(d, "TE_WIZSPIKE", "1");
 645                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")), "\n");
 646                         db_put(d, "TE_KNIGHTSPIKE", "1");
 647                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 648                         db_put(d, "TE_EXPLOSION", "1");
 649                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")), "\n");
 650                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 651                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 652                         db_put(d, "TE_TAREXPLOSION", "1");
 653                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")), "\n");
 654                         db_put(d, "TE_TELEPORT", "1");
 655                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")), "\n");
 656                         db_put(d, "TE_LAVASPLASH", "1");
 657                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")), "\n");
 658                         db_put(d, "TE_SMALLFLASH", "1");
 659                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")), "\n");
 660                         db_put(d, "TE_FLAMEJET", "1");
 661                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")), "\n");
 662                         db_put(d, "EF_FLAME", "1");
 663                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")), "\n");
 664                         db_put(d, "TE_BLOOD", "1");
 665                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")), "\n");
 666                         db_put(d, "TE_SPARK", "1");
 667                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")), "\n");
 668                         db_put(d, "TE_PLASMABURN", "1");
 669                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")), "\n");
 670                         db_put(d, "TE_TEI_G3", "1");
 671                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")), "\n");
 672                         db_put(d, "TE_TEI_SMOKE", "1");
 673                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")), "\n");
 674                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 675                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 676                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 677                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 678                         db_put(d, "EF_STARDUST", "1");
 679                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")), "\n");
 680                         db_put(d, "TR_ROCKET", "1");
 681                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")), "\n");
 682                         db_put(d, "TR_GRENADE", "1");
 683                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")), "\n");
 684                         db_put(d, "TR_BLOOD", "1");
 685                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")), "\n");
 686                         db_put(d, "TR_WIZSPIKE", "1");
 687                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")), "\n");
 688                         db_put(d, "TR_SLIGHTBLOOD", "1");
 689                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 690                         db_put(d, "TR_KNIGHTSPIKE", "1");
 691                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 692                         db_put(d, "TR_VORESPIKE", "1");
 693                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")), "\n");
 694                         db_put(d, "TR_NEHAHRASMOKE", "1");
 695                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 696                         db_put(d, "TR_NEXUIZPLASMA", "1");
 697                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 698                         db_put(d, "TR_GLOWTRAIL", "1");
 699                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")), "\n");
 700                         db_put(d, "TR_SEEKER", "1");
 701                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")), "\n");
 702                         db_put(d, "SVC_PARTICLE", "1");
 703                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")), "\n");
 704
 705                         fh = fopen("effectinfo.txt", FILE_READ);
 706                         while ((s = fgets(fh)))
 707                         {
 708                                 tokenize_console(s);
 709                                 if (argv(0) == "effect")
 710                                 {
 711                                         if (db_get(d, argv(1)) != "1")
 712                                         {
 713                                                 int i = _particleeffectnum(argv(1));
 714                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i), "\n");
 715                                                 db_put(d, argv(1), "1");
 716                                         }
 717                                 }
 718                         }
 719                         LOG_INFO("end of effects list\n");
 720
 721                         db_close(d);
 722                         return;
 723                 }
 724
 725                 default:
 726                 case CMD_REQUEST_USAGE:
 727                 {
 728                         LOG_INFO("\nUsage:^3 sv_cmd effectindexdump\n");
 729                         LOG_INFO("  No arguments required.\n");
 730                         return;
 731                 }
 732         }
 733 }
 734
 735 void GameCommand_extendmatchtime(float request)
 736 {
 737         switch (request)
 738         {
 739                 case CMD_REQUEST_COMMAND:
 740                 {
 741                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 742                         return;
 743                 }
 744
 745                 default:
 746                 case CMD_REQUEST_USAGE:
 747                 {
 748                         LOG_INFO("\nUsage:^3 sv_cmd extendmatchtime\n");
 749                         LOG_INFO("  No arguments required.\n");
 750                         LOG_INFO("See also: ^2reducematchtime^7\n");
 751                         return;
 752                 }
 753         }
 754 }
 755
 756 void GameCommand_gametype(float request, float argc)
 757 {
 758         switch (request)
 759         {
 760                 case CMD_REQUEST_COMMAND:
 761                 {
 762                         if (argv(1) != "")
 763                         {
 764                                 string s = argv(1);
 765                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 766
 767                                 if (t)
 768                                 {
 769                                         MapInfo_SwitchGameType(t);
 770                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 771                                         if (MapInfo_count > 0)
 772                                         {
 773                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 774                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 775                                                 lsmaps_reply = strzone(getlsmaps());
 776                                                 bprint("Game type successfully switched to ", s, "\n");
 777                                         }
 778                                         else
 779                                         {
 780                                                 bprint("Cannot use this game type: no map for it found\n");
 781                                                 MapInfo_SwitchGameType(tsave);
 782                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 783                                         }
 784                                 }
 785                                 else
 786                                 {
 787                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 788                                 }
 789
 790                                 return;
 791                         }
 792                 }
 793
 794                 default:
 795                         LOG_INFO("Incorrect parameters for ^2gametype^7\n");
 796                 case CMD_REQUEST_USAGE:
 797                 {
 798                         LOG_INFO("\nUsage:^3 sv_cmd gametype mode\n");
 799                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.\n");
 800                         LOG_INFO("See also: ^2gotomap^7\n");
 801                         return;
 802                 }
 803         }
 804 }
 805
 806 void GameCommand_gettaginfo(float request, float argc)
 807 {
 808         switch (request)
 809         {
 810                 case CMD_REQUEST_COMMAND:
 811                 {
 812                         entity tmp_entity;
 813                         float i;
 814                         vector v;
 815
 816                         if (argc >= 4)
 817                         {
 818                                 tmp_entity = spawn();
 819                                 if (argv(1) == "w")
 820                                 {
 821                                         .entity weaponentity = weaponentities[0];
 822                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 823                                 }
 824                                 else
 825                                 {
 826                                         precache_model(argv(1));
 827                                         _setmodel(tmp_entity, argv(1));
 828                                 }
 829                                 tmp_entity.frame = stof(argv(2));
 830                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 831                                 else i = gettagindex(tmp_entity, argv(3));
 832                                 if (i)
 833                                 {
 834                                         v = gettaginfo(tmp_entity, i);
 835                                         LOG_INFO("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 836                                         LOG_INFO(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 837                                         LOG_INFO(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 838                                         LOG_INFO(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 839                                         LOG_INFO(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 840                                         LOG_INFO(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 841                                         LOG_INFO(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 842                                         if (argc >= 6)
 843                                         {
 844                                                 v.y = -v.y;
 845                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 846                                         }
 847                                 }
 848                                 else
 849                                 {
 850                                         LOG_INFO("bone not found\n");
 851                                 }
 852
 853                                 delete(tmp_entity);
 854                                 return;
 855                         }
 856                 }
 857
 858                 default:
 859                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 860                 case CMD_REQUEST_USAGE:
 861                 {
 862                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 863                         LOG_INFO("See also: ^2bbox, trace^7\n");
 864                         return;
 865                 }
 866         }
 867 }
 868
 869 void GameCommand_animbench(float request, float argc)
 870 {
 871         switch (request)
 872         {
 873                 case CMD_REQUEST_COMMAND:
 874                 {
 875                         entity tmp_entity;
 876
 877                         if (argc >= 4)
 878                         {
 879                                 tmp_entity = spawn();
 880                                 if (argv(1) == "w")
 881                                 {
 882                                         .entity weaponentity = weaponentities[0];
 883                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 884                                 }
 885                                 else
 886                                 {
 887                                         precache_model(argv(1));
 888                                         _setmodel(tmp_entity, argv(1));
 889                                 }
 890                                 float f1 = stof(argv(2));
 891                                 float f2 = stof(argv(3));
 892                                 float t0;
 893                                 float t1 = 0;
 894                                 float t2 = 0;
 895                                 float n = 0;
 896
 897                                 while (t1 + t2 < 1)
 898                                 {
 899                                         tmp_entity.frame = f1;
 900                                         t0 = gettime(GETTIME_HIRES);
 901                                         getsurfacepoint(tmp_entity, 0, 0);
 902                                         t1 += gettime(GETTIME_HIRES) - t0;
 903                                         tmp_entity.frame = f2;
 904                                         t0 = gettime(GETTIME_HIRES);
 905                                         getsurfacepoint(tmp_entity, 0, 0);
 906                                         t2 += gettime(GETTIME_HIRES) - t0;
 907                                         n += 1;
 908                                 }
 909                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 910                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 911
 912                                 delete(tmp_entity);
 913                                 return;
 914                         }
 915                 }
 916
 917                 default:
 918                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 919                 case CMD_REQUEST_USAGE:
 920                 {
 921                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 922                         LOG_INFO("See also: ^2bbox, trace^7\n");
 923                         return;
 924                 }
 925         }
 926 }
 927
 928 void GameCommand_gotomap(float request, float argc)
 929 {
 930         switch (request)
 931         {
 932                 case CMD_REQUEST_COMMAND:
 933                 {
 934                         if (argv(1))
 935                         {
 936                                 LOG_INFO(GotoMap(argv(1)), "\n");
 937                                 return;
 938                         }
 939                 }
 940
 941                 default:
 942                         LOG_INFO("Incorrect parameters for ^2gotomap^7\n");
 943                 case CMD_REQUEST_USAGE:
 944                 {
 945                         LOG_INFO("\nUsage:^3 sv_cmd gotomap map\n");
 946                         LOG_INFO("  Where 'map' is the *.bsp file to change to.\n");
 947                         LOG_INFO("See also: ^2gametype^7\n");
 948                         return;
 949                 }
 950         }
 951 }
 952
 953 void GameCommand_lockteams(float request)
 954 {
 955         switch (request)
 956         {
 957                 case CMD_REQUEST_COMMAND:
 958                 {
 959                         if (teamplay)
 960                         {
 961                                 lockteams = 1;
 962                                 bprint("^1The teams are now locked.\n");
 963                         }
 964                         else
 965                         {
 966                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 967                         }
 968                         return;
 969                 }
 970
 971                 default:
 972                 case CMD_REQUEST_USAGE:
 973                 {
 974                         LOG_INFO("\nUsage:^3 sv_cmd lockteams\n");
 975                         LOG_INFO("  No arguments required.\n");
 976                         LOG_INFO("See also: ^2unlockteams^7\n");
 977                         return;
 978                 }
 979         }
 980 }
 981
 982 void GameCommand_make_mapinfo(float request)
 983 {
 984         switch (request)
 985         {
 986                 case CMD_REQUEST_COMMAND:
 987                 {
 988                         entity tmp_entity;
 989
 990                         tmp_entity = new(make_mapinfo);
 991                         setthink(tmp_entity, make_mapinfo_Think);
 992                         tmp_entity.nextthink = time;
 993                         MapInfo_Enumerate();
 994                         return;
 995                 }
 996
 997                 default:
 998                 case CMD_REQUEST_USAGE:
 999                 {
1000                         LOG_INFO("\nUsage:^3 sv_cmd make_mapinfo\n");
1001                         LOG_INFO("  No arguments required.\n");
1002                         LOG_INFO("See also: ^2radarmap^7\n");
1003                         return;
1004                 }
1005         }
1006 }
1007
1008 void GameCommand_moveplayer(float request, float argc)
1009 {
1010         switch (request)
1011         {
1012                 case CMD_REQUEST_COMMAND:
1013                 {
1014                         float accepted;
1015                         entity client;
1016
1017                         string targets = strreplace(",", " ", argv(1));
1018                         string original_targets = strreplace(" ", ", ", targets);
1019                         string destination = argv(2);
1020
1021                         string successful, t;
1022                         successful = string_null;
1023
1024                         // lets see if the target(s) even actually exist.
1025                         if ((targets) && (destination))
1026                         {
1027                                 for ( ; targets; )
1028                                 {
1029                                         t = car(targets);
1030                                         targets = cdr(targets);
1031
1032                                         // Check to see if the player is a valid target
1033                                         client = GetFilteredEntity(t);
1034                                         accepted = VerifyClientEntity(client, false, false);
1035
1036                                         if (accepted <= 0)
1037                                         {
1038                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1039                                                 continue;
1040                                         }
1041
1042                                         // Where are we putting this player?
1043                                         if (destination == "spec" || destination == "spectator")
1044                                         {
1045                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1046                                                 {
1047                                                         if (client.caplayer) client.caplayer = 0;
1048                                                         PutObserverInServer(client);
1049
1050                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1051                                                 }
1052                                                 else
1053                                                 {
1054                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.\n");
1055                                                 }
1056                                                 continue;
1057                                         }
1058                                         else
1059                                         {
1060                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1061                                                 {
1062                                                         if (teamplay)
1063                                                         {
1064                                                                 // set up
1065                                                                 float team_id;
1066                                                                 float save = client.team_forced;
1067                                                                 client.team_forced = 0;
1068
1069                                                                 // find the team to move the player to
1070                                                                 team_id = Team_ColorToTeam(destination);
1071                                                                 if (team_id == client.team)  // already on the destination team
1072                                                                 {
1073                                                                         // keep the forcing undone
1074                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1075                                                                         continue;
1076                                                                 }
1077                                                                 else if (team_id == 0)  // auto team
1078                                                                 {
1079                                                                         CheckAllowedTeams(client);
1080                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1081                                                                 }
1082                                                                 else
1083                                                                 {
1084                                                                         CheckAllowedTeams(client);
1085                                                                 }
1086                                                                 client.team_forced = save;
1087
1088                                                                 // Check to see if the destination team is even available
1089                                                                 switch (team_id)
1090                                                                 {
1091                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1092                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1093                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1094                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1095
1096                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
1097                                                                                 return;
1098                                                                 }
1099
1100                                                                 // If so, lets continue and finally move the player
1101                                                                 client.team_forced = 0;
1102                                                                 if (MoveToTeam(client, team_id, 6))
1103                                                                 {
1104                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1105                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1106                                                                 }
1107                                                                 else
1108                                                                 {
1109                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1110                                                                 }
1111                                                                 continue;
1112                                                         }
1113                                                         else
1114                                                         {
1115                                                                 LOG_INFO("Can't change teams when currently not playing a team game.\n");
1116                                                                 return;
1117                                                         }
1118                                                 }
1119                                                 else
1120                                                 {
1121                                                         LOG_INFO("Can't change teams if the player isn't in the game.\n");  // well technically we could, but should we allow that? :P
1122                                                         return;
1123                                                 }
1124                                         }
1125                                 }
1126
1127                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1128                                 else LOG_INFO("No players given (", original_targets, ") are able to move.\n");
1129
1130                                 return;  // still correct parameters so return to avoid usage print
1131                         }
1132                 }
1133
1134                 default:
1135                         LOG_INFO("Incorrect parameters for ^2moveplayer^7\n");
1136                 case CMD_REQUEST_USAGE:
1137                 {
1138                         LOG_INFO("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1139                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1140                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating\n");
1141                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1142                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1143                         LOG_INFO("          sv_cmd moveplayer 2 spec \n");
1144                         LOG_INFO("See also: ^2allspec, shuffleteams^7\n");
1145                         return;
1146                 }
1147         }
1148 }
1149
1150 void GameCommand_nospectators(float request)
1151 {
1152         switch (request)
1153         {
1154                 case CMD_REQUEST_COMMAND:
1155                 {
1156                         blockSpectators = 1;
1157                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1158                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, LAMBDA(
1159                                 if(!it.caplayer)
1160                                 {
1161                                         it.spectatortime = time;
1162                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1163                                 }
1164                         ));
1165                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1166                         return;
1167                 }
1168
1169                 default:
1170                 case CMD_REQUEST_USAGE:
1171                 {
1172                         LOG_INFO("\nUsage:^3 sv_cmd nospectators\n");
1173                         LOG_INFO("  No arguments required.\n");
1174                         return;
1175                 }
1176         }
1177 }
1178
1179 void GameCommand_playerdemo(float request, float argc)
1180 {
1181         switch (request)
1182         {
1183                 case CMD_REQUEST_COMMAND:
1184                 {
1185                         if (argv(2) && argv(3))
1186                         {
1187                                 entity client;
1188                                 float i, n, accepted;
1189
1190                                 switch (argv(1))
1191                                 {
1192                                         case "read":
1193                                         {
1194                                                 client = GetIndexedEntity(argc, 2);
1195                                                 accepted = VerifyClientEntity(client, false, true);
1196
1197                                                 if (accepted <= 0)
1198                                                 {
1199                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1200                                                         return;
1201                                                 }
1202
1203                                                 playerdemo_open_read(client, argv(next_token));
1204                                                 return;
1205                                         }
1206
1207                                         case "write":
1208                                         {
1209                                                 client = GetIndexedEntity(argc, 2);
1210                                                 accepted = VerifyClientEntity(client, false, false);
1211
1212                                                 if (accepted <= 0)
1213                                                 {
1214                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1215                                                         return;
1216                                                 }
1217
1218                                                 playerdemo_open_write(client, argv(next_token));
1219                                                 return;
1220                                         }
1221
1222                                         case "auto_read_and_write":
1223                                         {
1224                                                 n = GetFilteredNumber(argv(3));
1225                                                 cvar_set("bot_number", ftos(n));
1226
1227                                                 localcmd("wait; wait; wait\n");
1228                                                 for (i = 0; i < n; ++i)
1229                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1230                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1231                                                 return;
1232                                         }
1233
1234                                         case "auto_read":
1235                                         {
1236                                                 n = GetFilteredNumber(argv(3));
1237                                                 cvar_set("bot_number", ftos(n));
1238
1239                                                 localcmd("wait; wait; wait\n");
1240                                                 for (i = 0; i < n; ++i)
1241                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1242                                                 return;
1243                                         }
1244                                 }
1245                         }
1246                 }
1247
1248                 default:
1249                         LOG_INFO("Incorrect parameters for ^2playerdemo^7\n");
1250                 case CMD_REQUEST_USAGE:
1251                 {
1252                         LOG_INFO("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1253                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1254                         return;
1255                 }
1256         }
1257 }
1258
1259 void GameCommand_printstats(float request)
1260 {
1261         switch (request)
1262         {
1263                 case CMD_REQUEST_COMMAND:
1264                 {
1265                         DumpStats(false);
1266                         LOG_INFO("stats dumped.\n");
1267                         return;
1268                 }
1269
1270                 default:
1271                 case CMD_REQUEST_USAGE:
1272                 {
1273                         LOG_INFO("\nUsage:^3 sv_cmd printstats\n");
1274                         LOG_INFO("  No arguments required.\n");
1275                         return;
1276                 }
1277         }
1278 }
1279
1280 void GameCommand_radarmap(float request, float argc)
1281 {
1282         switch (request)
1283         {
1284                 case CMD_REQUEST_COMMAND:
1285                 {
1286                         if (RadarMap_Make(argc)) return;
1287                 }
1288
1289                 default:
1290                         LOG_INFO("Incorrect parameters for ^2radarmap^7\n");
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         LOG_INFO("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1294                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.\n");
1295                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1296                         LOG_INFO("See also: ^2make_mapinfo^7\n");
1297                         return;
1298                 }
1299         }
1300 }
1301
1302 void GameCommand_reducematchtime(float request)
1303 {
1304         switch (request)
1305         {
1306                 case CMD_REQUEST_COMMAND:
1307                 {
1308                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1309                         return;
1310                 }
1311
1312                 default:
1313                 case CMD_REQUEST_USAGE:
1314                 {
1315                         LOG_INFO("\nUsage:^3 sv_cmd reducematchtime\n");
1316                         LOG_INFO("  No arguments required.\n");
1317                         LOG_INFO("See also: ^2extendmatchtime^7\n");
1318                         return;
1319                 }
1320         }
1321 }
1322
1323 void GameCommand_setbots(float request, float argc)
1324 {
1325         switch (request)
1326         {
1327                 case CMD_REQUEST_COMMAND:
1328                 {
1329                         if (argc >= 2)
1330                         {
1331                                 cvar_settemp("minplayers", "0");
1332                                 cvar_settemp("bot_number", argv(1));
1333                                 bot_fixcount();
1334                                 return;
1335                         }
1336                 }
1337
1338                 default:
1339                         LOG_INFO("Incorrect parameters for ^2setbots^7\n");
1340                 case CMD_REQUEST_USAGE:
1341                 {
1342                         LOG_INFO("\nUsage:^3 sv_cmd setbots botnumber\n");
1343                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1344                         LOG_INFO("See also: ^2bot_cmd^7\n");
1345                         return;
1346                 }
1347         }
1348 }
1349
1350 void GameCommand_shuffleteams(float request)
1351 {
1352         switch (request)
1353         {
1354                 case CMD_REQUEST_COMMAND:
1355                 {
1356                         if (!teamplay)
1357                         {
1358                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.\n");
1359                                 return;
1360                         }
1361
1362                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, LAMBDA(
1363                                 if (it.team_forced) {
1364                                         // we could theoretically assign forced players to their teams
1365                                         // and shuffle the rest to fill the empty spots but in practise
1366                                         // either all players or none are gonna have forced teams
1367                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.\n");
1368                                         return;
1369                                 }
1370                         ));
1371
1372                         int number_of_teams = 0;
1373                         CheckAllowedTeams(NULL);
1374                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1375                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1376                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1377                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1378
1379                         int team_index = 0;
1380                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, LAMBDA(
1381                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1382                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1383                                 team_index = (team_index + 1) % number_of_teams;
1384                         ));
1385
1386                         bprint("Successfully shuffled the players around randomly.\n");
1387                         return;
1388                 }
1389
1390                 default:
1391                 case CMD_REQUEST_USAGE:
1392                 {
1393                         LOG_INFO("\nUsage:^3 sv_cmd shuffleteams\n");
1394                         LOG_INFO("  No arguments required.\n");
1395                         LOG_INFO("See also: ^2moveplayer, allspec^7\n");
1396                         return;
1397                 }
1398         }
1399 }
1400
1401 void GameCommand_stuffto(float request, float argc)
1402 {
1403         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1404         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1405         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1406
1407 #ifdef STUFFTO_ENABLED
1408                 switch (request)
1409                 {
1410                         case CMD_REQUEST_COMMAND:
1411                         {
1412                                 if (argv(2))
1413                                 {
1414                                         entity client = GetIndexedEntity(argc, 1);
1415                                         float accepted = VerifyClientEntity(client, true, false);
1416
1417                                         if (accepted > 0)
1418                                         {
1419                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1420                                                 LOG_INFO(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").\n"));
1421                                         }
1422                                         else
1423                                         {
1424                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1425                                         }
1426
1427                                         return;
1428                                 }
1429                         }
1430
1431                         default:
1432                                 LOG_INFO("Incorrect parameters for ^2stuffto^7\n");
1433                         case CMD_REQUEST_USAGE:
1434                         {
1435                                 LOG_INFO("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1436                                 LOG_INFO("  'client' is the entity number or name of the player,\n");
1437                                 LOG_INFO("  and 'command' is the command to be sent to that player.\n");
1438                                 return;
1439                         }
1440                 }
1441 #else
1442                 if (request)
1443                 {
1444                         LOG_INFO("stuffto command is not enabled on this server.\n");
1445                         return;
1446                 }
1447 #endif
1448 }
1449
1450 void GameCommand_trace(float request, float argc)
1451 {
1452         switch (request)
1453         {
1454                 case CMD_REQUEST_COMMAND:
1455                 {
1456                         entity e;
1457                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1458                         float i, f, safe, unsafe, dq, dqf;
1459
1460                         switch (argv(1))
1461                         {
1462                                 case "debug":
1463                                 {
1464                                         float hitcount = 0;
1465                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1466                                         float worst_endpos_bug = 0;
1467                                         for ( ; ; )
1468                                         {
1469                                                 org = world.mins;
1470                                                 delta = world.maxs - world.mins;
1471
1472                                                 start.x = org.x + random() * delta.x;
1473                                                 start.y = org.y + random() * delta.y;
1474                                                 start.z = org.z + random() * delta.z;
1475
1476                                                 end.x = org.x + random() * delta.x;
1477                                                 end.y = org.y + random() * delta.y;
1478                                                 end.z = org.z + random() * delta.z;
1479
1480                                                 start = stov(vtos(start));
1481                                                 end = stov(vtos(end));
1482
1483                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1484                                                 if (!trace_startsolid && trace_fraction < 1)
1485                                                 {
1486                                                         p = trace_endpos;
1487                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1488                                                         if (trace_startsolid)
1489                                                         {
1490                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1491                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1492
1493                                                                 // how much do we need to back off?
1494                                                                 safe = 1;
1495                                                                 unsafe = 0;
1496                                                                 for ( ; ; )
1497                                                                 {
1498                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1499                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1500                                                                         if (trace_startsolid)
1501                                                                         {
1502                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1503                                                                                 unsafe = (safe + unsafe) * 0.5;
1504                                                                         }
1505                                                                         else
1506                                                                         {
1507                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1508                                                                                 safe = (safe + unsafe) * 0.5;
1509                                                                         }
1510                                                                 }
1511
1512                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1513                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1514
1515                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1516                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1517                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1518                                                                 if (++hitcount >= 10) break;
1519                                                         }
1520                                                         else
1521                                                         {
1522                                                                 q0 = p;
1523                                                                 dq = 0;
1524                                                                 dqf = 1;
1525                                                                 for ( ; ; )
1526                                                                 {
1527                                                                         q = p + normalize(end - p) * (dq + dqf);
1528                                                                         if (q == q0) break;
1529                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1530                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1531                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1532                                                                         dqf *= 0.5;
1533                                                                         q0 = q;
1534                                                                 }
1535                                                                 if (dq > worst_endpos_bug)
1536                                                                 {
1537                                                                         worst_endpos_bug = dq;
1538                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1539                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1540                                                                         if (++hitcount >= 10) break;
1541                                                                 }
1542                                                         }
1543                                                 }
1544                                         }
1545                                         return;
1546                                 }
1547
1548                                 case "debug2":
1549                                 {
1550                                         e = nextent(NULL);
1551                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1552                                         vv = trace_endpos;
1553                                         if (trace_fraction == 1)
1554                                         {
1555                                                 LOG_INFO("not above ground, aborting\n");
1556                                                 return;
1557                                         }
1558                                         f = 0;
1559                                         for (i = 0; i < 100000; ++i)
1560                                         {
1561                                                 dv = randomvec();
1562                                                 if (dv.z > 0) dv = -1 * dv;
1563                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1564                                                 if (trace_startsolid) LOG_INFO("bug 1\n");
1565                                                 if (trace_fraction == 1)
1566                                                 {
1567                                                         if (dv.z < f)
1568                                                         {
1569                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1570                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1571                                                                 f = dv.z;
1572                                                         }
1573                                                 }
1574                                         }
1575                                         LOG_INFO("highest possible dist: ", ftos(f), "\n");
1576                                         return;
1577                                 }
1578
1579                                 case "walk":
1580                                 {
1581                                         if (argc == 4)
1582                                         {
1583                                                 e = nextent(NULL);
1584                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL)) LOG_INFO("can walk\n");
1585                                                 else LOG_INFO("cannot walk\n");
1586                                                 return;
1587                                         }
1588                                 }
1589
1590                                 case "showline":
1591                                 {
1592                                         if (argc == 4)
1593                                         {
1594                                                 vv = stov(argv(2));
1595                                                 dv = stov(argv(3));
1596                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1597                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1598                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1599                                                 return;
1600                                         }
1601                                 }
1602
1603                                         // no default case, just go straight to invalid
1604                         }
1605                 }
1606
1607                 default:
1608                         LOG_INFO("Incorrect parameters for ^2trace^7\n");
1609                 case CMD_REQUEST_USAGE:
1610                 {
1611                         LOG_INFO("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1612                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1613                         LOG_INFO("See also: ^2bbox, gettaginfo^7\n");
1614                         return;
1615                 }
1616         }
1617 }
1618
1619 void GameCommand_unlockteams(float request)
1620 {
1621         switch (request)
1622         {
1623                 case CMD_REQUEST_COMMAND:
1624                 {
1625                         if (teamplay)
1626                         {
1627                                 lockteams = 0;
1628                                 bprint("^1The teams are now unlocked.\n");
1629                         }
1630                         else
1631                         {
1632                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1633                         }
1634                         return;
1635                 }
1636
1637                 default:
1638                 case CMD_REQUEST_USAGE:
1639                 {
1640                         LOG_INFO("\nUsage:^3 sv_cmd unlockteams\n");
1641                         LOG_INFO("  No arguments required.\n");
1642                         LOG_INFO("See also: ^2lockteams^7\n");
1643                         return;
1644                 }
1645         }
1646 }
1647
1648 void GameCommand_warp(float request, float argc)
1649 {
1650         switch (request)
1651         {
1652                 case CMD_REQUEST_COMMAND:
1653                 {
1654                         if (autocvar_g_campaign)
1655                         {
1656                                 if (argc >= 2)
1657                                 {
1658                                         CampaignLevelWarp(stof(argv(1)));
1659                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".\n");
1660                                 }
1661                                 else
1662                                 {
1663                                         CampaignLevelWarp(-1);
1664                                         LOG_INFO("Successfully warped to next campaign level.\n");
1665                                 }
1666                         }
1667                         else
1668                         {
1669                                 LOG_INFO("Not in campaign, can't level warp\n");
1670                         }
1671                         return;
1672                 }
1673
1674                 default:
1675                 case CMD_REQUEST_USAGE:
1676                 {
1677                         LOG_INFO("\nUsage:^3 sv_cmd warp [level]\n");
1678                         LOG_INFO("  'level' is the level to change campaign mode to.\n");
1679                         LOG_INFO("  if 'level' is not provided it will change to the next level.\n");
1680                         return;
1681                 }
1682         }
1683 }
1684
1685 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1686 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1687 void GameCommand_(float request)
1688 {
1689     switch(request)
1690     {
1691         case CMD_REQUEST_COMMAND:
1692         {
1693
1694             return;
1695         }
1696
1697         default:
1698         case CMD_REQUEST_USAGE:
1699         {
1700             print("\nUsage:^3 sv_cmd \n");
1701             print("  No arguments required.\n");
1702             return;
1703         }
1704     }
1705 }
1706 */
1707
1708
1709 // ==================================
1710 //  Macro system for server commands
1711 // ==================================
1712
1713 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1714 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1715 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1716 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1717 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1718 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1719 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1720 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1721 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1722 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1723 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1724 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1725 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1726 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1727 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1728 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1729 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1730 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1731 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1732 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1733 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1734 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1735 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1736 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1737 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1738 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1739 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1740 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1741 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1742 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1743 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1744 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1745
1746 void GameCommand_macro_help()
1747 {
1748         FOREACH(SERVER_COMMANDS, true, LAMBDA(LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description)));
1749 }
1750
1751 float GameCommand_macro_command(float argc, string command)
1752 {
1753         string c = strtolower(argv(0));
1754         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1755                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1756                 return true;
1757         ));
1758         return false;
1759 }
1760
1761 float GameCommand_macro_usage(float argc)
1762 {
1763         string c = strtolower(argv(1));
1764         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1765                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1766                 return true;
1767         ));
1768         return false;
1769 }
1770
1771 void GameCommand_macro_write_aliases(float fh)
1772 {
1773         FOREACH(SERVER_COMMANDS, true, LAMBDA(CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description)));
1774 }
1775
1776
1777 // =========================================
1778 //  Main Function Called By Engine (sv_cmd)
1779 // =========================================
1780 // If this function exists, game code handles gamecommand instead of the engine code.
1781
1782 void GameCommand(string command)
1783 {
1784         float argc = tokenize_console(command);
1785
1786         // Guide for working with argc arguments by example:
1787         // argc:   1    - 2      - 3     - 4
1788         // argv:   0    - 1      - 2     - 3
1789         // cmd     vote - master - login - password
1790
1791         if (strtolower(argv(0)) == "help")
1792         {
1793                 if (argc == 1)
1794                 {
1795                         LOG_INFO("\nServer console commands:\n");
1796                         GameCommand_macro_help();
1797
1798                         LOG_INFO("\nBanning commands:\n");
1799                         BanCommand_macro_help();
1800
1801                         LOG_INFO("\nCommon networked commands:\n");
1802                         CommonCommand_macro_help(NULL);
1803
1804                         LOG_INFO("\nGeneric commands shared by all programs:\n");
1805                         GenericCommand_macro_help();
1806
1807                         LOG_INFO("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1808                         LOG_INFO("For help about a specific command, type sv_cmd help COMMAND\n");
1809
1810                         return;
1811                 }
1812                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1813                 {
1814                         return;
1815                 }
1816                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1817                 {
1818                         return;
1819                 }
1820                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1821                 {
1822                         return;
1823                 }
1824                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1825                 {
1826                         return;
1827                 }
1828         }
1829         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1830         {
1831                 return;  // handled by a mutator
1832         }
1833         else if (BanCommand(command))
1834         {
1835                 return;  // handled by server/command/ipban.qc
1836         }
1837         else if (CommonCommand_macro_command(argc, NULL, command))
1838         {
1839                 return;  // handled by server/command/common.qc
1840         }
1841         else if (GenericCommand(command))
1842         {
1843                 return;                                        // handled by common/command/generic.qc
1844         }
1845         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1846         {
1847                 return;                                        // handled by one of the above GameCommand_* functions
1848         }
1849
1850         // nothing above caught the command, must be invalid
1851         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1852 }