qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_td");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ctf_ignore_frags");
 364                 BADCVAR("g_domination_point_limit");
 365                 BADCVAR("g_friendlyfire");
 366                 BADCVAR("g_fullbrightitems");
 367                 BADCVAR("g_fullbrightplayers");
 368                 BADCVAR("g_keyhunt_point_limit");
 369                 BADCVAR("g_keyhunt_teams_override");
 370                 BADCVAR("g_lms_lives_override");
 371                 BADCVAR("g_maplist");
 372                 BADCVAR("g_maplist_check_waypoints");
 373                 BADCVAR("g_maplist_mostrecent_count");
 374                 BADCVAR("g_maplist_shuffle");
 375                 BADCVAR("g_maplist_votable");
 376                 BADCVAR("g_maplist_votable_abstain");
 377                 BADCVAR("g_maplist_votable_nodetail");
 378                 BADCVAR("g_maplist_votable_suggestions");
 379                 BADCVAR("g_maxplayers");
 380                 BADCVAR("g_mirrordamage");
 381                 BADCVAR("g_nexball_goallimit");
 382                 BADCVAR("g_powerups");
 383                 BADCVAR("g_start_delay");
 384                 BADCVAR("g_warmup");
 385                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 386                 BADCVAR("hostname");
 387                 BADCVAR("log_file");
 388                 BADCVAR("maxplayers");
 389                 BADCVAR("minplayers");
 390                 BADCVAR("net_address");
 391                 BADCVAR("port");
 392                 BADCVAR("rcon_password");
 393                 BADCVAR("rcon_restricted_commands");
 394                 BADCVAR("rcon_restricted_password");
 395                 BADCVAR("skill");
 396                 BADCVAR("sv_adminnick");
 397                 BADCVAR("sv_autoscreenshot");
 398                 BADCVAR("sv_autotaunt");
 399                 BADCVAR("sv_curl_defaulturl");
 400                 BADCVAR("sv_defaultcharacter");
 401                 BADCVAR("sv_defaultplayercolors");
 402                 BADCVAR("sv_defaultplayermodel");
 403                 BADCVAR("sv_defaultplayerskin");
 404                 BADCVAR("sv_maxidle");
 405                 BADCVAR("sv_maxrate");
 406                 BADCVAR("sv_motd");
 407                 BADCVAR("sv_public");
 408                 BADCVAR("sv_ready_restart");
 409                 BADCVAR("sv_status_privacy");
 410                 BADCVAR("sv_taunt");
 411                 BADCVAR("sv_vote_call");
 412                 BADCVAR("sv_vote_commands");
 413                 BADCVAR("sv_vote_majority_factor");
 414                 BADCVAR("sv_vote_master");
 415                 BADCVAR("sv_vote_master_commands");
 416                 BADCVAR("sv_vote_master_password");
 417                 BADCVAR("sv_vote_simple_majority_factor");
 418                 BADCVAR("sys_ticrate");
 419                 BADCVAR("teamplay_mode");
 420                 BADCVAR("timelimit_override");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADPREFIX("g_warmup_");
 423                 BADPREFIX("sv_ready_restart_");
 424
 425                 // mutators that announce themselves properly to the server browser
 426                 BADCVAR("g_minstagib");
 427                 BADCVAR("g_new_toys");
 428                 BADCVAR("g_nix");
 429
 430                 if(autocvar_g_minstagib)
 431                 {
 432                         BADCVAR("g_grappling_hook");
 433                         BADCVAR("g_jetpack");
 434                 }
 435 #undef BADPREFIX
 436 #undef BADCVAR
 437
 438                 if(pureadding)
 439                 {
 440                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 441                         if(strlen(cvar_purechanges) > 16384)
 442                         {
 443                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 444                                 pureadding = 0;
 445                         }
 446                 }
 447                 ++cvar_purechanges_count;
 448                 // WARNING: this variable is used for the server list
 449                 // NEVER dare to skip this code!
 450                 // Hacks to intentionally appearing as "pure server" even though you DO have
 451                 // modified settings may be punished by removal from the server list.
 452                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 453                 // though.
 454         }
 455         buf_del(h);
 456         if(cvar_changes == "")
 457                 cvar_changes = "// this server runs at default server settings\n";
 458         else
 459                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 460         cvar_changes = strzone(cvar_changes);
 461         if(cvar_purechanges == "")
 462                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 463         else
 464                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 465         cvar_purechanges = strzone(cvar_purechanges);
 466 }
 467
 468 void detect_maptype()
 469 {
 470 #if 0
 471         vector o, v;
 472         float i;
 473
 474         for(;;)
 475         {
 476                 o = world.mins;
 477                 o_x += random() * (world.maxs_x - world.mins_x);
 478                 o_y += random() * (world.maxs_y - world.mins_y);
 479                 o_z += random() * (world.maxs_z - world.mins_z);
 480
 481                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 482                 if(trace_fraction == 1)
 483                         continue;
 484
 485                 v = trace_endpos;
 486
 487                 for(i = 0; i < 64; i += 4)
 488                 {
 489                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 490         if(trace_fraction == 1)
 491                 continue;
 492                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 493                 }
 494
 495                 break;
 496         }
 497 #endif
 498 }
 499
 500 entity randomseed;
 501 float RandomSeed_Send(entity to, float sf)
 502 {
 503         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 504         WriteShort(MSG_ENTITY, self.cnt);
 505         return TRUE;
 506 }
 507 void RandomSeed_Think()
 508 {
 509         self.cnt = bound(0, floor(random() * 65536), 65535);
 510         self.nextthink = time + 5;
 511
 512         self.SendFlags |= 1;
 513 }
 514 void RandomSeed_Spawn()
 515 {
 516         randomseed = spawn();
 517         randomseed.think = RandomSeed_Think;
 518         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 519
 520         entity oldself;
 521         oldself = self;
 522         self = randomseed;
 523         self.think(); // sets random seed and nextthink
 524         self = oldself;
 525 }
 526
 527 void spawnfunc___init_dedicated_server(void)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e;
 539         e = spawn();
 540         e.think = GotoFirstMap;
 541         e.nextthink = time; // this is usually 1 at this point
 542
 543         e = spawn();
 544         e.classname = "info_player_deathmatch"; // safeguard against player joining
 545
 546         self.classname = "worldspawn"; // safeguard against various stuff ;)
 547
 548         // needs to be done so early because of the constants they create
 549         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 550         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 551         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 552         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s, col;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         allowed_to_spawn = TRUE;
 586
 587         entity head;
 588         head = nextent(world);
 589         maxclients = 0;
 590         while(head)
 591         {
 592                 ++maxclients;
 593                 head = nextent(head);
 594         }
 595
 596         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 597
 598         // needs to be done so early because of the constants they create
 599         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 600         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 601         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 602         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         GameLogInit(); // prepare everything
 674         // NOTE for matchid:
 675         // changing the logic generating it is okay. But:
 676         // it HAS to stay <= 64 chars
 677         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 678         if(autocvar_sv_eventlog)
 679         {
 680                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 681                 matchid = strzone(s);
 682
 683                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 684                 s = ":gameinfo:mutators:LIST";
 685
 686                 ret_string = s;
 687                 MUTATOR_CALLHOOK(BuildMutatorsString);
 688                 s = ret_string;
 689
 690                 // simple, probably not good in the mutator system
 691                 if(autocvar_g_grappling_hook)
 692                         s = strcat(s, ":grappling_hook");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(!autocvar_g_use_ammunition)
 696                         s = strcat(s, ":no_use_ammunition");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_pickup_items == 0)
 700                         s = strcat(s, ":no_pickup_items");
 701                 if(autocvar_g_pickup_items > 0)
 702                         s = strcat(s, ":pickup_items");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_weaponarena != "0")
 706                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_norecoil)
 710                         s = strcat(s, ":norecoil");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_midair)
 714                         s = strcat(s, ":midair");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_minstagib)
 718                         s = strcat(s, ":minstagib");
 719
 720                 // TODO to mutator system
 721                 if(autocvar_g_powerups == 0)
 722                         s = strcat(s, ":no_powerups");
 723                 if(autocvar_g_powerups > 0)
 724                         s = strcat(s, ":powerups");
 725
 726                 GameLogEcho(s);
 727                 GameLogEcho(":gameinfo:end");
 728         }
 729         else
 730                 matchid = strzone(ftos(random()));
 731
 732         cvar_set("nextmap", "");
 733
 734         SetDefaultAlpha();
 735
 736         if(autocvar_g_campaign)
 737                 CampaignPostInit();
 738
 739         fteqcc_testbugs();
 740
 741         Ban_LoadBans();
 742
 743         MapInfo_Enumerate();
 744         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 745
 746         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 747         {
 748                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 749                 if(fd != -1)
 750                 {
 751                         while((s = fgets(fd)))
 752                         {
 753                                 l = tokenize_console(s);
 754                                 if(l < 2)
 755                                         continue;
 756                                 if(argv(0) == "cd")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  cdtrack ", argv(2), "\n");
 760                                 }
 761                                 else if(argv(0) == "fog")
 762                                 {
 763                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 764                                         print("  \"fog\" \"", s, "\"\n");
 765                                 }
 766                                 else if(argv(0) == "set")
 767                                 {
 768                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 769                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 770                                 }
 771                                 else if(argv(0) != "//")
 772                                 {
 773                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 774                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 775                                 }
 776                         }
 777                         fclose(fd);
 778                 }
 779         }
 780
 781         WeaponStats_Init();
 782
 783         WEPSET_ADDSTAT();
 784         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 785         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 786         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 787         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 788         Nagger_Init();
 789
 790         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 791         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 792         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 793         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 794         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 795         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 796         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 797         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 798         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 799         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 800         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 801         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 802         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 803
 804         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 805         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 806
 807         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 808
 809         if(g_ca || g_freezetag)
 810         {
 811                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 812                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 813                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 814                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 815         }
 816         if(g_freezetag)
 817                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 818
 819         if(g_td)
 820         {
 821                 addstat(STAT_CURRENT_WAVE, AS_FLOAT, stat_current_wave);
 822                 addstat(STAT_TOTALWAVES, AS_FLOAT, stat_totalwaves);
 823         }
 824
 825         // freeze attacks
 826         addstat(STAT_FROZEN, AS_INT, frozen);
 827         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 828
 829         // g_movementspeed hack
 830         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 831         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 832         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 833         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 834
 835         // secrets
 836         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 837         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 838
 839         // monsters
 840         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 841         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 842
 843         // misc
 844         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 845
 846         next_pingtime = time + 5;
 847
 848         detect_maptype();
 849
 850         // set up information replies for clients and server to use
 851         lsmaps_reply = "^7Maps available: ";
 852         lsnewmaps_reply = "^7Maps without a record set: ";
 853         for(i = 0, j = 0; i < MapInfo_count; ++i)
 854         {
 855                 if(MapInfo_Get_ByID(i))
 856                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 857                         {
 858                                 if(mod(i, 2))
 859                                         col = "^2";
 860                                 else
 861                                         col = "^3";
 862
 863                                 ++j;
 864
 865                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 866
 867                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 868                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 869                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 870                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 871                         }
 872         }
 873
 874         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 875         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 876
 877         maplist_reply = "^7Maps in list: ";
 878         n = tokenize_console(autocvar_g_maplist);
 879         for(i = 0, j = 0; i < n; ++i)
 880         {
 881                 if(MapInfo_CheckMap(argv(i)))
 882                 {
 883                         if(mod(j, 2))
 884                                 col = "^2";
 885                         else
 886                                 col = "^3";
 887                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 888                         ++j;
 889                 }
 890         }
 891         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 892         MapInfo_ClearTemps();
 893
 894         for(i = 0; i < 10; ++i)
 895         {
 896                 s = getrecords(i);
 897                 if (s)
 898                         records_reply[i] = strzone(s);
 899         }
 900
 901         ladder_reply = strzone(getladder());
 902
 903         rankings_reply = strzone(getrankings());
 904
 905         // begin other init
 906         ClientInit_Spawn();
 907         RandomSeed_Spawn();
 908         PingPLReport_Spawn();
 909
 910         CheatInit();
 911
 912         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 913
 914         // fill sv_curl_serverpackages from .serverpackage files
 915         if(autocvar_sv_curl_serverpackages_auto)
 916         {
 917                 s = "";
 918                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 919                 for(i = 0; i < n; ++i)
 920                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 921                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 922                                 s = strcat(s, " ", argv(i));
 923                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 924                 if(fd >= 0)
 925                 {
 926                         j = search_getsize(fd);
 927                         for(i = 0; i < j; ++i)
 928                                 s = strcat(s, " ", search_getfilename(fd, i));
 929                         search_end(fd);
 930                 }
 931                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 932                 if(fd >= 0)
 933                 {
 934                         j = search_getsize(fd);
 935                         for(i = 0; i < j; ++i)
 936                                 s = strcat(s, " ", search_getfilename(fd, i));
 937                         search_end(fd);
 938                 }
 939                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 940         }
 941
 942         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 943         modname = "Xonotic";
 944         // physics/balance/config changes that count as mod
 945         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 946                 modname = cvar_string("g_mod_physics");
 947         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 948                 modname = cvar_string("g_mod_balance");
 949         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 950                 modname = cvar_string("g_mod_config");
 951         // weird mutators that deserve to count as mod
 952         if(autocvar_g_minstagib)
 953                 modname = "MinstaGib";
 954         if(autocvar_g_monsters)
 955                 modname = "Monsters";
 956         // extra mutators that deserve to count as mod
 957         MUTATOR_CALLHOOK(SetModname);
 958
 959         // save it for later
 960         modname = strzone(modname);
 961
 962         WinningConditionHelper(); // set worldstatus
 963
 964         world_initialized = 1;
 965 }
 966
 967 void spawnfunc_light (void)
 968 {
 969         //makestatic (self); // Who the f___ did that?
 970         remove(self);
 971 }
 972
 973 string GetGametype()
 974 {
 975         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 976 }
 977
 978 string getmapname_stored;
 979 string GetMapname()
 980 {
 981         return mapname;
 982 }
 983
 984 float Map_Count, Map_Current;
 985 string Map_Current_Name;
 986
 987 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 988 float GetMaplistPosition()
 989 {
 990         float pos, idx;
 991         string map;
 992
 993         map = GetMapname();
 994         idx = autocvar_g_maplist_index;
 995
 996         if(idx >= 0)
 997                 if(idx < Map_Count)
 998                         if(map == argv(idx))
 999                                 return idx;
1000
1001         for(pos = 0; pos < Map_Count; ++pos)
1002                 if(map == argv(pos))
1003                         return pos;
1004
1005         // resume normal maplist rotation if current map is not in g_maplist
1006         return idx;
1007 }
1008
1009 float MapHasRightSize(string map)
1010 {
1011         float fh;
1012         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1013         if(autocvar_g_maplist_check_waypoints)
1014         {
1015                 dprint("checkwp "); dprint(map);
1016                 if(!fexists(strcat("maps/", map, ".waypoints")))
1017                 {
1018                         dprint(": no waypoints\n");
1019                         return FALSE;
1020                 }
1021                 dprint(": has waypoints\n");
1022         }
1023
1024         // open map size restriction file
1025         dprint("opensize "); dprint(map);
1026         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1027         if(fh >= 0)
1028         {
1029                 float mapmin, mapmax;
1030                 dprint(": ok, ");
1031                 mapmin = stof(fgets(fh));
1032                 mapmax = stof(fgets(fh));
1033                 fclose(fh);
1034                 if(player_count < mapmin)
1035                 {
1036                         dprint("not enough\n");
1037                         return FALSE;
1038                 }
1039                 if(player_count > mapmax)
1040                 {
1041                         dprint("too many\n");
1042                         return FALSE;
1043                 }
1044                 dprint("right size\n");
1045                 return TRUE;
1046         }
1047         dprint(": not found\n");
1048         return TRUE;
1049 }
1050
1051 string Map_Filename(float position)
1052 {
1053         return strcat("maps/", argv(position), ".bsp");
1054 }
1055
1056 string strwords(string s, float w)
1057 {
1058         float endpos;
1059         for(endpos = 0; w && endpos >= 0; --w)
1060                 endpos = strstrofs(s, " ", endpos + 1);
1061         if(endpos < 0)
1062                 return s;
1063         else
1064                 return substring(s, 0, endpos);
1065 }
1066
1067 float strhasword(string s, string w)
1068 {
1069         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1070 }
1071
1072 void Map_MarkAsRecent(string m)
1073 {
1074         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1075 }
1076
1077 float Map_IsRecent(string m)
1078 {
1079         return strhasword(autocvar_g_maplist_mostrecent, m);
1080 }
1081
1082 float Map_Check(float position, float pass)
1083 {
1084         string filename;
1085         string map_next;
1086         map_next = argv(position);
1087         if(pass <= 1)
1088         {
1089                 if(Map_IsRecent(map_next))
1090                         return 0;
1091         }
1092         filename = Map_Filename(position);
1093         if(MapInfo_CheckMap(map_next))
1094         {
1095                 if(pass == 2)
1096                         return 1;
1097                 if(MapHasRightSize(map_next))
1098                         return 1;
1099                 return 0;
1100         }
1101         else
1102                 dprint( "Couldn't select '", filename, "'..\n" );
1103
1104         return 0;
1105 }
1106
1107 void Map_Goto_SetStr(string nextmapname)
1108 {
1109         if(getmapname_stored != "")
1110                 strunzone(getmapname_stored);
1111         if(nextmapname == "")
1112                 getmapname_stored = "";
1113         else
1114                 getmapname_stored = strzone(nextmapname);
1115 }
1116
1117 void Map_Goto_SetFloat(float position)
1118 {
1119         cvar_set("g_maplist_index", ftos(position));
1120         Map_Goto_SetStr(argv(position));
1121 }
1122
1123 void Map_Goto(float reinit)
1124 {
1125         MapInfo_LoadMap(getmapname_stored, reinit);
1126 }
1127
1128 // return codes of map selectors:
1129 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1130 //   -2 = permanent failure
1131 float() MaplistMethod_Iterate = // usual method
1132 {
1133         float pass, i;
1134
1135         for(pass = 1; pass <= 2; ++pass)
1136         {
1137                 for(i = 1; i < Map_Count; ++i)
1138                 {
1139                         float mapindex;
1140                         mapindex = mod(i + Map_Current, Map_Count);
1141                         if(Map_Check(mapindex, pass))
1142                                 return mapindex;
1143                 }
1144         }
1145         return -1;
1146 }
1147
1148 float() MaplistMethod_Repeat = // fallback method
1149 {
1150         if(Map_Check(Map_Current, 2))
1151                 return Map_Current;
1152         return -2;
1153 }
1154
1155 float() MaplistMethod_Random = // random map selection
1156 {
1157         float i, imax;
1158
1159         imax = 42;
1160
1161         for(i = 0; i <= imax; ++i)
1162         {
1163                 float mapindex;
1164                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1165                 if(Map_Check(mapindex, 1))
1166                         return mapindex;
1167         }
1168         return -1;
1169 }
1170
1171 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1172 // the exponent sets a bias on the map selection:
1173 // the higher the exponent, the less likely "shortly repeated" same maps are
1174 {
1175         float i, j, imax, insertpos;
1176
1177         imax = 42;
1178
1179         for(i = 0; i <= imax; ++i)
1180         {
1181                 string newlist;
1182
1183                 // now reinsert this at another position
1184                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1185                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1186                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1187                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1188
1189                 // insert the current map there
1190                 newlist = "";
1191                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1192                         newlist = strcat(newlist, " ", argv(j));
1193                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1194                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1195                         newlist = strcat(newlist, " ", argv(j));
1196                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1197                 cvar_set("g_maplist", newlist);
1198                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1199
1200                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1201                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1202                 if(Map_Check(Map_Current, 1))
1203                         return Map_Current;
1204         }
1205         return -1;
1206 }
1207
1208 void Maplist_Init()
1209 {
1210         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1211         if(Map_Count == 0)
1212         {
1213                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1214                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1215                 if(autocvar_g_maplist_shuffle)
1216                         ShuffleMaplist();
1217                 localcmd("\nmenu_cmd sync\n");
1218                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1219         }
1220         if(Map_Count == 0)
1221                 error("empty maplist, cannot select a new map");
1222         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1223
1224         if(Map_Current_Name)
1225                 strunzone(Map_Current_Name);
1226         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1227         // this may or may not be correct, but who cares, in the worst case a map
1228         // isn't chosen in the first pass that should have been
1229 }
1230
1231 string GetNextMap()
1232 {
1233         float nextMap;
1234
1235         Maplist_Init();
1236         nextMap = -1;
1237
1238         if(nextMap == -1)
1239                 if(autocvar_g_maplist_shuffle > 0)
1240                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1241
1242         if(nextMap == -1)
1243                 if(autocvar_g_maplist_selectrandom)
1244                         nextMap = MaplistMethod_Random();
1245
1246         if(nextMap == -1)
1247                 nextMap = MaplistMethod_Iterate();
1248
1249         if(nextMap == -1)
1250                 nextMap = MaplistMethod_Repeat();
1251
1252         if(nextMap >= 0)
1253         {
1254                 Map_Goto_SetFloat(nextMap);
1255                 return getmapname_stored;
1256         }
1257
1258         return "";
1259 }
1260
1261 float DoNextMapOverride(float reinit)
1262 {
1263         if(autocvar_g_campaign)
1264         {
1265                 CampaignPostIntermission();
1266                 alreadychangedlevel = TRUE;
1267                 return TRUE;
1268         }
1269         if(autocvar_quit_when_empty)
1270         {
1271                 if(player_count <= currentbots)
1272                 {
1273                         localcmd("quit\n");
1274                         alreadychangedlevel = TRUE;
1275                         return TRUE;
1276                 }
1277         }
1278         if(autocvar_quit_and_redirect != "")
1279         {
1280                 redirection_target = strzone(autocvar_quit_and_redirect);
1281                 alreadychangedlevel = TRUE;
1282                 return TRUE;
1283         }
1284         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1285         {
1286                 localcmd("restart\n");
1287                 alreadychangedlevel = TRUE;
1288                 return TRUE;
1289         }
1290         if(autocvar_nextmap != "")
1291                 if(MapInfo_CheckMap(autocvar_nextmap))
1292                 {
1293                         Map_Goto_SetStr(autocvar_nextmap);
1294                         Map_Goto(reinit);
1295                         alreadychangedlevel = TRUE;
1296                         return TRUE;
1297                 }
1298         if(!reinit && autocvar_lastlevel)
1299         {
1300                 cvar_settemp_restore();
1301                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1302                 alreadychangedlevel = TRUE;
1303                 return TRUE;
1304         }
1305         return FALSE;
1306 }
1307
1308 void GotoNextMap(float reinit)
1309 {
1310         //string nextmap;
1311         //float n, nummaps;
1312         //string s;
1313         if (alreadychangedlevel)
1314                 return;
1315         alreadychangedlevel = TRUE;
1316
1317         {
1318                 string nextMap;
1319                 float allowReset;
1320
1321                 for(allowReset = 1; allowReset >= 0; --allowReset)
1322                 {
1323                         nextMap = GetNextMap();
1324                         if(nextMap != "")
1325                                 break;
1326
1327                         if(allowReset)
1328                         {
1329                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1330                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1331                                 if(autocvar_g_maplist_shuffle)
1332                                         ShuffleMaplist();
1333                                 localcmd("\nmenu_cmd sync\n");
1334                         }
1335                         else
1336                         {
1337                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1338                         }
1339                 }
1340                 Map_Goto(reinit);
1341         }
1342 }
1343
1344
1345 /*
1346 ============
1347 IntermissionThink
1348
1349 When the player presses attack or jump, change to the next level
1350 ============
1351 */
1352 .float autoscreenshot;
1353 void() MapVote_Start;
1354 void() MapVote_Think;
1355 float mapvote_initialized;
1356 void IntermissionThink()
1357 {
1358         FixIntermissionClient(self);
1359
1360         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1361         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1362
1363         if( (server_screenshot || client_screenshot)
1364                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1365         {
1366                 self.autoscreenshot = -1;
1367                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1368                 return;
1369         }
1370
1371         if (time < intermission_exittime)
1372                 return;
1373
1374         if(!mapvote_initialized)
1375                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1376                         return;
1377
1378         MapVote_Start();
1379 }
1380
1381 /*
1382 ============
1383 FindIntermission
1384
1385 Returns the entity to view from
1386 ============
1387 */
1388 /*
1389 entity FindIntermission()
1390 {
1391         local   entity spot;
1392         local   float cyc;
1393
1394 // look for info_intermission first
1395         spot = find (world, classname, "info_intermission");
1396         if (spot)
1397         {       // pick a random one
1398                 cyc = random() * 4;
1399                 while (cyc > 1)
1400                 {
1401                         spot = find (spot, classname, "info_intermission");
1402                         if (!spot)
1403                                 spot = find (spot, classname, "info_intermission");
1404                         cyc = cyc - 1;
1405                 }
1406                 return spot;
1407         }
1408
1409 // then look for the start position
1410         spot = find (world, classname, "info_player_start");
1411         if (spot)
1412                 return spot;
1413
1414 // testinfo_player_start is only found in regioned levels
1415         spot = find (world, classname, "testplayerstart");
1416         if (spot)
1417                 return spot;
1418
1419 // then look for the start position
1420         spot = find (world, classname, "info_player_deathmatch");
1421         if (spot)
1422                 return spot;
1423
1424         //objerror ("FindIntermission: no spot");
1425         return world;
1426 }
1427 */
1428
1429 /*
1430 ===============================================================================
1431
1432 RULES
1433
1434 ===============================================================================
1435 */
1436
1437 void DumpStats(float final)
1438 {
1439         float file;
1440         string s;
1441         float to_console;
1442         float to_eventlog;
1443         float to_file;
1444         float i;
1445
1446         to_console = autocvar_sv_logscores_console;
1447         to_eventlog = autocvar_sv_eventlog;
1448         to_file = autocvar_sv_logscores_file;
1449
1450         if(!final)
1451         {
1452                 to_console = TRUE; // always print printstats replies
1453                 to_eventlog = FALSE; // but never print them to the event log
1454         }
1455
1456         if(to_eventlog)
1457                 if(autocvar_sv_eventlog_console)
1458                         to_console = FALSE; // otherwise we get the output twice
1459
1460         if(final)
1461                 s = ":scores:";
1462         else
1463                 s = ":status:";
1464         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1465
1466         if(to_console)
1467                 print(s, "\n");
1468         if(to_eventlog)
1469                 GameLogEcho(s);
1470
1471         file = -1;
1472         if(to_file)
1473         {
1474                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1475                 if(file == -1)
1476                         to_file = FALSE;
1477                 else
1478                         fputs(file, strcat(s, "\n"));
1479         }
1480
1481         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1482         if(to_console)
1483                 print(s, "\n");
1484         if(to_eventlog)
1485                 GameLogEcho(s);
1486         if(to_file)
1487                 fputs(file, strcat(s, "\n"));
1488
1489         FOR_EACH_CLIENT(other)
1490         {
1491                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1492                 {
1493                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1494                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1495                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1496                                 s = strcat(s, ftos(other.team), ":");
1497                         else
1498                                 s = strcat(s, "spectator:");
1499
1500                         if(to_console)
1501                                 print(s, other.netname, "\n");
1502                         if(to_eventlog)
1503                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1504                         if(to_file)
1505                                 fputs(file, strcat(s, other.netname, "\n"));
1506                 }
1507         }
1508
1509         if(teamplay)
1510         {
1511                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1512                 if(to_console)
1513                         print(s, "\n");
1514                 if(to_eventlog)
1515                         GameLogEcho(s);
1516                 if(to_file)
1517                         fputs(file, strcat(s, "\n"));
1518
1519                 for(i = 1; i < 16; ++i)
1520                 {
1521                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1522                         s = strcat(s, ":", ftos(i));
1523                         if(to_console)
1524                                 print(s, "\n");
1525                         if(to_eventlog)
1526                                 GameLogEcho(s);
1527                         if(to_file)
1528                                 fputs(file, strcat(s, "\n"));
1529                 }
1530         }
1531
1532         if(to_console)
1533                 print(":end\n");
1534         if(to_eventlog)
1535                 GameLogEcho(":end");
1536         if(to_file)
1537         {
1538                 fputs(file, ":end\n");
1539                 fclose(file);
1540         }
1541 }
1542
1543 void FixIntermissionClient(entity e)
1544 {
1545         string s;
1546         if(!e.autoscreenshot) // initial call
1547         {
1548                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1549                 e.health = -2342;
1550                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1551                 e.solid = SOLID_NOT;
1552                 e.movetype = MOVETYPE_NONE;
1553                 e.takedamage = DAMAGE_NO;
1554                 if(e.weaponentity)
1555                 {
1556                         e.weaponentity.effects = EF_NODRAW;
1557                         if (e.weaponentity.weaponentity)
1558                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1559                 }
1560                 if(clienttype(e) == CLIENTTYPE_REAL)
1561                 {
1562                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1563                         s = autocvar_sv_intermission_cdtrack;
1564                         if(s != "")
1565                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1566                         msg_entity = e;
1567                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1568                 }
1569         }
1570 }
1571
1572 void minstagib_stop_countdown(entity e);
1573 /*
1574 go to the next level for deathmatch
1575 only called if a time or frag limit has expired
1576 */
1577 void NextLevel()
1578 {
1579         gameover = TRUE;
1580
1581         intermission_running = 1;
1582
1583 // enforce a wait time before allowing changelevel
1584         if(player_count > 0)
1585                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1586         else
1587                 intermission_exittime = -1;
1588
1589         /*
1590         WriteByte (MSG_ALL, SVC_CDTRACK);
1591         WriteByte (MSG_ALL, 3);
1592         WriteByte (MSG_ALL, 3);
1593         // done in FixIntermission
1594         */
1595
1596         //pos = FindIntermission ();
1597
1598         VoteReset();
1599
1600         DumpStats(TRUE);
1601
1602         // send statistics
1603         entity e;
1604         PlayerStats_EndMatch(1);
1605         FOR_EACH_CLIENT(e)
1606                 PlayerStats_AddGlobalInfo(e);
1607         PlayerStats_Shutdown();
1608         WeaponStats_Shutdown();
1609
1610         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1611
1612         if(autocvar_sv_eventlog)
1613                 GameLogEcho(":gameover");
1614
1615         GameLogClose();
1616
1617         FOR_EACH_PLAYER(other) {
1618                 minstagib_stop_countdown(other);
1619                 FixIntermissionClient(other);
1620                 if(other.winning)
1621                         bprint(other.netname, " ^7wins.\n");
1622         }
1623
1624         if(autocvar_g_campaign)
1625                 CampaignPreIntermission();
1626
1627         MUTATOR_CALLHOOK(MatchEnd);
1628
1629         localcmd("\nsv_hook_gameend\n");
1630 }
1631
1632 /*
1633 ============
1634 CheckRules_Player
1635
1636 Exit deathmatch games upon conditions
1637 ============
1638 */
1639 void CheckRules_Player()
1640 {
1641         if (gameover)   // someone else quit the game already
1642                 return;
1643
1644         if(self.deadflag == DEAD_NO)
1645                 self.play_time += frametime;
1646
1647         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1648         //   (div0: and that in CheckRules_World please)
1649 }
1650
1651 float checkrules_equality;
1652 float checkrules_suddendeathwarning;
1653 float checkrules_suddendeathend;
1654 float checkrules_overtimesadded; //how many overtimes have been already added
1655
1656 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1657 float WINNING_YES = 1; // winner found
1658 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1659 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1660
1661 float InitiateSuddenDeath()
1662 {
1663         // Check first whether normal overtimes could be added before initiating suddendeath mode
1664         // - for this timelimit_overtime needs to be >0 of course
1665         // - also check the winning condition calculated in the previous frame and only add normal overtime
1666         //   again, if at the point at which timelimit would be extended again, still no winner was found
1667         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1668         {
1669                 return 1; // need to call InitiateOvertime later
1670         }
1671         else
1672         {
1673                 if(!checkrules_suddendeathend)
1674                 {
1675                         if(autocvar_g_campaign)
1676                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1677                         else
1678                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1679                         if(g_race && !g_race_qualifying)
1680                                 race_StartCompleting();
1681                 }
1682                 return 0;
1683         }
1684 }
1685
1686 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1687 {
1688         ++checkrules_overtimesadded;
1689         //add one more overtime by simply extending the timelimit
1690         float tl;
1691         tl = autocvar_timelimit;
1692         tl += autocvar_timelimit_overtime;
1693         cvar_set("timelimit", ftos(tl));
1694
1695         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime);
1696 }
1697
1698 float GetWinningCode(float fraglimitreached, float equality)
1699 {
1700         if(autocvar_g_campaign == 1)
1701                 if(fraglimitreached)
1702                         return WINNING_YES;
1703                 else
1704                         return WINNING_NO;
1705
1706         else
1707                 if(equality)
1708                         if(fraglimitreached)
1709                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1710                         else
1711                                 return WINNING_NEVER;
1712                 else
1713                         if(fraglimitreached)
1714                                 return WINNING_YES;
1715                         else
1716                                 return WINNING_NO;
1717 }
1718
1719 // set the .winning flag for exactly those players with a given field value
1720 void SetWinners(.float field, float value)
1721 {
1722         entity head;
1723         FOR_EACH_PLAYER(head)
1724                 head.winning = (head.field == value);
1725 }
1726
1727 // set the .winning flag for those players with a given field value
1728 void AddWinners(.float field, float value)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 if(head.field == value)
1733                         head.winning = 1;
1734 }
1735
1736 // clear the .winning flags
1737 void ClearWinners(void)
1738 {
1739         entity head;
1740         FOR_EACH_PLAYER(head)
1741                 head.winning = 0;
1742 }
1743
1744 // Onslaught winning condition:
1745 // game terminates if only one team has a working generator (or none)
1746 float WinningCondition_Onslaught()
1747 {
1748         entity head;
1749         float t1, t2, t3, t4;
1750
1751         WinningConditionHelper(); // set worldstatus
1752
1753         if(inWarmupStage)
1754                 return WINNING_NO;
1755
1756         // first check if the game has ended
1757         t1 = t2 = t3 = t4 = 0;
1758         head = find(world, classname, "onslaught_generator");
1759         while (head)
1760         {
1761                 if (head.health > 0)
1762                 {
1763                         if (head.team == NUM_TEAM_1) t1 = 1;
1764                         if (head.team == NUM_TEAM_2) t2 = 1;
1765                         if (head.team == NUM_TEAM_3) t3 = 1;
1766                         if (head.team == NUM_TEAM_4) t4 = 1;
1767                 }
1768                 head = find(head, classname, "onslaught_generator");
1769         }
1770         if (t1 + t2 + t3 + t4 < 2)
1771         {
1772                 // game over, only one team remains (or none)
1773                 ClearWinners();
1774                 if (t1) SetWinners(team, NUM_TEAM_1);
1775                 if (t2) SetWinners(team, NUM_TEAM_2);
1776                 if (t3) SetWinners(team, NUM_TEAM_3);
1777                 if (t4) SetWinners(team, NUM_TEAM_4);
1778                 dprint("Have a winner, ending game.\n");
1779                 return WINNING_YES;
1780         }
1781
1782         // Two or more teams remain
1783         return WINNING_NO;
1784 }
1785
1786 float LMS_NewPlayerLives()
1787 {
1788         float fl;
1789         fl = autocvar_fraglimit;
1790         if(fl == 0)
1791                 fl = 999;
1792
1793         // first player has left the game for dying too much? Nobody else can get in.
1794         if(lms_lowest_lives < 1)
1795                 return 0;
1796
1797         if(!autocvar_g_lms_join_anytime)
1798                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1799                         return 0;
1800
1801         return bound(1, lms_lowest_lives, fl);
1802 }
1803
1804 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1805 // they win. Otherwise the defending team wins once the timelimit passes.
1806 void assault_new_round();
1807 float WinningCondition_Assault()
1808 {
1809         float status;
1810
1811         WinningConditionHelper(); // set worldstatus
1812
1813         status = WINNING_NO;
1814         // as the timelimit has not yet passed just assume the defending team will win
1815         if(assault_attacker_team == NUM_TEAM_1)
1816         {
1817                 SetWinners(team, NUM_TEAM_2);
1818         }
1819         else
1820         {
1821                 SetWinners(team, NUM_TEAM_1);
1822         }
1823
1824         entity ent;
1825         ent = find(world, classname, "target_assault_roundend");
1826         if(ent)
1827         {
1828                 if(ent.winning) // round end has been triggered by attacking team
1829                 {
1830                         bprint("ASSAULT: round completed...\n");
1831                         SetWinners(team, assault_attacker_team);
1832
1833                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1834
1835                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1836                         {
1837                                 status = WINNING_YES;
1838                         }
1839                         else
1840                         {
1841                                 entity oldself;
1842                                 oldself = self;
1843                                 self = ent;
1844                                 assault_new_round();
1845                                 self = oldself;
1846                         }
1847                 }
1848         }
1849
1850         return status;
1851 }
1852
1853 // LMS winning condition: game terminates if and only if there's at most one
1854 // one player who's living lives. Top two scores being equal cancels the time
1855 // limit.
1856 float WinningCondition_LMS()
1857 {
1858         entity head, head2;
1859         float have_player;
1860         float have_players;
1861         float l;
1862
1863         have_player = FALSE;
1864         have_players = FALSE;
1865         l = LMS_NewPlayerLives();
1866
1867         head = find(world, classname, "player");
1868         if(head)
1869                 have_player = TRUE;
1870         head2 = find(head, classname, "player");
1871         if(head2)
1872                 have_players = TRUE;
1873
1874         if(have_player)
1875         {
1876                 // we have at least one player
1877                 if(have_players)
1878                 {
1879                         // two or more active players - continue with the game
1880                 }
1881                 else
1882                 {
1883                         // exactly one player?
1884
1885                         ClearWinners();
1886                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1887
1888                         if(l)
1889                         {
1890                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1891                                 return WINNING_NO;
1892                         }
1893                         else
1894                         {
1895                                 // a winner!
1896                                 // and assign him his first place
1897                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1898                                 return WINNING_YES;
1899                         }
1900                 }
1901         }
1902         else
1903         {
1904                 // nobody is playing at all...
1905                 if(l)
1906                 {
1907                         // wait for players...
1908                 }
1909                 else
1910                 {
1911                         // SNAFU (maybe a draw game?)
1912                         ClearWinners();
1913                         dprint("No players, ending game.\n");
1914                         return WINNING_YES;
1915                 }
1916         }
1917
1918         // When we get here, we have at least two players who are actually LIVING,
1919         // now check if the top two players have equal score.
1920         WinningConditionHelper();
1921
1922         ClearWinners();
1923         if(WinningConditionHelper_winner)
1924                 WinningConditionHelper_winner.winning = TRUE;
1925         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1926                 return WINNING_NEVER;
1927
1928         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1929         return WINNING_NO;
1930 }
1931
1932 void ShuffleMaplist()
1933 {
1934         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1935 }
1936
1937 float leaderfrags;
1938 float WinningCondition_Scores(float limit, float leadlimit)
1939 {
1940         float limitreached;
1941
1942         // TODO make everything use THIS winning condition (except LMS)
1943         WinningConditionHelper();
1944
1945         if(teamplay)
1946         {
1947                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1948                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1949                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1950                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1951         }
1952
1953         ClearWinners();
1954         if(WinningConditionHelper_winner)
1955                 WinningConditionHelper_winner.winning = 1;
1956         if(WinningConditionHelper_winnerteam >= 0)
1957                 SetWinners(team, WinningConditionHelper_winnerteam);
1958
1959         if(WinningConditionHelper_lowerisbetter)
1960         {
1961                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1962                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1963                 limit = -limit;
1964         }
1965
1966         if(WinningConditionHelper_zeroisworst)
1967                 leadlimit = 0; // not supported in this mode
1968
1969         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1970         // these modes always score in increments of 1, thus this makes sense
1971         {
1972                 if(leaderfrags != WinningConditionHelper_topscore)
1973                 {
1974                         leaderfrags = WinningConditionHelper_topscore;
1975
1976                         if (limit)
1977                         if (leaderfrags == limit - 1)
1978                                 Announce("1fragleft");
1979                         else if (leaderfrags == limit - 2)
1980                                 Announce("2fragsleft");
1981                         else if (leaderfrags == limit - 3)
1982                                 Announce("3fragsleft");
1983                 }
1984         }
1985
1986         limitreached = FALSE;
1987         if(limit)
1988                 if(WinningConditionHelper_topscore >= limit)
1989                         limitreached = TRUE;
1990         if(leadlimit)
1991         {
1992                 float leadlimitreached;
1993                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1994                 if(autocvar_leadlimit_and_fraglimit)
1995                         limitreached = (limitreached && leadlimitreached);
1996                 else
1997                         limitreached = (limitreached || leadlimitreached);
1998         }
1999
2000         if(limit)
2001                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2002
2003         return GetWinningCode(
2004                 WinningConditionHelper_topscore && limitreached,
2005                 WinningConditionHelper_equality
2006         );
2007 }
2008
2009 float WinningCondition_Race(float fraglimit)
2010 {
2011         float wc;
2012         entity p;
2013         float n, c;
2014
2015         n = 0;
2016         c = 0;
2017         FOR_EACH_PLAYER(p)
2018         {
2019                 ++n;
2020                 if(p.race_completed)
2021                         ++c;
2022         }
2023         if(n && (n == c))
2024                 return WINNING_YES;
2025         wc = WinningCondition_Scores(fraglimit, 0);
2026
2027         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2028         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2029         // do NOT support equality when the laps are all raced!
2030                 return WINNING_STARTSUDDENDEATHOVERTIME;
2031         else
2032                 return WINNING_NEVER;
2033 }
2034
2035 float WinningCondition_QualifyingThenRace(float limit)
2036 {
2037         float wc;
2038         wc = WinningCondition_Scores(limit, 0);
2039
2040         // NEVER initiate overtime
2041         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2042         {
2043                 return WINNING_YES;
2044         }
2045
2046         return wc;
2047 }
2048
2049 float WinningCondition_RanOutOfSpawns()
2050 {
2051         entity head;
2052
2053         if(have_team_spawns <= 0)
2054                 return WINNING_NO;
2055
2056         if(autocvar_g_spawn_useallspawns <= 0)
2057                 return WINNING_NO;
2058
2059         if(!some_spawn_has_been_used)
2060                 return WINNING_NO;
2061
2062         team1_score = team2_score = team3_score = team4_score = 0;
2063
2064         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2065         {
2066                 if(head.team == NUM_TEAM_1)
2067                         team1_score = 1;
2068                 else if(head.team == NUM_TEAM_2)
2069                         team2_score = 1;
2070                 else if(head.team == NUM_TEAM_3)
2071                         team3_score = 1;
2072                 else if(head.team == NUM_TEAM_4)
2073                         team4_score = 1;
2074         }
2075
2076         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2077         {
2078                 if(head.team == NUM_TEAM_1)
2079                         team1_score = 1;
2080                 else if(head.team == NUM_TEAM_2)
2081                         team2_score = 1;
2082                 else if(head.team == NUM_TEAM_3)
2083                         team3_score = 1;
2084                 else if(head.team == NUM_TEAM_4)
2085                         team4_score = 1;
2086         }
2087
2088         ClearWinners();
2089         if(team1_score + team2_score + team3_score + team4_score == 0)
2090         {
2091                 checkrules_equality = TRUE;
2092                 return WINNING_YES;
2093         }
2094         else if(team1_score + team2_score + team3_score + team4_score == 1)
2095         {
2096                 float t, i;
2097                 if(team1_score)
2098                         t = NUM_TEAM_1;
2099                 else if(team2_score)
2100                         t = NUM_TEAM_2;
2101                 else if(team3_score)
2102                         t = NUM_TEAM_3;
2103                 else // if(team4_score)
2104                         t = NUM_TEAM_4;
2105                 CheckAllowedTeams(world);
2106                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2107                 {
2108                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2109                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2110                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2111                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2112                 }
2113
2114                 AddWinners(team, t);
2115                 return WINNING_YES;
2116         }
2117         else
2118                 return WINNING_NO;
2119 }
2120
2121 // TD winning condition:
2122 // game terminates if there are no generators (or 1 dies if td_dontend is TRUE)
2123 float gensurvived;
2124 float WinningCondition_TowerDefense()
2125 {
2126         WinningConditionHelper(); // set worldstatus
2127
2128         if(inWarmupStage)
2129                 return WINNING_NO;
2130
2131         // first check if the game has ended
2132         if(gendestroyed == TRUE) // FALSE means either generator hasen't spawned yet, or mapper didn't add one
2133         if(td_gencount < 1 || !td_dont_end)
2134         {
2135                 ClearWinners();
2136                 dprint("Everyone lost, ending game.\n");
2137                 return WINNING_YES;
2138         }
2139
2140         if(gensurvived)
2141         {
2142                 ClearWinners();
2143                 SetWinners(winning, 4);
2144                 return WINNING_YES;
2145         }
2146
2147         // Two or more teams remain
2148         return WINNING_NO;
2149 }
2150
2151 /*
2152 ============
2153 CheckRules_World
2154
2155 Exit deathmatch games upon conditions
2156 ============
2157 */
2158 void ReadyRestart();
2159 void CheckRules_World()
2160 {
2161         float timelimit;
2162         float fraglimit;
2163         float leadlimit;
2164
2165         VoteThink();
2166         MapVote_Think();
2167
2168         SetDefaultAlpha();
2169
2170         /*
2171         MapVote_Think should now do that part
2172         if (intermission_running)
2173                 if (time >= intermission_exittime + 60)
2174                 {
2175                         if(!DoNextMapOverride())
2176                                 GotoNextMap();
2177                         return;
2178                 }
2179         */
2180
2181         if (gameover)   // someone else quit the game already
2182         {
2183                 if(player_count == 0) // Nobody there? Then let's go to the next map
2184                         MapVote_Start();
2185                         // this will actually check the player count in the next frame
2186                         // again, but this shouldn't hurt
2187                 return;
2188         }
2189
2190         timelimit = autocvar_timelimit * 60;
2191         fraglimit = autocvar_fraglimit;
2192         leadlimit = autocvar_leadlimit;
2193
2194         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2195         {
2196                 if(timelimit > 0)
2197                         timelimit = 0; // timelimit is not made for warmup
2198                 if(fraglimit > 0)
2199                         fraglimit = 0; // no fraglimit for now
2200                 leadlimit = 0; // no leadlimit for now
2201         }
2202
2203         if(timelimit > 0)
2204         {
2205                 timelimit += game_starttime;
2206         }
2207         else if (timelimit < 0)
2208         {
2209                 // endmatch
2210                 NextLevel();
2211                 return;
2212         }
2213
2214         if(g_onslaught)
2215                 timelimit = 0; // ONS has its own overtime rule
2216
2217         float wantovertime;
2218         wantovertime = 0;
2219
2220         if(timelimit > game_starttime)
2221                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2222         else
2223                 game_completion_ratio = 0;
2224
2225         if(checkrules_suddendeathend)
2226         {
2227                 if(!checkrules_suddendeathwarning)
2228                 {
2229                         checkrules_suddendeathwarning = TRUE;
2230                         if(g_race && !g_race_qualifying)
2231                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2232                         else
2233                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2234                 }
2235         }
2236         else
2237         {
2238                 if (timelimit && time >= timelimit)
2239                 {
2240                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2241                         {
2242                                 float totalplayers;
2243                                 float playerswithlaps;
2244                                 float readyplayers;
2245                                 entity head;
2246                                 totalplayers = playerswithlaps = readyplayers = 0;
2247                                 FOR_EACH_PLAYER(head)
2248                                 {
2249                                         ++totalplayers;
2250                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2251                                                 ++playerswithlaps;
2252                                         if(head.ready)
2253                                                 ++readyplayers;
2254                                 }
2255
2256                                 // at least 2 of the players have completed a lap: start the RACE
2257                                 // otherwise, the players should end the qualifying on their own
2258                                 if(readyplayers || playerswithlaps >= 2)
2259                                 {
2260                                         checkrules_suddendeathend = 0;
2261                                         ReadyRestart(); // go to race
2262                                         return;
2263                                 }
2264                                 else
2265                                         wantovertime |= InitiateSuddenDeath();
2266                         }
2267                         else
2268                                 wantovertime |= InitiateSuddenDeath();
2269                 }
2270         }
2271
2272         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2273         {
2274                 NextLevel();
2275                 return;
2276         }
2277
2278         float checkrules_status;
2279         checkrules_status = WinningCondition_RanOutOfSpawns();
2280         if(checkrules_status == WINNING_YES)
2281         {
2282                 bprint("Hey! Someone ran out of spawns!\n");
2283         }
2284         else if(g_race && !g_race_qualifying && timelimit >= 0)
2285         {
2286                 checkrules_status = WinningCondition_Race(fraglimit);
2287                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2288         }
2289         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2290         {
2291                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2292                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2293         }
2294         else if(g_assault)
2295         {
2296                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2297         }
2298         else if(g_lms)
2299         {
2300                 checkrules_status = WinningCondition_LMS();
2301         }
2302         else if (g_onslaught)
2303         {
2304                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2305         }
2306         else if(g_td)
2307         {
2308                 checkrules_status = WinningCondition_TowerDefense();
2309         }
2310         else
2311         {
2312                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2313                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2314         }
2315
2316         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2317         {
2318                 checkrules_status = WINNING_NEVER;
2319                 checkrules_overtimesadded = -1;
2320                 wantovertime |= InitiateSuddenDeath();
2321         }
2322
2323         if(checkrules_status == WINNING_NEVER)
2324                 // equality cases! Nobody wins if the overtime ends in a draw.
2325                 ClearWinners();
2326
2327         if(wantovertime)
2328         {
2329                 if(checkrules_status == WINNING_NEVER)
2330                         InitiateOvertime();
2331                 else
2332                         checkrules_status = WINNING_YES;
2333         }
2334
2335         if(checkrules_suddendeathend)
2336                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2337                         checkrules_status = WINNING_YES;
2338
2339         if(checkrules_status == WINNING_YES)
2340         {
2341                 //print("WINNING\n");
2342                 NextLevel();
2343         }
2344 }
2345
2346 float mapvote_nextthink;
2347 float mapvote_initialized;
2348 float mapvote_keeptwotime;
2349 float mapvote_timeout;
2350 string mapvote_message;
2351 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2352 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2353 float mapvote_screenshot_dirs_count;
2354
2355 float mapvote_count;
2356 float mapvote_count_real;
2357 string mapvote_maps[MAPVOTE_COUNT];
2358 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2359 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2360 float mapvote_maps_suggested[MAPVOTE_COUNT];
2361 string mapvote_suggestions[MAPVOTE_COUNT];
2362 float mapvote_suggestion_ptr;
2363 float mapvote_voters;
2364 float mapvote_selections[MAPVOTE_COUNT];
2365 float mapvote_run;
2366 float mapvote_detail;
2367 float mapvote_abstain;
2368 .float mapvote;
2369
2370 void MapVote_ClearAllVotes()
2371 {
2372         FOR_EACH_CLIENT(other)
2373                 other.mapvote = 0;
2374 }
2375
2376 string MapVote_Suggest(string m)
2377 {
2378         float i;
2379         if(m == "")
2380                 return "That's not how to use this command.";
2381         if(!autocvar_g_maplist_votable_suggestions)
2382                 return "Suggestions are not accepted on this server.";
2383         if(mapvote_initialized)
2384                 return "Can't suggest - voting is already in progress!";
2385         m = MapInfo_FixName(m);
2386         if not(m)
2387                 return "The map you suggested is not available on this server.";
2388         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2389                 if(Map_IsRecent(m))
2390                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2391
2392         if(!MapInfo_CheckMap(m))
2393                 return "The map you suggested does not support the current game mode.";
2394         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2395                 if(mapvote_suggestions[i] == m)
2396                         return "This map was already suggested.";
2397         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2398         {
2399                 i = floor(random() * mapvote_suggestion_ptr);
2400         }
2401         else
2402         {
2403                 i = mapvote_suggestion_ptr;
2404                 mapvote_suggestion_ptr += 1;
2405         }
2406         if(mapvote_suggestions[i] != "")
2407                 strunzone(mapvote_suggestions[i]);
2408         mapvote_suggestions[i] = strzone(m);
2409         if(autocvar_sv_eventlog)
2410                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2411         return strcat("Suggestion of ", m, " accepted.");
2412 }
2413
2414 void MapVote_AddVotable(string nextMap, float isSuggestion)
2415 {
2416         float j, i, o;
2417         string pakfile, mapfile;
2418
2419         if(nextMap == "")
2420                 return;
2421         for(j = 0; j < mapvote_count; ++j)
2422                 if(mapvote_maps[j] == nextMap)
2423                         return;
2424         // suggestions might be no longer valid/allowed after gametype switch!
2425         if(isSuggestion)
2426                 if(!MapInfo_CheckMap(nextMap))
2427                         return;
2428         mapvote_maps[mapvote_count] = strzone(nextMap);
2429         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2430
2431         pakfile = string_null;
2432         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2433         {
2434                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2435                 pakfile = whichpack(strcat(mapfile, ".tga"));
2436                 if(pakfile == "")
2437                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2438                 if(pakfile == "")
2439                         pakfile = whichpack(strcat(mapfile, ".png"));
2440                 if(pakfile != "")
2441                         break;
2442         }
2443         if(i >= mapvote_screenshot_dirs_count)
2444                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2445         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2446                 pakfile = substring(pakfile, o, -1);
2447
2448         mapvote_maps_screenshot_dir[mapvote_count] = i;
2449         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2450
2451         mapvote_count += 1;
2452 }
2453
2454 void MapVote_Spawn();
2455 void MapVote_Init()
2456 {
2457         float i;
2458         float nmax, smax;
2459
2460         MapVote_ClearAllVotes();
2461
2462         mapvote_count = 0;
2463         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2464         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2465
2466         if(mapvote_abstain)
2467                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2468         else
2469                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2470         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2471
2472         // we need this for AddVotable, as that cycles through the screenshot dirs
2473         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2474         if(mapvote_screenshot_dirs_count == 0)
2475                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2476         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2477         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2478                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2479
2480         if(mapvote_suggestion_ptr)
2481                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2482                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2483
2484         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2485                 MapVote_AddVotable(GetNextMap(), FALSE);
2486
2487         if(mapvote_count == 0)
2488         {
2489                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2490                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2491                 if(autocvar_g_maplist_shuffle)
2492                         ShuffleMaplist();
2493                 localcmd("\nmenu_cmd sync\n");
2494                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2495                         MapVote_AddVotable(GetNextMap(), FALSE);
2496         }
2497
2498         mapvote_count_real = mapvote_count;
2499         if(mapvote_abstain)
2500                 MapVote_AddVotable("don't care", 0);
2501
2502         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2503
2504         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2505         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2506         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2507                 mapvote_keeptwotime = 0;
2508         mapvote_message = "Choose a map and press its key!";
2509
2510         MapVote_Spawn();
2511 }
2512
2513 void MapVote_SendPicture(float id)
2514 {
2515         msg_entity = self;
2516         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2517         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2518         WriteByte(MSG_ONE, id);
2519         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2520 }
2521
2522 float MapVote_GetMapMask()
2523 {
2524         float mask, i, power;
2525         mask = 0;
2526         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2527                 if(mapvote_maps[i] != "")
2528                         mask |= power;
2529         return mask;
2530 }
2531
2532 entity mapvote_ent;
2533 float MapVote_SendEntity(entity to, float sf)
2534 {
2535         float i;
2536
2537         if(sf & 1)
2538                 sf &~= 2; // if we send 1, we don't need to also send 2
2539
2540         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2541         WriteByte(MSG_ENTITY, sf);
2542
2543         if(sf & 1)
2544         {
2545                 // flag 1 == initialization
2546                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2547                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2548                 WriteString(MSG_ENTITY, "");
2549                 WriteByte(MSG_ENTITY, mapvote_count);
2550                 WriteByte(MSG_ENTITY, mapvote_abstain);
2551                 WriteByte(MSG_ENTITY, mapvote_detail);
2552                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2553                 if(mapvote_count <= 8)
2554                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2555                 else
2556                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2557                 for(i = 0; i < mapvote_count; ++i)
2558                         if(mapvote_maps[i] != "")
2559                         {
2560                                 if(mapvote_abstain && i == mapvote_count - 1)
2561                                 {
2562                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2563                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2564                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2565                                 }
2566                                 else
2567                                 {
2568                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2569                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2570                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2571                                 }
2572                         }
2573         }
2574
2575         if(sf & 2)
2576         {
2577                 // flag 2 == update of mask
2578                 if(mapvote_count <= 8)
2579                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2580                 else
2581                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2582         }
2583
2584         if(sf & 4)
2585         {
2586                 if(mapvote_detail)
2587                         for(i = 0; i < mapvote_count; ++i)
2588                                 if(mapvote_maps[i] != "")
2589                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2590
2591                 WriteByte(MSG_ENTITY, to.mapvote);
2592         }
2593
2594         return TRUE;
2595 }
2596
2597 void MapVote_Spawn()
2598 {
2599         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2600 }
2601
2602 void MapVote_TouchMask()
2603 {
2604         mapvote_ent.SendFlags |= 2;
2605 }
2606
2607 void MapVote_TouchVotes(entity voter)
2608 {
2609         mapvote_ent.SendFlags |= 4;
2610 }
2611
2612 float MapVote_Finished(float mappos)
2613 {
2614         string result;
2615         float i;
2616         float didntvote;
2617
2618         if(autocvar_sv_eventlog)
2619         {
2620                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2621                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2622                 didntvote = mapvote_voters;
2623                 for(i = 0; i < mapvote_count; ++i)
2624                         if(mapvote_maps[i] != "")
2625                         {
2626                                 didntvote -= mapvote_selections[i];
2627                                 if(i != mappos)
2628                                 {
2629                                         result = strcat(result, ":", mapvote_maps[i]);
2630                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2631                                 }
2632                         }
2633                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2634
2635                 GameLogEcho(result);
2636                 if(mapvote_maps_suggested[mappos])
2637                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2638         }
2639
2640         FOR_EACH_REALCLIENT(other)
2641                 FixClientCvars(other);
2642
2643         Map_Goto_SetStr(mapvote_maps[mappos]);
2644         Map_Goto(0);
2645         alreadychangedlevel = TRUE;
2646         return TRUE;
2647 }
2648 void MapVote_CheckRules_1()
2649 {
2650         float i;
2651
2652         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2653         {
2654                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2655                 mapvote_selections[i] = 0;
2656         }
2657
2658         mapvote_voters = 0;
2659         FOR_EACH_REALCLIENT(other)
2660         {
2661                 ++mapvote_voters;
2662                 if(other.mapvote)
2663                 {
2664                         i = other.mapvote - 1;
2665                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2666                         mapvote_selections[i] = mapvote_selections[i] + 1;
2667                 }
2668         }
2669 }
2670
2671 float MapVote_CheckRules_2()
2672 {
2673         float i;
2674         float firstPlace, secondPlace;
2675         float firstPlaceVotes, secondPlaceVotes;
2676         float mapvote_voters_real;
2677         string result;
2678
2679         if(mapvote_count_real == 1)
2680                 return MapVote_Finished(0);
2681
2682         mapvote_voters_real = mapvote_voters;
2683         if(mapvote_abstain)
2684                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2685
2686         RandomSelection_Init();
2687         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2688                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2689         firstPlace = RandomSelection_chosen_float;
2690         firstPlaceVotes = RandomSelection_best_priority;
2691         //dprint("First place: ", ftos(firstPlace), "\n");
2692         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2693
2694         RandomSelection_Init();
2695         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2696                 if(i != firstPlace)
2697                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2698         secondPlace = RandomSelection_chosen_float;
2699         secondPlaceVotes = RandomSelection_best_priority;
2700         //dprint("Second place: ", ftos(secondPlace), "\n");
2701         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2702
2703         if(firstPlace == -1)
2704                 error("No first place in map vote... WTF?");
2705
2706         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2707                 return MapVote_Finished(firstPlace);
2708
2709         if(mapvote_keeptwotime)
2710                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2711                 {
2712                         float didntvote;
2713                         MapVote_TouchMask();
2714                         mapvote_message = "Now decide between the TOP TWO!";
2715                         mapvote_keeptwotime = 0;
2716                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2717                         result = strcat(result, ":", ftos(firstPlaceVotes));
2718                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2719                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2720                         didntvote = mapvote_voters;
2721                         for(i = 0; i < mapvote_count; ++i)
2722                                 if(mapvote_maps[i] != "")
2723                                 {
2724                                         didntvote -= mapvote_selections[i];
2725                                         if(i != firstPlace)
2726                                                 if(i != secondPlace)
2727                                                 {
2728                                                         result = strcat(result, ":", mapvote_maps[i]);
2729                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2730                                                         if(i < mapvote_count_real)
2731                                                         {
2732                                                                 strunzone(mapvote_maps[i]);
2733                                                                 mapvote_maps[i] = "";
2734                                                                 strunzone(mapvote_maps_pakfile[i]);
2735                                                                 mapvote_maps_pakfile[i] = "";
2736                                                         }
2737                                                 }
2738                                 }
2739                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2740                         if(autocvar_sv_eventlog)
2741                                 GameLogEcho(result);
2742                 }
2743
2744         return FALSE;
2745 }
2746 void MapVote_Tick()
2747 {
2748         float keeptwo;
2749         float totalvotes;
2750
2751         keeptwo = mapvote_keeptwotime;
2752         MapVote_CheckRules_1(); // count
2753         if(MapVote_CheckRules_2()) // decide
2754                 return;
2755
2756         totalvotes = 0;
2757         FOR_EACH_REALCLIENT(other)
2758         {
2759                 // hide scoreboard again
2760                 if(other.health != 2342)
2761                 {
2762                         other.health = 2342;
2763                         other.impulse = 0;
2764                         if(clienttype(other) == CLIENTTYPE_REAL)
2765                         {
2766                                 msg_entity = other;
2767                                 WriteByte(MSG_ONE, SVC_FINALE);
2768                                 WriteString(MSG_ONE, "");
2769                         }
2770                 }
2771
2772                 // clear possibly invalid votes
2773                 if(mapvote_maps[other.mapvote - 1] == "")
2774                         other.mapvote = 0;
2775                 // use impulses as new vote
2776                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2777                         if(mapvote_maps[other.impulse - 1] != "")
2778                         {
2779                                 other.mapvote = other.impulse;
2780                                 MapVote_TouchVotes(other);
2781                         }
2782                 other.impulse = 0;
2783
2784                 if(other.mapvote)
2785                         ++totalvotes;
2786         }
2787
2788         MapVote_CheckRules_1(); // just count
2789 }
2790 void MapVote_Start()
2791 {
2792         if(mapvote_run)
2793                 return;
2794
2795         // wait for stats to be sent first
2796         if(!playerstats_waitforme)
2797                 return;
2798
2799         MapInfo_Enumerate();
2800         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2801                 mapvote_run = TRUE;
2802 }
2803 void MapVote_Think()
2804 {
2805         if(!mapvote_run)
2806                 return;
2807
2808         if(alreadychangedlevel)
2809                 return;
2810
2811         if(time < mapvote_nextthink)
2812                 return;
2813         //dprint("tick\n");
2814
2815         mapvote_nextthink = time + 0.5;
2816
2817         if(!mapvote_initialized)
2818         {
2819                 if(autocvar_rescan_pending == 1)
2820                 {
2821                         cvar_set("rescan_pending", "2");
2822                         localcmd("fs_rescan\nrescan_pending 3\n");
2823                         return;
2824                 }
2825                 else if(autocvar_rescan_pending == 2)
2826                 {
2827                         return;
2828                 }
2829                 else if(autocvar_rescan_pending == 3)
2830                 {
2831                         // now build missing mapinfo files
2832                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2833                                 return;
2834
2835                         // we're done, start the timer
2836                         cvar_set("rescan_pending", "0");
2837                 }
2838
2839                 mapvote_initialized = TRUE;
2840                 if(DoNextMapOverride(0))
2841                         return;
2842                 if(!autocvar_g_maplist_votable || player_count <= 0)
2843                 {
2844                         GotoNextMap(0);
2845                         return;
2846                 }
2847                 MapVote_Init();
2848         }
2849
2850         MapVote_Tick();
2851 }
2852
2853 string GotoMap(string m)
2854 {
2855         if(!MapInfo_CheckMap(m))
2856                 return "The map you chose is not available on this server.";
2857         cvar_set("nextmap", m);
2858         cvar_set("timelimit", "-1");
2859         if(mapvote_initialized || alreadychangedlevel)
2860         {
2861                 if(DoNextMapOverride(0))
2862                         return "Map switch initiated.";
2863                 else
2864                         return "Hm... no. For some reason I like THIS map more.";
2865         }
2866         else
2867                 return "Map switch will happen after scoreboard.";
2868 }
2869
2870
2871 void EndFrame()
2872 {
2873         float altime;
2874         FOR_EACH_REALCLIENT(self)
2875         {
2876                 if(self.classname == "spectator")
2877                 {
2878                         if(self.enemy.typehitsound)
2879                                 self.typehit_time = time;
2880                         else if(self.enemy.hitsound)
2881                                 self.hit_time = time;
2882                 }
2883                 else
2884                 {
2885                         if(self.typehitsound)
2886                                 self.typehit_time = time;
2887                         else if(self.hitsound)
2888                                 self.hit_time = time;
2889                 }
2890         }
2891         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2892         // add 1 frametime because after this, engine SV_Physics
2893         // increases time by a frametime and then networks the frame
2894         // add another frametime because client shows everything with
2895         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2896         // needed!
2897         FOR_EACH_CLIENT(self)
2898         {
2899                 self.hitsound = FALSE;
2900                 self.typehitsound = FALSE;
2901                 antilag_record(self, altime);
2902         }
2903 }
2904
2905
2906 /*
2907  * RedirectionThink:
2908  * returns TRUE if redirecting
2909  */
2910 float redirection_timeout;
2911 float redirection_nextthink;
2912 float RedirectionThink()
2913 {
2914         float clients_found;
2915
2916         if(redirection_target == "")
2917                 return FALSE;
2918
2919         if(!redirection_timeout)
2920         {
2921                 cvar_set("sv_public", "-2");
2922                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2923                 if(redirection_target == "self")
2924                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2925                 else
2926                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2927         }
2928
2929         if(time < redirection_nextthink)
2930                 return TRUE;
2931
2932         redirection_nextthink = time + 1;
2933
2934         clients_found = 0;
2935         FOR_EACH_REALCLIENT(self)
2936         {
2937                 // TODO add timer
2938                 print("Redirecting: sending connect command to ", self.netname, "\n");
2939                 if(redirection_target == "self")
2940                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2941                 else
2942                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2943                 ++clients_found;
2944         }
2945
2946         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2947
2948         if(time > redirection_timeout || clients_found == 0)
2949                 localcmd("\nwait; wait; wait; quit\n");
2950
2951         return TRUE;
2952 }
2953
2954 void TargetMusic_RestoreGame();
2955 void RestoreGame()
2956 {
2957         // Loaded from a save game
2958         // some things then break, so let's work around them...
2959
2960         // Progs DB (capture records)
2961         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2962
2963         // Mapinfo
2964         MapInfo_Shutdown();
2965         MapInfo_Enumerate();
2966         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2967         WeaponStats_Init();
2968
2969         TargetMusic_RestoreGame();
2970 }
2971
2972 void Shutdown()
2973 {
2974         entity e;
2975
2976         gameover = 2;
2977
2978         if(world_initialized > 0)
2979         {
2980                 world_initialized = 0;
2981                 print("Saving persistent data...\n");
2982                 Ban_SaveBans();
2983
2984                 PlayerStats_EndMatch(0);
2985                 FOR_EACH_CLIENT(e)
2986                         PlayerStats_AddGlobalInfo(e);
2987                 PlayerStats_Shutdown();
2988
2989                 if(!cheatcount_total)
2990                 {
2991                         if(autocvar_sv_db_saveasdump)
2992                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2993                         else
2994                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2995                 }
2996                 if(autocvar_developer)
2997                 {
2998                         if(autocvar_sv_db_saveasdump)
2999                                 db_dump(TemporaryDB, "server-temp.db");
3000                         else
3001                                 db_save(TemporaryDB, "server-temp.db");
3002                 }
3003                 CheatShutdown(); // must be after cheatcount check
3004                 db_close(ServerProgsDB);
3005                 db_close(TemporaryDB);
3006                 print("done!\n");
3007                 // tell the bot system the game is ending now
3008                 bot_endgame();
3009
3010                 WeaponStats_Shutdown();
3011                 MapInfo_Shutdown();
3012         }
3013         else if(world_initialized == 0)
3014         {
3015                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3016         }
3017 }