qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include <server/gamelog.qh>
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include <server/mutators/_mod.qh>
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "scores_rules.qh"
  21 #include "teamplay.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/constants.qh"
  24 #include <common/net_linked.qh>
  25 #include "../common/deathtypes/all.qh"
  26 #include "../common/gamemodes/sv_rules.qh"
  27 #include "../common/mapinfo.qh"
  28 #include "../common/monsters/_mod.qh"
  29 #include "../common/monsters/sv_monsters.qh"
  30 #include "../common/vehicles/all.qh"
  31 #include "../common/notifications/all.qh"
  32 #include "../common/physics/player.qh"
  33 #include "../common/playerstats.qh"
  34 #include "../common/stats.qh"
  35 #include "../common/teams.qh"
  36 #include "../common/mapobjects/trigger/secret.qh"
  37 #include "../common/mapobjects/target/music.qh"
  38 #include "../common/util.qh"
  39 #include "../common/items/_mod.qh"
  40 #include <common/weapons/_all.qh>
  41 #include "../common/state.qh"
  42
  43 const float LATENCY_THINKRATE = 10;
  44 .float latency_sum;
  45 .float latency_cnt;
  46 .float latency_time;
  47 entity pingplreport;
  48 void PingPLReport_Think(entity this)
  49 {
  50         float delta;
  51         entity e;
  52
  53         delta = 3 / maxclients;
  54         if(delta < sys_frametime)
  55                 delta = 0;
  56         this.nextthink = time + delta;
  57
  58         e = edict_num(this.cnt + 1);
  59         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  60         {
  61                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  62                 WriteByte(MSG_BROADCAST, this.cnt);
  63                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  64                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  65                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  66
  67                 // record latency times for clients throughout the match so we can report it to playerstats
  68                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  69                 {
  70                         CS(e).latency_sum += CS(e).ping;
  71                         CS(e).latency_cnt += 1;
  72                         CS(e).latency_time = time;
  73                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  74                 }
  75         }
  76         else
  77         {
  78                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  79                 WriteByte(MSG_BROADCAST, this.cnt);
  80                 WriteShort(MSG_BROADCAST, 0);
  81                 WriteByte(MSG_BROADCAST, 0);
  82                 WriteByte(MSG_BROADCAST, 0);
  83         }
  84         this.cnt = (this.cnt + 1) % maxclients;
  85 }
  86 void PingPLReport_Spawn()
  87 {
  88         pingplreport = new_pure(pingplreport);
  89         setthink(pingplreport, PingPLReport_Think);
  90         pingplreport.nextthink = time;
  91 }
  92
  93 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  94 string redirection_target;
  95 float world_initialized;
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         strfree(cvar_changes);
 149         strfree(cvar_purechanges);
 150         cvar_purechanges_count = 0;
 151
 152         h = buf_create();
 153         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 154         n = buf_getsize(h);
 155
 156         adding = true;
 157         pureadding = true;
 158
 159         for(i = 0; i < n; ++i)
 160         {
 161                 k = bufstr_get(h, i);
 162
 163 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 164 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 165 #define BADCVAR(p) if(k == p) continue
 166
 167                 // general excludes and namespaces for server admin used cvars
 168                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 169
 170                 // internal
 171                 BADPREFIX("csqc_");
 172                 BADPREFIX("cvar_check_");
 173                 BADCVAR("gamecfg");
 174                 BADCVAR("g_configversion");
 175                 BADCVAR("halflifebsp");
 176                 BADCVAR("sv_mapformat_is_quake2");
 177                 BADCVAR("sv_mapformat_is_quake3");
 178                 BADPREFIX("sv_world");
 179
 180                 // client
 181                 BADPREFIX("chase_");
 182                 BADPREFIX("cl_");
 183                 BADPREFIX("con_");
 184                 BADPREFIX("scoreboard_");
 185                 BADPREFIX("g_campaign");
 186                 BADPREFIX("g_waypointsprite_");
 187                 BADPREFIX("gl_");
 188                 BADPREFIX("joy");
 189                 BADPREFIX("hud_");
 190                 BADPREFIX("m_");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("snd_");
 197                 BADPREFIX("show");
 198                 BADPREFIX("sensitivity");
 199                 BADPREFIX("userbind");
 200                 BADPREFIX("v_");
 201                 BADPREFIX("vid_");
 202                 BADPREFIX("crosshair");
 203                 BADCVAR("mod_q3bsp_lightmapmergepower");
 204                 BADCVAR("mod_q3bsp_nolightmaps");
 205                 BADCVAR("fov");
 206                 BADCVAR("mastervolume");
 207                 BADCVAR("volume");
 208                 BADCVAR("bgmvolume");
 209                 BADCVAR("in_pitch_min");
 210                 BADCVAR("in_pitch_max");
 211
 212                 // private
 213                 BADCVAR("developer");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("net_address");
 216                 BADCVAR("net_address_ipv6");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("serverconfig");
 220                 BADCVAR("sv_autoscreenshot");
 221                 BADCVAR("sv_heartbeatperiod");
 222                 BADCVAR("sv_vote_master_password");
 223                 BADCVAR("sys_colortranslation");
 224                 BADCVAR("sys_specialcharactertranslation");
 225                 BADCVAR("timeformat");
 226                 BADCVAR("timestamps");
 227                 BADCVAR("g_require_stats");
 228                 BADPREFIX("developer_");
 229                 BADPREFIX("g_ban_");
 230                 BADPREFIX("g_banned_list");
 231                 BADPREFIX("g_require_stats_");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("quit_");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251                 BADCVAR("sv_muteban_list");
 252                 BADCVAR("sv_voteban_list");
 253                 BADCVAR("sv_allow_customplayermodels_idlist");
 254                 BADCVAR("sv_allow_customplayermodels_speciallist");
 255
 256                 // mapinfo
 257                 BADCVAR("fraglimit");
 258                 BADCVAR("g_arena");
 259                 BADCVAR("g_assault");
 260                 BADCVAR("g_ca");
 261                 BADCVAR("g_ca_teams");
 262                 BADCVAR("g_conquest");
 263                 BADCVAR("g_conquest_teams");
 264                 BADCVAR("g_ctf");
 265                 BADCVAR("g_cts");
 266                 BADCVAR("g_dotc");
 267                 BADCVAR("g_dm");
 268                 BADCVAR("g_domination");
 269                 BADCVAR("g_domination_default_teams");
 270                 BADCVAR("g_duel");
 271                 BADCVAR("g_duel_not_dm_maps");
 272                 BADCVAR("g_freezetag");
 273                 BADCVAR("g_freezetag_teams");
 274                 BADCVAR("g_invasion_teams");
 275                 BADCVAR("g_invasion_type");
 276                 BADCVAR("g_jailbreak");
 277                 BADCVAR("g_jailbreak_teams");
 278                 BADCVAR("g_keepaway");
 279                 BADCVAR("g_keyhunt");
 280                 BADCVAR("g_keyhunt_teams");
 281                 BADCVAR("g_lms");
 282                 BADCVAR("g_nexball");
 283                 BADCVAR("g_onslaught");
 284                 BADCVAR("g_race");
 285                 BADCVAR("g_race_laps_limit");
 286                 BADCVAR("g_race_qualifying_timelimit");
 287                 BADCVAR("g_race_qualifying_timelimit_override");
 288                 BADCVAR("g_runematch");
 289                 BADCVAR("g_shootfromeye");
 290                 BADCVAR("g_snafu");
 291                 BADCVAR("g_survival");
 292                 BADCVAR("g_survival_not_dm_maps");
 293                 BADCVAR("g_tdm");
 294                 BADCVAR("g_tdm_on_dm_maps");
 295                 BADCVAR("g_tdm_teams");
 296                 BADCVAR("g_vip");
 297                 BADCVAR("leadlimit");
 298                 BADCVAR("nextmap");
 299                 BADCVAR("teamplay");
 300                 BADCVAR("timelimit");
 301                 BADCVAR("g_mapinfo_settemp_acl");
 302                 BADCVAR("g_mapinfo_ignore_warnings");
 303                 BADCVAR("g_maplist_ignore_sizes");
 304                 BADCVAR("g_maplist_sizes_count_bots");
 305
 306                 // long
 307                 BADCVAR("hostname");
 308                 BADCVAR("g_maplist");
 309                 BADCVAR("g_maplist_mostrecent");
 310                 BADCVAR("sv_motd");
 311
 312                 v = cvar_string(k);
 313                 d = cvar_defstring(k);
 314                 if(v == d)
 315                         continue;
 316
 317                 if(adding)
 318                 {
 319                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 320                         if(strlen(cvar_changes) > 16384)
 321                         {
 322                                 cvar_changes = "// too many settings have been changed to show them here\n";
 323                                 adding = 0;
 324                         }
 325                 }
 326
 327                 // now check if the changes are actually gameplay relevant
 328
 329                 // does nothing gameplay relevant
 330                 BADCVAR("captureleadlimit_override");
 331                 BADCVAR("condump_stripcolors");
 332                 BADCVAR("gameversion");
 333                 BADCVAR("fs_gamedir");
 334                 BADCVAR("g_allow_oldvortexbeam");
 335                 BADCVAR("g_balance_kill_delay");
 336                 BADCVAR("g_buffs_pickup_anyway");
 337                 BADCVAR("g_buffs_randomize");
 338                 BADCVAR("g_buffs_randomize_teamplay");
 339                 BADCVAR("g_campcheck_distance");
 340                 BADCVAR("g_chatsounds");
 341                 BADCVAR("g_ca_point_leadlimit");
 342                 BADCVAR("g_ca_point_limit");
 343                 BADCVAR("g_ctf_captimerecord_always");
 344                 BADCVAR("g_ctf_flag_glowtrails");
 345                 BADCVAR("g_ctf_dynamiclights");
 346                 BADCVAR("g_ctf_flag_pickup_verbosename");
 347                 BADPRESUFFIX("g_ctf_flag_", "_model");
 348                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 349                 BADCVAR("g_domination_point_leadlimit");
 350                 BADCVAR("g_forced_respawn");
 351                 BADCVAR("g_freezetag_point_leadlimit");
 352                 BADCVAR("g_freezetag_point_limit");
 353                 BADCVAR("g_glowtrails");
 354                 BADCVAR("g_hats");
 355                 BADCVAR("g_casings");
 356                 BADCVAR("g_invasion_point_limit");
 357                 BADCVAR("g_jump_grunt");
 358                 BADCVAR("g_keepaway_ballcarrier_effects");
 359                 BADCVAR("g_keepawayball_effects");
 360                 BADCVAR("g_keyhunt_point_leadlimit");
 361                 BADCVAR("g_nexball_goalleadlimit");
 362                 BADCVAR("g_new_toys_autoreplace");
 363                 BADCVAR("g_new_toys_use_pickupsound");
 364                 BADCVAR("g_physics_predictall");
 365                 BADCVAR("g_piggyback");
 366                 BADCVAR("g_playerclip_collisions");
 367                 BADCVAR("g_spawn_alloweffects");
 368                 BADCVAR("g_tdm_point_leadlimit");
 369                 BADCVAR("g_tdm_point_limit");
 370                 BADCVAR("leadlimit_and_fraglimit");
 371                 BADCVAR("leadlimit_override");
 372                 BADCVAR("pausable");
 373                 BADCVAR("sv_announcer");
 374                 BADCVAR("sv_checkforpacketsduringsleep");
 375                 BADCVAR("sv_damagetext");
 376                 BADCVAR("sv_db_saveasdump");
 377                 BADCVAR("sv_intermission_cdtrack");
 378                 BADCVAR("sv_mapchange_delay");
 379                 BADCVAR("sv_minigames");
 380                 BADCVAR("sv_namechangetimer");
 381                 BADCVAR("sv_precacheplayermodels");
 382                 BADCVAR("sv_radio");
 383                 BADCVAR("sv_stepheight");
 384                 BADCVAR("sv_timeout");
 385                 BADCVAR("sv_weapons_modeloverride");
 386                 BADCVAR("w_prop_interval");
 387                 BADPREFIX("chat_");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("gameversion_");
 390                 BADPREFIX("g_chat_");
 391                 BADPREFIX("g_ctf_captimerecord_");
 392                 BADPREFIX("g_hats_");
 393                 BADPREFIX("g_maplist_");
 394                 BADPREFIX("g_mod_");
 395                 BADPREFIX("g_respawn_");
 396                 BADPREFIX("net_");
 397                 BADPREFIX("notification_");
 398                 BADPREFIX("prvm_");
 399                 BADPREFIX("skill_");
 400                 BADPREFIX("sv_allow_");
 401                 BADPREFIX("sv_cullentities_");
 402                 BADPREFIX("sv_maxidle_");
 403                 BADPREFIX("sv_minigames_");
 404                 BADPREFIX("sv_radio_");
 405                 BADPREFIX("sv_timeout_");
 406                 BADPREFIX("sv_vote_");
 407                 BADPREFIX("timelimit_");
 408
 409                 // allowed changes to server admins (please sync this to server.cfg)
 410                 // vi commands:
 411                 //   :/"impure"/,$d
 412                 //   :g!,^\/\/[^ /],d
 413                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 414                 //   :%!sort
 415                 // yes, this does contain some redundant stuff, don't really care
 416                 BADPREFIX("bot_ai_");
 417                 BADCVAR("bot_config_file");
 418                 BADCVAR("bot_number");
 419                 BADCVAR("bot_prefix");
 420                 BADCVAR("bot_suffix");
 421                 BADCVAR("capturelimit_override");
 422                 BADCVAR("fraglimit_override");
 423                 BADCVAR("gametype");
 424                 BADCVAR("g_antilag");
 425                 BADCVAR("g_balance_teams");
 426                 BADCVAR("g_balance_teams_prevent_imbalance");
 427                 BADCVAR("g_balance_teams_scorefactor");
 428                 BADCVAR("g_ban_sync_trusted_servers");
 429                 BADCVAR("g_ban_sync_uri");
 430                 BADCVAR("g_buffs");
 431                 BADCVAR("g_ca_teams_override");
 432                 BADCVAR("g_ctf_fullbrightflags");
 433                 BADCVAR("g_ctf_ignore_frags");
 434                 BADCVAR("g_ctf_leaderboard");
 435                 BADCVAR("g_domination_point_limit");
 436                 BADCVAR("g_domination_teams_override");
 437                 BADCVAR("g_freezetag_teams_override");
 438                 BADCVAR("g_friendlyfire");
 439                 BADCVAR("g_fullbrightitems");
 440                 BADCVAR("g_fullbrightplayers");
 441                 BADCVAR("g_keyhunt_point_limit");
 442                 BADCVAR("g_keyhunt_teams_override");
 443                 BADCVAR("g_lms_lives_override");
 444                 BADCVAR("g_maplist");
 445                 BADCVAR("g_maxplayers");
 446                 BADCVAR("g_mirrordamage");
 447                 BADCVAR("g_nexball_goallimit");
 448                 BADCVAR("g_norecoil");
 449                 BADCVAR("g_physics_clientselect");
 450                 BADCVAR("g_pinata");
 451                 BADCVAR("g_powerups");
 452                 BADCVAR("g_player_brightness");
 453                 BADCVAR("g_rocket_flying");
 454                 BADCVAR("g_rocket_flying_disabledelays");
 455                 BADCVAR("g_spawnshieldtime");
 456                 BADCVAR("g_start_delay");
 457                 BADCVAR("g_superspectate");
 458                 BADCVAR("g_tdm_teams_override");
 459                 BADCVAR("g_warmup");
 460                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 461                 BADCVAR("hostname");
 462                 BADCVAR("log_file");
 463                 BADCVAR("maxplayers");
 464                 BADCVAR("minplayers");
 465                 BADCVAR("minplayers_per_team");
 466                 BADCVAR("net_address");
 467                 BADCVAR("port");
 468                 BADCVAR("rcon_password");
 469                 BADCVAR("rcon_restricted_commands");
 470                 BADCVAR("rcon_restricted_password");
 471                 BADCVAR("skill");
 472                 BADCVAR("sv_adminnick");
 473                 BADCVAR("sv_autoscreenshot");
 474                 BADCVAR("sv_autotaunt");
 475                 BADCVAR("sv_curl_defaulturl");
 476                 BADCVAR("sv_defaultcharacter");
 477                 BADCVAR("sv_defaultcharacterskin");
 478                 BADCVAR("sv_defaultplayercolors");
 479                 BADCVAR("sv_defaultplayermodel");
 480                 BADCVAR("sv_defaultplayerskin");
 481                 BADCVAR("sv_maxidle");
 482                 BADCVAR("sv_maxrate");
 483                 BADCVAR("sv_motd");
 484                 BADCVAR("sv_public");
 485                 BADCVAR("sv_ready_restart");
 486                 BADCVAR("sv_status_privacy");
 487                 BADCVAR("sv_taunt");
 488                 BADCVAR("sv_vote_call");
 489                 BADCVAR("sv_vote_commands");
 490                 BADCVAR("sv_vote_majority_factor");
 491                 BADCVAR("sv_vote_master");
 492                 BADCVAR("sv_vote_master_commands");
 493                 BADCVAR("sv_vote_master_password");
 494                 BADCVAR("sv_vote_simple_majority_factor");
 495                 BADCVAR("teamplay_mode");
 496                 BADCVAR("timelimit_override");
 497                 BADPREFIX("g_warmup_");
 498                 BADPREFIX("sv_info_");
 499                 BADPREFIX("sv_ready_restart_");
 500
 501                 // mutators that announce themselves properly to the server browser
 502                 BADCVAR("g_instagib");
 503                 BADCVAR("g_new_toys");
 504                 BADCVAR("g_nix");
 505                 BADCVAR("g_grappling_hook");
 506                 BADCVAR("g_jetpack");
 507
 508                 // temporary for testing
 509                 // TODO remove before 0.8.3 release
 510                 BADCVAR("g_ca_weaponarena");
 511                 BADCVAR("g_freezetag_weaponarena");
 512                 BADCVAR("g_lms_weaponarena");
 513                 BADCVAR("g_ctf_stalemate_time");
 514
 515                 if(cvar_string("g_mod_balance") == "Testing")
 516                 {
 517                         // (temporary) while using the Testing balance, any weapon balance cvars are allowed to be changed
 518                         BADPREFIX("g_balance_");
 519                 }
 520
 521 #undef BADPRESUFFIX
 522 #undef BADPREFIX
 523 #undef BADCVAR
 524
 525                 if(pureadding)
 526                 {
 527                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 528                         if(strlen(cvar_purechanges) > 16384)
 529                         {
 530                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 531                                 pureadding = 0;
 532                         }
 533                 }
 534                 ++cvar_purechanges_count;
 535                 // WARNING: this variable is used for the server list
 536                 // NEVER dare to skip this code!
 537                 // Hacks to intentionally appearing as "pure server" even though you DO have
 538                 // modified settings may be punished by removal from the server list.
 539                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 540                 // though.
 541         }
 542         buf_del(h);
 543         if(cvar_changes == "")
 544                 cvar_changes = "// this server runs at default server settings\n";
 545         else
 546                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 547         cvar_changes = strzone(cvar_changes);
 548         if(cvar_purechanges == "")
 549                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 550         else
 551                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 552         cvar_purechanges = strzone(cvar_purechanges);
 553 }
 554
 555 entity randomseed;
 556 bool RandomSeed_Send(entity this, entity to, int sf)
 557 {
 558         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 559         WriteShort(MSG_ENTITY, this.cnt);
 560         return true;
 561 }
 562 void RandomSeed_Think(entity this)
 563 {
 564         this.cnt = bound(0, floor(random() * 65536), 65535);
 565         this.nextthink = time + 5;
 566
 567         this.SendFlags |= 1;
 568 }
 569 void RandomSeed_Spawn()
 570 {
 571         randomseed = new_pure(randomseed);
 572         setthink(randomseed, RandomSeed_Think);
 573         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 574
 575         getthink(randomseed)(randomseed); // sets random seed and nextthink
 576 }
 577
 578 spawnfunc(__init_dedicated_server)
 579 {
 580         // handler for _init/_init map (only for dedicated server initialization)
 581
 582         world_initialized = -1; // don't complain
 583
 584         delete_fn = remove_unsafely;
 585
 586         entity e = spawn();
 587         setthink(e, GotoFirstMap);
 588         e.nextthink = time; // this is usually 1 at this point
 589
 590         e = new(info_player_deathmatch);  // safeguard against player joining
 591
 592     // assign reflectively to avoid "assignment to world" warning
 593     for (int i = 0, n = numentityfields(); i < n; ++i) {
 594         string k = entityfieldname(i);
 595         if (k == "classname") {
 596             // safeguard against various stuff ;)
 597             putentityfieldstring(i, this, "worldspawn");
 598             break;
 599         }
 600     }
 601
 602         // needs to be done so early because of the constants they create
 603         static_init();
 604         static_init_late();
 605         static_init_precache();
 606
 607         IL_PUSH(g_spawnpoints, e); // just incase
 608
 609         MapInfo_Enumerate();
 610         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 611 }
 612
 613 void __init_dedicated_server_shutdown() {
 614         MapInfo_Shutdown();
 615 }
 616
 617 STATIC_INIT_EARLY(maxclients)
 618 {
 619         maxclients = 0;
 620         for (entity head = nextent(NULL); head; head = nextent(head)) {
 621                 ++maxclients;
 622         }
 623 }
 624
 625 void default_delayedinit(entity this)
 626 {
 627         if(!scores_initialized)
 628                 ScoreRules_generic();
 629 }
 630
 631 void InitGameplayMode()
 632 {
 633         VoteReset();
 634
 635         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 636         get_mi_min_max(1);
 637         // assign reflectively to avoid "assignment to world" warning
 638         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 639             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 640             if (v) {
 641             putentityfieldstring(i, world, sprintf("%v", v));
 642             if (++done == 2) break;
 643         }
 644         }
 645         // currently, NetRadiant's limit is 131072 qu for each side
 646         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 647         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 648         // in case somebody makes extremely large maps
 649         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 650
 651         MapInfo_LoadMapSettings(mapname);
 652         GameRules_teams(false);
 653
 654         if (!cvar_value_issafe(world.fog))
 655         {
 656                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 657                 world.fog = string_null;
 658         }
 659         if(MapInfo_Map_fog != "")
 660         {
 661                 if(MapInfo_Map_fog == "none")
 662                         world.fog = string_null;
 663                 else
 664                         world.fog = strzone(MapInfo_Map_fog);
 665         }
 666         clientstuff = strzone(MapInfo_Map_clientstuff);
 667
 668         MapInfo_ClearTemps();
 669
 670         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 671
 672         cache_mutatormsg = strzone("");
 673         cache_lastmutatormsg = strzone("");
 674
 675         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 676 }
 677
 678 void Map_MarkAsRecent(string m);
 679 float world_already_spawned;
 680 spawnfunc(worldspawn)
 681 {
 682         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 683
 684         bool wantrestart = false;
 685         {
 686                 if (!server_is_dedicated)
 687                 {
 688                         // force unloading of server pk3 files when starting a listen server
 689                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 690                         // restore csqc_progname too
 691                         string expect = "csprogs.dat";
 692                         wantrestart = cvar_string("csqc_progname") != expect;
 693                         cvar_set("csqc_progname", expect);
 694                 }
 695                 else
 696                 {
 697                         // Try to use versioned csprogs from pk3
 698                         // Only ever use versioned csprogs.dat files on dedicated servers;
 699                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 700                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 701                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 702                         string select = "csprogs.dat";
 703                         if (fexists(pk3csprogs)) select = pk3csprogs;
 704                         if (cvar_string("csqc_progname") != select)
 705                         {
 706                                 cvar_set("csqc_progname", select);
 707                                 wantrestart = true;
 708                         }
 709                         // Check for updates on startup
 710                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 711                         int sentinel = fopen("progs.txt", FILE_READ);
 712                         if (sentinel >= 0)
 713                         {
 714                                 string switchversion = fgets(sentinel);
 715                                 fclose(sentinel);
 716                                 if (switchversion != "" && switchversion != WATERMARK)
 717                                 {
 718                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 719                                         // if it doesn't exist, assume either:
 720                                         //   a) the current program was overwritten
 721                                         //   b) this is a client only update
 722                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 723                                         if (fexists(newprogs))
 724                                         {
 725                                                 cvar_set("sv_progs", newprogs);
 726                                                 wantrestart = true;
 727                                         }
 728                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 729                                         if (fexists(newcsprogs))
 730                                         {
 731                                                 cvar_set("csqc_progname", newcsprogs);
 732                                                 wantrestart = true;
 733                                         }
 734                                 }
 735                         }
 736                 }
 737                 if (wantrestart)
 738                 {
 739                         LOG_INFO("Restart requested");
 740                         changelevel(mapname);
 741                         // let initialization continue, shutdown depends on it
 742                 }
 743         }
 744
 745         if(world_already_spawned)
 746                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 747         world_already_spawned = true;
 748
 749         delete_fn = remove_safely; // during spawning, watch what you remove!
 750
 751         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 752
 753         // needs to be done so early because of the constants they create
 754         static_init();
 755
 756         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 757
 758         TemporaryDB = db_create();
 759
 760         // 0 normal
 761         lightstyle(0, "m");
 762
 763         // 1 FLICKER (first variety)
 764         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 765
 766         // 2 SLOW STRONG PULSE
 767         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 768
 769         // 3 CANDLE (first variety)
 770         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 771
 772         // 4 FAST STROBE
 773         lightstyle(4, "mamamamamama");
 774
 775         // 5 GENTLE PULSE 1
 776         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 777
 778         // 6 FLICKER (second variety)
 779         lightstyle(6, "nmonqnmomnmomomno");
 780
 781         // 7 CANDLE (second variety)
 782         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 783
 784         // 8 CANDLE (third variety)
 785         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 786
 787         // 9 SLOW STROBE (fourth variety)
 788         lightstyle(9, "aaaaaaaazzzzzzzz");
 789
 790         // 10 FLUORESCENT FLICKER
 791         lightstyle(10, "mmamammmmammamamaaamammma");
 792
 793         // 11 SLOW PULSE NOT FADE TO BLACK
 794         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 795
 796         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 797
 798         // 63 testing
 799         lightstyle(63, "a");
 800
 801         if(autocvar_g_campaign)
 802                 CampaignPreInit();
 803
 804         Map_MarkAsRecent(mapname);
 805
 806         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 807
 808         InitGameplayMode();
 809         static_init_late();
 810         static_init_precache();
 811         readlevelcvars();
 812         GrappleHookInit();
 813
 814         GameRules_limit_fallbacks();
 815
 816         if(warmup_limit == 0)
 817                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 818
 819         player_count = 0;
 820         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 821         if(bot_waypoints_for_items == 1)
 822                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 823                         bot_waypoints_for_items = 0;
 824
 825         WaypointSprite_Init();
 826
 827         GameLogInit(); // prepare everything
 828         // NOTE for matchid:
 829         // changing the logic generating it is okay. But:
 830         // it HAS to stay <= 64 chars
 831         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 832         if(autocvar_sv_eventlog)
 833         {
 834                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 835                 matchid = strzone(s);
 836
 837                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 838                 s = ":gameinfo:mutators:LIST";
 839
 840                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 841                 s = M_ARGV(0, string);
 842
 843                 // initialiation stuff, not good in the mutator system
 844                 if(!autocvar_g_use_ammunition)
 845                         s = strcat(s, ":no_use_ammunition");
 846
 847                 // initialiation stuff, not good in the mutator system
 848                 if(autocvar_g_pickup_items == 0)
 849                         s = strcat(s, ":no_pickup_items");
 850                 if(autocvar_g_pickup_items > 0)
 851                         s = strcat(s, ":pickup_items");
 852
 853                 // initialiation stuff, not good in the mutator system
 854                 if(autocvar_g_weaponarena != "0")
 855                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 856
 857                 // TODO to mutator system
 858                 if(autocvar_g_norecoil)
 859                         s = strcat(s, ":norecoil");
 860
 861                 // TODO to mutator system
 862                 if(autocvar_g_powerups == 0)
 863                         s = strcat(s, ":no_powerups");
 864                 if(autocvar_g_powerups > 0)
 865                         s = strcat(s, ":powerups");
 866
 867                 GameLogEcho(s);
 868                 GameLogEcho(":gameinfo:end");
 869         }
 870         else
 871                 matchid = strzone(ftos(random()));
 872
 873         cvar_set("nextmap", "");
 874
 875         SetDefaultAlpha();
 876
 877         if(autocvar_g_campaign)
 878                 CampaignPostInit();
 879
 880         Ban_LoadBans();
 881
 882         MapInfo_Enumerate();
 883         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 884
 885         q3compat = BITSET(q3compat, BIT(0), fexists(strcat("scripts/", mapname, ".arena")));
 886         q3compat = BITSET(q3compat, BIT(1), fexists(strcat("scripts/", mapname, ".defi")));
 887         LOG_INFO("CHECKED FOR: scripts/", mapname, ".arena and scripts/", mapname, ".defi, q3compat set to ", ftos(q3compat));
 888
 889         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 890         {
 891                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 892                 if(fd != -1)
 893                 {
 894                         string s;
 895                         while((s = fgets(fd)))
 896                         {
 897                                 int l = tokenize_console(s);
 898                                 if(l < 2)
 899                                         continue;
 900                                 if(argv(0) == "cd")
 901                                 {
 902                                         string trackname = argv(2);
 903                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 904                                         LOG_INFO("  cdtrack ", trackname);
 905                                         if (cvar_value_issafe(trackname))
 906                                         {
 907                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 908                                                 strcpy(clientstuff, newstuff);
 909                                         }
 910                                 }
 911                                 else if(argv(0) == "fog")
 912                                 {
 913                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 914                                         LOG_INFO("  \"fog\" \"", s, "\"");
 915                                 }
 916                                 else if(argv(0) == "set")
 917                                 {
 918                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 919                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 920                                 }
 921                                 else if(argv(0) != "//")
 922                                 {
 923                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 924                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 925                                 }
 926                         }
 927                         fclose(fd);
 928                 }
 929         }
 930
 931         WeaponStats_Init();
 932
 933         Nagger_Init();
 934
 935         next_pingtime = time + 5;
 936
 937         // set up information replies for clients and server to use
 938         maplist_reply = strzone(getmaplist());
 939         lsmaps_reply = strzone(getlsmaps());
 940         monsterlist_reply = strzone(getmonsterlist());
 941         for(int i = 0; i < 10; ++i)
 942         {
 943                 string s = getrecords(i);
 944                 if (s)
 945                         records_reply[i] = strzone(s);
 946         }
 947         ladder_reply = strzone(getladder());
 948         rankings_reply = strzone(getrankings());
 949
 950         // begin other init
 951         ClientInit_Spawn();
 952         RandomSeed_Spawn();
 953         PingPLReport_Spawn();
 954
 955         CheatInit();
 956
 957         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 958
 959         // fill sv_curl_serverpackages from .serverpackage files
 960         if (autocvar_sv_curl_serverpackages_auto)
 961         {
 962                 string s = "csprogs-" WATERMARK ".txt";
 963                 // remove automatically managed files from the list to prevent duplicates
 964                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 965                 {
 966                         string pkg = argv(i);
 967                         if (startsWith(pkg, "csprogs-")) continue;
 968                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 969                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 970                         s = cons(s, pkg);
 971                 }
 972                 // add automatically managed files to the list
 973                 #define X(match) MACRO_BEGIN \
 974                         int fd = search_begin(match, true, false); \
 975                         if (fd >= 0) \
 976                         { \
 977                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 978                                 { \
 979                                         s = cons(s, search_getfilename(fd, i)); \
 980                                 } \
 981                                 search_end(fd); \
 982                         } \
 983                 MACRO_END
 984                 X("*-serverpackage.txt");
 985                 X("*.serverpackage");
 986                 #undef X
 987                 cvar_set("sv_curl_serverpackages", s);
 988         }
 989
 990         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 991         modname = "Xonotic";
 992         // physics/balance/config changes that count as mod
 993         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 994                 modname = cvar_string("g_mod_physics");
 995         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 996                 modname = cvar_string("g_mod_balance");
 997         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 998                 modname = cvar_string("g_mod_config");
 999         // extra mutators that deserve to count as mod
1000         MUTATOR_CALLHOOK(SetModname, modname);
1001         modname = M_ARGV(0, string);
1002
1003         // save it for later
1004         modname = strzone(modname);
1005
1006         WinningConditionHelper(this); // set worldstatus
1007
1008         world_initialized = 1;
1009         __spawnfunc_spawn_all();
1010 }
1011
1012 spawnfunc(light)
1013 {
1014         //makestatic (this); // Who the f___ did that?
1015         delete(this);
1016 }
1017
1018 string GetGametype()
1019 {
1020         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1021 }
1022
1023 string GetMapname()
1024 {
1025         return mapname;
1026 }
1027
1028 float Map_Count, Map_Current;
1029 string Map_Current_Name;
1030
1031 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1032 int GetMaplistPosition()
1033 {
1034         string map = GetMapname();
1035         int idx = autocvar_g_maplist_index;
1036
1037         if(idx >= 0)
1038         {
1039                 if(idx < Map_Count)
1040                 {
1041                         if(map == argv(idx))
1042                         {
1043                                 return idx;
1044                         }
1045                 }
1046         }
1047
1048         for(int pos = 0; pos < Map_Count; ++pos)
1049         {
1050                 if(map == argv(pos))
1051                         return pos;
1052         }
1053
1054         // resume normal maplist rotation if current map is not in g_maplist
1055         return idx;
1056 }
1057
1058 bool MapHasRightSize(string map)
1059 {
1060         int minplayers = max(0, floor(autocvar_minplayers));
1061         if (teamplay)
1062                 minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
1063         if (autocvar_g_maplist_check_waypoints
1064                 && (currentbots || autocvar_bot_number || player_count < minplayers))
1065         {
1066                 string checkwp_msg = strcat("checkwp ", map);
1067                 if(!fexists(strcat("maps/", map, ".waypoints")))
1068                 {
1069                         LOG_TRACE(checkwp_msg, ": no waypoints");
1070                         return false;
1071                 }
1072                 LOG_TRACE(checkwp_msg, ": has waypoints");
1073         }
1074
1075         if(autocvar_g_maplist_ignore_sizes)
1076                 return true;
1077
1078         // open map size restriction file
1079         string opensize_msg = strcat("opensize ", map);
1080         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1081         int player_limit = ((autocvar_g_maplist_sizes_count_maxplayers) ? GetPlayerLimit() : 0);
1082         int pcount = ((player_limit > 0) ? min(player_count, player_limit) : player_count); // bind it to the player limit so that forced spectators don't influence the limits
1083         if(!autocvar_g_maplist_sizes_count_bots)
1084                 pcount -= currentbots;
1085         if(fh >= 0)
1086         {
1087                 opensize_msg = strcat(opensize_msg, ": ok, ");
1088                 int mapmin = stoi(fgets(fh));
1089                 int mapmax = stoi(fgets(fh));
1090                 fclose(fh);
1091                 if(pcount < mapmin)
1092                 {
1093                         LOG_TRACE(opensize_msg, "not enough");
1094                         return false;
1095                 }
1096                 if(mapmax && pcount > mapmax)
1097                 {
1098                         LOG_TRACE(opensize_msg, "too many");
1099                         return false;
1100                 }
1101                 LOG_TRACE(opensize_msg, "right size");
1102                 return true;
1103         }
1104         LOG_TRACE(opensize_msg, ": not found");
1105         return true;
1106 }
1107
1108 string Map_Filename(float position)
1109 {
1110         return strcat("maps/", argv(position), ".bsp");
1111 }
1112
1113 void Map_MarkAsRecent(string m)
1114 {
1115         cvar_set("g_maplist_mostrecent", strwords(cons(m, autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1116 }
1117
1118 float Map_IsRecent(string m)
1119 {
1120         return strhasword(autocvar_g_maplist_mostrecent, m);
1121 }
1122
1123 float Map_Check(float position, float pass)
1124 {
1125         string filename;
1126         string map_next;
1127         map_next = argv(position);
1128         if(pass <= 1)
1129         {
1130                 if(Map_IsRecent(map_next))
1131                         return 0;
1132         }
1133         filename = Map_Filename(position);
1134         if(MapInfo_CheckMap(map_next))
1135         {
1136                 if(pass == 2)
1137                         return 1;
1138                 if(MapHasRightSize(map_next))
1139                         return 1;
1140                 return 0;
1141         }
1142         else
1143                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1144
1145         return 0;
1146 }
1147
1148 void Map_Goto_SetStr(string nextmapname)
1149 {
1150         if(getmapname_stored != "")
1151                 strunzone(getmapname_stored);
1152         if(nextmapname == "")
1153                 getmapname_stored = "";
1154         else
1155                 getmapname_stored = strzone(nextmapname);
1156 }
1157
1158 void Map_Goto_SetFloat(float position)
1159 {
1160         cvar_set("g_maplist_index", ftos(position));
1161         Map_Goto_SetStr(argv(position));
1162 }
1163
1164 void Map_Goto(float reinit)
1165 {
1166         MapInfo_LoadMap(getmapname_stored, reinit);
1167 }
1168
1169 // return codes of map selectors:
1170 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1171 //   -2 = permanent failure
1172 float MaplistMethod_Iterate() // usual method
1173 {
1174         float pass, i;
1175
1176         LOG_TRACE("Trying MaplistMethod_Iterate");
1177
1178         for(pass = 1; pass <= 2; ++pass)
1179         {
1180                 for(i = 1; i < Map_Count; ++i)
1181                 {
1182                         float mapindex;
1183                         mapindex = (i + Map_Current) % Map_Count;
1184                         if(Map_Check(mapindex, pass))
1185                                 return mapindex;
1186                 }
1187         }
1188         return -1;
1189 }
1190
1191 float MaplistMethod_Repeat() // fallback method
1192 {
1193         LOG_TRACE("Trying MaplistMethod_Repeat");
1194
1195         if(Map_Check(Map_Current, 2))
1196                 return Map_Current;
1197         return -2;
1198 }
1199
1200 float MaplistMethod_Random() // random map selection
1201 {
1202         float i, imax;
1203
1204         LOG_TRACE("Trying MaplistMethod_Random");
1205
1206         imax = 42;
1207
1208         for(i = 0; i <= imax; ++i)
1209         {
1210                 float mapindex;
1211                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1212                 if(Map_Check(mapindex, 1))
1213                         return mapindex;
1214         }
1215         return -1;
1216 }
1217
1218 float MaplistMethod_Shuffle(float exponent) // more clever shuffling
1219 // the exponent sets a bias on the map selection:
1220 // the higher the exponent, the less likely "shortly repeated" same maps are
1221 {
1222         float i, j, imax, insertpos;
1223
1224         LOG_TRACE("Trying MaplistMethod_Shuffle");
1225
1226         imax = 42;
1227
1228         for(i = 0; i <= imax; ++i)
1229         {
1230                 string newlist;
1231
1232                 // now reinsert this at another position
1233                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1234                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1235                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1236                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1237
1238                 // insert the current map there
1239                 newlist = "";
1240                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1241                         newlist = strcat(newlist, " ", argv(j));
1242                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1243                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1244                         newlist = strcat(newlist, " ", argv(j));
1245                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1246                 cvar_set("g_maplist", newlist);
1247                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1248
1249                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1250                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1251                 if(Map_Check(Map_Current, 1))
1252                         return Map_Current;
1253         }
1254         return -1;
1255 }
1256
1257 void Maplist_Init()
1258 {
1259         float i = Map_Count = 0;
1260         if(autocvar_g_maplist != "")
1261         {
1262                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1263                 for (i = 0; i < Map_Count; ++i)
1264                 {
1265                         if (Map_Check(i, 2))
1266                                 break;
1267                 }
1268         }
1269
1270         if (i == Map_Count)
1271         {
1272                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1273                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1274                 if(autocvar_g_maplist_shuffle)
1275                         ShuffleMaplist();
1276                 if(!server_is_dedicated)
1277                         localcmd("\nmenu_cmd sync\n");
1278                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1279         }
1280         if(Map_Count == 0)
1281                 error("empty maplist, cannot select a new map");
1282         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1283
1284         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1285         // this may or may not be correct, but who cares, in the worst case a map
1286         // isn't chosen in the first pass that should have been
1287 }
1288
1289 string GetNextMap()
1290 {
1291         Maplist_Init();
1292         float nextMap = -1;
1293
1294         if(nextMap == -1)
1295                 if(autocvar_g_maplist_shuffle > 0)
1296                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1297
1298         if(nextMap == -1)
1299                 if(autocvar_g_maplist_selectrandom)
1300                         nextMap = MaplistMethod_Random();
1301
1302         if(nextMap == -1)
1303                 nextMap = MaplistMethod_Iterate();
1304
1305         if(nextMap == -1)
1306                 nextMap = MaplistMethod_Repeat();
1307
1308         if(nextMap >= 0)
1309         {
1310                 Map_Goto_SetFloat(nextMap);
1311                 return getmapname_stored;
1312         }
1313
1314         return "";
1315 }
1316
1317 float DoNextMapOverride(float reinit)
1318 {
1319         if(autocvar_g_campaign)
1320         {
1321                 CampaignPostIntermission();
1322                 alreadychangedlevel = true;
1323                 return true;
1324         }
1325         if(autocvar_quit_when_empty)
1326         {
1327                 if(player_count <= currentbots)
1328                 {
1329                         localcmd("quit\n");
1330                         alreadychangedlevel = true;
1331                         return true;
1332                 }
1333         }
1334         if(autocvar_quit_and_redirect != "")
1335         {
1336                 redirection_target = strzone(autocvar_quit_and_redirect);
1337                 alreadychangedlevel = true;
1338                 return true;
1339         }
1340         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1341         {
1342                 localcmd("restart\n");
1343                 alreadychangedlevel = true;
1344                 return true;
1345         }
1346         if(autocvar_nextmap != "")
1347         {
1348                 string m;
1349                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1350                 cvar_set("nextmap",m);
1351
1352                 if(!m || gametypevote)
1353                         return false;
1354                 if(autocvar_sv_vote_gametype)
1355                 {
1356                         Map_Goto_SetStr(m);
1357                         return false;
1358                 }
1359
1360                 if(MapInfo_CheckMap(m))
1361                 {
1362                         Map_Goto_SetStr(m);
1363                         Map_Goto(reinit);
1364                         alreadychangedlevel = true;
1365                         return true;
1366                 }
1367         }
1368         if(!reinit && autocvar_lastlevel)
1369         {
1370                 cvar_settemp_restore();
1371                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1372                 alreadychangedlevel = true;
1373                 return true;
1374         }
1375         return false;
1376 }
1377
1378 void GotoNextMap(float reinit)
1379 {
1380         //string nextmap;
1381         //float n, nummaps;
1382         //string s;
1383         if (alreadychangedlevel)
1384                 return;
1385         alreadychangedlevel = true;
1386
1387         string nextMap = GetNextMap();
1388         if(nextMap == "")
1389                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1390         Map_Goto(reinit);
1391 }
1392
1393
1394 /*
1395 ============
1396 IntermissionThink
1397
1398 When the player presses attack or jump, change to the next level
1399 ============
1400 */
1401 .float autoscreenshot;
1402 void IntermissionThink(entity this)
1403 {
1404         FixIntermissionClient(this);
1405
1406         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1407         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1408
1409         if( (server_screenshot || client_screenshot)
1410                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1411         {
1412                 this.autoscreenshot = -1;
1413                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1414                 return;
1415         }
1416
1417         if (time < intermission_exittime)
1418                 return;
1419
1420         if(!mapvote_initialized)
1421                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1422                         return;
1423
1424         MapVote_Start();
1425 }
1426
1427 /*
1428 ===============================================================================
1429
1430 RULES
1431
1432 ===============================================================================
1433 */
1434
1435 void DumpStats(float final)
1436 {
1437         float file;
1438         string s;
1439         float to_console;
1440         float to_eventlog;
1441         float to_file;
1442         float i;
1443
1444         to_console = autocvar_sv_logscores_console;
1445         to_eventlog = autocvar_sv_eventlog;
1446         to_file = autocvar_sv_logscores_file;
1447
1448         if(!final)
1449         {
1450                 to_console = true; // always print printstats replies
1451                 to_eventlog = false; // but never print them to the event log
1452         }
1453
1454         if(to_eventlog)
1455                 if(autocvar_sv_eventlog_console)
1456                         to_console = false; // otherwise we get the output twice
1457
1458         if(final)
1459                 s = ":scores:";
1460         else
1461                 s = ":status:";
1462         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1463
1464         if(to_console)
1465                 LOG_INFO(s);
1466         if(to_eventlog)
1467                 GameLogEcho(s);
1468
1469         file = -1;
1470         if(to_file)
1471         {
1472                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1473                 if(file == -1)
1474                         to_file = false;
1475                 else
1476                         fputs(file, strcat(s, "\n"));
1477         }
1478
1479         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1480         if(to_console)
1481                 LOG_INFO(s);
1482         if(to_eventlog)
1483                 GameLogEcho(s);
1484         if(to_file)
1485                 fputs(file, strcat(s, "\n"));
1486
1487         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1488                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1489                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1490                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1491                         s = strcat(s, ftos(it.team), ":");
1492                 else
1493                         s = strcat(s, "spectator:");
1494
1495                 if(to_console)
1496                         LOG_INFO(s, playername(it, false));
1497                 if(to_eventlog)
1498                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1499                 if(to_file)
1500                         fputs(file, strcat(s, playername(it, false), "\n"));
1501         });
1502
1503         if(teamplay)
1504         {
1505                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1506                 if(to_console)
1507                         LOG_INFO(s);
1508                 if(to_eventlog)
1509                         GameLogEcho(s);
1510                 if(to_file)
1511                         fputs(file, strcat(s, "\n"));
1512
1513                 for(i = 1; i < 16; ++i)
1514                 {
1515                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1516                         s = strcat(s, ":", ftos(i));
1517                         if(to_console)
1518                                 LOG_INFO(s);
1519                         if(to_eventlog)
1520                                 GameLogEcho(s);
1521                         if(to_file)
1522                                 fputs(file, strcat(s, "\n"));
1523                 }
1524         }
1525
1526         if(to_console)
1527                 LOG_INFO(":end");
1528         if(to_eventlog)
1529                 GameLogEcho(":end");
1530         if(to_file)
1531         {
1532                 fputs(file, ":end\n");
1533                 fclose(file);
1534         }
1535 }
1536
1537 void FixIntermissionClient(entity e)
1538 {
1539         if(!e.autoscreenshot) // initial call
1540         {
1541                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1542                 SetResourceExplicit(e, RES_HEALTH, -2342);
1543                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1544                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1545                 {
1546                     .entity weaponentity = weaponentities[slot];
1547                         if(e.(weaponentity))
1548                         {
1549                                 e.(weaponentity).effects = EF_NODRAW;
1550                                 if (e.(weaponentity).weaponchild)
1551                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1552                         }
1553                 }
1554                 if(IS_REAL_CLIENT(e))
1555                 {
1556                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1557                         RandomSelection_Init();
1558                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1559                                 RandomSelection_AddString(it, 1, 1);
1560                         });
1561                         if (RandomSelection_chosen_string != "")
1562                         {
1563                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1564                         }
1565                         msg_entity = e;
1566                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1567                 }
1568         }
1569 }
1570
1571 /*
1572 go to the next level for deathmatch
1573 only called if a time or frag limit has expired
1574 */
1575 void NextLevel()
1576 {
1577         game_stopped = true;
1578         intermission_running = 1; // game over
1579
1580         // enforce a wait time before allowing changelevel
1581         if(player_count > 0)
1582                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1583         else
1584                 intermission_exittime = -1;
1585
1586         /*
1587         WriteByte (MSG_ALL, SVC_CDTRACK);
1588         WriteByte (MSG_ALL, 3);
1589         WriteByte (MSG_ALL, 3);
1590         // done in FixIntermission
1591         */
1592
1593         //pos = FindIntermission ();
1594
1595         VoteReset();
1596
1597         DumpStats(true);
1598
1599         // send statistics
1600         PlayerStats_GameReport(true);
1601         WeaponStats_Shutdown();
1602
1603         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1604
1605         if(autocvar_sv_eventlog)
1606                 GameLogEcho(":gameover");
1607
1608         GameLogClose();
1609
1610         FOREACH_CLIENT(IS_PLAYER(it), {
1611                 FixIntermissionClient(it);
1612                 if(it.winning)
1613                         bprint(playername(it, false), " ^7wins.\n");
1614         });
1615
1616         target_music_kill();
1617
1618         if(autocvar_g_campaign)
1619                 CampaignPreIntermission();
1620
1621         MUTATOR_CALLHOOK(MatchEnd);
1622
1623         localcmd("\nsv_hook_gameend\n");
1624 }
1625
1626
1627 float InitiateSuddenDeath()
1628 {
1629         // Check first whether normal overtimes could be added before initiating suddendeath mode
1630         // - for this timelimit_overtime needs to be >0 of course
1631         // - also check the winning condition calculated in the previous frame and only add normal overtime
1632         //   again, if at the point at which timelimit would be extended again, still no winner was found
1633         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1634                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1635                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1636         {
1637                 return 1; // need to call InitiateOvertime later
1638         }
1639         else
1640         {
1641                 if(!checkrules_suddendeathend)
1642                 {
1643                         if(autocvar_g_campaign)
1644                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1645                         else
1646                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1647                         if(g_race && !g_race_qualifying)
1648                                 race_StartCompleting();
1649                 }
1650                 return 0;
1651         }
1652 }
1653
1654 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1655 {
1656         ++checkrules_overtimesadded;
1657         //add one more overtime by simply extending the timelimit
1658         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1659         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1660 }
1661
1662 float GetWinningCode(float fraglimitreached, float equality)
1663 {
1664         if(autocvar_g_campaign == 1)
1665         {
1666                 if(fraglimitreached)
1667                         return WINNING_YES;
1668                 else
1669                         return WINNING_NO;
1670         }
1671         else
1672         {
1673                 if(equality)
1674                 {
1675                         if(fraglimitreached)
1676                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1677                         else
1678                                 return WINNING_NEVER;
1679                 }
1680                 else
1681                 {
1682                         if(fraglimitreached)
1683                                 return WINNING_YES;
1684                         else
1685                                 return WINNING_NO;
1686                 }
1687         }
1688 }
1689
1690 // set the .winning flag for exactly those players with a given field value
1691 void SetWinners(.float field, float value)
1692 {
1693         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1694 }
1695
1696 // set the .winning flag for those players with a given field value
1697 void AddWinners(.float field, float value)
1698 {
1699         FOREACH_CLIENT(IS_PLAYER(it), {
1700                 if(it.(field) == value)
1701                         it.winning = 1;
1702         });
1703 }
1704
1705 // clear the .winning flags
1706 void ClearWinners()
1707 {
1708         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1709 }
1710
1711 void ShuffleMaplist()
1712 {
1713         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1714 }
1715
1716 int fragsleft_last;
1717 float WinningCondition_Scores(float limit, float leadlimit)
1718 {
1719         // TODO make everything use THIS winning condition (except LMS)
1720         WinningConditionHelper(NULL);
1721
1722         if(teamplay)
1723         {
1724                 for (int i = 1; i < 5; ++i)
1725                 {
1726                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1727                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1728                 }
1729         }
1730
1731         ClearWinners();
1732         if(WinningConditionHelper_winner)
1733                 WinningConditionHelper_winner.winning = 1;
1734         if(WinningConditionHelper_winnerteam >= 0)
1735                 SetWinners(team, WinningConditionHelper_winnerteam);
1736
1737         if(WinningConditionHelper_lowerisbetter)
1738         {
1739                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1740                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1741                 limit = -limit;
1742         }
1743
1744         if(WinningConditionHelper_zeroisworst)
1745                 leadlimit = 0; // not supported in this mode
1746
1747         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1748         {
1749                 float fragsleft;
1750                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1751                 {
1752                         fragsleft = 1;
1753                 }
1754                 else
1755                 {
1756                         fragsleft = FLOAT_MAX;
1757                         float leadingfragsleft = FLOAT_MAX;
1758                         if (limit)
1759                                 fragsleft = limit - WinningConditionHelper_topscore;
1760                         if (leadlimit)
1761                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1762
1763                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1764                                 fragsleft = max(fragsleft, leadingfragsleft);
1765                         else
1766                                 fragsleft = min(fragsleft, leadingfragsleft);
1767                 }
1768
1769                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1770                 {
1771                         if (fragsleft == 1)
1772                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1773                         else if (fragsleft == 2)
1774                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1775                         else if (fragsleft == 3)
1776                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1777
1778                         fragsleft_last = fragsleft;
1779                 }
1780         }
1781
1782         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1783         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1784
1785         bool limit_reached;
1786         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1787         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1788                 limit_reached = (fraglimit_reached && leadlimit_reached);
1789         else
1790                 limit_reached = (fraglimit_reached || leadlimit_reached);
1791
1792         return GetWinningCode(
1793                 WinningConditionHelper_topscore && limit_reached,
1794                 WinningConditionHelper_equality
1795         );
1796 }
1797
1798 float WinningCondition_RanOutOfSpawns()
1799 {
1800         if(have_team_spawns <= 0)
1801                 return WINNING_NO;
1802
1803         if(!autocvar_g_spawn_useallspawns)
1804                 return WINNING_NO;
1805
1806         if(!some_spawn_has_been_used)
1807                 return WINNING_NO;
1808
1809         for (int i = 1; i < 5; ++i)
1810         {
1811                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1812         }
1813
1814         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1815         {
1816                 if (Team_IsValidTeam(it.team))
1817                 {
1818                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1819                 }
1820         });
1821
1822         IL_EACH(g_spawnpoints, true,
1823         {
1824                 if (Team_IsValidTeam(it.team))
1825                 {
1826                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1827                 }
1828         });
1829
1830         ClearWinners();
1831         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1832         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1833         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1834         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1835         if(team1_score + team2_score + team3_score + team4_score == 0)
1836         {
1837                 checkrules_equality = true;
1838                 return WINNING_YES;
1839         }
1840         else if(team1_score + team2_score + team3_score + team4_score == 1)
1841         {
1842                 float t, i;
1843                 if(team1_score)
1844                         t = 1;
1845                 else if(team2_score)
1846                         t = 2;
1847                 else if(team3_score)
1848                         t = 3;
1849                 else // if(team4_score)
1850                         t = 4;
1851                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1852                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1853                 {
1854                         for (int j = 1; j <= NUM_TEAMS; ++j)
1855                         {
1856                                 if (t == j)
1857                                 {
1858                                         continue;
1859                                 }
1860                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1861                                 {
1862                                         continue;
1863                                 }
1864                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1865                         }
1866                 }
1867
1868                 AddWinners(team, t);
1869                 return WINNING_YES;
1870         }
1871         else
1872                 return WINNING_NO;
1873 }
1874
1875 /*
1876 ============
1877 CheckRules_World
1878
1879 Exit deathmatch games upon conditions
1880 ============
1881 */
1882 void CheckRules_World()
1883 {
1884         VoteThink();
1885         MapVote_Think();
1886
1887         SetDefaultAlpha();
1888
1889         if (intermission_running) // someone else quit the game already
1890         {
1891                 if(player_count == 0) // Nobody there? Then let's go to the next map
1892                         MapVote_Start();
1893                         // this will actually check the player count in the next frame
1894                         // again, but this shouldn't hurt
1895                 return;
1896         }
1897
1898         float timelimit = autocvar_timelimit * 60;
1899         float fraglimit = autocvar_fraglimit;
1900         float leadlimit = autocvar_leadlimit;
1901         if (leadlimit < 0) leadlimit = 0;
1902
1903         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1904         {
1905                 if(timelimit > 0)
1906                         timelimit = 0; // timelimit is not made for warmup
1907                 if(fraglimit > 0)
1908                         fraglimit = 0; // no fraglimit for now
1909                 leadlimit = 0; // no leadlimit for now
1910         }
1911
1912         if(timelimit > 0)
1913         {
1914                 timelimit += game_starttime;
1915         }
1916         else if (timelimit < 0)
1917         {
1918                 // endmatch
1919                 NextLevel();
1920                 return;
1921         }
1922
1923         float wantovertime;
1924         wantovertime = 0;
1925
1926         if(checkrules_suddendeathend)
1927         {
1928                 if(!checkrules_suddendeathwarning)
1929                 {
1930                         checkrules_suddendeathwarning = true;
1931                         if(g_race && !g_race_qualifying)
1932                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1933                         else
1934                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1935                 }
1936         }
1937         else
1938         {
1939                 if (timelimit && time >= timelimit)
1940                 {
1941                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1942                         {
1943                                 float totalplayers;
1944                                 float playerswithlaps;
1945                                 float readyplayers;
1946                                 totalplayers = playerswithlaps = readyplayers = 0;
1947                                 FOREACH_CLIENT(IS_PLAYER(it), {
1948                                         ++totalplayers;
1949                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1950                                                 ++playerswithlaps;
1951                                         if(it.ready)
1952                                                 ++readyplayers;
1953                                 });
1954
1955                                 // at least 2 of the players have completed a lap: start the RACE
1956                                 // otherwise, the players should end the qualifying on their own
1957                                 if(readyplayers || playerswithlaps >= 2)
1958                                 {
1959                                         checkrules_suddendeathend = 0;
1960                                         ReadyRestart(); // go to race
1961                                         return;
1962                                 }
1963                                 else
1964                                         wantovertime |= InitiateSuddenDeath();
1965                         }
1966                         else
1967                                 wantovertime |= InitiateSuddenDeath();
1968                 }
1969         }
1970
1971         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1972         {
1973                 NextLevel();
1974                 return;
1975         }
1976
1977         int checkrules_status = WinningCondition_RanOutOfSpawns();
1978         if(checkrules_status == WINNING_YES)
1979                 bprint("Hey! Someone ran out of spawns!\n");
1980         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1981                 checkrules_status = M_ARGV(0, float);
1982         else
1983                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1984
1985         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1986         {
1987                 checkrules_status = WINNING_NEVER;
1988                 checkrules_overtimesadded = -1;
1989                 wantovertime |= InitiateSuddenDeath();
1990         }
1991
1992         if(checkrules_status == WINNING_NEVER)
1993                 // equality cases! Nobody wins if the overtime ends in a draw.
1994                 ClearWinners();
1995
1996         if(wantovertime)
1997         {
1998                 if(checkrules_status == WINNING_NEVER)
1999                         InitiateOvertime();
2000                 else
2001                         checkrules_status = WINNING_YES;
2002         }
2003
2004         if(checkrules_suddendeathend)
2005                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2006                         checkrules_status = WINNING_YES;
2007
2008         if(checkrules_status == WINNING_YES)
2009         {
2010                 //print("WINNING\n");
2011                 NextLevel();
2012         }
2013 }
2014
2015 string GotoMap(string m)
2016 {
2017         m = GameTypeVote_MapInfo_FixName(m);
2018         if (!m)
2019                 return "The map you suggested is not available on this server.";
2020         if (!autocvar_sv_vote_gametype)
2021         if(!MapInfo_CheckMap(m))
2022                 return "The map you suggested does not support the current game mode.";
2023         cvar_set("nextmap", m);
2024         cvar_set("timelimit", "-1");
2025         if(mapvote_initialized || alreadychangedlevel)
2026         {
2027                 if(DoNextMapOverride(0))
2028                         return "Map switch initiated.";
2029                 else
2030                         return "Hm... no. For some reason I like THIS map more.";
2031         }
2032         else
2033                 return "Map switch will happen after scoreboard.";
2034 }
2035
2036 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2037 void RunThink(entity this)
2038 {
2039         // don't let things stay in the past.
2040         // it is possible to start that way by a trigger with a local time.
2041         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2042                 return;
2043
2044         float oldtime = time; // do we need to save this?
2045
2046         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2047         {
2048                 time = max(oldtime, this.nextthink);
2049                 this.nextthink = 0;
2050
2051                 if(getthink(this))
2052                         getthink(this)(this);
2053                 // mods often set nextthink to time to cause a think every frame,
2054                 // we don't want to loop in that case, so exit if the new nextthink is
2055                 // <= the time the qc was told, also exit if it is past the end of the
2056                 // frame
2057                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2058                         break;
2059         }
2060
2061         time = oldtime;
2062 }
2063
2064 bool autocvar_sv_freezenonclients;
2065 bool autocvar_sv_gameplayfix_delayprojectiles = false;
2066 void Physics_Frame()
2067 {
2068         if(autocvar_sv_freezenonclients)
2069                 return;
2070
2071         IL_EACH(g_moveables, true,
2072         {
2073                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PHYSICS)
2074                         continue;
2075
2076                 //set_movetype(it, it.move_movetype);
2077                 // inline the set_movetype function, since this is called a lot
2078                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2079
2080                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2081                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2082
2083                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2084                 {
2085                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2086                                 continue; // these movetypes have no regular think function
2087                         // handle thinking here
2088                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2089                                 RunThink(it);
2090                 }
2091         });
2092
2093         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2094                 return;
2095
2096         IL_EACH(g_moveables, it.move_qcphysics,
2097         {
2098                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2099                         continue;
2100                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2101         });
2102 }
2103
2104 void systems_update();
2105 void EndFrame()
2106 {
2107         anticheat_endframe();
2108
2109         Physics_Frame();
2110
2111         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2112                 entity e = IS_SPEC(it) ? it.enemy : it;
2113                 if (e.typehitsound) {
2114                         STAT(TYPEHIT_TIME, it) = time;
2115                 } else if (e.killsound) {
2116                         STAT(KILL_TIME, it) = time;
2117                 } else if (e.damage_dealt) {
2118                         STAT(HIT_TIME, it) = time;
2119                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2120                 }
2121         });
2122         // add 1 frametime because after this, engine SV_Physics
2123         // increases time by a frametime and then networks the frame
2124         // add another frametime because client shows everything with
2125         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2126         // needed!
2127         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2128         FOREACH_CLIENT(true, {
2129                 it.typehitsound = false;
2130                 it.damage_dealt = 0;
2131                 it.killsound = false;
2132                 antilag_record(it, CS(it), altime);
2133         });
2134         IL_EACH(g_monsters, true,
2135         {
2136                 antilag_record(it, it, altime);
2137         });
2138         IL_EACH(g_projectiles, it.classname == "nade",
2139         {
2140                 antilag_record(it, it, altime);
2141         });
2142         systems_update();
2143         IL_ENDFRAME();
2144 }
2145
2146
2147 /*
2148  * RedirectionThink:
2149  * returns true if redirecting
2150  */
2151 float redirection_timeout;
2152 float redirection_nextthink;
2153 float RedirectionThink()
2154 {
2155         float clients_found;
2156
2157         if(redirection_target == "")
2158                 return false;
2159
2160         if(!redirection_timeout)
2161         {
2162                 cvar_set("sv_public", "-2");
2163                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2164                 if(redirection_target == "self")
2165                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2166                 else
2167                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2168         }
2169
2170         if(time < redirection_nextthink)
2171                 return true;
2172
2173         redirection_nextthink = time + 1;
2174
2175         clients_found = 0;
2176         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2177                 // TODO add timer
2178                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2179                 if(redirection_target == "self")
2180                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2181                 else
2182                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2183                 ++clients_found;
2184         });
2185
2186         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2187
2188         if(time > redirection_timeout || clients_found == 0)
2189                 localcmd("\nwait; wait; wait; quit\n");
2190
2191         return true;
2192 }
2193
2194 void RestoreGame()
2195 {
2196         // Loaded from a save game
2197         // some things then break, so let's work around them...
2198
2199         // Progs DB (capture records)
2200         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2201
2202         // Mapinfo
2203         MapInfo_Shutdown();
2204         MapInfo_Enumerate();
2205         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2206         WeaponStats_Init();
2207
2208         TargetMusic_RestoreGame();
2209 }
2210
2211 void Shutdown()
2212 {
2213         game_stopped = 2;
2214
2215         if(world_initialized > 0)
2216         {
2217                 world_initialized = 0;
2218
2219                 // if a timeout is active, reset the slowmo value to normal
2220                 if(timeout_status == TIMEOUT_ACTIVE)
2221                         cvar_set("slowmo", ftos(orig_slowmo));
2222
2223                 LOG_TRACE("Saving persistent data...");
2224                 Ban_SaveBans();
2225
2226                 // playerstats with unfinished match
2227                 PlayerStats_GameReport(false);
2228
2229                 if(!cheatcount_total)
2230                 {
2231                         if(autocvar_sv_db_saveasdump)
2232                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2233                         else
2234                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2235                 }
2236                 if(autocvar_developer > 0)
2237                 {
2238                         if(autocvar_sv_db_saveasdump)
2239                                 db_dump(TemporaryDB, "server-temp.db");
2240                         else
2241                                 db_save(TemporaryDB, "server-temp.db");
2242                 }
2243                 CheatShutdown(); // must be after cheatcount check
2244                 db_close(ServerProgsDB);
2245                 db_close(TemporaryDB);
2246                 LOG_TRACE("Saving persistent data... done!");
2247                 // tell the bot system the game is ending now
2248                 bot_endgame();
2249
2250                 WeaponStats_Shutdown();
2251                 MapInfo_Shutdown();
2252         }
2253         else if(world_initialized == 0)
2254         {
2255                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2256         }
2257         else
2258         {
2259                 __init_dedicated_server_shutdown();
2260         }
2261 }