qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240                 // internal
 241                 BADPREFIX("csqc_");
 242                 BADPREFIX("cvar_check_");
 243                 BADCVAR("gamecfg");
 244                 BADCVAR("g_configversion");
 245                 BADCVAR("g_maplist_index");
 246                 BADCVAR("halflifebsp");
 247                 BADPREFIX("sv_world");
 248
 249                 // client
 250                 BADPREFIX("chase_");
 251                 BADPREFIX("cl_");
 252                 BADPREFIX("con_");
 253                 BADPREFIX("scoreboard_");
 254                 BADPREFIX("g_campaign");
 255                 BADPREFIX("gl_");
 256                 BADPREFIX("joy");
 257                 BADPREFIX("hud_");
 258                 BADPREFIX("m_");
 259                 BADPREFIX("menu_");
 260                 BADPREFIX("net_slist_");
 261                 BADPREFIX("r_");
 262                 BADPREFIX("sbar_");
 263                 BADPREFIX("scr_");
 264                 BADPREFIX("snd_");
 265                 BADPREFIX("show");
 266                 BADPREFIX("sensitivity");
 267                 BADPREFIX("userbind");
 268                 BADPREFIX("v_");
 269                 BADPREFIX("vid_");
 270                 BADPREFIX("crosshair");
 271                 BADCVAR("mod_q3bsp_lightmapmergepower");
 272                 BADCVAR("mod_q3bsp_nolightmaps");
 273                 BADCVAR("fov");
 274                 BADCVAR("mastervolume");
 275                 BADCVAR("volume");
 276                 BADCVAR("bgmvolume");
 277
 278                 // private
 279                 BADCVAR("developer");
 280                 BADCVAR("g_banned_list");
 281                 BADCVAR("log_dest_udp");
 282                 BADCVAR("log_file");
 283                 BADCVAR("net_address");
 284                 BADCVAR("net_address_ipv6");
 285                 BADCVAR("port");
 286                 BADCVAR("savedgamecfg");
 287                 BADCVAR("serverconfig");
 288                 BADCVAR("sv_heartbeatperiod");
 289                 BADCVAR("sv_vote_master_password");
 290                 BADCVAR("sys_colortranslation");
 291                 BADCVAR("sys_specialcharactertranslation");
 292                 BADCVAR("timestamps");
 293                 BADPREFIX("developer_");
 294                 BADPREFIX("g_ban_");
 295                 BADPREFIX("g_chat_flood_");
 296                 BADPREFIX("g_voice_flood_");
 297                 BADPREFIX("rcon_");
 298                 BADPREFIX("settemp_");
 299                 BADPREFIX("sv_allowdownloads_");
 300                 BADPREFIX("sv_autodemo");
 301                 BADPREFIX("sv_curl_");
 302                 BADPREFIX("sv_eventlog");
 303                 BADPREFIX("sv_logscores_");
 304                 BADPREFIX("sv_master");
 305                 BADPREFIX("sv_weaponstats_");
 306
 307                 // these can contain player IDs, so better hide
 308                 BADCVAR("g_forced_team_red");
 309                 BADCVAR("g_forced_team_blue");
 310                 BADCVAR("g_forced_team_yellow");
 311                 BADCVAR("g_forced_team_pink");
 312
 313                 // mapinfo
 314                 BADCVAR("fraglimit");
 315                 BADCVAR("g_arena");
 316                 BADCVAR("g_assault");
 317                 BADCVAR("g_ca");
 318                 BADCVAR("g_ctf");
 319                 BADCVAR("g_cts");
 320                 BADCVAR("g_dm");
 321                 BADCVAR("g_domination");
 322                 BADCVAR("g_domination_default_teams");
 323                 BADCVAR("g_freezetag");
 324                 BADCVAR("g_keepaway");
 325                 BADCVAR("g_keyhunt");
 326                 BADCVAR("g_keyhunt_teams");
 327                 BADCVAR("g_keyhunt_teams");
 328                 BADCVAR("g_lms");
 329                 BADCVAR("g_nexball");
 330                 BADCVAR("g_onslaught");
 331                 BADCVAR("g_race");
 332                 BADCVAR("g_race_qualifying_timelimit");
 333                 BADCVAR("g_runematch");
 334                 BADCVAR("g_tdm");
 335                 BADCVAR("g_tdm_teams");
 336                 BADCVAR("leadlimit");
 337                 BADCVAR("nextmap");
 338                 BADCVAR("teamplay");
 339                 BADCVAR("timelimit");
 340
 341                 // long
 342                 BADCVAR("hostname");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_mostrecent");
 345                 BADCVAR("sv_motd");
 346
 347                 v = cvar_string(k);
 348                 d = cvar_defstring(k);
 349                 if(v == d)
 350                         continue;
 351
 352                 if(adding)
 353                 {
 354                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 355                         if(strlen(cvar_changes) > 16384)
 356                         {
 357                                 cvar_changes = "// too many settings have been changed to show them here\n";
 358                                 adding = 0;
 359                         }
 360                 }
 361
 362                 // now check if the changes are actually gameplay relevant
 363
 364                 // does nothing visible
 365                 BADCVAR("captureleadlimit_override");
 366                 BADCVAR("g_arena_point_leadlimit");
 367                 BADCVAR("g_balance_kill_delay");
 368                 BADCVAR("g_ca_point_leadlimit");
 369                 BADCVAR("g_ctf_captimerecord_always");
 370                 BADCVAR("g_ctf_capture_leadlimit");
 371                 BADCVAR("g_ctf_flag_capture_effects");
 372                 BADCVAR("g_ctf_flag_glowtrails");
 373                 BADCVAR("g_ctf_flag_pickup_effects");
 374                 BADCVAR("g_domination_point_leadlimit");
 375                 BADCVAR("g_forced_respawn");
 376                 BADCVAR("g_keyhunt_point_leadlimit");
 377                 BADCVAR("g_nexball_goalleadlimit");
 378                 BADCVAR("g_runematch_point_leadlimit");
 379                 BADCVAR("leadlimit_and_fraglimit");
 380                 BADCVAR("leadlimit_override");
 381                 BADCVAR("pausable");
 382                 BADCVAR("sv_checkforpacketsduringsleep");
 383                 BADCVAR("sv_timeout");
 384                 BADCVAR("welcome_message_time");
 385                 BADPREFIX("crypto_");
 386                 BADPREFIX("g_chat_");
 387                 BADPREFIX("g_ctf_captimerecord_");
 388                 BADPREFIX("g_maplist_votable_");
 389                 BADPREFIX("net_");
 390                 BADPREFIX("prvm_");
 391                 BADPREFIX("skill_");
 392                 BADPREFIX("sv_fragmessage_");
 393                 BADPREFIX("sv_maxidle_");
 394                 BADPREFIX("sv_vote_");
 395                 BADPREFIX("timelimit_");
 396
 397                 // allowed changes to server admins (please sync this to server.cfg)
 398                 // vi commands:
 399                 //   :/"impure"/,$d
 400                 //   :g!,^\/\/[^ /],d
 401                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 402                 //   :%!sort
 403                 // yes, this does contain some redundant stuff, don't really care
 404                 BADCVAR("bot_number");
 405                 BADCVAR("bot_prefix");
 406                 BADCVAR("bot_suffix");
 407                 BADCVAR("capturelimit_override");
 408                 BADCVAR("fraglimit_override");
 409                 BADCVAR("gametype");
 410                 BADCVAR("g_antilag");
 411                 BADCVAR("g_balance_teams");
 412                 BADCVAR("g_balance_teams_force");
 413                 BADCVAR("g_ban_sync_trusted_servers");
 414                 BADCVAR("g_ban_sync_uri");
 415                 BADCVAR("g_ctf_capture_limit");
 416                 BADCVAR("g_ctf_ignore_frags");
 417                 BADCVAR("g_ctf_win_mode");
 418                 BADCVAR("g_domination_point_limit");
 419                 BADCVAR("g_fullbrightitems");
 420                 BADCVAR("g_fullbrightplayers");
 421                 BADCVAR("g_keyhunt_point_limit");
 422                 BADCVAR("g_keyhunt_teams_override");
 423                 BADCVAR("g_lms_lives_override");
 424                 BADCVAR("g_maplist");
 425                 BADCVAR("g_maplist_check_waypoints");
 426                 BADCVAR("g_maplist_mostrecent_count");
 427                 BADCVAR("g_maplist_shuffle");
 428                 BADCVAR("g_maplist_votable");
 429                 BADCVAR("g_maplist_votable_abstain");
 430                 BADCVAR("g_maplist_votable_nodetail");
 431                 BADCVAR("g_maplist_votable_suggestions");
 432                 BADCVAR("g_minstagib");
 433                 BADCVAR("g_nexball_goallimit");
 434                 BADCVAR("g_runematch_point_limit");
 435                 BADCVAR("g_start_delay");
 436                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 437                 BADCVAR("hostname");
 438                 BADCVAR("log_file");
 439                 BADCVAR("maxplayers");
 440                 BADCVAR("minplayers");
 441                 BADCVAR("net_address");
 442                 BADCVAR("port");
 443                 BADCVAR("rcon_password");
 444                 BADCVAR("rcon_restricted_commands");
 445                 BADCVAR("rcon_restricted_password");
 446                 BADCVAR("skill");
 447                 BADCVAR("sv_adminnick");
 448                 BADCVAR("sv_autoscreenshot");
 449                 BADCVAR("sv_curl_defaulturl");
 450                 BADCVAR("sv_defaultcharacter");
 451                 BADCVAR("sv_defaultplayercolors");
 452                 BADCVAR("sv_defaultplayermodel");
 453                 BADCVAR("sv_defaultplayerskin");
 454                 BADCVAR("sv_maxidle");
 455                 BADCVAR("sv_maxrate");
 456                 BADCVAR("sv_motd");
 457                 BADCVAR("sv_public");
 458                 BADCVAR("sv_ready_restart");
 459                 BADCVAR("sv_status_privacy");
 460                 BADCVAR("sv_vote_call");
 461                 BADCVAR("sv_vote_commands");
 462                 BADCVAR("sv_vote_majority_factor");
 463                 BADCVAR("sv_vote_master");
 464                 BADCVAR("sv_vote_master_commands");
 465                 BADCVAR("sv_vote_master_password");
 466                 BADCVAR("sv_vote_simple_majority_factor");
 467                 BADCVAR("timelimit_override");
 468                 BADCVAR("g_warmup");
 469                 BADPREFIX("g_warmup_");
 470                 BADCVAR("teamplay_mode");
 471
 472                 if(autocvar_g_minstagib)
 473                 {
 474                         BADCVAR("g_grappling_hook");
 475                         BADCVAR("g_jetpack");
 476                 }
 477 #undef BADPREFIX
 478 #undef BADCVAR
 479
 480                 if(pureadding)
 481                 {
 482                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 483                         if(strlen(cvar_purechanges) > 16384)
 484                         {
 485                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 486                                 pureadding = 0;
 487                         }
 488                 }
 489                 ++cvar_purechanges_count;
 490                 // WARNING: this variable is used for the server list
 491                 // NEVER dare to skip this code!
 492                 // Hacks to intentionally appearing as "pure server" even though you DO have
 493                 // modified settings may be punished by removal from the server list.
 494                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 495                 // though.
 496         }
 497         buf_del(h);
 498         if(cvar_changes == "")
 499                 cvar_changes = "// this server runs at default server settings\n";
 500         else
 501                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 502         cvar_changes = strzone(cvar_changes);
 503         if(cvar_purechanges == "")
 504                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 505         else
 506                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 507         cvar_purechanges = strzone(cvar_purechanges);
 508 }
 509
 510 void detect_maptype()
 511 {
 512 #if 0
 513         vector o, v;
 514         float i;
 515
 516         for(;;)
 517         {
 518                 o = world.mins;
 519                 o_x += random() * (world.maxs_x - world.mins_x);
 520                 o_y += random() * (world.maxs_y - world.mins_y);
 521                 o_z += random() * (world.maxs_z - world.mins_z);
 522
 523                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 524                 if(trace_fraction == 1)
 525                         continue;
 526
 527                 v = trace_endpos;
 528
 529                 for(i = 0; i < 64; i += 4)
 530                 {
 531                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 532         if(trace_fraction == 1)
 533                 continue;
 534                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 535                 }
 536
 537                 break;
 538         }
 539 #endif
 540 }
 541
 542 entity randomseed;
 543 float RandomSeed_Send(entity to, float sf)
 544 {
 545         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 546         WriteShort(MSG_ENTITY, self.cnt);
 547         return TRUE;
 548 }
 549 void RandomSeed_Think()
 550 {
 551         self.cnt = bound(0, floor(random() * 65536), 65535);
 552         self.nextthink = time + 5;
 553
 554         self.SendFlags |= 1;
 555 }
 556 void RandomSeed_Spawn()
 557 {
 558         randomseed = spawn();
 559         randomseed.think = RandomSeed_Think;
 560         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 561
 562         entity oldself;
 563         oldself = self;
 564         self = randomseed;
 565         self.think(); // sets random seed and nextthink
 566         self = oldself;
 567 }
 568
 569 void spawnfunc___init_dedicated_server(void)
 570 {
 571         // handler for _init/_init map (only for dedicated server initialization)
 572
 573         world_initialized = -1; // don't complain
 574         cvar = cvar_normal;
 575         cvar_string = cvar_string_normal;
 576         cvar_set = cvar_set_normal;
 577
 578         remove = remove_unsafely;
 579
 580         entity e;
 581         e = spawn();
 582         e.think = GotoFirstMap;
 583         e.nextthink = time; // this is usually 1 at this point
 584
 585         e = spawn();
 586         e.classname = "info_player_deathmatch"; // safeguard against player joining
 587
 588         self.classname = "worldspawn"; // safeguard against various stuff ;)
 589
 590         MapInfo_Enumerate();
 591         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 592 }
 593
 594 void Map_MarkAsRecent(string m);
 595 float world_already_spawned;
 596 void RegisterWeapons();
 597 void Nagger_Init();
 598 void ClientInit_Spawn();
 599 void WeaponStats_Init();
 600 void WeaponStats_Shutdown();
 601 void spawnfunc_worldspawn (void)
 602 {
 603         float fd, l, i, j, n;
 604         string s, col;
 605
 606         cvar = cvar_normal;
 607         cvar_string = cvar_string_normal;
 608         cvar_set = cvar_set_normal;
 609
 610         if(world_already_spawned)
 611                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 612         world_already_spawned = TRUE;
 613
 614         remove = remove_safely; // during spawning, watch what you remove!
 615
 616         check_unacceptable_compiler_bugs();
 617
 618         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 619
 620         compressShortVector_init();
 621
 622         allowed_to_spawn = TRUE;
 623
 624         local entity head;
 625         head = nextent(world);
 626         maxclients = 0;
 627         while(head)
 628         {
 629                 ++maxclients;
 630                 head = nextent(head);
 631         }
 632
 633         // needs to be done so early as they would still spawn
 634         RegisterWeapons();
 635
 636         ServerProgsDB = db_load("server.db");
 637
 638         TemporaryDB = db_create();
 639
 640         // 0 normal
 641         lightstyle(0, "m");
 642
 643         // 1 FLICKER (first variety)
 644         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 645
 646         // 2 SLOW STRONG PULSE
 647         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 648
 649         // 3 CANDLE (first variety)
 650         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 651
 652         // 4 FAST STROBE
 653         lightstyle(4, "mamamamamama");
 654
 655         // 5 GENTLE PULSE 1
 656         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 657
 658         // 6 FLICKER (second variety)
 659         lightstyle(6, "nmonqnmomnmomomno");
 660
 661         // 7 CANDLE (second variety)
 662         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 663
 664         // 8 CANDLE (third variety)
 665         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 666
 667         // 9 SLOW STROBE (fourth variety)
 668         lightstyle(9, "aaaaaaaazzzzzzzz");
 669
 670         // 10 FLUORESCENT FLICKER
 671         lightstyle(10, "mmamammmmammamamaaamammma");
 672
 673         // 11 SLOW PULSE NOT FADE TO BLACK
 674         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 675
 676         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 677
 678         // 63 testing
 679         lightstyle(63, "a");
 680
 681         if(autocvar_g_campaign)
 682                 CampaignPreInit();
 683
 684         Map_MarkAsRecent(mapname);
 685
 686         precache_model ("null"); // we need this one before InitGameplayMode
 687         InitGameplayMode();
 688         readlevelcvars();
 689         GrappleHookInit();
 690         ElectroInit();
 691         LaserInit();
 692
 693         player_count = 0;
 694         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 695         if(bot_waypoints_for_items == 1)
 696                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 697                         bot_waypoints_for_items = 0;
 698
 699         // for setting by mapinfo
 700         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 701         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 702
 703         precache();
 704
 705         WaypointSprite_Init();
 706
 707         //if (g_domination)
 708         //      dom_init();
 709
 710         GameLogInit(); // prepare everything
 711         if(autocvar_sv_eventlog)
 712         {
 713                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 714                 s = strcat(s, ftos(random()));
 715                 matchid = strzone(s);
 716
 717                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 718                 s = ":gameinfo:mutators:LIST";
 719
 720                 ret_string = s;
 721                 MUTATOR_CALLHOOK(BuildMutatorsString);
 722                 s = ret_string;
 723
 724                 // simple, probably not good in the mutator system
 725                 if(autocvar_g_grappling_hook)
 726                         s = strcat(s, ":grappling_hook");
 727
 728                 // initialiation stuff, not good in the mutator system
 729                 if(!autocvar_g_use_ammunition)
 730                         s = strcat(s, ":no_use_ammunition");
 731
 732                 // initialiation stuff, not good in the mutator system
 733                 if(!autocvar_g_pickup_items)
 734                         s = strcat(s, ":no_pickup_items");
 735
 736                 // initialiation stuff, not good in the mutator system
 737                 if(autocvar_g_weaponarena != "0")
 738                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 739
 740                 // TODO to mutator system
 741                 if(autocvar_g_norecoil)
 742                         s = strcat(s, ":norecoil");
 743
 744                 // TODO to mutator system
 745                 if(autocvar_g_midair)
 746                         s = strcat(s, ":midair");
 747
 748                 // TODO to mutator system
 749                 if(autocvar_g_minstagib)
 750                         s = strcat(s, ":minstagib");
 751
 752                 GameLogEcho(s);
 753                 GameLogEcho(":gameinfo:end");
 754         }
 755         else
 756                 matchid = strzone(ftos(random()));
 757
 758         cvar_set("nextmap", "");
 759
 760         SetDefaultAlpha();
 761
 762         if(autocvar_g_campaign)
 763                 CampaignPostInit();
 764
 765         fteqcc_testbugs();
 766
 767         Ban_LoadBans();
 768
 769         MapInfo_Enumerate();
 770         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 771
 772         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 773         {
 774                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 775                 if(fd != -1)
 776                 {
 777                         while((s = fgets(fd)))
 778                         {
 779                                 l = tokenize_console(s);
 780                                 if(l < 2)
 781                                         continue;
 782                                 if(argv(0) == "cd")
 783                                 {
 784                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 785                                         print("  cdtrack ", argv(2), "\n");
 786                                 }
 787                                 else if(argv(0) == "fog")
 788                                 {
 789                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 790                                         print("  \"fog\" \"", s, "\"\n");
 791                                 }
 792                                 else if(argv(0) == "set")
 793                                 {
 794                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 795                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 796                                 }
 797                                 else if(argv(0) != "//")
 798                                 {
 799                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 800                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 801                                 }
 802                         }
 803                         fclose(fd);
 804                 }
 805         }
 806
 807         WeaponStats_Init();
 808
 809         addstat(STAT_WEAPONS, AS_INT, weapons);
 810         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 811         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 812         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 813         Nagger_Init();
 814
 815         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 816         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 817         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 818         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 819         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 820         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 821         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 822         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 823         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 824
 825         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 826         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 827
 828         if(g_ca || g_freezetag)
 829         {
 830                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 831                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 832                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 833                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 834         }
 835         if(g_freezetag)
 836         {
 837                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 838                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 839         }
 840
 841         // g_movementspeed hack
 842         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 843         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 844         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 845         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 846
 847         next_pingtime = time + 5;
 848
 849         detect_maptype();
 850
 851         lsmaps_reply = "^7Maps available: ";
 852         lsnewmaps_reply = "^7Maps without a record set: ";
 853         for(i = 0, j = 0; i < MapInfo_count; ++i)
 854         {
 855                 if(MapInfo_Get_ByID(i))
 856                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 857                         {
 858                                 if(mod(i, 2))
 859                                         col = "^2";
 860                                 else
 861                                         col = "^3";
 862                                 ++j;
 863                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 864                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 865                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 866                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 867                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 868                         }
 869         }
 870         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 871         if (!g_race && !g_cts)
 872                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 873         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 874
 875         maplist_reply = "^7Maps in list: ";
 876         n = tokenize_console(autocvar_g_maplist);
 877         for(i = 0, j = 0; i < n; ++i)
 878         {
 879                 if(MapInfo_CheckMap(argv(i)))
 880                 {
 881                         if(mod(j, 2))
 882                                 col = "^2";
 883                         else
 884                                 col = "^3";
 885                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 886                         ++j;
 887                 }
 888         }
 889         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 890         MapInfo_ClearTemps();
 891
 892         for(i = 0; i < 10; ++i)
 893         {
 894                 records_reply[i] = strzone(getrecords(i));
 895         }
 896         if(g_cts)
 897                 ladder_reply = strzone(getladder());
 898
 899         rankings_reply = strzone(getrankings());
 900
 901         ClientInit_Spawn();
 902         RandomSeed_Spawn();
 903         PingPLReport_Spawn();
 904
 905         CheatInit();
 906
 907         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 908
 909         // fill sv_curl_serverpackages from .serverpackage files
 910         if(autocvar_sv_curl_serverpackages_auto)
 911         {
 912                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 913                 s = "";
 914                 if(fd >= 0)
 915                 {
 916                         j = search_getsize(fd);
 917                         for(i = 0; i < j; ++i)
 918                                 s = strcat(s, " ", search_getfilename(fd, i));
 919                         search_end(fd);
 920                 }
 921                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 922         }
 923
 924         PlayerStats_Init();
 925
 926         world_initialized = 1;
 927 }
 928
 929 void spawnfunc_light (void)
 930 {
 931         //makestatic (self); // Who the f___ did that?
 932         remove(self);
 933 }
 934
 935 float TryFile( string pFilename )
 936 {
 937         local float lHandle;
 938         dprint("TryFile(\"", pFilename, "\")\n");
 939         lHandle = fopen( pFilename, FILE_READ );
 940         if( lHandle != -1 ) {
 941                 fclose( lHandle );
 942                 return TRUE;
 943         } else {
 944                 return FALSE;
 945         }
 946 };
 947
 948 string GetGametype()
 949 {
 950         return GametypeNameFromType(game);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 992                 if(fh < 0)
 993                 {
 994                         dprint(": no waypoints\n");
 995                         return FALSE;
 996                 }
 997                 dprint(": has waypoints\n");
 998                 fclose(fh);
 999         }
