qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         local float nPlayerHealth = rint(enPlayer.health);
  85         local float nPlayerArmor = rint(enPlayer.armorvalue);
  86         local float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         local float nPlayerPing = rint(enPlayer.ping);
  88         local string strPlayerPingColor;
  89         local string strMessage;
  90         if(nPlayerPing >= 150)
  91                 strPlayerPingColor = "^1";
  92         else
  93                 strPlayerPingColor = "^2";
  94
  95         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  96                 strMessage = strcat(strMessage, "\n^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  97
  98         if(autocvar_sv_fragmessage_information_ping) {
  99                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 100                         strMessage = strcat(strMessage, " ^7(^2Bot");
 101                 else
 102                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 103                 if(autocvar_sv_fragmessage_information_handicap)
 104                         if(autocvar_sv_fragmessage_information_handicap == 2)
 105                                 if(nPlayerHandicap <= 1)
 106                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 107                                 else
 108                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 109                         else if not(nPlayerHandicap <= 1)
 110                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 111                 else
 112                         strMessage = strcat(strMessage, "^7)");
 113         } else if(autocvar_sv_fragmessage_information_handicap) {
 114                 if(autocvar_sv_fragmessage_information_handicap == 2)
 115                         if(nPlayerHandicap <= 1)
 116                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2Off^7)");
 117                         else
 118                                 strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 119                 else if(nPlayerHandicap > 1)
 120                         strMessage = strcat(strMessage, "\n^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 121         }
 122         return strMessage;
 123 }
 124 void bcenterprint(string s)
 125 {
 126     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 127     entity head;
 128     FOR_EACH_PLAYER(head)
 129     if (clienttype(head) == CLIENTTYPE_REAL)
 130         centerprint(head, s);
 131 }
 132
 133 void GameLogEcho(string s)
 134 {
 135     string fn;
 136     float matches;
 137
 138     if (autocvar_sv_eventlog_files)
 139     {
 140         if (!logfile_open)
 141         {
 142             logfile_open = TRUE;
 143             matches = autocvar_sv_eventlog_files_counter + 1;
 144             cvar_set("sv_eventlog_files_counter", ftos(matches));
 145             fn = ftos(matches);
 146             if (strlen(fn) < 8)
 147                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 148             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 149             logfile = fopen(fn, FILE_APPEND);
 150             fputs(logfile, ":logversion:3\n");
 151         }
 152         if (logfile >= 0)
 153         {
 154             if (autocvar_sv_eventlog_files_timestamps)
 155                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 156             else
 157                 fputs(logfile, strcat(s, "\n"));
 158         }
 159     }
 160     if (autocvar_sv_eventlog_console)
 161     {
 162         print(s, "\n");
 163     }
 164 }
 165
 166 void GameLogInit()
 167 {
 168     logfile_open = 0;
 169     // will be opened later
 170 }
 171
 172 void GameLogClose()
 173 {
 174     if (logfile_open && logfile >= 0)
 175     {
 176         fclose(logfile);
 177         logfile = -1;
 178     }
 179 }
 180
 181 vector PL_VIEW_OFS;
 182 vector PL_MIN;
 183 vector PL_MAX;
 184 vector PL_HEAD;
 185 vector PL_CROUCH_VIEW_OFS;
 186 vector PL_CROUCH_MIN;
 187 vector PL_CROUCH_MAX;
 188
 189 float spawnpoint_nag;
 190 void relocate_spawnpoint()
 191 {
 192     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 193     PL_MIN                                  = stov(autocvar_sv_player_mins);
 194     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 195     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 196     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 197     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 198     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 199
 200     // nudge off the floor
 201     setorigin(self, self.origin + '0 0 1');
 202
 203     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 204     if (trace_startsolid)
 205     {
 206         vector o;
 207         o = self.origin;
 208         self.mins = PL_MIN;
 209         self.maxs = PL_MAX;
 210         if (!move_out_of_solid(self))
 211             objerror("could not get out of solid at all!");
 212         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 213         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 214         print(" ", ftos(self.origin_y - o_y));
 215         print(" ", ftos(self.origin_z - o_z), "'\n");
 216         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 217         {
 218             if (!spawnpoint_nag)
 219                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 220             spawnpoint_nag = 1;
 221         }
 222         else
 223         {
 224             setorigin(self, o);
 225             self.mins = self.maxs = '0 0 0';
 226             objerror("player spawn point in solid, mapper sucks!\n");
 227             return;
 228         }
 229     }
 230
 231     self.use = spawnpoint_use;
 232     self.team_saved = self.team;
 233     if (!self.cnt)
 234         self.cnt = 1;
 235
 236     if (have_team_spawns != 0)
 237         if (self.team)
 238             have_team_spawns = 1;
 239
 240     if (autocvar_r_showbboxes)
 241     {
 242         // show where spawnpoints point at too
 243         makevectors(self.angles);
 244         entity e;
 245         e = spawn();
 246         e.classname = "info_player_foo";
 247         setorigin(e, self.origin + v_forward * 24);
 248         setsize(e, '-8 -8 -8', '8 8 8');
 249         e.solid = SOLID_TRIGGER;
 250     }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281     entity localhead;
 282     float i;
 283     float j;
 284     float len;
 285     vector dist;
 286
 287     float num_nearest;
 288     num_nearest = 0;
 289
 290     localhead = find(world, field, value);
 291     while (localhead)
 292     {
 293         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294             dist = localhead.oldorigin;
 295         else
 296             dist = localhead.origin;
 297         dist = dist - point;
 298         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299         len = vlen(dist);
 300
 301         for (i = 0; i < num_nearest; ++i)
 302         {
 303             if (len < nearest_length[i])
 304                 break;
 305         }
 306
 307         // now i tells us where to insert at
 308         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309         if (i < NUM_NEAREST_ENTITIES)
 310         {
 311             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312             {
 313                 nearest_length[j + 1] = nearest_length[j];
 314                 nearest_entity[j + 1] = nearest_entity[j];
 315             }
 316             nearest_length[i] = len;
 317             nearest_entity[i] = localhead;
 318             if (num_nearest < NUM_NEAREST_ENTITIES)
 319                 num_nearest = num_nearest + 1;
 320         }
 321
 322         localhead = find(localhead, field, value);
 323     }
 324
 325     // now use the first one from our list that we can see
 326     for (i = 0; i < num_nearest; ++i)
 327     {
 328         traceline(point, nearest_entity[i].origin, TRUE, world);
 329         if (trace_fraction == 1)
 330         {
 331             if (i != 0)
 332             {
 333                 dprint("Nearest point (");
 334                 dprint(nearest_entity[0].netname);
 335                 dprint(") is not visible, using a visible one.\n");
 336             }
 337             return nearest_entity[i];
 338         }
 339     }
 340
 341     if (num_nearest == 0)
 342         return world;
 343
 344     dprint("Not seeing any location point, using nearest as fallback.\n");
 345     /* DEBUGGING CODE:
 346     dprint("Candidates were: ");
 347     for(j = 0; j < num_nearest; ++j)
 348     {
 349         if(j != 0)
 350                 dprint(", ");
 351         dprint(nearest_entity[j].netname);
 352     }
 353     dprint("\n");
 354     */
 355
 356     return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361     self.classname = "target_location";
 362     // location name in netname
 363     // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368     self.classname = "target_location";
 369     self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374     entity loc;
 375     string ret;
 376     ret = "somewhere";
 377     loc = findnearest(p, classname, "target_location", '1 1 1');
 378     if (loc)
 379     {
 380         ret = loc.message;
 381     }
 382     else
 383     {
 384         loc = findnearest(p, target, "###item###", '1 1 4');
 385         if (loc)
 386             ret = loc.netname;
 387     }
 388     return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p, p1, p2;
 394         float n;
 395         vector cursor;
 396         entity cursor_ent;
 397         string escape;
 398         string replacement;
 399         p = 0;
 400         n = 7;
 401
 402         WarpZone_crosshair_trace(self);
 403         cursor = trace_endpos;
 404         cursor_ent = trace_ent;
 405
 406         while (1) {
 407                 if (n < 1)
 408                         break; // too many replacements
 409
 410                 n = n - 1;
 411                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 413
 414                 if (p1 < 0)
 415                         p1 = p2;
 416
 417                 if (p2 < 0)
 418                         p2 = p1;
 419
 420                 p = min(p1, p2);
 421
 422                 if (p < 0)
 423                         break;
 424
 425                 replacement = substring(msg, p, 2);
 426                 escape = substring(msg, p + 1, 1);
 427
 428                 if (escape == "%")
 429                         replacement = "%";
 430                 else if (escape == "\\")
 431                         replacement = "\\";
 432                 else if (escape == "n")
 433                         replacement = "\n";
 434                 else if (escape == "a")
 435                         replacement = ftos(floor(self.armorvalue));
 436                 else if (escape == "h")
 437                         replacement = ftos(floor(self.health));
 438                 else if (escape == "l")
 439                         replacement = NearestLocation(self.origin);
 440                 else if (escape == "y")
 441                         replacement = NearestLocation(cursor);
 442                 else if (escape == "d")
 443                         replacement = NearestLocation(self.death_origin);
 444                 else if (escape == "w") {
 445                         float wep;
 446                         wep = self.weapon;
 447                         if (!wep)
 448                                 wep = self.switchweapon;
 449                         if (!wep)
 450                                 wep = self.cnt;
 451                         replacement = W_Name(wep);
 452                 } else if (escape == "W") {
 453                         if (self.items & IT_SHELLS) replacement = "shells";
 454                         else if (self.items & IT_NAILS) replacement = "bullets";
 455                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 456                         else if (self.items & IT_CELLS) replacement = "cells";
 457                         else replacement = "batteries"; // ;)
 458                 } else if (escape == "x") {
 459                         replacement = cursor_ent.netname;
 460                         if (!replacement || !cursor_ent)
 461                                 replacement = "nothing";
 462                 } else if (escape == "p") {
 463                         if (self.last_selected_player)
 464                                 replacement = self.last_selected_player.netname;
 465                         else
 466                                 replacement = "(nobody)";
 467                 } else if (escape == "s")
 468                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 469                 else if (escape == "S")
 470                         replacement = ftos(vlen(self.velocity));
 471
 472                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 473                 p = p + strlen(replacement);
 474         }
 475         return msg;
 476 }
 477
 478 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 479         return (value == 0) ? FALSE : TRUE;
 480 }
 481
 482 /*
 483 =============
 484 GetCvars
 485 =============
 486 Called with:
 487   0:  sends the request
 488   >0: receives a cvar from name=argv(f) value=argv(f+1)
 489 */
 490 void GetCvars_handleString(string thisname, float f, .string field, string name)
 491 {
 492         if (f < 0)
 493         {
 494                 if (self.field)
 495                         strunzone(self.field);
 496                 self.field = string_null;
 497         }
 498         else if (f > 0)
 499         {
 500                 if (thisname == name)
 501                 {
 502                         if (self.field)
 503                                 strunzone(self.field);
 504                         self.field = strzone(argv(f + 1));
 505                 }
 506         }
 507         else
 508                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 509 }
 510 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 511 {
 512         GetCvars_handleString(thisname, f, field, name);
 513         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 514                 if (thisname == name)
 515                 {
 516                         string s;
 517                         s = func(strcat1(self.field));
 518                         if (s != self.field)
 519                         {
 520                                 strunzone(self.field);
 521                                 self.field = strzone(s);
 522                         }
 523                 }
 524 }
 525 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 526 {
 527         if (f < 0)
 528         {
 529         }
 530         else if (f > 0)
 531         {
 532                 if (thisname == name)
 533                         self.field = stof(argv(f + 1));
 534         }
 535         else
 536                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 537 }
 538 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 539 {
 540         if (f < 0)
 541         {
 542         }
 543         else if (f > 0)
 544         {
 545                 if (thisname == name)
 546                 {
 547                         if(!self.field)
 548                         {
 549                                 self.field = stof(argv(f + 1));
 550                                 if(!self.field)
 551                                         self.field = -1;
 552                         }
 553                 }
 554         }
 555         else
 556         {
 557                 if(!self.field)
 558                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 559         }
 560 }
 561 float w_getbestweapon(entity e);
 562 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 563 {
 564         string o;
 565         o = W_FixWeaponOrder_ForceComplete(wo);
 566         if(self.weaponorder_byimpulse)
 567         {
 568                 strunzone(self.weaponorder_byimpulse);
 569                 self.weaponorder_byimpulse = string_null;
 570         }
 571         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 572         return o;
 573 }
 574 void GetCvars(float f)
 575 {
 576         string s;
 577
 578         if (f > 0)
 579                 s = strcat1(argv(f));
 580
 581         get_cvars_f = f;
 582         get_cvars_s = s;
 583         MUTATOR_CALLHOOK(GetCvars);
 584         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 585         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 586         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 587         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 588         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 589         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 608         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 609
 610         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 611         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 612
 613 #ifdef ALLOW_FORCEMODELS
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 615         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 616 #endif
 617         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 619
 620         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 621         if (f > 0)
 622         {
 623                 if (s == "cl_weaponpriority")
 624                         self.switchweapon = w_getbestweapon(self);
 625         }
 626 }
 627
 628 float fexists(string f)
 629 {
 630     float fh;
 631     fh = fopen(f, FILE_READ);
 632     if (fh < 0)
 633         return FALSE;
 634     fclose(fh);
 635     return TRUE;
 636 }
 637
 638 void backtrace(string msg)
 639 {
 640     float dev, war;
 641     dev = autocvar_developer;
 642     war = autocvar_prvm_backtraceforwarnings;
 643     cvar_set("developer", "1");
 644     cvar_set("prvm_backtraceforwarnings", "1");
 645     print("\n");
 646     print("--- CUT HERE ---\nWARNING: ");
 647     print(msg);
 648     print("\n");
 649     remove(world); // isn't there any better way to cause a backtrace?
 650     print("\n--- CUT UNTIL HERE ---\n");
 651     cvar_set("developer", ftos(dev));
 652     cvar_set("prvm_backtraceforwarnings", ftos(war));
 653 }
 654
 655 string Team_ColorCode(float teamid)
 656 {
 657     if (teamid == COLOR_TEAM1)
 658         return "^1";
 659     else if (teamid == COLOR_TEAM2)
 660         return "^4";
 661     else if (teamid == COLOR_TEAM3)
 662         return "^3";
 663     else if (teamid == COLOR_TEAM4)
 664         return "^6";
 665     else
 666         return "^7";
 667 }
 668
 669 string Team_ColorName(float t)
 670 {
 671     // fixme: Search for team entities and get their .netname's!
 672     if (t == COLOR_TEAM1)
 673         return "Red";
 674     if (t == COLOR_TEAM2)
 675         return "Blue";
 676     if (t == COLOR_TEAM3)
 677         return "Yellow";
 678     if (t == COLOR_TEAM4)
 679         return "Pink";
 680     return "Neutral";
 681 }
 682
 683 string Team_ColorNameLowerCase(float t)
 684 {
 685     // fixme: Search for team entities and get their .netname's!
 686     if (t == COLOR_TEAM1)
 687         return "red";
 688     if (t == COLOR_TEAM2)
 689         return "blue";
 690     if (t == COLOR_TEAM3)
 691         return "yellow";
 692     if (t == COLOR_TEAM4)
 693         return "pink";
 694     return "neutral";
 695 }
 696
 697 float ColourToNumber(string team_colour)
 698 {
 699         if (team_colour == "red")
 700                 return COLOR_TEAM1;
 701
 702         if (team_colour == "blue")
 703                 return COLOR_TEAM2;
 704
 705         if (team_colour == "yellow")
 706                 return COLOR_TEAM3;
 707
 708         if (team_colour == "pink")
 709                 return COLOR_TEAM4;
 710
 711         if (team_colour == "auto")
 712                 return 0;
 713
 714         return -1;
 715 }
 716
 717 float NumberToTeamNumber(float number)
 718 {
 719         if (number == 1)
 720                 return COLOR_TEAM1;
 721
 722         if (number == 2)
 723                 return COLOR_TEAM2;
 724
 725         if (number == 3)
 726                 return COLOR_TEAM3;
 727
 728         if (number == 4)
 729                 return COLOR_TEAM4;
 730
 731         return -1;
 732 }
 733
 734 #define CENTERPRIO_POINT 1
 735 #define CENTERPRIO_SPAM 2
 736 #define CENTERPRIO_VOTE 4
 737 #define CENTERPRIO_NORMAL 5
 738 #define CENTERPRIO_SHIELDING 7
 739 #define CENTERPRIO_MAPVOTE 9
 740 #define CENTERPRIO_IDLEKICK 50
 741 #define CENTERPRIO_ADMIN 99
 742 .float centerprint_priority;
 743 .float centerprint_expires;
 744 void centerprint_atprio(entity e, float prio, string s)
 745 {
 746     if (intermission_running)
 747         if (prio < CENTERPRIO_MAPVOTE)
 748             return;
 749     if (time > e.centerprint_expires)
 750         e.centerprint_priority = 0;
 751     if (prio >= e.centerprint_priority)
 752     {
 753         e.centerprint_priority = prio;
 754         if (timeoutStatus == 2)
 755             e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 756         else
 757             e.centerprint_expires = time + e.cvar_scr_centertime;
 758         centerprint_builtin(e, s);
 759     }
 760 }
 761 void centerprint_expire(entity e, float prio)
 762 {
 763     if (prio == e.centerprint_priority)
 764     {
 765         e.centerprint_priority = 0;
 766         centerprint_builtin(e, "");
 767     }
 768 }
 769 void centerprint(entity e, string s)
 770 {
 771     centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 772 }
 773
 774 // decolorizes and team colors the player name when needed
 775 string playername(entity p)
 776 {
 777     string t;
 778     if (teams_matter && !intermission_running && p.classname == "player")
 779     {
 780         t = Team_ColorCode(p.team);
 781         return strcat(t, strdecolorize(p.netname));
 782     }
 783     else
 784         return p.netname;
 785 }
 786
 787 vector randompos(vector m1, vector m2)
 788 {
 789     local vector v;
 790     m2 = m2 - m1;
 791     v_x = m2_x * random() + m1_x;
 792     v_y = m2_y * random() + m1_y;
 793     v_z = m2_z * random() + m1_z;
 794     return  v;
 795 };
 796
 797 //#NO AUTOCVARS START
 798
 799 float g_pickup_shells;
 800 float g_pickup_shells_max;
 801 float g_pickup_nails;
 802 float g_pickup_nails_max;
 803 float g_pickup_rockets;
 804 float g_pickup_rockets_max;
 805 float g_pickup_cells;
 806 float g_pickup_cells_max;
 807 float g_pickup_fuel;
 808 float g_pickup_fuel_jetpack;
 809 float g_pickup_fuel_max;
 810 float g_pickup_armorsmall;
 811 float g_pickup_armorsmall_max;
 812 float g_pickup_armorsmall_anyway;
 813 float g_pickup_armormedium;
 814 float g_pickup_armormedium_max;
 815 float g_pickup_armormedium_anyway;
 816 float g_pickup_armorbig;
 817 float g_pickup_armorbig_max;
 818 float g_pickup_armorbig_anyway;
 819 float g_pickup_armorlarge;
 820 float g_pickup_armorlarge_max;
 821 float g_pickup_armorlarge_anyway;
 822 float g_pickup_healthsmall;
 823 float g_pickup_healthsmall_max;
 824 float g_pickup_healthsmall_anyway;
 825 float g_pickup_healthmedium;
 826 float g_pickup_healthmedium_max;
 827 float g_pickup_healthmedium_anyway;
 828 float g_pickup_healthlarge;
 829 float g_pickup_healthlarge_max;
 830 float g_pickup_healthlarge_anyway;
 831 float g_pickup_healthmega;
 832 float g_pickup_healthmega_max;
 833 float g_pickup_healthmega_anyway;
 834 float g_pickup_ammo_anyway;
 835 float g_pickup_weapons_anyway;
 836 float g_weaponarena;
 837 float g_weaponarena_random;
 838 float g_weaponarena_random_with_laser;
 839 string g_weaponarena_list;
 840 float g_weaponspeedfactor;
 841 float g_weaponratefactor;
 842 float g_weapondamagefactor;
 843 float g_weaponforcefactor;
 844 float g_weaponspreadfactor;
 845
 846 float start_weapons;
 847 float start_items;
 848 float start_ammo_shells;
 849 float start_ammo_nails;
 850 float start_ammo_rockets;
 851 float start_ammo_cells;
 852 float start_ammo_fuel;
 853 float start_health;
 854 float start_armorvalue;
 855 float warmup_start_weapons;
 856 float warmup_start_ammo_shells;
 857 float warmup_start_ammo_nails;
 858 float warmup_start_ammo_rockets;
 859 float warmup_start_ammo_cells;
 860 float warmup_start_ammo_fuel;
 861 float warmup_start_health;
 862 float warmup_start_armorvalue;
 863 float g_weapon_stay;
 864 float g_ghost_items;
 865
 866 entity get_weaponinfo(float w);
 867
 868 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 869 {
 870         var float i = weaponinfo.weapon;
 871
 872         if (!i)
 873                 return 0;
 874
 875         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 876
 877         if (t < 0) // "default" weapon selection
 878         {
 879                 if (g_lms || g_ca || allguns)
 880                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 881                 else if(t < -1)
 882                         t = 0;
 883                 else if (g_race)
 884                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 885                 else if (g_cts)
 886                         t = (i == WEP_SHOTGUN);
 887                 else if (g_nexball)
 888                         t = 0; // weapon is set a few lines later
 889                 else
 890                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 891                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 892                         t |= (i == WEP_HOOK);
 893         }
 894
 895         // we cannot disable porto in Nexball, we must force it
 896         if(g_nexball && i == WEP_PORTO)
 897                 t = 1;
 898
 899         return t;
 900 }
 901
 902 void readplayerstartcvars()
 903 {
 904         entity e;
 905         float i, j, t;
 906         string s;
 907
 908         // initialize starting values for players
 909         start_weapons = 0;
 910         start_items = 0;
 911         start_ammo_shells = 0;
 912         start_ammo_nails = 0;
 913         start_ammo_rockets = 0;
 914         start_ammo_cells = 0;
 915         start_health = cvar("g_balance_health_start");
 916         start_armorvalue = cvar("g_balance_armor_start");
 917
 918         g_weaponarena = 0;
 919         s = cvar_string("g_weaponarena");
 920         if (s == "0")
 921         {
 922         }
 923         else if (s == "all")
 924         {
 925                 g_weaponarena_list = "All Weapons";
 926                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 927                 {
 928                         e = get_weaponinfo(j);
 929                         g_weaponarena |= e.weapons;
 930                         weapon_action(e.weapon, WR_PRECACHE);
 931                 }
 932         }
 933         else if (s == "most")
 934         {
 935                 g_weaponarena_list = "Most Weapons";
 936                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 937                 {
 938                         e = get_weaponinfo(j);
 939                         if (e.spawnflags & WEP_FLAG_NORMAL)
 940                         {
 941                                 g_weaponarena |= e.weapons;
 942                                 weapon_action(e.weapon, WR_PRECACHE);
 943                         }
 944                 }
 945         }
 946         else if (s == "none")
 947         {
 948                 g_weaponarena_list = "No Weapons";
 949                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 950         }
 951         else
 952         {
 953                 t = tokenize_console(s);
 954                 g_weaponarena_list = "";
 955                 for (i = 0; i < t; ++i)
 956                 {
 957                         s = argv(i);
 958                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 959                         {
 960                                 e = get_weaponinfo(j);
 961                                 if (e.netname == s)
 962                                 {
 963                                         g_weaponarena |= e.weapons;
 964                                         weapon_action(e.weapon, WR_PRECACHE);
 965                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 966                                         break;
 967                                 }
 968                         }
 969                         if (j > WEP_LAST)
 970                         {
 971                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 972                         }
 973                 }
 974                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 975         }
 976
 977         if(g_weaponarena)
 978                 g_weaponarena_random = cvar("g_weaponarena_random");
 979         else
 980                 g_weaponarena_random = 0;
 981         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 982
 983         if (g_weaponarena)
 984         {
 985                 start_weapons = g_weaponarena;
 986                 if (g_weaponarena & (WEPBIT_GRENADE_LAUNCHER | WEPBIT_MINE_LAYER | WEPBIT_HAGAR | WEPBIT_ROCKET_LAUNCHER))
 987                         start_ammo_rockets = 999;
 988                 if (g_weaponarena & WEPBIT_SHOTGUN)
 989                         start_ammo_shells = 999;
 990                 if (g_weaponarena & (WEPBIT_ELECTRO | WEPBIT_CRYLINK | WEPBIT_NEX | WEPBIT_MINSTANEX | WEPBIT_HLAC | WEPBIT_HOOK))
 991                         start_ammo_cells = 999;
 992                 if (g_weaponarena & (WEPBIT_UZI | WEPBIT_CAMPINGRIFLE))
 993                         start_ammo_nails = 999;
 994                 if (g_weaponarena & WEPBIT_HOOK)
 995                         start_ammo_fuel = 999;
 996                 start_items |= IT_UNLIMITED_AMMO;
 997         }
 998         else if (g_minstagib)
 999         {
1000                 start_health = 100;
1001                 start_armorvalue = 0;
1002                 start_weapons = WEPBIT_MINSTANEX;
1003                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
1004                 start_ammo_cells = cvar("g_minstagib_ammo_start");
1005                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
1006                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1007
1008                 if (g_minstagib_invis_alpha <= 0)
1009                         g_minstagib_invis_alpha = -1;
1010         }
1011         else
1012         {
1013                 if (g_lms || g_ca)
1014                 {
1015                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
1016                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
1017                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
1018                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
1019                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
1020                         start_health = cvar("g_lms_start_health");
1021                         start_armorvalue = cvar("g_lms_start_armor");
1022                 }
1023                 else
1024                 {
1025                         start_ammo_shells = cvar("g_start_ammo_shells");
1026                         start_ammo_nails = cvar("g_start_ammo_nails");
1027                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1028                         start_ammo_cells = cvar("g_start_ammo_cells");
1029                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1030                 }
1031
1032                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1033                 {
1034                         e = get_weaponinfo(i);
1035                         if(want_weapon("g_start_weapon_", e, FALSE))
1036                                 start_weapons |= e.weapons;
1037                 }
1038         }
1039
1040         if (inWarmupStage)
1041         {
1042                 warmup_start_ammo_shells = start_ammo_shells;
1043                 warmup_start_ammo_nails = start_ammo_nails;
1044                 warmup_start_ammo_rockets = start_ammo_rockets;
1045                 warmup_start_ammo_cells = start_ammo_cells;
1046                 warmup_start_ammo_fuel = start_ammo_fuel;
1047                 warmup_start_health = start_health;
1048                 warmup_start_armorvalue = start_armorvalue;
1049                 warmup_start_weapons = start_weapons;
1050
1051                 if (!g_weaponarena && !g_minstagib && !g_ca)
1052                 {
1053                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1054                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1055                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1056                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1057                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1058                         warmup_start_health = cvar("g_warmup_start_health");
1059                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1060                         warmup_start_weapons = 0;
1061                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1062                         {
1063                                 e = get_weaponinfo(i);
1064                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1065                                         warmup_start_weapons |= e.weapons;
1066                         }
1067                 }
1068         }
1069
1070         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1071         {
1072                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1073                 start_items |= IT_FUEL_REGEN;
1074                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1075                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1076         }
1077
1078         if(!cvar("g_use_ammunition"))
1079         {
1080                 start_ammo_shells = cvar("g_pickup_shells_max");
1081                 start_ammo_nails = cvar("g_pickup_nails_max");
1082                 start_ammo_rockets = cvar("g_pickup_rockets_max");
1083                 start_ammo_cells = cvar("g_pickup_cells_max");
1084                 start_ammo_fuel = cvar("g_pickup_fuel_max");
1085                 start_items |= IT_UNLIMITED_AMMO;
1086                 warmup_start_ammo_shells = cvar("g_pickup_shells_max");
1087                 warmup_start_ammo_nails = cvar("g_pickup_nails_max");
1088                 warmup_start_ammo_rockets = cvar("g_pickup_rockets_max");
1089                 warmup_start_ammo_cells = cvar("g_pickup_cells_max");
1090                 warmup_start_ammo_fuel = cvar("g_pickup_fuel_max");
1091                 //warmup_start_items |= IT_UNLIMITED_AMMO;
1092         }
1093
1094         if (g_jetpack)
1095                 start_items |= IT_JETPACK;
1096
1097         if (g_weapon_stay == 2)
1098         {
1099                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1100                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1101                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1102                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1103                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1104                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1105                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1106                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1107                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1108                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1109         }
1110
1111         MUTATOR_CALLHOOK(SetStartItems);
1112
1113         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1114         {
1115                 e = get_weaponinfo(i);
1116                 if(e.weapons & (start_weapons | warmup_start_weapons))
1117                         weapon_action(e.weapon, WR_PRECACHE);
1118         }
1119
1120         start_ammo_shells = max(0, start_ammo_shells);
1121         start_ammo_nails = max(0, start_ammo_nails);
1122         start_ammo_cells = max(0, start_ammo_cells);
1123         start_ammo_rockets = max(0, start_ammo_rockets);
1124         start_ammo_fuel = max(0, start_ammo_fuel);
1125
1126         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1127         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1128         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1129         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1130         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1131 }
1132
1133 float g_bugrigs;
1134 float g_bugrigs_planar_movement;
1135 float g_bugrigs_planar_movement_car_jumping;
1136 float g_bugrigs_reverse_spinning;
1137 float g_bugrigs_reverse_speeding;
1138 float g_bugrigs_reverse_stopping;
1139 float g_bugrigs_air_steering;
1140 float g_bugrigs_angle_smoothing;
1141 float g_bugrigs_friction_floor;
1142 float g_bugrigs_friction_brake;
1143 float g_bugrigs_friction_air;
1144 float g_bugrigs_accel;
1145 float g_bugrigs_speed_ref;
1146 float g_bugrigs_speed_pow;
1147 float g_bugrigs_steer;
1148
1149 float g_touchexplode;
1150 float g_touchexplode_radius;
1151 float g_touchexplode_damage;
1152 float g_touchexplode_edgedamage;
1153 float g_touchexplode_force;
1154
1155 float sv_autotaunt;
1156 float sv_taunt;
1157
1158 float sv_pitch_min;
1159 float sv_pitch_max;
1160 float sv_pitch_fixyaw;
1161
1162 void readlevelcvars(void)
1163 {
1164         // first load all the mutators
1165         if(cvar("g_nix"))
1166                 MUTATOR_ADD(mutator_nix);
1167         if(cvar("g_dodging"))
1168                 MUTATOR_ADD(mutator_dodging);
1169         if(cvar("g_rocket_flying"))
1170                 MUTATOR_ADD(mutator_rocketflying);
1171         if(cvar("g_vampire"))
1172                 MUTATOR_ADD(mutator_vampire);
1173
1174         if(cvar("sv_allow_fullbright"))
1175                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1176
1177     g_bugrigs = cvar("g_bugrigs");
1178     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1179     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1180     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1181     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1182     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1183     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1184     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1185     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1186     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1187     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1188     g_bugrigs_accel = cvar("g_bugrigs_accel");
1189     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1190     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1191     g_bugrigs_steer = cvar("g_bugrigs_steer");
1192
1193     g_touchexplode = cvar("g_touchexplode");
1194     g_touchexplode_radius = cvar("g_touchexplode_radius");
1195     g_touchexplode_damage = cvar("g_touchexplode_damage");
1196     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1197     g_touchexplode_force = cvar("g_touchexplode_force");
1198
1199 #ifdef ALLOW_FORCEMODELS
1200         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1201 #endif
1202         sv_loddistance1 = cvar("sv_loddistance1");
1203         sv_loddistance2 = cvar("sv_loddistance2");
1204
1205         if(sv_loddistance2 <= sv_loddistance1)
1206                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1207
1208         sv_clones = cvar("sv_clones");
1209         sv_gentle = cvar("sv_gentle");
1210         sv_foginterval = cvar("sv_foginterval");
1211         g_cloaked = cvar("g_cloaked");
1212         g_jump_grunt = cvar("g_jump_grunt");
1213         g_footsteps = cvar("g_footsteps");
1214         g_grappling_hook = cvar("g_grappling_hook");
1215         g_jetpack = cvar("g_jetpack");
1216         g_midair = cvar("g_midair");
1217         g_minstagib = cvar("g_minstagib");
1218         g_norecoil = cvar("g_norecoil");
1219         g_bloodloss = cvar("g_bloodloss");
1220         sv_maxidle = cvar("sv_maxidle");
1221         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1222         sv_pogostick = cvar("sv_pogostick");
1223         g_ctf_reverse = cvar("g_ctf_reverse");
1224         sv_autotaunt = cvar("sv_autotaunt");
1225         sv_taunt = cvar("sv_taunt");
1226
1227         inWarmupStage = cvar("g_warmup");
1228         g_warmup_limit = cvar("g_warmup_limit");
1229         g_warmup_allguns = cvar("g_warmup_allguns");
1230         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1231
1232         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1233                 inWarmupStage = 0; // these modes cannot work together, sorry
1234
1235         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1236         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1237         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1238         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1239         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1240         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1241         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1242         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1243         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1244         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1245         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1246         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1247
1248         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1249         g_weaponratefactor = cvar("g_weaponratefactor");
1250         g_weapondamagefactor = cvar("g_weapondamagefactor");
1251         g_weaponforcefactor = cvar("g_weaponforcefactor");
1252         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1253
1254         g_pickup_shells = cvar("g_pickup_shells");
1255         g_pickup_shells_max = cvar("g_pickup_shells_max");
1256         g_pickup_nails = cvar("g_pickup_nails");
1257         g_pickup_nails_max = cvar("g_pickup_nails_max");
1258         g_pickup_rockets = cvar("g_pickup_rockets");
1259         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1260         g_pickup_cells = cvar("g_pickup_cells");
1261         g_pickup_cells_max = cvar("g_pickup_cells_max");
1262         g_pickup_fuel = cvar("g_pickup_fuel");
1263         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1264         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1265         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1266         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1267         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1268         g_pickup_armormedium = cvar("g_pickup_armormedium");
1269         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1270         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1271         g_pickup_armorbig = cvar("g_pickup_armorbig");
1272         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1273         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1274         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1275         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1276         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1277         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1278         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1279         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1280         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1281         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1282         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1283         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1284         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1285         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1286         g_pickup_healthmega = cvar("g_pickup_healthmega");
1287         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1288         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1289
1290         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1291         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1292
1293         g_pinata = cvar("g_pinata");
1294
1295         g_weapon_stay = cvar("g_weapon_stay");
1296
1297         if (!g_weapon_stay && (cvar("deathmatch") == 2))
1298                 g_weapon_stay = 1;
1299
1300         g_ghost_items = cvar("g_ghost_items");
1301
1302         if(g_ghost_items >= 1)
1303                 g_ghost_items = 0.25; // default alpha value
1304
1305         if not(inWarmupStage && !g_ca)
1306                 game_starttime = cvar("g_start_delay");
1307
1308         sv_pitch_min = cvar("sv_pitch_min");
1309         sv_pitch_max = cvar("sv_pitch_max");
1310         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1311
1312         readplayerstartcvars();
1313 }
1314
1315 //#NO AUTOCVARS END
1316
1317 // Sound functions
1318 string precache_sound (string s) = #19;
1319 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1320 float precache_sound_index (string s) = #19;
1321
1322 #define SND_VOLUME      1
1323 #define SND_ATTENUATION 2
1324 #define SND_LARGEENTITY 8
1325 #define SND_LARGESOUND  16
1326
1327 float sound_allowed(float dest, entity e)
1328 {
1329     // sounds from world may always pass
1330     for (;;)
1331     {
1332         if (e.classname == "body")
1333             e = e.enemy;
1334         if (e.owner && e.owner != e)
1335             e = e.owner;
1336         else
1337             break;
1338     }
1339     // sounds to self may always pass
1340     if (dest == MSG_ONE)
1341         if (e == msg_entity)
1342             return TRUE;
1343     // sounds by players can be removed
1344     if (autocvar_bot_sound_monopoly)
1345         if (clienttype(e) == CLIENTTYPE_REAL)
1346             return FALSE;
1347     // anything else may pass
1348     return TRUE;
1349 }
1350
1351 void sound(entity e, float chan, string samp, float vol, float atten)
1352 {
1353     if (!sound_allowed(MSG_BROADCAST, e))
1354         return;
1355     sound_builtin(e, chan, samp, vol, atten);
1356 }
1357 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1358 {
1359     float entno, idx;
1360
1361     if (!sound_allowed(dest, e))
1362         return;
1363
1364     entno = num_for_edict(e);
1365     idx = precache_sound_index(samp);
1366
1367     float sflags;
1368     sflags = 0;
1369
1370     atten = floor(atten * 64);
1371     vol = floor(vol * 255);
1372
1373     if (vol != 255)
1374         sflags |= SND_VOLUME;
1375     if (atten != 64)
1376         sflags |= SND_ATTENUATION;
1377     if (entno >= 8192)
1378         sflags |= SND_LARGEENTITY;
1379     if (idx >= 256)
1380         sflags |= SND_LARGESOUND;
1381
1382     WriteByte(dest, SVC_SOUND);
1383     WriteByte(dest, sflags);
1384     if (sflags & SND_VOLUME)
1385         WriteByte(dest, vol);
1386     if (sflags & SND_ATTENUATION)
1387         WriteByte(dest, atten);
1388     if (sflags & SND_LARGEENTITY)
1389     {
1390         WriteShort(dest, entno);
1391         WriteByte(dest, chan);
1392     }
1393     else
1394     {
1395         WriteShort(dest, entno * 8 + chan);
1396     }
1397     if (sflags & SND_LARGESOUND)
1398         WriteShort(dest, idx);
1399     else
1400         WriteByte(dest, idx);
1401
1402     WriteCoord(dest, o_x);
1403     WriteCoord(dest, o_y);
1404     WriteCoord(dest, o_z);
1405 }
1406 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1407 {
1408     vector o;
1409
1410     if (!sound_allowed(dest, e))
1411         return;
1412
1413     o = e.origin + 0.5 * (e.mins + e.maxs);
1414     soundtoat(dest, e, o, chan, samp, vol, atten);
1415 }
1416 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1417 {
1418     soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1419 }
1420 void stopsoundto(float dest, entity e, float chan)
1421 {
1422     float entno;
1423
1424     if (!sound_allowed(dest, e))
1425         return;
1426
1427     entno = num_for_edict(e);
1428
1429     if (entno >= 8192)
1430     {
1431         float idx, sflags;
1432         idx = precache_sound_index("misc/null.wav");
1433         sflags = SND_LARGEENTITY;
1434         if (idx >= 256)
1435             sflags |= SND_LARGESOUND;
1436         WriteByte(dest, SVC_SOUND);
1437         WriteByte(dest, sflags);
1438         WriteShort(dest, entno);
1439         WriteByte(dest, chan);
1440         if (sflags & SND_LARGESOUND)
1441             WriteShort(dest, idx);
1442         else
1443             WriteByte(dest, idx);
1444         WriteCoord(dest, e.origin_x);
1445         WriteCoord(dest, e.origin_y);
1446         WriteCoord(dest, e.origin_z);
1447     }
1448     else
1449     {
1450         WriteByte(dest, SVC_STOPSOUND);
1451         WriteShort(dest, entno * 8 + chan);
1452     }
1453 }
1454 void stopsound(entity e, float chan)
1455 {
1456     if (!sound_allowed(MSG_BROADCAST, e))
1457         return;
1458
1459     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1460     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1461 }
1462
1463 void play2(entity e, string filename)
1464 {
1465     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1466     msg_entity = e;
1467     soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1468 }
1469
1470 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1471 .float spamtime;
1472 float spamsound(entity e, float chan, string samp, float vol, float atten)
1473 {
1474     if (!sound_allowed(MSG_BROADCAST, e))
1475         return FALSE;
1476
1477     if (time > e.spamtime)
1478     {
1479         e.spamtime = time;
1480         sound(e, chan, samp, vol, atten);
1481         return TRUE;
1482     }
1483     return FALSE;
1484 }
1485
1486 void play2team(float t, string filename)
1487 {
1488     local entity head;
1489
1490     if (autocvar_bot_sound_monopoly)
1491         return;
1492
1493     FOR_EACH_REALPLAYER(head)
1494     {
1495         if (head.team == t)
1496             play2(head, filename);
1497     }
1498 }
1499
1500 void play2all(string samp)
1501 {
1502     if (autocvar_bot_sound_monopoly)
1503         return;
1504
1505     sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1506 }
1507
1508 void PrecachePlayerSounds(string f);
1509 void precache_playermodel(string m)
1510 {
1511         float globhandle, i, n;
1512         string f;
1513
1514         if(substring(m, -9,5) == "_lod1")
1515                 return;
1516         if(substring(m, -9,5) == "_lod2")
1517                 return;
1518         precache_model(m);
1519         if(sv_loddistance1)
1520         {
1521                 precache_model(strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1)));
1522                 precache_model(strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1)));
1523         }
1524
1525         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1526         if (globhandle < 0)
1527                 return;
1528         n = search_getsize(globhandle);
1529         for (i = 0; i < n; ++i)
1530         {
1531                 //print(search_getfilename(globhandle, i), "\n");
1532                 f = search_getfilename(globhandle, i);
1533                 PrecachePlayerSounds(f);
1534         }
1535         search_end(globhandle);
1536 }
1537 void precache_all_playermodels(string pattern)
1538 {
1539         float globhandle, i, n;
1540         string f;
1541
1542         globhandle = search_begin(pattern, TRUE, FALSE);
1543         if (globhandle < 0)
1544                 return;
1545         n = search_getsize(globhandle);
1546         for (i = 0; i < n; ++i)
1547         {
1548                 //print(search_getfilename(globhandle, i), "\n");
1549                 f = search_getfilename(globhandle, i);
1550                 precache_playermodel(f);
1551         }
1552         search_end(globhandle);
1553 }
1554
1555 void precache()
1556 {
1557     // gamemode related things
1558     precache_model ("models/misc/chatbubble.spr");
1559     precache_model ("models/misc/teambubble.spr");
1560     if (g_runematch)
1561     {
1562         precache_model ("models/runematch/curse.mdl");
1563         precache_model ("models/runematch/rune.mdl");
1564     }
1565
1566 #ifdef TTURRETS_ENABLED
1567     if (autocvar_g_turrets)
1568         turrets_precash();
1569 #endif
1570
1571     // Precache all player models if desired
1572     if (autocvar_sv_precacheplayermodels)
1573     {
1574         PrecachePlayerSounds("sound/player/default.sounds");
1575         precache_all_playermodels("models/player/*.zym");
1576         precache_all_playermodels("models/player/*.dpm");
1577         precache_all_playermodels("models/player/*.md3");
1578         precache_all_playermodels("models/player/*.psk");
1579         precache_all_playermodels("models/player/*.iqm");
1580     }
1581
1582     if (autocvar_sv_defaultcharacter)
1583     {
1584         string s;
1585         s = autocvar_sv_defaultplayermodel_red;
1586         if (s != "")
1587             precache_playermodel(s);
1588         s = autocvar_sv_defaultplayermodel_blue;
1589         if (s != "")
1590             precache_playermodel(s);
1591         s = autocvar_sv_defaultplayermodel_yellow;
1592         if (s != "")
1593             precache_playermodel(s);
1594         s = autocvar_sv_defaultplayermodel_pink;
1595         if (s != "")
1596             precache_playermodel(s);
1597         s = autocvar_sv_defaultplayermodel;
1598         if (s != "")
1599             precache_playermodel(s);
1600     }
1601
1602     if (g_footsteps)
1603     {
1604         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1605         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1606     }
1607
1608     // gore and miscellaneous sounds
1609     //precache_sound ("misc/h2ohit.wav");
1610     precache_model ("models/hook.md3");
1611     precache_sound ("misc/armorimpact.wav");
1612     precache_sound ("misc/bodyimpact1.wav");
1613     precache_sound ("misc/bodyimpact2.wav");
1614     precache_sound ("misc/gib.wav");
1615     precache_sound ("misc/gib_splat01.wav");
1616     precache_sound ("misc/gib_splat02.wav");
1617     precache_sound ("misc/gib_splat03.wav");
1618     precache_sound ("misc/gib_splat04.wav");
1619     precache_sound ("misc/hit.wav");
1620         precache_sound ("misc/typehit.wav");
1621     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1622     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1623     precache_sound ("misc/null.wav");
1624     precache_sound ("misc/spawn.wav");
1625     precache_sound ("misc/talk.wav");
1626     precache_sound ("misc/teleport.wav");
1627     precache_sound ("misc/poweroff.wav");
1628     precache_sound ("player/lava.wav");
1629     precache_sound ("player/slime.wav");
1630
1631     if (g_jetpack)
1632         precache_sound ("misc/jetpack_fly.wav");
1633
1634     precache_model ("models/sprites/0.spr32");
1635     precache_model ("models/sprites/1.spr32");
1636     precache_model ("models/sprites/2.spr32");
1637     precache_model ("models/sprites/3.spr32");
1638     precache_model ("models/sprites/4.spr32");
1639     precache_model ("models/sprites/5.spr32");
1640     precache_model ("models/sprites/6.spr32");
1641     precache_model ("models/sprites/7.spr32");
1642     precache_model ("models/sprites/8.spr32");
1643     precache_model ("models/sprites/9.spr32");
1644     precache_model ("models/sprites/10.spr32");
1645
1646     // common weapon precaches
1647     precache_sound ("weapons/weapon_switch.wav");
1648     precache_sound ("weapons/weaponpickup.wav");
1649     precache_sound ("weapons/unavailable.wav");
1650     precache_sound ("weapons/dryfire.wav");
1651     if (g_grappling_hook)
1652     {
1653         precache_sound ("weapons/hook_fire.wav"); // hook
1654         precache_sound ("weapons/hook_impact.wav"); // hook
1655     }
1656
1657     if(autocvar_sv_precacheweapons)
1658     {
1659         //precache weapon models/sounds
1660         local float wep;
1661         wep = WEP_FIRST;
1662         while (wep <= WEP_LAST)
1663         {
1664             weapon_action(wep, WR_PRECACHE);
1665             wep = wep + 1;
1666         }
1667     }
1668
1669     precache_model("models/elaser.mdl");
1670     precache_model("models/laser.mdl");
1671     precache_model("models/ebomb.mdl");
1672
1673 #if 0
1674     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1675
1676     if (!self.noise && self.music) // quake 3 uses the music field
1677         self.noise = self.music;
1678
1679     // plays music for the level if there is any
1680     if (self.noise)
1681     {
1682         precache_sound (self.noise);
1683         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1684     }
1685 #endif
1686 }
1687
1688 // sorry, but using \ in macros breaks line numbers
1689 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1690 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1691 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1692
1693 // WARNING: this kills the trace globals
1694 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1695 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1696
1697 #define INITPRIO_FIRST              0
1698 #define INITPRIO_GAMETYPE           0
1699 #define INITPRIO_GAMETYPE_FALLBACK  1
1700 #define INITPRIO_FINDTARGET        10
1701 #define INITPRIO_DROPTOFLOOR       20
1702 #define INITPRIO_SETLOCATION       90
1703 #define INITPRIO_LINKDOORS         91
1704 #define INITPRIO_LAST              99
1705
1706 .void(void) initialize_entity;
1707 .float initialize_entity_order;
1708 .entity initialize_entity_next;
1709 entity initialize_entity_first;
1710
1711 void make_safe_for_remove(entity e)
1712 {
1713     if (e.initialize_entity)
1714     {
1715         entity ent, prev;
1716         for (ent = initialize_entity_first; ent; )
1717         {
1718             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1719             {
1720                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1721                 // skip it in linked list
1722                 if (prev)
1723                 {
1724                     prev.initialize_entity_next = ent.initialize_entity_next;
1725                     ent = prev.initialize_entity_next;
1726                 }
1727                 else
1728                 {
1729                     initialize_entity_first = ent.initialize_entity_next;
1730                     ent = initialize_entity_first;
1731                 }
1732             }
1733             else
1734             {
1735                 prev = ent;
1736                 ent = ent.initialize_entity_next;
1737             }
1738         }
1739     }
1740 }
1741
1742 void objerror(string s)
1743 {
1744     make_safe_for_remove(self);
1745     objerror_builtin(s);
1746 }
1747
1748 void remove_unsafely(entity e)
1749 {
1750     remove_builtin(e);
1751 }
1752
1753 void remove_safely(entity e)
1754 {
1755     make_safe_for_remove(e);
1756     remove_builtin(e);
1757 }
1758
1759 void InitializeEntity(entity e, void(void) func, float order)
1760 {
1761     entity prev, cur;
1762
1763     if (!e || e.initialize_entity)
1764     {
1765         // make a proxy initializer entity
1766         entity e_old;
1767         e_old = e;
1768         e = spawn();
1769         e.classname = "initialize_entity";
1770         e.enemy = e_old;
1771     }
1772
1773     e.initialize_entity = func;
1774     e.initialize_entity_order = order;
1775
1776     cur = initialize_entity_first;
1777     for (;;)
1778     {
1779         if (!cur || cur.initialize_entity_order > order)
1780         {
1781             // insert between prev and cur
1782             if (prev)
1783                 prev.initialize_entity_next = e;
1784             else
1785                 initialize_entity_first = e;
1786             e.initialize_entity_next = cur;
1787             return;
1788         }
1789         prev = cur;
1790         cur = cur.initialize_entity_next;
1791     }
1792 }
1793 void InitializeEntitiesRun()
1794 {
1795     entity startoflist;
1796     startoflist = initialize_entity_first;
1797     initialize_entity_first = world;
1798     for (self = startoflist; self; )
1799     {
1800         entity e;
1801         var void(void) func;
1802         e = self.initialize_entity_next;
1803         func = self.initialize_entity;
1804         self.initialize_entity_order = 0;
1805         self.initialize_entity = func_null;
1806         self.initialize_entity_next = world;
1807         if (self.classname == "initialize_entity")
1808         {
1809             entity e_old;
1810             e_old = self.enemy;
1811             remove_builtin(self);
1812             self = e_old;
1813         }
1814         //dprint("Delayed initialization: ", self.classname, "\n");
1815         if(func != func_null)
1816             func();
1817         else
1818         {
1819             eprint(self);
1820             backtrace(strcat("Null function in: ", self.classname, "\n"));
1821         }
1822         self = e;
1823     }
1824 }
1825
1826 .float uncustomizeentityforclient_set;
1827 .void(void) uncustomizeentityforclient;
1828 void(void) SUB_Nullpointer = #0;
1829 void UncustomizeEntitiesRun()
1830 {
1831     entity oldself;
1832     oldself = self;
1833     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1834         self.uncustomizeentityforclient();
1835     self = oldself;
1836 }
1837 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1838 {
1839     e.customizeentityforclient = customizer;
1840     e.uncustomizeentityforclient = uncustomizer;
1841     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1842 }
1843
1844 .float nottargeted;
1845 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1846
1847 void() SUB_Remove;
1848 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1849 {
1850     vector mi, ma;
1851
1852     if (e.classname == "")
1853         e.classname = "net_linked";
1854
1855     if (e.model == "" || self.modelindex == 0)
1856     {
1857         mi = e.mins;
1858         ma = e.maxs;
1859         setmodel(e, "null");
1860         setsize(e, mi, ma);
1861     }
1862
1863     e.SendEntity = sendfunc;
1864     e.SendFlags = 0xFFFFFF;
1865
1866     if (!docull)
1867         e.effects |= EF_NODEPTHTEST;
1868
1869     if (dt)
1870     {
1871         e.nextthink = time + dt;
1872         e.think = SUB_Remove;
1873     }
1874 }
1875
1876 void adaptor_think2touch()
1877 {
1878     entity o;
1879     o = other;
1880     other = world;
1881     self.touch();
1882     other = o;
1883 }
1884
1885 void adaptor_think2use()
1886 {
1887     entity o, a;
1888     o = other;
1889     a = activator;
1890     activator = world;
1891     other = world;
1892     self.use();
1893     other = o;
1894     activator = a;
1895 }
1896
1897 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1898 {
1899         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1900                 self.projectiledeathtype |= HITTYPE_SPLASH;
1901         adaptor_think2use();
1902 }
1903
1904 // deferred dropping
1905 void DropToFloor_Handler()
1906 {
1907     droptofloor_builtin();
1908     self.dropped_origin = self.origin;
1909 }
1910
1911 void droptofloor()
1912 {
1913     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1914 }
1915
1916
1917
1918 float trace_hits_box_a0, trace_hits_box_a1;
1919
1920 float trace_hits_box_1d(float end, float thmi, float thma)
1921 {
1922     if (end == 0)
1923     {
1924         // just check if x is in range
1925         if (0 < thmi)
1926             return FALSE;
1927         if (0 > thma)
1928             return FALSE;
1929     }
1930     else
1931     {
1932         // do the trace with respect to x
1933         // 0 -> end has to stay in thmi -> thma
1934         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1935         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1936         if (trace_hits_box_a0 > trace_hits_box_a1)
1937             return FALSE;
1938     }
1939     return TRUE;
1940 }
1941
1942 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1943 {
1944     end -= start;
1945     thmi -= start;
1946     thma -= start;
1947     // now it is a trace from 0 to end
1948
1949     trace_hits_box_a0 = 0;
1950     trace_hits_box_a1 = 1;
1951
1952     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1953         return FALSE;
1954     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1955         return FALSE;
1956     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1957         return FALSE;
1958
1959     return TRUE;
1960 }
1961
1962 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1963 {
1964     return trace_hits_box(start, end, thmi - ma, thma - mi);
1965 }
1966
1967 float SUB_NoImpactCheck()
1968 {
1969         // zero hitcontents = this is not the real impact, but either the
1970         // mirror-impact of something hitting the projectile instead of the
1971         // projectile hitting the something, or a touchareagrid one. Neither of
1972         // these stop the projectile from moving, so...
1973         if(trace_dphitcontents == 0)
1974         {
1975                 dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1976                 checkclient();
1977         }
1978     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1979         return 1;
1980     if (other == world && self.size != '0 0 0')
1981     {
1982         vector tic;
1983         tic = self.velocity * sys_frametime;
1984         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1985         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1986         if (trace_fraction >= 1)
1987         {
1988             dprint("Odd... did not hit...?\n");
1989         }
1990         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1991         {
1992             dprint("Detected and prevented the sky-grapple bug.\n");
1993             return 1;
1994         }
1995     }
1996
1997     return 0;
1998 }
1999
2000 #define SUB_OwnerCheck() (other && (other == self.owner))
2001
2002 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2003 {
2004         if(SUB_OwnerCheck())
2005                 return TRUE;
2006         if(SUB_NoImpactCheck())
2007         {
2008                 remove(self);
2009                 return TRUE;
2010         }
2011         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2012                 UpdateCSQCProjectileNextFrame(self);
2013         return FALSE;
2014 }
2015 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2016
2017 float MAX_IPBAN_URIS           = 16;
2018
2019 float URI_GET_DISCARD          = 0;
2020 float URI_GET_IPBAN            = 1;
2021 float URI_GET_IPBAN_END        = 16;
2022 float URI_GET_PLAYERSTATS_SENT = 17;
2023
2024 void URI_Get_Callback(float id, float status, string data)
2025 {
2026     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2027     dprint(data);
2028     dprint("\nEnd of data.\n");
2029
2030     if (id == URI_GET_DISCARD)
2031     {
2032         // discard
2033     }
2034     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2035     {
2036         // online ban list
2037         OnlineBanList_URI_Get_Callback(id, status, data);
2038     }
2039     else if (id == URI_GET_PLAYERSTATS_SENT)
2040     {
2041         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2042     }
2043     else
2044     {
2045         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2046     }
2047 }
2048
2049 void print_to(entity e, string s)
2050 {
2051     if (e)
2052         sprint(e, strcat(s, "\n"));
2053     else
2054         print(s, "\n");
2055 }
2056
2057 string uid2name(string myuid) {
2058         string s;
2059         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2060
2061         if(s == "")
2062                 s = "^1Unregistered Player";
2063         return s;
2064 }
2065
2066 float race_readTime(string map, float pos)
2067 {
2068         string rr;
2069         if(g_cts)
2070                 rr = CTS_RECORD;
2071         else
2072                 rr = RACE_RECORD;
2073
2074         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2075 }
2076
2077 string race_readUID(string map, float pos)
2078 {
2079         string rr;
2080         if(g_cts)
2081                 rr = CTS_RECORD;
2082         else
2083                 rr = RACE_RECORD;
2084
2085         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2086 }
2087
2088 float race_readPos(string map, float t) {
2089         float i;
2090         for (i = 1; i <= RANKINGS_CNT; ++i)
2091                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2092                         return i;
2093
2094         return 0; // pos is zero if unranked
2095 }
2096
2097 void race_writeTime(string map, float t, string myuid)
2098 {
2099         string rr;
2100         if(g_cts)
2101                 rr = CTS_RECORD;
2102         else
2103                 rr = RACE_RECORD;
2104
2105         float newpos;
2106         newpos = race_readPos(map, t);
2107
2108         float i, prevpos;
2109         for(i = 1; i <= RANKINGS_CNT; ++i)
2110         {
2111                 if(race_readUID(map, i) == myuid)
2112                         prevpos = i;
2113         }
2114         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2115                 for (i = prevpos; i > newpos; --i) {
2116                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2117                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2118                 }
2119         } else { // player has no ranked record yet
2120                 for (i = RANKINGS_CNT; i > newpos; --i) {
2121                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2122                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2123                 }
2124         }
2125
2126         // store new time itself
2127         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2128         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2129 }
2130
2131 string race_readName(string map, float pos)
2132 {
2133         string rr;
2134         if(g_cts)
2135                 rr = CTS_RECORD;
2136         else
2137                 rr = RACE_RECORD;
2138
2139         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2140 }
2141
2142 string race_placeName(float pos) {
2143         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2144         {
2145                 if(mod(pos, 10) == 1)
2146                         return strcat(ftos(pos), "st");
2147                 else if(mod(pos, 10) == 2)
2148                         return strcat(ftos(pos), "nd");
2149                 else if(mod(pos, 10) == 3)
2150                         return strcat(ftos(pos), "rd");
2151                 else
2152                         return strcat(ftos(pos), "th");
2153         }
2154         else
2155                 return strcat(ftos(pos), "th");
2156 }
2157 string getrecords(float page) // 50 records per page
2158 {
2159     float rec;
2160     string h;
2161     float r;
2162     float i;
2163     string s;
2164
2165     rec = 0;
2166
2167     s = "";
2168
2169     if (g_ctf)
2170     {
2171         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2172         {
2173             if (MapInfo_Get_ByID(i))
2174             {
2175                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2176                 if (r == 0)
2177                     continue;
2178                 // TODO: uid2name
2179                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2180                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2181                 ++rec;
2182             }
2183         }
2184     }
2185
2186     if (g_race)
2187     {
2188         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2189         {
2190             if (MapInfo_Get_ByID(i))
2191             {
2192                 r = race_readTime(MapInfo_Map_bspname, 1);
2193                 if (r == 0)
2194                     continue;
2195                 h = race_readName(MapInfo_Map_bspname, 1);
2196                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2197                 ++rec;
2198             }
2199         }
2200     }
2201
2202     if (g_cts)
2203     {
2204         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2205         {
2206             if (MapInfo_Get_ByID(i))
2207             {
2208                 r = race_readTime(MapInfo_Map_bspname, 1);
2209                 if (r == 0)
2210                     continue;
2211                 h = race_readName(MapInfo_Map_bspname, 1);
2212                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2213                 ++rec;
2214             }
2215         }
2216     }
2217
2218     MapInfo_ClearTemps();
2219
2220     if (s == "" && page == 0)
2221         return "No records are available on this server.\n";
2222     else
2223         return s;
2224 }
2225
2226 string getrankings()
2227 {
2228     string n;
2229     float t;
2230     float i;
2231     string s;
2232     string p;
2233     string map;
2234
2235     s = "";
2236
2237     map = GetMapname();
2238
2239     for (i = 1; i <= RANKINGS_CNT; ++i)
2240     {
2241         t = race_readTime(map, i);
2242         if (t == 0)
2243             continue;
2244         n = race_readName(map, i);
2245         p = race_placeName(i);
2246         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2247     }
2248
2249     MapInfo_ClearTemps();
2250
2251     if (s == "")
2252         return strcat("No records are available for the map: ", map, "\n");
2253     else
2254         return strcat("Records for ", map, ":\n", s);
2255 }
2256
2257 #define LADDER_FIRSTPOINT 100
2258 #define LADDER_CNT 10
2259         // position X still gives LADDER_FIRSTPOINT/X points
2260 #define LADDER_SIZE 30
2261         // ladder shows the top X players
2262 string top_uids[LADDER_SIZE];
2263 float top_scores[LADDER_SIZE];
2264 string getladder()
2265 {
2266     float i, j, k, uidcnt;
2267     string s, temp_s;
2268
2269     s = "";
2270     temp_s = "";
2271
2272     string rr;
2273     if(g_cts)
2274         rr = CTS_RECORD;
2275     else
2276         rr = RACE_RECORD;
2277
2278     string myuid;
2279
2280     for (k = 0; k < MapInfo_count; ++k)
2281     {
2282         if (MapInfo_Get_ByID(k))
2283         {
2284                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2285                         if(i == 0) // speed award
2286                         {
2287                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2288                                         continue;
2289
2290                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2291                         }
2292                         else // normal record, if it exists (else break)
2293                         {
2294                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2295                                         continue;
2296
2297                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2298                         }
2299
2300                         // string s contains:
2301                         // arg 0 = # of speed recs
2302                         // arg 1 = # of 1st place recs
2303                         // arg 2 = # of 2nd place recs
2304                         // ... etc
2305                         // LADDER_CNT+1 = total points
2306
2307                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2308                         if (temp_s == "")
2309                         {
2310                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2311                             ++uidcnt;
2312                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2313                             {
2314                                 if(j != LADDER_CNT + 1)
2315                                     temp_s = strcat(temp_s, "0 ");
2316                                 else
2317                                     temp_s = strcat(temp_s, "0");
2318                             }
2319                         }
2320
2321                         tokenize_console(temp_s);
2322                         s = "";
2323
2324                         if(i == 0) // speed award
2325                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2326                             {
2327                                 if(j == 0) // speed award
2328                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2329                                 else
2330                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2331                             }
2332                         else // record
2333                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2334                             {
2335                                 if(j == 0)
2336                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2337                                 else if(j == i) // wanted rec!
2338                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2339                                 else
2340                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2341                             }
2342
2343                         // total points are (by default) calculated like this:
2344                         // speedrec = floor(100 / 10) = 10 points
2345                         // 1st place = floor(100 / 1) = 100 points
2346                         // 2nd place = floor(100 / 2) = 50 points
2347                         // 3rd place = floor(100 / 3) = 33 points
2348                         // 4th place = floor(100 / 4) = 25 points
2349                         // 5th place = floor(100 / 5) = 20 points
2350                         // ... etc
2351
2352                         if(i == 0)
2353                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2354                         else
2355                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2356
2357                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2358                 }
2359         }
2360     }
2361
2362     float thiscnt;
2363     string thisuid;
2364     for (i = 0; i <= uidcnt; ++i) // for each known uid
2365     {
2366         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2367         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2368         tokenize_console(temp_s);
2369         thiscnt = stof(argv(LADDER_CNT+1));
2370
2371         if(thiscnt > top_scores[LADDER_SIZE-1])
2372         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2373         {
2374             if(thiscnt > top_scores[j])
2375             {
2376                 for (k = LADDER_SIZE-1; k >= j; --k)
2377                 {
2378                     top_uids[k] = top_uids[k-1];
2379                     top_scores[k] = top_scores[k-1];
2380                 }
2381                 top_uids[j] = thisuid;
2382                 top_scores[j] = thiscnt;
2383                 break;
2384             }
2385         }
2386     }
2387
2388     s = "^3-----------------------\n\n";
2389
2390     s = strcat(s, "Pos ^3|");
2391     s = strcat(s, " ^7Total  ^3|");
2392     for (i = 1; i <= LADDER_CNT; ++i)
2393     {
2394         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2395     }
2396     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2397
2398     s = strcat(s, "\n^3----+--------");
2399     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2400     {
2401         s = strcat(s, "+-----");
2402     }
2403 #if LADDER_CNT > 9
2404     for (i = 1; i <= LADDER_CNT - 9; ++i)
2405     {
2406         s = strcat(s, "+------");
2407     }
2408 #endif
2409
2410     s = strcat(s, "+--------------+--------------------\n");
2411
2412     for (i = 0; i < LADDER_SIZE; ++i)
2413     {
2414         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2415         tokenize_console(temp_s);
2416         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2417             continue;
2418         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2419         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2420         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2421         {
2422             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2423         }
2424 #if LADDER_CNT > 9
2425         for (j = 10; j <= LADDER_CNT; ++j)
2426         {
2427             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2428         }
2429 #endif
2430
2431         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2432         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2433     }
2434
2435     MapInfo_ClearTemps();
2436
2437     if (s == "")
2438         return "No ladder on this server!\n";
2439     else
2440         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2441 }
2442
2443
2444 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2445 {
2446     float m, i;
2447     vector start, org, delta, end, enddown, mstart;
2448
2449     m = e.dphitcontentsmask;
2450     e.dphitcontentsmask = goodcontents | badcontents;
2451
2452     org = world.mins;
2453     delta = world.maxs - world.mins;
2454
2455     for (i = 0; i < attempts; ++i)
2456     {
2457         start_x = org_x + random() * delta_x;
2458         start_y = org_y + random() * delta_y;
2459         start_z = org_z + random() * delta_z;
2460
2461         // rule 1: start inside world bounds, and outside
2462         // solid, and don't start from somewhere where you can
2463         // fall down to evil
2464         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2465         if (trace_fraction >= 1)
2466             continue;
2467         if (trace_startsolid)
2468             continue;
2469         if (trace_dphitcontents & badcontents)
2470             continue;
2471         if (trace_dphitq3surfaceflags & badsurfaceflags)
2472             continue;
2473
2474         // rule 2: if we are too high, lower the point
2475         if (trace_fraction * delta_z > maxaboveground)
2476             start = trace_endpos + '0 0 1' * maxaboveground;
2477         enddown = trace_endpos;
2478
2479         // rule 3: make sure we aren't outside the map. This only works
2480         // for somewhat well formed maps. A good rule of thumb is that
2481         // the map should have a convex outside hull.
2482         // these can be traceLINES as we already verified the starting box
2483         mstart = start + 0.5 * (e.mins + e.maxs);
2484         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2485         if (trace_fraction >= 1)
2486             continue;
2487         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2488         if (trace_fraction >= 1)
2489             continue;
2490         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2491         if (trace_fraction >= 1)
2492             continue;
2493         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2494         if (trace_fraction >= 1)
2495             continue;
2496         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2497         if (trace_fraction >= 1)
2498             continue;
2499
2500         // find a random vector to "look at"
2501         end_x = org_x + random() * delta_x;
2502         end_y = org_y + random() * delta_y;
2503         end_z = org_z + random() * delta_z;
2504         end = start + normalize(end - start) * vlen(delta);
2505
2506         // rule 4: start TO end must not be too short
2507         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2508         if (trace_startsolid)
2509             continue;
2510         if (trace_fraction < minviewdistance / vlen(delta))
2511             continue;
2512
2513         // rule 5: don't want to look at sky
2514         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2515             continue;
2516
2517         // rule 6: we must not end up in trigger_hurt
2518         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2519         {
2520             dprint("trigger_hurt! ouch! and nothing else could find it!\n");
2521             continue;
2522         }
2523
2524         break;
2525     }
2526
2527     e.dphitcontentsmask = m;
2528
2529     if (i < attempts)
2530     {
2531         setorigin(e, start);
2532         e.angles = vectoangles(end - start);
2533         dprint("Needed ", ftos(i + 1), " attempts\n");
2534         return TRUE;
2535     }
2536     else
2537         return FALSE;
2538 }
2539
2540 float zcurveparticles_effectno;
2541 vector zcurveparticles_start;
2542 float zcurveparticles_spd;
2543
2544 void endzcurveparticles()
2545 {
2546         if(zcurveparticles_effectno)
2547         {
2548                 // terminator
2549                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2550         }
2551         zcurveparticles_effectno = 0;
2552 }
2553
2554 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2555 {
2556         spd = bound(0, floor(spd / 16), 32767);
2557         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2558         {
2559                 endzcurveparticles();
2560                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2561                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2562                 WriteShort(MSG_BROADCAST, effectno);
2563                 WriteCoord(MSG_BROADCAST, start_x);
2564                 WriteCoord(MSG_BROADCAST, start_y);
2565                 WriteCoord(MSG_BROADCAST, start_z);
2566                 zcurveparticles_effectno = effectno;
2567                 zcurveparticles_start = start;
2568         }
2569         else
2570                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2571         WriteCoord(MSG_BROADCAST, end_x);
2572         WriteCoord(MSG_BROADCAST, end_y);
2573         WriteCoord(MSG_BROADCAST, end_z);
2574         WriteCoord(MSG_BROADCAST, end_dz);
2575         zcurveparticles_spd = spd;
2576 }
2577
2578 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2579 {
2580         float end_dz;
2581         vector vecxy, velxy;
2582
2583         vecxy = end - start;
2584         vecxy_z = 0;
2585         velxy = vel;
2586         velxy_z = 0;
2587
2588         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2589         {
2590                 endzcurveparticles();
2591                 trailparticles(world, effectno, start, end);
2592                 return;
2593         }
2594
2595         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2596         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2597 }
2598
2599 string GetGametype(); // g_world.qc
2600 void write_recordmarker(entity pl, float tstart, float dt)
2601 {
2602     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2603
2604     // also write a marker into demo files for demotc-race-record-extractor to find
2605     stuffcmd(pl,
2606              strcat(
2607                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2608                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2609 }
2610
2611 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2612 {
2613         switch(algn)
2614         {
2615                 case 1: // right
2616                         break;
2617
2618                 case 2: // left
2619                         vecs_y = -vecs_y;
2620                         break;
2621
2622                 default:
2623                 case 3:
2624                         if(allowcenter) // 2: allow center handedness
2625                         {
2626                                 // center
2627                                 vecs_y = 0;
2628                                 vecs_z -= 2;
2629                         }
2630                         else
2631                         {
2632                                 // right
2633                         }
2634                         break;
2635
2636                 case 4:
2637                         if(allowcenter) // 2: allow center handedness
2638                         {
2639                                 // center
2640                                 vecs_y = 0;
2641                                 vecs_z -= 2;
2642                         }
2643                         else
2644                         {
2645                                 // left
2646                                 vecs_y = -vecs_y;
2647                         }
2648                         break;
2649         }
2650         return vecs;
2651 }
2652
2653 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2654 {
2655         string s;
2656         vector v;
2657
2658         if (autocvar_g_shootfromeye)
2659         {
2660                 if (visual)
2661                 {
2662                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2663                 }
2664                 else
2665                 {
2666                         vecs_y = 0;
2667                         vecs_z = 0;
2668                 }
2669         }
2670         else if (autocvar_g_shootfromcenter)
2671         {
2672                 if (visual)
2673                 {
2674                         vecs = shotorg_adjustfromclient(vecs, y_is_right, TRUE, algn);
2675                 }
2676                 else
2677                 {
2678                         vecs_y = 0;
2679                         vecs_z -= 2;
2680                 }
2681         }
2682         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2683         {
2684                 v = stov(s);
2685                 if (y_is_right)
2686                         v_y = -v_y;
2687                 if (v_x != 0)
2688                         vecs_x = v_x;
2689                 vecs_y = v_y;
2690                 vecs_z = v_z;
2691         }
2692         else if (autocvar_g_shootfromclient)
2693         {
2694                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2695         }
2696         return vecs;
2697 }
2698
2699 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2700 {
2701         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2702 }
2703
2704
2705 void attach_sameorigin(entity e, entity to, string tag)
2706 {
2707     vector org, t_forward, t_left, t_up, e_forward, e_up;
2708     vector org0, ang0;
2709     float tagscale;
2710
2711     ang0 = e.angles;
2712     org0 = e.origin;
2713
2714     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2715     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2716     t_forward = v_forward * tagscale;
2717     t_left = v_right * -tagscale;
2718     t_up = v_up * tagscale;
2719
2720     e.origin_x = org * t_forward;
2721     e.origin_y = org * t_left;
2722     e.origin_z = org * t_up;
2723
2724     // current forward and up directions
2725     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2726                 e.angles = AnglesTransform_FromVAngles(e.angles);
2727         else
2728                 e.angles = AnglesTransform_FromAngles(e.angles);
2729     fixedmakevectors(e.angles);
2730
2731     // untransform forward, up!
2732     e_forward_x = v_forward * t_forward;
2733     e_forward_y = v_forward * t_left;
2734     e_forward_z = v_forward * t_up;
2735     e_up_x = v_up * t_forward;
2736     e_up_y = v_up * t_left;
2737     e_up_z = v_up * t_up;
2738
2739     e.angles = fixedvectoangles2(e_forward, e_up);
2740     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2741                 e.angles = AnglesTransform_ToVAngles(e.angles);
2742         else
2743                 e.angles = AnglesTransform_ToAngles(e.angles);
2744
2745     setattachment(e, to, tag);
2746     setorigin(e, e.origin);
2747 }
2748
2749 void detach_sameorigin(entity e)
2750 {
2751     vector org;
2752     org = gettaginfo(e, 0);
2753     e.angles = fixedvectoangles2(v_forward, v_up);
2754     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2755                 e.angles = AnglesTransform_ToVAngles(e.angles);
2756         else
2757                 e.angles = AnglesTransform_ToAngles(e.angles);
2758     setorigin(e, org);
2759     setattachment(e, world, "");
2760     setorigin(e, e.origin);
2761 }
2762
2763 void follow_sameorigin(entity e, entity to)
2764 {
2765     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2766     e.aiment = to; // make the hole follow bmodel
2767     e.punchangle = to.angles; // the original angles of bmodel
2768     e.view_ofs = e.origin - to.origin; // relative origin
2769     e.v_angle = e.angles - to.angles; // relative angles
2770 }
2771
2772 void unfollow_sameorigin(entity e)
2773 {
2774     e.movetype = MOVETYPE_NONE;
2775 }
2776
2777 entity gettaginfo_relative_ent;
2778 vector gettaginfo_relative(entity e, float tag)
2779 {
2780     if (!gettaginfo_relative_ent)
2781     {
2782         gettaginfo_relative_ent = spawn();
2783         gettaginfo_relative_ent.effects = EF_NODRAW;
2784     }
2785     gettaginfo_relative_ent.model = e.model;
2786     gettaginfo_relative_ent.modelindex = e.modelindex;
2787     gettaginfo_relative_ent.frame = e.frame;
2788     return gettaginfo(gettaginfo_relative_ent, tag);
2789 }
2790
2791 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2792 {
2793     float p;
2794     p = pow(2, chan);
2795     if (pl.soundentity.cnt & p)
2796         return;
2797     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2798     pl.soundentity.cnt |= p;
2799 }
2800
2801 void SoundEntity_StopSound(entity pl, float chan)
2802 {
2803     float p;
2804     p = pow(2, chan);
2805     if (pl.soundentity.cnt & p)
2806     {
2807         stopsoundto(MSG_ALL, pl.soundentity, chan);
2808         pl.soundentity.cnt &~= p;
2809     }
2810 }
2811
2812 void SoundEntity_Attach(entity pl)
2813 {
2814     pl.soundentity = spawn();
2815     pl.soundentity.classname = "soundentity";
2816     pl.soundentity.owner = pl;
2817     setattachment(pl.soundentity, pl, "");
2818     setmodel(pl.soundentity, "null");
2819 }
2820
2821 void SoundEntity_Detach(entity pl)
2822 {
2823     float i;
2824     for (i = 0; i <= 7; ++i)
2825         SoundEntity_StopSound(pl, i);
2826 }
2827
2828
2829 float ParseCommandPlayerSlotTarget_firsttoken;
2830 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2831 {
2832     string s;
2833     entity e, head;
2834     float n;
2835
2836     s = string_null;
2837
2838     ParseCommandPlayerSlotTarget_firsttoken = -1;
2839
2840     if (tokens > idx)
2841     {
2842         if (substring(argv(idx), 0, 1) == "#")
2843         {
2844             s = substring(argv(idx), 1, -1);
2845             ++idx;
2846             if (s == "")
2847                 if (tokens > idx)
2848                 {
2849                     s = argv(idx);
2850                     ++idx;
2851                 }
2852                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2853             if (s == ftos(stof(s)))
2854             {
2855                 e = edict_num(stof(s));
2856                 if (e.flags & FL_CLIENT)
2857                     return e;
2858             }
2859         }
2860         else
2861         {
2862             // it must be a nick name
2863             s = argv(idx);
2864             ++idx;
2865                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2866
2867             n = 0;
2868             FOR_EACH_CLIENT(head)
2869             if (head.netname == s)
2870             {
2871                 e = head;
2872                 ++n;
2873             }
2874             if (n == 1)
2875                 return e;
2876
2877             s = strdecolorize(s);
2878             n = 0;
2879             FOR_EACH_CLIENT(head)
2880             if (strdecolorize(head.netname) == s)
2881             {
2882                 e = head;
2883                 ++n;
2884             }
2885             if (n == 1)
2886                 return e;
2887         }
2888     }
2889
2890     return world;
2891 }
2892
2893 .float scale2;
2894
2895 float modeleffect_SendEntity(entity to, float sf)
2896 {
2897         float f;
2898         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2899
2900         f = 0;
2901         if(self.velocity != '0 0 0')
2902                 f |= 1;
2903         if(self.angles != '0 0 0')
2904                 f |= 2;
2905         if(self.avelocity != '0 0 0')
2906                 f |= 4;
2907
2908         WriteByte(MSG_ENTITY, f);
2909         WriteShort(MSG_ENTITY, self.modelindex);
2910         WriteByte(MSG_ENTITY, self.skin);
2911         WriteByte(MSG_ENTITY, self.frame);
2912         WriteCoord(MSG_ENTITY, self.origin_x);
2913         WriteCoord(MSG_ENTITY, self.origin_y);
2914         WriteCoord(MSG_ENTITY, self.origin_z);
2915         if(f & 1)
2916         {
2917                 WriteCoord(MSG_ENTITY, self.velocity_x);
2918                 WriteCoord(MSG_ENTITY, self.velocity_y);
2919                 WriteCoord(MSG_ENTITY, self.velocity_z);
2920         }
2921         if(f & 2)
2922         {
2923                 WriteCoord(MSG_ENTITY, self.angles_x);
2924                 WriteCoord(MSG_ENTITY, self.angles_y);
2925                 WriteCoord(MSG_ENTITY, self.angles_z);
2926         }
2927         if(f & 4)
2928         {
2929                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2930                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2931                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2932         }
2933         WriteShort(MSG_ENTITY, self.scale * 256.0);
2934         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2935         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2936         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2937         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2938
2939         return TRUE;
2940 }
2941
2942 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2943 {
2944         entity e;
2945         float sz;
2946         e = spawn();
2947         e.classname = "modeleffect";
2948         setmodel(e, m);
2949         e.frame = f;
2950         setorigin(e, o);
2951         e.velocity = v;
2952         e.angles = ang;
2953         e.avelocity = angv;
2954         e.alpha = a;
2955         e.teleport_time = t1;
2956         e.fade_time = t2;
2957         e.skin = s;
2958         if(s0 >= 0)
2959                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2960         else
2961                 e.scale = -s0;
2962         if(s2 >= 0)
2963                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2964         else
2965                 e.scale2 = -s2;
2966         sz = max(e.scale, e.scale2);
2967         setsize(e, e.mins * sz, e.maxs * sz);
2968         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2969 }
2970
2971 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2972 {
2973         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2974 }
2975
2976 float randombit(float bits)
2977 {
2978         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2979                 return bits;
2980
2981         float n, f, b, r;
2982
2983         r = random();
2984         b = 0;
2985         n = 0;
2986
2987         for(f = 1; f <= bits; f *= 2)
2988         {
2989                 if(bits & f)
2990                 {
2991                         ++n;
2992                         r *= n;
2993                         if(r <= 1)
2994                                 b = f;
2995                         else
2996                                 r = (r - 1) / (n - 1);
2997                 }
2998         }
2999
3000         return b;
3001 }
3002
3003 float randombits(float bits, float k, float error_return)
3004 {
3005         float r;
3006         r = 0;
3007         while(k > 0 && bits != r)
3008         {
3009                 r += randombit(bits - r);
3010                 --k;
3011         }
3012         if(error_return)
3013                 if(k > 0)
3014                         return -1; // all
3015         return r;
3016 }
3017
3018 void randombit_test(float bits, float iter)
3019 {
3020         while(iter > 0)
3021         {
3022                 print(ftos(randombit(bits)), "\n");
3023                 --iter;
3024         }
3025 }
3026
3027 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3028 {
3029         if(halflifedist > 0)
3030                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3031         else if(halflifedist < 0)
3032                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3033         else
3034                 return 1;
3035 }
3036
3037
3038
3039
3040 #ifdef RELEASE
3041 #define cvar_string_normal cvar_string_builtin
3042 #define cvar_normal cvar_builtin
3043 #else
3044 string cvar_string_normal(string n)
3045 {
3046         if not(cvar_type(n) & 1)
3047                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3048         return cvar_string_builtin(n);
3049 }
3050
3051 float cvar_normal(string n)
3052 {
3053         return stof(cvar_string_normal(n));
3054 }
3055 #endif
3056 #define cvar_set_normal cvar_set_builtin
3057
3058 void defer_think()
3059 {
3060     entity oself;
3061
3062     oself           = self;
3063     self            = self.owner;
3064     oself.think     = SUB_Remove;
3065     oself.nextthink = time;
3066
3067     oself.use();
3068 }
3069
3070 /*
3071     Execute func() after time + fdelay.
3072     self when func is executed = self when defer is called
3073 */
3074 void defer(float fdelay, void() func)
3075 {
3076     entity e;
3077
3078     e           = spawn();
3079     e.owner     = self;
3080     e.use       = func;
3081     e.think     = defer_think;
3082     e.nextthink = time + fdelay;
3083 }