qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/_mod.qh"
   9 #include "../common/t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/_mod.qh"
  14 #include "../common/constants.qh"
  15 #include <common/net_linked.qh>
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/notifications/all.qh"
  19 #include "../common/playerstats.qh"
  20 #include "../common/teams.qh"
  21 #include "../common/triggers/subs.qh"
  22 #include "../common/util.qh"
  23 #include "../common/turrets/sv_turrets.qh"
  24 #include <common/weapons/_all.qh>
  25 #include "../common/vehicles/sv_vehicles.qh"
  26 #include "../common/vehicles/vehicle.qh"
  27 #include "../common/items/_mod.qh"
  28 #include "../common/state.qh"
  29 #include "../common/effects/qc/globalsound.qh"
  30 #include "../common/wepent.qh"
  31 #include "../lib/csqcmodel/sv_model.qh"
  32 #include "../lib/warpzone/anglestransform.qh"
  33 #include "../lib/warpzone/server.qh"
  34
  35 void crosshair_trace(entity pl)
  36 {
  37         traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  38 }
  39 .bool ctrace_solidchanged;
  40 void crosshair_trace_plusvisibletriggers(entity pl)
  41 {
  42         FOREACH_ENTITY_FLOAT(solid, SOLID_TRIGGER,
  43         {
  44                 if(it.model != "")
  45                 {
  46                         it.solid = SOLID_BSP;
  47                         it.ctrace_solidchanged = true;
  48                         IL_PUSH(g_ctrace_changed, it);
  49                 }
  50         });
  51
  52         crosshair_trace(pl);
  53
  54         IL_EACH(g_ctrace_changed, it.ctrace_solidchanged,
  55         {
  56                 it.solid = SOLID_TRIGGER;
  57                 it.ctrace_solidchanged = false;
  58         });
  59
  60         IL_CLEAR(g_ctrace_changed);
  61 }
  62 void WarpZone_crosshair_trace(entity pl)
  63 {
  64         WarpZone_traceline_antilag(pl, CS(pl).cursor_trace_start, CS(pl).cursor_trace_start + normalize(CS(pl).cursor_trace_endpos - CS(pl).cursor_trace_start) * max_shot_distance, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  65 }
  66
  67
  68 void GameLogEcho(string s)
  69 {
  70     string fn;
  71     int matches;
  72
  73     if (autocvar_sv_eventlog_files)
  74     {
  75         if (!logfile_open)
  76         {
  77             logfile_open = true;
  78             matches = autocvar_sv_eventlog_files_counter + 1;
  79             cvar_set("sv_eventlog_files_counter", itos(matches));
  80             fn = ftos(matches);
  81             if (strlen(fn) < 8)
  82                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  83             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  84             logfile = fopen(fn, FILE_APPEND);
  85             fputs(logfile, ":logversion:3\n");
  86         }
  87         if (logfile >= 0)
  88         {
  89             if (autocvar_sv_eventlog_files_timestamps)
  90                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  91             else
  92                 fputs(logfile, strcat(s, "\n"));
  93         }
  94     }
  95     if (autocvar_sv_eventlog_console)
  96     {
  97         dedicated_print(strcat(s, "\n"));
  98     }
  99 }
 100
 101 void GameLogInit()
 102 {
 103     logfile_open = 0;
 104     // will be opened later
 105 }
 106
 107 void GameLogClose()
 108 {
 109     if (logfile_open && logfile >= 0)
 110     {
 111         fclose(logfile);
 112         logfile = -1;
 113     }
 114 }
 115
 116 entity findnearest(vector point, bool checkitems, vector axismod)
 117 {
 118     vector dist;
 119     int num_nearest = 0;
 120
 121     IL_EACH(((checkitems) ? g_items : g_locations), ((checkitems) ? (it.target == "###item###") : (it.classname == "target_location")),
 122     {
 123         if ((it.items == IT_KEY1 || it.items == IT_KEY2) && it.target == "###item###")
 124             dist = it.oldorigin;
 125         else
 126             dist = it.origin;
 127         dist = dist - point;
 128         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 129         float len = vlen2(dist);
 130
 131         int l;
 132         for (l = 0; l < num_nearest; ++l)
 133         {
 134             if (len < nearest_length[l])
 135                 break;
 136         }
 137
 138         // now i tells us where to insert at
 139         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 140         if (l < NUM_NEAREST_ENTITIES)
 141         {
 142             for (int j = NUM_NEAREST_ENTITIES - 1; j >= l; --j)
 143             {
 144                 nearest_length[j + 1] = nearest_length[j];
 145                 nearest_entity[j + 1] = nearest_entity[j];
 146             }
 147             nearest_length[l] = len;
 148             nearest_entity[l] = it;
 149             if (num_nearest < NUM_NEAREST_ENTITIES)
 150                 num_nearest = num_nearest + 1;
 151         }
 152     });
 153
 154     // now use the first one from our list that we can see
 155     for (int j = 0; j < num_nearest; ++j)
 156     {
 157         traceline(point, nearest_entity[j].origin, true, NULL);
 158         if (trace_fraction == 1)
 159         {
 160             if (j != 0)
 161                 LOG_TRACEF("Nearest point (%s) is not visible, using a visible one.", nearest_entity[0].netname);
 162             return nearest_entity[j];
 163         }
 164     }
 165
 166     if (num_nearest == 0)
 167         return NULL;
 168
 169     LOG_TRACE("Not seeing any location point, using nearest as fallback.");
 170     /* DEBUGGING CODE:
 171     dprint("Candidates were: ");
 172     for(j = 0; j < num_nearest; ++j)
 173     {
 174         if(j != 0)
 175                 dprint(", ");
 176         dprint(nearest_entity[j].netname);
 177     }
 178     dprint("\n");
 179     */
 180
 181     return nearest_entity[0];
 182 }
 183
 184 string NearestLocation(vector p)
 185 {
 186     string ret = "somewhere";
 187     entity loc = findnearest(p, false, '1 1 1');
 188     if (loc)
 189         ret = loc.message;
 190     else
 191     {
 192         loc = findnearest(p, true, '1 1 4');
 193         if (loc)
 194             ret = loc.netname;
 195     }
 196     return ret;
 197 }
 198
 199 string AmmoNameFromWeaponentity(entity wpn)
 200 {
 201         string ammoitems = "batteries";
 202         switch ((wpn.m_weapon).ammo_type)
 203         {
 204                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 205                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 206                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 207                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 208                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 209                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 210         }
 211         return ammoitems;
 212 }
 213
 214 string formatmessage(entity this, string msg)
 215 {
 216         float p, p1, p2;
 217         float n;
 218         vector cursor;
 219         entity cursor_ent;
 220         string escape;
 221         string replacement;
 222         p = 0;
 223         n = 7;
 224
 225         WarpZone_crosshair_trace(this);
 226         cursor = trace_endpos;
 227         cursor_ent = trace_ent;
 228
 229         MUTATOR_CALLHOOK(PreFormatMessage, this, msg);
 230         msg = M_ARGV(1, string);
 231
 232         while (1) {
 233                 if (n < 1)
 234                         break; // too many replacements
 235
 236                 n = n - 1;
 237                 p1 = strstrofs(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 238                 p2 = strstrofs(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 239
 240                 if (p1 < 0)
 241                         p1 = p2;
 242
 243                 if (p2 < 0)
 244                         p2 = p1;
 245
 246                 p = min(p1, p2);
 247
 248                 if (p < 0)
 249                         break;
 250
 251                 replacement = substring(msg, p, 2);
 252                 escape = substring(msg, p + 1, 1);
 253
 254                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 255
 256                 switch(escape)
 257                 {
 258                         case "%": replacement = "%"; break;
 259                         case "\\":replacement = "\\"; break;
 260                         case "n": replacement = "\n"; break;
 261                         case "a": replacement = ftos(floor(this.armorvalue)); break;
 262                         case "h": replacement = ftos(floor(this.health)); break;
 263                         case "l": replacement = NearestLocation(this.origin); break;
 264                         case "y": replacement = NearestLocation(cursor); break;
 265                         case "d": replacement = NearestLocation(this.death_origin); break;
 266                         case "w": replacement = ((this.(weaponentity).m_weapon == WEP_Null) ? ((this.(weaponentity).m_switchweapon == WEP_Null) ? Weapons_from(this.(weaponentity).cnt) : this.(weaponentity).m_switchweapon) : this.(weaponentity).m_weapon).m_name; break;
 267                         case "W": replacement = AmmoNameFromWeaponentity(this.(weaponentity)); break;
 268                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 269                         case "s": replacement = ftos(vlen(this.velocity - this.velocity_z * '0 0 1')); break;
 270                         case "S": replacement = ftos(vlen(this.velocity)); break;
 271                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 272                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 273                         default:
 274                         {
 275                                 MUTATOR_CALLHOOK(FormatMessage, this, escape, replacement, msg);
 276                                 replacement = M_ARGV(2, string);
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(entity this, entity store, string thisname, float f, .string field, string name)
 296 {
 297         if (f < 0)
 298         {
 299                 if (store.(field))
 300                         strunzone(store.(field));
 301                 store.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (store.(field))
 308                                 strunzone(store.(field));
 309                         store.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(entity this, entity store, string thisname, float f, .string field, string name, string(entity, string) func)
 316 {
 317         GetCvars_handleString(this, store, thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(this, strcat1(store.(field)));
 322                         if (s != store.(field))
 323                         {
 324                                 strunzone(store.(field));
 325                                 store.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(entity this, entity store, string thisname, float f, .float field, string name)
 330 {
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         store.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(entity this, entity store, string thisname, float f, .float field, string name)
 343 {
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!store.(field))
 352                         {
 353                                 store.(field) = stof(argv(f + 1));
 354                                 if (!store.(field))
 355                                         store.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!store.(field))
 362                         stuffcmd(this, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 366 {
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(this.weaponorder_byimpulse)
 370         {
 371                 strunzone(this.weaponorder_byimpulse);
 372                 this.weaponorder_byimpulse = string_null;
 373         }
 374         this.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377
 378 REPLICATE(autoswitch, bool, "cl_autoswitch");
 379
 380 REPLICATE(cvar_cl_allow_uid2name, bool, "cl_allow_uid2name");
 381
 382 REPLICATE(cvar_cl_autoscreenshot, int, "cl_autoscreenshot");
 383
 384 REPLICATE(cvar_cl_autotaunt, float, "cl_autotaunt");
 385
 386 REPLICATE(cvar_cl_clippedspectating, bool, "cl_clippedspectating");
 387
 388 REPLICATE(cvar_cl_handicap, float, "cl_handicap");
 389
 390 REPLICATE(cvar_cl_jetpack_jump, bool, "cl_jetpack_jump");
 391
 392 REPLICATE(cvar_cl_movement_track_canjump, bool, "cl_movement_track_canjump");
 393
 394 REPLICATE(cvar_cl_newusekeysupported, bool, "cl_newusekeysupported");
 395
 396 REPLICATE(cvar_cl_noantilag, bool, "cl_noantilag");
 397
 398 REPLICATE(cvar_cl_physics, string, "cl_physics");
 399
 400 REPLICATE(cvar_cl_voice_directional, int, "cl_voice_directional");
 401
 402 REPLICATE(cvar_cl_voice_directional_taunt_attenuation, float, "cl_voice_directional_taunt_attenuation");
 403
 404 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 405
 406 REPLICATE(cvar_g_xonoticversion, string, "g_xonoticversion");
 407
 408 /**
 409  * @param f -1: cleanup, 0: request, 1: receive
 410  */
 411 void GetCvars(entity this, entity store, int f)
 412 {
 413         string s = string_null;
 414
 415         if (f > 0)
 416                 s = strcat1(argv(f));
 417
 418         get_cvars_f = f;
 419         get_cvars_s = s;
 420         MUTATOR_CALLHOOK(GetCvars);
 421
 422         Notification_GetCvars(this);
 423
 424         ReplicateVars(this, store, s, f);
 425
 426         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 427         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 428         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 429         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 430         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(this, store, s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 437
 438         GetCvars_handleFloat(this, store, s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 439
 440         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 441         if (f > 0)
 442         {
 443                 if (s == "cl_weaponpriority")
 444                 {
 445                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 446                         {
 447                                 .entity weaponentity = weaponentities[slot];
 448                                 if (this.(weaponentity) && (this.(weaponentity).m_weapon != WEP_Null || slot == 0))
 449                                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 450                         }
 451                 }
 452                 if (s == "cl_allow_uidtracking")
 453                         PlayerStats_GameReport_AddPlayer(this);
 454         }
 455 }
 456
 457 // decolorizes and team colors the player name when needed
 458 string playername(entity p, bool team_colorize)
 459 {
 460     string t;
 461     if (team_colorize && teamplay && !intermission_running && IS_PLAYER(p))
 462     {
 463         t = Team_ColorCode(p.team);
 464         return strcat(t, strdecolorize(p.netname));
 465     }
 466     else
 467         return p.netname;
 468 }
 469
 470 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 471 {
 472         int i = weaponinfo.m_id;
 473         int d = 0;
 474         bool allow_mutatorblocked = false;
 475
 476         if(!i)
 477                 return 0;
 478
 479         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 480         d = M_ARGV(1, float);
 481         allguns = M_ARGV(2, bool);
 482         allow_mutatorblocked = M_ARGV(3, bool);
 483
 484         if(allguns)
 485         {
 486                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 487                         d = true;
 488                 else
 489                         d = false;
 490         }
 491         else if(!mutator_returnvalue)
 492                 d = !(!weaponinfo.weaponstart);
 493
 494         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 495                 d = 0;
 496
 497         float t = weaponinfo.weaponstartoverride;
 498
 499         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 500
 501         // bit order in t:
 502         // 1: want or not
 503         // 2: is default?
 504         // 4: is set by default?
 505         if(t < 0)
 506                 t = 4 | (3 * d);
 507         else
 508                 t |= (2 * d);
 509
 510         return t;
 511 }
 512
 513 void readplayerstartcvars()
 514 {
 515         float i, t;
 516         string s;
 517
 518         // initialize starting values for players
 519         start_weapons = '0 0 0';
 520         start_weapons_default = '0 0 0';
 521         start_weapons_defaultmask = '0 0 0';
 522         start_items = 0;
 523         start_ammo_shells = 0;
 524         start_ammo_nails = 0;
 525         start_ammo_rockets = 0;
 526         start_ammo_cells = 0;
 527         start_ammo_plasma = 0;
 528         if (random_start_ammo == NULL)
 529         {
 530                 random_start_ammo = spawn();
 531         }
 532         start_health = cvar("g_balance_health_start");
 533         start_armorvalue = cvar("g_balance_armor_start");
 534
 535         g_weaponarena = 0;
 536         g_weaponarena_weapons = '0 0 0';
 537
 538         s = cvar_string("g_weaponarena");
 539
 540         MUTATOR_CALLHOOK(SetWeaponArena, s);
 541         s = M_ARGV(0, string);
 542
 543         if (s == "0" || s == "")
 544         {
 545                 // no arena
 546         }
 547         else if (s == "off")
 548         {
 549                 // forcibly turn off weaponarena
 550         }
 551         else if (s == "all" || s == "1")
 552         {
 553                 g_weaponarena = 1;
 554                 g_weaponarena_list = "All Weapons";
 555                 FOREACH(Weapons, it != WEP_Null, {
 556                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 557                                 g_weaponarena_weapons |= (it.m_wepset);
 558                 });
 559         }
 560         else if (s == "devall")
 561         {
 562                 g_weaponarena = 1;
 563                 g_weaponarena_list = "All Weapons"; // TODO: report as more than just all weapons?
 564                 FOREACH(Weapons, it != WEP_Null,
 565                 {
 566                         g_weaponarena_weapons |= (it.m_wepset);
 567                 });
 568         }
 569         else if (s == "most")
 570         {
 571                 g_weaponarena = 1;
 572                 g_weaponarena_list = "Most Weapons";
 573                 FOREACH(Weapons, it != WEP_Null, {
 574                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 575                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 576                                         g_weaponarena_weapons |= (it.m_wepset);
 577                 });
 578         }
 579         else if (s == "none")
 580         {
 581                 g_weaponarena = 1;
 582                 g_weaponarena_list = "No Weapons";
 583         }
 584         else
 585         {
 586                 g_weaponarena = 1;
 587                 t = tokenize_console(s);
 588                 g_weaponarena_list = "";
 589                 for (i = 0; i < t; ++i)
 590                 {
 591                         s = argv(i);
 592                         FOREACH(Weapons, it != WEP_Null, {
 593                                 if(it.netname == s)
 594                                 {
 595                                         g_weaponarena_weapons |= (it.m_wepset);
 596                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 597                                         break;
 598                                 }
 599                         });
 600                 }
 601                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 602         }
 603
 604         if(g_weaponarena)
 605                 g_weaponarena_random = cvar("g_weaponarena_random");
 606         else
 607                 g_weaponarena_random = 0;
 608         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 609
 610         if (g_weaponarena)
 611         {
 612                 g_weapon_stay = 0; // incompatible
 613                 start_weapons = g_weaponarena_weapons;
 614                 start_items |= IT_UNLIMITED_AMMO;
 615         }
 616         else
 617         {
 618                 FOREACH(Weapons, it != WEP_Null, {
 619                         int w = want_weapon(it, false);
 620                         WepSet s = it.m_wepset;
 621                         if(w & 1)
 622                                 start_weapons |= s;
 623                         if(w & 2)
 624                                 start_weapons_default |= s;
 625                         if(w & 4)
 626                                 start_weapons_defaultmask |= s;
 627                 });
 628         }
 629
 630         if(!cvar("g_use_ammunition"))
 631                 start_items |= IT_UNLIMITED_AMMO;
 632
 633         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 634         {
 635                 start_ammo_shells = 999;
 636                 start_ammo_nails = 999;
 637                 start_ammo_rockets = 999;
 638                 start_ammo_cells = 999;
 639                 start_ammo_plasma = 999;
 640                 start_ammo_fuel = 999;
 641         }
 642         else
 643         {
 644                 start_ammo_shells = cvar("g_start_ammo_shells");
 645                 start_ammo_nails = cvar("g_start_ammo_nails");
 646                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 647                 start_ammo_cells = cvar("g_start_ammo_cells");
 648                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 649                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 650                 random_start_weapons_count = cvar("g_random_start_weapons_count");
 651                 SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, cvar(
 652                         "g_random_start_shells"));
 653                 SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, cvar(
 654                         "g_random_start_bullets"));
 655                 SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS,
 656                         cvar("g_random_start_rockets"));
 657                 SetResourceAmount(random_start_ammo, RESOURCE_CELLS, cvar(
 658                         "g_random_start_cells"));
 659                 SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, cvar(
 660                         "g_random_start_plasma"));
 661         }
 662
 663         if (warmup_stage)
 664         {
 665                 warmup_start_ammo_shells = start_ammo_shells;
 666                 warmup_start_ammo_nails = start_ammo_nails;
 667                 warmup_start_ammo_rockets = start_ammo_rockets;
 668                 warmup_start_ammo_cells = start_ammo_cells;
 669                 warmup_start_ammo_plasma = start_ammo_plasma;
 670                 warmup_start_ammo_fuel = start_ammo_fuel;
 671                 warmup_start_health = start_health;
 672                 warmup_start_armorvalue = start_armorvalue;
 673                 warmup_start_weapons = start_weapons;
 674                 warmup_start_weapons_default = start_weapons_default;
 675                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 676
 677                 if (!g_weaponarena && !g_ca && !g_freezetag)
 678                 {
 679                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 680                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 681                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 682                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 683                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 684                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 685                         warmup_start_health = cvar("g_warmup_start_health");
 686                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 687                         warmup_start_weapons = '0 0 0';
 688                         warmup_start_weapons_default = '0 0 0';
 689                         warmup_start_weapons_defaultmask = '0 0 0';
 690                         FOREACH(Weapons, it != WEP_Null, {
 691                                 int w = want_weapon(it, g_warmup_allguns);
 692                                 WepSet s = (it.m_wepset);
 693                                 if(w & 1)
 694                                         warmup_start_weapons |= s;
 695                                 if(w & 2)
 696                                         warmup_start_weapons_default |= s;
 697                                 if(w & 4)
 698                                         warmup_start_weapons_defaultmask |= s;
 699                         });
 700                 }
 701         }
 702
 703         if (g_jetpack)
 704                 start_items |= ITEM_Jetpack.m_itemid;
 705
 706         MUTATOR_CALLHOOK(SetStartItems);
 707
 708         if (start_items & ITEM_Jetpack.m_itemid)
 709         {
 710                 start_items |= ITEM_JetpackRegen.m_itemid;
 711                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 712                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 713         }
 714
 715         WepSet precache_weapons = start_weapons;
 716         if (g_warmup_allguns != 1)
 717                 precache_weapons |= warmup_start_weapons;
 718         FOREACH(Weapons, it != WEP_Null, {
 719                 if(precache_weapons & (it.m_wepset))
 720                         it.wr_init(it);
 721         });
 722
 723         start_ammo_shells = max(0, start_ammo_shells);
 724         start_ammo_nails = max(0, start_ammo_nails);
 725         start_ammo_rockets = max(0, start_ammo_rockets);
 726         start_ammo_cells = max(0, start_ammo_cells);
 727         start_ammo_plasma = max(0, start_ammo_plasma);
 728         start_ammo_fuel = max(0, start_ammo_fuel);
 729         SetResourceAmount(random_start_ammo, RESOURCE_SHELLS, max(0,
 730                 GetResourceAmount(random_start_ammo, RESOURCE_SHELLS)));
 731         SetResourceAmount(random_start_ammo, RESOURCE_BULLETS, max(0,
 732                 GetResourceAmount(random_start_ammo, RESOURCE_BULLETS)));
 733         SetResourceAmount(random_start_ammo, RESOURCE_ROCKETS, max(0,
 734                 GetResourceAmount(random_start_ammo, RESOURCE_ROCKETS)));
 735         SetResourceAmount(random_start_ammo, RESOURCE_CELLS, max(0,
 736                 GetResourceAmount(random_start_ammo, RESOURCE_CELLS)));
 737         SetResourceAmount(random_start_ammo, RESOURCE_PLASMA, max(0,
 738                 GetResourceAmount(random_start_ammo, RESOURCE_PLASMA)));
 739
 740         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 741         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 742         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 743         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 744         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 745         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 746 }
 747
 748 void precache_playermodel(string m)
 749 {
 750         float globhandle, i, n;
 751         string f;
 752
 753         if(substring(m, -9,5) == "_lod1")
 754                 return;
 755         if(substring(m, -9,5) == "_lod2")
 756                 return;
 757         precache_model(m);
 758         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 759         if(fexists(f))
 760                 precache_model(f);
 761         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 762         if(fexists(f))
 763                 precache_model(f);
 764
 765         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 766         if (globhandle < 0)
 767                 return;
 768         n = search_getsize(globhandle);
 769         for (i = 0; i < n; ++i)
 770         {
 771                 //print(search_getfilename(globhandle, i), "\n");
 772                 f = search_getfilename(globhandle, i);
 773                 PrecachePlayerSounds(f);
 774         }
 775         search_end(globhandle);
 776 }
 777 void precache_all_playermodels(string pattern)
 778 {
 779         int globhandle = search_begin(pattern, true, false);
 780         if (globhandle < 0) return;
 781         int n = search_getsize(globhandle);
 782         for (int i = 0; i < n; ++i)
 783         {
 784                 string s = search_getfilename(globhandle, i);
 785                 precache_playermodel(s);
 786         }
 787         search_end(globhandle);
 788 }
 789
 790 void precache_playermodels(string s)
 791 {
 792         FOREACH_WORD(s, true, { precache_playermodel(it); });
 793 }
 794
 795 void precache()
 796 {
 797     // gamemode related things
 798
 799     // Precache all player models if desired
 800     if (autocvar_sv_precacheplayermodels)
 801     {
 802         PrecachePlayerSounds("sound/player/default.sounds");
 803         precache_all_playermodels("models/player/*.zym");
 804         precache_all_playermodels("models/player/*.dpm");
 805         precache_all_playermodels("models/player/*.md3");
 806         precache_all_playermodels("models/player/*.psk");
 807         precache_all_playermodels("models/player/*.iqm");
 808     }
 809
 810     if (autocvar_sv_defaultcharacter)
 811     {
 812                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 813                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 814                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 815                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 816                 precache_playermodels(autocvar_sv_defaultplayermodel);
 817     }
 818
 819 #if 0
 820     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 821
 822     if (!this.noise && this.music) // quake 3 uses the music field
 823         this.noise = this.music;
 824
 825     // plays music for the level if there is any
 826     if (this.noise)
 827     {
 828         precache_sound (this.noise);
 829         ambientsound ('0 0 0', this.noise, VOL_BASE, ATTEN_NONE);
 830     }
 831 #endif
 832 }
 833
 834
 835 void make_safe_for_remove(entity e)
 836 {
 837     if (e.initialize_entity)
 838     {
 839         entity ent, prev = NULL;
 840         for (ent = initialize_entity_first; ent; )
 841         {
 842             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 843             {
 844                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 845                 // skip it in linked list
 846                 if (prev)
 847                 {
 848                     prev.initialize_entity_next = ent.initialize_entity_next;
 849                     ent = prev.initialize_entity_next;
 850                 }
 851                 else
 852                 {
 853                     initialize_entity_first = ent.initialize_entity_next;
 854                     ent = initialize_entity_first;
 855                 }
 856             }
 857             else
 858             {
 859                 prev = ent;
 860                 ent = ent.initialize_entity_next;
 861             }
 862         }
 863     }
 864 }
 865
 866 .float remove_except_protected_forbidden;
 867 void remove_except_protected(entity e)
 868 {
 869         if(e.remove_except_protected_forbidden)
 870                 error("not allowed to remove this at this point");
 871         builtin_remove(e);
 872 }
 873
 874 void remove_unsafely(entity e)
 875 {
 876     if(e.classname == "spike")
 877         error("Removing spikes is forbidden (crylink bug), please report");
 878     builtin_remove(e);
 879 }
 880
 881 void remove_safely(entity e)
 882 {
 883     make_safe_for_remove(e);
 884     builtin_remove(e);
 885 }
 886
 887 void InitializeEntity(entity e, void(entity this) func, float order)
 888 {
 889     entity prev, cur;
 890
 891     if (!e || e.initialize_entity)
 892     {
 893         // make a proxy initializer entity
 894         entity e_old = e;
 895         e = new(initialize_entity);
 896         e.enemy = e_old;
 897     }
 898
 899     e.initialize_entity = func;
 900     e.initialize_entity_order = order;
 901
 902     cur = initialize_entity_first;
 903     prev = NULL;
 904     for (;;)
 905     {
 906         if (!cur || cur.initialize_entity_order > order)
 907         {
 908             // insert between prev and cur
 909             if (prev)
 910                 prev.initialize_entity_next = e;
 911             else
 912                 initialize_entity_first = e;
 913             e.initialize_entity_next = cur;
 914             return;
 915         }
 916         prev = cur;
 917         cur = cur.initialize_entity_next;
 918     }
 919 }
 920 void InitializeEntitiesRun()
 921 {
 922     entity startoflist = initialize_entity_first;
 923     initialize_entity_first = NULL;
 924     delete_fn = remove_except_protected;
 925     for (entity e = startoflist; e; e = e.initialize_entity_next)
 926     {
 927                 e.remove_except_protected_forbidden = 1;
 928     }
 929     for (entity e = startoflist; e; )
 930     {
 931                 e.remove_except_protected_forbidden = 0;
 932         e.initialize_entity_order = 0;
 933         entity next = e.initialize_entity_next;
 934         e.initialize_entity_next = NULL;
 935         var void(entity this) func = e.initialize_entity;
 936         e.initialize_entity = func_null;
 937         if (e.classname == "initialize_entity")
 938         {
 939             entity wrappee = e.enemy;
 940             builtin_remove(e);
 941             e = wrappee;
 942         }
 943         //dprint("Delayed initialization: ", e.classname, "\n");
 944         if (func)
 945         {
 946                 func(e);
 947         }
 948         else
 949         {
 950             eprint(e);
 951             backtrace(strcat("Null function in: ", e.classname, "\n"));
 952         }
 953         e = next;
 954     }
 955     delete_fn = remove_unsafely;
 956 }
 957
 958 .float(entity) isEliminated;
 959 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 960 {
 961         Stream out = MSG_ENTITY;
 962         WriteHeader(out, ENT_CLIENT_ELIMINATEDPLAYERS);
 963         serialize(byte, out, sendflags);
 964         if (sendflags & 1) {
 965                 for (int i = 1; i <= maxclients; i += 8) {
 966                         int f = 0;
 967                         entity e = edict_num(i);
 968                         for (int b = 0; b < 8; ++b, e = nextent(e)) {
 969                                 if (eliminatedPlayers.isEliminated(e)) {
 970                                         f |= BIT(b);
 971                                 }
 972                         }
 973                         serialize(byte, out, f);
 974                 }
 975         }
 976         return true;
 977 }
 978
 979 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 980 {
 981         if(eliminatedPlayers)
 982         {
 983                 backtrace("Can't spawn eliminatedPlayers again!");
 984                 return;
 985         }
 986         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 987         eliminatedPlayers.isEliminated = isEliminated_func;
 988 }
 989
 990
 991
 992
 993 void adaptor_think2use_hittype_splash(entity this) // for timed projectile detonation
 994 {
 995         if(!(IS_ONGROUND(this))) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 996                 this.projectiledeathtype |= HITTYPE_SPLASH;
 997         adaptor_think2use(this);
 998 }
 999
1000 // deferred dropping
1001 void DropToFloor_Handler(entity this)
1002 {
1003     WITHSELF(this, builtin_droptofloor());
1004     this.dropped_origin = this.origin;
1005 }
1006
1007 void droptofloor(entity this)
1008 {
1009     InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1010 }
1011
1012
1013
1014 float trace_hits_box_a0, trace_hits_box_a1;
1015
1016 float trace_hits_box_1d(float end, float thmi, float thma)
1017 {
1018     if (end == 0)
1019     {
1020         // just check if x is in range
1021         if (0 < thmi)
1022             return false;
1023         if (0 > thma)
1024             return false;
1025     }
1026     else
1027     {
1028         // do the trace with respect to x
1029         // 0 -> end has to stay in thmi -> thma
1030         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1031         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1032         if (trace_hits_box_a0 > trace_hits_box_a1)
1033             return false;
1034     }
1035     return true;
1036 }
1037
1038 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1039 {
1040     end -= start;
1041     thmi -= start;
1042     thma -= start;
1043     // now it is a trace from 0 to end
1044
1045     trace_hits_box_a0 = 0;
1046     trace_hits_box_a1 = 1;
1047
1048     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1049         return false;
1050     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1051         return false;
1052     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1053         return false;
1054
1055     return true;
1056 }
1057
1058 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1059 {
1060     return trace_hits_box(start, end, thmi - ma, thma - mi);
1061 }
1062
1063 bool SUB_NoImpactCheck(entity this, entity toucher)
1064 {
1065         // zero hitcontents = this is not the real impact, but either the
1066         // mirror-impact of something hitting the projectile instead of the
1067         // projectile hitting the something, or a touchareagrid one. Neither of
1068         // these stop the projectile from moving, so...
1069         if(trace_dphitcontents == 0)
1070         {
1071                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct. (edict: %i, classname: %s, origin: %v)", this, this.classname, this.origin);
1072                 checkclient(this);
1073         }
1074     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1075         return true;
1076     if (toucher == NULL && this.size != '0 0 0')
1077     {
1078         vector tic;
1079         tic = this.velocity * sys_frametime;
1080         tic = tic + normalize(tic) * vlen(this.maxs - this.mins);
1081         traceline(this.origin - tic, this.origin + tic, MOVE_NORMAL, this);
1082         if (trace_fraction >= 1)
1083         {
1084             LOG_TRACE("Odd... did not hit...?");
1085         }
1086         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1087         {
1088             LOG_TRACE("Detected and prevented the sky-grapple bug.");
1089             return true;
1090         }
1091     }
1092
1093     return false;
1094 }
1095
1096 #define SUB_OwnerCheck(ent,oth) ((oth) && ((oth) == (ent).owner))
1097
1098 void W_Crylink_Dequeue(entity e);
1099 bool WarpZone_Projectile_Touch_ImpactFilter_Callback(entity this, entity toucher)
1100 {
1101         if(SUB_OwnerCheck(this, toucher))
1102                 return true;
1103         if(SUB_NoImpactCheck(this, toucher))
1104         {
1105                 if(this.classname == "nade")
1106                         return false; // no checks here
1107                 else if(this.classname == "grapplinghook")
1108                         RemoveHook(this);
1109                 else if(this.classname == "spike")
1110                 {
1111                         W_Crylink_Dequeue(this);
1112                         delete(this);
1113                 }
1114                 else
1115                         delete(this);
1116                 return true;
1117         }
1118         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1119                 UpdateCSQCProjectile(this);
1120         return false;
1121 }
1122
1123 /** engine callback */
1124 void URI_Get_Callback(float id, float status, string data)
1125 {
1126         if(url_URI_Get_Callback(id, status, data))
1127         {
1128                 // handled
1129         }
1130         else if (id == URI_GET_DISCARD)
1131         {
1132                 // discard
1133         }
1134         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1135         {
1136                 // sv_cmd curl
1137                 Curl_URI_Get_Callback(id, status, data);
1138         }
1139         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1140         {
1141                 // online ban list
1142                 OnlineBanList_URI_Get_Callback(id, status, data);
1143         }
1144         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
1145         {
1146                 // handled by a mutator
1147         }
1148         else
1149         {
1150                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
1151         }
1152 }
1153
1154 string uid2name(string myuid) {
1155         string s;
1156         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1157
1158         // FIXME remove this later after 0.6 release
1159         // convert old style broken records to correct style
1160         if(s == "")
1161         {
1162                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1163                 if(s != "")
1164                 {
1165                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1166                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1167                 }
1168         }
1169
1170         if(s == "")
1171                 s = "^1Unregistered Player";
1172         return s;
1173 }
1174
1175 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1176 {
1177     float m, i;
1178     vector start, org, delta, end, enddown, mstart;
1179
1180     m = e.dphitcontentsmask;
1181     e.dphitcontentsmask = goodcontents | badcontents;
1182
1183     org = boundmin;
1184     delta = boundmax - boundmin;
1185
1186     start = end = org;
1187
1188     for (i = 0; i < attempts; ++i)
1189     {
1190         start.x = org.x + random() * delta.x;
1191         start.y = org.y + random() * delta.y;
1192         start.z = org.z + random() * delta.z;
1193
1194         // rule 1: start inside world bounds, and outside
1195         // solid, and don't start from somewhere where you can
1196         // fall down to evil
1197         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1198         if (trace_fraction >= 1)
1199             continue;
1200         if (trace_startsolid)
1201             continue;
1202         if (trace_dphitcontents & badcontents)
1203             continue;
1204         if (trace_dphitq3surfaceflags & badsurfaceflags)
1205             continue;
1206
1207         // rule 2: if we are too high, lower the point
1208         if (trace_fraction * delta.z > maxaboveground)
1209             start = trace_endpos + '0 0 1' * maxaboveground;
1210         enddown = trace_endpos;
1211
1212         // rule 3: make sure we aren't outside the map. This only works
1213         // for somewhat well formed maps. A good rule of thumb is that
1214         // the map should have a convex outside hull.
1215         // these can be traceLINES as we already verified the starting box
1216         mstart = start + 0.5 * (e.mins + e.maxs);
1217         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1230         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1231             continue;
1232
1233         // rule 4: we must "see" some spawnpoint or item
1234     entity sp = NULL;
1235     IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1236     {
1237         if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1238         {
1239                 sp = it;
1240                 break;
1241         }
1242     });
1243         if(!sp)
1244         {
1245                 IL_EACH(g_items, checkpvs(mstart, it),
1246                 {
1247                         if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1248                         {
1249                                 sp = it;
1250                                 break;
1251                         }
1252                 });
1253
1254                 if(!sp)
1255                         continue;
1256         }
1257
1258         // find a random vector to "look at"
1259         end.x = org.x + random() * delta.x;
1260         end.y = org.y + random() * delta.y;
1261         end.z = org.z + random() * delta.z;
1262         end = start + normalize(end - start) * vlen(delta);
1263
1264         // rule 4: start TO end must not be too short
1265         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1266         if (trace_startsolid)
1267             continue;
1268         if (trace_fraction < minviewdistance / vlen(delta))
1269             continue;
1270
1271         // rule 5: don't want to look at sky
1272         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1273             continue;
1274
1275         // rule 6: we must not end up in trigger_hurt
1276         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1277             continue;
1278
1279         break;
1280     }
1281
1282     e.dphitcontentsmask = m;
1283
1284     if (i < attempts)
1285     {
1286         setorigin(e, start);
1287         e.angles = vectoangles(end - start);
1288         LOG_DEBUG("Needed ", ftos(i + 1), " attempts");
1289         return true;
1290     }
1291     else
1292         return false;
1293 }
1294
1295 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1296 {
1297         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1298 }
1299
1300 void write_recordmarker(entity pl, float tstart, float dt)
1301 {
1302     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1303
1304     // also write a marker into demo files for demotc-race-record-extractor to find
1305     stuffcmd(pl,
1306              strcat(
1307                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1308                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1309 }
1310
1311 void attach_sameorigin(entity e, entity to, string tag)
1312 {
1313     vector org, t_forward, t_left, t_up, e_forward, e_up;
1314     float tagscale;
1315
1316     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1317     tagscale = (vlen(v_forward) ** -2); // undo a scale on the tag
1318     t_forward = v_forward * tagscale;
1319     t_left = v_right * -tagscale;
1320     t_up = v_up * tagscale;
1321
1322     e.origin_x = org * t_forward;
1323     e.origin_y = org * t_left;
1324     e.origin_z = org * t_up;
1325
1326     // current forward and up directions
1327     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1328                 e.angles = AnglesTransform_FromVAngles(e.angles);
1329         else
1330                 e.angles = AnglesTransform_FromAngles(e.angles);
1331     fixedmakevectors(e.angles);
1332
1333     // untransform forward, up!
1334     e_forward.x = v_forward * t_forward;
1335     e_forward.y = v_forward * t_left;
1336     e_forward.z = v_forward * t_up;
1337     e_up.x = v_up * t_forward;
1338     e_up.y = v_up * t_left;
1339     e_up.z = v_up * t_up;
1340
1341     e.angles = fixedvectoangles2(e_forward, e_up);
1342     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1343                 e.angles = AnglesTransform_ToVAngles(e.angles);
1344         else
1345                 e.angles = AnglesTransform_ToAngles(e.angles);
1346
1347     setattachment(e, to, tag);
1348     setorigin(e, e.origin);
1349 }
1350
1351 void detach_sameorigin(entity e)
1352 {
1353     vector org;
1354     org = gettaginfo(e, 0);
1355     e.angles = fixedvectoangles2(v_forward, v_up);
1356     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1357                 e.angles = AnglesTransform_ToVAngles(e.angles);
1358         else
1359                 e.angles = AnglesTransform_ToAngles(e.angles);
1360     setorigin(e, org);
1361     setattachment(e, NULL, "");
1362     setorigin(e, e.origin);
1363 }
1364
1365 void follow_sameorigin(entity e, entity to)
1366 {
1367     set_movetype(e, MOVETYPE_FOLLOW); // make the hole follow
1368     e.aiment = to; // make the hole follow bmodel
1369     e.punchangle = to.angles; // the original angles of bmodel
1370     e.view_ofs = e.origin - to.origin; // relative origin
1371     e.v_angle = e.angles - to.angles; // relative angles
1372 }
1373
1374 void unfollow_sameorigin(entity e)
1375 {
1376     set_movetype(e, MOVETYPE_NONE);
1377 }
1378
1379 entity gettaginfo_relative_ent;
1380 vector gettaginfo_relative(entity e, float tag)
1381 {
1382     if (!gettaginfo_relative_ent)
1383     {
1384         gettaginfo_relative_ent = spawn();
1385         gettaginfo_relative_ent.effects = EF_NODRAW;
1386     }
1387     gettaginfo_relative_ent.model = e.model;
1388     gettaginfo_relative_ent.modelindex = e.modelindex;
1389     gettaginfo_relative_ent.frame = e.frame;
1390     return gettaginfo(gettaginfo_relative_ent, tag);
1391 }
1392
1393 .string aiment_classname;
1394 .float aiment_deadflag;
1395 void SetMovetypeFollow(entity ent, entity e)
1396 {
1397         // FIXME this may not be warpzone aware
1398         set_movetype(ent, MOVETYPE_FOLLOW); // make the hole follow
1399         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1400         ent.aiment = e; // make the hole follow bmodel
1401         ent.punchangle = e.angles; // the original angles of bmodel
1402         ent.view_ofs = ent.origin - e.origin; // relative origin
1403         ent.v_angle = ent.angles - e.angles; // relative angles
1404         ent.aiment_classname = strzone(e.classname);
1405         ent.aiment_deadflag = e.deadflag;
1406 }
1407 void UnsetMovetypeFollow(entity ent)
1408 {
1409         set_movetype(ent, MOVETYPE_FLY);
1410         PROJECTILE_MAKETRIGGER(ent);
1411         ent.aiment = NULL;
1412 }
1413 float LostMovetypeFollow(entity ent)
1414 {
1415 /*
1416         if(ent.move_movetype != MOVETYPE_FOLLOW)
1417                 if(ent.aiment)
1418                         error("???");
1419 */
1420         if(ent.aiment)
1421         {
1422                 if(ent.aiment.classname != ent.aiment_classname)
1423                         return 1;
1424                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1425                         return 1;
1426         }
1427         return 0;
1428 }
1429
1430 .bool pushable;
1431 bool isPushable(entity e)
1432 {
1433         if(e.pushable)
1434                 return true;
1435         if(IS_VEHICLE(e))
1436                 return false;
1437         if(e.iscreature)
1438                 return true;
1439         switch(e.classname)
1440         {
1441                 case "body":
1442                 case "droppedweapon":
1443                         return true;
1444                 case "bullet": // antilagged bullets can't hit this either
1445                         return false;
1446         }
1447         if (e.projectiledeathtype)
1448                 return true;
1449         return false;
1450 }