qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("gl_");
 257                 BADPREFIX("joy");
 258                 BADPREFIX("hud_");
 259                 BADPREFIX("m_");
 260                 BADPREFIX("menu_");
 261                 BADPREFIX("net_slist_");
 262                 BADPREFIX("r_");
 263                 BADPREFIX("sbar_");
 264                 BADPREFIX("scr_");
 265                 BADPREFIX("snd_");
 266                 BADPREFIX("show");
 267                 BADPREFIX("sensitivity");
 268                 BADPREFIX("userbind");
 269                 BADPREFIX("v_");
 270                 BADPREFIX("vid_");
 271                 BADPREFIX("crosshair");
 272                 BADCVAR("mod_q3bsp_lightmapmergepower");
 273                 BADCVAR("mod_q3bsp_nolightmaps");
 274                 BADCVAR("fov");
 275                 BADCVAR("mastervolume");
 276                 BADCVAR("volume");
 277                 BADCVAR("bgmvolume");
 278
 279                 // private
 280                 BADCVAR("developer");
 281                 BADCVAR("g_banned_list");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_heartbeatperiod");
 290                 BADCVAR("sv_vote_master_password");
 291                 BADCVAR("sys_colortranslation");
 292                 BADCVAR("sys_specialcharactertranslation");
 293                 BADCVAR("timeformat");
 294                 BADCVAR("timestamps");
 295                 BADPREFIX("developer_");
 296                 BADPREFIX("g_ban_");
 297                 BADPREFIX("g_chat_flood_");
 298                 BADPREFIX("g_voice_flood_");
 299                 BADPREFIX("rcon_");
 300                 BADPREFIX("settemp_");
 301                 BADPREFIX("sv_allowdownloads_");
 302                 BADPREFIX("sv_autodemo");
 303                 BADPREFIX("sv_curl_");
 304                 BADPREFIX("sv_eventlog");
 305                 BADPREFIX("sv_logscores_");
 306                 BADPREFIX("sv_master");
 307                 BADPREFIX("sv_weaponstats_");
 308
 309                 // these can contain player IDs, so better hide
 310                 BADCVAR("g_forced_team_red");
 311                 BADCVAR("g_forced_team_blue");
 312                 BADCVAR("g_forced_team_yellow");
 313                 BADCVAR("g_forced_team_pink");
 314
 315                 // mapinfo
 316                 BADCVAR("fraglimit");
 317                 BADCVAR("g_arena");
 318                 BADCVAR("g_assault");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_ctf");
 321                 BADCVAR("g_cts");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_domination_default_teams");
 325                 BADCVAR("g_freezetag");
 326                 BADCVAR("g_keepaway");
 327                 BADCVAR("g_keyhunt");
 328                 BADCVAR("g_keyhunt_teams");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_lms");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("g_onslaught");
 333                 BADCVAR("g_race");
 334                 BADCVAR("g_race_qualifying_timelimit");
 335                 BADCVAR("g_runematch");
 336                 BADCVAR("g_tdm");
 337                 BADCVAR("g_tdm_teams");
 338                 BADCVAR("leadlimit");
 339                 BADCVAR("nextmap");
 340                 BADCVAR("teamplay");
 341                 BADCVAR("timelimit");
 342
 343                 // long
 344                 BADCVAR("hostname");
 345                 BADCVAR("g_maplist");
 346                 BADCVAR("g_maplist_mostrecent");
 347                 BADCVAR("sv_motd");
 348
 349                 v = cvar_string(k);
 350                 d = cvar_defstring(k);
 351                 if(v == d)
 352                         continue;
 353
 354                 if(adding)
 355                 {
 356                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 357                         if(strlen(cvar_changes) > 16384)
 358                         {
 359                                 cvar_changes = "// too many settings have been changed to show them here\n";
 360                                 adding = 0;
 361                         }
 362                 }
 363
 364                 // now check if the changes are actually gameplay relevant
 365
 366                 // does nothing visible
 367                 BADCVAR("captureleadlimit_override");
 368                 BADCVAR("g_arena_point_leadlimit");
 369                 BADCVAR("g_balance_kill_delay");
 370                 BADCVAR("g_ca_point_leadlimit");
 371                 BADCVAR("g_ctf_captimerecord_always");
 372                 BADCVAR("g_ctf_capture_leadlimit");
 373                 BADCVAR("g_ctf_flag_capture_effects");
 374                 BADCVAR("g_ctf_flag_glowtrails");
 375                 BADCVAR("g_ctf_flag_pickup_effects");
 376                 BADCVAR("g_domination_point_leadlimit");
 377                 BADCVAR("g_forced_respawn");
 378                 BADCVAR("g_keyhunt_point_leadlimit");
 379                 BADCVAR("g_nexball_goalleadlimit");
 380                 BADCVAR("g_runematch_point_leadlimit");
 381                 BADCVAR("leadlimit_and_fraglimit");
 382                 BADCVAR("leadlimit_override");
 383                 BADCVAR("pausable");
 384                 BADCVAR("sv_checkforpacketsduringsleep");
 385                 BADCVAR("sv_timeout");
 386                 BADCVAR("welcome_message_time");
 387                 BADPREFIX("crypto_");
 388                 BADPREFIX("g_chat_");
 389                 BADPREFIX("g_ctf_captimerecord_");
 390                 BADPREFIX("g_maplist_votable_");
 391                 BADPREFIX("net_");
 392                 BADPREFIX("prvm_");
 393                 BADPREFIX("skill_");
 394                 BADPREFIX("sv_fragmessage_");
 395                 BADPREFIX("sv_maxidle_");
 396                 BADPREFIX("sv_vote_");
 397                 BADPREFIX("timelimit_");
 398
 399                 // allowed changes to server admins (please sync this to server.cfg)
 400                 // vi commands:
 401                 //   :/"impure"/,$d
 402                 //   :g!,^\/\/[^ /],d
 403                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 404                 //   :%!sort
 405                 // yes, this does contain some redundant stuff, don't really care
 406                 BADCVAR("bot_number");
 407                 BADCVAR("bot_prefix");
 408                 BADCVAR("bot_suffix");
 409                 BADCVAR("capturelimit_override");
 410                 BADCVAR("fraglimit_override");
 411                 BADCVAR("gametype");
 412                 BADCVAR("g_antilag");
 413                 BADCVAR("g_balance_teams");
 414                 BADCVAR("g_balance_teams_force");
 415                 BADCVAR("g_ban_sync_trusted_servers");
 416                 BADCVAR("g_ban_sync_uri");
 417                 BADCVAR("g_ctf_capture_limit");
 418                 BADCVAR("g_ctf_ignore_frags");
 419                 BADCVAR("g_ctf_win_mode");
 420                 BADCVAR("g_domination_point_limit");
 421                 BADCVAR("g_fullbrightitems");
 422                 BADCVAR("g_fullbrightplayers");
 423                 BADCVAR("g_keyhunt_point_limit");
 424                 BADCVAR("g_keyhunt_teams_override");
 425                 BADCVAR("g_lms_lives_override");
 426                 BADCVAR("g_maplist");
 427                 BADCVAR("g_maplist_check_waypoints");
 428                 BADCVAR("g_maplist_mostrecent_count");
 429                 BADCVAR("g_maplist_shuffle");
 430                 BADCVAR("g_maplist_votable");
 431                 BADCVAR("g_maplist_votable_abstain");
 432                 BADCVAR("g_maplist_votable_nodetail");
 433                 BADCVAR("g_maplist_votable_suggestions");
 434                 BADCVAR("g_minstagib");
 435                 BADCVAR("g_nexball_goallimit");
 436                 BADCVAR("g_runematch_point_limit");
 437                 BADCVAR("g_start_delay");
 438                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 439                 BADCVAR("hostname");
 440                 BADCVAR("log_file");
 441                 BADCVAR("maxplayers");
 442                 BADCVAR("g_maxplayers");
 443                 BADCVAR("minplayers");
 444                 BADCVAR("net_address");
 445                 BADCVAR("port");
 446                 BADCVAR("rcon_password");
 447                 BADCVAR("rcon_restricted_commands");
 448                 BADCVAR("rcon_restricted_password");
 449                 BADCVAR("skill");
 450                 BADCVAR("sv_adminnick");
 451                 BADCVAR("sv_autoscreenshot");
 452                 BADCVAR("sv_curl_defaulturl");
 453                 BADCVAR("sv_defaultcharacter");
 454                 BADCVAR("sv_defaultplayercolors");
 455                 BADCVAR("sv_defaultplayermodel");
 456                 BADCVAR("sv_defaultplayerskin");
 457                 BADCVAR("sv_maxidle");
 458                 BADCVAR("sv_maxrate");
 459                 BADCVAR("sv_motd");
 460                 BADCVAR("sv_public");
 461                 BADCVAR("sv_ready_restart");
 462                 BADCVAR("sv_status_privacy");
 463                 BADCVAR("sv_vote_call");
 464                 BADCVAR("sv_vote_commands");
 465                 BADCVAR("sv_vote_majority_factor");
 466                 BADCVAR("sv_vote_master");
 467                 BADCVAR("sv_vote_master_commands");
 468                 BADCVAR("sv_vote_master_password");
 469                 BADCVAR("sv_vote_simple_majority_factor");
 470                 BADCVAR("timelimit_override");
 471                 BADCVAR("g_warmup");
 472                 BADPREFIX("g_warmup_");
 473                 BADCVAR("teamplay_mode");
 474
 475                 if(autocvar_g_minstagib)
 476                 {
 477                         BADCVAR("g_grappling_hook");
 478                         BADCVAR("g_jetpack");
 479                 }
 480 #undef BADPREFIX
 481 #undef BADCVAR
 482
 483                 if(pureadding)
 484                 {
 485                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 486                         if(strlen(cvar_purechanges) > 16384)
 487                         {
 488                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 489                                 pureadding = 0;
 490                         }
 491                 }
 492                 ++cvar_purechanges_count;
 493                 // WARNING: this variable is used for the server list
 494                 // NEVER dare to skip this code!
 495                 // Hacks to intentionally appearing as "pure server" even though you DO have
 496                 // modified settings may be punished by removal from the server list.
 497                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 498                 // though.
 499         }
 500         buf_del(h);
 501         if(cvar_changes == "")
 502                 cvar_changes = "// this server runs at default server settings\n";
 503         else
 504                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 505         cvar_changes = strzone(cvar_changes);
 506         if(cvar_purechanges == "")
 507                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 508         else
 509                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 510         cvar_purechanges = strzone(cvar_purechanges);
 511 }
 512
 513 void detect_maptype()
 514 {
 515 #if 0
 516         vector o, v;
 517         float i;
 518
 519         for(;;)
 520         {
 521                 o = world.mins;
 522                 o_x += random() * (world.maxs_x - world.mins_x);
 523                 o_y += random() * (world.maxs_y - world.mins_y);
 524                 o_z += random() * (world.maxs_z - world.mins_z);
 525
 526                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 527                 if(trace_fraction == 1)
 528                         continue;
 529
 530                 v = trace_endpos;
 531
 532                 for(i = 0; i < 64; i += 4)
 533                 {
 534                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 535         if(trace_fraction == 1)
 536                 continue;
 537                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 538                 }
 539
 540                 break;
 541         }
 542 #endif
 543 }
 544
 545 entity randomseed;
 546 float RandomSeed_Send(entity to, float sf)
 547 {
 548         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 549         WriteShort(MSG_ENTITY, self.cnt);
 550         return TRUE;
 551 }
 552 void RandomSeed_Think()
 553 {
 554         self.cnt = bound(0, floor(random() * 65536), 65535);
 555         self.nextthink = time + 5;
 556
 557         self.SendFlags |= 1;
 558 }
 559 void RandomSeed_Spawn()
 560 {
 561         randomseed = spawn();
 562         randomseed.think = RandomSeed_Think;
 563         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 564
 565         entity oldself;
 566         oldself = self;
 567         self = randomseed;
 568         self.think(); // sets random seed and nextthink
 569         self = oldself;
 570 }
 571
 572 void spawnfunc___init_dedicated_server(void)
 573 {
 574         // handler for _init/_init map (only for dedicated server initialization)
 575
 576         world_initialized = -1; // don't complain
 577         cvar = cvar_normal;
 578         cvar_string = cvar_string_normal;
 579         cvar_set = cvar_set_normal;
 580
 581         remove = remove_unsafely;
 582
 583         entity e;
 584         e = spawn();
 585         e.think = GotoFirstMap;
 586         e.nextthink = time; // this is usually 1 at this point
 587
 588         e = spawn();
 589         e.classname = "info_player_deathmatch"; // safeguard against player joining
 590
 591         self.classname = "worldspawn"; // safeguard against various stuff ;)
 592
 593         MapInfo_Enumerate();
 594         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 595 }
 596
 597 void Map_MarkAsRecent(string m);
 598 float world_already_spawned;
 599 void RegisterWeapons();
 600 void Nagger_Init();
 601 void ClientInit_Spawn();
 602 void WeaponStats_Init();
 603 void WeaponStats_Shutdown();
 604 void spawnfunc_worldspawn (void)
 605 {
 606         float fd, l, i, j, n;
 607         string s, col;
 608
 609         cvar = cvar_normal;
 610         cvar_string = cvar_string_normal;
 611         cvar_set = cvar_set_normal;
 612
 613         if(world_already_spawned)
 614                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 615         world_already_spawned = TRUE;
 616
 617         remove = remove_safely; // during spawning, watch what you remove!
 618
 619         check_unacceptable_compiler_bugs();
 620
 621         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 622
 623         compressShortVector_init();
 624
 625         allowed_to_spawn = TRUE;
 626
 627         local entity head;
 628         head = nextent(world);
 629         maxclients = 0;
 630         while(head)
 631         {
 632                 ++maxclients;
 633                 head = nextent(head);
 634         }
 635
 636         // needs to be done so early as they would still spawn
 637         RegisterWeapons();
 638
 639         ServerProgsDB = db_load("server.db");
 640
 641         TemporaryDB = db_create();
 642
 643         // 0 normal
 644         lightstyle(0, "m");
 645
 646         // 1 FLICKER (first variety)
 647         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 648
 649         // 2 SLOW STRONG PULSE
 650         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 651
 652         // 3 CANDLE (first variety)
 653         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 654
 655         // 4 FAST STROBE
 656         lightstyle(4, "mamamamamama");
 657
 658         // 5 GENTLE PULSE 1
 659         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 660
 661         // 6 FLICKER (second variety)
 662         lightstyle(6, "nmonqnmomnmomomno");
 663
 664         // 7 CANDLE (second variety)
 665         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 666
 667         // 8 CANDLE (third variety)
 668         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 669
 670         // 9 SLOW STROBE (fourth variety)
 671         lightstyle(9, "aaaaaaaazzzzzzzz");
 672
 673         // 10 FLUORESCENT FLICKER
 674         lightstyle(10, "mmamammmmammamamaaamammma");
 675
 676         // 11 SLOW PULSE NOT FADE TO BLACK
 677         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 678
 679         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 680
 681         // 63 testing
 682         lightstyle(63, "a");
 683
 684         if(autocvar_g_campaign)
 685                 CampaignPreInit();
 686
 687         Map_MarkAsRecent(mapname);
 688
 689         precache_model ("null"); // we need this one before InitGameplayMode
 690         InitGameplayMode();
 691         readlevelcvars();
 692         GrappleHookInit();
 693         ElectroInit();
 694         LaserInit();
 695
 696         player_count = 0;
 697         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 698         if(bot_waypoints_for_items == 1)
 699                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 700                         bot_waypoints_for_items = 0;
 701
 702         // for setting by mapinfo
 703         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 704         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 705
 706         precache();
 707
 708         WaypointSprite_Init();
 709
 710         //if (g_domination)
 711         //      dom_init();
 712
 713         GameLogInit(); // prepare everything
 714         if(autocvar_sv_eventlog)
 715         {
 716                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 717                 matchid = strzone(s);
 718
 719                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 720                 s = ":gameinfo:mutators:LIST";
 721
 722                 ret_string = s;
 723                 MUTATOR_CALLHOOK(BuildMutatorsString);
 724                 s = ret_string;
 725
 726                 // simple, probably not good in the mutator system
 727                 if(autocvar_g_grappling_hook)
 728                         s = strcat(s, ":grappling_hook");
 729
 730                 // initialiation stuff, not good in the mutator system
 731                 if(!autocvar_g_use_ammunition)
 732                         s = strcat(s, ":no_use_ammunition");
 733
 734                 // initialiation stuff, not good in the mutator system
 735                 if(!autocvar_g_pickup_items)
 736                         s = strcat(s, ":no_pickup_items");
 737
 738                 // initialiation stuff, not good in the mutator system
 739                 if(autocvar_g_weaponarena != "0")
 740                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 741
 742                 // TODO to mutator system
 743                 if(autocvar_g_norecoil)
 744                         s = strcat(s, ":norecoil");
 745
 746                 // TODO to mutator system
 747                 if(autocvar_g_midair)
 748                         s = strcat(s, ":midair");
 749
 750                 // TODO to mutator system
 751                 if(autocvar_g_minstagib)
 752                         s = strcat(s, ":minstagib");
 753
 754                 GameLogEcho(s);
 755                 GameLogEcho(":gameinfo:end");
 756         }
 757         else
 758                 matchid = strzone(ftos(random()));
 759
 760         cvar_set("nextmap", "");
 761
 762         SetDefaultAlpha();
 763
 764         if(autocvar_g_campaign)
 765                 CampaignPostInit();
 766
 767         fteqcc_testbugs();
 768
 769         Ban_LoadBans();
 770
 771         MapInfo_Enumerate();
 772         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 773
 774         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 775         {
 776                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 777                 if(fd != -1)
 778                 {
 779                         while((s = fgets(fd)))
 780                         {
 781                                 l = tokenize_console(s);
 782                                 if(l < 2)
 783                                         continue;
 784                                 if(argv(0) == "cd")
 785                                 {
 786                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 787                                         print("  cdtrack ", argv(2), "\n");
 788                                 }
 789                                 else if(argv(0) == "fog")
 790                                 {
 791                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 792                                         print("  \"fog\" \"", s, "\"\n");
 793                                 }
 794                                 else if(argv(0) == "set")
 795                                 {
 796                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 797                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 798                                 }
 799                                 else if(argv(0) != "//")
 800                                 {
 801                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 802                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 803                                 }
 804                         }
 805                         fclose(fd);
 806                 }
 807         }
 808
 809         WeaponStats_Init();
 810
 811         addstat(STAT_WEAPONS, AS_INT, weapons);
 812         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 813         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 814         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 815         Nagger_Init();
 816
 817         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 818         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 819         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 820         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 821         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 822         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 823         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 824         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 825         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 826         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 827         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 828         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 829
 830         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 831         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 832
 833         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 834
 835         if(g_ca || g_freezetag)
 836         {
 837                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 838                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 839                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 840                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 841         }
 842         if(g_freezetag)
 843         {
 844                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 845                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 846         }
 847
 848         // g_movementspeed hack
 849         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 850         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 851         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 852         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 853
 854         next_pingtime = time + 5;
 855
 856         detect_maptype();
 857
 858         lsmaps_reply = "^7Maps available: ";
 859         lsnewmaps_reply = "^7Maps without a record set: ";
 860         for(i = 0, j = 0; i < MapInfo_count; ++i)
 861         {
 862                 if(MapInfo_Get_ByID(i))
 863                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 864                         {
 865                                 if(mod(i, 2))
 866                                         col = "^2";
 867                                 else
 868                                         col = "^3";
 869                                 ++j;
 870                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 871                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 872                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 873                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 874                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 875                         }
 876         }
 877         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 878         if (!g_race && !g_cts)
 879                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 880         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 881
 882         maplist_reply = "^7Maps in list: ";
 883         n = tokenize_console(autocvar_g_maplist);
 884         for(i = 0, j = 0; i < n; ++i)
 885         {
 886                 if(MapInfo_CheckMap(argv(i)))
 887                 {
 888                         if(mod(j, 2))
 889                                 col = "^2";
 890                         else
 891                                 col = "^3";
 892                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 893                         ++j;
 894                 }
 895         }
 896         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 897         MapInfo_ClearTemps();
 898
 899         for(i = 0; i < 10; ++i)
 900         {
 901                 records_reply[i] = strzone(getrecords(i));
 902         }
 903         if(g_cts)
 904                 ladder_reply = strzone(getladder());
 905
 906         rankings_reply = strzone(getrankings());
 907
 908         ClientInit_Spawn();
 909         RandomSeed_Spawn();
 910         PingPLReport_Spawn();
 911
 912         CheatInit();
 913
 914         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 915
 916         // fill sv_curl_serverpackages from .serverpackage files
 917         if(autocvar_sv_curl_serverpackages_auto)
 918         {
 919                 s = "";
 920                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 921                 for(i = 0; i < n; ++i)
 922                         if(substring(argv(i), -14, -1) != ".serverpackage")
 923                                 s = strcat(s, " ", argv(i));
 924                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 925                 if(fd >= 0)
 926                 {
 927                         j = search_getsize(fd);
 928                         for(i = 0; i < j; ++i)
 929                                 s = strcat(s, " ", search_getfilename(fd, i));
 930                         search_end(fd);
 931                 }
 932                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 933         }
 934
 935         PlayerStats_Init();
 936
 937         world_initialized = 1;
 938 }
 939
 940 void spawnfunc_light (void)
 941 {
 942         //makestatic (self); // Who the f___ did that?
 943         remove(self);
 944 }
 945
 946 string GetGametype()
 947 {
 948         return GametypeNameFromType(game);
 949 }
 950
 951 string getmapname_stored;
 952 string GetMapname()
 953 {
 954         return mapname;
 955 }
 956
 957 float Map_Count, Map_Current;
 958 string Map_Current_Name;
 959
 960 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 961 float GetMaplistPosition()
 962 {
 963         float pos, idx;
 964         string map;
 965
 966         map = GetMapname();
 967         idx = autocvar_g_maplist_index;
 968
 969         if(idx >= 0)
 970                 if(idx < Map_Count)
 971                         if(map == argv(idx))
 972                                 return idx;
 973
 974         for(pos = 0; pos < Map_Count; ++pos)
 975                 if(map == argv(pos))
 976                         return pos;
 977
 978         // resume normal maplist rotation if current map is not in g_maplist
 979         return idx;
 980 }
 981
 982 float MapHasRightSize(string map)
 983 {
 984         float fh;
 985         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 986         if(autocvar_g_maplist_check_waypoints)
 987         {
 988                 dprint("checkwp "); dprint(map);
 989                 if(!fexists(strcat("maps/", map, ".waypoints")))
 990                 {
 991                         dprint(": no waypoints\n");
 992                         return FALSE;
 993                 }
 994                 dprint(": has waypoints\n");
 995         }
 996
 997         // open map size restriction file
 998         dprint("opensize "); dprint(map);
 999         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1000         if(fh >= 0)
1001         {
1002                 float mapmin, mapmax;
1003                 dprint(": ok, ");
1004                 mapmin = stof(fgets(fh));
1005                 mapmax = stof(fgets(fh));
1006                 fclose(fh);
1007                 if(player_count < mapmin)
1008                 {
1009                         dprint("not enough\n");
1010                         return FALSE;
1011                 }
1012                 if(player_count > mapmax)
1013                 {
1014                         dprint("too many\n");
1015                         return FALSE;
1016                 }
1017                 dprint("right size\n");
1018                 return TRUE;
1019         }
1020         dprint(": not found\n");
1021         return TRUE;
1022 }
1023
1024 string Map_Filename(float position)
1025 {
1026         return strcat("maps/", argv(position), ".bsp");
1027 }
1028
1029 string strwords(string s, float w)
1030 {
1031         float endpos;
1032         for(endpos = 0; w && endpos >= 0; --w)
1033                 endpos = strstrofs(s, " ", endpos + 1);
1034         if(endpos < 0)
1035                 return s;
1036         else
1037                 return substring(s, 0, endpos);
1038 }
1039
1040 float strhasword(string s, string w)
1041 {
1042         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1043 }
1044
1045 void Map_MarkAsRecent(string m)
1046 {
1047         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1048 }
1049
1050 float Map_IsRecent(string m)
1051 {
1052         return strhasword(autocvar_g_maplist_mostrecent, m);
1053 }
1054
1055 float Map_Check(float position, float pass)
1056 {
1057         string filename;
1058         string map_next;
1059         map_next = argv(position);
1060         if(pass <= 1)
1061         {
1062                 if(Map_IsRecent(map_next))
1063                         return 0;
1064         }
1065         filename = Map_Filename(position);
1066         if(MapInfo_CheckMap(map_next))
1067         {
1068                 if(pass == 2)
1069                         return 1;
1070                 if(MapHasRightSize(map_next))
1071                         return 1;
1072                 return 0;
1073         }
1074         else
1075                 dprint( "Couldn't select '", filename, "'..\n" );
1076
1077         return 0;
1078 }
1079
1080 void Map_Goto_SetStr(string nextmapname)
1081 {
1082         if(getmapname_stored != "")
1083                 strunzone(getmapname_stored);
1084         if(nextmapname == "")
1085                 getmapname_stored = "";
1086         else
1087                 getmapname_stored = strzone(nextmapname);
1088 }
1089
1090 void Map_Goto_SetFloat(float position)
1091 {
1092         cvar_set("g_maplist_index", ftos(position));
1093         Map_Goto_SetStr(argv(position));
1094 }
1095
1096 void GameResetCfg()
1097 {
1098         // settings persist, except...
1099         localcmd("\nsettemp_restore\n");
1100 };
1101
1102 void Map_Goto()
1103 {
1104         GameResetCfg();
1105         MapInfo_LoadMap(getmapname_stored);
1106 }
1107
1108 // return codes of map selectors:
1109 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1110 //   -2 = permanent failure
1111 float() MaplistMethod_Iterate = // usual method
1112 {
1113         float pass, i;
1114
1115         for(pass = 1; pass <= 2; ++pass)
1116         {
1117                 for(i = 1; i < Map_Count; ++i)
1118                 {
1119                         float mapindex;
1120                         mapindex = mod(i + Map_Current, Map_Count);
1121                         if(Map_Check(mapindex, pass))
1122                                 return mapindex;
1123                 }
1124         }
1125         return -1;
1126 }
1127
1128 float() MaplistMethod_Repeat = // fallback method
1129 {
1130         if(Map_Check(Map_Current, 2))
1131                 return Map_Current;
1132         return -2;
1133 }
1134
1135 float() MaplistMethod_Random = // random map selection
1136 {
1137         float i, imax;
1138
1139         imax = 42;
1140
1141         for(i = 0; i <= imax; ++i)
1142         {
1143                 float mapindex;
1144                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1145                 if(Map_Check(mapindex, 1))
1146                         return mapindex;
1147         }
1148         return -1;
1149 }
1150
1151 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1152 // the exponent sets a bias on the map selection:
1153 // the higher the exponent, the less likely "shortly repeated" same maps are
1154 {
1155         float i, j, imax, insertpos;
1156
1157         imax = 42;
1158
1159         for(i = 0; i <= imax; ++i)
1160         {
1161                 string newlist;
1162
1163                 // now reinsert this at another position
1164                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1165                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1166                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1167                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1168
1169                 // insert the current map there
1170                 newlist = "";
1171                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1172                         newlist = strcat(newlist, " ", argv(j));
1173                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1174                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1175                         newlist = strcat(newlist, " ", argv(j));
1176                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1177                 cvar_set("g_maplist", newlist);
1178                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1179
1180                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1181                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1182                 if(Map_Check(Map_Current, 1))
1183                         return Map_Current;
1184         }
1185         return -1;
1186 }
1187
1188 void Maplist_Init()
1189 {
1190         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1191         if(Map_Count == 0)
1192         {
1193                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1194                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1195                 if(autocvar_g_maplist_shuffle)
1196                         ShuffleMaplist();
1197                 localcmd("\nmenu_cmd sync\n");
1198                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1199         }
1200         if(Map_Count == 0)
1201                 error("empty maplist, cannot select a new map");
1202         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1203
1204         if(Map_Current_Name)
1205                 strunzone(Map_Current_Name);
1206         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1207         // this may or may not be correct, but who cares, in the worst case a map
1208         // isn't chosen in the first pass that should have been
1209 }
1210
1211 string GetNextMap()
1212 {
1213         float nextMap;
1214
1215         Maplist_Init();
1216         nextMap = -1;
1217
1218         if(nextMap == -1)
1219                 if(autocvar_g_maplist_shuffle > 0)
1220                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1221
1222         if(nextMap == -1)
1223                 if(autocvar_g_maplist_selectrandom)
1224                         nextMap = MaplistMethod_Random();
1225
1226         if(nextMap == -1)
1227                 nextMap = MaplistMethod_Iterate();
1228
1229         if(nextMap == -1)
1230                 nextMap = MaplistMethod_Repeat();
1231
1232         if(nextMap >= 0)
1233         {
1234                 Map_Goto_SetFloat(nextMap);
1235                 return getmapname_stored;
1236         }
1237
1238         return "";
1239 };
1240
1241 float DoNextMapOverride()
1242 {
1243         if(autocvar_g_campaign)
1244         {
1245                 CampaignPostIntermission();
1246                 alreadychangedlevel = TRUE;
1247                 return TRUE;
1248         }
1249         if(autocvar_quit_when_empty)
1250         {
1251                 if(player_count <= currentbots)
1252                 {
1253                         localcmd("quit\n");
1254                         alreadychangedlevel = TRUE;
1255                         return TRUE;
1256                 }
1257         }
1258         if(autocvar_quit_and_redirect != "")
1259         {
1260                 redirection_target = strzone(autocvar_quit_and_redirect);
1261                 alreadychangedlevel = TRUE;
1262                 return TRUE;
1263         }
1264         if (autocvar_samelevel) // if samelevel is set, stay on same level
1265         {
1266                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1267                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1268                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1269                 localcmd("restart\n");
1270                 //changelevel (mapname);
1271                 alreadychangedlevel = TRUE;
1272                 return TRUE;
1273         }
1274         if(autocvar_nextmap != "")
1275                 if(MapInfo_CheckMap(autocvar_nextmap))
1276                 {
1277                         Map_Goto_SetStr(autocvar_nextmap);
1278                         Map_Goto();
1279                         alreadychangedlevel = TRUE;
1280                         return TRUE;
1281                 }
1282         if(autocvar_lastlevel)
1283         {
1284                 GameResetCfg();
1285                 localcmd("set lastlevel 0\ntogglemenu\n");
1286                 alreadychangedlevel = TRUE;
1287                 return TRUE;
1288         }
1289         return FALSE;
1290 };
1291
1292 void GotoNextMap()
1293 {
1294         //local string nextmap;
1295         //local float n, nummaps;
1296         //local string s;
1297         if (alreadychangedlevel)
1298                 return;
1299         alreadychangedlevel = TRUE;
1300
1301         {
1302                 string nextMap;
1303                 float allowReset;
1304
1305                 for(allowReset = 1; allowReset >= 0; --allowReset)
1306                 {
1307                         nextMap = GetNextMap();
1308                         if(nextMap != "")
1309                                 break;
1310
1311                         if(allowReset)
1312                         {
1313                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1314                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1315                                 if(autocvar_g_maplist_shuffle)
1316                                         ShuffleMaplist();
1317                                 localcmd("\nmenu_cmd sync\n");
1318                         }
1319                         else
1320                         {
1321                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1322                         }
1323                 }
1324                 Map_Goto();
1325         }
1326 };
1327
1328
1329 /*
1330 ============
1331 IntermissionThink
1332
1333 When the player presses attack or jump, change to the next level
1334 ============
1335 */
1336 .float autoscreenshot;
1337 void() MapVote_Start;
1338 void() MapVote_Think;
1339 float mapvote_initialized;
1340 void IntermissionThink()
1341 {
1342         FixIntermissionClient(self);
1343
1344         if(autocvar_sv_autoscreenshot)
1345         if(self.autoscreenshot > 0)
1346         if(time > self.autoscreenshot)
1347         {
1348                 self.autoscreenshot = -1;
1349                 if(clienttype(self) == CLIENTTYPE_REAL)
1350                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1351                 return;
1352         }
1353
1354         if (time < intermission_exittime)
1355                 return;
1356
1357         if(!mapvote_initialized)
1358                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1359                         return;
1360
1361         MapVote_Start();
1362 };
1363
1364 /*
1365 ============
1366 FindIntermission
1367
1368 Returns the entity to view from
1369 ============
1370 */
1371 /*
1372 entity FindIntermission()
1373 {
1374         local   entity spot;
1375         local   float cyc;
1376
1377 // look for info_intermission first
1378         spot = find (world, classname, "info_intermission");
1379         if (spot)
1380         {       // pick a random one
1381                 cyc = random() * 4;
1382                 while (cyc > 1)
1383                 {
1384                         spot = find (spot, classname, "info_intermission");
1385                         if (!spot)
1386                                 spot = find (spot, classname, "info_intermission");
1387                         cyc = cyc - 1;
1388                 }
1389                 return spot;
1390         }
1391
1392 // then look for the start position
1393         spot = find (world, classname, "info_player_start");
1394         if (spot)
1395                 return spot;
1396
1397 // testinfo_player_start is only found in regioned levels
1398         spot = find (world, classname, "testplayerstart");
1399         if (spot)
1400                 return spot;
1401
1402 // then look for the start position
1403         spot = find (world, classname, "info_player_deathmatch");
1404         if (spot)
1405                 return spot;
1406
1407         //objerror ("FindIntermission: no spot");
1408         return world;
1409 };
1410 */
1411
1412 /*
1413 ===============================================================================
1414
1415 RULES
1416
1417 ===============================================================================
1418 */
1419
1420 void DumpStats(float final)
1421 {
1422         float file;
1423         string s;
1424         float to_console;
1425         float to_eventlog;
1426         float to_file;
1427         float i;
1428
1429         to_console = autocvar_sv_logscores_console;
1430         to_eventlog = autocvar_sv_eventlog;
1431         to_file = autocvar_sv_logscores_file;
1432
1433         if(!final)
1434         {
1435                 to_console = TRUE; // always print printstats replies
1436                 to_eventlog = FALSE; // but never print them to the event log
1437         }
1438
1439         if(to_eventlog)
1440                 if(autocvar_sv_eventlog_console)
1441                         to_console = FALSE; // otherwise we get the output twice
1442
1443         if(final)
1444                 s = ":scores:";
1445         else
1446                 s = ":status:";
1447         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1448
1449         if(to_console)
1450                 print(s, "\n");
1451         if(to_eventlog)
1452                 GameLogEcho(s);
1453         if(to_file)
1454         {
1455                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1456                 if(file == -1)
1457                         to_file = FALSE;
1458                 else
1459                         fputs(file, strcat(s, "\n"));
1460         }
1461
1462         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1463         if(to_console)
1464                 print(s, "\n");
1465         if(to_eventlog)
1466                 GameLogEcho(s);
1467         if(to_file)
1468                 fputs(file, strcat(s, "\n"));
1469
1470         FOR_EACH_CLIENT(other)
1471         {
1472                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1473                 {
1474                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1475                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1476                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1477                                 s = strcat(s, ftos(other.team), ":");
1478                         else
1479                                 s = strcat(s, "spectator:");
1480
1481                         if(to_console)
1482                                 print(s, other.netname, "\n");
1483                         if(to_eventlog)
1484                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1485                         if(to_file)
1486                                 fputs(file, strcat(s, other.netname, "\n"));
1487                 }
1488         }
1489
1490         if(teamplay)
1491         {
1492                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1493                 if(to_console)
1494                         print(s, "\n");
1495                 if(to_eventlog)
1496                         GameLogEcho(s);
1497                 if(to_file)
1498                         fputs(file, strcat(s, "\n"));
1499
1500                 for(i = 1; i < 16; ++i)
1501                 {
1502                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1503                         s = strcat(s, ":", ftos(i));
1504                         if(to_console)
1505                                 print(s, "\n");
1506                         if(to_eventlog)
1507                                 GameLogEcho(s);
1508                         if(to_file)
1509                                 fputs(file, strcat(s, "\n"));
1510                 }
1511         }
1512
1513         if(to_console)
1514                 print(":end\n");
1515         if(to_eventlog)
1516                 GameLogEcho(":end");
1517         if(to_file)
1518         {
1519                 fputs(file, ":end\n");
1520                 fclose(file);
1521         }
1522 }
1523
1524 void FixIntermissionClient(entity e)
1525 {
1526         string s;
1527         if(!e.autoscreenshot) // initial call
1528         {
1529                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1530                 e.health = -2342;
1531                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1532                 e.solid = SOLID_NOT;
1533                 e.movetype = MOVETYPE_NONE;
1534                 e.takedamage = DAMAGE_NO;
1535                 if(e.weaponentity)
1536                 {
1537                         e.weaponentity.effects = EF_NODRAW;
1538                         if (e.weaponentity.weaponentity)
1539                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1540                 }
1541                 if(clienttype(e) == CLIENTTYPE_REAL)
1542                 {
1543                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1544                         s = autocvar_sv_intermission_cdtrack;
1545                         if(s != "")
1546                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1547                         msg_entity = e;
1548                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1549                 }
1550         }
1551 }
1552
1553
1554 /*
1555 go to the next level for deathmatch
1556 only called if a time or frag limit has expired
1557 */
1558 void NextLevel()
1559 {
1560         gameover = TRUE;
1561
1562         intermission_running = 1;
1563
1564 // enforce a wait time before allowing changelevel
1565         if(player_count > 0)
1566                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1567         else
1568                 intermission_exittime = -1;
1569
1570         /*
1571         WriteByte (MSG_ALL, SVC_CDTRACK);
1572         WriteByte (MSG_ALL, 3);
1573         WriteByte (MSG_ALL, 3);
1574         // done in FixIntermission
1575         */
1576
1577         //pos = FindIntermission ();
1578
1579         VoteReset();
1580
1581         DumpStats(TRUE);
1582
1583         // send statistics
1584         entity e;
1585         PlayerStats_EndMatch(1);
1586         FOR_EACH_CLIENT(e)
1587                 PlayerStats_AddGlobalInfo(e);
1588         PlayerStats_Shutdown();
1589         WeaponStats_Shutdown();
1590
1591         if(autocvar_sv_eventlog)
1592                 GameLogEcho(":gameover");
1593
1594         GameLogClose();
1595
1596         FOR_EACH_PLAYER(other) {
1597                 FixIntermissionClient(other);
1598                 if(other.winning)
1599                         bprint(other.netname, " ^7wins.\n");
1600         }
1601
1602         if(autocvar_g_campaign)
1603                 CampaignPreIntermission();
1604
1605         localcmd("\nsv_hook_gameend\n");
1606 }
1607
1608 /*
1609 ============
1610 CheckRules_Player
1611
1612 Exit deathmatch games upon conditions
1613 ============
1614 */
1615 void CheckRules_Player()
1616 {
1617         if (gameover)   // someone else quit the game already
1618                 return;
1619
1620         if(self.deadflag == DEAD_NO)
1621                 self.play_time += frametime;
1622
1623         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1624         //   (div0: and that in CheckRules_World please)
1625 };
1626
1627 float checkrules_equality;
1628 float checkrules_suddendeathwarning;
1629 float checkrules_suddendeathend;
1630 float checkrules_overtimesadded; //how many overtimes have been already added
1631
1632 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1633 float WINNING_YES = 1; // winner found
1634 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1635 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1636
1637 float InitiateSuddenDeath()
1638 {
1639         // Check first whether normal overtimes could be added before initiating suddendeath mode
1640         // - for this timelimit_overtime needs to be >0 of course
1641         // - also check the winning condition calculated in the previous frame and only add normal overtime
1642         //   again, if at the point at which timelimit would be extended again, still no winner was found
1643         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1644         {
1645                 return 1; // need to call InitiateOvertime later
1646         }
1647         else
1648         {
1649                 if(!checkrules_suddendeathend)
1650                 {
1651                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1652                         if(g_race && !g_race_qualifying)
1653                                 race_StartCompleting();
1654                 }
1655                 return 0;
1656         }
1657 }
1658
1659 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1660 {
1661         ++checkrules_overtimesadded;
1662         //add one more overtime by simply extending the timelimit
1663         float tl;
1664         tl = autocvar_timelimit;
1665         tl += autocvar_timelimit_overtime;
1666         cvar_set("timelimit", ftos(tl));
1667         string minutesPlural;
1668         if (autocvar_timelimit_overtime == 1)
1669                 minutesPlural = " ^3minute";
1670         else
1671                 minutesPlural = " ^3minutes";
1672
1673         bcenterprint(
1674                 strcat(
1675                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1676                         ftos(autocvar_timelimit_overtime),
1677                         minutesPlural,
1678                         " to the game!"
1679                 )
1680         );
1681 }
1682
1683 float GetWinningCode(float fraglimitreached, float equality)
1684 {
1685         if(autocvar_g_campaign == 1)
1686                 if(fraglimitreached)
1687                         return WINNING_YES;
1688                 else
1689                         return WINNING_NO;
1690
1691         else
1692                 if(equality)
1693                         if(fraglimitreached)
1694                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1695                         else
1696                                 return WINNING_NEVER;
1697                 else
1698                         if(fraglimitreached)
1699                                 return WINNING_YES;
1700                         else
1701                                 return WINNING_NO;
1702 }
1703
1704 // set the .winning flag for exactly those players with a given field value
1705 void SetWinners(.float field, float value)
1706 {
1707         entity head;
1708         FOR_EACH_PLAYER(head)
1709                 head.winning = (head.field == value);
1710 }
1711
1712 // set the .winning flag for those players with a given field value
1713 void AddWinners(.float field, float value)
1714 {
1715         entity head;
1716         FOR_EACH_PLAYER(head)
1717                 if(head.field == value)
1718                         head.winning = 1;
1719 }
1720
1721 // clear the .winning flags
1722 void ClearWinners(void)
1723 {
1724         entity head;
1725         FOR_EACH_PLAYER(head)
1726                 head.winning = 0;
1727 }
1728
1729 // Onslaught winning condition:
1730 // game terminates if only one team has a working generator (or none)
1731 float WinningCondition_Onslaught()
1732 {
1733         entity head;
1734         local float t1, t2, t3, t4;
1735
1736         WinningConditionHelper(); // set worldstatus
1737
1738         if(inWarmupStage)
1739                 return WINNING_NO;
1740
1741         // first check if the game has ended
1742         t1 = t2 = t3 = t4 = 0;
1743         head = find(world, classname, "onslaught_generator");
1744         while (head)
1745         {
1746                 if (head.health > 0)
1747                 {
1748                         if (head.team == COLOR_TEAM1) t1 = 1;
1749                         if (head.team == COLOR_TEAM2) t2 = 1;
1750                         if (head.team == COLOR_TEAM3) t3 = 1;
1751                         if (head.team == COLOR_TEAM4) t4 = 1;
1752                 }
1753                 head = find(head, classname, "onslaught_generator");
1754         }
1755         if (t1 + t2 + t3 + t4 < 2)
1756         {
1757                 // game over, only one team remains (or none)
1758                 ClearWinners();
1759                 if (t1) SetWinners(team, COLOR_TEAM1);
1760                 if (t2) SetWinners(team, COLOR_TEAM2);
1761                 if (t3) SetWinners(team, COLOR_TEAM3);
1762                 if (t4) SetWinners(team, COLOR_TEAM4);
1763                 dprint("Have a winner, ending game.\n");
1764                 return WINNING_YES;
1765         }
1766
1767         // Two or more teams remain
1768         return WINNING_NO;
1769 }
1770
1771 float LMS_NewPlayerLives()
1772 {
1773         float fl;
1774         fl = autocvar_fraglimit;
1775         if(fl == 0)
1776                 fl = 999;
1777
1778         // first player has left the game for dying too much? Nobody else can get in.
1779         if(lms_lowest_lives < 1)
1780                 return 0;
1781
1782         if(!autocvar_g_lms_join_anytime)
1783                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1784                         return 0;
1785
1786         return bound(1, lms_lowest_lives, fl);
1787 }
1788
1789 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1790 // they win. Otherwise the defending team wins once the timelimit passes.
1791 void assault_new_round();
1792 float WinningCondition_Assault()
1793 {
1794         local float status;
1795
1796         WinningConditionHelper(); // set worldstatus
1797
1798         status = WINNING_NO;
1799         // as the timelimit has not yet passed just assume the defending team will win
1800         if(assault_attacker_team == COLOR_TEAM1)
1801         {
1802                 SetWinners(team, COLOR_TEAM2);
1803         }
1804         else
1805         {
1806                 SetWinners(team, COLOR_TEAM1);
1807         }
1808
1809         local entity ent;
1810         ent = find(world, classname, "target_assault_roundend");
1811         if(ent)
1812         {
1813                 if(ent.winning) // round end has been triggered by attacking team
1814                 {
1815                         bprint("ASSAULT: round completed...\n");
1816                         SetWinners(team, assault_attacker_team);
1817
1818                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1819
1820                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1821                         {
1822                                 status = WINNING_YES;
1823                         }
1824                         else
1825                         {
1826                                 local entity oldself;
1827                                 oldself = self;
1828                                 self = ent;
1829                                 assault_new_round();
1830                                 self = oldself;
1831                         }
1832                 }
1833         }
1834
1835         return status;
1836 }
1837
1838 // LMS winning condition: game terminates if and only if there's at most one
1839 // one player who's living lives. Top two scores being equal cancels the time
1840 // limit.
1841 float WinningCondition_LMS()
1842 {
1843         entity head, head2;
1844         float have_player;
1845         float have_players;
1846         float l;
1847
1848         have_player = FALSE;
1849         have_players = FALSE;
1850         l = LMS_NewPlayerLives();
1851
1852         head = find(world, classname, "player");
1853         if(head)
1854                 have_player = TRUE;
1855         head2 = find(head, classname, "player");
1856         if(head2)
1857                 have_players = TRUE;
1858
1859         if(have_player)
1860         {
1861                 // we have at least one player
1862                 if(have_players)
1863                 {
1864                         // two or more active players - continue with the game
1865                 }
1866                 else
1867                 {
1868                         // exactly one player?
1869
1870                         ClearWinners();
1871                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1872
1873                         if(l)
1874                         {
1875                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1876                                 return WINNING_NO;
1877                         }
1878                         else
1879                         {
1880                                 // a winner!
1881                                 // and assign him his first place
1882                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1883                                 return WINNING_YES;
1884                         }
1885                 }
1886         }
1887         else
1888         {
1889                 // nobody is playing at all...
1890                 if(l)
1891                 {
1892                         // wait for players...
1893                 }
1894                 else
1895                 {
1896                         // SNAFU (maybe a draw game?)
1897                         ClearWinners();
1898                         dprint("No players, ending game.\n");
1899                         return WINNING_YES;
1900                 }
1901         }
1902
1903         // When we get here, we have at least two players who are actually LIVING,
1904         // now check if the top two players have equal score.
1905         WinningConditionHelper();
1906
1907         ClearWinners();
1908         if(WinningConditionHelper_winner)
1909                 WinningConditionHelper_winner.winning = TRUE;
1910         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1911                 return WINNING_NEVER;
1912
1913         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1914         return WINNING_NO;
1915 }
1916
1917 void ShuffleMaplist()
1918 {
1919         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1920 }
1921
1922 float leaderfrags;
1923 float WinningCondition_Scores(float limit, float leadlimit)
1924 {
1925         float limitreached;
1926
1927         // TODO make everything use THIS winning condition (except LMS)
1928         WinningConditionHelper();
1929
1930         if(teamplay)
1931         {
1932                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1933                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1934                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1935                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1936         }
1937
1938         ClearWinners();
1939         if(WinningConditionHelper_winner)
1940                 WinningConditionHelper_winner.winning = 1;
1941         if(WinningConditionHelper_winnerteam >= 0)
1942                 SetWinners(team, WinningConditionHelper_winnerteam);
1943
1944         if(WinningConditionHelper_lowerisbetter)
1945         {
1946                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1947                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1948                 limit = -limit;
1949         }
1950
1951         if(WinningConditionHelper_zeroisworst)
1952                 leadlimit = 0; // not supported in this mode
1953
1954         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1955         // these modes always score in increments of 1, thus this makes sense
1956         {
1957                 if(leaderfrags != WinningConditionHelper_topscore)
1958                 {
1959                         leaderfrags = WinningConditionHelper_topscore;
1960
1961                         if (limit)
1962                         if (leaderfrags == limit - 1)
1963                                 Announce("1fragleft");
1964                         else if (leaderfrags == limit - 2)
1965                                 Announce("2fragsleft");
1966                         else if (leaderfrags == limit - 3)
1967                                 Announce("3fragsleft");
1968                 }
1969         }
1970
1971         limitreached = FALSE;
1972         if(limit)
1973                 if(WinningConditionHelper_topscore >= limit)
1974                         limitreached = TRUE;
1975         if(leadlimit)
1976         {
1977                 float leadlimitreached;
1978                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1979                 if(autocvar_leadlimit_and_fraglimit)
1980                         limitreached = (limitreached && leadlimitreached);
1981                 else
1982                         limitreached = (limitreached || leadlimitreached);
1983         }
1984
1985         return GetWinningCode(
1986                 WinningConditionHelper_topscore && limitreached,
1987                 WinningConditionHelper_equality
1988         );
1989 }
1990
1991 float WinningCondition_Race(float fraglimit)
1992 {
1993         float wc;
1994         entity p;
1995         float n, c;
1996
1997         n = 0;
1998         c = 0;
1999         FOR_EACH_PLAYER(p)
2000         {
2001                 ++n;
2002                 if(p.race_completed)
2003                         ++c;
2004         }
2005         if(n && (n == c))
2006                 return WINNING_YES;
2007         wc = WinningCondition_Scores(fraglimit, 0);
2008
2009         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2010         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2011         // do NOT support equality when the laps are all raced!
2012                 return WINNING_STARTSUDDENDEATHOVERTIME;
2013         else
2014                 return WINNING_NEVER;
2015         return wc;
2016 }
2017
2018 void ReadyRestart();
2019 float WinningCondition_QualifyingThenRace(float limit)
2020 {
2021         float wc;
2022         wc = WinningCondition_Scores(limit, 0);
2023
2024         // NEVER initiate overtime
2025         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2026         {
2027                 return WINNING_YES;
2028         }
2029
2030         return wc;
2031 }
2032
2033 float WinningCondition_RanOutOfSpawns()
2034 {
2035         entity head;
2036
2037         if(have_team_spawns <= 0)
2038                 return WINNING_NO;
2039
2040         if(!some_spawn_has_been_used)
2041                 return WINNING_NO;
2042
2043         team1_score = team2_score = team3_score = team4_score = 0;
2044
2045         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2046         {
2047                 if(head.team == COLOR_TEAM1)
2048                         team1_score = 1;
2049                 else if(head.team == COLOR_TEAM2)
2050                         team2_score = 1;
2051                 else if(head.team == COLOR_TEAM3)
2052                         team3_score = 1;
2053                 else if(head.team == COLOR_TEAM4)
2054                         team4_score = 1;
2055         }
2056
2057         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2058         {
2059                 if(head.team == COLOR_TEAM1)
2060                         team1_score = 1;
2061                 else if(head.team == COLOR_TEAM2)
2062                         team2_score = 1;
2063                 else if(head.team == COLOR_TEAM3)
2064                         team3_score = 1;
2065                 else if(head.team == COLOR_TEAM4)
2066                         team4_score = 1;
2067         }
2068
2069         ClearWinners();
2070         if(team1_score + team2_score + team3_score + team4_score == 0)
2071         {
2072                 checkrules_equality = TRUE;
2073                 return WINNING_YES;
2074         }
2075         else if(team1_score + team2_score + team3_score + team4_score == 1)
2076         {
2077                 float t, i;
2078                 if(team1_score) t = COLOR_TEAM1;
2079                 if(team2_score) t = COLOR_TEAM2;
2080                 if(team3_score) t = COLOR_TEAM3;
2081                 if(team4_score) t = COLOR_TEAM4;
2082                 CheckAllowedTeams(world);
2083                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2084                 {
2085                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2086                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2087                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2088                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2089                 }
2090
2091                 AddWinners(team, t);
2092                 return WINNING_YES;
2093         }
2094         else
2095                 return WINNING_NO;
2096 }
2097
2098 /*
2099 ============
2100 CheckRules_World
2101
2102 Exit deathmatch games upon conditions
2103 ============
2104 */
2105 void CheckRules_World()
2106 {
2107         float timelimit;
2108         float fraglimit;
2109         float leadlimit;
2110
2111         VoteThink();
2112         MapVote_Think();
2113
2114         SetDefaultAlpha();
2115
2116         /*
2117         MapVote_Think should now do that part
2118         if (intermission_running)
2119                 if (time >= intermission_exittime + 60)
2120                 {
2121                         if(!DoNextMapOverride())
2122                                 GotoNextMap();
2123                         return;
2124                 }
2125         */
2126
2127         if (gameover)   // someone else quit the game already
2128         {
2129                 if(player_count == 0) // Nobody there? Then let's go to the next map
2130                         MapVote_Start();
2131                         // this will actually check the player count in the next frame
2132                         // again, but this shouldn't hurt
2133                 return;
2134         }
2135
2136         timelimit = autocvar_timelimit * 60;
2137         fraglimit = autocvar_fraglimit;
2138         leadlimit = autocvar_leadlimit;
2139
2140         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2141         {
2142                 if(timelimit > 0)
2143                         timelimit = 0; // timelimit is not made for warmup
2144                 if(fraglimit > 0)
2145                         fraglimit = 0; // no fraglimit for now
2146                 leadlimit = 0; // no leadlimit for now
2147         }
2148
2149         if(g_onslaught)
2150                 timelimit = 0; // ONS has its own overtime rule
2151
2152         if(timelimit > 0)
2153         {
2154                 timelimit += game_starttime;
2155         }
2156         else if (timelimit < 0)
2157         {
2158                 // endmatch
2159                 NextLevel();
2160                 return;
2161         }
2162
2163         float wantovertime;
2164         wantovertime = 0;
2165
2166         if(checkrules_suddendeathend)
2167         {
2168                 if(!checkrules_suddendeathwarning)
2169                 {
2170                         checkrules_suddendeathwarning = TRUE;
2171                         if(g_race && !g_race_qualifying)
2172                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2173                         else
2174                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2175                 }
2176         }
2177         else
2178         {
2179                 if (timelimit && time >= timelimit)
2180                 {
2181                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2182                         {
2183                                 float totalplayers;
2184                                 float playerswithlaps;
2185                                 float readyplayers;
2186                                 entity head;
2187                                 totalplayers = playerswithlaps = readyplayers = 0;
2188                                 FOR_EACH_PLAYER(head)
2189                                 {
2190                                         ++totalplayers;
2191                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2192                                                 ++playerswithlaps;
2193                                         if(head.ready)
2194                                                 ++readyplayers;
2195                                 }
2196
2197                                 // at least 2 of the players have completed a lap: start the RACE
2198                                 // otherwise, the players should end the qualifying on their own
2199                                 if(readyplayers || playerswithlaps >= 2)
2200                                 {
2201                                         checkrules_suddendeathend = 0;
2202                                         ReadyRestart(); // go to race
2203                                         return;
2204                                 }
2205                                 else
2206                                         wantovertime |= InitiateSuddenDeath();
2207                         }
2208                         else
2209                                 wantovertime |= InitiateSuddenDeath();
2210                 }
2211         }
2212
2213         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2214         {
2215                 NextLevel();
2216                 return;
2217         }
2218
2219         float checkrules_status;
2220         checkrules_status = WinningCondition_RanOutOfSpawns();
2221         if(checkrules_status == WINNING_YES)
2222         {
2223                 bprint("Hey! Someone ran out of spawns!\n");
2224         }
2225         else if(g_race && !g_race_qualifying && timelimit >= 0)
2226         {
2227                 checkrules_status = WinningCondition_Race(fraglimit);
2228                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2229         }
2230         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2231         {
2232                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2233                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2234         }
2235         else if(g_assault)
2236         {
2237                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2238         }
2239         else if(g_lms)
2240         {
2241                 checkrules_status = WinningCondition_LMS();
2242         }
2243         else if (g_onslaught)
2244         {
2245                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2246         }
2247         else
2248         {
2249                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2250                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2251         }
2252
2253         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2254         {
2255                 checkrules_status = WINNING_NEVER;
2256                 checkrules_overtimesadded = -1;
2257                 wantovertime |= InitiateSuddenDeath();
2258         }
2259
2260         if(checkrules_status == WINNING_NEVER)
2261                 // equality cases! Nobody wins if the overtime ends in a draw.
2262                 ClearWinners();
2263
2264         if(wantovertime)
2265         {
2266                 if(checkrules_status == WINNING_NEVER)
2267                         InitiateOvertime();
2268                 else
2269                         checkrules_status = WINNING_YES;
2270         }
2271
2272         if(checkrules_suddendeathend)
2273                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2274                         checkrules_status = WINNING_YES;
2275
2276         if(checkrules_status == WINNING_YES)
2277         {
2278                 //print("WINNING\n");
2279                 NextLevel();
2280         }
2281 };
2282
2283 float mapvote_nextthink;
2284 float mapvote_initialized;
2285 float mapvote_keeptwotime;
2286 float mapvote_timeout;
2287 string mapvote_message;
2288 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2289 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2290 float mapvote_screenshot_dirs_count;
2291
2292 float mapvote_count;
2293 float mapvote_count_real;
2294 string mapvote_maps[MAPVOTE_COUNT];
2295 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2296 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2297 float mapvote_maps_suggested[MAPVOTE_COUNT];
2298 string mapvote_suggestions[MAPVOTE_COUNT];
2299 float mapvote_suggestion_ptr;
2300 float mapvote_voters;
2301 float mapvote_votes[MAPVOTE_COUNT];
2302 float mapvote_run;
2303 float mapvote_detail;
2304 float mapvote_abstain;
2305 .float mapvote;
2306
2307 void MapVote_ClearAllVotes()
2308 {
2309         FOR_EACH_CLIENT(other)
2310                 other.mapvote = 0;
2311 }
2312
2313 string MapVote_Suggest(string m)
2314 {
2315         float i;
2316         if(m == "")
2317                 return "That's not how to use this command.";
2318         if(!autocvar_g_maplist_votable_suggestions)
2319                 return "Suggestions are not accepted on this server.";
2320         if(mapvote_initialized)
2321                 return "Can't suggest - voting is already in progress!";
2322         m = MapInfo_FixName(m);
2323         if(!m)
2324                 return "The map you suggested is not available on this server.";
2325         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2326                 if(Map_IsRecent(m))
2327                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2328
2329         if(!MapInfo_CheckMap(m))
2330                 return "The map you suggested does not support the current game mode.";
2331         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2332                 if(mapvote_suggestions[i] == m)
2333                         return "This map was already suggested.";
2334         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2335         {
2336                 i = floor(random() * mapvote_suggestion_ptr);
2337         }
2338         else
2339         {
2340                 i = mapvote_suggestion_ptr;
2341                 mapvote_suggestion_ptr += 1;
2342         }
2343         if(mapvote_suggestions[i] != "")
2344                 strunzone(mapvote_suggestions[i]);
2345         mapvote_suggestions[i] = strzone(m);
2346         if(autocvar_sv_eventlog)
2347                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2348         return strcat("Suggestion of ", m, " accepted.");
2349 }
2350
2351 void MapVote_AddVotable(string nextMap, float isSuggestion)
2352 {
2353         float j, i, o;
2354         string pakfile, mapfile;
2355
2356         if(nextMap == "")
2357                 return;
2358         for(j = 0; j < mapvote_count; ++j)
2359                 if(mapvote_maps[j] == nextMap)
2360                         return;
2361         // suggestions might be no longer valid/allowed after gametype switch!
2362         if(isSuggestion)
2363                 if(!MapInfo_CheckMap(nextMap))
2364                         return;
2365         mapvote_maps[mapvote_count] = strzone(nextMap);
2366         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2367
2368         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2369         {
2370                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2371                 pakfile = whichpack(strcat(mapfile, ".tga"));
2372                 if(pakfile == "")
2373                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2374                 if(pakfile == "")
2375                         pakfile = whichpack(strcat(mapfile, ".png"));
2376                 if(pakfile != "")
2377                         break;
2378         }
2379         if(i >= mapvote_screenshot_dirs_count)
2380                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2381         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2382                 pakfile = substring(pakfile, o, -1);
2383
2384         mapvote_maps_screenshot_dir[mapvote_count] = i;
2385         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2386
2387         mapvote_count += 1;
2388 }
2389
2390 void MapVote_Spawn();
2391 void MapVote_Init()
2392 {
2393         float i;
2394         float nmax, smax;
2395
2396         MapVote_ClearAllVotes();
2397
2398         mapvote_count = 0;
2399         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2400         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2401
2402         if(mapvote_abstain)
2403                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2404         else
2405                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2406         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2407
2408         // we need this for AddVotable, as that cycles through the screenshot dirs
2409         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2410         if(mapvote_screenshot_dirs_count == 0)
2411                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2412         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2413         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2414                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2415
2416         if(mapvote_suggestion_ptr)
2417                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2418                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2419
2420         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2421                 MapVote_AddVotable(GetNextMap(), FALSE);
2422
2423         if(mapvote_count == 0)
2424         {
2425                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2426                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2427                 if(autocvar_g_maplist_shuffle)
2428                         ShuffleMaplist();
2429                 localcmd("\nmenu_cmd sync\n");
2430                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                         MapVote_AddVotable(GetNextMap(), FALSE);
2432         }
2433
2434         mapvote_count_real = mapvote_count;
2435         if(mapvote_abstain)
2436                 MapVote_AddVotable("don't care", 0);
2437
2438         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2439
2440         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2441         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2442         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2443                 mapvote_keeptwotime = 0;
2444         mapvote_message = "Choose a map and press its key!";
2445
2446         MapVote_Spawn();
2447 }
2448
2449 void MapVote_SendPicture(float id)
2450 {
2451         msg_entity = self;
2452         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2453         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2454         WriteByte(MSG_ONE, id);
2455         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2456 }
2457
2458 float GameCommand_MapVote(string cmd)
2459 {
2460         if(!intermission_running)
2461                 return FALSE;
2462
2463         if(cmd == "mv_getpic")
2464         {
2465                 MapVote_SendPicture(stof(argv(1)));
2466                 return TRUE;
2467         }
2468
2469         return FALSE;
2470 }
2471
2472 float MapVote_GetMapMask()
2473 {
2474         float mask, i, power;
2475         mask = 0;
2476         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2477                 if(mapvote_maps[i] != "")
2478                         mask |= power;
2479         return mask;
2480 }
2481
2482 entity mapvote_ent;
2483 float MapVote_SendEntity(entity to, float sf)
2484 {
2485         float i;
2486
2487         if(sf & 1)
2488                 sf &~= 2; // if we send 1, we don't need to also send 2
2489
2490         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2491         WriteByte(MSG_ENTITY, sf);
2492
2493         if(sf & 1)
2494         {
2495                 // flag 1 == initialization
2496                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2497                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2498                 WriteString(MSG_ENTITY, "");
2499                 WriteByte(MSG_ENTITY, mapvote_count);
2500                 WriteByte(MSG_ENTITY, mapvote_abstain);
2501                 WriteByte(MSG_ENTITY, mapvote_detail);
2502                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2503                 if(mapvote_count <= 8)
2504                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2505                 else
2506                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2507                 for(i = 0; i < mapvote_count; ++i)
2508                         if(mapvote_maps[i] != "")
2509                         {
2510                                 if(mapvote_abstain && i == mapvote_count - 1)
2511                                 {
2512                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2513                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2514                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2515                                 }
2516                                 else
2517                                 {
2518                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2519                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2520                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2521                                 }
2522                         }
2523         }
2524
2525         if(sf & 2)
2526         {
2527                 // flag 2 == update of mask
2528                 if(mapvote_count <= 8)
2529                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2530                 else
2531                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2532         }
2533
2534         if(sf & 4)
2535         {
2536                 if(mapvote_detail)
2537                         for(i = 0; i < mapvote_count; ++i)
2538                                 if(mapvote_maps[i] != "")
2539                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2540
2541                 WriteByte(MSG_ENTITY, to.mapvote);
2542         }
2543
2544         return TRUE;
2545 }
2546
2547 void MapVote_Spawn()
2548 {
2549         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2550 }
2551
2552 void MapVote_TouchMask()
2553 {
2554         mapvote_ent.SendFlags |= 2;
2555 }
2556
2557 void MapVote_TouchVotes(entity voter)
2558 {
2559         mapvote_ent.SendFlags |= 4;
2560 }
2561
2562 float MapVote_Finished(float mappos)
2563 {
2564         string result;
2565         float i;
2566         float didntvote;
2567
2568         if(autocvar_sv_eventlog)
2569         {
2570                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2571                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2572                 didntvote = mapvote_voters;
2573                 for(i = 0; i < mapvote_count; ++i)
2574                         if(mapvote_maps[i] != "")
2575                         {
2576                                 didntvote -= mapvote_votes[i];
2577                                 if(i != mappos)
2578                                 {
2579                                         result = strcat(result, ":", mapvote_maps[i]);
2580                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2581                                 }
2582                         }
2583                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2584
2585                 GameLogEcho(result);
2586                 if(mapvote_maps_suggested[mappos])
2587                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2588         }
2589
2590         FOR_EACH_REALCLIENT(other)
2591                 FixClientCvars(other);
2592
2593         Map_Goto_SetStr(mapvote_maps[mappos]);
2594         Map_Goto();
2595         alreadychangedlevel = TRUE;
2596         return TRUE;
2597 }
2598 void MapVote_CheckRules_1()
2599 {
2600         float i;
2601
2602         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2603         {
2604                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2605                 mapvote_votes[i] = 0;
2606         }
2607
2608         mapvote_voters = 0;
2609         FOR_EACH_REALCLIENT(other)
2610         {
2611                 ++mapvote_voters;
2612                 if(other.mapvote)
2613                 {
2614                         i = other.mapvote - 1;
2615                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2616                         mapvote_votes[i] = mapvote_votes[i] + 1;
2617                 }
2618         }
2619 }
2620
2621 float MapVote_CheckRules_2()
2622 {
2623         float i;
2624         float firstPlace, secondPlace;
2625         float firstPlaceVotes, secondPlaceVotes;
2626         float mapvote_voters_real;
2627         string result;
2628
2629         if(mapvote_count_real == 1)
2630                 return MapVote_Finished(0);
2631
2632         mapvote_voters_real = mapvote_voters;
2633         if(mapvote_abstain)
2634                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2635
2636         RandomSelection_Init();
2637         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2638                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2639         firstPlace = RandomSelection_chosen_float;
2640         firstPlaceVotes = RandomSelection_best_priority;
2641         //dprint("First place: ", ftos(firstPlace), "\n");
2642         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2643
2644         RandomSelection_Init();
2645         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2646                 if(i != firstPlace)
2647                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2648         secondPlace = RandomSelection_chosen_float;
2649         secondPlaceVotes = RandomSelection_best_priority;
2650         //dprint("Second place: ", ftos(secondPlace), "\n");
2651         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2652
2653         if(firstPlace == -1)
2654                 error("No first place in map vote... WTF?");
2655
2656         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2657                 return MapVote_Finished(firstPlace);
2658
2659         if(mapvote_keeptwotime)
2660                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2661                 {
2662                         float didntvote;
2663                         MapVote_TouchMask();
2664                         mapvote_message = "Now decide between the TOP TWO!";
2665                         mapvote_keeptwotime = 0;
2666                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2667                         result = strcat(result, ":", ftos(firstPlaceVotes));
2668                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2669                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2670                         didntvote = mapvote_voters;
2671                         for(i = 0; i < mapvote_count; ++i)
2672                                 if(mapvote_maps[i] != "")
2673                                 {
2674                                         didntvote -= mapvote_votes[i];
2675                                         if(i != firstPlace)
2676                                                 if(i != secondPlace)
2677                                                 {
2678                                                         result = strcat(result, ":", mapvote_maps[i]);
2679                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2680                                                         if(i < mapvote_count_real)
2681                                                         {
2682                                                                 strunzone(mapvote_maps[i]);
2683                                                                 mapvote_maps[i] = "";
2684                                                                 strunzone(mapvote_maps_pakfile[i]);
2685                                                                 mapvote_maps_pakfile[i] = "";
2686                                                         }
2687                                                 }
2688                                 }
2689                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2690                         if(autocvar_sv_eventlog)
2691                                 GameLogEcho(result);
2692                 }
2693
2694         return FALSE;
2695 }
2696 void MapVote_Tick()
2697 {
2698         float keeptwo;
2699         float totalvotes;
2700
2701         keeptwo = mapvote_keeptwotime;
2702         MapVote_CheckRules_1(); // count
2703         if(MapVote_CheckRules_2()) // decide
2704                 return;
2705
2706         totalvotes = 0;
2707         FOR_EACH_REALCLIENT(other)
2708         {
2709                 // hide scoreboard again
2710                 if(other.health != 2342)
2711                 {
2712                         other.health = 2342;
2713                         other.impulse = 0;
2714                         if(clienttype(other) == CLIENTTYPE_REAL)
2715                         {
2716                                 msg_entity = other;
2717                                 WriteByte(MSG_ONE, SVC_FINALE);
2718                                 WriteString(MSG_ONE, "");
2719                         }
2720                 }
2721
2722                 // clear possibly invalid votes
2723                 if(mapvote_maps[other.mapvote - 1] == "")
2724                         other.mapvote = 0;
2725                 // use impulses as new vote
2726                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2727                         if(mapvote_maps[other.impulse - 1] != "")
2728                         {
2729                                 other.mapvote = other.impulse;
2730                                 MapVote_TouchVotes(other);
2731                         }
2732                 other.impulse = 0;
2733
2734                 if(other.mapvote)
2735                         ++totalvotes;
2736         }
2737
2738         MapVote_CheckRules_1(); // just count
2739 }
2740 void MapVote_Start()
2741 {
2742         if(mapvote_run)
2743                 return;
2744
2745         // wait for stats to be sent first
2746         if(!playerstats_waitforme)
2747                 return;
2748
2749         MapInfo_Enumerate();
2750         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2751                 mapvote_run = TRUE;
2752 }
2753 void MapVote_Think()
2754 {
2755         if(!mapvote_run)
2756                 return;
2757
2758         if(alreadychangedlevel)
2759                 return;
2760
2761         if(time < mapvote_nextthink)
2762                 return;
2763         //dprint("tick\n");
2764
2765         mapvote_nextthink = time + 0.5;
2766
2767         if(!mapvote_initialized)
2768         {
2769                 if(autocvar_rescan_pending == 1)
2770                 {
2771                         cvar_set("rescan_pending", "2");
2772                         localcmd("fs_rescan\nrescan_pending 3\n");
2773                         return;
2774                 }
2775                 else if(autocvar_rescan_pending == 2)
2776                 {
2777                         return;
2778                 }
2779                 else if(autocvar_rescan_pending == 3)
2780                 {
2781                         // now build missing mapinfo files
2782                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2783                                 return;
2784
2785                         // we're done, start the timer
2786                         cvar_set("rescan_pending", "0");
2787                 }
2788
2789                 mapvote_initialized = TRUE;
2790                 if(DoNextMapOverride())
2791                         return;
2792                 if(!autocvar_g_maplist_votable || player_count <= 0)
2793                 {
2794                         GotoNextMap();
2795                         return;
2796                 }
2797                 MapVote_Init();
2798         }
2799
2800         MapVote_Tick();
2801 };
2802
2803 string GotoMap(string m)
2804 {
2805         if(!MapInfo_CheckMap(m))
2806                 return "The map you chose is not available on this server.";
2807         cvar_set("nextmap", m);
2808         cvar_set("timelimit", "-1");
2809         if(mapvote_initialized || alreadychangedlevel)
2810         {
2811                 if(DoNextMapOverride())
2812                         return "Map switch initiated.";
2813                 else
2814                         return "Hm... no. For some reason I like THIS map more.";
2815         }
2816         else
2817                 return "Map switch will happen after scoreboard.";
2818 }
2819
2820
2821 void EndFrame()
2822 {
2823         float altime;
2824         FOR_EACH_REALCLIENT(self)
2825         {
2826                 if(self.classname == "spectator")
2827                 {
2828                         if(self.enemy.typehitsound)
2829                                 self.typehit_time = time;
2830                         else if(self.enemy.hitsound)
2831                                 self.hit_time = time;
2832                 }
2833                 else
2834                 {
2835                         if(self.typehitsound)
2836                                 self.typehit_time = time;
2837                         else if(self.hitsound)
2838                                 self.hit_time = time;
2839                 }
2840         }
2841         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2842         // add 1 frametime because after this, engine SV_Physics
2843         // increases time by a frametime and then networks the frame
2844         // add another frametime because client shows everything with
2845         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2846         // needed!
2847         FOR_EACH_CLIENT(self)
2848         {
2849                 self.hitsound = FALSE;
2850                 self.typehitsound = FALSE;
2851                 antilag_record(self, altime);
2852         }
2853 }
2854
2855
2856 /*
2857  * RedirectionThink:
2858  * returns TRUE if redirecting
2859  */
2860 float redirection_timeout;
2861 float redirection_nextthink;
2862 float RedirectionThink()
2863 {
2864         float clients_found;
2865
2866         if(redirection_target == "")
2867                 return FALSE;
2868
2869         if(!redirection_timeout)
2870         {
2871                 cvar_set("sv_public", "-2");
2872                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2873                 if(redirection_target == "self")
2874                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2875                 else
2876                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2877         }
2878
2879         if(time < redirection_nextthink)
2880                 return TRUE;
2881
2882         redirection_nextthink = time + 1;
2883
2884         clients_found = 0;
2885         FOR_EACH_REALCLIENT(self)
2886         {
2887                 print("Redirecting: sending connect command to ", self.netname, "\n");
2888                 if(redirection_target == "self")
2889                         stuffcmd(self, "\ndisconnect; reconnect\n");
2890                 else
2891                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2892                 ++clients_found;
2893         }
2894
2895         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2896
2897         if(time > redirection_timeout || clients_found == 0)
2898                 localcmd("\nwait; wait; wait; quit\n");
2899
2900         return TRUE;
2901 }
2902
2903 void TargetMusic_RestoreGame();
2904 void RestoreGame()
2905 {
2906         // Loaded from a save game
2907         // some things then break, so let's work around them...
2908
2909         // Progs DB (capture records)
2910         ServerProgsDB = db_load("server.db");
2911
2912         // Mapinfo
2913         MapInfo_Shutdown();
2914         MapInfo_Enumerate();
2915         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2916         WeaponStats_Init();
2917
2918         TargetMusic_RestoreGame();
2919 }
2920
2921 void SV_Shutdown()
2922 {
2923         entity e;
2924
2925         if(gameover > 1) // shutting down already?
2926                 return;
2927
2928         gameover = 2; // 2 = server shutting down
2929
2930         if(world_initialized > 0)
2931         {
2932                 world_initialized = 0;
2933                 print("Saving persistent data...\n");
2934                 Ban_SaveBans();
2935
2936                 PlayerStats_EndMatch(0);
2937                 FOR_EACH_CLIENT(e)
2938                         PlayerStats_AddGlobalInfo(e);
2939                 PlayerStats_Shutdown();
2940
2941                 if(!cheatcount_total)
2942                 {
2943                         if(autocvar_sv_db_saveasdump)
2944                                 db_dump(ServerProgsDB, "server.db");
2945                         else
2946                                 db_save(ServerProgsDB, "server.db");
2947                 }
2948                 if(autocvar_developer)
2949                 {
2950                         if(autocvar_sv_db_saveasdump)
2951                                 db_dump(TemporaryDB, "server-temp.db");
2952                         else
2953                                 db_save(TemporaryDB, "server-temp.db");
2954                 }
2955                 CheatShutdown(); // must be after cheatcount check
2956                 db_close(ServerProgsDB);
2957                 db_close(TemporaryDB);
2958                 print("done!\n");
2959                 // tell the bot system the game is ending now
2960                 bot_endgame();
2961
2962                 WeaponStats_Shutdown();
2963                 MapInfo_Shutdown();
2964         }
2965         else if(world_initialized == 0)
2966         {
2967                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2968         }
2969 }