qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 312 {
 313         float handled, hits;
 314         if(DEATH_ISSPECIAL(deathtype))
 315         {
 316                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 317                         { if(deathtype == max(0, name)) \
 318                         { \
 319                                 #if msg_death != NO_MSG \
 320                                         if not(murder) \
 321                                         { \
 322                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 323                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 324                                                 ++handled; \
 325                                         } \
 326                                 #endif \
 327                                 #if msg_death_by != NO_MSG \
 328                                         if(murder) \
 329                                         { \
 330                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 331                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 332                                                 ++handled; \
 333                                         } \
 334                                 #endif \
 335                                 ++hits; \
 336                         } }
 337
 338                 DEATHTYPES
 339                 #undef DEATHTYPE
 340
 341                 if not(hits)
 342                 {
 343                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 344                         //return;
 345                 }
 346                 if not(handled)
 347                 {
 348                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 349                         return;
 350                 }
 351         }
 352 }
 353 float w_deathtype;
 354 void Obituary_WeaponDeath(float murder, float deathtype, string s1, string s2)
 355 {
 356         float death_weapon = DEATH_WEAPONOF(deathtype);
 357
 358         if(death_weapon)
 359         {
 360                 w_deathtype = deathtype;
 361                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 362                 w_deathtype = FALSE;
 363
 364                 if(death_message) { Send_Notification(world, MSG_ALL, MSG_WEAPON, death_message, s1, s2, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 365                 else { print(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 366         }
 367 }
 368
 369 .float FRAG_VERBOSE;
 370
 371 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 372 {
 373         // Sanity check
 374         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 375
 376         // Declarations
 377         string  s, a, msg;
 378         float w, type;
 379
 380         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 381         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 382         float notif_firstblood;
 383
 384         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 385
 386         // =======
 387         // SUICIDE
 388         // =======
 389         if(targ == attacker)
 390         {
 391                 if(DEATH_ISSPECIAL(deathtype))
 392                 {
 393                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 394                         {
 395                                 s1 = targ.netname;
 396                                 f1 = targ.team;
 397                         }
 398                         else
 399                         {
 400                                 switch(deathtype)
 401                                 {
 402                                         case DEATH_MIRRORDAMAGE:
 403                                         {
 404                                                 s1 = targ.netname;
 405                                                 f1 = targ.killcount;
 406                                                 break;
 407                                         }
 408
 409                                         default:
 410                                         {
 411                                                 s1 = targ.netname;
 412                                                 f1 = targ.killcount;
 413                                                 s2 = NO_STR_ARG;
 414                                                 f2 = f3 = NO_FL_ARG;
 415                                                 break;
 416                                         }
 417                                 }
 418                                 LogDeath("suicide", deathtype, targ, targ);
 419                                 GiveFrags(attacker, targ, -1, deathtype);
 420                         }
 421                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 422                 }
 423                 else if(DEATH_WEAPONOF(deathtype))
 424                 {
 425                         Obituary_WeaponDeath(FALSE, deathtype, targ.netname, NO_STR_ARG);
 426                 }
 427                 else
 428                 {
 429                         backtrace("SUICIDE: what the hell happened here?\n");
 430                 }
 431         }
 432
 433         // ======
 434         // MURDER
 435         // ======
 436         else if(attacker.classname == "player")
 437         {
 438                 s1 = attacker.netname;
 439                 s2 = targ.netname;
 440
 441                 // TODO: ADD REAL CHECK HERE!
 442                 attacker.FRAG_VERBOSE = TRUE;
 443                 targ.FRAG_VERBOSE = TRUE;
 444
 445                 if(!IsDifferentTeam(attacker, targ))
 446                 {
 447                         LogDeath("tk", deathtype, attacker, targ);
 448                         GiveFrags(attacker, targ, -1, deathtype);
 449
 450                         attacker.killcount = 0;
 451
 452                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 453                         Send_Notification(targ, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 454                         Send_Notification(world, MSG_ALL, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 455
 456                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 457                         // No need for specific death/weapon messages...
 458                 }
 459                 else
 460                 {
 461                         LogDeath("frag", deathtype, attacker, targ);
 462                         GiveFrags(attacker, targ, 1, deathtype);
 463
 464                         attacker.taunt_soundtime = time + 1;
 465                         attacker.killcount = attacker.killcount + 1;
 466                         if(targ.killcount > 2) { Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE); }
 467
 468                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 469                                 case numa: \
 470                                 { \
 471                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 472                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 473                                         break; \
 474                                 }
 475                         switch(attacker.killcount)
 476                         {
 477                                 ADD_ACHIEVEMENT_CASE(3, 03)
 478                                 ADD_ACHIEVEMENT_CASE(5, 05)
 479                                 ADD_ACHIEVEMENT_CASE(10, 10)
 480                                 ADD_ACHIEVEMENT_CASE(15, 15)
 481                                 ADD_ACHIEVEMENT_CASE(20, 20)
 482                                 ADD_ACHIEVEMENT_CASE(25, 25)
 483                                 ADD_ACHIEVEMENT_CASE(30, 30)
 484                                 default: break;
 485                         }
 486                         #undef ADD_ACHIEVEMENT_CASE
 487
 488                         if(!checkrules_firstblood)
 489                         {
 490                                 checkrules_firstblood = TRUE;
 491                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 492                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 493                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 494                         }
 495
 496                         if(notif_firstblood) // first blood, no kill sprees yet
 497                         {
 498                                 if(targ.istypefrag)
 499                                 {
 500                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 501                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 502
 503                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 504                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 505                                 }
 506                                 else
 507                                 {
 508                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 509                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 510
 511                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 512                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 513                                 }
 514                         }
 515                         else // normal frags, kill sprees listed
 516                         {
 517                                 if(targ.istypefrag)
 518                                 {
 519                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 520                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 521
 522                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 523                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 524                                 }
 525                                 else
 526                                 {
 527                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 528                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 529
 530                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 531                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 532                                 }
 533                         }
 534
 535                         if(DEATH_WEAPONOF(deathtype)) { Obituary_WeaponDeath(TRUE, deathtype, targ.netname, attacker.netname); }
 536                         else { Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG); }
 537                 }
 538         }
 539
 540         // =============
 541         // ACCIDENT/TRAP
 542         // =============
 543         else
 544         {
 545                 switch(deathtype)
 546                 {
 547                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 548                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 549                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 550                         /*case DEATH_HURTTRIGGER:
 551                         {
 552                                 s1 = targ.netname;
 553                                 s2 = inflictor.message;
 554                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 555                                 break;
 556                         }*/
 557
 558                         case DEATH_CUSTOM:
 559                         {
 560                                 s1 = targ.netname;
 561                                 s2 = deathmessage;
 562                                 f1 = targ.killcount;
 563                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 564                                 f2 = f3 = NO_FL_ARG;
 565                                 break;
 566                         }
 567
 568                         default:
 569                         {
 570                                 s1 = targ.netname;
 571                                 f1 = targ.killcount;
 572                                 s2 = NO_STR_ARG;
 573                                 f2 = f3 = NO_FL_ARG;
 574                                 break;
 575                         }
 576                 }
 577
 578                 LogDeath("accident", deathtype, targ, targ);
 579                 GiveFrags(targ, targ, -1, deathtype);
 580
 581                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 582                 {
 583                         AnnounceTo(targ, "botlike");
 584                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 585                 }
 586
 587                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 588         }
 589
 590         // Set final information for the death
 591         targ.death_origin = targ.origin;
 592         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 593         if(targ.killcount) { targ.killcount = 0; }
 594 }
 595
 596 // these are updated by each Damage call for use in button triggering and such
 597 entity damage_targ;
 598 entity damage_inflictor;
 599 entity damage_attacker;
 600
 601 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 602 {
 603         float mirrordamage;
 604         float mirrorforce;
 605         float teamdamage0;
 606         entity attacker_save;
 607         mirrordamage = 0;
 608         mirrorforce = 0;
 609
 610         if (gameover || targ.killcount == -666)
 611                 return;
 612
 613         entity oldself;
 614         oldself = self;
 615         self = targ;
 616         damage_targ = targ;
 617         damage_inflictor = inflictor;
 618         damage_attacker = attacker;
 619                 attacker_save = attacker;
 620
 621         if(targ.classname == "player")
 622                 if(targ.hook)
 623                         if(targ.hook.aiment)
 624                                 if(targ.hook.aiment == attacker)
 625                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 626
 627         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 628         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 629         {
 630                 if(targ.classname == "player")
 631                         if not(IsDifferentTeam(targ, attacker))
 632                         {
 633                                 self = oldself;
 634                                 return;
 635                         }
 636         }
 637
 638         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 639         {
 640                 // These are ALWAYS lethal
 641                 // No damage modification here
 642                 // Instead, prepare the victim for his death...
 643                 targ.armorvalue = 0;
 644                 targ.spawnshieldtime = 0;
 645                 targ.health = 0.9; // this is < 1
 646                 targ.flags -= targ.flags & FL_GODMODE;
 647                 damage = 100000;
 648         }
 649         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 650         {
 651                 // no processing
 652         }
 653         else
 654         {
 655                 /*
 656                 skill based bot damage? gtfo. (tZork)
 657                 if (targ.classname == "player")
 658                 if (attacker.classname == "player")
 659                 if (!targ.isbot)
 660                 if (attacker.isbot)
 661                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 662         */
 663
 664                 // nullify damage if teamplay is on
 665                 if(deathtype != DEATH_TELEFRAG)
 666                 if(attacker.classname == "player")
 667                 {
 668                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 669                         {
 670                                 damage = 0;
 671                                 force = '0 0 0';
 672                         }
 673                         else if(!IsDifferentTeam(attacker, targ))
 674                         {
 675                                 if(autocvar_teamplay_mode == 1)
 676                                         damage = 0;
 677                                 else if(attacker != targ)
 678                                 {
 679                                         if(autocvar_teamplay_mode == 3)
 680                                                 damage = 0;
 681                                         else if(autocvar_teamplay_mode == 4)
 682                                         {
 683                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 684                                                 {
 685                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 686                                                         attacker.dmg_team = attacker.dmg_team + damage;
 687                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 688                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 689                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 690                                                         if(g_minstagib)
 691                                                         {
 692                                                                 if(autocvar_g_friendlyfire == 0)
 693                                                                         damage = 0;
 694                                                         }
 695                                                         else if(g_ca)
 696                                                                 damage = 0;
 697                                                         else
 698                                                                 damage = autocvar_g_friendlyfire * damage;
 699                                                         // mirrordamage will be used LATER
 700
 701                                                         if(autocvar_g_mirrordamage_virtual)
 702                                                         {
 703                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 704                                                                 attacker.dmg_take += v_x;
 705                                                                 attacker.dmg_save += v_y;
 706                                                                 attacker.dmg_inflictor = inflictor;
 707                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 708                                                                 mirrorforce = 0;
 709                                                         }
 710
 711                                                         if(autocvar_g_friendlyfire_virtual)
 712                                                         {
 713                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 714                                                                 targ.dmg_take += v_x;
 715                                                                 targ.dmg_save += v_y;
 716                                                                 targ.dmg_inflictor = inflictor;
 717                                                                 damage = 0;
 718                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 719                                                                         force = '0 0 0';
 720                                                         }
 721                                                 }
 722                                                 else
 723                                                         damage = 0;
 724                                         }
 725                                 }
 726                         }
 727                 }
 728
 729                 if(targ.classname == "player")
 730                 if(attacker.classname == "player")
 731                 if(attacker != targ)
 732                 {
 733                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 734                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 735                 }
 736
 737                 if(targ.classname == "player")
 738                 if (g_minstagib)
 739                 {
 740                         if ((deathtype == DEATH_FALL)  ||
 741                                 (deathtype == DEATH_DROWN) ||
 742                                 (deathtype == DEATH_SLIME) ||
 743                                 (deathtype == DEATH_LAVA)  ||
 744                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 745                         {
 746                                 self = oldself;
 747                                 return;
 748                         }
 749                         if(damage > 0)
 750                             damage = 10000;
 751                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 752                         {
 753                                 targ.armorvalue -= 1;
 754                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 755                                 damage = 0;
 756                                 targ.hitsound += 1;
 757                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 758                         }
 759                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 760                         {
 761                                 damage = 0;
 762                                 mirrordamage = 0;
 763                                 if (targ != attacker)
 764                                 {
 765                                         if ((targ.health >= 1) && (targ.classname == "player"))
 766                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 767                                         force = '0 0 0';
 768                                         // keep mirrorforce
 769                                         attacker = targ;
 770                                 }
 771                         }
 772                 }
 773
 774                 if not(DEATH_ISSPECIAL(deathtype))
 775                 {
 776                         damage *= g_weapondamagefactor;
 777                         mirrordamage *= g_weapondamagefactor;
 778                         force = force * g_weaponforcefactor;
 779                         mirrorforce *= g_weaponforcefactor;
 780                 }
 781
 782                 // should this be changed at all? If so, in what way?
 783                 frag_attacker = attacker;
 784                 frag_target = targ;
 785                 frag_damage = damage;
 786                 frag_force = force;
 787         frag_deathtype = deathtype;
 788                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 789                 damage = frag_damage;
 790                 force = frag_force;
 791
 792                 // apply strength multiplier
 793                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 794                 {
 795                         if(targ == attacker)
 796                         {
 797                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 798                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 799                         }
 800                         else
 801                         {
 802                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 803                                 force = force * autocvar_g_balance_powerup_strength_force;
 804                         }
 805                 }
 806
 807                 // apply invincibility multiplier
 808                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 809                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 810
 811                 if (targ == attacker)
 812                 {
 813                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 814                                 damage = 0;
 815                         else
 816                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 817                 }
 818
 819                 if(g_runematch)
 820                 {
 821                         // apply strength rune
 822                         if (attacker.runes & RUNE_STRENGTH)
 823                         {
 824                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 825                                 {
 826                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 827                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 828                                 }
 829                                 else
 830                                 {
 831                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 832                                         force = force * autocvar_g_balance_rune_strength_force;
 833                                 }
 834                         }
 835                         else if (attacker.runes & CURSE_WEAK)
 836                         {
 837                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 838                                 force = force * autocvar_g_balance_curse_weak_force;
 839                         }
 840
 841                         // apply defense rune
 842                         if (targ.runes & RUNE_DEFENSE)
 843                         {
 844                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 845                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 846                                 else
 847                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 848                         }
 849                         else if (targ.runes & CURSE_VULNER)
 850                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 851                 }
 852
 853                 // count the damage
 854                 if(attacker)
 855                 if(!targ.deadflag)
 856                 if(targ.takedamage == DAMAGE_AIM)
 857                 if(targ != attacker)
 858                 {
 859                         if(damage_headshotbonus)
 860                         {
 861                                 if(targ.classname == "player")
 862                                 {
 863                                         // HEAD SHOT:
 864                                         // find height of hit on player axis
 865                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 866                                         vector headmins, headmaxs, org;
 867                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 868                                         headmins = org + GetHeadshotMins(targ);
 869                                         headmaxs = org + GetHeadshotMaxs(targ);
 870                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 871                                         {
 872                                                 deathtype |= HITTYPE_HEADSHOT;
 873                                         }
 874                                 }
 875                                 else if(targ.classname == "turret_head")
 876                                 {
 877                                         deathtype |= HITTYPE_HEADSHOT;
 878                                 }
 879                                 if(deathtype & HITTYPE_HEADSHOT)
 880                                         if(damage_headshotbonus > 0)
 881                                                 damage *= 1 + damage_headshotbonus;
 882                         }
 883
 884                         entity victim;
 885                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 886                                 victim = targ.owner;
 887                         else
 888                                 victim = targ;
 889
 890                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 891                         {
 892                                 if(IsDifferentTeam(victim, attacker))
 893                                 {
 894                                         if(damage > 0)
 895                                         {
 896                                                 if(deathtype != DEATH_FIRE)
 897                                                 {
 898                                                         if(victim.BUTTON_CHAT)
 899                                                                 attacker.typehitsound += 1;
 900                                                         else
 901                                                                 attacker.hitsound += 1;
 902                                                 }
 903
 904                                                 damage_goodhits += 1;
 905                                                 damage_gooddamage += damage;
 906
 907                                                 if not(DEATH_ISSPECIAL(deathtype))
 908                                                 {
 909                                                         if(targ.classname == "player") // don't do this for vehicles
 910                                                         if(!g_minstagib)
 911                                                         if(IsFlying(victim))
 912                                                                 yoda = 1;
 913
 914                                                         if(g_minstagib)
 915                                                         if(victim.items & IT_STRENGTH)
 916                                                                 yoda = 1;
 917
 918                                                         if(deathtype & HITTYPE_HEADSHOT)
 919                                                                 headshot = 1;
 920                                                 }
 921                                         }
 922                                 }
 923                                 else
 924                                 {
 925                                         if(deathtype != DEATH_FIRE)
 926                                         {
 927                                                 attacker.typehitsound += 1;
 928                                         }
 929                                         if(mirrordamage > 0)
 930                                                 if(time > attacker.teamkill_complain)
 931                                                 {
 932                                                         attacker.teamkill_complain = time + 5;
 933                                                         attacker.teamkill_soundtime = time + 0.4;
 934                                                         attacker.teamkill_soundsource = targ;
 935                                                 }
 936                                 }
 937                         }
 938                 }
 939         }
 940
 941         // apply push
 942         if (self.damageforcescale)
 943         if (vlen(force))
 944         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 945         {
 946                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 947                 if(self.movetype == MOVETYPE_PHYSICS)
 948                 {
 949                         entity farcent;
 950                         farcent = spawn();
 951                         farcent.classname = "farce";
 952                         farcent.enemy = self;
 953                         farcent.movedir = farce * 10;
 954                         if(self.mass)
 955                                 farcent.movedir = farcent.movedir * self.mass;
 956                         farcent.origin = hitloc;
 957                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 958                         farcent.nextthink = time + 0.1;
 959                         farcent.think = SUB_Remove;
 960                 }
 961                 else
 962                         self.velocity = self.velocity + farce;
 963                 self.flags &~= FL_ONGROUND;
 964                 UpdateCSQCProjectile(self);
 965         }
 966         // apply damage
 967         if (damage != 0 || (self.damageforcescale && vlen(force)))
 968         if (self.event_damage)
 969                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 970         self = oldself;
 971
 972         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 973         {
 974                 if(g_runematch)
 975                 {
 976                         if (attacker.runes & RUNE_VAMPIRE)
 977                         {
 978                         // apply vampire rune
 979                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 980                                 {
 981                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 982                                         attacker.health = bound(
 983                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 984                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 985                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 986                                 }
 987                                 else
 988                                 {
 989                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 990                                         attacker.health = bound(
 991                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 992                                                                                         // empathy won't let you gain health in the same way...
 993                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 994                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 995                                         }
 996                         }
 997                         // apply empathy curse
 998                         else if (attacker.runes & CURSE_EMPATHY)
 999                         {
1000                                 attacker.health = bound(
1001                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1002                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1003                                         attacker.health);
1004                         }
1005                 }
1006         }
1007
1008         // apply mirror damage if any
1009         if(mirrordamage > 0 || mirrorforce > 0)
1010         {
1011                 attacker = attacker_save;
1012                 if(g_minstagib)
1013                 if(mirrordamage > 0)
1014                 {
1015                         // just lose extra LIVES, don't kill the player for mirror damage
1016                         if(attacker.armorvalue > 0)
1017                         {
1018                                 attacker.armorvalue = attacker.armorvalue - 1;
1019                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1020                                 attacker.hitsound += 1;
1021                         }
1022                         mirrordamage = 0;
1023                 }
1024
1025                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1026                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1027         }
1028 }
1029
1030 float RadiusDamage_running;
1031 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1032         // Returns total damage applies to creatures
1033 {
1034         entity  targ;
1035         vector  blastorigin;
1036         vector  force;
1037         float   total_damage_to_creatures;
1038         entity  next;
1039         float   tfloordmg;
1040         float   tfloorforce;
1041
1042         float stat_damagedone;
1043
1044         if(RadiusDamage_running)
1045         {
1046                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1047                 return 0;
1048         }
1049
1050         RadiusDamage_running = 1;
1051
1052         tfloordmg = autocvar_g_throughfloor_damage;
1053         tfloorforce = autocvar_g_throughfloor_force;
1054
1055         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1056         total_damage_to_creatures = 0;
1057
1058         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1059                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1060                 {
1061                         force = inflictor.velocity;
1062                         if(vlen(force) == 0)
1063                                 force = '0 0 -1';
1064                         else
1065                                 force = normalize(force);
1066                         if(forceintensity >= 0)
1067                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1068                         else
1069                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1070                 }
1071
1072         stat_damagedone = 0;
1073
1074         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1075         while (targ)
1076         {
1077                 next = targ.chain;
1078                 if (targ != inflictor)
1079                         if (ignore != targ) if(targ.takedamage)
1080                         {
1081                                 vector nearest;
1082                                 vector diff;
1083                                 float power;
1084
1085                                 // LordHavoc: measure distance to nearest point on target (not origin)
1086                                 // (this guarentees 100% damage on a touch impact)
1087                                 nearest = targ.WarpZone_findradius_nearest;
1088                                 diff = targ.WarpZone_findradius_dist;
1089                                 // round up a little on the damage to ensure full damage on impacts
1090                                 // and turn the distance into a fraction of the radius
1091                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1092                                 //bprint(" ");
1093                                 //bprint(ftos(power));
1094                                 //if (targ == attacker)
1095                                 //      print(ftos(power), "\n");
1096                                 if (power > 0)
1097                                 {
1098                                         float finaldmg;
1099                                         if (power > 1)
1100                                                 power = 1;
1101                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1102                                         if (finaldmg > 0)
1103                                         {
1104                                                 float a;
1105                                                 float c;
1106                                                 vector hitloc;
1107                                                 vector myblastorigin;
1108                                                 vector center;
1109
1110                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1111
1112                                                 // if it's a player, use the view origin as reference
1113                                                 center = CENTER_OR_VIEWOFS(targ);
1114
1115                                                 force = normalize(center - myblastorigin);
1116                                                 force = force * (finaldmg / coredamage) * forceintensity;
1117                                                 hitloc = nearest;
1118
1119                                                 if(targ != directhitentity)
1120                                                 {
1121                                                         float hits;
1122                                                         float total;
1123                                                         float hitratio;
1124                                                         float mininv_f, mininv_d;
1125
1126                                                         // test line of sight to multiple positions on box,
1127                                                         // and do damage if any of them hit
1128                                                         hits = 0;
1129
1130                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1131                                                         // so for a given max stddev:
1132                                                         // n = (1 / (2 * max stddev of hitratio))^2
1133
1134                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1135                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1136
1137                                                         if(autocvar_g_throughfloor_debug)
1138                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1139
1140                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1141
1142                                                         if(autocvar_g_throughfloor_debug)
1143                                                                 print(sprintf(" steps=%f", total));
1144
1145                                                         if (targ.classname == "player")
1146                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1147                                                         else
1148                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1149
1150                                                         if(autocvar_g_throughfloor_debug)
1151                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1152
1153                                                         for(c = 0; c < total; ++c)
1154                                                         {
1155                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1156                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1157                                                                 if (trace_fraction == 1 || trace_ent == targ)
1158                                                                 {
1159                                                                         ++hits;
1160                                                                         if (hits > 1)
1161                                                                                 hitloc = hitloc + nearest;
1162                                                                         else
1163                                                                                 hitloc = nearest;
1164                                                                 }
1165                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1166                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1167                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1168                                                         }
1169
1170                                                         nearest = hitloc * (1 / max(1, hits));
1171                                                         hitratio = (hits / total);
1172                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1173                                                         finaldmg = finaldmg * a;
1174                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1175                                                         force = force * a;
1176
1177                                                         if(autocvar_g_throughfloor_debug)
1178                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1179                                                 }
1180
1181                                                 // laser force adjustments :P
1182                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1183                                                 {
1184                                                         if (targ == attacker)
1185                                                         {
1186                                                                 vector vel;
1187
1188                                                                 float force_zscale;
1189                                                                 float force_velocitybiasramp;
1190                                                                 float force_velocitybias;
1191
1192                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1193                                                                 if(deathtype & HITTYPE_SECONDARY)
1194                                                                 {
1195                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1196                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1197                                                                 }
1198                                                                 else
1199                                                                 {
1200                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1201                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1202                                                                 }
1203
1204                                                                 vel = targ.velocity;
1205                                                                 vel_z = 0;
1206                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1207                                                                 force =
1208                                                                         vlen(force)
1209                                                                         *
1210                                                                         normalize(normalize(force) + vel);
1211
1212                                                                 force_z *= force_zscale;
1213                                                         }
1214                                                         else
1215                                                         {
1216                                                                 if(deathtype & HITTYPE_SECONDARY)
1217                                                                 {
1218                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1219                                                                 }
1220                                                                 else
1221                                                                 {
1222                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1223                                                                 }
1224                                                         }
1225                                                 }
1226
1227                                                 //if (targ == attacker)
1228                                                 //{
1229                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1230                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1231                                                 //      print(" (", ftos(a), ")\n");
1232                                                 //}
1233                                                 if(finaldmg || vlen(force))
1234                                                 {
1235                                                         if(targ.iscreature)
1236                                                         {
1237                                                                 total_damage_to_creatures += finaldmg;
1238
1239                                                                 if(accuracy_isgooddamage(attacker, targ))
1240                                                                         stat_damagedone += finaldmg;
1241                                                         }
1242
1243                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1244                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1245                                                         else
1246                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1247                                                 }
1248                                         }
1249                                 }
1250                         }
1251                 targ = next;
1252         }
1253
1254         RadiusDamage_running = 0;
1255
1256         if(!DEATH_ISSPECIAL(deathtype))
1257                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1258
1259         return total_damage_to_creatures;
1260 }
1261
1262 .float fire_damagepersec;
1263 .float fire_endtime;
1264 .float fire_deathtype;
1265 .entity fire_owner;
1266 .float fire_hitsound;
1267 .entity fire_burner;
1268
1269 void fireburner_think();
1270
1271 float Fire_IsBurning(entity e)
1272 {
1273         return (time < e.fire_endtime);
1274 }
1275
1276 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1277 {
1278         float dps;
1279         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1280
1281         if(e.classname == "player")
1282         {
1283                 if(e.deadflag)
1284                         return -1;
1285         }
1286         else
1287         {
1288                 if(!e.fire_burner)
1289                 {
1290                         // print("adding a fire burner to ", e.classname, "\n");
1291                         e.fire_burner = spawn();
1292                         e.fire_burner.classname = "fireburner";
1293                         e.fire_burner.think = fireburner_think;
1294                         e.fire_burner.nextthink = time;
1295                         e.fire_burner.owner = e;
1296                 }
1297         }
1298
1299         t = max(t, 0.1);
1300         dps = d / t;
1301         if(Fire_IsBurning(e))
1302         {
1303                 mintime = e.fire_endtime - time;
1304                 maxtime = max(mintime, t);
1305
1306                 mindps = e.fire_damagepersec;
1307                 maxdps = max(mindps, dps);
1308
1309                 if(maxtime > mintime || maxdps > mindps)
1310                 {
1311                         // Constraints:
1312
1313                         // damage we have right now
1314                         mindamage = mindps * mintime;
1315
1316                         // damage we want to get
1317                         maxdamage = mindamage + d;
1318
1319                         // but we can't exceed maxtime * maxdps!
1320                         totaldamage = min(maxdamage, maxtime * maxdps);
1321
1322                         // LEMMA:
1323                         // Look at:
1324                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1325                         // We see:
1326                         // totaldamage <= maxtime * maxdps
1327                         // ==> totaldamage / maxdps <= maxtime.
1328                         // We also see:
1329                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1330                         //                     >= min(mintime, maxtime)
1331                         // ==> totaldamage / maxdps >= mintime.
1332
1333                         /*
1334                         // how long do we damage then?
1335                         // at least as long as before
1336                         // but, never exceed maxdps
1337                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1338                         */
1339
1340                         // alternate:
1341                         // at most as long as maximum allowed
1342                         // but, never below mindps
1343                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1344
1345                         // assuming t > mintime, dps > mindps:
1346                         // we get d = t * dps = maxtime * maxdps
1347                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1348                         // totaldamage / maxdps = maxtime
1349                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1350                         // FROM THIS:
1351                         // a) totaltime = max(mintime, maxtime) = maxtime
1352                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1353
1354                         // assuming t <= mintime:
1355                         // we get maxtime = mintime
1356                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1357                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1358
1359                         // assuming dps <= mindps:
1360                         // we get mindps = maxdps.
1361                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1362                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1363                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1364
1365                         e.fire_damagepersec = totaldamage / totaltime;
1366                         e.fire_endtime = time + totaltime;
1367                         if(totaldamage > 1.2 * mindamage)
1368                         {
1369                                 e.fire_deathtype = dt;
1370                                 if(e.fire_owner != o)
1371                                 {
1372                                         e.fire_owner = o;
1373                                         e.fire_hitsound = FALSE;
1374                                 }
1375                         }
1376                         if(accuracy_isgooddamage(o, e))
1377                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1378                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1379                 }
1380                 else
1381                         return 0;
1382         }
1383         else
1384         {
1385                 e.fire_damagepersec = dps;
1386                 e.fire_endtime = time + t;
1387                 e.fire_deathtype = dt;
1388                 e.fire_owner = o;
1389                 e.fire_hitsound = FALSE;
1390                 if(accuracy_isgooddamage(o, e))
1391                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1392                 return d;
1393         }
1394 }
1395
1396 void Fire_ApplyDamage(entity e)
1397 {
1398         float t, d, hi, ty;
1399         entity o;
1400
1401         if not(Fire_IsBurning(e))
1402                 return;
1403
1404         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1405         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1406                 o = e.fire_owner;
1407
1408         // water and slime stop fire
1409         if(e.waterlevel)
1410         if(e.watertype != CONTENT_LAVA)
1411                 e.fire_endtime = 0;
1412
1413         // ice stops fire
1414         if(e.freezetag_frozen)
1415                 e.fire_endtime = 0;
1416
1417         t = min(frametime, e.fire_endtime - time);
1418         d = e.fire_damagepersec * t;
1419
1420         hi = e.fire_owner.hitsound;
1421         ty = e.fire_owner.typehitsound;
1422         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1423         if(e.fire_hitsound && e.fire_owner)
1424         {
1425                 e.fire_owner.hitsound = hi;
1426                 e.fire_owner.typehitsound = ty;
1427         }
1428         e.fire_hitsound = TRUE;
1429
1430         if not(IS_INDEPENDENT_PLAYER(e))
1431         FOR_EACH_PLAYER(other) if(e != other)
1432         {
1433                 if(other.classname == "player")
1434                 if(other.deadflag == DEAD_NO)
1435                 if not(IS_INDEPENDENT_PLAYER(other))
1436                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1437                 {
1438                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1439                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1440                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1441                 }
1442         }
1443 }
1444
1445 void Fire_ApplyEffect(entity e)
1446 {
1447         if(Fire_IsBurning(e))
1448                 e.effects |= EF_FLAME;
1449         else
1450                 e.effects &~= EF_FLAME;
1451 }
1452
1453 void fireburner_think()
1454 {
1455         // for players, this is done in the regular loop
1456         if(wasfreed(self.owner))
1457         {
1458                 remove(self);
1459                 return;
1460         }
1461         Fire_ApplyEffect(self.owner);
1462         if(!Fire_IsBurning(self.owner))
1463         {
1464                 self.owner.fire_burner = world;
1465                 remove(self);
1466                 return;
1467         }
1468         Fire_ApplyDamage(self.owner);
1469         self.nextthink = time;
1470 }