qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "antilag.qh"
   3 #include "command/common.qh"
   4 #include "constants.qh"
   5 #include "g_hook.qh"
   6 #include "ipban.qh"
   7 #include "mutators/all.qh"
   8 #include "t_items.qh"
   9 #include "weapons/accuracy.qh"
  10 #include "weapons/csqcprojectile.qh"
  11 #include "weapons/selection.qh"
  12 #include "../common/command/generic.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/notifications.qh"
  17 #include "../common/playerstats.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/triggers/subs.qh"
  20 #include "../common/util.qh"
  21 #include "../common/turrets/sv_turrets.qh"
  22 #include "../common/weapons/all.qh"
  23 #include "../common/vehicles/sv_vehicles.qh"
  24 #include "../common/vehicles/vehicle.qh"
  25 #include "../common/items/all.qc"
  26 #include "../lib/csqcmodel/sv_model.qh"
  27 #include "../lib/warpzone/anglestransform.qh"
  28 #include "../lib/warpzone/server.qh"
  29
  30 void crosshair_trace(entity pl)
  31 {
  32         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  33 }
  34 void crosshair_trace_plusvisibletriggers(entity pl)
  35 {
  36         entity first;
  37         entity e;
  38         first = findchainfloat(solid, SOLID_TRIGGER);
  39
  40         for (e = first; e; e = e.chain)
  41                 if (e.model != "")
  42                         e.solid = SOLID_BSP;
  43
  44         crosshair_trace(pl);
  45
  46         for (e = first; e; e = e.chain)
  47                 e.solid = SOLID_TRIGGER;
  48 }
  49 void WarpZone_crosshair_trace(entity pl)
  50 {
  51         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  52 }
  53
  54
  55 string admin_name()
  56 {
  57         if(autocvar_sv_adminnick != "")
  58                 return autocvar_sv_adminnick;
  59         else
  60                 return "SERVER ADMIN";
  61 }
  62
  63
  64 void GameLogEcho(string s)
  65 {
  66     string fn;
  67     int matches;
  68
  69     if (autocvar_sv_eventlog_files)
  70     {
  71         if (!logfile_open)
  72         {
  73             logfile_open = true;
  74             matches = autocvar_sv_eventlog_files_counter + 1;
  75             cvar_set("sv_eventlog_files_counter", itos(matches));
  76             fn = ftos(matches);
  77             if (strlen(fn) < 8)
  78                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  79             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  80             logfile = fopen(fn, FILE_APPEND);
  81             fputs(logfile, ":logversion:3\n");
  82         }
  83         if (logfile >= 0)
  84         {
  85             if (autocvar_sv_eventlog_files_timestamps)
  86                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  87             else
  88                 fputs(logfile, strcat(s, "\n"));
  89         }
  90     }
  91     if (autocvar_sv_eventlog_console)
  92     {
  93         LOG_INFO(s, "\n");
  94     }
  95 }
  96
  97 void GameLogInit()
  98 {
  99     logfile_open = 0;
 100     // will be opened later
 101 }
 102
 103 void GameLogClose()
 104 {
 105     if (logfile_open && logfile >= 0)
 106     {
 107         fclose(logfile);
 108         logfile = -1;
 109     }
 110 }
 111
 112 entity findnearest(vector point, .string field, string value, vector axismod)
 113 {
 114     entity localhead;
 115     float i;
 116     float j;
 117     float len;
 118     vector dist;
 119
 120     float num_nearest;
 121     num_nearest = 0;
 122
 123     localhead = find(world, field, value);
 124     while (localhead)
 125     {
 126         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 127             dist = localhead.oldorigin;
 128         else
 129             dist = localhead.origin;
 130         dist = dist - point;
 131         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 132         len = vlen(dist);
 133
 134         for (i = 0; i < num_nearest; ++i)
 135         {
 136             if (len < nearest_length[i])
 137                 break;
 138         }
 139
 140         // now i tells us where to insert at
 141         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 142         if (i < NUM_NEAREST_ENTITIES)
 143         {
 144             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 145             {
 146                 nearest_length[j + 1] = nearest_length[j];
 147                 nearest_entity[j + 1] = nearest_entity[j];
 148             }
 149             nearest_length[i] = len;
 150             nearest_entity[i] = localhead;
 151             if (num_nearest < NUM_NEAREST_ENTITIES)
 152                 num_nearest = num_nearest + 1;
 153         }
 154
 155         localhead = find(localhead, field, value);
 156     }
 157
 158     // now use the first one from our list that we can see
 159     for (i = 0; i < num_nearest; ++i)
 160     {
 161         traceline(point, nearest_entity[i].origin, true, world);
 162         if (trace_fraction == 1)
 163         {
 164             if (i != 0)
 165             {
 166                 LOG_TRACE("Nearest point (");
 167                 LOG_TRACE(nearest_entity[0].netname);
 168                 LOG_TRACE(") is not visible, using a visible one.\n");
 169             }
 170             return nearest_entity[i];
 171         }
 172     }
 173
 174     if (num_nearest == 0)
 175         return world;
 176
 177     LOG_TRACE("Not seeing any location point, using nearest as fallback.\n");
 178     /* DEBUGGING CODE:
 179     dprint("Candidates were: ");
 180     for(j = 0; j < num_nearest; ++j)
 181     {
 182         if(j != 0)
 183                 dprint(", ");
 184         dprint(nearest_entity[j].netname);
 185     }
 186     dprint("\n");
 187     */
 188
 189     return nearest_entity[0];
 190 }
 191
 192 string NearestLocation(vector p)
 193 {
 194     entity loc;
 195     string ret;
 196     ret = "somewhere";
 197     loc = findnearest(p, classname, "target_location", '1 1 1');
 198     if (loc)
 199     {
 200         ret = loc.message;
 201     }
 202     else
 203     {
 204         loc = findnearest(p, target, "###item###", '1 1 4');
 205         if (loc)
 206             ret = loc.netname;
 207     }
 208     return ret;
 209 }
 210
 211 string formatmessage(string msg)
 212 {SELFPARAM();
 213         float p, p1, p2;
 214         float n;
 215         vector cursor;
 216         entity cursor_ent;
 217         string escape;
 218         string replacement;
 219         string ammoitems;
 220         p = 0;
 221         n = 7;
 222
 223         ammoitems = "batteries";
 224         if(self.items & ITEM_Plasma.m_itemid) ammoitems = ITEM_Plasma.m_name;
 225         if(self.items & ITEM_Cells.m_itemid) ammoitems = ITEM_Cells.m_name;
 226         if(self.items & ITEM_Rockets.m_itemid) ammoitems = ITEM_Rockets.m_name;
 227         if(self.items & ITEM_Shells.m_itemid) ammoitems = ITEM_Shells.m_name;
 228
 229         WarpZone_crosshair_trace(self);
 230         cursor = trace_endpos;
 231         cursor_ent = trace_ent;
 232
 233         while (1) {
 234                 if (n < 1)
 235                         break; // too many replacements
 236
 237                 n = n - 1;
 238                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 239                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 240
 241                 if (p1 < 0)
 242                         p1 = p2;
 243
 244                 if (p2 < 0)
 245                         p2 = p1;
 246
 247                 p = min(p1, p2);
 248
 249                 if (p < 0)
 250                         break;
 251
 252                 replacement = substring(msg, p, 2);
 253                 escape = substring(msg, p + 1, 1);
 254
 255                 switch(escape)
 256                 {
 257                         case "%": replacement = "%"; break;
 258                         case "\\":replacement = "\\"; break;
 259                         case "n": replacement = "\n"; break;
 260                         case "a": replacement = ftos(floor(self.armorvalue)); break;
 261                         case "h": replacement = ftos(floor(self.health)); break;
 262                         case "l": replacement = NearestLocation(self.origin); break;
 263                         case "y": replacement = NearestLocation(cursor); break;
 264                         case "d": replacement = NearestLocation(self.death_origin); break;
 265                         case "w": replacement = ((PS(self).m_weapon == WEP_Null) ? ((PS(self).m_switchweapon == WEP_Null) ? Weapons_from(self.cnt) : PS(self).m_switchweapon) : PS(self).m_weapon).m_name; break;
 266                         case "W": replacement = ammoitems; break;
 267                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 268                         case "s": replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1')); break;
 269                         case "S": replacement = ftos(vlen(self.velocity)); break;
 270                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 271                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 272                         default:
 273                         {
 274                                 MUTATOR_CALLHOOK(FormatMessage, escape, replacement, msg);
 275                                 escape = format_escape;
 276                                 replacement = format_replacement;
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(string thisname, float f, .string field, string name)
 296 {SELFPARAM();
 297         if (f < 0)
 298         {
 299                 if (self.(field))
 300                         strunzone(self.(field));
 301                 self.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (self.(field))
 308                                 strunzone(self.(field));
 309                         self.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 316 {SELFPARAM();
 317         GetCvars_handleString(thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(strcat1(self.(field)));
 322                         if (s != self.(field))
 323                         {
 324                                 strunzone(self.(field));
 325                                 self.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 330 {SELFPARAM();
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         self.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 343 {SELFPARAM();
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!self.(field))
 352                         {
 353                                 self.(field) = stof(argv(f + 1));
 354                                 if (!self.(field))
 355                                         self.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!self.(field))
 362                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 366 {SELFPARAM();
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(self.weaponorder_byimpulse)
 370         {
 371                 strunzone(self.weaponorder_byimpulse);
 372                 self.weaponorder_byimpulse = string_null;
 373         }
 374         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377
 378 /**
 379  * @param f -1: cleanup, 0: request, 1: receive
 380  */
 381 void GetCvars(int f)
 382 {SELFPARAM();
 383         string s = string_null;
 384
 385         if (f > 0)
 386                 s = strcat1(argv(f));
 387
 388         get_cvars_f = f;
 389         get_cvars_s = s;
 390         MUTATOR_CALLHOOK(GetCvars);
 391
 392         Notification_GetCvars();
 393
 394         ReplicateVars(this, s, f);
 395
 396         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 397         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 398         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 399         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 400         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 401         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 402         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 403         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 404         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 405         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 406         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 407         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 408         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 409         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 410         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 411         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 412         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 413         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 414         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 415         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 416         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 417         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 418         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 419
 420         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 421         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 422         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 423         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 424
 425         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 426         if (f > 0)
 427         {
 428                 if (s == "cl_weaponpriority")
 429                         if (PS(self)) PS(self).m_switchweapon = w_getbestweapon(self);
 430                 if (s == "cl_allow_uidtracking")
 431                         PlayerStats_GameReport_AddPlayer(self);
 432         }
 433 }
 434
 435 // decolorizes and team colors the player name when needed
 436 string playername(entity p)
 437 {
 438     string t;
 439     if (teamplay && !intermission_running && IS_PLAYER(p))
 440     {
 441         t = Team_ColorCode(p.team);
 442         return strcat(t, strdecolorize(p.netname));
 443     }
 444     else
 445         return p.netname;
 446 }
 447
 448 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 449 {
 450         int i = weaponinfo.m_id;
 451         int d = 0;
 452         bool allow_mutatorblocked = false;
 453
 454         if(!i)
 455                 return 0;
 456
 457         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 458         d = ret_float;
 459         allguns = want_allguns;
 460         allow_mutatorblocked = false;
 461
 462         if(allguns)
 463         {
 464                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 465                         d = true;
 466                 else
 467                         d = false;
 468         }
 469         else if(!mutator_returnvalue)
 470                 d = !(!weaponinfo.weaponstart);
 471
 472         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 473                 d = 0;
 474
 475         float t = weaponinfo.weaponstartoverride;
 476
 477         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 478
 479         // bit order in t:
 480         // 1: want or not
 481         // 2: is default?
 482         // 4: is set by default?
 483         if(t < 0)
 484                 t = 4 | (3 * d);
 485         else
 486                 t |= (2 * d);
 487
 488         return t;
 489 }
 490
 491 void readplayerstartcvars()
 492 {
 493         entity e;
 494         float i, t;
 495         string s;
 496
 497         // initialize starting values for players
 498         start_weapons = '0 0 0';
 499         start_weapons_default = '0 0 0';
 500         start_weapons_defaultmask = '0 0 0';
 501         start_items = 0;
 502         start_ammo_shells = 0;
 503         start_ammo_nails = 0;
 504         start_ammo_rockets = 0;
 505         start_ammo_cells = 0;
 506         start_ammo_plasma = 0;
 507         start_health = cvar("g_balance_health_start");
 508         start_armorvalue = cvar("g_balance_armor_start");
 509
 510         g_weaponarena = 0;
 511         g_weaponarena_weapons = '0 0 0';
 512
 513         s = cvar_string("g_weaponarena");
 514
 515         MUTATOR_CALLHOOK(SetWeaponArena, s);
 516         s = ret_string;
 517
 518         if (s == "0" || s == "")
 519         {
 520                 // no arena
 521         }
 522         else if (s == "off")
 523         {
 524                 // forcibly turn off weaponarena
 525         }
 526         else if (s == "all" || s == "1")
 527         {
 528                 g_weaponarena = 1;
 529                 g_weaponarena_list = "All Weapons";
 530                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 531                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 532                                 g_weaponarena_weapons |= (it.m_wepset);
 533                 ));
 534         }
 535         else if (s == "most")
 536         {
 537                 g_weaponarena = 1;
 538                 g_weaponarena_list = "Most Weapons";
 539                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 540                         if(!(it.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 541                                 if(it.spawnflags & WEP_FLAG_NORMAL)
 542                                         g_weaponarena_weapons |= (it.m_wepset);
 543                 ));
 544         }
 545         else if (s == "none")
 546         {
 547                 g_weaponarena = 1;
 548                 g_weaponarena_list = "No Weapons";
 549         }
 550         else
 551         {
 552                 g_weaponarena = 1;
 553                 t = tokenize_console(s);
 554                 g_weaponarena_list = "";
 555                 for (i = 0; i < t; ++i)
 556                 {
 557                         s = argv(i);
 558                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 559                                 if(it.netname == s)
 560                                 {
 561                                         g_weaponarena_weapons |= (it.m_wepset);
 562                                         g_weaponarena_list = strcat(g_weaponarena_list, it.m_name, " & ");
 563                                         break;
 564                                 }
 565                         ));
 566                 }
 567                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 568         }
 569
 570         if(g_weaponarena)
 571                 g_weaponarena_random = cvar("g_weaponarena_random");
 572         else
 573                 g_weaponarena_random = 0;
 574         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 575
 576         if (g_weaponarena)
 577         {
 578                 g_weapon_stay = 0; // incompatible
 579                 start_weapons = g_weaponarena_weapons;
 580                 start_items |= IT_UNLIMITED_AMMO;
 581         }
 582         else
 583         {
 584                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 585                         int w = want_weapon(it, false);
 586                         WepSet s = it.m_wepset;
 587                         if(w & 1)
 588                                 start_weapons |= s;
 589                         if(w & 2)
 590                                 start_weapons_default |= s;
 591                         if(w & 4)
 592                                 start_weapons_defaultmask |= s;
 593                 ));
 594         }
 595
 596         if(!cvar("g_use_ammunition"))
 597                 start_items |= IT_UNLIMITED_AMMO;
 598
 599         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 600         {
 601                 start_ammo_shells = 999;
 602                 start_ammo_nails = 999;
 603                 start_ammo_rockets = 999;
 604                 start_ammo_cells = 999;
 605                 start_ammo_plasma = 999;
 606                 start_ammo_fuel = 999;
 607         }
 608         else
 609         {
 610                 start_ammo_shells = cvar("g_start_ammo_shells");
 611                 start_ammo_nails = cvar("g_start_ammo_nails");
 612                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 613                 start_ammo_cells = cvar("g_start_ammo_cells");
 614                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 615                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 616         }
 617
 618         if (warmup_stage)
 619         {
 620                 warmup_start_ammo_shells = start_ammo_shells;
 621                 warmup_start_ammo_nails = start_ammo_nails;
 622                 warmup_start_ammo_rockets = start_ammo_rockets;
 623                 warmup_start_ammo_cells = start_ammo_cells;
 624                 warmup_start_ammo_plasma = start_ammo_plasma;
 625                 warmup_start_ammo_fuel = start_ammo_fuel;
 626                 warmup_start_health = start_health;
 627                 warmup_start_armorvalue = start_armorvalue;
 628                 warmup_start_weapons = start_weapons;
 629                 warmup_start_weapons_default = start_weapons_default;
 630                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 631
 632                 if (!g_weaponarena && !g_ca && !g_freezetag)
 633                 {
 634                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 635                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 636                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 637                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 638                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 639                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 640                         warmup_start_health = cvar("g_warmup_start_health");
 641                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 642                         warmup_start_weapons = '0 0 0';
 643                         warmup_start_weapons_default = '0 0 0';
 644                         warmup_start_weapons_defaultmask = '0 0 0';
 645                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 646                         {
 647                                 e = Weapons_from(i);
 648                                 int w = want_weapon(e, g_warmup_allguns);
 649                                 WepSet s = (e.m_wepset);
 650                                 if(w & 1)
 651                                         warmup_start_weapons |= s;
 652                                 if(w & 2)
 653                                         warmup_start_weapons_default |= s;
 654                                 if(w & 4)
 655                                         warmup_start_weapons_defaultmask |= s;
 656                         }
 657                 }
 658         }
 659
 660         if (g_jetpack)
 661                 start_items |= ITEM_Jetpack.m_itemid;
 662
 663         MUTATOR_CALLHOOK(SetStartItems);
 664
 665         if (start_items & ITEM_Jetpack.m_itemid)
 666         {
 667                 start_items |= ITEM_JetpackRegen.m_itemid;
 668                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 669                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 670         }
 671
 672         WepSet precache_weapons = start_weapons;
 673         if (g_warmup_allguns != 1)
 674                 precache_weapons |= warmup_start_weapons;
 675         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 676                 if(precache_weapons & (it.m_wepset))
 677                         it.wr_init(it);
 678         ));
 679
 680         start_ammo_shells = max(0, start_ammo_shells);
 681         start_ammo_nails = max(0, start_ammo_nails);
 682         start_ammo_rockets = max(0, start_ammo_rockets);
 683         start_ammo_cells = max(0, start_ammo_cells);
 684         start_ammo_plasma = max(0, start_ammo_plasma);
 685         start_ammo_fuel = max(0, start_ammo_fuel);
 686
 687         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 688         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 689         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 690         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 691         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 692         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 693 }
 694
 695 void precache_playermodel(string m)
 696 {
 697         float globhandle, i, n;
 698         string f;
 699
 700         if(substring(m, -9,5) == "_lod1")
 701                 return;
 702         if(substring(m, -9,5) == "_lod2")
 703                 return;
 704         precache_model(m);
 705         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 706         if(fexists(f))
 707                 precache_model(f);
 708         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 709         if(fexists(f))
 710                 precache_model(f);
 711
 712         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 713         if (globhandle < 0)
 714                 return;
 715         n = search_getsize(globhandle);
 716         for (i = 0; i < n; ++i)
 717         {
 718                 //print(search_getfilename(globhandle, i), "\n");
 719                 f = search_getfilename(globhandle, i);
 720                 PrecachePlayerSounds(f);
 721         }
 722         search_end(globhandle);
 723 }
 724 void precache_all_playermodels(string pattern)
 725 {
 726         int globhandle = search_begin(pattern, true, false);
 727         if (globhandle < 0) return;
 728         int n = search_getsize(globhandle);
 729         for (int i = 0; i < n; ++i)
 730         {
 731                 string s = search_getfilename(globhandle, i);
 732                 precache_playermodel(s);
 733         }
 734         search_end(globhandle);
 735 }
 736
 737 void precache_playermodels(string s)
 738 {
 739         FOREACH_WORD(s, true, LAMBDA(precache_playermodel(it)));
 740 }
 741
 742 void precache()
 743 {SELFPARAM();
 744     // gamemode related things
 745
 746     // Precache all player models if desired
 747     if (autocvar_sv_precacheplayermodels)
 748     {
 749         PrecachePlayerSounds("sound/player/default.sounds");
 750         precache_all_playermodels("models/player/*.zym");
 751         precache_all_playermodels("models/player/*.dpm");
 752         precache_all_playermodels("models/player/*.md3");
 753         precache_all_playermodels("models/player/*.psk");
 754         precache_all_playermodels("models/player/*.iqm");
 755     }
 756
 757     if (autocvar_sv_defaultcharacter)
 758     {
 759                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 760                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 761                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 762                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 763                 precache_playermodels(autocvar_sv_defaultplayermodel);
 764     }
 765
 766 #if 0
 767     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 768
 769     if (!self.noise && self.music) // quake 3 uses the music field
 770         self.noise = self.music;
 771
 772     // plays music for the level if there is any
 773     if (self.noise)
 774     {
 775         precache_sound (self.noise);
 776         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
 777     }
 778 #endif
 779 }
 780
 781
 782 void make_safe_for_remove(entity e)
 783 {
 784     if (e.initialize_entity)
 785     {
 786         entity ent, prev = world;
 787         for (ent = initialize_entity_first; ent; )
 788         {
 789             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 790             {
 791                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 792                 // skip it in linked list
 793                 if (prev)
 794                 {
 795                     prev.initialize_entity_next = ent.initialize_entity_next;
 796                     ent = prev.initialize_entity_next;
 797                 }
 798                 else
 799                 {
 800                     initialize_entity_first = ent.initialize_entity_next;
 801                     ent = initialize_entity_first;
 802                 }
 803             }
 804             else
 805             {
 806                 prev = ent;
 807                 ent = ent.initialize_entity_next;
 808             }
 809         }
 810     }
 811 }
 812
 813 void objerror(string s)
 814 {SELFPARAM();
 815     make_safe_for_remove(self);
 816     builtin_objerror(s);
 817 }
 818
 819 .float remove_except_protected_forbidden;
 820 void remove_except_protected(entity e)
 821 {
 822         if(e.remove_except_protected_forbidden)
 823                 error("not allowed to remove this at this point");
 824         builtin_remove(e);
 825 }
 826
 827 void remove_unsafely(entity e)
 828 {
 829     if(e.classname == "spike")
 830         error("Removing spikes is forbidden (crylink bug), please report");
 831     builtin_remove(e);
 832 }
 833
 834 void remove_safely(entity e)
 835 {
 836     make_safe_for_remove(e);
 837     builtin_remove(e);
 838 }
 839
 840 void InitializeEntity(entity e, void() func, float order)
 841 {
 842     entity prev, cur;
 843
 844     if (!e || e.initialize_entity)
 845     {
 846         // make a proxy initializer entity
 847         entity e_old = e;
 848         e = new(initialize_entity);
 849         e.enemy = e_old;
 850     }
 851
 852     e.initialize_entity = func;
 853     e.initialize_entity_order = order;
 854
 855     cur = initialize_entity_first;
 856     prev = world;
 857     for (;;)
 858     {
 859         if (!cur || cur.initialize_entity_order > order)
 860         {
 861             // insert between prev and cur
 862             if (prev)
 863                 prev.initialize_entity_next = e;
 864             else
 865                 initialize_entity_first = e;
 866             e.initialize_entity_next = cur;
 867             return;
 868         }
 869         prev = cur;
 870         cur = cur.initialize_entity_next;
 871     }
 872 }
 873 void InitializeEntitiesRun()
 874 {SELFPARAM();
 875     entity startoflist = initialize_entity_first;
 876     initialize_entity_first = NULL;
 877     remove = remove_except_protected;
 878     for (entity e = startoflist; e; e = e.initialize_entity_next)
 879     {
 880                 e.remove_except_protected_forbidden = 1;
 881     }
 882     for (entity e = startoflist; e; )
 883     {
 884                 e.remove_except_protected_forbidden = 0;
 885         e.initialize_entity_order = 0;
 886         entity next = e.initialize_entity_next;
 887         e.initialize_entity_next = NULL;
 888         var void() func = e.initialize_entity;
 889         e.initialize_entity = func_null;
 890         if (e.classname == "initialize_entity")
 891         {
 892             entity wrappee = e.enemy;
 893             builtin_remove(e);
 894             e = wrappee;
 895         }
 896         //dprint("Delayed initialization: ", e.classname, "\n");
 897         if (func)
 898         {
 899                 WITH(entity, self, e, func());
 900         }
 901         else
 902         {
 903             eprint(e);
 904             backtrace(strcat("Null function in: ", e.classname, "\n"));
 905         }
 906         e = next;
 907     }
 908     remove = remove_unsafely;
 909 }
 910
 911 .float(entity) isEliminated;
 912 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 913 {
 914         float i, f, b;
 915         entity e;
 916         WriteHeader(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 917         WriteByte(MSG_ENTITY, sendflags);
 918
 919         if(sendflags & 1)
 920         {
 921                 for(i = 1; i <= maxclients; i += 8)
 922                 {
 923                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 924                         {
 925                                 if(eliminatedPlayers.isEliminated(e))
 926                                         f |= b;
 927                         }
 928                         WriteByte(MSG_ENTITY, f);
 929                 }
 930         }
 931
 932         return true;
 933 }
 934
 935 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 936 {
 937         if(eliminatedPlayers)
 938         {
 939                 backtrace("Can't spawn eliminatedPlayers again!");
 940                 return;
 941         }
 942         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 943         eliminatedPlayers.isEliminated = isEliminated_func;
 944 }
 945
 946
 947 void adaptor_think2touch()
 948 {SELFPARAM();
 949     entity o;
 950     o = other;
 951     other = world;
 952     self.touch();
 953     other = o;
 954 }
 955
 956 void adaptor_think2use()
 957 {SELFPARAM();
 958     entity o, a;
 959     o = other;
 960     a = activator;
 961     activator = world;
 962     other = world;
 963     self.use();
 964     other = o;
 965     activator = a;
 966 }
 967
 968 void adaptor_think2use_hittype_splash() // for timed projectile detonation
 969 {SELFPARAM();
 970         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 971                 self.projectiledeathtype |= HITTYPE_SPLASH;
 972         adaptor_think2use();
 973 }
 974
 975 // deferred dropping
 976 void DropToFloor_Handler()
 977 {SELFPARAM();
 978     builtin_droptofloor();
 979     self.dropped_origin = self.origin;
 980 }
 981
 982 void droptofloor()
 983 {SELFPARAM();
 984     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
 985 }
 986
 987
 988
 989 float trace_hits_box_a0, trace_hits_box_a1;
 990
 991 float trace_hits_box_1d(float end, float thmi, float thma)
 992 {
 993     if (end == 0)
 994     {
 995         // just check if x is in range
 996         if (0 < thmi)
 997             return false;
 998         if (0 > thma)
 999             return false;
1000     }
1001     else
1002     {
1003         // do the trace with respect to x
1004         // 0 -> end has to stay in thmi -> thma
1005         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1006         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1007         if (trace_hits_box_a0 > trace_hits_box_a1)
1008             return false;
1009     }
1010     return true;
1011 }
1012
1013 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1014 {
1015     end -= start;
1016     thmi -= start;
1017     thma -= start;
1018     // now it is a trace from 0 to end
1019
1020     trace_hits_box_a0 = 0;
1021     trace_hits_box_a1 = 1;
1022
1023     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1024         return false;
1025     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1026         return false;
1027     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1028         return false;
1029
1030     return true;
1031 }
1032
1033 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1034 {
1035     return trace_hits_box(start, end, thmi - ma, thma - mi);
1036 }
1037
1038 float SUB_NoImpactCheck()
1039 {SELFPARAM();
1040         // zero hitcontents = this is not the real impact, but either the
1041         // mirror-impact of something hitting the projectile instead of the
1042         // projectile hitting the something, or a touchareagrid one. Neither of
1043         // these stop the projectile from moving, so...
1044         if(trace_dphitcontents == 0)
1045         {
1046                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1047                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", etof(self), self.classname, vtos(self.origin));
1048                 checkclient();
1049         }
1050     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1051         return 1;
1052     if (other == world && self.size != '0 0 0')
1053     {
1054         vector tic;
1055         tic = self.velocity * sys_frametime;
1056         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1057         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1058         if (trace_fraction >= 1)
1059         {
1060             LOG_TRACE("Odd... did not hit...?\n");
1061         }
1062         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1063         {
1064             LOG_TRACE("Detected and prevented the sky-grapple bug.\n");
1065             return 1;
1066         }
1067     }
1068
1069     return 0;
1070 }
1071
1072 #define SUB_OwnerCheck() (other && (other == self.owner))
1073
1074 void W_Crylink_Dequeue(entity e);
1075 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1076 {SELFPARAM();
1077         if(SUB_OwnerCheck())
1078                 return true;
1079         if(SUB_NoImpactCheck())
1080         {
1081                 if(self.classname == "nade")
1082                         return false; // no checks here
1083                 else if(self.classname == "grapplinghook")
1084                         RemoveGrapplingHook(self.realowner);
1085                 else if(self.classname == "spike")
1086                 {
1087                         W_Crylink_Dequeue(self);
1088                         remove(self);
1089                 }
1090                 else
1091                         remove(self);
1092                 return true;
1093         }
1094         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1095                 UpdateCSQCProjectile(self);
1096         return false;
1097 }
1098
1099 /** engine callback */
1100 void URI_Get_Callback(float id, float status, string data)
1101 {
1102         if(url_URI_Get_Callback(id, status, data))
1103         {
1104                 // handled
1105         }
1106         else if (id == URI_GET_DISCARD)
1107         {
1108                 // discard
1109         }
1110         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1111         {
1112                 // sv_cmd curl
1113                 Curl_URI_Get_Callback(id, status, data);
1114         }
1115         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1116         {
1117                 // online ban list
1118                 OnlineBanList_URI_Get_Callback(id, status, data);
1119         }
1120         else
1121         {
1122                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1123         }
1124 }
1125
1126 string uid2name(string myuid) {
1127         string s;
1128         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1129
1130         // FIXME remove this later after 0.6 release
1131         // convert old style broken records to correct style
1132         if(s == "")
1133         {
1134                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1135                 if(s != "")
1136                 {
1137                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1138                         db_remove(ServerProgsDB, strcat("uid2name", myuid));
1139                 }
1140         }
1141
1142         if(s == "")
1143                 s = "^1Unregistered Player";
1144         return s;
1145 }
1146
1147 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1148 {
1149     float m, i;
1150     vector start, org, delta, end, enddown, mstart;
1151     entity sp;
1152
1153     m = e.dphitcontentsmask;
1154     e.dphitcontentsmask = goodcontents | badcontents;
1155
1156     org = boundmin;
1157     delta = boundmax - boundmin;
1158
1159     start = end = org;
1160
1161     for (i = 0; i < attempts; ++i)
1162     {
1163         start.x = org.x + random() * delta.x;
1164         start.y = org.y + random() * delta.y;
1165         start.z = org.z + random() * delta.z;
1166
1167         // rule 1: start inside world bounds, and outside
1168         // solid, and don't start from somewhere where you can
1169         // fall down to evil
1170         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1171         if (trace_fraction >= 1)
1172             continue;
1173         if (trace_startsolid)
1174             continue;
1175         if (trace_dphitcontents & badcontents)
1176             continue;
1177         if (trace_dphitq3surfaceflags & badsurfaceflags)
1178             continue;
1179
1180         // rule 2: if we are too high, lower the point
1181         if (trace_fraction * delta.z > maxaboveground)
1182             start = trace_endpos + '0 0 1' * maxaboveground;
1183         enddown = trace_endpos;
1184
1185         // rule 3: make sure we aren't outside the map. This only works
1186         // for somewhat well formed maps. A good rule of thumb is that
1187         // the map should have a convex outside hull.
1188         // these can be traceLINES as we already verified the starting box
1189         mstart = start + 0.5 * (e.mins + e.maxs);
1190         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1191         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1192             continue;
1193         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1194         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1195             continue;
1196         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1197         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1198             continue;
1199         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1200         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1201             continue;
1202         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1203         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1204             continue;
1205
1206         // rule 4: we must "see" some spawnpoint or item
1207         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1208                 if(checkpvs(mstart, sp))
1209                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1210                                 break;
1211         if(!sp)
1212         {
1213                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1214                         if(checkpvs(mstart, sp))
1215                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1216                                         break;
1217                 if(!sp)
1218                         continue;
1219         }
1220
1221         // find a random vector to "look at"
1222         end.x = org.x + random() * delta.x;
1223         end.y = org.y + random() * delta.y;
1224         end.z = org.z + random() * delta.z;
1225         end = start + normalize(end - start) * vlen(delta);
1226
1227         // rule 4: start TO end must not be too short
1228         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1229         if (trace_startsolid)
1230             continue;
1231         if (trace_fraction < minviewdistance / vlen(delta))
1232             continue;
1233
1234         // rule 5: don't want to look at sky
1235         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1236             continue;
1237
1238         // rule 6: we must not end up in trigger_hurt
1239         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1240             continue;
1241
1242         break;
1243     }
1244
1245     e.dphitcontentsmask = m;
1246
1247     if (i < attempts)
1248     {
1249         setorigin(e, start);
1250         e.angles = vectoangles(end - start);
1251         LOG_TRACE("Needed ", ftos(i + 1), " attempts\n");
1252         return true;
1253     }
1254     else
1255         return false;
1256 }
1257
1258 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1259 {
1260         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1261 }
1262
1263 void write_recordmarker(entity pl, float tstart, float dt)
1264 {
1265     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1266
1267     // also write a marker into demo files for demotc-race-record-extractor to find
1268     stuffcmd(pl,
1269              strcat(
1270                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1271                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1272 }
1273
1274 void attach_sameorigin(entity e, entity to, string tag)
1275 {
1276     vector org, t_forward, t_left, t_up, e_forward, e_up;
1277     float tagscale;
1278
1279     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1280     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1281     t_forward = v_forward * tagscale;
1282     t_left = v_right * -tagscale;
1283     t_up = v_up * tagscale;
1284
1285     e.origin_x = org * t_forward;
1286     e.origin_y = org * t_left;
1287     e.origin_z = org * t_up;
1288
1289     // current forward and up directions
1290     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1291                 e.angles = AnglesTransform_FromVAngles(e.angles);
1292         else
1293                 e.angles = AnglesTransform_FromAngles(e.angles);
1294     fixedmakevectors(e.angles);
1295
1296     // untransform forward, up!
1297     e_forward.x = v_forward * t_forward;
1298     e_forward.y = v_forward * t_left;
1299     e_forward.z = v_forward * t_up;
1300     e_up.x = v_up * t_forward;
1301     e_up.y = v_up * t_left;
1302     e_up.z = v_up * t_up;
1303
1304     e.angles = fixedvectoangles2(e_forward, e_up);
1305     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1306                 e.angles = AnglesTransform_ToVAngles(e.angles);
1307         else
1308                 e.angles = AnglesTransform_ToAngles(e.angles);
1309
1310     setattachment(e, to, tag);
1311     setorigin(e, e.origin);
1312 }
1313
1314 void detach_sameorigin(entity e)
1315 {
1316     vector org;
1317     org = gettaginfo(e, 0);
1318     e.angles = fixedvectoangles2(v_forward, v_up);
1319     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1320                 e.angles = AnglesTransform_ToVAngles(e.angles);
1321         else
1322                 e.angles = AnglesTransform_ToAngles(e.angles);
1323     setorigin(e, org);
1324     setattachment(e, world, "");
1325     setorigin(e, e.origin);
1326 }
1327
1328 void follow_sameorigin(entity e, entity to)
1329 {
1330     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1331     e.aiment = to; // make the hole follow bmodel
1332     e.punchangle = to.angles; // the original angles of bmodel
1333     e.view_ofs = e.origin - to.origin; // relative origin
1334     e.v_angle = e.angles - to.angles; // relative angles
1335 }
1336
1337 void unfollow_sameorigin(entity e)
1338 {
1339     e.movetype = MOVETYPE_NONE;
1340 }
1341
1342 entity gettaginfo_relative_ent;
1343 vector gettaginfo_relative(entity e, float tag)
1344 {
1345     if (!gettaginfo_relative_ent)
1346     {
1347         gettaginfo_relative_ent = spawn();
1348         gettaginfo_relative_ent.effects = EF_NODRAW;
1349     }
1350     gettaginfo_relative_ent.model = e.model;
1351     gettaginfo_relative_ent.modelindex = e.modelindex;
1352     gettaginfo_relative_ent.frame = e.frame;
1353     return gettaginfo(gettaginfo_relative_ent, tag);
1354 }
1355
1356 .string aiment_classname;
1357 .float aiment_deadflag;
1358 void SetMovetypeFollow(entity ent, entity e)
1359 {
1360         // FIXME this may not be warpzone aware
1361         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1362         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1363         ent.aiment = e; // make the hole follow bmodel
1364         ent.punchangle = e.angles; // the original angles of bmodel
1365         ent.view_ofs = ent.origin - e.origin; // relative origin
1366         ent.v_angle = ent.angles - e.angles; // relative angles
1367         ent.aiment_classname = strzone(e.classname);
1368         ent.aiment_deadflag = e.deadflag;
1369 }
1370 void UnsetMovetypeFollow(entity ent)
1371 {
1372         ent.movetype = MOVETYPE_FLY;
1373         PROJECTILE_MAKETRIGGER(ent);
1374         ent.aiment = world;
1375 }
1376 float LostMovetypeFollow(entity ent)
1377 {
1378 /*
1379         if(ent.movetype != MOVETYPE_FOLLOW)
1380                 if(ent.aiment)
1381                         error("???");
1382 */
1383         if(ent.aiment)
1384         {
1385                 if(ent.aiment.classname != ent.aiment_classname)
1386                         return 1;
1387                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1388                         return 1;
1389         }
1390         return 0;
1391 }
1392
1393 float isPushable(entity e)
1394 {
1395         if(e.pushable)
1396                 return true;
1397         if(IS_VEHICLE(e))
1398                 return false;
1399         if(e.iscreature)
1400                 return true;
1401         switch(e.classname)
1402         {
1403                 case "body":
1404                 case "droppedweapon":
1405                 case "keepawayball":
1406                 case "nexball_basketball":
1407                 case "nexball_football":
1408                         return true;
1409                 case "bullet": // antilagged bullets can't hit this either
1410                         return false;
1411         }
1412         if (e.projectiledeathtype)
1413                 return true;
1414         return false;
1415 }