qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7 .float debrismovetype;
   8 .float debrissolid;
   9 .vector debrisvelocity;
  10 .vector debrisvelocityjitter;
  11 .vector debrisavelocityjitter;
  12 .float debristime;
  13 .float debristimejitter;
  14 .float debrisfadetime;
  15 .float debrisdamageforcescale;
  16 .float debrisskin;
  17
  18 .string mdl_dead; // or "" to hide when broken
  19 .string debris; // space separated list of debris models
  20 // other fields:
  21 //   mdl = particle effect name
  22 //   count = particle effect multiplier
  23 //   targetname = target to trigger to unbreak the model
  24 //   target = targets to trigger when broken
  25 //   health = amount of damage it can take
  26 //   spawnflags:
  27 //     1 = start disabled (needs to be triggered to activate)
  28 //     2 = indicate damage
  29 // notes:
  30 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  31 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  32 //   want that!
  33
  34 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  35
  36 //
  37 // func_breakable
  38 // - basically func_assault_destructible for general gameplay use
  39 //
  40 void LaunchDebris (string debrisname, vector force) =
  41 {
  42         local   entity dbr;
  43
  44         dbr = spawn();
  45         setorigin(dbr, self.absmin
  46                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  47                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  48                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z));
  49         setmodel (dbr, debrisname );
  50         dbr.skin = self.debrisskin;
  51         dbr.colormap = self.colormap; // inherit team colors
  52         dbr.owner = self; // do not be affected by our own explosion
  53         dbr.movetype = self.debrismovetype;
  54         dbr.solid = self.debrissolid;
  55         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  56                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  57         dbr.velocity_x = self.debrisvelocity_x + self.debrisvelocityjitter_x * crandom();
  58         dbr.velocity_y = self.debrisvelocity_y + self.debrisvelocityjitter_y * crandom();
  59         dbr.velocity_z = self.debrisvelocity_z + self.debrisvelocityjitter_z * crandom();
  60         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  61         dbr.avelocity_x = random()*self.debrisavelocityjitter_x;
  62         dbr.avelocity_y = random()*self.debrisavelocityjitter_y;
  63         dbr.avelocity_z = random()*self.debrisavelocityjitter_z;
  64         dbr.damageforcescale = self.debrisdamageforcescale;
  65         if(dbr.damageforcescale)
  66                 dbr.takedamage = DAMAGE_YES;
  67         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  68 };
  69
  70 void func_breakable_colormod()
  71 {
  72         float h;
  73         if not(self.spawnflags & 2)
  74                 return;
  75         h = self.health / self.max_health;
  76         if(h < 0.25)
  77                 self.colormod = '1 0 0';
  78         else if(h <= 0.75)
  79                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  80         else
  81                 self.colormod = '1 1 1';
  82 }
  83
  84 void func_breakable_look_destroyed()
  85 {
  86         local float floor_z;
  87
  88         if(self.mdl_dead == "")
  89                 self.model = "";
  90         else {
  91                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  92                         floor_z = self.absmin_z;
  93                         setorigin(self,((self.absmax+self.absmin)*.5));
  94                         self.origin_z = floor_z;
  95                 }
  96                 setmodel(self, self.mdl_dead);
  97         }
  98
  99         self.solid = SOLID_NOT;
 100 }
 101
 102 void func_breakable_look_restore()
 103 {
 104         setmodel(self, self.mdl);
 105         self.solid = SOLID_BSP;
 106 }
 107
 108 void func_breakable_behave_destroyed()
 109 {
 110         self.health = self.max_health;
 111         self.takedamage = DAMAGE_NO;
 112         self.event_damage = SUB_Null;
 113         self.state = 1;
 114         func_breakable_colormod();
 115 }
 116
 117 void func_breakable_behave_restore()
 118 {
 119         self.health = self.max_health;
 120         self.takedamage = DAMAGE_AIM;
 121         self.event_damage = func_breakable_damage;
 122         self.state = 0;
 123         func_breakable_colormod();
 124 }
 125
 126 void func_breakable_destroyed()
 127 {
 128         func_breakable_look_destroyed();
 129         func_breakable_behave_destroyed();
 130 }
 131
 132 void func_breakable_restore()
 133 {
 134         func_breakable_look_restore();
 135         func_breakable_behave_restore();
 136 }
 137
 138 vector debrisforce; // global, set before calling this
 139 void func_breakable_destroy() {
 140         float n, i;
 141         string oldmsg;
 142
 143         activator = self.owner;
 144
 145         // now throw around the debris
 146         n = tokenize_console(self.debris);
 147         for(i = 0; i < n; ++i)
 148                 LaunchDebris(argv(i), debrisforce);
 149
 150         func_breakable_destroyed();
 151
 152         if(self.noise)
 153                 sound (self, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 154
 155         if(self.dmg)
 156                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, self.dmg_force, DEATH_HURTTRIGGER, world);
 157
 158         if(self.cnt)
 159                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 160
 161         oldmsg = self.message;
 162         self.message = "";
 163         SUB_UseTargets();
 164         self.message = oldmsg;
 165 }
 166
 167 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 168 {
 169         if(self.state == 1)
 170                 return;
 171         if(self.spawnflags & DOOR_NOSPLASH)
 172                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 173                         return;
 174         if(self.team)
 175                 if(attacker.team == self.team)
 176                         return;
 177         if(self.sprite)
 178                 WaypointSprite_Ping(self.sprite);
 179         self.health = self.health - damage;
 180         func_breakable_colormod();
 181
 182         if(self.health <= 0)
 183         {
 184                 debrisforce = force;
 185                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 186         }
 187 }
 188
 189 void func_breakable_reset()
 190 {
 191         self.team = self.team_saved;
 192         func_breakable_look_restore();
 193         if(self.spawnflags & 1)
 194                 func_breakable_behave_destroyed();
 195         else
 196                 func_breakable_behave_restore();
 197 }
 198
 199 // destructible walls that can be used to trigger target_objective_decrease
 200 void spawnfunc_func_breakable() {
 201         float n, i;
 202         if(!self.health)
 203                 self.health = 100;
 204         self.max_health = self.health;
 205
 206         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 207         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 208         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 209         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 210         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 211         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 212         if(!self.debristime) self.debristime = 3.5;
 213         if(!self.debristimejitter) self.debristime = 2.5;
 214
 215         if(self.mdl != "")
 216                 self.cnt = particleeffectnum(self.mdl);
 217         if(self.count == 0)
 218                 self.count = 1;
 219
 220         if(!self.message)
 221                 self.message = "got too close to an explosion";
 222         if(!self.message2)
 223                 self.message2 = "was pushed into an explosion by";
 224         if(!self.dmg_radius)
 225                 self.dmg_radius = 150;
 226         if(!self.dmg_force)
 227                 self.dmg_force = 200;
 228
 229         self.mdl = self.model;
 230         SetBrushEntityModel();
 231
 232         self.use = func_breakable_restore;
 233
 234         // precache all the models
 235         if (self.mdl_dead)
 236                 precache_model(self.mdl_dead);
 237         n = tokenize_console(self.debris);
 238         for(i = 0; i < n; ++i)
 239                 precache_model(argv(i));
 240         if(self.noise)
 241                 precache_sound(self.noise);
 242
 243         self.team_saved = self.team;
 244
 245         self.reset = func_breakable_reset;
 246         func_breakable_reset();
 247 }