qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = WEP_NAME(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else if (self.items & IT_PLASMA) replacement = "plasma";
 365                         else replacement = "batteries"; // ;)
 366                 } else if (escape == "x") {
 367                         replacement = cursor_ent.netname;
 368                         if (replacement == "" || !cursor_ent)
 369                                 replacement = "nothing";
 370                 } else if (escape == "s")
 371                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 372                 else if (escape == "S")
 373                         replacement = ftos(vlen(self.velocity));
 374
 375                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 376                 p = p + strlen(replacement);
 377         }
 378         return msg;
 379 }
 380
 381 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 382         return (value == 0) ? FALSE : TRUE;
 383 }
 384
 385 /*
 386 =============
 387 GetCvars
 388 =============
 389 Called with:
 390   0:  sends the request
 391   >0: receives a cvar from name=argv(f) value=argv(f+1)
 392 */
 393 void GetCvars_handleString(string thisname, float f, .string field, string name)
 394 {
 395         if (f < 0)
 396         {
 397                 if (self.field)
 398                         strunzone(self.field);
 399                 self.field = string_null;
 400         }
 401         else if (f > 0)
 402         {
 403                 if (thisname == name)
 404                 {
 405                         if (self.field)
 406                                 strunzone(self.field);
 407                         self.field = strzone(argv(f + 1));
 408                 }
 409         }
 410         else
 411                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 412 }
 413 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 414 {
 415         GetCvars_handleString(thisname, f, field, name);
 416         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 417                 if (thisname == name)
 418                 {
 419                         string s;
 420                         s = func(strcat1(self.field));
 421                         if (s != self.field)
 422                         {
 423                                 strunzone(self.field);
 424                                 self.field = strzone(s);
 425                         }
 426                 }
 427 }
 428 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 429 {
 430         if (f < 0)
 431         {
 432         }
 433         else if (f > 0)
 434         {
 435                 if (thisname == name)
 436                         self.field = stof(argv(f + 1));
 437         }
 438         else
 439                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 440 }
 441 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 442 {
 443         if (f < 0)
 444         {
 445         }
 446         else if (f > 0)
 447         {
 448                 if (thisname == name)
 449                 {
 450                         if(!self.field)
 451                         {
 452                                 self.field = stof(argv(f + 1));
 453                                 if(!self.field)
 454                                         self.field = -1;
 455                         }
 456                 }
 457         }
 458         else
 459         {
 460                 if(!self.field)
 461                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462         }
 463 }
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 493         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 494         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 495         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 507         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 508         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 509         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 511         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 513         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 514
 515         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 516         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 517
 518         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 520         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 521         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 522         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 523
 524         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 525         if (f > 0)
 526         {
 527                 if (s == "cl_weaponpriority")
 528                         self.switchweapon = w_getbestweapon(self);
 529                 if (s == "cl_allow_uidtracking")
 530                         PlayerStats_GameReport_AddPlayer(self);
 531         }
 532 }
 533
 534 // decolorizes and team colors the player name when needed
 535 string playername(entity p)
 536 {
 537     string t;
 538     if (teamplay && !intermission_running && IS_PLAYER(p))
 539     {
 540         t = Team_ColorCode(p.team);
 541         return strcat(t, strdecolorize(p.netname));
 542     }
 543     else
 544         return p.netname;
 545 }
 546
 547 //#NO AUTOCVARS START
 548
 549 float g_pickup_shells;
 550 float g_pickup_shells_max;
 551 float g_pickup_nails;
 552 float g_pickup_nails_max;
 553 float g_pickup_rockets;
 554 float g_pickup_rockets_max;
 555 float g_pickup_cells;
 556 float g_pickup_cells_max;
 557 float g_pickup_plasma;
 558 float g_pickup_plasma_max;
 559 float g_pickup_fuel;
 560 float g_pickup_fuel_jetpack;
 561 float g_pickup_fuel_max;
 562 float g_pickup_armorsmall;
 563 float g_pickup_armorsmall_max;
 564 float g_pickup_armorsmall_anyway;
 565 float g_pickup_armormedium;
 566 float g_pickup_armormedium_max;
 567 float g_pickup_armormedium_anyway;
 568 float g_pickup_armorbig;
 569 float g_pickup_armorbig_max;
 570 float g_pickup_armorbig_anyway;
 571 float g_pickup_armorlarge;
 572 float g_pickup_armorlarge_max;
 573 float g_pickup_armorlarge_anyway;
 574 float g_pickup_healthsmall;
 575 float g_pickup_healthsmall_max;
 576 float g_pickup_healthsmall_anyway;
 577 float g_pickup_healthmedium;
 578 float g_pickup_healthmedium_max;
 579 float g_pickup_healthmedium_anyway;
 580 float g_pickup_healthlarge;
 581 float g_pickup_healthlarge_max;
 582 float g_pickup_healthlarge_anyway;
 583 float g_pickup_healthmega;
 584 float g_pickup_healthmega_max;
 585 float g_pickup_healthmega_anyway;
 586 float g_pickup_ammo_anyway;
 587 float g_pickup_weapons_anyway;
 588 float g_weaponarena;
 589 WepSet g_weaponarena_weapons;
 590 float g_weaponarena_random;
 591 float g_weaponarena_random_with_blaster;
 592 string g_weaponarena_list;
 593 float g_weaponspeedfactor;
 594 float g_weaponratefactor;
 595 float g_weapondamagefactor;
 596 float g_weaponforcefactor;
 597 float g_weaponspreadfactor;
 598
 599 WepSet start_weapons;
 600 WepSet start_weapons_default;
 601 WepSet start_weapons_defaultmask;
 602 float start_items;
 603 float start_ammo_shells;
 604 float start_ammo_nails;
 605 float start_ammo_rockets;
 606 float start_ammo_cells;
 607 float start_ammo_plasma;
 608 float start_ammo_fuel;
 609 float start_health;
 610 float start_armorvalue;
 611 WepSet warmup_start_weapons;
 612 WepSet warmup_start_weapons_default;
 613 WepSet warmup_start_weapons_defaultmask;
 614 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 615 float warmup_start_ammo_shells;
 616 float warmup_start_ammo_nails;
 617 float warmup_start_ammo_rockets;
 618 float warmup_start_ammo_cells;
 619 float warmup_start_ammo_plasma;
 620 float warmup_start_ammo_fuel;
 621 float warmup_start_health;
 622 float warmup_start_armorvalue;
 623 float g_weapon_stay;
 624
 625 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 626 {
 627         var float i = weaponinfo.weapon;
 628         var float d = 0;
 629
 630         if (!i)
 631                 return 0;
 632
 633         if (g_lms || g_ca || allguns)
 634         {
 635                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 636                         d = TRUE;
 637                 else
 638                         d = FALSE;
 639         }
 640         else if (g_cts)
 641                 d = (i == WEP_SHOTGUN);
 642         else if (g_nexball)
 643                 d = 0; // weapon is set a few lines later
 644         else
 645                 d = !(!weaponinfo.weaponstart);
 646
 647         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 648                 d |= (i == WEP_HOOK);
 649         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 650                 d = 0;
 651
 652         var float t = weaponinfo.weaponstartoverride;
 653
 654         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 655
 656         // bit order in t:
 657         // 1: want or not
 658         // 2: is default?
 659         // 4: is set by default?
 660         if(t < 0)
 661                 t = 4 | (3 * d);
 662         else
 663                 t |= (2 * d);
 664
 665         return t;
 666 }
 667
 668 void readplayerstartcvars()
 669 {
 670         entity e;
 671         float i, j, t;
 672         string s;
 673
 674         // initialize starting values for players
 675         start_weapons = '0 0 0';
 676         start_weapons_default = '0 0 0';
 677         start_weapons_defaultmask = '0 0 0';
 678         start_items = 0;
 679         start_ammo_shells = 0;
 680         start_ammo_nails = 0;
 681         start_ammo_rockets = 0;
 682         start_ammo_cells = 0;
 683         start_ammo_plasma = 0;
 684         start_health = cvar("g_balance_health_start");
 685         start_armorvalue = cvar("g_balance_armor_start");
 686
 687         g_weaponarena = 0;
 688         g_weaponarena_weapons = '0 0 0';
 689
 690         s = cvar_string("g_weaponarena");
 691         if (s == "0" || s == "")
 692         {
 693                 if(g_ca)
 694                         s = "most";
 695         }
 696
 697         if (s == "0" || s == "")
 698         {
 699                 // no arena
 700         }
 701         else if (s == "off")
 702         {
 703                 // forcibly turn off weaponarena
 704         }
 705         else if (s == "all" || s == "1")
 706         {
 707                 g_weaponarena = 1;
 708                 g_weaponarena_list = "All Weapons";
 709                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 710                 {
 711                         e = get_weaponinfo(j);
 712                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 713                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 714                 }
 715         }
 716         else if (s == "most")
 717         {
 718                 g_weaponarena = 1;
 719                 g_weaponarena_list = "Most Weapons";
 720                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 721                 {
 722                         e = get_weaponinfo(j);
 723                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 724                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 725                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 726                 }
 727         }
 728         else if (s == "none")
 729         {
 730                 g_weaponarena = 1;
 731                 g_weaponarena_list = "No Weapons";
 732         }
 733         else
 734         {
 735                 g_weaponarena = 1;
 736                 t = tokenize_console(s);
 737                 g_weaponarena_list = "";
 738                 for (i = 0; i < t; ++i)
 739                 {
 740                         s = argv(i);
 741                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 742                         {
 743                                 e = get_weaponinfo(j);
 744                                 if (e.netname == s)
 745                                 {
 746                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 747                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 748                                         break;
 749                                 }
 750                         }
 751                         if (j > WEP_LAST)
 752                         {
 753                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 754                         }
 755                 }
 756                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 757         }
 758
 759         if(g_weaponarena)
 760                 g_weaponarena_random = cvar("g_weaponarena_random");
 761         else
 762                 g_weaponarena_random = 0;
 763         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 764
 765         if (g_weaponarena)
 766         {
 767                 g_weapon_stay = 0; // incompatible
 768                 start_weapons = g_weaponarena_weapons;
 769                 start_items |= IT_UNLIMITED_AMMO;
 770         }
 771         else
 772         {
 773                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 774                 {
 775                         e = get_weaponinfo(i);
 776                         float w = want_weapon(e, FALSE);
 777                         if(w & 1)
 778                                 start_weapons |= WepSet_FromWeapon(i);
 779                         if(w & 2)
 780                                 start_weapons_default |= WepSet_FromWeapon(i);
 781                         if(w & 4)
 782                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 783                 }
 784         }
 785
 786         if(!cvar("g_use_ammunition"))
 787                 start_items |= IT_UNLIMITED_AMMO;
 788
 789         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 790         {
 791                 start_ammo_shells = 999;
 792                 start_ammo_nails = 999;
 793                 start_ammo_rockets = 999;
 794                 start_ammo_cells = 999;
 795                 start_ammo_plasma = 999;
 796                 start_ammo_fuel = 999;
 797         }
 798         else
 799         {
 800                 start_ammo_shells = cvar("g_start_ammo_shells");
 801                 start_ammo_nails = cvar("g_start_ammo_nails");
 802                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 803                 start_ammo_cells = cvar("g_start_ammo_cells");
 804                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 805                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 806         }
 807
 808         if (warmup_stage)
 809         {
 810                 warmup_start_ammo_shells = start_ammo_shells;
 811                 warmup_start_ammo_nails = start_ammo_nails;
 812                 warmup_start_ammo_rockets = start_ammo_rockets;
 813                 warmup_start_ammo_cells = start_ammo_cells;
 814                 warmup_start_ammo_plasma = start_ammo_plasma;
 815                 warmup_start_ammo_fuel = start_ammo_fuel;
 816                 warmup_start_health = start_health;
 817                 warmup_start_armorvalue = start_armorvalue;
 818                 warmup_start_weapons = start_weapons;
 819                 warmup_start_weapons_default = start_weapons_default;
 820                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 821
 822                 if (!g_weaponarena && !g_ca)
 823                 {
 824                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 825                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 826                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 827                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 828                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 829                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 830                         warmup_start_health = cvar("g_warmup_start_health");
 831                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 832                         warmup_start_weapons = '0 0 0';
 833                         warmup_start_weapons_default = '0 0 0';
 834                         warmup_start_weapons_defaultmask = '0 0 0';
 835                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 836                         {
 837                                 e = get_weaponinfo(i);
 838                                 float w = want_weapon(e, g_warmup_allguns);
 839                                 if(w & 1)
 840                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 841                                 if(w & 2)
 842                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 843                                 if(w & 4)
 844                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 845                         }
 846                 }
 847         }
 848
 849         if (g_jetpack)
 850                 start_items |= IT_JETPACK;
 851
 852         MUTATOR_CALLHOOK(SetStartItems);
 853
 854         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 855         {
 856                 start_items |= IT_FUEL_REGEN;
 857                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 858                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 859         }
 860
 861         WepSet precache_weapons = start_weapons;
 862         if (g_warmup_allguns != 1)
 863                 precache_weapons |= warmup_start_weapons;
 864         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 865         {
 866                 e = get_weaponinfo(i);
 867                 if(precache_weapons & WepSet_FromWeapon(i))
 868                         WEP_ACTION(i, WR_INIT);
 869         }
 870
 871         start_ammo_shells = max(0, start_ammo_shells);
 872         start_ammo_nails = max(0, start_ammo_nails);
 873         start_ammo_rockets = max(0, start_ammo_rockets);
 874         start_ammo_cells = max(0, start_ammo_cells);
 875         start_ammo_plasma = max(0, start_ammo_plasma);
 876         start_ammo_fuel = max(0, start_ammo_fuel);
 877
 878         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 879         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 880         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 881         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 882         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 883         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 884 }
 885
 886 float g_bugrigs;
 887 float g_bugrigs_planar_movement;
 888 float g_bugrigs_planar_movement_car_jumping;
 889 float g_bugrigs_reverse_spinning;
 890 float g_bugrigs_reverse_speeding;
 891 float g_bugrigs_reverse_stopping;
 892 float g_bugrigs_air_steering;
 893 float g_bugrigs_angle_smoothing;
 894 float g_bugrigs_friction_floor;
 895 float g_bugrigs_friction_brake;
 896 float g_bugrigs_friction_air;
 897 float g_bugrigs_accel;
 898 float g_bugrigs_speed_ref;
 899 float g_bugrigs_speed_pow;
 900 float g_bugrigs_steer;
 901
 902 float sv_autotaunt;
 903 float sv_taunt;
 904
 905 string GetGametype(); // g_world.qc
 906 void mutators_add(); // mutators.qc
 907 void readlevelcvars(void)
 908 {
 909         // load mutators
 910         mutators_add();
 911
 912         if(cvar("sv_allow_fullbright"))
 913                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 914
 915     g_bugrigs = cvar("g_bugrigs");
 916     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 917     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 918     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 919     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 920     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 921     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 922     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 923     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 924     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 925     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 926     g_bugrigs_accel = cvar("g_bugrigs_accel");
 927     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 928     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 929     g_bugrigs_steer = cvar("g_bugrigs_steer");
 930
 931         g_instagib = cvar("g_instagib");
 932
 933         sv_clones = cvar("sv_clones");
 934         sv_foginterval = cvar("sv_foginterval");
 935         g_cloaked = cvar("g_cloaked");
 936         g_footsteps = cvar("g_footsteps");
 937         g_grappling_hook = cvar("g_grappling_hook");
 938         g_jetpack = cvar("g_jetpack");
 939         sv_maxidle = cvar("sv_maxidle");
 940         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 941         sv_autotaunt = cvar("sv_autotaunt");
 942         sv_taunt = cvar("sv_taunt");
 943
 944         warmup_stage = cvar("g_warmup");
 945         g_warmup_limit = cvar("g_warmup_limit");
 946         g_warmup_allguns = cvar("g_warmup_allguns");
 947         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 948
 949         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 950                 warmup_stage = 0; // these modes cannot work together, sorry
 951
 952         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 953         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 954         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 955         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 956         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 957         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 958         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 959         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 960         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 961         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 962         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 963         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 964         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 965         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 966
 967         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 968         g_weaponratefactor = cvar("g_weaponratefactor");
 969         g_weapondamagefactor = cvar("g_weapondamagefactor");
 970         g_weaponforcefactor = cvar("g_weaponforcefactor");
 971         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 972
 973         g_pickup_shells = cvar("g_pickup_shells");
 974         g_pickup_shells_max = cvar("g_pickup_shells_max");
 975         g_pickup_nails = cvar("g_pickup_nails");
 976         g_pickup_nails_max = cvar("g_pickup_nails_max");
 977         g_pickup_rockets = cvar("g_pickup_rockets");
 978         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 979         g_pickup_cells = cvar("g_pickup_cells");
 980         g_pickup_cells_max = cvar("g_pickup_cells_max");
 981         g_pickup_plasma = cvar("g_pickup_plasma");
 982         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 983         g_pickup_fuel = cvar("g_pickup_fuel");
 984         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 985         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 986         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 987         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 988         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 989         g_pickup_armormedium = cvar("g_pickup_armormedium");
 990         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 991         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
 992         g_pickup_armorbig = cvar("g_pickup_armorbig");
 993         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
 994         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
 995         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
 996         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
 997         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
 998         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
 999         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1000         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1001         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1002         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1003         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1004         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1005         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1006         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1007         g_pickup_healthmega = cvar("g_pickup_healthmega");
1008         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1009         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1010
1011         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1012         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1013
1014     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1015     if(!g_weapon_stay)
1016         g_weapon_stay = cvar("g_weapon_stay");
1017
1018         if (!warmup_stage)
1019                 game_starttime = time + cvar("g_start_delay");
1020
1021         readplayerstartcvars();
1022 }
1023
1024 //#NO AUTOCVARS END
1025
1026 // Sound functions
1027 string precache_sound (string s) = #19;
1028 float precache_sound_index (string s) = #19;
1029
1030 #define SND_VOLUME      1
1031 #define SND_ATTENUATION 2
1032 #define SND_LARGEENTITY 8
1033 #define SND_LARGESOUND  16
1034
1035 float sound_allowed(float dest, entity e)
1036 {
1037     // sounds from world may always pass
1038     for (;;)
1039     {
1040         if (e.classname == "body")
1041             e = e.enemy;
1042         else if (e.realowner && e.realowner != e)
1043             e = e.realowner;
1044         else if (e.owner && e.owner != e)
1045             e = e.owner;
1046         else
1047             break;
1048     }
1049     // sounds to self may always pass
1050     if (dest == MSG_ONE)
1051         if (e == msg_entity)
1052             return TRUE;
1053     // sounds by players can be removed
1054     if (autocvar_bot_sound_monopoly)
1055         if (IS_REAL_CLIENT(e))
1056             return FALSE;
1057     // anything else may pass
1058     return TRUE;
1059 }
1060
1061 #undef sound
1062 void sound(entity e, float chan, string samp, float vol, float atten)
1063 {
1064     if (!sound_allowed(MSG_BROADCAST, e))
1065         return;
1066     sound7(e, chan, samp, vol, atten, 0, 0);
1067 }
1068
1069 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1070 {
1071     float entno, idx;
1072
1073     if (!sound_allowed(dest, e))
1074         return;
1075
1076     entno = num_for_edict(e);
1077     idx = precache_sound_index(samp);
1078
1079     float sflags;
1080     sflags = 0;
1081
1082     atten = floor(atten * 64);
1083     vol = floor(vol * 255);
1084
1085     if (vol != 255)
1086         sflags |= SND_VOLUME;
1087     if (atten != 64)
1088         sflags |= SND_ATTENUATION;
1089     if (entno >= 8192 || chan < 0 || chan > 7)
1090         sflags |= SND_LARGEENTITY;
1091     if (idx >= 256)
1092         sflags |= SND_LARGESOUND;
1093
1094     WriteByte(dest, SVC_SOUND);
1095     WriteByte(dest, sflags);
1096     if (sflags & SND_VOLUME)
1097         WriteByte(dest, vol);
1098     if (sflags & SND_ATTENUATION)
1099         WriteByte(dest, atten);
1100     if (sflags & SND_LARGEENTITY)
1101     {
1102         WriteShort(dest, entno);
1103         WriteByte(dest, chan);
1104     }
1105     else
1106     {
1107         WriteShort(dest, entno * 8 + chan);
1108     }
1109     if (sflags & SND_LARGESOUND)
1110         WriteShort(dest, idx);
1111     else
1112         WriteByte(dest, idx);
1113
1114     WriteCoord(dest, o_x);
1115     WriteCoord(dest, o_y);
1116     WriteCoord(dest, o_z);
1117 }
1118 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1119 {
1120     vector o;
1121
1122     if (!sound_allowed(dest, e))
1123         return;
1124
1125     o = e.origin + 0.5 * (e.mins + e.maxs);
1126     soundtoat(dest, e, o, chan, samp, vol, atten);
1127 }
1128 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1129 {
1130     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1131 }
1132 void stopsoundto(float dest, entity e, float chan)
1133 {
1134     float entno;
1135
1136     if (!sound_allowed(dest, e))
1137         return;
1138
1139     entno = num_for_edict(e);
1140
1141     if (entno >= 8192 || chan < 0 || chan > 7)
1142     {
1143         float idx, sflags;
1144         idx = precache_sound_index("misc/null.wav");
1145         sflags = SND_LARGEENTITY;
1146         if (idx >= 256)
1147             sflags |= SND_LARGESOUND;
1148         WriteByte(dest, SVC_SOUND);
1149         WriteByte(dest, sflags);
1150         WriteShort(dest, entno);
1151         WriteByte(dest, chan);
1152         if (sflags & SND_LARGESOUND)
1153             WriteShort(dest, idx);
1154         else
1155             WriteByte(dest, idx);
1156         WriteCoord(dest, e.origin_x);
1157         WriteCoord(dest, e.origin_y);
1158         WriteCoord(dest, e.origin_z);
1159     }
1160     else
1161     {
1162         WriteByte(dest, SVC_STOPSOUND);
1163         WriteShort(dest, entno * 8 + chan);
1164     }
1165 }
1166 void stopsound(entity e, float chan)
1167 {
1168     if (!sound_allowed(MSG_BROADCAST, e))
1169         return;
1170
1171     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1172     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1173 }
1174
1175 void play2(entity e, string filename)
1176 {
1177     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1178     msg_entity = e;
1179     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1180 }
1181
1182 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1183 .float spamtime;
1184 float spamsound(entity e, float chan, string samp, float vol, float atten)
1185 {
1186     if (!sound_allowed(MSG_BROADCAST, e))
1187         return FALSE;
1188
1189     if (time > e.spamtime)
1190     {
1191         e.spamtime = time;
1192         sound(e, chan, samp, vol, atten);
1193         return TRUE;
1194     }
1195     return FALSE;
1196 }
1197
1198 void play2team(float t, string filename)
1199 {
1200     entity head;
1201
1202     if (autocvar_bot_sound_monopoly)
1203         return;
1204
1205     FOR_EACH_REALPLAYER(head)
1206     {
1207         if (head.team == t)
1208             play2(head, filename);
1209     }
1210 }
1211
1212 void play2all(string samp)
1213 {
1214     if (autocvar_bot_sound_monopoly)
1215         return;
1216
1217     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1218 }
1219
1220 void PrecachePlayerSounds(string f);
1221 void precache_playermodel(string m)
1222 {
1223         float globhandle, i, n;
1224         string f;
1225
1226         if(substring(m, -9,5) == "_lod1")
1227                 return;
1228         if(substring(m, -9,5) == "_lod2")
1229                 return;
1230         precache_model(m);
1231         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1232         if(fexists(f))
1233                 precache_model(f);
1234         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1235         if(fexists(f))
1236                 precache_model(f);
1237
1238         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1239         if (globhandle < 0)
1240                 return;
1241         n = search_getsize(globhandle);
1242         for (i = 0; i < n; ++i)
1243         {
1244                 //print(search_getfilename(globhandle, i), "\n");
1245                 f = search_getfilename(globhandle, i);
1246                 PrecachePlayerSounds(f);
1247         }
1248         search_end(globhandle);
1249 }
1250 void precache_all_playermodels(string pattern)
1251 {
1252         float globhandle, i, n;
1253         string f;
1254
1255         globhandle = search_begin(pattern, TRUE, FALSE);
1256         if (globhandle < 0)
1257                 return;
1258         n = search_getsize(globhandle);
1259         for (i = 0; i < n; ++i)
1260         {
1261                 //print(search_getfilename(globhandle, i), "\n");
1262                 f = search_getfilename(globhandle, i);
1263                 precache_playermodel(f);
1264         }
1265         search_end(globhandle);
1266 }
1267
1268 void precache()
1269 {
1270     // gamemode related things
1271     precache_model ("models/misc/chatbubble.spr");
1272         precache_model("models/ice/ice.md3");
1273
1274 #ifdef TTURRETS_ENABLED
1275     if (autocvar_g_turrets)
1276         turrets_precash();
1277 #endif
1278
1279     // Precache all player models if desired
1280     if (autocvar_sv_precacheplayermodels)
1281     {
1282         PrecachePlayerSounds("sound/player/default.sounds");
1283         precache_all_playermodels("models/player/*.zym");
1284         precache_all_playermodels("models/player/*.dpm");
1285         precache_all_playermodels("models/player/*.md3");
1286         precache_all_playermodels("models/player/*.psk");
1287         precache_all_playermodels("models/player/*.iqm");
1288     }
1289
1290     if (autocvar_sv_defaultcharacter)
1291     {
1292         string s;
1293         s = autocvar_sv_defaultplayermodel_red;
1294         if (s != "")
1295             precache_playermodel(s);
1296         s = autocvar_sv_defaultplayermodel_blue;
1297         if (s != "")
1298             precache_playermodel(s);
1299         s = autocvar_sv_defaultplayermodel_yellow;
1300         if (s != "")
1301             precache_playermodel(s);
1302         s = autocvar_sv_defaultplayermodel_pink;
1303         if (s != "")
1304             precache_playermodel(s);
1305         s = autocvar_sv_defaultplayermodel;
1306         if (s != "")
1307             precache_playermodel(s);
1308     }
1309
1310     if (g_footsteps)
1311     {
1312         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1313         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1314     }
1315
1316     // gore and miscellaneous sounds
1317     //precache_sound ("misc/h2ohit.wav");
1318     precache_model ("models/hook.md3");
1319     precache_sound ("misc/armorimpact.wav");
1320     precache_sound ("misc/bodyimpact1.wav");
1321     precache_sound ("misc/bodyimpact2.wav");
1322     precache_sound ("misc/gib.wav");
1323     precache_sound ("misc/gib_splat01.wav");
1324     precache_sound ("misc/gib_splat02.wav");
1325     precache_sound ("misc/gib_splat03.wav");
1326     precache_sound ("misc/gib_splat04.wav");
1327     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1328     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1329     precache_sound ("misc/null.wav");
1330     precache_sound ("misc/spawn.wav");
1331     precache_sound ("misc/talk.wav");
1332     precache_sound ("misc/teleport.wav");
1333     precache_sound ("misc/poweroff.wav");
1334     precache_sound ("player/lava.wav");
1335     precache_sound ("player/slime.wav");
1336
1337     precache_model ("models/sprites/0.spr32");
1338     precache_model ("models/sprites/1.spr32");
1339     precache_model ("models/sprites/2.spr32");
1340     precache_model ("models/sprites/3.spr32");
1341     precache_model ("models/sprites/4.spr32");
1342     precache_model ("models/sprites/5.spr32");
1343     precache_model ("models/sprites/6.spr32");
1344     precache_model ("models/sprites/7.spr32");
1345     precache_model ("models/sprites/8.spr32");
1346     precache_model ("models/sprites/9.spr32");
1347     precache_model ("models/sprites/10.spr32");
1348
1349     // common weapon precaches
1350         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1351     precache_sound ("weapons/weapon_switch.wav");
1352     precache_sound ("weapons/weaponpickup.wav");
1353     precache_sound ("weapons/unavailable.wav");
1354     precache_sound ("weapons/dryfire.wav");
1355     if (g_grappling_hook)
1356     {
1357         precache_sound ("weapons/hook_fire.wav"); // hook
1358         precache_sound ("weapons/hook_impact.wav"); // hook
1359     }
1360
1361     precache_model("models/elaser.mdl");
1362     precache_model("models/laser.mdl");
1363     precache_model("models/ebomb.mdl");
1364
1365 #if 0
1366     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1367
1368     if (!self.noise && self.music) // quake 3 uses the music field
1369         self.noise = self.music;
1370
1371     // plays music for the level if there is any
1372     if (self.noise)
1373     {
1374         precache_sound (self.noise);
1375         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1376     }
1377 #endif
1378
1379 #include "precache-for-csqc.inc"
1380 }
1381
1382 // WARNING: this kills the trace globals
1383 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1384 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1385
1386 #define INITPRIO_FIRST              0
1387 #define INITPRIO_GAMETYPE           0
1388 #define INITPRIO_GAMETYPE_FALLBACK  1
1389 #define INITPRIO_FINDTARGET        10
1390 #define INITPRIO_DROPTOFLOOR       20
1391 #define INITPRIO_SETLOCATION       90
1392 #define INITPRIO_LINKDOORS         91
1393 #define INITPRIO_LAST              99
1394
1395 .void(void) initialize_entity;
1396 .float initialize_entity_order;
1397 .entity initialize_entity_next;
1398 entity initialize_entity_first;
1399
1400 void make_safe_for_remove(entity e)
1401 {
1402     if (e.initialize_entity)
1403     {
1404         entity ent, prev = world;
1405         for (ent = initialize_entity_first; ent; )
1406         {
1407             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1408             {
1409                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1410                 // skip it in linked list
1411                 if (prev)
1412                 {
1413                     prev.initialize_entity_next = ent.initialize_entity_next;
1414                     ent = prev.initialize_entity_next;
1415                 }
1416                 else
1417                 {
1418                     initialize_entity_first = ent.initialize_entity_next;
1419                     ent = initialize_entity_first;
1420                 }
1421             }
1422             else
1423             {
1424                 prev = ent;
1425                 ent = ent.initialize_entity_next;
1426             }
1427         }
1428     }
1429 }
1430
1431 void objerror(string s)
1432 {
1433     make_safe_for_remove(self);
1434     builtin_objerror(s);
1435 }
1436
1437 .float remove_except_protected_forbidden;
1438 void remove_except_protected(entity e)
1439 {
1440         if(e.remove_except_protected_forbidden)
1441                 error("not allowed to remove this at this point");
1442         builtin_remove(e);
1443 }
1444
1445 void remove_unsafely(entity e)
1446 {
1447     if(e.classname == "spike")
1448         error("Removing spikes is forbidden (crylink bug), please report");
1449     builtin_remove(e);
1450 }
1451
1452 void remove_safely(entity e)
1453 {
1454     make_safe_for_remove(e);
1455     builtin_remove(e);
1456 }
1457
1458 void InitializeEntity(entity e, void(void) func, float order)
1459 {
1460     entity prev, cur;
1461
1462     if (!e || e.initialize_entity)
1463     {
1464         // make a proxy initializer entity
1465         entity e_old;
1466         e_old = e;
1467         e = spawn();
1468         e.classname = "initialize_entity";
1469         e.enemy = e_old;
1470     }
1471
1472     e.initialize_entity = func;
1473     e.initialize_entity_order = order;
1474
1475     cur = initialize_entity_first;
1476     prev = world;
1477     for (;;)
1478     {
1479         if (!cur || cur.initialize_entity_order > order)
1480         {
1481             // insert between prev and cur
1482             if (prev)
1483                 prev.initialize_entity_next = e;
1484             else
1485                 initialize_entity_first = e;
1486             e.initialize_entity_next = cur;
1487             return;
1488         }
1489         prev = cur;
1490         cur = cur.initialize_entity_next;
1491     }
1492 }
1493 void InitializeEntitiesRun()
1494 {
1495     entity startoflist;
1496     startoflist = initialize_entity_first;
1497     initialize_entity_first = world;
1498     remove = remove_except_protected;
1499     for (self = startoflist; self; self = self.initialize_entity_next)
1500     {
1501         self.remove_except_protected_forbidden = 1;
1502     }
1503     for (self = startoflist; self; )
1504     {
1505         entity e;
1506         var void(void) func;
1507         e = self.initialize_entity_next;
1508         func = self.initialize_entity;
1509         self.initialize_entity_order = 0;
1510         self.initialize_entity = func_null;
1511         self.initialize_entity_next = world;
1512         self.remove_except_protected_forbidden = 0;
1513         if (self.classname == "initialize_entity")
1514         {
1515             entity e_old;
1516             e_old = self.enemy;
1517             builtin_remove(self);
1518             self = e_old;
1519         }
1520         //dprint("Delayed initialization: ", self.classname, "\n");
1521         if(func)
1522             func();
1523         else
1524         {
1525             eprint(self);
1526             backtrace(strcat("Null function in: ", self.classname, "\n"));
1527         }
1528         self = e;
1529     }
1530     remove = remove_unsafely;
1531 }
1532
1533 .float uncustomizeentityforclient_set;
1534 .void(void) uncustomizeentityforclient;
1535 void UncustomizeEntitiesRun()
1536 {
1537     entity oldself;
1538     oldself = self;
1539     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1540         self.uncustomizeentityforclient();
1541     self = oldself;
1542 }
1543 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1544 {
1545     e.customizeentityforclient = customizer;
1546     e.uncustomizeentityforclient = uncustomizer;
1547     e.uncustomizeentityforclient_set = !!uncustomizer;
1548 }
1549
1550 .float nottargeted;
1551 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1552
1553 void() SUB_Remove;
1554 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1555 {
1556     vector mi, ma;
1557
1558     if (e.classname == "")
1559         e.classname = "net_linked";
1560
1561     if (e.model == "" || self.modelindex == 0)
1562     {
1563         mi = e.mins;
1564         ma = e.maxs;
1565         setmodel(e, "null");
1566         setsize(e, mi, ma);
1567     }
1568
1569     e.SendEntity = sendfunc;
1570     e.SendFlags = 0xFFFFFF;
1571
1572     if (!docull)
1573         e.effects |= EF_NODEPTHTEST;
1574
1575     if (dt)
1576     {
1577         e.nextthink = time + dt;
1578         e.think = SUB_Remove;
1579     }
1580 }
1581
1582
1583 entity eliminatedPlayers;
1584 .float(entity) isEliminated;
1585 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1586 {
1587         float i, f, b;
1588         entity e;
1589         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1590         WriteByte(MSG_ENTITY, sendflags);
1591
1592         if(sendflags & 1)
1593         {
1594                 for(i = 1; i <= maxclients; i += 8)
1595                 {
1596                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1597                         {
1598                                 if(eliminatedPlayers.isEliminated(e))
1599                                         f |= b;
1600                         }
1601                         WriteByte(MSG_ENTITY, f);
1602                 }
1603         }
1604
1605         return TRUE;
1606 }
1607
1608 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1609 {
1610         if(eliminatedPlayers)
1611         {
1612                 backtrace("Can't spawn eliminatedPlayers again!");
1613                 return;
1614         }
1615         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1616         eliminatedPlayers.isEliminated = isEliminated_func;
1617 }
1618
1619
1620 void adaptor_think2touch()
1621 {
1622     entity o;
1623     o = other;
1624     other = world;
1625     self.touch();
1626     other = o;
1627 }
1628
1629 void adaptor_think2use()
1630 {
1631     entity o, a;
1632     o = other;
1633     a = activator;
1634     activator = world;
1635     other = world;
1636     self.use();
1637     other = o;
1638     activator = a;
1639 }
1640
1641 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1642 {
1643         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1644                 self.projectiledeathtype |= HITTYPE_SPLASH;
1645         adaptor_think2use();
1646 }
1647
1648 // deferred dropping
1649 void DropToFloor_Handler()
1650 {
1651     builtin_droptofloor();
1652     self.dropped_origin = self.origin;
1653 }
1654
1655 void droptofloor()
1656 {
1657     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1658 }
1659
1660
1661
1662 float trace_hits_box_a0, trace_hits_box_a1;
1663
1664 float trace_hits_box_1d(float end, float thmi, float thma)
1665 {
1666     if (end == 0)
1667     {
1668         // just check if x is in range
1669         if (0 < thmi)
1670             return FALSE;
1671         if (0 > thma)
1672             return FALSE;
1673     }
1674     else
1675     {
1676         // do the trace with respect to x
1677         // 0 -> end has to stay in thmi -> thma
1678         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1679         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1680         if (trace_hits_box_a0 > trace_hits_box_a1)
1681             return FALSE;
1682     }
1683     return TRUE;
1684 }
1685
1686 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1687 {
1688     end -= start;
1689     thmi -= start;
1690     thma -= start;
1691     // now it is a trace from 0 to end
1692
1693     trace_hits_box_a0 = 0;
1694     trace_hits_box_a1 = 1;
1695
1696     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1697         return FALSE;
1698     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1699         return FALSE;
1700     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1701         return FALSE;
1702
1703     return TRUE;
1704 }
1705
1706 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1707 {
1708     return trace_hits_box(start, end, thmi - ma, thma - mi);
1709 }
1710
1711 float SUB_NoImpactCheck()
1712 {
1713         // zero hitcontents = this is not the real impact, but either the
1714         // mirror-impact of something hitting the projectile instead of the
1715         // projectile hitting the something, or a touchareagrid one. Neither of
1716         // these stop the projectile from moving, so...
1717         if(trace_dphitcontents == 0)
1718         {
1719                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1720                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1721                 checkclient();
1722         }
1723     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1724         return 1;
1725     if (other == world && self.size != '0 0 0')
1726     {
1727         vector tic;
1728         tic = self.velocity * sys_frametime;
1729         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1730         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1731         if (trace_fraction >= 1)
1732         {
1733             dprint("Odd... did not hit...?\n");
1734         }
1735         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1736         {
1737             dprint("Detected and prevented the sky-grapple bug.\n");
1738             return 1;
1739         }
1740     }
1741
1742     return 0;
1743 }
1744
1745 #define SUB_OwnerCheck() (other && (other == self.owner))
1746
1747 void RemoveGrapplingHook(entity pl);
1748 void W_Crylink_Dequeue(entity e);
1749 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1750 {
1751         if(SUB_OwnerCheck())
1752                 return TRUE;
1753         if(SUB_NoImpactCheck())
1754         {
1755                 if(self.classname == "nade")
1756                         return FALSE; // no checks here
1757                 else if(self.classname == "grapplinghook")
1758                         RemoveGrapplingHook(self.realowner);
1759                 else if(self.classname == "spike")
1760                 {
1761                         W_Crylink_Dequeue(self);
1762                         remove(self);
1763                 }
1764                 else
1765                         remove(self);
1766                 return TRUE;
1767         }
1768         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1769                 UpdateCSQCProjectile(self);
1770         return FALSE;
1771 }
1772 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1773
1774 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1775 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1776
1777 void URI_Get_Callback(float id, float status, string data)
1778 {
1779         if(url_URI_Get_Callback(id, status, data))
1780         {
1781                 // handled
1782         }
1783         else if (id == URI_GET_DISCARD)
1784         {
1785                 // discard
1786         }
1787         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1788         {
1789                 // sv_cmd curl
1790                 Curl_URI_Get_Callback(id, status, data);
1791         }
1792         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1793         {
1794                 // online ban list
1795                 OnlineBanList_URI_Get_Callback(id, status, data);
1796         }
1797         else
1798         {
1799                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1800         }
1801 }
1802
1803 string uid2name(string myuid) {
1804         string s;
1805         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1806
1807         // FIXME remove this later after 0.6 release
1808         // convert old style broken records to correct style
1809         if(s == "")
1810         {
1811                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1812                 if(s != "")
1813                 {
1814                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1815                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1816                 }
1817         }
1818
1819         if(s == "")
1820                 s = "^1Unregistered Player";
1821         return s;
1822 }
1823
1824 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1825 {
1826     float m, i;
1827     vector start, org, delta, end, enddown, mstart;
1828     entity sp;
1829
1830     m = e.dphitcontentsmask;
1831     e.dphitcontentsmask = goodcontents | badcontents;
1832
1833     org = world.mins;
1834     delta = world.maxs - world.mins;
1835
1836     start = end = org;
1837
1838     for (i = 0; i < attempts; ++i)
1839     {
1840         start_x = org_x + random() * delta_x;
1841         start_y = org_y + random() * delta_y;
1842         start_z = org_z + random() * delta_z;
1843
1844         // rule 1: start inside world bounds, and outside
1845         // solid, and don't start from somewhere where you can
1846         // fall down to evil
1847         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1848         if (trace_fraction >= 1)
1849             continue;
1850         if (trace_startsolid)
1851             continue;
1852         if (trace_dphitcontents & badcontents)
1853             continue;
1854         if (trace_dphitq3surfaceflags & badsurfaceflags)
1855             continue;
1856
1857         // rule 2: if we are too high, lower the point
1858         if (trace_fraction * delta_z > maxaboveground)
1859             start = trace_endpos + '0 0 1' * maxaboveground;
1860         enddown = trace_endpos;
1861
1862         // rule 3: make sure we aren't outside the map. This only works
1863         // for somewhat well formed maps. A good rule of thumb is that
1864         // the map should have a convex outside hull.
1865         // these can be traceLINES as we already verified the starting box
1866         mstart = start + 0.5 * (e.mins + e.maxs);
1867         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1868         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1869             continue;
1870         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1871         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1872             continue;
1873         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1874         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1875             continue;
1876         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1877         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1878             continue;
1879         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1880         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1881             continue;
1882
1883         // rule 4: we must "see" some spawnpoint or item
1884         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1885                 if(checkpvs(mstart, sp))
1886                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1887                                 break;
1888         if(!sp)
1889         {
1890                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1891                         if(checkpvs(mstart, sp))
1892                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1893                                         break;
1894                 if(!sp)
1895                         continue;
1896         }
1897
1898         // find a random vector to "look at"
1899         end_x = org_x + random() * delta_x;
1900         end_y = org_y + random() * delta_y;
1901         end_z = org_z + random() * delta_z;
1902         end = start + normalize(end - start) * vlen(delta);
1903
1904         // rule 4: start TO end must not be too short
1905         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1906         if (trace_startsolid)
1907             continue;
1908         if (trace_fraction < minviewdistance / vlen(delta))
1909             continue;
1910
1911         // rule 5: don't want to look at sky
1912         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1913             continue;
1914
1915         // rule 6: we must not end up in trigger_hurt
1916         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1917             continue;
1918
1919         break;
1920     }
1921
1922     e.dphitcontentsmask = m;
1923
1924     if (i < attempts)
1925     {
1926         setorigin(e, start);
1927         e.angles = vectoangles(end - start);
1928         dprint("Needed ", ftos(i + 1), " attempts\n");
1929         return TRUE;
1930     }
1931     else
1932         return FALSE;
1933 }
1934
1935 void write_recordmarker(entity pl, float tstart, float dt)
1936 {
1937     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1938
1939     // also write a marker into demo files for demotc-race-record-extractor to find
1940     stuffcmd(pl,
1941              strcat(
1942                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1943                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1944 }
1945
1946 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1947 {
1948         switch(algn)
1949         {
1950                 default:
1951                 case 3: // right
1952                         break;
1953
1954                 case 4: // left
1955                         vecs_y = -vecs_y;
1956                         break;
1957
1958                 case 1:
1959                         if(allowcenter) // 2: allow center handedness
1960                         {
1961                                 // center
1962                                 vecs_y = 0;
1963                                 vecs_z -= 2;
1964                         }
1965                         else
1966                         {
1967                                 // right
1968                         }
1969                         break;
1970
1971                 case 2:
1972                         if(allowcenter) // 2: allow center handedness
1973                         {
1974                                 // center
1975                                 vecs_y = 0;
1976                                 vecs_z -= 2;
1977                         }
1978                         else
1979                         {
1980                                 // left
1981                                 vecs_y = -vecs_y;
1982                         }
1983                         break;
1984         }
1985         return vecs;
1986 }
1987
1988 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1989 {
1990         string s;
1991         vector v;
1992
1993         if (autocvar_g_shootfromeye)
1994         {
1995                 if (visual)
1996                 {
1997                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1998                         else { vecs_y = 0; vecs_z -= 2; }
1999                 }
2000                 else
2001                 {
2002                         vecs_y = 0;
2003                         vecs_z = 0;
2004                 }
2005         }
2006         else if (autocvar_g_shootfromcenter)
2007         {
2008                 vecs_y = 0;
2009                 vecs_z -= 2;
2010         }
2011         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2012         {
2013                 v = stov(s);
2014                 if (y_is_right)
2015                         v_y = -v_y;
2016                 if (v_x != 0)
2017                         vecs_x = v_x;
2018                 vecs_y = v_y;
2019                 vecs_z = v_z;
2020         }
2021         else if (autocvar_g_shootfromclient)
2022         {
2023                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2024         }
2025         return vecs;
2026 }
2027
2028 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2029 {
2030         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2031 }
2032
2033
2034 void attach_sameorigin(entity e, entity to, string tag)
2035 {
2036     vector org, t_forward, t_left, t_up, e_forward, e_up;
2037     float tagscale;
2038
2039     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2040     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2041     t_forward = v_forward * tagscale;
2042     t_left = v_right * -tagscale;
2043     t_up = v_up * tagscale;
2044
2045     e.origin_x = org * t_forward;
2046     e.origin_y = org * t_left;
2047     e.origin_z = org * t_up;
2048
2049     // current forward and up directions
2050     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2051                 e.angles = AnglesTransform_FromVAngles(e.angles);
2052         else
2053                 e.angles = AnglesTransform_FromAngles(e.angles);
2054     fixedmakevectors(e.angles);
2055
2056     // untransform forward, up!
2057     e_forward_x = v_forward * t_forward;
2058     e_forward_y = v_forward * t_left;
2059     e_forward_z = v_forward * t_up;
2060     e_up_x = v_up * t_forward;
2061     e_up_y = v_up * t_left;
2062     e_up_z = v_up * t_up;
2063
2064     e.angles = fixedvectoangles2(e_forward, e_up);
2065     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2066                 e.angles = AnglesTransform_ToVAngles(e.angles);
2067         else
2068                 e.angles = AnglesTransform_ToAngles(e.angles);
2069
2070     setattachment(e, to, tag);
2071     setorigin(e, e.origin);
2072 }
2073
2074 void detach_sameorigin(entity e)
2075 {
2076     vector org;
2077     org = gettaginfo(e, 0);
2078     e.angles = fixedvectoangles2(v_forward, v_up);
2079     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2080                 e.angles = AnglesTransform_ToVAngles(e.angles);
2081         else
2082                 e.angles = AnglesTransform_ToAngles(e.angles);
2083     setorigin(e, org);
2084     setattachment(e, world, "");
2085     setorigin(e, e.origin);
2086 }
2087
2088 void follow_sameorigin(entity e, entity to)
2089 {
2090     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2091     e.aiment = to; // make the hole follow bmodel
2092     e.punchangle = to.angles; // the original angles of bmodel
2093     e.view_ofs = e.origin - to.origin; // relative origin
2094     e.v_angle = e.angles - to.angles; // relative angles
2095 }
2096
2097 void unfollow_sameorigin(entity e)
2098 {
2099     e.movetype = MOVETYPE_NONE;
2100 }
2101
2102 entity gettaginfo_relative_ent;
2103 vector gettaginfo_relative(entity e, float tag)
2104 {
2105     if (!gettaginfo_relative_ent)
2106     {
2107         gettaginfo_relative_ent = spawn();
2108         gettaginfo_relative_ent.effects = EF_NODRAW;
2109     }
2110     gettaginfo_relative_ent.model = e.model;
2111     gettaginfo_relative_ent.modelindex = e.modelindex;
2112     gettaginfo_relative_ent.frame = e.frame;
2113     return gettaginfo(gettaginfo_relative_ent, tag);
2114 }
2115
2116 .float scale2;
2117
2118 float modeleffect_SendEntity(entity to, float sf)
2119 {
2120         float f;
2121         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2122
2123         f = 0;
2124         if(self.velocity != '0 0 0')
2125                 f |= 1;
2126         if(self.angles != '0 0 0')
2127                 f |= 2;
2128         if(self.avelocity != '0 0 0')
2129                 f |= 4;
2130
2131         WriteByte(MSG_ENTITY, f);
2132         WriteShort(MSG_ENTITY, self.modelindex);
2133         WriteByte(MSG_ENTITY, self.skin);
2134         WriteByte(MSG_ENTITY, self.frame);
2135         WriteCoord(MSG_ENTITY, self.origin_x);
2136         WriteCoord(MSG_ENTITY, self.origin_y);
2137         WriteCoord(MSG_ENTITY, self.origin_z);
2138         if(f & 1)
2139         {
2140                 WriteCoord(MSG_ENTITY, self.velocity_x);
2141                 WriteCoord(MSG_ENTITY, self.velocity_y);
2142                 WriteCoord(MSG_ENTITY, self.velocity_z);
2143         }
2144         if(f & 2)
2145         {
2146                 WriteCoord(MSG_ENTITY, self.angles_x);
2147                 WriteCoord(MSG_ENTITY, self.angles_y);
2148                 WriteCoord(MSG_ENTITY, self.angles_z);
2149         }
2150         if(f & 4)
2151         {
2152                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2153                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2154                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2155         }
2156         WriteShort(MSG_ENTITY, self.scale * 256.0);
2157         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2158         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2159         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2160         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2161
2162         return TRUE;
2163 }
2164
2165 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2166 {
2167         entity e;
2168         float sz;
2169         e = spawn();
2170         e.classname = "modeleffect";
2171         setmodel(e, m);
2172         e.frame = f;
2173         setorigin(e, o);
2174         e.velocity = v;
2175         e.angles = ang;
2176         e.avelocity = angv;
2177         e.alpha = a;
2178         e.teleport_time = t1;
2179         e.fade_time = t2;
2180         e.skin = s;
2181         if(s0 >= 0)
2182                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2183         else
2184                 e.scale = -s0;
2185         if(s2 >= 0)
2186                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2187         else
2188                 e.scale2 = -s2;
2189         sz = max(e.scale, e.scale2);
2190         setsize(e, e.mins * sz, e.maxs * sz);
2191         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2192 }
2193
2194 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2195 {
2196         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2197 }
2198
2199 float randombit(float bits)
2200 {
2201         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2202                 return bits;
2203
2204         float n, f, b, r;
2205
2206         r = random();
2207         b = 0;
2208         n = 0;
2209
2210         for(f = 1; f <= bits; f *= 2)
2211         {
2212                 if(bits & f)
2213                 {
2214                         ++n;
2215                         r *= n;
2216                         if(r <= 1)
2217                                 b = f;
2218                         else
2219                                 r = (r - 1) / (n - 1);
2220                 }
2221         }
2222
2223         return b;
2224 }
2225
2226 float randombits(float bits, float k, float error_return)
2227 {
2228         float r;
2229         r = 0;
2230         while(k > 0 && bits != r)
2231         {
2232                 r += randombit(bits - r);
2233                 --k;
2234         }
2235         if(error_return)
2236                 if(k > 0)
2237                         return -1; // all
2238         return r;
2239 }
2240
2241 void randombit_test(float bits, float iter)
2242 {
2243         while(iter > 0)
2244         {
2245                 print(ftos(randombit(bits)), "\n");
2246                 --iter;
2247         }
2248 }
2249
2250 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2251 {
2252         if(halflifedist > 0)
2253                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2254         else if(halflifedist < 0)
2255                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2256         else
2257                 return 1;
2258 }
2259
2260
2261
2262
2263 #ifdef RELEASE
2264 #define cvar_string_normal builtin_cvar_string
2265 #define cvar_normal builtin_cvar
2266 #else
2267 string cvar_string_normal(string n)
2268 {
2269         if (!(cvar_type(n) & 1))
2270                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2271         return builtin_cvar_string(n);
2272 }
2273
2274 float cvar_normal(string n)
2275 {
2276         return stof(cvar_string_normal(n));
2277 }
2278 #endif
2279 #define cvar_set_normal builtin_cvar_set
2280
2281 void defer_think()
2282 {
2283     entity oself;
2284
2285     oself           = self;
2286     self            = self.owner;
2287     oself.think     = SUB_Remove;
2288     oself.nextthink = time;
2289
2290     oself.use();
2291 }
2292
2293 /*
2294     Execute func() after time + fdelay.
2295     self when func is executed = self when defer is called
2296 */
2297 void defer(float fdelay, void() func)
2298 {
2299     entity e;
2300
2301     e           = spawn();
2302     e.owner     = self;
2303     e.use       = func;
2304     e.think     = defer_think;
2305     e.nextthink = time + fdelay;
2306 }
2307
2308 .string aiment_classname;
2309 .float aiment_deadflag;
2310 void SetMovetypeFollow(entity ent, entity e)
2311 {
2312         // FIXME this may not be warpzone aware
2313         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2314         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2315         ent.aiment = e; // make the hole follow bmodel
2316         ent.punchangle = e.angles; // the original angles of bmodel
2317         ent.view_ofs = ent.origin - e.origin; // relative origin
2318         ent.v_angle = ent.angles - e.angles; // relative angles
2319         ent.aiment_classname = strzone(e.classname);
2320         ent.aiment_deadflag = e.deadflag;
2321 }
2322 void UnsetMovetypeFollow(entity ent)
2323 {
2324         ent.movetype = MOVETYPE_FLY;
2325         PROJECTILE_MAKETRIGGER(ent);
2326         ent.aiment = world;
2327 }
2328 float LostMovetypeFollow(entity ent)
2329 {
2330 /*
2331         if(ent.movetype != MOVETYPE_FOLLOW)
2332                 if(ent.aiment)
2333                         error("???");
2334 */
2335         if(ent.aiment)
2336         {
2337                 if(ent.aiment.classname != ent.aiment_classname)
2338                         return 1;
2339                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2340                         return 1;
2341         }
2342         return 0;
2343 }
2344
2345 float isPushable(entity e)
2346 {
2347         if(e.iscreature)
2348                 return TRUE;
2349         if(e.pushable)
2350                 return TRUE;
2351         switch(e.classname)
2352         {
2353                 case "body":
2354                 case "droppedweapon":
2355                 case "keepawayball":
2356                 case "nexball_basketball":
2357                 case "nexball_football":
2358                         return TRUE;
2359                 case "bullet": // antilagged bullets can't hit this either
2360                         return FALSE;
2361         }
2362         if (e.projectiledeathtype)
2363                 return TRUE;
2364         return FALSE;
2365 }