qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 void bcenterprint(string s)
  83 {
  84     // TODO replace by MSG_ALL (would show it to spectators too, though)?
  85     entity head;
  86     FOR_EACH_PLAYER(head)
  87     if (clienttype(head) == CLIENTTYPE_REAL)
  88         centerprint(head, s);
  89 }
  90
  91 void GameLogEcho(string s)
  92 {
  93     string fn;
  94     float matches;
  95
  96     if (autocvar_sv_eventlog_files)
  97     {
  98         if (!logfile_open)
  99         {
 100             logfile_open = TRUE;
 101             matches = autocvar_sv_eventlog_files_counter + 1;
 102             cvar_set("sv_eventlog_files_counter", ftos(matches));
 103             fn = ftos(matches);
 104             if (strlen(fn) < 8)
 105                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 106             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 107             logfile = fopen(fn, FILE_APPEND);
 108             fputs(logfile, ":logversion:3\n");
 109         }
 110         if (logfile >= 0)
 111         {
 112             if (autocvar_sv_eventlog_files_timestamps)
 113                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 114             else
 115                 fputs(logfile, strcat(s, "\n"));
 116         }
 117     }
 118     if (autocvar_sv_eventlog_console)
 119     {
 120         print(s, "\n");
 121     }
 122 }
 123
 124 void GameLogInit()
 125 {
 126     logfile_open = 0;
 127     // will be opened later
 128 }
 129
 130 void GameLogClose()
 131 {
 132     if (logfile_open && logfile >= 0)
 133     {
 134         fclose(logfile);
 135         logfile = -1;
 136     }
 137 }
 138
 139 vector PL_VIEW_OFS;
 140 vector PL_MIN;
 141 vector PL_MAX;
 142 vector PL_HEAD;
 143 vector PL_CROUCH_VIEW_OFS;
 144 vector PL_CROUCH_MIN;
 145 vector PL_CROUCH_MAX;
 146
 147 float spawnpoint_nag;
 148 void relocate_spawnpoint()
 149 {
 150     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 151     PL_MIN                                  = stov(autocvar_sv_player_mins);
 152     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 153     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 154     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 155     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 156     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 157
 158     // nudge off the floor
 159     setorigin(self, self.origin + '0 0 1');
 160
 161     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 162     if (trace_startsolid)
 163     {
 164         vector o;
 165         o = self.origin;
 166         self.mins = PL_MIN;
 167         self.maxs = PL_MAX;
 168         if (!move_out_of_solid(self))
 169             objerror("could not get out of solid at all!");
 170         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 171         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 172         print(" ", ftos(self.origin_y - o_y));
 173         print(" ", ftos(self.origin_z - o_z), "'\n");
 174         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 175         {
 176             if (!spawnpoint_nag)
 177                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 178             spawnpoint_nag = 1;
 179         }
 180         else
 181         {
 182             setorigin(self, o);
 183             self.mins = self.maxs = '0 0 0';
 184             objerror("player spawn point in solid, mapper sucks!\n");
 185             return;
 186         }
 187     }
 188
 189     self.use = spawnpoint_use;
 190     self.team_saved = self.team;
 191     if (!self.cnt)
 192         self.cnt = 1;
 193
 194     if (have_team_spawns != 0)
 195         if (self.team)
 196             have_team_spawns = 1;
 197     have_team_spawns_forteam[self.team] = 1;
 198
 199     if (autocvar_r_showbboxes)
 200     {
 201         // show where spawnpoints point at too
 202         makevectors(self.angles);
 203         entity e;
 204         e = spawn();
 205         e.classname = "info_player_foo";
 206         setorigin(e, self.origin + v_forward * 24);
 207         setsize(e, '-8 -8 -8', '8 8 8');
 208         e.solid = SOLID_TRIGGER;
 209     }
 210 }
 211
 212 #define strstr strstrofs
 213 /*
 214 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 215 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 216 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 217 // BE CONSTANT OR strzoneD!
 218 float strstr(string haystack, string needle, float offset)
 219 {
 220         float len, endpos;
 221         string found;
 222         len = strlen(needle);
 223         endpos = strlen(haystack) - len;
 224         while(offset <= endpos)
 225         {
 226                 found = substring(haystack, offset, len);
 227                 if(found == needle)
 228                         return offset;
 229                 offset = offset + 1;
 230         }
 231         return -1;
 232 }
 233 */
 234
 235 float NUM_NEAREST_ENTITIES = 4;
 236 entity nearest_entity[NUM_NEAREST_ENTITIES];
 237 float nearest_length[NUM_NEAREST_ENTITIES];
 238 entity findnearest(vector point, .string field, string value, vector axismod)
 239 {
 240     entity localhead;
 241     float i;
 242     float j;
 243     float len;
 244     vector dist;
 245
 246     float num_nearest;
 247     num_nearest = 0;
 248
 249     localhead = find(world, field, value);
 250     while (localhead)
 251     {
 252         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 253             dist = localhead.oldorigin;
 254         else
 255             dist = localhead.origin;
 256         dist = dist - point;
 257         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 258         len = vlen(dist);
 259
 260         for (i = 0; i < num_nearest; ++i)
 261         {
 262             if (len < nearest_length[i])
 263                 break;
 264         }
 265
 266         // now i tells us where to insert at
 267         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 268         if (i < NUM_NEAREST_ENTITIES)
 269         {
 270             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 271             {
 272                 nearest_length[j + 1] = nearest_length[j];
 273                 nearest_entity[j + 1] = nearest_entity[j];
 274             }
 275             nearest_length[i] = len;
 276             nearest_entity[i] = localhead;
 277             if (num_nearest < NUM_NEAREST_ENTITIES)
 278                 num_nearest = num_nearest + 1;
 279         }
 280
 281         localhead = find(localhead, field, value);
 282     }
 283
 284     // now use the first one from our list that we can see
 285     for (i = 0; i < num_nearest; ++i)
 286     {
 287         traceline(point, nearest_entity[i].origin, TRUE, world);
 288         if (trace_fraction == 1)
 289         {
 290             if (i != 0)
 291             {
 292                 dprint("Nearest point (");
 293                 dprint(nearest_entity[0].netname);
 294                 dprint(") is not visible, using a visible one.\n");
 295             }
 296             return nearest_entity[i];
 297         }
 298     }
 299
 300     if (num_nearest == 0)
 301         return world;
 302
 303     dprint("Not seeing any location point, using nearest as fallback.\n");
 304     /* DEBUGGING CODE:
 305     dprint("Candidates were: ");
 306     for(j = 0; j < num_nearest; ++j)
 307     {
 308         if(j != 0)
 309                 dprint(", ");
 310         dprint(nearest_entity[j].netname);
 311     }
 312     dprint("\n");
 313     */
 314
 315     return nearest_entity[0];
 316 }
 317
 318 void spawnfunc_target_location()
 319 {
 320     self.classname = "target_location";
 321     // location name in netname
 322     // eventually support: count, teamgame selectors, line of sight?
 323 };
 324
 325 void spawnfunc_info_location()
 326 {
 327     self.classname = "target_location";
 328     self.message = self.netname;
 329 };
 330
 331 string NearestLocation(vector p)
 332 {
 333     entity loc;
 334     string ret;
 335     ret = "somewhere";
 336     loc = findnearest(p, classname, "target_location", '1 1 1');
 337     if (loc)
 338     {
 339         ret = loc.message;
 340     }
 341     else
 342     {
 343         loc = findnearest(p, target, "###item###", '1 1 4');
 344         if (loc)
 345             ret = loc.netname;
 346     }
 347     return ret;
 348 }
 349
 350 string formatmessage(string msg)
 351 {
 352         float p, p1, p2;
 353         float n;
 354         vector cursor;
 355         entity cursor_ent;
 356         string escape;
 357         string replacement;
 358         p = 0;
 359         n = 7;
 360
 361         WarpZone_crosshair_trace(self);
 362         cursor = trace_endpos;
 363         cursor_ent = trace_ent;
 364
 365         while (1) {
 366                 if (n < 1)
 367                         break; // too many replacements
 368
 369                 n = n - 1;
 370                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 371                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 372
 373                 if (p1 < 0)
 374                         p1 = p2;
 375
 376                 if (p2 < 0)
 377                         p2 = p1;
 378
 379                 p = min(p1, p2);
 380
 381                 if (p < 0)
 382                         break;
 383
 384                 replacement = substring(msg, p, 2);
 385                 escape = substring(msg, p + 1, 1);
 386
 387                 if (escape == "%")
 388                         replacement = "%";
 389                 else if (escape == "\\")
 390                         replacement = "\\";
 391                 else if (escape == "n")
 392                         replacement = "\n";
 393                 else if (escape == "a")
 394                         replacement = ftos(floor(self.armorvalue));
 395                 else if (escape == "h")
 396                         replacement = ftos(floor(self.health));
 397                 else if (escape == "l")
 398                         replacement = NearestLocation(self.origin);
 399                 else if (escape == "y")
 400                         replacement = NearestLocation(cursor);
 401                 else if (escape == "d")
 402                         replacement = NearestLocation(self.death_origin);
 403                 else if (escape == "w") {
 404                         float wep;
 405                         wep = self.weapon;
 406                         if (!wep)
 407                                 wep = self.switchweapon;
 408                         if (!wep)
 409                                 wep = self.cnt;
 410                         replacement = W_Name(wep);
 411                 } else if (escape == "W") {
 412                         if (self.items & IT_SHELLS) replacement = "shells";
 413                         else if (self.items & IT_NAILS) replacement = "bullets";
 414                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 415                         else if (self.items & IT_CELLS) replacement = "cells";
 416                         else replacement = "batteries"; // ;)
 417                 } else if (escape == "x") {
 418                         replacement = cursor_ent.netname;
 419                         if (!replacement || !cursor_ent)
 420                                 replacement = "nothing";
 421                 } else if (escape == "s")
 422                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 423                 else if (escape == "S")
 424                         replacement = ftos(vlen(self.velocity));
 425
 426                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 427                 p = p + strlen(replacement);
 428         }
 429         return msg;
 430 }
 431
 432 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 433         return (value == 0) ? FALSE : TRUE;
 434 }
 435
 436 /*
 437 =============
 438 GetCvars
 439 =============
 440 Called with:
 441   0:  sends the request
 442   >0: receives a cvar from name=argv(f) value=argv(f+1)
 443 */
 444 void GetCvars_handleString(string thisname, float f, .string field, string name)
 445 {
 446         if (f < 0)
 447         {
 448                 if (self.field)
 449                         strunzone(self.field);
 450                 self.field = string_null;
 451         }
 452         else if (f > 0)
 453         {
 454                 if (thisname == name)
 455                 {
 456                         if (self.field)
 457                                 strunzone(self.field);
 458                         self.field = strzone(argv(f + 1));
 459                 }
 460         }
 461         else
 462                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 463 }
 464 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 465 {
 466         GetCvars_handleString(thisname, f, field, name);
 467         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 468                 if (thisname == name)
 469                 {
 470                         string s;
 471                         s = func(strcat1(self.field));
 472                         if (s != self.field)
 473                         {
 474                                 strunzone(self.field);
 475                                 self.field = strzone(s);
 476                         }
 477                 }
 478 }
 479 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 480 {
 481         if (f < 0)
 482         {
 483         }
 484         else if (f > 0)
 485         {
 486                 if (thisname == name)
 487                         self.field = stof(argv(f + 1));
 488         }
 489         else
 490                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 491 }
 492 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 493 {
 494         if (f < 0)
 495         {
 496         }
 497         else if (f > 0)
 498         {
 499                 if (thisname == name)
 500                 {
 501                         if(!self.field)
 502                         {
 503                                 self.field = stof(argv(f + 1));
 504                                 if(!self.field)
 505                                         self.field = -1;
 506                         }
 507                 }
 508         }
 509         else
 510         {
 511                 if(!self.field)
 512                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 513         }
 514 }
 515 float w_getbestweapon(entity e);
 516 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 517 {
 518         string o;
 519         o = W_FixWeaponOrder_ForceComplete(wo);
 520         if(self.weaponorder_byimpulse)
 521         {
 522                 strunzone(self.weaponorder_byimpulse);
 523                 self.weaponorder_byimpulse = string_null;
 524         }
 525         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 526         return o;
 527 }
 528 void GetCvars(float f)
 529 {
 530         string s;
 531
 532         if (f > 0)
 533                 s = strcat1(argv(f));
 534
 535         get_cvars_f = f;
 536         get_cvars_s = s;
 537         MUTATOR_CALLHOOK(GetCvars);
 538         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 539         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 540         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 541         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 542         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 555         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 556         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 560         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 561
 562         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 563         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 564
 565 #ifdef ALLOW_FORCEMODELS
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 567         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 568 #endif
 569         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 571         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 572         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 573         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 574
 575         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 576         if (f > 0)
 577         {
 578                 if (s == "cl_weaponpriority")
 579                         self.switchweapon = w_getbestweapon(self);
 580                 if (s == "cl_allow_uidtracking")
 581                         PlayerStats_AddPlayer(self);
 582         }
 583 }
 584
 585 void backtrace(string msg)
 586 {
 587     float dev, war;
 588     dev = autocvar_developer;
 589     war = autocvar_prvm_backtraceforwarnings;
 590     cvar_set("developer", "1");
 591     cvar_set("prvm_backtraceforwarnings", "1");
 592     print("\n");
 593     print("--- CUT HERE ---\nWARNING: ");
 594     print(msg);
 595     print("\n");
 596     remove(world); // isn't there any better way to cause a backtrace?
 597     print("\n--- CUT UNTIL HERE ---\n");
 598     cvar_set("developer", ftos(dev));
 599     cvar_set("prvm_backtraceforwarnings", ftos(war));
 600 }
 601
 602 string Team_ColorCode(float teamid)
 603 {
 604     if (teamid == COLOR_TEAM1)
 605         return "^1";
 606     else if (teamid == COLOR_TEAM2)
 607         return "^4";
 608     else if (teamid == COLOR_TEAM3)
 609         return "^3";
 610     else if (teamid == COLOR_TEAM4)
 611         return "^6";
 612     else
 613         return "^7";
 614 }
 615
 616 string Team_ColorName(float t)
 617 {
 618     // fixme: Search for team entities and get their .netname's!
 619     if (t == COLOR_TEAM1)
 620         return "Red";
 621     if (t == COLOR_TEAM2)
 622         return "Blue";
 623     if (t == COLOR_TEAM3)
 624         return "Yellow";
 625     if (t == COLOR_TEAM4)
 626         return "Pink";
 627     return "Neutral";
 628 }
 629
 630 string Team_ColorNameLowerCase(float t)
 631 {
 632     // fixme: Search for team entities and get their .netname's!
 633     if (t == COLOR_TEAM1)
 634         return "red";
 635     if (t == COLOR_TEAM2)
 636         return "blue";
 637     if (t == COLOR_TEAM3)
 638         return "yellow";
 639     if (t == COLOR_TEAM4)
 640         return "pink";
 641     return "neutral";
 642 }
 643
 644 float ColourToNumber(string team_colour)
 645 {
 646         if (team_colour == "red")
 647                 return COLOR_TEAM1;
 648
 649         if (team_colour == "blue")
 650                 return COLOR_TEAM2;
 651
 652         if (team_colour == "yellow")
 653                 return COLOR_TEAM3;
 654
 655         if (team_colour == "pink")
 656                 return COLOR_TEAM4;
 657
 658         if (team_colour == "auto")
 659                 return 0;
 660
 661         return -1;
 662 }
 663
 664 float NumberToTeamNumber(float number)
 665 {
 666         if (number == 1)
 667                 return COLOR_TEAM1;
 668
 669         if (number == 2)
 670                 return COLOR_TEAM2;
 671
 672         if (number == 3)
 673                 return COLOR_TEAM3;
 674
 675         if (number == 4)
 676                 return COLOR_TEAM4;
 677
 678         return -1;
 679 }
 680
 681 // decolorizes and team colors the player name when needed
 682 string playername(entity p)
 683 {
 684     string t;
 685     if (teamplay && !intermission_running && p.classname == "player")
 686     {
 687         t = Team_ColorCode(p.team);
 688         return strcat(t, strdecolorize(p.netname));
 689     }
 690     else
 691         return p.netname;
 692 }
 693
 694 vector randompos(vector m1, vector m2)
 695 {
 696     local vector v;
 697     m2 = m2 - m1;
 698     v_x = m2_x * random() + m1_x;
 699     v_y = m2_y * random() + m1_y;
 700     v_z = m2_z * random() + m1_z;
 701     return  v;
 702 };
 703
 704 //#NO AUTOCVARS START
 705
 706 float g_pickup_shells;
 707 float g_pickup_shells_max;
 708 float g_pickup_nails;
 709 float g_pickup_nails_max;
 710 float g_pickup_rockets;
 711 float g_pickup_rockets_max;
 712 float g_pickup_cells;
 713 float g_pickup_cells_max;
 714 float g_pickup_fuel;
 715 float g_pickup_fuel_jetpack;
 716 float g_pickup_fuel_max;
 717 float g_pickup_armorsmall;
 718 float g_pickup_armorsmall_max;
 719 float g_pickup_armorsmall_anyway;
 720 float g_pickup_armormedium;
 721 float g_pickup_armormedium_max;
 722 float g_pickup_armormedium_anyway;
 723 float g_pickup_armorbig;
 724 float g_pickup_armorbig_max;
 725 float g_pickup_armorbig_anyway;
 726 float g_pickup_armorlarge;
 727 float g_pickup_armorlarge_max;
 728 float g_pickup_armorlarge_anyway;
 729 float g_pickup_healthsmall;
 730 float g_pickup_healthsmall_max;
 731 float g_pickup_healthsmall_anyway;
 732 float g_pickup_healthmedium;
 733 float g_pickup_healthmedium_max;
 734 float g_pickup_healthmedium_anyway;
 735 float g_pickup_healthlarge;
 736 float g_pickup_healthlarge_max;
 737 float g_pickup_healthlarge_anyway;
 738 float g_pickup_healthmega;
 739 float g_pickup_healthmega_max;
 740 float g_pickup_healthmega_anyway;
 741 float g_pickup_ammo_anyway;
 742 float g_pickup_weapons_anyway;
 743 float g_weaponarena;
 744 float g_weaponarena_random;
 745 float g_weaponarena_random_with_laser;
 746 string g_weaponarena_list;
 747 float g_weaponspeedfactor;
 748 float g_weaponratefactor;
 749 float g_weapondamagefactor;
 750 float g_weaponforcefactor;
 751 float g_weaponspreadfactor;
 752
 753 float start_weapons;
 754 float start_items;
 755 float start_ammo_shells;
 756 float start_ammo_nails;
 757 float start_ammo_rockets;
 758 float start_ammo_cells;
 759 float start_ammo_fuel;
 760 float start_health;
 761 float start_armorvalue;
 762 float warmup_start_weapons;
 763 float warmup_start_ammo_shells;
 764 float warmup_start_ammo_nails;
 765 float warmup_start_ammo_rockets;
 766 float warmup_start_ammo_cells;
 767 float warmup_start_ammo_fuel;
 768 float warmup_start_health;
 769 float warmup_start_armorvalue;
 770 float g_weapon_stay;
 771 float g_ghost_items;
 772
 773 entity get_weaponinfo(float w);
 774
 775 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 776 {
 777         var float i = weaponinfo.weapon;
 778
 779         if (!i)
 780                 return 0;
 781
 782         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 783
 784         if (t < 0) // "default" weapon selection
 785         {
 786                 if (g_lms || g_ca || allguns)
 787                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 788                 else if(t < -1)
 789                         t = 0;
 790                 else if (g_cts)
 791                         t = (i == WEP_SHOTGUN);
 792                 else if (g_nexball)
 793                         t = 0; // weapon is set a few lines later
 794                 else
 795                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 796                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 797                         t |= (i == WEP_HOOK);
 798         }
 799
 800         // we cannot disable porto in Nexball, we must force it
 801         if(g_nexball && i == WEP_PORTO)
 802                 t = 1;
 803
 804         return t;
 805 }
 806
 807 void readplayerstartcvars()
 808 {
 809         entity e;
 810         float i, j, t;
 811         string s;
 812
 813         // initialize starting values for players
 814         start_weapons = 0;
 815         start_items = 0;
 816         start_ammo_shells = 0;
 817         start_ammo_nails = 0;
 818         start_ammo_rockets = 0;
 819         start_ammo_cells = 0;
 820         start_health = cvar("g_balance_health_start");
 821         start_armorvalue = cvar("g_balance_armor_start");
 822
 823         g_weaponarena = 0;
 824         s = cvar_string("g_weaponarena");
 825         if (s == "0" || s == "")
 826         {
 827                 if(g_lms || g_ca)
 828                         s = "most";
 829         }
 830
 831         if (s == "0" || s == "")
 832         {
 833                 // no arena
 834         }
 835         else if (s == "off")
 836         {
 837                 // forcibly turn off weaponarena
 838         }
 839         else if (s == "all")
 840         {
 841                 g_weaponarena_list = "All Weapons";
 842                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 843                 {
 844                         e = get_weaponinfo(j);
 845                         g_weaponarena |= e.weapons;
 846                         weapon_action(e.weapon, WR_PRECACHE);
 847                 }
 848         }
 849         else if (s == "most")
 850         {
 851                 g_weaponarena_list = "Most Weapons";
 852                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 853                 {
 854                         e = get_weaponinfo(j);
 855                         if (e.spawnflags & WEP_FLAG_NORMAL)
 856                         {
 857                                 g_weaponarena |= e.weapons;
 858                                 weapon_action(e.weapon, WR_PRECACHE);
 859                         }
 860                 }
 861         }
 862         else if (s == "none")
 863         {
 864                 g_weaponarena_list = "No Weapons";
 865                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 866         }
 867         else
 868         {
 869                 t = tokenize_console(s);
 870                 g_weaponarena_list = "";
 871                 for (i = 0; i < t; ++i)
 872                 {
 873                         s = argv(i);
 874                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 875                         {
 876                                 e = get_weaponinfo(j);
 877                                 if (e.netname == s)
 878                                 {
 879                                         g_weaponarena |= e.weapons;
 880                                         weapon_action(e.weapon, WR_PRECACHE);
 881                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 882                                         break;
 883                                 }
 884                         }
 885                         if (j > WEP_LAST)
 886                         {
 887                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 888                         }
 889                 }
 890                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 891         }
 892
 893         if(g_weaponarena)
 894                 g_weaponarena_random = cvar("g_weaponarena_random");
 895         else
 896                 g_weaponarena_random = 0;
 897         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 898
 899         if (g_weaponarena)
 900         {
 901                 start_weapons = g_weaponarena;
 902                 if(!(g_lms || g_ca))
 903                         start_items |= IT_UNLIMITED_AMMO;
 904         }
 905         else if (g_minstagib)
 906         {
 907                 start_health = 100;
 908                 start_armorvalue = 0;
 909                 start_weapons = WEPBIT_MINSTANEX;
 910                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 911                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 912
 913                 if (g_minstagib_invis_alpha <= 0)
 914                         g_minstagib_invis_alpha = -1;
 915         }
 916         else
 917         {
 918                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 919                 {
 920                         e = get_weaponinfo(i);
 921                         if(want_weapon("g_start_weapon_", e, FALSE))
 922                                 start_weapons |= e.weapons;
 923                 }
 924         }
 925
 926         if(!cvar("g_use_ammunition"))
 927                 start_items |= IT_UNLIMITED_AMMO;
 928
 929         if(g_minstagib)
 930         {
 931                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 932                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 933         }
 934         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 935         {
 936                 start_ammo_rockets = 999;
 937                 start_ammo_shells = 999;
 938                 start_ammo_cells = 999;
 939                 start_ammo_nails = 999;
 940                 start_ammo_fuel = 999;
 941         }
 942         else
 943         {
 944                 if(g_lms || g_ca)
 945                 {
 946                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 947                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 948                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 949                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 950                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 951                 }
 952                 else
 953                 {
 954                         start_ammo_shells = cvar("g_start_ammo_shells");
 955                         start_ammo_nails = cvar("g_start_ammo_nails");
 956                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 957                         start_ammo_cells = cvar("g_start_ammo_cells");
 958                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 959                 }
 960         }
 961
 962         if (g_lms || g_ca)
 963         {
 964                 start_health = cvar("g_lms_start_health");
 965                 start_armorvalue = cvar("g_lms_start_armor");
 966         }
 967
 968         if (inWarmupStage)
 969         {
 970                 warmup_start_ammo_shells = start_ammo_shells;
 971                 warmup_start_ammo_nails = start_ammo_nails;
 972                 warmup_start_ammo_rockets = start_ammo_rockets;
 973                 warmup_start_ammo_cells = start_ammo_cells;
 974                 warmup_start_ammo_fuel = start_ammo_fuel;
 975                 warmup_start_health = start_health;
 976                 warmup_start_armorvalue = start_armorvalue;
 977                 warmup_start_weapons = start_weapons;
 978
 979                 if (!g_weaponarena && !g_minstagib && !g_ca)
 980                 {
 981                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 982                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 983                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 984                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 985                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 986                         warmup_start_health = cvar("g_warmup_start_health");
 987                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 988                         warmup_start_weapons = 0;
 989                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 990                         {
 991                                 e = get_weaponinfo(i);
 992                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 993                                         warmup_start_weapons |= e.weapons;
 994                         }
 995                 }
 996         }
 997
 998         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
 999         {
1000                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1001                 start_items |= IT_FUEL_REGEN;
1002                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1003                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1004         }
1005
1006         if (g_jetpack)
1007                 start_items |= IT_JETPACK;
1008
1009         if (g_weapon_stay == 2)
1010         {
1011                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1012                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1013                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1014                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1015                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1016                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1017                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1018                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1019                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1020                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1021         }
1022
1023         MUTATOR_CALLHOOK(SetStartItems);
1024
1025         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1026         {
1027                 e = get_weaponinfo(i);
1028                 if(e.weapons & (start_weapons | warmup_start_weapons))
1029                         weapon_action(e.weapon, WR_PRECACHE);
1030         }
1031
1032         start_ammo_shells = max(0, start_ammo_shells);
1033         start_ammo_nails = max(0, start_ammo_nails);
1034         start_ammo_cells = max(0, start_ammo_cells);
1035         start_ammo_rockets = max(0, start_ammo_rockets);
1036         start_ammo_fuel = max(0, start_ammo_fuel);
1037
1038         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1039         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1040         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1041         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1042         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1043 }
1044
1045 float g_bugrigs;
1046 float g_bugrigs_planar_movement;
1047 float g_bugrigs_planar_movement_car_jumping;
1048 float g_bugrigs_reverse_spinning;
1049 float g_bugrigs_reverse_speeding;
1050 float g_bugrigs_reverse_stopping;
1051 float g_bugrigs_air_steering;
1052 float g_bugrigs_angle_smoothing;
1053 float g_bugrigs_friction_floor;
1054 float g_bugrigs_friction_brake;
1055 float g_bugrigs_friction_air;
1056 float g_bugrigs_accel;
1057 float g_bugrigs_speed_ref;
1058 float g_bugrigs_speed_pow;
1059 float g_bugrigs_steer;
1060
1061 float g_touchexplode;
1062 float g_touchexplode_radius;
1063 float g_touchexplode_damage;
1064 float g_touchexplode_edgedamage;
1065 float g_touchexplode_force;
1066
1067 float sv_autotaunt;
1068 float sv_taunt;
1069
1070 float sv_pitch_min;
1071 float sv_pitch_max;
1072 float sv_pitch_fixyaw;
1073
1074 string GetGametype(); // g_world.qc
1075 void readlevelcvars(void)
1076 {
1077         // first load all the mutators
1078         if(cvar("g_nix"))
1079                 MUTATOR_ADD(mutator_nix);
1080         if(cvar("g_dodging"))
1081                 MUTATOR_ADD(mutator_dodging);
1082         if(cvar("g_rocket_flying"))
1083                 MUTATOR_ADD(mutator_rocketflying);
1084         if(cvar("g_vampire"))
1085                 MUTATOR_ADD(mutator_vampire);
1086
1087         if(cvar("sv_allow_fullbright"))
1088                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1089
1090     g_bugrigs = cvar("g_bugrigs");
1091     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1092     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1093     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1094     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1095     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1096     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1097     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1098     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1099     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1100     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1101     g_bugrigs_accel = cvar("g_bugrigs_accel");
1102     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1103     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1104     g_bugrigs_steer = cvar("g_bugrigs_steer");
1105
1106     g_touchexplode = cvar("g_touchexplode");
1107     g_touchexplode_radius = cvar("g_touchexplode_radius");
1108     g_touchexplode_damage = cvar("g_touchexplode_damage");
1109     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1110     g_touchexplode_force = cvar("g_touchexplode_force");
1111
1112 #ifdef ALLOW_FORCEMODELS
1113         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1114 #endif
1115         sv_loddistance1 = cvar("sv_loddistance1");
1116         sv_loddistance2 = cvar("sv_loddistance2");
1117
1118         if(sv_loddistance2 <= sv_loddistance1)
1119                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1120
1121         sv_clones = cvar("sv_clones");
1122         sv_gentle = cvar("sv_gentle");
1123         sv_foginterval = cvar("sv_foginterval");
1124         g_cloaked = cvar("g_cloaked");
1125     if(g_cts)
1126         g_cloaked = 1; // always enable cloak in CTS
1127         g_jump_grunt = cvar("g_jump_grunt");
1128         g_footsteps = cvar("g_footsteps");
1129         g_grappling_hook = cvar("g_grappling_hook");
1130         g_jetpack = cvar("g_jetpack");
1131         g_midair = cvar("g_midair");
1132         g_minstagib = cvar("g_minstagib");
1133         g_norecoil = cvar("g_norecoil");
1134         g_bloodloss = cvar("g_bloodloss");
1135         sv_maxidle = cvar("sv_maxidle");
1136         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1137         g_ctf_reverse = cvar("g_ctf_reverse");
1138         sv_autotaunt = cvar("sv_autotaunt");
1139         sv_taunt = cvar("sv_taunt");
1140
1141         inWarmupStage = cvar("g_warmup");
1142         g_warmup_limit = cvar("g_warmup_limit");
1143         g_warmup_allguns = cvar("g_warmup_allguns");
1144         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1145
1146         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1147                 inWarmupStage = 0; // these modes cannot work together, sorry
1148
1149         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1150         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1151         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1152         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1153         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1154         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1155         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1156         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1157         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1158         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1159         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1160         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1161
1162         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1163         g_weaponratefactor = cvar("g_weaponratefactor");
1164         g_weapondamagefactor = cvar("g_weapondamagefactor");
1165         g_weaponforcefactor = cvar("g_weaponforcefactor");
1166         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1167
1168         g_pickup_shells = cvar("g_pickup_shells");
1169         g_pickup_shells_max = cvar("g_pickup_shells_max");
1170         g_pickup_nails = cvar("g_pickup_nails");
1171         g_pickup_nails_max = cvar("g_pickup_nails_max");
1172         g_pickup_rockets = cvar("g_pickup_rockets");
1173         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1174         g_pickup_cells = cvar("g_pickup_cells");
1175         g_pickup_cells_max = cvar("g_pickup_cells_max");
1176         g_pickup_fuel = cvar("g_pickup_fuel");
1177         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1178         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1179         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1180         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1181         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1182         g_pickup_armormedium = cvar("g_pickup_armormedium");
1183         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1184         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1185         g_pickup_armorbig = cvar("g_pickup_armorbig");
1186         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1187         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1188         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1189         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1190         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1191         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1192         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1193         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1194         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1195         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1196         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1197         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1198         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1199         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1200         g_pickup_healthmega = cvar("g_pickup_healthmega");
1201         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1202         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1203
1204         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1205         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1206
1207         g_pinata = cvar("g_pinata");
1208
1209     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1210     if(!g_weapon_stay)
1211         g_weapon_stay = cvar("g_weapon_stay");
1212
1213         g_ghost_items = cvar("g_ghost_items");
1214
1215         if(g_ghost_items >= 1)
1216                 g_ghost_items = 0.25; // default alpha value
1217
1218         if not(inWarmupStage && !g_ca)
1219                 game_starttime = cvar("g_start_delay");
1220
1221         sv_pitch_min = cvar("sv_pitch_min");
1222         sv_pitch_max = cvar("sv_pitch_max");
1223         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1224
1225         readplayerstartcvars();
1226 }
1227
1228 //#NO AUTOCVARS END
1229
1230 // Sound functions
1231 string precache_sound (string s) = #19;
1232 float precache_sound_index (string s) = #19;
1233
1234 #define SND_VOLUME      1
1235 #define SND_ATTENUATION 2
1236 #define SND_LARGEENTITY 8
1237 #define SND_LARGESOUND  16
1238
1239 float sound_allowed(float dest, entity e)
1240 {
1241     // sounds from world may always pass
1242     for (;;)
1243     {
1244         if (e.classname == "body")
1245             e = e.enemy;
1246         if (e.owner && e.owner != e)
1247             e = e.owner;
1248         else
1249             break;
1250     }
1251     // sounds to self may always pass
1252     if (dest == MSG_ONE)
1253         if (e == msg_entity)
1254             return TRUE;
1255     // sounds by players can be removed
1256     if (autocvar_bot_sound_monopoly)
1257         if (clienttype(e) == CLIENTTYPE_REAL)
1258             return FALSE;
1259     // anything else may pass
1260     return TRUE;
1261 }
1262
1263 #ifdef COMPAT_XON010_CHANNELS
1264 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1265 void sound(entity e, float chan, string samp, float vol, float atten)
1266 {
1267     if (!sound_allowed(MSG_BROADCAST, e))
1268         return;
1269     sound_builtin(e, chan, samp, vol, atten);
1270 }
1271 #else
1272 #undef sound
1273 void sound(entity e, float chan, string samp, float vol, float atten)
1274 {
1275     if (!sound_allowed(MSG_BROADCAST, e))
1276         return;
1277     sound7(e, chan, samp, vol, atten, 0, 0);
1278 }
1279 #endif
1280
1281 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1282 {
1283     float entno, idx;
1284
1285     if (!sound_allowed(dest, e))
1286         return;
1287
1288     entno = num_for_edict(e);
1289     idx = precache_sound_index(samp);
1290
1291     float sflags;
1292     sflags = 0;
1293
1294     atten = floor(atten * 64);
1295     vol = floor(vol * 255);
1296
1297     if (vol != 255)
1298         sflags |= SND_VOLUME;
1299     if (atten != 64)
1300         sflags |= SND_ATTENUATION;
1301     if (entno >= 8192 || chan < 0 || chan > 7)
1302         sflags |= SND_LARGEENTITY;
1303     if (idx >= 256)
1304         sflags |= SND_LARGESOUND;
1305
1306     WriteByte(dest, SVC_SOUND);
1307     WriteByte(dest, sflags);
1308     if (sflags & SND_VOLUME)
1309         WriteByte(dest, vol);
1310     if (sflags & SND_ATTENUATION)
1311         WriteByte(dest, atten);
1312     if (sflags & SND_LARGEENTITY)
1313     {
1314         WriteShort(dest, entno);
1315         WriteByte(dest, chan);
1316     }
1317     else
1318     {
1319         WriteShort(dest, entno * 8 + chan);
1320     }
1321     if (sflags & SND_LARGESOUND)
1322         WriteShort(dest, idx);
1323     else
1324         WriteByte(dest, idx);
1325
1326     WriteCoord(dest, o_x);
1327     WriteCoord(dest, o_y);
1328     WriteCoord(dest, o_z);
1329 }
1330 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1331 {
1332     vector o;
1333
1334     if (!sound_allowed(dest, e))
1335         return;
1336
1337     o = e.origin + 0.5 * (e.mins + e.maxs);
1338     soundtoat(dest, e, o, chan, samp, vol, atten);
1339 }
1340 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1341 {
1342     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1343 }
1344 void stopsoundto(float dest, entity e, float chan)
1345 {
1346     float entno;
1347
1348     if (!sound_allowed(dest, e))
1349         return;
1350
1351     entno = num_for_edict(e);
1352
1353     if (entno >= 8192 || chan < 0 || chan > 7)
1354     {
1355         float idx, sflags;
1356         idx = precache_sound_index("misc/null.wav");
1357         sflags = SND_LARGEENTITY;
1358         if (idx >= 256)
1359             sflags |= SND_LARGESOUND;
1360         WriteByte(dest, SVC_SOUND);
1361         WriteByte(dest, sflags);
1362         WriteShort(dest, entno);
1363         WriteByte(dest, chan);
1364         if (sflags & SND_LARGESOUND)
1365             WriteShort(dest, idx);
1366         else
1367             WriteByte(dest, idx);
1368         WriteCoord(dest, e.origin_x);
1369         WriteCoord(dest, e.origin_y);
1370         WriteCoord(dest, e.origin_z);
1371     }
1372     else
1373     {
1374         WriteByte(dest, SVC_STOPSOUND);
1375         WriteShort(dest, entno * 8 + chan);
1376     }
1377 }
1378 void stopsound(entity e, float chan)
1379 {
1380     if (!sound_allowed(MSG_BROADCAST, e))
1381         return;
1382
1383     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1384     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1385 }
1386
1387 void play2(entity e, string filename)
1388 {
1389     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1390     msg_entity = e;
1391     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1392 }
1393
1394 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1395 .float spamtime;
1396 float spamsound(entity e, float chan, string samp, float vol, float atten)
1397 {
1398     if (!sound_allowed(MSG_BROADCAST, e))
1399         return FALSE;
1400
1401     if (time > e.spamtime)
1402     {
1403         e.spamtime = time;
1404         sound(e, chan, samp, vol, atten);
1405         return TRUE;
1406     }
1407     return FALSE;
1408 }
1409
1410 void play2team(float t, string filename)
1411 {
1412     local entity head;
1413
1414     if (autocvar_bot_sound_monopoly)
1415         return;
1416
1417     FOR_EACH_REALPLAYER(head)
1418     {
1419         if (head.team == t)
1420             play2(head, filename);
1421     }
1422 }
1423
1424 void play2all(string samp)
1425 {
1426     if (autocvar_bot_sound_monopoly)
1427         return;
1428
1429     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1430 }
1431
1432 void PrecachePlayerSounds(string f);
1433 void precache_playermodel(string m)
1434 {
1435         float globhandle, i, n;
1436         string f;
1437
1438         if(substring(m, -9,5) == "_lod1")
1439                 return;
1440         if(substring(m, -9,5) == "_lod2")
1441                 return;
1442         precache_model(m);
1443         if(sv_loddistance1)
1444         {
1445                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1446                 if(fexists(f))
1447                         precache_model(f);
1448                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1449                 if(fexists(f))
1450                         precache_model(f);
1451         }
1452
1453         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1454         if (globhandle < 0)
1455                 return;
1456         n = search_getsize(globhandle);
1457         for (i = 0; i < n; ++i)
1458         {
1459                 //print(search_getfilename(globhandle, i), "\n");
1460                 f = search_getfilename(globhandle, i);
1461                 PrecachePlayerSounds(f);
1462         }
1463         search_end(globhandle);
1464 }
1465 void precache_all_playermodels(string pattern)
1466 {
1467         float globhandle, i, n;
1468         string f;
1469
1470         globhandle = search_begin(pattern, TRUE, FALSE);
1471         if (globhandle < 0)
1472                 return;
1473         n = search_getsize(globhandle);
1474         for (i = 0; i < n; ++i)
1475         {
1476                 //print(search_getfilename(globhandle, i), "\n");
1477                 f = search_getfilename(globhandle, i);
1478                 precache_playermodel(f);
1479         }
1480         search_end(globhandle);
1481 }
1482
1483 void precache()
1484 {
1485     // gamemode related things
1486     precache_model ("models/misc/chatbubble.spr");
1487     if (g_runematch)
1488     {
1489         precache_model ("models/runematch/curse.mdl");
1490         precache_model ("models/runematch/rune.mdl");
1491     }
1492
1493 #ifdef TTURRETS_ENABLED
1494     if (autocvar_g_turrets)
1495         turrets_precash();
1496 #endif
1497
1498     // Precache all player models if desired
1499     if (autocvar_sv_precacheplayermodels)
1500     {
1501         PrecachePlayerSounds("sound/player/default.sounds");
1502         precache_all_playermodels("models/player/*.zym");
1503         precache_all_playermodels("models/player/*.dpm");
1504         precache_all_playermodels("models/player/*.md3");
1505         precache_all_playermodels("models/player/*.psk");
1506         precache_all_playermodels("models/player/*.iqm");
1507     }
1508
1509     if (autocvar_sv_defaultcharacter)
1510     {
1511         string s;
1512         s = autocvar_sv_defaultplayermodel_red;
1513         if (s != "")
1514             precache_playermodel(s);
1515         s = autocvar_sv_defaultplayermodel_blue;
1516         if (s != "")
1517             precache_playermodel(s);
1518         s = autocvar_sv_defaultplayermodel_yellow;
1519         if (s != "")
1520             precache_playermodel(s);
1521         s = autocvar_sv_defaultplayermodel_pink;
1522         if (s != "")
1523             precache_playermodel(s);
1524         s = autocvar_sv_defaultplayermodel;
1525         if (s != "")
1526             precache_playermodel(s);
1527     }
1528
1529     if (g_footsteps)
1530     {
1531         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1532         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1533     }
1534
1535     // gore and miscellaneous sounds
1536     //precache_sound ("misc/h2ohit.wav");
1537     precache_model ("models/hook.md3");
1538     precache_sound ("misc/armorimpact.wav");
1539     precache_sound ("misc/bodyimpact1.wav");
1540     precache_sound ("misc/bodyimpact2.wav");
1541     precache_sound ("misc/gib.wav");
1542     precache_sound ("misc/gib_splat01.wav");
1543     precache_sound ("misc/gib_splat02.wav");
1544     precache_sound ("misc/gib_splat03.wav");
1545     precache_sound ("misc/gib_splat04.wav");
1546     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1547     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1548     precache_sound ("misc/null.wav");
1549     precache_sound ("misc/spawn.wav");
1550     precache_sound ("misc/talk.wav");
1551     precache_sound ("misc/teleport.wav");
1552     precache_sound ("misc/poweroff.wav");
1553     precache_sound ("player/lava.wav");
1554     precache_sound ("player/slime.wav");
1555
1556     if (g_jetpack)
1557         precache_sound ("misc/jetpack_fly.wav");
1558
1559     precache_model ("models/sprites/0.spr32");
1560     precache_model ("models/sprites/1.spr32");
1561     precache_model ("models/sprites/2.spr32");
1562     precache_model ("models/sprites/3.spr32");
1563     precache_model ("models/sprites/4.spr32");
1564     precache_model ("models/sprites/5.spr32");
1565     precache_model ("models/sprites/6.spr32");
1566     precache_model ("models/sprites/7.spr32");
1567     precache_model ("models/sprites/8.spr32");
1568     precache_model ("models/sprites/9.spr32");
1569     precache_model ("models/sprites/10.spr32");
1570
1571     // common weapon precaches
1572         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1573     precache_sound ("weapons/weapon_switch.wav");
1574     precache_sound ("weapons/weaponpickup.wav");
1575     precache_sound ("weapons/unavailable.wav");
1576     precache_sound ("weapons/dryfire.wav");
1577     if (g_grappling_hook)
1578     {
1579         precache_sound ("weapons/hook_fire.wav"); // hook
1580         precache_sound ("weapons/hook_impact.wav"); // hook
1581     }
1582
1583     if(autocvar_sv_precacheweapons)
1584     {
1585         //precache weapon models/sounds
1586         local float wep;
1587         wep = WEP_FIRST;
1588         while (wep <= WEP_LAST)
1589         {
1590             weapon_action(wep, WR_PRECACHE);
1591             wep = wep + 1;
1592         }
1593     }
1594
1595     precache_model("models/elaser.mdl");
1596     precache_model("models/laser.mdl");
1597     precache_model("models/ebomb.mdl");
1598
1599 #if 0
1600     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1601
1602     if (!self.noise && self.music) // quake 3 uses the music field
1603         self.noise = self.music;
1604
1605     // plays music for the level if there is any
1606     if (self.noise)
1607     {
1608         precache_sound (self.noise);
1609         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1610     }
1611 #endif
1612 }
1613
1614 // sorry, but using \ in macros breaks line numbers
1615 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1616 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1617 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1618
1619
1620 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1621 {
1622         if (clienttype(e) == CLIENTTYPE_REAL)
1623         {
1624                 msg_entity = e;
1625                 WRITESPECTATABLE_MSG_ONE({
1626                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1627                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1628                         WriteByte(MSG_ONE, id);
1629                         WriteString(MSG_ONE, s);
1630                         if (id != 0 && s != "")
1631                         {
1632                                 WriteByte(MSG_ONE, duration);
1633                                 WriteByte(MSG_ONE, countdown_num);
1634                         }
1635                 });
1636         }
1637 }
1638 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1639 {
1640         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1641 }
1642 // WARNING: this kills the trace globals
1643 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1644 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1645
1646 #define INITPRIO_FIRST              0
1647 #define INITPRIO_GAMETYPE           0
1648 #define INITPRIO_GAMETYPE_FALLBACK  1
1649 #define INITPRIO_FINDTARGET        10
1650 #define INITPRIO_DROPTOFLOOR       20
1651 #define INITPRIO_SETLOCATION       90
1652 #define INITPRIO_LINKDOORS         91
1653 #define INITPRIO_LAST              99
1654
1655 .void(void) initialize_entity;
1656 .float initialize_entity_order;
1657 .entity initialize_entity_next;
1658 entity initialize_entity_first;
1659
1660 void make_safe_for_remove(entity e)
1661 {
1662     if (e.initialize_entity)
1663     {
1664         entity ent, prev;
1665         for (ent = initialize_entity_first; ent; )
1666         {
1667             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1668             {
1669                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1670                 // skip it in linked list
1671                 if (prev)
1672                 {
1673                     prev.initialize_entity_next = ent.initialize_entity_next;
1674                     ent = prev.initialize_entity_next;
1675                 }
1676                 else
1677                 {
1678                     initialize_entity_first = ent.initialize_entity_next;
1679                     ent = initialize_entity_first;
1680                 }
1681             }
1682             else
1683             {
1684                 prev = ent;
1685                 ent = ent.initialize_entity_next;
1686             }
1687         }
1688     }
1689 }
1690
1691 void objerror(string s)
1692 {
1693     make_safe_for_remove(self);
1694     objerror_builtin(s);
1695 }
1696
1697 .float remove_except_protected_forbidden;
1698 void remove_except_protected(entity e)
1699 {
1700         if(e.remove_except_protected_forbidden)
1701                 error("not allowed to remove this at this point");
1702         remove_builtin(e);
1703 }
1704
1705 void remove_unsafely(entity e)
1706 {
1707     if(e.classname == "spike")
1708         error("Removing spikes is forbidden (crylink bug), please report");
1709     remove_builtin(e);
1710 }
1711
1712 void remove_safely(entity e)
1713 {
1714     make_safe_for_remove(e);
1715     remove_builtin(e);
1716 }
1717
1718 void InitializeEntity(entity e, void(void) func, float order)
1719 {
1720     entity prev, cur;
1721
1722     if (!e || e.initialize_entity)
1723     {
1724         // make a proxy initializer entity
1725         entity e_old;
1726         e_old = e;
1727         e = spawn();
1728         e.classname = "initialize_entity";
1729         e.enemy = e_old;
1730     }
1731
1732     e.initialize_entity = func;
1733     e.initialize_entity_order = order;
1734
1735     cur = initialize_entity_first;
1736     for (;;)
1737     {
1738         if (!cur || cur.initialize_entity_order > order)
1739         {
1740             // insert between prev and cur
1741             if (prev)
1742                 prev.initialize_entity_next = e;
1743             else
1744                 initialize_entity_first = e;
1745             e.initialize_entity_next = cur;
1746             return;
1747         }
1748         prev = cur;
1749         cur = cur.initialize_entity_next;
1750     }
1751 }
1752 void InitializeEntitiesRun()
1753 {
1754     entity startoflist;
1755     startoflist = initialize_entity_first;
1756     initialize_entity_first = world;
1757     remove = remove_except_protected;
1758     for (self = startoflist; self; self = self.initialize_entity_next)
1759     {
1760         self.remove_except_protected_forbidden = 1;
1761     }
1762     for (self = startoflist; self; )
1763     {
1764         entity e;
1765         var void(void) func;
1766         e = self.initialize_entity_next;
1767         func = self.initialize_entity;
1768         self.initialize_entity_order = 0;
1769         self.initialize_entity = func_null;
1770         self.initialize_entity_next = world;
1771         self.remove_except_protected_forbidden = 0;
1772         if (self.classname == "initialize_entity")
1773         {
1774             entity e_old;
1775             e_old = self.enemy;
1776             remove_builtin(self);
1777             self = e_old;
1778         }
1779         //dprint("Delayed initialization: ", self.classname, "\n");
1780         if(func != func_null)
1781             func();
1782         else
1783         {
1784             eprint(self);
1785             backtrace(strcat("Null function in: ", self.classname, "\n"));
1786         }
1787         self = e;
1788     }
1789     remove = remove_unsafely;
1790 }
1791
1792 .float uncustomizeentityforclient_set;
1793 .void(void) uncustomizeentityforclient;
1794 void(void) SUB_Nullpointer = #0;
1795 void UncustomizeEntitiesRun()
1796 {
1797     entity oldself;
1798     oldself = self;
1799     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1800         self.uncustomizeentityforclient();
1801     self = oldself;
1802 }
1803 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1804 {
1805     e.customizeentityforclient = customizer;
1806     e.uncustomizeentityforclient = uncustomizer;
1807     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1808 }
1809
1810 .float nottargeted;
1811 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1812
1813 void() SUB_Remove;
1814 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1815 {
1816     vector mi, ma;
1817
1818     if (e.classname == "")
1819         e.classname = "net_linked";
1820
1821     if (e.model == "" || self.modelindex == 0)
1822     {
1823         mi = e.mins;
1824         ma = e.maxs;
1825         setmodel(e, "null");
1826         setsize(e, mi, ma);
1827     }
1828
1829     e.SendEntity = sendfunc;
1830     e.SendFlags = 0xFFFFFF;
1831
1832     if (!docull)
1833         e.effects |= EF_NODEPTHTEST;
1834
1835     if (dt)
1836     {
1837         e.nextthink = time + dt;
1838         e.think = SUB_Remove;
1839     }
1840 }
1841
1842 void adaptor_think2touch()
1843 {
1844     entity o;
1845     o = other;
1846     other = world;
1847     self.touch();
1848     other = o;
1849 }
1850
1851 void adaptor_think2use()
1852 {
1853     entity o, a;
1854     o = other;
1855     a = activator;
1856     activator = world;
1857     other = world;
1858     self.use();
1859     other = o;
1860     activator = a;
1861 }
1862
1863 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1864 {
1865         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1866                 self.projectiledeathtype |= HITTYPE_SPLASH;
1867         adaptor_think2use();
1868 }
1869
1870 // deferred dropping
1871 void DropToFloor_Handler()
1872 {
1873     droptofloor_builtin();
1874     self.dropped_origin = self.origin;
1875 }
1876
1877 void droptofloor()
1878 {
1879     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1880 }
1881
1882
1883
1884 float trace_hits_box_a0, trace_hits_box_a1;
1885
1886 float trace_hits_box_1d(float end, float thmi, float thma)
1887 {
1888     if (end == 0)
1889     {
1890         // just check if x is in range
1891         if (0 < thmi)
1892             return FALSE;
1893         if (0 > thma)
1894             return FALSE;
1895     }
1896     else
1897     {
1898         // do the trace with respect to x
1899         // 0 -> end has to stay in thmi -> thma
1900         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1901         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1902         if (trace_hits_box_a0 > trace_hits_box_a1)
1903             return FALSE;
1904     }
1905     return TRUE;
1906 }
1907
1908 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1909 {
1910     end -= start;
1911     thmi -= start;
1912     thma -= start;
1913     // now it is a trace from 0 to end
1914
1915     trace_hits_box_a0 = 0;
1916     trace_hits_box_a1 = 1;
1917
1918     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1919         return FALSE;
1920     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1921         return FALSE;
1922     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1923         return FALSE;
1924
1925     return TRUE;
1926 }
1927
1928 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1929 {
1930     return trace_hits_box(start, end, thmi - ma, thma - mi);
1931 }
1932
1933 float SUB_NoImpactCheck()
1934 {
1935         // zero hitcontents = this is not the real impact, but either the
1936         // mirror-impact of something hitting the projectile instead of the
1937         // projectile hitting the something, or a touchareagrid one. Neither of
1938         // these stop the projectile from moving, so...
1939         if(trace_dphitcontents == 0)
1940         {
1941                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1942                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1943                 checkclient();
1944         }
1945     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1946         return 1;
1947     if (other == world && self.size != '0 0 0')
1948     {
1949         vector tic;
1950         tic = self.velocity * sys_frametime;
1951         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1952         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1953         if (trace_fraction >= 1)
1954         {
1955             dprint("Odd... did not hit...?\n");
1956         }
1957         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1958         {
1959             dprint("Detected and prevented the sky-grapple bug.\n");
1960             return 1;
1961         }
1962     }
1963
1964     return 0;
1965 }
1966
1967 #define SUB_OwnerCheck() (other && (other == self.owner))
1968
1969 void RemoveGrapplingHook(entity pl);
1970 void W_Crylink_Dequeue(entity e);
1971 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1972 {
1973         if(SUB_OwnerCheck())
1974                 return TRUE;
1975         if(SUB_NoImpactCheck())
1976         {
1977                 if(self.classname == "grapplinghook")
1978                         RemoveGrapplingHook(self.realowner);
1979                 else if(self.classname == "spike")
1980                 {
1981                         W_Crylink_Dequeue(self);
1982                         remove(self);
1983                 }
1984                 else
1985                         remove(self);
1986                 return TRUE;
1987         }
1988         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1989                 UpdateCSQCProjectile(self);
1990         return FALSE;
1991 }
1992 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1993
1994 float MAX_IPBAN_URIS           = 16;
1995
1996 float URI_GET_DISCARD          = 0;
1997 float URI_GET_IPBAN            = 1;
1998 float URI_GET_IPBAN_END        = 16;
1999
2000 void URI_Get_Callback(float id, float status, string data)
2001 {
2002     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2003     dprint(data);
2004     dprint("\nEnd of data.\n");
2005
2006     if(url_URI_Get_Callback(id, status, data))
2007     {
2008         // handled
2009     }
2010     else if (id == URI_GET_DISCARD)
2011     {
2012         // discard
2013     }
2014     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2015     {
2016         // online ban list
2017         OnlineBanList_URI_Get_Callback(id, status, data);
2018     }
2019     else
2020     {
2021         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2022     }
2023 }
2024
2025 void print_to(entity e, string s)
2026 {
2027     if (e)
2028         sprint(e, strcat(s, "\n"));
2029     else
2030         print(s, "\n");
2031 }
2032
2033 string uid2name(string myuid) {
2034         string s;
2035         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2036
2037         if(s == "")
2038                 s = "^1Unregistered Player";
2039         return s;
2040 }
2041
2042 float race_readTime(string map, float pos)
2043 {
2044         string rr;
2045         if(g_cts)
2046                 rr = CTS_RECORD;
2047         else
2048                 rr = RACE_RECORD;
2049
2050         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2051 }
2052
2053 string race_readUID(string map, float pos)
2054 {
2055         string rr;
2056         if(g_cts)
2057                 rr = CTS_RECORD;
2058         else
2059                 rr = RACE_RECORD;
2060
2061         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2062 }
2063
2064 float race_readPos(string map, float t) {
2065         float i;
2066         for (i = 1; i <= RANKINGS_CNT; ++i)
2067                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2068                         return i;
2069
2070         return 0; // pos is zero if unranked
2071 }
2072
2073 void race_writeTime(string map, float t, string myuid)
2074 {
2075         string rr;
2076         if(g_cts)
2077                 rr = CTS_RECORD;
2078         else
2079                 rr = RACE_RECORD;
2080
2081         float newpos;
2082         newpos = race_readPos(map, t);
2083
2084         float i, prevpos;
2085         for(i = 1; i <= RANKINGS_CNT; ++i)
2086         {
2087                 if(race_readUID(map, i) == myuid)
2088                         prevpos = i;
2089         }
2090         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2091                 for (i = prevpos; i > newpos; --i) {
2092                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2093                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2094                 }
2095         } else { // player has no ranked record yet
2096                 for (i = RANKINGS_CNT; i > newpos; --i) {
2097                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2098                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2099                 }
2100         }
2101
2102         // store new time itself
2103         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2104         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2105 }
2106
2107 string race_readName(string map, float pos)
2108 {
2109         string rr;
2110         if(g_cts)
2111                 rr = CTS_RECORD;
2112         else
2113                 rr = RACE_RECORD;
2114
2115         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2116 }
2117
2118 string race_placeName(float pos) {
2119         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2120         {
2121                 if(mod(pos, 10) == 1)
2122                         return strcat(ftos(pos), "st");
2123                 else if(mod(pos, 10) == 2)
2124                         return strcat(ftos(pos), "nd");
2125                 else if(mod(pos, 10) == 3)
2126                         return strcat(ftos(pos), "rd");
2127                 else
2128                         return strcat(ftos(pos), "th");
2129         }
2130         else
2131                 return strcat(ftos(pos), "th");
2132 }
2133 string getrecords(float page) // 50 records per page
2134 {
2135     float rec;
2136     string h;
2137     float r;
2138     float i;
2139     string s;
2140
2141     rec = 0;
2142
2143     s = "";
2144
2145     if (g_ctf)
2146     {
2147         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2148         {
2149             if (MapInfo_Get_ByID(i))
2150             {
2151                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2152                 if (r == 0)
2153                     continue;
2154                 // TODO: uid2name
2155                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2156                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2157                 ++rec;
2158             }
2159         }
2160     }
2161
2162     if (g_race)
2163     {
2164         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2165         {
2166             if (MapInfo_Get_ByID(i))
2167             {
2168                 r = race_readTime(MapInfo_Map_bspname, 1);
2169                 if (r == 0)
2170                     continue;
2171                 h = race_readName(MapInfo_Map_bspname, 1);
2172                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2173                 ++rec;
2174             }
2175         }
2176     }
2177
2178     if (g_cts)
2179     {
2180         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2181         {
2182             if (MapInfo_Get_ByID(i))
2183             {
2184                 r = race_readTime(MapInfo_Map_bspname, 1);
2185                 if (r == 0)
2186                     continue;
2187                 h = race_readName(MapInfo_Map_bspname, 1);
2188                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2189                 ++rec;
2190             }
2191         }
2192     }
2193
2194     MapInfo_ClearTemps();
2195
2196     if (s == "" && page == 0)
2197         return "No records are available on this server.\n";
2198     else
2199         return s;
2200 }
2201
2202 string getrankings()
2203 {
2204     string n;
2205     float t;
2206     float i;
2207     string s;
2208     string p;
2209     string map;
2210
2211     s = "";
2212
2213     map = GetMapname();
2214
2215     for (i = 1; i <= RANKINGS_CNT; ++i)
2216     {
2217         t = race_readTime(map, i);
2218         if (t == 0)
2219             continue;
2220         n = race_readName(map, i);
2221         p = race_placeName(i);
2222         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2223     }
2224
2225     MapInfo_ClearTemps();
2226
2227     if (s == "")
2228         return strcat("No records are available for the map: ", map, "\n");
2229     else
2230         return strcat("Records for ", map, ":\n", s);
2231 }
2232
2233 #define LADDER_FIRSTPOINT 100
2234 #define LADDER_CNT 10
2235         // position X still gives LADDER_FIRSTPOINT/X points
2236 #define LADDER_SIZE 30
2237         // ladder shows the top X players
2238 string top_uids[LADDER_SIZE];
2239 float top_scores[LADDER_SIZE];
2240 string getladder()
2241 {
2242     float i, j, k, uidcnt;
2243     string s, temp_s;
2244
2245     s = "";
2246     temp_s = "";
2247
2248     string rr;
2249     if(g_cts)
2250         rr = CTS_RECORD;
2251     else
2252         rr = RACE_RECORD;
2253
2254     string myuid;
2255
2256     for (k = 0; k < MapInfo_count; ++k)
2257     {
2258         if (MapInfo_Get_ByID(k))
2259         {
2260                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2261                         if(i == 0) // speed award
2262                         {
2263                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2264                                         continue;
2265
2266                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2267                         }
2268                         else // normal record, if it exists (else break)
2269                         {
2270                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2271                                         continue;
2272
2273                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2274                         }
2275
2276                         // string s contains:
2277                         // arg 0 = # of speed recs
2278                         // arg 1 = # of 1st place recs
2279                         // arg 2 = # of 2nd place recs
2280                         // ... etc
2281                         // LADDER_CNT+1 = total points
2282
2283                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2284                         if (temp_s == "")
2285                         {
2286                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2287                             ++uidcnt;
2288                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2289                             {
2290                                 if(j != LADDER_CNT + 1)
2291                                     temp_s = strcat(temp_s, "0 ");
2292                                 else
2293                                     temp_s = strcat(temp_s, "0");
2294                             }
2295                         }
2296
2297                         tokenize_console(temp_s);
2298                         s = "";
2299
2300                         if(i == 0) // speed award
2301                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2302                             {
2303                                 if(j == 0) // speed award
2304                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2305                                 else
2306                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2307                             }
2308                         else // record
2309                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2310                             {
2311                                 if(j == 0)
2312                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2313                                 else if(j == i) // wanted rec!
2314                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2315                                 else
2316                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2317                             }
2318
2319                         // total points are (by default) calculated like this:
2320                         // speedrec = floor(100 / 10) = 10 points
2321                         // 1st place = floor(100 / 1) = 100 points
2322                         // 2nd place = floor(100 / 2) = 50 points
2323                         // 3rd place = floor(100 / 3) = 33 points
2324                         // 4th place = floor(100 / 4) = 25 points
2325                         // 5th place = floor(100 / 5) = 20 points
2326                         // ... etc
2327
2328                         if(i == 0)
2329                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2330                         else
2331                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2332
2333                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2334                 }
2335         }
2336     }
2337
2338     float thiscnt;
2339     string thisuid;
2340     for (i = 0; i <= uidcnt; ++i) // for each known uid
2341     {
2342         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2343         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2344         tokenize_console(temp_s);
2345         thiscnt = stof(argv(LADDER_CNT+1));
2346
2347         if(thiscnt > top_scores[LADDER_SIZE-1])
2348         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2349         {
2350             if(thiscnt > top_scores[j])
2351             {
2352                 for (k = LADDER_SIZE-1; k >= j; --k)
2353                 {
2354                     top_uids[k] = top_uids[k-1];
2355                     top_scores[k] = top_scores[k-1];
2356                 }
2357                 top_uids[j] = thisuid;
2358                 top_scores[j] = thiscnt;
2359                 break;
2360             }
2361         }
2362     }
2363
2364     s = "^3-----------------------\n\n";
2365
2366     s = strcat(s, "Pos ^3|");
2367     s = strcat(s, " ^7Total  ^3|");
2368     for (i = 1; i <= LADDER_CNT; ++i)
2369     {
2370         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2371     }
2372     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2373
2374     s = strcat(s, "\n^3----+--------");
2375     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2376     {
2377         s = strcat(s, "+-----");
2378     }
2379 #if LADDER_CNT > 9
2380     for (i = 1; i <= LADDER_CNT - 9; ++i)
2381     {
2382         s = strcat(s, "+------");
2383     }
2384 #endif
2385
2386     s = strcat(s, "+--------------+--------------------\n");
2387
2388     for (i = 0; i < LADDER_SIZE; ++i)
2389     {
2390         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2391         tokenize_console(temp_s);
2392         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2393             continue;
2394         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2395         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2396         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2397         {
2398             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2399         }
2400 #if LADDER_CNT > 9
2401         for (j = 10; j <= LADDER_CNT; ++j)
2402         {
2403             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2404         }
2405 #endif
2406
2407         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2408         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2409     }
2410
2411     MapInfo_ClearTemps();
2412
2413     if (s == "")
2414         return "No ladder on this server!\n";
2415     else
2416         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2417 }
2418
2419
2420 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2421 {
2422     float m, i;
2423     vector start, org, delta, end, enddown, mstart;
2424     entity sp;
2425
2426     m = e.dphitcontentsmask;
2427     e.dphitcontentsmask = goodcontents | badcontents;
2428
2429     org = world.mins;
2430     delta = world.maxs - world.mins;
2431
2432     for (i = 0; i < attempts; ++i)
2433     {
2434         start_x = org_x + random() * delta_x;
2435         start_y = org_y + random() * delta_y;
2436         start_z = org_z + random() * delta_z;
2437
2438         // rule 1: start inside world bounds, and outside
2439         // solid, and don't start from somewhere where you can
2440         // fall down to evil
2441         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2442         if (trace_fraction >= 1)
2443             continue;
2444         if (trace_startsolid)
2445             continue;
2446         if (trace_dphitcontents & badcontents)
2447             continue;
2448         if (trace_dphitq3surfaceflags & badsurfaceflags)
2449             continue;
2450
2451         // rule 2: if we are too high, lower the point
2452         if (trace_fraction * delta_z > maxaboveground)
2453             start = trace_endpos + '0 0 1' * maxaboveground;
2454         enddown = trace_endpos;
2455
2456         // rule 3: make sure we aren't outside the map. This only works
2457         // for somewhat well formed maps. A good rule of thumb is that
2458         // the map should have a convex outside hull.
2459         // these can be traceLINES as we already verified the starting box
2460         mstart = start + 0.5 * (e.mins + e.maxs);
2461         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2462         if (trace_fraction >= 1)
2463             continue;
2464         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2465         if (trace_fraction >= 1)
2466             continue;
2467         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2468         if (trace_fraction >= 1)
2469             continue;
2470         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2471         if (trace_fraction >= 1)
2472             continue;
2473         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2474         if (trace_fraction >= 1)
2475             continue;
2476
2477         // rule 4: we must "see" some spawnpoint
2478         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2479                 if(checkpvs(mstart, sp))
2480                         break;
2481         if(!sp)
2482         {
2483                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2484                         if(checkpvs(mstart, sp))
2485                                 break;
2486                 if(!sp)
2487                         continue;
2488         }
2489
2490         // find a random vector to "look at"
2491         end_x = org_x + random() * delta_x;
2492         end_y = org_y + random() * delta_y;
2493         end_z = org_z + random() * delta_z;
2494         end = start + normalize(end - start) * vlen(delta);
2495
2496         // rule 4: start TO end must not be too short
2497         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2498         if (trace_startsolid)
2499             continue;
2500         if (trace_fraction < minviewdistance / vlen(delta))
2501             continue;
2502
2503         // rule 5: don't want to look at sky
2504         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2505             continue;
2506
2507         // rule 6: we must not end up in trigger_hurt
2508         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2509             continue;
2510
2511         break;
2512     }
2513
2514     e.dphitcontentsmask = m;
2515
2516     if (i < attempts)
2517     {
2518         setorigin(e, start);
2519         e.angles = vectoangles(end - start);
2520         dprint("Needed ", ftos(i + 1), " attempts\n");
2521         return TRUE;
2522     }
2523     else
2524         return FALSE;
2525 }
2526
2527 float zcurveparticles_effectno;
2528 vector zcurveparticles_start;
2529 float zcurveparticles_spd;
2530
2531 void endzcurveparticles()
2532 {
2533         if(zcurveparticles_effectno)
2534         {
2535                 // terminator
2536                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2537         }
2538         zcurveparticles_effectno = 0;
2539 }
2540
2541 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2542 {
2543         spd = bound(0, floor(spd / 16), 32767);
2544         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2545         {
2546                 endzcurveparticles();
2547                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2548                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2549                 WriteShort(MSG_BROADCAST, effectno);
2550                 WriteCoord(MSG_BROADCAST, start_x);
2551                 WriteCoord(MSG_BROADCAST, start_y);
2552                 WriteCoord(MSG_BROADCAST, start_z);
2553                 zcurveparticles_effectno = effectno;
2554                 zcurveparticles_start = start;
2555         }
2556         else
2557                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2558         WriteCoord(MSG_BROADCAST, end_x);
2559         WriteCoord(MSG_BROADCAST, end_y);
2560         WriteCoord(MSG_BROADCAST, end_z);
2561         WriteCoord(MSG_BROADCAST, end_dz);
2562         zcurveparticles_spd = spd;
2563 }
2564
2565 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2566 {
2567         float end_dz;
2568         vector vecxy, velxy;
2569
2570         vecxy = end - start;
2571         vecxy_z = 0;
2572         velxy = vel;
2573         velxy_z = 0;
2574
2575         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2576         {
2577                 endzcurveparticles();
2578                 trailparticles(world, effectno, start, end);
2579                 return;
2580         }
2581
2582         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2583         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2584 }
2585
2586 void write_recordmarker(entity pl, float tstart, float dt)
2587 {
2588     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2589
2590     // also write a marker into demo files for demotc-race-record-extractor to find
2591     stuffcmd(pl,
2592              strcat(
2593                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2594                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2595 }
2596
2597 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2598 {
2599         switch(algn)
2600         {
2601                 default:
2602                 case 3: // right
2603                         break;
2604
2605                 case 4: // left
2606                         vecs_y = -vecs_y;
2607                         break;
2608
2609                 case 1:
2610                         if(allowcenter) // 2: allow center handedness
2611                         {
2612                                 // center
2613                                 vecs_y = 0;
2614                                 vecs_z -= 2;
2615                         }
2616                         else
2617                         {
2618                                 // right
2619                         }
2620                         break;
2621
2622                 case 2:
2623                         if(allowcenter) // 2: allow center handedness
2624                         {
2625                                 // center
2626                                 vecs_y = 0;
2627                                 vecs_z -= 2;
2628                         }
2629                         else
2630                         {
2631                                 // left
2632                                 vecs_y = -vecs_y;
2633                         }
2634                         break;
2635         }
2636         return vecs;
2637 }
2638
2639 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2640 {
2641         string s;
2642         vector v;
2643
2644         if (autocvar_g_shootfromeye)
2645         {
2646                 if (visual)
2647                 {
2648                         vecs_y = 0;
2649                         vecs_z -= 2;
2650                 }
2651                 else
2652                 {
2653                         vecs_y = 0;
2654                         vecs_z = 0;
2655                 }
2656         }
2657         else if (autocvar_g_shootfromcenter)
2658         {
2659                 vecs_y = 0;
2660                 vecs_z -= 2;
2661         }
2662         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2663         {
2664                 v = stov(s);
2665                 if (y_is_right)
2666                         v_y = -v_y;
2667                 if (v_x != 0)
2668                         vecs_x = v_x;
2669                 vecs_y = v_y;
2670                 vecs_z = v_z;
2671         }
2672         else if (autocvar_g_shootfromclient)
2673         {
2674                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2675         }
2676         return vecs;
2677 }
2678
2679 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2680 {
2681         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2682 }
2683
2684
2685 void attach_sameorigin(entity e, entity to, string tag)
2686 {
2687     vector org, t_forward, t_left, t_up, e_forward, e_up;
2688     vector org0, ang0;
2689     float tagscale;
2690
2691     ang0 = e.angles;
2692     org0 = e.origin;
2693
2694     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2695     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2696     t_forward = v_forward * tagscale;
2697     t_left = v_right * -tagscale;
2698     t_up = v_up * tagscale;
2699
2700     e.origin_x = org * t_forward;
2701     e.origin_y = org * t_left;
2702     e.origin_z = org * t_up;
2703
2704     // current forward and up directions
2705     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2706                 e.angles = AnglesTransform_FromVAngles(e.angles);
2707         else
2708                 e.angles = AnglesTransform_FromAngles(e.angles);
2709     fixedmakevectors(e.angles);
2710
2711     // untransform forward, up!
2712     e_forward_x = v_forward * t_forward;
2713     e_forward_y = v_forward * t_left;
2714     e_forward_z = v_forward * t_up;
2715     e_up_x = v_up * t_forward;
2716     e_up_y = v_up * t_left;
2717     e_up_z = v_up * t_up;
2718
2719     e.angles = fixedvectoangles2(e_forward, e_up);
2720     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2721                 e.angles = AnglesTransform_ToVAngles(e.angles);
2722         else
2723                 e.angles = AnglesTransform_ToAngles(e.angles);
2724
2725     setattachment(e, to, tag);
2726     setorigin(e, e.origin);
2727 }
2728
2729 void detach_sameorigin(entity e)
2730 {
2731     vector org;
2732     org = gettaginfo(e, 0);
2733     e.angles = fixedvectoangles2(v_forward, v_up);
2734     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2735                 e.angles = AnglesTransform_ToVAngles(e.angles);
2736         else
2737                 e.angles = AnglesTransform_ToAngles(e.angles);
2738     setorigin(e, org);
2739     setattachment(e, world, "");
2740     setorigin(e, e.origin);
2741 }
2742
2743 void follow_sameorigin(entity e, entity to)
2744 {
2745     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2746     e.aiment = to; // make the hole follow bmodel
2747     e.punchangle = to.angles; // the original angles of bmodel
2748     e.view_ofs = e.origin - to.origin; // relative origin
2749     e.v_angle = e.angles - to.angles; // relative angles
2750 }
2751
2752 void unfollow_sameorigin(entity e)
2753 {
2754     e.movetype = MOVETYPE_NONE;
2755 }
2756
2757 entity gettaginfo_relative_ent;
2758 vector gettaginfo_relative(entity e, float tag)
2759 {
2760     if (!gettaginfo_relative_ent)
2761     {
2762         gettaginfo_relative_ent = spawn();
2763         gettaginfo_relative_ent.effects = EF_NODRAW;
2764     }
2765     gettaginfo_relative_ent.model = e.model;
2766     gettaginfo_relative_ent.modelindex = e.modelindex;
2767     gettaginfo_relative_ent.frame = e.frame;
2768     return gettaginfo(gettaginfo_relative_ent, tag);
2769 }
2770
2771 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2772 {
2773     float p;
2774     p = pow(2, chan);
2775     if (pl.soundentity.cnt & p)
2776         return;
2777     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2778     pl.soundentity.cnt |= p;
2779 }
2780
2781 void SoundEntity_StopSound(entity pl, float chan)
2782 {
2783     float p;
2784     p = pow(2, chan);
2785     if (pl.soundentity.cnt & p)
2786     {
2787         stopsoundto(MSG_ALL, pl.soundentity, chan);
2788         pl.soundentity.cnt &~= p;
2789     }
2790 }
2791
2792 void SoundEntity_Attach(entity pl)
2793 {
2794     pl.soundentity = spawn();
2795     pl.soundentity.classname = "soundentity";
2796     pl.soundentity.owner = pl;
2797     setattachment(pl.soundentity, pl, "");
2798     setmodel(pl.soundentity, "null");
2799 }
2800
2801 void SoundEntity_Detach(entity pl)
2802 {
2803     float i;
2804     for (i = 0; i <= 7; ++i)
2805         SoundEntity_StopSound(pl, i);
2806 }
2807
2808
2809 float ParseCommandPlayerSlotTarget_firsttoken;
2810 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2811 {
2812         string s;
2813         entity e, head;
2814         float n;
2815
2816         s = string_null;
2817
2818         ParseCommandPlayerSlotTarget_firsttoken = -1;
2819
2820         if (tokens > idx)
2821         {
2822                 if (substring(argv(idx), 0, 1) == "#")
2823                 {
2824                         s = substring(argv(idx), 1, -1);
2825                         ++idx;
2826                         if (s == "") if (tokens > idx)
2827                         {
2828                                 s = argv(idx);
2829                                 ++idx;
2830                         }
2831                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2832                         n = stof(s);
2833                         if (s == ftos(n) && n > 0 && n <= maxclients)
2834                         {
2835                                 e = edict_num(n);
2836                                 if (e.flags & FL_CLIENT)
2837                                         return e;
2838                         }
2839                 }
2840                 else
2841                 {
2842                         // it must be a nick name
2843                         s = argv(idx);
2844                         ++idx;
2845                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2846
2847                         n = 0;
2848                         FOR_EACH_CLIENT(head)
2849                                 if (head.netname == s)
2850                                 {
2851                                         e = head;
2852                                         ++n;
2853                                 }
2854                         if (n == 1)
2855                                 return e;
2856
2857                         s = strdecolorize(s);
2858                         n = 0;
2859                         FOR_EACH_CLIENT(head)
2860                                 if (strdecolorize(head.netname) == s)
2861                                 {
2862                                         e = head;
2863                                         ++n;
2864                                 }
2865                         if (n == 1)
2866                                 return e;
2867                 }
2868         }
2869
2870         return world;
2871 }
2872
2873 .float scale2;
2874
2875 float modeleffect_SendEntity(entity to, float sf)
2876 {
2877         float f;
2878         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2879
2880         f = 0;
2881         if(self.velocity != '0 0 0')
2882                 f |= 1;
2883         if(self.angles != '0 0 0')
2884                 f |= 2;
2885         if(self.avelocity != '0 0 0')
2886                 f |= 4;
2887
2888         WriteByte(MSG_ENTITY, f);
2889         WriteShort(MSG_ENTITY, self.modelindex);
2890         WriteByte(MSG_ENTITY, self.skin);
2891         WriteByte(MSG_ENTITY, self.frame);
2892         WriteCoord(MSG_ENTITY, self.origin_x);
2893         WriteCoord(MSG_ENTITY, self.origin_y);
2894         WriteCoord(MSG_ENTITY, self.origin_z);
2895         if(f & 1)
2896         {
2897                 WriteCoord(MSG_ENTITY, self.velocity_x);
2898                 WriteCoord(MSG_ENTITY, self.velocity_y);
2899                 WriteCoord(MSG_ENTITY, self.velocity_z);
2900         }
2901         if(f & 2)
2902         {
2903                 WriteCoord(MSG_ENTITY, self.angles_x);
2904                 WriteCoord(MSG_ENTITY, self.angles_y);
2905                 WriteCoord(MSG_ENTITY, self.angles_z);
2906         }
2907         if(f & 4)
2908         {
2909                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2910                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2911                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2912         }
2913         WriteShort(MSG_ENTITY, self.scale * 256.0);
2914         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2915         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2916         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2917         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2918
2919         return TRUE;
2920 }
2921
2922 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2923 {
2924         entity e;
2925         float sz;
2926         e = spawn();
2927         e.classname = "modeleffect";
2928         setmodel(e, m);
2929         e.frame = f;
2930         setorigin(e, o);
2931         e.velocity = v;
2932         e.angles = ang;
2933         e.avelocity = angv;
2934         e.alpha = a;
2935         e.teleport_time = t1;
2936         e.fade_time = t2;
2937         e.skin = s;
2938         if(s0 >= 0)
2939                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2940         else
2941                 e.scale = -s0;
2942         if(s2 >= 0)
2943                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2944         else
2945                 e.scale2 = -s2;
2946         sz = max(e.scale, e.scale2);
2947         setsize(e, e.mins * sz, e.maxs * sz);
2948         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2949 }
2950
2951 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2952 {
2953         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2954 }
2955
2956 float randombit(float bits)
2957 {
2958         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2959                 return bits;
2960
2961         float n, f, b, r;
2962
2963         r = random();
2964         b = 0;
2965         n = 0;
2966
2967         for(f = 1; f <= bits; f *= 2)
2968         {
2969                 if(bits & f)
2970                 {
2971                         ++n;
2972                         r *= n;
2973                         if(r <= 1)
2974                                 b = f;
2975                         else
2976                                 r = (r - 1) / (n - 1);
2977                 }
2978         }
2979
2980         return b;
2981 }
2982
2983 float randombits(float bits, float k, float error_return)
2984 {
2985         float r;
2986         r = 0;
2987         while(k > 0 && bits != r)
2988         {
2989                 r += randombit(bits - r);
2990                 --k;
2991         }
2992         if(error_return)
2993                 if(k > 0)
2994                         return -1; // all
2995         return r;
2996 }
2997
2998 void randombit_test(float bits, float iter)
2999 {
3000         while(iter > 0)
3001         {
3002                 print(ftos(randombit(bits)), "\n");
3003                 --iter;
3004         }
3005 }
3006
3007 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3008 {
3009         if(halflifedist > 0)
3010                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3011         else if(halflifedist < 0)
3012                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3013         else
3014                 return 1;
3015 }
3016
3017
3018
3019
3020 #ifdef RELEASE
3021 #define cvar_string_normal cvar_string_builtin
3022 #define cvar_normal cvar_builtin
3023 #else
3024 string cvar_string_normal(string n)
3025 {
3026         if not(cvar_type(n) & 1)
3027                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3028         return cvar_string_builtin(n);
3029 }
3030
3031 float cvar_normal(string n)
3032 {
3033         return stof(cvar_string_normal(n));
3034 }
3035 #endif
3036 #define cvar_set_normal cvar_set_builtin
3037
3038 void defer_think()
3039 {
3040     entity oself;
3041
3042     oself           = self;
3043     self            = self.owner;
3044     oself.think     = SUB_Remove;
3045     oself.nextthink = time;
3046
3047     oself.use();
3048 }
3049
3050 /*
3051     Execute func() after time + fdelay.
3052     self when func is executed = self when defer is called
3053 */
3054 void defer(float fdelay, void() func)
3055 {
3056     entity e;
3057
3058     e           = spawn();
3059     e.owner     = self;
3060     e.use       = func;
3061     e.think     = defer_think;
3062     e.nextthink = time + fdelay;
3063 }
3064
3065 .string aiment_classname;
3066 .float aiment_deadflag;
3067 void SetMovetypeFollow(entity ent, entity e)
3068 {
3069         // FIXME this may not be warpzone aware
3070         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3071         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3072         ent.aiment = e; // make the hole follow bmodel
3073         ent.punchangle = e.angles; // the original angles of bmodel
3074         ent.view_ofs = ent.origin - e.origin; // relative origin
3075         ent.v_angle = ent.angles - e.angles; // relative angles
3076         ent.aiment_classname = strzone(e.classname);
3077         ent.aiment_deadflag = e.deadflag;
3078 }
3079 void UnsetMovetypeFollow(entity ent)
3080 {
3081         ent.movetype = MOVETYPE_FLY;
3082         PROJECTILE_MAKETRIGGER(ent);
3083         ent.aiment = world;
3084 }
3085 float LostMovetypeFollow(entity ent)
3086 {
3087 /*
3088         if(ent.movetype != MOVETYPE_FOLLOW)
3089                 if(ent.aiment)
3090                         error("???");
3091 */
3092         if(ent.aiment)
3093         {
3094                 if(ent.aiment.classname != ent.aiment_classname)
3095                         return 1;
3096                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3097                         return 1;
3098         }
3099         return 0;
3100 }
3101
3102 float isPushable(entity e)
3103 {
3104         if(e.iscreature)
3105                 return TRUE;
3106         switch(e.classname)
3107         {
3108                 case "body":
3109                 case "droppedweapon":
3110                 case "keepawayball":
3111                 case "nexball_basketball":
3112                 case "nexball_football":
3113                         return TRUE;
3114                 case "bullet": // antilagged bullets can't hit this either
3115                         return FALSE;
3116         }
3117         if (e.projectiledeathtype)
3118                 return TRUE;
3119         return FALSE;
3120 }