qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 void Obituary_SpecialDeath(
 263         entity notif_target,
 264         float murder,
 265         float deathtype,
 266         string s1, string s2, string s3,
 267         float f1, float f2, float f3)
 268 {
 269         if(DEATH_ISSPECIAL(deathtype))
 270         {
 271                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 272                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 273
 274                 if(murder)
 275                 {
 276                         if(deathent.death_msgmurder)
 277                         {
 278                                 Send_Notification_WOVA(
 279                                         NOTIF_ONE,
 280                                         notif_target,
 281                                         MSG_MULTI,
 282                                         deathent.death_msgmurder.nent_id,
 283                                         s1, s2, s3, "",
 284                                         f1, f2, f3, 0
 285                                 );
 286                                 Send_Notification_WOVA(
 287                                         NOTIF_ALL_EXCEPT,
 288                                         notif_target,
 289                                         MSG_INFO,
 290                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 291                                         s1, s2, s3, "",
 292                                         f1, f2, f3, 0
 293                                 );
 294                         }
 295                 }
 296                 else
 297                 {
 298                         if(deathent.death_msgself)
 299                         {
 300                                 Send_Notification_WOVA(
 301                                         NOTIF_ONE,
 302                                         notif_target,
 303                                         MSG_MULTI,
 304                                         deathent.death_msgself.nent_id,
 305                                         s1, s2, s3, "",
 306                                         f1, f2, f3, 0
 307                                 );
 308                                 Send_Notification_WOVA(
 309                                         NOTIF_ALL_EXCEPT,
 310                                         notif_target,
 311                                         MSG_INFO,
 312                                         deathent.death_msgself.nent_msginfo.nent_id,
 313                                         s1, s2, s3, "",
 314                                         f1, f2, f3, 0
 315                                 );
 316                         }
 317                 }
 318         }
 319         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 320 }
 321
 322 float w_deathtype;
 323 float Obituary_WeaponDeath(
 324         entity notif_target,
 325         float murder,
 326         float deathtype,
 327         string s1, string s2, string s3,
 328         float f1, float f2)
 329 {
 330         float death_weapon = DEATH_WEAPONOF(deathtype);
 331         if(death_weapon)
 332         {
 333                 w_deathtype = deathtype;
 334                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 335                 w_deathtype = FALSE;
 336
 337                 if(death_message)
 338                 {
 339                         Send_Notification_WOVA(
 340                                 NOTIF_ONE,
 341                                 notif_target,
 342                                 MSG_MULTI,
 343                                 death_message,
 344                                 s1, s2, s3, "",
 345                                 f1, f2, 0, 0
 346                         );
 347                         Send_Notification_WOVA(
 348                                 NOTIF_ALL_EXCEPT,
 349                                 notif_target,
 350                                 MSG_INFO,
 351                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 352                                 s1, s2, s3, "",
 353                                 f1, f2, 0, 0
 354                         );
 355                 }
 356                 else
 357                 {
 358                         dprint(sprintf(
 359                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 360                                 deathtype,
 361                                 death_weapon
 362                         ));
 363                 }
 364
 365                 return TRUE;
 366         }
 367         return FALSE;
 368 }
 369
 370 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 371 {
 372         // Sanity check
 373         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 374
 375         // Declarations
 376         float notif_firstblood = FALSE;
 377         float kill_count_to_attacker, kill_count_to_target;
 378
 379         // Set final information for the death
 380         targ.death_origin = targ.origin;
 381         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 382         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 383
 384         #ifdef NOTIFICATIONS_DEBUG
 385         dprint(
 386                 sprintf(
 387                         "Obituary(%s, %s, %s, %s = %d);\n",
 388                         attacker.netname,
 389                         inflictor.netname,
 390                         targ.netname,
 391                         Deathtype_Name(deathtype),
 392                         deathtype
 393                 )
 394         );
 395         #endif
 396
 397         // =======
 398         // SUICIDE
 399         // =======
 400         if(targ == attacker)
 401         {
 402                 if(DEATH_ISSPECIAL(deathtype))
 403                 {
 404                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 405                         {
 406                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 407                         }
 408                         else
 409                         {
 410                                 switch(deathtype)
 411                                 {
 412                                         case DEATH_MIRRORDAMAGE:
 413                                         {
 414                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 415                                                 break;
 416                                         }
 417
 418                                         default:
 419                                         {
 420                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 421                                                 break;
 422                                         }
 423                                 }
 424                         }
 425                 }
 426                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 427                 {
 428                         backtrace("SUICIDE: what the hell happened here?\n");
 429                         return;
 430                 }
 431                 LogDeath("suicide", deathtype, targ, targ);
 432                 GiveFrags(attacker, targ, -1, deathtype);
 433         }
 434
 435         // ======
 436         // MURDER
 437         // ======
 438         else if(IS_PLAYER(attacker))
 439         {
 440                 if(!IsDifferentTeam(attacker, targ))
 441                 {
 442                         LogDeath("tk", deathtype, attacker, targ);
 443                         GiveFrags(attacker, targ, -1, deathtype);
 444
 445                         attacker.killcount = 0;
 446
 447                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 448                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 449                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 450
 451                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 452                         // No need for specific death/weapon messages...
 453                 }
 454                 else
 455                 {
 456                         LogDeath("frag", deathtype, attacker, targ);
 457                         GiveFrags(attacker, targ, 1, deathtype);
 458
 459                         attacker.taunt_soundtime = time + 1;
 460                         attacker.killcount = attacker.killcount + 1;
 461
 462                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 463                                 case counta: \
 464                                 { \
 465                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 466                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 467                                         break; \
 468                                 }
 469                         switch(attacker.killcount)
 470                         {
 471                                 KILL_SPREE_LIST
 472                                 default: break;
 473                         }
 474                         #undef SPREE_ITEM
 475
 476                         if(!checkrules_firstblood)
 477                         {
 478                                 checkrules_firstblood = TRUE;
 479                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 480                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 481                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 482
 483                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 484                                 kill_count_to_attacker = -1;
 485                                 kill_count_to_target = -2;
 486                         }
 487                         else
 488                         {
 489                                 kill_count_to_attacker = attacker.killcount;
 490                                 kill_count_to_target = 0;
 491                         }
 492
 493                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 494                         if(targ.istypefrag)
 495                         {
 496                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 497                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 498                                 else
 499                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 500
 501                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 502                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 503                                 else
 504                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 505                         }
 506                         else
 507                         {
 508                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 509                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 510                                 else
 511                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 512
 513                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 514                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 515                                 else
 516                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 517                         }
 518
 519                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 520                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 521                 }
 522         }
 523
 524         // =============
 525         // ACCIDENT/TRAP
 526         // =============
 527         else
 528         {
 529                 switch(deathtype)
 530                 {
 531                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 532                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 533                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 534                         /*case DEATH_HURTTRIGGER:
 535                         {
 536                                 s1 = targ.netname;
 537                                 s2 = inflictor.message;
 538                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 539                                 break;
 540                         }*/
 541
 542                         case DEATH_CUSTOM:
 543                         {
 544                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 545                                         targ.netname,
 546                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 547                                         deathlocation,
 548                                         targ.killcount,
 549                                         0,
 550                                         0);
 551                                 break;
 552                         }
 553
 554                         default:
 555                         {
 556                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 557                                 break;
 558                         }
 559                 }
 560
 561                 LogDeath("accident", deathtype, targ, targ);
 562                 GiveFrags(targ, targ, -1, deathtype);
 563
 564                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 565                 {
 566                         AnnounceTo(targ, "botlike");
 567                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 568                 }
 569         }
 570
 571         // reset target kill count
 572         if(targ.killcount) { targ.killcount = 0; }
 573 }
 574
 575 // these are updated by each Damage call for use in button triggering and such
 576 entity damage_targ;
 577 entity damage_inflictor;
 578 entity damage_attacker;
 579
 580 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 581 {
 582         float mirrordamage;
 583         float mirrorforce;
 584         float complainteamdamage = 0;
 585         entity attacker_save;
 586         mirrordamage = 0;
 587         mirrorforce = 0;
 588
 589         if (gameover || targ.killcount == -666)
 590                 return;
 591
 592         entity oldself;
 593         oldself = self;
 594         self = targ;
 595         damage_targ = targ;
 596         damage_inflictor = inflictor;
 597         damage_attacker = attacker;
 598                 attacker_save = attacker;
 599
 600         if(targ.classname == "player")
 601                 if(targ.hook)
 602                         if(targ.hook.aiment)
 603                                 if(targ.hook.aiment == attacker)
 604                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 605
 606         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 607         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 608         {
 609                 if(targ.classname == "player")
 610                         if not(IsDifferentTeam(targ, attacker))
 611                         {
 612                                 self = oldself;
 613                                 return;
 614                         }
 615         }
 616
 617         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 618         {
 619                 // These are ALWAYS lethal
 620                 // No damage modification here
 621                 // Instead, prepare the victim for his death...
 622                 targ.armorvalue = 0;
 623                 targ.spawnshieldtime = 0;
 624                 targ.health = 0.9; // this is < 1
 625                 targ.flags -= targ.flags & FL_GODMODE;
 626                 damage = 100000;
 627         }
 628         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 629         {
 630                 // no processing
 631         }
 632         else
 633         {
 634                 /*
 635                 skill based bot damage? gtfo. (tZork)
 636                 if (targ.classname == "player")
 637                 if (attacker.classname == "player")
 638                 if (!targ.isbot)
 639                 if (attacker.isbot)
 640                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 641         */
 642
 643                 // nullify damage if teamplay is on
 644                 if(deathtype != DEATH_TELEFRAG)
 645                 if(attacker.classname == "player")
 646                 {
 647                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 648                         {
 649                                 damage = 0;
 650                                 force = '0 0 0';
 651                         }
 652                         else if(!IsDifferentTeam(attacker, targ))
 653                         {
 654                                 if(autocvar_teamplay_mode == 1)
 655                                         damage = 0;
 656                                 else if(attacker != targ)
 657                                 {
 658                                         if(autocvar_teamplay_mode == 3)
 659                                                 damage = 0;
 660                                         else if(autocvar_teamplay_mode == 4)
 661                                         {
 662                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 663                                                 {
 664                                                         attacker.dmg_team = attacker.dmg_team + damage;
 665                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 666                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 667                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 668                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 669                                                         if(g_ca)
 670                                                                 damage = 0;
 671                                                         else
 672                                                                 damage = autocvar_g_friendlyfire * damage;
 673                                                         // mirrordamage will be used LATER
 674
 675                                                         if(autocvar_g_mirrordamage_virtual)
 676                                                         {
 677                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 678                                                                 attacker.dmg_take += v_x;
 679                                                                 attacker.dmg_save += v_y;
 680                                                                 attacker.dmg_inflictor = inflictor;
 681                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 682                                                                 mirrorforce = 0;
 683                                                         }
 684
 685                                                         if(autocvar_g_friendlyfire_virtual)
 686                                                         {
 687                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 688                                                                 targ.dmg_take += v_x;
 689                                                                 targ.dmg_save += v_y;
 690                                                                 targ.dmg_inflictor = inflictor;
 691                                                                 damage = 0;
 692                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 693                                                                         force = '0 0 0';
 694                                                         }
 695                                                 }
 696                                                 else
 697                                                         damage = 0;
 698                                         }
 699                                 }
 700                         }
 701                 }
 702
 703                 if(targ.classname == "player")
 704                 if(attacker.classname == "player")
 705                 if(attacker != targ)
 706                 {
 707                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 708                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 709                 }
 710
 711                 if not(DEATH_ISSPECIAL(deathtype))
 712                 {
 713                         damage *= g_weapondamagefactor;
 714                         mirrordamage *= g_weapondamagefactor;
 715                         complainteamdamage *= g_weapondamagefactor;
 716                         force = force * g_weaponforcefactor;
 717                         mirrorforce *= g_weaponforcefactor;
 718                 }
 719
 720                 // should this be changed at all? If so, in what way?
 721                 frag_attacker = attacker;
 722                 frag_target = targ;
 723                 frag_damage = damage;
 724                 frag_force = force;
 725         frag_deathtype = deathtype;
 726                 frag_mirrordamage = mirrordamage;
 727                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 728                 damage = frag_damage;
 729                 mirrordamage = frag_mirrordamage;
 730                 force = frag_force;
 731
 732                 if not(g_minstagib)
 733                 {
 734                         // apply strength multiplier
 735                         if (attacker.items & IT_STRENGTH)
 736                         {
 737                                 if(targ == attacker)
 738                                 {
 739                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 740                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 741                                 }
 742                                 else
 743                                 {
 744                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 745                                         force = force * autocvar_g_balance_powerup_strength_force;
 746                                 }
 747                         }
 748
 749                         // apply invincibility multiplier
 750                         if (targ.items & IT_INVINCIBLE)
 751                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 752                 }
 753
 754                 if (targ == attacker)
 755                 {
 756                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 757                                 damage = 0;
 758                         else
 759                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 760                 }
 761
 762                 if(g_runematch)
 763                 {
 764                         // apply strength rune
 765                         if (attacker.runes & RUNE_STRENGTH)
 766                         {
 767                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 768                                 {
 769                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 770                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 771                                 }
 772                                 else
 773                                 {
 774                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 775                                         force = force * autocvar_g_balance_rune_strength_force;
 776                                 }
 777                         }
 778                         else if (attacker.runes & CURSE_WEAK)
 779                         {
 780                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 781                                 force = force * autocvar_g_balance_curse_weak_force;
 782                         }
 783
 784                         // apply defense rune
 785                         if (targ.runes & RUNE_DEFENSE)
 786                         {
 787                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 788                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 789                                 else
 790                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 791                         }
 792                         else if (targ.runes & CURSE_VULNER)
 793                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 794                 }
 795
 796                 // count the damage
 797                 if(attacker)
 798                 if(!targ.deadflag)
 799                 if(targ.takedamage == DAMAGE_AIM)
 800                 if(targ != attacker)
 801                 {
 802                         entity victim;
 803                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 804                                 victim = targ.owner;
 805                         else
 806                                 victim = targ;
 807
 808                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 809                         {
 810                                 if(IsDifferentTeam(victim, attacker))
 811                                 {
 812                                         if(damage > 0)
 813                                         {
 814                                                 if(deathtype != DEATH_FIRE)
 815                                                 {
 816                                                         if(victim.BUTTON_CHAT)
 817                                                                 attacker.typehitsound += 1;
 818                                                         else
 819                                                                 attacker.hitsound += 1;
 820                                                 }
 821
 822                                                 damage_goodhits += 1;
 823                                                 damage_gooddamage += damage;
 824
 825                                                 if not(DEATH_ISSPECIAL(deathtype))
 826                                                 {
 827                                                         if(targ.classname == "player") // don't do this for vehicles
 828                                                         if(IsFlying(victim))
 829                                                                 yoda = 1;
 830                                                 }
 831                                         }
 832                                 }
 833                                 else
 834                                 {
 835                                         if(deathtype != DEATH_FIRE)
 836                                         {
 837                                                 attacker.typehitsound += 1;
 838                                         }
 839                                         if(complainteamdamage > 0)
 840                                                 if(time > attacker.teamkill_complain)
 841                                                 {
 842                                                         attacker.teamkill_complain = time + 5;
 843                                                         attacker.teamkill_soundtime = time + 0.4;
 844                                                         attacker.teamkill_soundsource = targ;
 845                                                 }
 846                                 }
 847                         }
 848                 }
 849         }
 850
 851         // apply push
 852         if (self.damageforcescale)
 853         if (vlen(force))
 854         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 855         {
 856                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 857                 if(self.movetype == MOVETYPE_PHYSICS)
 858                 {
 859                         entity farcent;
 860                         farcent = spawn();
 861                         farcent.classname = "farce";
 862                         farcent.enemy = self;
 863                         farcent.movedir = farce * 10;
 864                         if(self.mass)
 865                                 farcent.movedir = farcent.movedir * self.mass;
 866                         farcent.origin = hitloc;
 867                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 868                         farcent.nextthink = time + 0.1;
 869                         farcent.think = SUB_Remove;
 870                 }
 871                 else
 872                         self.velocity = self.velocity + farce;
 873                 self.flags &~= FL_ONGROUND;
 874                 UpdateCSQCProjectile(self);
 875         }
 876         // apply damage
 877         if (damage != 0 || (self.damageforcescale && vlen(force)))
 878         if (self.event_damage)
 879                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 880         self = oldself;
 881
 882         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 883         {
 884                 if(g_runematch)
 885                 {
 886                         if (attacker.runes & RUNE_VAMPIRE)
 887                         {
 888                         // apply vampire rune
 889                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 890                                 {
 891                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 892                                         attacker.health = bound(
 893                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 894                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 895                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 896                                 }
 897                                 else
 898                                 {
 899                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 900                                         attacker.health = bound(
 901                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 902                                                                                         // empathy won't let you gain health in the same way...
 903                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 904                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 905                                         }
 906                         }
 907                         // apply empathy curse
 908                         else if (attacker.runes & CURSE_EMPATHY)
 909                         {
 910                                 attacker.health = bound(
 911                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 912                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 913                                         attacker.health);
 914                         }
 915                 }
 916         }
 917
 918         // apply mirror damage if any
 919         if(mirrordamage > 0 || mirrorforce > 0)
 920         {
 921                 attacker = attacker_save;
 922
 923                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 924                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 925         }
 926 }
 927
 928 float RadiusDamage_running;
 929 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 930         // Returns total damage applies to creatures
 931 {
 932         entity  targ;
 933         vector  blastorigin;
 934         vector  force;
 935         float   total_damage_to_creatures;
 936         entity  next;
 937         float   tfloordmg;
 938         float   tfloorforce;
 939
 940         float stat_damagedone;
 941
 942         if(RadiusDamage_running)
 943         {
 944                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 945                 return 0;
 946         }
 947
 948         RadiusDamage_running = 1;
 949
 950         tfloordmg = autocvar_g_throughfloor_damage;
 951         tfloorforce = autocvar_g_throughfloor_force;
 952
 953         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 954         total_damage_to_creatures = 0;
 955
 956         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 957                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 958                 {
 959                         force = inflictor.velocity;
 960                         if(vlen(force) == 0)
 961                                 force = '0 0 -1';
 962                         else
 963                                 force = normalize(force);
 964                         if(forceintensity >= 0)
 965                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 966                         else
 967                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 968                 }
 969
 970         stat_damagedone = 0;
 971
 972         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 973         while (targ)
 974         {
 975                 next = targ.chain;
 976                 if (targ != inflictor)
 977                         if (ignore != targ) if(targ.takedamage)
 978                         {
 979                                 vector nearest;
 980                                 vector diff;
 981                                 float power;
 982
 983                                 // LordHavoc: measure distance to nearest point on target (not origin)
 984                                 // (this guarentees 100% damage on a touch impact)
 985                                 nearest = targ.WarpZone_findradius_nearest;
 986                                 diff = targ.WarpZone_findradius_dist;
 987                                 // round up a little on the damage to ensure full damage on impacts
 988                                 // and turn the distance into a fraction of the radius
 989                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 990                                 //bprint(" ");
 991                                 //bprint(ftos(power));
 992                                 //if (targ == attacker)
 993                                 //      print(ftos(power), "\n");
 994                                 if (power > 0)
 995                                 {
 996                                         float finaldmg;
 997                                         if (power > 1)
 998                                                 power = 1;
 999                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1000                                         if (finaldmg > 0)
1001                                         {
1002                                                 float a;
1003                                                 float c;
1004                                                 vector hitloc;
1005                                                 vector myblastorigin;
1006                                                 vector center;
1007
1008                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1009
1010                                                 // if it's a player, use the view origin as reference
1011                                                 center = CENTER_OR_VIEWOFS(targ);
1012
1013                                                 force = normalize(center - myblastorigin);
1014                                                 force = force * (finaldmg / coredamage) * forceintensity;
1015                                                 hitloc = nearest;
1016
1017                                                 if(targ != directhitentity)
1018                                                 {
1019                                                         float hits;
1020                                                         float total;
1021                                                         float hitratio;
1022                                                         float mininv_f, mininv_d;
1023
1024                                                         // test line of sight to multiple positions on box,
1025                                                         // and do damage if any of them hit
1026                                                         hits = 0;
1027
1028                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1029                                                         // so for a given max stddev:
1030                                                         // n = (1 / (2 * max stddev of hitratio))^2
1031
1032                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1033                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1034
1035                                                         if(autocvar_g_throughfloor_debug)
1036                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1037
1038                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1039
1040                                                         if(autocvar_g_throughfloor_debug)
1041                                                                 print(sprintf(" steps=%f", total));
1042
1043                                                         if (targ.classname == "player")
1044                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1045                                                         else
1046                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1047
1048                                                         if(autocvar_g_throughfloor_debug)
1049                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1050
1051                                                         for(c = 0; c < total; ++c)
1052                                                         {
1053                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1054                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1055                                                                 if (trace_fraction == 1 || trace_ent == targ)
1056                                                                 {
1057                                                                         ++hits;
1058                                                                         if (hits > 1)
1059                                                                                 hitloc = hitloc + nearest;
1060                                                                         else
1061                                                                                 hitloc = nearest;
1062                                                                 }
1063                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1064                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1065                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1066                                                         }
1067
1068                                                         nearest = hitloc * (1 / max(1, hits));
1069                                                         hitratio = (hits / total);
1070                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1071                                                         finaldmg = finaldmg * a;
1072                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1073                                                         force = force * a;
1074
1075                                                         if(autocvar_g_throughfloor_debug)
1076                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1077                                                 }
1078
1079                                                 // laser force adjustments :P
1080                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1081                                                 {
1082                                                         if (targ == attacker)
1083                                                         {
1084                                                                 vector vel;
1085
1086                                                                 float force_zscale;
1087                                                                 float force_velocitybiasramp;
1088                                                                 float force_velocitybias;
1089
1090                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1091                                                                 if(deathtype & HITTYPE_SECONDARY)
1092                                                                 {
1093                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1094                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1095                                                                 }
1096                                                                 else
1097                                                                 {
1098                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1099                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1100                                                                 }
1101
1102                                                                 vel = targ.velocity;
1103                                                                 vel_z = 0;
1104                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1105                                                                 force =
1106                                                                         vlen(force)
1107                                                                         *
1108                                                                         normalize(normalize(force) + vel);
1109
1110                                                                 force_z *= force_zscale;
1111                                                         }
1112                                                         else
1113                                                         {
1114                                                                 if(deathtype & HITTYPE_SECONDARY)
1115                                                                 {
1116                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1117                                                                 }
1118                                                                 else
1119                                                                 {
1120                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1121                                                                 }
1122                                                         }
1123                                                 }
1124
1125                                                 //if (targ == attacker)
1126                                                 //{
1127                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1128                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1129                                                 //      print(" (", ftos(a), ")\n");
1130                                                 //}
1131                                                 if(finaldmg || vlen(force))
1132                                                 {
1133                                                         if(targ.iscreature)
1134                                                         {
1135                                                                 total_damage_to_creatures += finaldmg;
1136
1137                                                                 if(accuracy_isgooddamage(attacker, targ))
1138                                                                         stat_damagedone += finaldmg;
1139                                                         }
1140
1141                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1142                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1143                                                         else
1144                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1145                                                 }
1146                                         }
1147                                 }
1148                         }
1149                 targ = next;
1150         }
1151
1152         RadiusDamage_running = 0;
1153
1154         if(!DEATH_ISSPECIAL(deathtype))
1155                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1156
1157         return total_damage_to_creatures;
1158 }
1159
1160 .float fire_damagepersec;
1161 .float fire_endtime;
1162 .float fire_deathtype;
1163 .entity fire_owner;
1164 .float fire_hitsound;
1165 .entity fire_burner;
1166
1167 void fireburner_think();
1168
1169 float Fire_IsBurning(entity e)
1170 {
1171         return (time < e.fire_endtime);
1172 }
1173
1174 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1175 {
1176         float dps;
1177         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1178
1179         if(e.classname == "player")
1180         {
1181                 if(e.deadflag)
1182                         return -1;
1183         }
1184         else
1185         {
1186                 if(!e.fire_burner)
1187                 {
1188                         // print("adding a fire burner to ", e.classname, "\n");
1189                         e.fire_burner = spawn();
1190                         e.fire_burner.classname = "fireburner";
1191                         e.fire_burner.think = fireburner_think;
1192                         e.fire_burner.nextthink = time;
1193                         e.fire_burner.owner = e;
1194                 }
1195         }
1196
1197         t = max(t, 0.1);
1198         dps = d / t;
1199         if(Fire_IsBurning(e))
1200         {
1201                 mintime = e.fire_endtime - time;
1202                 maxtime = max(mintime, t);
1203
1204                 mindps = e.fire_damagepersec;
1205                 maxdps = max(mindps, dps);
1206
1207                 if(maxtime > mintime || maxdps > mindps)
1208                 {
1209                         // Constraints:
1210
1211                         // damage we have right now
1212                         mindamage = mindps * mintime;
1213
1214                         // damage we want to get
1215                         maxdamage = mindamage + d;
1216
1217                         // but we can't exceed maxtime * maxdps!
1218                         totaldamage = min(maxdamage, maxtime * maxdps);
1219
1220                         // LEMMA:
1221                         // Look at:
1222                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1223                         // We see:
1224                         // totaldamage <= maxtime * maxdps
1225                         // ==> totaldamage / maxdps <= maxtime.
1226                         // We also see:
1227                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1228                         //                     >= min(mintime, maxtime)
1229                         // ==> totaldamage / maxdps >= mintime.
1230
1231                         /*
1232                         // how long do we damage then?
1233                         // at least as long as before
1234                         // but, never exceed maxdps
1235                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1236                         */
1237
1238                         // alternate:
1239                         // at most as long as maximum allowed
1240                         // but, never below mindps
1241                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1242
1243                         // assuming t > mintime, dps > mindps:
1244                         // we get d = t * dps = maxtime * maxdps
1245                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1246                         // totaldamage / maxdps = maxtime
1247                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1248                         // FROM THIS:
1249                         // a) totaltime = max(mintime, maxtime) = maxtime
1250                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1251
1252                         // assuming t <= mintime:
1253                         // we get maxtime = mintime
1254                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1255                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1256
1257                         // assuming dps <= mindps:
1258                         // we get mindps = maxdps.
1259                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1260                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1261                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1262
1263                         e.fire_damagepersec = totaldamage / totaltime;
1264                         e.fire_endtime = time + totaltime;
1265                         if(totaldamage > 1.2 * mindamage)
1266                         {
1267                                 e.fire_deathtype = dt;
1268                                 if(e.fire_owner != o)
1269                                 {
1270                                         e.fire_owner = o;
1271                                         e.fire_hitsound = FALSE;
1272                                 }
1273                         }
1274                         if(accuracy_isgooddamage(o, e))
1275                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1276                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1277                 }
1278                 else
1279                         return 0;
1280         }
1281         else
1282         {
1283                 e.fire_damagepersec = dps;
1284                 e.fire_endtime = time + t;
1285                 e.fire_deathtype = dt;
1286                 e.fire_owner = o;
1287                 e.fire_hitsound = FALSE;
1288                 if(accuracy_isgooddamage(o, e))
1289                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1290                 return d;
1291         }
1292 }
1293
1294 void Fire_ApplyDamage(entity e)
1295 {
1296         float t, d, hi, ty;
1297         entity o;
1298
1299         if not(Fire_IsBurning(e))
1300                 return;
1301
1302         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1303         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1304                 o = e.fire_owner;
1305
1306         // water and slime stop fire
1307         if(e.waterlevel)
1308         if(e.watertype != CONTENT_LAVA)
1309                 e.fire_endtime = 0;
1310
1311         // ice stops fire
1312         if(e.freezetag_frozen)
1313                 e.fire_endtime = 0;
1314
1315         t = min(frametime, e.fire_endtime - time);
1316         d = e.fire_damagepersec * t;
1317
1318         hi = e.fire_owner.hitsound;
1319         ty = e.fire_owner.typehitsound;
1320         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1321         if(e.fire_hitsound && e.fire_owner)
1322         {
1323                 e.fire_owner.hitsound = hi;
1324                 e.fire_owner.typehitsound = ty;
1325         }
1326         e.fire_hitsound = TRUE;
1327
1328         if not(IS_INDEPENDENT_PLAYER(e))
1329         FOR_EACH_PLAYER(other) if(e != other)
1330         {
1331                 if(other.classname == "player")
1332                 if(other.deadflag == DEAD_NO)
1333                 if not(IS_INDEPENDENT_PLAYER(other))
1334                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1335                 {
1336                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1337                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1338                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1339                 }
1340         }
1341 }
1342
1343 void Fire_ApplyEffect(entity e)
1344 {
1345         if(Fire_IsBurning(e))
1346                 e.effects |= EF_FLAME;
1347         else
1348                 e.effects &~= EF_FLAME;
1349 }
1350
1351 void fireburner_think()
1352 {
1353         // for players, this is done in the regular loop
1354         if(wasfreed(self.owner))
1355         {
1356                 remove(self);
1357                 return;
1358         }
1359         Fire_ApplyEffect(self.owner);
1360         if(!Fire_IsBurning(self.owner))
1361         {
1362                 self.owner.fire_burner = world;
1363                 remove(self);
1364                 return;
1365         }
1366         Fire_ApplyDamage(self.owner);
1367         self.nextthink = time;
1368 }