qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 312 {
 313         float handled, hits;
 314         if(DEATH_ISSPECIAL(deathtype))
 315         {
 316                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 317                         { if(deathtype == max(0, name)) \
 318                         { \
 319                                 #if msg_death != NO_MSG \
 320                                         if not(murder) \
 321                                         { \
 322                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 323                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 324                                                 ++handled; \
 325                                         } \
 326                                 #endif \
 327                                 #if msg_death_by != NO_MSG \
 328                                         if(murder) \
 329                                         { \
 330                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 331                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 332                                                 ++handled; \
 333                                         } \
 334                                 #endif \
 335                                 ++hits; \
 336                         } }
 337
 338                 DEATHTYPES
 339                 #undef DEATHTYPE
 340
 341                 if not(hits)
 342                 {
 343                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 344                         //return;
 345                 }
 346                 if not(handled)
 347                 {
 348                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 349                         return;
 350                 }
 351         }
 352 }
 353 float w_deathtype;
 354 void Obituary_WeaponDeath(float murder, float deathtype, string s1, string s2)
 355 {
 356         float death_weapon = DEATH_WEAPONOF(deathtype);
 357
 358         if(death_weapon)
 359         {
 360                 w_deathtype = deathtype;
 361                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 362                 w_deathtype = FALSE;
 363
 364                 if(death_message) { Send_Notification(world, MSG_ALL, MSG_WEAPON, death_message, s1, s2, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 365                 else { print(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 366         }
 367 }
 368
 369 .float FRAG_VERBOSE;
 370
 371 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 372 {
 373         // Sanity check
 374         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 375
 376         // Declarations
 377         string  s, a, msg;
 378         float w, type;
 379
 380         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 381         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 382         float notif_firstblood;
 383
 384
 385         dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 386
 387
 388         // =======
 389         // SUICIDE
 390         // =======
 391         if(targ == attacker)
 392         {
 393                 if(DEATH_ISSPECIAL(deathtype))
 394                 {
 395                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 396                         {
 397                                 s1 = targ.netname;
 398                                 f1 = targ.team;
 399                         }
 400                         else
 401                         {
 402                                 switch(deathtype)
 403                                 {
 404                                         case DEATH_MIRRORDAMAGE:
 405                                         {
 406                                                 s1 = targ.netname;
 407                                                 f1 = targ.killcount;
 408                                                 break;
 409                                         }
 410
 411                                         default:
 412                                         {
 413                                                 s1 = targ.netname;
 414                                                 f1 = targ.killcount;
 415                                                 s2 = NO_STR_ARG;
 416                                                 f2 = f3 = NO_FL_ARG;
 417                                                 break;
 418                                         }
 419                                 }
 420                                 LogDeath("suicide", deathtype, targ, targ);
 421                                 GiveFrags(attacker, targ, -1, deathtype);
 422                         }
 423                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 424                 }
 425                 else if(DEATH_WEAPONOF(deathtype))
 426                 {
 427                         Obituary_WeaponDeath(FALSE, deathtype, targ.netname, NO_STR_ARG);
 428                 }
 429                 else
 430                 {
 431                         backtrace("SUICIDE: what the hell happened here?\n");
 432                 }
 433         }
 434
 435
 436         // ======
 437         // MURDER
 438         // ======
 439         else if(attacker.classname == "player")
 440         {
 441                 s1 = attacker.netname;
 442                 s2 = targ.netname;
 443
 444                 // TODO: ADD REAL CHECK HERE!
 445                 attacker.FRAG_VERBOSE = TRUE;
 446                 targ.FRAG_VERBOSE = TRUE;
 447
 448                 if(!IsDifferentTeam(attacker, targ))
 449                 {
 450                         LogDeath("tk", deathtype, attacker, targ);
 451                         GiveFrags(attacker, targ, -1, deathtype);
 452
 453                         attacker.killcount = 0;
 454
 455                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 456                         Send_Notification(targ, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 457                         Send_Notification(world, MSG_ALL, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 458
 459                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 460                         // No need for specific death/weapon messages...
 461                         //if(DEATH_WEAPONOF(deathtype)) { print("Currently unhandled...\n"); }
 462                         //else { Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 463                 }
 464                 else
 465                 {
 466                         LogDeath("frag", deathtype, attacker, targ);
 467                         GiveFrags(attacker, targ, 1, deathtype);
 468
 469                         attacker.taunt_soundtime = time + 1;
 470                         attacker.killcount = attacker.killcount + 1;
 471                         if(targ.killcount > 2) { Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE); }
 472
 473                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 474                                 case numa: \
 475                                 { \
 476                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 478                                         break; \
 479                                 }
 480                         switch(attacker.killcount)
 481                         {
 482                                 ADD_ACHIEVEMENT_CASE(3, 03)
 483                                 ADD_ACHIEVEMENT_CASE(5, 05)
 484                                 ADD_ACHIEVEMENT_CASE(10, 10)
 485                                 ADD_ACHIEVEMENT_CASE(15, 15)
 486                                 ADD_ACHIEVEMENT_CASE(20, 20)
 487                                 ADD_ACHIEVEMENT_CASE(25, 25)
 488                                 ADD_ACHIEVEMENT_CASE(30, 30)
 489                                 default: break;
 490                         }
 491                         #undef ADD_ACHIEVEMENT_CASE
 492
 493                         if(!checkrules_firstblood)
 494                         {
 495                                 checkrules_firstblood = TRUE;
 496                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 497                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 498                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 499                         }
 500
 501                         if(notif_firstblood) // first blood, no kill sprees yet
 502                         {
 503                                 if(targ.istypefrag)
 504                                 {
 505                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 506                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 507
 508                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 509                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 510                                 }
 511                                 else
 512                                 {
 513                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 514                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 515
 516                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 517                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 518                                 }
 519                         }
 520                         else // normal frags, kill sprees listed
 521                         {
 522                                 if(targ.istypefrag)
 523                                 {
 524                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 525                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 526
 527                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 528                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 529                                 }
 530                                 else
 531                                 {
 532                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 533                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 534
 535                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 536                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 537                                 }
 538                         }
 539
 540                         if(DEATH_WEAPONOF(deathtype)) { Obituary_WeaponDeath(TRUE, deathtype, targ.netname, attacker.netname); }
 541                         else { Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG); }
 542                 }
 543         }
 544
 545         // =============
 546         // ACCIDENT/TRAP
 547         // =============
 548         else
 549         {
 550                 switch(deathtype)
 551                 {
 552                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 553                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 554                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 555                         /*case DEATH_HURTTRIGGER:
 556                         {
 557                                 s1 = targ.netname;
 558                                 s2 = inflictor.message;
 559                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 560                                 break;
 561                         }*/
 562
 563                         case DEATH_CUSTOM:
 564                         {
 565                                 s1 = targ.netname;
 566                                 s2 = deathmessage;
 567                                 f1 = targ.killcount;
 568                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 569                                 f2 = f3 = NO_FL_ARG;
 570                                 break;
 571                         }
 572
 573                         default:
 574                         {
 575                                 s1 = targ.netname;
 576                                 f1 = targ.killcount;
 577                                 s2 = NO_STR_ARG;
 578                                 f2 = f3 = NO_FL_ARG;
 579                                 break;
 580                         }
 581                 }
 582
 583                 LogDeath("accident", deathtype, targ, targ);
 584                 GiveFrags(targ, targ, -1, deathtype);
 585
 586                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 587                 {
 588                         AnnounceTo(targ, "botlike");
 589                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 590                 }
 591
 592                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 593         }
 594
 595         // Set final information for the death
 596         targ.death_origin = targ.origin;
 597         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 598         if(targ.killcount) { targ.killcount = 0; }
 599 }
 600
 601 // these are updated by each Damage call for use in button triggering and such
 602 entity damage_targ;
 603 entity damage_inflictor;
 604 entity damage_attacker;
 605
 606 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 607 {
 608         float mirrordamage;
 609         float mirrorforce;
 610         float teamdamage0;
 611         entity attacker_save;
 612         mirrordamage = 0;
 613         mirrorforce = 0;
 614
 615         if (gameover || targ.killcount == -666)
 616                 return;
 617
 618         entity oldself;
 619         oldself = self;
 620         self = targ;
 621         damage_targ = targ;
 622         damage_inflictor = inflictor;
 623         damage_attacker = attacker;
 624                 attacker_save = attacker;
 625
 626         if(targ.classname == "player")
 627                 if(targ.hook)
 628                         if(targ.hook.aiment)
 629                                 if(targ.hook.aiment == attacker)
 630                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 631
 632         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 633         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 634         {
 635                 if(targ.classname == "player")
 636                         if not(IsDifferentTeam(targ, attacker))
 637                         {
 638                                 self = oldself;
 639                                 return;
 640                         }
 641         }
 642
 643         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 644         {
 645                 // These are ALWAYS lethal
 646                 // No damage modification here
 647                 // Instead, prepare the victim for his death...
 648                 targ.armorvalue = 0;
 649                 targ.spawnshieldtime = 0;
 650                 targ.health = 0.9; // this is < 1
 651                 targ.flags -= targ.flags & FL_GODMODE;
 652                 damage = 100000;
 653         }
 654         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 655         {
 656                 // no processing
 657         }
 658         else
 659         {
 660                 /*
 661                 skill based bot damage? gtfo. (tZork)
 662                 if (targ.classname == "player")
 663                 if (attacker.classname == "player")
 664                 if (!targ.isbot)
 665                 if (attacker.isbot)
 666                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 667         */
 668
 669                 // nullify damage if teamplay is on
 670                 if(deathtype != DEATH_TELEFRAG)
 671                 if(attacker.classname == "player")
 672                 {
 673                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 674                         {
 675                                 damage = 0;
 676                                 force = '0 0 0';
 677                         }
 678                         else if(!IsDifferentTeam(attacker, targ))
 679                         {
 680                                 if(autocvar_teamplay_mode == 1)
 681                                         damage = 0;
 682                                 else if(attacker != targ)
 683                                 {
 684                                         if(autocvar_teamplay_mode == 3)
 685                                                 damage = 0;
 686                                         else if(autocvar_teamplay_mode == 4)
 687                                         {
 688                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 689                                                 {
 690                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 691                                                         attacker.dmg_team = attacker.dmg_team + damage;
 692                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 693                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 694                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 695                                                         if(g_minstagib)
 696                                                         {
 697                                                                 if(autocvar_g_friendlyfire == 0)
 698                                                                         damage = 0;
 699                                                         }
 700                                                         else if(g_ca)
 701                                                                 damage = 0;
 702                                                         else
 703                                                                 damage = autocvar_g_friendlyfire * damage;
 704                                                         // mirrordamage will be used LATER
 705
 706                                                         if(autocvar_g_mirrordamage_virtual)
 707                                                         {
 708                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 709                                                                 attacker.dmg_take += v_x;
 710                                                                 attacker.dmg_save += v_y;
 711                                                                 attacker.dmg_inflictor = inflictor;
 712                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 713                                                                 mirrorforce = 0;
 714                                                         }
 715
 716                                                         if(autocvar_g_friendlyfire_virtual)
 717                                                         {
 718                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 719                                                                 targ.dmg_take += v_x;
 720                                                                 targ.dmg_save += v_y;
 721                                                                 targ.dmg_inflictor = inflictor;
 722                                                                 damage = 0;
 723                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 724                                                                         force = '0 0 0';
 725                                                         }
 726                                                 }
 727                                                 else
 728                                                         damage = 0;
 729                                         }
 730                                 }
 731                         }
 732                 }
 733
 734                 if(targ.classname == "player")
 735                 if(attacker.classname == "player")
 736                 if(attacker != targ)
 737                 {
 738                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 739                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 740                 }
 741
 742                 if(targ.classname == "player")
 743                 if (g_minstagib)
 744                 {
 745                         if ((deathtype == DEATH_FALL)  ||
 746                                 (deathtype == DEATH_DROWN) ||
 747                                 (deathtype == DEATH_SLIME) ||
 748                                 (deathtype == DEATH_LAVA)  ||
 749                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 750                         {
 751                                 self = oldself;
 752                                 return;
 753                         }
 754                         if(damage > 0)
 755                             damage = 10000;
 756                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 757                         {
 758                                 targ.armorvalue -= 1;
 759                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 760                                 damage = 0;
 761                                 targ.hitsound += 1;
 762                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 763                         }
 764                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 765                         {
 766                                 damage = 0;
 767                                 mirrordamage = 0;
 768                                 if (targ != attacker)
 769                                 {
 770                                         if ((targ.health >= 1) && (targ.classname == "player"))
 771                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 772                                         force = '0 0 0';
 773                                         // keep mirrorforce
 774                                         attacker = targ;
 775                                 }
 776                         }
 777                 }
 778
 779                 if not(DEATH_ISSPECIAL(deathtype))
 780                 {
 781                         damage *= g_weapondamagefactor;
 782                         mirrordamage *= g_weapondamagefactor;
 783                         force = force * g_weaponforcefactor;
 784                         mirrorforce *= g_weaponforcefactor;
 785                 }
 786
 787                 // should this be changed at all? If so, in what way?
 788                 frag_attacker = attacker;
 789                 frag_target = targ;
 790                 frag_damage = damage;
 791                 frag_force = force;
 792         frag_deathtype = deathtype;
 793                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 794                 damage = frag_damage;
 795                 force = frag_force;
 796
 797                 // apply strength multiplier
 798                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 799                 {
 800                         if(targ == attacker)
 801                         {
 802                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 803                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 804                         }
 805                         else
 806                         {
 807                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 808                                 force = force * autocvar_g_balance_powerup_strength_force;
 809                         }
 810                 }
 811
 812                 // apply invincibility multiplier
 813                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 814                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 815
 816                 if (targ == attacker)
 817                 {
 818                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 819                                 damage = 0;
 820                         else
 821                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 822                 }
 823
 824                 if(g_runematch)
 825                 {
 826                         // apply strength rune
 827                         if (attacker.runes & RUNE_STRENGTH)
 828                         {
 829                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 830                                 {
 831                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 832                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 833                                 }
 834                                 else
 835                                 {
 836                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 837                                         force = force * autocvar_g_balance_rune_strength_force;
 838                                 }
 839                         }
 840                         else if (attacker.runes & CURSE_WEAK)
 841                         {
 842                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 843                                 force = force * autocvar_g_balance_curse_weak_force;
 844                         }
 845
 846                         // apply defense rune
 847                         if (targ.runes & RUNE_DEFENSE)
 848                         {
 849                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 850                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 851                                 else
 852                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 853                         }
 854                         else if (targ.runes & CURSE_VULNER)
 855                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 856                 }
 857
 858                 // count the damage
 859                 if(attacker)
 860                 if(!targ.deadflag)
 861                 if(targ.takedamage == DAMAGE_AIM)
 862                 if(targ != attacker)
 863                 {
 864                         if(damage_headshotbonus)
 865                         {
 866                                 if(targ.classname == "player")
 867                                 {
 868                                         // HEAD SHOT:
 869                                         // find height of hit on player axis
 870                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 871                                         vector headmins, headmaxs, org;
 872                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 873                                         headmins = org + GetHeadshotMins(targ);
 874                                         headmaxs = org + GetHeadshotMaxs(targ);
 875                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 876                                         {
 877                                                 deathtype |= HITTYPE_HEADSHOT;
 878                                         }
 879                                 }
 880                                 else if(targ.classname == "turret_head")
 881                                 {
 882                                         deathtype |= HITTYPE_HEADSHOT;
 883                                 }
 884                                 if(deathtype & HITTYPE_HEADSHOT)
 885                                         if(damage_headshotbonus > 0)
 886                                                 damage *= 1 + damage_headshotbonus;
 887                         }
 888
 889                         entity victim;
 890                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 891                                 victim = targ.owner;
 892                         else
 893                                 victim = targ;
 894
 895                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 896                         {
 897                                 if(IsDifferentTeam(victim, attacker))
 898                                 {
 899                                         if(damage > 0)
 900                                         {
 901                                                 if(deathtype != DEATH_FIRE)
 902                                                 {
 903                                                         if(victim.BUTTON_CHAT)
 904                                                                 attacker.typehitsound += 1;
 905                                                         else
 906                                                                 attacker.hitsound += 1;
 907                                                 }
 908
 909                                                 damage_goodhits += 1;
 910                                                 damage_gooddamage += damage;
 911
 912                                                 if not(DEATH_ISSPECIAL(deathtype))
 913                                                 {
 914                                                         if(targ.classname == "player") // don't do this for vehicles
 915                                                         if(!g_minstagib)
 916                                                         if(IsFlying(victim))
 917                                                                 yoda = 1;
 918
 919                                                         if(g_minstagib)
 920                                                         if(victim.items & IT_STRENGTH)
 921                                                                 yoda = 1;
 922
 923                                                         if(deathtype & HITTYPE_HEADSHOT)
 924                                                                 headshot = 1;
 925                                                 }
 926                                         }
 927                                 }
 928                                 else
 929                                 {
 930                                         if(deathtype != DEATH_FIRE)
 931                                         {
 932                                                 attacker.typehitsound += 1;
 933                                         }
 934                                         if(mirrordamage > 0)
 935                                                 if(time > attacker.teamkill_complain)
 936                                                 {
 937                                                         attacker.teamkill_complain = time + 5;
 938                                                         attacker.teamkill_soundtime = time + 0.4;
 939                                                         attacker.teamkill_soundsource = targ;
 940                                                 }
 941                                 }
 942                         }
 943                 }
 944         }
 945
 946         // apply push
 947         if (self.damageforcescale)
 948         if (vlen(force))
 949         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 950         {
 951                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 952                 if(self.movetype == MOVETYPE_PHYSICS)
 953                 {
 954                         entity farcent;
 955                         farcent = spawn();
 956                         farcent.classname = "farce";
 957                         farcent.enemy = self;
 958                         farcent.movedir = farce * 10;
 959                         if(self.mass)
 960                                 farcent.movedir = farcent.movedir * self.mass;
 961                         farcent.origin = hitloc;
 962                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 963                         farcent.nextthink = time + 0.1;
 964                         farcent.think = SUB_Remove;
 965                 }
 966                 else
 967                         self.velocity = self.velocity + farce;
 968                 self.flags &~= FL_ONGROUND;
 969                 UpdateCSQCProjectile(self);
 970         }
 971         // apply damage
 972         if (damage != 0 || (self.damageforcescale && vlen(force)))
 973         if (self.event_damage)
 974                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 975         self = oldself;
 976
 977         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 978         {
 979                 if(g_runematch)
 980                 {
 981                         if (attacker.runes & RUNE_VAMPIRE)
 982                         {
 983                         // apply vampire rune
 984                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 985                                 {
 986                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 987                                         attacker.health = bound(
 988                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 989                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 990                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 991                                 }
 992                                 else
 993                                 {
 994                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 995                                         attacker.health = bound(
 996                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 997                                                                                         // empathy won't let you gain health in the same way...
 998                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 999                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1000                                         }
1001                         }
1002                         // apply empathy curse
1003                         else if (attacker.runes & CURSE_EMPATHY)
1004                         {
1005                                 attacker.health = bound(
1006                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1007                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1008                                         attacker.health);
1009                         }
1010                 }
1011         }
1012
1013         // apply mirror damage if any
1014         if(mirrordamage > 0 || mirrorforce > 0)
1015         {
1016                 attacker = attacker_save;
1017                 if(g_minstagib)
1018                 if(mirrordamage > 0)
1019                 {
1020                         // just lose extra LIVES, don't kill the player for mirror damage
1021                         if(attacker.armorvalue > 0)
1022                         {
1023                                 attacker.armorvalue = attacker.armorvalue - 1;
1024                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1025                                 attacker.hitsound += 1;
1026                         }
1027                         mirrordamage = 0;
1028                 }
1029
1030                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1031                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1032         }
1033 }
1034
1035 float RadiusDamage_running;
1036 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1037         // Returns total damage applies to creatures
1038 {
1039         entity  targ;
1040         vector  blastorigin;
1041         vector  force;
1042         float   total_damage_to_creatures;
1043         entity  next;
1044         float   tfloordmg;
1045         float   tfloorforce;
1046
1047         float stat_damagedone;
1048
1049         if(RadiusDamage_running)
1050         {
1051                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1052                 return 0;
1053         }
1054
1055         RadiusDamage_running = 1;
1056
1057         tfloordmg = autocvar_g_throughfloor_damage;
1058         tfloorforce = autocvar_g_throughfloor_force;
1059
1060         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1061         total_damage_to_creatures = 0;
1062
1063         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1064                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1065                 {
1066                         force = inflictor.velocity;
1067                         if(vlen(force) == 0)
1068                                 force = '0 0 -1';
1069                         else
1070                                 force = normalize(force);
1071                         if(forceintensity >= 0)
1072                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1073                         else
1074                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1075                 }
1076
1077         stat_damagedone = 0;
1078
1079         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1080         while (targ)
1081         {
1082                 next = targ.chain;
1083                 if (targ != inflictor)
1084                         if (ignore != targ) if(targ.takedamage)
1085                         {
1086                                 vector nearest;
1087                                 vector diff;
1088                                 float power;
1089
1090                                 // LordHavoc: measure distance to nearest point on target (not origin)
1091                                 // (this guarentees 100% damage on a touch impact)
1092                                 nearest = targ.WarpZone_findradius_nearest;
1093                                 diff = targ.WarpZone_findradius_dist;
1094                                 // round up a little on the damage to ensure full damage on impacts
1095                                 // and turn the distance into a fraction of the radius
1096                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1097                                 //bprint(" ");
1098                                 //bprint(ftos(power));
1099                                 //if (targ == attacker)
1100                                 //      print(ftos(power), "\n");
1101                                 if (power > 0)
1102                                 {
1103                                         float finaldmg;
1104                                         if (power > 1)
1105                                                 power = 1;
1106                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1107                                         if (finaldmg > 0)
1108                                         {
1109                                                 float a;
1110                                                 float c;
1111                                                 vector hitloc;
1112                                                 vector myblastorigin;
1113                                                 vector center;
1114
1115                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1116
1117                                                 // if it's a player, use the view origin as reference
1118                                                 center = CENTER_OR_VIEWOFS(targ);
1119
1120                                                 force = normalize(center - myblastorigin);
1121                                                 force = force * (finaldmg / coredamage) * forceintensity;
1122                                                 hitloc = nearest;
1123
1124                                                 if(targ != directhitentity)
1125                                                 {
1126                                                         float hits;
1127                                                         float total;
1128                                                         float hitratio;
1129                                                         float mininv_f, mininv_d;
1130
1131                                                         // test line of sight to multiple positions on box,
1132                                                         // and do damage if any of them hit
1133                                                         hits = 0;
1134
1135                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1136                                                         // so for a given max stddev:
1137                                                         // n = (1 / (2 * max stddev of hitratio))^2
1138
1139                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1140                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1141
1142                                                         if(autocvar_g_throughfloor_debug)
1143                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1144
1145                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1146
1147                                                         if(autocvar_g_throughfloor_debug)
1148                                                                 print(sprintf(" steps=%f", total));
1149
1150                                                         if (targ.classname == "player")
1151                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1152                                                         else
1153                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1154
1155                                                         if(autocvar_g_throughfloor_debug)
1156                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1157
1158                                                         for(c = 0; c < total; ++c)
1159                                                         {
1160                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1161                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1162                                                                 if (trace_fraction == 1 || trace_ent == targ)
1163                                                                 {
1164                                                                         ++hits;
1165                                                                         if (hits > 1)
1166                                                                                 hitloc = hitloc + nearest;
1167                                                                         else
1168                                                                                 hitloc = nearest;
1169                                                                 }
1170                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1171                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1172                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1173                                                         }
1174
1175                                                         nearest = hitloc * (1 / max(1, hits));
1176                                                         hitratio = (hits / total);
1177                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1178                                                         finaldmg = finaldmg * a;
1179                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1180                                                         force = force * a;
1181
1182                                                         if(autocvar_g_throughfloor_debug)
1183                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1184                                                 }
1185
1186                                                 // laser force adjustments :P
1187                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1188                                                 {
1189                                                         if (targ == attacker)
1190                                                         {
1191                                                                 vector vel;
1192
1193                                                                 float force_zscale;
1194                                                                 float force_velocitybiasramp;
1195                                                                 float force_velocitybias;
1196
1197                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1198                                                                 if(deathtype & HITTYPE_SECONDARY)
1199                                                                 {
1200                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1201                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1202                                                                 }
1203                                                                 else
1204                                                                 {
1205                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1206                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1207                                                                 }
1208
1209                                                                 vel = targ.velocity;
1210                                                                 vel_z = 0;
1211                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1212                                                                 force =
1213                                                                         vlen(force)
1214                                                                         *
1215                                                                         normalize(normalize(force) + vel);
1216
1217                                                                 force_z *= force_zscale;
1218                                                         }
1219                                                         else
1220                                                         {
1221                                                                 if(deathtype & HITTYPE_SECONDARY)
1222                                                                 {
1223                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1224                                                                 }
1225                                                                 else
1226                                                                 {
1227                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1228                                                                 }
1229                                                         }
1230                                                 }
1231
1232                                                 //if (targ == attacker)
1233                                                 //{
1234                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1235                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1236                                                 //      print(" (", ftos(a), ")\n");
1237                                                 //}
1238                                                 if(finaldmg || vlen(force))
1239                                                 {
1240                                                         if(targ.iscreature)
1241                                                         {
1242                                                                 total_damage_to_creatures += finaldmg;
1243
1244                                                                 if(accuracy_isgooddamage(attacker, targ))
1245                                                                         stat_damagedone += finaldmg;
1246                                                         }
1247
1248                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1249                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1250                                                         else
1251                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1252                                                 }
1253                                         }
1254                                 }
1255                         }
1256                 targ = next;
1257         }
1258
1259         RadiusDamage_running = 0;
1260
1261         if(!DEATH_ISSPECIAL(deathtype))
1262                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1263
1264         return total_damage_to_creatures;
1265 }
1266
1267 .float fire_damagepersec;
1268 .float fire_endtime;
1269 .float fire_deathtype;
1270 .entity fire_owner;
1271 .float fire_hitsound;
1272 .entity fire_burner;
1273
1274 void fireburner_think();
1275
1276 float Fire_IsBurning(entity e)
1277 {
1278         return (time < e.fire_endtime);
1279 }
1280
1281 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1282 {
1283         float dps;
1284         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1285
1286         if(e.classname == "player")
1287         {
1288                 if(e.deadflag)
1289                         return -1;
1290         }
1291         else
1292         {
1293                 if(!e.fire_burner)
1294                 {
1295                         // print("adding a fire burner to ", e.classname, "\n");
1296                         e.fire_burner = spawn();
1297                         e.fire_burner.classname = "fireburner";
1298                         e.fire_burner.think = fireburner_think;
1299                         e.fire_burner.nextthink = time;
1300                         e.fire_burner.owner = e;
1301                 }
1302         }
1303
1304         t = max(t, 0.1);
1305         dps = d / t;
1306         if(Fire_IsBurning(e))
1307         {
1308                 mintime = e.fire_endtime - time;
1309                 maxtime = max(mintime, t);
1310
1311                 mindps = e.fire_damagepersec;
1312                 maxdps = max(mindps, dps);
1313
1314                 if(maxtime > mintime || maxdps > mindps)
1315                 {
1316                         // Constraints:
1317
1318                         // damage we have right now
1319                         mindamage = mindps * mintime;
1320
1321                         // damage we want to get
1322                         maxdamage = mindamage + d;
1323
1324                         // but we can't exceed maxtime * maxdps!
1325                         totaldamage = min(maxdamage, maxtime * maxdps);
1326
1327                         // LEMMA:
1328                         // Look at:
1329                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1330                         // We see:
1331                         // totaldamage <= maxtime * maxdps
1332                         // ==> totaldamage / maxdps <= maxtime.
1333                         // We also see:
1334                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1335                         //                     >= min(mintime, maxtime)
1336                         // ==> totaldamage / maxdps >= mintime.
1337
1338                         /*
1339                         // how long do we damage then?
1340                         // at least as long as before
1341                         // but, never exceed maxdps
1342                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1343                         */
1344
1345                         // alternate:
1346                         // at most as long as maximum allowed
1347                         // but, never below mindps
1348                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1349
1350                         // assuming t > mintime, dps > mindps:
1351                         // we get d = t * dps = maxtime * maxdps
1352                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1353                         // totaldamage / maxdps = maxtime
1354                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1355                         // FROM THIS:
1356                         // a) totaltime = max(mintime, maxtime) = maxtime
1357                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1358
1359                         // assuming t <= mintime:
1360                         // we get maxtime = mintime
1361                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1362                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1363
1364                         // assuming dps <= mindps:
1365                         // we get mindps = maxdps.
1366                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1367                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1368                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1369
1370                         e.fire_damagepersec = totaldamage / totaltime;
1371                         e.fire_endtime = time + totaltime;
1372                         if(totaldamage > 1.2 * mindamage)
1373                         {
1374                                 e.fire_deathtype = dt;
1375                                 if(e.fire_owner != o)
1376                                 {
1377                                         e.fire_owner = o;
1378                                         e.fire_hitsound = FALSE;
1379                                 }
1380                         }
1381                         if(accuracy_isgooddamage(o, e))
1382                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1383                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1384                 }
1385                 else
1386                         return 0;
1387         }
1388         else
1389         {
1390                 e.fire_damagepersec = dps;
1391                 e.fire_endtime = time + t;
1392                 e.fire_deathtype = dt;
1393                 e.fire_owner = o;
1394                 e.fire_hitsound = FALSE;
1395                 if(accuracy_isgooddamage(o, e))
1396                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1397                 return d;
1398         }
1399 }
1400
1401 void Fire_ApplyDamage(entity e)
1402 {
1403         float t, d, hi, ty;
1404         entity o;
1405
1406         if not(Fire_IsBurning(e))
1407                 return;
1408
1409         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1410         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1411                 o = e.fire_owner;
1412
1413         // water and slime stop fire
1414         if(e.waterlevel)
1415         if(e.watertype != CONTENT_LAVA)
1416                 e.fire_endtime = 0;
1417
1418         // ice stops fire
1419         if(e.freezetag_frozen)
1420                 e.fire_endtime = 0;
1421
1422         t = min(frametime, e.fire_endtime - time);
1423         d = e.fire_damagepersec * t;
1424
1425         hi = e.fire_owner.hitsound;
1426         ty = e.fire_owner.typehitsound;
1427         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1428         if(e.fire_hitsound && e.fire_owner)
1429         {
1430                 e.fire_owner.hitsound = hi;
1431                 e.fire_owner.typehitsound = ty;
1432         }
1433         e.fire_hitsound = TRUE;
1434
1435         if not(IS_INDEPENDENT_PLAYER(e))
1436         FOR_EACH_PLAYER(other) if(e != other)
1437         {
1438                 if(other.classname == "player")
1439                 if(other.deadflag == DEAD_NO)
1440                 if not(IS_INDEPENDENT_PLAYER(other))
1441                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1442                 {
1443                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1444                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1445                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1446                 }
1447         }
1448 }
1449
1450 void Fire_ApplyEffect(entity e)
1451 {
1452         if(Fire_IsBurning(e))
1453                 e.effects |= EF_FLAME;
1454         else
1455                 e.effects &~= EF_FLAME;
1456 }
1457
1458 void fireburner_think()
1459 {
1460         // for players, this is done in the regular loop
1461         if(wasfreed(self.owner))
1462         {
1463                 remove(self);
1464                 return;
1465         }
1466         Fire_ApplyEffect(self.owner);
1467         if(!Fire_IsBurning(self.owner))
1468         {
1469                 self.owner.fire_burner = world;
1470                 remove(self);
1471                 return;
1472         }
1473         Fire_ApplyDamage(self.owner);
1474         self.nextthink = time;
1475 }