qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 float g_weaponarena_random;
 744 float g_weaponarena_random_with_laser;
 745 string g_weaponarena_list;
 746 float g_weaponspeedfactor;
 747 float g_weaponratefactor;
 748 float g_weapondamagefactor;
 749 float g_weaponforcefactor;
 750 float g_weaponspreadfactor;
 751
 752 float start_weapons;
 753 float start_items;
 754 float start_ammo_shells;
 755 float start_ammo_nails;
 756 float start_ammo_rockets;
 757 float start_ammo_cells;
 758 float start_ammo_fuel;
 759 float start_health;
 760 float start_armorvalue;
 761 float warmup_start_weapons;
 762 float warmup_start_ammo_shells;
 763 float warmup_start_ammo_nails;
 764 float warmup_start_ammo_rockets;
 765 float warmup_start_ammo_cells;
 766 float warmup_start_ammo_fuel;
 767 float warmup_start_health;
 768 float warmup_start_armorvalue;
 769 float g_weapon_stay;
 770 float g_ghost_items;
 771
 772 entity get_weaponinfo(float w);
 773
 774 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 775 {
 776         var float i = weaponinfo.weapon;
 777
 778         if (!i)
 779                 return 0;
 780
 781         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 782
 783         if (t < 0) // "default" weapon selection
 784         {
 785                 if (g_lms || g_ca || allguns)
 786                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 787                 else if(t < -1)
 788                         t = 0;
 789                 else if (g_cts)
 790                         t = (i == WEP_SHOTGUN);
 791                 else if (g_nexball)
 792                         t = 0; // weapon is set a few lines later
 793                 else
 794                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 795                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 796                         t |= (i == WEP_HOOK);
 797         }
 798
 799         // we cannot disable porto in Nexball, we must force it
 800         if(g_nexball && i == WEP_PORTO)
 801                 t = 1;
 802
 803         return t;
 804 }
 805
 806 void readplayerstartcvars()
 807 {
 808         entity e;
 809         float i, j, t;
 810         string s;
 811
 812         // initialize starting values for players
 813         start_weapons = 0;
 814         start_items = 0;
 815         start_ammo_shells = 0;
 816         start_ammo_nails = 0;
 817         start_ammo_rockets = 0;
 818         start_ammo_cells = 0;
 819         start_health = cvar("g_balance_health_start");
 820         start_armorvalue = cvar("g_balance_armor_start");
 821
 822         g_weaponarena = 0;
 823         s = cvar_string("g_weaponarena");
 824         if (s == "0" || s == "")
 825         {
 826                 if(g_lms || g_ca)
 827                         s = "most";
 828         }
 829
 830         if (s == "0" || s == "")
 831         {
 832                 // no arena
 833         }
 834         else if (s == "off")
 835         {
 836                 // forcibly turn off weaponarena
 837         }
 838         else if (s == "all")
 839         {
 840                 g_weaponarena_list = "All Weapons";
 841                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 842                 {
 843                         e = get_weaponinfo(j);
 844                         g_weaponarena |= e.weapons;
 845                         weapon_action(e.weapon, WR_PRECACHE);
 846                 }
 847         }
 848         else if (s == "most")
 849         {
 850                 g_weaponarena_list = "Most Weapons";
 851                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 852                 {
 853                         e = get_weaponinfo(j);
 854                         if (e.spawnflags & WEP_FLAG_NORMAL)
 855                         {
 856                                 g_weaponarena |= e.weapons;
 857                                 weapon_action(e.weapon, WR_PRECACHE);
 858                         }
 859                 }
 860         }
 861         else if (s == "none")
 862         {
 863                 g_weaponarena_list = "No Weapons";
 864                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 865         }
 866         else
 867         {
 868                 t = tokenize_console(s);
 869                 g_weaponarena_list = "";
 870                 for (i = 0; i < t; ++i)
 871                 {
 872                         s = argv(i);
 873                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 874                         {
 875                                 e = get_weaponinfo(j);
 876                                 if (e.netname == s)
 877                                 {
 878                                         g_weaponarena |= e.weapons;
 879                                         weapon_action(e.weapon, WR_PRECACHE);
 880                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 881                                         break;
 882                                 }
 883                         }
 884                         if (j > WEP_LAST)
 885                         {
 886                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 887                         }
 888                 }
 889                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 890         }
 891
 892         if(g_weaponarena)
 893                 g_weaponarena_random = cvar("g_weaponarena_random");
 894         else
 895                 g_weaponarena_random = 0;
 896         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 897
 898         if (g_weaponarena)
 899         {
 900                 start_weapons = g_weaponarena;
 901                 if(!(g_lms || g_ca))
 902                         start_items |= IT_UNLIMITED_AMMO;
 903         }
 904         else if (g_minstagib)
 905         {
 906                 start_health = 100;
 907                 start_armorvalue = 0;
 908                 start_weapons = WEPBIT_MINSTANEX;
 909                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 910                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 911
 912                 if (g_minstagib_invis_alpha <= 0)
 913                         g_minstagib_invis_alpha = -1;
 914         }
 915         else
 916         {
 917                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 918                 {
 919                         e = get_weaponinfo(i);
 920                         if(want_weapon("g_start_weapon_", e, FALSE))
 921                                 start_weapons |= e.weapons;
 922                 }
 923         }
 924
 925         if(!cvar("g_use_ammunition"))
 926                 start_items |= IT_UNLIMITED_AMMO;
 927
 928         if(g_minstagib)
 929         {
 930                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 931                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 932         }
 933         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 934         {
 935                 start_ammo_rockets = 999;
 936                 start_ammo_shells = 999;
 937                 start_ammo_cells = 999;
 938                 start_ammo_nails = 999;
 939                 start_ammo_fuel = 999;
 940         }
 941         else
 942         {
 943                 if(g_lms || g_ca)
 944                 {
 945                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 946                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 947                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 948                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 949                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 950                 }
 951                 else
 952                 {
 953                         start_ammo_shells = cvar("g_start_ammo_shells");
 954                         start_ammo_nails = cvar("g_start_ammo_nails");
 955                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 956                         start_ammo_cells = cvar("g_start_ammo_cells");
 957                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 958                 }
 959         }
 960
 961         if (g_lms || g_ca)
 962         {
 963                 start_health = cvar("g_lms_start_health");
 964                 start_armorvalue = cvar("g_lms_start_armor");
 965         }
 966
 967         if (inWarmupStage)
 968         {
 969                 warmup_start_ammo_shells = start_ammo_shells;
 970                 warmup_start_ammo_nails = start_ammo_nails;
 971                 warmup_start_ammo_rockets = start_ammo_rockets;
 972                 warmup_start_ammo_cells = start_ammo_cells;
 973                 warmup_start_ammo_fuel = start_ammo_fuel;
 974                 warmup_start_health = start_health;
 975                 warmup_start_armorvalue = start_armorvalue;
 976                 warmup_start_weapons = start_weapons;
 977
 978                 if (!g_weaponarena && !g_minstagib && !g_ca)
 979                 {
 980                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 981                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 982                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 983                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 984                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 985                         warmup_start_health = cvar("g_warmup_start_health");
 986                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 987                         warmup_start_weapons = 0;
 988                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 989                         {
 990                                 e = get_weaponinfo(i);
 991                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 992                                         warmup_start_weapons |= e.weapons;
 993                         }
 994                 }
 995         }
 996
 997         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
 998         {
 999                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1000                 start_items |= IT_FUEL_REGEN;
1001                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1002                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1003         }
1004
1005         if (g_jetpack)
1006                 start_items |= IT_JETPACK;
1007
1008         if (g_weapon_stay == 2)
1009         {
1010                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1011                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1012                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1013                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1014                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1015                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1016                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1017                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1018                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1019                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1020         }
1021
1022         MUTATOR_CALLHOOK(SetStartItems);
1023
1024         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1025         {
1026                 e = get_weaponinfo(i);
1027                 if(e.weapons & (start_weapons | warmup_start_weapons))
1028                         weapon_action(e.weapon, WR_PRECACHE);
1029         }
1030
1031         start_ammo_shells = max(0, start_ammo_shells);
1032         start_ammo_nails = max(0, start_ammo_nails);
1033         start_ammo_cells = max(0, start_ammo_cells);
1034         start_ammo_rockets = max(0, start_ammo_rockets);
1035         start_ammo_fuel = max(0, start_ammo_fuel);
1036
1037         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1038         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1039         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1040         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1041         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1042 }
1043
1044 float g_bugrigs;
1045 float g_bugrigs_planar_movement;
1046 float g_bugrigs_planar_movement_car_jumping;
1047 float g_bugrigs_reverse_spinning;
1048 float g_bugrigs_reverse_speeding;
1049 float g_bugrigs_reverse_stopping;
1050 float g_bugrigs_air_steering;
1051 float g_bugrigs_angle_smoothing;
1052 float g_bugrigs_friction_floor;
1053 float g_bugrigs_friction_brake;
1054 float g_bugrigs_friction_air;
1055 float g_bugrigs_accel;
1056 float g_bugrigs_speed_ref;
1057 float g_bugrigs_speed_pow;
1058 float g_bugrigs_steer;
1059
1060 float g_touchexplode;
1061 float g_touchexplode_radius;
1062 float g_touchexplode_damage;
1063 float g_touchexplode_edgedamage;
1064 float g_touchexplode_force;
1065
1066 float sv_autotaunt;
1067 float sv_taunt;
1068
1069 float sv_pitch_min;
1070 float sv_pitch_max;
1071 float sv_pitch_fixyaw;
1072
1073 string GetGametype(); // g_world.qc
1074 void readlevelcvars(void)
1075 {
1076         // first load all the mutators
1077         if(cvar("g_invincible_projectiles"))
1078                 MUTATOR_ADD(mutator_invincibleprojectiles);
1079         if(cvar("g_nix"))
1080                 MUTATOR_ADD(mutator_nix);
1081         if(cvar("g_dodging"))
1082                 MUTATOR_ADD(mutator_dodging);
1083         if(cvar("g_rocket_flying"))
1084                 MUTATOR_ADD(mutator_rocketflying);
1085         if(cvar("g_vampire"))
1086                 MUTATOR_ADD(mutator_vampire);
1087         if(cvar("g_spawn_near_teammate"))
1088                 MUTATOR_ADD(mutator_spawn_near_teammate);
1089
1090         // is this a mutator? is this a mode?
1091         if(cvar("g_sandbox"))
1092                 MUTATOR_ADD(sandbox);
1093
1094         if(cvar("sv_allow_fullbright"))
1095                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1096
1097     g_bugrigs = cvar("g_bugrigs");
1098     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1099     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1100     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1101     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1102     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1103     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1104     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1105     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1106     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1107     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1108     g_bugrigs_accel = cvar("g_bugrigs_accel");
1109     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1110     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1111     g_bugrigs_steer = cvar("g_bugrigs_steer");
1112
1113     g_touchexplode = cvar("g_touchexplode");
1114     g_touchexplode_radius = cvar("g_touchexplode_radius");
1115     g_touchexplode_damage = cvar("g_touchexplode_damage");
1116     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1117     g_touchexplode_force = cvar("g_touchexplode_force");
1118
1119 #ifdef ALLOW_FORCEMODELS
1120         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1121 #endif
1122
1123         sv_clones = cvar("sv_clones");
1124         sv_gentle = cvar("sv_gentle");
1125         sv_foginterval = cvar("sv_foginterval");
1126         g_cloaked = cvar("g_cloaked");
1127     if(g_cts)
1128         g_cloaked = 1; // always enable cloak in CTS
1129         g_jump_grunt = cvar("g_jump_grunt");
1130         g_footsteps = cvar("g_footsteps");
1131         g_grappling_hook = cvar("g_grappling_hook");
1132         g_jetpack = cvar("g_jetpack");
1133         g_midair = cvar("g_midair");
1134         g_minstagib = cvar("g_minstagib");
1135         g_norecoil = cvar("g_norecoil");
1136         g_bloodloss = cvar("g_bloodloss");
1137         sv_maxidle = cvar("sv_maxidle");
1138         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1139         g_ctf_reverse = cvar("g_ctf_reverse");
1140         sv_autotaunt = cvar("sv_autotaunt");
1141         sv_taunt = cvar("sv_taunt");
1142
1143         inWarmupStage = cvar("g_warmup");
1144         g_warmup_limit = cvar("g_warmup_limit");
1145         g_warmup_allguns = cvar("g_warmup_allguns");
1146         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1147
1148         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1149                 inWarmupStage = 0; // these modes cannot work together, sorry
1150
1151         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1152         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1153         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1154         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1155         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1156         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1157         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1158         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1159         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1160         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1161         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1162         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1163
1164         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1165         g_weaponratefactor = cvar("g_weaponratefactor");
1166         g_weapondamagefactor = cvar("g_weapondamagefactor");
1167         g_weaponforcefactor = cvar("g_weaponforcefactor");
1168         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1169
1170         g_pickup_shells = cvar("g_pickup_shells");
1171         g_pickup_shells_max = cvar("g_pickup_shells_max");
1172         g_pickup_nails = cvar("g_pickup_nails");
1173         g_pickup_nails_max = cvar("g_pickup_nails_max");
1174         g_pickup_rockets = cvar("g_pickup_rockets");
1175         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1176         g_pickup_cells = cvar("g_pickup_cells");
1177         g_pickup_cells_max = cvar("g_pickup_cells_max");
1178         g_pickup_fuel = cvar("g_pickup_fuel");
1179         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1180         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1181         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1182         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1183         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1184         g_pickup_armormedium = cvar("g_pickup_armormedium");
1185         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1186         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1187         g_pickup_armorbig = cvar("g_pickup_armorbig");
1188         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1189         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1190         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1191         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1192         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1193         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1194         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1195         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1196         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1197         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1198         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1199         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1200         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1201         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1202         g_pickup_healthmega = cvar("g_pickup_healthmega");
1203         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1204         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1205
1206         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1207         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1208
1209         g_pinata = cvar("g_pinata");
1210
1211     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1212     if(!g_weapon_stay)
1213         g_weapon_stay = cvar("g_weapon_stay");
1214
1215         g_ghost_items = cvar("g_ghost_items");
1216
1217         if(g_ghost_items >= 1)
1218                 g_ghost_items = 0.25; // default alpha value
1219
1220         if not(inWarmupStage && !g_ca)
1221                 game_starttime = cvar("g_start_delay");
1222
1223         sv_pitch_min = cvar("sv_pitch_min");
1224         sv_pitch_max = cvar("sv_pitch_max");
1225         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1226
1227         readplayerstartcvars();
1228 }
1229
1230 //#NO AUTOCVARS END
1231
1232 // Sound functions
1233 string precache_sound (string s) = #19;
1234 float precache_sound_index (string s) = #19;
1235
1236 #define SND_VOLUME      1
1237 #define SND_ATTENUATION 2
1238 #define SND_LARGEENTITY 8
1239 #define SND_LARGESOUND  16
1240
1241 float sound_allowed(float dest, entity e)
1242 {
1243     // sounds from world may always pass
1244     for (;;)
1245     {
1246         if (e.classname == "body")
1247             e = e.enemy;
1248         else if (e.realowner && e.realowner != e)
1249             e = e.realowner;
1250         else if (e.owner && e.owner != e)
1251             e = e.owner;
1252         else
1253             break;
1254     }
1255     // sounds to self may always pass
1256     if (dest == MSG_ONE)
1257         if (e == msg_entity)
1258             return TRUE;
1259     // sounds by players can be removed
1260     if (autocvar_bot_sound_monopoly)
1261         if (clienttype(e) == CLIENTTYPE_REAL)
1262             return FALSE;
1263     // anything else may pass
1264     return TRUE;
1265 }
1266
1267 #ifdef COMPAT_XON010_CHANNELS
1268 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1269 void sound(entity e, float chan, string samp, float vol, float atten)
1270 {
1271     if (!sound_allowed(MSG_BROADCAST, e))
1272         return;
1273     builtin_sound(e, chan, samp, vol, atten);
1274 }
1275 #else
1276 #undef sound
1277 void sound(entity e, float chan, string samp, float vol, float atten)
1278 {
1279     if (!sound_allowed(MSG_BROADCAST, e))
1280         return;
1281     sound7(e, chan, samp, vol, atten, 0, 0);
1282 }
1283 #endif
1284
1285 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1286 {
1287     float entno, idx;
1288
1289     if (!sound_allowed(dest, e))
1290         return;
1291
1292     entno = num_for_edict(e);
1293     idx = precache_sound_index(samp);
1294
1295     float sflags;
1296     sflags = 0;
1297
1298     atten = floor(atten * 64);
1299     vol = floor(vol * 255);
1300
1301     if (vol != 255)
1302         sflags |= SND_VOLUME;
1303     if (atten != 64)
1304         sflags |= SND_ATTENUATION;
1305     if (entno >= 8192 || chan < 0 || chan > 7)
1306         sflags |= SND_LARGEENTITY;
1307     if (idx >= 256)
1308         sflags |= SND_LARGESOUND;
1309
1310     WriteByte(dest, SVC_SOUND);
1311     WriteByte(dest, sflags);
1312     if (sflags & SND_VOLUME)
1313         WriteByte(dest, vol);
1314     if (sflags & SND_ATTENUATION)
1315         WriteByte(dest, atten);
1316     if (sflags & SND_LARGEENTITY)
1317     {
1318         WriteShort(dest, entno);
1319         WriteByte(dest, chan);
1320     }
1321     else
1322     {
1323         WriteShort(dest, entno * 8 + chan);
1324     }
1325     if (sflags & SND_LARGESOUND)
1326         WriteShort(dest, idx);
1327     else
1328         WriteByte(dest, idx);
1329
1330     WriteCoord(dest, o_x);
1331     WriteCoord(dest, o_y);
1332     WriteCoord(dest, o_z);
1333 }
1334 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1335 {
1336     vector o;
1337
1338     if (!sound_allowed(dest, e))
1339         return;
1340
1341     o = e.origin + 0.5 * (e.mins + e.maxs);
1342     soundtoat(dest, e, o, chan, samp, vol, atten);
1343 }
1344 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1345 {
1346     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1347 }
1348 void stopsoundto(float dest, entity e, float chan)
1349 {
1350     float entno;
1351
1352     if (!sound_allowed(dest, e))
1353         return;
1354
1355     entno = num_for_edict(e);
1356
1357     if (entno >= 8192 || chan < 0 || chan > 7)
1358     {
1359         float idx, sflags;
1360         idx = precache_sound_index("misc/null.wav");
1361         sflags = SND_LARGEENTITY;
1362         if (idx >= 256)
1363             sflags |= SND_LARGESOUND;
1364         WriteByte(dest, SVC_SOUND);
1365         WriteByte(dest, sflags);
1366         WriteShort(dest, entno);
1367         WriteByte(dest, chan);
1368         if (sflags & SND_LARGESOUND)
1369             WriteShort(dest, idx);
1370         else
1371             WriteByte(dest, idx);
1372         WriteCoord(dest, e.origin_x);
1373         WriteCoord(dest, e.origin_y);
1374         WriteCoord(dest, e.origin_z);
1375     }
1376     else
1377     {
1378         WriteByte(dest, SVC_STOPSOUND);
1379         WriteShort(dest, entno * 8 + chan);
1380     }
1381 }
1382 void stopsound(entity e, float chan)
1383 {
1384     if (!sound_allowed(MSG_BROADCAST, e))
1385         return;
1386
1387     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1388     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1389 }
1390
1391 void play2(entity e, string filename)
1392 {
1393     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1394     msg_entity = e;
1395     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1396 }
1397
1398 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1399 .float spamtime;
1400 float spamsound(entity e, float chan, string samp, float vol, float atten)
1401 {
1402     if (!sound_allowed(MSG_BROADCAST, e))
1403         return FALSE;
1404
1405     if (time > e.spamtime)
1406     {
1407         e.spamtime = time;
1408         sound(e, chan, samp, vol, atten);
1409         return TRUE;
1410     }
1411     return FALSE;
1412 }
1413
1414 void play2team(float t, string filename)
1415 {
1416     entity head;
1417
1418     if (autocvar_bot_sound_monopoly)
1419         return;
1420
1421     FOR_EACH_REALPLAYER(head)
1422     {
1423         if (head.team == t)
1424             play2(head, filename);
1425     }
1426 }
1427
1428 void play2all(string samp)
1429 {
1430     if (autocvar_bot_sound_monopoly)
1431         return;
1432
1433     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1434 }
1435
1436 void PrecachePlayerSounds(string f);
1437 void precache_playermodel(string m)
1438 {
1439         float globhandle, i, n;
1440         string f;
1441
1442         if(substring(m, -9,5) == "_lod1")
1443                 return;
1444         if(substring(m, -9,5) == "_lod2")
1445                 return;
1446         precache_model(m);
1447         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1448         if(fexists(f))
1449                 precache_model(f);
1450         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1451         if(fexists(f))
1452                 precache_model(f);
1453
1454         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1455         if (globhandle < 0)
1456                 return;
1457         n = search_getsize(globhandle);
1458         for (i = 0; i < n; ++i)
1459         {
1460                 //print(search_getfilename(globhandle, i), "\n");
1461                 f = search_getfilename(globhandle, i);
1462                 PrecachePlayerSounds(f);
1463         }
1464         search_end(globhandle);
1465 }
1466 void precache_all_playermodels(string pattern)
1467 {
1468         float globhandle, i, n;
1469         string f;
1470
1471         globhandle = search_begin(pattern, TRUE, FALSE);
1472         if (globhandle < 0)
1473                 return;
1474         n = search_getsize(globhandle);
1475         for (i = 0; i < n; ++i)
1476         {
1477                 //print(search_getfilename(globhandle, i), "\n");
1478                 f = search_getfilename(globhandle, i);
1479                 precache_playermodel(f);
1480         }
1481         search_end(globhandle);
1482 }
1483
1484 void precache()
1485 {
1486     // gamemode related things
1487     precache_model ("models/misc/chatbubble.spr");
1488     if (g_runematch)
1489     {
1490         precache_model ("models/runematch/curse.mdl");
1491         precache_model ("models/runematch/rune.mdl");
1492     }
1493
1494 #ifdef TTURRETS_ENABLED
1495     if (autocvar_g_turrets)
1496         turrets_precash();
1497 #endif
1498
1499     // Precache all player models if desired
1500     if (autocvar_sv_precacheplayermodels)
1501     {
1502         PrecachePlayerSounds("sound/player/default.sounds");
1503         precache_all_playermodels("models/player/*.zym");
1504         precache_all_playermodels("models/player/*.dpm");
1505         precache_all_playermodels("models/player/*.md3");
1506         precache_all_playermodels("models/player/*.psk");
1507         precache_all_playermodels("models/player/*.iqm");
1508     }
1509
1510     if (autocvar_sv_defaultcharacter)
1511     {
1512         string s;
1513         s = autocvar_sv_defaultplayermodel_red;
1514         if (s != "")
1515             precache_playermodel(s);
1516         s = autocvar_sv_defaultplayermodel_blue;
1517         if (s != "")
1518             precache_playermodel(s);
1519         s = autocvar_sv_defaultplayermodel_yellow;
1520         if (s != "")
1521             precache_playermodel(s);
1522         s = autocvar_sv_defaultplayermodel_pink;
1523         if (s != "")
1524             precache_playermodel(s);
1525         s = autocvar_sv_defaultplayermodel;
1526         if (s != "")
1527             precache_playermodel(s);
1528     }
1529
1530     if (g_footsteps)
1531     {
1532         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1533         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1534     }
1535
1536     // gore and miscellaneous sounds
1537     //precache_sound ("misc/h2ohit.wav");
1538     precache_model ("models/hook.md3");
1539     precache_sound ("misc/armorimpact.wav");
1540     precache_sound ("misc/bodyimpact1.wav");
1541     precache_sound ("misc/bodyimpact2.wav");
1542     precache_sound ("misc/gib.wav");
1543     precache_sound ("misc/gib_splat01.wav");
1544     precache_sound ("misc/gib_splat02.wav");
1545     precache_sound ("misc/gib_splat03.wav");
1546     precache_sound ("misc/gib_splat04.wav");
1547     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1548     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1549     precache_sound ("misc/null.wav");
1550     precache_sound ("misc/spawn.wav");
1551     precache_sound ("misc/talk.wav");
1552     precache_sound ("misc/teleport.wav");
1553     precache_sound ("misc/poweroff.wav");
1554     precache_sound ("player/lava.wav");
1555     precache_sound ("player/slime.wav");
1556
1557     if (g_jetpack)
1558         precache_sound ("misc/jetpack_fly.wav");
1559
1560     precache_model ("models/sprites/0.spr32");
1561     precache_model ("models/sprites/1.spr32");
1562     precache_model ("models/sprites/2.spr32");
1563     precache_model ("models/sprites/3.spr32");
1564     precache_model ("models/sprites/4.spr32");
1565     precache_model ("models/sprites/5.spr32");
1566     precache_model ("models/sprites/6.spr32");
1567     precache_model ("models/sprites/7.spr32");
1568     precache_model ("models/sprites/8.spr32");
1569     precache_model ("models/sprites/9.spr32");
1570     precache_model ("models/sprites/10.spr32");
1571
1572     // common weapon precaches
1573         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1574     precache_sound ("weapons/weapon_switch.wav");
1575     precache_sound ("weapons/weaponpickup.wav");
1576     precache_sound ("weapons/unavailable.wav");
1577     precache_sound ("weapons/dryfire.wav");
1578     if (g_grappling_hook)
1579     {
1580         precache_sound ("weapons/hook_fire.wav"); // hook
1581         precache_sound ("weapons/hook_impact.wav"); // hook
1582     }
1583
1584     if(autocvar_sv_precacheweapons)
1585     {
1586         //precache weapon models/sounds
1587         float wep;
1588         wep = WEP_FIRST;
1589         while (wep <= WEP_LAST)
1590         {
1591             weapon_action(wep, WR_PRECACHE);
1592             wep = wep + 1;
1593         }
1594     }
1595
1596     precache_model("models/elaser.mdl");
1597     precache_model("models/laser.mdl");
1598     precache_model("models/ebomb.mdl");
1599
1600 #if 0
1601     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1602
1603     if (!self.noise && self.music) // quake 3 uses the music field
1604         self.noise = self.music;
1605
1606     // plays music for the level if there is any
1607     if (self.noise)
1608     {
1609         precache_sound (self.noise);
1610         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1611     }
1612 #endif
1613 }
1614
1615 // sorry, but using \ in macros breaks line numbers
1616 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1617 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1618 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1619
1620
1621 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1622 {
1623         if (clienttype(e) == CLIENTTYPE_REAL)
1624         {
1625                 msg_entity = e;
1626                 WRITESPECTATABLE_MSG_ONE({
1627                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1628                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1629                         WriteByte(MSG_ONE, id);
1630                         WriteString(MSG_ONE, s);
1631                         if (id != 0 && s != "")
1632                         {
1633                                 WriteByte(MSG_ONE, duration);
1634                                 WriteByte(MSG_ONE, countdown_num);
1635                         }
1636                 });
1637         }
1638 }
1639 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1640 {
1641         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1642 }
1643 // WARNING: this kills the trace globals
1644 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1645 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1646
1647 #define INITPRIO_FIRST              0
1648 #define INITPRIO_GAMETYPE           0
1649 #define INITPRIO_GAMETYPE_FALLBACK  1
1650 #define INITPRIO_FINDTARGET        10
1651 #define INITPRIO_DROPTOFLOOR       20
1652 #define INITPRIO_SETLOCATION       90
1653 #define INITPRIO_LINKDOORS         91
1654 #define INITPRIO_LAST              99
1655
1656 .void(void) initialize_entity;
1657 .float initialize_entity_order;
1658 .entity initialize_entity_next;
1659 entity initialize_entity_first;
1660
1661 void make_safe_for_remove(entity e)
1662 {
1663     if (e.initialize_entity)
1664     {
1665         entity ent, prev;
1666         for (ent = initialize_entity_first; ent; )
1667         {
1668             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1669             {
1670                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1671                 // skip it in linked list
1672                 if (prev)
1673                 {
1674                     prev.initialize_entity_next = ent.initialize_entity_next;
1675                     ent = prev.initialize_entity_next;
1676                 }
1677                 else
1678                 {
1679                     initialize_entity_first = ent.initialize_entity_next;
1680                     ent = initialize_entity_first;
1681                 }
1682             }
1683             else
1684             {
1685                 prev = ent;
1686                 ent = ent.initialize_entity_next;
1687             }
1688         }
1689     }
1690 }
1691
1692 void objerror(string s)
1693 {
1694     make_safe_for_remove(self);
1695     builtin_objerror(s);
1696 }
1697
1698 .float remove_except_protected_forbidden;
1699 void remove_except_protected(entity e)
1700 {
1701         if(e.remove_except_protected_forbidden)
1702                 error("not allowed to remove this at this point");
1703         builtin_remove(e);
1704 }
1705
1706 void remove_unsafely(entity e)
1707 {
1708     if(e.classname == "spike")
1709         error("Removing spikes is forbidden (crylink bug), please report");
1710     builtin_remove(e);
1711 }
1712
1713 void remove_safely(entity e)
1714 {
1715     make_safe_for_remove(e);
1716     builtin_remove(e);
1717 }
1718
1719 void InitializeEntity(entity e, void(void) func, float order)
1720 {
1721     entity prev, cur;
1722
1723     if (!e || e.initialize_entity)
1724     {
1725         // make a proxy initializer entity
1726         entity e_old;
1727         e_old = e;
1728         e = spawn();
1729         e.classname = "initialize_entity";
1730         e.enemy = e_old;
1731     }
1732
1733     e.initialize_entity = func;
1734     e.initialize_entity_order = order;
1735
1736     cur = initialize_entity_first;
1737     for (;;)
1738     {
1739         if (!cur || cur.initialize_entity_order > order)
1740         {
1741             // insert between prev and cur
1742             if (prev)
1743                 prev.initialize_entity_next = e;
1744             else
1745                 initialize_entity_first = e;
1746             e.initialize_entity_next = cur;
1747             return;
1748         }
1749         prev = cur;
1750         cur = cur.initialize_entity_next;
1751     }
1752 }
1753 void InitializeEntitiesRun()
1754 {
1755     entity startoflist;
1756     startoflist = initialize_entity_first;
1757     initialize_entity_first = world;
1758     remove = remove_except_protected;
1759     for (self = startoflist; self; self = self.initialize_entity_next)
1760     {
1761         self.remove_except_protected_forbidden = 1;
1762     }
1763     for (self = startoflist; self; )
1764     {
1765         entity e;
1766         var void(void) func;
1767         e = self.initialize_entity_next;
1768         func = self.initialize_entity;
1769         self.initialize_entity_order = 0;
1770         self.initialize_entity = func_null;
1771         self.initialize_entity_next = world;
1772         self.remove_except_protected_forbidden = 0;
1773         if (self.classname == "initialize_entity")
1774         {
1775             entity e_old;
1776             e_old = self.enemy;
1777             builtin_remove(self);
1778             self = e_old;
1779         }
1780         //dprint("Delayed initialization: ", self.classname, "\n");
1781         if(func != func_null)
1782             func();
1783         else
1784         {
1785             eprint(self);
1786             backtrace(strcat("Null function in: ", self.classname, "\n"));
1787         }
1788         self = e;
1789     }
1790     remove = remove_unsafely;
1791 }
1792
1793 .float uncustomizeentityforclient_set;
1794 .void(void) uncustomizeentityforclient;
1795 void(void) SUB_Nullpointer = #0;
1796 void UncustomizeEntitiesRun()
1797 {
1798     entity oldself;
1799     oldself = self;
1800     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1801         self.uncustomizeentityforclient();
1802     self = oldself;
1803 }
1804 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1805 {
1806     e.customizeentityforclient = customizer;
1807     e.uncustomizeentityforclient = uncustomizer;
1808     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1809 }
1810
1811 .float nottargeted;
1812 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1813
1814 void() SUB_Remove;
1815 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1816 {
1817     vector mi, ma;
1818
1819     if (e.classname == "")
1820         e.classname = "net_linked";
1821
1822     if (e.model == "" || self.modelindex == 0)
1823     {
1824         mi = e.mins;
1825         ma = e.maxs;
1826         setmodel(e, "null");
1827         setsize(e, mi, ma);
1828     }
1829
1830     e.SendEntity = sendfunc;
1831     e.SendFlags = 0xFFFFFF;
1832
1833     if (!docull)
1834         e.effects |= EF_NODEPTHTEST;
1835
1836     if (dt)
1837     {
1838         e.nextthink = time + dt;
1839         e.think = SUB_Remove;
1840     }
1841 }
1842
1843 void adaptor_think2touch()
1844 {
1845     entity o;
1846     o = other;
1847     other = world;
1848     self.touch();
1849     other = o;
1850 }
1851
1852 void adaptor_think2use()
1853 {
1854     entity o, a;
1855     o = other;
1856     a = activator;
1857     activator = world;
1858     other = world;
1859     self.use();
1860     other = o;
1861     activator = a;
1862 }
1863
1864 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1865 {
1866         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1867                 self.projectiledeathtype |= HITTYPE_SPLASH;
1868         adaptor_think2use();
1869 }
1870
1871 // deferred dropping
1872 void DropToFloor_Handler()
1873 {
1874     builtin_droptofloor();
1875     self.dropped_origin = self.origin;
1876 }
1877
1878 void droptofloor()
1879 {
1880     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1881 }
1882
1883
1884
1885 float trace_hits_box_a0, trace_hits_box_a1;
1886
1887 float trace_hits_box_1d(float end, float thmi, float thma)
1888 {
1889     if (end == 0)
1890     {
1891         // just check if x is in range
1892         if (0 < thmi)
1893             return FALSE;
1894         if (0 > thma)
1895             return FALSE;
1896     }
1897     else
1898     {
1899         // do the trace with respect to x
1900         // 0 -> end has to stay in thmi -> thma
1901         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1902         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1903         if (trace_hits_box_a0 > trace_hits_box_a1)
1904             return FALSE;
1905     }
1906     return TRUE;
1907 }
1908
1909 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1910 {
1911     end -= start;
1912     thmi -= start;
1913     thma -= start;
1914     // now it is a trace from 0 to end
1915
1916     trace_hits_box_a0 = 0;
1917     trace_hits_box_a1 = 1;
1918
1919     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1920         return FALSE;
1921     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1922         return FALSE;
1923     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1924         return FALSE;
1925
1926     return TRUE;
1927 }
1928
1929 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1930 {
1931     return trace_hits_box(start, end, thmi - ma, thma - mi);
1932 }
1933
1934 float SUB_NoImpactCheck()
1935 {
1936         // zero hitcontents = this is not the real impact, but either the
1937         // mirror-impact of something hitting the projectile instead of the
1938         // projectile hitting the something, or a touchareagrid one. Neither of
1939         // these stop the projectile from moving, so...
1940         if(trace_dphitcontents == 0)
1941         {
1942                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1943                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1944                 checkclient();
1945         }
1946     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1947         return 1;
1948     if (other == world && self.size != '0 0 0')
1949     {
1950         vector tic;
1951         tic = self.velocity * sys_frametime;
1952         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1953         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1954         if (trace_fraction >= 1)
1955         {
1956             dprint("Odd... did not hit...?\n");
1957         }
1958         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1959         {
1960             dprint("Detected and prevented the sky-grapple bug.\n");
1961             return 1;
1962         }
1963     }
1964
1965     return 0;
1966 }
1967
1968 #define SUB_OwnerCheck() (other && (other == self.owner))
1969
1970 void RemoveGrapplingHook(entity pl);
1971 void W_Crylink_Dequeue(entity e);
1972 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1973 {
1974         if(SUB_OwnerCheck())
1975                 return TRUE;
1976         if(SUB_NoImpactCheck())
1977         {
1978                 if(self.classname == "grapplinghook")
1979                         RemoveGrapplingHook(self.realowner);
1980                 else if(self.classname == "spike")
1981                 {
1982                         W_Crylink_Dequeue(self);
1983                         remove(self);
1984                 }
1985                 else
1986                         remove(self);
1987                 return TRUE;
1988         }
1989         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1990                 UpdateCSQCProjectile(self);
1991         return FALSE;
1992 }
1993 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1994
1995 float MAX_IPBAN_URIS           = 16;
1996
1997 float URI_GET_DISCARD          = 0;
1998 float URI_GET_IPBAN            = 1;
1999 float URI_GET_IPBAN_END        = 16;
2000
2001 void URI_Get_Callback(float id, float status, string data)
2002 {
2003     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2004     dprint(data);
2005     dprint("\nEnd of data.\n");
2006
2007     if(url_URI_Get_Callback(id, status, data))
2008     {
2009         // handled
2010     }
2011     else if (id == URI_GET_DISCARD)
2012     {
2013         // discard
2014     }
2015     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2016     {
2017         // online ban list
2018         OnlineBanList_URI_Get_Callback(id, status, data);
2019     }
2020     else
2021     {
2022         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2023     }
2024 }
2025
2026 void print_to(entity e, string s)
2027 {
2028     if (e)
2029         sprint(e, strcat(s, "\n"));
2030     else
2031         print(s, "\n");
2032 }
2033
2034 string uid2name(string myuid) {
2035         string s;
2036         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2037
2038         // FIXME remove this later after 0.6 release
2039         // convert old style broken records to correct style
2040         if(s == "")
2041         {
2042                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2043                 if(s != "")
2044                 {
2045                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2046                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2047                 }
2048         }
2049
2050         if(s == "")
2051                 s = "^1Unregistered Player";
2052         return s;
2053 }
2054
2055 float race_readTime(string map, float pos)
2056 {
2057         string rr;
2058         if(g_cts)
2059                 rr = CTS_RECORD;
2060         else
2061                 rr = RACE_RECORD;
2062
2063         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2064 }
2065
2066 string race_readUID(string map, float pos)
2067 {
2068         string rr;
2069         if(g_cts)
2070                 rr = CTS_RECORD;
2071         else
2072                 rr = RACE_RECORD;
2073
2074         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2075 }
2076
2077 float race_readPos(string map, float t) {
2078         float i;
2079         for (i = 1; i <= RANKINGS_CNT; ++i)
2080                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2081                         return i;
2082
2083         return 0; // pos is zero if unranked
2084 }
2085
2086 void race_writeTime(string map, float t, string myuid)
2087 {
2088         string rr;
2089         if(g_cts)
2090                 rr = CTS_RECORD;
2091         else
2092                 rr = RACE_RECORD;
2093
2094         float newpos;
2095         newpos = race_readPos(map, t);
2096
2097         float i, prevpos;
2098         for(i = 1; i <= RANKINGS_CNT; ++i)
2099         {
2100                 if(race_readUID(map, i) == myuid)
2101                         prevpos = i;
2102         }
2103         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2104                 for (i = prevpos; i > newpos; --i) {
2105                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2106                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2107                 }
2108         } else { // player has no ranked record yet
2109                 for (i = RANKINGS_CNT; i > newpos; --i) {
2110                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2111                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2112                 }
2113         }
2114
2115         // store new time itself
2116         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2117         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2118 }
2119
2120 string race_readName(string map, float pos)
2121 {
2122         string rr;
2123         if(g_cts)
2124                 rr = CTS_RECORD;
2125         else
2126                 rr = RACE_RECORD;
2127
2128         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2129 }
2130
2131 string race_placeName(float pos) {
2132         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2133         {
2134                 if(mod(pos, 10) == 1)
2135                         return strcat(ftos(pos), "st");
2136                 else if(mod(pos, 10) == 2)
2137                         return strcat(ftos(pos), "nd");
2138                 else if(mod(pos, 10) == 3)
2139                         return strcat(ftos(pos), "rd");
2140                 else
2141                         return strcat(ftos(pos), "th");
2142         }
2143         else
2144                 return strcat(ftos(pos), "th");
2145 }
2146 string getrecords(float page) // 50 records per page
2147 {
2148     float rec;
2149     string h;
2150     float r;
2151     float i;
2152     string s;
2153
2154     rec = 0;
2155
2156     s = "";
2157
2158     if (g_ctf)
2159     {
2160         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2161         {
2162             if (MapInfo_Get_ByID(i))
2163             {
2164                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2165                 if (r == 0)
2166                     continue;
2167                 // TODO: uid2name
2168                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2169                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2170                 ++rec;
2171             }
2172         }
2173     }
2174
2175     if (g_race)
2176     {
2177         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2178         {
2179             if (MapInfo_Get_ByID(i))
2180             {
2181                 r = race_readTime(MapInfo_Map_bspname, 1);
2182                 if (r == 0)
2183                     continue;
2184                 h = race_readName(MapInfo_Map_bspname, 1);
2185                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2186                 ++rec;
2187             }
2188         }
2189     }
2190
2191     if (g_cts)
2192     {
2193         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2194         {
2195             if (MapInfo_Get_ByID(i))
2196             {
2197                 r = race_readTime(MapInfo_Map_bspname, 1);
2198                 if (r == 0)
2199                     continue;
2200                 h = race_readName(MapInfo_Map_bspname, 1);
2201                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2202                 ++rec;
2203             }
2204         }
2205     }
2206
2207     MapInfo_ClearTemps();
2208
2209     if (s == "" && page == 0)
2210         return "No records are available on this server.\n";
2211     else
2212         return s;
2213 }
2214
2215 string getrankings()
2216 {
2217     string n;
2218     float t;
2219     float i;
2220     string s;
2221     string p;
2222     string map;
2223
2224     s = "";
2225
2226     map = GetMapname();
2227
2228     for (i = 1; i <= RANKINGS_CNT; ++i)
2229     {
2230         t = race_readTime(map, i);
2231         if (t == 0)
2232             continue;
2233         n = race_readName(map, i);
2234         p = race_placeName(i);
2235         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2236     }
2237
2238     MapInfo_ClearTemps();
2239
2240     if (s == "")
2241         return strcat("No records are available for the map: ", map, "\n");
2242     else
2243         return strcat("Records for ", map, ":\n", s);
2244 }
2245
2246 #define LADDER_FIRSTPOINT 100
2247 #define LADDER_CNT 10
2248         // position X still gives LADDER_FIRSTPOINT/X points
2249 #define LADDER_SIZE 30
2250         // ladder shows the top X players
2251 string top_uids[LADDER_SIZE];
2252 float top_scores[LADDER_SIZE];
2253 string getladder()
2254 {
2255     float i, j, k, uidcnt;
2256     string s, temp_s;
2257
2258     s = "";
2259     temp_s = "";
2260
2261     string rr;
2262     if(g_cts)
2263         rr = CTS_RECORD;
2264     else
2265         rr = RACE_RECORD;
2266
2267     string myuid;
2268
2269     for (k = 0; k < MapInfo_count; ++k)
2270     {
2271         if (MapInfo_Get_ByID(k))
2272         {
2273                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2274                         if(i == 0) // speed award
2275                         {
2276                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2277                                         continue;
2278
2279                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2280                         }
2281                         else // normal record, if it exists (else break)
2282                         {
2283                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2284                                         continue;
2285
2286                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2287                         }
2288
2289                         // string s contains:
2290                         // arg 0 = # of speed recs
2291                         // arg 1 = # of 1st place recs
2292                         // arg 2 = # of 2nd place recs
2293                         // ... etc
2294                         // LADDER_CNT+1 = total points
2295
2296                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2297                         if (temp_s == "")
2298                         {
2299                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2300                             ++uidcnt;
2301                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2302                             {
2303                                 if(j != LADDER_CNT + 1)
2304                                     temp_s = strcat(temp_s, "0 ");
2305                                 else
2306                                     temp_s = strcat(temp_s, "0");
2307                             }
2308                         }
2309
2310                         tokenize_console(temp_s);
2311                         s = "";
2312
2313                         if(i == 0) // speed award
2314                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2315                             {
2316                                 if(j == 0) // speed award
2317                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2318                                 else
2319                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2320                             }
2321                         else // record
2322                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2323                             {
2324                                 if(j == 0)
2325                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2326                                 else if(j == i) // wanted rec!
2327                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2328                                 else
2329                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2330                             }
2331
2332                         // total points are (by default) calculated like this:
2333                         // speedrec = floor(100 / 10) = 10 points
2334                         // 1st place = floor(100 / 1) = 100 points
2335                         // 2nd place = floor(100 / 2) = 50 points
2336                         // 3rd place = floor(100 / 3) = 33 points
2337                         // 4th place = floor(100 / 4) = 25 points
2338                         // 5th place = floor(100 / 5) = 20 points
2339                         // ... etc
2340
2341                         if(i == 0)
2342                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2343                         else
2344                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2345
2346                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2347                 }
2348         }
2349     }
2350
2351     float thiscnt;
2352     string thisuid;
2353     for (i = 0; i <= uidcnt; ++i) // for each known uid
2354     {
2355         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2356         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2357         tokenize_console(temp_s);
2358         thiscnt = stof(argv(LADDER_CNT+1));
2359
2360         if(thiscnt > top_scores[LADDER_SIZE-1])
2361         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2362         {
2363             if(thiscnt > top_scores[j])
2364             {
2365                 for (k = LADDER_SIZE-1; k >= j; --k)
2366                 {
2367                     top_uids[k] = top_uids[k-1];
2368                     top_scores[k] = top_scores[k-1];
2369                 }
2370                 top_uids[j] = thisuid;
2371                 top_scores[j] = thiscnt;
2372                 break;
2373             }
2374         }
2375     }
2376
2377     s = "^3-----------------------\n\n";
2378
2379     s = strcat(s, "Pos ^3|");
2380     s = strcat(s, " ^7Total  ^3|");
2381     for (i = 1; i <= LADDER_CNT; ++i)
2382     {
2383         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2384     }
2385     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2386
2387     s = strcat(s, "\n^3----+--------");
2388     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2389     {
2390         s = strcat(s, "+-----");
2391     }
2392 #if LADDER_CNT > 9
2393     for (i = 1; i <= LADDER_CNT - 9; ++i)
2394     {
2395         s = strcat(s, "+------");
2396     }
2397 #endif
2398
2399     s = strcat(s, "+--------------+--------------------\n");
2400
2401     for (i = 0; i < LADDER_SIZE; ++i)
2402     {
2403         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2404         tokenize_console(temp_s);
2405         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2406             continue;
2407         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2408         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2409         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2410         {
2411             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2412         }
2413 #if LADDER_CNT > 9
2414         for (j = 10; j <= LADDER_CNT; ++j)
2415         {
2416             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2417         }
2418 #endif
2419
2420         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2421         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2422     }
2423
2424     MapInfo_ClearTemps();
2425
2426     if (s == "")
2427         return "No ladder on this server!\n";
2428     else
2429         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2430 }
2431
2432
2433 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2434 {
2435     float m, i;
2436     vector start, org, delta, end, enddown, mstart;
2437     entity sp;
2438
2439     m = e.dphitcontentsmask;
2440     e.dphitcontentsmask = goodcontents | badcontents;
2441
2442     org = world.mins;
2443     delta = world.maxs - world.mins;
2444
2445     for (i = 0; i < attempts; ++i)
2446     {
2447         start_x = org_x + random() * delta_x;
2448         start_y = org_y + random() * delta_y;
2449         start_z = org_z + random() * delta_z;
2450
2451         // rule 1: start inside world bounds, and outside
2452         // solid, and don't start from somewhere where you can
2453         // fall down to evil
2454         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2455         if (trace_fraction >= 1)
2456             continue;
2457         if (trace_startsolid)
2458             continue;
2459         if (trace_dphitcontents & badcontents)
2460             continue;
2461         if (trace_dphitq3surfaceflags & badsurfaceflags)
2462             continue;
2463
2464         // rule 2: if we are too high, lower the point
2465         if (trace_fraction * delta_z > maxaboveground)
2466             start = trace_endpos + '0 0 1' * maxaboveground;
2467         enddown = trace_endpos;
2468
2469         // rule 3: make sure we aren't outside the map. This only works
2470         // for somewhat well formed maps. A good rule of thumb is that
2471         // the map should have a convex outside hull.
2472         // these can be traceLINES as we already verified the starting box
2473         mstart = start + 0.5 * (e.mins + e.maxs);
2474         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2475         if (trace_fraction >= 1)
2476             continue;
2477         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2478         if (trace_fraction >= 1)
2479             continue;
2480         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2481         if (trace_fraction >= 1)
2482             continue;
2483         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2484         if (trace_fraction >= 1)
2485             continue;
2486         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2487         if (trace_fraction >= 1)
2488             continue;
2489
2490         // rule 4: we must "see" some spawnpoint
2491         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2492                 if(checkpvs(mstart, sp))
2493                         break;
2494         if(!sp)
2495         {
2496                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2497                         if(checkpvs(mstart, sp))
2498                                 break;
2499                 if(!sp)
2500                         continue;
2501         }
2502
2503         // find a random vector to "look at"
2504         end_x = org_x + random() * delta_x;
2505         end_y = org_y + random() * delta_y;
2506         end_z = org_z + random() * delta_z;
2507         end = start + normalize(end - start) * vlen(delta);
2508
2509         // rule 4: start TO end must not be too short
2510         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2511         if (trace_startsolid)
2512             continue;
2513         if (trace_fraction < minviewdistance / vlen(delta))
2514             continue;
2515
2516         // rule 5: don't want to look at sky
2517         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2518             continue;
2519
2520         // rule 6: we must not end up in trigger_hurt
2521         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2522             continue;
2523
2524         break;
2525     }
2526
2527     e.dphitcontentsmask = m;
2528
2529     if (i < attempts)
2530     {
2531         setorigin(e, start);
2532         e.angles = vectoangles(end - start);
2533         dprint("Needed ", ftos(i + 1), " attempts\n");
2534         return TRUE;
2535     }
2536     else
2537         return FALSE;
2538 }
2539
2540 float zcurveparticles_effectno;
2541 vector zcurveparticles_start;
2542 float zcurveparticles_spd;
2543
2544 void endzcurveparticles()
2545 {
2546         if(zcurveparticles_effectno)
2547         {
2548                 // terminator
2549                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2550         }
2551         zcurveparticles_effectno = 0;
2552 }
2553
2554 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2555 {
2556         spd = bound(0, floor(spd / 16), 32767);
2557         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2558         {
2559                 endzcurveparticles();
2560                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2561                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2562                 WriteShort(MSG_BROADCAST, effectno);
2563                 WriteCoord(MSG_BROADCAST, start_x);
2564                 WriteCoord(MSG_BROADCAST, start_y);
2565                 WriteCoord(MSG_BROADCAST, start_z);
2566                 zcurveparticles_effectno = effectno;
2567                 zcurveparticles_start = start;
2568         }
2569         else
2570                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2571         WriteCoord(MSG_BROADCAST, end_x);
2572         WriteCoord(MSG_BROADCAST, end_y);
2573         WriteCoord(MSG_BROADCAST, end_z);
2574         WriteCoord(MSG_BROADCAST, end_dz);
2575         zcurveparticles_spd = spd;
2576 }
2577
2578 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2579 {
2580         float end_dz;
2581         vector vecxy, velxy;
2582
2583         vecxy = end - start;
2584         vecxy_z = 0;
2585         velxy = vel;
2586         velxy_z = 0;
2587
2588         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2589         {
2590                 endzcurveparticles();
2591                 trailparticles(world, effectno, start, end);
2592                 return;
2593         }
2594
2595         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2596         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2597 }
2598
2599 void write_recordmarker(entity pl, float tstart, float dt)
2600 {
2601     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2602
2603     // also write a marker into demo files for demotc-race-record-extractor to find
2604     stuffcmd(pl,
2605              strcat(
2606                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2607                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2608 }
2609
2610 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2611 {
2612         switch(algn)
2613         {
2614                 default:
2615                 case 3: // right
2616                         break;
2617
2618                 case 4: // left
2619                         vecs_y = -vecs_y;
2620                         break;
2621
2622                 case 1:
2623                         if(allowcenter) // 2: allow center handedness
2624                         {
2625                                 // center
2626                                 vecs_y = 0;
2627                                 vecs_z -= 2;
2628                         }
2629                         else
2630                         {
2631                                 // right
2632                         }
2633                         break;
2634
2635                 case 2:
2636                         if(allowcenter) // 2: allow center handedness
2637                         {
2638                                 // center
2639                                 vecs_y = 0;
2640                                 vecs_z -= 2;
2641                         }
2642                         else
2643                         {
2644                                 // left
2645                                 vecs_y = -vecs_y;
2646                         }
2647                         break;
2648         }
2649         return vecs;
2650 }
2651
2652 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2653 {
2654         string s;
2655         vector v;
2656
2657         if (autocvar_g_shootfromeye)
2658         {
2659                 if (visual)
2660                 {
2661                         vecs_y = 0;
2662                         vecs_z -= 2;
2663                 }
2664                 else
2665                 {
2666                         vecs_y = 0;
2667                         vecs_z = 0;
2668                 }
2669         }
2670         else if (autocvar_g_shootfromcenter)
2671         {
2672                 vecs_y = 0;
2673                 vecs_z -= 2;
2674         }
2675         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2676         {
2677                 v = stov(s);
2678                 if (y_is_right)
2679                         v_y = -v_y;
2680                 if (v_x != 0)
2681                         vecs_x = v_x;
2682                 vecs_y = v_y;
2683                 vecs_z = v_z;
2684         }
2685         else if (autocvar_g_shootfromclient)
2686         {
2687                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2688         }
2689         return vecs;
2690 }
2691
2692 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2693 {
2694         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2695 }
2696
2697
2698 void attach_sameorigin(entity e, entity to, string tag)
2699 {
2700     vector org, t_forward, t_left, t_up, e_forward, e_up;
2701     vector org0, ang0;
2702     float tagscale;
2703
2704     ang0 = e.angles;
2705     org0 = e.origin;
2706
2707     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2708     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2709     t_forward = v_forward * tagscale;
2710     t_left = v_right * -tagscale;
2711     t_up = v_up * tagscale;
2712
2713     e.origin_x = org * t_forward;
2714     e.origin_y = org * t_left;
2715     e.origin_z = org * t_up;
2716
2717     // current forward and up directions
2718     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2719                 e.angles = AnglesTransform_FromVAngles(e.angles);
2720         else
2721                 e.angles = AnglesTransform_FromAngles(e.angles);
2722     fixedmakevectors(e.angles);
2723
2724     // untransform forward, up!
2725     e_forward_x = v_forward * t_forward;
2726     e_forward_y = v_forward * t_left;
2727     e_forward_z = v_forward * t_up;
2728     e_up_x = v_up * t_forward;
2729     e_up_y = v_up * t_left;
2730     e_up_z = v_up * t_up;
2731
2732     e.angles = fixedvectoangles2(e_forward, e_up);
2733     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2734                 e.angles = AnglesTransform_ToVAngles(e.angles);
2735         else
2736                 e.angles = AnglesTransform_ToAngles(e.angles);
2737
2738     setattachment(e, to, tag);
2739     setorigin(e, e.origin);
2740 }
2741
2742 void detach_sameorigin(entity e)
2743 {
2744     vector org;
2745     org = gettaginfo(e, 0);
2746     e.angles = fixedvectoangles2(v_forward, v_up);
2747     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2748                 e.angles = AnglesTransform_ToVAngles(e.angles);
2749         else
2750                 e.angles = AnglesTransform_ToAngles(e.angles);
2751     setorigin(e, org);
2752     setattachment(e, world, "");
2753     setorigin(e, e.origin);
2754 }
2755
2756 void follow_sameorigin(entity e, entity to)
2757 {
2758     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2759     e.aiment = to; // make the hole follow bmodel
2760     e.punchangle = to.angles; // the original angles of bmodel
2761     e.view_ofs = e.origin - to.origin; // relative origin
2762     e.v_angle = e.angles - to.angles; // relative angles
2763 }
2764
2765 void unfollow_sameorigin(entity e)
2766 {
2767     e.movetype = MOVETYPE_NONE;
2768 }
2769
2770 entity gettaginfo_relative_ent;
2771 vector gettaginfo_relative(entity e, float tag)
2772 {
2773     if (!gettaginfo_relative_ent)
2774     {
2775         gettaginfo_relative_ent = spawn();
2776         gettaginfo_relative_ent.effects = EF_NODRAW;
2777     }
2778     gettaginfo_relative_ent.model = e.model;
2779     gettaginfo_relative_ent.modelindex = e.modelindex;
2780     gettaginfo_relative_ent.frame = e.frame;
2781     return gettaginfo(gettaginfo_relative_ent, tag);
2782 }
2783
2784 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2785 {
2786     float p;
2787     p = pow(2, chan);
2788     if (pl.soundentity.cnt & p)
2789         return;
2790     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2791     pl.soundentity.cnt |= p;
2792 }
2793
2794 void SoundEntity_StopSound(entity pl, float chan)
2795 {
2796     float p;
2797     p = pow(2, chan);
2798     if (pl.soundentity.cnt & p)
2799     {
2800         stopsoundto(MSG_ALL, pl.soundentity, chan);
2801         pl.soundentity.cnt &~= p;
2802     }
2803 }
2804
2805 void SoundEntity_Attach(entity pl)
2806 {
2807     pl.soundentity = spawn();
2808     pl.soundentity.classname = "soundentity";
2809     pl.soundentity.owner = pl;
2810     setattachment(pl.soundentity, pl, "");
2811     setmodel(pl.soundentity, "null");
2812 }
2813
2814 void SoundEntity_Detach(entity pl)
2815 {
2816     float i;
2817     for (i = 0; i <= 7; ++i)
2818         SoundEntity_StopSound(pl, i);
2819 }
2820
2821
2822 float ParseCommandPlayerSlotTarget_firsttoken;
2823 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2824 {
2825         string s;
2826         entity e, head;
2827         float n;
2828
2829         s = string_null;
2830
2831         ParseCommandPlayerSlotTarget_firsttoken = -1;
2832
2833         if (tokens > idx)
2834         {
2835                 if (substring(argv(idx), 0, 1) == "#")
2836                 {
2837                         s = substring(argv(idx), 1, -1);
2838                         ++idx;
2839                         if (s == "") if (tokens > idx)
2840                         {
2841                                 s = argv(idx);
2842                                 ++idx;
2843                         }
2844                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2845                         n = stof(s);
2846                         if (s == ftos(n) && n > 0 && n <= maxclients)
2847                         {
2848                                 e = edict_num(n);
2849                                 if (e.flags & FL_CLIENT)
2850                                         return e;
2851                         }
2852                 }
2853                 else
2854                 {
2855                         // it must be a nick name
2856                         s = argv(idx);
2857                         ++idx;
2858                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2859
2860                         n = 0;
2861                         FOR_EACH_CLIENT(head)
2862                                 if (head.netname == s)
2863                                 {
2864                                         e = head;
2865                                         ++n;
2866                                 }
2867                         if (n == 1)
2868                                 return e;
2869
2870                         s = strdecolorize(s);
2871                         n = 0;
2872                         FOR_EACH_CLIENT(head)
2873                                 if (strdecolorize(head.netname) == s)
2874                                 {
2875                                         e = head;
2876                                         ++n;
2877                                 }
2878                         if (n == 1)
2879                                 return e;
2880                 }
2881         }
2882
2883         return world;
2884 }
2885
2886 .float scale2;
2887
2888 float modeleffect_SendEntity(entity to, float sf)
2889 {
2890         float f;
2891         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2892
2893         f = 0;
2894         if(self.velocity != '0 0 0')
2895                 f |= 1;
2896         if(self.angles != '0 0 0')
2897                 f |= 2;
2898         if(self.avelocity != '0 0 0')
2899                 f |= 4;
2900
2901         WriteByte(MSG_ENTITY, f);
2902         WriteShort(MSG_ENTITY, self.modelindex);
2903         WriteByte(MSG_ENTITY, self.skin);
2904         WriteByte(MSG_ENTITY, self.frame);
2905         WriteCoord(MSG_ENTITY, self.origin_x);
2906         WriteCoord(MSG_ENTITY, self.origin_y);
2907         WriteCoord(MSG_ENTITY, self.origin_z);
2908         if(f & 1)
2909         {
2910                 WriteCoord(MSG_ENTITY, self.velocity_x);
2911                 WriteCoord(MSG_ENTITY, self.velocity_y);
2912                 WriteCoord(MSG_ENTITY, self.velocity_z);
2913         }
2914         if(f & 2)
2915         {
2916                 WriteCoord(MSG_ENTITY, self.angles_x);
2917                 WriteCoord(MSG_ENTITY, self.angles_y);
2918                 WriteCoord(MSG_ENTITY, self.angles_z);
2919         }
2920         if(f & 4)
2921         {
2922                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2923                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2924                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2925         }
2926         WriteShort(MSG_ENTITY, self.scale * 256.0);
2927         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2928         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2929         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2930         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2931
2932         return TRUE;
2933 }
2934
2935 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2936 {
2937         entity e;
2938         float sz;
2939         e = spawn();
2940         e.classname = "modeleffect";
2941         setmodel(e, m);
2942         e.frame = f;
2943         setorigin(e, o);
2944         e.velocity = v;
2945         e.angles = ang;
2946         e.avelocity = angv;
2947         e.alpha = a;
2948         e.teleport_time = t1;
2949         e.fade_time = t2;
2950         e.skin = s;
2951         if(s0 >= 0)
2952                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2953         else
2954                 e.scale = -s0;
2955         if(s2 >= 0)
2956                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2957         else
2958                 e.scale2 = -s2;
2959         sz = max(e.scale, e.scale2);
2960         setsize(e, e.mins * sz, e.maxs * sz);
2961         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2962 }
2963
2964 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2965 {
2966         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2967 }
2968
2969 float randombit(float bits)
2970 {
2971         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2972                 return bits;
2973
2974         float n, f, b, r;
2975
2976         r = random();
2977         b = 0;
2978         n = 0;
2979
2980         for(f = 1; f <= bits; f *= 2)
2981         {
2982                 if(bits & f)
2983                 {
2984                         ++n;
2985                         r *= n;
2986                         if(r <= 1)
2987                                 b = f;
2988                         else
2989                                 r = (r - 1) / (n - 1);
2990                 }
2991         }
2992
2993         return b;
2994 }
2995
2996 float randombits(float bits, float k, float error_return)
2997 {
2998         float r;
2999         r = 0;
3000         while(k > 0 && bits != r)
3001         {
3002                 r += randombit(bits - r);
3003                 --k;
3004         }
3005         if(error_return)
3006                 if(k > 0)
3007                         return -1; // all
3008         return r;
3009 }
3010
3011 void randombit_test(float bits, float iter)
3012 {
3013         while(iter > 0)
3014         {
3015                 print(ftos(randombit(bits)), "\n");
3016                 --iter;
3017         }
3018 }
3019
3020 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3021 {
3022         if(halflifedist > 0)
3023                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3024         else if(halflifedist < 0)
3025                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3026         else
3027                 return 1;
3028 }
3029
3030
3031
3032
3033 #ifdef RELEASE
3034 #define cvar_string_normal builtin_cvar_string
3035 #define cvar_normal builtin_cvar
3036 #else
3037 string cvar_string_normal(string n)
3038 {
3039         if not(cvar_type(n) & 1)
3040                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3041         return builtin_cvar_string(n);
3042 }
3043
3044 float cvar_normal(string n)
3045 {
3046         return stof(cvar_string_normal(n));
3047 }
3048 #endif
3049 #define cvar_set_normal builtin_cvar_set
3050
3051 void defer_think()
3052 {
3053     entity oself;
3054
3055     oself           = self;
3056     self            = self.owner;
3057     oself.think     = SUB_Remove;
3058     oself.nextthink = time;
3059
3060     oself.use();
3061 }
3062
3063 /*
3064     Execute func() after time + fdelay.
3065     self when func is executed = self when defer is called
3066 */
3067 void defer(float fdelay, void() func)
3068 {
3069     entity e;
3070
3071     e           = spawn();
3072     e.owner     = self;
3073     e.use       = func;
3074     e.think     = defer_think;
3075     e.nextthink = time + fdelay;
3076 }
3077
3078 .string aiment_classname;
3079 .float aiment_deadflag;
3080 void SetMovetypeFollow(entity ent, entity e)
3081 {
3082         // FIXME this may not be warpzone aware
3083         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3084         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3085         ent.aiment = e; // make the hole follow bmodel
3086         ent.punchangle = e.angles; // the original angles of bmodel
3087         ent.view_ofs = ent.origin - e.origin; // relative origin
3088         ent.v_angle = ent.angles - e.angles; // relative angles
3089         ent.aiment_classname = strzone(e.classname);
3090         ent.aiment_deadflag = e.deadflag;
3091 }
3092 void UnsetMovetypeFollow(entity ent)
3093 {
3094         ent.movetype = MOVETYPE_FLY;
3095         PROJECTILE_MAKETRIGGER(ent);
3096         ent.aiment = world;
3097 }
3098 float LostMovetypeFollow(entity ent)
3099 {
3100 /*
3101         if(ent.movetype != MOVETYPE_FOLLOW)
3102                 if(ent.aiment)
3103                         error("???");
3104 */
3105         if(ent.aiment)
3106         {
3107                 if(ent.aiment.classname != ent.aiment_classname)
3108                         return 1;
3109                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3110                         return 1;
3111         }
3112         return 0;
3113 }
3114
3115 float isPushable(entity e)
3116 {
3117         if(e.iscreature)
3118                 return TRUE;
3119         switch(e.classname)
3120         {
3121                 case "body":
3122                 case "droppedweapon":
3123                 case "keepawayball":
3124                 case "nexball_basketball":
3125                 case "nexball_football":
3126                         return TRUE;
3127                 case "bullet": // antilagged bullets can't hit this either
3128                         return FALSE;
3129         }
3130         if (e.projectiledeathtype)
3131                 return TRUE;
3132         return FALSE;
3133 }