qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/mutators_include.qh"
  14
  15 #include "../../common/constants.qh"
  16 #include "../../common/mapinfo.qh"
  17 #include "../../common/notifications.qh"
  18 #include "../../common/playerstats.qh"
  19 #include "../../common/util.qh"
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 float Nagger_SendEntity(entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if(readycount)
  45         {
  46                 nags |= 1;
  47                 if(to.ready == 0)
  48                         nags |= 2;
  49         }
  50         if(vote_called)
  51         {
  52                 nags |= 4;
  53                 if(to.vote_selection == 0)
  54                         nags |= 8;
  55         }
  56         if(warmup_stage)
  57                 nags |= 16;
  58
  59         if(sendflags & 64)
  60                 nags |= 64;
  61
  62         if(sendflags & 128)
  63                 nags |= 128;
  64
  65         if(!(nags & 4)) // no vote called? send no string
  66                 nags &= ~(64 | 128);
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if(nags & 64)
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if(nags & 128)
  79                 WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if(nags & 1)
  82         {
  83                 for(i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  86                                 if(!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if(nagger)
 103                 nagger.SendFlags |= 128;
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if(nagger)
 109                 nagger.SendFlags |= 64;
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if(nagger)
 115                 nagger.SendFlags |= 1;
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller))
 122                 return vote_caller.netname;
 123         return vote_caller_name;
 124 }
 125
 126 // =======================
 127 //  Game logic for voting
 128 // =======================
 129
 130 void VoteReset()
 131 {
 132         entity tmp_player;
 133
 134         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 135
 136         if(vote_called)
 137         {
 138                 strunzone(vote_called_command);
 139                 strunzone(vote_called_display);
 140                 strunzone(vote_caller_name);
 141         }
 142
 143         vote_called = VOTE_NULL;
 144         vote_caller = world;
 145         vote_caller_name = string_null;
 146         vote_endtime = 0;
 147
 148         vote_called_command = string_null;
 149         vote_called_display = string_null;
 150
 151         vote_parsed_command = string_null;
 152         vote_parsed_display = string_null;
 153
 154         Nagger_VoteChanged();
 155 }
 156
 157 void VoteStop(entity stopper)
 158 {
 159         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 160         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 161
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 164
 165         VoteReset();
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if((vote_called == VOTE_MASTER) && vote_caller)
 173                 vote_caller.vote_master = 1;
 174         else
 175                 localcmd(strcat(vote_called_command, "\n"));
 176
 177         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 178
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 181 }
 182
 183 void VoteReject()
 184 {
 185         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 186         VoteReset();
 187         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 188 }
 189
 190 void VoteTimeout()
 191 {
 192         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 193         VoteReset();
 194         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 195 }
 196
 197 void VoteSpam(float notvoters, float mincount, string result)
 198 {
 199         bprint(strcat(
 200                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 201                 strcat("^2:^1", ftos(vote_reject_count)),
 202                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 203                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 204                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 205
 206         if(autocvar_sv_eventlog)
 207         {
 208                 GameLogEcho(strcat(
 209                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 210                         strcat(":", ftos(vote_reject_count)),
 211                         strcat(":", ftos(vote_abstain_count)),
 212                         strcat(":", ftos(notvoters)),
 213                         strcat(":", ftos(mincount))));
 214         }
 215 }
 216
 217 void VoteCount(float first_count)
 218 {
 219         // declarations
 220         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 221
 222         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 223                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 224                                 || (autocvar_sv_vote_nospectators == 0));
 225
 226         float vote_player_count = 0, notvoters = 0;
 227         float vote_real_player_count = 0, vote_real_accept_count = 0;
 228         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 229         float vote_needed_of_voted, final_needed_votes;
 230         float vote_factor_overall, vote_factor_of_voted;
 231
 232         entity tmp_player;
 233
 234         Nagger_VoteCountChanged();
 235
 236         // add up all the votes from each connected client
 237         FOR_EACH_REALCLIENT(tmp_player)
 238         {
 239                 ++vote_player_count;
 240                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 241
 242                 switch(tmp_player.vote_selection)
 243                 {
 244                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 245                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 246                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 247                         default: break;
 248                 }
 249         }
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset();
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if(!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if(vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if(vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if(time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if(autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if(vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if(vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if(vote_endtime > 0) // a vote was called
 336         if(time > vote_endtime) // time is up
 337         {
 338                 VoteCount(false);
 339         }
 340
 341         return;
 342 }
 343
 344
 345 // =======================
 346 //  Game logic for warmup
 347 // =======================
 348
 349 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 350 void reset_map(float dorespawn)
 351 {SELFPARAM();
 352
 353         if(time <= game_starttime && round_handler_IsActive())
 354                 round_handler_Reset(game_starttime);
 355
 356         MUTATOR_CALLHOOK(reset_map_global);
 357
 358         for(entity e = world; (e = nextent(e)); )
 359         {
 360                 setself(e);
 361                 if(IS_NOT_A_CLIENT(self))
 362                 {
 363                         if(self.reset)
 364                         {
 365                                 self.reset();
 366                                 continue;
 367                         }
 368
 369                         if(self.team_saved)
 370                                 self.team = self.team_saved;
 371
 372                         if(self.flags & FL_PROJECTILE) // remove any projectiles left
 373                                 remove(self);
 374                 }
 375         }
 376
 377         // Waypoints and assault start come LAST
 378         for(entity e = world; (e = nextent(e)); )
 379         {
 380                 setself(e);
 381                 if(IS_NOT_A_CLIENT(self))
 382                 {
 383                         if(self.reset2)
 384                         {
 385                                 self.reset2();
 386                                 continue;
 387                         }
 388                 }
 389         }
 390
 391         entity e;
 392         FOR_EACH_PLAYER(e)
 393         if(e.frozen)
 394         {
 395                 WITH(entity, self, e, Unfreeze(self));
 396         }
 397
 398         // Moving the player reset code here since the player-reset depends
 399         // on spawnpoint entities which have to be reset first --blub
 400         if(dorespawn)
 401         if(!MUTATOR_CALLHOOK(reset_map_players))
 402         FOR_EACH_CLIENT(e) // reset all players
 403         {
 404                 setself(e);
 405                 /*
 406                 only reset players if a restart countdown is active
 407                 this can either be due to cvar sv_ready_restart_after_countdown having set
 408                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 409                 sv_ready_restart_after_countdown is not used and countdown is still running
 410                 */
 411                 if (restart_mapalreadyrestarted || (time < game_starttime))
 412                 {
 413                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 414                         if (IS_PLAYER(self)) {
 415                                 //PlayerScore_Clear(self);
 416                                 self.killcount = 0;
 417                                 //stop the player from moving so that he stands still once he gets respawned
 418                                 self.velocity = '0 0 0';
 419                                 self.avelocity = '0 0 0';
 420                                 self.movement = '0 0 0';
 421                                 PutClientInServer();
 422                         }
 423                 }
 424         }
 425
 426         if(g_keyhunt)
 427                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 428
 429         setself(this);
 430 }
 431
 432 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 433 void ReadyRestart_think()
 434 {SELFPARAM();
 435         restart_mapalreadyrestarted = 1;
 436         reset_map(true);
 437         Score_ClearAll();
 438         remove(self);
 439
 440         return;
 441 }
 442
 443 // Forces a restart of the game without actually reloading the map // this is a mess...
 444 void ReadyRestart_force()
 445 {
 446         entity tmp_player, restart_timer;
 447
 448         bprint("^1Server is restarting...\n");
 449
 450         VoteReset();
 451
 452         // clear overtime, we have to decrease timelimit to its original value again.
 453         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 454
 455         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 456
 457         readyrestart_happened = 1;
 458         game_starttime = time + RESTART_COUNTDOWN;
 459
 460         // clear player attributes
 461         FOR_EACH_CLIENT(tmp_player)
 462         {
 463                 tmp_player.alivetime = 0;
 464                 tmp_player.killcount = 0;
 465                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 466         }
 467
 468         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 469
 470         // disable the warmup global for the server
 471         warmup_stage = 0; // once the game is restarted the game is in match stage
 472
 473         // reset the .ready status of all players (also spectators)
 474         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 475         readycount = 0;
 476         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 477
 478         // lock teams with lockonrestart
 479         if(autocvar_teamplay_lockonrestart && teamplay)
 480         {
 481                 lockteams = 1;
 482                 bprint("^1The teams are now locked.\n");
 483         }
 484
 485         //initiate the restart-countdown-announcer entity
 486         if(autocvar_sv_ready_restart_after_countdown)
 487         {
 488                 restart_timer = spawn();
 489                 restart_timer.think = ReadyRestart_think;
 490                 restart_timer.nextthink = game_starttime;
 491         }
 492
 493         // after a restart every players number of allowed timeouts gets reset, too
 494         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 495
 496         //reset map immediately if this cvar is not set
 497         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 498
 499         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 500 }
 501
 502 void ReadyRestart()
 503 {
 504         // no arena, assault support yet...
 505         if(g_assault | gameover | intermission_running | race_completing)
 506                 localcmd("restart\n");
 507         else
 508                 localcmd("\nsv_hook_gamerestart\n");
 509
 510         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 511         // Otherwise scores could be manipulated during the countdown.
 512         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 513
 514         ReadyRestart_force();
 515
 516         return;
 517 }
 518
 519 // Count the players who are ready and determine whether or not to restart the match
 520 void ReadyCount()
 521 {
 522         entity tmp_player;
 523         float ready_needed_factor, ready_needed_count;
 524         float t_ready = 0, t_players = 0;
 525
 526         FOR_EACH_REALCLIENT(tmp_player)
 527         {
 528                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 529                 {
 530                         ++t_players;
 531                         if(tmp_player.ready) { ++t_ready; }
 532                 }
 533         }
 534
 535         readycount = t_ready;
 536
 537         Nagger_ReadyCounted();
 538
 539         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 540         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 541
 542         if(readycount >= ready_needed_count)
 543         {
 544                 ReadyRestart();
 545         }
 546
 547         return;
 548 }
 549
 550
 551 // ======================================
 552 //  Supporting functions for VoteCommand
 553 // ======================================
 554
 555 float Votecommand_check_assignment(entity caller, float assignment)
 556 {
 557         float from_server = (!caller);
 558
 559         if((assignment == VC_ASGNMNT_BOTH)
 560                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 561                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 562         {
 563                 return true;
 564         }
 565
 566         return false;
 567 }
 568
 569 string VoteCommand_extractcommand(string input, float startpos, float argc)
 570 {
 571         string output;
 572
 573         if((argc - 1) < startpos)
 574                 output = "";
 575         else
 576                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 577
 578         return output;
 579 }
 580
 581 float VoteCommand_checknasty(string vote_command)
 582 {
 583         if((strstrofs(vote_command, ";", 0) >= 0)
 584                 || (strstrofs(vote_command, "\n", 0) >= 0)
 585                 || (strstrofs(vote_command, "\r", 0) >= 0)
 586                 || (strstrofs(vote_command, "$", 0) >= 0))
 587                 return false;
 588
 589         return true;
 590 }
 591
 592 float VoteCommand_checkinlist(string vote_command, string list)
 593 {
 594         string l = strcat(" ", list, " ");
 595
 596         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 597                 return true;
 598
 599         return false;
 600 }
 601
 602 string ValidateMap(string validated_map, entity caller)
 603 {
 604         validated_map = MapInfo_FixName(validated_map);
 605
 606         if (!validated_map)
 607         {
 608                 print_to(caller, "This map is not available on this server.");
 609                 return string_null;
 610         }
 611
 612         if(!autocvar_sv_vote_override_mostrecent && caller)
 613         {
 614                 if(Map_IsRecent(validated_map))
 615                 {
 616                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 617                         return string_null;
 618                 }
 619         }
 620
 621         if(!MapInfo_CheckMap(validated_map))
 622         {
 623                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 624                 return string_null;
 625         }
 626
 627         return validated_map;
 628 }
 629
 630 float VoteCommand_checkargs(float startpos, float argc)
 631 {
 632         float p, q, check, minargs;
 633         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 634         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 635         string charlist, arg;
 636         float checkmate;
 637
 638         if(cmdrestriction == "")
 639                 return true;
 640
 641         ++startpos; // skip command name
 642
 643         // check minimum arg count
 644
 645         // 0 args: argc == startpos
 646         // 1 args: argc == startpos + 1
 647         // ...
 648
 649         minargs = stof(cmdrestriction);
 650         if(argc - startpos < minargs)
 651                 return false;
 652
 653         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 654
 655         for (;;)
 656         {
 657                 // we know that at any time, startpos <= argc - minargs
 658                 // so this means: argc-minargs >= startpos >= argc, thus
 659                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 660                 // have been seen already
 661
 662                 if(startpos >= argc) // all args checked? GOOD
 663                         break;
 664
 665                 if(p < 0) // no more args? FAIL
 666                 {
 667                         // exception: exactly minargs left, this one included
 668                         if(argc - startpos == minargs)
 669                                 break;
 670
 671                         // otherwise fail
 672                         return false;
 673                 }
 674
 675                 // cut to next semicolon
 676                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 677                 if(q < 0)
 678                         charlist = substring(cmdrestriction, p+1, -1);
 679                 else
 680                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 681
 682                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 683                 // charlist = strreplace("^^", ";", charlist);
 684
 685                 if(charlist != "")
 686                 {
 687                         // verify the arg only contains allowed chars
 688                         arg = argv(startpos);
 689                         checkmate = strlen(arg);
 690                         for(check = 0; check < checkmate; ++check)
 691                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 692                                         return false; // not allowed character
 693                         // all characters are allowed. FINE.
 694                 }
 695
 696                 ++startpos;
 697                 --minargs;
 698                 p = q;
 699         }
 700
 701         return true;
 702 }
 703
 704 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 705 {
 706         string first_command;
 707
 708         first_command = argv(startpos);
 709
 710         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 711                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 712                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 713         );*/
 714
 715         if(
 716                 (autocvar_sv_vote_limit > 0)
 717                 &&
 718                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 719         )
 720                 return false;
 721
 722         if (!VoteCommand_checkinlist(first_command, vote_list))
 723                 return false;
 724
 725         if (!VoteCommand_checkargs(startpos, argc))
 726                 return false;
 727
 728         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 729         {
 730                 case "kick":
 731                 case "kickban": // catch all kick/kickban commands
 732                 {
 733                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 734                         float accepted = VerifyClientEntity(victim, true, false);
 735
 736                         if(accepted > 0)
 737                         {
 738                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 739                                 string command_arguments;
 740
 741                                 if(first_command == "kickban")
 742                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 743                                 else
 744                                         command_arguments = reason;
 745
 746                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 747                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 748                         }
 749                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 750
 751                         break;
 752                 }
 753
 754                 case "map":
 755                 case "chmap":
 756                 case "gotomap": // re-direct all map selection commands to gotomap
 757                 {
 758                         vote_command = ValidateMap(argv(startpos + 1), caller);
 759                         if (!vote_command) { return false; }
 760                         vote_parsed_command = strcat("gotomap ", vote_command);
 761                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 762
 763                         break;
 764                 }
 765
 766                 default:
 767                 {
 768                         vote_parsed_command = vote_command;
 769                         vote_parsed_display = strzone(strcat("^1", vote_command));
 770
 771                         break;
 772                 }
 773         }
 774
 775         return true;
 776 }
 777
 778
 779 // =======================
 780 //  Command Sub-Functions
 781 // =======================
 782
 783 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 784 {
 785         switch(request)
 786         {
 787                 case CMD_REQUEST_COMMAND:
 788                 {
 789                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 790                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 791
 792                         else // everything went okay, continue changing vote
 793                         {
 794                                 print_to(caller, "^1You abstained from your vote.");
 795                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 796                                 msg_entity = caller;
 797                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 798                         }
 799
 800                         return;
 801                 }
 802
 803                 default:
 804                 case CMD_REQUEST_USAGE:
 805                 {
 806                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 807                         print_to(caller, "  No arguments required.");
 808                         return;
 809                 }
 810         }
 811 }
 812
 813 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 814 {
 815         switch(request)
 816         {
 817                 case CMD_REQUEST_COMMAND:
 818                 {
 819                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 820                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 821                                 || (autocvar_sv_vote_nospectators == 0));
 822
 823                         float tmp_playercount = 0;
 824                         entity tmp_player;
 825
 826                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 827
 828                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 829                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 830                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 831                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 832                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 833                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 834                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 835                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 836                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 837
 838                         else // everything went okay, continue with calling the vote
 839                         {
 840                                 vote_caller = caller; // remember who called the vote
 841                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 842                                 vote_called = VOTE_NORMAL;
 843                                 vote_called_command = strzone(vote_parsed_command);
 844                                 vote_called_display = strzone(vote_parsed_display);
 845                                 vote_endtime = time + autocvar_sv_vote_timeout;
 846
 847                                 if(caller)
 848                                 {
 849                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 850                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 851                                         msg_entity = caller;
 852                                 }
 853
 854                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 855                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 856
 857                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 858                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 859                                 Nagger_VoteChanged();
 860                                 VoteCount(true); // needed if you are the only one
 861                         }
 862
 863                         return;
 864                 }
 865
 866                 default:
 867                 case CMD_REQUEST_USAGE:
 868                 {
 869                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 870                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 871                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 872                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 873                         return;
 874                 }
 875         }
 876 }
 877
 878 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 879 {
 880         switch(request)
 881         {
 882                 case CMD_REQUEST_COMMAND:
 883                 {
 884                         if(autocvar_sv_vote_master)
 885                         {
 886                                 switch(strtolower(argv(2)))
 887                                 {
 888                                         case "do":
 889                                         {
 890                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 891
 892                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 893                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 894                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 895
 896                                                 else // everything went okay, proceed with command
 897                                                 {
 898                                                         localcmd(strcat(vote_parsed_command, "\n"));
 899                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 900                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 901                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 902                                                 }
 903
 904                                                 return;
 905                                         }
 906
 907                                         case "login":
 908                                         {
 909                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 910                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 911                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 912
 913                                                 else // everything went okay, proceed with giving this player master privilages
 914                                                 {
 915                                                         caller.vote_master = true;
 916                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 917                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 918                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 919                                                 }
 920
 921                                                 return;
 922                                         }
 923
 924                                         default: // calling a vote for master
 925                                         {
 926                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 927                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 928                                                         || (autocvar_sv_vote_nospectators == 0));
 929
 930                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 931                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 932                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 933                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 934
 935                                                 else // everything went okay, continue with creating vote
 936                                                 {
 937                                                         vote_caller = caller;
 938                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 939                                                         vote_called = VOTE_MASTER;
 940                                                         vote_called_command = strzone("XXX");
 941                                                         vote_called_display = strzone("^3master");
 942                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 943
 944                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 945                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 946
 947                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 948                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 949                                                         Nagger_VoteChanged();
 950                                                         VoteCount(true); // needed if you are the only one
 951                                                 }
 952
 953                                                 return;
 954                                         }
 955                                 }
 956                         }
 957                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 958
 959                         return;
 960                 }
 961
 962                 default:
 963                 case CMD_REQUEST_USAGE:
 964                 {
 965                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 966                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 967                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 968                         return;
 969                 }
 970         }
 971 }
 972
 973 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 974 {
 975         switch(request)
 976         {
 977                 case CMD_REQUEST_COMMAND:
 978                 {
 979                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 980                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 981                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 982
 983                         else // everything went okay, continue changing vote
 984                         {
 985                                 print_to(caller, "^1You rejected the vote.");
 986                                 caller.vote_selection = VOTE_SELECT_REJECT;
 987                                 msg_entity = caller;
 988                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 989                         }
 990
 991                         return;
 992                 }
 993
 994                 default:
 995                 case CMD_REQUEST_USAGE:
 996                 {
 997                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 998                         print_to(caller, "  No arguments required.");
 999                         return;
1000                 }
1001         }
1002 }
1003
1004 void VoteCommand_status(float request, entity caller) // BOTH
1005 {
1006         switch(request)
1007         {
1008                 case CMD_REQUEST_COMMAND:
1009                 {
1010                         if(vote_called)
1011                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1012                         else
1013                                 print_to(caller, "^1No vote called.");
1014
1015                         return;
1016                 }
1017
1018                 default:
1019                 case CMD_REQUEST_USAGE:
1020                 {
1021                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1022                         print_to(caller, "  No arguments required.");
1023                         return;
1024                 }
1025         }
1026 }
1027
1028 void VoteCommand_stop(float request, entity caller) // BOTH
1029 {
1030         switch(request)
1031         {
1032                 case CMD_REQUEST_COMMAND:
1033                 {
1034                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1035                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1036                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1037
1038                         return;
1039                 }
1040
1041                 default:
1042                 case CMD_REQUEST_USAGE:
1043                 {
1044                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1045                         print_to(caller, "  No arguments required.");
1046                         return;
1047                 }
1048         }
1049 }
1050
1051 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1052 {
1053         switch(request)
1054         {
1055                 case CMD_REQUEST_COMMAND:
1056                 {
1057                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1058                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1059
1060                         else // everything went okay, continue changing vote
1061                         {
1062                                 print_to(caller, "^1You accepted the vote.");
1063                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1064                                 msg_entity = caller;
1065                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1066                         }
1067
1068                         return;
1069                 }
1070
1071                 default:
1072                 case CMD_REQUEST_USAGE:
1073                 {
1074                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1075                         print_to(caller, "  No arguments required.");
1076                         return;
1077                 }
1078         }
1079 }
1080
1081 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1082 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1083 void VoteCommand_(float request)
1084 {
1085         switch(request)
1086         {
1087                 case CMD_REQUEST_COMMAND:
1088                 {
1089
1090                         return;
1091                 }
1092
1093                 default:
1094                 case CMD_REQUEST_USAGE:
1095                 {
1096                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1097                         print_to(caller, "  No arguments required.");
1098                         return;
1099                 }
1100         }
1101 }
1102 */
1103
1104
1105 // ================================
1106 //  Macro system for vote commands
1107 // ================================
1108
1109 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1110 #define VOTE_COMMANDS(request,caller,arguments,command) \
1111         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1112         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1113         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1114         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1115         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1116         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1117         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1118         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1119         /* nothing */
1120
1121 void VoteCommand_macro_help(entity caller, float argc)
1122 {
1123         string command_origin = GetCommandPrefix(caller);
1124
1125         if(argc == 2 || argv(2) == "help") // help display listing all commands
1126         {
1127                 print_to(caller, "\nVoting commands:\n");
1128                 #define VOTE_COMMAND(name,function,description,assignment) \
1129                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1130
1131                 VOTE_COMMANDS(0, caller, 0, "");
1132                 #undef VOTE_COMMAND
1133
1134                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1135                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1136                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1137         }
1138         else // usage for individual command
1139         {
1140                 #define VOTE_COMMAND(name,function,description,assignment) \
1141                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1142
1143                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1144                 #undef VOTE_COMMAND
1145         }
1146
1147         return;
1148 }
1149
1150 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1151 {
1152         #define VOTE_COMMAND(name,function,description,assignment) \
1153                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1154
1155         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1156         #undef VOTE_COMMAND
1157
1158         return false;
1159 }
1160
1161
1162 // ======================================
1163 //  Main function handling vote commands
1164 // ======================================
1165
1166 void VoteCommand(float request, entity caller, float argc, string vote_command)
1167 {
1168         // Guide for working with argc arguments by example:
1169         // argc:   1    - 2      - 3     - 4
1170         // argv:   0    - 1      - 2     - 3
1171         // cmd     vote - master - login - password
1172
1173         switch(request)
1174         {
1175                 case CMD_REQUEST_COMMAND:
1176                 {
1177                         if(VoteCommand_macro_command(caller, argc, vote_command))
1178                                 return;
1179                 }
1180
1181                 default:
1182                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1183                 case CMD_REQUEST_USAGE:
1184                 {
1185                         VoteCommand_macro_help(caller, argc);
1186                         return;
1187                 }
1188         }
1189 }