qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_td");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_runematch");
 276                 BADCVAR("g_tdm");
 277                 BADCVAR("g_tdm_teams");
 278                 BADCVAR("leadlimit");
 279                 BADCVAR("nextmap");
 280                 BADCVAR("teamplay");
 281                 BADCVAR("timelimit");
 282
 283                 // long
 284                 BADCVAR("hostname");
 285                 BADCVAR("g_maplist");
 286                 BADCVAR("g_maplist_mostrecent");
 287                 BADCVAR("sv_motd");
 288
 289                 v = cvar_string(k);
 290                 d = cvar_defstring(k);
 291                 if(v == d)
 292                         continue;
 293
 294                 if(adding)
 295                 {
 296                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 297                         if(strlen(cvar_changes) > 16384)
 298                         {
 299                                 cvar_changes = "// too many settings have been changed to show them here\n";
 300                                 adding = 0;
 301                         }
 302                 }
 303
 304                 // now check if the changes are actually gameplay relevant
 305
 306                 // does nothing visible
 307                 BADCVAR("captureleadlimit_override");
 308                 BADCVAR("g_arena_point_leadlimit");
 309                 BADCVAR("g_balance_kill_delay");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ctf_captimerecord_always");
 312                 BADCVAR("g_ctf_flag_glowtrails");
 313                 BADCVAR("g_ctf_flag_pickup_verbosename");
 314                 BADCVAR("g_domination_point_leadlimit");
 315                 BADCVAR("g_forced_respawn");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_runematch_point_leadlimit");
 320                 BADCVAR("leadlimit_and_fraglimit");
 321                 BADCVAR("leadlimit_override");
 322                 BADCVAR("pausable");
 323                 BADCVAR("sv_allow_fullbright");
 324                 BADCVAR("sv_checkforpacketsduringsleep");
 325                 BADCVAR("sv_fraginfo");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADCVAR("welcome_message_time");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_fraginfo_");
 338                 BADPREFIX("sv_maxidle_");
 339                 BADPREFIX("sv_vote_");
 340                 BADPREFIX("timelimit_");
 341                 BADCVAR("gameversion");
 342                 BADPREFIX("gameversion_");
 343                 BADCVAR("sv_namechangetimer");
 344 #ifndef NO_LEGACY_NETWORKING
 345                 BADCVAR("sv_use_csqc_players"); // transition
 346 #endif
 347
 348                 // allowed changes to server admins (please sync this to server.cfg)
 349                 // vi commands:
 350                 //   :/"impure"/,$d
 351                 //   :g!,^\/\/[^ /],d
 352                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 353                 //   :%!sort
 354                 // yes, this does contain some redundant stuff, don't really care
 355                 BADCVAR("bot_config_file");
 356                 BADCVAR("bot_number");
 357                 BADCVAR("bot_prefix");
 358                 BADCVAR("bot_suffix");
 359                 BADCVAR("capturelimit_override");
 360                 BADCVAR("fraglimit_override");
 361                 BADCVAR("gametype");
 362                 BADCVAR("g_antilag");
 363                 BADCVAR("g_balance_teams");
 364                 BADCVAR("g_balance_teams_prevent_imbalance");
 365                 BADCVAR("g_balance_teams_scorefactor");
 366                 BADCVAR("g_ban_sync_trusted_servers");
 367                 BADCVAR("g_ban_sync_uri");
 368                 BADCVAR("g_ctf_ignore_frags");
 369                 BADCVAR("g_domination_point_limit");
 370                 BADCVAR("g_friendlyfire");
 371                 BADCVAR("g_fullbrightitems");
 372                 BADCVAR("g_fullbrightplayers");
 373                 BADCVAR("g_keyhunt_point_limit");
 374                 BADCVAR("g_keyhunt_teams_override");
 375                 BADCVAR("g_lms_lives_override");
 376                 BADCVAR("g_maplist");
 377                 BADCVAR("g_maplist_check_waypoints");
 378                 BADCVAR("g_maplist_mostrecent_count");
 379                 BADCVAR("g_maplist_shuffle");
 380                 BADCVAR("g_maplist_votable");
 381                 BADCVAR("g_maplist_votable_abstain");
 382                 BADCVAR("g_maplist_votable_nodetail");
 383                 BADCVAR("g_maplist_votable_suggestions");
 384                 BADCVAR("g_maxplayers");
 385                 BADCVAR("g_mirrordamage");
 386                 BADCVAR("g_nexball_goallimit");
 387                 BADCVAR("g_powerups");
 388                 BADCVAR("g_runematch_point_limit");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_warmup");
 391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_adminnick");
 403                 BADCVAR("sv_autoscreenshot");
 404                 BADCVAR("sv_autotaunt");
 405                 BADCVAR("sv_curl_defaulturl");
 406                 BADCVAR("sv_defaultcharacter");
 407                 BADCVAR("sv_defaultplayercolors");
 408                 BADCVAR("sv_defaultplayermodel");
 409                 BADCVAR("sv_defaultplayerskin");
 410                 BADCVAR("sv_maxidle");
 411                 BADCVAR("sv_maxrate");
 412                 BADCVAR("sv_motd");
 413                 BADCVAR("sv_public");
 414                 BADCVAR("sv_ready_restart");
 415                 BADCVAR("sv_status_privacy");
 416                 BADCVAR("sv_taunt");
 417                 BADCVAR("sv_vote_call");
 418                 BADCVAR("sv_vote_commands");
 419                 BADCVAR("sv_vote_majority_factor");
 420                 BADCVAR("sv_vote_master");
 421                 BADCVAR("sv_vote_master_commands");
 422                 BADCVAR("sv_vote_master_password");
 423                 BADCVAR("sv_vote_simple_majority_factor");
 424                 BADCVAR("sys_ticrate");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_minstagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435
 436                 if(autocvar_g_minstagib)
 437                 {
 438                         BADCVAR("g_grappling_hook");
 439                         BADCVAR("g_jetpack");
 440                 }
 441 #undef BADPREFIX
 442 #undef BADCVAR
 443
 444                 if(pureadding)
 445                 {
 446                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 447                         if(strlen(cvar_purechanges) > 16384)
 448                         {
 449                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 450                                 pureadding = 0;
 451                         }
 452                 }
 453                 ++cvar_purechanges_count;
 454                 // WARNING: this variable is used for the server list
 455                 // NEVER dare to skip this code!
 456                 // Hacks to intentionally appearing as "pure server" even though you DO have
 457                 // modified settings may be punished by removal from the server list.
 458                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 459                 // though.
 460         }
 461         buf_del(h);
 462         if(cvar_changes == "")
 463                 cvar_changes = "// this server runs at default server settings\n";
 464         else
 465                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 466         cvar_changes = strzone(cvar_changes);
 467         if(cvar_purechanges == "")
 468                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 469         else
 470                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 471         cvar_purechanges = strzone(cvar_purechanges);
 472 }
 473
 474 void detect_maptype()
 475 {
 476 #if 0
 477         vector o, v;
 478         float i;
 479
 480         for(;;)
 481         {
 482                 o = world.mins;
 483                 o_x += random() * (world.maxs_x - world.mins_x);
 484                 o_y += random() * (world.maxs_y - world.mins_y);
 485                 o_z += random() * (world.maxs_z - world.mins_z);
 486
 487                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 488                 if(trace_fraction == 1)
 489                         continue;
 490
 491                 v = trace_endpos;
 492
 493                 for(i = 0; i < 64; i += 4)
 494                 {
 495                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 496         if(trace_fraction == 1)
 497                 continue;
 498                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 499                 }
 500
 501                 break;
 502         }
 503 #endif
 504 }
 505
 506 entity randomseed;
 507 float RandomSeed_Send(entity to, float sf)
 508 {
 509         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 510         WriteShort(MSG_ENTITY, self.cnt);
 511         return TRUE;
 512 }
 513 void RandomSeed_Think()
 514 {
 515         self.cnt = bound(0, floor(random() * 65536), 65535);
 516         self.nextthink = time + 5;
 517
 518         self.SendFlags |= 1;
 519 }
 520 void RandomSeed_Spawn()
 521 {
 522         randomseed = spawn();
 523         randomseed.think = RandomSeed_Think;
 524         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 525
 526         entity oldself;
 527         oldself = self;
 528         self = randomseed;
 529         self.think(); // sets random seed and nextthink
 530         self = oldself;
 531 }
 532
 533 void spawnfunc___init_dedicated_server(void)
 534 {
 535         // handler for _init/_init map (only for dedicated server initialization)
 536
 537         world_initialized = -1; // don't complain
 538         cvar = cvar_normal;
 539         cvar_string = cvar_string_normal;
 540         cvar_set = cvar_set_normal;
 541
 542         remove = remove_unsafely;
 543
 544         entity e;
 545         e = spawn();
 546         e.think = GotoFirstMap;
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = spawn();
 550         e.classname = "info_player_deathmatch"; // safeguard against player joining
 551
 552         self.classname = "worldspawn"; // safeguard against various stuff ;)
 553
 554         // needs to be done so early because of the constants they create
 555         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 556         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 557
 558         MapInfo_Enumerate();
 559         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 560 }
 561
 562 void Map_MarkAsRecent(string m);
 563 float world_already_spawned;
 564 void Nagger_Init();
 565 void ClientInit_Spawn();
 566 void WeaponStats_Init();
 567 void WeaponStats_Shutdown();
 568 void spawnfunc_worldspawn (void)
 569 {
 570         float fd, l, i, j, n;
 571         string s, col;
 572
 573         cvar = cvar_normal;
 574         cvar_string = cvar_string_normal;
 575         cvar_set = cvar_set_normal;
 576
 577         if(world_already_spawned)
 578                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 579         world_already_spawned = TRUE;
 580
 581         remove = remove_safely; // during spawning, watch what you remove!
 582
 583         check_unacceptable_compiler_bugs();
 584
 585         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 586
 587         compressShortVector_init();
 588
 589         allowed_to_spawn = TRUE;
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         // needs to be done so early because of the constants they create
 601         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 602         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 788         Nagger_Init();
 789
 790         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 791         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 792         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 793         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 794         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 795         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 796         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 797         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 798         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 799         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 800         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 801         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 802         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 803
 804         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 805         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 806
 807         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 808
 809         if(g_ca || g_freezetag)
 810         {
 811                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 812                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 813                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 814                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 815         }
 816         if(g_freezetag)
 817         {
 818                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 819                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 820         }
 821
 822         if(g_td)
 823         {
 824                 addstat(STAT_CURRENT_WAVE, AS_FLOAT, stat_current_wave);
 825                 addstat(STAT_TOTALWAVES, AS_FLOAT, stat_totalwaves);
 826         }
 827
 828         // freeze attacks
 829         addstat(STAT_FROZEN, AS_INT, frozen);
 830         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 831
 832         // g_movementspeed hack
 833         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 834         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 835         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 836         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 837
 838         // secrets
 839         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 840         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 841
 842         // monsters
 843         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 844         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 845
 846         // misc
 847         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 848
 849         next_pingtime = time + 5;
 850
 851         detect_maptype();
 852
 853         // set up information replies for clients and server to use
 854         lsmaps_reply = "^7Maps available: ";
 855         lsnewmaps_reply = "^7Maps without a record set: ";
 856         for(i = 0, j = 0; i < MapInfo_count; ++i)
 857         {
 858                 if(MapInfo_Get_ByID(i))
 859                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 860                         {
 861                                 if(mod(i, 2))
 862                                         col = "^2";
 863                                 else
 864                                         col = "^3";
 865
 866                                 ++j;
 867
 868                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 869
 870                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 871                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 872                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 873                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 874                         }
 875         }
 876
 877         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 878         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 879
 880         maplist_reply = "^7Maps in list: ";
 881         n = tokenize_console(autocvar_g_maplist);
 882         for(i = 0, j = 0; i < n; ++i)
 883         {
 884                 if(MapInfo_CheckMap(argv(i)))
 885                 {
 886                         if(mod(j, 2))
 887                                 col = "^2";
 888                         else
 889                                 col = "^3";
 890                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 891                         ++j;
 892                 }
 893         }
 894         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 895         MapInfo_ClearTemps();
 896
 897         for(i = 0; i < 10; ++i)
 898         {
 899                 s = getrecords(i);
 900                 if (s)
 901                         records_reply[i] = strzone(s);
 902         }
 903
 904         ladder_reply = strzone(getladder());
 905
 906         rankings_reply = strzone(getrankings());
 907
 908         // begin other init
 909         ClientInit_Spawn();
 910         RandomSeed_Spawn();
 911         PingPLReport_Spawn();
 912
 913         CheatInit();
 914
 915         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 916
 917         // fill sv_curl_serverpackages from .serverpackage files
 918         if(autocvar_sv_curl_serverpackages_auto)
 919         {
 920                 s = "";
 921                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 922                 for(i = 0; i < n; ++i)
 923                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 924                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 925                                 s = strcat(s, " ", argv(i));
 926                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 927                 if(fd >= 0)
 928                 {
 929                         j = search_getsize(fd);
 930                         for(i = 0; i < j; ++i)
 931                                 s = strcat(s, " ", search_getfilename(fd, i));
 932                         search_end(fd);
 933                 }
 934                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 935                 if(fd >= 0)
 936                 {
 937                         j = search_getsize(fd);
 938                         for(i = 0; i < j; ++i)
 939                                 s = strcat(s, " ", search_getfilename(fd, i));
 940                         search_end(fd);
 941                 }
 942                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 943         }
 944
 945         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 946         modname = "Xonotic";
 947         // physics/balance/config changes that count as mod
 948         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 949                 modname = cvar_string("g_mod_physics");
 950         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 951                 modname = cvar_string("g_mod_balance");
 952         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 953                 modname = cvar_string("g_mod_config");
 954         // weird mutators that deserve to count as mod
 955         if(autocvar_g_minstagib)
 956                 modname = "MinstaGib";
 957         if(autocvar_g_monsters)
 958                 modname = "Monsters";
 959         // extra mutators that deserve to count as mod
 960         MUTATOR_CALLHOOK(SetModname);
 961
 962         // save it for later
 963         modname = strzone(modname);
 964
 965         WinningConditionHelper(); // set worldstatus
 966
 967         world_initialized = 1;
 968 }
 969
 970 void spawnfunc_light (void)
 971 {
 972         //makestatic (self); // Who the f___ did that?
 973         remove(self);
 974 }
 975
 976 string GetGametype()
 977 {
 978         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 979 }
 980
 981 string getmapname_stored;
 982 string GetMapname()
 983 {
 984         return mapname;
 985 }
 986
 987 float Map_Count, Map_Current;
 988 string Map_Current_Name;
 989
 990 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 991 float GetMaplistPosition()
 992 {
 993         float pos, idx;
 994         string map;
 995
 996         map = GetMapname();
 997         idx = autocvar_g_maplist_index;
 998
 999         if(idx >= 0)
1000                 if(idx < Map_Count)
1001                         if(map == argv(idx))
1002                                 return idx;
1003
1004         for(pos = 0; pos < Map_Count; ++pos)
1005                 if(map == argv(pos))
1006                         return pos;
1007
1008         // resume normal maplist rotation if current map is not in g_maplist
1009         return idx;
1010 }
1011
1012 float MapHasRightSize(string map)
1013 {
1014         float fh;
1015         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1016         if(autocvar_g_maplist_check_waypoints)
1017         {
1018                 dprint("checkwp "); dprint(map);
1019                 if(!fexists(strcat("maps/", map, ".waypoints")))
1020                 {
1021                         dprint(": no waypoints\n");
1022                         return FALSE;
1023                 }
1024                 dprint(": has waypoints\n");
1025         }
1026
1027         // open map size restriction file
1028         dprint("opensize "); dprint(map);
1029         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1030         if(fh >= 0)
1031         {
1032                 float mapmin, mapmax;
1033                 dprint(": ok, ");
1034                 mapmin = stof(fgets(fh));
1035                 mapmax = stof(fgets(fh));
1036                 fclose(fh);
1037                 if(player_count < mapmin)
1038                 {
1039                         dprint("not enough\n");
1040                         return FALSE;
1041                 }
1042                 if(player_count > mapmax)
1043                 {
1044                         dprint("too many\n");
1045                         return FALSE;
1046                 }
1047                 dprint("right size\n");
1048                 return TRUE;
1049         }
1050         dprint(": not found\n");
1051         return TRUE;
1052 }
1053
1054 string Map_Filename(float position)
1055 {
1056         return strcat("maps/", argv(position), ".bsp");
1057 }
1058
1059 string strwords(string s, float w)
1060 {
1061         float endpos;
1062         for(endpos = 0; w && endpos >= 0; --w)
1063                 endpos = strstrofs(s, " ", endpos + 1);
1064         if(endpos < 0)
1065                 return s;
1066         else
1067                 return substring(s, 0, endpos);
1068 }
1069
1070 float strhasword(string s, string w)
1071 {
1072         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1073 }
1074
1075 void Map_MarkAsRecent(string m)
1076 {
1077         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1078 }
1079
1080 float Map_IsRecent(string m)
1081 {
1082         return strhasword(autocvar_g_maplist_mostrecent, m);
1083 }
1084
1085 float Map_Check(float position, float pass)
1086 {
1087         string filename;
1088         string map_next;
1089         map_next = argv(position);
1090         if(pass <= 1)
1091         {
1092                 if(Map_IsRecent(map_next))
1093                         return 0;
1094         }
1095         filename = Map_Filename(position);
1096         if(MapInfo_CheckMap(map_next))
1097         {
1098                 if(pass == 2)
1099                         return 1;
1100                 if(MapHasRightSize(map_next))
1101                         return 1;
1102                 return 0;
1103         }
1104         else
1105                 dprint( "Couldn't select '", filename, "'..\n" );
1106
1107         return 0;
1108 }
1109
1110 void Map_Goto_SetStr(string nextmapname)
1111 {
1112         if(getmapname_stored != "")
1113                 strunzone(getmapname_stored);
1114         if(nextmapname == "")
1115                 getmapname_stored = "";
1116         else
1117                 getmapname_stored = strzone(nextmapname);
1118 }
1119
1120 void Map_Goto_SetFloat(float position)
1121 {
1122         cvar_set("g_maplist_index", ftos(position));
1123         Map_Goto_SetStr(argv(position));
1124 }
1125
1126 void Map_Goto(float reinit)
1127 {
1128         MapInfo_LoadMap(getmapname_stored, reinit);
1129 }
1130
1131 // return codes of map selectors:
1132 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1133 //   -2 = permanent failure
1134 float() MaplistMethod_Iterate = // usual method
1135 {
1136         float pass, i;
1137
1138         for(pass = 1; pass <= 2; ++pass)
1139         {
1140                 for(i = 1; i < Map_Count; ++i)
1141                 {
1142                         float mapindex;
1143                         mapindex = mod(i + Map_Current, Map_Count);
1144                         if(Map_Check(mapindex, pass))
1145                                 return mapindex;
1146                 }
1147         }
1148         return -1;
1149 }
1150
1151 float() MaplistMethod_Repeat = // fallback method
1152 {
1153         if(Map_Check(Map_Current, 2))
1154                 return Map_Current;
1155         return -2;
1156 }
1157
1158 float() MaplistMethod_Random = // random map selection
1159 {
1160         float i, imax;
1161
1162         imax = 42;
1163
1164         for(i = 0; i <= imax; ++i)
1165         {
1166                 float mapindex;
1167                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1168                 if(Map_Check(mapindex, 1))
1169                         return mapindex;
1170         }
1171         return -1;
1172 }
1173
1174 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1175 // the exponent sets a bias on the map selection:
1176 // the higher the exponent, the less likely "shortly repeated" same maps are
1177 {
1178         float i, j, imax, insertpos;
1179
1180         imax = 42;
1181
1182         for(i = 0; i <= imax; ++i)
1183         {
1184                 string newlist;
1185
1186                 // now reinsert this at another position
1187                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1188                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1189                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1190                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1191
1192                 // insert the current map there
1193                 newlist = "";
1194                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1195                         newlist = strcat(newlist, " ", argv(j));
1196                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1197                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1198                         newlist = strcat(newlist, " ", argv(j));
1199                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1200                 cvar_set("g_maplist", newlist);
1201                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1202
1203                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1204                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1205                 if(Map_Check(Map_Current, 1))
1206                         return Map_Current;
1207         }
1208         return -1;
1209 }
1210
1211 void Maplist_Init()
1212 {
1213         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1214         if(Map_Count == 0)
1215         {
1216                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1217                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1218                 if(autocvar_g_maplist_shuffle)
1219                         ShuffleMaplist();
1220                 localcmd("\nmenu_cmd sync\n");
1221                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1222         }
1223         if(Map_Count == 0)
1224                 error("empty maplist, cannot select a new map");
1225         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1226
1227         if(Map_Current_Name)
1228                 strunzone(Map_Current_Name);
1229         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1230         // this may or may not be correct, but who cares, in the worst case a map
1231         // isn't chosen in the first pass that should have been
1232 }
1233
1234 string GetNextMap()
1235 {
1236         float nextMap;
1237
1238         Maplist_Init();
1239         nextMap = -1;
1240
1241         if(nextMap == -1)
1242                 if(autocvar_g_maplist_shuffle > 0)
1243                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1244
1245         if(nextMap == -1)
1246                 if(autocvar_g_maplist_selectrandom)
1247                         nextMap = MaplistMethod_Random();
1248
1249         if(nextMap == -1)
1250                 nextMap = MaplistMethod_Iterate();
1251
1252         if(nextMap == -1)
1253                 nextMap = MaplistMethod_Repeat();
1254
1255         if(nextMap >= 0)
1256         {
1257                 Map_Goto_SetFloat(nextMap);
1258                 return getmapname_stored;
1259         }
1260
1261         return "";
1262 }
1263
1264 float DoNextMapOverride(float reinit)
1265 {
1266         if(autocvar_g_campaign)
1267         {
1268                 CampaignPostIntermission();
1269                 alreadychangedlevel = TRUE;
1270                 return TRUE;
1271         }
1272         if(autocvar_quit_when_empty)
1273         {
1274                 if(player_count <= currentbots)
1275                 {
1276                         localcmd("quit\n");
1277                         alreadychangedlevel = TRUE;
1278                         return TRUE;
1279                 }
1280         }
1281         if(autocvar_quit_and_redirect != "")
1282         {
1283                 redirection_target = strzone(autocvar_quit_and_redirect);
1284                 alreadychangedlevel = TRUE;
1285                 return TRUE;
1286         }
1287         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1288         {
1289                 localcmd("restart\n");
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         if(autocvar_nextmap != "")
1294                 if(MapInfo_CheckMap(autocvar_nextmap))
1295                 {
1296                         Map_Goto_SetStr(autocvar_nextmap);
1297                         Map_Goto(reinit);
1298                         alreadychangedlevel = TRUE;
1299                         return TRUE;
1300                 }
1301         if(!reinit && autocvar_lastlevel)
1302         {
1303                 cvar_settemp_restore();
1304                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1305                 alreadychangedlevel = TRUE;
1306                 return TRUE;
1307         }
1308         return FALSE;
1309 }
1310
1311 void GotoNextMap(float reinit)
1312 {
1313         //string nextmap;
1314         //float n, nummaps;
1315         //string s;
1316         if (alreadychangedlevel)
1317                 return;
1318         alreadychangedlevel = TRUE;
1319
1320         {
1321                 string nextMap;
1322                 float allowReset;
1323
1324                 for(allowReset = 1; allowReset >= 0; --allowReset)
1325                 {
1326                         nextMap = GetNextMap();
1327                         if(nextMap != "")
1328                                 break;
1329
1330                         if(allowReset)
1331                         {
1332                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1333                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1334                                 if(autocvar_g_maplist_shuffle)
1335                                         ShuffleMaplist();
1336                                 localcmd("\nmenu_cmd sync\n");
1337                         }
1338                         else
1339                         {
1340                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1341                         }
1342                 }
1343                 Map_Goto(reinit);
1344         }
1345 }
1346
1347
1348 /*
1349 ============
1350 IntermissionThink
1351
1352 When the player presses attack or jump, change to the next level
1353 ============
1354 */
1355 .float autoscreenshot;
1356 void() MapVote_Start;
1357 void() MapVote_Think;
1358 float mapvote_initialized;
1359 void IntermissionThink()
1360 {
1361         FixIntermissionClient(self);
1362
1363         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1364         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1365
1366         if( (server_screenshot || client_screenshot)
1367                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1368         {
1369                 self.autoscreenshot = -1;
1370                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1371                 return;
1372         }
1373
1374         if (time < intermission_exittime)
1375                 return;
1376
1377         if(!mapvote_initialized)
1378                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1379                         return;
1380
1381         MapVote_Start();
1382 }
1383
1384 /*
1385 ============
1386 FindIntermission
1387
1388 Returns the entity to view from
1389 ============
1390 */
1391 /*
1392 entity FindIntermission()
1393 {
1394         local   entity spot;
1395         local   float cyc;
1396
1397 // look for info_intermission first
1398         spot = find (world, classname, "info_intermission");
1399         if (spot)
1400         {       // pick a random one
1401                 cyc = random() * 4;
1402                 while (cyc > 1)
1403                 {
1404                         spot = find (spot, classname, "info_intermission");
1405                         if (!spot)
1406                                 spot = find (spot, classname, "info_intermission");
1407                         cyc = cyc - 1;
1408                 }
1409                 return spot;
1410         }
1411
1412 // then look for the start position
1413         spot = find (world, classname, "info_player_start");
1414         if (spot)
1415                 return spot;
1416
1417 // testinfo_player_start is only found in regioned levels
1418         spot = find (world, classname, "testplayerstart");
1419         if (spot)
1420                 return spot;
1421
1422 // then look for the start position
1423         spot = find (world, classname, "info_player_deathmatch");
1424         if (spot)
1425                 return spot;
1426
1427         //objerror ("FindIntermission: no spot");
1428         return world;
1429 }
1430 */
1431
1432 /*
1433 ===============================================================================
1434
1435 RULES
1436
1437 ===============================================================================
1438 */
1439
1440 void DumpStats(float final)
1441 {
1442         float file;
1443         string s;
1444         float to_console;
1445         float to_eventlog;
1446         float to_file;
1447         float i;
1448
1449         to_console = autocvar_sv_logscores_console;
1450         to_eventlog = autocvar_sv_eventlog;
1451         to_file = autocvar_sv_logscores_file;
1452
1453         if(!final)
1454         {
1455                 to_console = TRUE; // always print printstats replies
1456                 to_eventlog = FALSE; // but never print them to the event log
1457         }
1458
1459         if(to_eventlog)
1460                 if(autocvar_sv_eventlog_console)
1461                         to_console = FALSE; // otherwise we get the output twice
1462
1463         if(final)
1464                 s = ":scores:";
1465         else
1466                 s = ":status:";
1467         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1468
1469         if(to_console)
1470                 print(s, "\n");
1471         if(to_eventlog)
1472                 GameLogEcho(s);
1473
1474         file = -1;
1475         if(to_file)
1476         {
1477                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1478                 if(file == -1)
1479                         to_file = FALSE;
1480                 else
1481                         fputs(file, strcat(s, "\n"));
1482         }
1483
1484         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1485         if(to_console)
1486                 print(s, "\n");
1487         if(to_eventlog)
1488                 GameLogEcho(s);
1489         if(to_file)
1490                 fputs(file, strcat(s, "\n"));
1491
1492         FOR_EACH_CLIENT(other)
1493         {
1494                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1495                 {
1496                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1497                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1498                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1499                                 s = strcat(s, ftos(other.team), ":");
1500                         else
1501                                 s = strcat(s, "spectator:");
1502
1503                         if(to_console)
1504                                 print(s, other.netname, "\n");
1505                         if(to_eventlog)
1506                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1507                         if(to_file)
1508                                 fputs(file, strcat(s, other.netname, "\n"));
1509                 }
1510         }
1511
1512         if(teamplay)
1513         {
1514                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1515                 if(to_console)
1516                         print(s, "\n");
1517                 if(to_eventlog)
1518                         GameLogEcho(s);
1519                 if(to_file)
1520                         fputs(file, strcat(s, "\n"));
1521
1522                 for(i = 1; i < 16; ++i)
1523                 {
1524                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1525                         s = strcat(s, ":", ftos(i));
1526                         if(to_console)
1527                                 print(s, "\n");
1528                         if(to_eventlog)
1529                                 GameLogEcho(s);
1530                         if(to_file)
1531                                 fputs(file, strcat(s, "\n"));
1532                 }
1533         }
1534
1535         if(to_console)
1536                 print(":end\n");
1537         if(to_eventlog)
1538                 GameLogEcho(":end");
1539         if(to_file)
1540         {
1541                 fputs(file, ":end\n");
1542                 fclose(file);
1543         }
1544 }
1545
1546 void FixIntermissionClient(entity e)
1547 {
1548         string s;
1549         if(!e.autoscreenshot) // initial call
1550         {
1551                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1552                 e.health = -2342;
1553                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1554                 e.solid = SOLID_NOT;
1555                 e.movetype = MOVETYPE_NONE;
1556                 e.takedamage = DAMAGE_NO;
1557                 if(e.weaponentity)
1558                 {
1559                         e.weaponentity.effects = EF_NODRAW;
1560                         if (e.weaponentity.weaponentity)
1561                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1562                 }
1563                 if(clienttype(e) == CLIENTTYPE_REAL)
1564                 {
1565                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1566                         s = autocvar_sv_intermission_cdtrack;
1567                         if(s != "")
1568                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1569                         msg_entity = e;
1570                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1571                 }
1572         }
1573 }
1574
1575 void minstagib_stop_countdown(entity e);
1576 /*
1577 go to the next level for deathmatch
1578 only called if a time or frag limit has expired
1579 */
1580 void NextLevel()
1581 {
1582         gameover = TRUE;
1583
1584         intermission_running = 1;
1585
1586 // enforce a wait time before allowing changelevel
1587         if(player_count > 0)
1588                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1589         else
1590                 intermission_exittime = -1;
1591
1592         /*
1593         WriteByte (MSG_ALL, SVC_CDTRACK);
1594         WriteByte (MSG_ALL, 3);
1595         WriteByte (MSG_ALL, 3);
1596         // done in FixIntermission
1597         */
1598
1599         //pos = FindIntermission ();
1600
1601         VoteReset();
1602
1603         DumpStats(TRUE);
1604
1605         // send statistics
1606         entity e;
1607         PlayerStats_EndMatch(1);
1608         FOR_EACH_CLIENT(e)
1609                 PlayerStats_AddGlobalInfo(e);
1610         PlayerStats_Shutdown();
1611         WeaponStats_Shutdown();
1612
1613         if(autocvar_sv_eventlog)
1614                 GameLogEcho(":gameover");
1615
1616         GameLogClose();
1617
1618         FOR_EACH_PLAYER(other) {
1619                 minstagib_stop_countdown(other);
1620                 FixIntermissionClient(other);
1621                 if(other.winning)
1622                         bprint(other.netname, " ^7wins.\n");
1623         }
1624
1625         if(autocvar_g_campaign)
1626                 CampaignPreIntermission();
1627
1628         MUTATOR_CALLHOOK(MatchEnd);
1629
1630         localcmd("\nsv_hook_gameend\n");
1631 }
1632
1633 /*
1634 ============
1635 CheckRules_Player
1636
1637 Exit deathmatch games upon conditions
1638 ============
1639 */
1640 void CheckRules_Player()
1641 {
1642         if (gameover)   // someone else quit the game already
1643                 return;
1644
1645         if(self.deadflag == DEAD_NO)
1646                 self.play_time += frametime;
1647
1648         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1649         //   (div0: and that in CheckRules_World please)
1650 }
1651
1652 float checkrules_equality;
1653 float checkrules_suddendeathwarning;
1654 float checkrules_suddendeathend;
1655 float checkrules_overtimesadded; //how many overtimes have been already added
1656
1657 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1658 float WINNING_YES = 1; // winner found
1659 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1660 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1661
1662 float InitiateSuddenDeath()
1663 {
1664         // Check first whether normal overtimes could be added before initiating suddendeath mode
1665         // - for this timelimit_overtime needs to be >0 of course
1666         // - also check the winning condition calculated in the previous frame and only add normal overtime
1667         //   again, if at the point at which timelimit would be extended again, still no winner was found
1668         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1669         {
1670                 return 1; // need to call InitiateOvertime later
1671         }
1672         else
1673         {
1674                 if(!checkrules_suddendeathend)
1675                 {
1676                         if(autocvar_g_campaign)
1677                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1678                         else
1679                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1680                         if(g_race && !g_race_qualifying)
1681                                 race_StartCompleting();
1682                 }
1683                 return 0;
1684         }
1685 }
1686
1687 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1688 {
1689         ++checkrules_overtimesadded;
1690         //add one more overtime by simply extending the timelimit
1691         float tl;
1692         tl = autocvar_timelimit;
1693         tl += autocvar_timelimit_overtime;
1694         cvar_set("timelimit", ftos(tl));
1695         string minutesPlural;
1696         if (autocvar_timelimit_overtime == 1)
1697                 minutesPlural = " ^3minute";
1698         else
1699                 minutesPlural = " ^3minutes";
1700
1701         bcenterprint(
1702                 strcat(
1703                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1704                         ftos(autocvar_timelimit_overtime),
1705                         minutesPlural,
1706                         " to the game!"
1707                 )
1708         );
1709 }
1710
1711 float GetWinningCode(float fraglimitreached, float equality)
1712 {
1713         if(autocvar_g_campaign == 1)
1714                 if(fraglimitreached)
1715                         return WINNING_YES;
1716                 else
1717                         return WINNING_NO;
1718
1719         else
1720                 if(equality)
1721                         if(fraglimitreached)
1722                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1723                         else
1724                                 return WINNING_NEVER;
1725                 else
1726                         if(fraglimitreached)
1727                                 return WINNING_YES;
1728                         else
1729                                 return WINNING_NO;
1730 }
1731
1732 // set the .winning flag for exactly those players with a given field value
1733 void SetWinners(.float field, float value)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 head.winning = (head.field == value);
1738 }
1739
1740 // set the .winning flag for those players with a given field value
1741 void AddWinners(.float field, float value)
1742 {
1743         entity head;
1744         FOR_EACH_PLAYER(head)
1745                 if(head.field == value)
1746                         head.winning = 1;
1747 }
1748
1749 // clear the .winning flags
1750 void ClearWinners(void)
1751 {
1752         entity head;
1753         FOR_EACH_PLAYER(head)
1754                 head.winning = 0;
1755 }
1756
1757 // Onslaught winning condition:
1758 // game terminates if only one team has a working generator (or none)
1759 float WinningCondition_Onslaught()
1760 {
1761         entity head;
1762         float t1, t2, t3, t4;
1763
1764         WinningConditionHelper(); // set worldstatus
1765
1766         if(inWarmupStage)
1767                 return WINNING_NO;
1768
1769         // first check if the game has ended
1770         t1 = t2 = t3 = t4 = 0;
1771         head = find(world, classname, "onslaught_generator");
1772         while (head)
1773         {
1774                 if (head.health > 0)
1775                 {
1776                         if (head.team == COLOR_TEAM1) t1 = 1;
1777                         if (head.team == COLOR_TEAM2) t2 = 1;
1778                         if (head.team == COLOR_TEAM3) t3 = 1;
1779                         if (head.team == COLOR_TEAM4) t4 = 1;
1780                 }
1781                 head = find(head, classname, "onslaught_generator");
1782         }
1783         if (t1 + t2 + t3 + t4 < 2)
1784         {
1785                 // game over, only one team remains (or none)
1786                 ClearWinners();
1787                 if (t1) SetWinners(team, COLOR_TEAM1);
1788                 if (t2) SetWinners(team, COLOR_TEAM2);
1789                 if (t3) SetWinners(team, COLOR_TEAM3);
1790                 if (t4) SetWinners(team, COLOR_TEAM4);
1791                 dprint("Have a winner, ending game.\n");
1792                 return WINNING_YES;
1793         }
1794
1795         // Two or more teams remain
1796         return WINNING_NO;
1797 }
1798
1799 float LMS_NewPlayerLives()
1800 {
1801         float fl;
1802         fl = autocvar_fraglimit;
1803         if(fl == 0)
1804                 fl = 999;
1805
1806         // first player has left the game for dying too much? Nobody else can get in.
1807         if(lms_lowest_lives < 1)
1808                 return 0;
1809
1810         if(!autocvar_g_lms_join_anytime)
1811                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1812                         return 0;
1813
1814         return bound(1, lms_lowest_lives, fl);
1815 }
1816
1817 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1818 // they win. Otherwise the defending team wins once the timelimit passes.
1819 void assault_new_round();
1820 float WinningCondition_Assault()
1821 {
1822         float status;
1823
1824         WinningConditionHelper(); // set worldstatus
1825
1826         status = WINNING_NO;
1827         // as the timelimit has not yet passed just assume the defending team will win
1828         if(assault_attacker_team == COLOR_TEAM1)
1829         {
1830                 SetWinners(team, COLOR_TEAM2);
1831         }
1832         else
1833         {
1834                 SetWinners(team, COLOR_TEAM1);
1835         }
1836
1837         entity ent;
1838         ent = find(world, classname, "target_assault_roundend");
1839         if(ent)
1840         {
1841                 if(ent.winning) // round end has been triggered by attacking team
1842                 {
1843                         bprint("ASSAULT: round completed...\n");
1844                         SetWinners(team, assault_attacker_team);
1845
1846                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1847
1848                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1849                         {
1850                                 status = WINNING_YES;
1851                         }
1852                         else
1853                         {
1854                                 entity oldself;
1855                                 oldself = self;
1856                                 self = ent;
1857                                 assault_new_round();
1858                                 self = oldself;
1859                         }
1860                 }
1861         }
1862
1863         return status;
1864 }
1865
1866 // LMS winning condition: game terminates if and only if there's at most one
1867 // one player who's living lives. Top two scores being equal cancels the time
1868 // limit.
1869 float WinningCondition_LMS()
1870 {
1871         entity head, head2;
1872         float have_player;
1873         float have_players;
1874         float l;
1875
1876         have_player = FALSE;
1877         have_players = FALSE;
1878         l = LMS_NewPlayerLives();
1879
1880         head = find(world, classname, "player");
1881         if(head)
1882                 have_player = TRUE;
1883         head2 = find(head, classname, "player");
1884         if(head2)
1885                 have_players = TRUE;
1886
1887         if(have_player)
1888         {
1889                 // we have at least one player
1890                 if(have_players)
1891                 {
1892                         // two or more active players - continue with the game
1893                 }
1894                 else
1895                 {
1896                         // exactly one player?
1897
1898                         ClearWinners();
1899                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1900
1901                         if(l)
1902                         {
1903                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1904                                 return WINNING_NO;
1905                         }
1906                         else
1907                         {
1908                                 // a winner!
1909                                 // and assign him his first place
1910                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1911                                 return WINNING_YES;
1912                         }
1913                 }
1914         }
1915         else
1916         {
1917                 // nobody is playing at all...
1918                 if(l)
1919                 {
1920                         // wait for players...
1921                 }
1922                 else
1923                 {
1924                         // SNAFU (maybe a draw game?)
1925                         ClearWinners();
1926                         dprint("No players, ending game.\n");
1927                         return WINNING_YES;
1928                 }
1929         }
1930
1931         // When we get here, we have at least two players who are actually LIVING,
1932         // now check if the top two players have equal score.
1933         WinningConditionHelper();
1934
1935         ClearWinners();
1936         if(WinningConditionHelper_winner)
1937                 WinningConditionHelper_winner.winning = TRUE;
1938         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1939                 return WINNING_NEVER;
1940
1941         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1942         return WINNING_NO;
1943 }
1944
1945 void ShuffleMaplist()
1946 {
1947         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1948 }
1949
1950 float leaderfrags;
1951 float WinningCondition_Scores(float limit, float leadlimit)
1952 {
1953         float limitreached;
1954
1955         // TODO make everything use THIS winning condition (except LMS)
1956         WinningConditionHelper();
1957
1958         if(teamplay)
1959         {
1960                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1961                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1962                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1963                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1964         }
1965
1966         ClearWinners();
1967         if(WinningConditionHelper_winner)
1968                 WinningConditionHelper_winner.winning = 1;
1969         if(WinningConditionHelper_winnerteam >= 0)
1970                 SetWinners(team, WinningConditionHelper_winnerteam);
1971
1972         if(WinningConditionHelper_lowerisbetter)
1973         {
1974                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1975                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1976                 limit = -limit;
1977         }
1978
1979         if(WinningConditionHelper_zeroisworst)
1980                 leadlimit = 0; // not supported in this mode
1981
1982         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1983         // these modes always score in increments of 1, thus this makes sense
1984         {
1985                 if(leaderfrags != WinningConditionHelper_topscore)
1986                 {
1987                         leaderfrags = WinningConditionHelper_topscore;
1988
1989                         if (limit)
1990                         if (leaderfrags == limit - 1)
1991                                 Announce("1fragleft");
1992                         else if (leaderfrags == limit - 2)
1993                                 Announce("2fragsleft");
1994                         else if (leaderfrags == limit - 3)
1995                                 Announce("3fragsleft");
1996                 }
1997         }
1998
1999         limitreached = FALSE;
2000         if(limit)
2001                 if(WinningConditionHelper_topscore >= limit)
2002                         limitreached = TRUE;
2003         if(leadlimit)
2004         {
2005                 float leadlimitreached;
2006                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2007                 if(autocvar_leadlimit_and_fraglimit)
2008                         limitreached = (limitreached && leadlimitreached);
2009                 else
2010                         limitreached = (limitreached || leadlimitreached);
2011         }
2012
2013         if(limit)
2014                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2015
2016         return GetWinningCode(
2017                 WinningConditionHelper_topscore && limitreached,
2018                 WinningConditionHelper_equality
2019         );
2020 }
2021
2022 float WinningCondition_Race(float fraglimit)
2023 {
2024         float wc;
2025         entity p;
2026         float n, c;
2027
2028         n = 0;
2029         c = 0;
2030         FOR_EACH_PLAYER(p)
2031         {
2032                 ++n;
2033                 if(p.race_completed)
2034                         ++c;
2035         }
2036         if(n && (n == c))
2037                 return WINNING_YES;
2038         wc = WinningCondition_Scores(fraglimit, 0);
2039
2040         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2041         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2042         // do NOT support equality when the laps are all raced!
2043                 return WINNING_STARTSUDDENDEATHOVERTIME;
2044         else
2045                 return WINNING_NEVER;
2046 }
2047
2048 float WinningCondition_QualifyingThenRace(float limit)
2049 {
2050         float wc;
2051         wc = WinningCondition_Scores(limit, 0);
2052
2053         // NEVER initiate overtime
2054         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2055         {
2056                 return WINNING_YES;
2057         }
2058
2059         return wc;
2060 }
2061
2062 float WinningCondition_RanOutOfSpawns()
2063 {
2064         entity head;
2065
2066         if(have_team_spawns <= 0)
2067                 return WINNING_NO;
2068
2069         if(autocvar_g_spawn_useallspawns <= 0)
2070                 return WINNING_NO;
2071
2072         if(!some_spawn_has_been_used)
2073                 return WINNING_NO;
2074
2075         team1_score = team2_score = team3_score = team4_score = 0;
2076
2077         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2078         {
2079                 if(head.team == COLOR_TEAM1)
2080                         team1_score = 1;
2081                 else if(head.team == COLOR_TEAM2)
2082                         team2_score = 1;
2083                 else if(head.team == COLOR_TEAM3)
2084                         team3_score = 1;
2085                 else if(head.team == COLOR_TEAM4)
2086                         team4_score = 1;
2087         }
2088
2089         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2090         {
2091                 if(head.team == COLOR_TEAM1)
2092                         team1_score = 1;
2093                 else if(head.team == COLOR_TEAM2)
2094                         team2_score = 1;
2095                 else if(head.team == COLOR_TEAM3)
2096                         team3_score = 1;
2097                 else if(head.team == COLOR_TEAM4)
2098                         team4_score = 1;
2099         }
2100
2101         ClearWinners();
2102         if(team1_score + team2_score + team3_score + team4_score == 0)
2103         {
2104                 checkrules_equality = TRUE;
2105                 return WINNING_YES;
2106         }
2107         else if(team1_score + team2_score + team3_score + team4_score == 1)
2108         {
2109                 float t, i;
2110                 if(team1_score)
2111                         t = COLOR_TEAM1;
2112                 else if(team2_score)
2113                         t = COLOR_TEAM2;
2114                 else if(team3_score)
2115                         t = COLOR_TEAM3;
2116                 else // if(team4_score)
2117                         t = COLOR_TEAM4;
2118                 CheckAllowedTeams(world);
2119                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2120                 {
2121                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2122                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2123                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2124                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2125                 }
2126
2127                 AddWinners(team, t);
2128                 return WINNING_YES;
2129         }
2130         else
2131                 return WINNING_NO;
2132 }
2133
2134 // TD winning condition:
2135 // game terminates if there are no generators (or 1 dies if td_dontend is TRUE)
2136 float gensurvived;
2137 float WinningCondition_TowerDefense()
2138 {
2139         WinningConditionHelper(); // set worldstatus
2140
2141         if(inWarmupStage)
2142                 return WINNING_NO;
2143
2144         // first check if the game has ended
2145         if(gendestroyed == TRUE) // FALSE means either generator hasen't spawned yet, or mapper didn't add one
2146         if(td_gencount < 1 || !td_dont_end)
2147         {
2148                 ClearWinners();
2149                 dprint("Everyone lost, ending game.\n");
2150                 return WINNING_YES;
2151         }
2152
2153         if(gensurvived)
2154         {
2155                 ClearWinners();
2156                 SetWinners(winning, 4);
2157                 return WINNING_YES;
2158         }
2159
2160         // Two or more teams remain
2161         return WINNING_NO;
2162 }
2163
2164 /*
2165 ============
2166 CheckRules_World
2167
2168 Exit deathmatch games upon conditions
2169 ============
2170 */
2171 void ReadyRestart();
2172 void CheckRules_World()
2173 {
2174         float timelimit;
2175         float fraglimit;
2176         float leadlimit;
2177
2178         VoteThink();
2179         MapVote_Think();
2180
2181         SetDefaultAlpha();
2182
2183         /*
2184         MapVote_Think should now do that part
2185         if (intermission_running)
2186                 if (time >= intermission_exittime + 60)
2187                 {
2188                         if(!DoNextMapOverride())
2189                                 GotoNextMap();
2190                         return;
2191                 }
2192         */
2193
2194         if (gameover)   // someone else quit the game already
2195         {
2196                 if(player_count == 0) // Nobody there? Then let's go to the next map
2197                         MapVote_Start();
2198                         // this will actually check the player count in the next frame
2199                         // again, but this shouldn't hurt
2200                 return;
2201         }
2202
2203         timelimit = autocvar_timelimit * 60;
2204         fraglimit = autocvar_fraglimit;
2205         leadlimit = autocvar_leadlimit;
2206
2207         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2208         {
2209                 if(timelimit > 0)
2210                         timelimit = 0; // timelimit is not made for warmup
2211                 if(fraglimit > 0)
2212                         fraglimit = 0; // no fraglimit for now
2213                 leadlimit = 0; // no leadlimit for now
2214         }
2215
2216         if(timelimit > 0)
2217         {
2218                 timelimit += game_starttime;
2219         }
2220         else if (timelimit < 0)
2221         {
2222                 // endmatch
2223                 NextLevel();
2224                 return;
2225         }
2226
2227         if(g_onslaught)
2228                 timelimit = 0; // ONS has its own overtime rule
2229
2230         float wantovertime;
2231         wantovertime = 0;
2232
2233         if(timelimit > game_starttime)
2234                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2235         else
2236                 game_completion_ratio = 0;
2237
2238         if(checkrules_suddendeathend)
2239         {
2240                 if(!checkrules_suddendeathwarning)
2241                 {
2242                         checkrules_suddendeathwarning = TRUE;
2243                         if(g_race && !g_race_qualifying)
2244                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2245                         else
2246                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2247                 }
2248         }
2249         else
2250         {
2251                 if (timelimit && time >= timelimit)
2252                 {
2253                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2254                         {
2255                                 float totalplayers;
2256                                 float playerswithlaps;
2257                                 float readyplayers;
2258                                 entity head;
2259                                 totalplayers = playerswithlaps = readyplayers = 0;
2260                                 FOR_EACH_PLAYER(head)
2261                                 {
2262                                         ++totalplayers;
2263                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2264                                                 ++playerswithlaps;
2265                                         if(head.ready)
2266                                                 ++readyplayers;
2267                                 }
2268
2269                                 // at least 2 of the players have completed a lap: start the RACE
2270                                 // otherwise, the players should end the qualifying on their own
2271                                 if(readyplayers || playerswithlaps >= 2)
2272                                 {
2273                                         checkrules_suddendeathend = 0;
2274                                         ReadyRestart(); // go to race
2275                                         return;
2276                                 }
2277                                 else
2278                                         wantovertime |= InitiateSuddenDeath();
2279                         }
2280                         else
2281                                 wantovertime |= InitiateSuddenDeath();
2282                 }
2283         }
2284
2285         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2286         {
2287                 NextLevel();
2288                 return;
2289         }
2290
2291         float checkrules_status;
2292         checkrules_status = WinningCondition_RanOutOfSpawns();
2293         if(checkrules_status == WINNING_YES)
2294         {
2295                 bprint("Hey! Someone ran out of spawns!\n");
2296         }
2297         else if(g_race && !g_race_qualifying && timelimit >= 0)
2298         {
2299                 checkrules_status = WinningCondition_Race(fraglimit);
2300                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2301         }
2302         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2303         {
2304                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2305                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2306         }
2307         else if(g_assault)
2308         {
2309                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2310         }
2311         else if(g_lms)
2312         {
2313                 checkrules_status = WinningCondition_LMS();
2314         }
2315         else if (g_onslaught)
2316         {
2317                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2318         }
2319         else if(g_td)
2320         {
2321                 checkrules_status = WinningCondition_TowerDefense(); // TODO make these mutator hooks?
2322         }
2323         else
2324         {
2325                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2326                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2327         }
2328
2329         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2330         {
2331                 checkrules_status = WINNING_NEVER;
2332                 checkrules_overtimesadded = -1;
2333                 wantovertime |= InitiateSuddenDeath();
2334         }
2335
2336         if(checkrules_status == WINNING_NEVER)
2337                 // equality cases! Nobody wins if the overtime ends in a draw.
2338                 ClearWinners();
2339
2340         if(wantovertime)
2341         {
2342                 if(checkrules_status == WINNING_NEVER)
2343                         InitiateOvertime();
2344                 else
2345                         checkrules_status = WINNING_YES;
2346         }
2347
2348         if(checkrules_suddendeathend)
2349                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2350                         checkrules_status = WINNING_YES;
2351
2352         if(checkrules_status == WINNING_YES)
2353         {
2354                 //print("WINNING\n");
2355                 NextLevel();
2356         }
2357 }
2358
2359 float mapvote_nextthink;
2360 float mapvote_initialized;
2361 float mapvote_keeptwotime;
2362 float mapvote_timeout;
2363 string mapvote_message;
2364 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2365 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2366 float mapvote_screenshot_dirs_count;
2367
2368 float mapvote_count;
2369 float mapvote_count_real;
2370 string mapvote_maps[MAPVOTE_COUNT];
2371 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2372 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2373 float mapvote_maps_suggested[MAPVOTE_COUNT];
2374 string mapvote_suggestions[MAPVOTE_COUNT];
2375 float mapvote_suggestion_ptr;
2376 float mapvote_voters;
2377 float mapvote_selections[MAPVOTE_COUNT];
2378 float mapvote_run;
2379 float mapvote_detail;
2380 float mapvote_abstain;
2381 .float mapvote;
2382
2383 void MapVote_ClearAllVotes()
2384 {
2385         FOR_EACH_CLIENT(other)
2386                 other.mapvote = 0;
2387 }
2388
2389 string MapVote_Suggest(string m)
2390 {
2391         float i;
2392         if(m == "")
2393                 return "That's not how to use this command.";
2394         if(!autocvar_g_maplist_votable_suggestions)
2395                 return "Suggestions are not accepted on this server.";
2396         if(mapvote_initialized)
2397                 return "Can't suggest - voting is already in progress!";
2398         m = MapInfo_FixName(m);
2399         if not(m)
2400                 return "The map you suggested is not available on this server.";
2401         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2402                 if(Map_IsRecent(m))
2403                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2404
2405         if(!MapInfo_CheckMap(m))
2406                 return "The map you suggested does not support the current game mode.";
2407         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2408                 if(mapvote_suggestions[i] == m)
2409                         return "This map was already suggested.";
2410         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2411         {
2412                 i = floor(random() * mapvote_suggestion_ptr);
2413         }
2414         else
2415         {
2416                 i = mapvote_suggestion_ptr;
2417                 mapvote_suggestion_ptr += 1;
2418         }
2419         if(mapvote_suggestions[i] != "")
2420                 strunzone(mapvote_suggestions[i]);
2421         mapvote_suggestions[i] = strzone(m);
2422         if(autocvar_sv_eventlog)
2423                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2424         return strcat("Suggestion of ", m, " accepted.");
2425 }
2426
2427 void MapVote_AddVotable(string nextMap, float isSuggestion)
2428 {
2429         float j, i, o;
2430         string pakfile, mapfile;
2431
2432         if(nextMap == "")
2433                 return;
2434         for(j = 0; j < mapvote_count; ++j)
2435                 if(mapvote_maps[j] == nextMap)
2436                         return;
2437         // suggestions might be no longer valid/allowed after gametype switch!
2438         if(isSuggestion)
2439                 if(!MapInfo_CheckMap(nextMap))
2440                         return;
2441         mapvote_maps[mapvote_count] = strzone(nextMap);
2442         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2443
2444         pakfile = string_null;
2445         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2446         {
2447                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2448                 pakfile = whichpack(strcat(mapfile, ".tga"));
2449                 if(pakfile == "")
2450                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2451                 if(pakfile == "")
2452                         pakfile = whichpack(strcat(mapfile, ".png"));
2453                 if(pakfile != "")
2454                         break;
2455         }
2456         if(i >= mapvote_screenshot_dirs_count)
2457                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2458         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2459                 pakfile = substring(pakfile, o, -1);
2460
2461         mapvote_maps_screenshot_dir[mapvote_count] = i;
2462         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2463
2464         mapvote_count += 1;
2465 }
2466
2467 void MapVote_Spawn();
2468 void MapVote_Init()
2469 {
2470         float i;
2471         float nmax, smax;
2472
2473         MapVote_ClearAllVotes();
2474
2475         mapvote_count = 0;
2476         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2477         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2478
2479         if(mapvote_abstain)
2480                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2481         else
2482                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2483         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2484
2485         // we need this for AddVotable, as that cycles through the screenshot dirs
2486         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2487         if(mapvote_screenshot_dirs_count == 0)
2488                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2489         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2490         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2491                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2492
2493         if(mapvote_suggestion_ptr)
2494                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2495                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2496
2497         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2498                 MapVote_AddVotable(GetNextMap(), FALSE);
2499
2500         if(mapvote_count == 0)
2501         {
2502                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2503                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2504                 if(autocvar_g_maplist_shuffle)
2505                         ShuffleMaplist();
2506                 localcmd("\nmenu_cmd sync\n");
2507                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2508                         MapVote_AddVotable(GetNextMap(), FALSE);
2509         }
2510
2511         mapvote_count_real = mapvote_count;
2512         if(mapvote_abstain)
2513                 MapVote_AddVotable("don't care", 0);
2514
2515         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2516
2517         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2518         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2519         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2520                 mapvote_keeptwotime = 0;
2521         mapvote_message = "Choose a map and press its key!";
2522
2523         MapVote_Spawn();
2524 }
2525
2526 void MapVote_SendPicture(float id)
2527 {
2528         msg_entity = self;
2529         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2530         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2531         WriteByte(MSG_ONE, id);
2532         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2533 }
2534
2535 float MapVote_GetMapMask()
2536 {
2537         float mask, i, power;
2538         mask = 0;
2539         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2540                 if(mapvote_maps[i] != "")
2541                         mask |= power;
2542         return mask;
2543 }
2544
2545 entity mapvote_ent;
2546 float MapVote_SendEntity(entity to, float sf)
2547 {
2548         float i;
2549
2550         if(sf & 1)
2551                 sf &~= 2; // if we send 1, we don't need to also send 2
2552
2553         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2554         WriteByte(MSG_ENTITY, sf);
2555
2556         if(sf & 1)
2557         {
2558                 // flag 1 == initialization
2559                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2560                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2561                 WriteString(MSG_ENTITY, "");
2562                 WriteByte(MSG_ENTITY, mapvote_count);
2563                 WriteByte(MSG_ENTITY, mapvote_abstain);
2564                 WriteByte(MSG_ENTITY, mapvote_detail);
2565                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2566                 if(mapvote_count <= 8)
2567                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2568                 else
2569                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2570                 for(i = 0; i < mapvote_count; ++i)
2571                         if(mapvote_maps[i] != "")
2572                         {
2573                                 if(mapvote_abstain && i == mapvote_count - 1)
2574                                 {
2575                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2576                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2577                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2578                                 }
2579                                 else
2580                                 {
2581                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2582                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2583                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2584                                 }
2585                         }
2586         }
2587
2588         if(sf & 2)
2589         {
2590                 // flag 2 == update of mask
2591                 if(mapvote_count <= 8)
2592                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2593                 else
2594                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2595         }
2596
2597         if(sf & 4)
2598         {
2599                 if(mapvote_detail)
2600                         for(i = 0; i < mapvote_count; ++i)
2601                                 if(mapvote_maps[i] != "")
2602                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2603
2604                 WriteByte(MSG_ENTITY, to.mapvote);
2605         }
2606
2607         return TRUE;
2608 }
2609
2610 void MapVote_Spawn()
2611 {
2612         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2613 }
2614
2615 void MapVote_TouchMask()
2616 {
2617         mapvote_ent.SendFlags |= 2;
2618 }
2619
2620 void MapVote_TouchVotes(entity voter)
2621 {
2622         mapvote_ent.SendFlags |= 4;
2623 }
2624
2625 float MapVote_Finished(float mappos)
2626 {
2627         string result;
2628         float i;
2629         float didntvote;
2630
2631         if(autocvar_sv_eventlog)
2632         {
2633                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2634                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2635                 didntvote = mapvote_voters;
2636                 for(i = 0; i < mapvote_count; ++i)
2637                         if(mapvote_maps[i] != "")
2638                         {
2639                                 didntvote -= mapvote_selections[i];
2640                                 if(i != mappos)
2641                                 {
2642                                         result = strcat(result, ":", mapvote_maps[i]);
2643                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2644                                 }
2645                         }
2646                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2647
2648                 GameLogEcho(result);
2649                 if(mapvote_maps_suggested[mappos])
2650                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2651         }
2652
2653         FOR_EACH_REALCLIENT(other)
2654                 FixClientCvars(other);
2655
2656         Map_Goto_SetStr(mapvote_maps[mappos]);
2657         Map_Goto(0);
2658         alreadychangedlevel = TRUE;
2659         return TRUE;
2660 }
2661 void MapVote_CheckRules_1()
2662 {
2663         float i;
2664
2665         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2666         {
2667                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2668                 mapvote_selections[i] = 0;
2669         }
2670
2671         mapvote_voters = 0;
2672         FOR_EACH_REALCLIENT(other)
2673         {
2674                 ++mapvote_voters;
2675                 if(other.mapvote)
2676                 {
2677                         i = other.mapvote - 1;
2678                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2679                         mapvote_selections[i] = mapvote_selections[i] + 1;
2680                 }
2681         }
2682 }
2683
2684 float MapVote_CheckRules_2()
2685 {
2686         float i;
2687         float firstPlace, secondPlace;
2688         float firstPlaceVotes, secondPlaceVotes;
2689         float mapvote_voters_real;
2690         string result;
2691
2692         if(mapvote_count_real == 1)
2693                 return MapVote_Finished(0);
2694
2695         mapvote_voters_real = mapvote_voters;
2696         if(mapvote_abstain)
2697                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2698
2699         RandomSelection_Init();
2700         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2701                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2702         firstPlace = RandomSelection_chosen_float;
2703         firstPlaceVotes = RandomSelection_best_priority;
2704         //dprint("First place: ", ftos(firstPlace), "\n");
2705         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2706
2707         RandomSelection_Init();
2708         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2709                 if(i != firstPlace)
2710                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2711         secondPlace = RandomSelection_chosen_float;
2712         secondPlaceVotes = RandomSelection_best_priority;
2713         //dprint("Second place: ", ftos(secondPlace), "\n");
2714         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2715
2716         if(firstPlace == -1)
2717                 error("No first place in map vote... WTF?");
2718
2719         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2720                 return MapVote_Finished(firstPlace);
2721
2722         if(mapvote_keeptwotime)
2723                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2724                 {
2725                         float didntvote;
2726                         MapVote_TouchMask();
2727                         mapvote_message = "Now decide between the TOP TWO!";
2728                         mapvote_keeptwotime = 0;
2729                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2730                         result = strcat(result, ":", ftos(firstPlaceVotes));
2731                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2732                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2733                         didntvote = mapvote_voters;
2734                         for(i = 0; i < mapvote_count; ++i)
2735                                 if(mapvote_maps[i] != "")
2736                                 {
2737                                         didntvote -= mapvote_selections[i];
2738                                         if(i != firstPlace)
2739                                                 if(i != secondPlace)
2740                                                 {
2741                                                         result = strcat(result, ":", mapvote_maps[i]);
2742                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2743                                                         if(i < mapvote_count_real)
2744                                                         {
2745                                                                 strunzone(mapvote_maps[i]);
2746                                                                 mapvote_maps[i] = "";
2747                                                                 strunzone(mapvote_maps_pakfile[i]);
2748                                                                 mapvote_maps_pakfile[i] = "";
2749                                                         }
2750                                                 }
2751                                 }
2752                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2753                         if(autocvar_sv_eventlog)
2754                                 GameLogEcho(result);
2755                 }
2756
2757         return FALSE;
2758 }
2759 void MapVote_Tick()
2760 {
2761         float keeptwo;
2762         float totalvotes;
2763
2764         keeptwo = mapvote_keeptwotime;
2765         MapVote_CheckRules_1(); // count
2766         if(MapVote_CheckRules_2()) // decide
2767                 return;
2768
2769         totalvotes = 0;
2770         FOR_EACH_REALCLIENT(other)
2771         {
2772                 // hide scoreboard again
2773                 if(other.health != 2342)
2774                 {
2775                         other.health = 2342;
2776                         other.impulse = 0;
2777                         if(clienttype(other) == CLIENTTYPE_REAL)
2778                         {
2779                                 msg_entity = other;
2780                                 WriteByte(MSG_ONE, SVC_FINALE);
2781                                 WriteString(MSG_ONE, "");
2782                         }
2783                 }
2784
2785                 // clear possibly invalid votes
2786                 if(mapvote_maps[other.mapvote - 1] == "")
2787                         other.mapvote = 0;
2788                 // use impulses as new vote
2789                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2790                         if(mapvote_maps[other.impulse - 1] != "")
2791                         {
2792                                 other.mapvote = other.impulse;
2793                                 MapVote_TouchVotes(other);
2794                         }
2795                 other.impulse = 0;
2796
2797                 if(other.mapvote)
2798                         ++totalvotes;
2799         }
2800
2801         MapVote_CheckRules_1(); // just count
2802 }
2803 void MapVote_Start()
2804 {
2805         if(mapvote_run)
2806                 return;
2807
2808         // wait for stats to be sent first
2809         if(!playerstats_waitforme)
2810                 return;
2811
2812         MapInfo_Enumerate();
2813         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2814                 mapvote_run = TRUE;
2815 }
2816 void MapVote_Think()
2817 {
2818         if(!mapvote_run)
2819                 return;
2820
2821         if(alreadychangedlevel)
2822                 return;
2823
2824         if(time < mapvote_nextthink)
2825                 return;
2826         //dprint("tick\n");
2827
2828         mapvote_nextthink = time + 0.5;
2829
2830         if(!mapvote_initialized)
2831         {
2832                 if(autocvar_rescan_pending == 1)
2833                 {
2834                         cvar_set("rescan_pending", "2");
2835                         localcmd("fs_rescan\nrescan_pending 3\n");
2836                         return;
2837                 }
2838                 else if(autocvar_rescan_pending == 2)
2839                 {
2840                         return;
2841                 }
2842                 else if(autocvar_rescan_pending == 3)
2843                 {
2844                         // now build missing mapinfo files
2845                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2846                                 return;
2847
2848                         // we're done, start the timer
2849                         cvar_set("rescan_pending", "0");
2850                 }
2851
2852                 mapvote_initialized = TRUE;
2853                 if(DoNextMapOverride(0))
2854                         return;
2855                 if(!autocvar_g_maplist_votable || player_count <= 0)
2856                 {
2857                         GotoNextMap(0);
2858                         return;
2859                 }
2860                 MapVote_Init();
2861         }
2862
2863         MapVote_Tick();
2864 }
2865
2866 string GotoMap(string m)
2867 {
2868         if(!MapInfo_CheckMap(m))
2869                 return "The map you chose is not available on this server.";
2870         cvar_set("nextmap", m);
2871         cvar_set("timelimit", "-1");
2872         if(mapvote_initialized || alreadychangedlevel)
2873         {
2874                 if(DoNextMapOverride(0))
2875                         return "Map switch initiated.";
2876                 else
2877                         return "Hm... no. For some reason I like THIS map more.";
2878         }
2879         else
2880                 return "Map switch will happen after scoreboard.";
2881 }
2882
2883
2884 void EndFrame()
2885 {
2886         float altime;
2887         FOR_EACH_REALCLIENT(self)
2888         {
2889                 if(self.classname == "spectator")
2890                 {
2891                         if(self.enemy.typehitsound)
2892                                 self.typehit_time = time;
2893                         else if(self.enemy.hitsound)
2894                                 self.hit_time = time;
2895                 }
2896                 else
2897                 {
2898                         if(self.typehitsound)
2899                                 self.typehit_time = time;
2900                         else if(self.hitsound)
2901                                 self.hit_time = time;
2902                 }
2903         }
2904         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2905         // add 1 frametime because after this, engine SV_Physics
2906         // increases time by a frametime and then networks the frame
2907         // add another frametime because client shows everything with
2908         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2909         // needed!
2910         FOR_EACH_CLIENT(self)
2911         {
2912                 self.hitsound = FALSE;
2913                 self.typehitsound = FALSE;
2914                 antilag_record(self, altime);
2915         }
2916 }
2917
2918
2919 /*
2920  * RedirectionThink:
2921  * returns TRUE if redirecting
2922  */
2923 float redirection_timeout;
2924 float redirection_nextthink;
2925 float RedirectionThink()
2926 {
2927         float clients_found;
2928
2929         if(redirection_target == "")
2930                 return FALSE;
2931
2932         if(!redirection_timeout)
2933         {
2934                 cvar_set("sv_public", "-2");
2935                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2936                 if(redirection_target == "self")
2937                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2938                 else
2939                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2940         }
2941
2942         if(time < redirection_nextthink)
2943                 return TRUE;
2944
2945         redirection_nextthink = time + 1;
2946
2947         clients_found = 0;
2948         FOR_EACH_REALCLIENT(self)
2949         {
2950                 // TODO add timer
2951                 print("Redirecting: sending connect command to ", self.netname, "\n");
2952                 if(redirection_target == "self")
2953                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2954                 else
2955                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2956                 ++clients_found;
2957         }
2958
2959         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2960
2961         if(time > redirection_timeout || clients_found == 0)
2962                 localcmd("\nwait; wait; wait; quit\n");
2963
2964         return TRUE;
2965 }
2966
2967 void TargetMusic_RestoreGame();
2968 void RestoreGame()
2969 {
2970         // Loaded from a save game
2971         // some things then break, so let's work around them...
2972
2973         // Progs DB (capture records)
2974         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2975
2976         // Mapinfo
2977         MapInfo_Shutdown();
2978         MapInfo_Enumerate();
2979         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2980         WeaponStats_Init();
2981
2982         TargetMusic_RestoreGame();
2983 }
2984
2985 void Shutdown()
2986 {
2987         entity e;
2988
2989         gameover = 2;
2990
2991         if(world_initialized > 0)
2992         {
2993                 world_initialized = 0;
2994                 print("Saving persistent data...\n");
2995                 Ban_SaveBans();
2996
2997                 PlayerStats_EndMatch(0);
2998                 FOR_EACH_CLIENT(e)
2999                         PlayerStats_AddGlobalInfo(e);
3000                 PlayerStats_Shutdown();
3001
3002                 if(!cheatcount_total)
3003                 {
3004                         if(autocvar_sv_db_saveasdump)
3005                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
3006                         else
3007                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
3008                 }
3009                 if(autocvar_developer)
3010                 {
3011                         if(autocvar_sv_db_saveasdump)
3012                                 db_dump(TemporaryDB, "server-temp.db");
3013                         else
3014                                 db_save(TemporaryDB, "server-temp.db");
3015                 }
3016                 CheatShutdown(); // must be after cheatcount check
3017                 db_close(ServerProgsDB);
3018                 db_close(TemporaryDB);
3019                 print("done!\n");
3020                 // tell the bot system the game is ending now
3021                 bot_endgame();
3022
3023                 WeaponStats_Shutdown();
3024                 MapInfo_Shutdown();
3025         }
3026         else if(world_initialized == 0)
3027         {
3028                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3029         }
3030 }