qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556
 557         MapInfo_Enumerate();
 558         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 559 }
 560
 561 void Map_MarkAsRecent(string m);
 562 float world_already_spawned;
 563 void Nagger_Init();
 564 void ClientInit_Spawn();
 565 void WeaponStats_Init();
 566 void WeaponStats_Shutdown();
 567 void spawnfunc_worldspawn (void)
 568 {
 569         float fd, l, i, j, n;
 570         string s, col;
 571
 572         cvar = cvar_normal;
 573         cvar_string = cvar_string_normal;
 574         cvar_set = cvar_set_normal;
 575
 576         if(world_already_spawned)
 577                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 578         world_already_spawned = TRUE;
 579
 580         remove = remove_safely; // during spawning, watch what you remove!
 581
 582         check_unacceptable_compiler_bugs();
 583
 584         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 585
 586         compressShortVector_init();
 587
 588         entity head;
 589         head = nextent(world);
 590         maxclients = 0;
 591         while(head)
 592         {
 593                 ++maxclients;
 594                 head = nextent(head);
 595         }
 596
 597         // needs to be done so early because of the constants they create
 598         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 599         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         //if (g_domination)
 671         //      dom_init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 788         Nagger_Init();
 789
 790         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 791         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 792         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 793         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 794         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 795         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 796         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 797         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 798         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 799         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 800         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 801         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 802         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 803
 804         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 805         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 806
 807         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 808
 809         if(g_ca)
 810         {
 811                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 812                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 813         }
 814
 815         // g_movementspeed hack
 816         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 817         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 818         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 819         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 820
 821         // secrets
 822         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 823         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 824
 825         // misc
 826         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 827
 828         next_pingtime = time + 5;
 829
 830         detect_maptype();
 831
 832         // set up information replies for clients and server to use
 833         lsmaps_reply = "^7Maps available: ";
 834         lsnewmaps_reply = "^7Maps without a record set: ";
 835         for(i = 0, j = 0; i < MapInfo_count; ++i)
 836         {
 837                 if(MapInfo_Get_ByID(i))
 838                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 839                         {
 840                                 if(mod(i, 2))
 841                                         col = "^2";
 842                                 else
 843                                         col = "^3";
 844
 845                                 ++j;
 846
 847                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 848
 849                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 850                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 851                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 852                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 853                         }
 854         }
 855
 856         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 857         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 858
 859         maplist_reply = "^7Maps in list: ";
 860         n = tokenize_console(autocvar_g_maplist);
 861         for(i = 0, j = 0; i < n; ++i)
 862         {
 863                 if(MapInfo_CheckMap(argv(i)))
 864                 {
 865                         if(mod(j, 2))
 866                                 col = "^2";
 867                         else
 868                                 col = "^3";
 869                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 870                         ++j;
 871                 }
 872         }
 873         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 874         MapInfo_ClearTemps();
 875
 876         for(i = 0; i < 10; ++i)
 877         {
 878                 s = getrecords(i);
 879                 if (s)
 880                         records_reply[i] = strzone(s);
 881         }
 882
 883         ladder_reply = strzone(getladder());
 884
 885         rankings_reply = strzone(getrankings());
 886
 887         // begin other init
 888         ClientInit_Spawn();
 889         RandomSeed_Spawn();
 890         PingPLReport_Spawn();
 891
 892         CheatInit();
 893
 894         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 895
 896         // fill sv_curl_serverpackages from .serverpackage files
 897         if(autocvar_sv_curl_serverpackages_auto)
 898         {
 899                 s = "";
 900                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 901                 for(i = 0; i < n; ++i)
 902                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 903                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 904                                 s = strcat(s, " ", argv(i));
 905                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 906                 if(fd >= 0)
 907                 {
 908                         j = search_getsize(fd);
 909                         for(i = 0; i < j; ++i)
 910                                 s = strcat(s, " ", search_getfilename(fd, i));
 911                         search_end(fd);
 912                 }
 913                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 914                 if(fd >= 0)
 915                 {
 916                         j = search_getsize(fd);
 917                         for(i = 0; i < j; ++i)
 918                                 s = strcat(s, " ", search_getfilename(fd, i));
 919                         search_end(fd);
 920                 }
 921                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 922         }
 923
 924         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 925         modname = "Xonotic";
 926         // physics/balance/config changes that count as mod
 927         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 928                 modname = cvar_string("g_mod_physics");
 929         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 930                 modname = cvar_string("g_mod_balance");
 931         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 932                 modname = cvar_string("g_mod_config");
 933         // weird mutators that deserve to count as mod
 934         if(autocvar_g_minstagib)
 935                 modname = "MinstaGib";
 936         // extra mutators that deserve to count as mod
 937         MUTATOR_CALLHOOK(SetModname);
 938         // weird game types that deserve to count as mod
 939         if(g_cts)
 940                 modname = "CTS";
 941         // save it for later
 942         modname = strzone(modname);
 943
 944         WinningConditionHelper(); // set worldstatus
 945
 946         world_initialized = 1;
 947 }
 948
 949 void spawnfunc_light (void)
 950 {
 951         //makestatic (self); // Who the f___ did that?
 952         remove(self);
 953 }
 954
 955 string GetGametype()
 956 {
 957         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 958 }
 959
 960 string getmapname_stored;
 961 string GetMapname()
 962 {
 963         return mapname;
 964 }
 965
 966 float Map_Count, Map_Current;
 967 string Map_Current_Name;
 968
 969 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 970 float GetMaplistPosition()
 971 {
 972         float pos, idx;
 973         string map;
 974
 975         map = GetMapname();
 976         idx = autocvar_g_maplist_index;
 977
 978         if(idx >= 0)
 979                 if(idx < Map_Count)
 980                         if(map == argv(idx))
 981                                 return idx;
 982
 983         for(pos = 0; pos < Map_Count; ++pos)
 984                 if(map == argv(pos))
 985                         return pos;
 986
 987         // resume normal maplist rotation if current map is not in g_maplist
 988         return idx;
 989 }
 990
 991 float MapHasRightSize(string map)
 992 {
 993         float fh;
 994         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 995         if(autocvar_g_maplist_check_waypoints)
 996         {
 997                 dprint("checkwp "); dprint(map);
 998                 if(!fexists(strcat("maps/", map, ".waypoints")))
 999                 {
1000                         dprint(": no waypoints\n");
1001                         return FALSE;
1002                 }
1003                 dprint(": has waypoints\n");
1004         }
1005
1006         // open map size restriction file
1007         dprint("opensize "); dprint(map);
1008         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1009         if(fh >= 0)
1010         {
1011                 float mapmin, mapmax;
1012                 dprint(": ok, ");
1013                 mapmin = stof(fgets(fh));
1014                 mapmax = stof(fgets(fh));
1015                 fclose(fh);
1016                 if(player_count < mapmin)
1017                 {
1018                         dprint("not enough\n");
1019                         return FALSE;
1020                 }
1021                 if(player_count > mapmax)
1022                 {
1023                         dprint("too many\n");
1024                         return FALSE;
1025                 }
1026                 dprint("right size\n");
1027                 return TRUE;
1028         }
1029         dprint(": not found\n");
1030         return TRUE;
1031 }
1032
1033 string Map_Filename(float position)
1034 {
1035         return strcat("maps/", argv(position), ".bsp");
1036 }
1037
1038 string strwords(string s, float w)
1039 {
1040         float endpos;
1041         for(endpos = 0; w && endpos >= 0; --w)
1042                 endpos = strstrofs(s, " ", endpos + 1);
1043         if(endpos < 0)
1044                 return s;
1045         else
1046                 return substring(s, 0, endpos);
1047 }
1048
1049 float strhasword(string s, string w)
1050 {
1051         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1052 }
1053
1054 void Map_MarkAsRecent(string m)
1055 {
1056         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1057 }
1058
1059 float Map_IsRecent(string m)
1060 {
1061         return strhasword(autocvar_g_maplist_mostrecent, m);
1062 }
1063
1064 float Map_Check(float position, float pass)
1065 {
1066         string filename;
1067         string map_next;
1068         map_next = argv(position);
1069         if(pass <= 1)
1070         {
1071                 if(Map_IsRecent(map_next))
1072                         return 0;
1073         }
1074         filename = Map_Filename(position);
1075         if(MapInfo_CheckMap(map_next))
1076         {
1077                 if(pass == 2)
1078                         return 1;
1079                 if(MapHasRightSize(map_next))
1080                         return 1;
1081                 return 0;
1082         }
1083         else
1084                 dprint( "Couldn't select '", filename, "'..\n" );
1085
1086         return 0;
1087 }
1088
1089 void Map_Goto_SetStr(string nextmapname)
1090 {
1091         if(getmapname_stored != "")
1092                 strunzone(getmapname_stored);
1093         if(nextmapname == "")
1094                 getmapname_stored = "";
1095         else
1096                 getmapname_stored = strzone(nextmapname);
1097 }
1098
1099 void Map_Goto_SetFloat(float position)
1100 {
1101         cvar_set("g_maplist_index", ftos(position));
1102         Map_Goto_SetStr(argv(position));
1103 }
1104
1105 void Map_Goto(float reinit)
1106 {
1107         MapInfo_LoadMap(getmapname_stored, reinit);
1108 }
1109
1110 // return codes of map selectors:
1111 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1112 //   -2 = permanent failure
1113 float() MaplistMethod_Iterate = // usual method
1114 {
1115         float pass, i;
1116
1117         for(pass = 1; pass <= 2; ++pass)
1118         {
1119                 for(i = 1; i < Map_Count; ++i)
1120                 {
1121                         float mapindex;
1122                         mapindex = mod(i + Map_Current, Map_Count);
1123                         if(Map_Check(mapindex, pass))
1124                                 return mapindex;
1125                 }
1126         }
1127         return -1;
1128 }
1129
1130 float() MaplistMethod_Repeat = // fallback method
1131 {
1132         if(Map_Check(Map_Current, 2))
1133                 return Map_Current;
1134         return -2;
1135 }
1136
1137 float() MaplistMethod_Random = // random map selection
1138 {
1139         float i, imax;
1140
1141         imax = 42;
1142
1143         for(i = 0; i <= imax; ++i)
1144         {
1145                 float mapindex;
1146                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1147                 if(Map_Check(mapindex, 1))
1148                         return mapindex;
1149         }
1150         return -1;
1151 }
1152
1153 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1154 // the exponent sets a bias on the map selection:
1155 // the higher the exponent, the less likely "shortly repeated" same maps are
1156 {
1157         float i, j, imax, insertpos;
1158
1159         imax = 42;
1160
1161         for(i = 0; i <= imax; ++i)
1162         {
1163                 string newlist;
1164
1165                 // now reinsert this at another position
1166                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1167                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1168                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1169                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1170
1171                 // insert the current map there
1172                 newlist = "";
1173                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1174                         newlist = strcat(newlist, " ", argv(j));
1175                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1176                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1177                         newlist = strcat(newlist, " ", argv(j));
1178                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1179                 cvar_set("g_maplist", newlist);
1180                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1181
1182                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1183                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1184                 if(Map_Check(Map_Current, 1))
1185                         return Map_Current;
1186         }
1187         return -1;
1188 }
1189
1190 void Maplist_Init()
1191 {
1192         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193         if(Map_Count == 0)
1194         {
1195                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1196                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1197                 if(autocvar_g_maplist_shuffle)
1198                         ShuffleMaplist();
1199                 localcmd("\nmenu_cmd sync\n");
1200                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         }
1202         if(Map_Count == 0)
1203                 error("empty maplist, cannot select a new map");
1204         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1205
1206         if(Map_Current_Name)
1207                 strunzone(Map_Current_Name);
1208         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1209         // this may or may not be correct, but who cares, in the worst case a map
1210         // isn't chosen in the first pass that should have been
1211 }
1212
1213 string GetNextMap()
1214 {
1215         float nextMap;
1216
1217         Maplist_Init();
1218         nextMap = -1;
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_shuffle > 0)
1222                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_selectrandom)
1226                         nextMap = MaplistMethod_Random();
1227
1228         if(nextMap == -1)
1229                 nextMap = MaplistMethod_Iterate();
1230
1231         if(nextMap == -1)
1232                 nextMap = MaplistMethod_Repeat();
1233
1234         if(nextMap >= 0)
1235         {
1236                 Map_Goto_SetFloat(nextMap);
1237                 return getmapname_stored;
1238         }
1239
1240         return "";
1241 }
1242
1243 float DoNextMapOverride(float reinit)
1244 {
1245         if(autocvar_g_campaign)
1246         {
1247                 CampaignPostIntermission();
1248                 alreadychangedlevel = TRUE;
1249                 return TRUE;
1250         }
1251         if(autocvar_quit_when_empty)
1252         {
1253                 if(player_count <= currentbots)
1254                 {
1255                         localcmd("quit\n");
1256                         alreadychangedlevel = TRUE;
1257                         return TRUE;
1258                 }
1259         }
1260         if(autocvar_quit_and_redirect != "")
1261         {
1262                 redirection_target = strzone(autocvar_quit_and_redirect);
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1267         {
1268                 localcmd("restart\n");
1269                 alreadychangedlevel = TRUE;
1270                 return TRUE;
1271         }
1272         if(autocvar_nextmap != "")
1273                 if(MapInfo_CheckMap(autocvar_nextmap))
1274                 {
1275                         Map_Goto_SetStr(autocvar_nextmap);
1276                         Map_Goto(reinit);
1277                         alreadychangedlevel = TRUE;
1278                         return TRUE;
1279                 }
1280         if(!reinit && autocvar_lastlevel)
1281         {
1282                 cvar_settemp_restore();
1283                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1284                 alreadychangedlevel = TRUE;
1285                 return TRUE;
1286         }
1287         return FALSE;
1288 }
1289
1290 void GotoNextMap(float reinit)
1291 {
1292         //string nextmap;
1293         //float n, nummaps;
1294         //string s;
1295         if (alreadychangedlevel)
1296                 return;
1297         alreadychangedlevel = TRUE;
1298
1299         {
1300                 string nextMap;
1301                 float allowReset;
1302
1303                 for(allowReset = 1; allowReset >= 0; --allowReset)
1304                 {
1305                         nextMap = GetNextMap();
1306                         if(nextMap != "")
1307                                 break;
1308
1309                         if(allowReset)
1310                         {
1311                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1312                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1313                                 if(autocvar_g_maplist_shuffle)
1314                                         ShuffleMaplist();
1315                                 localcmd("\nmenu_cmd sync\n");
1316                         }
1317                         else
1318                         {
1319                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1320                         }
1321                 }
1322                 Map_Goto(reinit);
1323         }
1324 }
1325
1326
1327 /*
1328 ============
1329 IntermissionThink
1330
1331 When the player presses attack or jump, change to the next level
1332 ============
1333 */
1334 .float autoscreenshot;
1335 void() MapVote_Start;
1336 void() MapVote_Think;
1337 float mapvote_initialized;
1338 void IntermissionThink()
1339 {
1340         FixIntermissionClient(self);
1341
1342         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1343         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1344
1345         if( (server_screenshot || client_screenshot)
1346                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1347         {
1348                 self.autoscreenshot = -1;
1349                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1350                 return;
1351         }
1352
1353         if (time < intermission_exittime)
1354                 return;
1355
1356         if(!mapvote_initialized)
1357                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1358                         return;
1359
1360         MapVote_Start();
1361 }
1362
1363 /*
1364 ============
1365 FindIntermission
1366
1367 Returns the entity to view from
1368 ============
1369 */
1370 /*
1371 entity FindIntermission()
1372 {
1373         local   entity spot;
1374         local   float cyc;
1375
1376 // look for info_intermission first
1377         spot = find (world, classname, "info_intermission");
1378         if (spot)
1379         {       // pick a random one
1380                 cyc = random() * 4;
1381                 while (cyc > 1)
1382                 {
1383                         spot = find (spot, classname, "info_intermission");
1384                         if (!spot)
1385                                 spot = find (spot, classname, "info_intermission");
1386                         cyc = cyc - 1;
1387                 }
1388                 return spot;
1389         }
1390
1391 // then look for the start position
1392         spot = find (world, classname, "info_player_start");
1393         if (spot)
1394                 return spot;
1395
1396 // testinfo_player_start is only found in regioned levels
1397         spot = find (world, classname, "testplayerstart");
1398         if (spot)
1399                 return spot;
1400
1401 // then look for the start position
1402         spot = find (world, classname, "info_player_deathmatch");
1403         if (spot)
1404                 return spot;
1405
1406         //objerror ("FindIntermission: no spot");
1407         return world;
1408 }
1409 */
1410
1411 /*
1412 ===============================================================================
1413
1414 RULES
1415
1416 ===============================================================================
1417 */
1418
1419 void DumpStats(float final)
1420 {
1421         float file;
1422         string s;
1423         float to_console;
1424         float to_eventlog;
1425         float to_file;
1426         float i;
1427
1428         to_console = autocvar_sv_logscores_console;
1429         to_eventlog = autocvar_sv_eventlog;
1430         to_file = autocvar_sv_logscores_file;
1431
1432         if(!final)
1433         {
1434                 to_console = TRUE; // always print printstats replies
1435                 to_eventlog = FALSE; // but never print them to the event log
1436         }
1437
1438         if(to_eventlog)
1439                 if(autocvar_sv_eventlog_console)
1440                         to_console = FALSE; // otherwise we get the output twice
1441
1442         if(final)
1443                 s = ":scores:";
1444         else
1445                 s = ":status:";
1446         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1447
1448         if(to_console)
1449                 print(s, "\n");
1450         if(to_eventlog)
1451                 GameLogEcho(s);
1452
1453         file = -1;
1454         if(to_file)
1455         {
1456                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1457                 if(file == -1)
1458                         to_file = FALSE;
1459                 else
1460                         fputs(file, strcat(s, "\n"));
1461         }
1462
1463         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1464         if(to_console)
1465                 print(s, "\n");
1466         if(to_eventlog)
1467                 GameLogEcho(s);
1468         if(to_file)
1469                 fputs(file, strcat(s, "\n"));
1470
1471         FOR_EACH_CLIENT(other)
1472         {
1473                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1474                 {
1475                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1476                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1477                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1478                                 s = strcat(s, ftos(other.team), ":");
1479                         else
1480                                 s = strcat(s, "spectator:");
1481
1482                         if(to_console)
1483                                 print(s, other.netname, "\n");
1484                         if(to_eventlog)
1485                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1486                         if(to_file)
1487                                 fputs(file, strcat(s, other.netname, "\n"));
1488                 }
1489         }
1490
1491         if(teamplay)
1492         {
1493                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1494                 if(to_console)
1495                         print(s, "\n");
1496                 if(to_eventlog)
1497                         GameLogEcho(s);
1498                 if(to_file)
1499                         fputs(file, strcat(s, "\n"));
1500
1501                 for(i = 1; i < 16; ++i)
1502                 {
1503                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1504                         s = strcat(s, ":", ftos(i));
1505                         if(to_console)
1506                                 print(s, "\n");
1507                         if(to_eventlog)
1508                                 GameLogEcho(s);
1509                         if(to_file)
1510                                 fputs(file, strcat(s, "\n"));
1511                 }
1512         }
1513
1514         if(to_console)
1515                 print(":end\n");
1516         if(to_eventlog)
1517                 GameLogEcho(":end");
1518         if(to_file)
1519         {
1520                 fputs(file, ":end\n");
1521                 fclose(file);
1522         }
1523 }
1524
1525 void FixIntermissionClient(entity e)
1526 {
1527         string s;
1528         if(!e.autoscreenshot) // initial call
1529         {
1530                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1531                 e.health = -2342;
1532                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1533                 e.solid = SOLID_NOT;
1534                 e.movetype = MOVETYPE_NONE;
1535                 e.takedamage = DAMAGE_NO;
1536                 if(e.weaponentity)
1537                 {
1538                         e.weaponentity.effects = EF_NODRAW;
1539                         if (e.weaponentity.weaponentity)
1540                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1541                 }
1542                 if(clienttype(e) == CLIENTTYPE_REAL)
1543                 {
1544                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1545                         s = autocvar_sv_intermission_cdtrack;
1546                         if(s != "")
1547                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1548                         msg_entity = e;
1549                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1550                 }
1551         }
1552 }
1553
1554 void minstagib_stop_countdown(entity e);
1555 /*
1556 go to the next level for deathmatch
1557 only called if a time or frag limit has expired
1558 */
1559 void NextLevel()
1560 {
1561         gameover = TRUE;
1562
1563         intermission_running = 1;
1564
1565 // enforce a wait time before allowing changelevel
1566         if(player_count > 0)
1567                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1568         else
1569                 intermission_exittime = -1;
1570
1571         /*
1572         WriteByte (MSG_ALL, SVC_CDTRACK);
1573         WriteByte (MSG_ALL, 3);
1574         WriteByte (MSG_ALL, 3);
1575         // done in FixIntermission
1576         */
1577
1578         //pos = FindIntermission ();
1579
1580         VoteReset();
1581
1582         DumpStats(TRUE);
1583
1584         // send statistics
1585         entity e;
1586         PlayerStats_EndMatch(1);
1587         FOR_EACH_CLIENT(e)
1588                 PlayerStats_AddGlobalInfo(e);
1589         PlayerStats_Shutdown();
1590         WeaponStats_Shutdown();
1591
1592         if(autocvar_sv_eventlog)
1593                 GameLogEcho(":gameover");
1594
1595         GameLogClose();
1596
1597         FOR_EACH_PLAYER(other) {
1598                 minstagib_stop_countdown(other);
1599                 FixIntermissionClient(other);
1600                 if(other.winning)
1601                         bprint(other.netname, " ^7wins.\n");
1602         }
1603
1604         if(autocvar_g_campaign)
1605                 CampaignPreIntermission();
1606
1607         MUTATOR_CALLHOOK(MatchEnd);
1608
1609         localcmd("\nsv_hook_gameend\n");
1610 }
1611
1612 /*
1613 ============
1614 CheckRules_Player
1615
1616 Exit deathmatch games upon conditions
1617 ============
1618 */
1619 void CheckRules_Player()
1620 {
1621         if (gameover)   // someone else quit the game already
1622                 return;
1623
1624         if(self.deadflag == DEAD_NO)
1625                 self.play_time += frametime;
1626
1627         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1628         //   (div0: and that in CheckRules_World please)
1629 }
1630
1631 float checkrules_equality;
1632 float checkrules_suddendeathwarning;
1633 float checkrules_suddendeathend;
1634 float checkrules_overtimesadded; //how many overtimes have been already added
1635
1636 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1637 float WINNING_YES = 1; // winner found
1638 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1639 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1640
1641 float InitiateSuddenDeath()
1642 {
1643         // Check first whether normal overtimes could be added before initiating suddendeath mode
1644         // - for this timelimit_overtime needs to be >0 of course
1645         // - also check the winning condition calculated in the previous frame and only add normal overtime
1646         //   again, if at the point at which timelimit would be extended again, still no winner was found
1647         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1648         {
1649                 return 1; // need to call InitiateOvertime later
1650         }
1651         else
1652         {
1653                 if(!checkrules_suddendeathend)
1654                 {
1655                         if(autocvar_g_campaign)
1656                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1657                         else
1658                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1659                         if(g_race && !g_race_qualifying)
1660                                 race_StartCompleting();
1661                 }
1662                 return 0;
1663         }
1664 }
1665
1666 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1667 {
1668         ++checkrules_overtimesadded;
1669         //add one more overtime by simply extending the timelimit
1670         float tl;
1671         tl = autocvar_timelimit;
1672         tl += autocvar_timelimit_overtime;
1673         cvar_set("timelimit", ftos(tl));
1674         string minutesPlural;
1675         if (autocvar_timelimit_overtime == 1)
1676                 minutesPlural = " ^3minute";
1677         else
1678                 minutesPlural = " ^3minutes";
1679
1680         bcenterprint(
1681                 strcat(
1682                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1683                         ftos(autocvar_timelimit_overtime),
1684                         minutesPlural,
1685                         " to the game!"
1686                 )
1687         );
1688 }
1689
1690 float GetWinningCode(float fraglimitreached, float equality)
1691 {
1692         if(autocvar_g_campaign == 1)
1693                 if(fraglimitreached)
1694                         return WINNING_YES;
1695                 else
1696                         return WINNING_NO;
1697
1698         else
1699                 if(equality)
1700                         if(fraglimitreached)
1701                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1702                         else
1703                                 return WINNING_NEVER;
1704                 else
1705                         if(fraglimitreached)
1706                                 return WINNING_YES;
1707                         else
1708                                 return WINNING_NO;
1709 }
1710
1711 // set the .winning flag for exactly those players with a given field value
1712 void SetWinners(.float field, float value)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = (head.field == value);
1717 }
1718
1719 // set the .winning flag for those players with a given field value
1720 void AddWinners(.float field, float value)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 if(head.field == value)
1725                         head.winning = 1;
1726 }
1727
1728 // clear the .winning flags
1729 void ClearWinners(void)
1730 {
1731         entity head;
1732         FOR_EACH_PLAYER(head)
1733                 head.winning = 0;
1734 }
1735
1736 // Onslaught winning condition:
1737 // game terminates if only one team has a working generator (or none)
1738 float WinningCondition_Onslaught()
1739 {
1740         entity head;
1741         float t1, t2, t3, t4;
1742
1743         WinningConditionHelper(); // set worldstatus
1744
1745         if(inWarmupStage)
1746                 return WINNING_NO;
1747
1748         // first check if the game has ended
1749         t1 = t2 = t3 = t4 = 0;
1750         head = find(world, classname, "onslaught_generator");
1751         while (head)
1752         {
1753                 if (head.health > 0)
1754                 {
1755                         if (head.team == COLOR_TEAM1) t1 = 1;
1756                         if (head.team == COLOR_TEAM2) t2 = 1;
1757                         if (head.team == COLOR_TEAM3) t3 = 1;
1758                         if (head.team == COLOR_TEAM4) t4 = 1;
1759                 }
1760                 head = find(head, classname, "onslaught_generator");
1761         }
1762         if (t1 + t2 + t3 + t4 < 2)
1763         {
1764                 // game over, only one team remains (or none)
1765                 ClearWinners();
1766                 if (t1) SetWinners(team, COLOR_TEAM1);
1767                 if (t2) SetWinners(team, COLOR_TEAM2);
1768                 if (t3) SetWinners(team, COLOR_TEAM3);
1769                 if (t4) SetWinners(team, COLOR_TEAM4);
1770                 dprint("Have a winner, ending game.\n");
1771                 return WINNING_YES;
1772         }
1773
1774         // Two or more teams remain
1775         return WINNING_NO;
1776 }
1777
1778 float LMS_NewPlayerLives()
1779 {
1780         float fl;
1781         fl = autocvar_fraglimit;
1782         if(fl == 0)
1783                 fl = 999;
1784
1785         // first player has left the game for dying too much? Nobody else can get in.
1786         if(lms_lowest_lives < 1)
1787                 return 0;
1788
1789         if(!autocvar_g_lms_join_anytime)
1790                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1791                         return 0;
1792
1793         return bound(1, lms_lowest_lives, fl);
1794 }
1795
1796 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1797 // they win. Otherwise the defending team wins once the timelimit passes.
1798 void assault_new_round();
1799 float WinningCondition_Assault()
1800 {
1801         float status;
1802
1803         WinningConditionHelper(); // set worldstatus
1804
1805         status = WINNING_NO;
1806         // as the timelimit has not yet passed just assume the defending team will win
1807         if(assault_attacker_team == COLOR_TEAM1)
1808         {
1809                 SetWinners(team, COLOR_TEAM2);
1810         }
1811         else
1812         {
1813                 SetWinners(team, COLOR_TEAM1);
1814         }
1815
1816         entity ent;
1817         ent = find(world, classname, "target_assault_roundend");
1818         if(ent)
1819         {
1820                 if(ent.winning) // round end has been triggered by attacking team
1821                 {
1822                         bprint("ASSAULT: round completed...\n");
1823                         SetWinners(team, assault_attacker_team);
1824
1825                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1826
1827                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1828                         {
1829                                 status = WINNING_YES;
1830                         }
1831                         else
1832                         {
1833                                 entity oldself;
1834                                 oldself = self;
1835                                 self = ent;
1836                                 assault_new_round();
1837                                 self = oldself;
1838                         }
1839                 }
1840         }
1841
1842         return status;
1843 }
1844
1845 // LMS winning condition: game terminates if and only if there's at most one
1846 // one player who's living lives. Top two scores being equal cancels the time
1847 // limit.
1848 float WinningCondition_LMS()
1849 {
1850         entity head, head2;
1851         float have_player;
1852         float have_players;
1853         float l;
1854
1855         have_player = FALSE;
1856         have_players = FALSE;
1857         l = LMS_NewPlayerLives();
1858
1859         head = find(world, classname, "player");
1860         if(head)
1861                 have_player = TRUE;
1862         head2 = find(head, classname, "player");
1863         if(head2)
1864                 have_players = TRUE;
1865
1866         if(have_player)
1867         {
1868                 // we have at least one player
1869                 if(have_players)
1870                 {
1871                         // two or more active players - continue with the game
1872                 }
1873                 else
1874                 {
1875                         // exactly one player?
1876
1877                         ClearWinners();
1878                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1879
1880                         if(l)
1881                         {
1882                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1883                                 return WINNING_NO;
1884                         }
1885                         else
1886                         {
1887                                 // a winner!
1888                                 // and assign him his first place
1889                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1890                                 return WINNING_YES;
1891                         }
1892                 }
1893         }
1894         else
1895         {
1896                 // nobody is playing at all...
1897                 if(l)
1898                 {
1899                         // wait for players...
1900                 }
1901                 else
1902                 {
1903                         // SNAFU (maybe a draw game?)
1904                         ClearWinners();
1905                         dprint("No players, ending game.\n");
1906                         return WINNING_YES;
1907                 }
1908         }
1909
1910         // When we get here, we have at least two players who are actually LIVING,
1911         // now check if the top two players have equal score.
1912         WinningConditionHelper();
1913
1914         ClearWinners();
1915         if(WinningConditionHelper_winner)
1916                 WinningConditionHelper_winner.winning = TRUE;
1917         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1918                 return WINNING_NEVER;
1919
1920         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1921         return WINNING_NO;
1922 }
1923
1924 void ShuffleMaplist()
1925 {
1926         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1927 }
1928
1929 float leaderfrags;
1930 float WinningCondition_Scores(float limit, float leadlimit)
1931 {
1932         float limitreached;
1933
1934         // TODO make everything use THIS winning condition (except LMS)
1935         WinningConditionHelper();
1936
1937         if(teamplay)
1938         {
1939                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1940                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1941                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1942                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1943         }
1944
1945         ClearWinners();
1946         if(WinningConditionHelper_winner)
1947                 WinningConditionHelper_winner.winning = 1;
1948         if(WinningConditionHelper_winnerteam >= 0)
1949                 SetWinners(team, WinningConditionHelper_winnerteam);
1950
1951         if(WinningConditionHelper_lowerisbetter)
1952         {
1953                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1954                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1955                 limit = -limit;
1956         }
1957
1958         if(WinningConditionHelper_zeroisworst)
1959                 leadlimit = 0; // not supported in this mode
1960
1961         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1962         // these modes always score in increments of 1, thus this makes sense
1963         {
1964                 if(leaderfrags != WinningConditionHelper_topscore)
1965                 {
1966                         leaderfrags = WinningConditionHelper_topscore;
1967
1968                         if (limit)
1969                         if (leaderfrags == limit - 1)
1970                                 Announce("1fragleft");
1971                         else if (leaderfrags == limit - 2)
1972                                 Announce("2fragsleft");
1973                         else if (leaderfrags == limit - 3)
1974                                 Announce("3fragsleft");
1975                 }
1976         }
1977
1978         limitreached = FALSE;
1979         if(limit)
1980                 if(WinningConditionHelper_topscore >= limit)
1981                         limitreached = TRUE;
1982         if(leadlimit)
1983         {
1984                 float leadlimitreached;
1985                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1986                 if(autocvar_leadlimit_and_fraglimit)
1987                         limitreached = (limitreached && leadlimitreached);
1988                 else
1989                         limitreached = (limitreached || leadlimitreached);
1990         }
1991
1992         if(limit)
1993                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1994
1995         return GetWinningCode(
1996                 WinningConditionHelper_topscore && limitreached,
1997                 WinningConditionHelper_equality
1998         );
1999 }
2000
2001 float WinningCondition_Race(float fraglimit)
2002 {
2003         float wc;
2004         entity p;
2005         float n, c;
2006
2007         n = 0;
2008         c = 0;
2009         FOR_EACH_PLAYER(p)
2010         {
2011                 ++n;
2012                 if(p.race_completed)
2013                         ++c;
2014         }
2015         if(n && (n == c))
2016                 return WINNING_YES;
2017         wc = WinningCondition_Scores(fraglimit, 0);
2018
2019         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2020         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2021         // do NOT support equality when the laps are all raced!
2022                 return WINNING_STARTSUDDENDEATHOVERTIME;
2023         else
2024                 return WINNING_NEVER;
2025 }
2026
2027 float WinningCondition_QualifyingThenRace(float limit)
2028 {
2029         float wc;
2030         wc = WinningCondition_Scores(limit, 0);
2031
2032         // NEVER initiate overtime
2033         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2034         {
2035                 return WINNING_YES;
2036         }
2037
2038         return wc;
2039 }
2040
2041 float WinningCondition_RanOutOfSpawns()
2042 {
2043         entity head;
2044
2045         if(have_team_spawns <= 0)
2046                 return WINNING_NO;
2047
2048         if(autocvar_g_spawn_useallspawns <= 0)
2049                 return WINNING_NO;
2050
2051         if(!some_spawn_has_been_used)
2052                 return WINNING_NO;
2053
2054         team1_score = team2_score = team3_score = team4_score = 0;
2055
2056         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2057         {
2058                 if(head.team == COLOR_TEAM1)
2059                         team1_score = 1;
2060                 else if(head.team == COLOR_TEAM2)
2061                         team2_score = 1;
2062                 else if(head.team == COLOR_TEAM3)
2063                         team3_score = 1;
2064                 else if(head.team == COLOR_TEAM4)
2065                         team4_score = 1;
2066         }
2067
2068         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2069         {
2070                 if(head.team == COLOR_TEAM1)
2071                         team1_score = 1;
2072                 else if(head.team == COLOR_TEAM2)
2073                         team2_score = 1;
2074                 else if(head.team == COLOR_TEAM3)
2075                         team3_score = 1;
2076                 else if(head.team == COLOR_TEAM4)
2077                         team4_score = 1;
2078         }
2079
2080         ClearWinners();
2081         if(team1_score + team2_score + team3_score + team4_score == 0)
2082         {
2083                 checkrules_equality = TRUE;
2084                 return WINNING_YES;
2085         }
2086         else if(team1_score + team2_score + team3_score + team4_score == 1)
2087         {
2088                 float t, i;
2089                 if(team1_score)
2090                         t = COLOR_TEAM1;
2091                 else if(team2_score)
2092                         t = COLOR_TEAM2;
2093                 else if(team3_score)
2094                         t = COLOR_TEAM3;
2095                 else // if(team4_score)
2096                         t = COLOR_TEAM4;
2097                 CheckAllowedTeams(world);
2098                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2099                 {
2100                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2101                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2102                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2103                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2104                 }
2105
2106                 AddWinners(team, t);
2107                 return WINNING_YES;
2108         }
2109         else
2110                 return WINNING_NO;
2111 }
2112
2113 /*
2114 ============
2115 CheckRules_World
2116
2117 Exit deathmatch games upon conditions
2118 ============
2119 */
2120 void ReadyRestart();
2121 void CheckRules_World()
2122 {
2123         float timelimit;
2124         float fraglimit;
2125         float leadlimit;
2126
2127         VoteThink();
2128         MapVote_Think();
2129
2130         SetDefaultAlpha();
2131
2132         /*
2133         MapVote_Think should now do that part
2134         if (intermission_running)
2135                 if (time >= intermission_exittime + 60)
2136                 {
2137                         if(!DoNextMapOverride())
2138                                 GotoNextMap();
2139                         return;
2140                 }
2141         */
2142
2143         if (gameover)   // someone else quit the game already
2144         {
2145                 if(player_count == 0) // Nobody there? Then let's go to the next map
2146                         MapVote_Start();
2147                         // this will actually check the player count in the next frame
2148                         // again, but this shouldn't hurt
2149                 return;
2150         }
2151
2152         timelimit = autocvar_timelimit * 60;
2153         fraglimit = autocvar_fraglimit;
2154         leadlimit = autocvar_leadlimit;
2155
2156         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2157         {
2158                 if(timelimit > 0)
2159                         timelimit = 0; // timelimit is not made for warmup
2160                 if(fraglimit > 0)
2161                         fraglimit = 0; // no fraglimit for now
2162                 leadlimit = 0; // no leadlimit for now
2163         }
2164
2165         if(timelimit > 0)
2166         {
2167                 timelimit += game_starttime;
2168         }
2169         else if (timelimit < 0)
2170         {
2171                 // endmatch
2172                 NextLevel();
2173                 return;
2174         }
2175
2176         if(g_onslaught)
2177                 timelimit = 0; // ONS has its own overtime rule
2178
2179         float wantovertime;
2180         wantovertime = 0;
2181
2182         if(timelimit > game_starttime)
2183                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2184         else
2185                 game_completion_ratio = 0;
2186
2187         if(checkrules_suddendeathend)
2188         {
2189                 if(!checkrules_suddendeathwarning)
2190                 {
2191                         checkrules_suddendeathwarning = TRUE;
2192                         if(g_race && !g_race_qualifying)
2193                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2194                         else
2195                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2196                 }
2197         }
2198         else
2199         {
2200                 if (timelimit && time >= timelimit)
2201                 {
2202                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2203                         {
2204                                 float totalplayers;
2205                                 float playerswithlaps;
2206                                 float readyplayers;
2207                                 entity head;
2208                                 totalplayers = playerswithlaps = readyplayers = 0;
2209                                 FOR_EACH_PLAYER(head)
2210                                 {
2211                                         ++totalplayers;
2212                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2213                                                 ++playerswithlaps;
2214                                         if(head.ready)
2215                                                 ++readyplayers;
2216                                 }
2217
2218                                 // at least 2 of the players have completed a lap: start the RACE
2219                                 // otherwise, the players should end the qualifying on their own
2220                                 if(readyplayers || playerswithlaps >= 2)
2221                                 {
2222                                         checkrules_suddendeathend = 0;
2223                                         ReadyRestart(); // go to race
2224                                         return;
2225                                 }
2226                                 else
2227                                         wantovertime |= InitiateSuddenDeath();
2228                         }
2229                         else
2230                                 wantovertime |= InitiateSuddenDeath();
2231                 }
2232         }
2233
2234         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2235         {
2236                 NextLevel();
2237                 return;
2238         }
2239
2240         float checkrules_status;
2241         checkrules_status = WinningCondition_RanOutOfSpawns();
2242         if(checkrules_status == WINNING_YES)
2243         {
2244                 bprint("Hey! Someone ran out of spawns!\n");
2245         }
2246         else if(g_race && !g_race_qualifying && timelimit >= 0)
2247         {
2248                 checkrules_status = WinningCondition_Race(fraglimit);
2249                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2250         }
2251         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2252         {
2253                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2254                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2255         }
2256         else if(g_assault)
2257         {
2258                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2259         }
2260         else if(g_lms)
2261         {
2262                 checkrules_status = WinningCondition_LMS();
2263         }
2264         else if (g_onslaught)
2265         {
2266                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2267         }
2268         else
2269         {
2270                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2271                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2272         }
2273
2274         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2275         {
2276                 checkrules_status = WINNING_NEVER;
2277                 checkrules_overtimesadded = -1;
2278                 wantovertime |= InitiateSuddenDeath();
2279         }
2280
2281         if(checkrules_status == WINNING_NEVER)
2282                 // equality cases! Nobody wins if the overtime ends in a draw.
2283                 ClearWinners();
2284
2285         if(wantovertime)
2286         {
2287                 if(checkrules_status == WINNING_NEVER)
2288                         InitiateOvertime();
2289                 else
2290                         checkrules_status = WINNING_YES;
2291         }
2292
2293         if(checkrules_suddendeathend)
2294                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2295                         checkrules_status = WINNING_YES;
2296
2297         if(checkrules_status == WINNING_YES)
2298         {
2299                 //print("WINNING\n");
2300                 NextLevel();
2301         }
2302 }
2303
2304 float mapvote_nextthink;
2305 float mapvote_initialized;
2306 float mapvote_keeptwotime;
2307 float mapvote_timeout;
2308 string mapvote_message;
2309 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2310 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2311 float mapvote_screenshot_dirs_count;
2312
2313 float mapvote_count;
2314 float mapvote_count_real;
2315 string mapvote_maps[MAPVOTE_COUNT];
2316 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2317 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2318 float mapvote_maps_suggested[MAPVOTE_COUNT];
2319 string mapvote_suggestions[MAPVOTE_COUNT];
2320 float mapvote_suggestion_ptr;
2321 float mapvote_voters;
2322 float mapvote_selections[MAPVOTE_COUNT];
2323 float mapvote_run;
2324 float mapvote_detail;
2325 float mapvote_abstain;
2326 .float mapvote;
2327
2328 void MapVote_ClearAllVotes()
2329 {
2330         FOR_EACH_CLIENT(other)
2331                 other.mapvote = 0;
2332 }
2333
2334 string MapVote_Suggest(string m)
2335 {
2336         float i;
2337         if(m == "")
2338                 return "That's not how to use this command.";
2339         if(!autocvar_g_maplist_votable_suggestions)
2340                 return "Suggestions are not accepted on this server.";
2341         if(mapvote_initialized)
2342                 return "Can't suggest - voting is already in progress!";
2343         m = MapInfo_FixName(m);
2344         if not(m)
2345                 return "The map you suggested is not available on this server.";
2346         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2347                 if(Map_IsRecent(m))
2348                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2349
2350         if(!MapInfo_CheckMap(m))
2351                 return "The map you suggested does not support the current game mode.";
2352         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2353                 if(mapvote_suggestions[i] == m)
2354                         return "This map was already suggested.";
2355         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2356         {
2357                 i = floor(random() * mapvote_suggestion_ptr);
2358         }
2359         else
2360         {
2361                 i = mapvote_suggestion_ptr;
2362                 mapvote_suggestion_ptr += 1;
2363         }
2364         if(mapvote_suggestions[i] != "")
2365                 strunzone(mapvote_suggestions[i]);
2366         mapvote_suggestions[i] = strzone(m);
2367         if(autocvar_sv_eventlog)
2368                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2369         return strcat("Suggestion of ", m, " accepted.");
2370 }
2371
2372 void MapVote_AddVotable(string nextMap, float isSuggestion)
2373 {
2374         float j, i, o;
2375         string pakfile, mapfile;
2376
2377         if(nextMap == "")
2378                 return;
2379         for(j = 0; j < mapvote_count; ++j)
2380                 if(mapvote_maps[j] == nextMap)
2381                         return;
2382         // suggestions might be no longer valid/allowed after gametype switch!
2383         if(isSuggestion)
2384                 if(!MapInfo_CheckMap(nextMap))
2385                         return;
2386         mapvote_maps[mapvote_count] = strzone(nextMap);
2387         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2388
2389         pakfile = string_null;
2390         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2391         {
2392                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2393                 pakfile = whichpack(strcat(mapfile, ".tga"));
2394                 if(pakfile == "")
2395                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2396                 if(pakfile == "")
2397                         pakfile = whichpack(strcat(mapfile, ".png"));
2398                 if(pakfile != "")
2399                         break;
2400         }
2401         if(i >= mapvote_screenshot_dirs_count)
2402                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2403         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2404                 pakfile = substring(pakfile, o, -1);
2405
2406         mapvote_maps_screenshot_dir[mapvote_count] = i;
2407         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2408
2409         mapvote_count += 1;
2410 }
2411
2412 void MapVote_Spawn();
2413 void MapVote_Init()
2414 {
2415         float i;
2416         float nmax, smax;
2417
2418         MapVote_ClearAllVotes();
2419
2420         mapvote_count = 0;
2421         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2422         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2423
2424         if(mapvote_abstain)
2425                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2426         else
2427                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2428         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2429
2430         // we need this for AddVotable, as that cycles through the screenshot dirs
2431         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2432         if(mapvote_screenshot_dirs_count == 0)
2433                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2434         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2435         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2436                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2437
2438         if(mapvote_suggestion_ptr)
2439                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2440                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2441
2442         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2443                 MapVote_AddVotable(GetNextMap(), FALSE);
2444
2445         if(mapvote_count == 0)
2446         {
2447                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2448                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2449                 if(autocvar_g_maplist_shuffle)
2450                         ShuffleMaplist();
2451                 localcmd("\nmenu_cmd sync\n");
2452                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2453                         MapVote_AddVotable(GetNextMap(), FALSE);
2454         }
2455
2456         mapvote_count_real = mapvote_count;
2457         if(mapvote_abstain)
2458                 MapVote_AddVotable("don't care", 0);
2459
2460         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2461
2462         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2463         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2464         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2465                 mapvote_keeptwotime = 0;
2466         mapvote_message = "Choose a map and press its key!";
2467
2468         MapVote_Spawn();
2469 }
2470
2471 void MapVote_SendPicture(float id)
2472 {
2473         msg_entity = self;
2474         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2475         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2476         WriteByte(MSG_ONE, id);
2477         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2478 }
2479
2480 float MapVote_GetMapMask()
2481 {
2482         float mask, i, power;
2483         mask = 0;
2484         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2485                 if(mapvote_maps[i] != "")
2486                         mask |= power;
2487         return mask;
2488 }
2489
2490 entity mapvote_ent;
2491 float MapVote_SendEntity(entity to, float sf)
2492 {
2493         float i;
2494
2495         if(sf & 1)
2496                 sf &~= 2; // if we send 1, we don't need to also send 2
2497
2498         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2499         WriteByte(MSG_ENTITY, sf);
2500
2501         if(sf & 1)
2502         {
2503                 // flag 1 == initialization
2504                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2505                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2506                 WriteString(MSG_ENTITY, "");
2507                 WriteByte(MSG_ENTITY, mapvote_count);
2508                 WriteByte(MSG_ENTITY, mapvote_abstain);
2509                 WriteByte(MSG_ENTITY, mapvote_detail);
2510                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2511                 if(mapvote_count <= 8)
2512                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2513                 else
2514                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2515                 for(i = 0; i < mapvote_count; ++i)
2516                         if(mapvote_maps[i] != "")
2517                         {
2518                                 if(mapvote_abstain && i == mapvote_count - 1)
2519                                 {
2520                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2521                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2522                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2523                                 }
2524                                 else
2525                                 {
2526                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2527                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2528                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2529                                 }
2530                         }
2531         }
2532
2533         if(sf & 2)
2534         {
2535                 // flag 2 == update of mask
2536                 if(mapvote_count <= 8)
2537                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2538                 else
2539                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2540         }
2541
2542         if(sf & 4)
2543         {
2544                 if(mapvote_detail)
2545                         for(i = 0; i < mapvote_count; ++i)
2546                                 if(mapvote_maps[i] != "")
2547                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2548
2549                 WriteByte(MSG_ENTITY, to.mapvote);
2550         }
2551
2552         return TRUE;
2553 }
2554
2555 void MapVote_Spawn()
2556 {
2557         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2558 }
2559
2560 void MapVote_TouchMask()
2561 {
2562         mapvote_ent.SendFlags |= 2;
2563 }
2564
2565 void MapVote_TouchVotes(entity voter)
2566 {
2567         mapvote_ent.SendFlags |= 4;
2568 }
2569
2570 float MapVote_Finished(float mappos)
2571 {
2572         string result;
2573         float i;
2574         float didntvote;
2575
2576         if(autocvar_sv_eventlog)
2577         {
2578                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2579                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2580                 didntvote = mapvote_voters;
2581                 for(i = 0; i < mapvote_count; ++i)
2582                         if(mapvote_maps[i] != "")
2583                         {
2584                                 didntvote -= mapvote_selections[i];
2585                                 if(i != mappos)
2586                                 {
2587                                         result = strcat(result, ":", mapvote_maps[i]);
2588                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2589                                 }
2590                         }
2591                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2592
2593                 GameLogEcho(result);
2594                 if(mapvote_maps_suggested[mappos])
2595                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2596         }
2597
2598         FOR_EACH_REALCLIENT(other)
2599                 FixClientCvars(other);
2600
2601         Map_Goto_SetStr(mapvote_maps[mappos]);
2602         Map_Goto(0);
2603         alreadychangedlevel = TRUE;
2604         return TRUE;
2605 }
2606 void MapVote_CheckRules_1()
2607 {
2608         float i;
2609
2610         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2611         {
2612                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2613                 mapvote_selections[i] = 0;
2614         }
2615
2616         mapvote_voters = 0;
2617         FOR_EACH_REALCLIENT(other)
2618         {
2619                 ++mapvote_voters;
2620                 if(other.mapvote)
2621                 {
2622                         i = other.mapvote - 1;
2623                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2624                         mapvote_selections[i] = mapvote_selections[i] + 1;
2625                 }
2626         }
2627 }
2628
2629 float MapVote_CheckRules_2()
2630 {
2631         float i;
2632         float firstPlace, secondPlace;
2633         float firstPlaceVotes, secondPlaceVotes;
2634         float mapvote_voters_real;
2635         string result;
2636
2637         if(mapvote_count_real == 1)
2638                 return MapVote_Finished(0);
2639
2640         mapvote_voters_real = mapvote_voters;
2641         if(mapvote_abstain)
2642                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2643
2644         RandomSelection_Init();
2645         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2646                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2647         firstPlace = RandomSelection_chosen_float;
2648         firstPlaceVotes = RandomSelection_best_priority;
2649         //dprint("First place: ", ftos(firstPlace), "\n");
2650         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2651
2652         RandomSelection_Init();
2653         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2654                 if(i != firstPlace)
2655                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2656         secondPlace = RandomSelection_chosen_float;
2657         secondPlaceVotes = RandomSelection_best_priority;
2658         //dprint("Second place: ", ftos(secondPlace), "\n");
2659         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2660
2661         if(firstPlace == -1)
2662                 error("No first place in map vote... WTF?");
2663
2664         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2665                 return MapVote_Finished(firstPlace);
2666
2667         if(mapvote_keeptwotime)
2668                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2669                 {
2670                         float didntvote;
2671                         MapVote_TouchMask();
2672                         mapvote_message = "Now decide between the TOP TWO!";
2673                         mapvote_keeptwotime = 0;
2674                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2675                         result = strcat(result, ":", ftos(firstPlaceVotes));
2676                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2677                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2678                         didntvote = mapvote_voters;
2679                         for(i = 0; i < mapvote_count; ++i)
2680                                 if(mapvote_maps[i] != "")
2681                                 {
2682                                         didntvote -= mapvote_selections[i];
2683                                         if(i != firstPlace)
2684                                                 if(i != secondPlace)
2685                                                 {
2686                                                         result = strcat(result, ":", mapvote_maps[i]);
2687                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2688                                                         if(i < mapvote_count_real)
2689                                                         {
2690                                                                 strunzone(mapvote_maps[i]);
2691                                                                 mapvote_maps[i] = "";
2692                                                                 strunzone(mapvote_maps_pakfile[i]);
2693                                                                 mapvote_maps_pakfile[i] = "";
2694                                                         }
2695                                                 }
2696                                 }
2697                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2698                         if(autocvar_sv_eventlog)
2699                                 GameLogEcho(result);
2700                 }
2701
2702         return FALSE;
2703 }
2704 void MapVote_Tick()
2705 {
2706         float keeptwo;
2707         float totalvotes;
2708
2709         keeptwo = mapvote_keeptwotime;
2710         MapVote_CheckRules_1(); // count
2711         if(MapVote_CheckRules_2()) // decide
2712                 return;
2713
2714         totalvotes = 0;
2715         FOR_EACH_REALCLIENT(other)
2716         {
2717                 // hide scoreboard again
2718                 if(other.health != 2342)
2719                 {
2720                         other.health = 2342;
2721                         other.impulse = 0;
2722                         if(clienttype(other) == CLIENTTYPE_REAL)
2723                         {
2724                                 msg_entity = other;
2725                                 WriteByte(MSG_ONE, SVC_FINALE);
2726                                 WriteString(MSG_ONE, "");
2727                         }
2728                 }
2729
2730                 // clear possibly invalid votes
2731                 if(mapvote_maps[other.mapvote - 1] == "")
2732                         other.mapvote = 0;
2733                 // use impulses as new vote
2734                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2735                         if(mapvote_maps[other.impulse - 1] != "")
2736                         {
2737                                 other.mapvote = other.impulse;
2738                                 MapVote_TouchVotes(other);
2739                         }
2740                 other.impulse = 0;
2741
2742                 if(other.mapvote)
2743                         ++totalvotes;
2744         }
2745
2746         MapVote_CheckRules_1(); // just count
2747 }
2748 void MapVote_Start()
2749 {
2750         if(mapvote_run)
2751                 return;
2752
2753         // wait for stats to be sent first
2754         if(!playerstats_waitforme)
2755                 return;
2756
2757         MapInfo_Enumerate();
2758         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2759                 mapvote_run = TRUE;
2760 }
2761 void MapVote_Think()
2762 {
2763         if(!mapvote_run)
2764                 return;
2765
2766         if(alreadychangedlevel)
2767                 return;
2768
2769         if(time < mapvote_nextthink)
2770                 return;
2771         //dprint("tick\n");
2772
2773         mapvote_nextthink = time + 0.5;
2774
2775         if(!mapvote_initialized)
2776         {
2777                 if(autocvar_rescan_pending == 1)
2778                 {
2779                         cvar_set("rescan_pending", "2");
2780                         localcmd("fs_rescan\nrescan_pending 3\n");
2781                         return;
2782                 }
2783                 else if(autocvar_rescan_pending == 2)
2784                 {
2785                         return;
2786                 }
2787                 else if(autocvar_rescan_pending == 3)
2788                 {
2789                         // now build missing mapinfo files
2790                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2791                                 return;
2792
2793                         // we're done, start the timer
2794                         cvar_set("rescan_pending", "0");
2795                 }
2796
2797                 mapvote_initialized = TRUE;
2798                 if(DoNextMapOverride(0))
2799                         return;
2800                 if(!autocvar_g_maplist_votable || player_count <= 0)
2801                 {
2802                         GotoNextMap(0);
2803                         return;
2804                 }
2805                 MapVote_Init();
2806         }
2807
2808         MapVote_Tick();
2809 }
2810
2811 string GotoMap(string m)
2812 {
2813         if(!MapInfo_CheckMap(m))
2814                 return "The map you chose is not available on this server.";
2815         cvar_set("nextmap", m);
2816         cvar_set("timelimit", "-1");
2817         if(mapvote_initialized || alreadychangedlevel)
2818         {
2819                 if(DoNextMapOverride(0))
2820                         return "Map switch initiated.";
2821                 else
2822                         return "Hm... no. For some reason I like THIS map more.";
2823         }
2824         else
2825                 return "Map switch will happen after scoreboard.";
2826 }
2827
2828
2829 void EndFrame()
2830 {
2831         float altime;
2832         FOR_EACH_REALCLIENT(self)
2833         {
2834                 if(self.classname == "spectator")
2835                 {
2836                         if(self.enemy.typehitsound)
2837                                 self.typehit_time = time;
2838                         else if(self.enemy.hitsound)
2839                                 self.hit_time = time;
2840                 }
2841                 else
2842                 {
2843                         if(self.typehitsound)
2844                                 self.typehit_time = time;
2845                         else if(self.hitsound)
2846                                 self.hit_time = time;
2847                 }
2848         }
2849         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2850         // add 1 frametime because after this, engine SV_Physics
2851         // increases time by a frametime and then networks the frame
2852         // add another frametime because client shows everything with
2853         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2854         // needed!
2855         FOR_EACH_CLIENT(self)
2856         {
2857                 self.hitsound = FALSE;
2858                 self.typehitsound = FALSE;
2859                 antilag_record(self, altime);
2860         }
2861 }
2862
2863
2864 /*
2865  * RedirectionThink:
2866  * returns TRUE if redirecting
2867  */
2868 float redirection_timeout;
2869 float redirection_nextthink;
2870 float RedirectionThink()
2871 {
2872         float clients_found;
2873
2874         if(redirection_target == "")
2875                 return FALSE;
2876
2877         if(!redirection_timeout)
2878         {
2879                 cvar_set("sv_public", "-2");
2880                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2881                 if(redirection_target == "self")
2882                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2883                 else
2884                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2885         }
2886
2887         if(time < redirection_nextthink)
2888                 return TRUE;
2889
2890         redirection_nextthink = time + 1;
2891
2892         clients_found = 0;
2893         FOR_EACH_REALCLIENT(self)
2894         {
2895                 // TODO add timer
2896                 print("Redirecting: sending connect command to ", self.netname, "\n");
2897                 if(redirection_target == "self")
2898                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2899                 else
2900                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2901                 ++clients_found;
2902         }
2903
2904         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2905
2906         if(time > redirection_timeout || clients_found == 0)
2907                 localcmd("\nwait; wait; wait; quit\n");
2908
2909         return TRUE;
2910 }
2911
2912 void TargetMusic_RestoreGame();
2913 void RestoreGame()
2914 {
2915         // Loaded from a save game
2916         // some things then break, so let's work around them...
2917
2918         // Progs DB (capture records)
2919         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2920
2921         // Mapinfo
2922         MapInfo_Shutdown();
2923         MapInfo_Enumerate();
2924         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2925         WeaponStats_Init();
2926
2927         TargetMusic_RestoreGame();
2928 }
2929
2930 void Shutdown()
2931 {
2932         entity e;
2933
2934         gameover = 2;
2935
2936         if(world_initialized > 0)
2937         {
2938                 world_initialized = 0;
2939                 print("Saving persistent data...\n");
2940                 Ban_SaveBans();
2941
2942                 PlayerStats_EndMatch(0);
2943                 FOR_EACH_CLIENT(e)
2944                         PlayerStats_AddGlobalInfo(e);
2945                 PlayerStats_Shutdown();
2946
2947                 if(!cheatcount_total)
2948                 {
2949                         if(autocvar_sv_db_saveasdump)
2950                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2951                         else
2952                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2953                 }
2954                 if(autocvar_developer)
2955                 {
2956                         if(autocvar_sv_db_saveasdump)
2957                                 db_dump(TemporaryDB, "server-temp.db");
2958                         else
2959                                 db_save(TemporaryDB, "server-temp.db");
2960                 }
2961                 CheatShutdown(); // must be after cheatcount check
2962                 db_close(ServerProgsDB);
2963                 db_close(TemporaryDB);
2964                 print("done!\n");
2965                 // tell the bot system the game is ending now
2966                 bot_endgame();
2967
2968                 WeaponStats_Shutdown();
2969                 MapInfo_Shutdown();
2970         }
2971         else if(world_initialized == 0)
2972         {
2973                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2974         }
2975 }