qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240                 // internal
 241                 BADPREFIX("csqc_");
 242                 BADPREFIX("cvar_check_");
 243                 BADCVAR("gamecfg");
 244                 BADCVAR("g_configversion");
 245                 BADCVAR("g_maplist_index");
 246                 BADCVAR("halflifebsp");
 247                 BADPREFIX("sv_world");
 248
 249                 // client
 250                 BADPREFIX("chase_");
 251                 BADPREFIX("cl_");
 252                 BADPREFIX("con_");
 253                 BADPREFIX("scoreboard_");
 254                 BADPREFIX("g_campaign");
 255                 BADPREFIX("gl_");
 256                 BADPREFIX("joy");
 257                 BADPREFIX("hud_");
 258                 BADPREFIX("m_");
 259                 BADPREFIX("menu_");
 260                 BADPREFIX("net_slist_");
 261                 BADPREFIX("r_");
 262                 BADPREFIX("sbar_");
 263                 BADPREFIX("scr_");
 264                 BADPREFIX("snd_");
 265                 BADPREFIX("show");
 266                 BADPREFIX("sensitivity");
 267                 BADPREFIX("userbind");
 268                 BADPREFIX("v_");
 269                 BADPREFIX("vid_");
 270                 BADPREFIX("crosshair");
 271                 BADCVAR("mod_q3bsp_lightmapmergepower");
 272                 BADCVAR("mod_q3bsp_nolightmaps");
 273                 BADCVAR("fov");
 274                 BADCVAR("mastervolume");
 275                 BADCVAR("volume");
 276                 BADCVAR("bgmvolume");
 277
 278                 // private
 279                 BADCVAR("developer");
 280                 BADCVAR("g_banned_list");
 281                 BADCVAR("log_dest_udp");
 282                 BADCVAR("log_file");
 283                 BADCVAR("net_address");
 284                 BADCVAR("net_address_ipv6");
 285                 BADCVAR("port");
 286                 BADCVAR("savedgamecfg");
 287                 BADCVAR("serverconfig");
 288                 BADCVAR("sv_heartbeatperiod");
 289                 BADCVAR("sv_vote_master_password");
 290                 BADCVAR("sys_colortranslation");
 291                 BADCVAR("sys_specialcharactertranslation");
 292                 BADCVAR("timestamps");
 293                 BADPREFIX("developer_");
 294                 BADPREFIX("g_ban_");
 295                 BADPREFIX("g_chat_flood_");
 296                 BADPREFIX("g_voice_flood_");
 297                 BADPREFIX("rcon_");
 298                 BADPREFIX("settemp_");
 299                 BADPREFIX("sv_allowdownloads_");
 300                 BADPREFIX("sv_autodemo");
 301                 BADPREFIX("sv_curl_");
 302                 BADPREFIX("sv_eventlog");
 303                 BADPREFIX("sv_logscores_");
 304                 BADPREFIX("sv_master");
 305                 BADPREFIX("sv_weaponstats_");
 306
 307                 // these can contain player IDs, so better hide
 308                 BADCVAR("g_forced_team_red");
 309                 BADCVAR("g_forced_team_blue");
 310                 BADCVAR("g_forced_team_yellow");
 311                 BADCVAR("g_forced_team_pink");
 312
 313                 // mapinfo
 314                 BADCVAR("timelimit");
 315                 BADCVAR("fraglimit");
 316                 BADCVAR("leadlimit");
 317                 BADCVAR("g_tdm_teams");
 318                 BADCVAR("g_keyhunt_teams");
 319                 BADCVAR("g_domination_default_teams");
 320                 BADCVAR("g_race_qualifying_timelimit");
 321                 BADCVAR("g_lms");
 322                 BADCVAR("g_arena");
 323                 BADCVAR("g_ca");
 324                 BADCVAR("g_assault");
 325                 BADCVAR("g_ctf");
 326                 BADCVAR("g_dm");
 327                 BADCVAR("g_domination");
 328                 BADCVAR("g_keyhunt");
 329                 BADCVAR("g_keyhunt_teams");
 330                 BADCVAR("g_onslaught");
 331                 BADCVAR("g_race");
 332                 BADCVAR("g_cts");
 333                 BADCVAR("g_runematch");
 334                 BADCVAR("g_tdm");
 335                 BADCVAR("g_nexball");
 336                 BADCVAR("g_keepaway");
 337                 BADCVAR("teamplay");
 338
 339                 // long
 340                 BADCVAR("hostname");
 341                 BADCVAR("g_maplist");
 342                 BADCVAR("g_maplist_mostrecent");
 343                 BADCVAR("sv_motd");
 344
 345                 v = cvar_string(k);
 346                 d = cvar_defstring(k);
 347                 if(v == d)
 348                         continue;
 349
 350                 if(adding)
 351                 {
 352                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 353                         if(strlen(cvar_changes) > 16384)
 354                         {
 355                                 cvar_changes = "// too many settings have been changed to show them here\n";
 356                                 adding = 0;
 357                         }
 358                 }
 359
 360                 // now check if the changes are actually gameplay relevant
 361
 362                 // does nothing visible
 363                 BADCVAR("captureleadlimit_override");
 364                 BADCVAR("g_arena_point_leadlimit");
 365                 BADCVAR("g_ca_point_leadlimit");
 366                 BADCVAR("g_ctf_capture_leadlimit");
 367                 BADCVAR("g_domination_point_leadlimit");
 368                 BADCVAR("g_keyhunt_point_leadlimit");
 369                 BADCVAR("g_nexball_goalleadlimit");
 370                 BADCVAR("g_runematch_point_leadlimit");
 371                 BADCVAR("leadlimit_and_fraglimit");
 372                 BADCVAR("leadlimit_override");
 373                 BADCVAR("sv_checkforpacketsduringsleep");
 374                 BADCVAR("pausable");
 375                 BADCVAR("sv_timeout");
 376                 BADPREFIX("crypto_");
 377                 BADPREFIX("g_chat_");
 378                 BADPREFIX("net_");
 379                 BADPREFIX("prvm_");
 380                 BADPREFIX("sv_fragmessage_");
 381                 BADPREFIX("sv_vote_");
 382                 BADPREFIX("timelimit_");
 383
 384                 // allowed changes to server admins (please sync this to server.cfg)
 385                 // vi commands:
 386                 //   :/"impure"/,$d
 387                 //   :g!,^\/\/[^ /],d
 388                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 389                 //   :%!sort
 390                 // yes, this does contain some redundant stuff, don't really care
 391                 BADCVAR("bot_number");
 392                 BADCVAR("bot_prefix");
 393                 BADCVAR("bot_suffix");
 394                 BADCVAR("capturelimit_override");
 395                 BADCVAR("fraglimit_override");
 396                 BADCVAR("gametype");
 397                 BADCVAR("g_antilag");
 398                 BADCVAR("g_balance_teams");
 399                 BADCVAR("g_balance_teams_force");
 400                 BADCVAR("g_ban_sync_trusted_servers");
 401                 BADCVAR("g_ban_sync_uri");
 402                 BADCVAR("g_ctf_capture_limit");
 403                 BADCVAR("g_ctf_ignore_frags");
 404                 BADCVAR("g_ctf_win_mode");
 405                 BADCVAR("g_domination_point_limit");
 406                 BADCVAR("g_fullbrightitems");
 407                 BADCVAR("g_fullbrightplayers");
 408                 BADCVAR("g_keyhunt_point_limit");
 409                 BADCVAR("g_keyhunt_teams_override");
 410                 BADCVAR("g_lms_lives_override");
 411                 BADCVAR("g_maplist");
 412                 BADCVAR("g_maplist_check_waypoints");
 413                 BADCVAR("g_maplist_mostrecent_count");
 414                 BADCVAR("g_maplist_shuffle");
 415                 BADCVAR("g_maplist_votable");
 416                 BADCVAR("g_maplist_votable_abstain");
 417                 BADCVAR("g_maplist_votable_nodetail");
 418                 BADCVAR("g_maplist_votable_suggestions");
 419                 BADCVAR("g_minstagib");
 420                 BADCVAR("g_nexball_goallimit");
 421                 BADCVAR("g_runematch_point_limit");
 422                 BADCVAR("g_start_delay");
 423                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 424                 BADCVAR("hostname");
 425                 BADCVAR("log_file");
 426                 BADCVAR("maxplayers");
 427                 BADCVAR("minplayers");
 428                 BADCVAR("net_address");
 429                 BADCVAR("port");
 430                 BADCVAR("rcon_password");
 431                 BADCVAR("rcon_restricted_commands");
 432                 BADCVAR("rcon_restricted_password");
 433                 BADCVAR("skill");
 434                 BADCVAR("sv_adminnick");
 435                 BADCVAR("sv_autoscreenshot");
 436                 BADCVAR("sv_curl_defaulturl");
 437                 BADCVAR("sv_defaultcharacter");
 438                 BADCVAR("sv_defaultplayercolors");
 439                 BADCVAR("sv_defaultplayermodel");
 440                 BADCVAR("sv_defaultplayerskin");
 441                 BADCVAR("sv_maxidle");
 442                 BADCVAR("sv_maxrate");
 443                 BADCVAR("sv_motd");
 444                 BADCVAR("sv_public");
 445                 BADCVAR("sv_ready_restart");
 446                 BADCVAR("sv_status_privacy");
 447                 BADCVAR("sv_vote_call");
 448                 BADCVAR("sv_vote_commands");
 449                 BADCVAR("sv_vote_majority_factor");
 450                 BADCVAR("sv_vote_master");
 451                 BADCVAR("sv_vote_master_commands");
 452                 BADCVAR("sv_vote_master_password");
 453                 BADCVAR("sv_vote_simple_majority_factor");
 454                 BADCVAR("timelimit_override");
 455
 456                 if(autocvar_g_minstagib)
 457                 {
 458                         BADCVAR("g_grappling_hook");
 459                         BADCVAR("g_jetpack");
 460                 }
 461 #undef BADPREFIX
 462 #undef BADCVAR
 463
 464                 if(pureadding)
 465                 {
 466                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 467                         if(strlen(cvar_purechanges) > 16384)
 468                         {
 469                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 470                                 pureadding = 0;
 471                         }
 472                 }
 473                 ++cvar_purechanges_count;
 474                 // WARNING: this variable is used for the server list
 475                 // NEVER dare to skip this code!
 476                 // Hacks to intentionally appearing as "pure server" even though you DO have
 477                 // modified settings may be punished by removal from the server list.
 478                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 479                 // though.
 480         }
 481         buf_del(h);
 482         if(cvar_changes == "")
 483                 cvar_changes = "// this server runs at default server settings\n";
 484         else
 485                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 486         cvar_changes = strzone(cvar_changes);
 487         if(cvar_purechanges == "")
 488                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 489         else
 490                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 491         cvar_purechanges = strzone(cvar_purechanges);
 492 }
 493
 494 void detect_maptype()
 495 {
 496 #if 0
 497         vector o, v;
 498         float i;
 499
 500         for(;;)
 501         {
 502                 o = world.mins;
 503                 o_x += random() * (world.maxs_x - world.mins_x);
 504                 o_y += random() * (world.maxs_y - world.mins_y);
 505                 o_z += random() * (world.maxs_z - world.mins_z);
 506
 507                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 508                 if(trace_fraction == 1)
 509                         continue;
 510
 511                 v = trace_endpos;
 512
 513                 for(i = 0; i < 64; i += 4)
 514                 {
 515                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 516         if(trace_fraction == 1)
 517                 continue;
 518                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 519                 }
 520
 521                 break;
 522         }
 523 #endif
 524 }
 525
 526 entity randomseed;
 527 float RandomSeed_Send(entity to, float sf)
 528 {
 529         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 530         WriteShort(MSG_ENTITY, self.cnt);
 531         return TRUE;
 532 }
 533 void RandomSeed_Think()
 534 {
 535         self.cnt = bound(0, floor(random() * 65536), 65535);
 536         self.nextthink = time + 5;
 537
 538         self.SendFlags |= 1;
 539 }
 540 void RandomSeed_Spawn()
 541 {
 542         randomseed = spawn();
 543         randomseed.think = RandomSeed_Think;
 544         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 545
 546         entity oldself;
 547         oldself = self;
 548         self = randomseed;
 549         self.think(); // sets random seed and nextthink
 550         self = oldself;
 551 }
 552
 553 void spawnfunc___init_dedicated_server(void)
 554 {
 555         // handler for _init/_init map (only for dedicated server initialization)
 556
 557         world_initialized = -1; // don't complain
 558         cvar = cvar_normal;
 559         cvar_string = cvar_string_normal;
 560         cvar_set = cvar_set_normal;
 561
 562         remove = remove_unsafely;
 563
 564         entity e;
 565         e = spawn();
 566         e.think = GotoFirstMap;
 567         e.nextthink = time; // this is usually 1 at this point
 568
 569         e = spawn();
 570         e.classname = "info_player_deathmatch"; // safeguard against player joining
 571
 572         self.classname = "worldspawn"; // safeguard against various stuff ;)
 573
 574         MapInfo_Enumerate();
 575         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 576 }
 577
 578 void Map_MarkAsRecent(string m);
 579 float world_already_spawned;
 580 void RegisterWeapons();
 581 void Nagger_Init();
 582 void ClientInit_Spawn();
 583 void WeaponStats_Init();
 584 void WeaponStats_Shutdown();
 585 void spawnfunc_worldspawn (void)
 586 {
 587         float fd, l, i, j, n;
 588         string s, col;
 589
 590         cvar = cvar_normal;
 591         cvar_string = cvar_string_normal;
 592         cvar_set = cvar_set_normal;
 593
 594         if(world_already_spawned)
 595                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 596         world_already_spawned = TRUE;
 597
 598         remove = remove_safely; // during spawning, watch what you remove!
 599
 600         check_unacceptable_compiler_bugs();
 601
 602         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 603
 604         compressShortVector_init();
 605
 606         allowed_to_spawn = TRUE;
 607
 608         local entity head;
 609         head = nextent(world);
 610         maxclients = 0;
 611         while(head)
 612         {
 613                 ++maxclients;
 614                 head = nextent(head);
 615         }
 616
 617         // needs to be done so early as they would still spawn
 618         RegisterWeapons();
 619
 620         ServerProgsDB = db_load("server.db");
 621
 622         TemporaryDB = db_create();
 623
 624         // 0 normal
 625         lightstyle(0, "m");
 626
 627         // 1 FLICKER (first variety)
 628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 629
 630         // 2 SLOW STRONG PULSE
 631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 632
 633         // 3 CANDLE (first variety)
 634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 635
 636         // 4 FAST STROBE
 637         lightstyle(4, "mamamamamama");
 638
 639         // 5 GENTLE PULSE 1
 640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 641
 642         // 6 FLICKER (second variety)
 643         lightstyle(6, "nmonqnmomnmomomno");
 644
 645         // 7 CANDLE (second variety)
 646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 647
 648         // 8 CANDLE (third variety)
 649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 650
 651         // 9 SLOW STROBE (fourth variety)
 652         lightstyle(9, "aaaaaaaazzzzzzzz");
 653
 654         // 10 FLUORESCENT FLICKER
 655         lightstyle(10, "mmamammmmammamamaaamammma");
 656
 657         // 11 SLOW PULSE NOT FADE TO BLACK
 658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 659
 660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 661
 662         // 63 testing
 663         lightstyle(63, "a");
 664
 665         if(autocvar_g_campaign)
 666                 CampaignPreInit();
 667
 668         Map_MarkAsRecent(mapname);
 669
 670         precache_model ("null"); // we need this one before InitGameplayMode
 671         InitGameplayMode();
 672         readlevelcvars();
 673         GrappleHookInit();
 674         ElectroInit();
 675         LaserInit();
 676
 677         player_count = 0;
 678         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 679         if(bot_waypoints_for_items == 1)
 680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 681                         bot_waypoints_for_items = 0;
 682
 683         // for setting by mapinfo
 684         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 685         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 686
 687         precache();
 688
 689         WaypointSprite_Init();
 690
 691         //if (g_domination)
 692         //      dom_init();
 693
 694         GameLogInit(); // prepare everything
 695         if(autocvar_sv_eventlog)
 696         {
 697                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 698                 s = strcat(s, ftos(random()));
 699                 matchid = strzone(s);
 700
 701                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 702                 s = ":gameinfo:mutators:LIST";
 703
 704                 ret_string = s;
 705                 MUTATOR_CALLHOOK(BuildMutatorsString);
 706                 s = ret_string;
 707
 708                 // simple, probably not good in the mutator system
 709                 if(autocvar_g_grappling_hook)
 710                         s = strcat(s, ":grappling_hook");
 711
 712                 // initialiation stuff, not good in the mutator system
 713                 if(!autocvar_g_use_ammunition)
 714                         s = strcat(s, ":no_use_ammunition");
 715
 716                 // initialiation stuff, not good in the mutator system
 717                 if(!autocvar_g_pickup_items)
 718                         s = strcat(s, ":no_pickup_items");
 719
 720                 // initialiation stuff, not good in the mutator system
 721                 if(autocvar_g_weaponarena != "0")
 722                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 723
 724                 // TODO to mutator system
 725                 if(autocvar_g_norecoil)
 726                         s = strcat(s, ":norecoil");
 727
 728                 // TODO to mutator system
 729                 if(autocvar_g_midair)
 730                         s = strcat(s, ":midair");
 731
 732                 // TODO to mutator system
 733                 if(autocvar_g_minstagib)
 734                         s = strcat(s, ":minstagib");
 735
 736                 GameLogEcho(s);
 737                 GameLogEcho(":gameinfo:end");
 738         }
 739         else
 740                 matchid = strzone(ftos(random()));
 741
 742         cvar_set("nextmap", "");
 743
 744         SetDefaultAlpha();
 745
 746         if(autocvar_g_campaign)
 747                 CampaignPostInit();
 748
 749         fteqcc_testbugs();
 750
 751         Ban_LoadBans();
 752
 753         MapInfo_Enumerate();
 754         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 755
 756         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 757         {
 758                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 759                 if(fd != -1)
 760                 {
 761                         while((s = fgets(fd)))
 762                         {
 763                                 l = tokenize_console(s);
 764                                 if(l < 2)
 765                                         continue;
 766                                 if(argv(0) == "cd")
 767                                 {
 768                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  cdtrack ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) == "fog")
 772                                 {
 773                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 774                                         print("  \"fog\" \"", s, "\"\n");
 775                                 }
 776                                 else if(argv(0) == "set")
 777                                 {
 778                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 779                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 780                                 }
 781                                 else if(argv(0) != "//")
 782                                 {
 783                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 784                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 785                                 }
 786                         }
 787                         fclose(fd);
 788                 }
 789         }
 790
 791         WeaponStats_Init();
 792
 793         addstat(STAT_WEAPONS, AS_INT, weapons);
 794         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 795         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 796         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 797         Nagger_Init();
 798
 799         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 800         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 801         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 802         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 803         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 804         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 805         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 806         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 807
 808         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 809         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 810
 811         if(g_ca || g_freezetag)
 812         {
 813                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 814                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 815                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 816                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 817         }
 818         if(g_freezetag)
 819         {
 820                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 821                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 822         }
 823
 824         // g_movementspeed hack
 825         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 826         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 827         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 828         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 829
 830         next_pingtime = time + 5;
 831
 832         detect_maptype();
 833
 834         lsmaps_reply = "^7Maps available: ";
 835         lsnewmaps_reply = "^7Maps without a record set: ";
 836         for(i = 0, j = 0; i < MapInfo_count; ++i)
 837         {
 838                 if(MapInfo_Get_ByID(i))
 839                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 840                         {
 841                                 if(mod(i, 2))
 842                                         col = "^2";
 843                                 else
 844                                         col = "^3";
 845                                 ++j;
 846                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 847                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 848                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 849                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 850                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 851                         }
 852         }
 853         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 854         if (!g_race && !g_cts)
 855                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 856         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 857
 858         maplist_reply = "^7Maps in list: ";
 859         n = tokenize_console(autocvar_g_maplist);
 860         for(i = 0, j = 0; i < n; ++i)
 861         {
 862                 if(MapInfo_CheckMap(argv(i)))
 863                 {
 864                         if(mod(j, 2))
 865                                 col = "^2";
 866                         else
 867                                 col = "^3";
 868                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 869                         ++j;
 870                 }
 871         }
 872         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 873         MapInfo_ClearTemps();
 874
 875         for(i = 0; i < 10; ++i)
 876         {
 877                 records_reply[i] = strzone(getrecords(i));
 878         }
 879         if(g_cts)
 880                 ladder_reply = strzone(getladder());
 881
 882         rankings_reply = strzone(getrankings());
 883
 884         ClientInit_Spawn();
 885         RandomSeed_Spawn();
 886         PingPLReport_Spawn();
 887
 888         CheatInit();
 889
 890         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 891
 892         // fill sv_curl_serverpackages from .serverpackage files
 893         if(autocvar_sv_curl_serverpackages_auto)
 894         {
 895                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 896                 s = "";
 897                 if(fd >= 0)
 898                 {
 899                         j = search_getsize(fd);
 900                         for(i = 0; i < j; ++i)
 901                                 s = strcat(s, " ", search_getfilename(fd, i));
 902                         search_end(fd);
 903                 }
 904                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 905         }
 906
 907         PlayerStats_Init();
 908
 909         world_initialized = 1;
 910 }
 911
 912 void spawnfunc_light (void)
 913 {
 914         //makestatic (self); // Who the f___ did that?
 915         remove(self);
 916 }
 917
 918 float TryFile( string pFilename )
 919 {
 920         local float lHandle;
 921         dprint("TryFile(\"", pFilename, "\")\n");
 922         lHandle = fopen( pFilename, FILE_READ );
 923         if( lHandle != -1 ) {
 924                 fclose( lHandle );
 925                 return TRUE;
 926         } else {
 927                 return FALSE;
 928         }
 929 };
 930
 931 string GetGametype()
 932 {
 933         return GametypeNameFromType(game);
 934 }
 935
 936 string getmapname_stored;
 937 string GetMapname()
 938 {
 939         return mapname;
 940 }
 941
 942 float Map_Count, Map_Current;
 943 string Map_Current_Name;
 944
 945 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 946 float GetMaplistPosition()
 947 {
 948         float pos, idx;
 949         string map;
 950
 951         map = GetMapname();
 952         idx = autocvar_g_maplist_index;
 953
 954         if(idx >= 0)
 955                 if(idx < Map_Count)
 956                         if(map == argv(idx))
 957                                 return idx;
 958
 959         for(pos = 0; pos < Map_Count; ++pos)
 960                 if(map == argv(pos))
 961                         return pos;
 962
 963         // resume normal maplist rotation if current map is not in g_maplist
 964         return idx;
 965 }
 966
 967 float MapHasRightSize(string map)
 968 {
 969         float fh;
 970         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 971         if(autocvar_g_maplist_check_waypoints)
 972         {
 973                 dprint("checkwp "); dprint(map);
 974                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 975                 if(fh < 0)
 976                 {
 977                         dprint(": no waypoints\n");
 978                         return FALSE;
 979                 }
 980                 dprint(": has waypoints\n");
 981                 fclose(fh);
 982         }
 983
 984         // open map size restriction file
 985         dprint("opensize "); dprint(map);
 986         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 987         if(fh >= 0)
 988         {
 989                 float mapmin, mapmax;
 990                 dprint(": ok, ");
 991                 mapmin = stof(fgets(fh));
 992                 mapmax = stof(fgets(fh));
 993                 fclose(fh);
 994                 if(player_count < mapmin)
 995                 {
 996                         dprint("not enough\n");
 997                         return FALSE;
 998                 }
 999                 if(player_count > mapmax)
1000                 {
1001                         dprint("too many\n");
1002                         return FALSE;
1003                 }
1004                 dprint("right size\n");
1005                 return TRUE;
1006         }
1007         dprint(": not found\n");
1008         return TRUE;
1009 }
1010
1011 string Map_Filename(float position)
1012 {
1013         return strcat("maps/", argv(position), ".bsp");
1014 }
1015
1016 string strwords(string s, float w)
1017 {
1018         float endpos;
1019         for(endpos = 0; w && endpos >= 0; --w)
1020                 endpos = strstrofs(s, " ", endpos + 1);
1021         if(endpos < 0)
1022                 return s;
1023         else
1024                 return substring(s, 0, endpos);
1025 }
1026
1027 float strhasword(string s, string w)
1028 {
1029         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1030 }
1031
1032 void Map_MarkAsRecent(string m)
1033 {
1034         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1035 }
1036
1037 float Map_IsRecent(string m)
1038 {
1039         return strhasword(autocvar_g_maplist_mostrecent, m);
1040 }
1041
1042 float Map_Check(float position, float pass)
1043 {
1044         string filename;
1045         string map_next;
1046         map_next = argv(position);
1047         if(pass <= 1)
1048         {
1049                 if(Map_IsRecent(map_next))
1050                         return 0;
1051         }
1052         filename = Map_Filename(position);
1053         if(MapInfo_CheckMap(map_next))
1054         {
1055                 if(pass == 2)
1056                         return 1;
1057                 if(MapHasRightSize(map_next))
1058                         return 1;
1059                 return 0;
1060         }
1061         else
1062                 dprint( "Couldn't select '", filename, "'..\n" );
1063
1064         return 0;
1065 }
1066
1067 void Map_Goto_SetStr(string nextmapname)
1068 {
1069         if(getmapname_stored != "")
1070                 strunzone(getmapname_stored);
1071         if(nextmapname == "")
1072                 getmapname_stored = "";
1073         else
1074                 getmapname_stored = strzone(nextmapname);
1075 }
1076
1077 void Map_Goto_SetFloat(float position)
1078 {
1079         cvar_set("g_maplist_index", ftos(position));
1080         Map_Goto_SetStr(argv(position));
1081 }
1082
1083 void GameResetCfg()
1084 {
1085         // settings persist, except...
1086         localcmd("\nsettemp_restore\n");
1087 };
1088
1089 void Map_Goto()
1090 {
1091         GameResetCfg();
1092         MapInfo_LoadMap(getmapname_stored);
1093 }
1094
1095 // return codes of map selectors:
1096 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1097 //   -2 = permanent failure
1098 float() MaplistMethod_Iterate = // usual method
1099 {
1100         float pass, i;
1101
1102         for(pass = 1; pass <= 2; ++pass)
1103         {
1104                 for(i = 1; i < Map_Count; ++i)
1105                 {
1106                         float mapindex;
1107                         mapindex = mod(i + Map_Current, Map_Count);
1108                         if(Map_Check(mapindex, pass))
1109                                 return mapindex;
1110                 }
1111         }
1112         return -1;
1113 }
1114
1115 float() MaplistMethod_Repeat = // fallback method
1116 {
1117         if(Map_Check(Map_Current, 2))
1118                 return Map_Current;
1119         return -2;
1120 }
1121
1122 float() MaplistMethod_Random = // random map selection
1123 {
1124         float i, imax;
1125
1126         imax = 42;
1127
1128         for(i = 0; i <= imax; ++i)
1129         {
1130                 float mapindex;
1131                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1132                 if(Map_Check(mapindex, 1))
1133                         return mapindex;
1134         }
1135         return -1;
1136 }
1137
1138 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1139 // the exponent sets a bias on the map selection:
1140 // the higher the exponent, the less likely "shortly repeated" same maps are
1141 {
1142         float i, j, imax, insertpos;
1143
1144         imax = 42;
1145
1146         for(i = 0; i <= imax; ++i)
1147         {
1148                 string newlist;
1149
1150                 // now reinsert this at another position
1151                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1152                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1153                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1154                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1155
1156                 // insert the current map there
1157                 newlist = "";
1158                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1159                         newlist = strcat(newlist, " ", argv(j));
1160                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1161                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1162                         newlist = strcat(newlist, " ", argv(j));
1163                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1164                 cvar_set("g_maplist", newlist);
1165                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1166
1167                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1168                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1169                 if(Map_Check(Map_Current, 1))
1170                         return Map_Current;
1171         }
1172         return -1;
1173 }
1174
1175 void Maplist_Init()
1176 {
1177         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1178         if(Map_Count == 0)
1179         {
1180                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1181                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1182                 if(autocvar_g_maplist_shuffle)
1183                         ShuffleMaplist();
1184                 localcmd("\nmenu_cmd sync\n");
1185                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1186         }
1187         if(Map_Count == 0)
1188                 error("empty maplist, cannot select a new map");
1189         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1190
1191         if(Map_Current_Name)
1192                 strunzone(Map_Current_Name);
1193         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1194         // this may or may not be correct, but who cares, in the worst case a map
1195         // isn't chosen in the first pass that should have been
1196 }
1197
1198 string GetNextMap()
1199 {
1200         float nextMap;
1201
1202         Maplist_Init();
1203         nextMap = -1;
1204
1205         if(nextMap == -1)
1206                 if(autocvar_g_maplist_shuffle > 0)
1207                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1208
1209         if(nextMap == -1)
1210                 if(autocvar_g_maplist_selectrandom)
1211                         nextMap = MaplistMethod_Random();
1212
1213         if(nextMap == -1)
1214                 nextMap = MaplistMethod_Iterate();
1215
1216         if(nextMap == -1)
1217                 nextMap = MaplistMethod_Repeat();
1218
1219         if(nextMap >= 0)
1220         {
1221                 Map_Goto_SetFloat(nextMap);
1222                 return getmapname_stored;
1223         }
1224
1225         return "";
1226 };
1227
1228 float DoNextMapOverride()
1229 {
1230         if(autocvar_g_campaign)
1231         {
1232                 CampaignPostIntermission();
1233                 alreadychangedlevel = TRUE;
1234                 return TRUE;
1235         }
1236         if(autocvar_quit_when_empty)
1237         {
1238                 if(player_count <= currentbots)
1239                 {
1240                         localcmd("quit\n");
1241                         alreadychangedlevel = TRUE;
1242                         return TRUE;
1243                 }
1244         }
1245         if(autocvar_quit_and_redirect != "")
1246         {
1247                 redirection_target = strzone(autocvar_quit_and_redirect);
1248                 alreadychangedlevel = TRUE;
1249                 return TRUE;
1250         }
1251         if (autocvar_samelevel) // if samelevel is set, stay on same level
1252         {
1253                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1254                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1255                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1256                 localcmd("restart\n");
1257                 //changelevel (mapname);
1258                 alreadychangedlevel = TRUE;
1259                 return TRUE;
1260         }
1261         if(autocvar_nextmap != "")
1262                 if(MapInfo_CheckMap(autocvar_nextmap))
1263                 {
1264                         Map_Goto_SetStr(autocvar_nextmap);
1265                         Map_Goto();
1266                         alreadychangedlevel = TRUE;
1267                         return TRUE;
1268                 }
1269         if(autocvar_lastlevel)
1270         {
1271                 GameResetCfg();
1272                 localcmd("set lastlevel 0\ntogglemenu\n");
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         return FALSE;
1277 };
1278
1279 void GotoNextMap()
1280 {
1281         //local string nextmap;
1282         //local float n, nummaps;
1283         //local string s;
1284         if (alreadychangedlevel)
1285                 return;
1286         alreadychangedlevel = TRUE;
1287
1288         {
1289                 string nextMap;
1290                 float allowReset;
1291
1292                 for(allowReset = 1; allowReset >= 0; --allowReset)
1293                 {
1294                         nextMap = GetNextMap();
1295                         if(nextMap != "")
1296                                 break;
1297
1298                         if(allowReset)
1299                         {
1300                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1301                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1302                                 if(autocvar_g_maplist_shuffle)
1303                                         ShuffleMaplist();
1304                                 localcmd("\nmenu_cmd sync\n");
1305                         }
1306                         else
1307                         {
1308                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1309                         }
1310                 }
1311                 Map_Goto();
1312         }
1313 };
1314
1315
1316 /*
1317 ============
1318 IntermissionThink
1319
1320 When the player presses attack or jump, change to the next level
1321 ============
1322 */
1323 .float autoscreenshot;
1324 void() MapVote_Start;
1325 void() MapVote_Think;
1326 float mapvote_initialized;
1327 void IntermissionThink()
1328 {
1329         FixIntermissionClient(self);
1330
1331         if(autocvar_sv_autoscreenshot)
1332         if(self.autoscreenshot > 0)
1333         if(time > self.autoscreenshot)
1334         {
1335                 self.autoscreenshot = -1;
1336                 if(clienttype(self) == CLIENTTYPE_REAL)
1337                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1338                 return;
1339         }
1340
1341         if (time < intermission_exittime)
1342                 return;
1343
1344         if(!mapvote_initialized)
1345                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1346                         return;
1347
1348         MapVote_Start();
1349 };
1350
1351 /*
1352 ============
1353 FindIntermission
1354
1355 Returns the entity to view from
1356 ============
1357 */
1358 /*
1359 entity FindIntermission()
1360 {
1361         local   entity spot;
1362         local   float cyc;
1363
1364 // look for info_intermission first
1365         spot = find (world, classname, "info_intermission");
1366         if (spot)
1367         {       // pick a random one
1368                 cyc = random() * 4;
1369                 while (cyc > 1)
1370                 {
1371                         spot = find (spot, classname, "info_intermission");
1372                         if (!spot)
1373                                 spot = find (spot, classname, "info_intermission");
1374                         cyc = cyc - 1;
1375                 }
1376                 return spot;
1377         }
1378
1379 // then look for the start position
1380         spot = find (world, classname, "info_player_start");
1381         if (spot)
1382                 return spot;
1383
1384 // testinfo_player_start is only found in regioned levels
1385         spot = find (world, classname, "testplayerstart");
1386         if (spot)
1387                 return spot;
1388
1389 // then look for the start position
1390         spot = find (world, classname, "info_player_deathmatch");
1391         if (spot)
1392                 return spot;
1393
1394         //objerror ("FindIntermission: no spot");
1395         return world;
1396 };
1397 */
1398
1399 /*
1400 ===============================================================================
1401
1402 RULES
1403
1404 ===============================================================================
1405 */
1406
1407 void DumpStats(float final)
1408 {
1409         float file;
1410         string s;
1411         float to_console;
1412         float to_eventlog;
1413         float to_file;
1414         float i;
1415         entity e;
1416
1417         to_console = autocvar_sv_logscores_console;
1418         to_eventlog = autocvar_sv_eventlog;
1419         to_file = autocvar_sv_logscores_file;
1420
1421         if(!final)
1422         {
1423                 to_console = TRUE; // always print printstats replies
1424                 to_eventlog = FALSE; // but never print them to the event log
1425         }
1426
1427         if(to_eventlog)
1428                 if(autocvar_sv_eventlog_console)
1429                         to_console = FALSE; // otherwise we get the output twice
1430
1431         if(final)
1432                 s = ":scores:";
1433         else
1434                 s = ":status:";
1435         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1436
1437         if(to_console)
1438                 print(s, "\n");
1439         if(to_eventlog)
1440                 GameLogEcho(s);
1441         if(to_file)
1442         {
1443                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1444                 if(file == -1)
1445                         to_file = FALSE;
1446                 else
1447                         fputs(file, strcat(s, "\n"));
1448         }
1449
1450         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1451         if(to_console)
1452                 print(s, "\n");
1453         if(to_eventlog)
1454                 GameLogEcho(s);
1455         if(to_file)
1456                 fputs(file, strcat(s, "\n"));
1457
1458         FOR_EACH_CLIENT(other)
1459         {
1460                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1461                 {
1462                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1463                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1464                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1465                                 s = strcat(s, ftos(other.team), ":");
1466                         else
1467                                 s = strcat(s, "spectator:");
1468
1469                         if(to_console)
1470                                 print(s, other.netname, "\n");
1471                         if(to_eventlog)
1472                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1473                         if(to_file)
1474                                 fputs(file, strcat(s, other.netname, "\n"));
1475                 }
1476         }
1477
1478         if(teams_matter)
1479         {
1480                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1481                 if(to_console)
1482                         print(s, "\n");
1483                 if(to_eventlog)
1484                         GameLogEcho(s);
1485                 if(to_file)
1486                         fputs(file, strcat(s, "\n"));
1487
1488                 for(i = 1; i < 16; ++i)
1489                 {
1490                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1491                         s = strcat(s, ":", ftos(i));
1492                         if(to_console)
1493                                 print(s, "\n");
1494                         if(to_eventlog)
1495                                 GameLogEcho(s);
1496                         if(to_file)
1497                                 fputs(file, strcat(s, "\n"));
1498                 }
1499         }
1500
1501         if(to_console)
1502                 print(":end\n");
1503         if(to_eventlog)
1504                 GameLogEcho(":end");
1505         if(to_file)
1506         {
1507                 fputs(file, ":end\n");
1508                 fclose(file);
1509         }
1510
1511         // send statistics
1512         FOR_EACH_CLIENT(e)
1513                 PlayerStats_AddGlobalInfo(e);
1514         PlayerStats_Shutdown();
1515 }
1516
1517 void FixIntermissionClient(entity e)
1518 {
1519         string s;
1520         if(!e.autoscreenshot) // initial call
1521         {
1522                 e.angles = e.v_angle;
1523                 e.angles_x = -e.angles_x;
1524                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1525                 e.health = -2342;
1526                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1527                 e.solid = SOLID_NOT;
1528                 e.movetype = MOVETYPE_NONE;
1529                 e.takedamage = DAMAGE_NO;
1530                 if(e.weaponentity)
1531                 {
1532                         e.weaponentity.effects = EF_NODRAW;
1533                         if (e.weaponentity.weaponentity)
1534                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1535                 }
1536                 if(clienttype(e) == CLIENTTYPE_REAL)
1537                 {
1538                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1539                         s = autocvar_sv_intermission_cdtrack;
1540                         if(s != "")
1541                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1542                         msg_entity = e;
1543                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1544                 }
1545         }
1546
1547         //e.velocity = '0 0 0';
1548         //e.fixangle = TRUE;
1549
1550         // TODO halt weapon animation
1551 }
1552
1553
1554 /*
1555 go to the next level for deathmatch
1556 only called if a time or frag limit has expired
1557 */
1558 void NextLevel()
1559 {
1560         gameover = TRUE;
1561
1562         intermission_running = 1;
1563
1564 // enforce a wait time before allowing changelevel
1565         if(player_count > 0)
1566                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1567         else
1568                 intermission_exittime = -1;
1569
1570         /*
1571         WriteByte (MSG_ALL, SVC_CDTRACK);
1572         WriteByte (MSG_ALL, 3);
1573         WriteByte (MSG_ALL, 3);
1574         // done in FixIntermission
1575         */
1576
1577         //pos = FindIntermission ();
1578
1579         VoteReset();
1580
1581         DumpStats(TRUE);
1582
1583         if(autocvar_sv_eventlog)
1584                 GameLogEcho(":gameover");
1585
1586         GameLogClose();
1587
1588         FOR_EACH_PLAYER(other) {
1589                 FixIntermissionClient(other);
1590                 if(other.winning)
1591                         bprint(other.netname, " ^7wins.\n");
1592         }
1593
1594         if(autocvar_g_campaign)
1595                 CampaignPreIntermission();
1596
1597         localcmd("\nsv_hook_gameend\n");
1598 }
1599
1600 /*
1601 ============
1602 CheckRules_Player
1603
1604 Exit deathmatch games upon conditions
1605 ============
1606 */
1607 void CheckRules_Player()
1608 {
1609         if (gameover)   // someone else quit the game already
1610                 return;
1611
1612         if(self.deadflag == DEAD_NO)
1613                 self.play_time += frametime;
1614
1615         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1616         //   (div0: and that in CheckRules_World please)
1617 };
1618
1619 float checkrules_equality;
1620 float checkrules_suddendeathwarning;
1621 float checkrules_suddendeathend;
1622 float checkrules_overtimesadded; //how many overtimes have been already added
1623
1624 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1625 float WINNING_YES = 1; // winner found
1626 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1627 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1628
1629 float InitiateSuddenDeath()
1630 {
1631         // Check first whether normal overtimes could be added before initiating suddendeath mode
1632         // - for this timelimit_overtime needs to be >0 of course
1633         // - also check the winning condition calculated in the previous frame and only add normal overtime
1634         //   again, if at the point at which timelimit would be extended again, still no winner was found
1635         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1636         {
1637                 return 1; // need to call InitiateOvertime later
1638         }
1639         else
1640         {
1641                 if(!checkrules_suddendeathend)
1642                 {
1643                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1644                         if(g_race && !g_race_qualifying)
1645                                 race_StartCompleting();
1646                 }
1647                 return 0;
1648         }
1649 }
1650
1651 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1652 {
1653         ++checkrules_overtimesadded;
1654         //add one more overtime by simply extending the timelimit
1655         float tl;
1656         tl = autocvar_timelimit;
1657         tl += autocvar_timelimit_overtime;
1658         cvar_set("timelimit", ftos(tl));
1659         string minutesPlural;
1660         if (autocvar_timelimit_overtime == 1)
1661                 minutesPlural = " ^3minute";
1662         else
1663                 minutesPlural = " ^3minutes";
1664
1665         bcenterprint(
1666                 strcat(
1667                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1668                         ftos(autocvar_timelimit_overtime),
1669                         minutesPlural,
1670                         " to the game!"
1671                 )
1672         );
1673 }
1674
1675 float GetWinningCode(float fraglimitreached, float equality)
1676 {
1677         if(autocvar_g_campaign == 1)
1678                 if(fraglimitreached)
1679                         return WINNING_YES;
1680                 else
1681                         return WINNING_NO;
1682
1683         else
1684                 if(equality)
1685                         if(fraglimitreached)
1686                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1687                         else
1688                                 return WINNING_NEVER;
1689                 else
1690                         if(fraglimitreached)
1691                                 return WINNING_YES;
1692                         else
1693                                 return WINNING_NO;
1694 }
1695
1696 // set the .winning flag for exactly those players with a given field value
1697 void SetWinners(.float field, float value)
1698 {
1699         entity head;
1700         FOR_EACH_PLAYER(head)
1701                 head.winning = (head.field == value);
1702 }
1703
1704 // set the .winning flag for those players with a given field value
1705 void AddWinners(.float field, float value)
1706 {
1707         entity head;
1708         FOR_EACH_PLAYER(head)
1709                 if(head.field == value)
1710                         head.winning = 1;
1711 }
1712
1713 // clear the .winning flags
1714 void ClearWinners(void)
1715 {
1716         entity head;
1717         FOR_EACH_PLAYER(head)
1718                 head.winning = 0;
1719 }
1720
1721 // Onslaught winning condition:
1722 // game terminates if only one team has a working generator (or none)
1723 float WinningCondition_Onslaught()
1724 {
1725         entity head;
1726         local float t1, t2, t3, t4;
1727
1728         WinningConditionHelper(); // set worldstatus
1729
1730         if(inWarmupStage)
1731                 return WINNING_NO;
1732
1733         // first check if the game has ended
1734         t1 = t2 = t3 = t4 = 0;
1735         head = find(world, classname, "onslaught_generator");
1736         while (head)
1737         {
1738                 if (head.health > 0)
1739                 {
1740                         if (head.team == COLOR_TEAM1) t1 = 1;
1741                         if (head.team == COLOR_TEAM2) t2 = 1;
1742                         if (head.team == COLOR_TEAM3) t3 = 1;
1743                         if (head.team == COLOR_TEAM4) t4 = 1;
1744                 }
1745                 head = find(head, classname, "onslaught_generator");
1746         }
1747         if (t1 + t2 + t3 + t4 < 2)
1748         {
1749                 // game over, only one team remains (or none)
1750                 ClearWinners();
1751                 if (t1) SetWinners(team, COLOR_TEAM1);
1752                 if (t2) SetWinners(team, COLOR_TEAM2);
1753                 if (t3) SetWinners(team, COLOR_TEAM3);
1754                 if (t4) SetWinners(team, COLOR_TEAM4);
1755                 dprint("Have a winner, ending game.\n");
1756                 return WINNING_YES;
1757         }
1758
1759         // Two or more teams remain
1760         return WINNING_NO;
1761 }
1762
1763 float LMS_NewPlayerLives()
1764 {
1765         float fl;
1766         fl = autocvar_fraglimit;
1767         if(fl == 0)
1768                 fl = 999;
1769
1770         // first player has left the game for dying too much? Nobody else can get in.
1771         if(lms_lowest_lives < 1)
1772                 return 0;
1773
1774         if(!autocvar_g_lms_join_anytime)
1775                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1776                         return 0;
1777
1778         return bound(1, lms_lowest_lives, fl);
1779 }
1780
1781 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1782 // they win. Otherwise the defending team wins once the timelimit passes.
1783 void assault_new_round();
1784 float WinningCondition_Assault()
1785 {
1786         local float status;
1787
1788         WinningConditionHelper(); // set worldstatus
1789
1790         status = WINNING_NO;
1791         // as the timelimit has not yet passed just assume the defending team will win
1792         if(assault_attacker_team == COLOR_TEAM1)
1793         {
1794                 SetWinners(team, COLOR_TEAM2);
1795         }
1796         else
1797         {
1798                 SetWinners(team, COLOR_TEAM1);
1799         }
1800
1801         local entity ent;
1802         ent = find(world, classname, "target_assault_roundend");
1803         if(ent)
1804         {
1805                 if(ent.winning) // round end has been triggered by attacking team
1806                 {
1807                         bprint("ASSAULT: round completed...\n");
1808                         SetWinners(team, assault_attacker_team);
1809
1810                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1811
1812                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1813                         {
1814                                 status = WINNING_YES;
1815                         }
1816                         else
1817                         {
1818                                 local entity oldself;
1819                                 oldself = self;
1820                                 self = ent;
1821                                 assault_new_round();
1822                                 self = oldself;
1823                         }
1824                 }
1825         }
1826
1827         return status;
1828 }
1829
1830 // LMS winning condition: game terminates if and only if there's at most one
1831 // one player who's living lives. Top two scores being equal cancels the time
1832 // limit.
1833 float WinningCondition_LMS()
1834 {
1835         entity head, head2;
1836         float have_player;
1837         float have_players;
1838         float l;
1839
1840         have_player = FALSE;
1841         have_players = FALSE;
1842         l = LMS_NewPlayerLives();
1843
1844         head = find(world, classname, "player");
1845         if(head)
1846                 have_player = TRUE;
1847         head2 = find(head, classname, "player");
1848         if(head2)
1849                 have_players = TRUE;
1850
1851         if(have_player)
1852         {
1853                 // we have at least one player
1854                 if(have_players)
1855                 {
1856                         // two or more active players - continue with the game
1857                 }
1858                 else
1859                 {
1860                         // exactly one player?
1861
1862                         ClearWinners();
1863                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1864
1865                         if(l)
1866                         {
1867                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1868                                 return WINNING_NO;
1869                         }
1870                         else
1871                         {
1872                                 // a winner!
1873                                 // and assign him his first place
1874                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1875                                 return WINNING_YES;
1876                         }
1877                 }
1878         }
1879         else
1880         {
1881                 // nobody is playing at all...
1882                 if(l)
1883                 {
1884                         // wait for players...
1885                 }
1886                 else
1887                 {
1888                         // SNAFU (maybe a draw game?)
1889                         ClearWinners();
1890                         dprint("No players, ending game.\n");
1891                         return WINNING_YES;
1892                 }
1893         }
1894
1895         // When we get here, we have at least two players who are actually LIVING,
1896         // now check if the top two players have equal score.
1897         WinningConditionHelper();
1898
1899         ClearWinners();
1900         if(WinningConditionHelper_winner)
1901                 WinningConditionHelper_winner.winning = TRUE;
1902         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1903                 return WINNING_NEVER;
1904
1905         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1906         return WINNING_NO;
1907 }
1908
1909 void ShuffleMaplist()
1910 {
1911         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1912 }
1913
1914 float leaderfrags;
1915 float WinningCondition_Scores(float limit, float leadlimit)
1916 {
1917         float limitreached;
1918
1919         // TODO make everything use THIS winning condition (except LMS)
1920         WinningConditionHelper();
1921
1922         if(teams_matter)
1923         {
1924                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1925                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1926                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1927                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1928         }
1929
1930         ClearWinners();
1931         if(WinningConditionHelper_winner)
1932                 WinningConditionHelper_winner.winning = 1;
1933         if(WinningConditionHelper_winnerteam >= 0)
1934                 SetWinners(team, WinningConditionHelper_winnerteam);
1935
1936         if(WinningConditionHelper_lowerisbetter)
1937         {
1938                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1939                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1940                 limit = -limit;
1941         }
1942
1943         if(WinningConditionHelper_zeroisworst)
1944                 leadlimit = 0; // not supported in this mode
1945
1946         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1947         // these modes always score in increments of 1, thus this makes sense
1948         {
1949                 if(leaderfrags != WinningConditionHelper_topscore)
1950                 {
1951                         leaderfrags = WinningConditionHelper_topscore;
1952
1953                         if (limit)
1954                         if (leaderfrags == limit - 1)
1955                                 Announce("1fragleft");
1956                         else if (leaderfrags == limit - 2)
1957                                 Announce("2fragsleft");
1958                         else if (leaderfrags == limit - 3)
1959                                 Announce("3fragsleft");
1960                 }
1961         }
1962
1963         limitreached = FALSE;
1964         if(limit)
1965                 if(WinningConditionHelper_topscore >= limit)
1966                         limitreached = TRUE;
1967         if(leadlimit)
1968         {
1969                 float leadlimitreached;
1970                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1971                 if(autocvar_leadlimit_and_fraglimit)
1972                         limitreached = (limitreached && leadlimitreached);
1973                 else
1974                         limitreached = (limitreached || leadlimitreached);
1975         }
1976
1977         return GetWinningCode(
1978                 WinningConditionHelper_topscore && limitreached,
1979                 WinningConditionHelper_equality
1980         );
1981 }
1982
1983 float WinningCondition_Race(float fraglimit)
1984 {
1985         float wc;
1986         entity p;
1987         float n, c;
1988
1989         n = 0;
1990         c = 0;
1991         FOR_EACH_PLAYER(p)
1992         {
1993                 ++n;
1994                 if(p.race_completed)
1995                         ++c;
1996         }
1997         if(n && (n == c))
1998                 return WINNING_YES;
1999         wc = WinningCondition_Scores(fraglimit, 0);
2000
2001         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2002         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2003         // do NOT support equality when the laps are all raced!
2004                 return WINNING_STARTSUDDENDEATHOVERTIME;
2005         else
2006                 return WINNING_NEVER;
2007         return wc;
2008 }
2009
2010 void ReadyRestart();
2011 float WinningCondition_QualifyingThenRace(float limit)
2012 {
2013         float wc;
2014         wc = WinningCondition_Scores(limit, 0);
2015
2016         // NEVER initiate overtime
2017         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2018         {
2019                 return WINNING_YES;
2020         }
2021
2022         return wc;
2023 }
2024
2025 float WinningCondition_RanOutOfSpawns()
2026 {
2027         entity head;
2028
2029         if(have_team_spawns <= 0)
2030                 return WINNING_NO;
2031
2032         if(!some_spawn_has_been_used)
2033                 return WINNING_NO;
2034
2035         team1_score = team2_score = team3_score = team4_score = 0;
2036
2037         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2038         {
2039                 if(head.team == COLOR_TEAM1)
2040                         team1_score = 1;
2041                 else if(head.team == COLOR_TEAM2)
2042                         team2_score = 1;
2043                 else if(head.team == COLOR_TEAM3)
2044                         team3_score = 1;
2045                 else if(head.team == COLOR_TEAM4)
2046                         team4_score = 1;
2047         }
2048
2049         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2050         {
2051                 if(head.team == COLOR_TEAM1)
2052                         team1_score = 1;
2053                 else if(head.team == COLOR_TEAM2)
2054                         team2_score = 1;
2055                 else if(head.team == COLOR_TEAM3)
2056                         team3_score = 1;
2057                 else if(head.team == COLOR_TEAM4)
2058                         team4_score = 1;
2059         }
2060
2061         ClearWinners();
2062         if(team1_score + team2_score + team3_score + team4_score == 0)
2063         {
2064                 checkrules_equality = TRUE;
2065                 return WINNING_YES;
2066         }
2067         else if(team1_score + team2_score + team3_score + team4_score == 1)
2068         {
2069                 float t, i;
2070                 if(team1_score) t = COLOR_TEAM1;
2071                 if(team2_score) t = COLOR_TEAM2;
2072                 if(team3_score) t = COLOR_TEAM3;
2073                 if(team4_score) t = COLOR_TEAM4;
2074                 CheckAllowedTeams(world);
2075                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2076                 {
2077                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2078                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2079                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2080                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2081                 }
2082
2083                 AddWinners(team, t);
2084                 return WINNING_YES;
2085         }
2086         else
2087                 return WINNING_NO;
2088 }
2089
2090 /*
2091 ============
2092 CheckRules_World
2093
2094 Exit deathmatch games upon conditions
2095 ============
2096 */
2097 void CheckRules_World()
2098 {
2099         float timelimit;
2100         float fraglimit;
2101         float leadlimit;
2102
2103         VoteThink();
2104         MapVote_Think();
2105
2106         SetDefaultAlpha();
2107
2108         /*
2109         MapVote_Think should now do that part
2110         if (intermission_running)
2111                 if (time >= intermission_exittime + 60)
2112                 {
2113                         if(!DoNextMapOverride())
2114                                 GotoNextMap();
2115                         return;
2116                 }
2117         */
2118
2119         if (gameover)   // someone else quit the game already
2120         {
2121                 if(player_count == 0) // Nobody there? Then let's go to the next map
2122                         MapVote_Start();
2123                         // this will actually check the player count in the next frame
2124                         // again, but this shouldn't hurt
2125                 return;
2126         }
2127
2128         timelimit = autocvar_timelimit * 60;
2129         fraglimit = autocvar_fraglimit;
2130         leadlimit = autocvar_leadlimit;
2131
2132         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2133         {
2134                 if(timelimit > 0)
2135                         timelimit = 0; // timelimit is not made for warmup
2136                 if(fraglimit > 0)
2137                         fraglimit = 0; // no fraglimit for now
2138                 leadlimit = 0; // no leadlimit for now
2139         }
2140
2141         if(g_onslaught)
2142                 timelimit = 0; // ONS has its own overtime rule
2143
2144         if(timelimit > 0)
2145         {
2146                 timelimit += game_starttime;
2147         }
2148         else if (timelimit < 0)
2149         {
2150                 // endmatch
2151                 NextLevel();
2152                 return;
2153         }
2154
2155         float wantovertime;
2156         wantovertime = 0;
2157
2158         if(checkrules_suddendeathend)
2159         {
2160                 if(!checkrules_suddendeathwarning)
2161                 {
2162                         checkrules_suddendeathwarning = TRUE;
2163                         if(g_race && !g_race_qualifying)
2164                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2165                         else
2166                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2167                 }
2168         }
2169         else
2170         {
2171                 if (timelimit && time >= timelimit)
2172                 {
2173                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2174                         {
2175                                 float totalplayers;
2176                                 float playerswithlaps;
2177                                 float readyplayers;
2178                                 entity head;
2179                                 totalplayers = playerswithlaps = readyplayers = 0;
2180                                 FOR_EACH_PLAYER(head)
2181                                 {
2182                                         ++totalplayers;
2183                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2184                                                 ++playerswithlaps;
2185                                         if(head.ready)
2186                                                 ++readyplayers;
2187                                 }
2188
2189                                 // at least 2 of the players have completed a lap: start the RACE
2190                                 // otherwise, the players should end the qualifying on their own
2191                                 if(readyplayers || playerswithlaps >= 2)
2192                                 {
2193                                         checkrules_suddendeathend = 0;
2194                                         ReadyRestart(); // go to race
2195                                         return;
2196                                 }
2197                                 else
2198                                         wantovertime |= InitiateSuddenDeath();
2199                         }
2200                         else
2201                                 wantovertime |= InitiateSuddenDeath();
2202                 }
2203         }
2204
2205         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2206         {
2207                 NextLevel();
2208                 return;
2209         }
2210
2211         float checkrules_status;
2212         checkrules_status = WinningCondition_RanOutOfSpawns();
2213         if(checkrules_status == WINNING_YES)
2214         {
2215                 bprint("Hey! Someone ran out of spawns!\n");
2216         }
2217         else if(g_race && !g_race_qualifying && timelimit >= 0)
2218         {
2219                 checkrules_status = WinningCondition_Race(fraglimit);
2220                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2221         }
2222         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2223         {
2224                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2225                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2226         }
2227         else if(g_assault)
2228         {
2229                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2230         }
2231         else if(g_lms)
2232         {
2233                 checkrules_status = WinningCondition_LMS();
2234         }
2235         else if (g_onslaught)
2236         {
2237                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2238         }
2239         else
2240         {
2241                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2242                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2243         }
2244
2245         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2246         {
2247                 checkrules_status = WINNING_NEVER;
2248                 checkrules_overtimesadded = -1;
2249                 wantovertime |= InitiateSuddenDeath();
2250         }
2251
2252         if(checkrules_status == WINNING_NEVER)
2253                 // equality cases! Nobody wins if the overtime ends in a draw.
2254                 ClearWinners();
2255
2256         if(wantovertime)
2257         {
2258                 if(checkrules_status == WINNING_NEVER)
2259                         InitiateOvertime();
2260                 else
2261                         checkrules_status = WINNING_YES;
2262         }
2263
2264         if(checkrules_suddendeathend)
2265                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2266                         checkrules_status = WINNING_YES;
2267
2268         if(checkrules_status == WINNING_YES)
2269         {
2270                 //print("WINNING\n");
2271                 NextLevel();
2272         }
2273 };
2274
2275 float mapvote_nextthink;
2276 float mapvote_initialized;
2277 float mapvote_keeptwotime;
2278 float mapvote_timeout;
2279 string mapvote_message;
2280 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2281 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2282 float mapvote_screenshot_dirs_count;
2283
2284 float mapvote_count;
2285 float mapvote_count_real;
2286 string mapvote_maps[MAPVOTE_COUNT];
2287 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2288 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2289 float mapvote_maps_suggested[MAPVOTE_COUNT];
2290 string mapvote_suggestions[MAPVOTE_COUNT];
2291 float mapvote_suggestion_ptr;
2292 float mapvote_maxlen;
2293 float mapvote_voters;
2294 float mapvote_votes[MAPVOTE_COUNT];
2295 float mapvote_run;
2296 float mapvote_detail;
2297 float mapvote_abstain;
2298 .float mapvote;
2299
2300 void MapVote_ClearAllVotes()
2301 {
2302         FOR_EACH_CLIENT(other)
2303                 other.mapvote = 0;
2304 }
2305
2306 string MapVote_Suggest(string m)
2307 {
2308         float i;
2309         if(m == "")
2310                 return "That's not how to use this command.";
2311         if(!autocvar_g_maplist_votable_suggestions)
2312                 return "Suggestions are not accepted on this server.";
2313         if(mapvote_initialized)
2314                 return "Can't suggest - voting is already in progress!";
2315         m = MapInfo_FixName(m);
2316         if(!m)
2317                 return "The map you suggested is not available on this server.";
2318         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2319                 if(Map_IsRecent(m))
2320                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2321
2322         if(!MapInfo_CheckMap(m))
2323                 return "The map you suggested does not support the current game mode.";
2324         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2325                 if(mapvote_suggestions[i] == m)
2326                         return "This map was already suggested.";
2327         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2328         {
2329                 i = floor(random() * mapvote_suggestion_ptr);
2330         }
2331         else
2332         {
2333                 i = mapvote_suggestion_ptr;
2334                 mapvote_suggestion_ptr += 1;
2335         }
2336         if(mapvote_suggestions[i] != "")
2337                 strunzone(mapvote_suggestions[i]);
2338         mapvote_suggestions[i] = strzone(m);
2339         if(autocvar_sv_eventlog)
2340                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2341         return strcat("Suggestion of ", m, " accepted.");
2342 }
2343
2344 void MapVote_AddVotable(string nextMap, float isSuggestion)
2345 {
2346         float j, i, o;
2347         string pakfile, mapfile;
2348
2349         if(nextMap == "")
2350                 return;
2351         for(j = 0; j < mapvote_count; ++j)
2352                 if(mapvote_maps[j] == nextMap)
2353                         return;
2354         if(strlen(nextMap) > mapvote_maxlen)
2355                 mapvote_maxlen = strlen(nextMap);
2356         mapvote_maps[mapvote_count] = strzone(nextMap);
2357         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2358
2359         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2360         {
2361                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2362                 pakfile = whichpack(strcat(mapfile, ".tga"));
2363                 if(pakfile == "")
2364                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2365                 if(pakfile == "")
2366                         pakfile = whichpack(strcat(mapfile, ".png"));
2367                 if(pakfile != "")
2368                         break;
2369         }
2370         if(i >= mapvote_screenshot_dirs_count)
2371                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2372         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2373                 pakfile = substring(pakfile, o, -1);
2374
2375         mapvote_maps_screenshot_dir[mapvote_count] = i;
2376         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2377
2378         mapvote_count += 1;
2379 }
2380
2381 void MapVote_Spawn();
2382 void MapVote_Init()
2383 {
2384         float i;
2385         float nmax, smax;
2386
2387         MapVote_ClearAllVotes();
2388
2389         mapvote_count = 0;
2390         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2391         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2392
2393         if(mapvote_abstain)
2394                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2395         else
2396                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2397         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2398
2399         // we need this for AddVotable, as that cycles through the screenshot dirs
2400         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2401         if(mapvote_screenshot_dirs_count == 0)
2402                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2403         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2404         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2405                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2406
2407         if(mapvote_suggestion_ptr)
2408                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2409                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2410
2411         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2412                 MapVote_AddVotable(GetNextMap(), FALSE);
2413
2414         if(mapvote_count == 0)
2415         {
2416                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2417                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2418                 if(autocvar_g_maplist_shuffle)
2419                         ShuffleMaplist();
2420                 localcmd("\nmenu_cmd sync\n");
2421                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2422                         MapVote_AddVotable(GetNextMap(), FALSE);
2423         }
2424
2425         mapvote_count_real = mapvote_count;
2426         if(mapvote_abstain)
2427                 MapVote_AddVotable("don't care", 0);
2428
2429         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2430
2431         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2432         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2433         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2434                 mapvote_keeptwotime = 0;
2435         mapvote_message = "Choose a map and press its key!";
2436
2437         MapVote_Spawn();
2438 }
2439
2440 void MapVote_SendPicture(float id)
2441 {
2442         msg_entity = self;
2443         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2444         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2445         WriteByte(MSG_ONE, id);
2446         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2447 }
2448
2449 float GameCommand_MapVote(string cmd)
2450 {
2451         if(!intermission_running)
2452                 return FALSE;
2453
2454         if(cmd == "mv_getpic")
2455         {
2456                 MapVote_SendPicture(stof(argv(1)));
2457                 return TRUE;
2458         }
2459
2460         return FALSE;
2461 }
2462
2463 float MapVote_GetMapMask()
2464 {
2465         float mask, i, power;
2466         mask = 0;
2467         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2468                 if(mapvote_maps[i] != "")
2469                         mask |= power;
2470         return mask;
2471 }
2472
2473 entity mapvote_ent;
2474 float MapVote_SendEntity(entity to, float sf)
2475 {
2476         float i;
2477
2478         if(sf & 1)
2479                 sf &~= 2; // if we send 1, we don't need to also send 2
2480
2481         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2482         WriteByte(MSG_ENTITY, sf);
2483
2484         if(sf & 1)
2485         {
2486                 // flag 1 == initialization
2487                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2488                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2489                 WriteString(MSG_ENTITY, "");
2490                 WriteByte(MSG_ENTITY, mapvote_count);
2491                 WriteByte(MSG_ENTITY, mapvote_abstain);
2492                 WriteByte(MSG_ENTITY, mapvote_detail);
2493                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2494                 if(mapvote_count <= 8)
2495                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2496                 else
2497                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2498                 for(i = 0; i < mapvote_count; ++i)
2499                         if(mapvote_maps[i] != "")
2500                         {
2501                                 if(mapvote_abstain && i == mapvote_count - 1)
2502                                 {
2503                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2504                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2505                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2506                                 }
2507                                 else
2508                                 {
2509                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2510                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2511                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2512                                 }
2513                         }
2514         }
2515
2516         if(sf & 2)
2517         {
2518                 // flag 2 == update of mask
2519                 if(mapvote_count <= 8)
2520                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2521                 else
2522                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2523         }
2524
2525         if(sf & 4)
2526         {
2527                 if(mapvote_detail)
2528                         for(i = 0; i < mapvote_count; ++i)
2529                                 if(mapvote_maps[i] != "")
2530                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2531
2532                 WriteByte(MSG_ENTITY, to.mapvote);
2533         }
2534
2535         return TRUE;
2536 }
2537
2538 void MapVote_Spawn()
2539 {
2540         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2541 }
2542
2543 void MapVote_TouchMask()
2544 {
2545         mapvote_ent.SendFlags |= 2;
2546 }
2547
2548 void MapVote_TouchVotes(entity voter)
2549 {
2550         mapvote_ent.SendFlags |= 4;
2551 }
2552
2553 float MapVote_Finished(float mappos)
2554 {
2555         string result;
2556         float i;
2557         float didntvote;
2558
2559         if(autocvar_sv_eventlog)
2560         {
2561                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2562                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2563                 didntvote = mapvote_voters;
2564                 for(i = 0; i < mapvote_count; ++i)
2565                         if(mapvote_maps[i] != "")
2566                         {
2567                                 didntvote -= mapvote_votes[i];
2568                                 if(i != mappos)
2569                                 {
2570                                         result = strcat(result, ":", mapvote_maps[i]);
2571                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2572                                 }
2573                         }
2574                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2575
2576                 GameLogEcho(result);
2577                 if(mapvote_maps_suggested[mappos])
2578                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2579         }
2580
2581         FOR_EACH_REALCLIENT(other)
2582                 FixClientCvars(other);
2583
2584         Map_Goto_SetStr(mapvote_maps[mappos]);
2585         Map_Goto();
2586         alreadychangedlevel = TRUE;
2587         return TRUE;
2588 }
2589 void MapVote_CheckRules_1()
2590 {
2591         float i;
2592
2593         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2594         {
2595                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2596                 mapvote_votes[i] = 0;
2597         }
2598
2599         mapvote_voters = 0;
2600         FOR_EACH_REALCLIENT(other)
2601         {
2602                 ++mapvote_voters;
2603                 if(other.mapvote)
2604                 {
2605                         i = other.mapvote - 1;
2606                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2607                         mapvote_votes[i] = mapvote_votes[i] + 1;
2608                 }
2609         }
2610 }
2611
2612 float MapVote_CheckRules_2()
2613 {
2614         float i;
2615         float firstPlace, secondPlace;
2616         float firstPlaceVotes, secondPlaceVotes;
2617         float mapvote_voters_real;
2618         string result;
2619
2620         if(mapvote_count_real == 1)
2621                 return MapVote_Finished(0);
2622
2623         mapvote_voters_real = mapvote_voters;
2624         if(mapvote_abstain)
2625                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2626
2627         RandomSelection_Init();
2628         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2629                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2630         firstPlace = RandomSelection_chosen_float;
2631         firstPlaceVotes = RandomSelection_best_priority;
2632         //dprint("First place: ", ftos(firstPlace), "\n");
2633         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2634
2635         RandomSelection_Init();
2636         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2637                 if(i != firstPlace)
2638                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2639         secondPlace = RandomSelection_chosen_float;
2640         secondPlaceVotes = RandomSelection_best_priority;
2641         //dprint("Second place: ", ftos(secondPlace), "\n");
2642         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2643
2644         if(firstPlace == -1)
2645                 error("No first place in map vote... WTF?");
2646
2647         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2648                 return MapVote_Finished(firstPlace);
2649
2650         if(mapvote_keeptwotime)
2651                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2652                 {
2653                         float didntvote;
2654                         MapVote_TouchMask();
2655                         mapvote_message = "Now decide between the TOP TWO!";
2656                         mapvote_keeptwotime = 0;
2657                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2658                         result = strcat(result, ":", ftos(firstPlaceVotes));
2659                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2660                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2661                         didntvote = mapvote_voters;
2662                         for(i = 0; i < mapvote_count; ++i)
2663                                 if(mapvote_maps[i] != "")
2664                                 {
2665                                         didntvote -= mapvote_votes[i];
2666                                         if(i != firstPlace)
2667                                                 if(i != secondPlace)
2668                                                 {
2669                                                         result = strcat(result, ":", mapvote_maps[i]);
2670                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2671                                                         if(i < mapvote_count_real)
2672                                                         {
2673                                                                 strunzone(mapvote_maps[i]);
2674                                                                 mapvote_maps[i] = "";
2675                                                                 strunzone(mapvote_maps_pakfile[i]);
2676                                                                 mapvote_maps_pakfile[i] = "";
2677                                                         }
2678                                                 }
2679                                 }
2680                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2681                         if(autocvar_sv_eventlog)
2682                                 GameLogEcho(result);
2683                 }
2684
2685         return FALSE;
2686 }
2687 void MapVote_Tick()
2688 {
2689         float keeptwo;
2690         float totalvotes;
2691
2692         keeptwo = mapvote_keeptwotime;
2693         MapVote_CheckRules_1(); // count
2694         if(MapVote_CheckRules_2()) // decide
2695                 return;
2696
2697         totalvotes = 0;
2698         FOR_EACH_REALCLIENT(other)
2699         {
2700                 // hide scoreboard again
2701                 if(other.health != 2342)
2702                 {
2703                         other.health = 2342;
2704                         other.impulse = 0;
2705                         if(clienttype(other) == CLIENTTYPE_REAL)
2706                         {
2707                                 msg_entity = other;
2708                                 WriteByte(MSG_ONE, SVC_FINALE);
2709                                 WriteString(MSG_ONE, "");
2710                         }
2711                 }
2712
2713                 // clear possibly invalid votes
2714                 if(mapvote_maps[other.mapvote - 1] == "")
2715                         other.mapvote = 0;
2716                 // use impulses as new vote
2717                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2718                         if(mapvote_maps[other.impulse - 1] != "")
2719                         {
2720                                 other.mapvote = other.impulse;
2721                                 MapVote_TouchVotes(other);
2722                         }
2723                 other.impulse = 0;
2724
2725                 if(other.mapvote)
2726                         ++totalvotes;
2727         }
2728
2729         MapVote_CheckRules_1(); // just count
2730 }
2731 void MapVote_Start()
2732 {
2733         if(mapvote_run)
2734                 return;
2735
2736         // wait for stats to be sent first
2737         if(!playerstats_waitforme)
2738                 return;
2739
2740         MapInfo_Enumerate();
2741         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2742                 mapvote_run = TRUE;
2743 }
2744 void MapVote_Think()
2745 {
2746         if(!mapvote_run)
2747                 return;
2748
2749         if(alreadychangedlevel)
2750                 return;
2751
2752         if(time < mapvote_nextthink)
2753                 return;
2754         //dprint("tick\n");
2755
2756         mapvote_nextthink = time + 0.5;
2757
2758         if(!mapvote_initialized)
2759         {
2760                 if(autocvar_rescan_pending == 1)
2761                 {
2762                         cvar_set("rescan_pending", "2");
2763                         localcmd("fs_rescan\nrescan_pending 3\n");
2764                         return;
2765                 }
2766                 else if(autocvar_rescan_pending == 2)
2767                 {
2768                         return;
2769                 }
2770                 else if(autocvar_rescan_pending == 3)
2771                 {
2772                         // now build missing mapinfo files
2773                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2774                                 return;
2775
2776                         // we're done, start the timer
2777                         cvar_set("rescan_pending", "0");
2778                 }
2779
2780                 mapvote_initialized = TRUE;
2781                 if(DoNextMapOverride())
2782                         return;
2783                 if(!autocvar_g_maplist_votable || player_count <= 0)
2784                 {
2785                         GotoNextMap();
2786                         return;
2787                 }
2788                 MapVote_Init();
2789         }
2790
2791         MapVote_Tick();
2792 };
2793
2794 string GotoMap(string m)
2795 {
2796         if(!MapInfo_CheckMap(m))
2797                 return "The map you chose is not available on this server.";
2798         cvar_set("nextmap", m);
2799         cvar_set("timelimit", "-1");
2800         if(mapvote_initialized || alreadychangedlevel)
2801         {
2802                 if(DoNextMapOverride())
2803                         return "Map switch initiated.";
2804                 else
2805                         return "Hm... no. For some reason I like THIS map more.";
2806         }
2807         else
2808                 return "Map switch will happen after scoreboard.";
2809 }
2810
2811
2812 void EndFrame()
2813 {
2814         float altime;
2815         FOR_EACH_REALCLIENT(self)
2816         {
2817                 if(self.classname == "spectator")
2818                 {
2819                         if(self.enemy.typehitsound)
2820                                 play2(self, "misc/typehit.wav");
2821                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2822                                 play2(self, "misc/hit.wav");
2823                 }
2824                 else
2825                 {
2826                         if(self.typehitsound)
2827                                 play2(self, "misc/typehit.wav");
2828                         else if(self.hitsound && self.cvar_cl_hitsound)
2829                                 play2(self, "misc/hit.wav");
2830                 }
2831         }
2832         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2833         // add 1 frametime because after this, engine SV_Physics
2834         // increases time by a frametime and then networks the frame
2835         // add another frametime because client shows everything with
2836         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2837         // needed!
2838         FOR_EACH_CLIENT(self)
2839         {
2840                 self.hitsound = FALSE;
2841                 self.typehitsound = FALSE;
2842                 antilag_record(self, altime);
2843         }
2844 }
2845
2846
2847 /*
2848  * RedirectionThink:
2849  * returns TRUE if redirecting
2850  */
2851 float redirection_timeout;
2852 float redirection_nextthink;
2853 float RedirectionThink()
2854 {
2855         float clients_found;
2856
2857         if(redirection_target == "")
2858                 return FALSE;
2859
2860         if(!redirection_timeout)
2861         {
2862                 cvar_set("sv_public", "-2");
2863                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2864                 if(redirection_target == "self")
2865                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2866                 else
2867                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2868         }
2869
2870         if(time < redirection_nextthink)
2871                 return TRUE;
2872
2873         redirection_nextthink = time + 1;
2874
2875         clients_found = 0;
2876         FOR_EACH_REALCLIENT(self)
2877         {
2878                 print("Redirecting: sending connect command to ", self.netname, "\n");
2879                 if(redirection_target == "self")
2880                         stuffcmd(self, "\ndisconnect; reconnect\n");
2881                 else
2882                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2883                 ++clients_found;
2884         }
2885
2886         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2887
2888         if(time > redirection_timeout || clients_found == 0)
2889                 localcmd("\nwait; wait; wait; quit\n");
2890
2891         return TRUE;
2892 }
2893
2894 void TargetMusic_RestoreGame();
2895 void RestoreGame()
2896 {
2897         // Loaded from a save game
2898         // some things then break, so let's work around them...
2899
2900         // Progs DB (capture records)
2901         ServerProgsDB = db_load("server.db");
2902
2903         // Mapinfo
2904         MapInfo_Shutdown();
2905         MapInfo_Enumerate();
2906         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2907         WeaponStats_Init();
2908
2909         TargetMusic_RestoreGame();
2910 }
2911
2912 void SV_Shutdown()
2913 {
2914         entity e;
2915
2916         if(gameover > 1) // shutting down already?
2917                 return;
2918
2919         gameover = 2; // 2 = server shutting down
2920
2921         if(world_initialized > 0)
2922         {
2923                 world_initialized = 0;
2924                 print("Saving persistent data...\n");
2925                 Ban_SaveBans();
2926
2927                 FOR_EACH_CLIENT(e)
2928                         PlayerStats_AddGlobalInfo(e);
2929                 PlayerStats_Shutdown();
2930
2931                 if(!cheatcount_total)
2932                 {
2933                         if(autocvar_sv_db_saveasdump)
2934                                 db_dump(ServerProgsDB, "server.db");
2935                         else
2936                                 db_save(ServerProgsDB, "server.db");
2937                 }
2938                 if(autocvar_developer)
2939                 {
2940                         if(autocvar_sv_db_saveasdump)
2941                                 db_dump(TemporaryDB, "server-temp.db");
2942                         else
2943                                 db_save(TemporaryDB, "server-temp.db");
2944                 }
2945                 CheatShutdown(); // must be after cheatcount check
2946                 db_close(ServerProgsDB);
2947                 db_close(TemporaryDB);
2948                 print("done!\n");
2949                 // tell the bot system the game is ending now
2950                 bot_endgame();
2951
2952                 WeaponStats_Shutdown();
2953                 MapInfo_Shutdown();
2954         }
2955         else if(world_initialized == 0)
2956         {
2957                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2958         }
2959 }