qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82
  83 string STR_PLAYER = "player";
  84 string STR_SPECTATOR = "spectator";
  85 string STR_OBSERVER = "observer";
  86
  87 #if 0
  88 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  89 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  90 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  91 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  92 #else
  93 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  94 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  95 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  96 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  97 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if(v.classname != STR_PLAYER)
  98 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  99 #endif
 100
 101 #define CENTER_OR_VIEWOFS(ent) (ent.origin + ((ent.classname == STR_PLAYER) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 102
 103 // copies a string to a tempstring (so one can strunzone it)
 104 string strcat1(string s) = #115; // FRIK_FILE
 105
 106 float logfile_open;
 107 float logfile;
 108
 109 void bcenterprint(string s)
 110 {
 111     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 112     entity head;
 113     FOR_EACH_PLAYER(head)
 114     if (clienttype(head) == CLIENTTYPE_REAL)
 115         centerprint(head, s);
 116 }
 117
 118 void GameLogEcho(string s)
 119 {
 120     string fn;
 121     float matches;
 122
 123     if (autocvar_sv_eventlog_files)
 124     {
 125         if (!logfile_open)
 126         {
 127             logfile_open = TRUE;
 128             matches = autocvar_sv_eventlog_files_counter + 1;
 129             cvar_set("sv_eventlog_files_counter", ftos(matches));
 130             fn = ftos(matches);
 131             if (strlen(fn) < 8)
 132                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 133             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 134             logfile = fopen(fn, FILE_APPEND);
 135             fputs(logfile, ":logversion:3\n");
 136         }
 137         if (logfile >= 0)
 138         {
 139             if (autocvar_sv_eventlog_files_timestamps)
 140                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 141             else
 142                 fputs(logfile, strcat(s, "\n"));
 143         }
 144     }
 145     if (autocvar_sv_eventlog_console)
 146     {
 147         print(s, "\n");
 148     }
 149 }
 150
 151 void GameLogInit()
 152 {
 153     logfile_open = 0;
 154     // will be opened later
 155 }
 156
 157 void GameLogClose()
 158 {
 159     if (logfile_open && logfile >= 0)
 160     {
 161         fclose(logfile);
 162         logfile = -1;
 163     }
 164 }
 165
 166 float spawnpoint_nag;
 167 void relocate_spawnpoint()
 168 {
 169     // nudge off the floor
 170     setorigin(self, self.origin + '0 0 1');
 171
 172     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 173     if (trace_startsolid)
 174     {
 175         vector o;
 176         o = self.origin;
 177         self.mins = PL_MIN;
 178         self.maxs = PL_MAX;
 179         if (!move_out_of_solid(self))
 180             objerror("could not get out of solid at all!");
 181         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 182         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 183         print(" ", ftos(self.origin_y - o_y));
 184         print(" ", ftos(self.origin_z - o_z), "'\n");
 185         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 186         {
 187             if (!spawnpoint_nag)
 188                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 189             spawnpoint_nag = 1;
 190         }
 191         else
 192         {
 193             setorigin(self, o);
 194             self.mins = self.maxs = '0 0 0';
 195             objerror("player spawn point in solid, mapper sucks!\n");
 196             return;
 197         }
 198     }
 199
 200     self.use = spawnpoint_use;
 201     self.team_saved = self.team;
 202     if (!self.cnt)
 203         self.cnt = 1;
 204
 205     if (have_team_spawns != 0)
 206         if (self.team)
 207             have_team_spawns = 1;
 208     have_team_spawns_forteam[self.team] = 1;
 209
 210     if (autocvar_r_showbboxes)
 211     {
 212         // show where spawnpoints point at too
 213         makevectors(self.angles);
 214         entity e;
 215         e = spawn();
 216         e.classname = "info_player_foo";
 217         setorigin(e, self.origin + v_forward * 24);
 218         setsize(e, '-8 -8 -8', '8 8 8');
 219         e.solid = SOLID_TRIGGER;
 220     }
 221 }
 222
 223 #define strstr strstrofs
 224 /*
 225 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 226 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 227 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 228 // BE CONSTANT OR strzoneD!
 229 float strstr(string haystack, string needle, float offset)
 230 {
 231         float len, endpos;
 232         string found;
 233         len = strlen(needle);
 234         endpos = strlen(haystack) - len;
 235         while(offset <= endpos)
 236         {
 237                 found = substring(haystack, offset, len);
 238                 if(found == needle)
 239                         return offset;
 240                 offset = offset + 1;
 241         }
 242         return -1;
 243 }
 244 */
 245
 246 float NUM_NEAREST_ENTITIES = 4;
 247 entity nearest_entity[NUM_NEAREST_ENTITIES];
 248 float nearest_length[NUM_NEAREST_ENTITIES];
 249 entity findnearest(vector point, .string field, string value, vector axismod)
 250 {
 251     entity localhead;
 252     float i;
 253     float j;
 254     float len;
 255     vector dist;
 256
 257     float num_nearest;
 258     num_nearest = 0;
 259
 260     localhead = find(world, field, value);
 261     while (localhead)
 262     {
 263         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 264             dist = localhead.oldorigin;
 265         else
 266             dist = localhead.origin;
 267         dist = dist - point;
 268         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 269         len = vlen(dist);
 270
 271         for (i = 0; i < num_nearest; ++i)
 272         {
 273             if (len < nearest_length[i])
 274                 break;
 275         }
 276
 277         // now i tells us where to insert at
 278         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 279         if (i < NUM_NEAREST_ENTITIES)
 280         {
 281             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 282             {
 283                 nearest_length[j + 1] = nearest_length[j];
 284                 nearest_entity[j + 1] = nearest_entity[j];
 285             }
 286             nearest_length[i] = len;
 287             nearest_entity[i] = localhead;
 288             if (num_nearest < NUM_NEAREST_ENTITIES)
 289                 num_nearest = num_nearest + 1;
 290         }
 291
 292         localhead = find(localhead, field, value);
 293     }
 294
 295     // now use the first one from our list that we can see
 296     for (i = 0; i < num_nearest; ++i)
 297     {
 298         traceline(point, nearest_entity[i].origin, TRUE, world);
 299         if (trace_fraction == 1)
 300         {
 301             if (i != 0)
 302             {
 303                 dprint("Nearest point (");
 304                 dprint(nearest_entity[0].netname);
 305                 dprint(") is not visible, using a visible one.\n");
 306             }
 307             return nearest_entity[i];
 308         }
 309     }
 310
 311     if (num_nearest == 0)
 312         return world;
 313
 314     dprint("Not seeing any location point, using nearest as fallback.\n");
 315     /* DEBUGGING CODE:
 316     dprint("Candidates were: ");
 317     for(j = 0; j < num_nearest; ++j)
 318     {
 319         if(j != 0)
 320                 dprint(", ");
 321         dprint(nearest_entity[j].netname);
 322     }
 323     dprint("\n");
 324     */
 325
 326     return nearest_entity[0];
 327 }
 328
 329 void spawnfunc_target_location()
 330 {
 331     self.classname = "target_location";
 332     // location name in netname
 333     // eventually support: count, teamgame selectors, line of sight?
 334 }
 335
 336 void spawnfunc_info_location()
 337 {
 338     self.classname = "target_location";
 339     self.message = self.netname;
 340 }
 341
 342 string NearestLocation(vector p)
 343 {
 344     entity loc;
 345     string ret;
 346     ret = "somewhere";
 347     loc = findnearest(p, classname, "target_location", '1 1 1');
 348     if (loc)
 349     {
 350         ret = loc.message;
 351     }
 352     else
 353     {
 354         loc = findnearest(p, target, "###item###", '1 1 4');
 355         if (loc)
 356             ret = loc.netname;
 357     }
 358     return ret;
 359 }
 360
 361 string formatmessage(string msg)
 362 {
 363         float p, p1, p2;
 364         float n;
 365         vector cursor;
 366         entity cursor_ent;
 367         string escape;
 368         string replacement;
 369         p = 0;
 370         n = 7;
 371
 372         WarpZone_crosshair_trace(self);
 373         cursor = trace_endpos;
 374         cursor_ent = trace_ent;
 375
 376         while (1) {
 377                 if (n < 1)
 378                         break; // too many replacements
 379
 380                 n = n - 1;
 381                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 382                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 383
 384                 if (p1 < 0)
 385                         p1 = p2;
 386
 387                 if (p2 < 0)
 388                         p2 = p1;
 389
 390                 p = min(p1, p2);
 391
 392                 if (p < 0)
 393                         break;
 394
 395                 replacement = substring(msg, p, 2);
 396                 escape = substring(msg, p + 1, 1);
 397
 398                 if (escape == "%")
 399                         replacement = "%";
 400                 else if (escape == "\\")
 401                         replacement = "\\";
 402                 else if (escape == "n")
 403                         replacement = "\n";
 404                 else if (escape == "a")
 405                         replacement = ftos(floor(self.armorvalue));
 406                 else if (escape == "h")
 407                         replacement = ftos(floor(self.health));
 408                 else if (escape == "l")
 409                         replacement = NearestLocation(self.origin);
 410                 else if (escape == "y")
 411                         replacement = NearestLocation(cursor);
 412                 else if (escape == "d")
 413                         replacement = NearestLocation(self.death_origin);
 414                 else if (escape == "w") {
 415                         float wep;
 416                         wep = self.weapon;
 417                         if (!wep)
 418                                 wep = self.switchweapon;
 419                         if (!wep)
 420                                 wep = self.cnt;
 421                         replacement = W_Name(wep);
 422                 } else if (escape == "W") {
 423                         if (self.items & IT_SHELLS) replacement = "shells";
 424                         else if (self.items & IT_NAILS) replacement = "bullets";
 425                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 426                         else if (self.items & IT_CELLS) replacement = "cells";
 427                         else replacement = "batteries"; // ;)
 428                 } else if (escape == "x") {
 429                         replacement = cursor_ent.netname;
 430                         if (replacement == "" || !cursor_ent)
 431                                 replacement = "nothing";
 432                 } else if (escape == "s")
 433                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 434                 else if (escape == "S")
 435                         replacement = ftos(vlen(self.velocity));
 436
 437                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 438                 p = p + strlen(replacement);
 439         }
 440         return msg;
 441 }
 442
 443 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 444         return (value == 0) ? FALSE : TRUE;
 445 }
 446
 447 /*
 448 =============
 449 GetCvars
 450 =============
 451 Called with:
 452   0:  sends the request
 453   >0: receives a cvar from name=argv(f) value=argv(f+1)
 454 */
 455 void GetCvars_handleString(string thisname, float f, .string field, string name)
 456 {
 457         if (f < 0)
 458         {
 459                 if (self.field)
 460                         strunzone(self.field);
 461                 self.field = string_null;
 462         }
 463         else if (f > 0)
 464         {
 465                 if (thisname == name)
 466                 {
 467                         if (self.field)
 468                                 strunzone(self.field);
 469                         self.field = strzone(argv(f + 1));
 470                 }
 471         }
 472         else
 473                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 474 }
 475 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 476 {
 477         GetCvars_handleString(thisname, f, field, name);
 478         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 479                 if (thisname == name)
 480                 {
 481                         string s;
 482                         s = func(strcat1(self.field));
 483                         if (s != self.field)
 484                         {
 485                                 strunzone(self.field);
 486                                 self.field = strzone(s);
 487                         }
 488                 }
 489 }
 490 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 491 {
 492         if (f < 0)
 493         {
 494         }
 495         else if (f > 0)
 496         {
 497                 if (thisname == name)
 498                         self.field = stof(argv(f + 1));
 499         }
 500         else
 501                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 504 {
 505         if (f < 0)
 506         {
 507         }
 508         else if (f > 0)
 509         {
 510                 if (thisname == name)
 511                 {
 512                         if(!self.field)
 513                         {
 514                                 self.field = stof(argv(f + 1));
 515                                 if(!self.field)
 516                                         self.field = -1;
 517                         }
 518                 }
 519         }
 520         else
 521         {
 522                 if(!self.field)
 523                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 524         }
 525 }
 526 float w_getbestweapon(entity e);
 527 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 528 {
 529         string o;
 530         o = W_FixWeaponOrder_ForceComplete(wo);
 531         if(self.weaponorder_byimpulse)
 532         {
 533                 strunzone(self.weaponorder_byimpulse);
 534                 self.weaponorder_byimpulse = string_null;
 535         }
 536         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 537         return o;
 538 }
 539 void GetCvars(float f)
 540 {
 541         string s = string_null;
 542
 543         if (f > 0)
 544                 s = strcat1(argv(f));
 545
 546         get_cvars_f = f;
 547         get_cvars_s = s;
 548         MUTATOR_CALLHOOK(GetCvars);
 549         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 550         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 551         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 552         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 553         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 566         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 567         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 568         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 569         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 570         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 571         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 572
 573         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 574         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 575
 576 #ifdef ALLOW_FORCEMODELS
 577         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 578         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 579 #endif
 580         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 581         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 582         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 583         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 584         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 585
 586         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 587         if (f > 0)
 588         {
 589                 if (s == "cl_weaponpriority")
 590                         self.switchweapon = w_getbestweapon(self);
 591                 if (s == "cl_allow_uidtracking")
 592                         PlayerStats_AddPlayer(self);
 593         }
 594 }
 595
 596 // decolorizes and team colors the player name when needed
 597 string playername(entity p)
 598 {
 599     string t;
 600     if (teamplay && !intermission_running && p.classname == "player")
 601     {
 602         t = Team_ColorCode(p.team);
 603         return strcat(t, strdecolorize(p.netname));
 604     }
 605     else
 606         return p.netname;
 607 }
 608
 609 vector randompos(vector m1, vector m2)
 610 {
 611     vector v;
 612     m2 = m2 - m1;
 613     v_x = m2_x * random() + m1_x;
 614     v_y = m2_y * random() + m1_y;
 615     v_z = m2_z * random() + m1_z;
 616     return  v;
 617 }
 618
 619 //#NO AUTOCVARS START
 620
 621 float g_pickup_shells;
 622 float g_pickup_shells_max;
 623 float g_pickup_nails;
 624 float g_pickup_nails_max;
 625 float g_pickup_rockets;
 626 float g_pickup_rockets_max;
 627 float g_pickup_cells;
 628 float g_pickup_cells_max;
 629 float g_pickup_fuel;
 630 float g_pickup_fuel_jetpack;
 631 float g_pickup_fuel_max;
 632 float g_pickup_armorsmall;
 633 float g_pickup_armorsmall_max;
 634 float g_pickup_armorsmall_anyway;
 635 float g_pickup_armormedium;
 636 float g_pickup_armormedium_max;
 637 float g_pickup_armormedium_anyway;
 638 float g_pickup_armorbig;
 639 float g_pickup_armorbig_max;
 640 float g_pickup_armorbig_anyway;
 641 float g_pickup_armorlarge;
 642 float g_pickup_armorlarge_max;
 643 float g_pickup_armorlarge_anyway;
 644 float g_pickup_healthsmall;
 645 float g_pickup_healthsmall_max;
 646 float g_pickup_healthsmall_anyway;
 647 float g_pickup_healthmedium;
 648 float g_pickup_healthmedium_max;
 649 float g_pickup_healthmedium_anyway;
 650 float g_pickup_healthlarge;
 651 float g_pickup_healthlarge_max;
 652 float g_pickup_healthlarge_anyway;
 653 float g_pickup_healthmega;
 654 float g_pickup_healthmega_max;
 655 float g_pickup_healthmega_anyway;
 656 float g_pickup_ammo_anyway;
 657 float g_pickup_weapons_anyway;
 658 float g_weaponarena;
 659 WEPSET_DECLARE_A(g_weaponarena_weapons);
 660 float g_weaponarena_random;
 661 float g_weaponarena_random_with_laser;
 662 string g_weaponarena_list;
 663 float g_weaponspeedfactor;
 664 float g_weaponratefactor;
 665 float g_weapondamagefactor;
 666 float g_weaponforcefactor;
 667 float g_weaponspreadfactor;
 668
 669 WEPSET_DECLARE_A(start_weapons);
 670 WEPSET_DECLARE_A(start_weapons_default);
 671 WEPSET_DECLARE_A(start_weapons_defaultmask);
 672 float start_items;
 673 float start_ammo_shells;
 674 float start_ammo_nails;
 675 float start_ammo_rockets;
 676 float start_ammo_cells;
 677 float start_ammo_fuel;
 678 float start_health;
 679 float start_armorvalue;
 680 WEPSET_DECLARE_A(warmup_start_weapons);
 681 WEPSET_DECLARE_A(warmup_start_weapons_default);
 682 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 683 float warmup_start_ammo_shells;
 684 float warmup_start_ammo_nails;
 685 float warmup_start_ammo_rockets;
 686 float warmup_start_ammo_cells;
 687 float warmup_start_ammo_fuel;
 688 float warmup_start_health;
 689 float warmup_start_armorvalue;
 690 float g_weapon_stay;
 691
 692 entity get_weaponinfo(float w);
 693
 694 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 695 {
 696         var float i = weaponinfo.weapon;
 697         var float d = 0;
 698
 699         if (!i)
 700                 return 0;
 701
 702         if (g_lms || g_ca || allguns)
 703         {
 704                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 705                         d = TRUE;
 706                 else
 707                         d = FALSE;
 708         }
 709         else if (g_cts)
 710                 d = (i == WEP_SHOTGUN);
 711         else if (g_nexball)
 712                 d = 0; // weapon is set a few lines later
 713         else
 714                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 715
 716         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 717                 d |= (i == WEP_HOOK);
 718         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 719                 d = 0;
 720
 721         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 722
 723         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 724
 725         // bit order in t:
 726         // 1: want or not
 727         // 2: is default?
 728         // 4: is set by default?
 729         if(t < 0)
 730                 t = 4 | (3 * d);
 731         else
 732                 t |= (2 * d);
 733
 734         return t;
 735 }
 736
 737 void readplayerstartcvars()
 738 {
 739         entity e;
 740         float i, j, t;
 741         string s;
 742
 743         // initialize starting values for players
 744         WEPSET_CLEAR_A(start_weapons);
 745         WEPSET_CLEAR_A(start_weapons_default);
 746         WEPSET_CLEAR_A(start_weapons_defaultmask);
 747         start_items = 0;
 748         start_ammo_shells = 0;
 749         start_ammo_nails = 0;
 750         start_ammo_rockets = 0;
 751         start_ammo_cells = 0;
 752         start_health = cvar("g_balance_health_start");
 753         start_armorvalue = cvar("g_balance_armor_start");
 754
 755         g_weaponarena = 0;
 756         WEPSET_CLEAR_A(g_weaponarena_weapons);
 757
 758         s = cvar_string("g_weaponarena");
 759         if (s == "0" || s == "")
 760         {
 761                 if(g_lms || g_ca)
 762                         s = "most";
 763         }
 764
 765         if (s == "0" || s == "")
 766         {
 767                 // no arena
 768         }
 769         else if (s == "off")
 770         {
 771                 // forcibly turn off weaponarena
 772         }
 773         else if (s == "all")
 774         {
 775                 g_weaponarena = 1;
 776                 g_weaponarena_list = "All Weapons";
 777                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 778                 {
 779                         e = get_weaponinfo(j);
 780                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 781                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 782                 }
 783         }
 784         else if (s == "most")
 785         {
 786                 g_weaponarena = 1;
 787                 g_weaponarena_list = "Most Weapons";
 788                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 789                 {
 790                         e = get_weaponinfo(j);
 791                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 792                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 793                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 794                 }
 795         }
 796         else if (s == "none")
 797         {
 798                 g_weaponarena = 1;
 799                 g_weaponarena_list = "No Weapons";
 800         }
 801         else
 802         {
 803                 g_weaponarena = 1;
 804                 t = tokenize_console(s);
 805                 g_weaponarena_list = "";
 806                 for (i = 0; i < t; ++i)
 807                 {
 808                         s = argv(i);
 809                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 810                         {
 811                                 e = get_weaponinfo(j);
 812                                 if (e.netname == s)
 813                                 {
 814                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 815                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 816                                         break;
 817                                 }
 818                         }
 819                         if (j > WEP_LAST)
 820                         {
 821                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 822                         }
 823                 }
 824                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 825         }
 826
 827         if(g_weaponarena)
 828                 g_weaponarena_random = cvar("g_weaponarena_random");
 829         else
 830                 g_weaponarena_random = 0;
 831         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 832
 833         if (g_weaponarena)
 834         {
 835                 g_minstagib = 0; // incompatible
 836                 g_pinata = 0; // incompatible
 837                 g_weapon_stay = 0; // incompatible
 838                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 839                 if(!(g_lms || g_ca))
 840                         start_items |= IT_UNLIMITED_AMMO;
 841         }
 842         else if (g_minstagib)
 843         {
 844                 g_pinata = 0; // incompatible
 845                 g_weapon_stay = 0; // incompatible
 846                 g_bloodloss = 0; // incompatible
 847                 start_health = 100;
 848                 start_armorvalue = 0;
 849                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 850                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 851                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 852
 853                 if (g_minstagib_invis_alpha <= 0)
 854                         g_minstagib_invis_alpha = -1;
 855         }
 856         else
 857         {
 858                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 859                 {
 860                         e = get_weaponinfo(i);
 861                         float w = want_weapon("g_start_weapon_", e, FALSE);
 862                         if(w & 1)
 863                                 WEPSET_OR_AW(start_weapons, i);
 864                         if(w & 2)
 865                                 WEPSET_OR_AW(start_weapons_default, i);
 866                         if(w & 4)
 867                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 868                 }
 869         }
 870
 871         if(!cvar("g_use_ammunition"))
 872                 start_items |= IT_UNLIMITED_AMMO;
 873
 874         if(cvar("g_nexball"))
 875                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 876
 877         if(g_minstagib)
 878         {
 879                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 880                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 881         }
 882         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 883         {
 884                 start_ammo_rockets = 999;
 885                 start_ammo_shells = 999;
 886                 start_ammo_cells = 999;
 887                 start_ammo_nails = 999;
 888                 start_ammo_fuel = 999;
 889         }
 890         else
 891         {
 892                 if(g_lms || g_ca)
 893                 {
 894                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 895                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 896                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 897                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 898                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 899                 }
 900                 else
 901                 {
 902                         start_ammo_shells = cvar("g_start_ammo_shells");
 903                         start_ammo_nails = cvar("g_start_ammo_nails");
 904                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 905                         start_ammo_cells = cvar("g_start_ammo_cells");
 906                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 907                 }
 908         }
 909
 910         if (g_lms || g_ca)
 911         {
 912                 start_health = cvar("g_lms_start_health");
 913                 start_armorvalue = cvar("g_lms_start_armor");
 914         }
 915
 916         if (inWarmupStage)
 917         {
 918                 warmup_start_ammo_shells = start_ammo_shells;
 919                 warmup_start_ammo_nails = start_ammo_nails;
 920                 warmup_start_ammo_rockets = start_ammo_rockets;
 921                 warmup_start_ammo_cells = start_ammo_cells;
 922                 warmup_start_ammo_fuel = start_ammo_fuel;
 923                 warmup_start_health = start_health;
 924                 warmup_start_armorvalue = start_armorvalue;
 925                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 926                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 927                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 928
 929                 if (!g_weaponarena && !g_minstagib && !g_ca)
 930                 {
 931                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 932                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 933                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 934                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 935                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 936                         warmup_start_health = cvar("g_warmup_start_health");
 937                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 938                         WEPSET_CLEAR_A(warmup_start_weapons);
 939                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 940                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 941                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 942                         {
 943                                 e = get_weaponinfo(i);
 944                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 945                                 if(w & 1)
 946                                         WEPSET_OR_AW(warmup_start_weapons, i);
 947                                 if(w & 2)
 948                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 949                                 if(w & 4)
 950                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 951                         }
 952                 }
 953         }
 954
 955         if (g_jetpack)
 956                 start_items |= IT_JETPACK;
 957
 958         MUTATOR_CALLHOOK(SetStartItems);
 959
 960         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 961         {
 962                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 963                 start_items |= IT_FUEL_REGEN;
 964                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 965                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 966         }
 967
 968         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 969         {
 970                 e = get_weaponinfo(i);
 971                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 972                         weapon_action(i, WR_PRECACHE);
 973         }
 974
 975         start_ammo_shells = max(0, start_ammo_shells);
 976         start_ammo_nails = max(0, start_ammo_nails);
 977         start_ammo_cells = max(0, start_ammo_cells);
 978         start_ammo_rockets = max(0, start_ammo_rockets);
 979         start_ammo_fuel = max(0, start_ammo_fuel);
 980
 981         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 982         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 983         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 984         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 985         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 986 }
 987
 988 float g_bugrigs;
 989 float g_bugrigs_planar_movement;
 990 float g_bugrigs_planar_movement_car_jumping;
 991 float g_bugrigs_reverse_spinning;
 992 float g_bugrigs_reverse_speeding;
 993 float g_bugrigs_reverse_stopping;
 994 float g_bugrigs_air_steering;
 995 float g_bugrigs_angle_smoothing;
 996 float g_bugrigs_friction_floor;
 997 float g_bugrigs_friction_brake;
 998 float g_bugrigs_friction_air;
 999 float g_bugrigs_accel;
1000 float g_bugrigs_speed_ref;
1001 float g_bugrigs_speed_pow;
1002 float g_bugrigs_steer;
1003
1004 float g_touchexplode;
1005 float g_touchexplode_radius;
1006 float g_touchexplode_damage;
1007 float g_touchexplode_edgedamage;
1008 float g_touchexplode_force;
1009
1010 float sv_autotaunt;
1011 float sv_taunt;
1012
1013 string GetGametype(); // g_world.qc
1014 void readlevelcvars(void)
1015 {
1016         g_minstagib = cvar("g_minstagib");
1017
1018         // load ALL the mutators
1019         if(cvar("g_dodging"))
1020                 MUTATOR_ADD(mutator_dodging);
1021         if(cvar("g_spawn_near_teammate"))
1022                 MUTATOR_ADD(mutator_spawn_near_teammate);
1023         if(cvar("g_physical_items"))
1024                 MUTATOR_ADD(mutator_physical_items);
1025         if(!g_minstagib)
1026         {
1027                 if(cvar("g_invincible_projectiles"))
1028                         MUTATOR_ADD(mutator_invincibleprojectiles);
1029                 if(cvar("g_new_toys"))
1030                         MUTATOR_ADD(mutator_new_toys);
1031                 if(cvar("g_nix"))
1032                         MUTATOR_ADD(mutator_nix);
1033                 if(cvar("g_rocket_flying"))
1034                         MUTATOR_ADD(mutator_rocketflying);
1035                 if(cvar("g_vampire"))
1036                         MUTATOR_ADD(mutator_vampire);
1037                 if(cvar("g_superspectate"))
1038                         MUTATOR_ADD(mutator_superspec);
1039         }
1040
1041         // is this a mutator? is this a mode?
1042         if(cvar("g_sandbox"))
1043                 MUTATOR_ADD(sandbox);
1044
1045         if(cvar("sv_allow_fullbright"))
1046                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1047
1048     g_bugrigs = cvar("g_bugrigs");
1049     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1050     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1051     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1052     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1053     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1054     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1055     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1056     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1057     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1058     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1059     g_bugrigs_accel = cvar("g_bugrigs_accel");
1060     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1061     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1062     g_bugrigs_steer = cvar("g_bugrigs_steer");
1063
1064     g_touchexplode = cvar("g_touchexplode");
1065     g_touchexplode_radius = cvar("g_touchexplode_radius");
1066     g_touchexplode_damage = cvar("g_touchexplode_damage");
1067     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1068     g_touchexplode_force = cvar("g_touchexplode_force");
1069
1070 #ifdef ALLOW_FORCEMODELS
1071         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1072 #endif
1073
1074         sv_clones = cvar("sv_clones");
1075         sv_foginterval = cvar("sv_foginterval");
1076         g_cloaked = cvar("g_cloaked");
1077     if(g_cts)
1078         g_cloaked = 1; // always enable cloak in CTS
1079         g_jump_grunt = cvar("g_jump_grunt");
1080         g_footsteps = cvar("g_footsteps");
1081         g_grappling_hook = cvar("g_grappling_hook");
1082         g_jetpack = cvar("g_jetpack");
1083         g_midair = cvar("g_midair");
1084         g_norecoil = cvar("g_norecoil");
1085         g_bloodloss = cvar("g_bloodloss");
1086         sv_maxidle = cvar("sv_maxidle");
1087         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1088         sv_autotaunt = cvar("sv_autotaunt");
1089         sv_taunt = cvar("sv_taunt");
1090
1091         inWarmupStage = cvar("g_warmup");
1092         g_warmup_limit = cvar("g_warmup_limit");
1093         g_warmup_allguns = cvar("g_warmup_allguns");
1094         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1095
1096         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1097                 inWarmupStage = 0; // these modes cannot work together, sorry
1098
1099         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1100         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1101         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1102         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1103         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1104         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1105         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1106         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1107         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1108         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1109         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1110         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1111         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1112         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1113
1114         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1115         g_weaponratefactor = cvar("g_weaponratefactor");
1116         g_weapondamagefactor = cvar("g_weapondamagefactor");
1117         g_weaponforcefactor = cvar("g_weaponforcefactor");
1118         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1119
1120         g_pickup_shells = cvar("g_pickup_shells");
1121         g_pickup_shells_max = cvar("g_pickup_shells_max");
1122         g_pickup_nails = cvar("g_pickup_nails");
1123         g_pickup_nails_max = cvar("g_pickup_nails_max");
1124         g_pickup_rockets = cvar("g_pickup_rockets");
1125         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1126         g_pickup_cells = cvar("g_pickup_cells");
1127         g_pickup_cells_max = cvar("g_pickup_cells_max");
1128         g_pickup_fuel = cvar("g_pickup_fuel");
1129         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1130         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1131         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1132         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1133         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1134         g_pickup_armormedium = cvar("g_pickup_armormedium");
1135         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1136         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1137         g_pickup_armorbig = cvar("g_pickup_armorbig");
1138         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1139         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1140         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1141         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1142         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1143         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1144         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1145         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1146         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1147         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1148         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1149         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1150         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1151         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1152         g_pickup_healthmega = cvar("g_pickup_healthmega");
1153         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1154         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1155
1156         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1157         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1158
1159         g_pinata = cvar("g_pinata");
1160
1161     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1162     if(!g_weapon_stay)
1163         g_weapon_stay = cvar("g_weapon_stay");
1164
1165         if not(inWarmupStage && !g_ca)
1166                 game_starttime = cvar("g_start_delay");
1167
1168         readplayerstartcvars();
1169 }
1170
1171 //#NO AUTOCVARS END
1172
1173 // Sound functions
1174 string precache_sound (string s) = #19;
1175 float precache_sound_index (string s) = #19;
1176
1177 #define SND_VOLUME      1
1178 #define SND_ATTENUATION 2
1179 #define SND_LARGEENTITY 8
1180 #define SND_LARGESOUND  16
1181
1182 float sound_allowed(float dest, entity e)
1183 {
1184     // sounds from world may always pass
1185     for (;;)
1186     {
1187         if (e.classname == "body")
1188             e = e.enemy;
1189         else if (e.realowner && e.realowner != e)
1190             e = e.realowner;
1191         else if (e.owner && e.owner != e)
1192             e = e.owner;
1193         else
1194             break;
1195     }
1196     // sounds to self may always pass
1197     if (dest == MSG_ONE)
1198         if (e == msg_entity)
1199             return TRUE;
1200     // sounds by players can be removed
1201     if (autocvar_bot_sound_monopoly)
1202         if (clienttype(e) == CLIENTTYPE_REAL)
1203             return FALSE;
1204     // anything else may pass
1205     return TRUE;
1206 }
1207
1208 #ifdef COMPAT_XON010_CHANNELS
1209 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1210 void sound(entity e, float chan, string samp, float vol, float atten)
1211 {
1212     if (!sound_allowed(MSG_BROADCAST, e))
1213         return;
1214     builtin_sound(e, chan, samp, vol, atten);
1215 }
1216 #else
1217 #undef sound
1218 void sound(entity e, float chan, string samp, float vol, float atten)
1219 {
1220     if (!sound_allowed(MSG_BROADCAST, e))
1221         return;
1222     sound7(e, chan, samp, vol, atten, 0, 0);
1223 }
1224 #endif
1225
1226 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1227 {
1228     float entno, idx;
1229
1230     if (!sound_allowed(dest, e))
1231         return;
1232
1233     entno = num_for_edict(e);
1234     idx = precache_sound_index(samp);
1235
1236     float sflags;
1237     sflags = 0;
1238
1239     atten = floor(atten * 64);
1240     vol = floor(vol * 255);
1241
1242     if (vol != 255)
1243         sflags |= SND_VOLUME;
1244     if (atten != 64)
1245         sflags |= SND_ATTENUATION;
1246     if (entno >= 8192 || chan < 0 || chan > 7)
1247         sflags |= SND_LARGEENTITY;
1248     if (idx >= 256)
1249         sflags |= SND_LARGESOUND;
1250
1251     WriteByte(dest, SVC_SOUND);
1252     WriteByte(dest, sflags);
1253     if (sflags & SND_VOLUME)
1254         WriteByte(dest, vol);
1255     if (sflags & SND_ATTENUATION)
1256         WriteByte(dest, atten);
1257     if (sflags & SND_LARGEENTITY)
1258     {
1259         WriteShort(dest, entno);
1260         WriteByte(dest, chan);
1261     }
1262     else
1263     {
1264         WriteShort(dest, entno * 8 + chan);
1265     }
1266     if (sflags & SND_LARGESOUND)
1267         WriteShort(dest, idx);
1268     else
1269         WriteByte(dest, idx);
1270
1271     WriteCoord(dest, o_x);
1272     WriteCoord(dest, o_y);
1273     WriteCoord(dest, o_z);
1274 }
1275 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1276 {
1277     vector o;
1278
1279     if (!sound_allowed(dest, e))
1280         return;
1281
1282     o = e.origin + 0.5 * (e.mins + e.maxs);
1283     soundtoat(dest, e, o, chan, samp, vol, atten);
1284 }
1285 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1286 {
1287     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1288 }
1289 void stopsoundto(float dest, entity e, float chan)
1290 {
1291     float entno;
1292
1293     if (!sound_allowed(dest, e))
1294         return;
1295
1296     entno = num_for_edict(e);
1297
1298     if (entno >= 8192 || chan < 0 || chan > 7)
1299     {
1300         float idx, sflags;
1301         idx = precache_sound_index("misc/null.wav");
1302         sflags = SND_LARGEENTITY;
1303         if (idx >= 256)
1304             sflags |= SND_LARGESOUND;
1305         WriteByte(dest, SVC_SOUND);
1306         WriteByte(dest, sflags);
1307         WriteShort(dest, entno);
1308         WriteByte(dest, chan);
1309         if (sflags & SND_LARGESOUND)
1310             WriteShort(dest, idx);
1311         else
1312             WriteByte(dest, idx);
1313         WriteCoord(dest, e.origin_x);
1314         WriteCoord(dest, e.origin_y);
1315         WriteCoord(dest, e.origin_z);
1316     }
1317     else
1318     {
1319         WriteByte(dest, SVC_STOPSOUND);
1320         WriteShort(dest, entno * 8 + chan);
1321     }
1322 }
1323 void stopsound(entity e, float chan)
1324 {
1325     if (!sound_allowed(MSG_BROADCAST, e))
1326         return;
1327
1328     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1329     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1330 }
1331
1332 void play2(entity e, string filename)
1333 {
1334     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1335     msg_entity = e;
1336     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1337 }
1338
1339 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1340 .float spamtime;
1341 float spamsound(entity e, float chan, string samp, float vol, float atten)
1342 {
1343     if (!sound_allowed(MSG_BROADCAST, e))
1344         return FALSE;
1345
1346     if (time > e.spamtime)
1347     {
1348         e.spamtime = time;
1349         sound(e, chan, samp, vol, atten);
1350         return TRUE;
1351     }
1352     return FALSE;
1353 }
1354
1355 void play2team(float t, string filename)
1356 {
1357     entity head;
1358
1359     if (autocvar_bot_sound_monopoly)
1360         return;
1361
1362     FOR_EACH_REALPLAYER(head)
1363     {
1364         if (head.team == t)
1365             play2(head, filename);
1366     }
1367 }
1368
1369 void play2all(string samp)
1370 {
1371     if (autocvar_bot_sound_monopoly)
1372         return;
1373
1374     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1375 }
1376
1377 void PrecachePlayerSounds(string f);
1378 void precache_playermodel(string m)
1379 {
1380         float globhandle, i, n;
1381         string f;
1382
1383         if(substring(m, -9,5) == "_lod1")
1384                 return;
1385         if(substring(m, -9,5) == "_lod2")
1386                 return;
1387         precache_model(m);
1388         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1389         if(fexists(f))
1390                 precache_model(f);
1391         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1392         if(fexists(f))
1393                 precache_model(f);
1394
1395         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1396         if (globhandle < 0)
1397                 return;
1398         n = search_getsize(globhandle);
1399         for (i = 0; i < n; ++i)
1400         {
1401                 //print(search_getfilename(globhandle, i), "\n");
1402                 f = search_getfilename(globhandle, i);
1403                 PrecachePlayerSounds(f);
1404         }
1405         search_end(globhandle);
1406 }
1407 void precache_all_playermodels(string pattern)
1408 {
1409         float globhandle, i, n;
1410         string f;
1411
1412         globhandle = search_begin(pattern, TRUE, FALSE);
1413         if (globhandle < 0)
1414                 return;
1415         n = search_getsize(globhandle);
1416         for (i = 0; i < n; ++i)
1417         {
1418                 //print(search_getfilename(globhandle, i), "\n");
1419                 f = search_getfilename(globhandle, i);
1420                 precache_playermodel(f);
1421         }
1422         search_end(globhandle);
1423 }
1424
1425 void precache()
1426 {
1427     // gamemode related things
1428     precache_model ("models/misc/chatbubble.spr");
1429     if (g_runematch)
1430     {
1431         precache_model ("models/runematch/curse.mdl");
1432         precache_model ("models/runematch/rune.mdl");
1433     }
1434
1435 #ifdef TTURRETS_ENABLED
1436     if (autocvar_g_turrets)
1437         turrets_precash();
1438 #endif
1439
1440     // Precache all player models if desired
1441     if (autocvar_sv_precacheplayermodels)
1442     {
1443         PrecachePlayerSounds("sound/player/default.sounds");
1444         precache_all_playermodels("models/player/*.zym");
1445         precache_all_playermodels("models/player/*.dpm");
1446         precache_all_playermodels("models/player/*.md3");
1447         precache_all_playermodels("models/player/*.psk");
1448         precache_all_playermodels("models/player/*.iqm");
1449     }
1450
1451     if (autocvar_sv_defaultcharacter)
1452     {
1453         string s;
1454         s = autocvar_sv_defaultplayermodel_red;
1455         if (s != "")
1456             precache_playermodel(s);
1457         s = autocvar_sv_defaultplayermodel_blue;
1458         if (s != "")
1459             precache_playermodel(s);
1460         s = autocvar_sv_defaultplayermodel_yellow;
1461         if (s != "")
1462             precache_playermodel(s);
1463         s = autocvar_sv_defaultplayermodel_pink;
1464         if (s != "")
1465             precache_playermodel(s);
1466         s = autocvar_sv_defaultplayermodel;
1467         if (s != "")
1468             precache_playermodel(s);
1469     }
1470
1471     if (g_footsteps)
1472     {
1473         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1474         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1475     }
1476
1477     // gore and miscellaneous sounds
1478     //precache_sound ("misc/h2ohit.wav");
1479     precache_model ("models/hook.md3");
1480     precache_sound ("misc/armorimpact.wav");
1481     precache_sound ("misc/bodyimpact1.wav");
1482     precache_sound ("misc/bodyimpact2.wav");
1483     precache_sound ("misc/gib.wav");
1484     precache_sound ("misc/gib_splat01.wav");
1485     precache_sound ("misc/gib_splat02.wav");
1486     precache_sound ("misc/gib_splat03.wav");
1487     precache_sound ("misc/gib_splat04.wav");
1488     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1489     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1490     precache_sound ("misc/null.wav");
1491     precache_sound ("misc/spawn.wav");
1492     precache_sound ("misc/talk.wav");
1493     precache_sound ("misc/teleport.wav");
1494     precache_sound ("misc/poweroff.wav");
1495     precache_sound ("player/lava.wav");
1496     precache_sound ("player/slime.wav");
1497
1498     precache_model ("models/sprites/0.spr32");
1499     precache_model ("models/sprites/1.spr32");
1500     precache_model ("models/sprites/2.spr32");
1501     precache_model ("models/sprites/3.spr32");
1502     precache_model ("models/sprites/4.spr32");
1503     precache_model ("models/sprites/5.spr32");
1504     precache_model ("models/sprites/6.spr32");
1505     precache_model ("models/sprites/7.spr32");
1506     precache_model ("models/sprites/8.spr32");
1507     precache_model ("models/sprites/9.spr32");
1508     precache_model ("models/sprites/10.spr32");
1509
1510     // common weapon precaches
1511         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1512     precache_sound ("weapons/weapon_switch.wav");
1513     precache_sound ("weapons/weaponpickup.wav");
1514     precache_sound ("weapons/unavailable.wav");
1515     precache_sound ("weapons/dryfire.wav");
1516     if (g_grappling_hook)
1517     {
1518         precache_sound ("weapons/hook_fire.wav"); // hook
1519         precache_sound ("weapons/hook_impact.wav"); // hook
1520     }
1521
1522     if(autocvar_sv_precacheweapons)
1523     {
1524         //precache weapon models/sounds
1525         float wep;
1526         wep = WEP_FIRST;
1527         while (wep <= WEP_LAST)
1528         {
1529             weapon_action(wep, WR_PRECACHE);
1530             wep = wep + 1;
1531         }
1532     }
1533
1534     precache_model("models/elaser.mdl");
1535     precache_model("models/laser.mdl");
1536     precache_model("models/ebomb.mdl");
1537
1538 #if 0
1539     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1540
1541     if (!self.noise && self.music) // quake 3 uses the music field
1542         self.noise = self.music;
1543
1544     // plays music for the level if there is any
1545     if (self.noise)
1546     {
1547         precache_sound (self.noise);
1548         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1549     }
1550 #endif
1551 }
1552
1553 // WARNING: this kills the trace globals
1554 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1555 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1556
1557 #define INITPRIO_FIRST              0
1558 #define INITPRIO_GAMETYPE           0
1559 #define INITPRIO_GAMETYPE_FALLBACK  1
1560 #define INITPRIO_FINDTARGET        10
1561 #define INITPRIO_DROPTOFLOOR       20
1562 #define INITPRIO_SETLOCATION       90
1563 #define INITPRIO_LINKDOORS         91
1564 #define INITPRIO_LAST              99
1565
1566 .void(void) initialize_entity;
1567 .float initialize_entity_order;
1568 .entity initialize_entity_next;
1569 entity initialize_entity_first;
1570
1571 void make_safe_for_remove(entity e)
1572 {
1573     if (e.initialize_entity)
1574     {
1575         entity ent, prev = world;
1576         for (ent = initialize_entity_first; ent; )
1577         {
1578             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1579             {
1580                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1581                 // skip it in linked list
1582                 if (prev)
1583                 {
1584                     prev.initialize_entity_next = ent.initialize_entity_next;
1585                     ent = prev.initialize_entity_next;
1586                 }
1587                 else
1588                 {
1589                     initialize_entity_first = ent.initialize_entity_next;
1590                     ent = initialize_entity_first;
1591                 }
1592             }
1593             else
1594             {
1595                 prev = ent;
1596                 ent = ent.initialize_entity_next;
1597             }
1598         }
1599     }
1600 }
1601
1602 void objerror(string s)
1603 {
1604     make_safe_for_remove(self);
1605     builtin_objerror(s);
1606 }
1607
1608 .float remove_except_protected_forbidden;
1609 void remove_except_protected(entity e)
1610 {
1611         if(e.remove_except_protected_forbidden)
1612                 error("not allowed to remove this at this point");
1613         builtin_remove(e);
1614 }
1615
1616 void remove_unsafely(entity e)
1617 {
1618     if(e.classname == "spike")
1619         error("Removing spikes is forbidden (crylink bug), please report");
1620     builtin_remove(e);
1621 }
1622
1623 void remove_safely(entity e)
1624 {
1625     make_safe_for_remove(e);
1626     builtin_remove(e);
1627 }
1628
1629 void InitializeEntity(entity e, void(void) func, float order)
1630 {
1631     entity prev, cur;
1632
1633     if (!e || e.initialize_entity)
1634     {
1635         // make a proxy initializer entity
1636         entity e_old;
1637         e_old = e;
1638         e = spawn();
1639         e.classname = "initialize_entity";
1640         e.enemy = e_old;
1641     }
1642
1643     e.initialize_entity = func;
1644     e.initialize_entity_order = order;
1645
1646     cur = initialize_entity_first;
1647     prev = world;
1648     for (;;)
1649     {
1650         if (!cur || cur.initialize_entity_order > order)
1651         {
1652             // insert between prev and cur
1653             if (prev)
1654                 prev.initialize_entity_next = e;
1655             else
1656                 initialize_entity_first = e;
1657             e.initialize_entity_next = cur;
1658             return;
1659         }
1660         prev = cur;
1661         cur = cur.initialize_entity_next;
1662     }
1663 }
1664 void InitializeEntitiesRun()
1665 {
1666     entity startoflist;
1667     startoflist = initialize_entity_first;
1668     initialize_entity_first = world;
1669     remove = remove_except_protected;
1670     for (self = startoflist; self; self = self.initialize_entity_next)
1671     {
1672         self.remove_except_protected_forbidden = 1;
1673     }
1674     for (self = startoflist; self; )
1675     {
1676         entity e;
1677         var void(void) func;
1678         e = self.initialize_entity_next;
1679         func = self.initialize_entity;
1680         self.initialize_entity_order = 0;
1681         self.initialize_entity = func_null;
1682         self.initialize_entity_next = world;
1683         self.remove_except_protected_forbidden = 0;
1684         if (self.classname == "initialize_entity")
1685         {
1686             entity e_old;
1687             e_old = self.enemy;
1688             builtin_remove(self);
1689             self = e_old;
1690         }
1691         //dprint("Delayed initialization: ", self.classname, "\n");
1692         if(func)
1693             func();
1694         else
1695         {
1696             eprint(self);
1697             backtrace(strcat("Null function in: ", self.classname, "\n"));
1698         }
1699         self = e;
1700     }
1701     remove = remove_unsafely;
1702 }
1703
1704 .float uncustomizeentityforclient_set;
1705 .void(void) uncustomizeentityforclient;
1706 void UncustomizeEntitiesRun()
1707 {
1708     entity oldself;
1709     oldself = self;
1710     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1711         self.uncustomizeentityforclient();
1712     self = oldself;
1713 }
1714 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1715 {
1716     e.customizeentityforclient = customizer;
1717     e.uncustomizeentityforclient = uncustomizer;
1718     e.uncustomizeentityforclient_set = !!uncustomizer;
1719 }
1720
1721 .float nottargeted;
1722 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1723
1724 void() SUB_Remove;
1725 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1726 {
1727     vector mi, ma;
1728
1729     if (e.classname == "")
1730         e.classname = "net_linked";
1731
1732     if (e.model == "" || self.modelindex == 0)
1733     {
1734         mi = e.mins;
1735         ma = e.maxs;
1736         setmodel(e, "null");
1737         setsize(e, mi, ma);
1738     }
1739
1740     e.SendEntity = sendfunc;
1741     e.SendFlags = 0xFFFFFF;
1742
1743     if (!docull)
1744         e.effects |= EF_NODEPTHTEST;
1745
1746     if (dt)
1747     {
1748         e.nextthink = time + dt;
1749         e.think = SUB_Remove;
1750     }
1751 }
1752
1753 void adaptor_think2touch()
1754 {
1755     entity o;
1756     o = other;
1757     other = world;
1758     self.touch();
1759     other = o;
1760 }
1761
1762 void adaptor_think2use()
1763 {
1764     entity o, a;
1765     o = other;
1766     a = activator;
1767     activator = world;
1768     other = world;
1769     self.use();
1770     other = o;
1771     activator = a;
1772 }
1773
1774 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1775 {
1776         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1777                 self.projectiledeathtype |= HITTYPE_SPLASH;
1778         adaptor_think2use();
1779 }
1780
1781 // deferred dropping
1782 void DropToFloor_Handler()
1783 {
1784     builtin_droptofloor();
1785     self.dropped_origin = self.origin;
1786 }
1787
1788 void droptofloor()
1789 {
1790     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1791 }
1792
1793
1794
1795 float trace_hits_box_a0, trace_hits_box_a1;
1796
1797 float trace_hits_box_1d(float end, float thmi, float thma)
1798 {
1799     if (end == 0)
1800     {
1801         // just check if x is in range
1802         if (0 < thmi)
1803             return FALSE;
1804         if (0 > thma)
1805             return FALSE;
1806     }
1807     else
1808     {
1809         // do the trace with respect to x
1810         // 0 -> end has to stay in thmi -> thma
1811         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1812         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1813         if (trace_hits_box_a0 > trace_hits_box_a1)
1814             return FALSE;
1815     }
1816     return TRUE;
1817 }
1818
1819 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1820 {
1821     end -= start;
1822     thmi -= start;
1823     thma -= start;
1824     // now it is a trace from 0 to end
1825
1826     trace_hits_box_a0 = 0;
1827     trace_hits_box_a1 = 1;
1828
1829     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1830         return FALSE;
1831     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1832         return FALSE;
1833     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1834         return FALSE;
1835
1836     return TRUE;
1837 }
1838
1839 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1840 {
1841     return trace_hits_box(start, end, thmi - ma, thma - mi);
1842 }
1843
1844 float SUB_NoImpactCheck()
1845 {
1846         // zero hitcontents = this is not the real impact, but either the
1847         // mirror-impact of something hitting the projectile instead of the
1848         // projectile hitting the something, or a touchareagrid one. Neither of
1849         // these stop the projectile from moving, so...
1850         if(trace_dphitcontents == 0)
1851         {
1852                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1853                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1854                 checkclient();
1855         }
1856     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1857         return 1;
1858     if (other == world && self.size != '0 0 0')
1859     {
1860         vector tic;
1861         tic = self.velocity * sys_frametime;
1862         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1863         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1864         if (trace_fraction >= 1)
1865         {
1866             dprint("Odd... did not hit...?\n");
1867         }
1868         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1869         {
1870             dprint("Detected and prevented the sky-grapple bug.\n");
1871             return 1;
1872         }
1873     }
1874
1875     return 0;
1876 }
1877
1878 #define SUB_OwnerCheck() (other && (other == self.owner))
1879
1880 void RemoveGrapplingHook(entity pl);
1881 void W_Crylink_Dequeue(entity e);
1882 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1883 {
1884         if(SUB_OwnerCheck())
1885                 return TRUE;
1886         if(SUB_NoImpactCheck())
1887         {
1888                 if(self.classname == "grapplinghook")
1889                         RemoveGrapplingHook(self.realowner);
1890                 else if(self.classname == "spike")
1891                 {
1892                         W_Crylink_Dequeue(self);
1893                         remove(self);
1894                 }
1895                 else
1896                         remove(self);
1897                 return TRUE;
1898         }
1899         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1900                 UpdateCSQCProjectile(self);
1901         return FALSE;
1902 }
1903 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1904
1905 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1906 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1907
1908 void URI_Get_Callback(float id, float status, string data)
1909 {
1910         if(url_URI_Get_Callback(id, status, data))
1911         {
1912                 // handled
1913         }
1914         else if (id == URI_GET_DISCARD)
1915         {
1916                 // discard
1917         }
1918         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1919         {
1920                 // sv_cmd curl
1921                 Curl_URI_Get_Callback(id, status, data);
1922         }
1923         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1924         {
1925                 // online ban list
1926                 OnlineBanList_URI_Get_Callback(id, status, data);
1927         }
1928         else
1929         {
1930                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1931         }
1932 }
1933
1934 string uid2name(string myuid) {
1935         string s;
1936         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1937
1938         // FIXME remove this later after 0.6 release
1939         // convert old style broken records to correct style
1940         if(s == "")
1941         {
1942                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1943                 if(s != "")
1944                 {
1945                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1946                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1947                 }
1948         }
1949
1950         if(s == "")
1951                 s = "^1Unregistered Player";
1952         return s;
1953 }
1954
1955 float race_readTime(string map, float pos)
1956 {
1957         string rr;
1958         if(g_cts)
1959                 rr = CTS_RECORD;
1960         else
1961                 rr = RACE_RECORD;
1962
1963         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1964 }
1965
1966 string race_readUID(string map, float pos)
1967 {
1968         string rr;
1969         if(g_cts)
1970                 rr = CTS_RECORD;
1971         else
1972                 rr = RACE_RECORD;
1973
1974         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1975 }
1976
1977 float race_readPos(string map, float t) {
1978         float i;
1979         for (i = 1; i <= RANKINGS_CNT; ++i)
1980                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1981                         return i;
1982
1983         return 0; // pos is zero if unranked
1984 }
1985
1986 void race_writeTime(string map, float t, string myuid)
1987 {
1988         string rr;
1989         if(g_cts)
1990                 rr = CTS_RECORD;
1991         else
1992                 rr = RACE_RECORD;
1993
1994         float newpos;
1995         newpos = race_readPos(map, t);
1996
1997         float i, prevpos = 0;
1998         for(i = 1; i <= RANKINGS_CNT; ++i)
1999         {
2000                 if(race_readUID(map, i) == myuid)
2001                         prevpos = i;
2002         }
2003         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2004                 for (i = prevpos; i > newpos; --i) {
2005                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2006                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2007                 }
2008         } else { // player has no ranked record yet
2009                 for (i = RANKINGS_CNT; i > newpos; --i) {
2010                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2011                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2012                 }
2013         }
2014
2015         // store new time itself
2016         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2017         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2018 }
2019
2020 string race_readName(string map, float pos)
2021 {
2022         string rr;
2023         if(g_cts)
2024                 rr = CTS_RECORD;
2025         else
2026                 rr = RACE_RECORD;
2027
2028         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2029 }
2030
2031 string race_placeName(float pos) {
2032         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2033         {
2034                 if(mod(pos, 10) == 1)
2035                         return strcat(ftos(pos), "st");
2036                 else if(mod(pos, 10) == 2)
2037                         return strcat(ftos(pos), "nd");
2038                 else if(mod(pos, 10) == 3)
2039                         return strcat(ftos(pos), "rd");
2040                 else
2041                         return strcat(ftos(pos), "th");
2042         }
2043         else
2044                 return strcat(ftos(pos), "th");
2045 }
2046
2047 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2048 {
2049     float m, i;
2050     vector start, org, delta, end, enddown, mstart;
2051     entity sp;
2052
2053     m = e.dphitcontentsmask;
2054     e.dphitcontentsmask = goodcontents | badcontents;
2055
2056     org = world.mins;
2057     delta = world.maxs - world.mins;
2058
2059     start = end = org;
2060
2061     for (i = 0; i < attempts; ++i)
2062     {
2063         start_x = org_x + random() * delta_x;
2064         start_y = org_y + random() * delta_y;
2065         start_z = org_z + random() * delta_z;
2066
2067         // rule 1: start inside world bounds, and outside
2068         // solid, and don't start from somewhere where you can
2069         // fall down to evil
2070         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2071         if (trace_fraction >= 1)
2072             continue;
2073         if (trace_startsolid)
2074             continue;
2075         if (trace_dphitcontents & badcontents)
2076             continue;
2077         if (trace_dphitq3surfaceflags & badsurfaceflags)
2078             continue;
2079
2080         // rule 2: if we are too high, lower the point
2081         if (trace_fraction * delta_z > maxaboveground)
2082             start = trace_endpos + '0 0 1' * maxaboveground;
2083         enddown = trace_endpos;
2084
2085         // rule 3: make sure we aren't outside the map. This only works
2086         // for somewhat well formed maps. A good rule of thumb is that
2087         // the map should have a convex outside hull.
2088         // these can be traceLINES as we already verified the starting box
2089         mstart = start + 0.5 * (e.mins + e.maxs);
2090         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2091         if (trace_fraction >= 1)
2092             continue;
2093         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2094         if (trace_fraction >= 1)
2095             continue;
2096         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2097         if (trace_fraction >= 1)
2098             continue;
2099         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2100         if (trace_fraction >= 1)
2101             continue;
2102         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2103         if (trace_fraction >= 1)
2104             continue;
2105
2106         // rule 4: we must "see" some spawnpoint
2107         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2108                 if(checkpvs(mstart, sp))
2109                         break;
2110         if(!sp)
2111         {
2112                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2113                         if(checkpvs(mstart, sp))
2114                                 break;
2115                 if(!sp)
2116                         continue;
2117         }
2118
2119         // find a random vector to "look at"
2120         end_x = org_x + random() * delta_x;
2121         end_y = org_y + random() * delta_y;
2122         end_z = org_z + random() * delta_z;
2123         end = start + normalize(end - start) * vlen(delta);
2124
2125         // rule 4: start TO end must not be too short
2126         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2127         if (trace_startsolid)
2128             continue;
2129         if (trace_fraction < minviewdistance / vlen(delta))
2130             continue;
2131
2132         // rule 5: don't want to look at sky
2133         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2134             continue;
2135
2136         // rule 6: we must not end up in trigger_hurt
2137         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2138             continue;
2139
2140         break;
2141     }
2142
2143     e.dphitcontentsmask = m;
2144
2145     if (i < attempts)
2146     {
2147         setorigin(e, start);
2148         e.angles = vectoangles(end - start);
2149         dprint("Needed ", ftos(i + 1), " attempts\n");
2150         return TRUE;
2151     }
2152     else
2153         return FALSE;
2154 }
2155
2156 float zcurveparticles_effectno;
2157 vector zcurveparticles_start;
2158 float zcurveparticles_spd;
2159
2160 void endzcurveparticles()
2161 {
2162         if(zcurveparticles_effectno)
2163         {
2164                 // terminator
2165                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2166         }
2167         zcurveparticles_effectno = 0;
2168 }
2169
2170 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2171 {
2172         spd = bound(0, floor(spd / 16), 32767);
2173         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2174         {
2175                 endzcurveparticles();
2176                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2177                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2178                 WriteShort(MSG_BROADCAST, effectno);
2179                 WriteCoord(MSG_BROADCAST, start_x);
2180                 WriteCoord(MSG_BROADCAST, start_y);
2181                 WriteCoord(MSG_BROADCAST, start_z);
2182                 zcurveparticles_effectno = effectno;
2183                 zcurveparticles_start = start;
2184         }
2185         else
2186                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2187         WriteCoord(MSG_BROADCAST, end_x);
2188         WriteCoord(MSG_BROADCAST, end_y);
2189         WriteCoord(MSG_BROADCAST, end_z);
2190         WriteCoord(MSG_BROADCAST, end_dz);
2191         zcurveparticles_spd = spd;
2192 }
2193
2194 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2195 {
2196         float end_dz;
2197         vector vecxy, velxy;
2198
2199         vecxy = end - start;
2200         vecxy_z = 0;
2201         velxy = vel;
2202         velxy_z = 0;
2203
2204         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2205         {
2206                 endzcurveparticles();
2207                 trailparticles(world, effectno, start, end);
2208                 return;
2209         }
2210
2211         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2212         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2213 }
2214
2215 void write_recordmarker(entity pl, float tstart, float dt)
2216 {
2217     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2218
2219     // also write a marker into demo files for demotc-race-record-extractor to find
2220     stuffcmd(pl,
2221              strcat(
2222                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2223                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2224 }
2225
2226 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2227 {
2228         switch(algn)
2229         {
2230                 default:
2231                 case 3: // right
2232                         break;
2233
2234                 case 4: // left
2235                         vecs_y = -vecs_y;
2236                         break;
2237
2238                 case 1:
2239                         if(allowcenter) // 2: allow center handedness
2240                         {
2241                                 // center
2242                                 vecs_y = 0;
2243                                 vecs_z -= 2;
2244                         }
2245                         else
2246                         {
2247                                 // right
2248                         }
2249                         break;
2250
2251                 case 2:
2252                         if(allowcenter) // 2: allow center handedness
2253                         {
2254                                 // center
2255                                 vecs_y = 0;
2256                                 vecs_z -= 2;
2257                         }
2258                         else
2259                         {
2260                                 // left
2261                                 vecs_y = -vecs_y;
2262                         }
2263                         break;
2264         }
2265         return vecs;
2266 }
2267
2268 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2269 {
2270         string s;
2271         vector v;
2272
2273         if (autocvar_g_shootfromeye)
2274         {
2275                 if (visual)
2276                 {
2277                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2278                         else { vecs_y = 0; vecs_z -= 2; }
2279                 }
2280                 else
2281                 {
2282                         vecs_y = 0;
2283                         vecs_z = 0;
2284                 }
2285         }
2286         else if (autocvar_g_shootfromcenter)
2287         {
2288                 vecs_y = 0;
2289                 vecs_z -= 2;
2290         }
2291         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2292         {
2293                 v = stov(s);
2294                 if (y_is_right)
2295                         v_y = -v_y;
2296                 if (v_x != 0)
2297                         vecs_x = v_x;
2298                 vecs_y = v_y;
2299                 vecs_z = v_z;
2300         }
2301         else if (autocvar_g_shootfromclient)
2302         {
2303                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2304         }
2305         return vecs;
2306 }
2307
2308 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2309 {
2310         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2311 }
2312
2313
2314 void attach_sameorigin(entity e, entity to, string tag)
2315 {
2316     vector org, t_forward, t_left, t_up, e_forward, e_up;
2317     float tagscale;
2318
2319     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2320     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2321     t_forward = v_forward * tagscale;
2322     t_left = v_right * -tagscale;
2323     t_up = v_up * tagscale;
2324
2325     e.origin_x = org * t_forward;
2326     e.origin_y = org * t_left;
2327     e.origin_z = org * t_up;
2328
2329     // current forward and up directions
2330     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2331                 e.angles = AnglesTransform_FromVAngles(e.angles);
2332         else
2333                 e.angles = AnglesTransform_FromAngles(e.angles);
2334     fixedmakevectors(e.angles);
2335
2336     // untransform forward, up!
2337     e_forward_x = v_forward * t_forward;
2338     e_forward_y = v_forward * t_left;
2339     e_forward_z = v_forward * t_up;
2340     e_up_x = v_up * t_forward;
2341     e_up_y = v_up * t_left;
2342     e_up_z = v_up * t_up;
2343
2344     e.angles = fixedvectoangles2(e_forward, e_up);
2345     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2346                 e.angles = AnglesTransform_ToVAngles(e.angles);
2347         else
2348                 e.angles = AnglesTransform_ToAngles(e.angles);
2349
2350     setattachment(e, to, tag);
2351     setorigin(e, e.origin);
2352 }
2353
2354 void detach_sameorigin(entity e)
2355 {
2356     vector org;
2357     org = gettaginfo(e, 0);
2358     e.angles = fixedvectoangles2(v_forward, v_up);
2359     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2360                 e.angles = AnglesTransform_ToVAngles(e.angles);
2361         else
2362                 e.angles = AnglesTransform_ToAngles(e.angles);
2363     setorigin(e, org);
2364     setattachment(e, world, "");
2365     setorigin(e, e.origin);
2366 }
2367
2368 void follow_sameorigin(entity e, entity to)
2369 {
2370     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2371     e.aiment = to; // make the hole follow bmodel
2372     e.punchangle = to.angles; // the original angles of bmodel
2373     e.view_ofs = e.origin - to.origin; // relative origin
2374     e.v_angle = e.angles - to.angles; // relative angles
2375 }
2376
2377 void unfollow_sameorigin(entity e)
2378 {
2379     e.movetype = MOVETYPE_NONE;
2380 }
2381
2382 entity gettaginfo_relative_ent;
2383 vector gettaginfo_relative(entity e, float tag)
2384 {
2385     if (!gettaginfo_relative_ent)
2386     {
2387         gettaginfo_relative_ent = spawn();
2388         gettaginfo_relative_ent.effects = EF_NODRAW;
2389     }
2390     gettaginfo_relative_ent.model = e.model;
2391     gettaginfo_relative_ent.modelindex = e.modelindex;
2392     gettaginfo_relative_ent.frame = e.frame;
2393     return gettaginfo(gettaginfo_relative_ent, tag);
2394 }
2395
2396 .float scale2;
2397
2398 float modeleffect_SendEntity(entity to, float sf)
2399 {
2400         float f;
2401         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2402
2403         f = 0;
2404         if(self.velocity != '0 0 0')
2405                 f |= 1;
2406         if(self.angles != '0 0 0')
2407                 f |= 2;
2408         if(self.avelocity != '0 0 0')
2409                 f |= 4;
2410
2411         WriteByte(MSG_ENTITY, f);
2412         WriteShort(MSG_ENTITY, self.modelindex);
2413         WriteByte(MSG_ENTITY, self.skin);
2414         WriteByte(MSG_ENTITY, self.frame);
2415         WriteCoord(MSG_ENTITY, self.origin_x);
2416         WriteCoord(MSG_ENTITY, self.origin_y);
2417         WriteCoord(MSG_ENTITY, self.origin_z);
2418         if(f & 1)
2419         {
2420                 WriteCoord(MSG_ENTITY, self.velocity_x);
2421                 WriteCoord(MSG_ENTITY, self.velocity_y);
2422                 WriteCoord(MSG_ENTITY, self.velocity_z);
2423         }
2424         if(f & 2)
2425         {
2426                 WriteCoord(MSG_ENTITY, self.angles_x);
2427                 WriteCoord(MSG_ENTITY, self.angles_y);
2428                 WriteCoord(MSG_ENTITY, self.angles_z);
2429         }
2430         if(f & 4)
2431         {
2432                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2433                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2434                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2435         }
2436         WriteShort(MSG_ENTITY, self.scale * 256.0);
2437         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2438         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2439         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2440         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2441
2442         return TRUE;
2443 }
2444
2445 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2446 {
2447         entity e;
2448         float sz;
2449         e = spawn();
2450         e.classname = "modeleffect";
2451         setmodel(e, m);
2452         e.frame = f;
2453         setorigin(e, o);
2454         e.velocity = v;
2455         e.angles = ang;
2456         e.avelocity = angv;
2457         e.alpha = a;
2458         e.teleport_time = t1;
2459         e.fade_time = t2;
2460         e.skin = s;
2461         if(s0 >= 0)
2462                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2463         else
2464                 e.scale = -s0;
2465         if(s2 >= 0)
2466                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2467         else
2468                 e.scale2 = -s2;
2469         sz = max(e.scale, e.scale2);
2470         setsize(e, e.mins * sz, e.maxs * sz);
2471         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2472 }
2473
2474 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2475 {
2476         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2477 }
2478
2479 float randombit(float bits)
2480 {
2481         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2482                 return bits;
2483
2484         float n, f, b, r;
2485
2486         r = random();
2487         b = 0;
2488         n = 0;
2489
2490         for(f = 1; f <= bits; f *= 2)
2491         {
2492                 if(bits & f)
2493                 {
2494                         ++n;
2495                         r *= n;
2496                         if(r <= 1)
2497                                 b = f;
2498                         else
2499                                 r = (r - 1) / (n - 1);
2500                 }
2501         }
2502
2503         return b;
2504 }
2505
2506 float randombits(float bits, float k, float error_return)
2507 {
2508         float r;
2509         r = 0;
2510         while(k > 0 && bits != r)
2511         {
2512                 r += randombit(bits - r);
2513                 --k;
2514         }
2515         if(error_return)
2516                 if(k > 0)
2517                         return -1; // all
2518         return r;
2519 }
2520
2521 void randombit_test(float bits, float iter)
2522 {
2523         while(iter > 0)
2524         {
2525                 print(ftos(randombit(bits)), "\n");
2526                 --iter;
2527         }
2528 }
2529
2530 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2531 {
2532         if(halflifedist > 0)
2533                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2534         else if(halflifedist < 0)
2535                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2536         else
2537                 return 1;
2538 }
2539
2540
2541
2542
2543 #ifdef RELEASE
2544 #define cvar_string_normal builtin_cvar_string
2545 #define cvar_normal builtin_cvar
2546 #else
2547 string cvar_string_normal(string n)
2548 {
2549         if not(cvar_type(n) & 1)
2550                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2551         return builtin_cvar_string(n);
2552 }
2553
2554 float cvar_normal(string n)
2555 {
2556         return stof(cvar_string_normal(n));
2557 }
2558 #endif
2559 #define cvar_set_normal builtin_cvar_set
2560
2561 void defer_think()
2562 {
2563     entity oself;
2564
2565     oself           = self;
2566     self            = self.owner;
2567     oself.think     = SUB_Remove;
2568     oself.nextthink = time;
2569
2570     oself.use();
2571 }
2572
2573 /*
2574     Execute func() after time + fdelay.
2575     self when func is executed = self when defer is called
2576 */
2577 void defer(float fdelay, void() func)
2578 {
2579     entity e;
2580
2581     e           = spawn();
2582     e.owner     = self;
2583     e.use       = func;
2584     e.think     = defer_think;
2585     e.nextthink = time + fdelay;
2586 }
2587
2588 .string aiment_classname;
2589 .float aiment_deadflag;
2590 void SetMovetypeFollow(entity ent, entity e)
2591 {
2592         // FIXME this may not be warpzone aware
2593         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2594         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2595         ent.aiment = e; // make the hole follow bmodel
2596         ent.punchangle = e.angles; // the original angles of bmodel
2597         ent.view_ofs = ent.origin - e.origin; // relative origin
2598         ent.v_angle = ent.angles - e.angles; // relative angles
2599         ent.aiment_classname = strzone(e.classname);
2600         ent.aiment_deadflag = e.deadflag;
2601 }
2602 void UnsetMovetypeFollow(entity ent)
2603 {
2604         ent.movetype = MOVETYPE_FLY;
2605         PROJECTILE_MAKETRIGGER(ent);
2606         ent.aiment = world;
2607 }
2608 float LostMovetypeFollow(entity ent)
2609 {
2610 /*
2611         if(ent.movetype != MOVETYPE_FOLLOW)
2612                 if(ent.aiment)
2613                         error("???");
2614 */
2615         if(ent.aiment)
2616         {
2617                 if(ent.aiment.classname != ent.aiment_classname)
2618                         return 1;
2619                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2620                         return 1;
2621         }
2622         return 0;
2623 }
2624
2625 float isPushable(entity e)
2626 {
2627         if(e.iscreature)
2628                 return TRUE;
2629         if(e.pushable)
2630                 return TRUE;
2631         switch(e.classname)
2632         {
2633                 case "body":
2634                 case "droppedweapon":
2635                 case "keepawayball":
2636                 case "nexball_basketball":
2637                 case "nexball_football":
2638                         return TRUE;
2639                 case "bullet": // antilagged bullets can't hit this either
2640                         return FALSE;
2641         }
2642         if (e.projectiledeathtype)
2643                 return TRUE;
2644         return FALSE;
2645 }
2646
2647 void dedicated_print(string input) // print(), but only print if the server is not local
2648 {
2649         if not(server_is_local) { print(input); }
2650 }