qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local entity plr;
 105         // NOTE: the below Send_CSQC_Centerprint_Generic send msgs with countdown_num
 106         // parameter set as 0, even if the msgs are part of a countdown
 107         if (timeoutStatus == 1) {
 108                 if (remainingLeadTime > 0) {
 109                         //centerprint the information to every player
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         FOR_EACH_REALCLIENT(plr) {
 137                                 if(plr.classname == "player") {
 138                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 139                                 }
 140                         }
 141                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 142                                 Announce("prepareforbattle");
 143                         }
 144                         remainingTimeoutTime -= 1;
 145                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 146                 }
 147                 else {
 148                         //unpause the game again
 149                         remainingTimeoutTime = timeoutStatus = 0;
 150                         cvar_set("slowmo", ftos(orig_slowmo));
 151                         //and unlock the fixed view again once there is no timeout active anymore
 152                         FOR_EACH_REALPLAYER(plr) {
 153                                 plr.fixangle = FALSE;
 154                         }
 155                         //get rid of the countdown message
 156                         FOR_EACH_REALCLIENT(plr) {
 157                                 if(plr.classname == "player") {
 158                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 159                                 }
 160                         }
 161                         remove(self);
 162                         return;
 163                 }
 164
 165         }
 166         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 167                 FOR_EACH_REALCLIENT(plr) {
 168                         if(plr.classname == "player") {
 169                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 170                         }
 171                 }
 172                 remove(self);
 173                 return;
 174         }
 175 }
 176
 177 void GotoFirstMap()
 178 {
 179         float n;
 180         if(autocvar__sv_init)
 181         {
 182                 // cvar_set("_sv_init", "0");
 183                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 184                 // to this "init" map on a dedicated server will cause no permanent
 185                 // harm
 186                 if(autocvar_g_maplist_shuffle)
 187                         ShuffleMaplist();
 188                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 189                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 190
 191                 MapInfo_Enumerate();
 192                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 193
 194                 if(!DoNextMapOverride())
 195                         GotoNextMap();
 196
 197                 return;
 198         }
 199
 200         if(time < 5)
 201         {
 202                 self.nextthink = time;
 203         }
 204         else
 205         {
 206                 self.nextthink = time + 1;
 207                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 208         }
 209 }
 210
 211 void cvar_changes_init()
 212 {
 213         float h;
 214         string k, v, d;
 215         float n, i, adding, pureadding;
 216
 217         if(cvar_changes)
 218                 strunzone(cvar_changes);
 219         cvar_changes = string_null;
 220         if(cvar_purechanges)
 221                 strunzone(cvar_purechanges);
 222         cvar_purechanges = string_null;
 223         cvar_purechanges_count = 0;
 224
 225         h = buf_create();
 226         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 227         n = buf_getsize(h);
 228
 229         adding = TRUE;
 230         pureadding = TRUE;
 231
 232         for(i = 0; i < n; ++i)
 233         {
 234                 k = bufstr_get(h, i);
 235
 236 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 237 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 238 #define BADCVAR(p) if(k == p) continue
 239
 240                 // general excludes and namespaces for server admin used cvars
 241                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 242
 243                 // internal
 244                 BADPREFIX("csqc_");
 245                 BADPREFIX("cvar_check_");
 246                 BADCVAR("gamecfg");
 247                 BADCVAR("g_configversion");
 248                 BADCVAR("g_maplist_index");
 249                 BADCVAR("halflifebsp");
 250                 BADPREFIX("sv_world");
 251
 252                 // client
 253                 BADPREFIX("chase_");
 254                 BADPREFIX("cl_");
 255                 BADPREFIX("con_");
 256                 BADPREFIX("scoreboard_");
 257                 BADPREFIX("g_campaign");
 258                 BADPREFIX("gl_");
 259                 BADPREFIX("joy");
 260                 BADPREFIX("hud_");
 261                 BADPREFIX("m_");
 262                 BADPREFIX("menu_");
 263                 BADPREFIX("net_slist_");
 264                 BADPREFIX("r_");
 265                 BADPREFIX("sbar_");
 266                 BADPREFIX("scr_");
 267                 BADPREFIX("snd_");
 268                 BADPREFIX("show");
 269                 BADPREFIX("sensitivity");
 270                 BADPREFIX("userbind");
 271                 BADPREFIX("v_");
 272                 BADPREFIX("vid_");
 273                 BADPREFIX("crosshair");
 274                 BADCVAR("mod_q3bsp_lightmapmergepower");
 275                 BADCVAR("mod_q3bsp_nolightmaps");
 276                 BADCVAR("fov");
 277                 BADCVAR("mastervolume");
 278                 BADCVAR("volume");
 279                 BADCVAR("bgmvolume");
 280
 281                 // private
 282                 BADCVAR("developer");
 283                 BADCVAR("g_banned_list");
 284                 BADCVAR("log_dest_udp");
 285                 BADCVAR("log_file");
 286                 BADCVAR("net_address");
 287                 BADCVAR("net_address_ipv6");
 288                 BADCVAR("port");
 289                 BADCVAR("savedgamecfg");
 290                 BADCVAR("serverconfig");
 291                 BADCVAR("sv_heartbeatperiod");
 292                 BADCVAR("sv_vote_master_password");
 293                 BADCVAR("sys_colortranslation");
 294                 BADCVAR("sys_specialcharactertranslation");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_chat_flood_");
 299                 BADPREFIX("g_voice_flood_");
 300                 BADPREFIX("rcon_");
 301                 BADPREFIX("settemp_");
 302                 BADPREFIX("sv_allowdownloads_");
 303                 BADPREFIX("sv_autodemo");
 304                 BADPREFIX("sv_curl_");
 305                 BADPREFIX("sv_eventlog");
 306                 BADPREFIX("sv_logscores_");
 307                 BADPREFIX("sv_master");
 308                 BADPREFIX("sv_weaponstats_");
 309
 310                 // these can contain player IDs, so better hide
 311                 BADCVAR("g_forced_team_red");
 312                 BADCVAR("g_forced_team_blue");
 313                 BADCVAR("g_forced_team_yellow");
 314                 BADCVAR("g_forced_team_pink");
 315
 316                 // mapinfo
 317                 BADCVAR("fraglimit");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_assault");
 320                 BADCVAR("g_ca");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_cts");
 323                 BADCVAR("g_dm");
 324                 BADCVAR("g_domination");
 325                 BADCVAR("g_domination_default_teams");
 326                 BADCVAR("g_freezetag");
 327                 BADCVAR("g_keepaway");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_lms");
 332                 BADCVAR("g_nexball");
 333                 BADCVAR("g_onslaught");
 334                 BADCVAR("g_race");
 335                 BADCVAR("g_race_qualifying_timelimit");
 336                 BADCVAR("g_runematch");
 337                 BADCVAR("g_tdm");
 338                 BADCVAR("g_tdm_teams");
 339                 BADCVAR("leadlimit");
 340                 BADCVAR("nextmap");
 341                 BADCVAR("teamplay");
 342                 BADCVAR("timelimit");
 343
 344                 // long
 345                 BADCVAR("hostname");
 346                 BADCVAR("g_maplist");
 347                 BADCVAR("g_maplist_mostrecent");
 348                 BADCVAR("sv_motd");
 349
 350                 v = cvar_string(k);
 351                 d = cvar_defstring(k);
 352                 if(v == d)
 353                         continue;
 354
 355                 if(adding)
 356                 {
 357                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 358                         if(strlen(cvar_changes) > 16384)
 359                         {
 360                                 cvar_changes = "// too many settings have been changed to show them here\n";
 361                                 adding = 0;
 362                         }
 363                 }
 364
 365                 // now check if the changes are actually gameplay relevant
 366
 367                 // does nothing visible
 368                 BADCVAR("captureleadlimit_override");
 369                 BADCVAR("g_arena_point_leadlimit");
 370                 BADCVAR("g_balance_kill_delay");
 371                 BADCVAR("g_ca_point_leadlimit");
 372                 BADCVAR("g_ctf_captimerecord_always");
 373                 BADCVAR("g_ctf_capture_leadlimit");
 374                 BADCVAR("g_ctf_flag_capture_effects");
 375                 BADCVAR("g_ctf_flag_glowtrails");
 376                 BADCVAR("g_ctf_flag_pickup_effects");
 377                 BADCVAR("g_domination_point_leadlimit");
 378                 BADCVAR("g_forced_respawn");
 379                 BADCVAR("g_keyhunt_point_leadlimit");
 380                 BADCVAR("g_nexball_goalleadlimit");
 381                 BADCVAR("g_runematch_point_leadlimit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_checkforpacketsduringsleep");
 386                 BADCVAR("sv_timeout");
 387                 BADCVAR("welcome_message_time");
 388                 BADPREFIX("crypto_");
 389                 BADPREFIX("g_chat_");
 390                 BADPREFIX("g_ctf_captimerecord_");
 391                 BADPREFIX("g_maplist_votable_");
 392                 BADPREFIX("net_");
 393                 BADPREFIX("prvm_");
 394                 BADPREFIX("skill_");
 395                 BADPREFIX("sv_fragmessage_");
 396                 BADPREFIX("sv_maxidle_");
 397                 BADPREFIX("sv_vote_");
 398                 BADPREFIX("timelimit_");
 399
 400                 // allowed changes to server admins (please sync this to server.cfg)
 401                 // vi commands:
 402                 //   :/"impure"/,$d
 403                 //   :g!,^\/\/[^ /],d
 404                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 405                 //   :%!sort
 406                 // yes, this does contain some redundant stuff, don't really care
 407                 BADCVAR("bot_number");
 408                 BADCVAR("bot_prefix");
 409                 BADCVAR("bot_suffix");
 410                 BADCVAR("capturelimit_override");
 411                 BADCVAR("fraglimit_override");
 412                 BADCVAR("gametype");
 413                 BADCVAR("g_antilag");
 414                 BADCVAR("g_balance_teams");
 415                 BADCVAR("g_balance_teams_force");
 416                 BADCVAR("g_ban_sync_trusted_servers");
 417                 BADCVAR("g_ban_sync_uri");
 418                 BADCVAR("g_ctf_capture_limit");
 419                 BADCVAR("g_ctf_ignore_frags");
 420                 BADCVAR("g_ctf_win_mode");
 421                 BADCVAR("g_domination_point_limit");
 422                 BADCVAR("g_fullbrightitems");
 423                 BADCVAR("g_fullbrightplayers");
 424                 BADCVAR("g_keyhunt_point_limit");
 425                 BADCVAR("g_keyhunt_teams_override");
 426                 BADCVAR("g_lms_lives_override");
 427                 BADCVAR("g_maplist");
 428                 BADCVAR("g_maplist_check_waypoints");
 429                 BADCVAR("g_maplist_mostrecent_count");
 430                 BADCVAR("g_maplist_shuffle");
 431                 BADCVAR("g_maplist_votable");
 432                 BADCVAR("g_maplist_votable_abstain");
 433                 BADCVAR("g_maplist_votable_nodetail");
 434                 BADCVAR("g_maplist_votable_suggestions");
 435                 BADCVAR("g_minstagib");
 436                 BADCVAR("g_nexball_goallimit");
 437                 BADCVAR("g_runematch_point_limit");
 438                 BADCVAR("g_start_delay");
 439                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 440                 BADCVAR("hostname");
 441                 BADCVAR("log_file");
 442                 BADCVAR("maxplayers");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("minplayers");
 445                 BADCVAR("net_address");
 446                 BADCVAR("port");
 447                 BADCVAR("rcon_password");
 448                 BADCVAR("rcon_restricted_commands");
 449                 BADCVAR("rcon_restricted_password");
 450                 BADCVAR("skill");
 451                 BADCVAR("sv_adminnick");
 452                 BADCVAR("sv_autoscreenshot");
 453                 BADCVAR("sv_curl_defaulturl");
 454                 BADCVAR("sv_defaultcharacter");
 455                 BADCVAR("sv_defaultplayercolors");
 456                 BADCVAR("sv_defaultplayermodel");
 457                 BADCVAR("sv_defaultplayerskin");
 458                 BADCVAR("sv_maxidle");
 459                 BADCVAR("sv_maxrate");
 460                 BADCVAR("sv_motd");
 461                 BADCVAR("sv_public");
 462                 BADCVAR("sv_ready_restart");
 463                 BADCVAR("sv_status_privacy");
 464                 BADCVAR("sv_vote_call");
 465                 BADCVAR("sv_vote_commands");
 466                 BADCVAR("sv_vote_majority_factor");
 467                 BADCVAR("sv_vote_master");
 468                 BADCVAR("sv_vote_master_commands");
 469                 BADCVAR("sv_vote_master_password");
 470                 BADCVAR("sv_vote_simple_majority_factor");
 471                 BADCVAR("timelimit_override");
 472                 BADCVAR("g_warmup");
 473                 BADPREFIX("g_warmup_");
 474                 BADCVAR("teamplay_mode");
 475
 476                 if(autocvar_g_minstagib)
 477                 {
 478                         BADCVAR("g_grappling_hook");
 479                         BADCVAR("g_jetpack");
 480                 }
 481 #undef BADPREFIX
 482 #undef BADCVAR
 483
 484                 if(pureadding)
 485                 {
 486                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 487                         if(strlen(cvar_purechanges) > 16384)
 488                         {
 489                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 490                                 pureadding = 0;
 491                         }
 492                 }
 493                 ++cvar_purechanges_count;
 494                 // WARNING: this variable is used for the server list
 495                 // NEVER dare to skip this code!
 496                 // Hacks to intentionally appearing as "pure server" even though you DO have
 497                 // modified settings may be punished by removal from the server list.
 498                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 499                 // though.
 500         }
 501         buf_del(h);
 502         if(cvar_changes == "")
 503                 cvar_changes = "// this server runs at default server settings\n";
 504         else
 505                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 506         cvar_changes = strzone(cvar_changes);
 507         if(cvar_purechanges == "")
 508                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 509         else
 510                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 511         cvar_purechanges = strzone(cvar_purechanges);
 512 }
 513
 514 void detect_maptype()
 515 {
 516 #if 0
 517         vector o, v;
 518         float i;
 519
 520         for(;;)
 521         {
 522                 o = world.mins;
 523                 o_x += random() * (world.maxs_x - world.mins_x);
 524                 o_y += random() * (world.maxs_y - world.mins_y);
 525                 o_z += random() * (world.maxs_z - world.mins_z);
 526
 527                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 528                 if(trace_fraction == 1)
 529                         continue;
 530
 531                 v = trace_endpos;
 532
 533                 for(i = 0; i < 64; i += 4)
 534                 {
 535                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 536         if(trace_fraction == 1)
 537                 continue;
 538                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 539                 }
 540
 541                 break;
 542         }
 543 #endif
 544 }
 545
 546 entity randomseed;
 547 float RandomSeed_Send(entity to, float sf)
 548 {
 549         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 550         WriteShort(MSG_ENTITY, self.cnt);
 551         return TRUE;
 552 }
 553 void RandomSeed_Think()
 554 {
 555         self.cnt = bound(0, floor(random() * 65536), 65535);
 556         self.nextthink = time + 5;
 557
 558         self.SendFlags |= 1;
 559 }
 560 void RandomSeed_Spawn()
 561 {
 562         randomseed = spawn();
 563         randomseed.think = RandomSeed_Think;
 564         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 565
 566         entity oldself;
 567         oldself = self;
 568         self = randomseed;
 569         self.think(); // sets random seed and nextthink
 570         self = oldself;
 571 }
 572
 573 void spawnfunc___init_dedicated_server(void)
 574 {
 575         // handler for _init/_init map (only for dedicated server initialization)
 576
 577         world_initialized = -1; // don't complain
 578         cvar = cvar_normal;
 579         cvar_string = cvar_string_normal;
 580         cvar_set = cvar_set_normal;
 581
 582         remove = remove_unsafely;
 583
 584         entity e;
 585         e = spawn();
 586         e.think = GotoFirstMap;
 587         e.nextthink = time; // this is usually 1 at this point
 588
 589         e = spawn();
 590         e.classname = "info_player_deathmatch"; // safeguard against player joining
 591
 592         self.classname = "worldspawn"; // safeguard against various stuff ;)
 593
 594         MapInfo_Enumerate();
 595         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 596 }
 597
 598 void Map_MarkAsRecent(string m);
 599 float world_already_spawned;
 600 void RegisterWeapons();
 601 void Nagger_Init();
 602 void ClientInit_Spawn();
 603 void WeaponStats_Init();
 604 void WeaponStats_Shutdown();
 605 void spawnfunc_worldspawn (void)
 606 {
 607         float fd, l, i, j, n;
 608         string s, col;
 609
 610         cvar = cvar_normal;
 611         cvar_string = cvar_string_normal;
 612         cvar_set = cvar_set_normal;
 613
 614         if(world_already_spawned)
 615                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 616         world_already_spawned = TRUE;
 617
 618         remove = remove_safely; // during spawning, watch what you remove!
 619
 620         check_unacceptable_compiler_bugs();
 621
 622         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 623
 624         compressShortVector_init();
 625
 626         allowed_to_spawn = TRUE;
 627
 628         local entity head;
 629         head = nextent(world);
 630         maxclients = 0;
 631         while(head)
 632         {
 633                 ++maxclients;
 634                 head = nextent(head);
 635         }
 636
 637         // needs to be done so early as they would still spawn
 638         RegisterWeapons();
 639
 640         ServerProgsDB = db_load("server.db");
 641
 642         TemporaryDB = db_create();
 643
 644         // 0 normal
 645         lightstyle(0, "m");
 646
 647         // 1 FLICKER (first variety)
 648         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 649
 650         // 2 SLOW STRONG PULSE
 651         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 652
 653         // 3 CANDLE (first variety)
 654         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 655
 656         // 4 FAST STROBE
 657         lightstyle(4, "mamamamamama");
 658
 659         // 5 GENTLE PULSE 1
 660         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 661
 662         // 6 FLICKER (second variety)
 663         lightstyle(6, "nmonqnmomnmomomno");
 664
 665         // 7 CANDLE (second variety)
 666         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 667
 668         // 8 CANDLE (third variety)
 669         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 670
 671         // 9 SLOW STROBE (fourth variety)
 672         lightstyle(9, "aaaaaaaazzzzzzzz");
 673
 674         // 10 FLUORESCENT FLICKER
 675         lightstyle(10, "mmamammmmammamamaaamammma");
 676
 677         // 11 SLOW PULSE NOT FADE TO BLACK
 678         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 679
 680         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 681
 682         // 63 testing
 683         lightstyle(63, "a");
 684
 685         if(autocvar_g_campaign)
 686                 CampaignPreInit();
 687
 688         Map_MarkAsRecent(mapname);
 689
 690         precache_model ("null"); // we need this one before InitGameplayMode
 691         InitGameplayMode();
 692         readlevelcvars();
 693         GrappleHookInit();
 694         ElectroInit();
 695         LaserInit();
 696
 697         player_count = 0;
 698         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 699         if(bot_waypoints_for_items == 1)
 700                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 701                         bot_waypoints_for_items = 0;
 702
 703         // for setting by mapinfo
 704         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 705         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 706
 707         precache();
 708
 709         WaypointSprite_Init();
 710
 711         //if (g_domination)
 712         //      dom_init();
 713
 714         GameLogInit(); // prepare everything
 715         if(autocvar_sv_eventlog)
 716         {
 717                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 718                 s = strcat(s, ftos(random()));
 719                 matchid = strzone(s);
 720
 721                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 722                 s = ":gameinfo:mutators:LIST";
 723
 724                 ret_string = s;
 725                 MUTATOR_CALLHOOK(BuildMutatorsString);
 726                 s = ret_string;
 727
 728                 // simple, probably not good in the mutator system
 729                 if(autocvar_g_grappling_hook)
 730                         s = strcat(s, ":grappling_hook");
 731
 732                 // initialiation stuff, not good in the mutator system
 733                 if(!autocvar_g_use_ammunition)
 734                         s = strcat(s, ":no_use_ammunition");
 735
 736                 // initialiation stuff, not good in the mutator system
 737                 if(!autocvar_g_pickup_items)
 738                         s = strcat(s, ":no_pickup_items");
 739
 740                 // initialiation stuff, not good in the mutator system
 741                 if(autocvar_g_weaponarena != "0")
 742                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 743
 744                 // TODO to mutator system
 745                 if(autocvar_g_norecoil)
 746                         s = strcat(s, ":norecoil");
 747
 748                 // TODO to mutator system
 749                 if(autocvar_g_midair)
 750                         s = strcat(s, ":midair");
 751
 752                 // TODO to mutator system
 753                 if(autocvar_g_minstagib)
 754                         s = strcat(s, ":minstagib");
 755
 756                 GameLogEcho(s);
 757                 GameLogEcho(":gameinfo:end");
 758         }
 759         else
 760                 matchid = strzone(ftos(random()));
 761
 762         cvar_set("nextmap", "");
 763
 764         SetDefaultAlpha();
 765
 766         if(autocvar_g_campaign)
 767                 CampaignPostInit();
 768
 769         fteqcc_testbugs();
 770
 771         Ban_LoadBans();
 772
 773         MapInfo_Enumerate();
 774         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 775
 776         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 777         {
 778                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 779                 if(fd != -1)
 780                 {
 781                         while((s = fgets(fd)))
 782                         {
 783                                 l = tokenize_console(s);
 784                                 if(l < 2)
 785                                         continue;
 786                                 if(argv(0) == "cd")
 787                                 {
 788                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 789                                         print("  cdtrack ", argv(2), "\n");
 790                                 }
 791                                 else if(argv(0) == "fog")
 792                                 {
 793                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 794                                         print("  \"fog\" \"", s, "\"\n");
 795                                 }
 796                                 else if(argv(0) == "set")
 797                                 {
 798                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 799                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 800                                 }
 801                                 else if(argv(0) != "//")
 802                                 {
 803                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 804                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 805                                 }
 806                         }
 807                         fclose(fd);
 808                 }
 809         }
 810
 811         WeaponStats_Init();
 812
 813         addstat(STAT_WEAPONS, AS_INT, weapons);
 814         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 815         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 816         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 817         Nagger_Init();
 818
 819         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 820         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 821         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 822         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 823         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 824         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 825         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 826         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 827         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 828         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 829         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 830         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 831
 832         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 833         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 834
 835         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 836
 837         if(g_ca || g_freezetag)
 838         {
 839                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 840                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 841                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 842                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 843         }
 844         if(g_freezetag)
 845         {
 846                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 847                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 848         }
 849
 850         // g_movementspeed hack
 851         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 852         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 853         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 854         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 855
 856         next_pingtime = time + 5;
 857
 858         detect_maptype();
 859
 860         lsmaps_reply = "^7Maps available: ";
 861         lsnewmaps_reply = "^7Maps without a record set: ";
 862         for(i = 0, j = 0; i < MapInfo_count; ++i)
 863         {
 864                 if(MapInfo_Get_ByID(i))
 865                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 866                         {
 867                                 if(mod(i, 2))
 868                                         col = "^2";
 869                                 else
 870                                         col = "^3";
 871                                 ++j;
 872                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 873                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 874                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 875                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 876                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 877                         }
 878         }
 879         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 880         if (!g_race && !g_cts)
 881                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 882         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 883
 884         maplist_reply = "^7Maps in list: ";
 885         n = tokenize_console(autocvar_g_maplist);
 886         for(i = 0, j = 0; i < n; ++i)
 887         {
 888                 if(MapInfo_CheckMap(argv(i)))
 889                 {
 890                         if(mod(j, 2))
 891                                 col = "^2";
 892                         else
 893                                 col = "^3";
 894                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 895                         ++j;
 896                 }
 897         }
 898         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 899         MapInfo_ClearTemps();
 900
 901         for(i = 0; i < 10; ++i)
 902         {
 903                 records_reply[i] = strzone(getrecords(i));
 904         }
 905         if(g_cts)
 906                 ladder_reply = strzone(getladder());
 907
 908         rankings_reply = strzone(getrankings());
 909
 910         ClientInit_Spawn();
 911         RandomSeed_Spawn();
 912         PingPLReport_Spawn();
 913
 914         CheatInit();
 915
 916         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 917
 918         // fill sv_curl_serverpackages from .serverpackage files
 919         if(autocvar_sv_curl_serverpackages_auto)
 920         {
 921                 s = "";
 922                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 923                 for(i = 0; i < n; ++i)
 924                         if(substring(argv(i), -14, -1) != ".serverpackage")
 925                                 s = strcat(s, " ", argv(i));
 926                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 927                 if(fd >= 0)
 928                 {
 929                         j = search_getsize(fd);
 930                         for(i = 0; i < j; ++i)
 931                                 s = strcat(s, " ", search_getfilename(fd, i));
 932                         search_end(fd);
 933                 }
 934                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 935         }
 936
 937         PlayerStats_Init();
 938
 939         world_initialized = 1;
 940 }
 941
 942 void spawnfunc_light (void)
 943 {
 944         //makestatic (self); // Who the f___ did that?
 945         remove(self);
 946 }
 947
 948 string GetGametype()
 949 {
 950         return GametypeNameFromType(game);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         dprint(": no waypoints\n");
 994                         return FALSE;
 995                 }
 996                 dprint(": has waypoints\n");
 997         }
 998
 999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return FALSE;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return FALSE;
