qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 void Obituary_SpecialDeath(
 263         entity notif_target,
 264         float murder,
 265         float deathtype,
 266         string s1, string s2, string s3,
 267         float f1, float f2, float f3)
 268 {
 269         if(DEATH_ISSPECIAL(deathtype))
 270         {
 271                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 272                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 273
 274                 if(murder)
 275                 {
 276                         if(deathent.death_msgmurder)
 277                         {
 278                                 Send_Notification_WOVA(
 279                                         NOTIF_ONE,
 280                                         notif_target,
 281                                         MSG_MULTI,
 282                                         deathent.death_msgmurder.nent_id,
 283                                         s1, s2, s3, "",
 284                                         f1, f2, f3, 0
 285                                 );
 286                                 Send_Notification_WOVA(
 287                                         NOTIF_ALL_EXCEPT,
 288                                         notif_target,
 289                                         MSG_INFO,
 290                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 291                                         s1, s2, s3, "",
 292                                         f1, f2, f3, 0
 293                                 );
 294                         }
 295                 }
 296                 else
 297                 {
 298                         if(deathent.death_msgself)
 299                         {
 300                                 Send_Notification_WOVA(
 301                                         NOTIF_ONE,
 302                                         notif_target,
 303                                         MSG_MULTI,
 304                                         deathent.death_msgself.nent_id,
 305                                         s1, s2, s3, "",
 306                                         f1, f2, f3, 0
 307                                 );
 308                                 Send_Notification_WOVA(
 309                                         NOTIF_ALL_EXCEPT,
 310                                         notif_target,
 311                                         MSG_INFO,
 312                                         deathent.death_msgself.nent_msginfo.nent_id,
 313                                         s1, s2, s3, "",
 314                                         f1, f2, f3, 0
 315                                 );
 316                         }
 317                 }
 318         }
 319         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 320 }
 321
 322 float w_deathtype;
 323 float Obituary_WeaponDeath(
 324         entity notif_target,
 325         float murder,
 326         float deathtype,
 327         string s1, string s2, string s3,
 328         float f1, float f2)
 329 {
 330         float death_weapon = DEATH_WEAPONOF(deathtype);
 331         if(death_weapon)
 332         {
 333                 w_deathtype = deathtype;
 334                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 335                 w_deathtype = FALSE;
 336
 337                 if(death_message)
 338                 {
 339                         Send_Notification_WOVA(
 340                                 NOTIF_ONE,
 341                                 notif_target,
 342                                 MSG_MULTI,
 343                                 death_message,
 344                                 s1, s2, s3, "",
 345                                 f1, f2, 0, 0
 346                         );
 347                         Send_Notification_WOVA(
 348                                 NOTIF_ALL_EXCEPT,
 349                                 notif_target,
 350                                 MSG_INFO,
 351                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 352                                 s1, s2, s3, "",
 353                                 f1, f2, 0, 0
 354                         );
 355                 }
 356                 else
 357                 {
 358                         dprint(sprintf(
 359                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 360                                 deathtype,
 361                                 death_weapon
 362                         ));
 363                 }
 364
 365                 return TRUE;
 366         }
 367         return FALSE;
 368 }
 369
 370 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 371 {
 372         // Sanity check
 373         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 374
 375         // Declarations
 376         float notif_firstblood = FALSE;
 377         float kill_count_to_attacker, kill_count_to_target;
 378
 379         // Set final information for the death
 380         targ.death_origin = targ.origin;
 381         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 382         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 383
 384         #ifdef NOTIFICATIONS_DEBUG
 385         dprint(
 386                 sprintf(
 387                         "Obituary(%s, %s, %s, %s = %d);\n",
 388                         attacker.netname,
 389                         inflictor.netname,
 390                         targ.netname,
 391                         Deathtype_Name(deathtype),
 392                         deathtype
 393                 )
 394         );
 395         #endif
 396
 397         // =======
 398         // SUICIDE
 399         // =======
 400         if(targ == attacker)
 401         {
 402                 if(DEATH_ISSPECIAL(deathtype))
 403                 {
 404                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 405                         {
 406                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 407                         }
 408                         else
 409                         {
 410                                 switch(deathtype)
 411                                 {
 412                                         case DEATH_MIRRORDAMAGE:
 413                                         {
 414                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 415                                                 break;
 416                                         }
 417
 418                                         default:
 419                                         {
 420                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 421                                                 break;
 422                                         }
 423                                 }
 424                         }
 425                 }
 426                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 427                 {
 428                         backtrace("SUICIDE: what the hell happened here?\n");
 429                         return;
 430                 }
 431                 LogDeath("suicide", deathtype, targ, targ);
 432                 GiveFrags(attacker, targ, -1, deathtype);
 433         }
 434
 435         // ======
 436         // MURDER
 437         // ======
 438         else if(IS_PLAYER(attacker))
 439         {
 440                 if(!IsDifferentTeam(attacker, targ))
 441                 {
 442                         LogDeath("tk", deathtype, attacker, targ);
 443                         GiveFrags(attacker, targ, -1, deathtype);
 444
 445                         attacker.killcount = 0;
 446
 447                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 448                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 449                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 450
 451                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 452                         // No need for specific death/weapon messages...
 453                 }
 454                 else
 455                 {
 456                         LogDeath("frag", deathtype, attacker, targ);
 457                         GiveFrags(attacker, targ, 1, deathtype);
 458
 459                         attacker.taunt_soundtime = time + 1;
 460                         attacker.killcount = attacker.killcount + 1;
 461
 462                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 463                                 case counta: \
 464                                 { \
 465                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 466                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 467                                         break; \
 468                                 }
 469                         switch(attacker.killcount)
 470                         {
 471                                 KILL_SPREE_LIST
 472                                 default: break;
 473                         }
 474                         #undef SPREE_ITEM
 475
 476                         if(!checkrules_firstblood)
 477                         {
 478                                 checkrules_firstblood = TRUE;
 479                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 480                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 481                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 482
 483                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 484                                 kill_count_to_attacker = -1;
 485                                 kill_count_to_target = -2;
 486                         }
 487                         else
 488                         {
 489                                 kill_count_to_attacker = attacker.killcount;
 490                                 kill_count_to_target = 0;
 491                         }
 492
 493                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 494                         if(targ.istypefrag)
 495                         {
 496                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 497                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 498                                 else
 499                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 500
 501                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 502                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 503                                 else
 504                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 505                         }
 506                         else
 507                         {
 508                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 509                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 510                                 else
 511                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 512
 513                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 514                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 515                                 else
 516                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 517                         }
 518
 519                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 520                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 521                 }
 522         }
 523
 524         // =============
 525         // ACCIDENT/TRAP
 526         // =============
 527         else
 528         {
 529                 switch(deathtype)
 530                 {
 531                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 532                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 533                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 534                         /*case DEATH_HURTTRIGGER:
 535                         {
 536                                 s1 = targ.netname;
 537                                 s2 = inflictor.message;
 538                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 539                                 break;
 540                         }*/
 541
 542                         case DEATH_CUSTOM:
 543                         {
 544                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 545                                         targ.netname,
 546                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 547                                         deathlocation,
 548                                         targ.killcount,
 549                                         0,
 550                                         0);
 551                                 break;
 552                         }
 553
 554                         default:
 555                         {
 556                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 557                                 break;
 558                         }
 559                 }
 560
 561                 LogDeath("accident", deathtype, targ, targ);
 562                 GiveFrags(targ, targ, -1, deathtype);
 563
 564                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 565                 {
 566                         AnnounceTo(targ, "botlike");
 567                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 568                 }
 569         }
 570
 571         // reset target kill count
 572         if(targ.killcount) { targ.killcount = 0; }
 573 }
 574
 575 void Ice_Think()
 576 {
 577         if(self.owner.health < 1)
 578         {
 579                 remove(self);
 580                 return;
 581         }
 582         setorigin(self, self.owner.origin - '0 0 16');
 583         self.nextthink = time;
 584 }
 585
 586 void Freeze (entity targ, float freeze_time)
 587 {
 588         float monster = (targ.flags & FL_MONSTER);
 589         float player = (targ.flags & FL_CLIENT);
 590
 591         if(!player && !monster) // only specified entities can be freezed
 592                 return;
 593
 594         if(targ.frozen || targ.freezetag_frozen)
 595                 return;
 596
 597         targ.frozen = 1;
 598         targ.revive_progress = 0;
 599         targ.health = 1;
 600         targ.revive_speed = freeze_time;
 601
 602         entity ice;
 603         ice = spawn();
 604         ice.owner = targ;
 605         ice.classname = "ice";
 606         ice.scale = targ.scale;
 607         ice.think = Ice_Think;
 608         ice.nextthink = time;
 609         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 610         setmodel(ice, "models/ice/ice.md3");
 611
 612         entity oldself;
 613         oldself = self;
 614         self = ice;
 615         Ice_Think();
 616         self = oldself;
 617
 618         RemoveGrapplingHook(targ);
 619 }
 620
 621 void Unfreeze (entity targ)
 622 {
 623         targ.frozen = 0;
 624         targ.revive_progress = 0;
 625         targ.health = ((targ.classname == STR_PLAYER) ? autocvar_g_balance_health_start : targ.max_health);
 626
 627         // remove the ice block
 628         entity ice;
 629         for(ice = world; (ice = find(ice, classname, "ice")); ) if(ice.owner == targ)
 630         {
 631                 remove(ice);
 632                 break;
 633         }
 634 }
 635
 636 // these are updated by each Damage call for use in button triggering and such
 637 entity damage_targ;
 638 entity damage_inflictor;
 639 entity damage_attacker;
 640
 641 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 642 {
 643         float mirrordamage;
 644         float mirrorforce;
 645         float complainteamdamage = 0;
 646         entity attacker_save;
 647         mirrordamage = 0;
 648         mirrorforce = 0;
 649
 650         if (gameover || targ.killcount == -666)
 651                 return;
 652
 653         entity oldself;
 654         oldself = self;
 655         self = targ;
 656         damage_targ = targ;
 657         damage_inflictor = inflictor;
 658         damage_attacker = attacker;
 659                 attacker_save = attacker;
 660
 661         if(targ.classname == "player")
 662                 if(targ.hook)
 663                         if(targ.hook.aiment)
 664                                 if(targ.hook.aiment == attacker)
 665                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 666
 667         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 668         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 669         {
 670                 if(targ.classname == "player")
 671                         if not(IsDifferentTeam(targ, attacker))
 672                         {
 673                                 self = oldself;
 674                                 return;
 675                         }
 676         }
 677
 678         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 679         {
 680                 // These are ALWAYS lethal
 681                 // No damage modification here
 682                 // Instead, prepare the victim for his death...
 683                 targ.armorvalue = 0;
 684                 targ.spawnshieldtime = 0;
 685                 targ.health = 0.9; // this is < 1
 686                 targ.flags -= targ.flags & FL_GODMODE;
 687                 damage = 100000;
 688         }
 689         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 690         {
 691                 // no processing
 692         }
 693         else
 694         {
 695                 /*
 696                 skill based bot damage? gtfo. (tZork)
 697                 if (targ.classname == "player")
 698                 if (attacker.classname == "player")
 699                 if (!targ.isbot)
 700                 if (attacker.isbot)
 701                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 702         */
 703
 704                 // nullify damage if teamplay is on
 705                 if(deathtype != DEATH_TELEFRAG)
 706                 if(attacker.classname == "player")
 707                 {
 708                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 709                         {
 710                                 damage = 0;
 711                                 force = '0 0 0';
 712                         }
 713                         else if(!IsDifferentTeam(attacker, targ))
 714                         {
 715                                 if(autocvar_teamplay_mode == 1)
 716                                         damage = 0;
 717                                 else if(attacker != targ)
 718                                 {
 719                                         if(autocvar_teamplay_mode == 3)
 720                                                 damage = 0;
 721                                         else if(autocvar_teamplay_mode == 4)
 722                                         {
 723                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 724                                                 {
 725                                                         attacker.dmg_team = attacker.dmg_team + damage;
 726                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 727                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 728                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 729                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 730                                                         if(g_minstagib)
 731                                                         {
 732                                                                 if(autocvar_g_friendlyfire == 0)
 733                                                                         damage = 0;
 734                                                         }
 735                                                         else if(g_ca)
 736                                                                 damage = 0;
 737                                                         else
 738                                                                 damage = autocvar_g_friendlyfire * damage;
 739                                                         // mirrordamage will be used LATER
 740
 741                                                         if(autocvar_g_mirrordamage_virtual)
 742                                                         {
 743                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 744                                                                 attacker.dmg_take += v_x;
 745                                                                 attacker.dmg_save += v_y;
 746                                                                 attacker.dmg_inflictor = inflictor;
 747                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 748                                                                 mirrorforce = 0;
 749                                                         }
 750
 751                                                         if(autocvar_g_friendlyfire_virtual)
 752                                                         {
 753                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 754                                                                 targ.dmg_take += v_x;
 755                                                                 targ.dmg_save += v_y;
 756                                                                 targ.dmg_inflictor = inflictor;
 757                                                                 damage = 0;
 758                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 759                                                                         force = '0 0 0';
 760                                                         }
 761                                                 }
 762                                                 else
 763                                                         damage = 0;
 764                                         }
 765                                 }
 766                         }
 767                 }
 768
 769                 if(targ.classname == "player")
 770                 if(attacker.classname == "player")
 771                 if(attacker != targ)
 772                 {
 773                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 774                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 775                 }
 776
 777                 if(targ.classname == "player")
 778                 if (g_minstagib)
 779                 {
 780                         if ((deathtype == DEATH_FALL)  ||
 781                                 (deathtype == DEATH_DROWN) ||
 782                                 (deathtype == DEATH_SLIME) ||
 783                                 (deathtype == DEATH_LAVA)  ||
 784                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 785                         {
 786                                 self = oldself;
 787                                 return;
 788                         }
 789                         if(damage > 0)
 790                             damage = 10000;
 791                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 792                         {
 793                                 targ.armorvalue -= 1;
 794                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 795                                 damage = 0;
 796                                 targ.hitsound += 1;
 797                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 798                         }
 799                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 800                         {
 801                                 damage = 0;
 802                                 mirrordamage = 0;
 803                                 complainteamdamage = 0;
 804                                 if (targ != attacker)
 805                                 {
 806                                         if ((targ.health >= 1) && (targ.classname == "player"))
 807                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 808                                         force = '0 0 0';
 809                                         // keep mirrorforce
 810                                         attacker = targ;
 811                                 }
 812                         }
 813                 }
 814
 815                 if not(DEATH_ISSPECIAL(deathtype))
 816                 {
 817                         damage *= g_weapondamagefactor;
 818                         mirrordamage *= g_weapondamagefactor;
 819                         complainteamdamage *= g_weapondamagefactor;
 820                         force = force * g_weaponforcefactor;
 821                         mirrorforce *= g_weaponforcefactor;
 822                 }
 823
 824                 if(targ.frozen && attacker.classname != "monster_spider")
 825                 {
 826                         damage = 0;
 827                         force *= 0.2;
 828                 }
 829
 830                 // should this be changed at all? If so, in what way?
 831                 frag_attacker = attacker;
 832                 frag_target = targ;
 833                 frag_damage = damage;
 834                 frag_force = force;
 835         frag_deathtype = deathtype;
 836                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 837                 damage = frag_damage;
 838                 force = frag_force;
 839
 840                 // apply strength multiplier
 841                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 842                 {
 843                         if(targ == attacker)
 844                         {
 845                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 846                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 847                         }
 848                         else
 849                         {
 850                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 851                                 force = force * autocvar_g_balance_powerup_strength_force;
 852                         }
 853                 }
 854
 855                 // apply invincibility multiplier
 856                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 857                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 858
 859                 if (targ == attacker)
 860                 {
 861                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 862                                 damage = 0;
 863                         else
 864                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 865                 }
 866
 867                 if(g_runematch)
 868                 {
 869                         // apply strength rune
 870                         if (attacker.runes & RUNE_STRENGTH)
 871                         {
 872                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 873                                 {
 874                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 875                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 876                                 }
 877                                 else
 878                                 {
 879                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 880                                         force = force * autocvar_g_balance_rune_strength_force;
 881                                 }
 882                         }
 883                         else if (attacker.runes & CURSE_WEAK)
 884                         {
 885                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 886                                 force = force * autocvar_g_balance_curse_weak_force;
 887                         }
 888
 889                         // apply defense rune
 890                         if (targ.runes & RUNE_DEFENSE)
 891                         {
 892                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 893                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 894                                 else
 895                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 896                         }
 897                         else if (targ.runes & CURSE_VULNER)
 898                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 899                 }
 900
 901                 // count the damage
 902                 if(attacker)
 903                 if(!targ.deadflag)
 904                 if(targ.takedamage == DAMAGE_AIM)
 905                 if(targ != attacker)
 906                 {
 907                         entity victim;
 908                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 909                                 victim = targ.owner;
 910                         else
 911                                 victim = targ;
 912
 913                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
 914                         {
 915                                 if(IsDifferentTeam(victim, attacker))
 916                                 {
 917                                         if(damage > 0)
 918                                         {
 919                                                 if(deathtype != DEATH_FIRE)
 920                                                 {
 921                                                         if(victim.BUTTON_CHAT)
 922                                                                 attacker.typehitsound += 1;
 923                                                         else
 924                                                                 attacker.hitsound += 1;
 925                                                 }
 926
 927                                                 damage_goodhits += 1;
 928                                                 damage_gooddamage += damage;
 929
 930                                                 if not(DEATH_ISSPECIAL(deathtype))
 931                                                 {
 932                                                         if(targ.classname == "player") // don't do this for vehicles
 933                                                         if(!g_minstagib)
 934                                                         if(IsFlying(victim))
 935                                                                 yoda = 1;
 936
 937                                                         if(g_minstagib)
 938                                                         if(victim.items & IT_STRENGTH)
 939                                                                 yoda = 1;
 940                                                 }
 941                                         }
 942                                 }
 943                                 else
 944                                 {
 945                                         if(deathtype != DEATH_FIRE)
 946                                         {
 947                                                 attacker.typehitsound += 1;
 948                                         }
 949                                         if(complainteamdamage > 0)
 950                                                 if(time > attacker.teamkill_complain)
 951                                                 {
 952                                                         attacker.teamkill_complain = time + 5;
 953                                                         attacker.teamkill_soundtime = time + 0.4;
 954                                                         attacker.teamkill_soundsource = targ;
 955                                                 }
 956                                 }
 957                         }
 958                 }
 959         }
 960
 961         // apply push
 962         if (self.damageforcescale)
 963         if (vlen(force))
 964         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 965         {
 966                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 967                 if(self.movetype == MOVETYPE_PHYSICS)
 968                 {
 969                         entity farcent;
 970                         farcent = spawn();
 971                         farcent.classname = "farce";
 972                         farcent.enemy = self;
 973                         farcent.movedir = farce * 10;
 974                         if(self.mass)
 975                                 farcent.movedir = farcent.movedir * self.mass;
 976                         farcent.origin = hitloc;
 977                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 978                         farcent.nextthink = time + 0.1;
 979                         farcent.think = SUB_Remove;
 980                 }
 981                 else
 982                         self.velocity = self.velocity + farce;
 983                 self.flags &~= FL_ONGROUND;
 984                 UpdateCSQCProjectile(self);
 985         }
 986         // apply damage
 987         if (damage != 0 || (self.damageforcescale && vlen(force)))
 988         if (self.event_damage)
 989                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 990         self = oldself;
 991
 992         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 993         {
 994                 if(g_runematch)
 995                 {
 996                         if (attacker.runes & RUNE_VAMPIRE)
 997                         {
 998                         // apply vampire rune
 999                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
1000                                 {
1001                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
1002                                         attacker.health = bound(
1003                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
1004                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
1005                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1006                                 }
1007                                 else
1008                                 {
1009                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
1010                                         attacker.health = bound(
1011                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
1012                                                                                         // empathy won't let you gain health in the same way...
1013                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
1014                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1015                                         }
1016                         }
1017                         // apply empathy curse
1018                         else if (attacker.runes & CURSE_EMPATHY)
1019                         {
1020                                 attacker.health = bound(
1021                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1022                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1023                                         attacker.health);
1024                         }
1025                 }
1026         }
1027
1028         // apply mirror damage if any
1029         if(mirrordamage > 0 || mirrorforce > 0)
1030         {
1031                 attacker = attacker_save;
1032                 if(g_minstagib)
1033                 if(mirrordamage > 0)
1034                 {
1035                         // just lose extra LIVES, don't kill the player for mirror damage
1036                         if(attacker.armorvalue > 0)
1037                         {
1038                                 attacker.armorvalue = attacker.armorvalue - 1;
1039                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1040                                 attacker.hitsound += 1;
1041                         }
1042                         mirrordamage = 0;
1043                 }
1044
1045                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1046                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1047         }
1048 }
1049
1050 float RadiusDamage_running;
1051 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1052         // Returns total damage applies to creatures
1053 {
1054         entity  targ;
1055         vector  blastorigin;
1056         vector  force;
1057         float   total_damage_to_creatures;
1058         entity  next;
1059         float   tfloordmg;
1060         float   tfloorforce;
1061
1062         float stat_damagedone;
1063
1064         if(RadiusDamage_running)
1065         {
1066                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1067                 return 0;
1068         }
1069
1070         RadiusDamage_running = 1;
1071
1072         tfloordmg = autocvar_g_throughfloor_damage;
1073         tfloorforce = autocvar_g_throughfloor_force;
1074
1075         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1076         total_damage_to_creatures = 0;
1077
1078         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1079                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1080                 {
1081                         force = inflictor.velocity;
1082                         if(vlen(force) == 0)
1083                                 force = '0 0 -1';
1084                         else
1085                                 force = normalize(force);
1086                         if(forceintensity >= 0)
1087                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1088                         else
1089                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1090                 }
1091
1092         stat_damagedone = 0;
1093
1094         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1095         while (targ)
1096         {
1097                 next = targ.chain;
1098                 if (targ != inflictor)
1099                         if (ignore != targ) if(targ.takedamage)
1100                         {
1101                                 vector nearest;
1102                                 vector diff;
1103                                 float power;
1104
1105                                 // LordHavoc: measure distance to nearest point on target (not origin)
1106                                 // (this guarentees 100% damage on a touch impact)
1107                                 nearest = targ.WarpZone_findradius_nearest;
1108                                 diff = targ.WarpZone_findradius_dist;
1109                                 // round up a little on the damage to ensure full damage on impacts
1110                                 // and turn the distance into a fraction of the radius
1111                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1112                                 //bprint(" ");
1113                                 //bprint(ftos(power));
1114                                 //if (targ == attacker)
1115                                 //      print(ftos(power), "\n");
1116                                 if (power > 0)
1117                                 {
1118                                         float finaldmg;
1119                                         if (power > 1)
1120                                                 power = 1;
1121                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1122                                         if (finaldmg > 0)
1123                                         {
1124                                                 float a;
1125                                                 float c;
1126                                                 vector hitloc;
1127                                                 vector myblastorigin;
1128                                                 vector center;
1129
1130                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1131
1132                                                 // if it's a player, use the view origin as reference
1133                                                 center = CENTER_OR_VIEWOFS(targ);
1134
1135                                                 force = normalize(center - myblastorigin);
1136                                                 force = force * (finaldmg / coredamage) * forceintensity;
1137                                                 hitloc = nearest;
1138
1139                                                 if(targ != directhitentity)
1140                                                 {
1141                                                         float hits;
1142                                                         float total;
1143                                                         float hitratio;
1144                                                         float mininv_f, mininv_d;
1145
1146                                                         // test line of sight to multiple positions on box,
1147                                                         // and do damage if any of them hit
1148                                                         hits = 0;
1149
1150                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1151                                                         // so for a given max stddev:
1152                                                         // n = (1 / (2 * max stddev of hitratio))^2
1153
1154                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1155                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1156
1157                                                         if(autocvar_g_throughfloor_debug)
1158                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1159
1160                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1161
1162                                                         if(autocvar_g_throughfloor_debug)
1163                                                                 print(sprintf(" steps=%f", total));
1164
1165                                                         if (targ.classname == "player")
1166                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1167                                                         else
1168                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1169
1170                                                         if(autocvar_g_throughfloor_debug)
1171                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1172
1173                                                         for(c = 0; c < total; ++c)
1174                                                         {
1175                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1176                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1177                                                                 if (trace_fraction == 1 || trace_ent == targ)
1178                                                                 {
1179                                                                         ++hits;
1180                                                                         if (hits > 1)
1181                                                                                 hitloc = hitloc + nearest;
1182                                                                         else
1183                                                                                 hitloc = nearest;
1184                                                                 }
1185                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1186                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1187                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1188                                                         }
1189
1190                                                         nearest = hitloc * (1 / max(1, hits));
1191                                                         hitratio = (hits / total);
1192                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1193                                                         finaldmg = finaldmg * a;
1194                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1195                                                         force = force * a;
1196
1197                                                         if(autocvar_g_throughfloor_debug)
1198                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1199                                                 }
1200
1201                                                 // laser force adjustments :P
1202                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1203                                                 {
1204                                                         if (targ == attacker)
1205                                                         {
1206                                                                 vector vel;
1207
1208                                                                 float force_zscale;
1209                                                                 float force_velocitybiasramp;
1210                                                                 float force_velocitybias;
1211
1212                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1213                                                                 if(deathtype & HITTYPE_SECONDARY)
1214                                                                 {
1215                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1216                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1217                                                                 }
1218                                                                 else
1219                                                                 {
1220                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1221                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1222                                                                 }
1223
1224                                                                 vel = targ.velocity;
1225                                                                 vel_z = 0;
1226                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1227                                                                 force =
1228                                                                         vlen(force)
1229                                                                         *
1230                                                                         normalize(normalize(force) + vel);
1231
1232                                                                 force_z *= force_zscale;
1233                                                         }
1234                                                         else
1235                                                         {
1236                                                                 if(deathtype & HITTYPE_SECONDARY)
1237                                                                 {
1238                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1239                                                                 }
1240                                                                 else
1241                                                                 {
1242                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1243                                                                 }
1244                                                         }
1245                                                 }
1246
1247                                                 //if (targ == attacker)
1248                                                 //{
1249                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1250                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1251                                                 //      print(" (", ftos(a), ")\n");
1252                                                 //}
1253                                                 if(finaldmg || vlen(force))
1254                                                 {
1255                                                         if(targ.iscreature)
1256                                                         {
1257                                                                 total_damage_to_creatures += finaldmg;
1258
1259                                                                 if(accuracy_isgooddamage(attacker, targ))
1260                                                                         stat_damagedone += finaldmg;
1261                                                         }
1262
1263                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1264                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1265                                                         else
1266                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1267                                                 }
1268                                         }
1269                                 }
1270                         }
1271                 targ = next;
1272         }
1273
1274         RadiusDamage_running = 0;
1275
1276         if(!DEATH_ISSPECIAL(deathtype))
1277                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1278
1279         return total_damage_to_creatures;
1280 }
1281
1282 .float fire_damagepersec;
1283 .float fire_endtime;
1284 .float fire_deathtype;
1285 .entity fire_owner;
1286 .float fire_hitsound;
1287 .entity fire_burner;
1288
1289 void fireburner_think();
1290
1291 float Fire_IsBurning(entity e)
1292 {
1293         return (time < e.fire_endtime);
1294 }
1295
1296 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1297 {
1298         float dps;
1299         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1300
1301         if(e.classname == "player")
1302         {
1303                 if(e.deadflag)
1304                         return -1;
1305         }
1306         else
1307         {
1308                 if(!e.fire_burner)
1309                 {
1310                         // print("adding a fire burner to ", e.classname, "\n");
1311                         e.fire_burner = spawn();
1312                         e.fire_burner.classname = "fireburner";
1313                         e.fire_burner.think = fireburner_think;
1314                         e.fire_burner.nextthink = time;
1315                         e.fire_burner.owner = e;
1316                 }
1317         }
1318
1319         t = max(t, 0.1);
1320         dps = d / t;
1321         if(Fire_IsBurning(e))
1322         {
1323                 mintime = e.fire_endtime - time;
1324                 maxtime = max(mintime, t);
1325
1326                 mindps = e.fire_damagepersec;
1327                 maxdps = max(mindps, dps);
1328
1329                 if(maxtime > mintime || maxdps > mindps)
1330                 {
1331                         // Constraints:
1332
1333                         // damage we have right now
1334                         mindamage = mindps * mintime;
1335
1336                         // damage we want to get
1337                         maxdamage = mindamage + d;
1338
1339                         // but we can't exceed maxtime * maxdps!
1340                         totaldamage = min(maxdamage, maxtime * maxdps);
1341
1342                         // LEMMA:
1343                         // Look at:
1344                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1345                         // We see:
1346                         // totaldamage <= maxtime * maxdps
1347                         // ==> totaldamage / maxdps <= maxtime.
1348                         // We also see:
1349                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1350                         //                     >= min(mintime, maxtime)
1351                         // ==> totaldamage / maxdps >= mintime.
1352
1353                         /*
1354                         // how long do we damage then?
1355                         // at least as long as before
1356                         // but, never exceed maxdps
1357                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1358                         */
1359
1360                         // alternate:
1361                         // at most as long as maximum allowed
1362                         // but, never below mindps
1363                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1364
1365                         // assuming t > mintime, dps > mindps:
1366                         // we get d = t * dps = maxtime * maxdps
1367                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1368                         // totaldamage / maxdps = maxtime
1369                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1370                         // FROM THIS:
1371                         // a) totaltime = max(mintime, maxtime) = maxtime
1372                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1373
1374                         // assuming t <= mintime:
1375                         // we get maxtime = mintime
1376                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1377                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1378
1379                         // assuming dps <= mindps:
1380                         // we get mindps = maxdps.
1381                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1382                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1383                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1384
1385                         e.fire_damagepersec = totaldamage / totaltime;
1386                         e.fire_endtime = time + totaltime;
1387                         if(totaldamage > 1.2 * mindamage)
1388                         {
1389                                 e.fire_deathtype = dt;
1390                                 if(e.fire_owner != o)
1391                                 {
1392                                         e.fire_owner = o;
1393                                         e.fire_hitsound = FALSE;
1394                                 }
1395                         }
1396                         if(accuracy_isgooddamage(o, e))
1397                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1398                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1399                 }
1400                 else
1401                         return 0;
1402         }
1403         else
1404         {
1405                 e.fire_damagepersec = dps;
1406                 e.fire_endtime = time + t;
1407                 e.fire_deathtype = dt;
1408                 e.fire_owner = o;
1409                 e.fire_hitsound = FALSE;
1410                 if(accuracy_isgooddamage(o, e))
1411                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1412                 return d;
1413         }
1414 }
1415
1416 void Fire_ApplyDamage(entity e)
1417 {
1418         float t, d, hi, ty;
1419         entity o;
1420
1421         if not(Fire_IsBurning(e))
1422                 return;
1423
1424         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1425         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1426                 o = e.fire_owner;
1427
1428         // water and slime stop fire
1429         if(e.waterlevel)
1430         if(e.watertype != CONTENT_LAVA)
1431                 e.fire_endtime = 0;
1432
1433         // ice stops fire
1434         if(e.freezetag_frozen || e.frozen)
1435                 e.fire_endtime = 0;
1436
1437         t = min(frametime, e.fire_endtime - time);
1438         d = e.fire_damagepersec * t;
1439
1440         hi = e.fire_owner.hitsound;
1441         ty = e.fire_owner.typehitsound;
1442         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1443         if(e.fire_hitsound && e.fire_owner)
1444         {
1445                 e.fire_owner.hitsound = hi;
1446                 e.fire_owner.typehitsound = ty;
1447         }
1448         e.fire_hitsound = TRUE;
1449
1450         if not(IS_INDEPENDENT_PLAYER(e))
1451         FOR_EACH_PLAYER(other) if(e != other)
1452         {
1453                 if(other.classname == "player")
1454                 if(other.deadflag == DEAD_NO)
1455                 if not(IS_INDEPENDENT_PLAYER(other))
1456                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1457                 {
1458                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1459                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1460                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1461                 }
1462         }
1463 }
1464
1465 void Fire_ApplyEffect(entity e)
1466 {
1467         if(Fire_IsBurning(e))
1468                 e.effects |= EF_FLAME;
1469         else
1470                 e.effects &~= EF_FLAME;
1471 }
1472
1473 void fireburner_think()
1474 {
1475         // for players, this is done in the regular loop
1476         if(wasfreed(self.owner))
1477         {
1478                 remove(self);
1479                 return;
1480         }
1481         Fire_ApplyEffect(self.owner);
1482         if(!Fire_IsBurning(self.owner))
1483         {
1484                 self.owner.fire_burner = world;
1485                 remove(self);
1486                 return;
1487         }
1488         Fire_ApplyDamage(self.owner);
1489         self.nextthink = time;
1490 }