1000
1001         // open map size restriction file
1002         dprint("opensize "); dprint(map);
1003         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1004         if(fh >= 0)
1005         {
1006                 float mapmin, mapmax;
1007                 dprint(": ok, ");
1008                 mapmin = stof(fgets(fh));
1009                 mapmax = stof(fgets(fh));
1010                 fclose(fh);
1011                 if(player_count < mapmin)
1012                 {
1013                         dprint("not enough\n");
1014                         return FALSE;
1015                 }
1016                 if(player_count > mapmax)
1017                 {
1018                         dprint("too many\n");
1019                         return FALSE;
1020                 }
1021                 dprint("right size\n");
1022                 return TRUE;
1023         }
1024         dprint(": not found\n");
1025         return TRUE;
1026 }
1027
1028 string Map_Filename(float position)
1029 {
1030         return strcat("maps/", argv(position), ".bsp");
1031 }
1032
1033 string strwords(string s, float w)
1034 {
1035         float endpos;
1036         for(endpos = 0; w && endpos >= 0; --w)
1037                 endpos = strstrofs(s, " ", endpos + 1);
1038         if(endpos < 0)
1039                 return s;
1040         else
1041                 return substring(s, 0, endpos);
1042 }
1043
1044 float strhasword(string s, string w)
1045 {
1046         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1047 }
1048
1049 void Map_MarkAsRecent(string m)
1050 {
1051         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1052 }
1053
1054 float Map_IsRecent(string m)
1055 {
1056         return strhasword(autocvar_g_maplist_mostrecent, m);
1057 }
1058
1059 float Map_Check(float position, float pass)
1060 {
1061         string filename;
1062         string map_next;
1063         map_next = argv(position);
1064         if(pass <= 1)
1065         {
1066                 if(Map_IsRecent(map_next))
1067                         return 0;
1068         }
1069         filename = Map_Filename(position);
1070         if(MapInfo_CheckMap(map_next))
1071         {
1072                 if(pass == 2)
1073                         return 1;
1074                 if(MapHasRightSize(map_next))
1075                         return 1;
1076                 return 0;
1077         }
1078         else
1079                 dprint( "Couldn't select '", filename, "'..\n" );
1080
1081         return 0;
1082 }
1083
1084 void Map_Goto_SetStr(string nextmapname)
1085 {
1086         if(getmapname_stored != "")
1087                 strunzone(getmapname_stored);
1088         if(nextmapname == "")
1089                 getmapname_stored = "";
1090         else
1091                 getmapname_stored = strzone(nextmapname);
1092 }
1093
1094 void Map_Goto_SetFloat(float position)
1095 {
1096         cvar_set("g_maplist_index", ftos(position));
1097         Map_Goto_SetStr(argv(position));
1098 }
1099
1100 void GameResetCfg()
1101 {
1102         // settings persist, except...
1103         localcmd("\nsettemp_restore\n");
1104 };
1105
1106 void Map_Goto()
1107 {
1108         GameResetCfg();
1109         MapInfo_LoadMap(getmapname_stored);
1110 }
1111
1112 // return codes of map selectors:
1113 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1114 //   -2 = permanent failure
1115 float() MaplistMethod_Iterate = // usual method
1116 {
1117         float pass, i;
1118
1119         for(pass = 1; pass <= 2; ++pass)
1120         {
1121                 for(i = 1; i < Map_Count; ++i)
1122                 {
1123                         float mapindex;
1124                         mapindex = mod(i + Map_Current, Map_Count);
1125                         if(Map_Check(mapindex, pass))
1126                                 return mapindex;
1127                 }
1128         }
1129         return -1;
1130 }
1131
1132 float() MaplistMethod_Repeat = // fallback method
1133 {
1134         if(Map_Check(Map_Current, 2))
1135                 return Map_Current;
1136         return -2;
1137 }
1138
1139 float() MaplistMethod_Random = // random map selection
1140 {
1141         float i, imax;
1142
1143         imax = 42;
1144
1145         for(i = 0; i <= imax; ++i)
1146         {
1147                 float mapindex;
1148                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1149                 if(Map_Check(mapindex, 1))
1150                         return mapindex;
1151         }
1152         return -1;
1153 }
1154
1155 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1156 // the exponent sets a bias on the map selection:
1157 // the higher the exponent, the less likely "shortly repeated" same maps are
1158 {
1159         float i, j, imax, insertpos;
1160
1161         imax = 42;
1162
1163         for(i = 0; i <= imax; ++i)
1164         {
1165                 string newlist;
1166
1167                 // now reinsert this at another position
1168                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1169                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1170                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1171                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1172
1173                 // insert the current map there
1174                 newlist = "";
1175                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1178                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1179                         newlist = strcat(newlist, " ", argv(j));
1180                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1181                 cvar_set("g_maplist", newlist);
1182                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1183
1184                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1185                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1186                 if(Map_Check(Map_Current, 1))
1187                         return Map_Current;
1188         }
1189         return -1;
1190 }
1191
1192 void Maplist_Init()
1193 {
1194         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         if(Map_Count == 0)
1196         {
1197                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1198                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1199                 if(autocvar_g_maplist_shuffle)
1200                         ShuffleMaplist();
1201                 localcmd("\nmenu_cmd sync\n");
1202                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1203         }
1204         if(Map_Count == 0)
1205                 error("empty maplist, cannot select a new map");
1206         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1207
1208         if(Map_Current_Name)
1209                 strunzone(Map_Current_Name);
1210         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1211         // this may or may not be correct, but who cares, in the worst case a map
1212         // isn't chosen in the first pass that should have been
1213 }
1214
1215 string GetNextMap()
1216 {
1217         float nextMap;
1218
1219         Maplist_Init();
1220         nextMap = -1;
1221
1222         if(nextMap == -1)
1223                 if(autocvar_g_maplist_shuffle > 0)
1224                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_selectrandom)
1228                         nextMap = MaplistMethod_Random();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Iterate();
1232
1233         if(nextMap == -1)
1234                 nextMap = MaplistMethod_Repeat();
1235
1236         if(nextMap >= 0)
1237         {
1238                 Map_Goto_SetFloat(nextMap);
1239                 return getmapname_stored;
1240         }
1241
1242         return "";
1243 };
1244
1245 float DoNextMapOverride()
1246 {
1247         if(autocvar_g_campaign)
1248         {
1249                 CampaignPostIntermission();
1250                 alreadychangedlevel = TRUE;
1251                 return TRUE;
1252         }
1253         if(autocvar_quit_when_empty)
1254         {
1255                 if(player_count <= currentbots)
1256                 {
1257                         localcmd("quit\n");
1258                         alreadychangedlevel = TRUE;
1259                         return TRUE;
1260                 }
1261         }
1262         if(autocvar_quit_and_redirect != "")
1263         {
1264                 redirection_target = strzone(autocvar_quit_and_redirect);
1265                 alreadychangedlevel = TRUE;
1266                 return TRUE;
1267         }
1268         if (autocvar_samelevel) // if samelevel is set, stay on same level
1269         {
1270                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1271                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1272                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1273                 localcmd("restart\n");
1274                 //changelevel (mapname);
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         if(autocvar_nextmap != "")
1279                 if(MapInfo_CheckMap(autocvar_nextmap))
1280                 {
1281                         Map_Goto_SetStr(autocvar_nextmap);
1282                         Map_Goto();
1283                         alreadychangedlevel = TRUE;
1284                         return TRUE;
1285                 }
1286         if(autocvar_lastlevel)
1287         {
1288                 GameResetCfg();
1289                 localcmd("set lastlevel 0\ntogglemenu\n");
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         return FALSE;
1294 };
1295
1296 void GotoNextMap()
1297 {
1298         //local string nextmap;
1299         //local float n, nummaps;
1300         //local string s;
1301         if (alreadychangedlevel)
1302                 return;
1303         alreadychangedlevel = TRUE;
1304
1305         {
1306                 string nextMap;
1307                 float allowReset;
1308
1309                 for(allowReset = 1; allowReset >= 0; --allowReset)
1310                 {
1311                         nextMap = GetNextMap();
1312                         if(nextMap != "")
1313                                 break;
1314
1315                         if(allowReset)
1316                         {
1317                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1318                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1319                                 if(autocvar_g_maplist_shuffle)
1320                                         ShuffleMaplist();
1321                                 localcmd("\nmenu_cmd sync\n");
1322                         }
1323                         else
1324                         {
1325                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1326                         }
1327                 }
1328                 Map_Goto();
1329         }
1330 };
1331
1332
1333 /*
1334 ============
1335 IntermissionThink
1336
1337 When the player presses attack or jump, change to the next level
1338 ============
1339 */
1340 .float autoscreenshot;
1341 void() MapVote_Start;
1342 void() MapVote_Think;
1343 float mapvote_initialized;
1344 void IntermissionThink()
1345 {
1346         FixIntermissionClient(self);
1347
1348         if(autocvar_sv_autoscreenshot)
1349         if(self.autoscreenshot > 0)
1350         if(time > self.autoscreenshot)
1351         {
1352                 self.autoscreenshot = -1;
1353                 if(clienttype(self) == CLIENTTYPE_REAL)
1354                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1355                 return;
1356         }
1357
1358         if (time < intermission_exittime)
1359                 return;
1360
1361         if(!mapvote_initialized)
1362                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1363                         return;
1364
1365         MapVote_Start();
1366 };
1367
1368 /*
1369 ============
1370 FindIntermission
1371
1372 Returns the entity to view from
1373 ============
1374 */
1375 /*
1376 entity FindIntermission()
1377 {
1378         local   entity spot;
1379         local   float cyc;
1380
1381 // look for info_intermission first
1382         spot = find (world, classname, "info_intermission");
1383         if (spot)
1384         {       // pick a random one
1385                 cyc = random() * 4;
1386                 while (cyc > 1)
1387                 {
1388                         spot = find (spot, classname, "info_intermission");
1389                         if (!spot)
1390                                 spot = find (spot, classname, "info_intermission");
1391                         cyc = cyc - 1;
1392                 }
1393                 return spot;
1394         }
1395
1396 // then look for the start position
1397         spot = find (world, classname, "info_player_start");
1398         if (spot)
1399                 return spot;
1400
1401 // testinfo_player_start is only found in regioned levels
1402         spot = find (world, classname, "testplayerstart");
1403         if (spot)
1404                 return spot;
1405
1406 // then look for the start position
1407         spot = find (world, classname, "info_player_deathmatch");
1408         if (spot)
1409                 return spot;
1410
1411         //objerror ("FindIntermission: no spot");
1412         return world;
1413 };
1414 */
1415
1416 /*
1417 ===============================================================================
1418
1419 RULES
1420
1421 ===============================================================================
1422 */
1423
1424 void DumpStats(float final)
1425 {
1426         float file;
1427         string s;
1428         float to_console;
1429         float to_eventlog;
1430         float to_file;
1431         float i;
1432         entity e;
1433
1434         to_console = autocvar_sv_logscores_console;
1435         to_eventlog = autocvar_sv_eventlog;
1436         to_file = autocvar_sv_logscores_file;
1437
1438         if(!final)
1439         {
1440                 to_console = TRUE; // always print printstats replies
1441                 to_eventlog = FALSE; // but never print them to the event log
1442         }
1443
1444         if(to_eventlog)
1445                 if(autocvar_sv_eventlog_console)
1446                         to_console = FALSE; // otherwise we get the output twice
1447
1448         if(final)
1449                 s = ":scores:";
1450         else
1451                 s = ":status:";
1452         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1453
1454         if(to_console)
1455                 print(s, "\n");
1456         if(to_eventlog)
1457                 GameLogEcho(s);
1458         if(to_file)
1459         {
1460                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1461                 if(file == -1)
1462                         to_file = FALSE;
1463                 else
1464                         fputs(file, strcat(s, "\n"));
1465         }
1466
1467         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1468         if(to_console)
1469                 print(s, "\n");
1470         if(to_eventlog)
1471                 GameLogEcho(s);
1472         if(to_file)
1473                 fputs(file, strcat(s, "\n"));
1474
1475         FOR_EACH_CLIENT(other)
1476         {
1477                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1478                 {
1479                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1480                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1481                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1482                                 s = strcat(s, ftos(other.team), ":");
1483                         else
1484                                 s = strcat(s, "spectator:");
1485
1486                         if(to_console)
1487                                 print(s, other.netname, "\n");
1488                         if(to_eventlog)
1489                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1490                         if(to_file)
1491                                 fputs(file, strcat(s, other.netname, "\n"));
1492                 }
1493         }
1494
1495         if(teams_matter)
1496         {
1497                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1498                 if(to_console)
1499                         print(s, "\n");
1500                 if(to_eventlog)
1501                         GameLogEcho(s);
1502                 if(to_file)
1503                         fputs(file, strcat(s, "\n"));
1504
1505                 for(i = 1; i < 16; ++i)
1506                 {
1507                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1508                         s = strcat(s, ":", ftos(i));
1509                         if(to_console)
1510                                 print(s, "\n");
1511                         if(to_eventlog)
1512                                 GameLogEcho(s);
1513                         if(to_file)
1514                                 fputs(file, strcat(s, "\n"));
1515                 }
1516         }
1517
1518         if(to_console)
1519                 print(":end\n");
1520         if(to_eventlog)
1521                 GameLogEcho(":end");
1522         if(to_file)
1523         {
1524                 fputs(file, ":end\n");
1525                 fclose(file);
1526         }
1527 }
1528
1529 void FixIntermissionClient(entity e)
1530 {
1531         string s;
1532         if(!e.autoscreenshot) // initial call
1533         {
1534                 e.angles = e.v_angle;
1535                 e.angles_x = -e.angles_x;
1536                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1537                 e.health = -2342;
1538                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1539                 e.solid = SOLID_NOT;
1540                 e.movetype = MOVETYPE_NONE;
1541                 e.takedamage = DAMAGE_NO;
1542                 if(e.weaponentity)
1543                 {
1544                         e.weaponentity.effects = EF_NODRAW;
1545                         if (e.weaponentity.weaponentity)
1546                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1547                 }
1548                 if(clienttype(e) == CLIENTTYPE_REAL)
1549                 {
1550                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1551                         s = autocvar_sv_intermission_cdtrack;
1552                         if(s != "")
1553                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1554                         msg_entity = e;
1555                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1556                 }
1557         }
1558
1559         //e.velocity = '0 0 0';
1560         //e.fixangle = TRUE;
1561
1562         // TODO halt weapon animation
1563 }
1564
1565
1566 /*
1567 go to the next level for deathmatch
1568 only called if a time or frag limit has expired
1569 */
1570 void NextLevel()
1571 {
1572         gameover = TRUE;
1573
1574         intermission_running = 1;
1575
1576 // enforce a wait time before allowing changelevel
1577         if(player_count > 0)
1578                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1579         else
1580                 intermission_exittime = -1;
1581
1582         /*
1583         WriteByte (MSG_ALL, SVC_CDTRACK);
1584         WriteByte (MSG_ALL, 3);
1585         WriteByte (MSG_ALL, 3);
1586         // done in FixIntermission
1587         */
1588
1589         //pos = FindIntermission ();
1590
1591         VoteReset();
1592
1593         DumpStats(TRUE);
1594
1595         // send statistics
1596         entity e;
1597         PlayerStats_EndMatch(1);
1598         FOR_EACH_CLIENT(e)
1599                 PlayerStats_AddGlobalInfo(e);
1600         PlayerStats_Shutdown();
1601
1602         if(autocvar_sv_eventlog)
1603                 GameLogEcho(":gameover");
1604
1605         GameLogClose();
1606
1607         FOR_EACH_PLAYER(other) {
1608                 FixIntermissionClient(other);
1609                 if(other.winning)
1610                         bprint(other.netname, " ^7wins.\n");
1611         }
1612
1613         if(autocvar_g_campaign)
1614                 CampaignPreIntermission();
1615
1616         localcmd("\nsv_hook_gameend\n");
1617 }
1618
1619 /*
1620 ============
1621 CheckRules_Player
1622
1623 Exit deathmatch games upon conditions
1624 ============
1625 */
1626 void CheckRules_Player()
1627 {
1628         if (gameover)   // someone else quit the game already
1629                 return;
1630
1631         if(self.deadflag == DEAD_NO)
1632                 self.play_time += frametime;
1633
1634         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1635         //   (div0: and that in CheckRules_World please)
1636 };
1637
1638 float checkrules_equality;
1639 float checkrules_suddendeathwarning;
1640 float checkrules_suddendeathend;
1641 float checkrules_overtimesadded; //how many overtimes have been already added
1642
1643 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1644 float WINNING_YES = 1; // winner found
1645 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1646 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1647
1648 float InitiateSuddenDeath()
1649 {
1650         // Check first whether normal overtimes could be added before initiating suddendeath mode
1651         // - for this timelimit_overtime needs to be >0 of course
1652         // - also check the winning condition calculated in the previous frame and only add normal overtime
1653         //   again, if at the point at which timelimit would be extended again, still no winner was found
1654         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1655         {
1656                 return 1; // need to call InitiateOvertime later
1657         }
1658         else
1659         {
1660                 if(!checkrules_suddendeathend)
1661                 {
1662                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1663                         if(g_race && !g_race_qualifying)
1664                                 race_StartCompleting();
1665                 }
1666                 return 0;
1667         }
1668 }
1669
1670 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1671 {
1672         ++checkrules_overtimesadded;
1673         //add one more overtime by simply extending the timelimit
1674         float tl;
1675         tl = autocvar_timelimit;
1676         tl += autocvar_timelimit_overtime;
1677         cvar_set("timelimit", ftos(tl));
1678         string minutesPlural;
1679         if (autocvar_timelimit_overtime == 1)
1680                 minutesPlural = " ^3minute";
1681         else
1682                 minutesPlural = " ^3minutes";
1683
1684         bcenterprint(
1685                 strcat(
1686                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1687                         ftos(autocvar_timelimit_overtime),
1688                         minutesPlural,
1689                         " to the game!"
1690                 )
1691         );
1692 }
1693
1694 float GetWinningCode(float fraglimitreached, float equality)
1695 {
1696         if(autocvar_g_campaign == 1)
1697                 if(fraglimitreached)
1698                         return WINNING_YES;
1699                 else
1700                         return WINNING_NO;
1701
1702         else
1703                 if(equality)
1704                         if(fraglimitreached)
1705                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1706                         else
1707                                 return WINNING_NEVER;
1708                 else
1709                         if(fraglimitreached)
1710                                 return WINNING_YES;
1711                         else
1712                                 return WINNING_NO;
1713 }
1714
1715 // set the .winning flag for exactly those players with a given field value
1716 void SetWinners(.float field, float value)
1717 {
1718         entity head;
1719         FOR_EACH_PLAYER(head)
1720                 head.winning = (head.field == value);
1721 }
1722
1723 // set the .winning flag for those players with a given field value
1724 void AddWinners(.float field, float value)
1725 {
1726         entity head;
1727         FOR_EACH_PLAYER(head)
1728                 if(head.field == value)
1729                         head.winning = 1;
1730 }
1731
1732 // clear the .winning flags
1733 void ClearWinners(void)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 head.winning = 0;
1738 }
1739
1740 // Onslaught winning condition:
1741 // game terminates if only one team has a working generator (or none)
1742 float WinningCondition_Onslaught()
1743 {
1744         entity head;
1745         local float t1, t2, t3, t4;
1746
1747         WinningConditionHelper(); // set worldstatus
1748
1749         if(inWarmupStage)
1750                 return WINNING_NO;
1751
1752         // first check if the game has ended
1753         t1 = t2 = t3 = t4 = 0;
1754         head = find(world, classname, "onslaught_generator");
1755         while (head)
1756         {
1757                 if (head.health > 0)
1758                 {
1759                         if (head.team == COLOR_TEAM1) t1 = 1;
1760                         if (head.team == COLOR_TEAM2) t2 = 1;
1761                         if (head.team == COLOR_TEAM3) t3 = 1;
1762                         if (head.team == COLOR_TEAM4) t4 = 1;
1763                 }
1764                 head = find(head, classname, "onslaught_generator");
1765         }
1766         if (t1 + t2 + t3 + t4 < 2)
1767         {
1768                 // game over, only one team remains (or none)
1769                 ClearWinners();
1770                 if (t1) SetWinners(team, COLOR_TEAM1);
1771                 if (t2) SetWinners(team, COLOR_TEAM2);
1772                 if (t3) SetWinners(team, COLOR_TEAM3);
1773                 if (t4) SetWinners(team, COLOR_TEAM4);
1774                 dprint("Have a winner, ending game.\n");
1775                 return WINNING_YES;
1776         }
1777
1778         // Two or more teams remain
1779         return WINNING_NO;
1780 }
1781
1782 float LMS_NewPlayerLives()
1783 {
1784         float fl;
1785         fl = autocvar_fraglimit;
1786         if(fl == 0)
1787                 fl = 999;
1788
1789         // first player has left the game for dying too much? Nobody else can get in.
1790         if(lms_lowest_lives < 1)
1791                 return 0;
1792
1793         if(!autocvar_g_lms_join_anytime)
1794                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1795                         return 0;
1796
1797         return bound(1, lms_lowest_lives, fl);
1798 }
1799
1800 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1801 // they win. Otherwise the defending team wins once the timelimit passes.
1802 void assault_new_round();
1803 float WinningCondition_Assault()
1804 {
1805         local float status;
1806
1807         WinningConditionHelper(); // set worldstatus
1808
1809         status = WINNING_NO;
1810         // as the timelimit has not yet passed just assume the defending team will win
1811         if(assault_attacker_team == COLOR_TEAM1)
1812         {
1813                 SetWinners(team, COLOR_TEAM2);
1814         }
1815         else
1816         {
1817                 SetWinners(team, COLOR_TEAM1);
1818         }
1819
1820         local entity ent;
1821         ent = find(world, classname, "target_assault_roundend");
1822         if(ent)
1823         {
1824                 if(ent.winning) // round end has been triggered by attacking team
1825                 {
1826                         bprint("ASSAULT: round completed...\n");
1827                         SetWinners(team, assault_attacker_team);
1828
1829                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1830
1831                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1832                         {
1833                                 status = WINNING_YES;
1834                         }
1835                         else
1836                         {
1837                                 local entity oldself;
1838                                 oldself = self;
1839                                 self = ent;
1840                                 assault_new_round();
1841                                 self = oldself;
1842                         }
1843                 }
1844         }
1845
1846         return status;
1847 }
1848
1849 // LMS winning condition: game terminates if and only if there's at most one
1850 // one player who's living lives. Top two scores being equal cancels the time
1851 // limit.
1852 float WinningCondition_LMS()
1853 {
1854         entity head, head2;
1855         float have_player;
1856         float have_players;
1857         float l;
1858
1859         have_player = FALSE;
1860         have_players = FALSE;
1861         l = LMS_NewPlayerLives();
1862
1863         head = find(world, classname, "player");
1864         if(head)
1865                 have_player = TRUE;
1866         head2 = find(head, classname, "player");
1867         if(head2)
1868                 have_players = TRUE;
1869
1870         if(have_player)
1871         {
1872                 // we have at least one player
1873                 if(have_players)
1874                 {
1875                         // two or more active players - continue with the game
1876                 }
1877                 else
1878                 {
1879                         // exactly one player?
1880
1881                         ClearWinners();
1882                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1883
1884                         if(l)
1885                         {
1886                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1887                                 return WINNING_NO;
1888                         }
1889                         else
1890                         {
1891                                 // a winner!
1892                                 // and assign him his first place
1893                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1894                                 return WINNING_YES;
1895                         }
1896                 }
1897         }
1898         else
1899         {
1900                 // nobody is playing at all...
1901                 if(l)
1902                 {
1903                         // wait for players...
1904                 }
1905                 else
1906                 {
1907                         // SNAFU (maybe a draw game?)
1908                         ClearWinners();
1909                         dprint("No players, ending game.\n");
1910                         return WINNING_YES;
1911                 }
1912         }
1913
1914         // When we get here, we have at least two players who are actually LIVING,
1915         // now check if the top two players have equal score.
1916         WinningConditionHelper();
1917
1918         ClearWinners();
1919         if(WinningConditionHelper_winner)
1920                 WinningConditionHelper_winner.winning = TRUE;
1921         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1922                 return WINNING_NEVER;
1923
1924         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1925         return WINNING_NO;
1926 }
1927
1928 void ShuffleMaplist()
1929 {
1930         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1931 }
1932
1933 float leaderfrags;
1934 float WinningCondition_Scores(float limit, float leadlimit)
1935 {
1936         float limitreached;
1937
1938         // TODO make everything use THIS winning condition (except LMS)
1939         WinningConditionHelper();
1940
1941         if(teams_matter)
1942         {
1943                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1944                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1945                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1946                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1947         }
1948
1949         ClearWinners();
1950         if(WinningConditionHelper_winner)
1951                 WinningConditionHelper_winner.winning = 1;
1952         if(WinningConditionHelper_winnerteam >= 0)
1953                 SetWinners(team, WinningConditionHelper_winnerteam);
1954
1955         if(WinningConditionHelper_lowerisbetter)
1956         {
1957                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1958                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1959                 limit = -limit;
1960         }
1961
1962         if(WinningConditionHelper_zeroisworst)
1963                 leadlimit = 0; // not supported in this mode
1964
1965         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1966         // these modes always score in increments of 1, thus this makes sense
1967         {
1968                 if(leaderfrags != WinningConditionHelper_topscore)
1969                 {
1970                         leaderfrags = WinningConditionHelper_topscore;
1971
1972                         if (limit)
1973                         if (leaderfrags == limit - 1)
1974                                 Announce("1fragleft");
1975                         else if (leaderfrags == limit - 2)
1976                                 Announce("2fragsleft");
1977                         else if (leaderfrags == limit - 3)
1978                                 Announce("3fragsleft");
1979                 }
1980         }
1981
1982         limitreached = FALSE;
1983         if(limit)
1984                 if(WinningConditionHelper_topscore >= limit)
1985                         limitreached = TRUE;
1986         if(leadlimit)
1987         {
1988                 float leadlimitreached;
1989                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1990                 if(autocvar_leadlimit_and_fraglimit)
1991                         limitreached = (limitreached && leadlimitreached);
1992                 else
1993                         limitreached = (limitreached || leadlimitreached);
1994         }
1995
1996         return GetWinningCode(
1997                 WinningConditionHelper_topscore && limitreached,
1998                 WinningConditionHelper_equality
1999         );
2000 }
2001
2002 float WinningCondition_Race(float fraglimit)
2003 {
2004         float wc;
2005         entity p;
2006         float n, c;
2007
2008         n = 0;
2009         c = 0;
2010         FOR_EACH_PLAYER(p)
2011         {
2012                 ++n;
2013                 if(p.race_completed)
2014                         ++c;
2015         }
2016         if(n && (n == c))
2017                 return WINNING_YES;
2018         wc = WinningCondition_Scores(fraglimit, 0);
2019
2020         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2021         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2022         // do NOT support equality when the laps are all raced!
2023                 return WINNING_STARTSUDDENDEATHOVERTIME;
2024         else
2025                 return WINNING_NEVER;
2026         return wc;
2027 }
2028
2029 void ReadyRestart();
2030 float WinningCondition_QualifyingThenRace(float limit)
2031 {
2032         float wc;
2033         wc = WinningCondition_Scores(limit, 0);
2034
2035         // NEVER initiate overtime
2036         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2037         {
2038                 return WINNING_YES;
2039         }
2040
2041         return wc;
2042 }
2043
2044 float WinningCondition_RanOutOfSpawns()
2045 {
2046         entity head;
2047
2048         if(have_team_spawns <= 0)
2049                 return WINNING_NO;
2050
2051         if(!some_spawn_has_been_used)
2052                 return WINNING_NO;
2053
2054         team1_score = team2_score = team3_score = team4_score = 0;
2055
2056         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2057         {
2058                 if(head.team == COLOR_TEAM1)
2059                         team1_score = 1;
2060                 else if(head.team == COLOR_TEAM2)
2061                         team2_score = 1;
2062                 else if(head.team == COLOR_TEAM3)
2063                         team3_score = 1;
2064                 else if(head.team == COLOR_TEAM4)
2065                         team4_score = 1;
2066         }
2067
2068         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2069         {
2070                 if(head.team == COLOR_TEAM1)
2071                         team1_score = 1;
2072                 else if(head.team == COLOR_TEAM2)
2073                         team2_score = 1;
2074                 else if(head.team == COLOR_TEAM3)
2075                         team3_score = 1;
2076                 else if(head.team == COLOR_TEAM4)
2077                         team4_score = 1;
2078         }
2079
2080         ClearWinners();
2081         if(team1_score + team2_score + team3_score + team4_score == 0)
2082         {
2083                 checkrules_equality = TRUE;
2084                 return WINNING_YES;
2085         }
2086         else if(team1_score + team2_score + team3_score + team4_score == 1)
2087         {
2088                 float t, i;
2089                 if(team1_score) t = COLOR_TEAM1;
2090                 if(team2_score) t = COLOR_TEAM2;
2091                 if(team3_score) t = COLOR_TEAM3;
2092                 if(team4_score) t = COLOR_TEAM4;
2093                 CheckAllowedTeams(world);
2094                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2095                 {
2096                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2097                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2098                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2099                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2100                 }
2101
2102                 AddWinners(team, t);
2103                 return WINNING_YES;
2104         }
2105         else
2106                 return WINNING_NO;
2107 }
2108
2109 /*
2110 ============
2111 CheckRules_World
2112
2113 Exit deathmatch games upon conditions
2114 ============
2115 */
2116 void CheckRules_World()
2117 {
2118         float timelimit;
2119         float fraglimit;
2120         float leadlimit;
2121
2122         VoteThink();
2123         MapVote_Think();
2124
2125         SetDefaultAlpha();
2126
2127         /*
2128         MapVote_Think should now do that part
2129         if (intermission_running)
2130                 if (time >= intermission_exittime + 60)
2131                 {
2132                         if(!DoNextMapOverride())
2133                                 GotoNextMap();
2134                         return;
2135                 }
2136         */
2137
2138         if (gameover)   // someone else quit the game already
2139         {
2140                 if(player_count == 0) // Nobody there? Then let's go to the next map
2141                         MapVote_Start();
2142                         // this will actually check the player count in the next frame
2143                         // again, but this shouldn't hurt
2144                 return;
2145         }
2146
2147         timelimit = autocvar_timelimit * 60;
2148         fraglimit = autocvar_fraglimit;
2149         leadlimit = autocvar_leadlimit;
2150
2151         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2152         {
2153                 if(timelimit > 0)
2154                         timelimit = 0; // timelimit is not made for warmup
2155                 if(fraglimit > 0)
2156                         fraglimit = 0; // no fraglimit for now
2157                 leadlimit = 0; // no leadlimit for now
2158         }
2159
2160         if(g_onslaught)
2161                 timelimit = 0; // ONS has its own overtime rule
2162
2163         if(timelimit > 0)
2164         {
2165                 timelimit += game_starttime;
2166         }
2167         else if (timelimit < 0)
2168         {
2169                 // endmatch
2170                 NextLevel();
2171                 return;
2172         }
2173
2174         float wantovertime;
2175         wantovertime = 0;
2176
2177         if(checkrules_suddendeathend)
2178         {
2179                 if(!checkrules_suddendeathwarning)
2180                 {
2181                         checkrules_suddendeathwarning = TRUE;
2182                         if(g_race && !g_race_qualifying)
2183                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2184                         else
2185                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2186                 }
2187         }
2188         else
2189         {
2190                 if (timelimit && time >= timelimit)
2191                 {
2192                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2193                         {
2194                                 float totalplayers;
2195                                 float playerswithlaps;
2196                                 float readyplayers;
2197                                 entity head;
2198                                 totalplayers = playerswithlaps = readyplayers = 0;
2199                                 FOR_EACH_PLAYER(head)
2200                                 {
2201                                         ++totalplayers;
2202                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2203                                                 ++playerswithlaps;
2204                                         if(head.ready)
2205                                                 ++readyplayers;
2206                                 }
2207
2208                                 // at least 2 of the players have completed a lap: start the RACE
2209                                 // otherwise, the players should end the qualifying on their own
2210                                 if(readyplayers || playerswithlaps >= 2)
2211                                 {
2212                                         checkrules_suddendeathend = 0;
2213                                         ReadyRestart(); // go to race
2214                                         return;
2215                                 }
2216                                 else
2217                                         wantovertime |= InitiateSuddenDeath();
2218                         }
2219                         else
2220                                 wantovertime |= InitiateSuddenDeath();
2221                 }
2222         }
2223
2224         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2225         {
2226                 NextLevel();
2227                 return;
2228         }
2229
2230         float checkrules_status;
2231         checkrules_status = WinningCondition_RanOutOfSpawns();
2232         if(checkrules_status == WINNING_YES)
2233         {
2234                 bprint("Hey! Someone ran out of spawns!\n");
2235         }
2236         else if(g_race && !g_race_qualifying && timelimit >= 0)
2237         {
2238                 checkrules_status = WinningCondition_Race(fraglimit);
2239                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2240         }
2241         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2242         {
2243                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2244                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2245         }
2246         else if(g_assault)
2247         {
2248                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2249         }
2250         else if(g_lms)
2251         {
2252                 checkrules_status = WinningCondition_LMS();
2253         }
2254         else if (g_onslaught)
2255         {
2256                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2257         }
2258         else
2259         {
2260                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2261                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2262         }
2263
2264         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2265         {
2266                 checkrules_status = WINNING_NEVER;
2267                 checkrules_overtimesadded = -1;
2268                 wantovertime |= InitiateSuddenDeath();
2269         }
2270
2271         if(checkrules_status == WINNING_NEVER)
2272                 // equality cases! Nobody wins if the overtime ends in a draw.
2273                 ClearWinners();
2274
2275         if(wantovertime)
2276         {
2277                 if(checkrules_status == WINNING_NEVER)
2278                         InitiateOvertime();
2279                 else
2280                         checkrules_status = WINNING_YES;
2281         }
2282
2283         if(checkrules_suddendeathend)
2284                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2285                         checkrules_status = WINNING_YES;
2286
2287         if(checkrules_status == WINNING_YES)
2288         {
2289                 //print("WINNING\n");
2290                 NextLevel();
2291         }
2292 };
2293
2294 float mapvote_nextthink;
2295 float mapvote_initialized;
2296 float mapvote_keeptwotime;
2297 float mapvote_timeout;
2298 string mapvote_message;
2299 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2300 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2301 float mapvote_screenshot_dirs_count;
2302
2303 float mapvote_count;
2304 float mapvote_count_real;
2305 string mapvote_maps[MAPVOTE_COUNT];
2306 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2307 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2308 float mapvote_maps_suggested[MAPVOTE_COUNT];
2309 string mapvote_suggestions[MAPVOTE_COUNT];
2310 float mapvote_suggestion_ptr;
2311 float mapvote_maxlen;
2312 float mapvote_voters;
2313 float mapvote_votes[MAPVOTE_COUNT];
2314 float mapvote_run;
2315 float mapvote_detail;
2316 float mapvote_abstain;
2317 .float mapvote;
2318
2319 void MapVote_ClearAllVotes()
2320 {
2321         FOR_EACH_CLIENT(other)
2322                 other.mapvote = 0;
2323 }
2324
2325 string MapVote_Suggest(string m)
2326 {
2327         float i;
2328         if(m == "")
2329                 return "That's not how to use this command.";
2330         if(!autocvar_g_maplist_votable_suggestions)
2331                 return "Suggestions are not accepted on this server.";
2332         if(mapvote_initialized)
2333                 return "Can't suggest - voting is already in progress!";
2334         m = MapInfo_FixName(m);
2335         if(!m)
2336                 return "The map you suggested is not available on this server.";
2337         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2338                 if(Map_IsRecent(m))
2339                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2340
2341         if(!MapInfo_CheckMap(m))
2342                 return "The map you suggested does not support the current game mode.";
2343         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2344                 if(mapvote_suggestions[i] == m)
2345                         return "This map was already suggested.";
2346         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2347         {
2348                 i = floor(random() * mapvote_suggestion_ptr);
2349         }
2350         else
2351         {
2352                 i = mapvote_suggestion_ptr;
2353                 mapvote_suggestion_ptr += 1;
2354         }
2355         if(mapvote_suggestions[i] != "")
2356                 strunzone(mapvote_suggestions[i]);
2357         mapvote_suggestions[i] = strzone(m);
2358         if(autocvar_sv_eventlog)
2359                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2360         return strcat("Suggestion of ", m, " accepted.");
2361 }
2362
2363 void MapVote_AddVotable(string nextMap, float isSuggestion)
2364 {
2365         float j, i, o;
2366         string pakfile, mapfile;
2367
2368         if(nextMap == "")
2369                 return;
2370         for(j = 0; j < mapvote_count; ++j)
2371                 if(mapvote_maps[j] == nextMap)
2372                         return;
2373         if(strlen(nextMap) > mapvote_maxlen)
2374                 mapvote_maxlen = strlen(nextMap);
2375         mapvote_maps[mapvote_count] = strzone(nextMap);
2376         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2377
2378         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2379         {
2380                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2381                 pakfile = whichpack(strcat(mapfile, ".tga"));
2382                 if(pakfile == "")
2383                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2384                 if(pakfile == "")
2385                         pakfile = whichpack(strcat(mapfile, ".png"));
2386                 if(pakfile != "")
2387                         break;
2388         }
2389         if(i >= mapvote_screenshot_dirs_count)
2390                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2391         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2392                 pakfile = substring(pakfile, o, -1);
2393
2394         mapvote_maps_screenshot_dir[mapvote_count] = i;
2395         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2396
2397         mapvote_count += 1;
2398 }
2399
2400 void MapVote_Spawn();
2401 void MapVote_Init()
2402 {
2403         float i;
2404         float nmax, smax;
2405
2406         MapVote_ClearAllVotes();
2407
2408         mapvote_count = 0;
2409         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2410         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2411
2412         if(mapvote_abstain)
2413                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2414         else
2415                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2416         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2417
2418         // we need this for AddVotable, as that cycles through the screenshot dirs
2419         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2420         if(mapvote_screenshot_dirs_count == 0)
2421                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2422         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2423         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2424                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2425
2426         if(mapvote_suggestion_ptr)
2427                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2428                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2429
2430         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2431                 MapVote_AddVotable(GetNextMap(), FALSE);
2432
2433         if(mapvote_count == 0)
2434         {
2435                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2436                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2437                 if(autocvar_g_maplist_shuffle)
2438                         ShuffleMaplist();
2439                 localcmd("\nmenu_cmd sync\n");
2440                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2441                         MapVote_AddVotable(GetNextMap(), FALSE);
2442         }
2443
2444         mapvote_count_real = mapvote_count;
2445         if(mapvote_abstain)
2446                 MapVote_AddVotable("don't care", 0);
2447
2448         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2449
2450         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2451         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2452         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2453                 mapvote_keeptwotime = 0;
2454         mapvote_message = "Choose a map and press its key!";
2455
2456         MapVote_Spawn();
2457 }
2458
2459 void MapVote_SendPicture(float id)
2460 {
2461         msg_entity = self;
2462         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2463         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2464         WriteByte(MSG_ONE, id);
2465         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2466 }
2467
2468 float GameCommand_MapVote(string cmd)
2469 {
2470         if(!intermission_running)
2471                 return FALSE;
2472
2473         if(cmd == "mv_getpic")
2474         {
2475                 MapVote_SendPicture(stof(argv(1)));
2476                 return TRUE;
2477         }
2478
2479         return FALSE;
2480 }
2481
2482 float MapVote_GetMapMask()
2483 {
2484         float mask, i, power;
2485         mask = 0;
2486         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2487                 if(mapvote_maps[i] != "")
2488                         mask |= power;
2489         return mask;
2490 }
2491
2492 entity mapvote_ent;
2493 float MapVote_SendEntity(entity to, float sf)
2494 {
2495         float i;
2496
2497         if(sf & 1)
2498                 sf &~= 2; // if we send 1, we don't need to also send 2
2499
2500         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2501         WriteByte(MSG_ENTITY, sf);
2502
2503         if(sf & 1)
2504         {
2505                 // flag 1 == initialization
2506                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2507                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2508                 WriteString(MSG_ENTITY, "");
2509                 WriteByte(MSG_ENTITY, mapvote_count);
2510                 WriteByte(MSG_ENTITY, mapvote_abstain);
2511                 WriteByte(MSG_ENTITY, mapvote_detail);
2512                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2513                 if(mapvote_count <= 8)
2514                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2515                 else
2516                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2517                 for(i = 0; i < mapvote_count; ++i)
2518                         if(mapvote_maps[i] != "")
2519                         {
2520                                 if(mapvote_abstain && i == mapvote_count - 1)
2521                                 {
2522                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2523                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2524                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2525                                 }
2526                                 else
2527                                 {
2528                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2529                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2530                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2531                                 }
2532                         }
2533         }
2534
2535         if(sf & 2)
2536         {
2537                 // flag 2 == update of mask
2538                 if(mapvote_count <= 8)
2539                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2540                 else
2541                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2542         }
2543
2544         if(sf & 4)
2545         {
2546                 if(mapvote_detail)
2547                         for(i = 0; i < mapvote_count; ++i)
2548                                 if(mapvote_maps[i] != "")
2549                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2550
2551                 WriteByte(MSG_ENTITY, to.mapvote);
2552         }
2553
2554         return TRUE;
2555 }
2556
2557 void MapVote_Spawn()
2558 {
2559         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2560 }
2561
2562 void MapVote_TouchMask()
2563 {
2564         mapvote_ent.SendFlags |= 2;
2565 }
2566
2567 void MapVote_TouchVotes(entity voter)
2568 {
2569         mapvote_ent.SendFlags |= 4;
2570 }
2571
2572 float MapVote_Finished(float mappos)
2573 {
2574         string result;
2575         float i;
2576         float didntvote;
2577
2578         if(autocvar_sv_eventlog)
2579         {
2580                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2581                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2582                 didntvote = mapvote_voters;
2583                 for(i = 0; i < mapvote_count; ++i)
2584                         if(mapvote_maps[i] != "")
2585                         {
2586                                 didntvote -= mapvote_votes[i];
2587                                 if(i != mappos)
2588                                 {
2589                                         result = strcat(result, ":", mapvote_maps[i]);
2590                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2591                                 }
2592                         }
2593                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2594
2595                 GameLogEcho(result);
2596                 if(mapvote_maps_suggested[mappos])
2597                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2598         }
2599
2600         FOR_EACH_REALCLIENT(other)
2601                 FixClientCvars(other);
2602
2603         Map_Goto_SetStr(mapvote_maps[mappos]);
2604         Map_Goto();
2605         alreadychangedlevel = TRUE;
2606         return TRUE;
2607 }
2608 void MapVote_CheckRules_1()
2609 {
2610         float i;
2611
2612         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2613         {
2614                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2615                 mapvote_votes[i] = 0;
2616         }
2617
2618         mapvote_voters = 0;
2619         FOR_EACH_REALCLIENT(other)
2620         {
2621                 ++mapvote_voters;
2622                 if(other.mapvote)
2623                 {
2624                         i = other.mapvote - 1;
2625                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2626                         mapvote_votes[i] = mapvote_votes[i] + 1;
2627                 }
2628         }
2629 }
2630
2631 float MapVote_CheckRules_2()
2632 {
2633         float i;
2634         float firstPlace, secondPlace;
2635         float firstPlaceVotes, secondPlaceVotes;
2636         float mapvote_voters_real;
2637         string result;
2638
2639         if(mapvote_count_real == 1)
2640                 return MapVote_Finished(0);
2641
2642         mapvote_voters_real = mapvote_voters;
2643         if(mapvote_abstain)
2644                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2645
2646         RandomSelection_Init();
2647         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2648                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2649         firstPlace = RandomSelection_chosen_float;
2650         firstPlaceVotes = RandomSelection_best_priority;
2651         //dprint("First place: ", ftos(firstPlace), "\n");
2652         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2653
2654         RandomSelection_Init();
2655         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2656                 if(i != firstPlace)
2657                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2658         secondPlace = RandomSelection_chosen_float;
2659         secondPlaceVotes = RandomSelection_best_priority;
2660         //dprint("Second place: ", ftos(secondPlace), "\n");
2661         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2662
2663         if(firstPlace == -1)
2664                 error("No first place in map vote... WTF?");
2665
2666         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2667                 return MapVote_Finished(firstPlace);
2668
2669         if(mapvote_keeptwotime)
2670                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2671                 {
2672                         float didntvote;
2673                         MapVote_TouchMask();
2674                         mapvote_message = "Now decide between the TOP TWO!";
2675                         mapvote_keeptwotime = 0;
2676                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2677                         result = strcat(result, ":", ftos(firstPlaceVotes));
2678                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2679                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2680                         didntvote = mapvote_voters;
2681                         for(i = 0; i < mapvote_count; ++i)
2682                                 if(mapvote_maps[i] != "")
2683                                 {
2684                                         didntvote -= mapvote_votes[i];
2685                                         if(i != firstPlace)
2686                                                 if(i != secondPlace)
2687                                                 {
2688                                                         result = strcat(result, ":", mapvote_maps[i]);
2689                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2690                                                         if(i < mapvote_count_real)
2691                                                         {
2692                                                                 strunzone(mapvote_maps[i]);
2693                                                                 mapvote_maps[i] = "";
2694                                                                 strunzone(mapvote_maps_pakfile[i]);
2695                                                                 mapvote_maps_pakfile[i] = "";
2696                                                         }
2697                                                 }
2698                                 }
2699                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2700                         if(autocvar_sv_eventlog)
2701                                 GameLogEcho(result);
2702                 }
2703
2704         return FALSE;
2705 }
2706 void MapVote_Tick()
2707 {
2708         float keeptwo;
2709         float totalvotes;
2710
2711         keeptwo = mapvote_keeptwotime;
2712         MapVote_CheckRules_1(); // count
2713         if(MapVote_CheckRules_2()) // decide
2714                 return;
2715
2716         totalvotes = 0;
2717         FOR_EACH_REALCLIENT(other)
2718         {
2719                 // hide scoreboard again
2720                 if(other.health != 2342)
2721                 {
2722                         other.health = 2342;
2723                         other.impulse = 0;
2724                         if(clienttype(other) == CLIENTTYPE_REAL)
2725                         {
2726                                 msg_entity = other;
2727                                 WriteByte(MSG_ONE, SVC_FINALE);
2728                                 WriteString(MSG_ONE, "");
2729                         }
2730                 }
2731
2732                 // clear possibly invalid votes
2733                 if(mapvote_maps[other.mapvote - 1] == "")
2734                         other.mapvote = 0;
2735                 // use impulses as new vote
2736                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2737                         if(mapvote_maps[other.impulse - 1] != "")
2738                         {
2739                                 other.mapvote = other.impulse;
2740                                 MapVote_TouchVotes(other);
2741                         }
2742                 other.impulse = 0;
2743
2744                 if(other.mapvote)
2745                         ++totalvotes;
2746         }
2747
2748         MapVote_CheckRules_1(); // just count
2749 }
2750 void MapVote_Start()
2751 {
2752         if(mapvote_run)
2753                 return;
2754
2755         // wait for stats to be sent first
2756         if(!playerstats_waitforme)
2757                 return;
2758
2759         MapInfo_Enumerate();
2760         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2761                 mapvote_run = TRUE;
2762 }
2763 void MapVote_Think()
2764 {
2765         if(!mapvote_run)
2766                 return;
2767
2768         if(alreadychangedlevel)
2769                 return;
2770
2771         if(time < mapvote_nextthink)
2772                 return;
2773         //dprint("tick\n");
2774
2775         mapvote_nextthink = time + 0.5;
2776
2777         if(!mapvote_initialized)
2778         {
2779                 if(autocvar_rescan_pending == 1)
2780                 {
2781                         cvar_set("rescan_pending", "2");
2782                         localcmd("fs_rescan\nrescan_pending 3\n");
2783                         return;
2784                 }
2785                 else if(autocvar_rescan_pending == 2)
2786                 {
2787                         return;
2788                 }
2789                 else if(autocvar_rescan_pending == 3)
2790                 {
2791                         // now build missing mapinfo files
2792                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2793                                 return;
2794
2795                         // we're done, start the timer
2796                         cvar_set("rescan_pending", "0");
2797                 }
2798
2799                 mapvote_initialized = TRUE;
2800                 if(DoNextMapOverride())
2801                         return;
2802                 if(!autocvar_g_maplist_votable || player_count <= 0)
2803                 {
2804                         GotoNextMap();
2805                         return;
2806                 }
2807                 MapVote_Init();
2808         }
2809
2810         MapVote_Tick();
2811 };
2812
2813 string GotoMap(string m)
2814 {
2815         if(!MapInfo_CheckMap(m))
2816                 return "The map you chose is not available on this server.";
2817         cvar_set("nextmap", m);
2818         cvar_set("timelimit", "-1");
2819         if(mapvote_initialized || alreadychangedlevel)
2820         {
2821                 if(DoNextMapOverride())
2822                         return "Map switch initiated.";
2823                 else
2824                         return "Hm... no. For some reason I like THIS map more.";
2825         }
2826         else
2827                 return "Map switch will happen after scoreboard.";
2828 }
2829
2830
2831 void EndFrame()
2832 {
2833         float altime;
2834         FOR_EACH_REALCLIENT(self)
2835         {
2836                 if(self.classname == "spectator")
2837                 {
2838                         if(self.enemy.typehitsound)
2839                                 play2(self, "misc/typehit.wav");
2840                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2841                                 play2(self, "misc/hit.wav");
2842                 }
2843                 else
2844                 {
2845                         if(self.typehitsound)
2846                                 play2(self, "misc/typehit.wav");
2847                         else if(self.hitsound && self.cvar_cl_hitsound)
2848                                 play2(self, "misc/hit.wav");
2849                 }
2850         }
2851         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2852         // add 1 frametime because after this, engine SV_Physics
2853         // increases time by a frametime and then networks the frame
2854         // add another frametime because client shows everything with
2855         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2856         // needed!
2857         FOR_EACH_CLIENT(self)
2858         {
2859                 self.hitsound = FALSE;
2860                 self.typehitsound = FALSE;
2861                 antilag_record(self, altime);
2862         }
2863 }
2864
2865
2866 /*
2867  * RedirectionThink:
2868  * returns TRUE if redirecting
2869  */
2870 float redirection_timeout;
2871 float redirection_nextthink;
2872 float RedirectionThink()
2873 {
2874         float clients_found;
2875
2876         if(redirection_target == "")
2877                 return FALSE;
2878
2879         if(!redirection_timeout)
2880         {
2881                 cvar_set("sv_public", "-2");
2882                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2883                 if(redirection_target == "self")
2884                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2885                 else
2886                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2887         }
2888
2889         if(time < redirection_nextthink)
2890                 return TRUE;
2891
2892         redirection_nextthink = time + 1;
2893
2894         clients_found = 0;
2895         FOR_EACH_REALCLIENT(self)
2896         {
2897                 print("Redirecting: sending connect command to ", self.netname, "\n");
2898                 if(redirection_target == "self")
2899                         stuffcmd(self, "\ndisconnect; reconnect\n");
2900                 else
2901                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2902                 ++clients_found;
2903         }
2904
2905         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2906
2907         if(time > redirection_timeout || clients_found == 0)
2908                 localcmd("\nwait; wait; wait; quit\n");
2909
2910         return TRUE;
2911 }
2912
2913 void TargetMusic_RestoreGame();
2914 void RestoreGame()
2915 {
2916         // Loaded from a save game
2917         // some things then break, so let's work around them...
2918
2919         // Progs DB (capture records)
2920         ServerProgsDB = db_load("server.db");
2921
2922         // Mapinfo
2923         MapInfo_Shutdown();
2924         MapInfo_Enumerate();
2925         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2926         WeaponStats_Init();
2927
2928         TargetMusic_RestoreGame();
2929 }
2930
2931 void SV_Shutdown()
2932 {
2933         entity e;
2934
2935         if(gameover > 1) // shutting down already?
2936                 return;
2937
2938         gameover = 2; // 2 = server shutting down
2939
2940         if(world_initialized > 0)
2941         {
2942                 world_initialized = 0;
2943                 print("Saving persistent data...\n");
2944                 Ban_SaveBans();
2945
2946                 PlayerStats_EndMatch(0);
2947                 FOR_EACH_CLIENT(e)
2948                         PlayerStats_AddGlobalInfo(e);
2949                 PlayerStats_Shutdown();
2950
2951                 if(!cheatcount_total)
2952                 {
2953                         if(autocvar_sv_db_saveasdump)
2954                                 db_dump(ServerProgsDB, "server.db");
2955                         else
2956                                 db_save(ServerProgsDB, "server.db");
2957                 }
2958                 if(autocvar_developer)
2959                 {
2960                         if(autocvar_sv_db_saveasdump)
2961                                 db_dump(TemporaryDB, "server-temp.db");
2962                         else
2963                                 db_save(TemporaryDB, "server-temp.db");
2964                 }
2965                 CheatShutdown(); // must be after cheatcount check
2966                 db_close(ServerProgsDB);
2967                 db_close(TemporaryDB);
2968                 print("done!\n");
2969                 // tell the bot system the game is ending now
2970                 bot_endgame();
2971
2972                 WeaponStats_Shutdown();
2973                 MapInfo_Shutdown();
2974         }
2975         else if(world_initialized == 0)
2976         {
2977                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2978         }
2979 }