1018                 }
1019                 dprint("right size\n");
1020                 return TRUE;
1021         }
1022         dprint(": not found\n");
1023         return TRUE;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void GameResetCfg()
1099 {
1100         // settings persist, except...
1101         localcmd("\nsettemp_restore\n");
1102 };
1103
1104 void Map_Goto()
1105 {
1106         GameResetCfg();
1107         MapInfo_LoadMap(getmapname_stored);
1108 }
1109
1110 // return codes of map selectors:
1111 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1112 //   -2 = permanent failure
1113 float() MaplistMethod_Iterate = // usual method
1114 {
1115         float pass, i;
1116
1117         for(pass = 1; pass <= 2; ++pass)
1118         {
1119                 for(i = 1; i < Map_Count; ++i)
1120                 {
1121                         float mapindex;
1122                         mapindex = mod(i + Map_Current, Map_Count);
1123                         if(Map_Check(mapindex, pass))
1124                                 return mapindex;
1125                 }
1126         }
1127         return -1;
1128 }
1129
1130 float() MaplistMethod_Repeat = // fallback method
1131 {
1132         if(Map_Check(Map_Current, 2))
1133                 return Map_Current;
1134         return -2;
1135 }
1136
1137 float() MaplistMethod_Random = // random map selection
1138 {
1139         float i, imax;
1140
1141         imax = 42;
1142
1143         for(i = 0; i <= imax; ++i)
1144         {
1145                 float mapindex;
1146                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1147                 if(Map_Check(mapindex, 1))
1148                         return mapindex;
1149         }
1150         return -1;
1151 }
1152
1153 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1154 // the exponent sets a bias on the map selection:
1155 // the higher the exponent, the less likely "shortly repeated" same maps are
1156 {
1157         float i, j, imax, insertpos;
1158
1159         imax = 42;
1160
1161         for(i = 0; i <= imax; ++i)
1162         {
1163                 string newlist;
1164
1165                 // now reinsert this at another position
1166                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1167                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1168                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1169                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1170
1171                 // insert the current map there
1172                 newlist = "";
1173                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1174                         newlist = strcat(newlist, " ", argv(j));
1175                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1176                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1177                         newlist = strcat(newlist, " ", argv(j));
1178                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1179                 cvar_set("g_maplist", newlist);
1180                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1181
1182                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1183                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1184                 if(Map_Check(Map_Current, 1))
1185                         return Map_Current;
1186         }
1187         return -1;
1188 }
1189
1190 void Maplist_Init()
1191 {
1192         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193         if(Map_Count == 0)
1194         {
1195                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1196                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1197                 if(autocvar_g_maplist_shuffle)
1198                         ShuffleMaplist();
1199                 localcmd("\nmenu_cmd sync\n");
1200                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         }
1202         if(Map_Count == 0)
1203                 error("empty maplist, cannot select a new map");
1204         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1205
1206         if(Map_Current_Name)
1207                 strunzone(Map_Current_Name);
1208         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1209         // this may or may not be correct, but who cares, in the worst case a map
1210         // isn't chosen in the first pass that should have been
1211 }
1212
1213 string GetNextMap()
1214 {
1215         float nextMap;
1216
1217         Maplist_Init();
1218         nextMap = -1;
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_shuffle > 0)
1222                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_selectrandom)
1226                         nextMap = MaplistMethod_Random();
1227
1228         if(nextMap == -1)
1229                 nextMap = MaplistMethod_Iterate();
1230
1231         if(nextMap == -1)
1232                 nextMap = MaplistMethod_Repeat();
1233
1234         if(nextMap >= 0)
1235         {
1236                 Map_Goto_SetFloat(nextMap);
1237                 return getmapname_stored;
1238         }
1239
1240         return "";
1241 };
1242
1243 float DoNextMapOverride()
1244 {
1245         if(autocvar_g_campaign)
1246         {
1247                 CampaignPostIntermission();
1248                 alreadychangedlevel = TRUE;
1249                 return TRUE;
1250         }
1251         if(autocvar_quit_when_empty)
1252         {
1253                 if(player_count <= currentbots)
1254                 {
1255                         localcmd("quit\n");
1256                         alreadychangedlevel = TRUE;
1257                         return TRUE;
1258                 }
1259         }
1260         if(autocvar_quit_and_redirect != "")
1261         {
1262                 redirection_target = strzone(autocvar_quit_and_redirect);
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if (autocvar_samelevel) // if samelevel is set, stay on same level
1267         {
1268                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1269                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1270                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1271                 localcmd("restart\n");
1272                 //changelevel (mapname);
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         if(autocvar_nextmap != "")
1277                 if(MapInfo_CheckMap(autocvar_nextmap))
1278                 {
1279                         Map_Goto_SetStr(autocvar_nextmap);
1280                         Map_Goto();
1281                         alreadychangedlevel = TRUE;
1282                         return TRUE;
1283                 }
1284         if(autocvar_lastlevel)
1285         {
1286                 GameResetCfg();
1287                 localcmd("set lastlevel 0\ntogglemenu\n");
1288                 alreadychangedlevel = TRUE;
1289                 return TRUE;
1290         }
1291         return FALSE;
1292 };
1293
1294 void GotoNextMap()
1295 {
1296         //local string nextmap;
1297         //local float n, nummaps;
1298         //local string s;
1299         if (alreadychangedlevel)
1300                 return;
1301         alreadychangedlevel = TRUE;
1302
1303         {
1304                 string nextMap;
1305                 float allowReset;
1306
1307                 for(allowReset = 1; allowReset >= 0; --allowReset)
1308                 {
1309                         nextMap = GetNextMap();
1310                         if(nextMap != "")
1311                                 break;
1312
1313                         if(allowReset)
1314                         {
1315                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1316                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1317                                 if(autocvar_g_maplist_shuffle)
1318                                         ShuffleMaplist();
1319                                 localcmd("\nmenu_cmd sync\n");
1320                         }
1321                         else
1322                         {
1323                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1324                         }
1325                 }
1326                 Map_Goto();
1327         }
1328 };
1329
1330
1331 /*
1332 ============
1333 IntermissionThink
1334
1335 When the player presses attack or jump, change to the next level
1336 ============
1337 */
1338 .float autoscreenshot;
1339 void() MapVote_Start;
1340 void() MapVote_Think;
1341 float mapvote_initialized;
1342 void IntermissionThink()
1343 {
1344         FixIntermissionClient(self);
1345
1346         if(autocvar_sv_autoscreenshot)
1347         if(self.autoscreenshot > 0)
1348         if(time > self.autoscreenshot)
1349         {
1350                 self.autoscreenshot = -1;
1351                 if(clienttype(self) == CLIENTTYPE_REAL)
1352                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1353                 return;
1354         }
1355
1356         if (time < intermission_exittime)
1357                 return;
1358
1359         if(!mapvote_initialized)
1360                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1361                         return;
1362
1363         MapVote_Start();
1364 };
1365
1366 /*
1367 ============
1368 FindIntermission
1369
1370 Returns the entity to view from
1371 ============
1372 */
1373 /*
1374 entity FindIntermission()
1375 {
1376         local   entity spot;
1377         local   float cyc;
1378
1379 // look for info_intermission first
1380         spot = find (world, classname, "info_intermission");
1381         if (spot)
1382         {       // pick a random one
1383                 cyc = random() * 4;
1384                 while (cyc > 1)
1385                 {
1386                         spot = find (spot, classname, "info_intermission");
1387                         if (!spot)
1388                                 spot = find (spot, classname, "info_intermission");
1389                         cyc = cyc - 1;
1390                 }
1391                 return spot;
1392         }
1393
1394 // then look for the start position
1395         spot = find (world, classname, "info_player_start");
1396         if (spot)
1397                 return spot;
1398
1399 // testinfo_player_start is only found in regioned levels
1400         spot = find (world, classname, "testplayerstart");
1401         if (spot)
1402                 return spot;
1403
1404 // then look for the start position
1405         spot = find (world, classname, "info_player_deathmatch");
1406         if (spot)
1407                 return spot;
1408
1409         //objerror ("FindIntermission: no spot");
1410         return world;
1411 };
1412 */
1413
1414 /*
1415 ===============================================================================
1416
1417 RULES
1418
1419 ===============================================================================
1420 */
1421
1422 void DumpStats(float final)
1423 {
1424         float file;
1425         string s;
1426         float to_console;
1427         float to_eventlog;
1428         float to_file;
1429         float i;
1430
1431         to_console = autocvar_sv_logscores_console;
1432         to_eventlog = autocvar_sv_eventlog;
1433         to_file = autocvar_sv_logscores_file;
1434
1435         if(!final)
1436         {
1437                 to_console = TRUE; // always print printstats replies
1438                 to_eventlog = FALSE; // but never print them to the event log
1439         }
1440
1441         if(to_eventlog)
1442                 if(autocvar_sv_eventlog_console)
1443                         to_console = FALSE; // otherwise we get the output twice
1444
1445         if(final)
1446                 s = ":scores:";
1447         else
1448                 s = ":status:";
1449         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1450
1451         if(to_console)
1452                 print(s, "\n");
1453         if(to_eventlog)
1454                 GameLogEcho(s);
1455         if(to_file)
1456         {
1457                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1458                 if(file == -1)
1459                         to_file = FALSE;
1460                 else
1461                         fputs(file, strcat(s, "\n"));
1462         }
1463
1464         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1465         if(to_console)
1466                 print(s, "\n");
1467         if(to_eventlog)
1468                 GameLogEcho(s);
1469         if(to_file)
1470                 fputs(file, strcat(s, "\n"));
1471
1472         FOR_EACH_CLIENT(other)
1473         {
1474                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1475                 {
1476                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1477                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1478                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1479                                 s = strcat(s, ftos(other.team), ":");
1480                         else
1481                                 s = strcat(s, "spectator:");
1482
1483                         if(to_console)
1484                                 print(s, other.netname, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1487                         if(to_file)
1488                                 fputs(file, strcat(s, other.netname, "\n"));
1489                 }
1490         }
1491
1492         if(teamplay)
1493         {
1494                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1495                 if(to_console)
1496                         print(s, "\n");
1497                 if(to_eventlog)
1498                         GameLogEcho(s);
1499                 if(to_file)
1500                         fputs(file, strcat(s, "\n"));
1501
1502                 for(i = 1; i < 16; ++i)
1503                 {
1504                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1505                         s = strcat(s, ":", ftos(i));
1506                         if(to_console)
1507                                 print(s, "\n");
1508                         if(to_eventlog)
1509                                 GameLogEcho(s);
1510                         if(to_file)
1511                                 fputs(file, strcat(s, "\n"));
1512                 }
1513         }
1514
1515         if(to_console)
1516                 print(":end\n");
1517         if(to_eventlog)
1518                 GameLogEcho(":end");
1519         if(to_file)
1520         {
1521                 fputs(file, ":end\n");
1522                 fclose(file);
1523         }
1524 }
1525
1526 void FixIntermissionClient(entity e)
1527 {
1528         string s;
1529         if(!e.autoscreenshot) // initial call
1530         {
1531                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1532                 e.health = -2342;
1533                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1534                 e.solid = SOLID_NOT;
1535                 e.movetype = MOVETYPE_NONE;
1536                 e.takedamage = DAMAGE_NO;
1537                 if(e.weaponentity)
1538                 {
1539                         e.weaponentity.effects = EF_NODRAW;
1540                         if (e.weaponentity.weaponentity)
1541                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1542                 }
1543                 if(clienttype(e) == CLIENTTYPE_REAL)
1544                 {
1545                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1546                         s = autocvar_sv_intermission_cdtrack;
1547                         if(s != "")
1548                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1549                         msg_entity = e;
1550                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1551                 }
1552         }
1553 }
1554
1555
1556 /*
1557 go to the next level for deathmatch
1558 only called if a time or frag limit has expired
1559 */
1560 void NextLevel()
1561 {
1562         gameover = TRUE;
1563
1564         intermission_running = 1;
1565
1566 // enforce a wait time before allowing changelevel
1567         if(player_count > 0)
1568                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1569         else
1570                 intermission_exittime = -1;
1571
1572         /*
1573         WriteByte (MSG_ALL, SVC_CDTRACK);
1574         WriteByte (MSG_ALL, 3);
1575         WriteByte (MSG_ALL, 3);
1576         // done in FixIntermission
1577         */
1578
1579         //pos = FindIntermission ();
1580
1581         VoteReset();
1582
1583         DumpStats(TRUE);
1584
1585         // send statistics
1586         entity e;
1587         PlayerStats_EndMatch(1);
1588         FOR_EACH_CLIENT(e)
1589                 PlayerStats_AddGlobalInfo(e);
1590         PlayerStats_Shutdown();
1591
1592         if(autocvar_sv_eventlog)
1593                 GameLogEcho(":gameover");
1594
1595         GameLogClose();
1596
1597         FOR_EACH_PLAYER(other) {
1598                 FixIntermissionClient(other);
1599                 if(other.winning)
1600                         bprint(other.netname, " ^7wins.\n");
1601         }
1602
1603         if(autocvar_g_campaign)
1604                 CampaignPreIntermission();
1605
1606         localcmd("\nsv_hook_gameend\n");
1607 }
1608
1609 /*
1610 ============
1611 CheckRules_Player
1612
1613 Exit deathmatch games upon conditions
1614 ============
1615 */
1616 void CheckRules_Player()
1617 {
1618         if (gameover)   // someone else quit the game already
1619                 return;
1620
1621         if(self.deadflag == DEAD_NO)
1622                 self.play_time += frametime;
1623
1624         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1625         //   (div0: and that in CheckRules_World please)
1626 };
1627
1628 float checkrules_equality;
1629 float checkrules_suddendeathwarning;
1630 float checkrules_suddendeathend;
1631 float checkrules_overtimesadded; //how many overtimes have been already added
1632
1633 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1634 float WINNING_YES = 1; // winner found
1635 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1636 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1637
1638 float InitiateSuddenDeath()
1639 {
1640         // Check first whether normal overtimes could be added before initiating suddendeath mode
1641         // - for this timelimit_overtime needs to be >0 of course
1642         // - also check the winning condition calculated in the previous frame and only add normal overtime
1643         //   again, if at the point at which timelimit would be extended again, still no winner was found
1644         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1645         {
1646                 return 1; // need to call InitiateOvertime later
1647         }
1648         else
1649         {
1650                 if(!checkrules_suddendeathend)
1651                 {
1652                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1653                         if(g_race && !g_race_qualifying)
1654                                 race_StartCompleting();
1655                 }
1656                 return 0;
1657         }
1658 }
1659
1660 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1661 {
1662         ++checkrules_overtimesadded;
1663         //add one more overtime by simply extending the timelimit
1664         float tl;
1665         tl = autocvar_timelimit;
1666         tl += autocvar_timelimit_overtime;
1667         cvar_set("timelimit", ftos(tl));
1668         string minutesPlural;
1669         if (autocvar_timelimit_overtime == 1)
1670                 minutesPlural = " ^3minute";
1671         else
1672                 minutesPlural = " ^3minutes";
1673
1674         bcenterprint(
1675                 strcat(
1676                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1677                         ftos(autocvar_timelimit_overtime),
1678                         minutesPlural,
1679                         " to the game!"
1680                 )
1681         );
1682 }
1683
1684 float GetWinningCode(float fraglimitreached, float equality)
1685 {
1686         if(autocvar_g_campaign == 1)
1687                 if(fraglimitreached)
1688                         return WINNING_YES;
1689                 else
1690                         return WINNING_NO;
1691
1692         else
1693                 if(equality)
1694                         if(fraglimitreached)
1695                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1696                         else
1697                                 return WINNING_NEVER;
1698                 else
1699                         if(fraglimitreached)
1700                                 return WINNING_YES;
1701                         else
1702                                 return WINNING_NO;
1703 }
1704
1705 // set the .winning flag for exactly those players with a given field value
1706 void SetWinners(.float field, float value)
1707 {
1708         entity head;
1709         FOR_EACH_PLAYER(head)
1710                 head.winning = (head.field == value);
1711 }
1712
1713 // set the .winning flag for those players with a given field value
1714 void AddWinners(.float field, float value)
1715 {
1716         entity head;
1717         FOR_EACH_PLAYER(head)
1718                 if(head.field == value)
1719                         head.winning = 1;
1720 }
1721
1722 // clear the .winning flags
1723 void ClearWinners(void)
1724 {
1725         entity head;
1726         FOR_EACH_PLAYER(head)
1727                 head.winning = 0;
1728 }
1729
1730 // Onslaught winning condition:
1731 // game terminates if only one team has a working generator (or none)
1732 float WinningCondition_Onslaught()
1733 {
1734         entity head;
1735         local float t1, t2, t3, t4;
1736
1737         WinningConditionHelper(); // set worldstatus
1738
1739         if(inWarmupStage)
1740                 return WINNING_NO;
1741
1742         // first check if the game has ended
1743         t1 = t2 = t3 = t4 = 0;
1744         head = find(world, classname, "onslaught_generator");
1745         while (head)
1746         {
1747                 if (head.health > 0)
1748                 {
1749                         if (head.team == COLOR_TEAM1) t1 = 1;
1750                         if (head.team == COLOR_TEAM2) t2 = 1;
1751                         if (head.team == COLOR_TEAM3) t3 = 1;
1752                         if (head.team == COLOR_TEAM4) t4 = 1;
1753                 }
1754                 head = find(head, classname, "onslaught_generator");
1755         }
1756         if (t1 + t2 + t3 + t4 < 2)
1757         {
1758                 // game over, only one team remains (or none)
1759                 ClearWinners();
1760                 if (t1) SetWinners(team, COLOR_TEAM1);
1761                 if (t2) SetWinners(team, COLOR_TEAM2);
1762                 if (t3) SetWinners(team, COLOR_TEAM3);
1763                 if (t4) SetWinners(team, COLOR_TEAM4);
1764                 dprint("Have a winner, ending game.\n");
1765                 return WINNING_YES;
1766         }
1767
1768         // Two or more teams remain
1769         return WINNING_NO;
1770 }
1771
1772 float LMS_NewPlayerLives()
1773 {
1774         float fl;
1775         fl = autocvar_fraglimit;
1776         if(fl == 0)
1777                 fl = 999;
1778
1779         // first player has left the game for dying too much? Nobody else can get in.
1780         if(lms_lowest_lives < 1)
1781                 return 0;
1782
1783         if(!autocvar_g_lms_join_anytime)
1784                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1785                         return 0;
1786
1787         return bound(1, lms_lowest_lives, fl);
1788 }
1789
1790 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1791 // they win. Otherwise the defending team wins once the timelimit passes.
1792 void assault_new_round();
1793 float WinningCondition_Assault()
1794 {
1795         local float status;
1796
1797         WinningConditionHelper(); // set worldstatus
1798
1799         status = WINNING_NO;
1800         // as the timelimit has not yet passed just assume the defending team will win
1801         if(assault_attacker_team == COLOR_TEAM1)
1802         {
1803                 SetWinners(team, COLOR_TEAM2);
1804         }
1805         else
1806         {
1807                 SetWinners(team, COLOR_TEAM1);
1808         }
1809
1810         local entity ent;
1811         ent = find(world, classname, "target_assault_roundend");
1812         if(ent)
1813         {
1814                 if(ent.winning) // round end has been triggered by attacking team
1815                 {
1816                         bprint("ASSAULT: round completed...\n");
1817                         SetWinners(team, assault_attacker_team);
1818
1819                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1820
1821                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1822                         {
1823                                 status = WINNING_YES;
1824                         }
1825                         else
1826                         {
1827                                 local entity oldself;
1828                                 oldself = self;
1829                                 self = ent;
1830                                 assault_new_round();
1831                                 self = oldself;
1832                         }
1833                 }
1834         }
1835
1836         return status;
1837 }
1838
1839 // LMS winning condition: game terminates if and only if there's at most one
1840 // one player who's living lives. Top two scores being equal cancels the time
1841 // limit.
1842 float WinningCondition_LMS()
1843 {
1844         entity head, head2;
1845         float have_player;
1846         float have_players;
1847         float l;
1848
1849         have_player = FALSE;
1850         have_players = FALSE;
1851         l = LMS_NewPlayerLives();
1852
1853         head = find(world, classname, "player");
1854         if(head)
1855                 have_player = TRUE;
1856         head2 = find(head, classname, "player");
1857         if(head2)
1858                 have_players = TRUE;
1859
1860         if(have_player)
1861         {
1862                 // we have at least one player
1863                 if(have_players)
1864                 {
1865                         // two or more active players - continue with the game
1866                 }
1867                 else
1868                 {
1869                         // exactly one player?
1870
1871                         ClearWinners();
1872                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1873
1874                         if(l)
1875                         {
1876                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1877                                 return WINNING_NO;
1878                         }
1879                         else
1880                         {
1881                                 // a winner!
1882                                 // and assign him his first place
1883                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1884                                 return WINNING_YES;
1885                         }
1886                 }
1887         }
1888         else
1889         {
1890                 // nobody is playing at all...
1891                 if(l)
1892                 {
1893                         // wait for players...
1894                 }
1895                 else
1896                 {
1897                         // SNAFU (maybe a draw game?)
1898                         ClearWinners();
1899                         dprint("No players, ending game.\n");
1900                         return WINNING_YES;
1901                 }
1902         }
1903
1904         // When we get here, we have at least two players who are actually LIVING,
1905         // now check if the top two players have equal score.
1906         WinningConditionHelper();
1907
1908         ClearWinners();
1909         if(WinningConditionHelper_winner)
1910                 WinningConditionHelper_winner.winning = TRUE;
1911         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1912                 return WINNING_NEVER;
1913
1914         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1915         return WINNING_NO;
1916 }
1917
1918 void ShuffleMaplist()
1919 {
1920         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1921 }
1922
1923 float leaderfrags;
1924 float WinningCondition_Scores(float limit, float leadlimit)
1925 {
1926         float limitreached;
1927
1928         // TODO make everything use THIS winning condition (except LMS)
1929         WinningConditionHelper();
1930
1931         if(teamplay)
1932         {
1933                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1934                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1935                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1936                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1937         }
1938
1939         ClearWinners();
1940         if(WinningConditionHelper_winner)
1941                 WinningConditionHelper_winner.winning = 1;
1942         if(WinningConditionHelper_winnerteam >= 0)
1943                 SetWinners(team, WinningConditionHelper_winnerteam);
1944
1945         if(WinningConditionHelper_lowerisbetter)
1946         {
1947                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1948                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1949                 limit = -limit;
1950         }
1951
1952         if(WinningConditionHelper_zeroisworst)
1953                 leadlimit = 0; // not supported in this mode
1954
1955         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1956         // these modes always score in increments of 1, thus this makes sense
1957         {
1958                 if(leaderfrags != WinningConditionHelper_topscore)
1959                 {
1960                         leaderfrags = WinningConditionHelper_topscore;
1961
1962                         if (limit)
1963                         if (leaderfrags == limit - 1)
1964                                 Announce("1fragleft");
1965                         else if (leaderfrags == limit - 2)
1966                                 Announce("2fragsleft");
1967                         else if (leaderfrags == limit - 3)
1968                                 Announce("3fragsleft");
1969                 }
1970         }
1971
1972         limitreached = FALSE;
1973         if(limit)
1974                 if(WinningConditionHelper_topscore >= limit)
1975                         limitreached = TRUE;
1976         if(leadlimit)
1977         {
1978                 float leadlimitreached;
1979                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1980                 if(autocvar_leadlimit_and_fraglimit)
1981                         limitreached = (limitreached && leadlimitreached);
1982                 else
1983                         limitreached = (limitreached || leadlimitreached);
1984         }
1985
1986         return GetWinningCode(
1987                 WinningConditionHelper_topscore && limitreached,
1988                 WinningConditionHelper_equality
1989         );
1990 }
1991
1992 float WinningCondition_Race(float fraglimit)
1993 {
1994         float wc;
1995         entity p;
1996         float n, c;
1997
1998         n = 0;
1999         c = 0;
2000         FOR_EACH_PLAYER(p)
2001         {
2002                 ++n;
2003                 if(p.race_completed)
2004                         ++c;
2005         }
2006         if(n && (n == c))
2007                 return WINNING_YES;
2008         wc = WinningCondition_Scores(fraglimit, 0);
2009
2010         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2011         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2012         // do NOT support equality when the laps are all raced!
2013                 return WINNING_STARTSUDDENDEATHOVERTIME;
2014         else
2015                 return WINNING_NEVER;
2016         return wc;
2017 }
2018
2019 void ReadyRestart();
2020 float WinningCondition_QualifyingThenRace(float limit)
2021 {
2022         float wc;
2023         wc = WinningCondition_Scores(limit, 0);
2024
2025         // NEVER initiate overtime
2026         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2027         {
2028                 return WINNING_YES;
2029         }
2030
2031         return wc;
2032 }
2033
2034 float WinningCondition_RanOutOfSpawns()
2035 {
2036         entity head;
2037
2038         if(have_team_spawns <= 0)
2039                 return WINNING_NO;
2040
2041         if(!some_spawn_has_been_used)
2042                 return WINNING_NO;
2043
2044         team1_score = team2_score = team3_score = team4_score = 0;
2045
2046         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2047         {
2048                 if(head.team == COLOR_TEAM1)
2049                         team1_score = 1;
2050                 else if(head.team == COLOR_TEAM2)
2051                         team2_score = 1;
2052                 else if(head.team == COLOR_TEAM3)
2053                         team3_score = 1;
2054                 else if(head.team == COLOR_TEAM4)
2055                         team4_score = 1;
2056         }
2057
2058         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2059         {
2060                 if(head.team == COLOR_TEAM1)
2061                         team1_score = 1;
2062                 else if(head.team == COLOR_TEAM2)
2063                         team2_score = 1;
2064                 else if(head.team == COLOR_TEAM3)
2065                         team3_score = 1;
2066                 else if(head.team == COLOR_TEAM4)
2067                         team4_score = 1;
2068         }
2069
2070         ClearWinners();
2071         if(team1_score + team2_score + team3_score + team4_score == 0)
2072         {
2073                 checkrules_equality = TRUE;
2074                 return WINNING_YES;
2075         }
2076         else if(team1_score + team2_score + team3_score + team4_score == 1)
2077         {
2078                 float t, i;
2079                 if(team1_score) t = COLOR_TEAM1;
2080                 if(team2_score) t = COLOR_TEAM2;
2081                 if(team3_score) t = COLOR_TEAM3;
2082                 if(team4_score) t = COLOR_TEAM4;
2083                 CheckAllowedTeams(world);
2084                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2085                 {
2086                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2087                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2088                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2089                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2090                 }
2091
2092                 AddWinners(team, t);
2093                 return WINNING_YES;
2094         }
2095         else
2096                 return WINNING_NO;
2097 }
2098
2099 /*
2100 ============
2101 CheckRules_World
2102
2103 Exit deathmatch games upon conditions
2104 ============
2105 */
2106 void CheckRules_World()
2107 {
2108         float timelimit;
2109         float fraglimit;
2110         float leadlimit;
2111
2112         VoteThink();
2113         MapVote_Think();
2114
2115         SetDefaultAlpha();
2116
2117         /*
2118         MapVote_Think should now do that part
2119         if (intermission_running)
2120                 if (time >= intermission_exittime + 60)
2121                 {
2122                         if(!DoNextMapOverride())
2123                                 GotoNextMap();
2124                         return;
2125                 }
2126         */
2127
2128         if (gameover)   // someone else quit the game already
2129         {
2130                 if(player_count == 0) // Nobody there? Then let's go to the next map
2131                         MapVote_Start();
2132                         // this will actually check the player count in the next frame
2133                         // again, but this shouldn't hurt
2134                 return;
2135         }
2136
2137         timelimit = autocvar_timelimit * 60;
2138         fraglimit = autocvar_fraglimit;
2139         leadlimit = autocvar_leadlimit;
2140
2141         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2142         {
2143                 if(timelimit > 0)
2144                         timelimit = 0; // timelimit is not made for warmup
2145                 if(fraglimit > 0)
2146                         fraglimit = 0; // no fraglimit for now
2147                 leadlimit = 0; // no leadlimit for now
2148         }
2149
2150         if(g_onslaught)
2151                 timelimit = 0; // ONS has its own overtime rule
2152
2153         if(timelimit > 0)
2154         {
2155                 timelimit += game_starttime;
2156         }
2157         else if (timelimit < 0)
2158         {
2159                 // endmatch
2160                 NextLevel();
2161                 return;
2162         }
2163
2164         float wantovertime;
2165         wantovertime = 0;
2166
2167         if(checkrules_suddendeathend)
2168         {
2169                 if(!checkrules_suddendeathwarning)
2170                 {
2171                         checkrules_suddendeathwarning = TRUE;
2172                         if(g_race && !g_race_qualifying)
2173                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2174                         else
2175                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2176                 }
2177         }
2178         else
2179         {
2180                 if (timelimit && time >= timelimit)
2181                 {
2182                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2183                         {
2184                                 float totalplayers;
2185                                 float playerswithlaps;
2186                                 float readyplayers;
2187                                 entity head;
2188                                 totalplayers = playerswithlaps = readyplayers = 0;
2189                                 FOR_EACH_PLAYER(head)
2190                                 {
2191                                         ++totalplayers;
2192                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2193                                                 ++playerswithlaps;
2194                                         if(head.ready)
2195                                                 ++readyplayers;
2196                                 }
2197
2198                                 // at least 2 of the players have completed a lap: start the RACE
2199                                 // otherwise, the players should end the qualifying on their own
2200                                 if(readyplayers || playerswithlaps >= 2)
2201                                 {
2202                                         checkrules_suddendeathend = 0;
2203                                         ReadyRestart(); // go to race
2204                                         return;
2205                                 }
2206                                 else
2207                                         wantovertime |= InitiateSuddenDeath();
2208                         }
2209                         else
2210                                 wantovertime |= InitiateSuddenDeath();
2211                 }
2212         }
2213
2214         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2215         {
2216                 NextLevel();
2217                 return;
2218         }
2219
2220         float checkrules_status;
2221         checkrules_status = WinningCondition_RanOutOfSpawns();
2222         if(checkrules_status == WINNING_YES)
2223         {
2224                 bprint("Hey! Someone ran out of spawns!\n");
2225         }
2226         else if(g_race && !g_race_qualifying && timelimit >= 0)
2227         {
2228                 checkrules_status = WinningCondition_Race(fraglimit);
2229                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2230         }
2231         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2232         {
2233                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2234                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2235         }
2236         else if(g_assault)
2237         {
2238                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2239         }
2240         else if(g_lms)
2241         {
2242                 checkrules_status = WinningCondition_LMS();
2243         }
2244         else if (g_onslaught)
2245         {
2246                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2247         }
2248         else
2249         {
2250                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2251                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2252         }
2253
2254         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2255         {
2256                 checkrules_status = WINNING_NEVER;
2257                 checkrules_overtimesadded = -1;
2258                 wantovertime |= InitiateSuddenDeath();
2259         }
2260
2261         if(checkrules_status == WINNING_NEVER)
2262                 // equality cases! Nobody wins if the overtime ends in a draw.
2263                 ClearWinners();
2264
2265         if(wantovertime)
2266         {
2267                 if(checkrules_status == WINNING_NEVER)
2268                         InitiateOvertime();
2269                 else
2270                         checkrules_status = WINNING_YES;
2271         }
2272
2273         if(checkrules_suddendeathend)
2274                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2275                         checkrules_status = WINNING_YES;
2276
2277         if(checkrules_status == WINNING_YES)
2278         {
2279                 //print("WINNING\n");
2280                 NextLevel();
2281         }
2282 };
2283
2284 float mapvote_nextthink;
2285 float mapvote_initialized;
2286 float mapvote_keeptwotime;
2287 float mapvote_timeout;
2288 string mapvote_message;
2289 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2290 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2291 float mapvote_screenshot_dirs_count;
2292
2293 float mapvote_count;
2294 float mapvote_count_real;
2295 string mapvote_maps[MAPVOTE_COUNT];
2296 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2297 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2298 float mapvote_maps_suggested[MAPVOTE_COUNT];
2299 string mapvote_suggestions[MAPVOTE_COUNT];
2300 float mapvote_suggestion_ptr;
2301 float mapvote_maxlen;
2302 float mapvote_voters;
2303 float mapvote_votes[MAPVOTE_COUNT];
2304 float mapvote_run;
2305 float mapvote_detail;
2306 float mapvote_abstain;
2307 .float mapvote;
2308
2309 void MapVote_ClearAllVotes()
2310 {
2311         FOR_EACH_CLIENT(other)
2312                 other.mapvote = 0;
2313 }
2314
2315 string MapVote_Suggest(string m)
2316 {
2317         float i;
2318         if(m == "")
2319                 return "That's not how to use this command.";
2320         if(!autocvar_g_maplist_votable_suggestions)
2321                 return "Suggestions are not accepted on this server.";
2322         if(mapvote_initialized)
2323                 return "Can't suggest - voting is already in progress!";
2324         m = MapInfo_FixName(m);
2325         if(!m)
2326                 return "The map you suggested is not available on this server.";
2327         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2328                 if(Map_IsRecent(m))
2329                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2330
2331         if(!MapInfo_CheckMap(m))
2332                 return "The map you suggested does not support the current game mode.";
2333         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2334                 if(mapvote_suggestions[i] == m)
2335                         return "This map was already suggested.";
2336         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2337         {
2338                 i = floor(random() * mapvote_suggestion_ptr);
2339         }
2340         else
2341         {
2342                 i = mapvote_suggestion_ptr;
2343                 mapvote_suggestion_ptr += 1;
2344         }
2345         if(mapvote_suggestions[i] != "")
2346                 strunzone(mapvote_suggestions[i]);
2347         mapvote_suggestions[i] = strzone(m);
2348         if(autocvar_sv_eventlog)
2349                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2350         return strcat("Suggestion of ", m, " accepted.");
2351 }
2352
2353 void MapVote_AddVotable(string nextMap, float isSuggestion)
2354 {
2355         float j, i, o;
2356         string pakfile, mapfile;
2357
2358         if(nextMap == "")
2359                 return;
2360         for(j = 0; j < mapvote_count; ++j)
2361                 if(mapvote_maps[j] == nextMap)
2362                         return;
2363         if(strlen(nextMap) > mapvote_maxlen)
2364                 mapvote_maxlen = strlen(nextMap);
2365         mapvote_maps[mapvote_count] = strzone(nextMap);
2366         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2367
2368         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2369         {
2370                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2371                 pakfile = whichpack(strcat(mapfile, ".tga"));
2372                 if(pakfile == "")
2373                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2374                 if(pakfile == "")
2375                         pakfile = whichpack(strcat(mapfile, ".png"));
2376                 if(pakfile != "")
2377                         break;
2378         }
2379         if(i >= mapvote_screenshot_dirs_count)
2380                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2381         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2382                 pakfile = substring(pakfile, o, -1);
2383
2384         mapvote_maps_screenshot_dir[mapvote_count] = i;
2385         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2386
2387         mapvote_count += 1;
2388 }
2389
2390 void MapVote_Spawn();
2391 void MapVote_Init()
2392 {
2393         float i;
2394         float nmax, smax;
2395
2396         MapVote_ClearAllVotes();
2397
2398         mapvote_count = 0;
2399         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2400         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2401
2402         if(mapvote_abstain)
2403                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2404         else
2405                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2406         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2407
2408         // we need this for AddVotable, as that cycles through the screenshot dirs
2409         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2410         if(mapvote_screenshot_dirs_count == 0)
2411                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2412         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2413         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2414                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2415
2416         if(mapvote_suggestion_ptr)
2417                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2418                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2419
2420         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2421                 MapVote_AddVotable(GetNextMap(), FALSE);
2422
2423         if(mapvote_count == 0)
2424         {
2425                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2426                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2427                 if(autocvar_g_maplist_shuffle)
2428                         ShuffleMaplist();
2429                 localcmd("\nmenu_cmd sync\n");
2430                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                         MapVote_AddVotable(GetNextMap(), FALSE);
2432         }
2433
2434         mapvote_count_real = mapvote_count;
2435         if(mapvote_abstain)
2436                 MapVote_AddVotable("don't care", 0);
2437
2438         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2439
2440         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2441         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2442         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2443                 mapvote_keeptwotime = 0;
2444         mapvote_message = "Choose a map and press its key!";
2445
2446         MapVote_Spawn();
2447 }
2448
2449 void MapVote_SendPicture(float id)
2450 {
2451         msg_entity = self;
2452         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2453         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2454         WriteByte(MSG_ONE, id);
2455         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2456 }
2457
2458 float GameCommand_MapVote(string cmd)
2459 {
2460         if(!intermission_running)
2461                 return FALSE;
2462
2463         if(cmd == "mv_getpic")
2464         {
2465                 MapVote_SendPicture(stof(argv(1)));
2466                 return TRUE;
2467         }
2468
2469         return FALSE;
2470 }
2471
2472 float MapVote_GetMapMask()
2473 {
2474         float mask, i, power;
2475         mask = 0;
2476         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2477                 if(mapvote_maps[i] != "")
2478                         mask |= power;
2479         return mask;
2480 }
2481
2482 entity mapvote_ent;
2483 float MapVote_SendEntity(entity to, float sf)
2484 {
2485         float i;
2486
2487         if(sf & 1)
2488                 sf &~= 2; // if we send 1, we don't need to also send 2
2489
2490         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2491         WriteByte(MSG_ENTITY, sf);
2492
2493         if(sf & 1)
2494         {
2495                 // flag 1 == initialization
2496                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2497                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2498                 WriteString(MSG_ENTITY, "");
2499                 WriteByte(MSG_ENTITY, mapvote_count);
2500                 WriteByte(MSG_ENTITY, mapvote_abstain);
2501                 WriteByte(MSG_ENTITY, mapvote_detail);
2502                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2503                 if(mapvote_count <= 8)
2504                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2505                 else
2506                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2507                 for(i = 0; i < mapvote_count; ++i)
2508                         if(mapvote_maps[i] != "")
2509                         {
2510                                 if(mapvote_abstain && i == mapvote_count - 1)
2511                                 {
2512                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2513                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2514                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2515                                 }
2516                                 else
2517                                 {
2518                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2519                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2520                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2521                                 }
2522                         }
2523         }
2524
2525         if(sf & 2)
2526         {
2527                 // flag 2 == update of mask
2528                 if(mapvote_count <= 8)
2529                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2530                 else
2531                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2532         }
2533
2534         if(sf & 4)
2535         {
2536                 if(mapvote_detail)
2537                         for(i = 0; i < mapvote_count; ++i)
2538                                 if(mapvote_maps[i] != "")
2539                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2540
2541                 WriteByte(MSG_ENTITY, to.mapvote);
2542         }
2543
2544         return TRUE;
2545 }
2546
2547 void MapVote_Spawn()
2548 {
2549         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2550 }
2551
2552 void MapVote_TouchMask()
2553 {
2554         mapvote_ent.SendFlags |= 2;
2555 }
2556
2557 void MapVote_TouchVotes(entity voter)
2558 {
2559         mapvote_ent.SendFlags |= 4;
2560 }
2561
2562 float MapVote_Finished(float mappos)
2563 {
2564         string result;
2565         float i;
2566         float didntvote;
2567
2568         if(autocvar_sv_eventlog)
2569         {
2570                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2571                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2572                 didntvote = mapvote_voters;
2573                 for(i = 0; i < mapvote_count; ++i)
2574                         if(mapvote_maps[i] != "")
2575                         {
2576                                 didntvote -= mapvote_votes[i];
2577                                 if(i != mappos)
2578                                 {
2579                                         result = strcat(result, ":", mapvote_maps[i]);
2580                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2581                                 }
2582                         }
2583                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2584
2585                 GameLogEcho(result);
2586                 if(mapvote_maps_suggested[mappos])
2587                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2588         }
2589
2590         FOR_EACH_REALCLIENT(other)
2591                 FixClientCvars(other);
2592
2593         Map_Goto_SetStr(mapvote_maps[mappos]);
2594         Map_Goto();
2595         alreadychangedlevel = TRUE;
2596         return TRUE;
2597 }
2598 void MapVote_CheckRules_1()
2599 {
2600         float i;
2601
2602         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2603         {
2604                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2605                 mapvote_votes[i] = 0;
2606         }
2607
2608         mapvote_voters = 0;
2609         FOR_EACH_REALCLIENT(other)
2610         {
2611                 ++mapvote_voters;
2612                 if(other.mapvote)
2613                 {
2614                         i = other.mapvote - 1;
2615                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2616                         mapvote_votes[i] = mapvote_votes[i] + 1;
2617                 }
2618         }
2619 }
2620
2621 float MapVote_CheckRules_2()
2622 {
2623         float i;
2624         float firstPlace, secondPlace;
2625         float firstPlaceVotes, secondPlaceVotes;
2626         float mapvote_voters_real;
2627         string result;
2628
2629         if(mapvote_count_real == 1)
2630                 return MapVote_Finished(0);
2631
2632         mapvote_voters_real = mapvote_voters;
2633         if(mapvote_abstain)
2634                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2635
2636         RandomSelection_Init();
2637         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2638                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2639         firstPlace = RandomSelection_chosen_float;
2640         firstPlaceVotes = RandomSelection_best_priority;
2641         //dprint("First place: ", ftos(firstPlace), "\n");
2642         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2643
2644         RandomSelection_Init();
2645         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2646                 if(i != firstPlace)
2647                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2648         secondPlace = RandomSelection_chosen_float;
2649         secondPlaceVotes = RandomSelection_best_priority;
2650         //dprint("Second place: ", ftos(secondPlace), "\n");
2651         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2652
2653         if(firstPlace == -1)
2654                 error("No first place in map vote... WTF?");
2655
2656         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2657                 return MapVote_Finished(firstPlace);
2658
2659         if(mapvote_keeptwotime)
2660                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2661                 {
2662                         float didntvote;
2663                         MapVote_TouchMask();
2664                         mapvote_message = "Now decide between the TOP TWO!";
2665                         mapvote_keeptwotime = 0;
2666                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2667                         result = strcat(result, ":", ftos(firstPlaceVotes));
2668                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2669                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2670                         didntvote = mapvote_voters;
2671                         for(i = 0; i < mapvote_count; ++i)
2672                                 if(mapvote_maps[i] != "")
2673                                 {
2674                                         didntvote -= mapvote_votes[i];
2675                                         if(i != firstPlace)
2676                                                 if(i != secondPlace)
2677                                                 {
2678                                                         result = strcat(result, ":", mapvote_maps[i]);
2679                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2680                                                         if(i < mapvote_count_real)
2681                                                         {
2682                                                                 strunzone(mapvote_maps[i]);
2683                                                                 mapvote_maps[i] = "";
2684                                                                 strunzone(mapvote_maps_pakfile[i]);
2685                                                                 mapvote_maps_pakfile[i] = "";
2686                                                         }
2687                                                 }
2688                                 }
2689                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2690                         if(autocvar_sv_eventlog)
2691                                 GameLogEcho(result);
2692                 }
2693
2694         return FALSE;
2695 }
2696 void MapVote_Tick()
2697 {
2698         float keeptwo;
2699         float totalvotes;
2700
2701         keeptwo = mapvote_keeptwotime;
2702         MapVote_CheckRules_1(); // count
2703         if(MapVote_CheckRules_2()) // decide
2704                 return;
2705
2706         totalvotes = 0;
2707         FOR_EACH_REALCLIENT(other)
2708         {
2709                 // hide scoreboard again
2710                 if(other.health != 2342)
2711                 {
2712                         other.health = 2342;
2713                         other.impulse = 0;
2714                         if(clienttype(other) == CLIENTTYPE_REAL)
2715                         {
2716                                 msg_entity = other;
2717                                 WriteByte(MSG_ONE, SVC_FINALE);
2718                                 WriteString(MSG_ONE, "");
2719                         }
2720                 }
2721
2722                 // clear possibly invalid votes
2723                 if(mapvote_maps[other.mapvote - 1] == "")
2724                         other.mapvote = 0;
2725                 // use impulses as new vote
2726                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2727                         if(mapvote_maps[other.impulse - 1] != "")
2728                         {
2729                                 other.mapvote = other.impulse;
2730                                 MapVote_TouchVotes(other);
2731                         }
2732                 other.impulse = 0;
2733
2734                 if(other.mapvote)
2735                         ++totalvotes;
2736         }
2737
2738         MapVote_CheckRules_1(); // just count
2739 }
2740 void MapVote_Start()
2741 {
2742         if(mapvote_run)
2743                 return;
2744
2745         // wait for stats to be sent first
2746         if(!playerstats_waitforme)
2747                 return;
2748
2749         MapInfo_Enumerate();
2750         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2751                 mapvote_run = TRUE;
2752 }
2753 void MapVote_Think()
2754 {
2755         if(!mapvote_run)
2756                 return;
2757
2758         if(alreadychangedlevel)
2759                 return;
2760
2761         if(time < mapvote_nextthink)
2762                 return;
2763         //dprint("tick\n");
2764
2765         mapvote_nextthink = time + 0.5;
2766
2767         if(!mapvote_initialized)
2768         {
2769                 if(autocvar_rescan_pending == 1)
2770                 {
2771                         cvar_set("rescan_pending", "2");
2772                         localcmd("fs_rescan\nrescan_pending 3\n");
2773                         return;
2774                 }
2775                 else if(autocvar_rescan_pending == 2)
2776                 {
2777                         return;
2778                 }
2779                 else if(autocvar_rescan_pending == 3)
2780                 {
2781                         // now build missing mapinfo files
2782                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2783                                 return;
2784
2785                         // we're done, start the timer
2786                         cvar_set("rescan_pending", "0");
2787                 }
2788
2789                 mapvote_initialized = TRUE;
2790                 if(DoNextMapOverride())
2791                         return;
2792                 if(!autocvar_g_maplist_votable || player_count <= 0)
2793                 {
2794                         GotoNextMap();
2795                         return;
2796                 }
2797                 MapVote_Init();
2798         }
2799
2800         MapVote_Tick();
2801 };
2802
2803 string GotoMap(string m)
2804 {
2805         if(!MapInfo_CheckMap(m))
2806                 return "The map you chose is not available on this server.";
2807         cvar_set("nextmap", m);
2808         cvar_set("timelimit", "-1");
2809         if(mapvote_initialized || alreadychangedlevel)
2810         {
2811                 if(DoNextMapOverride())
2812                         return "Map switch initiated.";
2813                 else
2814                         return "Hm... no. For some reason I like THIS map more.";
2815         }
2816         else
2817                 return "Map switch will happen after scoreboard.";
2818 }
2819
2820
2821 void EndFrame()
2822 {
2823         float altime;
2824         FOR_EACH_REALCLIENT(self)
2825         {
2826                 if(self.classname == "spectator")
2827                 {
2828                         if(self.enemy.typehitsound)
2829                                 self.typehit_time = time;
2830                         else if(self.enemy.hitsound)
2831                                 self.hit_time = time;
2832                 }
2833                 else
2834                 {
2835                         if(self.typehitsound)
2836                                 self.typehit_time = time;
2837                         else if(self.hitsound)
2838                                 self.hit_time = time;
2839                 }
2840         }
2841         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2842         // add 1 frametime because after this, engine SV_Physics
2843         // increases time by a frametime and then networks the frame
2844         // add another frametime because client shows everything with
2845         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2846         // needed!
2847         FOR_EACH_CLIENT(self)
2848         {
2849                 self.hitsound = FALSE;
2850                 self.typehitsound = FALSE;
2851                 antilag_record(self, altime);
2852         }
2853 }
2854
2855
2856 /*
2857  * RedirectionThink:
2858  * returns TRUE if redirecting
2859  */
2860 float redirection_timeout;
2861 float redirection_nextthink;
2862 float RedirectionThink()
2863 {
2864         float clients_found;
2865
2866         if(redirection_target == "")
2867                 return FALSE;
2868
2869         if(!redirection_timeout)
2870         {
2871                 cvar_set("sv_public", "-2");
2872                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2873                 if(redirection_target == "self")
2874                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2875                 else
2876                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2877         }
2878
2879         if(time < redirection_nextthink)
2880                 return TRUE;
2881
2882         redirection_nextthink = time + 1;
2883
2884         clients_found = 0;
2885         FOR_EACH_REALCLIENT(self)
2886         {
2887                 print("Redirecting: sending connect command to ", self.netname, "\n");
2888                 if(redirection_target == "self")
2889                         stuffcmd(self, "\ndisconnect; reconnect\n");
2890                 else
2891                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2892                 ++clients_found;
2893         }
2894
2895         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2896
2897         if(time > redirection_timeout || clients_found == 0)
2898                 localcmd("\nwait; wait; wait; quit\n");
2899
2900         return TRUE;
2901 }
2902
2903 void TargetMusic_RestoreGame();
2904 void RestoreGame()
2905 {
2906         // Loaded from a save game
2907         // some things then break, so let's work around them...
2908
2909         // Progs DB (capture records)
2910         ServerProgsDB = db_load("server.db");
2911
2912         // Mapinfo
2913         MapInfo_Shutdown();
2914         MapInfo_Enumerate();
2915         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2916         WeaponStats_Init();
2917
2918         TargetMusic_RestoreGame();
2919 }
2920
2921 void SV_Shutdown()
2922 {
2923         entity e;
2924
2925         if(gameover > 1) // shutting down already?
2926                 return;
2927
2928         gameover = 2; // 2 = server shutting down
2929
2930         if(world_initialized > 0)
2931         {
2932                 world_initialized = 0;
2933                 print("Saving persistent data...\n");
2934                 Ban_SaveBans();
2935
2936                 PlayerStats_EndMatch(0);
2937                 FOR_EACH_CLIENT(e)
2938                         PlayerStats_AddGlobalInfo(e);
2939                 PlayerStats_Shutdown();
2940
2941                 if(!cheatcount_total)
2942                 {
2943                         if(autocvar_sv_db_saveasdump)
2944                                 db_dump(ServerProgsDB, "server.db");
2945                         else
2946                                 db_save(ServerProgsDB, "server.db");
2947                 }
2948                 if(autocvar_developer)
2949                 {
2950                         if(autocvar_sv_db_saveasdump)
2951                                 db_dump(TemporaryDB, "server-temp.db");
2952                         else
2953                                 db_save(TemporaryDB, "server-temp.db");
2954                 }
2955                 CheatShutdown(); // must be after cheatcount check
2956                 db_close(ServerProgsDB);
2957                 db_close(TemporaryDB);
2958                 print("done!\n");
2959                 // tell the bot system the game is ending now
2960                 bot_endgame();
2961
2962                 WeaponStats_Shutdown();
2963                 MapInfo_Shutdown();
2964         }
2965         else if(world_initialized == 0)
2966         {
2967                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2968         }
2969 }